git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl This work is part of OpenLDAP Software <http://www.openldap.org/>.
   3 dnl
   4 dnl Copyright 1998-2011 The OpenLDAP Foundation.
   5 dnl All rights reserved.
   6 dnl
   7 dnl Redistribution and use in source and binary forms, with or without
   8 dnl modification, are permitted only as authorized by the OpenLDAP
   9 dnl Public License.
  10 dnl
  11 dnl A copy of this license is available in the file LICENSE in the
  12 dnl top-level directory of the distribution or, alternatively, at
  13 dnl <http://www.OpenLDAP.org/license.html>.
  14 dnl
  15 dnl ----------------------------------------------------------------
  16 dnl Disable config.cache!
  17 define([AC_CACHE_LOAD], )dnl
  18 define([AC_CACHE_SAVE], )dnl
  19 dnl ----------------------------------------------------------------
  20 dnl Disable libtool 1.5 support for languages we don't use
  21 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  22 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  23 define([AC_LIBTOOL_LANG_GCJ_CONFIG], [:])dnl
  24 dnl ================================================================
  25 dnl Configure.in for OpenLDAP
  26 AC_COPYRIGHT([[Copyright 1998-2011 The OpenLDAP Foundation. All rights reserved.
  27 Restrictions apply, see COPYRIGHT and LICENSE files.]])
  28 AC_REVISION([$Id$])
  29 AC_INIT([OpenLDAP],,[http://www.openldap.org/its/])
  30 m4_define([AC_PACKAGE_BUGREPORT],[<http://www.openldap.org/its/>])
  31 AC_CONFIG_SRCDIR(build/version.sh)dnl
  32 dnl ----------------------------------------------------------------
  33 dnl OpenLDAP Autoconf Macros
  34 builtin(include, build/openldap.m4)dnl
  35 dnl ================================================================
  36
  37 AC_CONFIG_AUX_DIR(build)dnl
  38
  39 eval `$ac_aux_dir/version.sh`
  40 if test -z "$OL_STRING"; then
  41         AC_MSG_ERROR([could not determine version])
  42 fi
  43
  44 if test -f "$ac_aux_dir/shtool" && test ! -d $ac_aux_dir/shtool; then
  45         ac_cv_shtool="$ac_aux_dir/shtool"
  46 else
  47         AC_MSG_ERROR([no shtool found in $ac_aux_dir])
  48 fi
  49
  50 SHTOOL="$ac_cv_shtool"
  51 dnl AC_SUBST(SHTOOL)dnl
  52
  53 TB="" TN=""
  54 if test -t 1; then
  55         TB="`$SHTOOL echo -e '%B' 2>/dev/null`"
  56         TN="`$SHTOOL echo -e '%b' 2>/dev/null`"
  57 fi
  58
  59 OPENLDAP_REPO=""
  60 if test -d $ac_aux_dir/../.git; then
  61         OPENLDAP_REPO="(from Git clone) "
  62 elif test -d $ac_aux_dir/CVS; then
  63         OPENLDAP_REPO="(from CVS checkout) "
  64 fi
  65
  66 echo "Configuring ${TB}${OL_STRING}${TN} ${OPENLDAP_REPO}..."
  67
  68 dnl Determine host platform
  69 dnl             we try not to use this for much
  70 AC_CANONICAL_TARGET([])
  71
  72 AM_INIT_AUTOMAKE([$OL_PACKAGE],[$OL_VERSION], [no defines])dnl
  73 AC_SUBST(PACKAGE)dnl
  74 AC_SUBST(VERSION)dnl
  75 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  76 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  77
  78 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION,$OL_API_INC,Version)
  79 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MAJOR,$OL_MAJOR,Major)
  80 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MINOR,$OL_MINOR,Minor)
  81 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_PATCH,$OL_PATCH,Patch)
  82
  83 OPENLDAP_LIBRELEASE=$OL_API_LIB_RELEASE
  84 AC_SUBST(OPENLDAP_LIBRELEASE)dnl
  85
  86 OPENLDAP_LIBVERSION=$OL_API_LIB_VERSION
  87 AC_SUBST(OPENLDAP_LIBVERSION)dnl
  88
  89 OPENLDAP_RELEASE_DATE="$OL_RELEASE_DATE"
  90 AC_SUBST(OPENLDAP_RELEASE_DATE)dnl
  91
  92 dnl We use autoconf features new to 2.59.  Later versions like won't work.
  93 dnl aclocal.m4 should be built using aclocal from automake 1.5
  94 dnl libtool 1.5 should be installed.
  95 AC_PREREQ(2.59)dnl Required Autoconf version
  96
  97 AH_TOP([
  98 /* begin of portable.h.pre */
  99 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
 100  *
 101  * Copyright 1998-2011 The OpenLDAP Foundation
 102  * All rights reserved.
 103  *
 104  * Redistribution and use in source and binary forms, with or without
 105  * modification, are permitted only as authorized by the OpenLDAP
 106  * Public License.
 107  *
 108  * A copy of this license is available in the file LICENSE in the
 109  * top-level directory of the distribution or, alternatively, at
 110  * <http://www.OpenLDAP.org/license.html>.
 111  */
 112
 113 #ifndef _LDAP_PORTABLE_H
 114 #define _LDAP_PORTABLE_H
 115
 116 /* define this if needed to get reentrant functions */
 117 #ifndef REENTRANT
 118 #undef REENTRANT
 119 #endif
 120 #ifndef _REENTRANT
 121 #undef _REENTRANT
 122 #endif
 123
 124 /* define this if needed to get threadsafe functions */
 125 #ifndef THREADSAFE
 126 #undef THREADSAFE
 127 #endif
 128 #ifndef _THREADSAFE
 129 #undef _THREADSAFE
 130 #endif
 131 #ifndef THREAD_SAFE
 132 #undef THREAD_SAFE
 133 #endif
 134 #ifndef _THREAD_SAFE
 135 #undef _THREAD_SAFE
 136 #endif
 137
 138 #ifndef _SGI_MP_SOURCE
 139 #undef _SGI_MP_SOURCE
 140 #endif
 141
 142 /* end of portable.h.pre */
 143 ])
 144 AH_BOTTOM([
 145 /* begin of portable.h.post */
 146
 147 #ifdef _WIN32
 148         /* don't suck in all of the win32 api */
 149 #       define WIN32_LEAN_AND_MEAN 1
 150 #endif
 151
 152 #ifndef LDAP_NEEDS_PROTOTYPES
 153 /* force LDAP_P to always include prototypes */
 154 #define LDAP_NEEDS_PROTOTYPES 1
 155 #endif
 156
 157 #ifndef LDAP_REL_ENG
 158 #if (LDAP_VENDOR_VERSION == 000000) && !defined(LDAP_DEVEL)
 159 #define LDAP_DEVEL
 160 #endif
 161 #if defined(LDAP_DEVEL) && !defined(LDAP_TEST)
 162 #define LDAP_TEST
 163 #endif
 164 #endif
 165
 166 #ifdef HAVE_STDDEF_H
 167 #       include <stddef.h>
 168 #endif
 169
 170 #ifdef HAVE_EBCDIC
 171 /* ASCII/EBCDIC converting replacements for stdio funcs
 172  * vsnprintf and snprintf are used too, but they are already
 173  * checked by the configure script
 174  */
 175 #define fputs ber_pvt_fputs
 176 #define fgets ber_pvt_fgets
 177 #define printf ber_pvt_printf
 178 #define fprintf ber_pvt_fprintf
 179 #define vfprintf ber_pvt_vfprintf
 180 #define vsprintf ber_pvt_vsprintf
 181 #endif
 182
 183 #include "ac/fdset.h"
 184
 185 #include "ldap_cdefs.h"
 186 #include "ldap_features.h"
 187
 188 #include "ac/assert.h"
 189 #include "ac/localize.h"
 190
 191 #endif /* _LDAP_PORTABLE_H */
 192 /* end of portable.h.post */
 193 ])
 194
 195 AC_CONFIG_HEADERS([include/portable.h:include/portable.hin])
 196 AC_CONFIG_HEADERS([include/ldap_features.h:include/ldap_features.hin])
 197 AC_CONFIG_HEADERS([include/lber_types.h:include/lber_types.hin])
 198
 199 dnl ================================================================
 200 dnl Start Args
 201 AC_MSG_CHECKING(configure arguments)
 202 AC_PREFIX_DEFAULT(/usr/local)
 203
 204 top_builddir=`pwd`
 205 AC_SUBST(top_builddir)dnl
 206
 207 dnl ----------------------------------------------------------------
 208 dnl --with-subdir
 209 ldap_subdir="/openldap"
 210
 211 AC_ARG_WITH(subdir,
 212 [  --with-subdir=DIR       change default subdirectory used for installs],
 213 [case "$withval" in
 214         no) ldap_subdir=""
 215                 ;;
 216         yes)
 217                 ;;
 218         /*|\\*)
 219                 ldap_subdir="$withval"
 220                 ;;
 221         *)
 222                 ldap_subdir="/$withval"
 223                 ;;
 224 esac
 225 ])dnl
 226
 227 AC_SUBST(ldap_subdir)dnl
 228
 229 dnl ----------------------------------------------------------------
 230 dnl General "enable" options
 231 dnl set default to traditional to enable the original debug style
 232 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes, [no yes traditional])dnl
 233 OL_ARG_ENABLE(dynamic,[  --enable-dynamic         enable linking built binaries with dynamic libs], no)dnl
 234 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 235 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 236 dnl OL_ARG_ENABLE(referrals,[  --enable-referrals         enable LDAPv2+ Referrals (experimental)], no)dnl
 237 ol_enable_referrals=${ol_enable_referrals-no}
 238 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 239 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 240
 241 dnl ----------------------------------------------------------------
 242 dnl General "with" options
 243 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 244         auto, [auto yes no] )
 245 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch(3) URL support],
 246         auto, [auto yes no] )
 247 OL_ARG_WITH(threads,[  --with-threads     with threads],
 248         auto, [auto nt posix mach pth lwp yes no manual] )
 249 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support auto|openssl|gnutls|moznss],
 250         auto, [auto openssl gnutls moznss yes no] )
 251 OL_ARG_WITH(yielding_select,
 252         [  --with-yielding-select  with implicitly yielding select],
 253         auto, [auto yes no manual] )
 254 OL_ARG_WITH(mp,
 255         [  --with-mp               with multiple precision statistics auto|longlong|long|bignum|gmp],
 256         auto, [auto longlong long bignum gmp yes no])
 257 OL_ARG_WITH(odbc,
 258         [  --with-odbc             with specific ODBC support iodbc|unixodbc|odbc32|auto],
 259         auto, [auto iodbc unixodbc odbc32] )
 260
 261 dnl ----------------------------------------------------------------
 262 dnl Server options
 263 dnl ----------------------------------------------------------------
 264
 265 dnl ----------------------------------------------------------------
 266 dnl SLAPD OPTIONS
 267 AC_ARG_ENABLE(xxslapdoptions,[
 268 SLAPD (Standalone LDAP Daemon) Options:])
 269 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 270 OL_ARG_ENABLE(dynacl,[    --enable-dynacl         enable run-time loadable ACL support (experimental)], no)dnl
 271 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs (experimental)], no, [no yes mod])dnl
 272 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 273 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], no)dnl
 274 OL_ARG_ENABLE(lmpasswd,[    --enable-lmpasswd     enable LAN Manager passwords], no)dnl
 275 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 276 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 277 OL_ARG_ENABLE(rewrite,[    --enable-rewrite       enable DN rewriting in back-ldap and rwm overlay], auto)dnl
 278 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups of client hostnames], no)dnl
 279 OL_ARG_ENABLE(slapi,[    --enable-slapi        enable SLAPI support (experimental)], no)dnl
 280 OL_ARG_ENABLE(slp,[    --enable-slp          enable SLPv2 support], no)dnl
 281 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 282
 283 dnl ----------------------------------------------------------------
 284 dnl SLAPD Backend Options
 285 Backends="bdb \
 286         dnssrv \
 287         hdb \
 288         ldap \
 289         meta \
 290         monitor \
 291         ndb \
 292         null \
 293         passwd \
 294         perl \
 295         relay \
 296         shell \
 297         sock \
 298         sql"
 299
 300 AC_ARG_ENABLE(xxslapbackends,[
 301 SLAPD Backend Options:])
 302
 303 OL_ARG_ENABLE(backends,[    --enable-backends     enable all available backends],
 304         --, [no yes mod])dnl
 305 OL_ARG_ENABLE(bdb,[    --enable-bdb       enable Berkeley DB backend],
 306         yes, [no yes mod], ol_enable_backends)dnl
 307 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend],
 308         no, [no yes mod], ol_enable_backends)dnl
 309 OL_ARG_ENABLE(hdb,[    --enable-hdb       enable Hierarchical DB backend],
 310         yes, [no yes mod], ol_enable_backends)dnl
 311 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend],
 312         no, [no yes mod], ol_enable_backends)dnl
 313 OL_ARG_ENABLE(meta,[    --enable-meta     enable metadirectory backend],
 314         no, [no yes mod], ol_enable_backends)dnl
 315 OL_ARG_ENABLE(monitor,[    --enable-monitor       enable monitor backend],
 316         yes, [no yes mod], ol_enable_backends)dnl
 317 OL_ARG_ENABLE(ndb,[    --enable-ndb       enable MySQL NDB Cluster backend],
 318         no, [no yes mod], ol_enable_backends)dnl
 319 OL_ARG_ENABLE(null,[    --enable-null     enable null backend],
 320         no, [no yes mod], ol_enable_backends)dnl
 321 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend],
 322         no, [no yes mod], ol_enable_backends)dnl
 323 OL_ARG_ENABLE(perl,[    --enable-perl     enable perl backend],
 324         no, [no yes mod], ol_enable_backends)dnl
 325 OL_ARG_ENABLE(relay,[    --enable-relay           enable relay backend],
 326         yes, [no yes mod], ol_enable_backends)dnl
 327 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend],
 328         no, [no yes mod], ol_enable_backends)dnl
 329 OL_ARG_ENABLE(sock,[    --enable-sock     enable sock backend],
 330         no, [no yes mod], ol_enable_backends)dnl
 331 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend],
 332         no, [no yes mod], ol_enable_backends)dnl
 333
 334 dnl ----------------------------------------------------------------
 335 dnl SLAPD Overlay Options
 336 Overlays="accesslog \
 337         auditlog \
 338         collect \
 339         constraint \
 340         dds \
 341         deref \
 342         dyngroup \
 343         dynlist \
 344         memberof \
 345         ppolicy \
 346         proxycache \
 347         refint \
 348         retcode \
 349         rwm \
 350         seqmod \
 351         sssvlv \
 352         syncprov \
 353         translucent \
 354         unique \
 355         valsort"
 356
 357 AC_ARG_ENABLE(xxslapoverlays,[
 358 SLAPD Overlay Options:])
 359
 360 OL_ARG_ENABLE(overlays,[    --enable-overlays     enable all available overlays],
 361         --, [no yes mod])dnl
 362 OL_ARG_ENABLE(accesslog,[    --enable-accesslog   In-Directory Access Logging overlay],
 363         no, [no yes mod], ol_enable_overlays)
 364 OL_ARG_ENABLE(auditlog,[    --enable-auditlog     Audit Logging overlay],
 365         no, [no yes mod], ol_enable_overlays)
 366 OL_ARG_ENABLE(collect,[    --enable-collect       Collect overlay],
 367         no, [no yes mod], ol_enable_overlays)
 368 OL_ARG_ENABLE(constraint,[    --enable-constraint         Attribute Constraint overlay],
 369         no, [no yes mod], ol_enable_overlays)
 370 OL_ARG_ENABLE(dds,[    --enable-dds       Dynamic Directory Services overlay],
 371         no, [no yes mod], ol_enable_overlays)
 372 OL_ARG_ENABLE(deref,[    --enable-deref   Dereference overlay],
 373         no, [no yes mod], ol_enable_overlays)
 374 OL_ARG_ENABLE(dyngroup,[    --enable-dyngroup     Dynamic Group overlay],
 375         no, [no yes mod], ol_enable_overlays)
 376 OL_ARG_ENABLE(dynlist,[    --enable-dynlist       Dynamic List overlay],
 377         no, [no yes mod], ol_enable_overlays)
 378 OL_ARG_ENABLE(memberof,[    --enable-memberof     Reverse Group Membership overlay],
 379         no, [no yes mod], ol_enable_overlays)
 380 OL_ARG_ENABLE(ppolicy,[    --enable-ppolicy       Password Policy overlay],
 381         no, [no yes mod], ol_enable_overlays)
 382 OL_ARG_ENABLE(proxycache,[    --enable-proxycache         Proxy Cache overlay],
 383         no, [no yes mod], ol_enable_overlays)
 384 OL_ARG_ENABLE(refint,[    --enable-refint         Referential Integrity overlay],
 385         no, [no yes mod], ol_enable_overlays)
 386 OL_ARG_ENABLE(retcode,[    --enable-retcode       Return Code testing overlay],
 387         no, [no yes mod], ol_enable_overlays)
 388 OL_ARG_ENABLE(rwm,[    --enable-rwm               Rewrite/Remap overlay],
 389         no, [no yes mod], ol_enable_overlays)
 390 OL_ARG_ENABLE(seqmod,[    --enable-seqmod         Sequential Modify overlay],
 391         no, [no yes mod], ol_enable_overlays)
 392 OL_ARG_ENABLE(sssvlv,[    --enable-sssvlv         ServerSideSort/VLV overlay],
 393         no, [no yes mod], ol_enable_overlays)
 394 OL_ARG_ENABLE(syncprov,[    --enable-syncprov     Syncrepl Provider overlay],
 395         yes, [no yes mod], ol_enable_overlays)
 396 OL_ARG_ENABLE(translucent,[    --enable-translucent  Translucent Proxy overlay],
 397         no, [no yes mod], ol_enable_overlays)
 398 OL_ARG_ENABLE(unique,[    --enable-unique       Attribute Uniqueness overlay],
 399         no, [no yes mod], ol_enable_overlays)
 400 OL_ARG_ENABLE(valsort,[    --enable-valsort      Value Sorting overlay],
 401         no, [no yes mod], ol_enable_overlays)
 402
 403 dnl ----------------------------------------------------------------
 404 AC_ARG_ENABLE(xxliboptions,[
 405 Library Generation & Linking Options])
 406 AC_ENABLE_STATIC
 407 AC_ENABLE_SHARED
 408
 409 dnl ----------------------------------------------------------------
 410
 411 # validate options
 412 if test $ol_enable_slapd = no ; then
 413         dnl SLAPD was specificallly disabled
 414         if test $ol_enable_slapi = yes ; then
 415                 AC_MSG_WARN([slapd disabled, ignoring --enable-slapi argument])
 416         fi
 417         case "$ol_enable_backends" in yes | mod)
 418                 AC_MSG_WARN([slapd disabled, ignoring --enable-backends argument])
 419         esac
 420         for i in $Backends; do
 421                 eval "ol_tmp=\$ol_enable_$i"
 422                 if test $ol_tmp != no ; then
 423                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 424                         eval "ol_enable_$i=no"
 425                 fi
 426         done
 427         if test $ol_enable_modules = yes ; then
 428                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 429         fi
 430         if test $ol_enable_wrappers = yes ; then
 431                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 432         fi
 433         if test $ol_enable_rlookups = yes ; then
 434                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 435         fi
 436         if test $ol_enable_dynacl = yes ; then
 437                 AC_MSG_WARN([slapd disabled, ignoring --enable-dynacl argument])
 438         fi
 439         if test $ol_enable_aci != no ; then
 440                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 441         fi
 442         if test $ol_enable_rewrite = yes ; then
 443                 AC_MSG_WARN([slapd disabled, ignoring --enable-rewrite argument])
 444         fi
 445         dnl overlays
 446         case "$ol_enable_overlays" in yes | mod)
 447                 AC_MSG_WARN([slapd disabled, ignoring --enable-overlays argument])
 448         esac
 449         for i in $Overlays; do
 450                 eval "ol_tmp=\$ol_enable_$i"
 451                 if test $ol_tmp != no ; then
 452                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 453                         eval "ol_enable_$i=no"
 454                 fi
 455         done
 456
 457         # force settings to no
 458         ol_enable_slapi=no
 459
 460         ol_enable_backends=
 461         ol_enable_overlays=
 462         ol_enable_modules=no
 463         ol_enable_rlookups=no
 464         ol_enable_dynacl=no
 465         ol_enable_aci=no
 466         ol_enable_wrappers=no
 467
 468         ol_enable_rewrite=no
 469
 470 elif test $ol_enable_modules != yes &&
 471         test $ol_enable_bdb = no &&
 472         test $ol_enable_dnssrv = no &&
 473         test $ol_enable_hdb = no &&
 474         test $ol_enable_ldap = no &&
 475         test $ol_enable_meta = no &&
 476         test $ol_enable_monitor = no &&
 477         test $ol_enable_ndb = no &&
 478         test $ol_enable_null = no &&
 479         test $ol_enable_passwd = no &&
 480         test $ol_enable_perl = no &&
 481         test $ol_enable_relay = no &&
 482         test $ol_enable_shell = no &&
 483         test $ol_enable_sock = no &&
 484         test $ol_enable_sql = no ; then
 485         dnl no slapd backend
 486
 487         if test $ol_enable_slapd = yes ; then
 488                 AC_MSG_ERROR([slapd requires a backend])
 489         else
 490                 AC_MSG_WARN([skipping slapd, no backend specified])
 491                 ol_enable_slapd=no
 492         fi
 493 fi
 494
 495 if test $ol_enable_meta/$ol_enable_ldap = yes/no ; then
 496         AC_MSG_ERROR([--enable-meta requires --enable-ldap])
 497 fi
 498
 499 if test $ol_enable_lmpasswd = yes ; then
 500         if test $ol_with_tls = no ; then
 501                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
 502         fi
 503 fi
 504
 505 if test $ol_enable_spasswd = yes ; then
 506         if test $ol_with_cyrus_sasl = no ; then
 507                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 508         fi
 509         ol_with_cyrus_sasl=yes
 510 fi
 511
 512 AC_MSG_RESULT(done)
 513
 514 dnl ----------------------------------------------------------------
 515 dnl Initialize vars
 516 LDAP_LIBS=
 517 BDB_LIBS=
 518 SLAPD_NDB_LIBS=
 519 SLAPD_NDB_INCS=
 520 LTHREAD_LIBS=
 521 LUTIL_LIBS=
 522
 523 SLAPD_LIBS=
 524
 525 BUILD_SLAPD=no
 526
 527 BUILD_THREAD=no
 528
 529 BUILD_SLAPI=no
 530 SLAPD_SLAPI_DEPEND=
 531
 532 BUILD_BDB=no
 533 BUILD_DNSSRV=no
 534 BUILD_HDB=no
 535 BUILD_LDAP=no
 536 BUILD_META=no
 537 BUILD_MONITOR=no
 538 BUILD_NDB=no
 539 BUILD_NULL=no
 540 BUILD_PASSWD=no
 541 BUILD_PERL=no
 542 BUILD_RELAY=no
 543 BUILD_SHELL=no
 544 BUILD_SOCK=no
 545 BUILD_SQL=no
 546
 547 BUILD_ACCESSLOG=no
 548 BUILD_AUDITLOG=no
 549 BUILD_CONSTRAINT=no
 550 BUILD_DDS=no
 551 BUILD_DENYOP=no
 552 BUILD_DEREF=no
 553 BUILD_DYNGROUP=no
 554 BUILD_DYNLIST=no
 555 BUILD_LASTMOD=no
 556 BUILD_MEMBEROF=no
 557 BUILD_PPOLICY=no
 558 BUILD_PROXYCACHE=no
 559 BUILD_REFINT=no
 560 BUILD_RETCODE=no
 561 BUILD_RWM=no
 562 BUILD_SEQMOD=no
 563 BUILD_SSSVLV=no
 564 BUILD_SYNCPROV=no
 565 BUILD_TRANSLUCENT=no
 566 BUILD_UNIQUE=no
 567 BUILD_VALSORT=no
 568
 569 SLAPD_STATIC_OVERLAYS=
 570 SLAPD_DYNAMIC_OVERLAYS=
 571
 572 SLAPD_MODULES_LDFLAGS=
 573 SLAPD_MODULES_CPPFLAGS=
 574
 575 SLAPD_STATIC_BACKENDS=back-ldif
 576 SLAPD_DYNAMIC_BACKENDS=
 577
 578 SLAPD_PERL_LDFLAGS=
 579 MOD_PERL_LDFLAGS=
 580 PERL_CPPFLAGS=
 581
 582 SLAPD_SQL_LDFLAGS=
 583 SLAPD_SQL_LIBS=
 584 SLAPD_SQL_INCLUDES=
 585
 586 KRB4_LIBS=
 587 KRB5_LIBS=
 588 SASL_LIBS=
 589 TLS_LIBS=
 590 MODULES_LIBS=
 591 SLAPI_LIBS=
 592 LIBSLAPI=
 593 LIBSLAPITOOLS=
 594 AUTH_LIBS=
 595 ICU_LIBS=
 596
 597 SLAPD_SLP_LIBS=
 598 SLAPD_GMP_LIBS=
 599
 600 dnl ================================================================
 601 dnl Checks for programs
 602
 603 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 604
 605 dnl ----------------------------------------------------------------
 606 dnl
 607 dnl Determine which C translator to use
 608 dnl
 609
 610 dnl AIX Thread requires we use cc_r or xlc_r.
 611 dnl But only do this IF AIX and CC is not set
 612 dnl and threads are auto|yes|posix.
 613 dnl
 614 dnl If we find cc_r|xlc_r, force pthreads and assume
 615 dnl             pthread_create is in $LIBS (ie: don't bring in
 616 dnl             any additional thread libraries)
 617 dnl If we do not find cc_r|xlc_r, disable threads
 618
 619 ol_aix_threads=no
 620 case "$target" in
 621 *-*-aix*) dnl all AIX is not a good idea.
 622         if test -z "$CC" ; then
 623                 case "$ol_with_threads" in
 624                 auto | yes |  posix) ol_aix_threads=yes ;;
 625                 esac
 626         fi
 627 ;;
 628 esac
 629
 630 if test $ol_aix_threads = yes ; then
 631         if test -z "${CC}" ; then
 632                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 633
 634                 if test "$CC" = cc ; then
 635                         dnl no CC! don't allow --with-threads
 636                         if test $ol_with_threads != auto ; then
 637                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 638                         else
 639                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 640                         fi
 641                         ol_with_threads=no
 642                 fi
 643         fi
 644
 645         case ${CC} in cc_r | xlc_r)
 646                 ol_with_threads=posix
 647                 ol_cv_pthread_create=yes
 648                 ;;
 649         esac
 650 fi
 651
 652 if test -z "${CC}"; then
 653         AC_CHECK_PROGS(CC,cc gcc,missing)
 654
 655         if test "${CC}" = "missing" ; then
 656                 AC_MSG_ERROR([Unable to locate cc(1) or suitable replacement.  Check PATH or set CC.])
 657         fi
 658 fi
 659
 660 if test -z "${AR}"; then
 661         AC_CHECK_PROGS(AR,ar gar,missing)
 662
 663         if test "${AR}" = "missing" ; then
 664                 AC_MSG_ERROR([Unable to locate ar(1) or suitable replacement.  Check PATH or set AR.])
 665         fi
 666 fi
 667
 668 AC_LIBTOOL_WIN32_DLL
 669 AC_LIBTOOL_DLOPEN
 670 AC_PROG_LIBTOOL
 671
 672 dnl ----------------------------------------------------------------
 673 dnl Perl
 674 ol_link_perl=no
 675 if test $ol_enable_perl != no ; then
 676         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 677
 678         if test "no$PERLBIN" = "no" ; then
 679                 if test $ol_enable_perl = yes ; then
 680                         AC_MSG_ERROR([could not locate perl])
 681                 fi
 682
 683         else
 684                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 685                 PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e 's/ -lc / /' -e 's/ -lc$//'`"
 686
 687                 if test x"$ol_enable_perl" = "xyes" ; then
 688                         SLAPD_PERL_LDFLAGS="$PERL_LDFLAGS"
 689                 else
 690                         MOD_PERL_LDFLAGS="$PERL_LDFLAGS"
 691                 fi
 692                 dnl should check perl version
 693                 ol_link_perl=yes
 694         fi
 695 fi
 696
 697 AC_PROG_CPP
 698 OL_MSVC
 699
 700 dnl ----------------------------------------------------------------
 701 dnl Checks for Windows NT
 702 case $host_os in
 703   *mingw32* ) ac_cv_mingw32=yes ;;
 704   *cygwin* ) ac_cv_cygwin=yes ;;
 705   *interix* ) ac_cv_interix=yes ;;
 706 esac
 707
 708 dnl ----------------------------------------------------------------
 709 dnl Checks for file extensions
 710 AC_EXEEXT
 711 AC_OBJEXT
 712 AC_DEFINE_UNQUOTED(EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 713
 714 dnl ----------------------------------------------------------------
 715 dnl BeOS requires -lbe -lroot -lnet
 716 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 717
 718 dnl ----------------------------------------------------------------
 719 dnl OpenLDAP requires STDC features
 720 AC_PROG_CC
 721 if test "X${ac_cv_prog_cc_stdc}" = "Xno" ; then
 722         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 723 fi
 724
 725 dnl ----------------------------------------------------------------
 726 dnl Check cc depend flags
 727 OL_MKDEPEND
 728 if test "${ol_cv_mkdep}" = no ; then
 729         # this will soon become an error
 730         AC_MSG_WARN([do not know how to generate dependencies])
 731 fi
 732
 733 dnl ----------------------------------------------------------------
 734 dnl Check for AIX security library
 735 AC_CHECK_LIB(s, afopen, [
 736         AUTH_LIBS=-ls
 737         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 738 ])
 739
 740 dnl ----------------------------------------------------------------
 741 dnl Check for IBM OS/390
 742 case "$target" in
 743 *-ibm-openedition)
 744         ac_cv_func_getopt=no
 745         AC_DEFINE(BOTH_STRINGS_H,1,[define to use both <string.h> and <strings.h>])
 746         ;;
 747 esac
 748
 749 dnl ----------------------------------------------------------------
 750 dnl Check for module support
 751 ol_link_modules=no
 752 WITH_MODULES_ENABLED=no
 753 if test $ol_enable_modules != no ; then
 754         AC_CHECK_HEADERS(ltdl.h)
 755
 756         if test $ac_cv_header_ltdl_h = no ; then
 757                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 758         fi
 759
 760         AC_CHECK_LIB(ltdl, lt_dlinit, [
 761                 MODULES_LIBS=-lltdl
 762                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 763         ])
 764
 765         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 766                 AC_MSG_ERROR([could not locate libtool -lltdl])
 767         fi
 768         ol_link_modules=yes
 769         WITH_MODULES_ENABLED=yes
 770
 771 else
 772         for i in $Backends; do
 773                 eval "ol_tmp=\$ol_enable_$i"
 774                 if test $ol_tmp = mod ; then
 775                         AC_MSG_WARN([building static $i backend])
 776                         eval "ol_enable_$i=yes"
 777                 fi
 778         done
 779         for i in $Overlays; do
 780                 eval "ol_tmp=\$ol_enable_$i"
 781                 if test $ol_tmp = mod ; then
 782                         AC_MSG_WARN([building static $i overlay])
 783                         eval "ol_enable_$i=yes"
 784                 fi
 785         done
 786 fi
 787
 788 dnl ----------------------------------------------------------------
 789 dnl Checks for header files.
 790 OL_HEADER_STDC
 791
 792 if test $ol_cv_header_stdc != yes; then
 793         AC_MSG_WARN([could not locate Standard C compliant headers])
 794 fi
 795
 796 AC_HEADER_DIRENT
 797 AC_HEADER_SYS_WAIT
 798 AC_HEADER_TIOCGWINSZ
 799
 800 AC_CHECK_HEADERS(       \
 801         arpa/inet.h             \
 802         arpa/nameser.h  \
 803         assert.h                \
 804         bits/types.h    \
 805         conio.h                 \
 806         crypt.h                 \
 807         direct.h                \
 808         errno.h                 \
 809         fcntl.h                 \
 810         filio.h                 \
 811         getopt.h                \
 812         grp.h                   \
 813         io.h                    \
 814         libutil.h               \
 815         limits.h                \
 816         locale.h                \
 817         malloc.h                \
 818         memory.h                \
 819         psap.h                  \
 820         pwd.h                   \
 821         process.h               \
 822         sgtty.h                 \
 823         shadow.h                \
 824         stddef.h                \
 825         string.h                \
 826         strings.h               \
 827         sysexits.h              \
 828         sys/file.h              \
 829         sys/filio.h             \
 830         sys/fstyp.h             \
 831         sys/errno.h             \
 832         sys/ioctl.h             \
 833         sys/param.h             \
 834         sys/privgrp.h   \
 835         sys/resource.h  \
 836         sys/select.h    \
 837         sys/socket.h    \
 838         sys/stat.h              \
 839         sys/syslog.h    \
 840         sys/time.h              \
 841         sys/types.h             \
 842         sys/uio.h               \
 843         sys/vmount.h    \
 844         syslog.h                \
 845         termios.h               \
 846         unistd.h                \
 847         utime.h                 \
 848 )
 849
 850 dnl Only check Winsock on MinGW
 851 if test "$ac_cv_mingw32" = yes \
 852         -o "$ac_cv_interix" = yes \
 853         -o "$ol_cv_msvc" = yes
 854 then
 855         AC_CHECK_HEADERS( winsock.h winsock2.h )
 856 fi
 857
 858 AC_CHECK_HEADERS( resolv.h, [], [],
 859 [$ac_includes_default
 860 #include <netinet/in.h>
 861 ])
 862
 863 AC_CHECK_HEADERS( netinet/tcp.h, [], [],
 864 [$ac_includes_default
 865 #include <netinet/in.h>
 866 ])
 867
 868 AC_CHECK_HEADERS( sys/ucred.h, [], [],
 869 [$ac_includes_default
 870 #ifdef HAVE_SYS_PARAM_H
 871 #include <sys/param.h>
 872 #endif
 873 ])
 874
 875 dnl ----------------------------------------------------------------
 876 dnl Checks for libraries
 877
 878 AC_CHECK_FUNCS( sigaction sigset )
 879
 880 dnl HP-UX requires -lV3
 881 dnl this is not needed on newer versions of HP-UX
 882 if test $ac_cv_func_sigaction = no && test $ac_cv_func_sigaction = no ; then
 883         AC_CHECK_LIB(V3, sigset)
 884 fi
 885
 886 if test $ol_cv_msvc = yes ; then
 887    ol_cv_winsock=yes
 888 fi
 889
 890 dnl The following is INTENTIONALLY scripted out because shell does not
 891 dnl support variable names with the '@' character, which is what
 892 dnl autoconf would try to generate if one merely used AC_SEARCH_LIBS
 893 if test "$ac_cv_header_winsock_h" = yes; then
 894         AC_CACHE_CHECK([for winsock], [ol_cv_winsock],[
 895         save_LIBS="$LIBS"
 896         for curlib in none ws2_32 wsock32; do
 897                 if test $curlib != none ; then
 898                 LIBS="$save_LIBS -l$curlib"
 899                 fi
 900                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <winsock.h>
 901                         ]], [[
 902                         socket(0,0,0);
 903                         select(0,NULL,NULL,NULL,NULL);
 904                         closesocket(0);
 905                         gethostname(NULL,0);
 906                         ]])],[ol_cv_winsock=$curlib],[ol_cv_winsock=no])
 907
 908                 test "$ol_cv_winsock" != no && break
 909         done
 910         LIBS="$save_LIBS"
 911         ])
 912
 913         if test $ol_cv_winsock != no ; then
 914         AC_DEFINE(HAVE_WINSOCK, 1, [define if you have winsock])
 915         ac_cv_func_socket=yes
 916         ac_cv_func_select=yes
 917         ac_cv_func_closesocket=yes
 918         ac_cv_func_gethostname=yes
 919
 920                 if test $ol_cv_winsock != none -a $ol_cv_winsock != yes ; then
 921                 LIBS="$LIBS -l$ol_cv_winsock"
 922                 fi
 923
 924         if test $ol_cv_winsock = ws2_32 -o $ol_cv_winsock = yes ; then
 925                         AC_DEFINE(HAVE_WINSOCK2, 1, [define if you have winsock2])
 926         fi
 927         fi
 928 fi
 929
 930 dnl Find socket()
 931 dnl Likely combinations:
 932 dnl             -lsocket [ -lnsl_s | -lnsl ]
 933 dnl             -linet
 934
 935 AC_CHECK_FUNC(socket, :, [
 936 dnl hopefully we won't include too many libraries
 937         AC_CHECK_LIB(socket, main)
 938         AC_CHECK_LIB(net, main)
 939         AC_CHECK_LIB(nsl_s, main)
 940         AC_CHECK_LIB(nsl, main)
 941         AC_CHECK_LIB(inet, socket)
 942         AC_CHECK_LIB(gen, main)
 943 ])
 944
 945 dnl require select
 946 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 947
 948 if test "${ac_cv_header_winsock_h}" != yes; then
 949         dnl Select arg types
 950         dnl (if this detection becomes permenent, it and the select() detection
 951         dnl should be done before the yielding select test)
 952         AC_FUNC_SELECT_ARGTYPES
 953 fi
 954
 955 dnl check to see if system call automatically restart
 956 dnl AC_SYS_RESTARTABLE_SYSCALLS
 957
 958 dnl ----------------------------------------------------------------
 959 AC_CHECK_FUNCS( poll )
 960 if test $ac_cv_func_poll = yes; then
 961 AC_CHECK_HEADERS( poll.h sys/poll.h )
 962 fi
 963
 964 dnl ----------------------------------------------------------------
 965 AC_CHECK_HEADERS( sys/epoll.h )
 966 if test "${ac_cv_header_sys_epoll_h}" = yes; then
 967         AC_MSG_CHECKING(for epoll system call)
 968         AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv)
 969 {
 970         int epfd = epoll_create(256);
 971         exit (epfd == -1 ? 1 : 0);
 972 }]])],[AC_MSG_RESULT(yes)
 973         AC_DEFINE(HAVE_EPOLL,1, [define if your system supports epoll])],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 974 fi
 975
 976 dnl ----------------------------------------------------------------
 977 AC_CHECK_HEADERS( sys/devpoll.h )
 978 dnl "/dev/poll" needs <sys/poll.h> as well...
 979 if test "${ac_cv_header_sys_devpoll_h}" = yes \
 980                 -a "${ac_cv_header_poll_h}" = yes ; \
 981 then
 982         AC_MSG_CHECKING(for /dev/poll)
 983         AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv)
 984 {
 985         int devpollfd = open("/dev/poll", /* O_RDWR */ 2);
 986         exit (devpollfd == -1 ? 1 : 0);
 987 }]])],[AC_MSG_RESULT(yes)
 988         AC_DEFINE(HAVE_DEVPOLL,1, [define if your system supports /dev/poll])],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 989 fi
 990
 991 dnl ----------------------------------------------------------------
 992 OL_STRERROR
 993
 994 dnl ----------------------------------------------------------------
 995 dnl require POSIX regex
 996 AC_CHECK_HEADERS( regex.h, [], [],
 997 [$ac_includes_default
 998 #ifdef HAVE_SYS_TYPES_H
 999 #include <sys/types.h>
1000 #endif
1001 ])
1002
1003 if test "$ac_cv_header_regex_h" != yes ; then
1004         AC_MSG_ERROR([POSIX regex.h required.])
1005 fi
1006 AC_SEARCH_LIBS(regfree, [regex gnuregex],
1007         :, AC_MSG_ERROR([POSIX regex required.]))
1008
1009 OL_POSIX_REGEX
1010 if test "$ol_cv_c_posix_regex" = no ; then
1011         AC_MSG_ERROR([broken POSIX regex!])
1012 fi
1013
1014 dnl ----------------------------------------------------------------
1015 dnl UUID Support
1016
1017 have_uuid=no
1018 AC_CHECK_HEADERS(sys/uuid.h)
1019 dnl The HAVE_UUID_TO_STR code path also needs uuid_create
1020 if test $ac_cv_header_sys_uuid_h = yes ; then
1021         save_LIBS="$LIBS"
1022         AC_SEARCH_LIBS([uuid_to_str], [uuid], [have_uuid=yes], :)
1023         AC_SEARCH_LIBS([uuid_create], [uuid], :, [have_uuid=no])
1024         LIBS="$save_LIBS"
1025
1026         if test $have_uuid = yes ; then
1027                 AC_DEFINE(HAVE_UUID_TO_STR,1,
1028                         [define if you have uuid_to_str()])
1029
1030                 test "$ac_cv_search_uuid_to_str" = "none required" || \
1031                         SLAPD_LIBS="$SLAPD_LIBS $ac_cv_search_uuid_to_str"
1032         fi
1033 fi
1034
1035 dnl Look for uuid_generate
1036 dnl The HAVE_UUID_GENERATE code path also needs uuid_unparse_lower
1037 if test $have_uuid = no ; then
1038         AC_CHECK_HEADERS(uuid/uuid.h)
1039         if test $ac_cv_header_uuid_uuid_h = yes ; then
1040                 save_LIBS="$LIBS"
1041                 AC_SEARCH_LIBS([uuid_generate], [uuid], [have_uuid=yes], :)
1042                 AC_SEARCH_LIBS([uuid_unparse_lower], [uuid], :, [have_uuid=no])
1043                 LIBS="$save_LIBS"
1044
1045                 if test $have_uuid = yes ; then
1046                         AC_DEFINE(HAVE_UUID_GENERATE,1,
1047                                 [define if you have uuid_generate()])
1048
1049                         test "$ac_cv_search_uuid_generate" = "none required" || \
1050                                 SLAPD_LIBS="$SLAPD_LIBS $ac_cv_search_uuid_generate"
1051                 fi
1052         fi
1053 fi
1054
1055 dnl For windows, check for the need of RPCRT for UUID function support
1056 if test $have_uuid = no ; then
1057         AC_MSG_CHECKING(to see if -lrpcrt4 is needed for win32 UUID support)
1058         save_LIBS="$LIBS"
1059         LIBS="$LIBS -lrpcrt4"
1060         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1061                 int __stdcall UuidCreate(void *);
1062                 int __stdcall UuidToStringA(void *,void **);
1063                 ]], [[
1064                 UuidCreate(0);
1065                 UuidToStringA(0,0);
1066                 ]])],[need_rpcrt=yes],[need_rpcrt=no])
1067         if test $need_rpcrt = yes; then
1068                 SLAPD_LIBS="$SLAPD_LIBS -lrpcrt4"
1069         fi
1070         LIBS="$save_LIBS"
1071         AC_MSG_RESULT($need_rpcrt)
1072 fi
1073
1074 dnl ----------------------------------------------------------------
1075 dnl Check for resolver routines
1076 OL_RESOLVER_LINK
1077
1078 ol_link_dnssrv=no
1079 if test "$ol_cv_lib_resolver" != no ; then
1080         AC_DEFINE(HAVE_RES_QUERY,1,
1081                 [define if you have res_query()])
1082
1083         if test "$ol_enable_dnssrv" != no ; then
1084                 ol_link_dnssrv=yes
1085         fi
1086
1087         if test "$ol_cv_lib_resolver" != yes ; then
1088                 LIBS="$ol_cv_lib_resolver $LIBS"
1089         fi
1090 fi
1091
1092 if test "$ol_enable_dnssrv" = yes || test "$ol_enable_dnssrv" = mod ; then
1093         if test "$ol_link_dnssrv" = no ; then
1094                 AC_MSG_ERROR([DNSSRV requires res_query()])
1095         fi
1096 else
1097         ol_enable_dnssrv=no
1098 fi
1099
1100 AC_CHECK_FUNCS( hstrerror )
1101
1102 dnl ----------------------------------------------------------------
1103 dnl PF_INET6 support requires getaddrinfo and INET6_ADDRSTRLEN
1104 dnl PF_LOCAL may use getaddrinfo in available
1105 AC_CHECK_FUNCS( getaddrinfo getnameinfo gai_strerror inet_ntop )
1106
1107 ol_link_ipv6=no
1108 if test $ac_cv_func_getaddrinfo = no || test $ac_cv_func_inet_ntop = no ; then
1109         if test $ol_enable_ipv6 = yes ; then
1110                 AC_MSG_ERROR([IPv6 support requires getaddrinfo() and inet_ntop()])
1111         fi
1112 elif test $ol_enable_ipv6 != no ; then
1113         AC_CACHE_CHECK([INET6_ADDRSTRLEN],[ol_cv_inet6_addrstrlen],[
1114                 AC_EGREP_CPP(__has_inet6_addrstrlen__,[
1115 #                       include <netinet/in.h>
1116 #                       ifdef INET6_ADDRSTRLEN
1117                                 __has_inet6_addrstrlen__;
1118 #                       endif
1119                 ], [ol_cv_inet6_addrstrlen=yes], [ol_cv_inet6_addrstrlen=no])])
1120
1121
1122         AC_CACHE_CHECK([struct sockaddr_storage],ol_cv_struct_sockaddr_storage,[
1123                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1124 #include <sys/types.h>
1125 #include <sys/socket.h>
1126 ]], [[
1127                         struct sockaddr_storage ss;
1128 ]])],[ol_cv_struct_sockaddr_storage=yes],[ol_cv_struct_sockaddr_storage=no])])
1129
1130         if test $ol_cv_inet6_addrstrlen = yes &&
1131            test $ol_cv_struct_sockaddr_storage = yes ; then
1132                 ol_link_ipv6=yes
1133         elif test $ol_enable_ipv6 = yes &&
1134              test $ol_cv_inet6_addrstrlen = no ; then
1135                 AC_MSG_ERROR([IPv6 support requires INET6_ADDRSTRLEN])
1136         elif test $ol_enable_ipv6 = yes &&
1137              test $ol_cv_struct_sockaddr_storage = no ; then
1138                 AC_MSG_ERROR([IPv6 support requires struct sockaddr_storage])
1139         fi
1140 fi
1141
1142 if test $ol_enable_local != no ; then
1143         AC_CHECK_HEADERS( sys/un.h )
1144
1145         if test $ol_enable_local = auto ; then
1146                 ol_enable_local=$ac_cv_header_sys_un_h
1147         elif test $ac_cv_header_sys_un_h = no ; then
1148                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
1149         fi
1150 fi
1151
1152 dnl ----------------------------------------------------------------
1153 dnl TLS/SSL
1154
1155 if test $ol_with_tls = yes ; then
1156         ol_with_tls=auto
1157 fi
1158
1159 ol_link_tls=no
1160 if test $ol_with_tls = openssl || test $ol_with_tls = auto ; then
1161         AC_CHECK_HEADERS(openssl/ssl.h)
1162
1163         if test $ac_cv_header_openssl_ssl_h = yes ; then
1164                 AC_CHECK_LIB(ssl, SSL_library_init,
1165                         [have_openssl=yes
1166                         need_rsaref=no], [have_openssl=no],
1167                         [-lcrypto])
1168
1169                 if test $have_openssl = no ; then
1170                         AC_CHECK_LIB(ssl, ssl3_accept,
1171                                 [have_openssl=yes
1172                                 need_rsaref=yes], [have_openssl=no],
1173                                 [-lcrypto -lRSAglue -lrsaref])
1174                 fi
1175
1176                 if test $have_openssl = yes ; then
1177                         ol_with_tls=openssl
1178                         ol_link_tls=yes
1179
1180                         AC_DEFINE(HAVE_OPENSSL, 1,
1181                                 [define if you have OpenSSL])
1182
1183                         if test $need_rsaref = yes; then
1184                                 AC_DEFINE(HAVE_RSAREF, 1,
1185                                         [define if OpenSSL needs RSAref])
1186
1187                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1188                         else
1189                                 TLS_LIBS="-lssl -lcrypto"
1190                         fi
1191
1192                         OL_SSL_COMPAT
1193                         if test $ol_cv_ssl_crl_compat = yes ; then
1194                                 AC_DEFINE(HAVE_OPENSSL_CRL, 1,
1195                                         [define if you have OpenSSL with CRL checking capability])
1196                         fi
1197                 fi
1198         fi
1199 fi
1200
1201 if test $ol_link_tls = no ; then
1202         if test $ol_with_tls = gnutls || test $ol_with_tls = auto ; then
1203                 AC_CHECK_HEADERS(gnutls/gnutls.h)
1204
1205                 if test $ac_cv_header_gnutls_gnutls_h = yes ; then
1206                         AC_CHECK_LIB(gnutls, gnutls_init,
1207                                 [have_gnutls=yes], [have_gnutls=no])
1208
1209                         if test $have_gnutls = yes ; then
1210                                 ol_with_tls=gnutls
1211                                 ol_link_tls=yes
1212
1213                                 TLS_LIBS="-lgnutls"
1214
1215                                 AC_DEFINE(HAVE_GNUTLS, 1,
1216                                         [define if you have GNUtls])
1217                         fi
1218                 fi
1219         fi
1220 fi
1221
1222 dnl NOTE: caller must specify -I/path/to/nspr4 and -I/path/to/nss3
1223 dnl and -L/path/to/nspr4 libs and -L/path/to/nss3 libs if those libs
1224 dnl are not in the default system location
1225 if test $ol_link_tls = no ; then
1226         if test $ol_with_tls = moznss || test $ol_with_tls = auto ; then
1227                 have_moznss=no
1228                 AC_CHECK_HEADERS([nssutil.h])
1229                 if test "$ac_cv_header_nssutil_h" = yes ; then
1230                         AC_CHECK_LIB([nss3], [NSS_Initialize],
1231                                                  [ have_moznss=yes ], [ have_moznss=no ])
1232                 fi
1233
1234                 if test "$have_moznss" = yes ; then
1235                         ol_with_tls=moznss
1236                         ol_link_tls=yes
1237                         AC_DEFINE(HAVE_MOZNSS, 1,
1238                                           [define if you have MozNSS])
1239                         TLS_LIBS="-lssl3 -lsmime3 -lnss3 -lnssutil3 -lplds4 -lplc4 -lnspr4"
1240                 else
1241                         AC_MSG_ERROR([MozNSS not found - please specify the location to the NSPR and NSS header files in CPPFLAGS and the location to the NSPR and NSS libraries in LDFLAGS (if not in the system location)])
1242                 fi
1243         fi
1244 fi
1245
1246 WITH_TLS=no
1247 if test $ol_link_tls = yes ; then
1248         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1249         WITH_TLS=yes
1250 elif test $ol_with_tls = auto ; then
1251         AC_MSG_WARN([Could not locate TLS/SSL package])
1252         AC_MSG_WARN([TLS data protection not supported!])
1253 elif test $ol_with_tls != no ; then
1254         AC_MSG_ERROR([Could not locate TLS/SSL package])
1255 else
1256         AC_MSG_WARN([TLS data protection not supported!])
1257 fi
1258
1259 dnl ----------------------------------------------------------------
1260 dnl LAN Manger password checking requires DES from OpenSSL
1261 if test $ol_enable_lmpasswd != no; then
1262         if test $ol_link_tls != yes ; then
1263                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
1264         fi
1265
1266         AC_DEFINE(SLAPD_LMHASH, 1, [define to support LAN Manager passwords])
1267 fi
1268
1269 dnl ----------------------------------------------------------------
1270 dnl Threads?
1271 ol_link_threads=no
1272
1273 case $ol_with_threads in auto | yes | nt)
1274
1275         OL_NT_THREADS
1276
1277         if test "$ol_cv_nt_threads" = yes ; then
1278                 ol_link_threads=nt
1279                 ol_with_threads=found
1280                 ol_with_yielding_select=yes
1281
1282                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1283                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1284         fi
1285
1286         if test $ol_with_threads = nt ; then
1287                 AC_MSG_ERROR([could not locate NT Threads])
1288         fi
1289         ;;
1290 esac
1291
1292 case $ol_with_threads in auto | yes | posix)
1293
1294         AC_CHECK_HEADERS(pthread.h)
1295
1296         if test $ac_cv_header_pthread_h = yes ; then
1297                 OL_POSIX_THREAD_VERSION
1298
1299                 if test $ol_cv_pthread_version != 0 ; then
1300                         AC_DEFINE_UNQUOTED(HAVE_PTHREADS,$ol_cv_pthread_version,
1301                                 [define to pthreads API spec revision])
1302                 else
1303                         AC_MSG_ERROR([unknown pthread version])
1304                 fi
1305
1306                 # consider threads found
1307                 ol_with_threads=found
1308
1309                 OL_HEADER_LINUX_THREADS
1310                 OL_HEADER_GNU_PTH_PTHREAD_H
1311
1312                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1313                         AC_CHECK_HEADERS(sched.h)
1314                 fi
1315
1316                 dnl Now the hard part, how to link?
1317                 dnl
1318                 dnl currently supported checks:
1319                 dnl
1320                 dnl Check for no flags
1321                 dnl     pthread_create() in $LIBS
1322                 dnl
1323                 dnl Check special pthread (final) flags
1324                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1325                 dnl     pthread_create() with -kthread (FreeBSD)
1326                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1327                 dnl     pthread_create() with -pthreads (?)
1328                 dnl     pthread_create() with -mthreads (AIX)
1329                 dnl     pthread_create() with -thread (?)
1330                 dnl
1331                 dnl Check pthread (final) libraries
1332                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1333                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1334                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1335                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1336                 dnl     pthread_create() in -lpthread (many)
1337                 dnl     pthread_create() in -lc_r (FreeBSD)
1338                 dnl
1339                 dnl Check pthread (draft4) flags (depreciated)
1340                 dnl     pthread_create() with -threads (OSF/1)
1341                 dnl
1342                 dnl Check pthread (draft4) libraries (depreciated)
1343                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1344                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1345                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1346                 dnl     pthread_create() in -lpthreads (many)
1347                 dnl
1348
1349                 dnl pthread_create in $LIBS
1350                 AC_CACHE_CHECK([for pthread_create in default libraries],
1351                         ol_cv_pthread_create,[
1352                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1353                                 [ol_cv_pthread_create=yes],
1354                                 [ol_cv_pthread_create=no],
1355                                 [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1356                                         [ol_cv_pthread_create=yes],
1357                                         [ol_cv_pthread_create=no])])])
1358
1359                 if test $ol_cv_pthread_create != no ; then
1360                         ol_link_threads=posix
1361                         ol_link_pthreads=""
1362                 fi
1363
1364 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1365                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1366                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1367                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1368                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1369                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1370
1371                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1372                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1373                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1374                         [ol_cv_pthread_lpthread_lmach_lexc])
1375 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1376 dnl                     [ol_cv_pthread_lpthread_lexc])
1377
1378                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1379                         [ol_cv_pthread_lib_lpthread_woff])
1380
1381                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1382                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1383
1384                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1385
1386                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1387                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1388                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1389                         [ol_cv_pthread_lpthreads_lmach_lexc])
1390                 OL_PTHREAD_TRY([-lpthreads -lexc],
1391                         [ol_cv_pthread_lpthreads_lexc])
1392
1393                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1394
1395                 if test $ol_link_threads != no ; then
1396                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1397
1398                         dnl save flags
1399                         save_CPPFLAGS="$CPPFLAGS"
1400                         save_LIBS="$LIBS"
1401                         LIBS="$LTHREAD_LIBS $LIBS"
1402
1403                         dnl All POSIX Thread (final) implementations should have
1404                         dnl sched_yield instead of pthread yield.
1405                         dnl check for both, and thr_yield for Solaris
1406                         AC_CHECK_FUNCS(sched_yield pthread_yield thr_yield)
1407
1408                         if test $ac_cv_func_sched_yield = no &&
1409                            test $ac_cv_func_pthread_yield = no &&
1410                            test $ac_cv_func_thr_yield = no ; then
1411                                 dnl Digital UNIX has sched_yield() in -lrt
1412                                 AC_CHECK_LIB(rt, sched_yield,
1413                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1414                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1415                                                 [Define if you have the sched_yield function.])
1416                                         ac_cv_func_sched_yield=yes],
1417                                         [ac_cv_func_sched_yield=no])
1418                         fi
1419                         if test $ac_cv_func_sched_yield = no &&
1420                            test $ac_cv_func_pthread_yield = no &&
1421                            test "$ac_cv_func_thr_yield" = no ; then
1422                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1423                         fi
1424
1425                         dnl Check functions for compatibility
1426                         AC_CHECK_FUNCS(pthread_kill)
1427
1428                         dnl Check for pthread_rwlock_destroy with <pthread.h>
1429                         dnl as pthread_rwlock_t may not be defined.
1430                         AC_CACHE_CHECK([for pthread_rwlock_destroy with <pthread.h>],
1431                                 [ol_cv_func_pthread_rwlock_destroy], [
1432                                 dnl save the flags
1433                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1434 #include <pthread.h>
1435 pthread_rwlock_t rwlock;
1436 ]], [[pthread_rwlock_destroy(&rwlock);]])],[ol_cv_func_pthread_rwlock_destroy=yes],[ol_cv_func_pthread_rwlock_destroy=no])
1437                         ])
1438                         if test $ol_cv_func_pthread_rwlock_destroy = yes ; then
1439                                 AC_DEFINE(HAVE_PTHREAD_RWLOCK_DESTROY,1,
1440                                         [define if you have pthread_rwlock_destroy function])
1441                         fi
1442
1443                         dnl Check for pthread_detach with <pthread.h> inclusion
1444                         dnl as it's symbol may have been mangled.
1445                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1446                                 [ol_cv_func_pthread_detach], [
1447                                 dnl save the flags
1448                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1449 #include <pthread.h>
1450 #ifndef NULL
1451 #define NULL (void*)0
1452 #endif
1453 ]], [[pthread_detach(NULL);]])],[ol_cv_func_pthread_detach=yes],[ol_cv_func_pthread_detach=no])
1454                         ])
1455
1456                         if test $ol_cv_func_pthread_detach = no ; then
1457                                 AC_MSG_ERROR([could not locate pthread_detach()])
1458                         fi
1459
1460                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1461                                 [define if you have pthread_detach function])
1462
1463                         dnl Check for setconcurreny functions
1464                         AC_CHECK_FUNCS( \
1465                                 pthread_setconcurrency \
1466                                 pthread_getconcurrency \
1467                                 thr_setconcurrency \
1468                                 thr_getconcurrency \
1469                         )
1470
1471                         OL_SYS_LINUX_THREADS
1472                         OL_LINUX_THREADS
1473
1474                         if test $ol_cv_linux_threads = error; then
1475                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1476                         fi
1477
1478                         AC_CACHE_CHECK([if pthread_create() works],
1479                                 ol_cv_pthread_create_works,[
1480                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1481                                 [ol_cv_pthread_create_works=yes],
1482                                 [ol_cv_pthread_create_works=no],
1483                                 [dnl assume yes
1484                                 ol_cv_pthread_create_works=yes])])
1485
1486                         if test $ol_cv_pthread_create_works = no ; then
1487                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1488                         fi
1489
1490                         ol_replace_broken_yield=no
1491 dnl                     case "$target" in
1492 dnl                     *-*-linux*)
1493 dnl                             AC_CHECK_FUNCS(nanosleep)
1494 dnl                             ol_replace_broken_yield=yes
1495 dnl                     ;;
1496 dnl                     esac
1497
1498                         if test $ol_replace_broken_yield = yes ; then
1499                                 AC_DEFINE([REPLACE_BROKEN_YIELD],1,
1500                                         [define if sched_yield yields the entire process])
1501                         fi
1502
1503                         dnl Check if select causes an yield
1504                         if test $ol_with_yielding_select = auto ; then
1505                                 AC_CACHE_CHECK([if select yields when using pthreads],
1506                                         ol_cv_pthread_select_yields,[
1507                                 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1508 #include <sys/types.h>
1509 #include <sys/time.h>
1510 #include <unistd.h>
1511 #include <pthread.h>
1512 #ifndef NULL
1513 #define NULL (void*) 0
1514 #endif
1515
1516 static int fildes[2];
1517
1518 static void *task(p)
1519         void *p;
1520 {
1521         int i;
1522         struct timeval tv;
1523
1524         fd_set rfds;
1525
1526         tv.tv_sec=10;
1527         tv.tv_usec=0;
1528
1529         FD_ZERO(&rfds);
1530         FD_SET(fildes[0], &rfds);
1531
1532         /* we're not interested in any fds */
1533         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1534
1535         if(i < 0) {
1536                 perror("select");
1537                 exit(10);
1538         }
1539
1540         exit(0); /* if we exit here, the select blocked the whole process */
1541 }
1542
1543 int main(argc, argv)
1544         int argc;
1545         char **argv;
1546 {
1547         pthread_t t;
1548
1549         /* create a pipe to select */
1550         if(pipe(&fildes[0])) {
1551                 perror("select");
1552                 exit(1);
1553         }
1554
1555 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1556         (void) pthread_setconcurrency(2);
1557 #else
1558 #ifdef HAVE_THR_SETCONCURRENCY
1559         /* Set Solaris LWP concurrency to 2 */
1560         thr_setconcurrency(2);
1561 #endif
1562 #endif
1563
1564 #if HAVE_PTHREADS < 6
1565         pthread_create(&t, pthread_attr_default, task, NULL);
1566 #else
1567         pthread_create(&t, NULL, task, NULL);
1568 #endif
1569
1570         /* make sure task runs first */
1571 #ifdef HAVE_THR_YIELD
1572         thr_yield();
1573 #elif defined( HAVE_SCHED_YIELD )
1574         sched_yield();
1575 #elif defined( HAVE_PTHREAD_YIELD )
1576         pthread_yield();
1577 #endif
1578
1579         exit(2);
1580 }]])],[ol_cv_pthread_select_yields=no],[ol_cv_pthread_select_yields=yes],[ol_cv_pthread_select_yields=cross])])
1581
1582                                 if test $ol_cv_pthread_select_yields = cross ; then
1583                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1584                                 fi
1585
1586                                 if test $ol_cv_pthread_select_yields = yes ; then
1587                                         ol_with_yielding_select=yes
1588                                 fi
1589                         fi
1590
1591                         dnl restore flags
1592                         CPPFLAGS="$save_CPPFLAGS"
1593                         LIBS="$save_LIBS"
1594                 else
1595                         AC_MSG_ERROR([could not locate usable POSIX Threads])
1596                 fi
1597         fi
1598
1599         if test $ol_with_threads = posix ; then
1600                 AC_MSG_ERROR([could not locate POSIX Threads])
1601         fi
1602         ;;
1603 esac
1604
1605 case $ol_with_threads in auto | yes | mach)
1606
1607         dnl check for Mach CThreads
1608         AC_CHECK_HEADERS(mach/cthreads.h cthreads.h)
1609         if test $ac_cv_header_mach_cthreads_h = yes ; then
1610                 ol_with_threads=found
1611
1612                 dnl check for cthreads support in current $LIBS
1613                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1614
1615                 if test $ol_link_threads = no ; then
1616                         dnl try -all_load
1617                         dnl this test needs work
1618                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1619                                 [ol_cv_cthread_all_load], [
1620                                 dnl save the flags
1621                                 save_LIBS="$LIBS"
1622                                 LIBS="-all_load $LIBS"
1623                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <mach/cthreads.h>]], [[
1624                                         cthread_fork((void *)0, (void *)0);
1625                                         ]])],[ol_cv_cthread_all_load=yes],[ol_cv_cthread_all_load=no])
1626                                 dnl restore the LIBS
1627                                 LIBS="$save_LIBS"
1628                         ])
1629
1630                         if test $ol_cv_cthread_all_load = yes ; then
1631                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1632                                 ol_link_threads=mach
1633                                 ol_with_threads=found
1634                         fi
1635                 fi
1636
1637         elif test $ac_cv_header_cthreads_h = yes ; then
1638                 dnl Hurd variant of Mach Cthreads
1639                 dnl uses <cthreads.h> and -lthreads
1640
1641                 ol_with_threads=found
1642
1643                 dnl save the flags
1644                 save_LIBS="$LIBS"
1645                 LIBS="$LIBS -lthreads"
1646                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1647                 LIBS="$save_LIBS"
1648
1649                 if test $ol_link_threads = yes ; then
1650                         LTHREAD_LIBS="-lthreads"
1651                         ol_link_threads=mach
1652                         ol_with_threads=found
1653                 else
1654                         AC_MSG_ERROR([could not link with Mach CThreads])
1655                 fi
1656
1657         elif test $ol_with_threads = mach ; then
1658                 AC_MSG_ERROR([could not locate Mach CThreads])
1659         fi
1660
1661         if test $ol_link_threads = mach ; then
1662                 AC_DEFINE(HAVE_MACH_CTHREADS,1,
1663                         [define if you have Mach Cthreads])
1664         elif test $ol_with_threads = found ; then
1665                 AC_MSG_ERROR([could not link with Mach CThreads])
1666         fi
1667         ;;
1668 esac
1669
1670 case $ol_with_threads in auto | yes | pth)
1671
1672         AC_CHECK_HEADERS(pth.h)
1673
1674         if test $ac_cv_header_pth_h = yes ; then
1675                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1676
1677                 if test $have_pth = yes ; then
1678                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1679                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1680                         ol_link_threads=pth
1681                         ol_with_threads=found
1682
1683                         if test $ol_with_yielding_select = auto ; then
1684                                 ol_with_yielding_select=yes
1685                         fi
1686                 fi
1687         fi
1688         ;;
1689 esac
1690
1691 case $ol_with_threads in auto | yes | lwp)
1692
1693         dnl check for SunOS5 LWP
1694         AC_CHECK_HEADERS(thread.h synch.h)
1695         if test $ac_cv_header_thread_h = yes &&
1696            test $ac_cv_header_synch_h = yes ; then
1697                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1698
1699                 if test $have_thr = yes ; then
1700                         AC_DEFINE(HAVE_THR,1,
1701                                 [if you have Solaris LWP (thr) package])
1702                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1703                         ol_link_threads=thr
1704
1705                         if test $ol_with_yielding_select = auto ; then
1706                                 ol_with_yielding_select=yes
1707                         fi
1708
1709                         dnl Check for setconcurreny functions
1710                         AC_CHECK_FUNCS( \
1711                                 thr_setconcurrency \
1712                                 thr_getconcurrency \
1713                         )
1714                 fi
1715         fi
1716         ;;
1717 esac
1718
1719 if test $ol_with_yielding_select = yes ; then
1720         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1721                 [define if select implicitly yields])
1722 fi
1723
1724 if test $ol_with_threads = manual ; then
1725         dnl User thinks he can manually configure threads.
1726         ol_link_threads=yes
1727
1728         AC_MSG_WARN([thread defines and link options must be set manually])
1729
1730         AC_CHECK_HEADERS(pthread.h sched.h)
1731         AC_CHECK_FUNCS(sched_yield pthread_yield)
1732         OL_HEADER_LINUX_THREADS
1733
1734         AC_CHECK_HEADERS(mach/cthreads.h)
1735         AC_CHECK_HEADERS(thread.h synch.h)
1736 fi
1737
1738 if test $ol_link_threads != no && test $ol_link_threads != nt ; then
1739         dnl needed to get reentrant/threadsafe versions
1740         dnl
1741         AC_DEFINE(REENTRANT,1)
1742         AC_DEFINE(_REENTRANT,1)
1743         AC_DEFINE(THREAD_SAFE,1)
1744         AC_DEFINE(_THREAD_SAFE,1)
1745         AC_DEFINE(THREADSAFE,1)
1746         AC_DEFINE(_THREADSAFE,1)
1747         AC_DEFINE(_SGI_MP_SOURCE,1)
1748
1749         dnl The errno declaration may dependent upon _REENTRANT.
1750         dnl If it does, we must link with thread support.
1751         AC_CACHE_CHECK([for thread specific errno],
1752                 [ol_cv_errno_thread_specific], [
1753                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[errno = 0;]])],[ol_cv_errno_thread_specific=yes],[ol_cv_errno_thread_specific=no])
1754         ])
1755
1756         dnl The h_errno declaration may dependent upon _REENTRANT.
1757         dnl If it does, we must link with thread support.
1758         AC_CACHE_CHECK([for thread specific h_errno],
1759                 [ol_cv_h_errno_thread_specific], [
1760                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[h_errno = 0;]])],[ol_cv_h_errno_thread_specific=yes],[ol_cv_h_errno_thread_specific=no])
1761         ])
1762
1763         if test $ol_cv_errno_thread_specific != yes ||
1764            test $ol_cv_h_errno_thread_specific != yes ; then
1765                 LIBS="$LTHREAD_LIBS $LIBS"
1766                 LTHREAD_LIBS=""
1767         fi
1768
1769 dnl When in thread environment, use
1770 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) || defined( HAVE_FUNC_R )
1771 dnl                     func_r(...);
1772 dnl             #else
1773 dnl             #       if defined( HAVE_THREADS )
1774 dnl                             /* lock */
1775 dnl             #       endif
1776 dnl                             func(...);
1777 dnl             #       if defined( HAVE_THREADS )
1778 dnl                             /* unlock */
1779 dnl             #       endif
1780 dnl             #endif
1781 dnl
1782 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1783 dnl             _POSIX_REENTRANT_FUNCTIONS
1784 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1785 dnl             _POSIX_THREADSAFE_FUNCTIONS
1786 dnl
1787 dnl             and is currently defined in <ldap_pvt_thread.h>
1788 dnl
1789 dnl HAVE_THREADS is defined by <ldap_pvt_thread.h> iff -UNO_THREADS
1790 dnl
1791 dnl libldap/*.c should only include <ldap_pvt_thread.h> iff
1792 dnl LDAP_R_COMPILE is defined.  ie:
1793 dnl             #ifdef LDAP_R_COMPILE
1794 dnl             #       include <ldap_pvt_thread.h>
1795 dnl             #endif
1796 dnl
1797 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1798 dnl specifically for compiling the threadsafe version of
1799 dnl     the ldap library (-lldap_r).
1800 dnl
1801 dnl     dnl check for reentrant/threadsafe functions
1802 dnl     dnl
1803 dnl     dnl note: these should only be used when linking
1804 dnl     dnl             with $LTHREAD_LIBS
1805 dnl     dnl
1806 dnl     save_CPPFLAGS="$CPPFLAGS"
1807 dnl     save_LIBS="$LIBS"
1808 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1809 dnl     AC_CHECK_FUNCS( \
1810 dnl             gmtime_r \
1811 dnl             gethostbyaddr_r gethostbyname_r \
1812 dnl             feof_unlocked unlocked_feof \
1813 dnl             putc_unlocked unlocked_putc \
1814 dnl             flockfile ftrylockfile \
1815 dnl     )
1816 dnl     CPPFLAGS="$save_CPPFLAGS"
1817 dnl     LIBS="$save_LIBS"
1818 fi
1819
1820 if test $ol_link_threads = no ; then
1821         if test $ol_with_threads = yes ; then
1822                 AC_MSG_ERROR([no suitable thread support])
1823         fi
1824
1825         if test $ol_with_threads = auto ; then
1826                 AC_MSG_WARN([no suitable thread support, disabling threads])
1827                 ol_with_threads=no
1828         fi
1829
1830         AC_DEFINE(NO_THREADS,1,
1831                 [define if you have (or want) no threads])
1832         LTHREAD_LIBS=""
1833         BUILD_THREAD=no
1834 else
1835         BUILD_THREAD=yes
1836 fi
1837
1838 if test $ol_link_threads != no ; then
1839         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1,
1840                 [define to 1 if library is thread safe])
1841 fi
1842
1843 dnl ----------------------------------------------------------------
1844 dnl Tests for reentrant functions necessary to build -lldap_r
1845 AC_CHECK_FUNCS(         \
1846         ctime_r                 \
1847         gmtime_r localtime_r \
1848         gethostbyname_r gethostbyaddr_r \
1849 )
1850
1851 if test "$ac_cv_func_ctime_r" = no ; then
1852         ol_cv_func_ctime_r_nargs=0
1853 else
1854         OL_FUNC_CTIME_R_NARGS
1855 dnl     OL_FUNC_CTIME_R_TYPE
1856 fi
1857
1858 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1859         OL_FUNC_GETHOSTBYNAME_R_NARGS
1860 else
1861         ol_cv_func_gethostbyname_r_nargs=0
1862 fi
1863
1864 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1865         OL_FUNC_GETHOSTBYADDR_R_NARGS
1866 else
1867         ol_cv_func_gethostbyaddr_r_nargs=0
1868 fi
1869
1870 dnl ----------------------------------------------------------------
1871 ol_link_bdb=no
1872
1873 if test $ol_enable_bdb/$ol_enable_hdb != no/no; then
1874         OL_BERKELEY_DB
1875
1876         if test $ol_cv_berkeley_db = no ; then
1877                 AC_MSG_ERROR(BDB/HDB: BerkeleyDB not available)
1878         fi
1879
1880         AC_DEFINE(HAVE_BERKELEY_DB,1,
1881                 [define this if Berkeley DB is available])
1882
1883         dnl $ol_cv_lib_db should be yes or -ldb
1884         dnl (it could be no, but that would be an error
1885         if test $ol_cv_lib_db != yes ; then
1886                 BDB_LIBS="$BDB_LIBS $ol_cv_lib_db"
1887         fi
1888
1889         SLAPD_LIBS="$SLAPD_LIBS \$(BDB_LIBS)"
1890
1891         ol_link_bdb=yes
1892 fi
1893
1894 dnl ----------------------------------------------------------------
1895
1896 if test $ol_enable_dynamic = yes && test $enable_shared = yes ; then
1897         BUILD_LIBS_DYNAMIC=shared
1898         AC_DEFINE(LDAP_LIBS_DYNAMIC, 1, [define if LDAP libs are dynamic])
1899         LTSTATIC=""
1900 else
1901         BUILD_LIBS_DYNAMIC=static
1902         LTSTATIC="-static"
1903 fi
1904 AC_SUBST(LTSTATIC)dnl
1905
1906 dnl ----------------------------------------------------------------
1907 if test $ol_enable_wrappers != no ; then
1908         AC_CHECK_HEADERS(tcpd.h,[
1909                 AC_MSG_CHECKING([for TCP wrappers library])
1910                 save_LIBS="$LIBS"
1911                 LIBS="$LIBS -lwrap"
1912                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1913 #include <tcpd.h>
1914 int allow_severity = 0;
1915 int deny_severity  = 0;
1916
1917 struct request_info *req;
1918                 ]], [[
1919 hosts_access(req)
1920                 ]])],[AC_MSG_RESULT([-lwrap])
1921                 have_wrappers=yes
1922                 LIBS="$save_LIBS"],[
1923                 dnl try with -lnsl
1924                 LIBS="$LIBS -lnsl"
1925                 AC_TRY_LINK([
1926 #include <tcpd.h>
1927 int allow_severity = 0;
1928 int deny_severity  = 0;
1929
1930 struct request_info *req;
1931                 ],[
1932 hosts_access(req)
1933                 ],[AC_MSG_RESULT([-lwrap -lnsl])
1934                 have_wrappers=yes
1935                 LIBS="$save_LIBS -lnsl"],[
1936                 AC_MSG_RESULT(no)
1937                 have_wrappers=no
1938                 LIBS=$save_LIBS])])],[have_wrappers=no])
1939
1940         if test $have_wrappers = yes ; then
1941                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1942                 WRAP_LIBS="-lwrap"
1943         elif test $ol_enable_wrappers = yes ; then
1944                 AC_MSG_ERROR([could not find TCP wrappers, select apppropriate options or disable])
1945         else
1946                 AC_MSG_WARN([could not find TCP wrappers, support disabled])
1947                 WRAP_LIBS=""
1948         fi
1949 fi
1950
1951 dnl ----------------------------------------------------------------
1952 if test $ol_enable_syslog != no ; then
1953         AC_CHECK_FUNC(openlog)
1954         if test $ac_cv_func_openlog = no && test $ol_enable_syslog = yes; then
1955                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1956         fi
1957         ol_enable_syslog=$ac_cv_func_openlog
1958 fi
1959
1960 dnl ----------------------------------------------------------------
1961 dnl SQL
1962 ol_link_sql=no
1963 if test $ol_enable_sql != no ; then
1964         AC_CHECK_HEADERS(sql.h sqlext.h,[],[
1965                 AC_MSG_ERROR([could not locate SQL headers])
1966         ])
1967
1968         sql_LIBS="$LIBS"
1969         LIBS="$LTHREAD_LIBS"
1970
1971         if test $ol_with_odbc = auto ; then
1972                 ol_with_odbc="iodbc unixodbc odbc32"
1973         fi
1974
1975         for odbc in $ol_with_odbc ; do
1976                 if test $ol_link_sql = no ; then
1977                         case $odbc in
1978                         iodbc)
1979                                 AC_CHECK_LIB(iodbc, SQLDriverConnect, [have_iodbc=yes], [have_iodbc=no])
1980                                 if test $have_iodbc = yes ; then
1981                                         ol_link_sql="-liodbc"
1982                                 fi
1983                                 ;;
1984
1985                         unixodbc)
1986                                 AC_CHECK_LIB(odbc, SQLDriverConnect, [have_odbc=yes], [have_odbc=no])
1987                                 if test $have_odbc = yes ; then
1988                                         ol_link_sql="-lodbc"
1989                                 fi
1990                                 ;;
1991
1992                         odbc32)
1993                                 AC_CHECK_LIB(odbc32, SQLDriverConnect, [have_odbc32=yes], [have_odbc32=no])
1994
1995                                 dnl The windows API uses __stdcall which cannot be detected by AC_CHECK_LIB
1996                                 if test $have_odbc32 = no ; then
1997                                         AC_MSG_CHECKING([for SQLDriverConnect in -lodbc32 with windows.h])
1998                                         save_LIBS="$LIBS"
1999                                         LIBS="$LIBS -lodbc32"
2000                                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <windows.h>
2001                                         #include <sqlext.h>
2002                                                 ]], [[
2003                                                 SQLDriverConnect(NULL,NULL,NULL,0,NULL,0,NULL,0);
2004                                                 ]])],[have_odbc32=yes], [have_odbc32=no])
2005                                         LIBS="$save_LIBS"
2006                                         AC_MSG_RESULT($have_odbc32)
2007                                 fi
2008
2009                                 if test $have_odbc32 = yes ; then
2010                                         ol_link_sql="-lodbc32"
2011                                 fi
2012                                 ;;
2013
2014                         *)
2015                                 AC_MSG_ERROR([unknown ODBC library])
2016                                 ;;
2017                         esac
2018                 fi
2019         done
2020
2021         LIBS="$sql_LIBS"
2022
2023         if test $ol_link_sql != no ; then
2024                 SLAPD_SQL_LIBS="$ol_link_sql"
2025
2026         elif test $ol_enable_sql != auto ; then
2027                 AC_MSG_ERROR([could not locate suitable ODBC library])
2028         fi
2029 fi
2030
2031 dnl ----------------------------------------------------------------
2032 dnl MySQL NDBapi
2033 dnl Note: uses C++, but we don't want to add C++ test overhead to
2034 dnl the rest of the libtool machinery.
2035 ol_link_ndb=no
2036 if test $ol_enable_ndb != no ; then
2037         AC_CHECK_PROG(MYSQL,mysql_config,yes)
2038         if test "$MYSQL" != yes ; then
2039                 AC_MSG_ERROR([could not locate mysql_config])
2040         fi
2041
2042         SQL_INC=`mysql_config --include`
2043         SLAPD_NDB_INCS="$SQL_INC $SQL_INC/storage/ndb $SQL_INC/storage/ndb/ndbapi"
2044
2045         save_CPPFLAGS="$CPPFLAGS"
2046         CPPFLAGS="$SLAPD_NDB_INCS"
2047         AC_MSG_CHECKING(for NdbApi.hpp)
2048         AC_PREPROC_IFELSE(
2049                 [AC_LANG_SOURCE([[#include <NdbApi.hpp>]])],
2050                         AC_MSG_RESULT(yes),
2051                         AC_MSG_ERROR([could not locate NdbApi headers])
2052         )
2053         CPPFLAGS="$save_CPPFLAGS"
2054
2055         SQL_LIB=`mysql_config --libs_r`
2056         SLAPD_NDB_LIBS="$SQL_LIB -lndbclient -lstdc++"
2057
2058         save_LDFLAGS="$LDFLAGS"
2059         save_LIBS="$LIBS"
2060         LDFLAGS="$SQL_LIB"
2061         AC_CHECK_LIB(ndbclient,ndb_init,[: ok],[
2062                 AC_MSG_ERROR([could not locate ndbclient library])
2063         ],[-lstdc++])
2064         LIBS="$save_LIBS"
2065         LDFLAGS="$save_LDFLAGS"
2066
2067         if test "$ol_enable_ndb" = yes ; then
2068                 SLAPD_LIBS="$SLAPD_LIBS \$(SLAPD_NDB_LIBS)"
2069         fi
2070 fi
2071
2072 dnl ----------------------------------------------------------------
2073 dnl International Components for Unicode
2074 OL_ICU
2075 if test "$ol_icu" = no ; then
2076         AC_MSG_WARN([ICU not available])
2077 else
2078         ICU_LIBS="$ol_icu"
2079 fi
2080 dnl ----------------------------------------------------------------
2081 dnl
2082 dnl Check for Cyrus SASL
2083 dnl
2084 WITH_SASL=no
2085 ol_link_sasl=no
2086 ol_link_spasswd=no
2087 if test $ol_with_cyrus_sasl != no ; then
2088         AC_CHECK_HEADERS(sasl/sasl.h sasl.h)
2089
2090         if test $ac_cv_header_sasl_sasl_h = yes ||
2091            test $ac_cv_header_sasl_h = yes; then
2092                 AC_CHECK_LIB(sasl2, sasl_client_init,
2093                         [ol_link_sasl="-lsasl2"],
2094                         [AC_CHECK_LIB(sasl, sasl_client_init,
2095                                 [ol_link_sasl="-lsasl"])])
2096         fi
2097
2098         if test $ol_link_sasl = no ; then
2099                 if test $ol_with_cyrus_sasl != auto ; then
2100                         AC_MSG_ERROR([Could not locate Cyrus SASL])
2101                 else
2102                         AC_MSG_WARN([Could not locate Cyrus SASL])
2103                         AC_MSG_WARN([SASL authentication not supported!])
2104                         if test $ol_link_tls = no ; then
2105                                 AC_MSG_WARN([Strong authentication not supported!])
2106                         fi
2107                 fi
2108         else
2109                 OL_SASL_COMPAT
2110                 if test $ol_cv_sasl_compat = no ; then
2111                         ol_link_sasl=no
2112                         AC_MSG_ERROR([Cyrus SASL library located but is incompatible])
2113                 fi
2114
2115                 AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
2116                 SASL_LIBS="$ol_link_sasl"
2117                 if test $ol_enable_spasswd != no ; then
2118                         ol_link_spasswd=yes
2119                 fi
2120
2121                 ac_save_LIBS="$LIBS"
2122                 LIBS="$LIBS $ol_link_sasl"
2123                 AC_CHECK_FUNC(sasl_version, [AC_DEFINE(HAVE_SASL_VERSION,1,
2124                         [define if your SASL library has sasl_version()])])
2125                 LIBS="$ac_save_LIBS"
2126
2127                 WITH_SASL=yes
2128         fi
2129
2130 else
2131         AC_MSG_WARN([SASL authentication not supported!])
2132         if test $ol_link_tls = no ; then
2133                 AC_MSG_WARN([Strong authentication not supported!])
2134         fi
2135 fi
2136
2137 dnl ----------------------------------------------------------------
2138 dnl Check for entropy sources
2139 if test $cross_compiling != yes && test "$ac_cv_mingw32" != yes ; then
2140         dev=no
2141         if test -r /dev/urandom ; then
2142                 dev="/dev/urandom";
2143         elif test -r /idev/urandom ; then
2144                 dev="/idev/urandom";
2145         elif test -r /dev/srandom ; then
2146                 dev="/dev/srandom";
2147         elif test -r /dev/random ; then
2148                 dev="/dev/random";
2149         elif test -r /idev/random ; then
2150                 dev="/idev/random";
2151         fi
2152
2153         if test $dev != no ; then
2154                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
2155         fi
2156 fi
2157
2158 dnl ----------------------------------------------------------------
2159 dnl
2160 dnl Check for fetch URL support
2161 dnl             should be extended to support other fetch URL APIs
2162 dnl
2163 ol_link_fetch=no
2164 if test $ol_with_fetch != no ; then
2165         OL_LIB_FETCH
2166
2167         if test $ol_cv_lib_fetch != no ; then
2168                 LUTIL_LIBS="$LUTIL_LIBS $ol_link_fetch"
2169                 ol_link_fetch=freebsd
2170
2171         elif test $ol_with_fetch != auto ; then
2172                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
2173         fi
2174 fi
2175
2176 dnl ----------------------------------------------------------------
2177 dnl FreeBSD (and others) have crypt(3) in -lcrypt
2178 if test $ol_enable_crypt != no ; then
2179         save_LIBS="$LIBS"
2180         LIBS="$TLS_LIBS $LIBS"
2181
2182         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
2183                 LIBS="$save_LIBS"
2184                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
2185                         have_crypt=yes], [have_crypt=no])])
2186
2187         LIBS="$save_LIBS"
2188
2189         if test $have_crypt = yes ; then
2190                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
2191         else
2192                 AC_MSG_WARN([could not find crypt])
2193                 if test $ol_enable_crypt = yes ; then
2194                         AC_MSG_ERROR([could not find crypt, select appropriate options or disable])
2195                 fi
2196
2197                 AC_MSG_WARN([disabling crypt support])
2198                 ol_enable_crypt=no
2199         fi
2200 fi
2201
2202 dnl ----------------------------------------------------------------
2203 dnl FreeBSD (and others) have setproctitle(3) in -lutil
2204 if test $ol_enable_proctitle != no ; then
2205         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
2206                 AC_CHECK_LIB(util, setproctitle,
2207                         [have_setproctitle=yes
2208                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
2209                         [have_setproctitle=no
2210                         AC_LIBOBJ(setproctitle)
2211                         LIBSRCS="$LIBSRCS setproctitle.c"])])
2212
2213         if test $have_setproctitle = yes ; then
2214                 AC_DEFINE(HAVE_SETPROCTITLE,1,
2215                         [define if setproctitle(3) is available])
2216         fi
2217 fi
2218
2219 dnl ----------------------------------------------------------------
2220 if test $ol_enable_slp != no ; then
2221         AC_CHECK_HEADERS( slp.h )
2222
2223         if test $ac_cv_header_slp_h = yes ; then
2224                 AC_CHECK_LIB(slp, SLPOpen, [have_slp=yes], [have_slp=no])
2225                 if test $have_slp = yes ; then
2226                         AC_DEFINE(HAVE_SLP, 1, [define if you have -lslp])
2227                         SLAPD_SLP_LIBS=-lslp
2228                 fi
2229
2230         elif test $ol_enable_slp = yes ; then
2231                 AC_MSG_ERROR([SLP not found])
2232         fi
2233 fi
2234
2235 dnl ----------------------------------------------------------------
2236 dnl Checks for typedefs, structures, and compiler characteristics.
2237
2238 AC_CHECK_TYPE(mode_t, int)
2239 AC_CHECK_TYPE(off_t, long)
2240 AC_CHECK_TYPE(pid_t, int)
2241 AC_CHECK_TYPE(ssize_t, [signed int])
2242 AC_CHECK_TYPE(caddr_t,  [char *])
2243 AC_CHECK_TYPE(size_t, unsigned)
2244
2245 AC_CHECK_TYPES([long long])
2246 AC_CHECK_TYPES([ptrdiff_t])
2247
2248
2249 AC_CHECK_TYPE([socklen_t],,, [$ac_includes_default
2250 #ifdef HAVE_SYS_SOCKET_H
2251 #include <sys/socket.h>
2252 #endif])
2253
2254 dnl socklen_t-like type in accept(), default socklen_t or int:
2255 dnl - The OS might define socklen_t without using it.  POSIX moved from
2256 dnl   int to size_t to socklen_t, hoping to stay at a 32-bit type, and
2257 dnl   HP-UX now has selectors for what to use.
2258 dnl - On Solaris 2.8 the prototype has void *len, but the default is OK.
2259 AC_MSG_CHECKING([the type of arg 3 to accept()])
2260 AC_CACHE_VAL(ol_cv_type_ber_socklen_t, [
2261         set socklen_t int unsigned "unsigned long" long size_t
2262         test "$ac_cv_type_socklen_t" = yes || shift
2263         ol_cv_type_ber_socklen_t=$1 guessing="guessing "
2264         for lentype in "$@" ; do for addrtype in "struct sockaddr" void ; do
2265                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([$ac_includes_default
2266 #ifdef HAVE_SYS_SOCKET_H
2267 #include <sys/socket.h>
2268 #endif
2269 extern int accept(int s, $addrtype *ap, $lentype *lp);
2270 ], [
2271 accept(0, (struct sockaddr *) 0, ($lentype *) 0);
2272 ])], [ol_cv_type_ber_socklen_t=$lentype guessing= ; break 2])
2273         done ; done])
2274 AC_MSG_RESULT([$guessing$ol_cv_type_ber_socklen_t *])
2275 AC_DEFINE_UNQUOTED(ber_socklen_t, $ol_cv_type_ber_socklen_t,
2276         [Define to the type of arg 3 for `accept'.])
2277
2278 dnl Modules should use ber_socklen_t, not socklen_t.  Define socklen_t
2279 dnl for the time being anyway, for backwards compatibility.
2280 if test "$ac_cv_type_socklen_t" != yes; then
2281         AC_DEFINE_UNQUOTED([socklen_t], [$ol_cv_type_ber_socklen_t],
2282                 [Define like ber_socklen_t if <sys/socket.h> does not define.])
2283 fi
2284
2285
2286 AC_TYPE_SIGNAL
2287
2288 AC_CHECK_TYPE([sig_atomic_t],,
2289         [AC_DEFINE_UNQUOTED([sig_atomic_t], [int],
2290                 [Define to `int' if <signal.h> does not define.])],
2291         [$ac_includes_default
2292 #include <signal.h>
2293         ])
2294
2295 AC_TYPE_UID_T
2296
2297 AC_HEADER_TIME
2298 AC_STRUCT_TM
2299 AC_CHECK_MEMBERS([struct stat.st_blksize])
2300 AC_CHECK_MEMBERS([struct passwd.pw_gecos],,,[$ac_includes_default
2301 #include <pwd.h>])
2302 AC_CHECK_MEMBERS([struct passwd.pw_passwd],,,[$ac_includes_default
2303 #include <pwd.h>])
2304
2305 OL_C_UPPER_LOWER
2306 AC_C_CONST
2307 OL_C_VOLATILE
2308
2309 if test $cross_compiling = yes ; then
2310         AC_MSG_WARN([Crossing compiling... all bets are off!])
2311         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2312 else
2313         AC_C_BIGENDIAN
2314 fi
2315
2316 AC_CHECK_SIZEOF(short)
2317 AC_CHECK_SIZEOF(int)
2318 AC_CHECK_SIZEOF(long)
2319 AC_CHECK_SIZEOF(long long)
2320 AC_CHECK_SIZEOF(wchar_t)
2321
2322 if test "$ac_cv_sizeof_int" -lt 4 ; then
2323         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2324
2325         AC_DEFINE(LBER_INT_T,long,[define to 32-bit or greater integer type])
2326 else
2327         AC_DEFINE(LBER_INT_T,int,[define to 32-bit or greater integer type])
2328 fi
2329
2330 AC_DEFINE(LBER_LEN_T,long,[define to large integer type])
2331 AC_DEFINE(LBER_SOCKET_T,int,[define to socket descriptor type])
2332 AC_DEFINE(LBER_TAG_T,long,[define to large integer type])
2333
2334 dnl ----------------------------------------------------------------
2335 dnl Check for multiple precision support
2336 if test $ol_with_mp = longlong || test $ol_with_mp = auto ; then
2337         if test $ac_cv_sizeof_long_long -gt 4 ; then
2338                 ol_with_mp=longlong
2339                 AC_DEFINE(USE_MP_LONG_LONG,1,[define to use 'long long' for MP])
2340         elif test $ol_with_mp = longlong ; then
2341                 AC_MSG_ERROR([long long unusable for multiple precision])
2342         fi
2343 fi
2344 if test $ol_with_mp = long || test $ol_with_mp = auto ; then
2345         if test $ac_cv_sizeof_long -gt 4 ; then
2346                 ol_with_mp=long
2347                 AC_DEFINE(USE_MP_LONG,1,[define to use 'long' for MP])
2348         elif test $ol_with_mp = long ; then
2349                 AC_MSG_ERROR([long unusable for multiple precision])
2350         fi
2351 fi
2352 if test $ol_with_mp = bignum || test $ol_with_mp = auto ; then
2353         AC_CHECK_HEADERS(openssl/bn.h)
2354         AC_CHECK_HEADERS(openssl/crypto.h)
2355         if test "$ac_cv_header_openssl_bn_h" = "yes" &&
2356                 test "$ac_cv_header_openssl_crypto_h" = "yes" &&
2357                 test "$ol_with_tls" = "found" ; then
2358                 ol_with_mp=bignum
2359                 AC_DEFINE(USE_MP_BIGNUM,1,[define to use OpenSSL BIGNUM for MP])
2360         elif test $ol_with_mp = bignum ; then
2361                 AC_MSG_ERROR([bignum not available])
2362         fi
2363 fi
2364 if test $ol_with_mp = gmp || test $ol_with_mp = auto ; then
2365         AC_CHECK_HEADERS(gmp.h)
2366         AC_CHECK_LIB(gmp, __gmpz_add_ui)
2367         if test $ac_cv_header_gmp_h = yes && test $ac_cv_lib_gmp___gmpz_add_ui = yes ; then
2368                 AC_DEFINE(USE_MP_GMP,1,[define to use GMP for MP])
2369                 ol_with_mp=gmp
2370         elif test $ol_with_mp = gmp ; then
2371                 AC_MSG_ERROR([gmp not available])
2372         fi
2373 fi
2374 if test $ol_with_mp = auto ; then
2375         ol_with_mp=no
2376 fi
2377
2378 dnl ----------------------------------------------------------------
2379 dnl Checks for library functions.
2380 AC_FUNC_MEMCMP
2381
2382 if test $ac_cv_func_memcmp_working = no ; then
2383         AC_DEFINE(NEED_MEMCMP_REPLACEMENT,1,
2384                 [define if memcmp is not 8-bit clean or is otherwise broken])
2385 fi
2386
2387 AC_FUNC_STRFTIME
2388
2389 OL_FUNC_INET_ATON
2390
2391 dnl Check for NT specific routines
2392 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2393
2394 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2395         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2396 ])
2397
2398 AC_CHECK_FUNCS(vsnprintf _vsnprintf)
2399
2400 if test $ac_cv_func_vsnprintf = no -a $ac_cv_func__vsnprintf = yes ; then
2401         ac_cv_func_vsnprintf=yes
2402         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2403 fi
2404
2405 AC_FUNC_VPRINTF
2406
2407 if test $ac_cv_func_vprintf = yes ; then
2408         dnl check for vsnprintf
2409         AC_CHECK_FUNCS(snprintf vsnprintf)
2410 fi
2411
2412 AC_CHECK_FUNCS(                 \
2413         bcopy                   \
2414         closesocket             \
2415         chroot                  \
2416         endgrent                \
2417         endpwent                \
2418         fcntl                   \
2419         flock                   \
2420         fstat                   \
2421         getdtablesize           \
2422         geteuid                 \
2423         getgrgid                \
2424         gethostname             \
2425         getpassphrase           \
2426         getpwuid                \
2427         getpwnam                \
2428         getspnam                \
2429         gettimeofday            \
2430         initgroups              \
2431         inet_ntoa_b             \
2432         ioctl                   \
2433         lockf                   \
2434         memcpy                  \
2435         memmove                 \
2436         memrchr                 \
2437         mkstemp                 \
2438         mktemp                  \
2439         pipe                    \
2440         read                    \
2441         recv                    \
2442         recvfrom                \
2443         setpwfile               \
2444         setgid                  \
2445         setegid                 \
2446         setsid                  \
2447         setuid                  \
2448         seteuid                 \
2449         signal                  \
2450         strdup                  \
2451         strpbrk                 \
2452         strrchr                 \
2453         strsep                  \
2454         strstr                  \
2455         strtol                  \
2456         strtoul                 \
2457         strtoq                  \
2458         strtouq                 \
2459         strtoll                 \
2460         strtoull                \
2461         strspn                  \
2462         sysconf                 \
2463         waitpid                 \
2464         wait4                   \
2465         write                   \
2466         send                    \
2467         sendmsg                 \
2468         sendto                  \
2469 )
2470
2471 dnl We actually may need to replace more than this.
2472 AC_REPLACE_FUNCS(getopt getpeereid)
2473
2474 if test "$ac_cv_func_getopt" != yes; then
2475         LIBSRCS="$LIBSRCS getopt.c"
2476 fi
2477
2478 if test "$ac_cv_func_getpeereid" != yes; then
2479         AC_CHECK_FUNCS( getpeerucred )
2480         if test "$ac_cv_func_getpeerucred" != yes ; then
2481                 AC_CHECK_MEMBERS([struct msghdr.msg_accrightslen],,,
2482                         [$ac_includes_default
2483 #ifdef HAVE_SYS_SOCKET_H
2484 #include <sys/socket.h>
2485 #endif])
2486                 if test "$ac_cv_member_struct_msghdr_msg_accrightslen" != yes; then
2487                         AC_CHECK_MEMBERS([struct msghdr.msg_control],,,
2488                                 [$ac_includes_default
2489 #ifdef HAVE_SYS_SOCKET_H
2490 #include <sys/socket.h>
2491 #endif])
2492                 fi
2493                 AC_CHECK_MEMBERS([struct stat.st_fstype, struct stat.st_vfstype])
2494                 if test "$ac_cv_member_struct_stat_st_fstype" = yes; then
2495                         AC_COMPILE_IFELSE([struct stat st; char *ptr=st.st_fstype;],
2496                                 AC_DEFINE([HAVE_STRUCT_STAT_ST_FSTYPE_CHAR],1,[define to 1 if st_fstype is char *]),
2497                                 AC_DEFINE([HAVE_STRUCT_STAT_ST_FSTYPE_INT],1,[define to 1 if st_fstype is int]))
2498                 fi
2499         fi
2500         LIBSRCS="$LIBSRCS getpeereid.c"
2501 fi
2502
2503 if test "$ac_cv_func_snprintf" != yes ||
2504    test "$ac_cv_func_vsnprintf" != yes; then
2505         if test "$ac_cv_func_snprintf" != yes; then
2506                 AC_DEFINE(snprintf, ber_pvt_snprintf, [define to snprintf routine])
2507         fi
2508         if test "$ac_cv_func_vsnprintf" != yes; then
2509                 AC_DEFINE(vsnprintf, ber_pvt_vsnprintf, [define to snprintf routine])
2510         fi
2511 fi
2512
2513 dnl ----------------------------------------------------------------
2514 dnl Sort out defines
2515
2516 if test "$ol_enable_slapi" != no ; then
2517         dnl This check is done also if --enable-modules is used;
2518         dnl it is duplicated here, 'cause it'd be cached anyway
2519         AC_CHECK_HEADERS(ltdl.h)
2520
2521         if test $ac_cv_header_ltdl_h != yes ; then
2522                 AC_MSG_ERROR([could not locate <ltdl.h>])
2523         fi
2524         AC_CHECK_LIB(ltdl, lt_dlinit, [
2525                 SLAPI_LIBS=-lltdl
2526                 LIBSLAPI=libslapi.a
2527                 LIBSLAPITOOLS=../libslapi.a
2528                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
2529         ],[AC_MSG_ERROR([could not locate libtool -lltdl])])
2530
2531         AC_DEFINE(LDAP_SLAPI,1, [define this to add SLAPI code])
2532 fi
2533
2534 if test "$ol_enable_debug" != no ; then
2535         if test "$ol_enable_debug" = traditional; then
2536                 AC_DEFINE(OLD_DEBUG,1,
2537                         [define to use the original debug style])
2538         fi
2539         AC_DEFINE(LDAP_DEBUG,1,
2540                 [define this to add debugging code])
2541 fi
2542 if test "$ol_enable_syslog" = yes ; then
2543         AC_DEFINE(LDAP_SYSLOG,1,
2544                 [define this to add syslog code])
2545 fi
2546 if test "$ol_enable_proctitle" != no ; then
2547         AC_DEFINE(LDAP_PROCTITLE,1,
2548                 [define this for LDAP process title support])
2549 fi
2550 if test "$ol_enable_referrals" != no ; then
2551         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION,
2552                 [define to LDAP VENDOR VERSION])
2553 fi
2554 if test "$ol_enable_local" != no; then
2555         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2556 fi
2557 if test "$ol_link_ipv6" != no; then
2558         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2559 fi
2560 if test "$ol_enable_cleartext" != no ; then
2561         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2562 fi
2563 if test "$ol_enable_crypt" != no ; then
2564         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2565 fi
2566 if test "$ol_link_spasswd" != no ; then
2567         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2568 fi
2569 if test "$ol_enable_rlookups" != no ; then
2570         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2571 fi
2572 if test "$ol_enable_aci" != no ; then
2573         if test $ol_enable_dynacl = no ; then
2574                 ol_enable_dynacl=yes
2575                 AC_MSG_WARN([ACIs need dynacl])
2576         fi
2577         if test "$ol_enable_aci" = mod ; then
2578                 MFLAG=SLAPD_MOD_DYNAMIC
2579                 dnl remove this after moving servers/slapd/aci.c in contrib/slapd-modules/acl
2580                 AC_MSG_ERROR([ACI build as dynamic module not supported (yet)])
2581         else
2582                 MFLAG=SLAPD_MOD_STATIC
2583         fi
2584         WITH_ACI_ENABLED=$ol_enable_aci
2585         AC_DEFINE_UNQUOTED(SLAPD_ACI_ENABLED,$MFLAG,[define to support per-object ACIs])
2586 else
2587         WITH_ACI_ENABLED=no
2588 fi
2589 if test "$ol_enable_dynacl" != no ; then
2590         AC_DEFINE(SLAP_DYNACL,1,[define to support run-time loadable ACL])
2591 fi
2592
2593 if test "$ol_link_modules" != no ; then
2594         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2595         BUILD_SLAPD=yes
2596         SLAPD_MODULES_LDFLAGS="-dlopen self"
2597 fi
2598
2599 AC_DEFINE(SLAPD_MOD_STATIC,1,[statically linked module])
2600 AC_DEFINE(SLAPD_MOD_DYNAMIC,2,[dynamically linked module])
2601
2602 dnl back-monitor goes first (well, after back-config)
2603 if test "$ol_enable_monitor" != no ; then
2604         BUILD_SLAPD=yes
2605         BUILD_MONITOR=$ol_enable_monitor
2606         if test "$ol_enable_monitor" = mod ; then
2607                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-monitor"
2608                 MFLAG=SLAPD_MOD_DYNAMIC
2609         else
2610                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-monitor"
2611                 MFLAG=SLAPD_MOD_STATIC
2612         fi
2613         AC_DEFINE_UNQUOTED(SLAPD_MONITOR,$MFLAG,[define to support cn=Monitor backend])
2614 fi
2615
2616 if test "$ol_enable_bdb" != no ; then
2617         BUILD_SLAPD=yes
2618         BUILD_BDB=$ol_enable_bdb
2619         if test "$ol_enable_bdb" = mod ; then
2620                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-bdb"
2621                 MFLAG=SLAPD_MOD_DYNAMIC
2622         else
2623                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-bdb"
2624                 MFLAG=SLAPD_MOD_STATIC
2625         fi
2626         AC_DEFINE_UNQUOTED(SLAPD_BDB,$MFLAG,[define to support BDB backend])
2627 fi
2628
2629 if test "$ol_enable_dnssrv" != no ; then
2630         BUILD_SLAPD=yes
2631         BUILD_DNSSRV=$ol_enable_dnssrv
2632         if test "$ol_enable_dnssrv" = mod ; then
2633                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-dnssrv"
2634                 MFLAG=SLAPD_MOD_DYNAMIC
2635         else
2636                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-dnssrv"
2637                 MFLAG=SLAPD_MOD_STATIC
2638         fi
2639         AC_DEFINE_UNQUOTED(SLAPD_DNSSRV,$MFLAG,[define to support DNS SRV backend])
2640 fi
2641
2642 if test "$ol_enable_hdb" != no ; then
2643         BUILD_SLAPD=yes
2644         BUILD_HDB=$ol_enable_hdb
2645         if test "$ol_enable_hdb" = mod ; then
2646                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-hdb"
2647                 MFLAG=SLAPD_MOD_DYNAMIC
2648         else
2649                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-hdb"
2650                 MFLAG=SLAPD_MOD_STATIC
2651         fi
2652         AC_DEFINE_UNQUOTED(SLAPD_HDB,$MFLAG,[define to support HDB backend])
2653 fi
2654
2655 if test "$ol_enable_ldap" != no ; then
2656         BUILD_SLAPD=yes
2657         BUILD_LDAP=$ol_enable_ldap
2658         if test "$ol_enable_ldap" = mod ; then
2659                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ldap"
2660                 MFLAG=SLAPD_MOD_DYNAMIC
2661         else
2662                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ldap"
2663                 MFLAG=SLAPD_MOD_STATIC
2664         fi
2665         AC_DEFINE_UNQUOTED(SLAPD_LDAP,$MFLAG,[define to support LDAP backend])
2666 fi
2667
2668 if test "$ol_enable_meta" != no ; then
2669         BUILD_SLAPD=yes
2670         BUILD_META=$ol_enable_meta
2671         BUILD_REWRITE=yes
2672         if test "$ol_enable_meta" = mod ; then
2673                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-meta"
2674                 MFLAG=SLAPD_MOD_DYNAMIC
2675         else
2676                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-meta"
2677                 MFLAG=SLAPD_MOD_STATIC
2678         fi
2679         AC_DEFINE_UNQUOTED(SLAPD_META,$MFLAG,[define to support LDAP Metadirectory backend])
2680 fi
2681
2682 if test "$ol_enable_ndb" != no ; then
2683         BUILD_SLAPD=yes
2684         BUILD_NDB=$ol_enable_ndb
2685         if test "$ol_enable_ndb" = mod ; then
2686                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ndb"
2687                 MFLAG=SLAPD_MOD_DYNAMIC
2688         else
2689                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ndb"
2690                 MFLAG=SLAPD_MOD_STATIC
2691         fi
2692         AC_DEFINE_UNQUOTED(SLAPD_NDB,$MFLAG,[define to support NDB backend])
2693 fi
2694
2695 if test "$ol_enable_null" != no ; then
2696         BUILD_SLAPD=yes
2697         BUILD_NULL=$ol_enable_null
2698         if test "$ol_enable_null" = mod ; then
2699                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-null"
2700                 MFLAG=SLAPD_MOD_DYNAMIC
2701         else
2702                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-null"
2703                 MFLAG=SLAPD_MOD_STATIC
2704         fi
2705         AC_DEFINE_UNQUOTED(SLAPD_NULL,$MFLAG,[define to support NULL backend])
2706 fi
2707
2708 if test "$ol_enable_passwd" != no ; then
2709         BUILD_SLAPD=yes
2710         BUILD_PASSWD=$ol_enable_passwd
2711         if test "$ol_enable_passwd" = mod ; then
2712                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-passwd"
2713                 MFLAG=SLAPD_MOD_DYNAMIC
2714         else
2715                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-passwd"
2716                 MFLAG=SLAPD_MOD_STATIC
2717         fi
2718         AC_DEFINE_UNQUOTED(SLAPD_PASSWD,$MFLAG,[define to support PASSWD backend])
2719 fi
2720
2721 if test "$ol_link_perl" != no ; then
2722         BUILD_SLAPD=yes
2723         BUILD_PERL=$ol_enable_perl
2724         if test "$ol_enable_perl" = mod ; then
2725                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-perl"
2726                 MFLAG=SLAPD_MOD_DYNAMIC
2727         else
2728                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-perl"
2729                 MFLAG=SLAPD_MOD_STATIC
2730         fi
2731         AC_DEFINE_UNQUOTED(SLAPD_PERL,$MFLAG,[define to support PERL backend])
2732 fi
2733
2734 if test "$ol_enable_relay" != no ; then
2735         BUILD_SLAPD=yes
2736         BUILD_RELAY=$ol_enable_relay
2737         if test "$ol_enable_relay" = mod ; then
2738                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-relay"
2739                 MFLAG=SLAPD_MOD_DYNAMIC
2740         else
2741                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-relay"
2742                 MFLAG=SLAPD_MOD_STATIC
2743         fi
2744         AC_DEFINE_UNQUOTED(SLAPD_RELAY,$MFLAG,[define to support relay backend])
2745 fi
2746
2747 if test "$ol_enable_shell" != no ; then
2748         if test "$ol_link_threads" != no ; then
2749                 AC_MSG_WARN([Use of --without-threads is recommended with back-shell])
2750         fi
2751         BUILD_SLAPD=yes
2752         BUILD_SHELL=$ol_enable_shell
2753         if test "$ol_enable_shell" = mod ; then
2754                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-shell"
2755                 MFLAG=SLAPD_MOD_DYNAMIC
2756         else
2757                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-shell"
2758                 MFLAG=SLAPD_MOD_STATIC
2759         fi
2760         AC_DEFINE_UNQUOTED(SLAPD_SHELL,$MFLAG,[define to support SHELL backend])
2761 fi
2762
2763 if test "$ol_enable_sock" != no ; then
2764         BUILD_SLAPD=yes
2765         BUILD_SOCK=$ol_enable_sock
2766         if test "$ol_enable_sock" = mod ; then
2767                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-sock"
2768                 MFLAG=SLAPD_MOD_DYNAMIC
2769         else
2770                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-sock"
2771                 MFLAG=SLAPD_MOD_STATIC
2772         fi
2773         AC_DEFINE_UNQUOTED(SLAPD_SOCK,$MFLAG,[define to support SOCK backend])
2774 fi
2775
2776 if test "$ol_link_sql" != no ; then
2777         BUILD_SLAPD=yes
2778         BUILD_SQL=$ol_enable_sql
2779         if test "$ol_enable_sql" = mod; then
2780                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-sql"
2781                 MFLAG=SLAPD_MOD_DYNAMIC
2782         else
2783                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-sql"
2784                 MFLAG=SLAPD_MOD_STATIC
2785         fi
2786         AC_DEFINE_UNQUOTED(SLAPD_SQL,$MFLAG,[define to support SQL backend])
2787 fi
2788
2789 if test "$ol_enable_accesslog" != no ; then
2790         BUILD_ACCESSLOG=$ol_enable_accesslog
2791         if test "$ol_enable_accesslog" = mod ; then
2792                 MFLAG=SLAPD_MOD_DYNAMIC
2793                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS accesslog.la"
2794         else
2795                 MFLAG=SLAPD_MOD_STATIC
2796                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS accesslog.o"
2797         fi
2798         AC_DEFINE_UNQUOTED(SLAPD_OVER_ACCESSLOG,$MFLAG,[define for In-Directory Access Logging overlay])
2799 fi
2800
2801 if test "$ol_enable_auditlog" != no ; then
2802         BUILD_AUDITLOG=$ol_enable_auditlog
2803         if test "$ol_enable_auditlog" = mod ; then
2804                 MFLAG=SLAPD_MOD_DYNAMIC
2805                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS auditlog.la"
2806         else
2807                 MFLAG=SLAPD_MOD_STATIC
2808                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS auditlog.o"
2809         fi
2810         AC_DEFINE_UNQUOTED(SLAPD_OVER_AUDITLOG,$MFLAG,[define for Audit Logging overlay])
2811 fi
2812
2813 if test "$ol_enable_collect" != no ; then
2814         BUILD_COLLECT=$ol_enable_collect
2815         if test "$ol_enable_collect" = mod ; then
2816                 MFLAG=SLAPD_MOD_DYNAMIC
2817                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS collect.la"
2818         else
2819                 MFLAG=SLAPD_MOD_STATIC
2820                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS collect.o"
2821         fi
2822         AC_DEFINE_UNQUOTED(SLAPD_OVER_COLLECT,$MFLAG,[define for Collect overlay])
2823 fi
2824
2825 if test "$ol_enable_constraint" != no ; then
2826         BUILD_CONSTRAINT=$ol_enable_constraint
2827         if test "$ol_enable_constraint" = mod ; then
2828                 MFLAG=SLAPD_MOD_DYNAMIC
2829                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS constraint.la"
2830         else
2831                 MFLAG=SLAPD_MOD_STATIC
2832                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS constraint.o"
2833         fi
2834         AC_DEFINE_UNQUOTED(SLAPD_OVER_CONSTRAINT,$MFLAG,[define for Attribute Constraint overlay])
2835 fi
2836
2837 if test "$ol_enable_dds" != no ; then
2838         BUILD_DDS=$ol_enable_dds
2839         if test "$ol_enable_dds" = mod ; then
2840                 MFLAG=SLAPD_MOD_DYNAMIC
2841                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dds.la"
2842         else
2843                 MFLAG=SLAPD_MOD_STATIC
2844                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dds.o"
2845         fi
2846         AC_DEFINE_UNQUOTED(SLAPD_OVER_DDS,$MFLAG,[define for Dynamic Directory Services overlay])
2847 fi
2848
2849 if test "$ol_enable_deref" != no ; then
2850         BUILD_DEREF=$ol_enable_deref
2851         if test "$ol_enable_deref" = mod ; then
2852                 MFLAG=SLAPD_MOD_DYNAMIC
2853                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS deref.la"
2854         else
2855                 MFLAG=SLAPD_MOD_STATIC
2856                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS deref.o"
2857         fi
2858         AC_DEFINE_UNQUOTED(SLAPD_OVER_DEREF,$MFLAG,[define for Dynamic Directory Services overlay])
2859 fi
2860
2861 if test "$ol_enable_dyngroup" != no ; then
2862         BUILD_DYNGROUP=$ol_enable_dyngroup
2863         if test "$ol_enable_dyngroup" = mod ; then
2864                 MFLAG=SLAPD_MOD_DYNAMIC
2865                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dyngroup.la"
2866         else
2867                 MFLAG=SLAPD_MOD_STATIC
2868                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dyngroup.o"
2869         fi
2870         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNGROUP,$MFLAG,[define for Dynamic Group overlay])
2871 fi
2872
2873 if test "$ol_enable_dynlist" != no ; then
2874         BUILD_DYNLIST=$ol_enable_dynlist
2875         if test "$ol_enable_dynlist" = mod ; then
2876                 MFLAG=SLAPD_MOD_DYNAMIC
2877                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dynlist.la"
2878         else
2879                 MFLAG=SLAPD_MOD_STATIC
2880                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dynlist.o"
2881         fi
2882         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNLIST,$MFLAG,[define for Dynamic List overlay])
2883 fi
2884
2885 if test "$ol_enable_memberof" != no ; then
2886         BUILD_MEMBEROF=$ol_enable_memberof
2887         if test "$ol_enable_memberof" = mod ; then
2888                 MFLAG=SLAPD_MOD_DYNAMIC
2889                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS memberof.la"
2890         else
2891                 MFLAG=SLAPD_MOD_STATIC
2892                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS memberof.o"
2893         fi
2894         AC_DEFINE_UNQUOTED(SLAPD_OVER_MEMBEROF,$MFLAG,[define for Reverse Group Membership overlay])
2895 fi
2896
2897 if test "$ol_enable_ppolicy" != no ; then
2898         BUILD_PPOLICY=$ol_enable_ppolicy
2899         if test "$ol_enable_ppolicy" = mod ; then
2900                 MFLAG=SLAPD_MOD_DYNAMIC
2901                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS ppolicy.la"
2902         else
2903                 MFLAG=SLAPD_MOD_STATIC
2904                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS ppolicy.o"
2905         fi
2906         AC_DEFINE_UNQUOTED(SLAPD_OVER_PPOLICY,$MFLAG,[define for Password Policy overlay])
2907 fi
2908
2909 if test "$ol_enable_proxycache" != no ; then
2910         BUILD_PROXYCACHE=$ol_enable_proxycache
2911         if test "$ol_enable_proxycache" = mod ; then
2912                 MFLAG=SLAPD_MOD_DYNAMIC
2913                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS pcache.la"
2914         else
2915                 MFLAG=SLAPD_MOD_STATIC
2916                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS pcache.o"
2917         fi
2918         AC_DEFINE_UNQUOTED(SLAPD_OVER_PROXYCACHE,$MFLAG,[define for Proxy Cache overlay])
2919 fi
2920
2921 if test "$ol_enable_refint" != no ; then
2922         BUILD_REFINT=$ol_enable_refint
2923         if test "$ol_enable_refint" = mod ; then
2924                 MFLAG=SLAPD_MOD_DYNAMIC
2925                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS refint.la"
2926         else
2927                 MFLAG=SLAPD_MOD_STATIC
2928                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS refint.o"
2929         fi
2930         AC_DEFINE_UNQUOTED(SLAPD_OVER_REFINT,$MFLAG,[define for Referential Integrity overlay])
2931 fi
2932
2933 if test "$ol_enable_retcode" != no ; then
2934         BUILD_RETCODE=$ol_enable_retcode
2935         if test "$ol_enable_retcode" = mod ; then
2936                 MFLAG=SLAPD_MOD_DYNAMIC
2937                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS retcode.la"
2938         else
2939                 MFLAG=SLAPD_MOD_STATIC
2940                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS retcode.o"
2941         fi
2942         AC_DEFINE_UNQUOTED(SLAPD_OVER_RETCODE,$MFLAG,[define for Referential Integrity overlay])
2943 fi
2944
2945 if test "$ol_enable_rwm" != no ; then
2946         BUILD_REWRITE=yes
2947         BUILD_RWM=$ol_enable_rwm
2948         if test "$ol_enable_rwm" = mod ; then
2949                 MFLAG=SLAPD_MOD_DYNAMIC
2950                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS rwm.la"
2951         else
2952                 MFLAG=SLAPD_MOD_STATIC
2953                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS rwm_x.o"
2954         fi
2955         AC_DEFINE_UNQUOTED(SLAPD_OVER_RWM,$MFLAG,[define for Rewrite/Remap overlay])
2956 fi
2957
2958 if test "$ol_enable_seqmod" != no ; then
2959         BUILD_SEQMOD=$ol_enable_seqmod
2960         if test "$ol_enable_seqmod" = mod ; then
2961                 MFLAG=SLAPD_MOD_DYNAMIC
2962                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS seqmod.la"
2963         else
2964                 MFLAG=SLAPD_MOD_STATIC
2965                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS seqmod.o"
2966         fi
2967         AC_DEFINE_UNQUOTED(SLAPD_OVER_SEQMOD,$MFLAG,[define for Sequential Modify overlay])
2968 fi
2969
2970 if test "$ol_enable_sssvlv" != no ; then
2971         BUILD_SSSVLV=$ol_enable_sssvlv
2972         if test "$ol_enable_sssvlv" = mod ; then
2973                 MFLAG=SLAPD_MOD_DYNAMIC
2974                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS sssvlv.la"
2975         else
2976                 MFLAG=SLAPD_MOD_STATIC
2977                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS sssvlv.o"
2978         fi
2979         AC_DEFINE_UNQUOTED(SLAPD_OVER_SSSVLV,$MFLAG,[define for ServerSideSort/VLV overlay])
2980 fi
2981
2982 if test "$ol_enable_syncprov" != no ; then
2983         BUILD_SYNCPROV=$ol_enable_syncprov
2984         if test "$ol_enable_syncprov" = mod ; then
2985                 MFLAG=SLAPD_MOD_DYNAMIC
2986                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS syncprov.la"
2987         else
2988                 MFLAG=SLAPD_MOD_STATIC
2989                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS syncprov.o"
2990         fi
2991         AC_DEFINE_UNQUOTED(SLAPD_OVER_SYNCPROV,$MFLAG,[define for Syncrepl Provider overlay])
2992 fi
2993
2994 if test "$ol_enable_translucent" != no ; then
2995         BUILD_TRANSLUCENT=$ol_enable_translucent
2996         if test "$ol_enable_translucent" = mod ; then
2997                 MFLAG=SLAPD_MOD_DYNAMIC
2998                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS translucent.la"
2999         else
3000                 MFLAG=SLAPD_MOD_STATIC
3001                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS translucent.o"
3002         fi
3003         AC_DEFINE_UNQUOTED(SLAPD_OVER_TRANSLUCENT,$MFLAG,[define for Translucent Proxy overlay])
3004 fi
3005
3006 if test "$ol_enable_unique" != no ; then
3007         BUILD_UNIQUE=$ol_enable_unique
3008         if test "$ol_enable_unique" = mod ; then
3009                 MFLAG=SLAPD_MOD_DYNAMIC
3010                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS unique.la"
3011         else
3012                 MFLAG=SLAPD_MOD_STATIC
3013                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS unique.o"
3014         fi
3015         AC_DEFINE_UNQUOTED(SLAPD_OVER_UNIQUE,$MFLAG,[define for Attribute Uniqueness overlay])
3016 fi
3017
3018 if test "$ol_enable_valsort" != no ; then
3019         BUILD_VALSORT=$ol_enable_valsort
3020         if test "$ol_enable_valsort" = mod ; then
3021                 MFLAG=SLAPD_MOD_DYNAMIC
3022                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS valsort.la"
3023         else
3024                 MFLAG=SLAPD_MOD_STATIC
3025                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS valsort.o"
3026         fi
3027         AC_DEFINE_UNQUOTED(SLAPD_OVER_VALSORT,$MFLAG,[define for Value Sorting overlay])
3028 fi
3029
3030 if test "$ol_enable_rewrite" != no ; then
3031         AC_DEFINE(ENABLE_REWRITE,1,[define to enable rewriting in back-ldap and back-meta])
3032         BUILD_REWRITE=yes
3033 fi
3034
3035 if test "$ol_enable_slapi" != no ; then
3036         AC_DEFINE(ENABLE_SLAPI,1,[define to enable slapi library])
3037         BUILD_SLAPI=yes
3038         SLAPD_SLAPI_DEPEND=libslapi.a
3039 fi
3040
3041 dnl ----------------------------------------------------------------
3042
3043 dnl
3044 dnl For Windows build, we don't want to include -dlopen flags.
3045 dnl They hurt more than they help.
3046 dnl
3047
3048 if test "$ac_cv_mingw32" = yes -o $ol_cv_msvc = yes ; then
3049         PLAT=NT
3050         SLAPD_MODULES_LDFLAGS=
3051 else
3052         PLAT=UNIX
3053 fi
3054
3055 AC_SUBST(LIBSRCS)
3056 AC_SUBST(PLAT)
3057 AC_SUBST(WITH_SASL)
3058 AC_SUBST(WITH_TLS)
3059 AC_SUBST(WITH_MODULES_ENABLED)
3060 AC_SUBST(WITH_ACI_ENABLED)
3061 AC_SUBST(BUILD_THREAD)
3062 AC_SUBST(BUILD_LIBS_DYNAMIC)
3063
3064 AC_SUBST(BUILD_SLAPD)
3065 dnl slapi
3066   AC_SUBST(BUILD_SLAPI)
3067   AC_SUBST(SLAPD_SLAPI_DEPEND)
3068 dnl backends
3069   AC_SUBST(BUILD_BDB)
3070   AC_SUBST(BUILD_DNSSRV)
3071   AC_SUBST(BUILD_HDB)
3072   AC_SUBST(BUILD_LDAP)
3073   AC_SUBST(BUILD_META)
3074   AC_SUBST(BUILD_MONITOR)
3075   AC_SUBST(BUILD_NDB)
3076   AC_SUBST(BUILD_NULL)
3077   AC_SUBST(BUILD_PASSWD)
3078   AC_SUBST(BUILD_RELAY)
3079   AC_SUBST(BUILD_PERL)
3080   AC_SUBST(BUILD_SHELL)
3081   AC_SUBST(BUILD_SOCK)
3082   AC_SUBST(BUILD_SQL)
3083 dnl overlays
3084   AC_SUBST(BUILD_ACCESSLOG)
3085   AC_SUBST(BUILD_AUDITLOG)
3086   AC_SUBST(BUILD_COLLECT)
3087   AC_SUBST(BUILD_CONSTRAINT)
3088   AC_SUBST(BUILD_DDS)
3089   AC_SUBST(BUILD_DENYOP)
3090   AC_SUBST(BUILD_DEREF)
3091   AC_SUBST(BUILD_DYNGROUP)
3092   AC_SUBST(BUILD_DYNLIST)
3093   AC_SUBST(BUILD_LASTMOD)
3094   AC_SUBST(BUILD_MEMBEROF)
3095   AC_SUBST(BUILD_PPOLICY)
3096   AC_SUBST(BUILD_PROXYCACHE)
3097   AC_SUBST(BUILD_REFINT)
3098   AC_SUBST(BUILD_RETCODE)
3099   AC_SUBST(BUILD_RWM)
3100   AC_SUBST(BUILD_SEQMOD)
3101   AC_SUBST(BUILD_SSSVLV)
3102   AC_SUBST(BUILD_SYNCPROV)
3103   AC_SUBST(BUILD_TRANSLUCENT)
3104   AC_SUBST(BUILD_UNIQUE)
3105   AC_SUBST(BUILD_VALSORT)
3106
3107 AC_SUBST(LDAP_LIBS)
3108 AC_SUBST(SLAPD_LIBS)
3109 AC_SUBST(BDB_LIBS)
3110 AC_SUBST(SLAPD_NDB_LIBS)
3111 AC_SUBST(SLAPD_NDB_INCS)
3112 AC_SUBST(LTHREAD_LIBS)
3113 AC_SUBST(LUTIL_LIBS)
3114 AC_SUBST(WRAP_LIBS)
3115
3116 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
3117 AC_SUBST(SLAPD_MODULES_LDFLAGS)
3118
3119 AC_SUBST(SLAPD_NO_STATIC)
3120 AC_SUBST(SLAPD_STATIC_BACKENDS)
3121 AC_SUBST(SLAPD_DYNAMIC_BACKENDS)
3122 AC_SUBST(SLAPD_STATIC_OVERLAYS)
3123 AC_SUBST(SLAPD_DYNAMIC_OVERLAYS)
3124
3125 AC_SUBST(PERL_CPPFLAGS)
3126 AC_SUBST(SLAPD_PERL_LDFLAGS)
3127 AC_SUBST(MOD_PERL_LDFLAGS)
3128
3129 AC_SUBST(KRB4_LIBS)
3130 AC_SUBST(KRB5_LIBS)
3131 AC_SUBST(SASL_LIBS)
3132 AC_SUBST(TLS_LIBS)
3133 AC_SUBST(MODULES_LIBS)
3134 AC_SUBST(SLAPI_LIBS)
3135 AC_SUBST(LIBSLAPI)
3136 AC_SUBST(LIBSLAPITOOLS)
3137 AC_SUBST(AUTH_LIBS)
3138 AC_SUBST(ICU_LIBS)
3139
3140 AC_SUBST(SLAPD_SLP_LIBS)
3141 AC_SUBST(SLAPD_GMP_LIBS)
3142
3143 AC_SUBST(SLAPD_SQL_LDFLAGS)
3144 AC_SUBST(SLAPD_SQL_LIBS)
3145 AC_SUBST(SLAPD_SQL_INCLUDES)
3146
3147 dnl ----------------------------------------------------------------
3148 dnl final help output
3149 AC_ARG_WITH(xxinstall,[
3150 See INSTALL file for further details.])
3151
3152 dnl ----------------------------------------------------------------
3153 dnl final output
3154 dnl
3155
3156 AC_CONFIG_FILES([Makefile:build/top.mk:Makefile.in:build/dir.mk]
3157 [doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk]
3158 [doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk]
3159 [doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk]
3160 [doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk]
3161 [doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk]
3162 [doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk]
3163 [clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk]
3164 [clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk]
3165 [include/Makefile:build/top.mk:include/Makefile.in]
3166 [libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk]
3167 [libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk]
3168 [libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk]
3169 [libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk]
3170 [libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk]
3171 [libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk]
3172 [libraries/librewrite/Makefile:build/top.mk:libraries/librewrite/Makefile.in:build/lib.mk:build/lib-static.mk]
3173 [servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk]
3174 [servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk]
3175 [servers/slapd/back-bdb/Makefile:build/top.mk:servers/slapd/back-bdb/Makefile.in:build/mod.mk]
3176 [servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk]
3177 [servers/slapd/back-hdb/Makefile:build/top.mk:servers/slapd/back-hdb/Makefile.in:build/mod.mk]
3178 [servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk]
3179 [servers/slapd/back-ldif/Makefile:build/top.mk:servers/slapd/back-ldif/Makefile.in:build/mod.mk]
3180 [servers/slapd/back-meta/Makefile:build/top.mk:servers/slapd/back-meta/Makefile.in:build/mod.mk]
3181 [servers/slapd/back-monitor/Makefile:build/top.mk:servers/slapd/back-monitor/Makefile.in:build/mod.mk]
3182 [servers/slapd/back-ndb/Makefile:build/top.mk:servers/slapd/back-ndb/Makefile.in:build/mod.mk]
3183 [servers/slapd/back-null/Makefile:build/top.mk:servers/slapd/back-null/Makefile.in:build/mod.mk]
3184 [servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk]
3185 [servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk]
3186 [servers/slapd/back-relay/Makefile:build/top.mk:servers/slapd/back-relay/Makefile.in:build/mod.mk]
3187 [servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk]
3188 [servers/slapd/back-sock/Makefile:build/top.mk:servers/slapd/back-sock/Makefile.in:build/mod.mk]
3189 [servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk]
3190 [servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk]
3191 [servers/slapd/slapi/Makefile:build/top.mk:servers/slapd/slapi/Makefile.in:build/lib.mk:build/lib-shared.mk]
3192 [servers/slapd/overlays/Makefile:build/top.mk:servers/slapd/overlays/Makefile.in:build/lib.mk]
3193 [tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk]
3194 [tests/run]
3195 [tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk])
3196
3197 AC_CONFIG_COMMANDS([default],[[
3198 chmod +x tests/run
3199 date > stamp-h
3200 BACKENDSC="servers/slapd/backends.c"
3201 echo "Making $BACKENDSC"
3202 rm -f $BACKENDSC
3203 cat > $BACKENDSC << ENDX
3204 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
3205  *
3206  * Copyright 1998-2011 The OpenLDAP Foundation.
3207  * All rights reserved.
3208  *
3209  * Redistribution and use in source and binary forms, with or without
3210  * modification, are permitted only as authorized by the OpenLDAP
3211  * Public License.
3212  *
3213  * A copy of this license is available in the file LICENSE in the
3214  * top-level directory of the distribution or, alternatively, at
3215  * <http://www.OpenLDAP.org/license.html>.
3216  */
3217 /* This file is automatically generated by configure; please do not edit. */
3218
3219 #include "portable.h"
3220 #include "slap.h"
3221
3222 ENDX
3223 if test "${STATIC_BACKENDS}"; then
3224         for b in config ${STATIC_BACKENDS}; do
3225                 bb=`echo "${b}" | sed -e 's/back-//'`
3226                 cat >> $BACKENDSC << ENDX
3227 extern BI_init ${bb}_back_initialize;
3228 ENDX
3229         done
3230
3231         cat >> $BACKENDSC << ENDX
3232
3233 BackendInfo slap_binfo[] = {
3234 ENDX
3235
3236         for b in config ${STATIC_BACKENDS}; do
3237                 bb=`echo "${b}" | sed -e 's/back-//'`
3238                 echo "    Add ${bb} ..."
3239                 cat >> $BACKENDSC << ENDX
3240         { "${bb}", ${bb}_back_initialize },
3241 ENDX
3242         done
3243
3244         cat >> $BACKENDSC << ENDX
3245         { NULL, NULL },
3246 };
3247
3248 /* end of generated file */
3249 ENDX
3250 fi
3251 OVERLAYSC="servers/slapd/overlays/statover.c"
3252 echo "Making $OVERLAYSC"
3253 rm -f $OVERLAYSC
3254 cat > $OVERLAYSC << ENDX
3255 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
3256  *
3257  * Copyright 1998-2011 The OpenLDAP Foundation.
3258  * All rights reserved.
3259  *
3260  * Redistribution and use in source and binary forms, with or without
3261  * modification, are permitted only as authorized by the OpenLDAP
3262  * Public License.
3263  *
3264  * A copy of this license is available in the file LICENSE in the
3265  * top-level directory of the distribution or, alternatively, at
3266  * <http://www.OpenLDAP.org/license.html>.
3267  */
3268 /* This file is automatically generated by configure; please do not edit. */
3269
3270 #include "portable.h"
3271 #include "slap.h"
3272
3273 ENDX
3274 if test "${STATIC_OVERLAYS}"; then
3275         for o in ${STATIC_OVERLAYS}; do
3276                 oo=`echo "${o}" | sed -e 's/.o$//' -e 's/_x$//'`
3277                 cat >> $OVERLAYSC << ENDX
3278 extern OV_init ${oo}_initialize;
3279 ENDX
3280         done
3281 fi
3282
3283 cat >> $OVERLAYSC << ENDX
3284
3285 OverlayInit slap_oinfo[] = {
3286 ENDX
3287
3288 if test "${STATIC_OVERLAYS}"; then
3289         for o in ${STATIC_OVERLAYS}; do
3290                 oo=`echo "${o}" | sed -e 's/.o$//' -e 's/_x$//'`
3291                 echo "    Add ${oo} ..."
3292                 cat >> $OVERLAYSC << ENDX
3293         { "${oo}", ${oo}_initialize },
3294 ENDX
3295         done
3296 fi
3297
3298         cat >> $OVERLAYSC << ENDX
3299         { NULL, NULL },
3300 };
3301
3302 /* end of generated file */
3303 ENDX
3304
3305 if test "${ol_cv_mkdep}" = no; then
3306         echo '(Do not "make depend"; we do not know how to build dependencies)'
3307 else
3308         echo 'Please run "make depend" to build dependencies'
3309 fi
3310 ]],[[
3311 STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS"
3312 STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS"
3313 ]])
3314 AC_OUTPUT