git.sur5r.net Git - freertos/blob - FreeRTOS/Source/portable/IAR/ARM_CA9/portASM.h

   1 ;/*\r
   2 ;    FreeRTOS V8.0.0 - Copyright (C) 2014 Real Time Engineers Ltd.\r
   3 ;    All rights reserved\r
   4 ;\r
   5 ;\r
   6 ;    ***************************************************************************\r
   7 ;     *                                                                       *\r
   8 ;     *    FreeRTOS tutorial books are available in pdf and paperback.        *\r
   9 ;     *    Complete, revised, and edited pdf reference manuals are also       *\r
  10 ;     *    available.                                                         *\r
  11 ;     *                                                                       *\r
  12 ;     *    Purchasing FreeRTOS documentation will not only help you, by       *\r
  13 ;     *    ensuring you get running as quickly as possible and with an        *\r
  14 ;     *    in-depth knowledge of how to use FreeRTOS, it will also help       *\r
  15 ;     *    the FreeRTOS project to continue with its mission of providing     *\r
  16 ;     *    professional grade, cross platform, de facto standard solutions    *\r
  17 ;     *    for microcontrollers - completely free of charge!                  *\r
  18 ;     *                                                                       *\r
  19 ;     *    >>> See http://www.FreeRTOS.org/Documentation for details. <<<     *\r
  20 ;     *                                                                       *\r
  21 ;     *    Thank you for using FreeRTOS, and thank you for your support!      *\r
  22 ;     *                                                                       *\r
  23 ;    ***************************************************************************\r
  24 ;\r
  25 ;\r
  26 ;    This file is part of the FreeRTOS distribution.\r
  27 ;\r
  28 ;    FreeRTOS is free software; you can redistribute it and/or modify it under\r
  29 ;    the terms of the GNU General Public License (version 2) as published by the\r
  30 ;    Free Software Foundation AND MODIFIED BY the FreeRTOS exception.\r
  31 ;    >>>NOTE<<< The modification to the GPL is included to allow you to\r
  32 ;    distribute a combined work that includes FreeRTOS without being obliged to\r
  33 ;    provide the source code for proprietary components outside of the FreeRTOS\r
  34 ;    kernel.  FreeRTOS is distributed in the hope that it will be useful, but\r
  35 ;    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY\r
  36 ;    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License for\r
  37 ;    more details. You should have received a copy of the GNU General Public\r
  38 ;    License and the FreeRTOS license exception along with FreeRTOS; if not it\r
  39 ;    can be viewed here: http://www.freertos.org/a00114.html and also obtained\r
  40 ;    by writing to Richard Barry, contact details for whom are available on the\r
  41 ;    FreeRTOS WEB site.\r
  42 ;\r
  43 ;    1 tab == 4 spaces!\r
  44 ;\r
  45 ;    http://www.FreeRTOS.org - Documentation, latest information, license and\r
  46 ;    contact details.\r
  47 ;\r
  48 ;    http://www.SafeRTOS.com - A version that is certified for use in safety\r
  49 ;    critical systems.\r
  50 ;\r
  51 ;    http://www.OpenRTOS.com - Commercial support, development, porting,\r
  52 ;    licensing and training services.\r
  53 ;*/\r
  54 \r
  55         EXTERN  vTaskSwitchContext\r
  56         EXTERN  ulCriticalNesting\r
  57         EXTERN  pxCurrentTCB\r
  58         EXTERN  ulPortTaskHasFPUContext\r
  59         EXTERN  ulAsmAPIPriorityMask\r
  60 \r
  61 portSAVE_CONTEXT macro\r
  62 \r
  63         ; Save the LR and SPSR onto the system mode stack before switching to\r
  64         ; system mode to save the remaining system mode registers\r
  65         SRSDB   sp!, #SYS_MODE\r
  66         CPS             #SYS_MODE\r
  67         PUSH    {R0-R12, R14}\r
  68 \r
  69         ; Push the critical nesting count\r
  70         LDR             R2, =ulCriticalNesting\r
  71         LDR             R1, [R2]\r
  72         PUSH    {R1}\r
  73 \r
  74         ; Does the task have a floating point context that needs saving?  If\r
  75         ; ulPortTaskHasFPUContext is 0 then no.\r
  76         LDR             R2, =ulPortTaskHasFPUContext\r
  77         LDR             R3, [R2]\r
  78         CMP             R3, #0\r
  79 \r
  80         ; Save the floating point context, if any\r
  81         FMRXNE  R1,  FPSCR\r
  82         VPUSHNE {D0-D15}\r
  83         VPUSHNE {D16-D31}\r
  84         PUSHNE  {R1}\r
  85 \r
  86         ; Save ulPortTaskHasFPUContext itself\r
  87         PUSH    {R3}\r
  88 \r
  89         ; Save the stack pointer in the TCB\r
  90         LDR             R0, =pxCurrentTCB\r
  91         LDR             R1, [R0]\r
  92         STR             SP, [R1]\r
  93 \r
  94         endm\r
  95 \r
  96 ; /**********************************************************************/\r
  97 \r
  98 portRESTORE_CONTEXT macro\r
  99 \r
 100         ; Switch to system mode\r
 101         CPS             #SYS_MODE\r
 102 \r
 103         ; Set the SP to point to the stack of the task being restored.\r
 104         LDR             R0, =pxCurrentTCB\r
 105         LDR             R1, [R0]\r
 106         LDR             SP, [R1]\r
 107 \r
 108         ; Is there a floating point context to restore?  If the restored\r
 109         ; ulPortTaskHasFPUContext is zero then no.\r
 110         LDR             R0, =ulPortTaskHasFPUContext\r
 111         POP             {R1}\r
 112         STR             R1, [R0]\r
 113         CMP             R1, #0\r
 114 \r
 115         ; Restore the floating point context, if any\r
 116         POPNE   {R0}\r
 117         VPOPNE  {D16-D31}\r
 118         VPOPNE  {D0-D15}\r
 119         VMSRNE  FPSCR, R0\r
 120 \r
 121         ; Restore the critical section nesting depth\r
 122         LDR             R0, =ulCriticalNesting\r
 123         POP             {R1}\r
 124         STR             R1, [R0]\r
 125 \r
 126         ; Ensure the priority mask is correct for the critical nesting depth\r
 127         LDR             R2, =portICCPMR_PRIORITY_MASK_REGISTER_ADDRESS\r
 128         CMP             R1, #0\r
 129         MOVEQ   R4, #255\r
 130         LDRNE   R4, =( configMAX_API_CALL_INTERRUPT_PRIORITY << portPRIORITY_SHIFT )\r
 131         STR             R4, [r2]\r
 132 \r
 133         ; Restore all system mode registers other than the SP (which is already\r
 134         ; being used)\r
 135         POP             {R0-R12, R14}\r
 136 \r
 137         ; Return to the task code, loading CPSR on the way.\r
 138         RFEIA   sp!\r
 139 \r
 140         endm\r
 141 \r
 142 \r
 143 \r
 144 \r
 145 \r