git.sur5r.net Git - freertos/blob - FreeRTOS/Demo/CORTEX_R5_UltraScale_MPSoC/RTOSDemo_R5_bsp/psu_cortexr5_0/libsrc/standalone_v6_6/src/xil-crt0.S

   1 /******************************************************************************
   2 *
   3 * Copyright (C) 2014 - 2017 Xilinx, Inc. All rights reserved.
   4 *
   5 * Permission is hereby granted, free of charge, to any person obtaining a copy
   6 * of this software and associated documentation files (the "Software"), to deal
   7 * in the Software without restriction, including without limitation the rights
   8 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   9 * copies of the Software, and to permit persons to whom the Software is
  10 * furnished to do so, subject to the following conditions:
  11 *
  12 * The above copyright notice and this permission notice shall be included in
  13 * all copies or substantial portions of the Software.
  14 *
  15 * Use of the Software is limited solely to applications:
  16 * (a) running on a Xilinx device, or
  17 * (b) that interact with a Xilinx device through a bus or interconnect.
  18 *
  19 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  20 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
  22 * XILINX  BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
  23 * WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF
  24 * OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  25 * SOFTWARE.
  26 *
  27 * Except as contained in this notice, the name of the Xilinx shall not be used
  28 * in advertising or otherwise to promote the sale, use or other dealings in
  29 * this Software without prior written authorization from Xilinx.
  30 *
  31 ******************************************************************************/
  32 /*****************************************************************************/
  33 /**
  34 * @file xil-crt0.S
  35 *
  36 * <pre>
  37 * MODIFICATION HISTORY:
  38 *
  39 * Ver   Who  Date     Changes
  40 * ----- ---- -------- ---------------------------------------------------
  41 * 5.00  pkp  02/10/14 First release
  42 * 5.04  pkp  12/18/15 Initialized global constructor for C++ applications
  43 * 5.04  pkp  02/19/16 Added timer configuration using XTime_StartTimer API when
  44 *                     TTC3 is present
  45 * 6.4   asa  08/16/17 Added call to Xil_InitializeExistingMPURegConfig to
  46 *                     initialize the MPU configuration table with the MPU
  47 *                     configurations already set in Init_Mpu function.
  48 * 6.6   srm  10/18/17 Updated the timer configuration with XTime_StartTTCTimer.
  49 *                     Now the timer instance as specified by the user will be
  50 *                     started.
  51 * </pre>
  52 *
  53 * @note
  54 *
  55 * None.
  56 *
  57 ******************************************************************************/
  58 #include "xparameters.h"
  59         .file   "xil-crt0.S"
  60         .section ".got2","aw"
  61         .align  2
  62
  63         .text
  64 .Lsbss_start:
  65         .long   __sbss_start
  66
  67 .Lsbss_end:
  68         .long   __sbss_end
  69
  70 .Lbss_start:
  71         .long   __bss_start__
  72
  73 .Lbss_end:
  74         .long   __bss_end__
  75
  76 .Lstack:
  77         .long   __stack
  78
  79 .set RPU_0_PWRCTL,      0xFF9A0108
  80 .set RPU_1_PWRCTL,      0xFF9A0208
  81 .set MPIDR_AFF0,        0xFF
  82 .set PWRCTL_MASK,       0x1
  83
  84         .globl  _startup
  85
  86 _startup:
  87         bl      __cpu_init              /* Initialize the CPU first (BSP provides this) */
  88         mrc     p15, 0, r0,  c0,  c0, 5 /* Read MPIDR register */
  89         ands    r0, r0, #MPIDR_AFF0     /* Get affinity level 0 */
  90         bne     core1
  91         ldr     r10, =RPU_0_PWRCTL      /* Load PWRCTRL address for core 0 */
  92         b       test_boot_status
  93
  94 core1:
  95         ldr     r10, =RPU_1_PWRCTL      /* Load PWRCTRL address for core 1 */
  96
  97 test_boot_status:
  98         ldr     r11, [r10]              /* Read PWRCTRL register */
  99         ands    r11, r11, #PWRCTL_MASK  /* Extract and test core's PWRCTRL */
 100
 101         /* if warm reset, skip the clearing of BSS and SBSS */
 102         bne     .Lenclbss
 103
 104         mov     r0, #0
 105
 106         /* clear sbss */
 107         ldr     r1,.Lsbss_start         /* calculate beginning of the SBSS */
 108         ldr     r2,.Lsbss_end           /* calculate end of the SBSS */
 109
 110 .Lloop_sbss:
 111         cmp     r1,r2
 112         bge     .Lenclsbss              /* If no SBSS, no clearing required */
 113         str     r0, [r1], #4
 114         b       .Lloop_sbss
 115
 116 .Lenclsbss:
 117         /* clear bss */
 118         ldr     r1,.Lbss_start          /* calculate beginning of the BSS */
 119         ldr     r2,.Lbss_end            /* calculate end of the BSS */
 120
 121 .Lloop_bss:
 122         cmp     r1,r2
 123         bge     .Lenclbss               /* If no BSS, no clearing required */
 124         str     r0, [r1], #4
 125         b       .Lloop_bss
 126
 127 .Lenclbss:
 128
 129         /* set stack pointer */
 130         ldr     r13,.Lstack             /* stack address */
 131
 132         /* configure the timer if TTC is present */
 133 #ifdef SLEEP_TIMER_BASEADDR
 134     bl XTime_StartTTCTimer
 135 #endif
 136         bl      Xil_InitializeExistingMPURegConfig      /* Initialize MPU config */
 137         /* run global constructors */
 138         bl __libc_init_array
 139
 140         /* make sure argc and argv are valid */
 141         mov     r0, #0
 142         mov     r1, #0
 143
 144         bl      main                    /* Jump to main C code */
 145
 146         /* Cleanup global constructors */
 147         bl __libc_fini_array
 148
 149         bl      exit
 150
 151 .Lexit: /* should never get here */
 152         b .Lexit
 153
 154 .Lstart:
 155         .size   _startup,.Lstart-_startup