git.sur5r.net Git - i3/i3/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Run autoreconf -fi to generate a configure script from this file.
   3
   4 AC_PREREQ([2.69])
   5 AC_INIT([i3], [4.16], [https://github.com/i3/i3/issues])
   6 # For AX_EXTEND_SRCDIR
   7 AX_ENABLE_BUILDDIR
   8 AM_INIT_AUTOMAKE([foreign subdir-objects -Wall no-dist-gzip dist-bzip2])
   9 # Default to silent rules, use V=1 to get verbose compilation output.
  10 AM_SILENT_RULES([yes])
  11 # Make it possible to disable maintainer mode to disable re-generation of build
  12 # system files.
  13 AM_MAINTAINER_MODE([enable])
  14 AC_CONFIG_SRCDIR([libi3/ipc_recv_message.c])
  15 AC_CONFIG_HEADERS([config.h])
  16 AC_CONFIG_MACRO_DIR([m4])
  17
  18 dnl Verify macros defined in m4/ such as AX_SANITIZERS are not present in the
  19 dnl output, i.e. are replaced as expected. This line results in a better error
  20 dnl message when using aclocal < 1.13 (which does not understand
  21 dnl AC_CONFIG_MACRO_DIR) without passing the -I m4 parameter.
  22 m4_pattern_forbid([AX_SANITIZERS])
  23
  24 # Verify we are using GNU make because we use '%'-style pattern rules in
  25 # Makefile.am, which are a GNU make extension. Pull requests to replace
  26 # '%'-style pattern rules with a more portable alternative are welcome.
  27 AX_CHECK_GNU_MAKE
  28 AS_VAR_IF([_cv_gnu_make_command], [""], [AC_MSG_ERROR([the i3 Makefile.am requires GNU make])])
  29
  30 AX_EXTEND_SRCDIR
  31
  32 AS_IF([test -d ${srcdir}/.git],
  33       [
  34         VERSION="$(git -C ${srcdir} describe --tags --abbrev=0)"
  35         I3_VERSION="$(git -C ${srcdir} describe --tags --always) ($(git -C ${srcdir} rev-list --format=%cd --date=short -n1 $(git rev-parse HEAD) | tail -n1), branch \\\"$(git -C ${srcdir} describe --tags --always --all | sed s:heads/::)\\\")"
  36         # Mirrors what libi3/is_debug_build.c does:
  37         is_release=$(test $(echo "${I3_VERSION}" | cut -d '(' -f 1 | wc -m) -lt 10 && echo yes || echo no)
  38       ],
  39       [
  40         VERSION="$(cut -d '-' -f 1 ${srcdir}/I3_VERSION | cut -d ' ' -f 1)"
  41         I3_VERSION="$(sed -e 's/@<:@\"?\\@:>@/\\&/g' ${srcdir}/I3_VERSION)"
  42         is_release="$(grep -q non-git ${srcdir}/I3_VERSION && echo no || echo yes)"
  43       ])
  44 AC_SUBST([I3_VERSION], [$I3_VERSION])
  45 MAJOR_VERSION="$(echo ${VERSION} | cut -d '.' -f 1)"
  46 MINOR_VERSION="$(echo ${VERSION} | cut -d '.' -f 2)"
  47 PATCH_VERSION="$(echo ${VERSION} | cut -d '.' -f 3)"
  48 AS_IF([test "x${PATCH_VERSION}" = x], [PATCH_VERSION=0])
  49 AC_DEFINE_UNQUOTED([I3_VERSION], ["${I3_VERSION}"], [i3 version])
  50 AC_DEFINE_UNQUOTED([MAJOR_VERSION], [${MAJOR_VERSION}], [i3 major version])
  51 AC_DEFINE_UNQUOTED([MINOR_VERSION], [${MINOR_VERSION}], [i3 minor version])
  52 AC_DEFINE_UNQUOTED([PATCH_VERSION], [${PATCH_VERSION}], [i3 patch version])
  53
  54 AX_CODE_COVERAGE
  55
  56 dnl is_release must be lowercase because AX_CHECK_ENABLE_DEBUG calls m4_tolower
  57 dnl on its fourth argument.
  58 AX_CHECK_ENABLE_DEBUG([yes], , [UNUSED_NDEBUG], [$is_release])
  59
  60 AC_PROG_CC_C99
  61
  62 # For strnlen() and vasprintf().
  63 AC_USE_SYSTEM_EXTENSIONS
  64
  65 # Checks for typedefs, structures, and compiler characteristics.
  66 AC_CHECK_HEADER_STDBOOL
  67 dnl The error message should include the specific type which could not be
  68 dnl found, but I do not see a way to achieve that.
  69 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t], , [AC_MSG_FAILURE([cannot find required type])])
  70
  71 # Checks for library functions.
  72 AC_FUNC_FORK
  73 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
  74 AC_FUNC_STRNLEN
  75 AC_CHECK_FUNCS([atexit dup2 ftruncate getcwd gettimeofday localtime_r memchr memset mkdir rmdir setlocale socket strcasecmp strchr strdup strerror strncasecmp strndup strrchr strspn strstr strtol strtoul], , [AC_MSG_FAILURE([cannot find the $ac_func function, which i3 requires])])
  76
  77 # Checks for libraries.
  78
  79 AC_SEARCH_LIBS([floor], [m], , [AC_MSG_FAILURE([cannot find the required floor() function despite trying to link with -lm])])
  80
  81 # libev does not ship with a pkg-config file :(.
  82 AC_SEARCH_LIBS([ev_run], [ev], , [AC_MSG_FAILURE([cannot find the required ev_run() function despite trying to link with -lev])])
  83
  84 AC_SEARCH_LIBS([shm_open], [rt], [], [], [-pthread])
  85
  86 AC_SEARCH_LIBS([iconv_open], [iconv], ,
  87 AC_SEARCH_LIBS([libiconv_open], [iconv], , [AC_MSG_FAILURE([cannot find the required iconv_open() function despite trying to link with -liconv])]))
  88
  89 AX_PTHREAD
  90
  91 dnl Each prefix corresponds to a source tarball which users might have
  92 dnl downloaded in a newer version and would like to overwrite.
  93 PKG_CHECK_MODULES([LIBSN], [libstartup-notification-1.0])
  94 PKG_CHECK_MODULES([XCB], [xcb xcb-xkb xcb-xinerama xcb-randr xcb-shape])
  95 PKG_CHECK_MODULES([XCB_UTIL], [xcb-event xcb-util])
  96 PKG_CHECK_MODULES([XCB_UTIL_CURSOR], [xcb-cursor])
  97 PKG_CHECK_MODULES([XCB_UTIL_KEYSYMS], [xcb-keysyms])
  98 PKG_CHECK_MODULES([XCB_UTIL_WM], [xcb-icccm])
  99 PKG_CHECK_MODULES([XCB_UTIL_XRM], [xcb-xrm])
 100 PKG_CHECK_MODULES([XKBCOMMON], [xkbcommon xkbcommon-x11])
 101 PKG_CHECK_MODULES([YAJL], [yajl])
 102 PKG_CHECK_MODULES([LIBPCRE], [libpcre >= 8.10])
 103 PKG_CHECK_MODULES([PANGOCAIRO], [cairo >= 1.14.4 pangocairo])
 104 PKG_CHECK_MODULES([GLIBGOBJECT], [glib-2.0 gobject-2.0])
 105
 106 # Checks for programs.
 107 AC_PROG_AWK
 108 AC_PROG_CPP
 109 AC_PROG_INSTALL
 110 AC_PROG_MAKE_SET
 111 AC_PROG_RANLIB
 112 AC_PROG_LN_S
 113
 114 AC_ARG_ENABLE(docs,
 115   AS_HELP_STRING(
 116     [--disable-docs],
 117     [disable building documentation]),
 118   [ax_docs=$enableval],
 119   [ax_docs=yes])
 120 AC_ARG_ENABLE(mans,
 121   AS_HELP_STRING(
 122     [--disable-mans],
 123     [disable building manual pages]),
 124   [ax_mans=$enableval],
 125   [ax_mans=yes])
 126 AS_IF([test x$ax_docs = xyes || test x$ax_mans = xyes], [
 127   AC_PATH_PROG([PATH_ASCIIDOC], [asciidoc])
 128 ])
 129 AS_IF([test x$ax_mans = xyes], [
 130   AC_PATH_PROG([PATH_XMLTO], [xmlto])
 131   AC_PATH_PROG([PATH_POD2MAN], [pod2man])
 132 ])
 133 AM_CONDITIONAL([BUILD_MANS], [test x$ax_mans = xyes && test x$PATH_ASCIIDOC != x && test x$PATH_XMLTO != x && test x$PATH_POD2MAN != x])
 134 AM_CONDITIONAL([BUILD_DOCS], [test x$ax_docs = xyes && test x$PATH_ASCIIDOC != x])
 135
 136 AM_PROG_AR
 137
 138 AX_FLAGS_WARN_ALL
 139 AX_CHECK_COMPILE_FLAG([-Wunused-value], [AX_APPEND_FLAG([-Wunused-value], [AM_CFLAGS])])
 140 AC_SUBST(AM_CFLAGS)
 141
 142 # Checks for header files.
 143 AC_CHECK_HEADERS([fcntl.h float.h inttypes.h limits.h locale.h netinet/in.h paths.h stddef.h stdint.h stdlib.h string.h sys/param.h sys/socket.h sys/time.h unistd.h], , [AC_MSG_FAILURE([cannot find the $ac_header header, which i3 requires])])
 144
 145 AC_CONFIG_FILES([Makefile testcases/lib/i3test.pm man/asciidoc.conf])
 146 AC_CONFIG_FILES([testcases/complete-run.pl], [chmod +x testcases/complete-run.pl])
 147
 148 # Enable address sanitizer for non-release builds. The performance hit is a
 149 # 50% increase of wallclock time for the testsuite on my machine.
 150 if test x$is_release = xyes; then
 151         default_sanitizers=
 152 else
 153         default_sanitizers=address
 154 fi
 155 AX_SANITIZERS(, [$default_sanitizers], [AC_DEFINE([I3_ASAN_ENABLED], [], [Enable ASAN])])
 156
 157 AC_OUTPUT
 158
 159 if test -z "${BUILD_DOCS_TRUE}"; then
 160         print_BUILD_DOCS=yes
 161 else
 162         print_BUILD_DOCS=no
 163 fi
 164
 165
 166 if test -z "${BUILD_MANS_TRUE}"; then
 167         print_BUILD_MANS=yes
 168 else
 169         print_BUILD_MANS=no
 170 fi
 171
 172 in_git_worktree=`git rev-parse --is-inside-work-tree 2>/dev/null`
 173 if [[ "$in_git_worktree" = "true" ]]; then
 174         git_dir=`git rev-parse --git-dir 2>/dev/null`
 175         srcdir=`dirname "$git_dir"`
 176         exclude_dir=`pwd | sed "s,^$srcdir,,g"`
 177         if ! grep -q "^$exclude_dir" "$git_dir/info/exclude"; then
 178                 echo "$exclude_dir" >> "$git_dir/info/exclude"
 179         fi
 180 fi
 181
 182 echo \
 183 "--------------------------------------------------------------------------------
 184 build configured:
 185
 186 AS_HELP_STRING([i3 version:], [`echo ${I3_VERSION} | sed 's,\\\\,,g'`])
 187 AS_HELP_STRING([is release version:], [${is_release}])
 188
 189 AS_HELP_STRING([build manpages:], [${print_BUILD_MANS}])
 190 AS_HELP_STRING([build docs:], [${print_BUILD_DOCS}])
 191 AS_HELP_STRING([enable debug flags:], [${ax_enable_debug}])
 192 AS_HELP_STRING([code coverage:], [${CODE_COVERAGE_ENABLED}])
 193 AS_HELP_STRING([enabled sanitizers:], [${ax_enabled_sanitizers}])
 194
 195 To compile, run:
 196
 197   cd `pwd` && make -j8
 198 --------------------------------------------------------------------------------"