git.sur5r.net Git - u-boot/blob - arch/arm/lib/crt0.S

   1 /*
   2  *  crt0 - C-runtime startup Code for ARM U-Boot
   3  *
   4  *  Copyright (c) 2012  Albert ARIBAUD <albert.u.boot@aribaud.net>
   5  *
   6  * SPDX-License-Identifier:     GPL-2.0+
   7  */
   8
   9 #include <config.h>
  10 #include <asm-offsets.h>
  11 #include <linux/linkage.h>
  12 #ifdef CONFIG_CPU_V7M
  13 #include <asm/armv7m.h>
  14 #endif
  15
  16 /*
  17  * This file handles the target-independent stages of the U-Boot
  18  * start-up where a C runtime environment is needed. Its entry point
  19  * is _main and is branched into from the target's start.S file.
  20  *
  21  * _main execution sequence is:
  22  *
  23  * 1. Set up initial environment for calling board_init_f().
  24  *    This environment only provides a stack and a place to store
  25  *    the GD ('global data') structure, both located in some readily
  26  *    available RAM (SRAM, locked cache...). In this context, VARIABLE
  27  *    global data, initialized or not (BSS), are UNAVAILABLE; only
  28  *    CONSTANT initialized data are available. GD should be zeroed
  29  *    before board_init_f() is called.
  30  *
  31  * 2. Call board_init_f(). This function prepares the hardware for
  32  *    execution from system RAM (DRAM, DDR...) As system RAM may not
  33  *    be available yet, , board_init_f() must use the current GD to
  34  *    store any data which must be passed on to later stages. These
  35  *    data include the relocation destination, the future stack, and
  36  *    the future GD location.
  37  *
  38  * 3. Set up intermediate environment where the stack and GD are the
  39  *    ones allocated by board_init_f() in system RAM, but BSS and
  40  *    initialized non-const data are still not available.
  41  *
  42  * 4a.For U-Boot proper (not SPL), call relocate_code(). This function
  43  *    relocates U-Boot from its current location into the relocation
  44  *    destination computed by board_init_f().
  45  *
  46  * 4b.For SPL, board_init_f() just returns (to crt0). There is no
  47  *    code relocation in SPL.
  48  *
  49  * 5. Set up final environment for calling board_init_r(). This
  50  *    environment has BSS (initialized to 0), initialized non-const
  51  *    data (initialized to their intended value), and stack in system
  52  *    RAM (for SPL moving the stack and GD into RAM is optional - see
  53  *    CONFIG_SPL_STACK_R). GD has retained values set by board_init_f().
  54  *
  55  * 6. For U-Boot proper (not SPL), some CPUs have some work left to do
  56  *    at this point regarding memory, so call c_runtime_cpu_setup.
  57  *
  58  * 7. Branch to board_init_r().
  59  *
  60  * For more information see 'Board Initialisation Flow in README.
  61  */
  62
  63 /*
  64  * entry point of crt0 sequence
  65  */
  66
  67 ENTRY(_main)
  68
  69 /*
  70  * Set up initial C runtime environment and call board_init_f(0).
  71  */
  72
  73 #if defined(CONFIG_SPL_BUILD) && defined(CONFIG_SPL_STACK)
  74         ldr     sp, =(CONFIG_SPL_STACK)
  75 #else
  76         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
  77 #endif
  78 #if defined(CONFIG_CPU_V7M)     /* v7M forbids using SP as BIC destination */
  79         mov     r3, sp
  80         bic     r3, r3, #7
  81         mov     sp, r3
  82 #else
  83         bic     sp, sp, #7      /* 8-byte alignment for ABI compliance */
  84 #endif
  85         mov     r0, sp
  86         bl      board_init_f_mem
  87         mov     sp, r0
  88
  89         mov     r0, #0
  90         bl      board_init_f
  91
  92 #if ! defined(CONFIG_SPL_BUILD)
  93
  94 /*
  95  * Set up intermediate environment (new sp and gd) and call
  96  * relocate_code(addr_moni). Trick here is that we'll return
  97  * 'here' but relocated.
  98  */
  99
 100         ldr     sp, [r9, #GD_START_ADDR_SP]     /* sp = gd->start_addr_sp */
 101 #if defined(CONFIG_CPU_V7M)     /* v7M forbids using SP as BIC destination */
 102         mov     r3, sp
 103         bic     r3, r3, #7
 104         mov     sp, r3
 105 #else
 106         bic     sp, sp, #7      /* 8-byte alignment for ABI compliance */
 107 #endif
 108         ldr     r9, [r9, #GD_BD]                /* r9 = gd->bd */
 109         sub     r9, r9, #GD_SIZE                /* new GD is below bd */
 110
 111         adr     lr, here
 112         ldr     r0, [r9, #GD_RELOC_OFF]         /* r0 = gd->reloc_off */
 113         add     lr, lr, r0
 114 #if defined(CONFIG_CPU_V7M)
 115         orr     lr, #1                          /* As required by Thumb-only */
 116 #endif
 117         ldr     r0, [r9, #GD_RELOCADDR]         /* r0 = gd->relocaddr */
 118         b       relocate_code
 119 here:
 120 /*
 121  * now relocate vectors
 122  */
 123
 124         bl      relocate_vectors
 125
 126 /* Set up final (full) environment */
 127
 128         bl      c_runtime_cpu_setup     /* we still call old routine here */
 129 #endif
 130 #if !defined(CONFIG_SPL_BUILD) || defined(CONFIG_SPL_FRAMEWORK)
 131 # ifdef CONFIG_SPL_BUILD
 132         /* Use a DRAM stack for the rest of SPL, if requested */
 133         bl      spl_relocate_stack_gd
 134         cmp     r0, #0
 135         movne   sp, r0
 136 # endif
 137         ldr     r0, =__bss_start        /* this is auto-relocated! */
 138
 139 #ifdef CONFIG_USE_ARCH_MEMSET
 140         ldr     r3, =__bss_end          /* this is auto-relocated! */
 141         mov     r1, #0x00000000         /* prepare zero to clear BSS */
 142
 143         subs    r2, r3, r0              /* r2 = memset len */
 144         bl      memset
 145 #else
 146         ldr     r1, =__bss_end          /* this is auto-relocated! */
 147         mov     r2, #0x00000000         /* prepare zero to clear BSS */
 148
 149 clbss_l:cmp     r0, r1                  /* while not at end of BSS */
 150 #if defined(CONFIG_CPU_V7M)
 151         itt     lo
 152 #endif
 153         strlo   r2, [r0]                /* clear 32-bit BSS word */
 154         addlo   r0, r0, #4              /* move to next */
 155         blo     clbss_l
 156 #endif
 157
 158 #if ! defined(CONFIG_SPL_BUILD)
 159         bl coloured_LED_init
 160         bl red_led_on
 161 #endif
 162         /* call board_init_r(gd_t *id, ulong dest_addr) */
 163         mov     r0, r9                  /* gd_t */
 164         ldr     r1, [r9, #GD_RELOCADDR] /* dest_addr */
 165         /* call board_init_r */
 166         ldr     pc, =board_init_r       /* this is auto-relocated! */
 167
 168         /* we should not return here. */
 169 #endif
 170
 171 ENDPROC(_main)