git.sur5r.net Git - bacula/bacula/blob - bacula/src/qt-console/tray-monitor/tray-monitor.pro.in

   1 ######################################################################
   2 #
   3 #  !!!!!!! IMPORTANT !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
   4 #
   5 #  Edit only tray-monitor.pro.in  -- tray-monitor.pro is built by the ./configure program
   6 #
   7 #  !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
   8 #
   9 # Copyright (C) 2000-2017 Kern Sibbald
  10 # License: BSD 2-Clause; see file LICENSE-FOSS
  11 #
  12 # CONFIG options for Windows are pulled from win32/qmake.conf
  13 CONFIG += qt
  14 #CONFIG += qt debug
  15
  16 cross-win32 {
  17   LIBS       +=  -mwindows -L../../win32/release32 -lbacula
  18   INCLUDEPATH += ../../win32/compat
  19 }
  20 !cross-win32 {
  21   LIBS        += -L../../lib -lbaccfg -lbac -L../../findlib -lbacfind @OPENSSL_LIBS@
  22 }
  23
  24
  25 bins.path = /$(DESTDIR)@sbindir@
  26 bins.files = bacula-tray-monitor
  27 confs.path = /$(DESTDIR)@sysconfdir@
  28 confs.commands = ./install_conf_file
  29
  30 TEMPLATE     = app
  31 TARGET       = bacula-tray-monitor
  32 QMAKE_EXTRA_TARGETS += depend
  33 DEPENDPATH  += .
  34 INCLUDEPATH += ../.. .
  35 LIBTOOL_LINK = @QMAKE_LIBTOOL@ --silent --tag=CXX --mode=link
  36 LIBTOOL_INSTALL = @QMAKE_LIBTOOL@ --silent --mode=install
  37 QMAKE_LINK   = $${LIBTOOL_LINK} $(CXX)
  38 QMAKE_INSTALL_PROGRAM = $${LIBTOOL_INSTALL} install -m @SBINPERM@ -p
  39 QMAKE_CLEAN += obj/* .libs/* bacula-tray-monitor release/bacula-tray-monitor
  40 QMAKE_CXXFLAGS += -DTRAY_MONITOR
  41 QMAKE_CFLAGS += -DTRAY_MONITOR
  42
  43 INSTALLS = bins confs
  44
  45 RESOURCES    = ../main.qrc
  46 MOC_DIR      = moc
  47 OBJECTS_DIR  = obj
  48 UI_DIR       = ui
  49
  50 # Main directory
  51 HEADERS += tray-monitor.h tray_conf.h tray-ui.h fdstatus.h task.h ../util/fmtwidgetitem.h dirstatus.h conf.h sdstatus.h runjob.h status.h
  52 SOURCES +=  tray-monitor.cpp tray_conf.cpp fdstatus.cpp task.cpp authenticate.cpp ../util/fmtwidgetitem.cpp dirstatus.cpp sdstatus.cpp conf.cpp runjob.cpp status.cpp common.h
  53
  54 FORMS += fd-monitor.ui dir-monitor.ui sd-monitor.ui main-conf.ui res-conf.ui run.ui
  55
  56 TRANSLATIONS += ts/tm_fr.ts ts/tm_de.ts ts/tm_ja.ts