git.sur5r.net Git - openldap/blob - build/openldap.m4

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998-2002 The OpenLDAP Foundation, Redwood City, California, USA
   4 dnl All rights reserved.
   5 dnl
   6 dnl Redistribution and use in source and binary forms, with or without
   7 dnl modification, are permitted only as authorized by the OpenLDAP
   8 dnl Public License.  A copy of this license is available at
   9 dnl http://www.OpenLDAP.org/license.html or in file LICENSE in the
  10 dnl top-level directory of the distribution.
  11 dnl
  12 dnl OpenLDAP Autoconf Macros
  13 dnl
  14 dnl --------------------------------------------------------------------
  15 dnl Restricted form of AC_ARG_ENABLE that limits user options
  16 dnl
  17 dnl $1 = option name
  18 dnl $2 = help-string
  19 dnl $3 = default value  (auto)
  20 dnl $4 = allowed values (auto yes no)
  21 AC_DEFUN([OL_ARG_ENABLE], [# OpenLDAP --enable-$1
  22         AC_ARG_ENABLE($1,changequote(<,>)<$2 [>ifelse($3,,auto,$3)<]>changequote([,]),[
  23         ol_arg=invalid
  24         for ol_val in ifelse($4,,[auto yes no],[$4]) ; do
  25                 if test "$enableval" = "$ol_val" ; then
  26                         ol_arg="$ol_val"
  27                 fi
  28         done
  29         if test "$ol_arg" = "invalid" ; then
  30                 AC_MSG_ERROR(bad value $enableval for --enable-$1)
  31         fi
  32         ol_enable_$1="$ol_arg"
  33 ],
  34 [       ol_enable_$1=ifelse($3,,"auto","$3")])dnl
  35 dnl AC_VERBOSE(OpenLDAP -enable-$1 $ol_enable_$1)
  36 # end --enable-$1
  37 ])dnl
  38 dnl
  39 dnl --------------------------------------------------------------------
  40 dnl Restricted form of AC_ARG_WITH that limits user options
  41 dnl
  42 dnl $1 = option name
  43 dnl $2 = help-string
  44 dnl $3 = default value (no)
  45 dnl $4 = allowed values (yes or no)
  46 AC_DEFUN([OL_ARG_WITH], [# OpenLDAP --with-$1
  47         AC_ARG_WITH($1,changequote(<,>)<$2 [>ifelse($3,,yes,$3)<]>changequote([,]),[
  48         ol_arg=invalid
  49         for ol_val in ifelse($4,,[yes no],[$4]) ; do
  50                 if test "$withval" = "$ol_val" ; then
  51                         ol_arg="$ol_val"
  52                 fi
  53         done
  54         if test "$ol_arg" = "invalid" ; then
  55                 AC_MSG_ERROR(bad value $withval for --with-$1)
  56         fi
  57         ol_with_$1="$ol_arg"
  58 ],
  59 [       ol_with_$1=ifelse($3,,"no","$3")])dnl
  60 dnl AC_VERBOSE(OpenLDAP --with-$1 $ol_with_$1)
  61 # end --with-$1
  62 ])dnl
  63 dnl
  64 dnl ====================================================================
  65 dnl
  66 AC_DEFUN(AC_COMPILE_CHECK_SIZEOF,
  67 [changequote(<<, >>)dnl
  68 dnl The name to #define.
  69 define(<<AC_TYPE_NAME>>, translit(sizeof_$1, [a-z *], [A-Z_P]))dnl
  70 dnl The cache variable name.
  71 define(<<AC_CV_NAME>>, translit(ac_cv_sizeof_$1, [ *], [_p]))dnl
  72 changequote([, ])dnl
  73 AC_MSG_CHECKING(size of $1)
  74 AC_CACHE_VAL(AC_CV_NAME,
  75 [for ac_size in 4 8 1 2 16 $2 ; do # List sizes in rough order of prevalence.
  76   AC_TRY_COMPILE([#include "confdefs.h"
  77 #include <sys/types.h>
  78 $2
  79 ], [switch (0) case 0: case (sizeof ($1) == $ac_size):;], AC_CV_NAME=$ac_size)
  80   if test x$AC_CV_NAME != x ; then break; fi
  81 done
  82 ])
  83 if test x$AC_CV_NAME = x ; then
  84   AC_MSG_ERROR([cannot determine a size for $1])
  85 fi
  86 AC_MSG_RESULT($AC_CV_NAME)
  87 AC_DEFINE_UNQUOTED(AC_TYPE_NAME, $AC_CV_NAME, [The number of bytes in type $1])
  88 undefine([AC_TYPE_NAME])dnl
  89 undefine([AC_CV_NAME])dnl
  90 ])
  91 dnl ====================================================================
  92 dnl check if hard links are supported.
  93 dnl
  94 AC_DEFUN([OL_PROG_LN_H], [# test for ln hardlink support
  95 AC_MSG_CHECKING(whether ln works)
  96 AC_CACHE_VAL(ol_cv_prog_LN_H,
  97 [rm -f conftest.src conftest.dst
  98 echo "conftest" > conftest.src
  99 if ln conftest.src conftest.dst 2>/dev/null
 100 then
 101   ol_cv_prog_LN_H="ln"
 102 else
 103   ol_cv_prog_LN_H="cp"
 104 fi
 105 rm -f conftest.src conftest.dst
 106 ])dnl
 107 LN_H="$ol_cv_prog_LN_H"
 108 if test "$ol_cv_prog_LN_H" = "ln"; then
 109         AC_MSG_RESULT(yes)
 110 else
 111         AC_MSG_RESULT(no)
 112 fi
 113 AC_SUBST(LN_H)dnl
 114 ])dnl
 115 dnl
 116 dnl ====================================================================
 117 dnl Check for dependency generation flag
 118 AC_DEFUN([OL_MKDEPEND], [# test for make depend flag
 119 OL_MKDEP=
 120 OL_MKDEP_FLAGS=
 121 if test -z "${MKDEP}"; then
 122         OL_MKDEP="${CC-cc}"
 123         if test -z "${MKDEP_FLAGS}"; then
 124                 AC_CACHE_CHECK([for ${OL_MKDEP} depend flag], ol_cv_mkdep, [
 125                         ol_cv_mkdep=no
 126                         for flag in "-M" "-xM"; do
 127                                 cat > conftest.c <<EOF
 128  noCode;
 129 EOF
 130                                 if AC_TRY_COMMAND($OL_MKDEP $flag conftest.c) \
 131                                         | egrep '^conftest\.'"${ac_objext}" >/dev/null 2>&1
 132                                 then
 133                                         if test ! -f conftest."${ac_object}" ; then
 134                                                 ol_cv_mkdep=$flag
 135                                                 OL_MKDEP_FLAGS="$flag"
 136                                                 break
 137                                         fi
 138                                 fi
 139                         done
 140                         rm -f conftest*
 141                 ])
 142         else
 143                 cc_cv_mkdep=yes
 144                 OL_MKDEP_FLAGS="${MKDEP_FLAGS}"
 145         fi
 146 else
 147         cc_cv_mkdep=yes
 148         OL_MKDEP="${MKDEP}"
 149         OL_MKDEP_FLAGS="${MKDEP_FLAGS}"
 150 fi
 151 AC_SUBST(OL_MKDEP)
 152 AC_SUBST(OL_MKDEP_FLAGS)
 153 ])
 154 dnl
 155 dnl ====================================================================
 156 dnl Check if system uses EBCDIC instead of ASCII
 157 AC_DEFUN([OL_CPP_EBCDIC], [# test for EBCDIC
 158 AC_CACHE_CHECK([for EBCDIC],ol_cv_cpp_ebcdic,[
 159         AC_TRY_CPP([
 160 #if !('M' == 0xd4)
 161 #include <__ASCII__/generate_error.h>
 162 #endif
 163 ],
 164         [ol_cv_cpp_ebcdic=yes],
 165         [ol_cv_cpp_ebcdic=no])])
 166 if test $ol_cv_cpp_ebcdic = yes ; then
 167         AC_DEFINE(HAVE_EBCDIC,1, [define if system uses EBCDIC instead of ASCII])
 168 fi
 169 ])
 170 dnl
 171 dnl --------------------------------------------------------------------
 172 dnl OpenLDAP version of STDC header check w/ EBCDIC support
 173 AC_DEFUN(OL_HEADER_STDC,
 174 [AC_REQUIRE_CPP()dnl
 175 AC_REQUIRE([OL_CPP_EBCDIC])dnl
 176 AC_CACHE_CHECK([for ANSI C header files], ol_cv_header_stdc,
 177 [AC_TRY_CPP([#include <stdlib.h>
 178 #include <stdarg.h>
 179 #include <string.h>
 180 #include <float.h>], ol_cv_header_stdc=yes, ol_cv_header_stdc=no)
 181
 182 if test $ol_cv_header_stdc = yes; then
 183   # SunOS 4.x string.h does not declare mem*, contrary to ANSI.
 184 AC_EGREP_HEADER(memchr, string.h, , ol_cv_header_stdc=no)
 185 fi
 186
 187 if test $ol_cv_header_stdc = yes; then
 188   # ISC 2.0.2 stdlib.h does not declare free, contrary to ANSI.
 189 AC_EGREP_HEADER(free, stdlib.h, , ol_cv_header_stdc=no)
 190 fi
 191
 192 if test $ol_cv_header_stdc = yes; then
 193   # /bin/cc in Irix-4.0.5 gets non-ANSI ctype macros unless using -ansi.
 194 AC_TRY_RUN([#include <ctype.h>
 195 #ifndef HAVE_EBCDIC
 196 #       define ISLOWER(c) ('a' <= (c) && (c) <= 'z')
 197 #       define TOUPPER(c) (ISLOWER(c) ? 'A' + ((c) - 'a') : (c))
 198 #else
 199 #       define ISLOWER(c) (('a' <= (c) && (c) <= 'i') \
 200                 || ('j' <= (c) && (c) <= 'r') \
 201                 || ('s' <= (c) && (c) <= 'z'))
 202 #       define TOUPPER(c)       (ISLOWER(c) ? ((c) | 0x40) : (c))
 203 #endif
 204 #define XOR(e, f) (((e) && !(f)) || (!(e) && (f)))
 205 int main () { int i; for (i = 0; i < 256; i++)
 206 if (XOR (islower (i), ISLOWER (i)) || toupper (i) != TOUPPER (i)) exit(2);
 207 exit (0); }
 208 ], , ol_cv_header_stdc=no, :)
 209 fi])
 210 if test $ol_cv_header_stdc = yes; then
 211   AC_DEFINE(STDC_HEADERS)
 212 fi
 213 ac_cv_header_stdc=disable
 214 ])
 215 dnl
 216 dnl ====================================================================
 217 dnl Check if struct passwd has pw_gecos
 218 AC_DEFUN([OL_STRUCT_PASSWD_PW_GECOS], [# test for pw_gecos in struct passwd
 219 AC_CACHE_CHECK([struct passwd for pw_gecos],ol_cv_struct_passwd_pw_gecos,[
 220         AC_TRY_COMPILE([#include <pwd.h>],[
 221         struct passwd pwd;
 222         pwd.pw_gecos = pwd.pw_name;
 223 ],
 224         [ol_cv_struct_passwd_pw_gecos=yes],
 225         [ol_cv_struct_passwd_pw_gecos=no])])
 226 if test $ol_cv_struct_passwd_pw_gecos = yes ; then
 227         AC_DEFINE(HAVE_PW_GECOS,1, [define if struct passwd has pw_gecos])
 228 fi
 229 ])
 230 dnl
 231 dnl --------------------------------------------------------------------
 232 dnl Check if struct passwd has pw_passwd
 233 AC_DEFUN([OL_STRUCT_PASSWD_PW_PASSWD], [# test for pw_passwd in struct passwd
 234 AC_CACHE_CHECK([struct passwd for pw_passwd],ol_cv_struct_passwd_pw_passwd,[
 235         AC_TRY_COMPILE([#include <pwd.h>],[
 236         struct passwd pwd;
 237         pwd.pw_passwd = pwd.pw_name;
 238 ],
 239         [ol_cv_struct_passwd_pw_passwd=yes],
 240         [ol_cv_struct_passwd_pw_passwd=no])])
 241 if test $ol_cv_struct_passwd_pw_passwd = yes ; then
 242         AC_DEFINE(HAVE_PW_PASSWD,1, [define if struct passwd has pw_passwd])
 243 fi
 244 ])
 245 dnl
 246 dnl ====================================================================
 247 dnl Berkeley DB macros
 248 dnl
 249 dnl --------------------------------------------------------------------
 250 dnl Try to link
 251 AC_DEFUN([OL_BERKELEY_DB_TRY],
 252 [if test $ol_cv_lib_db = no ; then
 253         AC_CACHE_CHECK([for Berkeley DB link (]ifelse($2,,default,$2)[)],[$1],
 254 [
 255         ol_DB_LIB=ifelse($2,,,$2)
 256         ol_LIBS=$LIBS
 257         LIBS="$ol_DB_LIB $LIBS"
 258
 259         AC_TRY_LINK([
 260 #ifdef HAVE_DB_185_H
 261 # include <db_185.h>
 262 #else
 263 # include <db.h>
 264 #endif
 265
 266 #ifndef DB_VERSION_MAJOR
 267 # define DB_VERSION_MAJOR 1
 268 #endif
 269
 270 #ifndef NULL
 271 #define NULL ((void*)0)
 272 #endif
 273 ],[
 274 #if DB_VERSION_MAJOR > 1
 275         {
 276                 char *version;
 277                 int major, minor, patch;
 278
 279                 version = db_version( &major, &minor, &patch );
 280
 281                 if( major != DB_VERSION_MAJOR ||
 282                         minor < DB_VERSION_MINOR )
 283                 {
 284                         printf("Berkeley DB version mismatch\n"
 285                                 "\texpected: %s\n\tgot: %s\n",
 286                                 DB_VERSION_STRING, version);
 287                         return 1;
 288                 }
 289         }
 290 #endif
 291
 292 #if DB_VERSION_MAJOR > 2
 293         db_env_create( NULL, 0 );
 294 #elif DB_VERSION_MAJOR > 1
 295         db_appexit( NULL );
 296 #else
 297         (void) dbopen( NULL, 0, 0, 0, NULL);
 298 #endif
 299 ],[$1=yes],[$1=no])
 300
 301         LIBS="$ol_LIBS"
 302 ])
 303
 304         if test $$1 = yes ; then
 305                 ol_cv_lib_db=ifelse($2,,yes,$2)
 306         fi
 307 fi
 308 ])
 309 dnl
 310 dnl --------------------------------------------------------------------
 311 dnl Try to locate appropriate library
 312 AC_DEFUN([OL_BERKELEY_DB_LINK],
 313 [ol_cv_lib_db=no
 314 OL_BERKELEY_DB_TRY(ol_cv_db_none)
 315 OL_BERKELEY_DB_TRY(ol_cv_db_db4,[-ldb4])
 316 OL_BERKELEY_DB_TRY(ol_cv_db_db_4,[-ldb-4])
 317 OL_BERKELEY_DB_TRY(ol_cv_db_db,[-ldb])
 318 OL_BERKELEY_DB_TRY(ol_cv_db_db3,[-ldb3])
 319 OL_BERKELEY_DB_TRY(ol_cv_db_db_3,[-ldb-3])
 320 OL_BERKELEY_DB_TRY(ol_cv_db_db2,[-ldb2])
 321 OL_BERKELEY_DB_TRY(ol_cv_db_db_2,[-ldb-2])
 322 OL_BERKELEY_DB_TRY(ol_cv_db_db1,[-ldb1])
 323 OL_BERKELEY_DB_TRY(ol_cv_db_db_1,[-ldb-1])
 324 ])
 325 dnl
 326 dnl --------------------------------------------------------------------
 327 dnl Check if Berkeley DB supports DB_THREAD
 328 AC_DEFUN([OL_BERKELEY_DB_THREAD],
 329 [AC_CACHE_CHECK([for Berkeley DB thread support], [ol_cv_berkeley_db_thread], [
 330         ol_LIBS="$LIBS"
 331         if test $ol_cv_lib_db != yes ; then
 332                 LIBS="$ol_cv_lib_db"
 333         fi
 334
 335         AC_TRY_RUN([
 336 #ifdef HAVE_DB_185_H
 337         choke me;
 338 #else
 339 #include <db.h>
 340 #endif
 341 #ifndef NULL
 342 #define NULL ((void *)0)
 343 #endif
 344 main()
 345 {
 346         int rc;
 347         u_int32_t flags = DB_CREATE |
 348 #ifdef DB_PRIVATE
 349                 DB_PRIVATE |
 350 #endif
 351                 DB_THREAD;
 352
 353 #if DB_VERSION_MAJOR > 2
 354         DB_ENV *env = NULL;
 355
 356         rc = db_env_create( &env, 0 );
 357
 358         flags |= DB_INIT_MPOOL;
 359 #ifdef DB_MPOOL_PRIVATE
 360         flags |= DB_MPOOL_PRIVATE;
 361 #endif
 362
 363         if( rc ) {
 364                 printf("BerkeleyDB: %s\n", db_strerror(rc) );
 365                 return rc;
 366         }
 367
 368 #if (DB_VERSION_MAJOR > 3) || (DB_VERSION_MINOR >= 1)
 369         rc = env->open( env, NULL, flags, 0 );
 370 #else
 371         rc = env->open( env, NULL, NULL, flags, 0 );
 372 #endif
 373
 374         if ( rc == 0 ) {
 375                 rc = env->close( env, 0 );
 376         }
 377
 378         if( rc ) {
 379                 printf("BerkeleyDB: %s\n", db_strerror(rc) );
 380                 return rc;
 381         }
 382
 383 #else
 384         DB_ENV env;
 385         memset( &env, '\0', sizeof(env) );
 386
 387         rc = db_appinit( NULL, NULL, &env, flags );
 388
 389         if( rc == 0 ) {
 390                 db_appexit( &env );
 391         }
 392
 393         unlink("__db_mpool.share");
 394         unlink("__db_lock.share");
 395 #endif
 396
 397         return rc;
 398 }],
 399         [ol_cv_berkeley_db_thread=yes],
 400         [ol_cv_berkeley_db_thread=no],
 401         [ol_cv_berkeley_db_thread=cross])
 402
 403         LIBS="$ol_LIBS"
 404
 405         if test $ol_cv_berkeley_db_thread != no ; then
 406                 AC_DEFINE(HAVE_BERKELEY_DB_THREAD, 1,
 407                         [define if Berkeley DB has DB_THREAD support])
 408         fi
 409 ])])dnl
 410 dnl
 411 dnl --------------------------------------------------------------------
 412 dnl Find any DB
 413 AC_DEFUN([OL_BERKELEY_DB],
 414 [ol_cv_berkeley_db=no
 415 AC_CHECK_HEADERS(db.h)
 416 if test $ac_cv_header_db_h = yes; then
 417         OL_BERKELEY_DB_LINK
 418         if test "$ol_cv_lib_db" != no ; then
 419                 ol_cv_berkeley_db=yes
 420                 OL_BERKELEY_DB_THREAD
 421         fi
 422 fi
 423 ])
 424 dnl --------------------------------------------------------------------
 425 dnl Check for version compatility with back-bdb
 426 AC_DEFUN([OL_BDB_COMPAT],
 427 [AC_CACHE_CHECK([Berkeley DB version for BDB backend], [ol_cv_bdb_compat],[
 428         AC_EGREP_CPP(__db_version_compat,[
 429 #include <db.h>
 430
 431  /* this check could be improved */
 432 #ifndef DB_VERSION_MAJOR
 433 #       define DB_VERSION_MAJOR 1
 434 #endif
 435
 436 /* require 4.0 or later */
 437 #if DB_VERSION_MAJOR >= 4
 438         __db_version_compat
 439 #endif
 440         ],      [ol_cv_bdb_compat=yes], [ol_cv_bdb_compat=no])])
 441 ])
 442
 443 dnl --------------------------------------------------------------------
 444 dnl Find old Berkeley DB 1.85/1.86
 445 AC_DEFUN([OL_BERKELEY_COMPAT_DB],
 446 [AC_CHECK_HEADERS(db_185.h db.h)
 447 if test $ac_cv_header_db_185_h = yes -o $ac_cv_header_db_h = yes; then
 448         AC_CACHE_CHECK([if Berkeley DB header compatibility], [ol_cv_header_db1],[
 449                 AC_EGREP_CPP(__db_version_1,[
 450 #if HAVE_DB_185_H
 451 #       include <db_185.h>
 452 #else
 453 #       include <db.h>
 454 #endif
 455
 456  /* this check could be improved */
 457 #ifndef DB_VERSION_MAJOR
 458 #       define DB_VERSION_MAJOR 1
 459 #endif
 460
 461 #if DB_VERSION_MAJOR == 1
 462         __db_version_1
 463 #endif
 464 ],      [ol_cv_header_db1=yes], [ol_cv_header_db1=no])])
 465
 466         if test $ol_cv_header_db1 = yes ; then
 467                 OL_BERKELEY_DB_LINK
 468                 if test "$ol_cv_lib_db" != no ; then
 469                         ol_cv_berkeley_db=yes
 470                 fi
 471         fi
 472 fi
 473 ])
 474 dnl
 475 dnl ====================================================================
 476 dnl Check if GDBM library exists
 477 dnl Check for gdbm_open in standard libraries or -lgdbm
 478 dnl
 479 dnl defines ol_cv_lib_gdbm to 'yes' or '-lgdbm' or 'no'
 480 dnl             'yes' implies gdbm_open is in $LIBS
 481 dnl
 482 dnl uses:
 483 dnl             AC_CHECK_FUNC(gdbm_open)
 484 dnl             AC_CHECK_LIB(gdbm,gdbm_open)
 485 dnl
 486 AC_DEFUN([OL_LIB_GDBM],
 487 [AC_CACHE_CHECK(for GDBM library, [ol_cv_lib_gdbm],
 488 [       ol_LIBS="$LIBS"
 489         AC_CHECK_FUNC(gdbm_open,[ol_cv_lib_gdbm=yes], [
 490                 AC_CHECK_LIB(gdbm,gdbm_open,[ol_cv_lib_gdbm=-lgdbm],[ol_cv_lib_gdbm=no])
 491         ])
 492         LIBS="$ol_LIBS"
 493 ])
 494 ])dnl
 495 dnl
 496 dnl --------------------------------------------------------------------
 497 dnl Check if GDBM exists
 498 dnl
 499 dnl defines ol_cv_gdbm to 'yes' or 'no'
 500 dnl
 501 dnl uses:
 502 dnl             OL_LIB_GDBM
 503 dnl             AC_CHECK_HEADERS(gdbm.h)
 504 dnl
 505 AC_DEFUN([OL_GDBM],
 506 [AC_REQUIRE([OL_LIB_GDBM])
 507  AC_CHECK_HEADERS(gdbm.h)
 508  AC_CACHE_CHECK(for db, [ol_cv_gdbm], [
 509         if test $ol_cv_lib_gdbm = no -o $ac_cv_header_gdbm_h = no ; then
 510                 ol_cv_gdbm=no
 511         else
 512                 ol_cv_gdbm=yes
 513         fi
 514 ])
 515  if test $ol_cv_gdbm = yes ; then
 516         AC_DEFINE(HAVE_GDBM,1, [define if GNU DBM is available])
 517  fi
 518 ])dnl
 519 dnl
 520 dnl ====================================================================
 521 dnl Check if MDBM library exists
 522 dnl Check for mdbm_open in standard libraries or -lmdbm
 523 dnl
 524 dnl defines ol_cv_lib_mdbm to 'yes' or '-lmdbm' or 'no'
 525 dnl             'yes' implies mdbm_open is in $LIBS
 526 dnl
 527 dnl uses:
 528 dnl             AC_CHECK_FUNC(mdbm_set_chain)
 529 dnl             AC_CHECK_LIB(mdbm,mdbm_set_chain)
 530 dnl
 531 AC_DEFUN([OL_LIB_MDBM],
 532 [AC_CACHE_CHECK(for MDBM library, [ol_cv_lib_mdbm],
 533 [       ol_LIBS="$LIBS"
 534         AC_CHECK_FUNC(mdbm_set_chain,[ol_cv_lib_mdbm=yes], [
 535                 AC_CHECK_LIB(mdbm,mdbm_set_chain,[ol_cv_lib_mdbm=-lmdbm],[ol_cv_lib_mdbm=no])
 536         ])
 537         LIBS="$ol_LIBS"
 538 ])
 539 ])dnl
 540 dnl
 541 dnl --------------------------------------------------------------------
 542 dnl Check if MDBM exists
 543 dnl
 544 dnl defines ol_cv_mdbm to 'yes' or 'no'
 545 dnl
 546 dnl uses:
 547 dnl             OL_LIB_MDBM
 548 dnl             AC_CHECK_HEADERS(mdbm.h)
 549 dnl
 550 AC_DEFUN([OL_MDBM],
 551 [AC_REQUIRE([OL_LIB_MDBM])
 552  AC_CHECK_HEADERS(mdbm.h)
 553  AC_CACHE_CHECK(for db, [ol_cv_mdbm], [
 554         if test $ol_cv_lib_mdbm = no -o $ac_cv_header_mdbm_h = no ; then
 555                 ol_cv_mdbm=no
 556         else
 557                 ol_cv_mdbm=yes
 558         fi
 559 ])
 560  if test $ol_cv_mdbm = yes ; then
 561         AC_DEFINE(HAVE_MDBM,1, [define if MDBM is available])
 562  fi
 563 ])dnl
 564 dnl
 565 dnl ====================================================================
 566 dnl Check if NDBM library exists
 567 dnl Check for dbm_open in standard libraries or -lndbm or -ldbm
 568 dnl
 569 dnl defines ol_cv_lib_ndbm to 'yes' or '-lndbm' or -ldbm or 'no'
 570 dnl             'yes' implies ndbm_open is in $LIBS
 571 dnl
 572 dnl uses:
 573 dnl             AC_CHECK_FUNC(dbm_open)
 574 dnl             AC_CHECK_LIB(ndbm,dbm_open)
 575 dnl             AC_CHECK_LIB(dbm,dbm_open)
 576 dnl
 577 dnl restrictions:
 578 dnl             should also check SVR4 case: dbm_open() in -lucb but that
 579 dnl             would requiring dealing with -L/usr/ucblib
 580 dnl
 581 AC_DEFUN([OL_LIB_NDBM],
 582 [AC_CACHE_CHECK(for NDBM library, [ol_cv_lib_ndbm],
 583 [       ol_LIBS="$LIBS"
 584         AC_CHECK_FUNC(dbm_open,[ol_cv_lib_ndbm=yes], [
 585                 AC_CHECK_LIB(ndbm,dbm_open,[ol_cv_lib_ndbm=-lndbm], [
 586                         AC_CHECK_LIB(dbm,dbm_open,[ol_cv_lib_ndbm=-ldbm],
 587                                 [ol_cv_lib_ndbm=no])dnl
 588                 ])
 589         ])
 590         LIBS="$ol_LIBS"
 591 ])
 592 ])dnl
 593 dnl
 594 dnl --------------------------------------------------------------------
 595 dnl Check if NDBM exists
 596 dnl
 597 dnl defines ol_cv_ndbm to 'yes' or 'no'
 598 dnl
 599 dnl uses:
 600 dnl             OL_LIB_NDBM
 601 dnl             AC_CHECK_HEADERS(ndbm.h)
 602 dnl
 603 dnl restrictions:
 604 dnl             Doesn't handle SVR4 case (see above)
 605 dnl
 606 AC_DEFUN([OL_NDBM],
 607 [AC_REQUIRE([OL_LIB_NDBM])
 608  AC_CHECK_HEADERS(ndbm.h)
 609  AC_CACHE_CHECK(for db, [ol_cv_ndbm], [
 610         if test $ol_cv_lib_ndbm = no -o $ac_cv_header_ndbm_h = no ; then
 611                 ol_cv_ndbm=no
 612         else
 613                 ol_cv_ndbm=yes
 614         fi
 615 ])
 616  if test $ol_cv_ndbm = yes ; then
 617         AC_DEFINE(HAVE_NDBM,1, [define if NDBM is available])
 618  fi
 619 ])dnl
 620 dnl
 621 dnl ====================================================================
 622 dnl Check POSIX Thread version
 623 dnl
 624 dnl defines ol_cv_pthread_version to 0, 4, 5, 6, 7, 10, depending on the
 625 dnl     version of the POSIX.4a Draft that is implemented.
 626 dnl     10 == POSIX.4a Final == POSIX.1c-1996 for our purposes.
 627 dnl     0 implies that the version could not be detected
 628 dnl             or that pthreads.h does exist.  Existence of pthreads.h
 629 dnl             should be tested separately.
 630 dnl
 631 dnl tests:
 632 dnl     pthread_yield() was dropped in Draft 9, so
 633 dnl             only a Draft <= 8 library will define this
 634 dnl     pthread_detach() was dropped in Draft 8, it is present
 635 dnl             in every other version
 636 dnl     PTHREAD_CREATE_UNDETACHED is only in Draft 7, it was called
 637 dnl             PTHREAD_CREATE_JOINABLE after that
 638 dnl     pthread_attr_default was dropped in Draft 6, only 4 and 5 have it
 639 dnl     PTHREAD_MUTEX_INITIALIZER was introduced in Draft 5. It's not
 640 dnl             interesting to us because we don't try to statically
 641 dnl             initialize mutexes. 5-10 has it.
 642 dnl     pthread_attr_create was renamed to pthread_attr_init after Draft 4.
 643 dnl             Draft 6-10 has _init, Draft 4 has _create. (dunno about 5)
 644 dnl
 645 dnl Draft 9 and 10 are equivalent for our purposes.
 646 dnl
 647 AC_DEFUN([OL_POSIX_THREAD_VERSION],
 648 [AC_CACHE_CHECK([POSIX thread version],[ol_cv_pthread_version],[
 649         AC_EGREP_HEADER(pthread_yield,pthread.h,[
 650         AC_EGREP_HEADER(pthread_detach,pthread.h,[
 651         AC_EGREP_CPP(draft7,[
 652 #               include <pthread.h>
 653 #               ifdef PTHREAD_CREATE_UNDETACHED
 654                 draft7
 655 #               endif
 656         ], ol_cv_pthread_version=7, [
 657         AC_EGREP_HEADER(pthread_attr_default,pthread.h,[
 658         AC_EGREP_CPP(draft5,[
 659 #               include <pthread.h>
 660 #ifdef          PTHREAD_MUTEX_INITIALIZER
 661                 draft5
 662 #endif
 663         ], ol_cv_pthread_version=5, [
 664         AC_EGREP_HEADER(pthread_attr_create,pthread.h,
 665         ol_cv_pthread_version=4, ol_cv_pthread_version=0) ]) ],
 666         ol_cv_pthread_version=6) ]) ],
 667         ol_cv_pthread_version=8) ],
 668         ol_cv_pthread_version=10)
 669 ])
 670 ])dnl
 671 dnl
 672 dnl --------------------------------------------------------------------
 673 AC_DEFUN([OL_PTHREAD_TEST_INCLUDES],
 674 [/* pthread test headers */
 675 #include <pthread.h>
 676 #if HAVE_PTHREADS < 7
 677 #include <errno.h>
 678 #endif
 679 #ifndef NULL
 680 #define NULL (void*)0
 681 #endif
 682
 683 static void *task(p)
 684         void *p;
 685 {
 686         return (void *) (p == NULL);
 687 }
 688 ])
 689 AC_DEFUN([OL_PTHREAD_TEST_FUNCTION],[
 690         /* pthread test function */
 691 #ifndef PTHREAD_CREATE_DETACHED
 692 #define PTHREAD_CREATE_DETACHED 1
 693 #endif
 694         pthread_t t;
 695         int status;
 696         int detach = PTHREAD_CREATE_DETACHED;
 697
 698 #if HAVE_PTHREADS > 4
 699         /* Final pthreads */
 700         pthread_attr_t attr;
 701
 702         status = pthread_attr_init(&attr);
 703         if( status ) return status;
 704
 705 #if HAVE_PTHREADS < 7
 706         status = pthread_attr_setdetachstate(&attr, &detach);
 707         if( status < 0 ) status = errno;
 708 #else
 709         status = pthread_attr_setdetachstate(&attr, detach);
 710 #endif
 711         if( status ) return status;
 712         status = pthread_create( &t, &attr, task, NULL );
 713 #if HAVE_PTHREADS < 7
 714         if( status < 0 ) status = errno;
 715 #endif
 716         if( status ) return status;
 717 #else
 718         /* Draft 4 pthreads */
 719         status = pthread_create( &t, pthread_attr_default, task, NULL );
 720         if( status ) return errno;
 721
 722         /* give thread a chance to complete */
 723         /* it should remain joinable and hence detachable */
 724         sleep( 1 );
 725
 726         status = pthread_detach( &t );
 727         if( status ) return errno;
 728 #endif
 729
 730 #ifdef HAVE_LINUX_THREADS
 731         pthread_kill_other_threads_np();
 732 #endif
 733
 734         return 0;
 735 ])
 736
 737 AC_DEFUN([OL_PTHREAD_TEST_PROGRAM],
 738 [OL_PTHREAD_TEST_INCLUDES
 739
 740 int main(argc, argv)
 741         int argc;
 742         char **argv;
 743 {
 744 OL_PTHREAD_TEST_FUNCTION
 745 }
 746 ])
 747 dnl --------------------------------------------------------------------
 748 AC_DEFUN([OL_PTHREAD_TRY], [# Pthread try link: $1 ($2)
 749 if test "$ol_link_threads" = no ; then
 750         # try $1
 751         AC_CACHE_CHECK([for pthread link with $1], [$2], [
 752                 # save the flags
 753                 ol_LIBS="$LIBS"
 754                 LIBS="$1 $LIBS"
 755
 756                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
 757                         [$2=yes], [$2=no],
 758                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
 759                                 [$2=yes], [$2=no])])
 760
 761                 # restore the LIBS
 762                 LIBS="$ol_LIBS"
 763         ])
 764
 765         if test $$2 = yes ; then
 766                 ol_link_pthreads="$1"
 767                 ol_link_threads=posix
 768         fi
 769 fi
 770 ])
 771 dnl
 772 dnl ====================================================================
 773 dnl Check GNU Pth pthread Header
 774 dnl
 775 dnl defines ol_cv_header linux_threads to 'yes' or 'no'
 776 dnl             'no' implies pthreads.h is not LinuxThreads or pthreads.h
 777 dnl             doesn't exists.  Existance of pthread.h should separately
 778 dnl             checked.
 779 dnl
 780 AC_DEFUN([OL_HEADER_GNU_PTH_PTHREAD_H], [
 781         AC_CACHE_CHECK([for GNU Pth pthread.h],
 782                 [ol_cv_header_gnu_pth_pthread_h],
 783                 [AC_EGREP_CPP(__gnu_pth__,
 784                         [#include <pthread.h>
 785 #ifdef _POSIX_THREAD_IS_GNU_PTH
 786         __gnu_pth__;
 787 #endif
 788 ],
 789                         [ol_cv_header_gnu_pth_pthread_h=yes],
 790                         [ol_cv_header_gnu_pth_pthread_h=no])
 791                 ])
 792 ])dnl
 793 dnl ====================================================================
 794 dnl Check for NT Threads
 795 AC_DEFUN([OL_NT_THREADS], [
 796         AC_CHECK_FUNC(_beginthread)
 797
 798         if test $ac_cv_func__beginthread = yes ; then
 799                 AC_DEFINE(HAVE_NT_THREADS,1,[if you have NT Threads])
 800                 ol_cv_nt_threads=yes
 801         fi
 802 ])
 803 dnl ====================================================================
 804 dnl Check LinuxThreads Header
 805 dnl
 806 dnl defines ol_cv_header linux_threads to 'yes' or 'no'
 807 dnl             'no' implies pthreads.h is not LinuxThreads or pthreads.h
 808 dnl             doesn't exists.  Existance of pthread.h should separately
 809 dnl             checked.
 810 dnl
 811 AC_DEFUN([OL_HEADER_LINUX_THREADS], [
 812         AC_CACHE_CHECK([for LinuxThreads pthread.h],
 813                 [ol_cv_header_linux_threads],
 814                 [AC_EGREP_CPP(pthread_kill_other_threads_np,
 815                         [#include <pthread.h>],
 816                         [ol_cv_header_linux_threads=yes],
 817                         [ol_cv_header_linux_threads=no])
 818                 ])
 819         if test $ol_cv_header_linux_threads = yes; then
 820                 AC_DEFINE(HAVE_LINUX_THREADS,1,[if you have LinuxThreads])
 821         fi
 822 ])dnl
 823 dnl --------------------------------------------------------------------
 824 dnl     Check LinuxThreads Implementation
 825 dnl
 826 dnl     defines ol_cv_sys_linux_threads to 'yes' or 'no'
 827 dnl     'no' implies pthreads implementation is not LinuxThreads.
 828 dnl
 829 AC_DEFUN([OL_SYS_LINUX_THREADS], [
 830         AC_CHECK_FUNCS(pthread_kill_other_threads_np)
 831         AC_CACHE_CHECK([for LinuxThreads implementation],
 832                 [ol_cv_sys_linux_threads],
 833                 [ol_cv_sys_linux_threads=$ac_cv_func_pthread_kill_other_threads_np])
 834 ])dnl
 835 dnl
 836 dnl --------------------------------------------------------------------
 837 dnl Check LinuxThreads consistency
 838 AC_DEFUN([OL_LINUX_THREADS], [
 839         AC_REQUIRE([OL_HEADER_LINUX_THREADS])
 840         AC_REQUIRE([OL_SYS_LINUX_THREADS])
 841         AC_CACHE_CHECK([for LinuxThreads consistency], [ol_cv_linux_threads], [
 842                 if test $ol_cv_header_linux_threads = yes -a \
 843                         $ol_cv_sys_linux_threads = yes; then
 844                         ol_cv_linux_threads=yes
 845                 elif test $ol_cv_header_linux_threads = no -a \
 846                         $ol_cv_sys_linux_threads = no; then
 847                         ol_cv_linux_threads=no
 848                 else
 849                         ol_cv_linux_threads=error
 850                 fi
 851         ])
 852 ])dnl
 853 dnl
 854 dnl ====================================================================
 855 dnl Check for POSIX Regex
 856 AC_DEFUN([OL_POSIX_REGEX], [
 857 AC_CACHE_CHECK([for compatible POSIX regex],ol_cv_c_posix_regex,[
 858         AC_TRY_RUN([
 859 #include <sys/types.h>
 860 #include <regex.h>
 861 static char *pattern, *string;
 862 main()
 863 {
 864         int rc;
 865         regex_t re;
 866
 867         pattern = "^A";
 868
 869         if(regcomp(&re, pattern, 0)) {
 870                 return -1;
 871         }
 872
 873         string = "ALL MATCH";
 874
 875         rc = regexec(&re, string, 0, (void*)0, 0);
 876
 877         regfree(&re);
 878
 879         return rc;
 880 }],
 881         [ol_cv_c_posix_regex=yes],
 882         [ol_cv_c_posix_regex=no],
 883         [ol_cv_c_posix_regex=cross])])
 884 ])
 885 dnl
 886 dnl ====================================================================
 887 dnl Check if toupper() requires islower() to be called first
 888 AC_DEFUN([OL_C_UPPER_LOWER],
 889 [AC_CACHE_CHECK([if toupper() requires islower()],ol_cv_c_upper_lower,[
 890         AC_TRY_RUN([
 891 #include <ctype.h>
 892 main()
 893 {
 894         if ('C' == toupper('C'))
 895                 exit(0);
 896         else
 897                 exit(1);
 898 }],
 899         [ol_cv_c_upper_lower=no],
 900         [ol_cv_c_upper_lower=yes],
 901         [ol_cv_c_upper_lower=safe])])
 902 if test $ol_cv_c_upper_lower != no ; then
 903         AC_DEFINE(C_UPPER_LOWER,1, [define if toupper() requires islower()])
 904 fi
 905 ])
 906 dnl
 907 dnl ====================================================================
 908 dnl Check for declaration of sys_errlist in one of stdio.h and errno.h.
 909 dnl Declaration of sys_errlist on BSD4.4 interferes with our declaration.
 910 dnl Reported by Keith Bostic.
 911 AC_DEFUN([OL_SYS_ERRLIST],
 912 [AC_CACHE_CHECK([declaration of sys_errlist],ol_cv_dcl_sys_errlist,[
 913         AC_TRY_COMPILE([
 914 #include <stdio.h>
 915 #include <sys/types.h>
 916 #include <errno.h>
 917 #ifdef WINNT
 918 #include <stdlib.h>
 919 #endif ],
 920         [char *c = (char *) *sys_errlist],
 921         [ol_cv_dcl_sys_errlist=yes
 922         ol_cv_have_sys_errlist=yes],
 923         [ol_cv_dcl_sys_errlist=no])])
 924 #
 925 # It's possible (for near-UNIX clones) that sys_errlist doesn't exist
 926 if test $ol_cv_dcl_sys_errlist = no ; then
 927         AC_DEFINE(DECL_SYS_ERRLIST,1,
 928                 [define if sys_errlist is not declared in stdio.h or errno.h])
 929
 930         AC_CACHE_CHECK([existence of sys_errlist],ol_cv_have_sys_errlist,[
 931                 AC_TRY_LINK([#include <errno.h>],
 932                         [char *c = (char *) *sys_errlist],
 933                         [ol_cv_have_sys_errlist=yes],
 934                         [ol_cv_have_sys_errlist=no])])
 935 fi
 936 if test $ol_cv_have_sys_errlist = yes ; then
 937         AC_DEFINE(HAVE_SYS_ERRLIST,1,
 938                 [define if you actually have sys_errlist in your libs])
 939 fi
 940 ])dnl
 941 dnl
 942 dnl ====================================================================
 943 dnl Early MIPS compilers (used in Ultrix 4.2) don't like
 944 dnl "int x; int *volatile a = &x; *a = 0;"
 945 dnl     -- borrowed from PDKSH
 946 AC_DEFUN(OL_C_VOLATILE,
 947  [AC_CACHE_CHECK(if compiler understands volatile, ol_cv_c_volatile,
 948     [AC_TRY_COMPILE([int x, y, z;],
 949       [volatile int a; int * volatile b = x ? &y : &z;
 950       /* Older MIPS compilers (eg., in Ultrix 4.2) don't like *b = 0 */
 951       *b = 0;], ol_cv_c_volatile=yes, ol_cv_c_volatile=no)])
 952   if test $ol_cv_c_volatile = yes; then
 953     :
 954   else
 955     AC_DEFINE(volatile,,[define as empty if volatile is not supported])
 956   fi
 957  ])dnl
 958 dnl
 959 dnl ====================================================================
 960 dnl Look for fetch(3)
 961 AC_DEFUN([OL_LIB_FETCH],
 962 [ol_LIBS=$LIBS
 963 LIBS="-lfetch -lcom_err $LIBS"
 964 AC_CACHE_CHECK([fetch(3) library],ol_cv_lib_fetch,[
 965         AC_TRY_LINK([
 966 #include <sys/param.h>
 967 #include <stdio.h>
 968 #include <fetch.h>],
 969         [struct url *u = fetchParseURL("file:///"); ],
 970         [ol_cv_lib_fetch=yes],
 971         [ol_cv_lib_fetch=no])])
 972 LIBS=$ol_LIBS
 973 if test $ol_cv_lib_fetch != no ; then
 974         ol_link_fetch="-lfetch -lcom_err"
 975         AC_DEFINE(HAVE_FETCH,1,
 976                 [define if you actually have FreeBSD fetch(3)])
 977 fi
 978 ])dnl
 979 dnl
 980 dnl ====================================================================
 981 dnl Define sig_atomic_t if not defined in signal.h
 982 AC_DEFUN(OL_TYPE_SIG_ATOMIC_T,
 983  [AC_CACHE_CHECK(for sig_atomic_t, ol_cv_type_sig_atomic_t,
 984     [AC_TRY_COMPILE([#include <signal.h>], [sig_atomic_t atomic;],
 985                 ol_cv_type_sig_atomic_t=yes, ol_cv_type_sig_atomic_t=no)])
 986   if test $ol_cv_type_sig_atomic_t = no; then
 987     AC_DEFINE(sig_atomic_t,int,
 988                 [define to atomic type if sig_atomic_t is not available])
 989   fi
 990  ])dnl
 991 dnl
 992 dnl ====================================================================
 993 dnl Define socklen_t if not defined in sys/types.h or sys/socket.h
 994 AC_DEFUN(OL_TYPE_SOCKLEN_T,
 995  [AC_CACHE_CHECK(for socklen_t, ol_cv_type_socklen_t,
 996     [AC_TRY_COMPILE([
 997 #ifdef HAVE_SYS_TYPES_H
 998 #include <sys/types.h>
 999 #endif
1000 #ifdef HAVE_SYS_SOCKET_H
1001 #include <sys/socket.h>
1002 #endif
1003 ], [socklen_t len;],
1004                 ol_cv_type_socklen_t=yes, ol_cv_type_socklen_t=no)])
1005   if test $ol_cv_type_socklen_t = no; then
1006     AC_DEFINE(socklen_t, int,
1007                 [define to int if socklen_t is not available])
1008   fi
1009  ])dnl
1010 dnl
1011 dnl ====================================================================
1012 dnl Define inet_aton is available
1013 AC_DEFUN(OL_FUNC_INET_ATON,
1014  [AC_CACHE_CHECK([for inet_aton()], ol_cv_func_inet_aton,
1015     [AC_TRY_LINK([
1016 #ifdef HAVE_SYS_TYPES_H
1017 #       include <sys/types.h>
1018 #endif
1019 #ifdef HAVE_SYS_SOCKET_H
1020 #       include <sys/socket.h>
1021 #       ifdef HAVE_SYS_SELECT_H
1022 #               include <sys/select.h>
1023 #       endif
1024 #       include <netinet/in.h>
1025 #       ifdef HAVE_ARPA_INET_H
1026 #               include <arpa/inet.h>
1027 #       endif
1028 #endif
1029 ], [struct in_addr in;
1030 int rc = inet_aton( "255.255.255.255", &in );],
1031                 ol_cv_func_inet_aton=yes, ol_cv_func_inet_aton=no)])
1032   if test $ol_cv_func_inet_aton != no; then
1033     AC_DEFINE(HAVE_INET_ATON, 1,
1034                 [define to you inet_aton(3) is available])
1035   fi
1036  ])dnl
1037 dnl
1038 dnl ====================================================================
1039 dnl check no of arguments for ctime_r
1040 AC_DEFUN(OL_FUNC_CTIME_R_NARGS,
1041  [AC_CACHE_CHECK(number of arguments of ctime_r, ol_cv_func_ctime_r_nargs,
1042    [AC_TRY_COMPILE([#include <time.h>],
1043                 [time_t ti; char *buffer; ctime_r(&ti,buffer,32);],
1044                         ol_cv_func_ctime_r_nargs3=yes,
1045                         ol_cv_func_ctime_r_nargs3=no)
1046
1047         AC_TRY_COMPILE([#include <time.h>],
1048                 [time_t ti; char *buffer; ctime_r(&ti,buffer);],
1049                         ol_cv_func_ctime_r_nargs2=yes,
1050                         ol_cv_func_ctime_r_nargs2=no)
1051
1052         if test $ol_cv_func_ctime_r_nargs3 = yes -a \
1053                 $ol_cv_func_ctime_r_nargs2 = no ; then
1054
1055                 ol_cv_func_ctime_r_nargs=3
1056
1057         elif test $ol_cv_func_ctime_r_nargs3 = no -a \
1058                 $ol_cv_func_ctime_r_nargs2 = yes ; then
1059
1060                 ol_cv_func_ctime_r_nargs=2
1061
1062         else
1063                 ol_cv_func_ctime_r_nargs=0
1064         fi
1065   ])
1066
1067   if test $ol_cv_func_ctime_r_nargs -gt 1 ; then
1068         AC_DEFINE_UNQUOTED(CTIME_R_NARGS, $ol_cv_func_ctime_r_nargs,
1069                 [set to the number of arguments ctime_r() expects])
1070   fi
1071 ])dnl
1072 dnl
1073 dnl --------------------------------------------------------------------
1074 dnl check return type of ctime_r()
1075 AC_DEFUN(OL_FUNC_CTIME_R_TYPE,
1076  [AC_CACHE_CHECK(return type of ctime_r, ol_cv_func_ctime_r_type,
1077    [AC_TRY_COMPILE([#include <time.h>],
1078                 [extern int (ctime_r)();],
1079                         ol_cv_func_ctime_r_type="int", ol_cv_func_ctime_r_type="charp")
1080         ])
1081   if test $ol_cv_func_ctime_r_type = "int" ; then
1082         AC_DEFINE(CTIME_R_RETURNS_INT,1, [define if ctime_r() returns int])
1083   fi
1084 ])dnl
1085 dnl ====================================================================
1086 dnl check no of arguments for gethostbyname_r
1087 AC_DEFUN(OL_FUNC_GETHOSTBYNAME_R_NARGS,
1088  [AC_CACHE_CHECK(number of arguments of gethostbyname_r,
1089         ol_cv_func_gethostbyname_r_nargs,
1090         [AC_TRY_COMPILE([#include <sys/types.h>
1091 #include <sys/socket.h>
1092 #include <netinet/in.h>
1093 #include <netdb.h>
1094 #define BUFSIZE (sizeof(struct hostent)+10)],
1095                 [struct hostent hent; char buffer[BUFSIZE];
1096                 int bufsize=BUFSIZE;int h_errno;
1097                 (void)gethostbyname_r("segovia.cs.purdue.edu", &hent,
1098                         buffer, bufsize, &h_errno);],
1099                 ol_cv_func_gethostbyname_r_nargs5=yes,
1100                 ol_cv_func_gethostbyname_r_nargs5=no)
1101
1102         AC_TRY_COMPILE([#include <sys/types.h>
1103 #include <sys/socket.h>
1104 #include <netinet/in.h>
1105 #include <netdb.h>
1106 #define BUFSIZE (sizeof(struct hostent)+10)],
1107                 [struct hostent hent;struct hostent *rhent;
1108                 char buffer[BUFSIZE];
1109                 int bufsize=BUFSIZE;int h_errno;
1110                 (void)gethostbyname_r("localhost", &hent, buffer, bufsize,
1111                         &rhent, &h_errno);],
1112                 ol_cv_func_gethostbyname_r_nargs6=yes,
1113                 ol_cv_func_gethostbyname_r_nargs6=no)
1114
1115         if test $ol_cv_func_gethostbyname_r_nargs5 = yes -a \
1116                 $ol_cv_func_gethostbyname_r_nargs6 = no ; then
1117
1118                 ol_cv_func_gethostbyname_r_nargs=5
1119
1120         elif test $ol_cv_func_gethostbyname_r_nargs5 = no -a \
1121                 $ol_cv_func_gethostbyname_r_nargs6 = yes ; then
1122
1123                 ol_cv_func_gethostbyname_r_nargs=6
1124
1125         else
1126                 ol_cv_func_gethostbyname_r_nargs=0
1127         fi
1128   ])
1129   if test $ol_cv_func_gethostbyname_r_nargs -gt 1 ; then
1130         AC_DEFINE_UNQUOTED(GETHOSTBYNAME_R_NARGS,
1131                 $ol_cv_func_gethostbyname_r_nargs,
1132                 [set to the number of arguments gethostbyname_r() expects])
1133   fi
1134 ])dnl
1135 dnl
1136 dnl check no of arguments for gethostbyaddr_r
1137 AC_DEFUN(OL_FUNC_GETHOSTBYADDR_R_NARGS,
1138  [AC_CACHE_CHECK(number of arguments of gethostbyaddr_r,
1139         [ol_cv_func_gethostbyaddr_r_nargs],
1140         [AC_TRY_COMPILE([#include <sys/types.h>
1141 #include <sys/socket.h>
1142 #include <netinet/in.h>
1143 #include <netdb.h>
1144 #define BUFSIZE (sizeof(struct hostent)+10)],
1145            [struct hostent hent; char buffer[BUFSIZE];
1146             struct in_addr add;
1147             size_t alen=sizeof(struct in_addr);
1148             int bufsize=BUFSIZE;int h_errno;
1149                 (void)gethostbyaddr_r( (void *)&(add.s_addr),
1150                         alen, AF_INET, &hent, buffer, bufsize, &h_errno);],
1151                 ol_cv_func_gethostbyaddr_r_nargs7=yes,
1152                 ol_cv_func_gethostbyaddr_r_nargs7=no)
1153
1154         AC_TRY_COMPILE([#include <sys/types.h>
1155 #include <sys/socket.h>
1156 #include <netinet/in.h>
1157 #include <netdb.h>
1158 #define BUFSIZE (sizeof(struct hostent)+10)],
1159                 [struct hostent hent;
1160                 struct hostent *rhent; char buffer[BUFSIZE];
1161                 struct in_addr add;
1162                 size_t alen=sizeof(struct in_addr);
1163                 int bufsize=BUFSIZE;int h_errno;
1164                 (void)gethostbyaddr_r( (void *)&(add.s_addr),
1165                         alen, AF_INET, &hent, buffer, bufsize,
1166                         &rhent, &h_errno);],
1167                 ol_cv_func_gethostbyaddr_r_nargs8=yes,
1168                 ol_cv_func_gethostbyaddr_r_nargs8=no)
1169
1170         if test $ol_cv_func_gethostbyaddr_r_nargs7 = yes -a \
1171                 $ol_cv_func_gethostbyaddr_r_nargs8 = no ; then
1172
1173                 ol_cv_func_gethostbyaddr_r_nargs=7
1174
1175         elif test $ol_cv_func_gethostbyaddr_r_nargs7 = no -a \
1176                 $ol_cv_func_gethostbyaddr_r_nargs8 = yes ; then
1177
1178                 ol_cv_func_gethostbyaddr_r_nargs=8
1179
1180         else
1181                 ol_cv_func_gethostbyaddr_r_nargs=0
1182         fi
1183   ])
1184   if test $ol_cv_func_gethostbyaddr_r_nargs -gt 1 ; then
1185     AC_DEFINE_UNQUOTED(GETHOSTBYADDR_R_NARGS,
1186                 $ol_cv_func_gethostbyaddr_r_nargs,
1187                 [set to the number of arguments gethostbyaddr_r() expects])
1188   fi
1189 ])dnl
1190 dnl
1191 dnl --------------------------------------------------------------------
1192 dnl Check for Cyrus SASL version compatility, need 2.1.3 or newer
1193 AC_DEFUN([OL_SASL_COMPAT],
1194 [AC_CACHE_CHECK([Cyrus SASL library version], [ol_cv_sasl_compat],[
1195         AC_EGREP_CPP(__sasl_compat,[
1196 #ifdef HAVE_SASL_SASL_H
1197 #include <sasl/sasl.h>
1198 #else
1199 #include <sasl.h>
1200 #endif
1201
1202 /* require 2.1.3 or later */
1203 #if SASL_VERSION_MAJOR == 1  && SASL_VERSION_MINOR >= 5
1204         char *__sasl_compat = "1.5.x okay";
1205 #elif SASL_VERSION_MAJOR == 2  && SASL_VERSION_MINOR > 1
1206         __sasl_compat "2.2+ or better okay (we guess)";
1207 #elif SASL_VERSION_MAJOR == 2  && SASL_VERSION_MINOR == 1 \
1208         && SASL_VERSION_STEP >=3
1209         __sasl_compat = "2.1.3+ or better okay";
1210 #endif
1211         ],      [ol_cv_sasl_compat=yes], [ol_cv_sasl_compat=no])])
1212 ])