git.sur5r.net Git - openldap/blob - aclocal.m4

   1 dnl
   2 dnl OpenLDAP Autoconf Macros
   3 dnl
   4 dnl --------------------------------------------------------------------
   5 dnl Restricted form of AC_ARG_ENABLE that limits user options
   6 dnl
   7 dnl $1 = option name
   8 dnl $2 = help-string
   9 dnl $3 = default value  (auto)
  10 dnl $4 = allowed values (auto yes no)
  11 AC_DEFUN([OL_ARG_ENABLE], [# OpenLDAP --enable-$1
  12         AC_ARG_ENABLE($1,[$2 (]ifelse($3,,auto,$3)[)],[
  13         ol_arg=invalid
  14         for ol_val in ifelse($4,,[auto yes no],[$4]) ; do
  15                 if test "$enableval" = "$ol_val" ; then
  16                         ol_arg="$ol_val"
  17                 fi
  18         done
  19         if test "$ol_arg" = "invalid" ; then
  20                 AC_MSG_ERROR(bad value $enableval for --enable-$1)
  21         fi
  22         ol_enable_$1="$ol_arg"
  23 ],
  24 [       ol_enable_$1=ifelse($3,,"auto","$3")])dnl
  25 dnl AC_VERBOSE(OpenLDAP -enable-$1 $ol_enable_$1)
  26 # end --enable-$1
  27 ])dnl
  28 dnl
  29 dnl --------------------------------------------------------------------
  30 dnl Restricted form of AC_ARG_WITH that limits user options
  31 dnl
  32 dnl $1 = option name
  33 dnl $2 = help-string
  34 dnl $3 = default value (no)
  35 dnl $4 = allowed values (yes or no)
  36 AC_DEFUN([OL_ARG_WITH], [# OpenLDAP --with-$1
  37         AC_ARG_WITH($1,[$2 (]ifelse($3,,yes,$3)[)],[
  38         ol_arg=invalid
  39         for ol_val in ifelse($4,,[yes no],[$4]) ; do
  40                 if test "$withval" = "$ol_val" ; then
  41                         ol_arg="$ol_val"
  42                 fi
  43         done
  44         if test "$ol_arg" = "invalid" ; then
  45                 AC_MSG_ERROR(bad value $withval for --with-$1)
  46         fi
  47         ol_with_$1="$ol_arg"
  48 ],
  49 [       ol_with_$1=ifelse($3,,"no","$3")])dnl
  50 dnl AC_VERBOSE(OpenLDAP --with-$1 $ol_with_$1)
  51 # end --with-$1
  52 ])dnl
  53 dnl
  54 dnl ====================================================================
  55 dnl Check if db.h is Berkeley DB2
  56 dnl
  57 dnl defines ol_cv_header_db2 to 'yes' or 'no'
  58 dnl
  59 dnl uses:
  60 dnl             AC_CHECK_HEADERS(db.h)
  61 dnl
  62 AC_DEFUN([OL_HEADER_BERKELEY_DB2],
  63 [AC_CHECK_HEADERS(db.h)
  64 if test $ac_cv_header_db_h = yes ; then
  65         AC_CACHE_CHECK([if db.h is DB2], [ol_cv_header_db2],[
  66                 AC_EGREP_CPP(__db_version_2,[
  67 #                       include <db.h>
  68                         /* this check could be improved */
  69 #                       ifdef DB_VERSION_MAJOR
  70 #                               if DB_VERSION_MAJOR == 2
  71                                         __db_version_2
  72 #                               endif
  73 #                       endif
  74                 ], ol_cv_header_db2=yes, ol_cv_header_db2=no)])
  75 fi
  76 ])dnl
  77 dnl --------------------------------------------------------------------
  78 dnl Check if Berkeley DB2 library exists
  79 dnl Check for dbopen in standard libraries or -ldb
  80 dnl
  81 dnl defines ol_cv_lib_db2 to '-ldb' or 'no'
  82 dnl
  83 dnl uses:
  84 dnl             AC_CHECK_LIB(db,db_open)
  85 dnl
  86 AC_DEFUN([OL_LIB_BERKELEY_DB2],
  87 [AC_CACHE_CHECK([for DB2 library], [ol_cv_lib_db2],
  88 [       ol_LIBS="$LIBS"
  89         AC_CHECK_LIB(db,db_open,[ol_cv_lib_db2=-ldb],[ol_cv_lib_db2=no])
  90         LIBS="$ol_LIBS"
  91 ])
  92 ])dnl
  93 dnl
  94 dnl --------------------------------------------------------------------
  95 dnl Check if Berkeley db2 exists
  96 dnl
  97 dnl defines ol_cv_berkeley_db2 to 'yes' or 'no'
  98 dnl
  99 dnl uses:
 100 dnl             OL_LIB_BERKELEY_DB2
 101 dnl             OL_HEADER_BERKELEY_DB2
 102 dnl
 103 AC_DEFUN([OL_BERKELEY_DB2],
 104 [AC_REQUIRE([OL_LIB_BERKELEY_DB2])
 105  AC_REQUIRE([OL_HEADER_BERKELEY_DB2])
 106  AC_CACHE_CHECK([for Berkeley DB2], [ol_cv_berkeley_db2], [
 107         if test $ol_cv_lib_db2 = no -o $ol_cv_header_db2 = no ; then
 108                 ol_cv_berkeley_db2=no
 109         else
 110                 ol_cv_berkeley_db2=yes
 111         fi
 112 ])
 113 ])dnl
 114 dnl
 115 dnl ====================================================================
 116 dnl Check for db.h/db_185.h is Berkeley DB
 117 dnl
 118 dnl defines ol_cv_header_db to 'yes' or 'no'
 119 dnl
 120 dnl uses:
 121 dnl             OL_HEADER_BERKELEY_DB2
 122 dnl             AC_CHECK_HEADERS(db_185.h)
 123 dnl
 124 AC_DEFUN([OL_HEADER_BERKELEY_DB],
 125 [AC_REQUIRE([OL_HEADER_BERKELEY_DB2])
 126 AC_CHECK_HEADERS(db_185.h)
 127 if test $ol_cv_header_db2 = yes ; then
 128         dnl db.h is db2!
 129
 130         ol_cv_header_db=$ac_cv_header_db_185_h
 131 else
 132         ol_cv_header_db=$ac_cv_header_db_h
 133 fi
 134 ])dnl
 135 dnl
 136 dnl --------------------------------------------------------------------
 137 dnl Check if Berkeley DB library exists
 138 dnl Check for dbopen in standard libraries or -ldb
 139 dnl
 140 dnl defines ol_cv_lib_db to 'yes' or '-ldb' or 'no'
 141 dnl             'yes' implies dbopen is in $LIBS
 142 dnl
 143 dnl uses:
 144 dnl             AC_CHECK_FUNC(dbopen)
 145 dnl             AC_CHECK_LIB(db,dbopen)
 146 dnl
 147 AC_DEFUN([OL_LIB_BERKELEY_DB],
 148 [AC_CACHE_CHECK([for Berkeley DB library], [ol_cv_lib_db],
 149 [       ol_LIBS="$LIBS"
 150         AC_CHECK_FUNC(dbopen,[ol_cv_lib_db=yes], [
 151                 AC_CHECK_LIB(db,dbopen,[ol_cv_lib_db=-ldb],[ol_cv_lib_db=no])
 152         ])
 153         LIBS="$ol_LIBS"
 154 ])
 155 ])dnl
 156 dnl
 157 dnl --------------------------------------------------------------------
 158 dnl Check if Berkeley DB exists
 159 dnl
 160 dnl defines ol_cv_berkeley_db to 'yes' or 'no'
 161 dnl
 162 dnl uses:
 163 dnl             OL_LIB_BERKELEY_DB
 164 dnl             OL_HEADER_BERKELEY_DB
 165 dnl
 166 AC_DEFUN([OL_BERKELEY_DB],
 167 [AC_REQUIRE([OL_LIB_BERKELEY_DB])
 168  AC_REQUIRE([OL_HEADER_BERKELEY_DB])
 169  AC_CACHE_CHECK([for Berkeley DB], [ol_cv_berkeley_db], [
 170         if test $ol_cv_lib_db = no -o $ol_cv_header_db = no ; then
 171                 ol_cv_berkeley_db=no
 172         else
 173                 ol_cv_berkeley_db=yes
 174         fi
 175 ])
 176 ])dnl
 177 dnl
 178 dnl ====================================================================
 179 dnl Check if GDBM library exists
 180 dnl Check for gdbm_open in standard libraries or -lgdbm
 181 AC_DEFUN([OL_LIB_GDBM],
 182 [AC_CACHE_CHECK(for GDBM library, [ol_cv_lib_gdbm],
 183 [       ol_LIBS="$LIBS"
 184         AC_CHECK_FUNC(gdbm_open,[ol_cv_lib_gdbm=yes], [
 185                 AC_CHECK_LIB(gdbm,gdbm_open,[ol_cv_lib_gdbm=-lgdbm],[ol_cv_lib_gdbm=no])
 186         ])
 187         LIBS="$ol_LIBS"
 188 ])
 189 ])dnl
 190 dnl
 191 dnl --------------------------------------------------------------------
 192 dnl Check if GDBM exists
 193 AC_DEFUN([OL_GDBM],
 194 [AC_REQUIRE([OL_LIB_GDBM])
 195  AC_CHECK_HEADERS(gdbm.h)
 196  AC_CACHE_CHECK(for db, [ol_cv_gdbm], [
 197         if test $ol_cv_lib_gdbm = no -o $ac_cv_header_gdbm_h = no ; then
 198                 ol_cv_gdbm=no
 199         else
 200                 ol_cv_gdbm=yes
 201         fi
 202 ])
 203 ])dnl
 204 dnl
 205 dnl ====================================================================
 206 dnl Check if NDBM library exists
 207 dnl Check for dbm_open in standard libraries or -lndbm or -ldbm
 208 AC_DEFUN([OL_LIB_NDBM],
 209 [AC_CACHE_CHECK(for NDBM library, [ol_cv_lib_ndbm],
 210 [       ol_LIBS="$LIBS"
 211         AC_CHECK_FUNC(dbm_open,[ol_cv_lib_ndbm=yes], [
 212                 AC_CHECK_LIB(ndbm,dbm_open,[ol_cv_lib_ndbm=-lndbm], [
 213                         AC_CHECK_LIB(dbm,dbm_open,[ol_cv_lib_ndbm=-ldbm],
 214                                 [ol_cv_lib_ndbm=no])dnl
 215                 ])
 216         ])
 217         LIBS="$ol_LIBS"
 218 ])
 219 ])dnl
 220 dnl
 221 dnl --------------------------------------------------------------------
 222 dnl Check if NDBM exists
 223 AC_DEFUN([OL_NDBM],
 224 [AC_REQUIRE([OL_LIB_NDBM])
 225  AC_CHECK_HEADERS(ndbm.h)
 226  AC_CACHE_CHECK(for db, [ol_cv_ndbm], [
 227         if test $ol_cv_lib_ndbm = no -o $ac_cv_header_ndbm_h = no ; then
 228                 ol_cv_ndbm=no
 229         else
 230                 ol_cv_ndbm=yes
 231         fi
 232 ])
 233 ])dnl
 234 dnl
 235 dnl ====================================================================
 236 dnl Check POSIX Thread version
 237 AC_DEFUN([OL_POSIX_THREAD_VERSION],
 238 [AC_CACHE_CHECK([POSIX thread version],[ol_cv_pthread_version],[
 239         AC_EGREP_CPP(final,[
 240 #               include <pthread.h>
 241                 /* this check could be improved */
 242 #               ifdef PTHREAD_ONCE_INIT
 243                         final
 244 #               endif
 245         ], ol_pthread_final=yes, ol_pthread_final=no)
 246
 247         AC_EGREP_CPP(draft4,[
 248 #               include <pthread.h>
 249                 /* this check could be improved */
 250 #               ifdef pthread_once_init
 251                         draft4
 252 #               endif
 253         ], ol_pthread_draft4=yes, ol_pthread_draft4=no)
 254
 255         if test $ol_pthread_final = yes -a $ol_pthread_draft4 = no; then
 256                 ol_cv_pthread_version=final
 257         elif test $ol_pthread_final = no -a $ol_pthread_draft4 = yes; then
 258                 ol_cv_pthread_version=draft4
 259         else
 260                 ol_cv_pthread_version=unknown
 261         fi
 262 ])
 263 ])dnl
 264 dnl
 265 dnl --------------------------------------------------------------------
 266 dnl Check LinuxThread
 267 AC_DEFUN([OL_LINUX_THREADS],
 268 [
 269 AC_CACHE_CHECK([for LinuxThreads], [ol_cv_linux_threads], [
 270         res=`grep Linuxthreads /usr/include/pthread.h 2>/dev/null | wc -l`
 271         if test "$res" -gt 0 ; then
 272                 ol_cv_linux_threads=yes
 273         else
 274                 ol_cv_linux_threads=no
 275         fi
 276 ])
 277 ])dnl
 278 dnl
 279 dnl ====================================================================
 280 dnl Check for declaration of sys_errlist in one of stdio.h and errno.h.
 281 dnl Declaration of sys_errlist on BSD4.4 interferes with our declaration.
 282 dnl Reported by Keith Bostic.
 283 AC_DEFUN([OL_SYS_ERRLIST],
 284 [
 285 AC_MSG_CHECKING([declaration of sys_errlist])
 286 AC_CACHE_VAL(ol_cv_dcl_sys_errlist,[
 287         AC_TRY_COMPILE([
 288 #include <stdio.h>
 289 #include <sys/types.h>
 290 #include <errno.h> ],
 291         [char *c = (char *) *sys_errlist],
 292         [ol_cv_dcl_sys_errlist=yes],
 293         [ol_cv_dcl_sys_errlist=no])])
 294 AC_MSG_RESULT($ol_cv_dcl_sys_errlist)
 295
 296 # It's possible (for near-UNIX clones) that sys_errlist doesn't exist
 297 if test $ol_cv_dcl_sys_errlist = no ; then
 298         AC_DEFINE(DECL_SYS_ERRLIST)
 299         AC_MSG_CHECKING([existence of sys_errlist])
 300         AC_CACHE_VAL(ol_cv_have_sys_errlist,[
 301                 AC_TRY_LINK([#include <errno.h>],
 302                         [char *c = (char *) *sys_errlist],
 303                         [ol_cv_have_sys_errlist=yes],
 304                         [ol_cv_have_sys_errlist=no])])
 305         AC_MSG_RESULT($ol_cv_have_sys_errlist)
 306 fi
 307 ])dnl