git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms are permitted only
   6 dnl as authorized by the OpenLDAP Public License.  A copy of this
   7 dnl license is available at http://www.OpenLDAP.org/license.html or
   8 dnl in file LICENSE in the top-level directory of the distribution.
   9 dnl
  10 dnl ----------------------------------------------------------------
  11 dnl Redefine AC_INIT_BINSH to provide RCS IDs and copyright notice
  12 dnl at top of generated configure script.  Prints simple copyright.
  13 define([AC_INIT_BINSH],
  14 [[#! /bin/sh
  15 # $]OpenLDAP[$
  16 # from] translit([$OpenLDAP$], $")] [
  17
  18 # Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
  19 #
  20 # Redistribution and use in source and binary forms are permitted only
  21 # as authorized by the OpenLDAP Public License.  A copy of this
  22 # license is available at http://www.OpenLDAP.org/license.html or
  23 # in file LICENSE in the top-level directory of the distribution.
  24
  25 echo "Copyright 1998-1999 The OpenLDAP Foundation,  All Rights Reserved."
  26 echo "Copying restrictions apply, see COPYRIGHT file."
  27 ])dnl
  28 dnl ----------------------------------------------------------------
  29 dnl Disable config.cache!
  30 define([AC_CACHE_LOAD], )dnl
  31 define([AC_CACHE_SAVE], )dnl
  32 dnl
  33 dnl ================================================================
  34 dnl Configure.in for OpenLDAP
  35 AC_INIT(build/version)dnl
  36 AC_CONFIG_AUX_DIR(build)dnl
  37
  38 OL_VERSION=`cat $ac_aux_dir/version`
  39 if test -z "$OL_VERSION"; then
  40         AC_MSG_ERROR([could not determine version])
  41 fi
  42
  43 echo "Configuring OpenLDAP $OL_VERSION ..."
  44
  45 dnl ----------------------------------------------------------------
  46 dnl Determine host platform
  47 dnl             we try not to use this for much
  48 AC_CANONICAL_SYSTEM
  49
  50 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  51 AC_SUBST(PACKAGE)
  52 AC_SUBST(VERSION)
  53 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  54 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  55
  56 dnl We use autoconf features new to 2.13.
  57 dnl aclocal.m4 should be built using aclocal from automake 1.4
  58 dnl libtool 1.3.3 should be installed.
  59 AC_PREREQ(2.13)dnl Required Autoconf version
  60
  61 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  62
  63 dnl ----------------------------------------------------------------
  64 dnl Start Args
  65 AC_MSG_CHECKING(configure arguments)
  66 AC_PREFIX_DEFAULT(/usr/local)
  67
  68 top_builddir=`pwd`
  69 AC_SUBST(top_builddir)dnl
  70
  71 ldap_subdir="/openldap"
  72
  73 AC_ARG_WITH(subdir,
  74 [  --with-subdir=DIR change default subdirectory used for installs],
  75 [case "$withval" in
  76         no) ldap_subdir=""
  77                 ;;
  78         yes)
  79                 ;;
  80         /*|\\*)
  81                 ldap_subdir="$withval"
  82                 ;;
  83         *)
  84                 ldap_subdir="/$withval"
  85                 ;;
  86 esac
  87 ])dnl
  88
  89 AC_SUBST(ldap_subdir)dnl
  90
  91 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  92 dnl ol_enable_syslog=no
  93 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  94 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  95 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  96 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DX Referrals extension], no)dnl
  97 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  98 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  99 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
 100         no, [yes no])dnl
 101
 102 dnl General "with" options
 103 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
 104
 105 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl     with Cyrus SASL support],
 106         auto, [auto yes no] )
 107 OL_ARG_WITH(fetch,[  --with-fetch               with fetch URL support],
 108         auto, [auto yes no] )
 109 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
 110         auto, [auto k5 k4 afs yes no])
 111 OL_ARG_WITH(readline,[  --with-readline with readline support],
 112         auto, [auto yes no] )
 113 OL_ARG_WITH(threads,[  --with-threads   use threads],
 114         auto, [auto posix mach pth lwp yes no manual] )
 115 OL_ARG_WITH(tls,[  --with-tls           with TLS/SSL support],
 116         auto, [auto ssleay openssl yes no] )
 117 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
 118         auto, [auto yes no manual] )
 119
 120 dnl Server options
 121
 122 dnl LDAPD OPTIONS
 123 AC_ARG_WITH(xxldapdoptions,[LDAPD (X.500-to-LDAP Gateway) Options:])
 124 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
 125
 126 dnl SLAPD OPTIONS
 127 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 128 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
 129 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
 130 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
 131 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
 132 OL_ARG_ENABLE(multimaster,[    --enable-multimaster     enable multimaster replication], no)dnl
 133 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
 134 OL_ARG_ENABLE(quipu,[    --enable-quipu build quipu migration tools], no)dnl
 135 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
 136 OL_ARG_ENABLE(aci,[    --enable-aci     enable per-object ACIs], no)dnl
 137 OL_ARG_ENABLE(discreteaci,[    --enable-discreteaci     enable discrete rights in ACIs], no)dnl
 138 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
 139
 140 dnl SLAPD Backend options
 141 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 142 OL_ARG_WITH(bdb2_module,[      --with-bdb2-module       module type], static,
 143         [static dynamic])
 144 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 145 OL_ARG_WITH(ldap_module,[      --with-ldap-module       module type], static,
 146         [static dynamic])
 147 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 148 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 149         [auto db2 db mdbm gdbm ndbm manual])
 150 OL_ARG_WITH(ldbm_module,[      --with-ldbm-module       module type], static,
 151         [static dynamic])
 152 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 153         [auto btree hash])
 154
 155 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 156 OL_ARG_WITH(passwd_module,[      --with-passwd-module   module type], static,
 157         [static dynamic])
 158 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 159 OL_ARG_WITH(perl_module,[      --with-perl-module       module type], static,
 160         [static dynamic])
 161 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 162 OL_ARG_WITH(shell_module,[      --with-shell-module     module type], static,
 163         [static dynamic])
 164 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 165 OL_ARG_WITH(tcl_module,[      --with-tcl-module module type], static,
 166         [static dynamic])
 167
 168 dnl SLURPD OPTIONS
 169 AC_ARG_WITH(xxslurpdoptions,[SLURPD (Replication Daemon) Options:])
 170 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 171
 172 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 173 AC_ENABLE_STATIC
 174 dnl AC_DISABLE_SHARED
 175 AC_ENABLE_SHARED
 176
 177 dnl General "enable" options
 178 # validate options
 179 if test $ol_enable_dns = yes ; then
 180         if test $ol_enable_referrals = no ; then
 181                 AC_MSG_ERROR([DNS requires --enable-referrals])
 182         fi
 183         if test $ol_enable_referrals = auto ; then
 184                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 185                 ol_enable_referrals=yes
 186         fi
 187 fi
 188
 189 if test $ol_enable_slapd = no ; then
 190         dnl SLAPD was specificallly disabled
 191         if test $ol_enable_bdb2 = yes ; then
 192                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 193         fi
 194         if test $ol_enable_ldap = yes ; then
 195                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 196         fi
 197         if test $ol_enable_ldbm = yes ; then
 198                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 199         fi
 200         if test $ol_enable_passwd = yes ; then
 201                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 202         fi
 203         if test $ol_enable_perl = yes ; then
 204                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 205         fi
 206         if test $ol_enable_shell = yes ; then
 207                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 208         fi
 209         if test $ol_enable_tcl = yes ; then
 210                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 211         fi
 212         if test $ol_enable_modules = yes ; then
 213                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 214         fi
 215         if test $ol_enable_multimaster = yes ; then
 216                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 217         fi
 218         if test $ol_enable_wrappers = yes ; then
 219                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 220         fi
 221         if test $ol_enable_phonetic = yes ; then
 222                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 223         fi
 224         if test $ol_enable_quipu = yes ; then
 225                 AC_MSG_WARN([slapd disabled, ignoring --enable-quipu argument])
 226         fi
 227         if test $ol_enable_rlookups = yes ; then
 228                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 229         fi
 230         if test $ol_enable_aci = yes ; then
 231                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 232         fi
 233         if test $ol_enable_discreteaci = yes ; then
 234                 AC_MSG_WARN([slapd disabled, ignoring --enable-discreteaci argument])
 235         fi
 236         if test $ol_with_ldbm_api != auto ; then
 237                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 238         fi
 239         if test $ol_with_ldbm_type != auto ; then
 240                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 241         fi
 242         if test $ol_with_bdb2_module != static ; then
 243                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb2-module argument])
 244         fi
 245         if test $ol_with_ldap_module != static ; then
 246                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 247         fi
 248         if test $ol_with_ldbm_module != static ; then
 249                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 250         fi
 251         if test $ol_with_passwd_module != static ; then
 252                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 253         fi
 254         if test $ol_with_perl_module != static ; then
 255                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 256         fi
 257         if test $ol_with_shell_module != static ; then
 258                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 259         fi
 260         if test $ol_with_tcl_module != static ; then
 261                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 262         fi
 263         if test $ol_enable_slurpd = yes ; then
 264                 AC_MSG_ERROR([slurpd requires slapd])
 265         fi
 266
 267         # force settings to no
 268         ol_enable_bdb2=no
 269         ol_enable_ldap=no
 270         ol_enable_ldbm=no
 271         ol_enable_passwd=no
 272         ol_enable_perl=no
 273         ol_enable_shell=no
 274         ol_enable_tcl=no
 275
 276         ol_enable_modules=no
 277         ol_enable_multimaster=no
 278         ol_enable_phonetic=no
 279         ol_enable_quipu=no
 280         ol_enable_rlookups=no
 281         ol_enable_aci=no
 282         ol_enable_discreteaci=no
 283         ol_enable_wrappers=no
 284
 285         ol_with_ldbm_api=no
 286         ol_with_ldbm_type=no
 287
 288         ol_with_bdb2_module=static
 289         ol_with_ldap_module=static
 290         ol_with_ldbm_module=static
 291         ol_with_passwd_module=static
 292         ol_with_perl_module=static
 293         ol_with_shell_module=static
 294         ol_with_tcl_module=static
 295
 296         ol_enable_slurpd=no
 297
 298 elif test $ol_enable_ldbm = no ; then
 299         dnl SLAPD without LDBM
 300
 301         if test $ol_with_ldbm_api != auto ; then
 302                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 303         fi
 304
 305         if test $ol_with_ldbm_type != auto ; then
 306                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 307         fi
 308
 309         if test $ol_with_ldbm_module != static ; then
 310                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 311         fi
 312
 313         if test $ol_enable_bdb2 = yes ; then
 314                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 315         fi
 316
 317         if test $ol_enable_modules != yes -a \
 318                 $ol_enable_ldap = no -a \
 319                 $ol_enable_passwd = no -a \
 320                 $ol_enable_perl = no -a \
 321                 $ol_enable_shell = no -a \
 322                 $ol_enable_tcl = no ; then
 323                 AC_MSG_ERROR([slapd requires a backend])
 324         fi
 325
 326         ol_with_ldbm_api=no
 327         ol_with_ldbm_type=no
 328         ol_with_ldbm_module=static
 329
 330 elif test $ol_enable_bdb2 = yes ; then
 331         dnl SLAPD with BDB2
 332
 333         if test $ol_with_ldbm_api != auto -a \
 334                 $ol_with_ldbm_api != db2 ; then
 335                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 336         fi
 337
 338         ol_with_ldbm_api=db2
 339
 340 else
 341         dnl SLAPD with LDBM
 342
 343         if test $ol_enable_bdb2 != no ; then
 344                 if test $ol_with_ldbm_api != auto -a \
 345                         $ol_with_ldbm_api != db2 ; then
 346                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 347                         ol_enable_bdb2=no
 348                 fi
 349         fi
 350
 351         if test $ol_with_ldbm_api = gdbm -a \
 352                 $ol_with_ldbm_type = btree ; then
 353                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 354         fi
 355         if test $ol_with_ldbm_api = mdbm -a \
 356                 $ol_with_ldbm_type = btree ; then
 357                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 358         fi
 359         if test $ol_with_ldbm_api = ndbm -a \
 360                 $ol_with_ldbm_type = btree ; then
 361                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 362         fi
 363 fi
 364
 365 if test $ol_enable_slurpd = yes ; then
 366         dnl SLURPD was specifically enabled
 367         if test $ol_with_threads = no ; then
 368                 AC_MSG_ERROR([slurpd requires threads])
 369         fi
 370 fi
 371
 372 AC_MSG_RESULT(done)
 373
 374 ## Initialize vars
 375 LDAP_LIBS=
 376 LDIF_LIBS=
 377 LDBM_LIBS=
 378 LTHREAD_LIBS=
 379 LUTIL_LIBS=
 380
 381 LDAPD_LIBS=
 382 SLAPD_LIBS=
 383 SLURPD_LIBS=
 384
 385 BUILD_LDAPD=no
 386 BUILD_SLAPD=no
 387 BUILD_SLURPD=no
 388
 389 BUILD_BDB2=no
 390 BUILD_LDAP=no
 391 BUILD_LDBM=no
 392 BUILD_PASSWD=no
 393 BUILD_PERL=no
 394 BUILD_QUIPU=no
 395 BUILD_SHELL=no
 396 BUILD_TCL=no
 397 BUILD_THREAD=no
 398
 399 BUILD_BDB2_DYNAMIC=static
 400 BUILD_LDAP_DYNAMIC=static
 401 BUILD_LDBM_DYNAMIC=static
 402 BUILD_PASSWD_DYNAMIC=static
 403 BUILD_PERL_DYNAMIC=static
 404 BUILD_SHELL_DYNAMIC=static
 405 BUILD_TCL_DYNAMIC=static
 406
 407 SLAPD_MODULES_LDFLAGS=
 408 SLAPD_MODULES_CPPFLAGS=
 409 SLAPD_MODULES_LIST=
 410
 411 SLAPD_PERL_LDFLAGS=
 412 SLAPD_PERL_CPPFLAGS=
 413
 414 KRB_LIBS=
 415 READLINE_LIBS=
 416 SASL_LIBS=
 417 TERMCAP_LIBS=
 418 TLS_LIBS=
 419 MODULES_LIBS=
 420
 421 dnl ----------------------------------------------------------------
 422 dnl Checks for programs
 423
 424 dnl AC_PROG_INSTALL
 425
 426 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 427
 428 dnl
 429 dnl Determine which C translator to use
 430 dnl
 431
 432 dnl AIX Thread requires we use cc_r or xlc_r.
 433 dnl But only do this IF AIX and CC is not set
 434 dnl and threads are auto|yes|posix.
 435 dnl
 436 dnl If we find cc_r|xlc_r, force pthreads and assume
 437 dnl             pthread_create is in $LIBS (ie: don't bring in
 438 dnl             any additional thread libraries)
 439 dnl If we do not find cc_r|xlc_r, disable threads
 440
 441 ol_aix_threads=no
 442 case "$target" in
 443 *-*-aix*) dnl all AIX is not a good idea.
 444         if test -z "$CC" ; then
 445                 case "$ol_with_threads" in
 446                 auto | yes |  posix) ol_aix_threads=yes ;;
 447                 esac
 448         fi
 449 ;;
 450 esac
 451
 452 if test $ol_aix_threads = yes ; then
 453         if test -z "${CC}" ; then
 454                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 455
 456                 if test "$CC" = cc ; then
 457                         dnl no CC! don't allow --with-threads
 458                         if test $ol_with_threads != auto ; then
 459                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 460                         else
 461                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 462                         fi
 463                         ol_with_threads=no
 464                 fi
 465         fi
 466
 467         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 468                 ol_with_threads=posix
 469                 ol_cv_pthread_create=yes
 470         fi
 471 fi
 472
 473 if test -z "${CC}"; then
 474         AC_CHECK_PROGS(CC,cc)
 475 fi
 476
 477 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 478 dnl (for now, let autoconf sort this out)
 479 dnl CFLAGS=${CFLAGS-""}
 480
 481 AC_LIBTOOL_DLOPEN
 482 AC_PROG_LIBTOOL
 483 dnl AC_PROG_MAKE_SET
 484
 485 AC_PROG_AWK
 486 OL_PROG_LN_H
 487 AC_PROG_LN_S
 488
 489 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 490         LN_S="$LN_H"
 491 fi
 492
 493 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 494         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 495 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 496 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 497
 498 ol_link_perl=no
 499 if test $ol_enable_perl != no ; then
 500         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 501
 502         if test "no$PERLBIN" = "no" ; then
 503                 if test $ol_enable_perl = yes ; then
 504                         AC_MSG_ERROR([could not locate perl])
 505                 fi
 506
 507         else
 508                 SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 509                 SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 510
 511                 dnl should check perl version
 512                 ol_link_perl=yes
 513         fi
 514 fi
 515
 516 AC_PROG_CPP
 517
 518 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 519         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 520
 521 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 522         AC_MSG_WARN([programs compiled here do run here...])
 523         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 524
 525 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 526         AC_MSG_WARN([programs compiled here do not run here...])
 527         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 528 fi
 529
 530 dnl Checks for UNIX Variants
 531 AC_AIX
 532 AC_ISC_POSIX
 533 AC_MINIX
 534
 535 dnl Checks for system services
 536 AC_CYGWIN
 537 AC_MINGW32
 538 AC_EXEEXT
 539 AC_OBJEXT
 540
 541 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 542
 543 dnl BeOS requires -lbe -lroot -lnet
 544 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 545
 546 dnl OpenLDAP requires STDC features
 547 AM_PROG_CC_STDC
 548 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 549         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 550 fi
 551
 552 dnl Check cc depend flags
 553 OL_MKDEPEND
 554 if test "${ol_cv_mkdep}" = no ; then
 555         # this will soon become an error
 556         AC_MSG_WARN([do not know how to generate dependencies])
 557 fi
 558
 559 dnl
 560 dnl Check for module support
 561 dnl
 562 ol_link_modules=no
 563 if test $ol_enable_modules != no ; then
 564         AC_CHECK_HEADERS(ltdl.h)
 565
 566         if test $ac_cv_header_ltdl_h = no ; then
 567                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 568
 569         fi
 570
 571         AC_CHECK_LIB(ltdl, lt_dlinit)
 572         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 573                 AC_MSG_ERROR([could not locate libtool -lltdl])
 574         fi
 575         ol_link_modules=yes
 576 else
 577         ol_with_bdb2_module=static
 578         ol_with_ldap_module=static
 579         ol_with_ldbm_module=static
 580         ol_with_passwd_module=static
 581         ol_with_perl_module=static
 582         ol_with_shell_module=static
 583         ol_with_tcl_module=static
 584 fi
 585
 586 dnl ----------------------------------------------------------------
 587 dnl Checks for header files.
 588 OL_HEADER_STDC
 589
 590 if test $ol_cv_header_stdc != yes; then
 591         AC_MSG_WARN([could not locate Standard C compliant headers])
 592 fi
 593
 594 AC_HEADER_DIRENT
 595 AC_HEADER_SYS_WAIT
 596 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 597 if test $am_cv_sys_posix_termios = yes ; then
 598         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 599                 [define if you have POSIX termios])
 600 fi
 601
 602 AC_CHECK_HEADERS(       \
 603         arpa/inet.h             \
 604         arpa/nameser.h  \
 605         assert.h                \
 606         crypt.h                 \
 607         errno.h                 \
 608         fcntl.h                 \
 609         filio.h                 \
 610         getopt.h                \
 611         grp.h                   \
 612         libutil.h               \
 613         limits.h                \
 614         locale.h                \
 615         netinet/tcp.h   \
 616         malloc.h                \
 617         memory.h                \
 618         psap.h                  \
 619         pwd.h                   \
 620         resolv.h                \
 621         sgtty.h                 \
 622         shadow.h                \
 623         stddef.h                \
 624         string.h                \
 625         strings.h               \
 626         sysexits.h              \
 627         sys/file.h              \
 628         sys/filio.h             \
 629         sys/errno.h             \
 630         sys/ioctl.h             \
 631         sys/param.h             \
 632         sys/resource.h  \
 633         sys/select.h    \
 634         sys/socket.h    \
 635         sys/syslog.h    \
 636         sys/time.h              \
 637         sys/types.h             \
 638         syslog.h                \
 639         termios.h               \
 640         unistd.h                \
 641 )
 642
 643 dnl ----------------------------------------------------------------
 644 dnl Checks for libraries
 645
 646 dnl Find socket()
 647 dnl Likely combinations:
 648 dnl             -lsocket [ -lnsl_s | -lnsl ]
 649 dnl             -linet
 650
 651 AC_CHECK_FUNC(socket, :, [
 652 dnl hopefully we won't include too many libraries
 653         AC_CHECK_LIB(socket, main)
 654         AC_CHECK_LIB(net, main)
 655         AC_CHECK_LIB(net, socket)
 656         AC_CHECK_LIB(nsl_s, main)
 657         AC_CHECK_LIB(nsl, main)
 658         AC_CHECK_LIB(inet, socket)
 659         AC_CHECK_LIB(gen, main)
 660 ])
 661
 662 dnl require select
 663 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 664 dnl AC_CHECK_FUNCS(socketpair)
 665
 666 dnl Select arg types
 667 dnl (if this detection becomes permenent, it and the select() detection
 668 dnl should be done before the yielding select test)
 669 AC_FUNC_SELECT_ARGTYPES
 670
 671 dnl check to see if system call automatically restart
 672 dnl AC_SYS_RESTARTABLE_SYSCALLS
 673
 674 dnl require POSIX regex
 675 AC_CHECK_HEADERS( regex.h )
 676 if test "$ac_cv_header_regex_h" != yes ; then
 677         AC_MSG_ERROR([POSIX regex.h required.])
 678 fi
 679 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 680
 681 OL_POSIX_REGEX
 682 if test "$ol_cv_c_posix_regex" = no ; then
 683         AC_MSG_ERROR([broken POSIX regex!])
 684 fi
 685
 686 dnl HP-UX requires -lV3
 687 AC_CHECK_LIB(V3, sigset)
 688
 689 dnl Check for resolver routines
 690 AC_CHECK_FUNC(res_search,:)
 691 if test $ac_cv_func_res_search = no ; then
 692         AC_CHECK_LIB(bind, res_search)
 693         ac_cv_func_res_search=$ac_cv_lib_bind_res_search
 694 fi
 695
 696 if test $ac_cv_func_res_search = no ; then
 697         AC_CHECK_LIB(bind, __res_search)
 698         ac_cv_func_res_search=$ac_cv_lib_bind___res_search
 699 fi
 700
 701 if test $ac_cv_func_res_search = no ; then
 702         AC_CHECK_LIB(resolv, res_search)
 703         ac_cv_func_res_search=$ac_cv_lib_resolv_res_search
 704 fi
 705
 706 if test "$ac_cv_func_res_search" = yes ; then
 707         AC_DEFINE(HAVE_RES_SEARCH,1,
 708                 [define if you have res_search()])
 709 elif test $ol_enable_dns = yes ; then
 710         AC_MSG_ERROR([--enable-dns requires res_search])
 711 elif test $ol_enable_dns != no ; then
 712         AC_MSG_WARN([no res_search, disabling DNS support])
 713 fi
 714
 715
 716 # ISODE tests
 717 ol_link_isode=no
 718 if test $ol_enable_ldapd != no ; then
 719         AC_MSG_WARN([ldapd is not supported and may suffer from bit rot.])
 720
 721         dnl look for ISODE libraries
 722         AC_CHECK_LIB(xtpp, main, [
 723                 ol_link_isode=yes
 724                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 725                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 726                 ],:,[-lxtdsap -lxtisode -losi])
 727         AC_CHECK_LIB(dsap, main, [
 728                 ol_link_isode=yes
 729                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 730                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 731                 ],:,[-lisode])
 732         AC_CHECK_LIB(isode, main, [
 733                 ol_link_isode=yes
 734                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 735                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 736                 ],:)
 737 fi
 738
 739 if test $ol_link_isode != no; then
 740         AC_CHECK_LIB(pp, main, [
 741                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 742                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 743                 ],:)
 744
 745         AC_PATH_PROG(PEPSY, pepsy)
 746 fi
 747
 748 if test $ol_enable_quipu != no ; then
 749         AC_CHECK_HEADERS(quipu/commonarg.h)
 750
 751         if test $ac_cv_header_quipu_commonarg_h = yes ; then
 752                 BUILD_QUIPU=yes
 753         elif test $ol_enable_quipu = auto ; then
 754                 AC_MSG_WARN([no quipu for --enable-quipu=auto, disabling])
 755         else
 756                 AC_MSG_ERROR(no quipu for --enable-quipu=$ol_enable_quipu)
 757         fi
 758 fi
 759
 760 dnl
 761 dnl check for kerberos
 762 dnl
 763 ol_link_kerberos=no
 764
 765 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 766         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 767
 768         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 769                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 770                         [-lkrb5 -ldes425])
 771
 772                 if test $have_k5 = yes ; then
 773                         ol_with_kerberos=found
 774                         ol_link_kerberos=yes
 775
 776                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 777
 778                         LIBS="$KRB_LIBS $LIBS"
 779
 780                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 781                                 [ol_cv_var_des_debug], [
 782                                 dnl save the flags
 783                                 save_LIBS="$LIBS"
 784                                 LIBS="$KRB_LIBS $LIBS"
 785                                 AC_TRY_LINK([
 786 #include <kerberosIV/krb.h>
 787 #include <kerberosIV/des.h>
 788 extern int des_debug;
 789 ],[
 790 des_debug = 1;
 791 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 792                                 dnl restore the LIBS
 793                                 LIBS="$save_LIBS"
 794                         ])
 795
 796                         if test $ol_cv_var_des_debug = yes ; then
 797                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 798                                         [define if you have Kerberos des_debug])
 799                         fi
 800
 801                         LIBS="$save_LIBS"
 802                 fi
 803         fi
 804 fi
 805
 806 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 807         AC_CHECK_HEADERS(krb.h des.h)
 808
 809         if test $ac_cv_header_krb_h = yes ; then
 810                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 811
 812                 if test $have_k4 = yes ; then
 813                         ol_with_kerberos=found
 814                         ol_link_kerberos=yes
 815
 816                         KRB_LIBS="-lkrb -ldes"
 817                 fi
 818         fi
 819 fi
 820
 821 if test $ol_link_kerberos = yes ; then
 822         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 823 fi
 824
 825 dnl
 826 dnl Check for SSL/TLS
 827 dnl
 828 ol_link_tls=no
 829 if test $ol_with_tls != no ; then
 830
 831         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 832
 833         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 834                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 835                         [have_ssleay=yes
 836                         need_rsaref=no],
 837                         [have_ssleay=no],
 838                         [-lcrypto])
 839
 840                 if test $have_ssleay = no ; then
 841                         AC_CHECK_LIB(ssl, SSL_library_init,
 842                                 [have_ssleay=yes
 843                                 need_rsaref=no], [have_ssleay=no],
 844                                 [-lcrypto])
 845                 fi
 846
 847                 if test $have_ssleay = no ; then
 848                         AC_CHECK_LIB(ssl, ssl3_accept,
 849                                 [have_ssleay=yes
 850                                 need_rsaref=yes], [have_ssleay=no],
 851                                 [-lcrypto -lRSAglue -lrsaref])
 852                 fi
 853
 854                 if test $have_ssleay = yes ; then
 855                         ol_with_tls=found
 856                         ol_link_tls=yes
 857
 858                         AC_DEFINE(HAVE_SSLEAY, 1,
 859                                 [define if you have SSLeay or OpenSSL])
 860
 861                         if test $need_rsaref = yes; then
 862                                 AC_DEFINE(HAVE_RSAREF, 1,
 863                                         [define if you have RSAref])
 864
 865                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 866                         else
 867                                 TLS_LIBS="-lssl -lcrypto"
 868                         fi
 869                 fi
 870         fi
 871 fi
 872
 873 if test $ol_link_tls = yes ; then
 874         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 875 fi
 876
 877 dnl Tests for reentrant functions necessary to build a
 878 dnl thread_safe -lldap.
 879 AC_CHECK_FUNCS(         \
 880         ctime_r                 \
 881         gethostbyname_r gethostbyaddr_r \
 882 )
 883
 884 if test "$ac_cv_func_ctime_r" = no ; then
 885         ol_cv_func_ctime_r_nargs=0
 886 else
 887         OL_FUNC_CTIME_R_NARGS
 888 dnl     OL_FUNC_CTIME_R_TYPE
 889 fi
 890
 891 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 892         OL_FUNC_GETHOSTBYNAME_R_NARGS
 893 else
 894         ol_cv_func_gethostbyname_r_nargs=0
 895 fi
 896
 897 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 898         OL_FUNC_GETHOSTBYADDR_R_NARGS
 899 else
 900         ol_cv_func_gethostbyaddr_r_nargs=0
 901 fi
 902
 903 if test "$ac_cv_func_ctime_r" = yes \
 904         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 905         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 906         -a "$ac_cv_func_gethostbyname_r" = yes \
 907         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 908         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 909         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 910         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 911         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 912         ; then
 913
 914         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 915 fi
 916
 917 ol_link_threads=no
 918 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 919         -o $ol_with_threads = posix ; then
 920
 921         AC_CHECK_HEADERS(pthread.h)
 922
 923         if test $ac_cv_header_pthread_h = yes ; then
 924                 OL_POSIX_THREAD_VERSION
 925
 926                 if test $ol_cv_pthread_version = final ; then
 927                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 928                                 [define if pthreads API compatible with final spec])
 929                 elif test $ol_cv_pthread_version = draft4 ; then
 930                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 931                                 [define if pthreads API compatible with draft4 spec])
 932                 else
 933                         AC_MSG_ERROR([unknown pthread version])
 934                 fi
 935
 936                 # consider threads found
 937                 ol_with_threads=found
 938
 939                 OL_HEADER_LINUX_THREADS
 940                 OL_HEADER_GNU_PTH_PTHREAD_H
 941
 942                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
 943                         AC_CHECK_HEADERS(sched.h)
 944                 fi
 945
 946                 dnl Now the hard part, how to link?
 947                 dnl
 948                 dnl currently supported checks:
 949                 dnl
 950                 dnl Check for no flags
 951                 dnl     pthread_create() in $LIBS
 952                 dnl
 953                 dnl Check special pthread (final) flags
 954                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
 955                 dnl     pthread_create() with -kthread (FreeBSD)
 956                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 957                 dnl     pthread_create() with -pthreads (?)
 958                 dnl     pthread_create() with -mthreads (AIX)
 959                 dnl     pthread_create() with -thread (?)
 960                 dnl
 961                 dnl Check pthread (final) libraries
 962                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 963                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 964                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 965                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
 966                 dnl     pthread_create() in -lpthread (many)
 967                 dnl     pthread_create() in -lc_r (FreeBSD)
 968                 dnl
 969                 dnl Check pthread (draft4) flags (depreciated)
 970                 dnl     pthread_create() with -threads (OSF/1)
 971                 dnl
 972                 dnl Check pthread (draft4) libraries (depreciated)
 973                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 974                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 975                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 976                 dnl     pthread_create() in -lpthreads (many)
 977                 dnl
 978
 979                 dnl pthread_create in $LIBS
 980                 AC_CACHE_CHECK([for pthread_create in default libraries],
 981                         ol_cv_pthread_create,[
 982                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
 983                         [ol_cv_pthread_create=yes],
 984                         [ol_cv_pthread_create=no],
 985                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
 986                                 [ol_cv_pthread_create=yes],
 987                                 [ol_cv_pthread_create=no])])])
 988
 989                 if test $ol_cv_pthread_create != no ; then
 990                         ol_link_threads=posix
 991                         ol_link_pthreads=""
 992                 fi
 993
 994 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
 995                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
 996                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
 997                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
 998                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
 999                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1000
1001                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1002                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1003                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1004                         [ol_cv_pthread_lpthread_lmach_lexc])
1005 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1006 dnl                     [ol_cv_pthread_lpthread_lexc])
1007
1008                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1009                         [ol_cv_pthread_lib_lpthread_woff])
1010
1011                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1012                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1013
1014                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1015
1016                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1017                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1018                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1019                         [ol_cv_pthread_lpthreads_lmach_lexc])
1020                 OL_PTHREAD_TRY([-lpthreads -lexc],
1021                         [ol_cv_pthread_lpthreads_lexc])
1022
1023                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1024
1025                 if test $ol_link_threads != no ; then
1026                         AC_DEFINE(HAVE_PTHREADS,1,
1027                                 [define if you have POSIX Threads])
1028
1029                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1030
1031                         dnl save flags
1032                         save_CPPFLAGS="$CPPFLAGS"
1033                         save_LIBS="$LIBS"
1034                         LIBS="$LTHREAD_LIBS $LIBS"
1035
1036                         dnl All POSIX Thread (final) implementations should have
1037                         dnl sched_yield instead of pthread yield.
1038                         dnl check for both
1039                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1040
1041                         if test $ac_cv_func_sched_yield = no -a \
1042                                 $ac_cv_func_pthread_yield = no ; then
1043                                 dnl Digital UNIX has sched_yield() in -lrt
1044                                 AC_CHECK_LIB(rt, sched_yield,
1045                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1046                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1047                                                 [Define if you have the sched_yield function.])
1048                                         ac_cv_func_sched_yield=yes],
1049                                         [ac_cv_func_sched_yield=no])
1050                         fi
1051                         if test $ac_cv_func_sched_yield = no -a \
1052                                 $ac_cv_func_pthread_yield = no ; then
1053                                 dnl Solaris has sched_yield() stub in -lposix4
1054                                 dnl but we'll use thr_yield instead.
1055                                 AC_CHECK_FUNCS(thr_yield)
1056                         fi
1057                         if test $ac_cv_func_sched_yield = no -a \
1058                                 $ac_cv_func_pthread_yield = no -a \
1059                                 "$ac_cv_func_thr_yield" = no ; then
1060                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1061                         fi
1062
1063                         dnl Check functions for compatibility
1064                         AC_CHECK_FUNCS(pthread_kill)
1065
1066                         dnl Check for pthread_detach with <pthread.h> inclusion
1067                         dnl as it's symbol may have been mangled.
1068                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1069                                 [ol_cv_func_pthread_detach], [
1070                                 dnl save the flags
1071                                 AC_TRY_LINK([
1072 #include <pthread.h>
1073 #ifndef NULL
1074 #define NULL (void*)0
1075 #endif
1076 ],
1077                                         [pthread_detach(NULL);],
1078                                         [ol_cv_func_pthread_detach=yes],
1079                                         [ol_cv_func_pthread_detach=no])
1080                         ])
1081
1082                         if test $ol_cv_func_pthread_detach = no ; then
1083                                 AC_MSG_ERROR([could not locate pthread_detach()])
1084                         fi
1085
1086                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1087                                 [define if you have pthread_detach function])
1088
1089                         dnl Check for setconcurreny functions
1090                         AC_CHECK_FUNCS( \
1091                                 pthread_setconcurrency \
1092                                 pthread_getconcurrency \
1093                                 thr_setconcurrency \
1094                                 thr_getconcurrency \
1095                         )
1096
1097                         OL_SYS_LINUX_THREADS
1098                         OL_LINUX_THREADS
1099
1100                         if test $ol_cv_linux_threads = error; then
1101                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1102                         fi
1103
1104                         AC_CACHE_CHECK([if pthread_create() works],
1105                                 ol_cv_pthread_create_works,[
1106                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1107                                 [ol_cv_pthread_create_works=yes],
1108                                 [ol_cv_pthread_create_works=no],
1109                                 [dnl assume yes
1110                                 ol_cv_pthread_create_works=yes])])
1111
1112                         if test $ol_cv_pthread_create_works = no ; then
1113                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1114                         fi
1115
1116                         dnl Check if select causes an yield
1117                         if test $ol_with_yielding_select = auto ; then
1118                                 AC_CACHE_CHECK([if select yields when using pthreads],
1119                                         ol_cv_pthread_select_yields,[
1120                                 AC_TRY_RUN([
1121 #include <sys/types.h>
1122 #include <sys/time.h>
1123 #include <unistd.h>
1124 #include <pthread.h>
1125 #ifndef NULL
1126 #define NULL (void*) 0
1127 #endif
1128
1129 static int fildes[2];
1130
1131 static void *task(p)
1132         void *p;
1133 {
1134         int i;
1135         struct timeval tv;
1136
1137         fd_set rfds;
1138
1139         tv.tv_sec=10;
1140         tv.tv_usec=0;
1141
1142         FD_ZERO(&rfds);
1143         FD_SET(fildes[0], &rfds);
1144
1145         /* we're not interested in any fds */
1146         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1147
1148         if(i < 0) {
1149                 perror("select");
1150                 exit(10);
1151         }
1152
1153         exit(0); /* if we exit here, the select blocked the whole process */
1154 }
1155
1156 int main(argc, argv)
1157         int argc;
1158         char **argv;
1159 {
1160         pthread_t t;
1161
1162         /* create a pipe to select */
1163         if(pipe(&fildes[0])) {
1164                 perror("select");
1165                 exit(1);
1166         }
1167
1168 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1169         (void) pthread_setconcurrency(2);
1170 #else
1171 #ifdef HAVE_THR_SETCONCURRENCY
1172         /* Set Solaris LWP concurrency to 2 */
1173         thr_setconcurrency(2);
1174 #endif
1175 #endif
1176
1177 #if HAVE_PTHREADS_D4
1178         pthread_create(&t, pthread_attr_default, task, NULL);
1179 #else
1180         pthread_create(&t, NULL, task, NULL);
1181 #endif
1182
1183 #if HAVE_SCHED_YIELD
1184         sched_yield();  /* make sure task runs first */
1185 #else
1186 #ifdef HAVE_PTHREAD_YIELD
1187         pthread_yield();        /* make sure task runs first */
1188 #endif
1189 #endif
1190
1191         exit(2);
1192 }],
1193                                 [ol_cv_pthread_select_yields=no],
1194                                 [ol_cv_pthread_select_yields=yes],
1195                                 [ol_cv_pthread_select_yields=cross])])
1196
1197                                 if test $ol_cv_pthread_select_yields = cross ; then
1198                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1199                                 fi
1200
1201                                 if test $ol_cv_pthread_select_yields = yes ; then
1202                                         ol_with_yielding_select=yes
1203                                 fi
1204                         fi
1205
1206                         dnl restore flags
1207                         CPPFLAGS="$save_CPPFLAGS"
1208                         LIBS="$save_LIBS"
1209                 else
1210                         AC_MSG_ERROR([could not link with POSIX Threads])
1211                 fi
1212         fi
1213
1214         if test $ol_with_threads = posix ; then
1215                 AC_MSG_ERROR([could not locate POSIX Threads])
1216         fi
1217 fi
1218
1219 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1220         -o $ol_with_threads = mach ; then
1221
1222         dnl check for Mach CThreads
1223         AC_CHECK_HEADERS(mach/cthreads.h)
1224         if test $ac_cv_header_mach_cthreads_h = yes ; then
1225                 ol_with_threads=found
1226
1227                 dnl check for cthread support in current $LIBS
1228                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1229
1230                 if test $ol_link_threads = no ; then
1231                         dnl try -all_load
1232                         dnl this test needs work
1233                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1234                                 [ol_cv_cthread_all_load], [
1235                                 dnl save the flags
1236                                 save_LIBS="$LIBS"
1237                                 LIBS="-all_load $LIBS"
1238                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1239                                         cthread_fork((void *)0, (void *)0);
1240                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1241                                 dnl restore the LIBS
1242                                 LIBS="$save_LIBS"
1243                         ])
1244
1245                         if test $ol_cv_cthread_all_load = yes ; then
1246                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1247                                 ol_link_threads=mach
1248                         fi
1249                 fi
1250
1251                 if test $ol_link_threads != no ; then
1252                         : check for cthread specific functionality here
1253                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1254                                 [define if you have Mach Cthreads])
1255                 else
1256                         AC_MSG_ERROR([could not link with Mach CThreads])
1257                 fi
1258         fi
1259
1260         if test $ol_with_threads = mach ; then
1261                 AC_MSG_ERROR([could not locate Mach CThreads])
1262         fi
1263 fi
1264
1265 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1266         -o $ol_with_threads = pth ; then
1267
1268         AC_CHECK_HEADERS(pth.h)
1269
1270         if test $ac_cv_header_pth_h = yes ; then
1271                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1272
1273                 if test $have_pth = yes ; then
1274                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1275                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1276                         ol_link_threads=pth
1277
1278                         if test $ol_with_yielding_select = auto ; then
1279                                 ol_with_yielding_select=yes
1280                         fi
1281                 fi
1282         fi
1283 fi
1284
1285 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1286         -o $ol_with_threads = lwp ; then
1287
1288         dnl check for SunOS5 LWP
1289         AC_CHECK_HEADERS(thread.h synch.h)
1290         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1291                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1292
1293                 if test $have_thr = yes ; then
1294                         AC_DEFINE(HAVE_THR,1,
1295                                 [if you have Solaris LWP (thr) package])
1296                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1297                         ol_link_threads=thr
1298
1299                         if test $ol_with_yielding_select = auto ; then
1300                                 ol_with_yielding_select=yes
1301                         fi
1302
1303                         dnl Check for setconcurreny functions
1304                         AC_CHECK_FUNCS( \
1305                                 thr_setconcurrency \
1306                                 thr_getconcurrency \
1307                         )
1308                 fi
1309         fi
1310
1311         dnl check for SunOS4 LWP
1312         AC_CHECK_HEADERS(lwp/lwp.h)
1313         if test $ac_cv_header_lwp_lwp_h = yes ; then
1314                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1315
1316                 if test $have_lwp = yes ; then
1317                         AC_DEFINE(HAVE_LWP,1,
1318                                 [if you have SunOS LWP package])
1319                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1320                         ol_link_threads=lwp
1321
1322                         if test $ol_with_yielding_select = auto ; then
1323                                 ol_with_yielding_select=no
1324                         fi
1325                 fi
1326         fi
1327 fi
1328
1329 if test $ol_with_yielding_select = yes ; then
1330         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1331                 [define if select implicitly yields])
1332 fi
1333
1334 if test $ol_with_threads = manual ; then
1335         dnl User thinks he can manually configure threads.
1336         ol_link_threads=yes
1337
1338         AC_MSG_WARN([thread defines and link options must be set manually])
1339
1340         AC_CHECK_HEADERS(pthread.h sched.h)
1341         AC_CHECK_FUNCS(sched_yield pthread_yield)
1342         OL_HEADER_LINUX_THREADS
1343
1344         AC_CHECK_HEADERS(mach/cthreads.h)
1345         AC_CHECK_HEADERS(lwp/lwp.h)
1346         AC_CHECK_HEADERS(thread.h synch.h)
1347 fi
1348
1349 if test $ol_link_threads != no ; then
1350         dnl needed to get reentrant/threadsafe versions
1351         dnl
1352         AC_DEFINE(REENTRANT,1)
1353         AC_DEFINE(_REENTRANT,1)
1354         AC_DEFINE(THREAD_SAFE,1)
1355         AC_DEFINE(_THREAD_SAFE,1)
1356         AC_DEFINE(THREADSAFE,1)
1357         AC_DEFINE(_THREADSAFE,1)
1358         AC_DEFINE(_SGI_MP_SOURCE,1)
1359
1360         dnl The errno declaration may dependent upon _REENTRANT.
1361         dnl If it does, we must link with thread support.
1362         AC_CACHE_CHECK([for thread specific errno],
1363                 [ol_cv_errno_thread_specific], [
1364                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1365                         [ol_cv_errno_thread_specific=yes],
1366                         [ol_cv_errno_thread_specific=no])
1367         ])
1368
1369         dnl The h_errno declaration may dependent upon _REENTRANT.
1370         dnl If it does, we must link with thread support.
1371         AC_CACHE_CHECK([for thread specific h_errno],
1372                 [ol_cv_h_errno_thread_specific], [
1373                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1374                         [ol_cv_h_errno_thread_specific=yes],
1375                         [ol_cv_h_errno_thread_specific=no])
1376         ])
1377
1378         if test $ol_cv_errno_thread_specific != yes \
1379                 -o $ol_cv_h_errno_thread_specific != yes ; then
1380                 LIBS="$LTHREAD_LIBS $LIBS"
1381                 LTHREAD_LIBS=""
1382         fi
1383
1384 dnl When in thread environment, use
1385 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1386 dnl                     || defined( HAVE_FUNC_R )
1387 dnl                     func_r(...);
1388 dnl             #else
1389 dnl             #       if defined( HAVE_THREADS )
1390 dnl                             /* lock */
1391 dnl             #       endif
1392 dnl                             func(...);
1393 dnl             #       if defined( HAVE_THREADS )
1394 dnl                             /* unlock */
1395 dnl             #       endif
1396 dnl             #endif
1397 dnl
1398 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1399 dnl             _POSIX_REENTRANT_FUNCTIONS
1400 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1401 dnl             _POSIX_THREADSAFE_FUNCTIONS
1402 dnl
1403 dnl             and is currently defined in lthread.h
1404 dnl
1405 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1406 dnl
1407 dnl libldap/*.c should only include <lthread.h> iff
1408 dnl LDAP_R_COMPILE is defined.  ie:
1409 dnl             #ifdef LDAP_R_COMPILE
1410 dnl             #       include LDAP_R_COMPILE
1411 dnl             #endif
1412 dnl
1413 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1414 dnl specifically for compiling the threadsafe version of
1415 dnl     the ldap library (-lldap_r).
1416 dnl
1417 dnl     dnl check for reentrant/threadsafe functions
1418 dnl     dnl
1419 dnl     dnl note: these should only be used when linking
1420 dnl     dnl       with $LTHREAD_LIBS
1421 dnl     dnl
1422 dnl     save_CPPFLAGS="$CPPFLAGS"
1423 dnl     save_LIBS="$LIBS"
1424 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1425 dnl     AC_CHECK_FUNCS( \
1426 dnl             gmtime_r \
1427 dnl             gethostbyaddr_r gethostbyname_r \
1428 dnl             feof_unlocked unlocked_feof \
1429 dnl             putc_unlocked unlocked_putc \
1430 dnl             flockfile ftrylockfile \
1431 dnl     )
1432 dnl     CPPFLAGS="$save_CPPFLAGS"
1433 dnl     LIBS="$save_LIBS"
1434 fi
1435
1436 if test $ol_link_threads = no ; then
1437         if test $ol_with_threads = yes ; then
1438                 AC_MSG_ERROR([no suitable thread support])
1439         fi
1440
1441         if test $ol_with_threads = auto ; then
1442                 AC_MSG_WARN([no suitable thread support, disabling threads])
1443                 ol_with_threads=no
1444         fi
1445
1446         AC_DEFINE(NO_THREADS,1,
1447                 [define if you have (or want) no threads])
1448         LTHREAD_LIBS=""
1449 fi
1450
1451 if test $ol_link_threads != no ; then
1452         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1453 fi
1454
1455 dnl ----------------------------------------------------------------
1456
1457 ol_link_ldbm=no
1458 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1459         OL_BERKELEY_DB2
1460
1461         if test $ol_cv_berkeley_db2 = yes ; then
1462                 ol_link_ldbm=db2
1463                 ol_with_ldbm_api=db2
1464
1465                 if test $ol_with_ldbm_type = hash ; then
1466                         AC_DEFINE(LDBM_USE_DBHASH,1,
1467                                 [define this to use DBHASH w/ LDBM backend])
1468                 else
1469                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1470                                 [define this to use DBBTREE w/ LDBM backend])
1471                 fi
1472
1473                 dnl $ol_cv_lib_db2 should be yes or -ldb
1474                 dnl (it could be no, but that would be an error
1475                 if test $ol_cv_lib_db2 != yes ; then
1476                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1477                 fi
1478         fi
1479 fi
1480
1481 ol_link_bdb2=no
1482 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1483         ol_link_bdb2=yes
1484 fi
1485
1486 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1487         OL_BERKELEY_DB
1488
1489         if test $ol_cv_berkeley_db = yes ; then
1490                 ol_link_ldbm=db
1491                 ol_with_ldbm_api=db
1492
1493                 if test $ol_with_ldbm_type = hash ; then
1494                         AC_DEFINE(LDBM_USE_DBHASH,1,
1495                                 [define this to use DBHASH w/ LDBM backend])
1496                 else
1497                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1498                                 [define this to use DBBTREE w/ LDBM backend])
1499                 fi
1500
1501                 dnl $ol_cv_lib_db should be yes or -ldb
1502                 dnl (it could be no, but that would be an error
1503                 if test $ol_cv_lib_db != yes ; then
1504                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1505                 fi
1506         fi
1507 fi
1508
1509 if test $ol_with_ldbm_api = manual ; then
1510         dnl User thinks he can manually configure LDBM api.
1511         ol_link_ldbm=yes
1512
1513         AC_MSG_WARN([LDBM defines and link options must be set manually])
1514
1515         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1516 fi
1517
1518 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1519         AC_MSG_WARN(Could not find LDBM with BTREE support)
1520         ol_with_ldbm_api=none
1521 fi
1522
1523 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1524         OL_MDBM
1525
1526         if test $ol_cv_mdbm = yes ; then
1527                 ol_link_ldbm=mdbm
1528                 ol_with_ldbm_api=mdbm
1529                 if test $ol_cv_lib_mdbm != yes ; then
1530                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1531                 fi
1532         fi
1533 fi
1534
1535 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1536         OL_GDBM
1537
1538         if test $ol_cv_gdbm = yes ; then
1539                 ol_link_ldbm=gdbm
1540                 ol_with_ldbm_api=gdbm
1541
1542                 if test $ol_cv_lib_gdbm != yes ; then
1543                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1544                 fi
1545         fi
1546 fi
1547
1548 if test $ol_with_ldbm_api = auto ; then
1549         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1550 elif test $ol_with_ldbm_api = ndbm ; then
1551         OL_NDBM
1552
1553         if test $ol_cv_ndbm = yes ; then
1554                 ol_link_ldbm=ndbm
1555                 ol_with_ldbm_api=ndbm
1556
1557                 if test $ol_cv_lib_ndbm != yes ; then
1558                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1559                 fi
1560         fi
1561 fi
1562
1563 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1564         AC_MSG_WARN(could not find suitable LDBM backend)
1565         if test $ol_enable_ldbm = yes ; then
1566                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1567         fi
1568
1569         AC_MSG_WARN(disabling LDBM)
1570         ol_enable_ldbm=no
1571 fi
1572
1573 if test $ol_enable_wrappers != no ; then
1574         AC_CHECK_HEADERS(tcpd.h)
1575
1576         if test $ac_cv_header_tcpd_h != yes ; then
1577                 have_wrappers=no
1578         else
1579                 AC_CHECK_LIB(wrap, main,
1580                         [have_wrappers=yes], [have_wrappers=no])
1581         fi
1582
1583         if test $have_wrappers = yes ; then
1584                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1585                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1586
1587                 dnl We add another check for -lnsl since some libwrap's
1588                 dnl need it, but it isn't always included from above
1589                 AC_CHECK_LIB(nsl, main)
1590         else
1591                 AC_MSG_WARN(could not find -lwrap)
1592                 if test $ol_enable_wrappers = yes ; then
1593                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1594                 fi
1595
1596                 AC_MSG_WARN(disabling wrappers support)
1597                 ol_enable_wrappers=no
1598         fi
1599 fi
1600
1601 if test $ol_enable_syslog != no ; then
1602         AC_CHECK_FUNC(openlog)
1603         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1604                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1605         fi
1606         ol_enable_syslog=$ac_cv_func_openlog
1607 fi
1608
1609 if test $ol_enable_dmalloc != no ; then
1610         AC_CHECK_HEADERS(dmalloc.h)
1611         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1612 fi
1613
1614 if test $ol_enable_tcl != no ; then
1615         AC_CHECK_HEADERS(tcl.h)
1616
1617         if test $ac_cv_header_tcl_h != yes ; then
1618                 have_tcl=no
1619         else
1620                 AC_CHECK_LIB(tcl,main,
1621                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1622                         [have_tcl=no])
1623
1624                 if test $have_tcl != yes; then
1625                         AC_CHECK_LIB(tcl7.6,main,
1626                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1627                                 [have_tcl=no])
1628                 fi
1629
1630                 if test $have_tcl != yes; then
1631                         AC_CHECK_LIB(tcl8.0,main,
1632                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1633                                 [have_tcl=no])
1634                 fi
1635         fi
1636
1637         if test $have_tcl != yes ; then
1638                 AC_MSG_WARN([could not find -ltcl])
1639                 if test $ol_enable_tcl = yes ; then
1640                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1641                 fi
1642
1643                 ol_enable_tcl=no
1644         fi
1645 fi
1646
1647 # ud needs termcap (should insert check here)
1648 ol_link_termcap=no
1649 AC_CHECK_HEADERS(termcap.h ncurses.h)
1650
1651 if test $ol_link_termcap = no ; then
1652         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1653         if test $have_termcap = yes ; then
1654                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1655                 ol_link_termcap=yes
1656                 TERMCAP_LIBS=-ltermcap
1657         fi
1658 fi
1659
1660 if test $ol_link_termcap = no ; then
1661         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1662         if test $have_ncurses = yes ; then
1663                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1664                 ol_link_termcap=yes
1665                 TERMCAP_LIBS=-lncurses
1666         fi
1667 fi
1668
1669 if test $ol_link_termcap = no ; then
1670         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1671         TERMCAP_LIBS=
1672 fi
1673
1674 dnl
1675 dnl Check for fetch URL support
1676 dnl             should be extended to support other fetch URL APIs
1677 dnl
1678 ol_link_sasl=no
1679 if test $ol_with_cyrus_sasl != no ; then
1680         AC_CHECK_HEADER(sasl.h)
1681
1682         if test $ac_cv_header_sasl_h = yes ; then
1683                 AC_CHECK_LIB(sasl, sasl_client_init,
1684                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1685
1686                 if test $have_cyrus_sasl != no ; then
1687                         SASL_LIBS="-lsasl"
1688                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1689                         ol_link_sasl=yes
1690                 fi
1691         fi
1692
1693         if test $ol_link_sasl = no -a $ol_with_cyrus_sasl = yes ; then
1694                 AC_MSG_ERROR(no suitable API for --with-cyrus-sasl=$ol_with_cyrus_sasl)
1695         fi
1696 fi
1697
1698 dnl
1699 dnl Check for fetch URL support
1700 dnl             should be extended to support other fetch URL APIs
1701 dnl
1702 ol_link_fetch=no
1703 if test $ol_with_fetch != no ; then
1704         OL_LIB_FETCH
1705
1706         if test $ol_cv_lib_fetch != no ; then
1707                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1708                 ol_link_fetch=freebsd
1709
1710         elif test $ol_with_fetch != auto ; then
1711                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1712         fi
1713 fi
1714
1715 dnl
1716 dnl Check for GNU readline
1717 dnl
1718 ol_link_readline=no
1719 if test $ol_with_readline != no ; then
1720         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1721
1722         if test $ac_cv_header_readline_readline_h = yes ; then
1723                 save_LIBS="$LIBS"
1724                 LIBS="$TERMCAP_LIBS $LIBS"
1725                 AC_CHECK_LIB(readline, readline,
1726                         [have_readline=yes], [have_readline=no])
1727                 LIBS="$save_LIBS"
1728
1729                 if test $have_readline = yes ; then
1730                         ol_with_readline=found
1731                         ol_link_readline=yes
1732
1733                         READLINE_LIBS="-lreadline"
1734                 fi
1735         fi
1736 fi
1737
1738 if test $ol_link_readline = yes ; then
1739         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1740 fi
1741
1742
1743 # FreeBSD (and others) have crypt(3) in -lcrypt
1744 if test $ol_enable_crypt != no ; then
1745         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1746                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1747                         have_crypt=yes], [have_crypt=no])])
1748
1749         if test $have_crypt = yes ; then
1750                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1751         else
1752                 AC_MSG_WARN(could not find crypt)
1753                 if test $ol_enable_crypt = yes ; then
1754                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1755                 fi
1756
1757                 AC_MSG_WARN(disabling crypt support)
1758                 ol_enable_crypt=no
1759         fi
1760 fi
1761
1762 # FreeBSD (and others) have setproctitle(3) in -lutil
1763 if test $ol_enable_proctitle != no ; then
1764         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1765                 AC_CHECK_LIB(util, setproctitle,
1766                         [have_setproctitle=yes
1767                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1768                         [have_setproctitle=no
1769                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1770
1771         if test $have_setproctitle = yes ; then
1772                 AC_DEFINE(HAVE_SETPROCTITLE,1,
1773                         [define if setproctitle(3) is available])
1774         fi
1775 fi
1776
1777 dnl ----------------------------------------------------------------
1778 dnl Checks for typedefs, structures, and compiler characteristics.
1779 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1780 AC_TYPE_MODE_T
1781 AC_TYPE_OFF_T
1782 AC_TYPE_PID_T
1783 AM_TYPE_PTRDIFF_T
1784 AC_TYPE_SIGNAL
1785 OL_TYPE_SIG_ATOMIC_T
1786 AC_TYPE_SIZE_T
1787 OL_TYPE_SOCKLEN_T
1788 AC_STRUCT_ST_BLKSIZE
1789 AC_HEADER_TIME
1790 AC_STRUCT_TM
1791 OL_STRUCT_PASSWD_PW_GECOS
1792 OL_STRUCT_PASSWD_PW_PASSWD
1793
1794 OL_C_UPPER_LOWER
1795 AC_C_CONST
1796 OL_C_VOLATILE
1797
1798 if test $cross_compiling = yes ; then
1799         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1800
1801         AC_DEFINE(LBER_INT_T,long)
1802         AC_DEFINE(LBER_TAG_T,long)
1803         AC_DEFINE(LBER_SOCKET_T,int)
1804
1805 else
1806         AC_C_BIGENDIAN
1807         AC_CHECK_SIZEOF(short)
1808         AC_CHECK_SIZEOF(int)
1809         AC_CHECK_SIZEOF(long)
1810
1811         if test "$ac_cv_sizeof_int" -lt 4 ; then
1812                 AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
1813
1814                 AC_DEFINE(LBER_INT_T,long)
1815                 AC_DEFINE(LBER_TAG_T,long)
1816                 AC_DEFINE(LBER_SOCKET_T,int)
1817         else
1818                 AC_DEFINE(LBER_INT_T,int)
1819                 AC_DEFINE(LBER_TAG_T,long)
1820                 AC_DEFINE(LBER_SOCKET_T,int)
1821         fi
1822 fi
1823
1824 AC_DEFINE(LBER_LEN_T,long)
1825
1826 dnl ----------------------------------------------------------------
1827 dnl Checks for library functions.
1828 AC_FUNC_MEMCMP
1829 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1830 AC_FUNC_STRFTIME
1831 dnl AM_FUNC_STRTOD
1832
1833 OL_FUNC_INET_ATON
1834
1835 dnl we should use vfork instead of fork in a number of places...
1836 dnl AC_FUNC_VFORK
1837 AC_FUNC_VPRINTF
1838
1839 if test $ac_cv_func_vprintf = yes ; then
1840         dnl check for vsnprintf
1841         AC_CHECK_FUNCS(vsnprintf vsprintf)
1842 fi
1843
1844 AC_CHECK_FUNCS(         \
1845         bcopy                   \
1846         closesocket             \
1847         endgrent                \
1848         endpwent                \
1849         flock                   \
1850         getdtablesize   \
1851         getgrgid                \
1852         gethostname             \
1853         getpass                 \
1854         getpwuid                \
1855         getpwnam                \
1856         getspnam                \
1857         gettimeofday    \
1858         initgroups              \
1859         lockf                   \
1860         memcpy                  \
1861         memmove                 \
1862         mkstemp                 \
1863         pipe                    \
1864         read                    \
1865         recv                    \
1866         recvfrom                \
1867         setpwfile               \
1868         setgid                  \
1869         setegid                 \
1870         setsid                  \
1871         setuid                  \
1872         seteuid                 \
1873         sigaction               \
1874         signal                  \
1875         sigset                  \
1876         snprintf                \
1877         strdup                  \
1878         strerror                \
1879         strpbrk                 \
1880         strrchr                 \
1881         strsep                  \
1882         strstr                  \
1883         strtol                  \
1884         strtoul                 \
1885         strspn                  \
1886         sysconf                 \
1887         waitpid                 \
1888         wait4                   \
1889         write                   \
1890         send                    \
1891         sendto                  \
1892 )
1893
1894 dnl We actually may need to replace more than this.
1895 AC_REPLACE_FUNCS(getopt tempnam)
1896
1897 dnl ----------------------------------------------------------------
1898 # Check Configuration
1899 OL_SYS_ERRLIST
1900
1901 dnl ----------------------------------------------------------------
1902 dnl Sort out defines
1903
1904 if test "$ol_enable_debug" != no ; then
1905         AC_DEFINE(LDAP_DEBUG,1,
1906                 [define this to add debugging code])
1907 fi
1908 if test "$ol_enable_syslog" = yes ; then
1909         AC_DEFINE(LDAP_SYSLOG,1,
1910                 [define this to add syslog code])
1911 fi
1912 if test "$ol_enable_libui" = yes ; then
1913         AC_DEFINE(LDAP_LIBUI,1,
1914                 [define this for LDAP User Interface support])
1915 fi
1916 if test "$ol_enable_cache" = no ; then
1917         AC_DEFINE(LDAP_NOCACHE,1,
1918                 [define this to remove -lldap cache support])
1919 fi
1920 if test "$ol_enable_dns" != no ; then
1921         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1922 fi
1923 if test "$ol_enable_proctitle" != no ; then
1924         AC_DEFINE(LDAP_PROCTITLE,1,
1925                 [define this for LDAP process title support])
1926 fi
1927 if test "$ol_enable_referrals" != no ; then
1928         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1929 fi
1930 if test "$ol_enable_cldap" != no ; then
1931         AC_DEFINE(LDAP_CONNECTIONLESS,1,[define to support CLDAP])
1932 fi
1933
1934 if test "$ol_enable_crypt" != no ; then
1935         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
1936 fi
1937 if test "$ol_enable_cleartext" != no ; then
1938         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
1939 fi
1940 if test "$ol_enable_multimaster" != no ; then
1941         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
1942 fi
1943 if test "$ol_enable_phonetic" != no ; then
1944         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
1945 fi
1946 if test "$ol_enable_rlookups" != no ; then
1947         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
1948 fi
1949 if test "$ol_enable_aci" != no ; then
1950         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
1951 fi
1952 if test "$ol_enable_discreteaci" != no ; then
1953         AC_DEFINE(SLAPD_ACI_DISCRETE_RIGHTS,1,[define to support discrete rights in ACIs])
1954 fi
1955
1956 if test "$ol_link_modules" != no ; then
1957         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
1958         BUILD_SLAPD=yes
1959         MODULES_LIBS=-lltdl
1960         SLAPD_MODULES_LDFLAGS="-dlopen self"
1961 fi
1962
1963 if test "$ol_link_bdb2" != no ; then
1964         AC_DEFINE(SLAPD_BDB2,1,[define to support BDB2 backend])
1965         BUILD_SLAPD=yes
1966         BUILD_BDB2=yes
1967         if test "$ol_with_bdb2_module" != static ; then
1968                 AC_DEFINE(SLAPD_BDB2_DYNAMIC,1,
1969                         [define to support dynamic BDB2 backend])
1970                 BUILD_BDB2=mod
1971                 BUILD_BDB2_DYNAMIC=shared
1972                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-bdb2/back_bdb2.la"
1973         fi
1974 fi
1975
1976 if test "$ol_enable_ldap" != no ; then
1977         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
1978         BUILD_SLAPD=yes
1979         BUILD_LDAP=yes
1980         if test "$ol_with_ldap_module" != static ; then
1981                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
1982                         [define to support dynamic LDAP backend])
1983                 BUILD_LDAP=mod
1984                 BUILD_LDAP_DYNAMIC=shared
1985                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
1986         fi
1987 fi
1988
1989 if test "$ol_link_ldbm" != no ; then
1990         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
1991         BUILD_SLAPD=yes
1992         BUILD_LDBM=yes
1993         if test "$ol_with_ldbm_module" != static ; then
1994                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
1995                         [define to support dynamic LDBM backend])
1996                 BUILD_LDBM=mod
1997                 BUILD_LDBM_DYNAMIC=shared
1998                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
1999         fi
2000 fi
2001
2002 if test "$ol_enable_passwd" != no ; then
2003         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2004         BUILD_SLAPD=yes
2005         BUILD_PASSWD=yes
2006         if test "$ol_with_passwd_module" != static ; then
2007                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2008                         [define to support dynamic PASSWD backend])
2009                 BUILD_PASSWD=mod
2010                 BUILD_PASSWD_DYNAMIC=shared
2011                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
2012         fi
2013 fi
2014
2015 if test "$ol_link_perl" != no ; then
2016         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
2017         BUILD_SLAPD=yes
2018         BUILD_PERL=yes
2019         if test "$ol_with_perl_module" != static ; then
2020                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
2021                         [define to support dynamic PERL backend])
2022                 BUILD_PERL=mod
2023                 BUILD_PERL_DYNAMIC=shared
2024                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-perl/back_perl.la"
2025         fi
2026 fi
2027
2028 if test "$ol_enable_shell" != no ; then
2029         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2030         BUILD_SLAPD=yes
2031         BUILD_SHELL=yes
2032         if test "$ol_with_shell_module" != static ; then
2033                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2034                         [define to support dynamic SHELL backend])
2035                 BUILD_SHELL=mod
2036                 BUILD_SHELL_DYNAMIC=shared
2037                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2038         fi
2039 fi
2040
2041 if test "$ol_enable_tcl" != no ; then
2042         AC_DEFINE(SLAPD_TCL,1,[define to support TCL backend])
2043         BUILD_SLAPD=yes
2044         BUILD_TCL=yes
2045         if test "$ol_with_tcl_module" != static; then
2046                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1,
2047                         [define to support dynamic TCL backend])
2048                 BUILD_TCL=mod
2049                 BUILD_TCL_DYNAMIC=shared
2050                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-tcl/back_tcl.la"
2051         fi
2052 fi
2053
2054 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2055         $BUILD_SLAPD = yes ; then
2056         BUILD_SLURPD=yes
2057 fi
2058
2059 if test "$ol_link_isode" != no ; then
2060         BUILD_LDAPD=yes
2061 fi
2062
2063 dnl ----------------------------------------------------------------
2064
2065 AC_SUBST(BUILD_LDAPD)
2066 AC_SUBST(BUILD_SLAPD)
2067   AC_SUBST(BUILD_BDB2)
2068   AC_SUBST(BUILD_LDAP)
2069   AC_SUBST(BUILD_LDBM)
2070   AC_SUBST(BUILD_PASSWD)
2071   AC_SUBST(BUILD_PERL)
2072   AC_SUBST(BUILD_QUIPU)
2073   AC_SUBST(BUILD_SHELL)
2074   AC_SUBST(BUILD_TCL)
2075   AC_SUBST(BUILD_BDB2_DYNAMIC)
2076   AC_SUBST(BUILD_LDAP_DYNAMIC)
2077   AC_SUBST(BUILD_LDBM_DYNAMIC)
2078   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2079   AC_SUBST(BUILD_PERL_DYNAMIC)
2080   AC_SUBST(BUILD_SHELL_DYNAMIC)
2081   AC_SUBST(BUILD_TCL_DYNAMIC)
2082 AC_SUBST(BUILD_SLURPD)
2083
2084 AC_SUBST(LDAP_LIBS)
2085 AC_SUBST(LDAPD_LIBS)
2086 AC_SUBST(LDIF_LIBS)
2087 AC_SUBST(SLAPD_LIBS)
2088 AC_SUBST(SLURPD_LIBS)
2089 AC_SUBST(LDBM_LIBS)
2090 AC_SUBST(LTHREAD_LIBS)
2091 AC_SUBST(LUTIL_LIBS)
2092
2093 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2094 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2095 AC_SUBST(SLAPD_MODULES_LIST)
2096
2097 AC_SUBST(SLAPD_PERL_CPPFLAGS)
2098 AC_SUBST(SLAPD_PERL_LDFLAGS)
2099
2100 AC_SUBST(KRB_LIBS)
2101 AC_SUBST(READLINE_LIBS)
2102 AC_SUBST(SASL_LIBS)
2103 AC_SUBST(TERMCAP_LIBS)
2104 AC_SUBST(TLS_LIBS)
2105 AC_SUBST(MODULES_LIBS)
2106
2107 dnl ----------------------------------------------------------------
2108 dnl final output
2109 dnl
2110
2111 AC_OUTPUT( \
2112 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2113 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2114 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2115 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2116 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2117 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2118 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2119 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2120 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2121 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2122 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2123 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2124 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2125 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2126 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2127 include/Makefile:build/top.mk:include/Makefile.in \
2128 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2129 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2130 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2131 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2132 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2133 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2134 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2135 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2136 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2137 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
2138 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2139 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/mod.mk \
2140 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2141 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2142 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2143 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk \
2144 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2145 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/mod.mk \
2146 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2147 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2148 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2149 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2150 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2151 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2152 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2153 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2154 ,[
2155 date > stamp-h
2156 echo Please \"make depend\" to build dependencies
2157 ])