git.sur5r.net Git - freertos/blob - Source/portable/IAR/STR91x/ISR_Support.h

   1 /*\r
   2         FreeRTOS.org V5.3.1 - Copyright (C) 2003-2009 Richard Barry.\r
   3 \r
   4         This file is part of the FreeRTOS.org distribution.\r
   5 \r
   6         FreeRTOS.org is free software; you can redistribute it and/or modify it\r
   7         under the terms of the GNU General Public License (version 2) as published\r
   8         by the Free Software Foundation and modified by the FreeRTOS exception.\r
   9         **NOTE** The exception to the GPL is included to allow you to distribute a\r
  10         combined work that includes FreeRTOS.org without being obliged to provide\r
  11         the source code for any proprietary components.  Alternative commercial\r
  12         license and support terms are also available upon request.  See the \r
  13         licensing section of http://www.FreeRTOS.org for full details.\r
  14 \r
  15         FreeRTOS.org is distributed in the hope that it will be useful, but WITHOUT\r
  16         ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or\r
  17         FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License for\r
  18         more details.\r
  19 \r
  20         You should have received a copy of the GNU General Public License along\r
  21         with FreeRTOS.org; if not, write to the Free Software Foundation, Inc., 59\r
  22         Temple Place, Suite 330, Boston, MA  02111-1307  USA.\r
  23 \r
  24 \r
  25         ***************************************************************************\r
  26         *                                                                         *\r
  27         * Get the FreeRTOS eBook!  See http://www.FreeRTOS.org/Documentation      *\r
  28         *                                                                         *\r
  29         * This is a concise, step by step, 'hands on' guide that describes both   *\r
  30         * general multitasking concepts and FreeRTOS specifics. It presents and   *\r
  31         * explains numerous examples that are written using the FreeRTOS API.     *\r
  32         * Full source code for all the examples is provided in an accompanying    *\r
  33         * .zip file.                                                              *\r
  34         *                                                                         *\r
  35         ***************************************************************************\r
  36 \r
  37         1 tab == 4 spaces!\r
  38 \r
  39         Please ensure to read the configuration and relevant port sections of the\r
  40         online documentation.\r
  41 \r
  42         http://www.FreeRTOS.org - Documentation, latest information, license and\r
  43         contact details.\r
  44 \r
  45         http://www.SafeRTOS.com - A version that is certified for use in safety\r
  46         critical systems.\r
  47 \r
  48         http://www.OpenRTOS.com - Commercial support, development, porting,\r
  49         licensing and training services.\r
  50 */\r
  51 \r
  52         EXTERN pxCurrentTCB\r
  53         EXTERN ulCriticalNesting\r
  54 \r
  55 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;\r
  56 ; Context save and restore macro definitions\r
  57 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;\r
  58 \r
  59 portSAVE_CONTEXT MACRO\r
  60 \r
  61         ; Push R0 as we are going to use the register.                                  \r
  62         STMDB   SP!, {R0}\r
  63 \r
  64         ; Set R0 to point to the task stack pointer.                                    \r
  65         STMDB   SP, {SP}^\r
  66         NOP\r
  67         SUB             SP, SP, #4\r
  68         LDMIA   SP!, {R0}\r
  69 \r
  70         ; Push the return address onto the stack.                                               \r
  71         STMDB   R0!, {LR}\r
  72 \r
  73         ; Now we have saved LR we can use it instead of R0.                             \r
  74         MOV             LR, R0\r
  75 \r
  76         ; Pop R0 so we can save it onto the system mode stack.                  \r
  77         LDMIA   SP!, {R0}\r
  78 \r
  79         ; Push all the system mode registers onto the task stack.               \r
  80         STMDB   LR, {R0-LR}^\r
  81         NOP\r
  82         SUB             LR, LR, #60\r
  83 \r
  84         ; Push the SPSR onto the task stack.                                                    \r
  85         MRS             R0, SPSR\r
  86         STMDB   LR!, {R0}\r
  87 \r
  88         LDR             R0, =ulCriticalNesting \r
  89         LDR             R0, [R0]\r
  90         STMDB   LR!, {R0}\r
  91 \r
  92         ; Store the new top of stack for the task.                                              \r
  93         LDR             R1, =pxCurrentTCB\r
  94         LDR             R0, [R1]\r
  95         STR             LR, [R0]\r
  96 \r
  97         ENDM\r
  98 \r
  99 \r
 100 portRESTORE_CONTEXT MACRO\r
 101 \r
 102         ; Set the LR to the task stack.                                                                         \r
 103         LDR             R1, =pxCurrentTCB\r
 104         LDR             R0, [R1]\r
 105         LDR             LR, [R0]\r
 106 \r
 107         ; The critical nesting depth is the first item on the stack.    \r
 108         ; Load it into the ulCriticalNesting variable.                                  \r
 109         LDR             R0, =ulCriticalNesting\r
 110         LDMFD   LR!, {R1}\r
 111         STR             R1, [R0]\r
 112 \r
 113         ; Get the SPSR from the stack.                                                                  \r
 114         LDMFD   LR!, {R0}\r
 115         MSR             SPSR_cxsf, R0\r
 116 \r
 117         ; Restore all system mode registers for the task.                               \r
 118         LDMFD   LR, {R0-R14}^\r
 119         NOP\r
 120 \r
 121         ; Restore the return address.                                                                   \r
 122         LDR             LR, [LR, #+60]\r
 123 \r
 124         ; And return - correcting the offset in the LR to obtain the    \r
 125         ; correct address.                                                                                              \r
 126         SUBS    PC, LR, #4\r
 127 \r
 128         ENDM\r
 129 \r