git.sur5r.net Git - u-boot/blob - arch/riscv/cpu/nx25/u-boot.lds

   1 /* SPDX-License-Identifier: GPL-2.0+ */
   2 /*
   3  * Copyright (C) 2017 Andes Technology Corporation
   4  * Rick Chen, Andes Technology Corporation <rick@andestech.com>
   5  */
   6 OUTPUT_ARCH("riscv")
   7 ENTRY(_start)
   8
   9 SECTIONS
  10 {
  11         . = ALIGN(4);
  12         .text :
  13         {
  14                 arch/riscv/cpu/nx25/start.o     (.text)
  15                 *(.text)
  16         }
  17
  18         . = ALIGN(4);
  19         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  20
  21         . = ALIGN(4);
  22         .data : {
  23                 __global_pointer$ = . + 0x800;
  24                 *(.data*)
  25         }
  26         . = ALIGN(4);
  27
  28         .got : {
  29            __got_start = .;
  30            *(.got.plt) *(.got)
  31            __got_end = .;
  32     }
  33
  34         . = ALIGN(4);
  35
  36         .u_boot_list : {
  37                 KEEP(*(SORT(.u_boot_list*)));
  38         }
  39
  40     . = ALIGN(4);
  41
  42     /DISCARD/ : { *(.rela.plt*) }
  43     .rela.dyn : {
  44         __rel_dyn_start = .;
  45         *(.rela*)
  46         __rel_dyn_end = .;
  47     }
  48
  49     . = ALIGN(4);
  50
  51     .dynsym : {
  52         __dyn_sym_start = .;
  53         *(.dynsym)
  54         __dyn_sym_end = .;
  55     }
  56
  57     . = ALIGN(4);
  58
  59         _end = .;
  60
  61         .bss : {
  62         __bss_start = .;
  63         *(.bss)
  64                 . = ALIGN(4);
  65                 __bss_end = .;
  66         }
  67
  68 }