git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Configure.in for OpenLDAP
  11 AC_INIT(include/ldap.h)dnl
  12 AC_CONFIG_AUX_DIR(build)dnl
  13 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no ac_define])dnl
  14
  15 dnl Do not use AutoConf 2.12; it produces a configuration script
  16 dnl that causes an "internal 2K buffer" error on HPUX when run
  17 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  18 AC_PREREQ(2.13)dnl Required Autoconf version
  19
  20 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  21
  22 dnl
  23 dnl Start Args
  24 AC_MSG_CHECKING(configure arguments)
  25 AC_PREFIX_DEFAULT(/usr/local)
  26
  27 top_builddir=`pwd`
  28 AC_SUBST(top_builddir)dnl
  29
  30 ldap_subdir="openldap"
  31
  32 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  33         if test "$withval" = "no"; then
  34                 ldap_subdir=""
  35         elif test "$withval" != "yes"; then
  36                 ldap_subdir="$withval"
  37         fi
  38 ])dnl
  39
  40 AC_SUBST(ldap_subdir)dnl
  41
  42 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  43 ol_enable_syslog=no
  44 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  45 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  46 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  47 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  48 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  49 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  50 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  51         no, [yes no])dnl
  52
  53
  54 dnl General "with" options
  55 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  56
  57 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  58         auto, [auto k5 k4 afs yes no])
  59 OL_ARG_WITH(threads,[  --with-threads   use threads],
  60         auto, [auto posix mach lwp yes no manual] )
  61 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  62         auto, [auto yes no manual] )
  63
  64 dnl Server options
  65
  66 dnl LDAPD OPTIONS
  67 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  68 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  69
  70 dnl SLAPD OPTIONS
  71 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  72 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  73 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  74 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  75 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  76 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  77 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  78 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  79
  80 dnl SLAPD Backend options
  81 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
  82 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  83 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  84         [auto db2 db gdbm ndbm manual])
  85 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  86         [auto btree hash])
  87
  88 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  89 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
  90 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  91
  92 dnl SLURPD OPTIONS
  93 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  94 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  95
  96 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
  97 AM_ENABLE_STATIC
  98 dnl AM_DISABLE_SHARED
  99 AM_ENABLE_SHARED
 100
 101 dnl General "enable" options
 102 # validate options
 103 if test $ol_enable_dns = yes ; then
 104         if test $ol_enable_referrals = no ; then
 105                 AC_MSG_ERROR([DNS requires --enable-referrals])
 106         fi
 107         if test $ol_enable_referrals = auto ; then
 108                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 109                 ol_enable_referrals=yes
 110         fi
 111 fi
 112
 113 if test $ol_enable_slapd = no ; then
 114         dnl SLAPD was specificallly disabled
 115         if test $ol_enable_bdb2 = yes ; then
 116                 AC_MSG_WARN([slapd disabled, ignoring --enable_bdb2 argument])
 117         fi
 118         if test $ol_enable_ldbm = yes ; then
 119                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 120         fi
 121         if test $ol_enable_passwd = yes ; then
 122                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 123         fi
 124         if test $ol_enable_perl = yes ; then
 125                 AC_MSG_WARN([slapd disabled, ignoring --enable_perl argument])
 126         fi
 127         if test $ol_enable_shell = yes ; then
 128                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 129         fi
 130         if test $ol_enable_aclgroups = yes ; then
 131                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 132         fi
 133         if test $ol_enable_wrappers = yes ; then
 134                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 135         fi
 136         if test $ol_enable_phonetic = yes ; then
 137                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 138         fi
 139         if test $ol_enable_rlookups = yes ; then
 140                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 141         fi
 142         if test $ol_with_ldbm_api != auto ; then
 143                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 144         fi
 145         if test $ol_with_ldbm_type != auto ; then
 146                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 147         fi
 148         if test $ol_enable_slurpd = yes ; then
 149                 AC_MSG_ERROR([slurpd requires slapd])
 150         fi
 151
 152         # force settings to no
 153         ol_enable_bdb2=no
 154         ol_enable_ldbm=no
 155         ol_enable_passwd=no
 156         ol_enable_perl=no
 157         ol_enable_shell=no
 158         ol_enable_aclgroups=no
 159         ol_enable_wrappers=no
 160         ol_enable_phonetic=no
 161         ol_enable_rlookups=no
 162         ol_with_ldbm_api=no
 163         ol_with_ldbm_type=no
 164         ol_enable_slurpd=no
 165
 166 elif test $ol_enable_ldbm = no ; then
 167         dnl SLAPD without LDBM
 168
 169         if test $ol_with_ldbm_api != auto ; then
 170                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 171         fi
 172
 173         if test $ol_with_ldbm_type != auto ; then
 174                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 175         fi
 176
 177         if test $ol_enable_ldbm = yes ; then
 178                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 179         fi
 180
 181         if test $ol_enable_passwd = no -a \
 182                 $ol_enable_perl = no -a
 183                 $ol_enable_shell = no ; then
 184                 AC_MSG_ERROR([slapd requires a backend])
 185         fi
 186
 187         ol_with_ldbm_api=no
 188         ol_with_ldbm_type=no
 189
 190 elif test $ol_enable_bdb2 = yes ; then
 191         dnl SLAPD with BDB2
 192
 193         if test $ol_with_ldbm_api != auto -a \
 194                 $ol_with_ldbm_api != db2 ; then
 195                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 196         fi
 197
 198         ol_with_ldbm_api=db2
 199
 200 else
 201         dnl SLAPD with LDBM
 202
 203         if test $ol_enable_bdb2 != no ; then
 204                 if test $ol_with_ldbm_api != auto -a \
 205                         $ol_with_ldbm_api != db2 ; then
 206                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 207                         ol_enable_bdb2=no
 208                 fi
 209         fi
 210
 211         if test $ol_with_ldbm_api = gdbm -a \
 212                 $ol_with_ldbm_type = btree ; then
 213                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 214         fi
 215         if test $ol_with_ldbm_api = ndbm -a \
 216                 $ol_with_ldbm_type = btree ; then
 217                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 218         fi
 219 fi
 220
 221 if test $ol_enable_slurpd = yes ; then
 222         dnl SLURPD was specifically enabled
 223         if test $ol_with_threads = no ; then
 224                 AC_MSG_ERROR([slurpd requires threads])
 225         fi
 226 fi
 227
 228 AC_MSG_RESULT(done)
 229
 230 AC_CANONICAL_HOST
 231
 232 ## Initialize vars
 233 LDAP_LIBS=
 234 LDBM_LIBS=
 235 LTHREAD_LIBS=
 236 LUTIL_LIBS=
 237
 238 LDAPD_LIBS=
 239 SLAPD_LIBS=
 240 SLURPD_LIBS=
 241
 242 BUILD_LDAPD=no
 243 BUILD_SLAPD=no
 244 BUILD_SLURPD=no
 245
 246 BUILD_BDB2=no
 247 BUILD_LDBM=no
 248 BUILD_PASSWD=no
 249 BUILD_PERL=no
 250 BUILD_SHELL=no
 251 BUILD_THREAD=no
 252
 253 SLAPD_PERL_LDFLAGS=
 254 SLAPD_PERL_CPPFLAGS=
 255
 256 KRB_LIBS=
 257 TERMCAP_LIBS=
 258
 259 dnl ----------------------------------------------------------------
 260 dnl Checks for programs
 261
 262 AC_PROG_INSTALL
 263 AM_PROG_LIBTOOL
 264 dnl AC_PROG_MAKE_SET
 265
 266 AC_PROG_AWK
 267 AC_PROG_LN_S
 268
 269 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 270         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 271 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 272 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 273
 274 if test $ol_enable_perl = yes ; then
 275         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 276
 277         if test "no$PERLBIN" = "no" ; then
 278                 ol_enable_perl=no
 279         fi
 280
 281         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 282         SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e perl_inc`"
 283 fi
 284
 285 AC_PROG_CPP
 286
 287 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 288         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 289
 290 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 291         AC_MSG_WARN([programs compiled here do run here...])
 292         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 293
 294 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 295         AC_MSG_WARN([programs compiled here do not run here...])
 296         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 297 fi
 298
 299 dnl Checks for UNIX Variants
 300 AC_AIX
 301 AC_ISC_POSIX
 302 AC_MINIX
 303
 304 dnl Checks for system services
 305 AC_CYGWIN
 306 AC_MINGW32
 307 AC_EXEEXT
 308 AC_OBJEXT
 309
 310 dnl OpenLDAP requires STDC features
 311 AM_PROG_CC_STDC
 312 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 313         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 314 fi
 315
 316 dnl AM_C_PROTOTYPES
 317
 318 dnl Checks for libraries
 319
 320 dnl Find socket()
 321 dnl Likely combinations:
 322 dnl             -lsocket [ -lnsl_s | -lnsl ]
 323 dnl             -linet
 324
 325 AC_CHECK_FUNC(socket, [have_socket=yes], [
 326 dnl
 327 dnl hopefully we won't include too many libraries
 328 dnl
 329         AC_CHECK_LIB(socket, main)
 330         AC_CHECK_LIB(net, main)
 331         AC_CHECK_LIB(nsl_s, main)
 332         AC_CHECK_LIB(nsl, main)
 333         AC_CHECK_LIB(inet, socket)
 334         AC_CHECK_LIB(gen, main)
 335 ])
 336
 337 dnl Check for resolver routines
 338 AC_CHECK_FUNCS(res_search)
 339 if test $ac_cv_func_res_search = "no" ; then
 340         AC_CHECK_LIB(bind, res_search)
 341         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 342                 AC_DEFINE(HAVE_RES_SEARCH,1)
 343         else
 344                 AC_CHECK_LIB(resolv, res_search)
 345                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 346                         AC_DEFINE(HAVE_RES_SEARCH,1)
 347                 fi
 348         fi
 349 fi
 350
 351 dnl HP-UX requires -lV3
 352 AC_CHECK_LIB(V3, sigset)
 353
 354 # ISODE tests
 355 ol_link_isode=no
 356 if test $ol_enable_ldapd != no ; then
 357         dnl look for ISODE libraries
 358         AC_CHECK_LIB(xtpp, main, [
 359                 ol_link_isode=yes
 360                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 361                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 362                 ],:,[-lxtdsap -lxtisode -losi])
 363         AC_CHECK_LIB(dsap, main, [
 364                 ol_link_isode=yes
 365                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 366                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 367                 ],:,[-lisode])
 368         AC_CHECK_LIB(isode, main, [
 369                 ol_link_isode=yes
 370                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 371                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 372                 ],:)
 373 fi
 374
 375 if test $ol_link_isode != no; then
 376         AC_CHECK_LIB(pp, main, [
 377                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 378                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 379                 ],:)
 380
 381         AC_PATH_PROG(PEPSY, pepsy)
 382 fi
 383
 384 dnl
 385 dnl check for kerberos
 386 dnl
 387 ol_link_kerberos=no
 388
 389 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 390         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 391
 392         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 393                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 394                         [-lkrb5 -ldes425])
 395
 396                 if test $have_k5 = yes ; then
 397                         ol_with_kerberos=found
 398                         ol_link_kerberos=yes
 399
 400                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 401                 fi
 402         fi
 403 fi
 404
 405 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 406         AC_CHECK_HEADERS(krb.h des.h)
 407
 408         if test $ac_cv_header_krb_h = yes ; then
 409                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 410
 411                 if test $have_k4 = yes ; then
 412                         ol_with_kerberos=found
 413                         ol_link_kerberos=yes
 414
 415                         KRB_LIBS="-lkrb -ldes"
 416                 fi
 417         fi
 418 fi
 419
 420 if test $ol_link_kerberos = yes ; then
 421         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 422 fi
 423
 424 ol_link_threads=no
 425 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 426         -o $ol_with_threads = posix ; then
 427
 428         AC_CHECK_HEADERS(pthread.h sched.h)
 429
 430         if test $ac_cv_header_pthread_h = yes ; then
 431                 OL_POSIX_THREAD_VERSION
 432
 433                 if test $ol_cv_pthread_version = final ; then
 434                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 435                                 [define if pthreads API compatible with final spec])
 436                 elif test $ol_cv_pthread_version = draft4 ; then
 437                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 438                                 [define if pthreads API compatible with draft4 spec])
 439                 else
 440                         AC_MSG_ERROR([unknown pthread version])
 441                 fi
 442
 443                 # consider threads found
 444                 ol_with_threads=found
 445
 446                 OL_LINUX_THREADS
 447
 448                 if test $ol_cv_linux_threads = yes ; then
 449                         AC_DEFINE(HAVE_LINUX_THREADS,1,
 450                                 [define if you have LinuxThreads])
 451                 fi
 452
 453                 dnl Now the hard part, how to link?
 454                 dnl
 455                 dnl currently supported checks:
 456                 dnl
 457                 dnl Check for no flags
 458                 dnl     pthread_create() in $LIBS
 459                 dnl
 460                 dnl Check special pthread (final) flags
 461                 dnl     pthread_create() with -kthread (FreeBSD)
 462                 dnl     pthread_create() with -pthread (FreeBSD)
 463                 dnl     pthread_create() with -pthreads (OSF/1)
 464                 dnl     pthread_create() with -thread (?)
 465                 dnl
 466                 dnl Check pthread (final) libraries
 467                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 468                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 469                 dnl     pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 470                 dnl     pthread_create() in -lpthread (many)
 471                 dnl     pthread_create() in -lc_r (FreeBSD)
 472                 dnl     pthread_create() in -lpthreads (many)
 473                 dnl     pthread_join() -Wl,-woff,85 -lpthreads (IRIX)
 474                 dnl     pthread_create() in HP-UX -lpthread (HP-UX 11)
 475                 dnl
 476                 dnl Check pthread (draft4) flags (to be depreciated)
 477                 dnl     pthread_create() with -threads (OSF/1)
 478                 dnl
 479                 dnl Check pthread (final) libraries (to be depreciated)
 480                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 481                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 482                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 483                 dnl
 484
 485                 dnl pthread_create in $LIBS
 486                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 487
 488                 if test $ol_link_threads = no ; then
 489                         dnl try -kthread
 490                         AC_CACHE_CHECK([for pthread_create with -kthread],
 491                                 [ol_cv_kthread_flag], [
 492                                 dnl save the flags
 493                                 save_LIBS="$LIBS"
 494                                 LIBS="-kthread $LIBS"
 495                                 AC_TRY_LINK([char pthread();],[
 496                                         pthread_create();
 497                                         ], ol_cv_kthread_flag=yes, ol_cv_kthread_flag=no)
 498                                 dnl restore the LIBS
 499                                 LIBS="$save_LIBS"
 500                         ])
 501
 502                         if test $ol_cv_kthread_flag = yes ; then
 503                                 LTHREAD_LIBS="$LTHREAD_LIBS -kthread"
 504                                 ol_link_threads=posix
 505                         fi
 506                 fi
 507
 508                 if test $ol_link_threads = no ; then
 509                         dnl try -pthread
 510                         AC_CACHE_CHECK([for pthread_create with -pthread],
 511                                 [ol_cv_pthread_flag], [
 512                                 dnl save the flags
 513                                 save_LIBS="$LIBS"
 514                                 LIBS="-pthread $LIBS"
 515                                 AC_TRY_LINK([char pthread();],[
 516                                         pthread_create();
 517                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 518                                 dnl restore the LIBS
 519                                 LIBS="$save_LIBS"
 520                         ])
 521
 522                         if test $ol_cv_pthread_flag = yes ; then
 523                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 524                                 ol_link_threads=posix
 525                         fi
 526                 fi
 527
 528                 if test $ol_link_threads = no ; then
 529                         dnl try -pthreads
 530                         AC_CACHE_CHECK([for pthread_create with -pthreads],
 531                                 [ol_cv_pthreads_flag], [
 532                                 dnl save the flags
 533                                 save_LIBS="$LIBS"
 534                                 LIBS="-pthreads $LIBS"
 535                                 AC_TRY_LINK([char pthread();],[
 536                                         pthread_create();
 537                                         ], ol_cv_pthreads_flag=yes, ol_cv_pthreads_flag=no)
 538                                 dnl restore the LIBS
 539                                 LIBS="$save_LIBS"
 540                         ])
 541
 542                         if test $ol_cv_pthreads_flag = yes ; then
 543                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthreads"
 544                                 ol_link_threads=posix
 545                         fi
 546                 fi
 547
 548                 if test $ol_link_threads = no ; then
 549                         dnl try -thread
 550                         AC_CACHE_CHECK([for pthread_create with -thread],
 551                                 [ol_cv_thread_flag], [
 552                                 dnl save the flags
 553                                 save_LIBS="$LIBS"
 554                                 LIBS="-thread $LIBS"
 555                                 AC_TRY_LINK([char pthread();],[
 556                                         pthread_create();
 557                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 558                                 dnl restore the LIBS
 559                                 LIBS="$save_LIBS"
 560                         ])
 561
 562                         if test $ol_cv_thread_flag = yes ; then
 563                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 564                                 ol_link_threads=posix
 565                         fi
 566                 fi
 567
 568                 if test $ol_link_threads = no ; then
 569                         dnl try DEC Threads -lpthread -lmach -lexc -lc_r
 570                         save_LIBS="$LIBS"
 571                         AC_CHECK_LIB(pthread, pthread_mutex_unlock, [
 572                                 ol_link_threads=posix
 573                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc -lc_r"
 574                                 if test $ol_with_yielding_select = auto ; then
 575                                         ol_with_yielding_select=yes
 576                                 fi
 577                                 ],:,[-lmach -lexc -lc_r])
 578                         LIBS="$save_LIBS"
 579                 fi
 580
 581                 if test $ol_link_threads = no ; then
 582                         dnl try DEC Threads -lpthread -lmach -lexc
 583                         save_LIBS="$LIBS"
 584                         AC_CHECK_LIB(pthread, pthread_mutex_lock, [
 585                                 ol_link_threads=posix
 586                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc"
 587                                 if test $ol_with_yielding_select = auto ; then
 588                                         ol_with_yielding_select=yes
 589                                 fi
 590                                 ],:,[-lmach -lexc])
 591                         LIBS="$save_LIBS"
 592                 fi
 593
 594                 if test $ol_link_threads = no ; then
 595                         dnl try DEC Threads -lpthread -lexc
 596                         save_LIBS="$LIBS"
 597                         AC_CHECK_LIB(pthread, pthread_mutex_trylock, [
 598                                 ol_link_threads=posix
 599                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 600                                 if test $ol_with_yielding_select = auto ; then
 601                                         ol_with_yielding_select=yes
 602                                 fi
 603                                 ],:,[-lexc])
 604                         LIBS="$save_LIBS"
 605                 fi
 606
 607                 if test $ol_link_threads = no ; then
 608                         dnl try -lpthread
 609                         save_LIBS="$LIBS"
 610                         AC_CHECK_LIB(pthread, pthread_create, [
 611                                 ol_link_threads=posix
 612                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"],:)
 613                         LIBS="$save_LIBS"
 614                 fi
 615
 616                 if test $ol_link_threads = no ; then
 617                         dnl try -lc_r
 618                         save_LIBS="$LIBS"
 619                         AC_CHECK_LIB(c_r, pthread_create, [
 620                                 ol_link_threads=posix
 621                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"],:)
 622                         LIBS="$save_LIBS"
 623                 fi
 624
 625                 if test $ol_link_threads = no ; then
 626                         dnl try -lpthreads
 627                         save_LIBS="$LIBS"
 628                         AC_CHECK_LIB(pthreads, pthread_create, [
 629                                 ol_link_threads=posix
 630                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"],:)
 631                         LIBS="$save_LIBS"
 632                 fi
 633
 634                 dnl IRIX Pthread check
 635                 if test $ol_link_threads = no ; then
 636                         dnl try IRIX Pthreads -Wl,-woff,85 -lpthreads
 637                         save_LIBS="$LIBS"
 638                         AC_CHECK_LIB(pthreads, pthread_join, [
 639                                 ol_link_threads=posix
 640                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"
 641                                 ],:,[-Wl,-woff,85])
 642                         LIBS="$save_LIBS"
 643                 fi
 644
 645                 dnl HP-UX 11 Pthread check
 646                 if test $ol_link_threads = no; then
 647                         save_LIBS="$LIBS"
 648                         LIBS="$LIBS -lpthread"
 649                         AC_MSG_CHECKING([for pthread_create() in HP-UX -lpthread])
 650                         ol_try_pthread_hpux_11=no
 651                         AC_CACHE_VAL(ol_cv_pthread_hpux_11,[
 652                                 AC_TRY_LINK([
 653 #include <pthread.h>
 654 #include <elf.h>
 655 #ifndef ELFABI_HPUX_REL11
 656         die horribly
 657 #endif
 658                                 ], [pthread_create(NULL, NULL, NULL, NULL);],
 659                                         ol_try_pthread_hpux_11=yes
 660                                         ol_cv_pthread_hpux_11=yes,
 661                                         ol_cv_pthread_hpux_11=no)])
 662                         AC_MSG_RESULT(yes)
 663                         LIBS="$save_LIBS"
 664
 665                         if test $ol_cv_pthread_hpux_11=yes ; then
 666                                 ol_link_threads=posix
 667                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"
 668                                 if test $ol_try_pthread_hpux_11=yes ; then
 669                                         dnl Some tests below may fail, cause we aint including
 670                                         dnl pthread.h. Force appropriate ones to yes
 671                                         ac_cv_func_pthread_attr_init=yes
 672                                 fi
 673                         fi
 674                 fi
 675
 676                 if test $ol_link_threads = no ; then
 677                         dnl try -threads
 678                         AC_CACHE_CHECK([for pthread_create with -threads],
 679                                 [ol_cv_thread_flag], [
 680                                 dnl save the flags
 681                                 save_LIBS="$LIBS"
 682                                 LIBS="-threads $LIBS"
 683                                 AC_TRY_LINK([char pthread();],[
 684                                         pthread_create();
 685                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 686                                 dnl restore the LIBS
 687                                 LIBS="$save_LIBS"
 688                         ])
 689
 690                         if test $ol_cv_thread_flag = yes ; then
 691                                 LTHREAD_LIBS="$LTHREAD_LIBS -threads"
 692                                 ol_link_threads=posix
 693                         fi
 694                 fi
 695
 696                 if test $ol_link_threads = no ; then
 697                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 698                         save_LIBS="$LIBS"
 699                         AC_CHECK_LIB(pthreads, pthread_mutex_unlock, [
 700                                 ol_link_threads=posix
 701                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 702                                 if test $ol_with_yielding_select = auto ; then
 703                                         ol_with_yielding_select=yes
 704                                 fi
 705                                 ],:,[-lmach -lexc -lc_r])
 706                         LIBS="$save_LIBS"
 707                 fi
 708
 709                 if test $ol_link_threads = no ; then
 710                         dnl try DEC Threads -lpthreads -lmach -lexc
 711                         save_LIBS="$LIBS"
 712                         AC_CHECK_LIB(pthreads, pthread_mutex_lock, [
 713                                 ol_link_threads=posix
 714                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc"
 715                                 if test $ol_with_yielding_select = auto ; then
 716                                         ol_with_yielding_select=yes
 717                                 fi
 718                                 ],:,[-lmach -lexc])
 719                         LIBS="$save_LIBS"
 720                 fi
 721
 722                 if test $ol_link_threads = no ; then
 723                         dnl try DEC Threads -lpthreads -lexc
 724                         save_LIBS="$LIBS"
 725                         AC_CHECK_LIB(pthreads, pthread_mutex_trylock, [
 726                                 ol_link_threads=posix
 727                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lexc"
 728                                 if test $ol_with_yielding_select = auto ; then
 729                                         ol_with_yielding_select=yes
 730                                 fi
 731                                 ],:,[-lexc])
 732                         LIBS="$save_LIBS"
 733                 fi
 734
 735                 if test $ol_link_threads != no ; then
 736                         AC_DEFINE(HAVE_PTHREADS,1,
 737                                 [define if you have POSIX Threads])
 738
 739                         dnl save flags
 740                         save_CPPFLAGS="$CPPFLAGS"
 741                         save_LIBS="$LIBS"
 742                         LIBS="$LTHREAD_LIBS $LIBS"
 743
 744                         dnl All POSIX Thread (final) implementations should have
 745                         dnl sched_yield instead of pthread yield.
 746                         dnl check for both
 747                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 748
 749                         if test $ac_cv_func_sched_yield = no -a \
 750                                 $ac_cv_func_pthread_yield = no ; then
 751                                 dnl Digital UNIX has sched_yield() in -lrt
 752                                 AC_CHECK_LIB(rt, sched_yield,
 753                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 754                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 755                                         ac_cv_func_sched_yield=yes],
 756                                         [ac_cv_func_sched_yield=no])
 757                         fi
 758                         if test $ac_cv_func_sched_yield = no -a \
 759                                 $ac_cv_func_pthread_yield = no ; then
 760                                 dnl Solaris has sched_yield() in -lposix4
 761                                 dnl but we'll use thr_yield instead.
 762                                 AC_CHECK_FUNCS(thr_yield)
 763                         fi
 764                         if test $ac_cv_func_sched_yield = no -a \
 765                                 $ac_cv_func_pthread_yield = no -a \
 766                                 "$ac_cv_func_thr_yield" = no ; then
 767                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 768                         fi
 769
 770                         dnl Check functions for compatibility
 771                         AC_CHECK_FUNCS(pthread_kill pthread_detach)
 772
 773                         if test $ac_cv_func_pthread_detach = no ; then
 774                                 AC_MSG_ERROR([could not locate pthread_detach()])
 775                         fi
 776
 777                         dnl Check for setconcurreny functions
 778                         AC_CHECK_FUNCS( \
 779                                 pthread_setconcurrency \
 780                                 pthread_getconcurrency \
 781                                 thr_setconcurrency \
 782                                 thr_getconcurrency \
 783                         )
 784
 785                         AC_MSG_CHECKING([if pthread_create() works])
 786                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 787                         AC_TRY_RUN([
 788 #include <pthread.h>
 789 #ifndef NULL
 790 #define NULL (void*)0
 791 #endif
 792
 793 static void *task(p)
 794         void *p;
 795 {
 796         return (void *) (p == NULL);
 797 }
 798
 799 int main(argc, argv)
 800         int argc;
 801         char **argv;
 802 {
 803         pthread_t t;
 804         exit(pthread_create(&t, NULL, task, NULL));
 805 }
 806 ],
 807                                 [ol_cv_pthread_create_works=yes],
 808                                 [ol_cv_pthread_create_works=no],
 809                                 [dnl assume yes
 810                                 ol_cv_pthread_create_works=yes])])
 811                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 812
 813                         if test $ol_cv_pthread_create_works = no ; then
 814                                 AC_MSG_ERROR([pthread.h and pthread_create are not compatible])
 815                         fi
 816
 817                         dnl Check if select causes an yield
 818                         if test $ol_with_yielding_select = auto ; then
 819                                 AC_MSG_CHECKING([if select yields when using pthreads])
 820                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 821                                 AC_TRY_RUN([
 822 #include <sys/types.h>
 823 #include <sys/time.h>
 824 #include <unistd.h>
 825 #include <pthread.h>
 826 #ifndef NULL
 827 #define NULL (void*) 0
 828 #endif
 829
 830 static int fildes[2];
 831
 832 static void *task(p)
 833         void *p;
 834 {
 835         int i;
 836         struct timeval tv;
 837
 838         fd_set rfds;
 839
 840         tv.tv_sec=10;
 841         tv.tv_usec=0;
 842
 843         FD_ZERO(&rfds);
 844         FD_SET(fildes[0], &rfds);
 845
 846         /* we're not interested in any fds */
 847         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 848
 849         if(i < 0) {
 850                 perror("select");
 851                 exit(10);
 852         }
 853
 854         exit(0); /* if we exit here, the select blocked the whole process */
 855 }
 856
 857 int main(argc, argv)
 858         int argc;
 859         char **argv;
 860 {
 861         pthread_t t;
 862
 863         /* create a pipe to select */
 864         if(pipe(&fildes[0])) {
 865                 perror("select");
 866                 exit(1);
 867         }
 868
 869 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 870         (void) pthread_setconcurrency(2);
 871 #else
 872 #ifdef HAVE_THR_SETCONCURRENCY
 873         /* Set Solaris LWP concurrency to 2 */
 874         thr_setconcurrency(2);
 875 #endif
 876 #endif
 877
 878         pthread_create(&t, NULL, task, NULL);
 879
 880 #if HAVE_SCHED_YIELD
 881         sched_yield();  /* make sure task runs first */
 882 #else
 883 #ifdef HAVE_PTHREAD_YIELD
 884         pthread_yield();        /* make sure task runs first */
 885 #endif
 886 #endif
 887
 888         exit(2);
 889 }],
 890                                 [ol_cv_pthread_select_yields=no],
 891                                 [ol_cv_pthread_select_yields=yes], [
 892                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
 893                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
 894
 895                                 if test $ol_cv_pthread_select_yields = yes ; then
 896                                         ol_with_yielding_select=yes
 897                                 fi
 898                         fi
 899
 900                         dnl restore flags
 901                         CPPFLAGS="$save_CPPFLAGS"
 902                         LIBS="$save_LIBS"
 903                 else
 904                         AC_MSG_ERROR([could not link with POSIX Threads])
 905                 fi
 906         fi
 907
 908         if test $ol_with_threads = posix ; then
 909                 AC_MSG_ERROR([could not locate POSIX Threads])
 910         fi
 911 fi
 912
 913 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 914         -o $ol_with_threads = mach ; then
 915
 916         dnl check for Mach CThreads
 917         AC_CHECK_HEADERS(mach/cthreads.h)
 918         if test $ac_cv_header_mach_cthreads_h = yes ; then
 919                 ol_with_threads=found
 920
 921                 dnl check for cthread support in current $LIBS
 922                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 923
 924                 if test $ol_link_threads = no ; then
 925                         dnl try -all_load
 926                         dnl this test needs work
 927                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 928                                 [ol_cv_cthread_all_load], [
 929                                 dnl save the flags
 930                                 save_LIBS="$LIBS"
 931                                 LIBS="-all_load $LIBS"
 932                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 933                                         cthread_fork((void *)0, (void *)0);
 934                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 935                                 dnl restore the LIBS
 936                                 LIBS="$save_LIBS"
 937                         ])
 938
 939                         if test $ol_cv_cthread_all_load = yes ; then
 940                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 941                                 ol_link_threads=mach
 942                         fi
 943                 fi
 944
 945                 if test $ol_link_threads != no ; then
 946                         : check for cthread specific functionality here
 947                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
 948                                 [define if you have Mach Cthreads])
 949                 else
 950                         AC_MSG_ERROR([could not link with Mach CThreads])
 951                 fi
 952         fi
 953
 954         if test $ol_with_threads = mach ; then
 955                 AC_MSG_ERROR([could not locate Mach CThreads])
 956         fi
 957 fi
 958
 959 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 960         -o $ol_with_threads = lwp ; then
 961
 962         dnl check for SunOS5 LWP
 963         AC_CHECK_HEADERS(thread.h synch.h)
 964         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 965                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
 966
 967                 if test $have_thr = yes ; then
 968                         AC_DEFINE(HAVE_THR,1,
 969                                 [if you have Solaris LWP (thr) package])
 970                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
 971                         ol_link_threads=thr
 972
 973                         if test $ol_with_yielding_select = auto ; then
 974                                 ol_with_yielding_select=yes
 975                         fi
 976
 977                         dnl Check for setconcurreny functions
 978                         AC_CHECK_FUNCS( \
 979                                 thr_setconcurrency \
 980                                 thr_getconcurrency \
 981                         )
 982                 fi
 983         fi
 984
 985         dnl check for SunOS4 LWP
 986         AC_CHECK_HEADERS(lwp/lwp.h)
 987         if test $ac_cv_header_lwp_lwp_h = yes ; then
 988                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 989
 990                 if test $have_lwp = yes ; then
 991                         AC_DEFINE(HAVE_LWP,1,
 992                                 [if you have SunOS LWP package])
 993                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 994                         ol_link_threads=lwp
 995
 996                         if test $ol_with_yielding_select = auto ; then
 997                                 ol_with_yielding_select=no
 998                         fi
 999                 fi
1000         fi
1001 fi
1002
1003 if test $ol_with_yielding_select = yes ; then
1004         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1005                 [define if select implicitly yields])
1006 fi
1007
1008 if test $ol_with_threads = manual ; then
1009         dnl User thinks he can manually configure threads.
1010         ol_link_threads=yes
1011
1012         AC_MSG_WARN([thread defines and link options must be set manually])
1013
1014         AC_CHECK_HEADERS(pthread.h sched.h)
1015         AC_CHECK_FUNCS(sched_yield pthread_yield)
1016         OL_LINUX_THREADS
1017
1018         AC_CHECK_HEADERS(mach/cthreads.h)
1019         AC_CHECK_HEADERS(lwp/lwp.h)
1020         AC_CHECK_HEADERS(thread.h synch.h)
1021 fi
1022
1023 if test $ol_link_threads != no ; then
1024         dnl needed to get reentrant/threadsafe versions
1025         dnl
1026         AC_DEFINE(REENTRANT,1)
1027         AC_DEFINE(_REENTRANT,1)
1028         AC_DEFINE(THREAD_SAFE,1)
1029         AC_DEFINE(_THREAD_SAFE,1)
1030         AC_DEFINE(THREADSAFE,1)
1031         AC_DEFINE(_THREADSAFE,1)
1032
1033         dnl this might cause the errno symbol to be
1034         dnl replaced with a function to get a thread specific errno.
1035         dnl check to see if everything needs to be compiled
1036         dnl with the thread libraries
1037         AC_CACHE_CHECK([for thread specific errno],
1038                 [ol_cv_errno_thread_specific], [
1039                 AC_TRY_LINK([
1040 #include <errno.h>
1041                         ], [
1042 int x = errno;
1043                         ],
1044                         [ol_cv_errno_thread_specific=yes],
1045                         [ol_cv_errno_thread_specific=no])
1046         ])
1047
1048         if test $ol_cv_errno_thread_specific != yes ; then
1049                 LIBS="$LTHREAD_LIBS $LIBS"
1050                 LTHREAD_LIBS=""
1051         fi
1052
1053 dnl When in thread environment, use
1054 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1055 dnl                     || defined( HAVE_FUNC_R )
1056 dnl                     func_r(...);
1057 dnl             #else
1058 dnl             #       if defined( HAVE_THREADS )
1059 dnl                             /* lock */
1060 dnl             #       endif
1061 dnl                             func(...);
1062 dnl             #       if defined( HAVE_THREADS )
1063 dnl                             /* unlock */
1064 dnl             #       endif
1065 dnl             #endif
1066 dnl
1067 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1068 dnl             _POSIX_REENTRANT_FUNCTIONS
1069 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1070 dnl             _POSIX_THREADSAFE_FUNCTIONS
1071 dnl
1072 dnl             and is currently defined in lthread.h
1073 dnl
1074 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1075 dnl
1076 dnl libldap/*.c should only include <lthread.h> iff
1077 dnl LDAP_R_COMPILE is defined.  ie:
1078 dnl             #ifdef LDAP_R_COMPILE
1079 dnl             #       include LDAP_R_COMPILE
1080 dnl             #endif
1081 dnl
1082 dnl LDAP_R_COMIPLE is defined by libldap_r/Makefile.in
1083 dnl specifically for compiling the threadsafe version of
1084 dnl     the ldap library (-lldap_r).
1085 dnl
1086 dnl     dnl check for reentrant/threadsafe functions
1087 dnl     dnl
1088 dnl     dnl note: these should only be used when linking
1089 dnl     dnl       with $LTHREAD_LIBS
1090 dnl     dnl
1091 dnl     save_CPPFLAGS="$CPPFLAGS"
1092 dnl     save_LIBS="$LIBS"
1093 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1094 dnl     AC_CHECK_FUNCS( \
1095 dnl             strtok_r \
1096 dnl             gmtime_r \
1097 dnl             gethostbyaddr_r gethostbyname_r \
1098 dnl             feof_unlocked unlocked_feof \
1099 dnl             putc_unlocked unlocked_putc \
1100 dnl             flockfile ftrylockfile \
1101 dnl     )
1102 dnl     CPPFLAGS="$save_CPPFLAGS"
1103 dnl     LIBS="$save_LIBS"
1104 fi
1105
1106 dnl ----------------------------------------------------------------
1107
1108 if test $ol_link_threads = no ; then
1109         if test $ol_with_threads = yes ; then
1110                 AC_MSG_ERROR([no suitable thread support])
1111         fi
1112
1113         if test $ol_with_threads = auto ; then
1114                 AC_MSG_WARN([no suitable thread support, disabling threads])
1115                 ol_with_threads=no
1116         fi
1117
1118         AC_DEFINE(NO_THREADS,1,
1119                 [define if you have (or want) no threads])
1120         LTHREAD_LIBS=""
1121 fi
1122
1123 ol_link_ldbm=no
1124 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1125         OL_BERKELEY_DB2
1126
1127         if test $ol_cv_berkeley_db2 = yes ; then
1128                 ol_link_ldbm=db2
1129                 ol_with_ldbm_api=db2
1130
1131                 if test $ol_with_ldbm_type = hash ; then
1132                         AC_DEFINE(LDBM_USE_DBHASH,1)
1133                 else
1134                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1135                 fi
1136
1137                 dnl $ol_cv_lib_db2 should be yes or -ldb
1138                 dnl (it could be no, but that would be an error
1139                 if test $ol_cv_lib_db2 != yes ; then
1140                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1141                 fi
1142         fi
1143 fi
1144
1145 ol_link_bdb2=no
1146 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1147         ol_link_bdb2=yes
1148 fi
1149
1150 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1151         OL_BERKELEY_DB
1152
1153         if test $ol_cv_berkeley_db = yes ; then
1154                 ol_link_ldbm=db
1155                 ol_with_ldbm_api=db
1156
1157                 if test $ol_with_ldbm_type = hash ; then
1158                         AC_DEFINE(LDBM_USE_DBHASH,1)
1159                 else
1160                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1161                 fi
1162
1163                 dnl $ol_cv_lib_db should be yes or -ldb
1164                 dnl (it could be no, but that would be an error
1165                 if test $ol_cv_lib_db != yes ; then
1166                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1167                 fi
1168         fi
1169 fi
1170
1171 if test $ol_with_ldbm_api = manual ; then
1172         dnl User thinks he can manually configure LDBM api.
1173         ol_link_ldbm=yes
1174
1175         AC_MSG_WARN([LDBM defines and link options must be set manually])
1176
1177         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1178 fi
1179
1180 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1181         AC_MSG_WARN(Could not find LDBM with BTREE support)
1182         ol_with_ldbm_api=none
1183 fi
1184
1185 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1186         OL_GDBM
1187
1188         if test $ol_cv_gdbm = yes ; then
1189                 ol_link_ldbm=gdbm
1190                 ol_with_ldbm_api=gdbm
1191
1192                 if test $ol_cv_lib_gdbm != yes ; then
1193                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1194                 fi
1195         fi
1196 fi
1197
1198 if test $ol_with_ldbm_api = auto ; then
1199         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1200 elif test $ol_with_ldbm_api = ndbm ; then
1201         OL_NDBM
1202
1203         if test $ol_cv_ndbm = yes ; then
1204                 ol_link_ldbm=ndbm
1205                 ol_with_ldbm_api=ndbm
1206
1207                 if test $ol_cv_lib_ndbm != yes ; then
1208                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1209                 fi
1210         fi
1211 fi
1212
1213 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1214         AC_MSG_WARN(could not find suitable LDBM backend)
1215         if test $ol_enable_ldbm = yes ; then
1216                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1217         fi
1218
1219         AC_MSG_WARN(disabling LDBM)
1220         ol_enable_ldbm=no
1221 fi
1222
1223 if test $ol_enable_wrappers != no ; then
1224         AC_CHECK_HEADERS(tcpd.h)
1225
1226         if test $ac_cv_header_tcpd_h != yes ; then
1227                 have_wrappers=no
1228         else
1229                 AC_CHECK_LIB(wrap, main,
1230                         [have_wrappers=yes], [have_wrappers=no])
1231         fi
1232
1233         if test $have_wrappers = yes ; then
1234                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1235                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1236         else
1237                 AC_MSG_WARN(could not find -lwrap)
1238                 if test $ol_enable_wrappers = yes ; then
1239                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1240                 fi
1241
1242                 AC_MSG_WARN(disabling wrappers support)
1243                 ol_enable_wrappers=no
1244         fi
1245 fi
1246
1247 if test $ol_enable_syslog != no ; then
1248         AC_CHECK_FUNC(openlog)
1249         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1250                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1251         fi
1252         ol_enable_syslog=$ac_cv_func_openlog
1253 fi
1254
1255 if test $ol_enable_dmalloc != no ; then
1256         AC_CHECK_HEADERS(dmalloc.h)
1257         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1258 fi
1259
1260 # ud needs termcap (should insert check here)
1261 ol_link_termcap=no
1262 AC_CHECK_HEADERS(termcap.h ncurses.h)
1263
1264 if test $ol_link_termcap = no ; then
1265         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1266         if test $have_termcap = yes ; then
1267                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1268                 ol_link_termcap=yes
1269                 TERMCAP_LIBS=-ltermcap
1270         fi
1271 fi
1272
1273 if test $ol_link_termcap = no ; then
1274         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1275         if test $have_ncurses = yes ; then
1276                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1277                 ol_link_termcap=yes
1278                 TERMCAP_LIBS=-lncurses
1279         fi
1280 fi
1281
1282 if test $ol_link_termcap = no ; then
1283         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1284         TERMCAP_LIBS=
1285 fi
1286
1287 # FreeBSD (and others) have crypt(3) in -lcrypt
1288 if test $ol_enable_crypt != no ; then
1289         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1290                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1291                         have_crypt=yes], [have_crypt=no])])
1292
1293         if test $have_crypt = yes ; then
1294                 AC_DEFINE(HAVE_CRYPT,1)
1295         else
1296                 AC_MSG_WARN(could not find crypt)
1297                 if test $ol_enable_crypt = yes ; then
1298                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1299                 fi
1300
1301                 AC_MSG_WARN(disabling crypt support)
1302                 ol_enable_crypt=no
1303         fi
1304 fi
1305
1306 # FreeBSD (and others) have setproctitle(3) in -lutil
1307 if test $ol_enable_proctitle != no ; then
1308         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1309                 AC_CHECK_LIB(util, setproctitle,
1310                         [have_setproctitle=yes
1311                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1312                         [have_setproctitle=no
1313                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1314
1315         if test $have_setproctitle = yes ; then
1316                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1317         fi
1318 fi
1319
1320 dnl ----------------------------------------------------------------
1321 dnl Checks for header files.
1322 AC_HEADER_STDC
1323
1324 if test $ac_cv_header_stdc != yes; then
1325         AC_MSG_WARN([could not Standard C compliant headers])
1326 fi
1327
1328 AC_HEADER_DIRENT
1329 AC_HEADER_SYS_WAIT
1330 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1331 if test $am_cv_sys_posix_termios = yes ; then
1332         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1333                 [define if you have POSIX termios])
1334 fi
1335
1336 AC_CHECK_HEADERS(       \
1337         crypt.h                 \
1338         errno.h                 \
1339         fcntl.h                 \
1340         filio.h                 \
1341         getopt.h                \
1342         libutil.h               \
1343         limits.h                \
1344         malloc.h                \
1345         memory.h                \
1346         regex.h                 \
1347         psap.h                  \
1348         pwd.h                   \
1349         sgtty.h                 \
1350         stdarg.h                \
1351         stddef.h                \
1352         string.h                \
1353         strings.h               \
1354         sysexits.h              \
1355         sys/file.h              \
1356         sys/filio.h             \
1357         sys/errno.h             \
1358         sys/ioctl.h             \
1359         sys/param.h             \
1360         sys/resource.h  \
1361         sys/socket.h    \
1362         sys/syslog.h    \
1363         sys/time.h              \
1364         sys/types.h             \
1365         syslog.h                \
1366         termios.h               \
1367         unistd.h                \
1368 )
1369
1370 dnl ----------------------------------------------------------------
1371 dnl Checks for typedefs, structures, and compiler characteristics.
1372 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1373 AC_TYPE_MODE_T
1374 AC_TYPE_OFF_T
1375 AC_TYPE_PID_T
1376 AM_TYPE_PTRDIFF_T
1377 AC_TYPE_SIGNAL
1378 OL_TYPE_SIG_ATOMIC_T
1379 AC_TYPE_SIZE_T
1380 AC_STRUCT_ST_BLKSIZE
1381 AC_HEADER_TIME
1382 AC_STRUCT_TM
1383
1384 OL_C_UPPER_LOWER
1385 AC_C_CONST
1386 OL_C_VOLATILE
1387
1388 if test $cross_compiling = yes ; then
1389         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1390 else
1391         AC_C_BIGENDIAN
1392         AC_CHECK_SIZEOF(short)
1393         AC_CHECK_SIZEOF(int)
1394         AC_CHECK_SIZEOF(long)
1395 fi
1396
1397 dnl ----------------------------------------------------------------
1398 dnl Checks for library functions.
1399 AC_FUNC_MEMCMP
1400 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1401 AC_FUNC_STRFTIME
1402 dnl AM_FUNC_STRTOD
1403 AC_FUNC_VPRINTF
1404
1405 if test $ac_cv_func_vprintf = yes ; then
1406         dnl check for vsnprintf
1407         AC_CHECK_FUNCS(vsnprintf vsprintf)
1408 fi
1409
1410 AC_CHECK_FUNCS(         \
1411         bcopy                   \
1412         flock                   \
1413         getdtablesize   \
1414         gethostname             \
1415         getpwuid                \
1416         gettimeofday    \
1417         lockf                   \
1418         memcpy                  \
1419         memmove                 \
1420         mkstemp                 \
1421         select                  \
1422         setpwfile               \
1423         setsid                  \
1424         signal                  \
1425         sigset                  \
1426         snprintf                \
1427         socket                  \
1428         strdup                  \
1429         strerror                \
1430         strpbrk                 \
1431         strrchr                 \
1432         strsep                  \
1433         strstr                  \
1434         strtok                  \
1435         strtol                  \
1436         strtoul                 \
1437         strspn                  \
1438         sysconf                 \
1439         waitpid                 \
1440 )
1441
1442 # these functions are required to build a thread_safe -lldap
1443 AC_CHECK_FUNCS(         \
1444         strtok_r                \
1445         ctime_r                 \
1446         gethostbyaddr_r \
1447         gethostbyname_r \
1448 )
1449
1450 if test "$ac_cv_func_ctime_r" = yes ; then
1451         OL_FUNC_CTIME_R_NARGS
1452 else
1453         ol_cv_func_ctime_r=0
1454 fi
1455
1456 if test "$ac_cv_func_strtok_r" = yes \
1457         -a "$ac_cv_func_ctime_r" = yes \
1458         -a "$ol_cv_func_ctime_r_nargs" -ge 2 -a "$ol_cv_func_ctime_r_nargs" -le 3 \
1459         -a "$ac_cv_func_gethostbyaddr_r" = yes \
1460         -a "$ac_cv_func_gethostbyname_r" = yes \
1461         ; then
1462
1463         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT, 1)
1464 fi
1465
1466 if test $ol_link_threads != no ; then
1467         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE, 1)
1468 fi
1469
1470 dnl We actually may need to replace more than this.
1471 AC_REPLACE_FUNCS(getopt tempnam)
1472
1473 dnl ----------------------------------------------------------------
1474 # Check Configuration
1475 OL_SYS_ERRLIST
1476
1477 dnl ----------------------------------------------------------------
1478 dnl Sort out defines
1479
1480 if test "$ol_enable_debug" != no ; then
1481         AC_DEFINE(LDAP_DEBUG,1)
1482 fi
1483 if test "$ol_enable_syslog" = yes ; then
1484         AC_DEFINE(LDAP_SYSLOG,1)
1485 fi
1486 if test "$ol_enable_libui" = yes ; then
1487         AC_DEFINE(LDAP_LIBUI,1)
1488 fi
1489 if test "$ol_enable_cache" = no ; then
1490         AC_DEFINE(LDAP_NOCACHE,1)
1491 fi
1492 if test "$ol_enable_dns" != no ; then
1493         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1494 fi
1495 if test "$ol_enable_proctitle" != no ; then
1496         AC_DEFINE(LDAP_PROCTITLE,1)
1497 fi
1498 if test "$ol_enable_referrals" != no ; then
1499         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1500 fi
1501 if test "$ol_enable_cldap" != no ; then
1502         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1503 fi
1504
1505 if test "$ol_enable_aclgroups" != no ; then
1506         AC_DEFINE(SLAPD_ACLGROUPS,1)
1507 fi
1508 if test "$ol_enable_crypt" != no ; then
1509         AC_DEFINE(SLAPD_CRYPT,1)
1510 fi
1511 if test "$ol_enable_cleartext" != no ; then
1512         AC_DEFINE(SLAPD_CLEARTEXT,1)
1513 fi
1514 if test "$ol_enable_phonetic" != no ; then
1515         AC_DEFINE(SLAPD_PHONETIC,1)
1516 fi
1517 if test "$ol_enable_rlookups" != no ; then
1518         AC_DEFINE(SLAPD_RLOOKUPS,1)
1519 fi
1520
1521 if test "$ol_link_bdb2" != no ; then
1522         AC_DEFINE(SLAPD_BDB2,1)
1523         BUILD_SLAPD=yes
1524         BUILD_BDB2=yes
1525 fi
1526
1527 if test "$ol_link_ldbm" != no ; then
1528         AC_DEFINE(SLAPD_LDBM,1)
1529         BUILD_SLAPD=yes
1530         BUILD_LDBM=yes
1531 fi
1532
1533 if test "$ol_enable_passwd" != no ; then
1534         AC_DEFINE(SLAPD_PASSWD,1)
1535         BUILD_SLAPD=yes
1536         BUILD_PASSWD=yes
1537 fi
1538
1539 if test "$ol_enable_perl" != no ; then
1540         AC_DEFINE(SLAPD_PERL,1)
1541         BUILD_SLAPD=yes
1542         BUILD_PERL=yes
1543 fi
1544
1545 if test "$ol_enable_shell" != no ; then
1546         AC_DEFINE(SLAPD_SHELL,1)
1547         BUILD_SLAPD=yes
1548         BUILD_SHELL=yes
1549 fi
1550
1551 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1552         $BUILD_SLAPD = yes ; then
1553         BUILD_SLURPD=yes
1554 fi
1555
1556 if test "$ol_link_isode" != no ; then
1557         BUILD_LDAPD=yes
1558 fi
1559
1560 dnl ----------------------------------------------------------------
1561
1562 AC_SUBST(BUILD_LDAPD)
1563 AC_SUBST(BUILD_SLAPD)
1564   AC_SUBST(BUILD_BDB2)
1565   AC_SUBST(BUILD_LDBM)
1566   AC_SUBST(BUILD_PASSWD)
1567   AC_SUBST(BUILD_PERL)
1568   AC_SUBST(BUILD_SHELL)
1569 AC_SUBST(BUILD_SLURPD)
1570
1571 AC_SUBST(LDAP_LIBS)
1572 AC_SUBST(LDAPD_LIBS)
1573 AC_SUBST(SLAPD_LIBS)
1574 AC_SUBST(SLURPD_LIBS)
1575 AC_SUBST(LDBM_LIBS)
1576 AC_SUBST(LTHREAD_LIBS)
1577 AC_SUBST(LUTIL_LIBS)
1578
1579 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1580 AC_SUBST(SLAPD_PERL_LDFLAGS)
1581
1582 AC_SUBST(KRB_LIBS)
1583 AC_SUBST(TERMCAP_LIBS)
1584
1585 dnl ----------------------------------------------------------------
1586 dnl final output
1587 dnl
1588
1589 AC_OUTPUT( \
1590 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1591 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1592 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1593 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1594 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1595 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1596 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1597 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1598 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1599 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1600 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1601 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1602 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1603 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1604 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1605 include/Makefile:build/top.mk:include/Makefile.in \
1606 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1607 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1608 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1609 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1610 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1611 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1612 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1613 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1614 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1615 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1616 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1617 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1618 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1619 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
1620 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1621 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1622 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1623 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1624 tests/Makefile:build/top.mk:tests/Makefile.in \
1625 ,[
1626 date > stamp-h
1627 echo Please \"make depend\" to build dependencies
1628 ])