git.sur5r.net Git - openldap/blob - aclocal.m4

   1 dnl
   2 dnl OpenLDAP Autoconf Macros
   3 dnl
   4 dnl --------------------------------------------------------------------
   5 dnl Restricted form of AC_ARG_ENABLE that limits user options
   6 dnl
   7 dnl $1 = option name
   8 dnl $2 = help-string
   9 dnl $3 = default value  (auto)
  10 dnl $4 = allowed values (auto yes no)
  11 AC_DEFUN([OL_ARG_ENABLE], [# OpenLDAP --enable-$1
  12         AC_ARG_ENABLE($1,[$2 (]ifelse($3,,auto,$3)[)],[
  13         ol_arg=invalid
  14         for ol_val in ifelse($4,,[auto yes no],[$4]) ; do
  15                 if test "$enableval" = "$ol_val" ; then
  16                         ol_arg="$ol_val"
  17                 fi
  18         done
  19         if test "$ol_arg" = "invalid" ; then
  20                 AC_MSG_ERROR(bad value $enableval for --enable-$1)
  21         fi
  22         ol_enable_$1="$ol_arg"
  23 ],
  24 [       ol_enable_$1=ifelse($3,,"auto","$3")])dnl
  25 dnl AC_VERBOSE(OpenLDAP -enable-$1 $ol_enable_$1)
  26 # end --enable-$1
  27 ])dnl
  28 dnl
  29 dnl --------------------------------------------------------------------
  30 dnl Restricted form of AC_ARG_WITH that limits user options
  31 dnl
  32 dnl $1 = option name
  33 dnl $2 = help-string
  34 dnl $3 = default value (no)
  35 dnl $4 = allowed values (yes or no)
  36 AC_DEFUN([OL_ARG_WITH], [# OpenLDAP --with-$1
  37         AC_ARG_WITH($1,[$2 (]ifelse($3,,yes,$3)[)],[
  38         ol_arg=invalid
  39         for ol_val in ifelse($4,,[yes no],[$4]) ; do
  40                 if test "$withval" = "$ol_val" ; then
  41                         ol_arg="$ol_val"
  42                 fi
  43         done
  44         if test "$ol_arg" = "invalid" ; then
  45                 AC_MSG_ERROR(bad value $withval for --with-$1)
  46         fi
  47         ol_with_$1="$ol_arg"
  48 ],
  49 [       ol_with_$1=ifelse($3,,"no","$3")])dnl
  50 dnl AC_VERBOSE(OpenLDAP --with-$1 $ol_with_$1)
  51 # end --with-$1
  52 ])dnl
  53 dnl
  54 dnl ====================================================================
  55 dnl Check if db.h is Berkeley DB2
  56 AC_DEFUN([OL_HEADER_BERKELEY_DB2],
  57 [AC_CHECK_HEADERS(db.h)
  58 if test $ac_cv_header_db_h = yes ; then
  59         AC_CACHE_CHECK(if db.h is DB2, [ol_cv_header_db2],[
  60                 AC_EGREP_CPP(__db_version_2,[
  61 #                       include <db.h>
  62                         /* this check could be improved */
  63 #                       ifdef DB_VERSION_MAJOR
  64 #                               if DB_VERSION_MAJOR == 2
  65                                         __db_version_2
  66 #                               endif
  67 #                       endif
  68                 ], ol_cv_header_db2=yes, ol_cv_header_db2=no)])
  69 fi
  70 ])dnl
  71 dnl --------------------------------------------------------------------
  72 dnl Check if Berkeley DB2 library exists
  73 dnl Check for dbopen in standard libraries or -ldb
  74 AC_DEFUN([OL_LIB_BERKELEY_DB2],
  75 [AC_CACHE_CHECK(for DB2 library, [ol_cv_lib_db2],
  76 [       ol_LIBS="$LIBS"
  77         AC_CHECK_LIB(db,db_open,[ol_cv_lib_db2=-ldb],[ol_cv_lib_db2=no])
  78         LIBS="$ol_LIBS"
  79 ])
  80 ])dnl
  81 dnl
  82 dnl --------------------------------------------------------------------
  83 dnl Check if Berkeley db2 exists
  84 AC_DEFUN([OL_BERKELEY_DB2],
  85 [AC_REQUIRE([OL_LIB_BERKELEY_DB2])
  86  AC_REQUIRE([OL_HEADER_BERKELEY_DB2])
  87  AC_CACHE_CHECK(for Berkeley DB2, [ol_cv_berkeley_db2], [
  88         if test $ol_cv_lib_db2 = no -o $ol_cv_header_db2 = no ; then
  89                 ol_cv_berkeley_db2=no
  90         else
  91                 ol_cv_berkeley_db2=yes
  92         fi
  93 ])
  94 ])dnl
  95 dnl
  96 dnl ====================================================================
  97 dnl Check for db.h/db_185.h is Berkeley DB
  98 AC_DEFUN([OL_HEADER_BERKELEY_DB],
  99 [AC_REQUIRE([OL_HEADER_BERKELEY_DB2])
 100 AC_CHECK_HEADERS(db_185.h)
 101 if test $ol_cv_header_db2 = yes ; then
 102         dnl db.h is db2!
 103
 104         ol_cv_header_db=$ac_cv_header_db_185_h
 105 else
 106         ol_cv_header_db=$ac_cv_header_db_h
 107 fi
 108 ])dnl
 109 dnl
 110 dnl --------------------------------------------------------------------
 111 dnl Check if Berkeley DB library exists
 112 dnl Check for dbopen in standard libraries or -ldb
 113 AC_DEFUN([OL_LIB_BERKELEY_DB],
 114 [AC_CACHE_CHECK(for Berkeley DB library, [ol_cv_lib_db],
 115 [       ol_LIBS="$LIBS"
 116         AC_CHECK_FUNC(dbopen,[ol_cv_lib_db=yes], [
 117                 AC_CHECK_LIB(db,dbopen,[ol_cv_lib_db=-ldb],[ol_cv_lib_db=no])
 118         ])
 119         LIBS="$ol_LIBS"
 120 ])
 121 ])dnl
 122 dnl
 123 dnl --------------------------------------------------------------------
 124 dnl Check if db exists
 125 AC_DEFUN([OL_BERKELEY_DB],
 126 [AC_REQUIRE([OL_LIB_BERKELEY_DB])
 127  AC_REQUIRE([OL_HEADER_BERKELEY_DB])
 128  AC_CACHE_CHECK(for Berkeley DB, [ol_cv_berkeley_db], [
 129         if test $ol_cv_lib_db = no -o $ol_cv_header_db = no ; then
 130                 ol_cv_berkeley_db=no
 131         else
 132                 ol_cv_berkeley_db=yes
 133         fi
 134 ])
 135 ])dnl
 136 dnl
 137 dnl ====================================================================
 138 dnl Check if GDBM library exists
 139 dnl Check for gdbm_open in standard libraries or -lgdbm
 140 AC_DEFUN([OL_LIB_GDBM],
 141 [AC_CACHE_CHECK(for GDBM library, [ol_cv_lib_gdbm],
 142 [       ol_LIBS="$LIBS"
 143         AC_CHECK_FUNC(gdbm_open,[ol_cv_lib_gdbm=yes], [
 144                 AC_CHECK_LIB(gdbm,gdbm_open,[ol_cv_lib_gdbm=-lgdbm],[ol_cv_lib_gdbm=no])
 145         ])
 146         LIBS="$ol_LIBS"
 147 ])
 148 ])dnl
 149 dnl
 150 dnl --------------------------------------------------------------------
 151 dnl Check if GDBM exists
 152 AC_DEFUN([OL_GDBM],
 153 [AC_REQUIRE([OL_LIB_GDBM])
 154  AC_CHECK_HEADERS(gdbm.h)
 155  AC_CACHE_CHECK(for db, [ol_cv_gdbm], [
 156         if test $ol_cv_lib_gdbm = no -o $ac_cv_header_gdbm_h = no ; then
 157                 ol_cv_gdbm=no
 158         else
 159                 ol_cv_gdbm=yes
 160         fi
 161 ])
 162 ])dnl
 163 dnl
 164 dnl ====================================================================
 165 dnl Check if NDBM library exists
 166 dnl Check for dbm_open in standard libraries or -lndbm or -ldbm
 167 AC_DEFUN([OL_LIB_NDBM],
 168 [AC_CACHE_CHECK(for NDBM library, [ol_cv_lib_ndbm],
 169 [       ol_LIBS="$LIBS"
 170         AC_CHECK_FUNC(dbm_open,[ol_cv_lib_ndbm=yes], [
 171                 AC_CHECK_LIB(ndbm,dbm_open,[ol_cv_lib_ndbm=-lndbm], [
 172                         AC_CHECK_LIB(dbm,dbm_open,[ol_cv_lib_ndbm=-ldbm],
 173                                 [ol_cv_lib_ndbm=no])dnl
 174                 ])
 175         ])
 176         LIBS="$ol_LIBS"
 177 ])
 178 ])dnl
 179 dnl
 180 dnl --------------------------------------------------------------------
 181 dnl Check if NDBM exists
 182 AC_DEFUN([OL_NDBM],
 183 [AC_REQUIRE([OL_LIB_NDBM])
 184  AC_CHECK_HEADERS(ndbm.h)
 185  AC_CACHE_CHECK(for db, [ol_cv_ndbm], [
 186         if test $ol_cv_lib_ndbm = no -o $ac_cv_header_ndbm_h = no ; then
 187                 ol_cv_ndbm=no
 188         else
 189                 ol_cv_ndbm=yes
 190         fi
 191 ])
 192 ])dnl
 193 dnl
 194 dnl ====================================================================
 195 dnl Check POSIX Thread version
 196 AC_DEFUN([OL_POSIX_THREAD_VERSION],
 197 [AC_CACHE_CHECK([POSIX thread version],[ol_cv_pthread_version],[
 198         AC_EGREP_CPP(final,[
 199 #               include <pthread.h>
 200                 /* this check could be improved */
 201 #               ifdef PTHREAD_ONCE_INIT
 202                         final
 203 #               endif
 204         ], ol_pthread_final=yes, ol_pthread_final=no)
 205
 206         AC_EGREP_CPP(draft4,[
 207 #               include <pthread.h>
 208                 /* this check could be improved */
 209 #               ifdef pthread_once_init
 210                         draft4
 211 #               endif
 212         ], ol_pthread_draft4=yes, ol_pthread_draft4=no)
 213
 214         if test $ol_pthread_final = yes -a $ol_pthread_draft4 = no; then
 215                 ol_cv_pthread_version=final
 216         elif test $ol_pthread_final = no -a $ol_pthread_draft4 = yes; then
 217                 ol_cv_pthread_version=draft4
 218         else
 219                 ol_cv_pthread_version=unknown
 220         fi
 221 ])
 222 ])dnl
 223 dnl
 224 dnl --------------------------------------------------------------------
 225 dnl Check LinuxThread
 226 AC_DEFUN([OL_LINUX_THREADS],
 227 [
 228 AC_CACHE_CHECK([for LinuxThreads], [ol_cv_linux_threads], [
 229         res=`grep Linuxthreads /usr/include/pthread.h 2>/dev/null | wc -l`
 230         if test "$res" -gt 0 ; then
 231                 ol_cv_linux_threads=yes
 232         else
 233                 ol_cv_linux_threads=no
 234         fi
 235 ])
 236 ])dnl
 237 dnl
 238 dnl ====================================================================
 239 dnl Check for declaration of sys_errlist in one of stdio.h and errno.h.
 240 dnl Declaration of sys_errlist on BSD4.4 interferes with our declaration.
 241 dnl Reported by Keith Bostic.
 242 AC_DEFUN([OL_SYS_ERRLIST],
 243 [
 244 AC_MSG_CHECKING([declaration of sys_errlist])
 245 AC_CACHE_VAL(ol_cv_dcl_sys_errlist,[
 246         AC_TRY_COMPILE([
 247 #include <stdio.h>
 248 #include <sys/types.h>
 249 #include <errno.h> ],
 250         [char *c = (char *) *sys_errlist],
 251         [ol_cv_dcl_sys_errlist=yes],
 252         [ol_cv_dcl_sys_errlist=no])])
 253 AC_MSG_RESULT($ol_cv_dcl_sys_errlist)
 254
 255 # It's possible (for near-UNIX clones) that sys_errlist doesn't exist
 256 if test $ol_cv_dcl_sys_errlist = no ; then
 257         AC_DEFINE(DECL_SYS_ERRLIST)
 258         AC_MSG_CHECKING([existence of sys_errlist])
 259         AC_CACHE_VAL(ol_cv_have_sys_errlist,[
 260                 AC_TRY_LINK([#include <errno.h>],
 261                         [char *c = (char *) *sys_errlist],
 262                         [ol_cv_have_sys_errlist=yes],
 263                         [ol_cv_have_sys_errlist=no])])
 264         AC_MSG_RESULT($ol_cv_have_sys_errlist)
 265 fi
 266 ])dnl