git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8
   9 dnl Configure.in for OpenLDAP
  10 AC_INIT(include/ldap.h)dnl
  11 AC_CONFIG_AUX_DIR(build)dnl
  12 AM_INIT_AUTOMAKE(OpenLDAP,[1.1-beta], [no ac_define])dnl
  13
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_PREREQ(2.10)dnl Required Autoconf version
  18
  19 AC_CONFIG_AUX_DIR(build)
  20 AC_CONFIG_HEADER(include/portable.h)dnl
  21
  22 dnl
  23 dnl Start Args
  24 AC_MSG_CHECKING(configure arguments)
  25 AC_PREFIX_DEFAULT(/usr/local)
  26
  27 top_builddir=`pwd`
  28 AC_SUBST(top_builddir)dnl
  29
  30 ldap_subdir="openldap"
  31
  32 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  33         if test "$withval" = "no"; then
  34                 ldap_subdir=""
  35         elif test "$withval" != "yes"; then
  36                 ldap_subdir="$withval"
  37         fi
  38 ])dnl
  39
  40 AC_SUBST(ldap_subdir)dnl
  41
  42 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  43 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  44 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  45 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  46 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  47 OL_ARG_ENABLE(dns,[  --enable-dns               enable dns support], no)dnl
  48 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable referrals], yes)dnl
  49 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  50 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  51         no, [yes no])dnl
  52
  53 dnl General "with" options
  54 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  55         auto, [auto k5 k4 afs yes no])
  56 OL_ARG_WITH(threads,[  --with-threads   use threads],
  57         auto, [auto posix mach lwp yes no manual] )
  58 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  59         auto, [auto yes no manual] )
  60
  61 dnl Server options
  62
  63 dnl LDAPD OPTIONS
  64 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  65 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  66
  67 dnl SLAPD OPTIONS
  68 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  69 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  70 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  71 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  72 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  73 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  74 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  75 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  76 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  77
  78 dnl SLAPD Backend options
  79 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  80 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  81         [auto db2 db gdbm ndbm manual])
  82 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  83         [auto btree hash])
  84
  85 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  86 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  87
  88 dnl SLURPD OPTIONS
  89 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  90 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  91
  92 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
  93 AM_ENABLE_STATIC
  94 dnl AM_DISABLE_SHARED
  95 AM_ENABLE_SHARED
  96
  97 dnl General "enable" options
  98 # validate options
  99 if test $ol_enable_referrals = no ; then
 100         if test $ol_enable_dns = yes ; then
 101                 AC_MSG_WARN([dns disabled, ignoring --enable-dns argument])
 102         fi
 103         ol_enable_dns=no
 104 fi
 105
 106 if test $ol_enable_slapd = no ; then
 107         dnl SLAPD was specificallly disabled
 108         if test $ol_enable_ldbm = yes ; then
 109                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 110         fi
 111         if test $ol_enable_passwd = yes ; then
 112                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 113         fi
 114         if test $ol_enable_shell = yes ; then
 115                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 116         fi
 117         if test $ol_enable_aclgroups = yes ; then
 118                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 119         fi
 120         if test $ol_enable_crypt = yes ; then
 121                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument])
 122         fi
 123         if test $ol_enable_md5 = yes ; then
 124                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument])
 125         fi
 126         if test $ol_enable_sha1 = yes ; then
 127                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument])
 128         fi
 129         if test $ol_enable_wrappers = yes ; then
 130                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 131         fi
 132         if test $ol_enable_phonetic = yes ; then
 133                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 134         fi
 135         if test $ol_enable_rlookups = yes ; then
 136                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 137         fi
 138         if test $ol_with_ldbm_api != auto ; then
 139                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 140         fi
 141         if test $ol_with_ldbm_type != auto ; then
 142                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 143         fi
 144         if test $ol_enable_slurpd = yes ; then
 145                 AC_MSG_ERROR([slurpd requires slapd])
 146         fi
 147
 148         # force settings to no
 149         ol_enable_ldbm=no
 150         ol_enable_shell=no
 151         ol_enable_passwd=no
 152         ol_enable_aclgroups=no
 153         ol_enable_crypt=no
 154         ol_enable_md5=no
 155         ol_enable_sha1=no
 156         ol_enable_wrappers=no
 157         ol_enable_phonetic=no
 158         ol_enable_rlookups=no
 159         ol_with_ldbm_api=no
 160         ol_with_ldbm_type=no
 161         ol_enable_slurpd=no
 162
 163 elif test $ol_enable_ldbm = no ; then
 164         dnl SLAPD without LDBM
 165
 166         if test $ol_with_ldbm_api != auto ; then
 167                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 168         fi
 169
 170         if test $ol_with_ldbm_type != auto ; then
 171                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 172         fi
 173
 174         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 175                 AC_MSG_ERROR([slapd requires a backend])
 176         fi
 177
 178         ol_with_ldbm_api=no
 179         ol_with_ldbm_type=no
 180
 181 else
 182         dnl SLAPD with LDBM
 183
 184         if test $ol_with_ldbm_api = gdbm -a \
 185                 $ol_with_ldbm_type = btree ; then
 186                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 187         fi
 188         if test $ol_with_ldbm_api = ndbm -a \
 189                 $ol_with_ldbm_type = btree ; then
 190                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 191         fi
 192 fi
 193
 194 if test $ol_enable_slurpd = yes ; then
 195         dnl SLURPD was specifically enabled
 196         if test $ol_with_threads = no ; then
 197                 AC_MSG_ERROR([slurpd requires threads])
 198         fi
 199 fi
 200
 201 AC_MSG_RESULT(done)
 202
 203 AC_CANONICAL_HOST
 204
 205 ## Initialize vars
 206 LDAP_LIBS=
 207 LDBM_LIBS=
 208 LTHREAD_LIBS=
 209 LUTIL_LIBS=
 210
 211 LDAPD_LIBS=
 212 SLAPD_LIBS=
 213 SLURPD_LIBS=
 214
 215 BUILD_LDAPD=no
 216 BUILD_SLAPD=no
 217 BUILD_SLURPD=no
 218
 219 BUILD_LDBM=no
 220 BUILD_PASSWD=no
 221 BUILD_SHELL=no
 222 BUILD_THREAD=no
 223
 224 KRB_LIBS=
 225 TERMCAP_LIBS=
 226
 227 dnl ----------------------------------------------------------------
 228 dnl Checks for programs
 229
 230 AC_PROG_INSTALL
 231 AM_PROG_LIBTOOL
 232 dnl AC_PROG_MAKE_SET
 233
 234 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 235         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 236 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 237 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 238
 239 dnl Checks the compiler and UNIX Variants
 240
 241 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 242         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 243
 244 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 245         AC_MSG_WARN([programs compiled here do run here...])
 246         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 247
 248 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 249         AC_MSG_WARN([programs compiled here do not run here...])
 250         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 251 fi
 252
 253 AC_PROG_CPP
 254
 255 AC_AIX
 256 AC_ISC_POSIX
 257 AC_MINIX
 258
 259 dnl OpenLDAP requires STDC features
 260 AM_PROG_CC_STDC
 261 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 262         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 263 fi
 264
 265 dnl AM_C_PROTOTYPES
 266
 267 dnl Checks for libraries
 268
 269 dnl Find socket()
 270 dnl Likely combinations:
 271 dnl             -lsocket [ -lnsl_s | -lnsl ]
 272 dnl             -linet
 273
 274 AC_CHECK_FUNC(socket, [have_socket=yes], [
 275 dnl
 276 dnl hopefully we won't include too many libraries
 277 dnl
 278         AC_CHECK_LIB(socket, main)
 279         AC_CHECK_LIB(net, main)
 280         AC_CHECK_LIB(nsl_s, main)
 281         AC_CHECK_LIB(nsl, main)
 282         AC_CHECK_LIB(inet, socket)
 283         AC_CHECK_LIB(gen, main)
 284 ])
 285
 286 dnl Check for resolv
 287 AC_CHECK_LIB(resolv, res_search)
 288
 289 dnl HP-UX requires -lV3
 290 AC_CHECK_LIB(V3, sigset)
 291
 292 # ISODE tests
 293 ol_link_isode=no
 294 if test $ol_enable_ldapd != no ; then
 295         dnl look for ISODE libraries
 296         AC_CHECK_LIB(xtpp, main, [
 297                 ol_link_isode=yes
 298                 AC_DEFINE(HAVE_XTPP,1)
 299                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 300                 ],:,[-lxtdsap -lxtisode -losi])
 301         AC_CHECK_LIB(dsap, main, [
 302                 ol_link_isode=yes
 303                 AC_DEFINE(HAVE_DSAP,1)
 304                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 305                 ],:,[-lisode])
 306         AC_CHECK_LIB(isode, main, [
 307                 ol_link_isode=yes
 308                 AC_DEFINE(HAVE_ISODE,1)
 309                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 310                 ],:)
 311 fi
 312
 313 if test $ol_link_isode != no; then
 314         AC_CHECK_LIB(pp, main, [
 315                 AC_DEFINE(HAVE_PP,1)
 316                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 317                 ],:)
 318
 319         AC_PATH_PROG(PEPSY, pepsy)
 320 fi
 321
 322 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 323         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 324
 325         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 326                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 327                         [-lkrb5 -ldes425])
 328
 329                 if test $have_k5 = yes ; then
 330                         ol_with_kerberos=found
 331                         ol_link_kerberos=yes
 332
 333                         AC_DEFINE(HAVE_KERBEROS)
 334
 335                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 336                 fi
 337         fi
 338 fi
 339 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 340         AC_CHECK_HEADERS(krb.h des.h)
 341
 342         if test $ac_cv_header_krb_h = yes ; then
 343                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 344
 345                 if test $have_k4 = yes ; then
 346                         ol_with_kerberos=found
 347                         ol_link_kerberos=yes
 348
 349                         AC_DEFINE(HAVE_KERBEROS)
 350                         KRB_LIBS="-lkrb -ldes"
 351
 352                         AC_CHECK_FUNCS(des_string_to_key)
 353                 fi
 354         fi
 355 fi
 356
 357 ol_link_threads=no
 358 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 359         AC_CHECK_HEADERS(pthread.h sched.h)
 360
 361         if test $ac_cv_header_pthread_h = yes ; then
 362                 OL_POSIX_THREAD_VERSION
 363
 364                 if test $ol_cv_pthread_version = final ; then
 365                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 366                 elif test $ol_cv_pthread_version = draft4 ; then
 367                         AC_DEFINE(HAVE_PTHREADS_D4)
 368                 else
 369                         AC_MSG_ERROR([unknown pthread version])
 370                 fi
 371
 372                 # consider threads found
 373                 ol_with_threads=found
 374
 375                 OL_LINUX_THREADS
 376
 377                 if test $ol_cv_linux_threads = yes ; then
 378                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 379                 fi
 380
 381                 dnl Now the hard part, how to link
 382
 383                 dnl Check for pthread support in current $LIBS
 384                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 385
 386                 if test $ol_link_threads = no ; then
 387                         dnl try -pthread
 388                         AC_CACHE_CHECK([for pthread_create with -pthread],
 389                                 [ol_cv_pthread_flag], [
 390                                 dnl save the flags
 391                                 save_LIBS="$LIBS"
 392                                 LIBS="-pthread $LIBS"
 393                                 AC_TRY_LINK([char pthread();],[
 394                                         pthread_create();
 395                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 396                                 dnl restore the LIBS
 397                                 LIBS="$save_LIBS"
 398                         ])
 399
 400                         if test $ol_cv_pthread_flag = yes ; then
 401                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 402                                 ol_link_threads=posix
 403                         fi
 404                 fi
 405
 406                 if test $ol_link_threads = no ; then
 407                         dnl try -thread
 408                         AC_CACHE_CHECK([for pthread_create with -thread],
 409                                 [ol_cv_thread_flag], [
 410                                 dnl save the flags
 411                                 save_LIBS="$LIBS"
 412                                 LIBS="-thread $LIBS"
 413                                 AC_TRY_LINK([char pthread();],[
 414                                         pthread_create();
 415                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 416                                 dnl restore the LIBS
 417                                 LIBS="$save_LIBS"
 418                         ])
 419
 420                         if test $ol_cv_thread_flag = yes ; then
 421                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 422                                 ol_link_threads=posix
 423                         fi
 424                 fi
 425
 426                 if test $ol_link_threads = no ; then
 427                         dnl try DEC Threads -lpthread -lexc
 428                         save_LIBS="$LIBS"
 429                         AC_CHECK_LIB(pthread, pthread_join, [
 430                                 ol_link_threads=posix
 431                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 432                                 if test $ol_with_yielding_select = auto ; then
 433                                         ol_with_yielding_select=yes
 434                                 fi
 435                                 ],,[-lexc])
 436                         LIBS="$save_LIBS"
 437                 fi
 438
 439                 if test $ol_link_threads = no ; then
 440                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 441                         save_LIBS="$LIBS"
 442                         AC_CHECK_LIB(pthreads, pthread_join, [
 443                                 ol_link_threads=posix
 444                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 445                                 if test $ol_with_yielding_select = auto ; then
 446                                         ol_with_yielding_select=yes
 447                                 fi
 448                                 ],,[-lmach -lexc -lc_r])
 449                         LIBS="$save_LIBS"
 450                 fi
 451
 452                 if test $ol_link_threads = no ; then
 453                         dnl try -lpthread
 454                         save_LIBS="$LIBS"
 455                         AC_CHECK_LIB(pthread, pthread_create, [
 456                                 ol_link_threads=posix
 457                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 458                         LIBS="$save_LIBS"
 459                 fi
 460
 461                 if test $ol_link_threads = no ; then
 462                         dnl try -lc_r
 463                         save_LIBS="$LIBS"
 464                         AC_CHECK_LIB(c_r, pthread_create, [
 465                                 ol_link_threads=posix
 466                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 467                         LIBS="$save_LIBS"
 468                 fi
 469
 470                 if test $ol_link_threads != no ; then
 471                         AC_DEFINE(HAVE_PTHREADS)
 472
 473                         dnl save flags
 474                         save_CPPFLAGS="$CPPFLAGS"
 475                         save_LIBS="$LIBS"
 476                         LIBS="$LTHREAD_LIBS $LIBS"
 477
 478                         dnl All POSIX Thread (final) implementations should have
 479                         dnl sched_yield instead of pthread yield.
 480                         dnl check for both
 481                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 482
 483                         if test $ac_cv_func_sched_yield = no -a \
 484                                 $ac_cv_func_pthread_yield = no ; then
 485                                 dnl Digital UNIX has sched_yield() in -lrt
 486                                 AC_CHECK_LIB(rt, sched_yield,
 487                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 488                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 489                                         ac_cv_func_sched_yield=yes],
 490                                         [ac_cv_func_sched_yield=no])
 491                         fi
 492                         if test $ac_cv_func_sched_yield = no -a \
 493                                 $ac_cv_func_pthread_yield = no ; then
 494                                 dnl Solaris has sched_yield() in -lposix4
 495                                 AC_CHECK_LIB(posix4, sched_yield,
 496                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 497                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 498                                         ac_cv_func_sched_yield=yes],
 499                                         [ac_cv_func_sched_yield=no])
 500                         fi
 501                         if test $ac_cv_func_sched_yield = no -a \
 502                                 $ac_cv_func_pthread_yield = no ; then
 503                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 504                                 AC_MSG_ERROR([POSIX Threads are not usable])
 505                         fi
 506
 507                         dnl Check functions for compatibility
 508                         AC_CHECK_FUNCS(pthread_kill)
 509                         AC_CHECK_FUNCS( \
 510                                 pthread_attr_create pthread_attr_init \
 511                                 pthread_attr_destroy pthread_attr_delete \
 512                                 pthread_attr_setdetachstate pthread_attr_setdetach_np \
 513                         )
 514
 515                         dnl Check for setconcurreny functions
 516                         AC_CHECK_FUNCS( \
 517                                 pthread_setconcurrency \
 518                                 thr_setconcurrency \
 519                         )
 520
 521                         dnl Check if select causes an yield
 522                         if test $ol_with_yielding_select = auto ; then
 523                                 AC_MSG_CHECKING([if select yields])
 524                                 AC_TRY_RUN([
 525 #include <sys/types.h>
 526 #include <sys/time.h>
 527 #include <unistd.h>
 528 #include <pthread.h>
 529 #ifndef NULL
 530 #define NULL 0
 531 #endif
 532
 533 int fildes[2];
 534
 535 int task(arg)
 536         int *arg;
 537 {
 538         int i;
 539         struct timeval tv;
 540
 541         fd_set rfds;
 542
 543         tv.tv_sec=10;
 544         tv.tv_usec=0;
 545
 546         FD_ZERO(&rfds);
 547         FD_SET(fildes[0], &rfds);
 548
 549         /* we're not interested in any fds */
 550         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 551
 552         if(i < 0) {
 553                 perror("select");
 554                 exit(0);
 555         }
 556
 557         exit(1); /* if we exit here, the select blocked the whole process */
 558 }
 559
 560 int main(argc, argv)
 561         int argc;
 562         char **argv;
 563 {
 564         pthread_t t;
 565
 566         /* create a pipe to select */
 567         if(pipe(&fildes[0])) {
 568                 perror("select");
 569                 exit(0);
 570         }
 571
 572 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 573         (void) pthread_setconcurrency(2);
 574 #else
 575 #ifdef HAVE_THR_SETCONCURRENCY
 576         /* Set Solaris LWP concurrency to 2 */
 577         thr_setconcurrency(2);
 578 #endif
 579 #endif
 580
 581         pthread_create(&t, NULL, (void *) task, NULL);
 582
 583 #if HAVE_SCHED_YIELD
 584         sched_yield();  /* make sure task runs first */
 585 #else
 586 #ifdef HAVE_PTHREAD_YIELD
 587         pthread_yield();        /* make sure task runs first */
 588 #endif
 589 #endif
 590         exit(0);
 591 }
 592                                 ], [ol_pthread_select_yields=yes], [ol_pthread_select_yields=no], [
 593                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])
 594                                 AC_MSG_RESULT($ol_pthread_select_yields)
 595
 596                                 if test $ol_pthread_select_yields = yes ; then
 597                                         ol_with_yielding_select=yes
 598                                 fi
 599                         fi
 600
 601 dnl                     dnl check for reentrant/threadsafe functions
 602 dnl                     AC_CHECK_FUNCS( \
 603 dnl                             feof_unlocked \
 604 dnl                             unlocked_feof \
 605 dnl                             ftrylockfile \
 606 dnl                             flockfile \
 607 dnl                             putc_unlocked \
 608 dnl                             gmtime_r \
 609 dnl                             strtok_r \
 610 dnl                     )
 611
 612                         dnl restore flags
 613                         CPPFLAGS="$save_CPPFLAGS"
 614                         LIBS="$save_LIBS"
 615                 else
 616                         AC_MSG_ERROR([could not link with POSIX Threads])
 617                 fi
 618         fi
 619
 620         if test $ol_with_threads = posix ; then
 621                 AC_MSG_ERROR([could not locate POSIX Threads])
 622         fi
 623 fi
 624
 625 if test $ol_with_threads = auto -o $ol_with_threads = mach ; then
 626         dnl check for Mach CThreads
 627         AC_CHECK_HEADERS(mach/cthreads.h)
 628         if test $ac_cv_header_mach_cthreads_h = yes ; then
 629                 ol_with_threads=found
 630
 631                 dnl check for cthread support in current $LIBS
 632                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 633
 634                 if test $ol_link_threads = no ; then
 635                         dnl try -all_load
 636                         dnl this test needs work
 637                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 638                                 [ol_cv_cthread_all_load], [
 639                                 dnl save the flags
 640                                 save_LIBS="$LIBS"
 641                                 LIBS="-all_load $LIBS"
 642                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 643                                         cthread_fork((void *)0, (void *)0);
 644                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 645                                 dnl restore the LIBS
 646                                 LIBS="$save_LIBS"
 647                         ])
 648
 649                         if test $ol_cv_cthread_all_load = yes ; then
 650                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 651                                 ol_link_threads=mach
 652                         fi
 653                 fi
 654
 655                 if test $ol_link_threads != no ; then
 656                         : check for cthread specific functionality here
 657                         AC_DEFINE(HAVE_MACH_CTHREADS,1)
 658                 else
 659                         AC_MSG_ERROR([could not link with Mach CThreads])
 660                 fi
 661         fi
 662
 663         if test $ol_with_threads = mach ; then
 664                 AC_MSG_ERROR([could not locate Mach CThreads])
 665         fi
 666 fi
 667
 668 if test $ol_with_threads = auto -o $ol_with_threads = lwp ; then
 669         dnl check for SunOS5 LWP
 670         AC_CHECK_HEADERS(thread.h synch.h)
 671         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 672                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
 673
 674                 if test $have_thr = yes ; then
 675                         AC_DEFINE(HAVE_THR)
 676                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
 677                         ol_link_threads=thr
 678
 679                         if test $ol_with_yielding_select = auto ; then
 680                                 ol_with_yielding_select=yes
 681                         fi
 682                 fi
 683         fi
 684
 685         dnl check for SunOS4 LWP
 686         AC_CHECK_HEADERS(lwp/lwp.h)
 687         if test $ac_cv_header_lwp_lwp_h = yes ; then
 688                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 689
 690                 if test $have_lwp = yes ; then
 691                         AC_DEFINE(HAVE_LWP)
 692                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 693                         ol_link_threads=lwp
 694
 695                         if test $ol_with_yielding_select = auto ; then
 696                                 ol_with_yielding_select=no
 697                         fi
 698                 fi
 699         fi
 700 fi
 701
 702 if test $ol_with_yielding_select = yes ; then
 703         AC_DEFINE(HAVE_YIELDING_SELECT,1)
 704 fi
 705
 706 if test $ol_with_threads = manual ; then
 707         dnl User thinks he can manually configure threads.
 708         ol_link_threads=yes
 709
 710         AC_MSG_WARN([thread defines and link options must be set manually])
 711
 712         AC_CHECK_HEADERS(pthread.h sched.h)
 713         AC_CHECK_FUNCS(sched_yield pthread_yield)
 714         OL_LINUX_THREADS
 715
 716         AC_CHECK_HEADERS(mach/cthreads.h)
 717         AC_CHECK_HEADERS(lwp/lwp.h)
 718         AC_CHECK_HEADERS(thread.h synch.h)
 719 fi
 720
 721 if test $ol_with_threads != no ; then
 722         dnl needed to get reentrant/threadsafe versions
 723         dnl
 724         AC_DEFINE(_REENTRANT,1)
 725         AC_DEFINE(_THREAD_SAFE,1)
 726         AC_DEFINE(_THREADSAFE,1)
 727
 728         dnl this might cause the errno symbol to be
 729         dnl replaced with a function to get a thread specific errno.
 730         dnl check to see if everything needs to be compiled
 731         dnl with the thread libraries
 732         AC_CACHE_CHECK([for thread specific errno],
 733                 [ol_cv_errno_thread_specific], [
 734                 AC_TRY_LINK([
 735 #include <errno.h>
 736                         ], [
 737 int x = errno;
 738                         ],
 739                         [ol_cv_errno_thread_specific=yes],
 740                         [ol_cv_errno_thread_specific=no])
 741         ])
 742
 743         if test $ol_cv_errno_thread_specific != yes ; then
 744                 LIBS="$LTHREAD_LIBS $LIBS"
 745                 LTHREAD_LIBS=""
 746         fi
 747 fi
 748
 749 dnl ----------------------------------------------------------------
 750
 751 if test $ol_link_threads = no ; then
 752         if test $ol_with_threads = yes ; then
 753                 AC_MSG_ERROR([no suitable thread support])
 754         fi
 755
 756         if test $ol_with_threads = auto ; then
 757                 AC_MSG_WARN([no suitable thread support, disabling threads])
 758                 ol_with_threads=no
 759         fi
 760
 761         AC_DEFINE(NO_THREADS,1)
 762         LTHREAD_LIBS=""
 763 fi
 764
 765 ol_link_ldbm=no
 766 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 767         OL_BERKELEY_DB2
 768
 769         if test $ol_cv_berkeley_db2 = yes ; then
 770                 ol_link_ldbm=db2
 771                 ol_with_ldbm_api=db2
 772
 773                 if test $ol_with_ldbm_type = hash ; then
 774                         AC_DEFINE(LDBM_USE_DBHASH,1)
 775                 else
 776                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 777                 fi
 778
 779                 dnl $ol_cv_lib_db2 should be yes or -ldb
 780                 dnl (it could be no, but that would be an error
 781                 if test $ol_cv_lib_db2 != yes ; then
 782                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 783                 fi
 784         fi
 785 fi
 786
 787 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 788         OL_BERKELEY_DB
 789
 790         if test $ol_cv_berkeley_db = yes ; then
 791                 ol_link_ldbm=db
 792                 ol_with_ldbm_api=db
 793
 794                 if test $ol_with_ldbm_type = hash ; then
 795                         AC_DEFINE(LDBM_USE_DBHASH,1)
 796                 else
 797                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 798                 fi
 799
 800                 dnl $ol_cv_lib_db should be yes or -ldb
 801                 dnl (it could be no, but that would be an error
 802                 if test $ol_cv_lib_db != yes ; then
 803                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 804                 fi
 805         fi
 806 fi
 807
 808 if test $ol_with_ldbm_api = manual ; then
 809         dnl User thinks he can manually configure LDBM api.
 810         ol_link_ldbm=yes
 811
 812         AC_MSG_WARN([LDBM defines and link options must be set manually])
 813
 814         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 815 fi
 816
 817 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 818         AC_MSG_WARN(Could not find LDBM with BTREE support)
 819         ol_with_ldbm_api=none
 820 fi
 821
 822 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 823         OL_GDBM
 824
 825         if test $ol_cv_gdbm = yes ; then
 826                 ol_link_ldbm=gdbm
 827                 ol_with_ldbm_api=gdbm
 828
 829                 if test $ol_cv_lib_gdbm != yes ; then
 830                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 831                 fi
 832         fi
 833 fi
 834
 835 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 836         OL_NDBM
 837
 838         if test $ol_cv_ndbm = yes ; then
 839                 if test $ol_with_ldbm_api = auto ; then
 840                         AC_MSG_WARN([Attempting to use NDBM.  Functionality will be limited.])
 841                 fi
 842
 843                 ol_link_ldbm=ndbm
 844                 ol_with_ldbm_api=ndbm
 845
 846                 if test $ol_cv_lib_ndbm != yes ; then
 847                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 848                 fi
 849         fi
 850 fi
 851
 852 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 853         AC_MSG_WARN(could not find suitable LDBM backend)
 854         if test $ol_enable_ldbm = yes ; then
 855                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 856         fi
 857
 858         AC_MSG_WARN(disabling LDBM)
 859         ol_enable_ldbm=no
 860 fi
 861
 862 if test $ol_enable_wrappers = yes ; then
 863         AC_CHECK_LIB(wrap, hosts_access,
 864                 [have_wrappers=yes], [have_wrappers=no])
 865
 866         if test $have_wrappers = yes ; then
 867                 AC_DEFINE(HAVE_TCPD)
 868                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 869         else
 870                 AC_MSG_WARN(could not find -lwrap)
 871                 if test $ol_enable_wrappers = yes ; then
 872                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 873                 fi
 874
 875                 AC_MSG_WARN(disabling wrappers support)
 876                 ol_enable_wrappers=no
 877         fi
 878
 879 fi
 880
 881 # ud needs termcap (should insert check here)
 882 ol_link_termcap=no
 883 AC_CHECK_HEADERS(termcap.h ncurses.h)
 884
 885 if test $ol_link_termcap = no ; then
 886         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 887         if test $have_termcap = yes ; then
 888                 AC_DEFINE(HAVE_TERMCAP)
 889                 ol_link_termcap=yes
 890                 TERMCAP_LIBS=-ltermcap
 891         fi
 892 fi
 893
 894 if test $ol_link_termcap = no ; then
 895         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 896         if test $have_ncurses = yes ; then
 897                 AC_DEFINE(HAVE_NCURSES)
 898                 ol_link_termcap=yes
 899                 TERMCAP_LIBS=-lncurses
 900         fi
 901 fi
 902
 903 if test $ol_link_termcap = no ; then
 904         AC_DEFINE(NO_TERMCAP,1)
 905         TERMCAP_LIBS=
 906 fi
 907
 908 # FreeBSD (and others) have crypt(3) in -lcrypt
 909 if test $ol_enable_crypt != no ; then
 910         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 911                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 912                         have_crypt=yes], [have_crypt=no])])
 913
 914         if test $have_crypt = yes ; then
 915                 AC_DEFINE(HAVE_CRYPT,1)
 916         else
 917                 AC_MSG_WARN(could not find crypt)
 918                 if test $ol_enable_crypt = yes ; then
 919                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 920                 fi
 921
 922                 AC_MSG_WARN(disabling crypt support)
 923                 ol_enable_crypt=no
 924         fi
 925 fi
 926
 927 # FreeBSD (and others) have setproctitle(3) in -lutil
 928 if test $ol_enable_proctitle != no ; then
 929         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 930                 AC_CHECK_LIB(util, setproctitle,
 931                         [have_setproctitle=yes
 932                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 933                         [have_setproctitle=no
 934                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 935
 936         if test $have_setproctitle = yes ; then
 937                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 938         fi
 939 fi
 940
 941 dnl ----------------------------------------------------------------
 942 dnl Checks for header files.
 943 AC_HEADER_STDC
 944
 945 if test $ac_cv_header_stdc != yes; then
 946         AC_MSG_WARN([could not Standard C compliant headers])
 947 fi
 948
 949 AC_HEADER_DIRENT
 950 AC_HEADER_SYS_WAIT
 951 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 952 if test $am_cv_sys_posix_termios = yes ; then
 953         AC_DEFINE(HAVE_POSIX_TERMIOS,1)
 954 fi
 955
 956 AC_CHECK_HEADERS(       \
 957         crypt.h                 \
 958         errno.h                 \
 959         fcntl.h                 \
 960         filio.h                 \
 961         getopt.h                \
 962         libutil.h               \
 963         limits.h                \
 964         malloc.h                \
 965         memory.h                \
 966         regex.h                 \
 967         psap.h                  \
 968         pwd.h                   \
 969         sgtty.h                 \
 970         stdarg.h                \
 971         stddef.h                \
 972         string.h                \
 973         strings.h               \
 974         sys/file.h              \
 975         sys/filio.h             \
 976         sys/errno.h             \
 977         sys/ioctl.h             \
 978         sys/param.h             \
 979         sys/resource.h  \
 980         sys/socket.h    \
 981         sys/syslog.h    \
 982         sys/time.h              \
 983         sys/types.h             \
 984         syslog.h                \
 985         termios.h               \
 986         unistd.h                \
 987 )
 988
 989 dnl ----------------------------------------------------------------
 990 dnl Checks for typedefs, structures, and compiler characteristics.
 991 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
 992 AC_TYPE_MODE_T
 993 AC_TYPE_OFF_T
 994 AC_TYPE_PID_T
 995 AM_TYPE_PTRDIFF_T
 996 AC_TYPE_SIGNAL
 997 AC_TYPE_SIZE_T
 998 AC_STRUCT_ST_BLKSIZE
 999 AC_HEADER_TIME
1000 AC_STRUCT_TM
1001
1002 OL_C_UPPER_LOWER
1003 AC_C_CONST
1004
1005 if test $cross_compiling = yes ; then
1006         AC_DEFINE(CROSS_COMPILING, 1)
1007 else
1008         AC_C_BIGENDIAN
1009         AC_CHECK_SIZEOF(short)
1010         AC_CHECK_SIZEOF(int)
1011         AC_CHECK_SIZEOF(long)
1012 fi
1013
1014 dnl ----------------------------------------------------------------
1015 dnl Checks for library functions.
1016 AC_FUNC_MEMCMP
1017 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1018 AC_FUNC_STRFTIME
1019 dnl AM_FUNC_STRTOD
1020 AC_FUNC_VPRINTF
1021
1022 if test $ac_cv_func_vprintf = yes ; then
1023         dnl check for vsnprintf
1024         AC_CHECK_FUNCS(vsnprintf)
1025 fi
1026
1027 AC_FUNC_WAIT3
1028
1029 AC_CHECK_FUNCS(         \
1030         bcopy                   \
1031         flock                   \
1032         getdtablesize   \
1033         gethostname             \
1034         getpwuid                \
1035         gettimeofday    \
1036         lockf                   \
1037         memcpy                  \
1038         memmove                 \
1039         mkstemp                 \
1040         res_search              \
1041         select                  \
1042         setpwfile               \
1043         setsid                  \
1044         signal                  \
1045         sigset                  \
1046         snprintf                \
1047         socket                  \
1048         strerror                \
1049         strpbrk                 \
1050         strrchr                 \
1051         strsep                  \
1052         strstr                  \
1053         strtok                  \
1054         strtol                  \
1055         strtoul                 \
1056         sysconf                 \
1057         waitpid                 \
1058 )
1059
1060 dnl We actually may need to replace more than this.
1061 AC_REPLACE_FUNCS(getopt strdup tempnam)
1062
1063 dnl ----------------------------------------------------------------
1064 # Check Configuration
1065 OL_SYS_ERRLIST
1066
1067 dnl ----------------------------------------------------------------
1068 dnl Sort out defines
1069
1070 if test $ol_enable_debug != no ; then
1071         AC_DEFINE(LDAP_DEBUG,1)
1072 fi
1073 dnl     if test $ol_enable_syslog != no ; then
1074 dnl             AC_DEFINE(LDAP_SYSLOG,1)
1075 dnl     fi
1076 if test $ol_enable_libui = yes ; then
1077         AC_DEFINE(LDAP_LIBUI,1)
1078 fi
1079 if test $ol_enable_cache = no ; then
1080         AC_DEFINE(LDAP_NOCACHE,1)
1081 fi
1082 if test $ol_enable_dns != no ; then
1083         AC_DEFINE(LDAP_DNS,1)
1084 fi
1085 if test $ol_enable_proctitle != no ; then
1086         AC_DEFINE(LDAP_PROCTITLE,1)
1087 fi
1088 if test $ol_enable_referrals != no ; then
1089         AC_DEFINE(LDAP_REFERRALS,1)
1090 fi
1091 if test $ol_enable_cldap != no ; then
1092         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1093 fi
1094
1095 if test $ol_enable_aclgroups != no ; then
1096         AC_DEFINE(SLAPD_ACLGROUPS,1)
1097 fi
1098 if test $ol_enable_crypt != no ; then
1099         AC_DEFINE(SLAPD_CRYPT,1)
1100 fi
1101 if test $ol_enable_md5 != no ; then
1102         AC_DEFINE(SLAPD_MD5,1)
1103 fi
1104 if test $ol_enable_sha1 != no ; then
1105         AC_DEFINE(SLAPD_SHA1,1)
1106 fi
1107 if test $ol_enable_phonetic != no ; then
1108         AC_DEFINE(SLAPD_PHONETIC,1)
1109 fi
1110 if test $ol_enable_rlookups != no ; then
1111         AC_DEFINE(SLAPD_RLOOKUPS,1)
1112 fi
1113
1114 if test $ol_link_ldbm != no ; then
1115         AC_DEFINE(SLAPD_LDBM,1)
1116         BUILD_SLAPD=yes
1117         BUILD_LDBM=yes
1118 fi
1119
1120 if test $ol_enable_passwd != no ; then
1121         AC_DEFINE(SLAPD_PASSWD,1)
1122         BUILD_SLAPD=yes
1123         BUILD_PASSWD=yes
1124 fi
1125
1126 if test $ol_enable_shell != no ; then
1127         AC_DEFINE(SLAPD_SHELL,1)
1128         BUILD_SLAPD=yes
1129         BUILD_SHELL=yes
1130 fi
1131
1132 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
1133         $BUILD_SLAPD = yes ; then
1134         BUILD_SLURPD=yes
1135 fi
1136
1137 if test $ol_link_isode != no ; then
1138         BUILD_LDAPD=yes
1139 fi
1140
1141 dnl ----------------------------------------------------------------
1142
1143 AC_SUBST(BUILD_LDAPD)
1144 AC_SUBST(BUILD_SLAPD)
1145   AC_SUBST(BUILD_LDBM)
1146   AC_SUBST(BUILD_PASSWD)
1147   AC_SUBST(BUILD_SHELL)
1148 AC_SUBST(BUILD_SLURPD)
1149
1150
1151 AC_SUBST(LDAP_LIBS)
1152 AC_SUBST(LDAPD_LIBS)
1153 AC_SUBST(SLAPD_LIBS)
1154 AC_SUBST(SLURPD_LIBS)
1155 AC_SUBST(LDBM_LIBS)
1156 AC_SUBST(LTHREAD_LIBS)
1157 AC_SUBST(LUTIL_LIBS)
1158
1159 AC_SUBST(KRB_LIBS)
1160 AC_SUBST(TERMCAP_LIBS)
1161
1162 dnl ----------------------------------------------------------------
1163 dnl final output
1164 dnl
1165
1166 AC_OUTPUT( \
1167 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1168 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1169 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1170 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1171 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1172 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1173 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1174 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1175 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1176 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1177 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1178 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1179 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1180 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1181 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1182 include/Makefile:build/top.mk:include/Makefile.in \
1183 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1184 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1185 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1186 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1187 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1188 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1189 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk:build/lib-static.mk    \
1190 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1191 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1192 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1193 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1194 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1195 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1196 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1197 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1198 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1199 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1200 tests/Makefile:build/top.mk:tests/Makefile.in \
1201 ,[
1202 date > stamp-h
1203 echo Please \"make depend\" to build dependencies
1204 ])