git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8 dnl Configure.in for OpenLDAP
   9 dnl
  10 AC_INIT(include/ldap.h)
  11 dnl
  12 dnl
  13 AC_PREREQ(2.10)dnl Required Autoconf version
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_CONFIG_AUX_DIR(build)
  18 AC_CONFIG_HEADER(include/portable.h)dnl
  19 dnl
  20 dnl Start Args
  21 AC_MSG_CHECKING(configure arguments)
  22 AC_PREFIX_DEFAULT(/usr/local)
  23
  24 dnl General "enable" options
  25 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  26 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  27 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  28 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  29 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  30 OL_ARG_ENABLE(dns,[  --enable-dns               enable dns support], no)dnl
  31 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable referrals], yes)dnl
  32 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  33 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  34         no, [yes no])dnl
  35
  36 dnl General "with" options
  37 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  38         auto, [auto k5 k4 afs yes no])
  39 OL_ARG_WITH(threads,[  --with-threads   use threads],
  40         auto, [auto posix mach lwp yes no manual] )
  41 OL_ARG_WITH(preemptive,[  --with-preemptive     thread implementation is preemptive],
  42         auto, [auto yes no manual] )
  43
  44 dnl Server options
  45
  46 dnl LDAPD OPTIONS
  47 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  48
  49 dnl SLAPD OPTIONS
  50 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  51 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  52 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  53 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  54 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  55 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  56 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  57 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  58
  59 dnl SLAPD Backend options
  60 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  61 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  62         [auto db2 db gdbm ndbm manual])
  63 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  64         [auto btree hash])
  65
  66 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  67 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  68
  69 dnl SLURPD OPTIONS
  70 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  71
  72 # validate options
  73 if test $ol_enable_referrals = no ; then
  74         if test $ol_enable_dns = yes ; then
  75                 AC_MSG_WARN([dns disabled, ignoring --enable-dns argument])
  76         fi
  77         ol_enable_dns=no
  78 fi
  79
  80 if test $ol_enable_slapd = no ; then
  81         dnl SLAPD was specificallly disabled
  82         if test $ol_enable_ldbm = yes ; then
  83                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
  84         fi
  85         if test $ol_enable_passwd = yes ; then
  86                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
  87         fi
  88         if test $ol_enable_shell = yes ; then
  89                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
  90         fi
  91         if test $ol_enable_aclgroups = yes ; then
  92                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
  93         fi
  94         if test $ol_enable_crypt = yes ; then
  95                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument])
  96         fi
  97         if test $ol_enable_md5 = yes ; then
  98                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument])
  99         fi
 100         if test $ol_enable_sha1 = yes ; then
 101                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument])
 102         fi
 103         if test $ol_enable_wrappers = yes ; then
 104                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 105         fi
 106         if test $ol_enable_phonetic = yes ; then
 107                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 108         fi
 109         if test $ol_enable_rlookups = yes ; then
 110                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 111         fi
 112         if test $ol_with_ldbm_api != auto ; then
 113                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 114         fi
 115         if test $ol_with_ldbm_type != auto ; then
 116                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 117         fi
 118         if test $ol_enable_slurpd = yes ; then
 119                 AC_MSG_ERROR([slurpd requires slapd])
 120         fi
 121
 122         # force settings to no
 123         ol_enable_ldbm=no
 124         ol_enable_shell=no
 125         ol_enable_passwd=no
 126         ol_enable_aclgroups=no
 127         ol_enable_crypt=no
 128         ol_enable_md5=no
 129         ol_enable_sha1=no
 130         ol_enable_wrappers=no
 131         ol_enable_phonetic=no
 132         ol_enable_rlookups=no
 133         ol_with_ldbm_api=no
 134         ol_with_ldbm_type=no
 135         ol_enable_slurpd=no
 136
 137 elif test $ol_enable_ldbm = no ; then
 138         dnl SLAPD without LDBM
 139
 140         if test $ol_with_ldbm_api != auto ; then
 141                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 142         fi
 143
 144         if test $ol_with_ldbm_type != auto ; then
 145                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 146         fi
 147
 148         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 149                 AC_MSG_ERROR([slapd requires a backend])
 150         fi
 151
 152         ol_with_ldbm_api=no
 153         ol_with_ldbm_type=no
 154
 155 else
 156         dnl SLAPD with LDBM
 157
 158         if test $ol_with_ldbm_api = gdbm -a \
 159                 $ol_with_ldbm_type = btree ; then
 160                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 161         fi
 162         if test $ol_with_ldbm_api = ndbm -a \
 163                 $ol_with_ldbm_type = btree ; then
 164                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 165         fi
 166 fi
 167
 168 if test $ol_enable_slurpd = yes ; then
 169         dnl SLURPD was specifically enabled
 170         if test $ol_with_threads = no ; then
 171                 AC_MSG_ERROR([slurpd requires threads])
 172         fi
 173 fi
 174
 175 AC_MSG_RESULT(done)
 176
 177 ## Initialize vars
 178 LDAP_LIBS=
 179 LDBM_LIBS=
 180 LTHREAD_LIBS=
 181 LUTIL_LIBS=
 182
 183 LDAPD_LIBS=
 184 SLAPD_LIBS=
 185 SLURPD_LIBS=
 186
 187 BUILD_LDAPD=no
 188 BUILD_SLAPD=no
 189 BUILD_SLURPD=no
 190
 191 BUILD_LDBM=no
 192 BUILD_PASSWD=no
 193 BUILD_SHELL=no
 194 BUILD_THREAD=no
 195
 196 KRB_LIBS=
 197 TERMCAP_LIBS=
 198
 199 dnl ----------------------------------------------------------------
 200 dnl Checks for programs
 201
 202 AC_PROG_LN_S
 203 AC_PROG_INSTALL
 204 AC_PROG_RANLIB
 205 AC_PROG_MAKE_SET
 206
 207 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 208         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 209 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 210 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 211
 212 dnl Checks the compiler and UNIX Variants
 213 AC_PROG_CC
 214
 215 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 216         AC_WARN([cross compiling....  some functionality will be removed.])
 217
 218 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 219         AC_WARN([programs compiled here do run here...])
 220         AC_ERROR([  if not cross compiling, use --disable-x-compile.])
 221
 222 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 223         AC_WARN([programs compiled here do not run here...])
 224         AC_ERROR([  if cross compiling,  add --enable-x-compile.])
 225 fi
 226
 227 dnl OpenLDAP requires STDC features
 228 dnl AC_PROG_GCC_TRADITIONAL
 229 AC_PROG_CPP
 230
 231
 232 AC_AIX
 233 AC_ISC_POSIX
 234 AC_MINIX
 235
 236 dnl Checks for libraries
 237
 238 dnl Find socket()
 239 dnl Likely combinations:
 240 dnl             -lsocket [ -lnsl_s | -lnsl ]
 241 dnl             -linet
 242
 243 AC_CHECK_FUNC(socket, :, [
 244 dnl
 245 dnl hopefully we won't include too many libraries
 246 dnl
 247         AC_CHECK_LIB(socket, main)
 248         AC_CHECK_LIB(net, main)
 249         AC_CHECK_LIB(nsl_s, main)
 250         AC_CHECK_LIB(nsl, main)
 251         AC_CHECK_LIB(inet, socket)
 252         AC_CHECK_LIB(gen, main)
 253 ])
 254
 255 dnl Check for resolv
 256 AC_CHECK_LIB(resolv, res_search)
 257
 258 dnl HP-UX requires -lV3
 259 AC_CHECK_LIB(V3, sigset)
 260
 261 # ISODE tests
 262 ol_link_isode=no
 263 if test $ol_enable_ldapd != no ; then
 264         dnl look for ISODE libraries
 265         AC_CHECK_LIB(xtpp, main, [
 266                 ol_link_isode=yes
 267                 AC_DEFINE(HAVE_XTPP,1)
 268                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 269                 ],:,[-lxtdsap -lxtisode -losi])
 270         AC_CHECK_LIB(dsap, main, [
 271                 ol_link_isode=yes
 272                 AC_DEFINE(HAVE_DSAP,1)
 273                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 274                 ],:,[-lisode])
 275         AC_CHECK_LIB(isode, main, [
 276                 ol_link_isode=yes
 277                 AC_DEFINE(HAVE_ISODE,1)
 278                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 279                 ],:)
 280 fi
 281
 282 if test $ol_link_isode != no; then
 283         AC_CHECK_LIB(pp, main, [
 284                 AC_DEFINE(HAVE_PP,1)
 285                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 286                 ],:)
 287
 288         AC_PATH_PROG(PEPSY, pepsy)
 289 fi
 290
 291 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 292         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 293
 294         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 295                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 296                         [-lkrb5 -ldes425])
 297
 298                 if test $have_k5 = yes ; then
 299                         ol_with_kerberos=found
 300                         ol_link_kerberos=yes
 301
 302                         AC_DEFINE(HAVE_KERBEROS)
 303
 304                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 305                 fi
 306         fi
 307 fi
 308 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 309         AC_CHECK_HEADERS(krb.h des.h)
 310
 311         if test $ac_cv_header_krb_h = yes ; then
 312                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 313
 314                 if test $have_k4 = yes ; then
 315                         ol_with_kerberos=found
 316                         ol_link_kerberos=yes
 317
 318                         AC_DEFINE(HAVE_KERBEROS)
 319
 320                         KRB_LIBS="-lkrb -ldes"
 321                 fi
 322         fi
 323 fi
 324
 325 ol_link_threads=no
 326 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 327         AC_CHECK_HEADERS(pthread.h sched.h)
 328
 329         if test $ac_cv_header_pthread_h = yes ; then
 330                 OL_POSIX_THREAD_VERSION
 331
 332                 if test $ol_cv_pthread_version = final ; then
 333                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 334                 elif test $ol_cv_pthread_version = draft4 ; then
 335                         AC_DEFINE(HAVE_PTHREADS_D4)
 336                 else
 337                         AC_MSG_ERROR([unknown pthread version])
 338                 fi
 339
 340                 # consider threads found
 341                 ol_with_threads=found
 342
 343                 OL_LINUX_THREADS
 344
 345                 if test $ol_cv_linux_threads = yes ; then
 346                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 347                 fi
 348
 349                 dnl Now the hard part, how to link
 350
 351                 dnl A few platforms have pthread support in standard libraries
 352                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 353
 354                 if test $ol_link_threads = no ; then
 355                         dnl try -pthread
 356                         AC_CACHE_CHECK([for pthread_create with -pthread],
 357                                 [ol_cv_pthread_flag], [
 358                                 dnl save the flags
 359                                 save_LIBS="$LIBS"
 360                                 LIBS="-pthread $LIBS"
 361                                 AC_TRY_LINK([char pthread();],[
 362                                         pthread_create();
 363                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 364                                 dnl restore the LIBS
 365                                 LIBS="$save_LIBS"
 366                         ])
 367
 368                         if test $ol_cv_pthread_flag = yes ; then
 369                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 370                                 ol_link_threads=posix
 371                         fi
 372                 fi
 373
 374                 if test $ol_link_threads = no ; then
 375                         dnl try -thread
 376                         AC_CACHE_CHECK([for pthread_create with -thread],
 377                                 [ol_cv_thread_flag], [
 378                                 dnl save the flags
 379                                 save_LIBS="$LIBS"
 380                                 LIBS="-thread $LIBS"
 381                                 AC_TRY_LINK([char pthread();],[
 382                                         pthread_create();
 383                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 384                                 dnl restore the LIBS
 385                                 LIBS="$save_LIBS"
 386                         ])
 387
 388                         if test $ol_cv_thread_flag = yes ; then
 389                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 390                                 ol_link_threads=posix
 391                         fi
 392                 fi
 393
 394                 if test $ol_link_threads = no ; then
 395                         dnl try DEC Threads -lpthread -lexc
 396                         save_LIBS="$LIBS"
 397                         AC_CHECK_LIB(pthread, pthread_join, [
 398                                 ol_link_threads=posix
 399                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 400                                 if test $ol_with_preemptive = auto ; then
 401                                         ol_with_preemptive=yes
 402                                 fi
 403                                 ],,[-lexc])
 404                         LIBS="$save_LIBS"
 405                 fi
 406
 407                 if test $ol_link_threads = no ; then
 408                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 409                         save_LIBS="$LIBS"
 410                         AC_CHECK_LIB(pthreads, pthread_join, [
 411                                 ol_link_threads=posix
 412                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 413                                 if test $ol_with_preemptive = auto ; then
 414                                         ol_with_preemptive=yes
 415                                 fi
 416                                 ],,[-lmach -lexc -lc_r])
 417                         LIBS="$save_LIBS"
 418                 fi
 419
 420                 if test $ol_link_threads = no ; then
 421                         dnl try -lpthread
 422                         save_LIBS="$LIBS"
 423                         AC_CHECK_LIB(pthread, pthread_create, [
 424                                 ol_link_threads=posix
 425                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 426                         LIBS="$save_LIBS"
 427                 fi
 428
 429                 if test $ol_link_threads = no ; then
 430                         dnl try -lc_r
 431                         save_LIBS="$LIBS"
 432                         AC_CHECK_LIB(c_r, pthread_create, [
 433                                 ol_link_threads=posix
 434                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 435                         LIBS="$save_LIBS"
 436                 fi
 437
 438                 if test $ol_link_threads != no ; then
 439                         AC_DEFINE(HAVE_PTHREADS)
 440
 441                         dnl save flags
 442                         save_CPPFLAGS="$CPPFLAGS"
 443                         save_LIBS="$LIBS"
 444                         LIBS="$LTHREAD_LIBS $LIBS"
 445
 446                         dnl All POSIX Thread (final) implementations should have
 447                         dnl sched_yield instead of pthread yield.
 448                         dnl check for both
 449                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 450
 451                         if test $ac_cv_func_sched_yield = no -a \
 452                                 $ac_cv_func_pthread_yield = no ; then
 453                                 dnl Digital UNIX has sched_yield() in -lrt
 454                                 AC_CHECK_LIB(rt, sched_yield,
 455                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 456                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 457                                         ac_cv_func_sched_yield=yes],
 458                                         [ac_cv_func_sched_yield=no])
 459                         fi
 460                         if test $ac_cv_func_sched_yield = no -a \
 461                                 $ac_cv_func_pthread_yield = no ; then
 462                                 dnl Solaris has sched_yield() in -lposix4
 463                                 AC_CHECK_LIB(posix4, sched_yield,
 464                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 465                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 466                                         ac_cv_func_sched_yield=yes],
 467                                         [ac_cv_func_sched_yield=no])
 468                         fi
 469                         if test $ac_cv_func_sched_yield = no -a \
 470                                 $ac_cv_func_pthread_yield = no ; then
 471                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 472                                 AC_MSG_ERROR([POSIX Threads are not usable])
 473                         fi
 474
 475                         dnl Check functions for compatibility
 476                         AC_CHECK_FUNCS(pthread_kill)
 477                         AC_CHECK_FUNCS( \
 478                                 pthread_attr_create pthread_attr_init \
 479                                 pthread_attr_destroy pthread_attr_delete \
 480                                 pthread_attr_setdetachstate pthread_attr_setdetach_np \
 481                         )
 482
 483                         dnl Check for setconcurreny functions
 484                         AC_CHECK_FUNCS( \
 485                                 pthread_setconcurrency \
 486                                 thr_setconcurrency \
 487                         )
 488
 489                         dnl Check PREEMPTIVE Implementation
 490                         if test $ol_with_preemptive = auto ; then
 491                                 AC_MSG_CHECKING([for preemptive Pthread implementation])
 492                                 AC_TRY_RUN([
 493 #include <sys/types.h>
 494 #include <sys/time.h>
 495 #include <unistd.h>
 496 #include <pthread.h>
 497 #ifndef NULL
 498 #define NULL 0
 499 #endif
 500
 501 int task(arg)
 502         int *arg;
 503 {
 504         int i;
 505         struct timeval tv;
 506
 507         tv.tv_sec=5;
 508         tv.tv_usec=0;
 509
 510         /* we're not interested in any fds */
 511         i = select(FD_SETSIZE, NULL, NULL, NULL, &tv);
 512
 513         if(i < 0) {
 514                 perror("select");
 515         }
 516
 517         exit(1); /* if we exit here, the select blocked the whole process */
 518 }
 519
 520 main(argc, argv)
 521 int argc; char **argv;
 522 {
 523         pthread_t t;
 524
 525 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 526         (void) pthread_setconcurrency(2);
 527 #else
 528 #ifdef HAVE_THR_SETCONCURRENCY
 529         /* Set Solaris LWP concurrency to 2 */
 530         thr_setconcurrency(2);
 531 #endif
 532 #endif
 533
 534         pthread_create(&t, NULL, (void *) task, NULL);
 535
 536 #if HAVE_SCHED_YIELD
 537         sched_yield();  /* make sure task runs first */
 538 #else
 539 #ifdef HAVE_PTHREAD_YIELD
 540         pthread_yield();        /* make sure task runs first */
 541 #endif
 542 #endif
 543         exit(0);
 544 }
 545                                 ], [ol_pthread_preemptive=yes], [ol_pthread_preemptive=no], [
 546                                 AC_MSG_ERROR([crossing compiling: use --with-preemptive=yes|no|manual])])
 547                                 AC_MSG_RESULT($ol_pthread_preemptive)
 548
 549                                 if test $ol_pthread_preemptive = yes ; then
 550                                         AC_DEFINE(HAVE_PREEMPTIVE_PTHREADS)
 551                                         ol_with_preemptive=yes
 552                                 fi
 553                         fi
 554
 555 dnl                     dnl check for reentrant/threadsafe functions
 556 dnl                     AC_CHECK_FUNCS( \
 557 dnl                             feof_unlocked \
 558 dnl                             unlocked_feof \
 559 dnl                             ftrylockfile \
 560 dnl                             flockfile \
 561 dnl                             putc_unlocked \
 562 dnl                             gmtime_r \
 563 dnl                             strtok_r \
 564 dnl                     )
 565
 566                         dnl restore flags
 567                         CPPFLAGS="$save_CPPFLAGS"
 568                         LIBS="$save_LIBS"
 569                 else
 570                         AC_MSG_ERROR([could not link with POSIX Threads])
 571                 fi
 572         fi
 573
 574         if test $ol_with_threads = posix ; then
 575                 AC_MSG_ERROR([could not locate POSIX Threads])
 576         fi
 577 fi
 578
 579 if test $ol_with_threads = auto -o $ol_with_threads = mach ; then
 580         dnl check for Mach CThreads
 581         AC_CHECK_HEADERS(mach/cthreads.h)
 582         if test $ac_cv_header_mach_cthreads_h = yes ; then
 583                 ol_with_threads=found
 584
 585                 dnl A few platforms have cthread support in standard libraries
 586                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 587
 588                 if test $ol_link_threads = no ; then
 589                         dnl try -all_load
 590                         dnl this test needs work
 591                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 592                                 [ol_cv_cthread_all_load], [
 593                                 dnl save the flags
 594                                 save_LIBS="$LIBS"
 595                                 LIBS="-all_load $LIBS"
 596                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 597                                         cthread_fork((void *)0, (void *)0);
 598                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 599                                 dnl restore the LIBS
 600                                 LIBS="$save_LIBS"
 601                         ])
 602
 603                         if test $ol_cv_cthread_all_load = yes ; then
 604                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 605                                 ol_link_threads=mach
 606                         fi
 607                 fi
 608
 609                 if test $ol_link_threads != no ; then
 610                         : check for cthread specific functionality here
 611                         AC_DEFINE(HAVE_MACH_CTHREADS,1)
 612                 else
 613                         AC_MSG_ERROR([could not link with Mach CThreads])
 614                 fi
 615         fi
 616
 617         if test $ol_with_threads = mach ; then
 618                 AC_MSG_ERROR([could not locate Mach CThreads])
 619         fi
 620 fi
 621
 622 if test $ol_with_threads = auto -o $ol_with_threads = lwp ; then
 623         dnl check for SunOS5 LWP
 624         AC_CHECK_HEADERS(thread.h synch.h)
 625         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 626                 AC_CHECK_LIB(thread, thr_create, [have_lwp=yes], [have_lwp=no])
 627
 628                 if test $have_lwp = yes ; then
 629                         AC_DEFINE(HAVE_THR)
 630                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 631
 632                         if test $ol_with_preemptive = auto ; then
 633                                 ol_with_preemptive=yes
 634                         fi
 635                 fi
 636         fi
 637
 638         dnl check for SunOS4 LWP
 639         AC_CHECK_HEADERS(lwp/lwp.h)
 640         if test $ac_cv_header_lwp_lwp_h = yes ; then
 641                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 642
 643                 if test $have_lwp = yes ; then
 644                         AC_DEFINE(HAVE_LWP)
 645                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 646
 647                         if test $ol_with_preemptive = auto ; then
 648                                 ol_with_preemptive=no
 649                         fi
 650                 fi
 651         fi
 652 fi
 653
 654 if test $ol_with_preemptive = yes ; then
 655         AC_DEFINE(PREEMPTIVE_THREADS,1)
 656 fi
 657
 658 if test $ol_with_threads = manual ; then
 659         dnl User thinks he can manually configure threads.
 660         ol_link_threads=yes
 661
 662         AC_MSG_WARN([thread defines and link options must be set manually])
 663
 664         AC_CHECK_HEADERS(pthread.h sched.h)
 665         AC_CHECK_FUNCS(sched_yield pthread_yield)
 666         OL_LINUX_THREADS
 667
 668         AC_CHECK_HEADERS(mach/cthreads.h)
 669         AC_CHECK_HEADERS(lwp/lwp.h)
 670         AC_CHECK_HEADERS(thread.h synch.h)
 671 fi
 672
 673 if test $ol_with_threads != no ; then
 674         dnl needed to get reentrant/threadsafe versions
 675         dnl
 676         AC_DEFINE(_REENTRANT,1)
 677         AC_DEFINE(_THREAD_SAFE,1)
 678         AC_DEFINE(_THREADSAFE,1)
 679
 680         dnl this might cause the errno symbol to be
 681         dnl replaced with a function to get a thread specific errno.
 682         dnl check to see if everything needs to be compiled
 683         dnl with the thread libraries
 684         AC_CACHE_CHECK([for thread specific errno],
 685                 [ol_cv_errno_thread_specific], [
 686                 AC_TRY_LINK([
 687 #include <errno.h>
 688                         ], [
 689 int x = errno;
 690                         ],
 691                         [ol_cv_errno_thread_specific=yes],
 692                         [ol_cv_errno_thread_specific=no])
 693         ])
 694
 695         if test $ol_cv_errno_thread_specific != yes ; then
 696                 LIBS="$LTHREAD_LIBS $LIBS"
 697                 LTHREAD_LIBS=""
 698         fi
 699 fi
 700
 701 dnl ----------------------------------------------------------------
 702
 703 if test $ol_link_threads = no ; then
 704         if test $ol_with_threads = yes ; then
 705                 AC_MSG_ERROR([no suitable thread support])
 706         fi
 707
 708         if test $ol_with_threads = auto ; then
 709                 AC_MSG_WARN([no suitable thread support, disabling threads])
 710                 ol_with_threads=no
 711         fi
 712
 713         AC_DEFINE(NO_THREADS,1)
 714         AC_DEFINE(PREEMPTIVE_THREADS,1)
 715         LTHREAD_LIBS=""
 716 fi
 717
 718 ol_link_ldbm=no
 719 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 720         OL_BERKELEY_DB2
 721
 722         if test $ol_cv_berkeley_db2 = yes ; then
 723                 ol_link_ldbm=db2
 724                 ol_with_ldbm_api=db2
 725
 726                 if test $ol_with_ldbm_type = hash ; then
 727                         AC_DEFINE(LDBM_USE_DBHASH,1)
 728                 else
 729                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 730                 fi
 731
 732                 dnl $ol_cv_lib_db2 should be yes or -ldb
 733                 dnl (it could be no, but that would be an error
 734                 if test $ol_cv_lib_db2 != yes ; then
 735                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 736                 fi
 737         fi
 738 fi
 739
 740 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 741         OL_BERKELEY_DB
 742
 743         if test $ol_cv_berkeley_db = yes ; then
 744                 ol_link_ldbm=db
 745                 ol_with_ldbm_api=db
 746
 747                 if test $ol_with_ldbm_type = hash ; then
 748                         AC_DEFINE(LDBM_USE_DBHASH,1)
 749                 else
 750                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 751                 fi
 752
 753                 dnl $ol_cv_lib_db should be yes or -ldb
 754                 dnl (it could be no, but that would be an error
 755                 if test $ol_cv_lib_db != yes ; then
 756                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 757                 fi
 758         fi
 759 fi
 760
 761 if test $ol_with_ldbm_api = manual ; then
 762         dnl User thinks he can manually configure LDBM api.
 763         ol_link_ldbm=yes
 764
 765         AC_MSG_WARN([LDBM defines and link options must be set manually])
 766
 767         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 768 fi
 769
 770 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 771         AC_MSG_WARN(Could not find LDBM with BTREE support)
 772         ol_with_ldbm_api=none
 773 fi
 774
 775 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 776         OL_GDBM
 777
 778         if test $ol_cv_gdbm = yes ; then
 779                 ol_link_ldbm=gdbm
 780                 ol_with_ldbm_api=gdbm
 781
 782                 if test $ol_cv_lib_gdbm != yes ; then
 783                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 784                 fi
 785         fi
 786 fi
 787
 788 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 789         OL_NDBM
 790
 791         if test $ol_cv_ndbm = yes ; then
 792                 ol_link_ldbm=ndbm
 793                 ol_with_ldbm_api=ndbm
 794
 795                 if test $ol_with_ldbm_api = ndbm ; then
 796                         AC_WARN([Attempting to use NDBM.  Functionality will be limited.])
 797                 fi
 798
 799                 if test $ol_cv_lib_ndbm != yes ; then
 800                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 801                 fi
 802         fi
 803 fi
 804
 805 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 806         AC_MSG_WARN(could not find suitable LDBM backend)
 807         if test $ol_enable_ldbm = yes ; then
 808                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 809         fi
 810
 811         AC_MSG_WARN(disabling LDBM)
 812         ol_enable_ldbm=no
 813 fi
 814
 815 if test $ol_enable_wrappers = yes ; then
 816         AC_CHECK_LIB(wrap, hosts_access,
 817                 [have_wrappers=yes], [have_wrappers=no])
 818
 819         if test $have_wrappers = yes ; then
 820                 AC_DEFINE(HAVE_TCPD)
 821                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 822         else
 823                 AC_MSG_WARN(could not find -lwrap)
 824                 if test $ol_enable_wrappers = yes ; then
 825                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 826                 fi
 827
 828                 AC_MSG_WARN(disabling wrappers support)
 829                 ol_enable_wrappers=no
 830         fi
 831
 832 fi
 833
 834 # ud needs termcap (should insert check here)
 835 ol_link_termcap=no
 836 AC_CHECK_HEADERS(termcap.h ncurses.h)
 837
 838 if test $ol_link_termcap = no ; then
 839         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 840         if test $have_termcap = yes ; then
 841                 AC_DEFINE(HAVE_TERMCAP)
 842                 ol_link_termcap=yes
 843                 TERMCAP_LIBS=-ltermcap
 844         fi
 845 fi
 846
 847 if test $ol_link_termcap = no ; then
 848         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 849         if test $have_ncurses = yes ; then
 850                 AC_DEFINE(HAVE_NCURSES)
 851                 ol_link_termcap=yes
 852                 TERMCAP_LIBS=-lncurses
 853         fi
 854 fi
 855
 856 if test $ol_link_termcap = no ; then
 857         AC_DEFINE(NO_TERMCAP,1)
 858         TERMCAP_LIBS=
 859 fi
 860
 861 # FreeBSD (and others) have crypt(3) in -lcrypt
 862 if test $ol_enable_crypt != no ; then
 863         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 864                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 865                         have_crypt=yes], [have_crypt=no])])
 866
 867         if test $have_crypt = yes ; then
 868                 AC_DEFINE(HAVE_CRYPT,1)
 869         else
 870                 AC_MSG_WARN(could not find crypt)
 871                 if test $ol_enable_crypt = yes ; then
 872                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 873                 fi
 874
 875                 AC_MSG_WARN(disabling crypt support)
 876                 ol_enable_crypt=no
 877         fi
 878 fi
 879
 880 # FreeBSD (and others) have setproctitle(3) in -lutil
 881 if test $ol_enable_proctitle != no ; then
 882         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 883                 AC_CHECK_LIB(util, setproctitle,
 884                         [have_setproctitle=yes
 885                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 886                         [have_setproctitle=no
 887                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 888
 889         if test $have_setproctitle = yes ; then
 890                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 891         fi
 892 fi
 893
 894 dnl ----------------------------------------------------------------
 895 dnl Checks for header files.
 896 AC_HEADER_STDC
 897
 898 if test $ac_cv_header_stdc != yes; then
 899         AC_MSG_WARN([could not locate Standard C headers])
 900 fi
 901
 902 AC_HEADER_DIRENT
 903 AC_HEADER_SYS_WAIT
 904 AC_CHECK_HEADERS(       \
 905         crypt.h                 \
 906         errno.h                 \
 907         fcntl.h                 \
 908         filio.h                 \
 909         getopt.h                \
 910         libutil.h               \
 911         limits.h                \
 912         malloc.h                \
 913         memory.h                \
 914         regex.h                 \
 915         pwd.h                   \
 916         sgtty.h                 \
 917         stdarg.h                \
 918         stddef.h                \
 919         string.h                \
 920         strings.h               \
 921         sys/file.h              \
 922         sys/filio.h             \
 923         sys/errno.h             \
 924         sys/ioctl.h             \
 925         sys/param.h             \
 926         sys/resource.h  \
 927         sys/socket.h    \
 928         sys/syslog.h    \
 929         sys/time.h              \
 930         sys/types.h             \
 931         syslog.h                \
 932         termios.h               \
 933         unistd.h                \
 934 )
 935
 936 dnl ----------------------------------------------------------------
 937 dnl Checks for typedefs, structures, and compiler characteristics.
 938 AC_TYPE_GETGROUPS
 939 AC_TYPE_MODE_T
 940 AC_TYPE_OFF_T
 941 AC_TYPE_PID_T
 942 AC_TYPE_SIGNAL
 943 AC_TYPE_SIZE_T
 944 AC_TYPE_UID_T
 945 AC_STRUCT_ST_BLKSIZE
 946 AC_HEADER_TIME
 947 AC_STRUCT_TM
 948
 949 OL_C_UPPER_LOWER
 950 AC_C_CONST
 951
 952 if test $cross_compiling = yes ; then
 953         AC_DEFINE(CROSS_COMPILING, 1)
 954 else
 955         AC_C_BIGENDIAN
 956         AC_CHECK_SIZEOF(short)
 957         AC_CHECK_SIZEOF(int)
 958         AC_CHECK_SIZEOF(long)
 959 fi
 960
 961 dnl ----------------------------------------------------------------
 962 dnl Checks for library functions.
 963 AC_FUNC_MEMCMP
 964 AC_FUNC_STRFTIME
 965 AC_FUNC_VPRINTF
 966
 967 if test $ac_cv_func_vprintf = yes ; then
 968         dnl check for vsnprintf
 969         AC_CHECK_FUNCS(vsnprintf)
 970 fi
 971
 972 AC_FUNC_WAIT3
 973
 974 AC_CHECK_FUNCS(         \
 975         bcopy                   \
 976         flock                   \
 977         getdtablesize   \
 978         gethostname             \
 979         getpwuid                \
 980         gettimeofday    \
 981         lockf                   \
 982         memcpy                  \
 983         memmove                 \
 984         mkstemp                 \
 985         mktime                  \
 986         res_search              \
 987         select                  \
 988         setpwfile               \
 989         setsid                  \
 990         signal                  \
 991         sigset                  \
 992         snprintf                \
 993         socket                  \
 994         strerror                \
 995         strpbrk                 \
 996         strrchr                 \
 997         strsep                  \
 998         strstr                  \
 999         strtod                  \
1000         strtok                  \
1001         strtol                  \
1002         strtoul                 \
1003         sysconf                 \
1004         waitpid                 \
1005 )
1006
1007 dnl We actually may need to replace more than this.
1008 AC_REPLACE_FUNCS(getopt strdup tempnam)
1009
1010 dnl ----------------------------------------------------------------
1011 # Check Configuration
1012 OL_SYS_ERRLIST
1013
1014 dnl ----------------------------------------------------------------
1015 dnl Sort out defines
1016
1017 if test $ol_enable_debug != no ; then
1018         AC_DEFINE(LDAP_DEBUG,1)
1019 fi
1020 dnl     if test $ol_enable_syslog != no ; then
1021 dnl             AC_DEFINE(LDAP_SYSLOG,1)
1022 dnl     fi
1023 if test $ol_enable_libui = yes ; then
1024         AC_DEFINE(LDAP_LIBUI,1)
1025 fi
1026 if test $ol_enable_cache = no ; then
1027         AC_DEFINE(LDAP_NOCACHE,1)
1028 fi
1029 if test $ol_enable_dns != no ; then
1030         AC_DEFINE(LDAP_DNS,1)
1031 fi
1032 if test $ol_enable_proctitle != no ; then
1033         AC_DEFINE(LDAP_PROCTITLE,1)
1034 fi
1035 if test $ol_enable_referrals != no ; then
1036         AC_DEFINE(LDAP_REFERRALS,1)
1037 fi
1038 if test $ol_enable_cldap != no ; then
1039         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1040 fi
1041
1042 if test $ol_enable_aclgroups != no ; then
1043         AC_DEFINE(SLAPD_ACLGROUPS,1)
1044 fi
1045 if test $ol_enable_crypt != no ; then
1046         AC_DEFINE(SLAPD_CRYPT,1)
1047 fi
1048 if test $ol_enable_md5 != no ; then
1049         AC_DEFINE(SLAPD_MD5,1)
1050 fi
1051 if test $ol_enable_sha1 != no ; then
1052         AC_DEFINE(SLAPD_SHA1,1)
1053 fi
1054 if test $ol_enable_phonetic != no ; then
1055         AC_DEFINE(SLAPD_PHONETIC,1)
1056 fi
1057 if test $ol_enable_rlookups != no ; then
1058         AC_DEFINE(SLAPD_RLOOKUPS,1)
1059 fi
1060
1061 if test $ol_link_ldbm != no ; then
1062         AC_DEFINE(SLAPD_LDBM,1)
1063         BUILD_SLAPD=yes
1064         BUILD_LDBM=yes
1065 fi
1066
1067 if test $ol_enable_passwd != no ; then
1068         AC_DEFINE(SLAPD_PASSWD,1)
1069         BUILD_SLAPD=yes
1070         BUILD_PASSWD=yes
1071 fi
1072
1073 if test $ol_enable_shell != no ; then
1074         AC_DEFINE(SLAPD_SHELL,1)
1075         BUILD_SLAPD=yes
1076         BUILD_SHELL=yes
1077 fi
1078
1079 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
1080         $BUILD_SLAPD = yes ; then
1081         BUILD_SLURPD=yes
1082 fi
1083
1084 if test $ol_link_isode != no ; then
1085         BUILD_LDAPD=yes
1086 fi
1087
1088 dnl ----------------------------------------------------------------
1089
1090 AC_SUBST(BUILD_LDAPD)
1091 AC_SUBST(BUILD_SLAPD)
1092   AC_SUBST(BUILD_LDBM)
1093   AC_SUBST(BUILD_PASSWD)
1094   AC_SUBST(BUILD_SHELL)
1095 AC_SUBST(BUILD_SLURPD)
1096
1097
1098 AC_SUBST(LDAP_LIBS)
1099 AC_SUBST(LDAPD_LIBS)
1100 AC_SUBST(SLAPD_LIBS)
1101 AC_SUBST(SLURPD_LIBS)
1102 AC_SUBST(LDBM_LIBS)
1103 AC_SUBST(LTHREAD_LIBS)
1104 AC_SUBST(LUTIL_LIBS)
1105
1106 AC_SUBST(KRB_LIBS)
1107 AC_SUBST(TERMCAP_LIBS)
1108
1109 dnl ----------------------------------------------------------------
1110 dnl final output
1111 dnl
1112
1113 AC_OUTPUT( \
1114 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1115 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1116 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1117 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1118 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1119 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1120 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1121 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1122 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1123 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1124 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1125 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1126 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1127 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1128 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1129 include/Makefile:build/top.mk:include/Makefile.in \
1130 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1131 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk \
1132 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk \
1133 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk \
1134 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk \
1135 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk \
1136 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk \
1137 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk \
1138 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1139 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1140 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1141 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1142 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1143 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1144 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1145 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1146 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1147 tests/Makefile:build/top.mk:tests/Makefile.in \
1148 ,[
1149 date > stamp-h
1150 echo Please \"make depend\" to build dependencies
1151 ])