git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8 dnl Configure.in for OpenLDAP
   9 dnl
  10 AC_INIT(include/ldap.h)
  11 dnl
  12 dnl
  13 AC_PREREQ(2.10)dnl Required Autoconf version
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_CONFIG_AUX_DIR(build)
  18 AC_CONFIG_HEADER(include/portable.h)dnl
  19 dnl
  20 dnl Start Args
  21 AC_MSG_CHECKING(configure arguments)
  22 AC_PREFIX_DEFAULT(/usr/local)
  23
  24 dnl General "enable" options
  25 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  26 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  27 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  28 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  29 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  30 OL_ARG_ENABLE(dns,[  --enable-dns               enable dns support], no)dnl
  31 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable referrals], yes)dnl
  32 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  33 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  34         no, [yes no])dnl
  35
  36 dnl General "with" options
  37 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  38         auto, [auto k5 k4 afs yes no])
  39 OL_ARG_WITH(threads,[  --with-threads   use threads],
  40         auto, [auto posix mach lwp yes no manual] )
  41 OL_ARG_WITH(preemptive,[  --with-preemptive     thread implementation is preemptive],
  42         auto, [auto yes no manual] )
  43
  44 dnl Server options
  45
  46 dnl LDAPD OPTIONS
  47 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  48
  49 dnl SLAPD OPTIONS
  50 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  51 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  52 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  53 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  54 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  55 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  56 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  57 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  58
  59 dnl SLAPD Backend options
  60 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  61 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  62         [auto db2 db gdbm ndbm manual])
  63 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  64         [auto btree hash])
  65
  66 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  67 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  68
  69 dnl SLURPD OPTIONS
  70 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  71
  72 if test $ol_enable_slapd = no ; then
  73         dnl SLAPD was specificallly disabled
  74         if test $ol_enable_ldbm = yes ; then
  75                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
  76         fi
  77         if test $ol_enable_passwd = yes ; then
  78                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
  79         fi
  80         if test $ol_enable_shell = yes ; then
  81                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
  82         fi
  83         if test $ol_enable_aclgroups = yes ; then
  84                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
  85         fi
  86         if test $ol_enable_crypt = yes ; then
  87                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument])
  88         fi
  89         if test $ol_enable_md5 = yes ; then
  90                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument])
  91         fi
  92         if test $ol_enable_sha1 = yes ; then
  93                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument])
  94         fi
  95         if test $ol_enable_wrappers = yes ; then
  96                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
  97         fi
  98         if test $ol_enable_phonetic = yes ; then
  99                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 100         fi
 101         if test $ol_enable_rlookups = yes ; then
 102                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 103         fi
 104         if test $ol_with_ldbm_api != auto ; then
 105                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 106         fi
 107         if test $ol_with_ldbm_type != auto ; then
 108                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 109         fi
 110         if test $ol_enable_slurpd = yes ; then
 111                 AC_MSG_ERROR([slurpd requires slapd])
 112         fi
 113
 114         # force settings to no
 115         ol_enable_ldbm=no
 116         ol_enable_shell=no
 117         ol_enable_passwd=no
 118         ol_enable_aclgroups=no
 119         ol_enable_crypt=no
 120         ol_enable_md5=no
 121         ol_enable_sha1=no
 122         ol_enable_wrappers=no
 123         ol_enable_phonetic=no
 124         ol_enable_rlookups=no
 125         ol_with_ldbm_api=no
 126         ol_with_ldbm_type=no
 127         ol_enable_slurpd=no
 128
 129 elif test $ol_enable_ldbm = no ; then
 130         dnl SLAPD without LDBM
 131
 132         if test $ol_with_ldbm_api != auto ; then
 133                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 134         fi
 135
 136         if test $ol_with_ldbm_type != auto ; then
 137                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 138         fi
 139
 140         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 141                 AC_MSG_ERROR([slapd requires a backend])
 142         fi
 143
 144         ol_with_ldbm_api=no
 145         ol_with_ldbm_type=no
 146
 147 else
 148         dnl SLAPD with LDBM
 149
 150         if test $ol_with_ldbm_api = gdbm -a \
 151                 $ol_with_ldbm_type = btree ; then
 152                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 153         fi
 154         if test $ol_with_ldbm_api = ndbm -a \
 155                 $ol_with_ldbm_type = btree ; then
 156                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 157         fi
 158 fi
 159
 160 if test $ol_enable_slurpd = yes ; then
 161         dnl SLURPD was specifically enabled
 162         if test $ol_with_threads = no ; then
 163                 AC_MSG_ERROR([slurpd requires threads])
 164         fi
 165 fi
 166
 167 AC_MSG_RESULT(done)
 168
 169 ## Initialize vars
 170 LDAP_LIBS=
 171 LDBM_LIBS=
 172 LTHREAD_LIBS=
 173 LUTIL_LIBS=
 174
 175 LDAPD_LIBS=
 176 SLAPD_LIBS=
 177 SLURPD_LIBS=
 178
 179 BUILD_LDAPD=no
 180 BUILD_SLAPD=no
 181 BUILD_SLURPD=no
 182
 183 BUILD_LDBM=no
 184 BUILD_PASSWD=no
 185 BUILD_SHELL=no
 186
 187 KRB_LIBS=
 188 TERMCAP_LIBS=
 189
 190 dnl ----------------------------------------------------------------
 191 dnl Checks for programs
 192
 193 AC_PROG_LN_S
 194 AC_PROG_INSTALL
 195 AC_PROG_RANLIB
 196 AC_PROG_MAKE_SET
 197
 198 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 199         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 200 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 201 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 202
 203 dnl Checks the compiler and UNIX Variants
 204 AC_PROG_CC
 205
 206 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 207         AC_WARN([cross compiling....  go for it])
 208
 209 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 210         AC_WARN([programs compiled here do run here...])
 211         AC_ERROR([  if not cross compiling, use --disable-x-compile.])
 212
 213 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 214         AC_WARN([programs compiled here do not run here...])
 215         AC_ERROR([  if cross compiling,  add --enable-x-compile.])
 216 fi
 217
 218 AC_PROG_GCC_TRADITIONAL
 219 AC_PROG_CPP
 220
 221
 222 AC_AIX
 223 AC_ISC_POSIX
 224 AC_MINIX
 225
 226 dnl ----------------------------------------------------------------
 227 dnl Checks for libraries
 228
 229 dnl Find socket()
 230 dnl Likely combinations:
 231 dnl             -lsocket [ -lnsl_s | -lnsl ]
 232 dnl             -linet
 233
 234 AC_CHECK_FUNC(socket, :, [
 235 dnl
 236 dnl hopefully we won't include too many libraries
 237 dnl
 238         AC_CHECK_LIB(socket, main)
 239         AC_CHECK_LIB(net, main)
 240         AC_CHECK_LIB(nsl_s, main)
 241         AC_CHECK_LIB(nsl, main)
 242         AC_CHECK_LIB(inet, socket)
 243         AC_CHECK_LIB(gen, main)
 244 ])
 245
 246 dnl HP-UX requires -lV3
 247 AC_CHECK_LIB(V3, sigset)
 248
 249 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 250         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 251
 252         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 253                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 254                         [-lkrb5 -ldes425])
 255
 256                 if test $have_k5 = yes ; then
 257                         ol_with_kerberos=found
 258                         ol_link_kerberos=yes
 259
 260                         AC_DEFINE(HAVE_KERBEROS)
 261
 262                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 263                 fi
 264         fi
 265 fi
 266 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 267         AC_CHECK_HEADERS(krb.h des.h)
 268
 269         if test $ac_cv_header_krb_h = yes ; then
 270                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 271
 272                 if test $have_k4 = yes ; then
 273                         ol_with_kerberos=found
 274                         ol_link_kerberos=yes
 275
 276                         AC_DEFINE(HAVE_KERBEROS)
 277
 278                         KRB_LIBS="-lkrb -ldes"
 279                 fi
 280         fi
 281 fi
 282
 283
 284 ol_link_threads=no
 285 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 286         AC_CHECK_HEADERS(pthread.h sched.h)
 287
 288         if test $ac_cv_header_pthread_h = yes ; then
 289                 OL_POSIX_THREAD_VERSION
 290
 291                 if test $ol_cv_pthread_version = final ; then
 292                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 293                 elif test $ol_cv_pthread_version = draft4 ; then
 294                         AC_DEFINE(HAVE_PTHREADS_D4)
 295                 else
 296                         AC_MSG_ERROR([unknown pthread version])
 297                 fi
 298
 299                 # consider threads found
 300                 ol_with_threads=found
 301
 302                 OL_LINUX_THREADS
 303
 304                 if test $ol_cv_linux_threads = yes ; then
 305                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 306                 fi
 307
 308                 dnl Now the hard part, how to link
 309
 310                 dnl A few platforms have pthread support in standard libraries
 311                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 312
 313                 if test $ol_link_threads = no ; then
 314                         dnl try -pthread
 315                         AC_CACHE_CHECK([for pthread_create with -pthread],
 316                                 [ol_cv_pthread_flag], [
 317                                 dnl save the CPPFLAGS
 318                                 save_LIBS="$LIBS"
 319                                 LIBS="-pthread $LIBS"
 320                                 AC_TRY_LINK([#include <pthread.h>],[
 321                                         pthread_create((pthread_t*) 0,
 322                                                 (pthread_attr_t*) 0, 0, 0);
 323                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 324                                 dnl restore the LIBS
 325                                 LIBS="$save_LIBS"
 326                         ])
 327
 328                         if test $ol_cv_pthread_flag = yes ; then
 329                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 330                                 ol_link_threads=posix
 331                         fi
 332                 fi
 333
 334                 if test $ol_link_threads = no ; then
 335                         dnl try -lpthread
 336                         save_LIBS="$LIBS"
 337                         AC_CHECK_LIB(pthread, pthread_create, [
 338                                 ol_link_threads=posix
 339                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 340                         LIBS="$save_LIBS"
 341                 fi
 342
 343                 if test $ol_link_threads = no ; then
 344                         dnl try -lc_r
 345                         save_LIBS="$LIBS"
 346                         AC_CHECK_LIB(c_r, pthread_create, [
 347                                 ol_link_threads=posix
 348                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 349                         LIBS="$save_LIBS"
 350                 fi
 351
 352                 if test $ol_link_threads = no ; then
 353                         dnl try DEC Threads
 354                         save_LIBS="$LIBS"
 355                         AC_CHECK_LIB(pthread, pthread_create, [
 356                                 AC_DEFINE(HAVE_DCE)
 357                                 ol_link_threads=posix
 358                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc -lc"
 359                                 if test $ol_with_preemptive = auto ; then
 360                                         ol_with_preemptive=yes
 361                                 fi
 362                                 ],,[-lmach -lexc -lc])
 363                         LIBS="$save_LIBS"
 364                 fi
 365
 366                 if test $ol_link_threads != no ; then
 367                         AC_DEFINE(HAVE_PTHREADS)
 368
 369                         dnl save DEFS/LIBS
 370                         save_CPPFLAGS="$CPPFLAGS"
 371                         save_LIBS="$LIBS"
 372                         LIBS="$LTHREAD_LIBS $LIBS"
 373
 374                         dnl All POSIX Thread (final) implementations should have
 375                         dnl sched_yield instead of pthread yield.
 376                         dnl check for both
 377                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 378
 379                         if test $ac_cv_func_sched_yield = no -a \
 380                                 $ac_cv_func_pthread_yield = no ; then
 381                                 dnl Digital UNIX has sched_yield() in -lrt
 382                                 AC_CHECK_LIB(rt, sched_yield,
 383                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 384                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 385                                         ac_cv_func_sched_yield=yes],
 386                                         [ac_cv_func_sched_yield=no])
 387                         fi
 388                         if test $ac_cv_func_sched_yield = no -a \
 389                                 $ac_cv_func_pthread_yield = no ; then
 390                                 dnl Solaris has sched_yield() in -lposix4
 391                                 AC_CHECK_LIB(posix4, sched_yield,
 392                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 393                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 394                                         ac_cv_func_sched_yield=yes],
 395                                         [ac_cv_func_sched_yield=no])
 396                         fi
 397                         if test $ac_cv_func_sched_yield = no -a \
 398                                 $ac_cv_func_pthread_yield = no ; then
 399                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 400                                 AC_MSG_ERROR([POSIX Threads are not usable])
 401                         fi
 402
 403                         dnl Check functions for compatibility
 404                         AC_CHECK_FUNCS(pthread_kill)
 405 dnl                     AC_CHECK_FUNCS( \
 406 dnl                             pthread_attr_create pthread_attr_init \
 407 dnl                             pthread_attr_destroy pthread_attr_delete \
 408 dnl                             pthread_attr_setdetachstate pthread_attr_setdetach_np \
 409 dnl                     )
 410
 411                         dnl Check for setconcurreny functions
 412                         AC_CHECK_FUNCS( \
 413                                 pthread_setconcurrency \
 414                                 thr_setconcurrency \
 415                         )
 416
 417                         dnl Check PREEMPTIVE Implementation
 418                         if test $ol_with_preemptive = auto ; then
 419                                 AC_MSG_CHECKING([for preemptive Pthread implementation])
 420                                 AC_TRY_RUN([
 421 #include <sys/types.h>
 422 #include <sys/time.h>
 423 #include <unistd.h>
 424 #include <pthread.h>
 425 #ifndef NULL
 426 #define NULL 0
 427 #endif
 428
 429 int task(arg)
 430         int *arg;
 431 {
 432         struct timeval tv;
 433
 434         tv.tv_sec=4;
 435         tv.tv_usec=0;
 436         select(0, NULL, NULL, NULL, &tv);
 437
 438         tv.tv_sec=6;
 439         tv.tv_usec=0;
 440         select(0, NULL, NULL, NULL, &tv);
 441
 442         exit(1); /* if we exit here, the select blocked the whole process */
 443 }
 444
 445 main(argc, argv)
 446 int argc; char **argv;
 447 {
 448         pthread_t t;
 449
 450 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 451         (void) pthread_setconcurrency(2);
 452 #elif HAVE_THR_SETCONCURRENCY
 453         /* Set Solaris LWP concurrency to 2 */
 454         thr_setconcurrency(2);
 455 #endif
 456
 457         pthread_create(&t, NULL, (void *) task, NULL);
 458
 459 #if HAVE_SCHED_YIELD
 460         sched_yield();  /* make sure task runs first */
 461 #else
 462 #if defined(HAVE_PTHREAD_YIELD)
 463         pthread_yield();        /* make sure task runs first */
 464 #endif
 465 #endif
 466         exit(0);
 467 }
 468                                 ], [ol_pthread_preemptive=yes], [ol_pthread_preemptive=no], [
 469                                 AC_MSG_ERROR([crossing compiling: use --with-preemptive=yes|no|manual])])
 470                                 AC_MSG_RESULT($ol_pthread_preemptive)
 471
 472                                 if test $ol_pthread_preemptive = yes ; then
 473                                         AC_DEFINE(HAVE_PREEMPTIVE_PTHREADS)
 474                                         ol_with_preemptive=yes
 475                                 fi
 476                         fi
 477
 478                         dnl check for reentrant/threadsafe functions
 479                         AC_CHECK_FUNCS( \
 480                                 feof_unlocked \
 481                                 unlocked_feof \
 482                                 ftrylockfile \
 483                                 flockfile \
 484                                 putc_unlocked \
 485                                 gmtime_r \
 486                                 strtok_r \
 487                         )
 488
 489                         dnl restore DEFS/LIBS
 490                         CPPFLAGS="$save_CPPFLAGS"
 491                         LIBS="$save_LIBS"
 492                 else
 493                         AC_MSG_ERROR([could not link with POSIX Threads])
 494                 fi
 495         fi
 496
 497         if test $ol_with_threads = posix ; then
 498                 AC_MSG_ERROR([could not locate POSIX Threads])
 499         fi
 500 fi
 501
 502 if test $ol_with_threads = auto -o $ol_with_threads = mach ; then
 503         dnl check for Mach CThreads
 504         AC_CHECK_HEADERS(mach/cthreads.h)
 505         if test $ac_cv_header_mach_cthreads_h = yes ; then
 506                 ol_with_threads=found
 507
 508                 dnl A few platforms have cthread support in standard libraries
 509                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 510
 511                 if test $ol_link_threads = no ; then
 512                         dnl try -all_load
 513                         dnl this test needs work
 514                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 515                                 [ol_cv_cthread_all_load], [
 516                                 dnl save the CPPFLAGS
 517                                 save_LIBS="$LIBS"
 518                                 LIBS="-all_load $LIBS"
 519                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 520                                         cthread_fork((void *)0, (void *)0);
 521                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 522                                 dnl restore the LIBS
 523                                 LIBS="$save_LIBS"
 524                         ])
 525
 526                         if test $ol_cv_cthread_all_load = yes ; then
 527                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 528                                 ol_link_threads=mach
 529                         fi
 530                 fi
 531
 532                 if test $ol_link_threads != no ; then
 533                         : check for cthread specific functionality here
 534                 else
 535                         AC_MSG_ERROR([could not link with Mach CThreads])
 536                 fi
 537         fi
 538
 539         if test $ol_with_threads = mach ; then
 540                 AC_MSG_ERROR([could not locate Mach CThreads])
 541         fi
 542 fi
 543
 544 if test $ol_with_threads = auto -o $ol_with_threads = lwp ; then
 545         dnl check for SunOS5 LWP
 546         AC_CHECK_HEADERS(thread.h synch.h)
 547         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 548                 AC_CHECK_LIB(thread, thr_create, [have_lwp=yes], [have_lwp=no])
 549
 550                 if test $have_lwp = yes ; then
 551                         AC_DEFINE(HAVE_THR)
 552                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 553
 554                         if test $ol_with_preemptive = auto ; then
 555                                 ol_with_preemptive=yes
 556                         fi
 557                 fi
 558         fi
 559
 560         dnl check for SunOS4 LWP
 561         AC_CHECK_HEADERS(lwp/lwp.h)
 562         if test $ac_cv_header_lwp_lwp_h = yes ; then
 563                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 564
 565                 if test $have_lwp = yes ; then
 566                         AC_DEFINE(HAVE_LWP)
 567                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 568
 569                         if test $ol_with_preemptive = auto ; then
 570                                 ol_with_preemptive=no
 571                         fi
 572                 fi
 573         fi
 574 fi
 575
 576 if test $ol_with_preemptive = yes ; then
 577         AC_DEFINE(PREEMPTIVE_THREADS,1)
 578 fi
 579
 580 if test $ol_with_threads = manual ; then
 581         dnl User thinks he can manually configure threads.
 582         ol_link_threads=yes
 583
 584         AC_MSG_WARN([thread defines and link options must be set manually])
 585
 586         AC_CHECK_HEADERS(pthread.h sched.h)
 587         AC_CHECK_FUNCS(sched_yield pthread_yield)
 588         OL_LINUX_THREADS
 589
 590         AC_CHECK_HEADERS(mach/cthreads.h)
 591         AC_CHECK_HEADERS(lwp/lwp.h)
 592         AC_CHECK_HEADERS(thread.h synch.h)
 593 fi
 594
 595 if test $ol_link_threads = no ; then
 596         if test $ol_with_threads = yes ; then
 597                 AC_MSG_ERROR([no suitable thread support])
 598         fi
 599
 600         if test $ol_with_threads = auto ; then
 601                 AC_MSG_WARN([no suitable thread support, disabling threads])
 602                 ol_with_threads=no
 603         fi
 604
 605         AC_DEFINE(NO_THREADS,1)
 606         AC_DEFINE(PREEMPTIVE_THREADS,1)
 607         LTHREAD_LIBS=""
 608 fi
 609
 610 ol_link_ldbm=no
 611 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 612         OL_BERKELEY_DB2
 613
 614         if test $ol_cv_berkeley_db2 = yes ; then
 615                 ol_link_ldbm=db2
 616                 ol_with_ldbm_api=db2
 617
 618                 if test $ol_with_ldbm_type = hash ; then
 619                         AC_DEFINE(LDBM_USE_DBHASH,1)
 620                 else
 621                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 622                 fi
 623
 624                 dnl $ol_cv_lib_db2 should be yes or -ldb
 625                 dnl (it could be no, but that would be an error
 626                 if test $ol_cv_lib_db2 != yes ; then
 627                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 628                 fi
 629         fi
 630 fi
 631
 632 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 633         OL_BERKELEY_DB
 634
 635         if test $ol_cv_berkeley_db = yes ; then
 636                 ol_link_ldbm=db
 637                 ol_with_ldbm_api=db
 638
 639                 if test $ol_with_ldbm_type = hash ; then
 640                         AC_DEFINE(LDBM_USE_DBHASH,1)
 641                 else
 642                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 643                 fi
 644
 645                 dnl $ol_cv_lib_db should be yes or -ldb
 646                 dnl (it could be no, but that would be an error
 647                 if test $ol_cv_lib_db != yes ; then
 648                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 649                 fi
 650         fi
 651 fi
 652
 653 if test $ol_with_ldbm_api = manual ; then
 654         dnl User thinks he can manually configure LDBM api.
 655         ol_link_ldbm=yes
 656
 657         AC_MSG_WARN([LDBM defines and link options must be set manually])
 658
 659         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 660 fi
 661
 662 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 663         AC_MSG_WARN(Could not find LDBM with BTREE support)
 664         ol_with_ldbm_api=none
 665 fi
 666
 667 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 668         OL_GDBM
 669
 670         if test $ol_cv_gdbm = yes ; then
 671                 ol_link_ldbm=gdbm
 672                 ol_with_ldbm_api=gdbm
 673
 674                 if test $ol_cv_lib_gdbm != yes ; then
 675                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 676                 fi
 677         fi
 678 fi
 679
 680 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 681         OL_NDBM
 682
 683         if test $ol_cv_ndbm = yes ; then
 684                 ol_link_ldbm=ndbm
 685                 ol_with_ldbm_api=ndbm
 686
 687                 if test $ol_with_ldbm_api = ndbm ; then
 688                         AC_WARN([Attempting to use NDBM.  Functionality will be limited.])
 689                 fi
 690
 691                 if test $ol_cv_lib_ndbm != yes ; then
 692                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 693                 fi
 694         fi
 695 fi
 696
 697 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 698         AC_MSG_WARN(could not find suitable LDBM backend)
 699         if test $ol_enable_ldbm = yes ; then
 700                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 701         fi
 702
 703         AC_MSG_WARN(disabling LDBM)
 704         ol_enable_ldbm=no
 705 fi
 706
 707 if test $ol_enable_wrappers = yes ; then
 708         AC_CHECK_LIB(wrap, hosts_access,
 709                 [have_wrappers=yes], [have_wrappers=no])
 710
 711         if test $have_wrappers = yes ; then
 712                 AC_DEFINE(HAVE_TCPD)
 713                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 714         else
 715                 AC_MSG_WARN(could not find -lwrap)
 716                 if test $ol_enable_wrappers = yes ; then
 717                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 718                 fi
 719
 720                 AC_MSG_WARN(disabling wrappers support)
 721                 ol_enable_wrappers=no
 722         fi
 723
 724 fi
 725
 726 # ud needs termcap (should insert check here)
 727 ol_link_termcap=no
 728 AC_CHECK_HEADERS(termcap.h ncurses.h)
 729
 730 if test $ol_link_termcap = no ; then
 731         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 732         if test $have_termcap = yes ; then
 733                 AC_DEFINE(HAVE_TERMCAP)
 734                 ol_link_termcap=yes
 735                 TERMCAP_LIBS=-ltermcap
 736         fi
 737 fi
 738
 739 if test $ol_link_termcap = no ; then
 740         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 741         if test $have_ncurses = yes ; then
 742                 AC_DEFINE(HAVE_NCURSES)
 743                 ol_link_termcap=yes
 744                 TERMCAP_LIBS=-lncurses
 745         fi
 746 fi
 747
 748 if test $ol_link_termcap = no ; then
 749         AC_DEFINE(NO_TERMCAP,1)
 750         TERMCAP_LIBS=
 751 fi
 752
 753 # FreeBSD (and others) have crypt(3) in -lcrypt
 754 if test $ol_enable_crypt != no ; then
 755         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 756                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 757                         have_crypt=yes], [have_crypt=no])])
 758
 759         if test $have_crypt = yes ; then
 760                 AC_DEFINE(HAVE_CRYPT,1)
 761         else
 762                 AC_MSG_WARN(could not find crypt)
 763                 if test $ol_enable_crypt = yes ; then
 764                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 765                 fi
 766
 767                 AC_MSG_WARN(disabling crypt support)
 768                 ol_enable_crypt=no
 769         fi
 770 fi
 771
 772 # FreeBSD (and others) have setproctitle(3) in -lutil
 773 if test $ol_enable_proctitle != no ; then
 774         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 775                 AC_CHECK_LIB(util, setproctitle,
 776                         [have_setproctitle=yes
 777                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 778                         [have_setproctitle=no
 779                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 780
 781         if test $have_setproctitle = yes ; then
 782                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 783         fi
 784 fi
 785
 786 dnl ----------------------------------------------------------------
 787 dnl Checks for header files.
 788 AC_HEADER_STDC
 789
 790 if test $ac_cv_header_stdc != yes; then
 791         AC_MSG_WARN([could not locate Standard C headers])
 792 fi
 793
 794 AC_HEADER_DIRENT
 795 AC_HEADER_SYS_WAIT
 796 AC_CHECK_HEADERS(       \
 797         stdarg.h                \
 798         stddef.h                \
 799         errno.h                 \
 800         fcntl.h                 \
 801         filio.h                 \
 802         getopt.h                \
 803         libutil.h               \
 804         limits.h                \
 805         malloc.h                \
 806         regex.h                 \
 807         sgtty.h                 \
 808         sys/file.h              \
 809         sys/filio.h             \
 810         sys/errno.h             \
 811         sys/ioctl.h             \
 812         sys/param.h             \
 813         sys/socket.h    \
 814         sys/syslog.h    \
 815         sys/time.h              \
 816         sys/types.h             \
 817         syslog.h                \
 818         termios.h               \
 819         unistd.h                \
 820 )
 821
 822 dnl ----------------------------------------------------------------
 823 dnl Checks for typedefs, structures, and compiler characteristics.
 824 AC_TYPE_GETGROUPS
 825 AC_TYPE_MODE_T
 826 AC_TYPE_OFF_T
 827 AC_TYPE_PID_T
 828 AC_TYPE_SIGNAL
 829 AC_TYPE_SIZE_T
 830 AC_TYPE_UID_T
 831 AC_STRUCT_ST_BLKSIZE
 832 AC_HEADER_TIME
 833 AC_STRUCT_TM
 834
 835 OL_C_UPPER_LOWER
 836 AC_C_CONST
 837
 838 dnl AC_CHECK_SIZEOF(short)
 839 dnl AC_CHECK_SIZEOF(int)
 840 dnl AC_CHECK_SIZEOF(long)
 841
 842 dnl ----------------------------------------------------------------
 843 dnl Checks for library functions.
 844 AC_FUNC_MEMCMP
 845 AC_FUNC_STRFTIME
 846 AC_FUNC_VPRINTF
 847
 848 if test $ac_cv_func_vprintf = yes ; then
 849         dnl check for vsnprintf
 850         AC_CHECK_FUNCS(vsnprintf)
 851 fi
 852
 853 AC_FUNC_WAIT3
 854
 855 AC_CHECK_FUNCS(         \
 856         bcopy                   \
 857         getopt                  \
 858         flock                   \
 859         gethostname             \
 860         gettimeofday    \
 861         getdtablesize   \
 862         lockf                   \
 863         memcpy                  \
 864         memmove                 \
 865         mkstemp                 \
 866         mktime                  \
 867         select                  \
 868         setpwfile               \
 869         setsid                  \
 870         signal                  \
 871         sigset                  \
 872         snprintf                \
 873         socket                  \
 874         strerror                \
 875         strstr                  \
 876         strrchr                 \
 877         strsep                  \
 878         strtod                  \
 879         strtol                  \
 880         strtoul                 \
 881         sysconf                 \
 882         tempnam                 \
 883         waitpid                 \
 884 )
 885
 886 AC_REPLACE_FUNCS(getopt strdup tempnam)
 887
 888 dnl ----------------------------------------------------------------
 889 # Check Configuration
 890 OL_SYS_ERRLIST
 891
 892 dnl ----------------------------------------------------------------
 893 dnl Sort out defines
 894
 895 if test $ol_enable_debug != no ; then
 896         AC_DEFINE(LDAP_DEBUG,1)
 897 fi
 898 dnl     if test $ol_enable_syslog != no ; then
 899 dnl             AC_DEFINE(LDAP_SYSLOG,1)
 900 dnl     fi
 901 if test $ol_enable_libui = yes ; then
 902         AC_DEFINE(LDAP_LIBUI,1)
 903 fi
 904 if test $ol_enable_cache = no ; then
 905         AC_DEFINE(LDAP_NOCACHE,1)
 906 fi
 907 if test $ol_enable_dns != no ; then
 908         AC_DEFINE(LDAP_DNS,1)
 909 fi
 910 if test $ol_enable_proctitle != no ; then
 911         AC_DEFINE(LDAP_PROCTITLE,1)
 912 fi
 913 if test $ol_enable_referrals != no ; then
 914         AC_DEFINE(LDAP_REFERRALS,1)
 915 fi
 916 if test $ol_enable_cldap != no ; then
 917         AC_DEFINE(LDAP_CONNECTIONLESS,1)
 918 fi
 919
 920 if test $ol_enable_aclgroups != no ; then
 921         AC_DEFINE(SLAPD_ACLGROUPS,1)
 922 fi
 923 if test $ol_enable_crypt != no ; then
 924         AC_DEFINE(SLAPD_CRYPT,1)
 925 fi
 926 if test $ol_enable_md5 != no ; then
 927         AC_DEFINE(SLAPD_MD5,1)
 928 fi
 929 if test $ol_enable_sha1 != no ; then
 930         AC_DEFINE(SLAPD_SHA1,1)
 931 fi
 932 if test $ol_enable_phonetic != no ; then
 933         AC_DEFINE(SLAPD_PHONETIC,1)
 934 fi
 935 if test $ol_enable_rlookups != no ; then
 936         AC_DEFINE(SLAPD_RLOOKUPS,1)
 937 fi
 938
 939 if test $ol_link_ldbm != no ; then
 940         AC_DEFINE(SLAPD_LDBM,1)
 941         BUILD_SLAPD=yes
 942         BUILD_LDBM=yes
 943 fi
 944
 945 if test $ol_enable_passwd != no ; then
 946         AC_DEFINE(SLAPD_PASSWD,1)
 947         BUILD_SLAPD=yes
 948         BUILD_PASSWD=yes
 949 fi
 950
 951 if test $ol_enable_shell != no ; then
 952         AC_DEFINE(SLAPD_SHELL,1)
 953         BUILD_SLAPD=yes
 954         BUILD_SHELL=yes
 955 fi
 956
 957 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
 958         $BUILD_SLAPD = yes ; then
 959         BUILD_SLURPD=yes
 960 fi
 961
 962 if test $ol_enable_ldapd != no ; then
 963         BUILD_LDAPD=yes
 964 fi
 965
 966 dnl ----------------------------------------------------------------
 967
 968 AC_SUBST(BUILD_LDAPD)
 969 AC_SUBST(BUILD_SLAPD)
 970   AC_SUBST(BUILD_LDBM)
 971   AC_SUBST(BUILD_PASSWD)
 972   AC_SUBST(BUILD_SHELL)
 973 AC_SUBST(BUILD_SLURPD)
 974
 975
 976 AC_SUBST(LDAP_LIBS)
 977 AC_SUBST(LDAPD_LIBS)
 978 AC_SUBST(SLAPD_LIBS)
 979 AC_SUBST(SLURPD_LIBS)
 980 AC_SUBST(LDBM_LIBS)
 981 AC_SUBST(LTHREAD_LIBS)
 982 AC_SUBST(LUTIL_LIBS)
 983
 984 AC_SUBST(KRB_LIBS)
 985 AC_SUBST(TERMCAP_LIBS)
 986
 987 dnl ----------------------------------------------------------------
 988 dnl final output
 989 dnl
 990
 991 dnl AC_OUTPUT( \
 992 dnl contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
 993 dnl contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
 994 dnl contrib/whois++/Makefile:build/top.mk:contrib/whois++/Makefile.in:build/rules.mk \
 995 dnl [date > stamp-h])
 996
 997 AC_OUTPUT( \
 998 Makefile:build/top.mk:Makefile.in:build/dir.mk \
 999 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1000 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1001 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1002 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1003 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1004 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1005 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1006 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1007 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1008 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1009 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1010 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1011 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1012 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1013 include/Makefile:build/top.mk:include/Makefile.in \
1014 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1015 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk \
1016 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk \
1017 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk \
1018 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk \
1019 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk \
1020 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk \
1021 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk \
1022 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1023 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1024 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1025 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1026 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1027 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1028 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1029 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1030 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1031 tests/Makefile:build/top.mk:tests/Makefile.in \
1032 ,[
1033 date > stamp-h
1034 echo Please \"make depend\" to build dependencies
1035 ])