git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998-2001 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms are permitted only
   6 dnl as authorized by the OpenLDAP Public License.  A copy of this
   7 dnl license is available at http://www.OpenLDAP.org/license.html or
   8 dnl in file LICENSE in the top-level directory of the distribution.
   9 dnl
  10 dnl ----------------------------------------------------------------
  11 dnl Redefine AC_INIT_BINSH to provide RCS IDs and copyright notice
  12 dnl at top of generated configure script.  Prints simple copyright.
  13 define([AC_INIT_BINSH],
  14 [[#! /bin/sh
  15 # $]OpenLDAP[$
  16 # from] translit([$OpenLDAP$], $")] [
  17
  18 # Copyright 1998-2001 The OpenLDAP Foundation.  All Rights Reserved.
  19 #
  20 # Redistribution and use in source and binary forms are permitted only
  21 # as authorized by the OpenLDAP Public License.  A copy of this
  22 # license is available at http://www.OpenLDAP.org/license.html or
  23 # in file LICENSE in the top-level directory of the distribution.
  24
  25 echo "Copyright 1998-2001 The OpenLDAP Foundation,  All Rights Reserved."
  26 echo "Restrictions apply, see COPYRIGHT and LICENSE files."
  27 ])dnl
  28 dnl ----------------------------------------------------------------
  29 dnl Disable config.cache!
  30 define([AC_CACHE_LOAD], )dnl
  31 define([AC_CACHE_SAVE], )dnl
  32 dnl ================================================================
  33 dnl Configure.in for OpenLDAP
  34 AC_INIT(build/version)dnl
  35
  36 # set unset (borrowed from autoconf 2.49c)
  37 if (OL_FOO=OL_FOO; unset OL_FOO) >/dev/null 2>&1; then
  38   ol_unset=unset
  39 else
  40   ol_unset=false
  41 fi
  42 # unset CDPATH
  43 $ol_unset CDPATH || test "${CDPATH+set}" != set || { CDPATH=:; export CDPATH; }
  44
  45 AC_CONFIG_AUX_DIR(build)dnl
  46
  47 OL_VERSION=`cat $ac_aux_dir/version`
  48 if test -z "$OL_VERSION"; then
  49         AC_MSG_ERROR([could not determine version])
  50 fi
  51
  52 echo "Configuring OpenLDAP $OL_VERSION ..."
  53
  54 dnl Determine host platform
  55 dnl             we try not to use this for much
  56 AC_CANONICAL_SYSTEM
  57
  58 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  59 AC_SUBST(PACKAGE)dnl
  60 AC_SUBST(VERSION)dnl
  61 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  62 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  63
  64 dnl We use autoconf features new to 2.13.
  65 dnl aclocal.m4 should be built using aclocal from automake 1.4
  66 dnl libtool 1.3.3 should be installed.
  67 AC_PREREQ(2.13)dnl Required Autoconf version
  68
  69 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  70
  71 dnl ================================================================
  72 dnl Start Args
  73 AC_MSG_CHECKING(configure arguments)
  74 AC_PREFIX_DEFAULT(/usr/local)
  75
  76 top_builddir=`pwd`
  77 AC_SUBST(top_builddir)dnl
  78
  79 dnl ----------------------------------------------------------------
  80 dnl --with-subdir
  81 ldap_subdir="/openldap"
  82
  83 AC_ARG_WITH(subdir,
  84 [  --with-subdir=DIR      change default subdirectory used for installs],
  85 [case "$withval" in
  86         no) ldap_subdir=""
  87                 ;;
  88         yes)
  89                 ;;
  90         /*|\\*)
  91                 ldap_subdir="$withval"
  92                 ;;
  93         *)
  94                 ldap_subdir="/$withval"
  95                 ;;
  96 esac
  97 ])dnl
  98
  99 AC_SUBST(ldap_subdir)dnl
 100
 101 dnl ----------------------------------------------------------------
 102 dnl General "enable" options
 103 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes)dnl
 104 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 105 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 106 OL_ARG_ENABLE(cache,[  --enable-cache     enable caching], yes)dnl
 107 OL_ARG_ENABLE(referrals,[  --enable-referrals     enable V2 Referrals extension], yes)dnl
 108 OL_ARG_ENABLE(kbind,[  --enable-kbind     enable V2 Kerberos IV bind], no)dnl
 109 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 110 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 111 OL_ARG_ENABLE(x_compile,[  --enable-x-compile     enable cross compiling],
 112         no, [yes no])dnl
 113
 114 dnl ----------------------------------------------------------------
 115 dnl General "with" options
 116 dnl OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc     enable debug malloc support], no)dnl
 117
 118 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 119         auto, [auto yes no] )
 120 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch URL support],
 121         auto, [auto yes no] )
 122 OL_ARG_WITH(kerberos,[  --with-kerberos   with support],
 123         auto, [auto k5 k5only k425 kth k4 afs yes no])
 124 OL_ARG_WITH(readline,[  --with-readline   with readline support],
 125         auto, [auto yes no] )
 126 OL_ARG_WITH(threads,[  --with-threads     with threads],
 127         auto, [auto nt posix mach pth lwp yes no manual] )
 128 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support],
 129         auto, [auto ssleay openssl yes no] )
 130 OL_ARG_WITH(yielding_select,[  --with-yielding-select  with implicitly yielding select],
 131         auto, [auto yes no manual] )
 132
 133 dnl ----------------------------------------------------------------
 134 dnl Server options
 135 dnl ----------------------------------------------------------------
 136
 137 dnl ----------------------------------------------------------------
 138 dnl SLAPD OPTIONS
 139 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 140 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 141 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 142 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], auto)dnl
 143 OL_ARG_ENABLE(kpasswd,[    --enable-kpasswd       enable kerberos password verification], no)dnl
 144 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 145 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 146 dnl OL_ARG_ENABLE(multimaster,[    --enable-multimaster  enable multimaster replication], no)dnl
 147 OL_ARG_ENABLE(phonetic,[    --enable-phonetic     enable phonetic/soundex], no)dnl
 148 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups], no)dnl
 149 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs], no)dnl
 150 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 151 OL_ARG_ENABLE(dynamic,[    --enable-dynamic       enable linking built binaries with dynamic libs], no)dnl
 152
 153 dnl SLAPD Backend options
 154 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend], no)dnl
 155 OL_ARG_WITH(dnssrv_module,[    --with-dnssrv-module  module type], static,
 156         [static dynamic])
 157 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend], no)dnl
 158 OL_ARG_WITH(ldap_module,[    --with-ldap-module   module type], static,
 159         [static dynamic])
 160 OL_ARG_ENABLE(ldbm,[    --enable-ldbm     enable ldbm backend], yes)dnl
 161 OL_ARG_WITH(ldbm_api,[    --with-ldbm-api       with LDBM API], auto,
 162         [auto berkeley bcompat mdbm gdbm])
 163 OL_ARG_WITH(ldbm_module,[    --with-ldbm-module   module type], static,
 164         [static dynamic])
 165 OL_ARG_WITH(ldbm_type,[    --with-ldbm-type       use LDBM type], auto,
 166         [auto btree hash])
 167 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend], no)dnl
 168 OL_ARG_WITH(passwd_module,[    --with-passwd-module  module type], static,
 169         [static dynamic])
 170 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend], no)dnl
 171 OL_ARG_WITH(shell_module,[    --with-shell-module         module type], static,
 172         [static dynamic])
 173 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend], no)dnl
 174 OL_ARG_WITH(sql_module,[    --with-sql-module     module type], static,
 175         [static dynamic])
 176
 177 dnl ----------------------------------------------------------------
 178 dnl SLURPD OPTIONS
 179 AC_ARG_WITH(xxslurpdoptions,[SLURPD (Replication Daemon) Options:])
 180 OL_ARG_ENABLE(slurpd,[  --enable-slurpd   enable building slurpd], auto)dnl
 181
 182 dnl ----------------------------------------------------------------
 183 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 184 AC_ENABLE_STATIC
 185 dnl AC_DISABLE_SHARED
 186 AC_ENABLE_SHARED
 187
 188 dnl ----------------------------------------------------------------
 189
 190 dnl General "enable" options
 191 # validate options
 192 if test $ol_enable_slapd = no ; then
 193         dnl SLAPD was specificallly disabled
 194         if test $ol_enable_dnssrv = yes ; then
 195                 AC_MSG_WARN([slapd disabled, ignoring --enable-dnssrv argument])
 196         fi
 197         if test $ol_enable_ldap = yes ; then
 198                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 199         fi
 200         if test $ol_enable_ldbm = yes ; then
 201                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 202         fi
 203         if test $ol_enable_passwd = yes ; then
 204                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 205         fi
 206         if test $ol_enable_shell = yes ; then
 207                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 208         fi
 209         if test $ol_enable_sql = yes ; then
 210                 AC_MSG_WARN([slapd disabled, ignoring --enable-sql argument])
 211         fi
 212         if test $ol_enable_modules = yes ; then
 213                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 214         fi
 215 dnl     if test $ol_enable_multimaster = yes ; then
 216 dnl             AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 217 dnl     fi
 218         if test $ol_enable_wrappers = yes ; then
 219                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 220         fi
 221         if test $ol_enable_phonetic = yes ; then
 222                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 223         fi
 224         if test $ol_enable_rlookups = yes ; then
 225                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 226         fi
 227         if test $ol_enable_aci = yes ; then
 228                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 229         fi
 230         if test $ol_with_ldbm_api != auto ; then
 231                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 232         fi
 233         if test $ol_with_ldbm_type != auto ; then
 234                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 235         fi
 236         if test $ol_with_dnssrv_module != static ; then
 237                 AC_MSG_WARN([slapd disabled, ignoring --with-dnssrv-module argument])
 238         fi
 239         if test $ol_with_ldap_module != static ; then
 240                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 241         fi
 242         if test $ol_with_ldbm_module != static ; then
 243                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 244         fi
 245         if test $ol_with_passwd_module != static ; then
 246                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 247         fi
 248         if test $ol_with_shell_module != static ; then
 249                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 250         fi
 251         if test $ol_with_sql_module != static ; then
 252                 AC_MSG_WARN([slapd disabled, ignoring --with-sql-module argument])
 253         fi
 254         if test $ol_enable_slurpd = yes ; then
 255                 AC_MSG_ERROR([slurpd requires slapd])
 256         fi
 257
 258         # force settings to no
 259         ol_enable_dnssrv=no
 260         ol_enable_ldap=no
 261         ol_enable_ldbm=no
 262         ol_enable_passwd=no
 263         ol_enable_shell=no
 264         ol_enable_sql=no
 265
 266         ol_enable_modules=no
 267 dnl     ol_enable_multimaster=no
 268         ol_enable_phonetic=no
 269         ol_enable_rlookups=no
 270         ol_enable_aci=no
 271         ol_enable_wrappers=no
 272         ol_enable_dynamic=no
 273
 274         ol_with_ldbm_api=no
 275         ol_with_ldbm_type=no
 276
 277         ol_with_dnssrv_module=static
 278         ol_with_ldap_module=static
 279         ol_with_ldbm_module=static
 280         ol_with_passwd_module=static
 281         ol_with_shell_module=static
 282         ol_with_sql_module=static
 283
 284         ol_enable_slurpd=no
 285
 286 elif test $ol_enable_ldbm = no ; then
 287         dnl SLAPD without LDBM
 288
 289         if test $ol_with_ldbm_api != auto ; then
 290                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 291         fi
 292
 293         if test $ol_with_ldbm_type != auto ; then
 294                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 295         fi
 296
 297         if test $ol_with_ldbm_module != static ; then
 298                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 299         fi
 300
 301         if test $ol_enable_modules != yes -a \
 302                 $ol_enable_dnssrv = no -a \
 303                 $ol_enable_ldap = no -a \
 304                 $ol_enable_passwd = no -a \
 305                 $ol_enable_shell = no -a \
 306                 $ol_enable_sql = no ; then
 307                 AC_MSG_ERROR([slapd requires a backend])
 308         fi
 309
 310         ol_with_ldbm_api=no
 311         ol_with_ldbm_type=no
 312         ol_with_ldbm_module=static
 313
 314 else
 315         dnl SLAPD with LDBM
 316         if test $ol_with_ldbm_api = gdbm -a \
 317                 $ol_with_ldbm_type = btree ; then
 318                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 319         fi
 320         if test $ol_with_ldbm_api = mdbm -a \
 321                 $ol_with_ldbm_type = btree ; then
 322                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 323         fi
 324         if test $ol_with_ldbm_api = ndbm -a \
 325                 $ol_with_ldbm_type = btree ; then
 326                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 327         fi
 328 fi
 329
 330 if test $ol_enable_slurpd = yes ; then
 331         dnl SLURPD was specifically enabled
 332         if test $ol_with_threads = no ; then
 333                 AC_MSG_ERROR([slurpd requires threads])
 334         fi
 335 fi
 336
 337 if test $ol_enable_kbind = yes -o $ol_enable_kpasswd = yes ; then
 338         if test $ol_with_kerberos = no ; then
 339                 AC_MSG_ERROR([options require --with-kerberos])
 340         fi
 341         ol_with_kerberos=yes
 342 elif test $ol_enable_kbind = no -o $ol_enable_kpasswd = no ; then
 343         if test $ol_with_kerberos != no -a $ol_with_kerberos != auto ; then
 344                 AC_MSG_WARN([Kerberos detection enabled unnecessarily]);
 345         fi
 346         ol_with_kerberos=no
 347 fi
 348
 349 if test $ol_enable_spasswd = yes ; then
 350         if test $ol_with_cyrus_sasl = no ; then
 351                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 352         fi
 353         ol_with_cyrus_sasl=yes
 354 fi
 355
 356 AC_MSG_RESULT(done)
 357
 358 dnl ----------------------------------------------------------------
 359 dnl Initialize vars
 360 LDAP_LIBS=
 361 LDIF_LIBS=
 362 LDBM_LIBS=
 363 LTHREAD_LIBS=
 364 LUTIL_LIBS=
 365
 366 SLAPD_LIBS=
 367 SLURPD_LIBS=
 368
 369 BUILD_SLAPD=no
 370 BUILD_SLURPD=no
 371
 372 BUILD_THREAD=no
 373
 374 BUILD_DNSSRV=no
 375 BUILD_LDAP=no
 376 BUILD_LDBM=no
 377 BUILD_PASSWD=no
 378 BUILD_SHELL=no
 379 BUILD_SQL=no
 380
 381 BUILD_DNSSRV_DYNAMIC=static
 382 BUILD_LDAP_DYNAMIC=static
 383 BUILD_LDBM_DYNAMIC=static
 384 BUILD_PASSWD_DYNAMIC=static
 385 BUILD_SHELL_DYNAMIC=static
 386 BUILD_SQL_DYNAMIC=static
 387
 388 SLAPD_MODULES_LDFLAGS=
 389 SLAPD_MODULES_CPPFLAGS=
 390 SLAPD_MODULES_LIST=
 391
 392 SLAPD_SQL_LDFLAGS=
 393 SLAPD_SQL_LIBS=
 394 SLAPD_SQL_INCLUDES=
 395
 396 KRB4_LIBS=
 397 KRB5_LIBS=
 398 READLINE_LIBS=
 399 SASL_LIBS=
 400 TERMCAP_LIBS=
 401 TLS_LIBS=
 402 MODULES_LIBS=
 403 AUTH_LIBS=
 404
 405 dnl ================================================================
 406 dnl Checks for programs
 407
 408 dnl AC_PROG_INSTALL
 409
 410 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 411
 412 dnl ----------------------------------------------------------------
 413 dnl
 414 dnl Determine which C translator to use
 415 dnl
 416
 417 dnl AIX Thread requires we use cc_r or xlc_r.
 418 dnl But only do this IF AIX and CC is not set
 419 dnl and threads are auto|yes|posix.
 420 dnl
 421 dnl If we find cc_r|xlc_r, force pthreads and assume
 422 dnl             pthread_create is in $LIBS (ie: don't bring in
 423 dnl             any additional thread libraries)
 424 dnl If we do not find cc_r|xlc_r, disable threads
 425
 426 ol_aix_threads=no
 427 case "$target" in
 428 *-*-aix*) dnl all AIX is not a good idea.
 429         if test -z "$CC" ; then
 430                 case "$ol_with_threads" in
 431                 auto | yes |  posix) ol_aix_threads=yes ;;
 432                 esac
 433         fi
 434 ;;
 435 esac
 436
 437 if test $ol_aix_threads = yes ; then
 438         if test -z "${CC}" ; then
 439                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 440
 441                 if test "$CC" = cc ; then
 442                         dnl no CC! don't allow --with-threads
 443                         if test $ol_with_threads != auto ; then
 444                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 445                         else
 446                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 447                         fi
 448                         ol_with_threads=no
 449                 fi
 450         fi
 451
 452         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 453                 ol_with_threads=posix
 454                 ol_cv_pthread_create=yes
 455         fi
 456 fi
 457
 458 if test -z "${CC}"; then
 459         AC_CHECK_PROGS(CC,cc)
 460 fi
 461
 462 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 463 dnl (for now, let autoconf sort this out)
 464 dnl CFLAGS=${CFLAGS-""}
 465
 466 AC_LIBTOOL_WIN32_DLL
 467 AC_LIBTOOL_DLOPEN
 468 AC_PROG_LIBTOOL
 469
 470 AC_PROG_AWK
 471 OL_PROG_LN_H
 472 AC_PROG_LN_S
 473
 474 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 475         LN_S="$LN_H"
 476 fi
 477
 478 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 479         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 480 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 481 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 482
 483 AC_PROG_CPP
 484
 485 dnl ----------------------------------------------------------------
 486 dnl Cross compiling checks
 487 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 488         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 489
 490 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 491         AC_MSG_WARN([programs compiled here do run here...])
 492         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 493
 494 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 495         AC_MSG_WARN([programs compiled here do not run here...])
 496         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 497 fi
 498
 499 dnl ----------------------------------------------------------------
 500 dnl Checks for UNIX Variants
 501 AC_AIX
 502 AC_ISC_POSIX
 503 AC_MINIX
 504
 505 dnl ----------------------------------------------------------------
 506 dnl Checks for system services
 507 AC_CYGWIN
 508 AC_MINGW32
 509 AC_EXEEXT
 510 AC_OBJEXT
 511
 512 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 513
 514 dnl ----------------------------------------------------------------
 515 dnl BeOS requires -lbe -lroot -lnet
 516 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 517
 518 dnl ----------------------------------------------------------------
 519 dnl OpenLDAP requires STDC features
 520 AM_PROG_CC_STDC
 521 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 522         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 523 fi
 524
 525 dnl ----------------------------------------------------------------
 526 dnl Check cc depend flags
 527 OL_MKDEPEND
 528 if test "${ol_cv_mkdep}" = no ; then
 529         # this will soon become an error
 530         AC_MSG_WARN([do not know how to generate dependencies])
 531 fi
 532
 533 dnl ----------------------------------------------------------------
 534 dnl Check for AIX security library
 535 AC_CHECK_LIB(s, afopen, [
 536         AUTH_LIBS=-ls
 537         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 538 ])
 539
 540
 541 dnl ----------------------------------------------------------------
 542 dnl Check for module support
 543 ol_link_modules=no
 544 if test $ol_enable_modules != no ; then
 545         AC_CHECK_HEADERS(ltdl.h)
 546
 547         if test $ac_cv_header_ltdl_h = no ; then
 548                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 549         fi
 550
 551         AC_CHECK_LIB(ltdl, lt_dlinit, [
 552             MODULES_LIBS=-lltdl
 553             AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 554         ])
 555
 556         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 557                 AC_MSG_ERROR([could not locate libtool -lltdl])
 558         fi
 559         ol_link_modules=yes
 560 else
 561         ol_with_dnssrv_module=static
 562         ol_with_ldap_module=static
 563         ol_with_ldbm_module=static
 564         ol_with_passwd_module=static
 565         ol_with_shell_module=static
 566         ol_with_sql_module=static
 567 fi
 568
 569 dnl ----------------------------------------------------------------
 570 dnl Checks for header files.
 571 OL_HEADER_STDC
 572
 573 if test $ol_cv_header_stdc != yes; then
 574         AC_MSG_WARN([could not locate Standard C compliant headers])
 575 fi
 576
 577 AC_HEADER_DIRENT
 578 AC_HEADER_SYS_WAIT
 579 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 580 if test $am_cv_sys_posix_termios = yes ; then
 581         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 582                 [define if you have POSIX termios])
 583 fi
 584
 585 AC_CHECK_HEADERS(       \
 586         arpa/inet.h             \
 587         arpa/nameser.h  \
 588         assert.h                \
 589         conio.h                 \
 590         crypt.h                 \
 591         direct.h                \
 592         errno.h                 \
 593         fcntl.h                 \
 594         filio.h                 \
 595         getopt.h                \
 596         grp.h                   \
 597         io.h                    \
 598         libutil.h               \
 599         limits.h                \
 600         locale.h                \
 601         netinet/tcp.h   \
 602         malloc.h                \
 603         memory.h                \
 604         psap.h                  \
 605         pwd.h                   \
 606         process.h               \
 607         resolv.h                \
 608         sgtty.h                 \
 609         shadow.h                \
 610         stddef.h                \
 611         string.h                \
 612         strings.h               \
 613         sysexits.h              \
 614         sys/file.h              \
 615         sys/filio.h             \
 616         sys/errno.h             \
 617         sys/ioctl.h             \
 618         sys/param.h             \
 619         sys/resource.h  \
 620         sys/select.h    \
 621         sys/socket.h    \
 622         sys/syslog.h    \
 623         sys/time.h              \
 624         sys/types.h             \
 625         syslog.h                \
 626         termios.h               \
 627         unistd.h                \
 628         winsock.h               \
 629 )
 630
 631
 632 dnl ----------------------------------------------------------------
 633 dnl Checks for libraries
 634
 635 dnl SASL and SSL need dlopen on some platforms
 636 AC_CHECK_FUNC(dlopen, :, [AC_CHECK_LIB(dl, dlopen)])
 637
 638 dnl HP-UX requires -lV3
 639 AC_CHECK_LIB(V3, sigset)
 640
 641 dnl Gotta check for winsock manually
 642 if test $ac_cv_header_winsock_h = yes; then
 643         AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 644         AC_TRY_LINK([#include <winsock.h>],[
 645                         socket(0,0,0);
 646                         select(0,NULL,NULL,NULL,NULL);
 647                         closesocket(0);
 648                         gethostname(NULL,0);
 649         ],[ol_cv_winsock=yes],[ol_cv_winsock=no])])
 650
 651         if test $ol_cv_winsock = yes ; then
 652                 AC_DEFINE(HAVE_WINSOCK,1,[define if you have winsock])
 653                 ac_cv_func_socket=yes
 654                 ac_cv_func_select=yes
 655                 ac_cv_func_closesocket=yes
 656                 ac_cv_func_gethostname=yes
 657         fi
 658 fi
 659
 660 dnl Find socket()
 661 dnl Likely combinations:
 662 dnl             -lsocket [ -lnsl_s | -lnsl ]
 663 dnl             -linet
 664
 665 AC_CHECK_FUNC(socket, :, [
 666 dnl hopefully we won't include too many libraries
 667         AC_CHECK_LIB(socket, main)
 668         AC_CHECK_LIB(net, main)
 669         AC_CHECK_LIB(nsl_s, main)
 670         AC_CHECK_LIB(nsl, main)
 671         AC_CHECK_LIB(inet, socket)
 672         AC_CHECK_LIB(gen, main)
 673 ])
 674
 675 dnl require select
 676 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 677
 678 if test "${ac_cv_header_winsock_h}" != yes; then
 679     dnl Select arg types
 680     dnl (if this detection becomes permenent, it and the select() detection
 681     dnl should be done before the yielding select test)
 682     AC_FUNC_SELECT_ARGTYPES
 683 fi
 684
 685 dnl check to see if system call automatically restart
 686 dnl AC_SYS_RESTARTABLE_SYSCALLS
 687
 688 dnl ----------------------------------------------------------------
 689 dnl require POSIX regex
 690 AC_CHECK_HEADERS( regex.h )
 691 if test "$ac_cv_header_regex_h" != yes ; then
 692         AC_MSG_ERROR([POSIX regex.h required.])
 693 fi
 694 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 695
 696 OL_POSIX_REGEX
 697 if test "$ol_cv_c_posix_regex" = no ; then
 698         AC_MSG_ERROR([broken POSIX regex!])
 699 fi
 700
 701 dnl ----------------------------------------------------------------
 702 dnl Check for resolver routines
 703 ol_link_dnssrv=no
 704 AC_CHECK_FUNC(res_query,:)
 705 if test $ac_cv_func_res_query = no ; then
 706         AC_CHECK_LIB(bind, res_query)
 707         ac_cv_func_res_query=$ac_cv_lib_bind_res_query
 708 fi
 709
 710 if test $ac_cv_func_res_query = no ; then
 711         AC_CHECK_LIB(bind, __res_query)
 712         ac_cv_func_res_query=$ac_cv_lib_bind___res_query
 713 fi
 714
 715 if test $ac_cv_func_res_query = no ; then
 716         AC_CHECK_LIB(resolv, res_query)
 717         ac_cv_func_res_query=$ac_cv_lib_resolv_res_query
 718 fi
 719
 720 if test "$ac_cv_func_res_query" = yes ; then
 721         AC_DEFINE(HAVE_RES_QUERY,1,
 722                 [define if you have res_query()])
 723
 724         if test $ol_enable_dnssrv != no ; then
 725                 ol_link_dnssrv=yes
 726         fi
 727 fi
 728
 729 if test "$ol_enable_dnssrv" = yes -a "$ol_link_dnssrv" = no ; then
 730         AC_MSG_ERROR([DNSSRV requires res_query()])
 731 fi
 732
 733 dnl ----------------------------------------------------------------
 734 dnl PF_INET6 support requires getaddrinfo and INET6_ADDRSTRLEN
 735 dnl PF_LOCAL may use getaddrinfo in available
 736 AC_CHECK_FUNCS( getaddrinfo inet_ntop )
 737
 738 ol_link_ipv6=no
 739 if test $ac_cv_func_getaddrinfo = no -o $ac_cv_func_inet_ntop = no ; then
 740         if test $ol_enable_ipv6 = yes ; then
 741                 AC_MSG_ERROR([IPv6 support requires getaddrinfo() and inet_ntop()])
 742         fi
 743 else
 744         AC_CHECK_FUNCS( gai_strerror )
 745
 746         AC_CACHE_CHECK([INET6_ADDRSTRLEN],[ol_cv_inet6_addrstrlen],[
 747                 AC_EGREP_CPP(__has_inet6_addrstrlen__,[
 748 #                       include <netinet/in.h>
 749 #                       ifdef INET6_ADDRSTRLEN
 750                                 __has_inet6_addrstrlen__;
 751 #                       endif
 752                 ], [ol_cv_inet6_addrstrlen=yes], [ol_cv_inet6_addrstrlen=no])])
 753
 754         if test $ol_cv_inet6_addrstrlen = yes ; then
 755                 ol_link_ipv6=yes
 756         elif test $ol_enable_ipv6 = yes ; then
 757                 AC_MSG_ERROR([IPv6 support requires INET6_ADDRSTRLEN])
 758         fi
 759 fi
 760
 761 if test $ol_enable_local != no ; then
 762         AC_CHECK_HEADERS( sys/un.h )
 763
 764         if test $ol_enable_local = auto ; then
 765                 ol_enable_local=$ac_cv_header_sys_un_h
 766         elif test $ac_cv_header_sys_un_h = no ; then
 767                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
 768         fi
 769 fi
 770
 771 dnl ----------------------------------------------------------------
 772 dnl Kerberos
 773 ol_link_kbind=no
 774 ol_link_kpasswd=no
 775 ol_link_krb5=no
 776 ol_link_krb4=no
 777
 778 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
 779         -o $ol_with_kerberos = k5 -o $ol_with_kerberos = k5only \
 780         -o $ol_with_kerberos = k425 ; then
 781
 782         AC_CHECK_HEADERS(krb5.h)
 783
 784         if test $ac_cv_header_krb5_h = yes ; then
 785                 dnl lazy check for Heimdal Kerberos
 786                 AC_CHECK_HEADERS(heim_err.h)
 787                 if test $ac_cv_header_heim_err_h = yes ; then
 788                         krb5_impl=heimdal
 789                 else
 790                         krb5_impl=mit
 791                 fi
 792
 793                 if test $krb5_impl = mit; then
 794                         AC_CHECK_LIB(krb5, main,
 795                                 [have_krb5=yes
 796                                 KRB5_LIBS="-lkrb5 -lcrypto -lcom_err"],
 797                                 [have_krb5=no],
 798                                 [-lcrypto -lcom_err])
 799
 800                 elif test $krb5_impl = heimdal; then
 801                         AC_CHECK_LIB(krb5, main,
 802                                 [have_krb5=yes
 803                                 KRB5_LIBS="-lkrb5 -ldes -lasn1 -lroken -lcom_err"],
 804                                 [have_krb5=no],
 805                                 [-ldes -lasn1 -lroken -lcom_err])
 806
 807                         AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1,
 808                                 [define if you have HEIMDAL Kerberos])
 809                 else
 810                         have_krb5=no
 811                         AC_MSG_WARN([Unrecongized Kerberos V Implementation])
 812                 fi
 813
 814                 if test $have_krb5 = yes ; then
 815                         ol_link_krb5=yes
 816
 817                         AC_DEFINE(HAVE_KRB5, 1,
 818                                 [define if you have Kerberos V])
 819
 820                         if test $ol_enable_kpasswd != no ; then
 821                                 ol_link_kpasswd=yes;
 822                         fi
 823
 824                         if test $ol_with_kerberos = k5only ; then
 825                                 ol_with_kerberos=found
 826                         fi
 827
 828                 elif test $ol_with_kerberos != auto ; then
 829                         AC_MSG_ERROR([Required Kerberos 5 support not available])
 830                 fi
 831
 832         fi
 833 fi
 834
 835 if test $ol_link_krb5 = yes -a \( $ol_with_kerberos = yes -o \
 836         $ol_with_kerberos = auto -o $ol_with_kerberos = k425 \) ; then
 837
 838         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 839
 840         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 841                 if test $krb5_impl = mit; then
 842                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 843                                 KRB4_LIBS="-lkrb4 -ldes425"], [have_k425=no],
 844                                 [-ldes425 -lkrb5 -lcrypto -lcom_err])
 845
 846                 elif test $krb5_impl = heimdal; then
 847                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 848                                 KRB4_LIBS="-lkrb4"], [have_k425=no],
 849                                 [-lkrb5 -ldes -lasn1 -lroken -lcom_err])
 850
 851                 else
 852                         have_425=no
 853                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 854                 fi
 855
 856                 if test $have_k425 = yes ; then
 857                         ol_with_kerberos=found
 858                         ol_link_krb4=yes
 859
 860                         AC_DEFINE(HAVE_KRB425, 1,
 861                                 [define if you have Kerberos V with IV support])
 862                         AC_DEFINE(HAVE_KRB4, 1,
 863                                 [define if you have Kerberos IV])
 864
 865                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 866                                 [ol_cv_var_des_debug], [
 867                                 dnl save the flags
 868                                 save_LIBS="$LIBS"
 869                                 LIBS="$KRB4_LIBS $KRB5_LIBS $LIBS"
 870                                 AC_TRY_LINK([
 871 #include <kerberosIV/krb.h>
 872 #include <kerberosIV/des.h>
 873 extern int des_debug;
 874 ],[
 875 des_debug = 1;
 876 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 877                                 dnl restore the LIBS
 878                                 LIBS="$save_LIBS"
 879                         ])
 880
 881                         if test $ol_cv_var_des_debug = yes ; then
 882                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 883                                         [define if you have Kerberos des_debug])
 884                         fi
 885
 886                         LIBS="$save_LIBS"
 887                 fi
 888         fi
 889 fi
 890
 891 if test $ol_link_krb5 = yes ; then
 892         ol_with_kerberos=found
 893 fi
 894
 895 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
 896         -o $ol_with_kerberos = k4 -o $ol_with_kerberos = kth ; then
 897
 898         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
 899
 900         if test $ac_cv_header_krb_h = yes ; then
 901                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 902
 903                 if test $have_k4 = yes ; then
 904                         ol_with_kerberos=found
 905                         ol_link_krb4=yes
 906
 907                         AC_DEFINE(HAVE_KRB4, 1,
 908                                 [define if you have Kerberos IV])
 909
 910                         KRB4_LIBS="-lkrb -ldes"
 911
 912                         if test $ac_cv_header_krb_archaeology_h = yes ; then
 913                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
 914                                         [define if you have Kth Kerberos])
 915                         fi
 916                 fi
 917         fi
 918 fi
 919
 920 if test $ol_link_krb4 = yes -a $ol_enable_kpasswd != no ; then
 921         ol_link_kpasswd=yes
 922 fi
 923
 924 if test $ol_link_krb4 = yes -a $ol_enable_kbind != no ; then
 925         ol_link_kbind=yes
 926
 927 elif test $ol_enable_kbind = yes ; then
 928         AC_MSG_ERROR([Kerberos IV detection failed])
 929 fi
 930
 931 if test $ol_link_krb4 = yes -o $ol_link_krb5 = yes ; then
 932         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 933
 934 elif test $ol_with_kerberos != auto -a $ol_with_kerberos != no ; then
 935         AC_MSG_ERROR([Kerberos detection failed])
 936 fi
 937
 938 dnl ----------------------------------------------------------------
 939 dnl TLS/SSL
 940 ol_link_tls=no
 941 if test $ol_with_tls != no ; then
 942         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 943
 944         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 945                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 946                         [have_ssleay=yes
 947                         need_rsaref=no],
 948                         [have_ssleay=no],
 949                         [-lcrypto])
 950
 951                 if test $have_ssleay = no ; then
 952                         AC_CHECK_LIB(ssl, SSL_library_init,
 953                                 [have_ssleay=yes
 954                                 need_rsaref=no], [have_ssleay=no],
 955                                 [-lcrypto])
 956                 fi
 957
 958                 if test $have_ssleay = no ; then
 959                         AC_CHECK_LIB(ssl, ssl3_accept,
 960                                 [have_ssleay=yes
 961                                 need_rsaref=yes], [have_ssleay=no],
 962                                 [-lcrypto -lRSAglue -lrsaref])
 963                 fi
 964
 965                 if test $have_ssleay = yes ; then
 966                         ol_with_tls=found
 967                         ol_link_tls=yes
 968
 969                         AC_DEFINE(HAVE_SSLEAY, 1,
 970                                 [define if you have SSLeay or OpenSSL])
 971
 972                         if test $need_rsaref = yes; then
 973                                 AC_DEFINE(HAVE_RSAREF, 1,
 974                                         [define if you have RSAref])
 975
 976                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 977                         else
 978                                 TLS_LIBS="-lssl -lcrypto"
 979                         fi
 980                 fi
 981         fi
 982
 983 else
 984         AC_WARN([TLS privacy protection not supported!])
 985 fi
 986
 987 if test $ol_link_tls = yes ; then
 988         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 989
 990 elif test $ol_with_tls = auto ; then
 991         AC_WARN([Could not locate TLS/SSL package])
 992         AC_WARN([TLS privacy protection not supported!])
 993
 994 elif test $ol_with_tls != no ; then
 995         AC_ERROR([Could not locate TLS/SSL package])
 996 fi
 997
 998 dnl ----------------------------------------------------------------
 999 dnl Tests for reentrant functions necessary to build a
1000 dnl thread_safe -lldap.
1001 AC_CHECK_FUNCS(         \
1002         ctime_r                 \
1003         gethostbyname_r gethostbyaddr_r \
1004 )
1005
1006 if test "$ac_cv_func_ctime_r" = no ; then
1007         ol_cv_func_ctime_r_nargs=0
1008 else
1009         OL_FUNC_CTIME_R_NARGS
1010 dnl     OL_FUNC_CTIME_R_TYPE
1011 fi
1012
1013 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1014         OL_FUNC_GETHOSTBYNAME_R_NARGS
1015 else
1016         ol_cv_func_gethostbyname_r_nargs=0
1017 fi
1018
1019 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1020         OL_FUNC_GETHOSTBYADDR_R_NARGS
1021 else
1022         ol_cv_func_gethostbyaddr_r_nargs=0
1023 fi
1024
1025 if test "$ac_cv_func_ctime_r" = yes \
1026         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
1027         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
1028         -a "$ac_cv_func_gethostbyname_r" = yes \
1029         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
1030         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
1031         -a "$ac_cv_func_gethostbyaddr_r" = yes \
1032         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
1033         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
1034         ; then
1035
1036         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
1037 fi
1038
1039 dnl ----------------------------------------------------------------
1040 dnl Threads?
1041 ol_link_threads=no
1042
1043 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1044         -o $ol_with_threads = nt ; then
1045
1046         OL_NT_THREADS
1047
1048         if test "$ol_cv_nt_threads" = yes ; then
1049         ol_link_threads=nt
1050         ol_with_threads=found
1051         ol_with_yielding_select=yes
1052
1053                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1054                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1055         fi
1056
1057         if test $ol_with_threads = nt ; then
1058                 AC_MSG_ERROR([could not locate NT Threads])
1059         fi
1060 fi
1061
1062 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1063         -o $ol_with_threads = posix ; then
1064
1065         AC_CHECK_HEADERS(pthread.h)
1066
1067         if test $ac_cv_header_pthread_h = yes ; then
1068                 OL_POSIX_THREAD_VERSION
1069
1070                 if test $ol_cv_pthread_version = final ; then
1071                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
1072                                 [define if pthreads API compatible with final spec])
1073                 elif test $ol_cv_pthread_version = draft4 ; then
1074                         AC_DEFINE(HAVE_PTHREADS_D4,1,
1075                                 [define if pthreads API compatible with draft4 spec])
1076                 else
1077                         AC_MSG_ERROR([unknown pthread version])
1078                 fi
1079
1080                 # consider threads found
1081                 ol_with_threads=found
1082
1083                 OL_HEADER_LINUX_THREADS
1084                 OL_HEADER_GNU_PTH_PTHREAD_H
1085
1086                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1087                         AC_CHECK_HEADERS(sched.h)
1088                 fi
1089
1090                 dnl Now the hard part, how to link?
1091                 dnl
1092                 dnl currently supported checks:
1093                 dnl
1094                 dnl Check for no flags
1095                 dnl     pthread_create() in $LIBS
1096                 dnl
1097                 dnl Check special pthread (final) flags
1098                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1099                 dnl     pthread_create() with -kthread (FreeBSD)
1100                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1101                 dnl     pthread_create() with -pthreads (?)
1102                 dnl     pthread_create() with -mthreads (AIX)
1103                 dnl     pthread_create() with -thread (?)
1104                 dnl
1105                 dnl Check pthread (final) libraries
1106                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1107                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1108                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1109                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1110                 dnl     pthread_create() in -lpthread (many)
1111                 dnl     pthread_create() in -lc_r (FreeBSD)
1112                 dnl
1113                 dnl Check pthread (draft4) flags (depreciated)
1114                 dnl     pthread_create() with -threads (OSF/1)
1115                 dnl
1116                 dnl Check pthread (draft4) libraries (depreciated)
1117                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1118                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1119                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1120                 dnl     pthread_create() in -lpthreads (many)
1121                 dnl
1122
1123                 dnl pthread_create in $LIBS
1124                 AC_CACHE_CHECK([for pthread_create in default libraries],
1125                         ol_cv_pthread_create,[
1126                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1127                         [ol_cv_pthread_create=yes],
1128                         [ol_cv_pthread_create=no],
1129                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1130                                 [ol_cv_pthread_create=yes],
1131                                 [ol_cv_pthread_create=no])])])
1132
1133                 if test $ol_cv_pthread_create != no ; then
1134                         ol_link_threads=posix
1135                         ol_link_pthreads=""
1136                 fi
1137
1138 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1139                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1140                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1141                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1142                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1143                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1144
1145                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1146                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1147                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1148                         [ol_cv_pthread_lpthread_lmach_lexc])
1149 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1150 dnl                     [ol_cv_pthread_lpthread_lexc])
1151
1152                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1153                         [ol_cv_pthread_lib_lpthread_woff])
1154
1155                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1156                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1157
1158                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1159
1160                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1161                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1162                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1163                         [ol_cv_pthread_lpthreads_lmach_lexc])
1164                 OL_PTHREAD_TRY([-lpthreads -lexc],
1165                         [ol_cv_pthread_lpthreads_lexc])
1166
1167                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1168
1169                 if test $ol_link_threads != no ; then
1170                         AC_DEFINE(HAVE_PTHREADS,1,
1171                                 [define if you have POSIX Threads])
1172
1173                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1174
1175                         dnl save flags
1176                         save_CPPFLAGS="$CPPFLAGS"
1177                         save_LIBS="$LIBS"
1178                         LIBS="$LTHREAD_LIBS $LIBS"
1179
1180                         dnl All POSIX Thread (final) implementations should have
1181                         dnl sched_yield instead of pthread yield.
1182                         dnl check for both
1183                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1184
1185                         if test $ac_cv_func_sched_yield = no -a \
1186                                 $ac_cv_func_pthread_yield = no ; then
1187                                 dnl Digital UNIX has sched_yield() in -lrt
1188                                 AC_CHECK_LIB(rt, sched_yield,
1189                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1190                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1191                                                 [Define if you have the sched_yield function.])
1192                                         ac_cv_func_sched_yield=yes],
1193                                         [ac_cv_func_sched_yield=no])
1194                         fi
1195                         if test $ac_cv_func_sched_yield = no -a \
1196                                 $ac_cv_func_pthread_yield = no ; then
1197                                 dnl Solaris has sched_yield() stub in -lposix4
1198                                 dnl but we'll use thr_yield instead.
1199                                 AC_CHECK_FUNCS(thr_yield)
1200                         fi
1201                         if test $ac_cv_func_sched_yield = no -a \
1202                                 $ac_cv_func_pthread_yield = no -a \
1203                                 "$ac_cv_func_thr_yield" = no ; then
1204                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1205                         fi
1206
1207                         dnl Check functions for compatibility
1208                         AC_CHECK_FUNCS(pthread_kill pthread_rwlock_destroy)
1209
1210                         dnl Check for pthread_detach with <pthread.h> inclusion
1211                         dnl as it's symbol may have been mangled.
1212                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1213                                 [ol_cv_func_pthread_detach], [
1214                                 dnl save the flags
1215                                 AC_TRY_LINK([
1216 #include <pthread.h>
1217 #ifndef NULL
1218 #define NULL (void*)0
1219 #endif
1220 ],
1221                                         [pthread_detach(NULL);],
1222                                         [ol_cv_func_pthread_detach=yes],
1223                                         [ol_cv_func_pthread_detach=no])
1224                         ])
1225
1226                         if test $ol_cv_func_pthread_detach = no ; then
1227                                 AC_MSG_ERROR([could not locate pthread_detach()])
1228                         fi
1229
1230                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1231                                 [define if you have pthread_detach function])
1232
1233                         dnl Check for setconcurreny functions
1234                         AC_CHECK_FUNCS( \
1235                                 pthread_setconcurrency \
1236                                 pthread_getconcurrency \
1237                                 thr_setconcurrency \
1238                                 thr_getconcurrency \
1239                         )
1240
1241                         OL_SYS_LINUX_THREADS
1242                         OL_LINUX_THREADS
1243
1244                         if test $ol_cv_linux_threads = error; then
1245                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1246                         fi
1247
1248                         AC_CACHE_CHECK([if pthread_create() works],
1249                                 ol_cv_pthread_create_works,[
1250                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1251                                 [ol_cv_pthread_create_works=yes],
1252                                 [ol_cv_pthread_create_works=no],
1253                                 [dnl assume yes
1254                                 ol_cv_pthread_create_works=yes])])
1255
1256                         if test $ol_cv_pthread_create_works = no ; then
1257                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1258                         fi
1259
1260                         dnl Check if select causes an yield
1261                         if test $ol_with_yielding_select = auto ; then
1262                                 AC_CACHE_CHECK([if select yields when using pthreads],
1263                                         ol_cv_pthread_select_yields,[
1264                                 AC_TRY_RUN([
1265 #include <sys/types.h>
1266 #include <sys/time.h>
1267 #include <unistd.h>
1268 #include <pthread.h>
1269 #ifndef NULL
1270 #define NULL (void*) 0
1271 #endif
1272
1273 static int fildes[2];
1274
1275 static void *task(p)
1276         void *p;
1277 {
1278         int i;
1279         struct timeval tv;
1280
1281         fd_set rfds;
1282
1283         tv.tv_sec=10;
1284         tv.tv_usec=0;
1285
1286         FD_ZERO(&rfds);
1287         FD_SET(fildes[0], &rfds);
1288
1289         /* we're not interested in any fds */
1290         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1291
1292         if(i < 0) {
1293                 perror("select");
1294                 exit(10);
1295         }
1296
1297         exit(0); /* if we exit here, the select blocked the whole process */
1298 }
1299
1300 int main(argc, argv)
1301         int argc;
1302         char **argv;
1303 {
1304         pthread_t t;
1305
1306         /* create a pipe to select */
1307         if(pipe(&fildes[0])) {
1308                 perror("select");
1309                 exit(1);
1310         }
1311
1312 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1313         (void) pthread_setconcurrency(2);
1314 #else
1315 #ifdef HAVE_THR_SETCONCURRENCY
1316         /* Set Solaris LWP concurrency to 2 */
1317         thr_setconcurrency(2);
1318 #endif
1319 #endif
1320
1321 #if HAVE_PTHREADS_D4
1322         pthread_create(&t, pthread_attr_default, task, NULL);
1323 #else
1324         pthread_create(&t, NULL, task, NULL);
1325 #endif
1326
1327 #if HAVE_SCHED_YIELD
1328         sched_yield();  /* make sure task runs first */
1329 #else
1330 #ifdef HAVE_PTHREAD_YIELD
1331         pthread_yield();        /* make sure task runs first */
1332 #endif
1333 #endif
1334
1335         exit(2);
1336 }],
1337                                 [ol_cv_pthread_select_yields=no],
1338                                 [ol_cv_pthread_select_yields=yes],
1339                                 [ol_cv_pthread_select_yields=cross])])
1340
1341                                 if test $ol_cv_pthread_select_yields = cross ; then
1342                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1343                                 fi
1344
1345                                 if test $ol_cv_pthread_select_yields = yes ; then
1346                                         ol_with_yielding_select=yes
1347                                 fi
1348                         fi
1349
1350                         dnl restore flags
1351                         CPPFLAGS="$save_CPPFLAGS"
1352                         LIBS="$save_LIBS"
1353                 else
1354                         AC_MSG_ERROR([could not link with POSIX Threads])
1355                 fi
1356         fi
1357
1358         if test $ol_with_threads = posix ; then
1359                 AC_MSG_ERROR([could not locate POSIX Threads])
1360         fi
1361 fi
1362
1363 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1364         -o $ol_with_threads = mach ; then
1365
1366         dnl check for Mach CThreads
1367         AC_CHECK_HEADERS(mach/cthreads.h)
1368         if test $ac_cv_header_mach_cthreads_h = yes ; then
1369                 ol_with_threads=found
1370
1371                 dnl check for cthread support in current $LIBS
1372                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1373
1374                 if test $ol_link_threads = no ; then
1375                         dnl try -all_load
1376                         dnl this test needs work
1377                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1378                                 [ol_cv_cthread_all_load], [
1379                                 dnl save the flags
1380                                 save_LIBS="$LIBS"
1381                                 LIBS="-all_load $LIBS"
1382                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1383                                         cthread_fork((void *)0, (void *)0);
1384                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1385                                 dnl restore the LIBS
1386                                 LIBS="$save_LIBS"
1387                         ])
1388
1389                         if test $ol_cv_cthread_all_load = yes ; then
1390                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1391                                 ol_link_threads=mach
1392                         fi
1393                 fi
1394
1395                 if test $ol_link_threads != no ; then
1396                         : check for cthread specific functionality here
1397                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1398                                 [define if you have Mach Cthreads])
1399                 else
1400                         AC_MSG_ERROR([could not link with Mach CThreads])
1401                 fi
1402         fi
1403
1404         if test $ol_with_threads = mach ; then
1405                 AC_MSG_ERROR([could not locate Mach CThreads])
1406         fi
1407 fi
1408
1409 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1410         -o $ol_with_threads = pth ; then
1411
1412         AC_CHECK_HEADERS(pth.h)
1413
1414         if test $ac_cv_header_pth_h = yes ; then
1415                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1416
1417                 if test $have_pth = yes ; then
1418                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1419                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1420                         ol_link_threads=pth
1421
1422                         if test $ol_with_yielding_select = auto ; then
1423                                 ol_with_yielding_select=yes
1424                         fi
1425                 fi
1426         fi
1427 fi
1428
1429 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1430         -o $ol_with_threads = lwp ; then
1431
1432         dnl check for SunOS5 LWP
1433         AC_CHECK_HEADERS(thread.h synch.h)
1434         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1435                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1436
1437                 if test $have_thr = yes ; then
1438                         AC_DEFINE(HAVE_THR,1,
1439                                 [if you have Solaris LWP (thr) package])
1440                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1441                         ol_link_threads=thr
1442
1443                         if test $ol_with_yielding_select = auto ; then
1444                                 ol_with_yielding_select=yes
1445                         fi
1446
1447                         dnl Check for setconcurreny functions
1448                         AC_CHECK_FUNCS( \
1449                                 thr_setconcurrency \
1450                                 thr_getconcurrency \
1451                         )
1452                 fi
1453         fi
1454
1455         dnl check for SunOS4 LWP
1456         AC_CHECK_HEADERS(lwp/lwp.h)
1457         if test $ac_cv_header_lwp_lwp_h = yes ; then
1458                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1459
1460                 if test $have_lwp = yes ; then
1461                         AC_DEFINE(HAVE_LWP,1,
1462                                 [if you have SunOS LWP package])
1463                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1464                         ol_link_threads=lwp
1465
1466                         if test $ol_with_yielding_select = auto ; then
1467                                 ol_with_yielding_select=no
1468                         fi
1469                 fi
1470         fi
1471 fi
1472
1473 if test $ol_with_yielding_select = yes ; then
1474         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1475                 [define if select implicitly yields])
1476 fi
1477
1478 if test $ol_with_threads = manual ; then
1479         dnl User thinks he can manually configure threads.
1480         ol_link_threads=yes
1481
1482         AC_MSG_WARN([thread defines and link options must be set manually])
1483
1484         AC_CHECK_HEADERS(pthread.h sched.h)
1485         AC_CHECK_FUNCS(sched_yield pthread_yield)
1486         OL_HEADER_LINUX_THREADS
1487
1488         AC_CHECK_HEADERS(mach/cthreads.h)
1489         AC_CHECK_HEADERS(lwp/lwp.h)
1490         AC_CHECK_HEADERS(thread.h synch.h)
1491 fi
1492
1493 if test $ol_link_threads != no -a $ol_link_threads != nt ; then
1494         dnl needed to get reentrant/threadsafe versions
1495         dnl
1496         AC_DEFINE(REENTRANT,1)
1497         AC_DEFINE(_REENTRANT,1)
1498         AC_DEFINE(THREAD_SAFE,1)
1499         AC_DEFINE(_THREAD_SAFE,1)
1500         AC_DEFINE(THREADSAFE,1)
1501         AC_DEFINE(_THREADSAFE,1)
1502         AC_DEFINE(_SGI_MP_SOURCE,1)
1503
1504         dnl The errno declaration may dependent upon _REENTRANT.
1505         dnl If it does, we must link with thread support.
1506         AC_CACHE_CHECK([for thread specific errno],
1507                 [ol_cv_errno_thread_specific], [
1508                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1509                         [ol_cv_errno_thread_specific=yes],
1510                         [ol_cv_errno_thread_specific=no])
1511         ])
1512
1513         dnl The h_errno declaration may dependent upon _REENTRANT.
1514         dnl If it does, we must link with thread support.
1515         AC_CACHE_CHECK([for thread specific h_errno],
1516                 [ol_cv_h_errno_thread_specific], [
1517                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1518                         [ol_cv_h_errno_thread_specific=yes],
1519                         [ol_cv_h_errno_thread_specific=no])
1520         ])
1521
1522         if test $ol_cv_errno_thread_specific != yes \
1523                 -o $ol_cv_h_errno_thread_specific != yes ; then
1524                 LIBS="$LTHREAD_LIBS $LIBS"
1525                 LTHREAD_LIBS=""
1526         fi
1527
1528 dnl When in thread environment, use
1529 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1530 dnl                     || defined( HAVE_FUNC_R )
1531 dnl                     func_r(...);
1532 dnl             #else
1533 dnl             #       if defined( HAVE_THREADS )
1534 dnl                             /* lock */
1535 dnl             #       endif
1536 dnl                             func(...);
1537 dnl             #       if defined( HAVE_THREADS )
1538 dnl                             /* unlock */
1539 dnl             #       endif
1540 dnl             #endif
1541 dnl
1542 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1543 dnl             _POSIX_REENTRANT_FUNCTIONS
1544 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1545 dnl             _POSIX_THREADSAFE_FUNCTIONS
1546 dnl
1547 dnl             and is currently defined in lthread.h
1548 dnl
1549 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1550 dnl
1551 dnl libldap/*.c should only include <lthread.h> iff
1552 dnl LDAP_R_COMPILE is defined.  ie:
1553 dnl             #ifdef LDAP_R_COMPILE
1554 dnl             #       include LDAP_R_COMPILE
1555 dnl             #endif
1556 dnl
1557 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1558 dnl specifically for compiling the threadsafe version of
1559 dnl     the ldap library (-lldap_r).
1560 dnl
1561 dnl     dnl check for reentrant/threadsafe functions
1562 dnl     dnl
1563 dnl     dnl note: these should only be used when linking
1564 dnl     dnl       with $LTHREAD_LIBS
1565 dnl     dnl
1566 dnl     save_CPPFLAGS="$CPPFLAGS"
1567 dnl     save_LIBS="$LIBS"
1568 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1569 dnl     AC_CHECK_FUNCS( \
1570 dnl             gmtime_r \
1571 dnl             gethostbyaddr_r gethostbyname_r \
1572 dnl             feof_unlocked unlocked_feof \
1573 dnl             putc_unlocked unlocked_putc \
1574 dnl             flockfile ftrylockfile \
1575 dnl     )
1576 dnl     CPPFLAGS="$save_CPPFLAGS"
1577 dnl     LIBS="$save_LIBS"
1578 fi
1579
1580 if test $ol_link_threads = no ; then
1581         if test $ol_with_threads = yes ; then
1582                 AC_MSG_ERROR([no suitable thread support])
1583         fi
1584
1585         if test $ol_with_threads = auto ; then
1586                 AC_MSG_WARN([no suitable thread support, disabling threads])
1587                 ol_with_threads=no
1588         fi
1589
1590         AC_DEFINE(NO_THREADS,1,
1591                 [define if you have (or want) no threads])
1592         LTHREAD_LIBS=""
1593 fi
1594
1595 if test $ol_link_threads != no ; then
1596         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1597 fi
1598
1599 dnl ----------------------------------------------------------------
1600 ol_link_ldbm=no
1601
1602 if test $ol_with_ldbm_api = auto \
1603         -o $ol_with_ldbm_api = berkeley \
1604         -o $ol_with_ldbm_api = bcompat ; then
1605
1606         if test $ol_with_ldbm_api = bcompat; then \
1607                 OL_BERKELEY_COMPAT_DB
1608         else
1609                 OL_BERKELEY_DB
1610         fi
1611
1612         if test $ol_cv_berkeley_db != no ; then
1613                 AC_DEFINE(HAVE_BERKELEY_DB,1,
1614                         [define this if Berkeley DB is available])
1615
1616                 ol_link_ldbm=berkeley
1617                 ol_with_ldbm_api=db
1618
1619                 if test $ol_with_ldbm_type = hash ; then
1620                         AC_DEFINE(LDBM_USE_DBHASH,1,
1621                                 [define this to use DBHASH w/ LDBM backend])
1622                 else
1623                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1624                                 [define this to use DBBTREE w/ LDBM backend])
1625                 fi
1626
1627                 dnl $ol_cv_lib_db should be yes or -ldb
1628                 dnl (it could be no, but that would be an error
1629                 if test $ol_cv_lib_db != yes ; then
1630                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1631                 fi
1632         fi
1633 fi
1634
1635 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1636         AC_MSG_WARN(Could not find LDBM with BTREE support)
1637         ol_with_ldbm_api=none
1638 fi
1639
1640 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1641         OL_MDBM
1642
1643         if test $ol_cv_mdbm = yes ; then
1644                 ol_link_ldbm=mdbm
1645                 ol_with_ldbm_api=mdbm
1646                 if test $ol_cv_lib_mdbm != yes ; then
1647                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1648                 fi
1649         fi
1650 fi
1651
1652 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1653         OL_GDBM
1654
1655         if test $ol_cv_gdbm = yes ; then
1656                 ol_link_ldbm=gdbm
1657                 ol_with_ldbm_api=gdbm
1658
1659                 if test $ol_cv_lib_gdbm != yes ; then
1660                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1661                 fi
1662         fi
1663 fi
1664
1665 if test $ol_with_ldbm_api = ndbm ; then
1666         OL_NDBM
1667
1668         if test $ol_cv_ndbm = yes ; then
1669                 ol_link_ldbm=ndbm
1670                 ol_with_ldbm_api=ndbm
1671
1672                 if test $ol_cv_lib_ndbm != yes ; then
1673                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1674                 fi
1675         fi
1676 fi
1677
1678 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1679         AC_MSG_WARN(could not find suitable LDBM backend)
1680         if test $ol_enable_ldbm = yes ; then
1681                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1682         fi
1683
1684         AC_MSG_WARN(disabling LDBM)
1685         ol_enable_ldbm=no
1686 fi
1687
1688 dnl ----------------------------------------------------------------
1689 if test $ol_enable_dynamic = yes -a $enable_shared = yes ; then
1690         LINK_BINS_DYNAMIC="yes"
1691 else
1692         LINK_BINS_DYNAMIC="no"
1693 fi
1694
1695 dnl ----------------------------------------------------------------
1696 if test $ol_enable_wrappers != no ; then
1697         AC_CHECK_HEADERS(tcpd.h)
1698
1699         if test $ac_cv_header_tcpd_h != yes ; then
1700                 have_wrappers=no
1701         else
1702                 AC_TRY_COMPILE([
1703 int allow_severity = 0;
1704 int deny_severity  = 0;
1705                 ],[hosts_access()],[have_wrappers=yes],[have_wrappers=no])
1706         fi
1707
1708         if test $have_wrappers = yes ; then
1709                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1710                 WRAP_LIBS="-lwrap"
1711
1712                 dnl We add another check for -lnsl since some libwrap's
1713                 dnl need it, but it isn't always included from above
1714                 AC_CHECK_LIB(nsl, main)
1715         else
1716                 AC_MSG_WARN(could not find -lwrap)
1717                 if test $ol_enable_wrappers = yes ; then
1718                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1719                 fi
1720
1721                 AC_MSG_WARN(disabling wrappers support)
1722                 ol_enable_wrappers=no
1723                 WRAP_LIBS=""
1724         fi
1725 fi
1726
1727 dnl ----------------------------------------------------------------
1728 if test $ol_enable_syslog != no ; then
1729         AC_CHECK_FUNC(openlog)
1730         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1731                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1732         fi
1733         ol_enable_syslog=$ac_cv_func_openlog
1734 fi
1735
1736 dnl ----------------------------------------------------------------
1737 dnl SQL
1738 ol_link_sql=no
1739 if test $ol_enable_sql != no ; then
1740         AC_CHECK_LIB(iodbc,SQLDriverConnect,[have_iodbc=yes],[have_iodbc=no])
1741         if test $have_iodbc = yes ; then
1742                 ol_link_sql="-liodbc"
1743         else
1744                 AC_CHECK_LIB(odbc,SQLDriverConnect,[have_odbc=yes],[have_odbc=no])
1745                 if test $have_odbc = yes ; then
1746                         ol_link_sql="-lodbc"
1747                 fi
1748         fi
1749
1750         if test $ol_link_sql != no ; then
1751                 SLAPD_SQL_LIBS="$ol_link_sql"
1752
1753         elif test $ol_enable_sql != auto ; then
1754                 AC_MSG_ERROR([could not locate suitable ODBC library])
1755         fi
1756 fi
1757
1758 dnl ----------------------------------------------------------------
1759 dnl ud needs termcap (should insert check here)
1760 ol_link_termcap=no
1761 AC_CHECK_HEADERS(termcap.h ncurses.h)
1762
1763 if test $ol_link_termcap = no ; then
1764         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1765         if test $have_termcap = yes ; then
1766                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1767                 ol_link_termcap=yes
1768                 TERMCAP_LIBS=-ltermcap
1769         fi
1770 fi
1771
1772 if test $ol_link_termcap = no ; then
1773         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1774         if test $have_ncurses = yes ; then
1775                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1776                 ol_link_termcap=yes
1777                 TERMCAP_LIBS=-lncurses
1778         fi
1779 fi
1780
1781 if test $ol_link_termcap = no ; then
1782         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1783         TERMCAP_LIBS=
1784 fi
1785
1786 dnl ----------------------------------------------------------------
1787 dnl
1788 dnl Check for Cyrus SASL
1789 dnl
1790 ol_link_sasl=no
1791 ol_link_spasswd=no
1792 if test $ol_with_cyrus_sasl != no ; then
1793         AC_CHECK_HEADERS(sasl.h)
1794
1795         if test $ac_cv_header_sasl_h = yes ; then
1796                 AC_CHECK_LIB(sasl, sasl_client_init,
1797                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1798
1799                 if test $have_cyrus_sasl != no ; then
1800                         SASL_LIBS="-lsasl"
1801                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1802                         ol_link_sasl=yes
1803                 fi
1804         fi
1805
1806         if test $ol_link_sasl = no ; then
1807                 if test $ol_with_cyrus_sasl != auto ; then
1808                         AC_MSG_ERROR([Could not locate Cyrus SASL])
1809                 else
1810                         AC_MSG_WARN([Could not locate Cyrus SASL])
1811                         AC_MSG_WARN([SASL authentication not supported!])
1812                         if test $ol_link_tls = no ; then
1813                                 AC_MSG_WARN([Strong authentication not supported!])
1814                         fi
1815                 fi
1816
1817         elif test $ol_enable_spasswd != no ; then
1818                 ol_link_spasswd=yes
1819         fi
1820
1821 else
1822         AC_MSG_WARN([SASL authentication not supported!])
1823         if test $ol_link_tls = no ; then
1824                 AC_MSG_WARN([Strong authentication not supported!])
1825         fi
1826 fi
1827
1828 dnl ----------------------------------------------------------------
1829 dnl Check for entropy sources
1830 if test $cross_compiling != yes ; then
1831         dev=no
1832         if test -r /dev/urandom ; then
1833                 dev="/dev/urandom";
1834         elif test -r /idev/urandom ; then
1835                 dev="/idev/urandom";
1836         elif test -r /dev/srandom ; then
1837                 dev="/dev/srandom";
1838         elif test -r /dev/random ; then
1839                 dev="/dev/random";
1840         elif test -r /idev/random ; then
1841                 dev="/idev/random";
1842         fi
1843
1844         if test $dev != no ; then
1845                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
1846         fi
1847 fi
1848
1849 dnl ----------------------------------------------------------------
1850 dnl
1851 dnl Check for fetch URL support
1852 dnl             should be extended to support other fetch URL APIs
1853 dnl
1854 ol_link_fetch=no
1855 if test $ol_with_fetch != no ; then
1856         OL_LIB_FETCH
1857
1858         if test $ol_cv_lib_fetch != no ; then
1859                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1860                 ol_link_fetch=freebsd
1861
1862         elif test $ol_with_fetch != auto ; then
1863                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1864         fi
1865 fi
1866
1867 dnl ----------------------------------------------------------------
1868 dnl
1869 dnl Check for GNU readline
1870 dnl
1871 ol_link_readline=no
1872 if test $ol_with_readline != no ; then
1873         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1874
1875         if test $ac_cv_header_readline_readline_h = yes ; then
1876                 save_LIBS="$LIBS"
1877                 LIBS="$TERMCAP_LIBS $LIBS"
1878                 AC_CHECK_LIB(readline, readline,
1879                         [have_readline=yes], [have_readline=no])
1880                 LIBS="$save_LIBS"
1881
1882                 if test $have_readline = yes ; then
1883                         ol_with_readline=found
1884                         ol_link_readline=yes
1885
1886                         READLINE_LIBS="-lreadline"
1887                 fi
1888         fi
1889 fi
1890
1891 if test $ol_link_readline = yes ; then
1892         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1893 fi
1894
1895
1896 dnl ----------------------------------------------------------------
1897 dnl FreeBSD (and others) have crypt(3) in -lcrypt
1898 if test $ol_enable_crypt != no ; then
1899         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1900                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1901                         have_crypt=yes], [have_crypt=no])])
1902
1903         if test $have_crypt = yes ; then
1904                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1905         else
1906                 AC_MSG_WARN(could not find crypt)
1907                 if test $ol_enable_crypt = yes ; then
1908                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1909                 fi
1910
1911                 AC_MSG_WARN(disabling crypt support)
1912                 ol_enable_crypt=no
1913         fi
1914 fi
1915
1916 dnl ----------------------------------------------------------------
1917 dnl FreeBSD (and others) have setproctitle(3) in -lutil
1918 if test $ol_enable_proctitle != no ; then
1919         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1920                 AC_CHECK_LIB(util, setproctitle,
1921                         [have_setproctitle=yes
1922                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1923                         [have_setproctitle=no
1924                         LIBOBJS="$LIBOBJS setproctitle.o"
1925                         LIBSRCS="$LIBSRCS setproctitle.c"])])
1926
1927         if test $have_setproctitle = yes ; then
1928                 AC_DEFINE(HAVE_SETPROCTITLE,1,
1929                         [define if setproctitle(3) is available])
1930         fi
1931 fi
1932
1933 dnl ----------------------------------------------------------------
1934 dnl Checks for typedefs, structures, and compiler characteristics.
1935 AC_TYPE_MODE_T
1936 AC_TYPE_OFF_T
1937 AC_TYPE_PID_T
1938 AM_TYPE_PTRDIFF_T
1939 AC_TYPE_SIGNAL
1940 AC_TYPE_SIZE_T
1941
1942 AC_CHECK_TYPE(ssize_t, [signed int])
1943 AC_CHECK_TYPE(caddr_t,  [char *])
1944
1945 OL_TYPE_SOCKLEN_T
1946 AC_STRUCT_ST_BLKSIZE
1947 AC_HEADER_TIME
1948 AC_STRUCT_TM
1949 AC_TYPE_UID_T
1950 OL_TYPE_SIG_ATOMIC_T
1951
1952 dnl AC_TYPE_GETGROUPS
1953
1954 OL_STRUCT_PASSWD_PW_GECOS
1955 OL_STRUCT_PASSWD_PW_PASSWD
1956
1957 OL_C_UPPER_LOWER
1958 AC_C_CONST
1959 OL_C_VOLATILE
1960
1961 if test $cross_compiling = yes ; then
1962         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1963 else
1964         AC_C_BIGENDIAN
1965 fi
1966
1967 AC_COMPILE_CHECK_SIZEOF(short)
1968 AC_COMPILE_CHECK_SIZEOF(int)
1969 AC_COMPILE_CHECK_SIZEOF(long)
1970
1971 if test "$ac_cv_sizeof_int" -lt 4 ; then
1972         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
1973
1974         AC_DEFINE(LBER_INT_T,long)
1975 else
1976         AC_DEFINE(LBER_INT_T,int)
1977 fi
1978
1979 AC_DEFINE(LBER_LEN_T,long)
1980 AC_DEFINE(LBER_SOCKET_T,int)
1981 AC_DEFINE(LBER_TAG_T,long)
1982
1983 dnl ----------------------------------------------------------------
1984 dnl Checks for library functions.
1985 AC_FUNC_MEMCMP
1986 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1987 AC_FUNC_STRFTIME
1988 dnl AM_FUNC_STRTOD
1989
1990 OL_FUNC_INET_ATON
1991
1992 dnl Check for NT specific routines
1993 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
1994
1995 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
1996         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
1997 ])
1998
1999 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2000         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2001 ])
2002
2003 AC_FUNC_VPRINTF
2004
2005 if test $ac_cv_func_vprintf = yes ; then
2006         dnl check for vsnprintf
2007         AC_CHECK_FUNCS(vsnprintf vsprintf)
2008 fi
2009
2010 AC_CHECK_FUNCS(         \
2011         bcopy                   \
2012         closesocket             \
2013         chroot                  \
2014         endgrent                \
2015         endpwent                \
2016         fcntl                   \
2017         flock                   \
2018         getdtablesize   \
2019         getgrgid                \
2020         gethostname             \
2021         getpass                 \
2022         getpassphrase   \
2023         getpwuid                \
2024         getpwnam                \
2025         getspnam                \
2026         gettimeofday    \
2027         initgroups              \
2028         lockf                   \
2029         memcpy                  \
2030         memmove                 \
2031         mkstemp                 \
2032         pipe                    \
2033         read                    \
2034         recv                    \
2035         recvfrom                \
2036         setpwfile               \
2037         setgid                  \
2038         setegid                 \
2039         setsid                  \
2040         setuid                  \
2041         seteuid                 \
2042         sigaction               \
2043         signal                  \
2044         sigset                  \
2045         snprintf                \
2046         strdup                  \
2047         strerror                \
2048         strpbrk                 \
2049         strrchr                 \
2050         strsep                  \
2051         strstr                  \
2052         strtol                  \
2053         strtoul                 \
2054         strspn                  \
2055         sysconf                 \
2056         waitpid                 \
2057         wait4                   \
2058         write                   \
2059         send                    \
2060         sendto                  \
2061 )
2062
2063 dnl We actually may need to replace more than this.
2064 AC_REPLACE_FUNCS(getopt tempnam)
2065
2066 if test "$ac_cv_func_getopt" != yes; then
2067     LIBSRCS="$LIBSRCS getopt.c"
2068 fi
2069
2070 if test "$ac_cv_func_tempnam" != yes; then
2071     LIBSRCS="$LIBSRCS tempnam.c"
2072 fi
2073
2074 dnl ----------------------------------------------------------------
2075 # Check Configuration
2076 OL_SYS_ERRLIST
2077
2078 dnl ----------------------------------------------------------------
2079 dnl Sort out defines
2080
2081 if test "$ol_enable_debug" != no ; then
2082         AC_DEFINE(LDAP_DEBUG,1,
2083                 [define this to add debugging code])
2084 fi
2085 if test "$ol_enable_syslog" = yes ; then
2086         AC_DEFINE(LDAP_SYSLOG,1,
2087                 [define this to add syslog code])
2088 fi
2089 if test "$ol_enable_cache" = no ; then
2090         AC_DEFINE(LDAP_NOCACHE,1,
2091                 [define this to remove -lldap cache support])
2092 fi
2093 if test "$ol_link_kbind" != no ; then
2094         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_KBIND,LDAP_VENDOR_VERSION)
2095 fi
2096 if test "$ol_enable_proctitle" != no ; then
2097         AC_DEFINE(LDAP_PROCTITLE,1,
2098                 [define this for LDAP process title support])
2099 fi
2100 if test "$ol_enable_referrals" != no ; then
2101         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
2102 fi
2103 if test "$ol_enable_local" != no; then
2104         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2105 fi
2106 if test "$ol_link_ipv6" != no; then
2107         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2108 fi
2109 if test "$ol_enable_cleartext" != no ; then
2110         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2111 fi
2112 if test "$ol_enable_crypt" != no ; then
2113         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2114 fi
2115 if test "$ol_link_kpasswd" != no ; then
2116         AC_DEFINE(SLAPD_KPASSWD,1,[define to support Kerberos passwords])
2117 fi
2118 if test "$ol_link_spasswd" != no ; then
2119         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2120 fi
2121 dnl if test "$ol_enable_multimaster" != no ; then
2122 dnl     AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2123 dnl fi
2124 if test "$ol_enable_phonetic" != no ; then
2125         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
2126 fi
2127 if test "$ol_enable_rlookups" != no ; then
2128         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2129 fi
2130 if test "$ol_enable_aci" != no ; then
2131         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2132 fi
2133
2134 if test "$ol_link_modules" != no ; then
2135         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2136         BUILD_SLAPD=yes
2137         SLAPD_MODULES_LDFLAGS="-dlopen self"
2138 fi
2139
2140 if test "$ol_link_dnssrv" != no ; then
2141         AC_DEFINE(SLAPD_DNSSRV,1,[define to support DNS SRV backend])
2142         BUILD_SLAPD=yes
2143         BUILD_DNSSRV=yes
2144         if test "$ol_with_dnssrv_module" != static ; then
2145                 AC_DEFINE(SLAPD_DNSSRV_DYNAMIC,1,
2146                         [define to support dynamic DNS SRV backend])
2147                 BUILD_DNSSRV=mod
2148                 BUILD_DNSSRV_DYNAMIC=shared
2149                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-dnssrv/back_dnssrv.la"
2150         fi
2151 fi
2152
2153 if test "$ol_enable_ldap" != no ; then
2154         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
2155         BUILD_SLAPD=yes
2156         BUILD_LDAP=yes
2157         if test "$ol_with_ldap_module" != static ; then
2158                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
2159                         [define to support dynamic LDAP backend])
2160                 BUILD_LDAP=mod
2161                 BUILD_LDAP_DYNAMIC=shared
2162                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
2163         fi
2164 fi
2165
2166 if test "$ol_link_ldbm" != no ; then
2167         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
2168         BUILD_SLAPD=yes
2169         BUILD_LDBM=yes
2170         if test "$ol_with_ldbm_module" != static ; then
2171                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
2172                         [define to support dynamic LDBM backend])
2173                 BUILD_LDBM=mod
2174                 BUILD_LDBM_DYNAMIC=shared
2175                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
2176         fi
2177 fi
2178
2179 if test "$ol_enable_passwd" != no ; then
2180         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2181         BUILD_SLAPD=yes
2182         BUILD_PASSWD=yes
2183         if test "$ol_with_passwd_module" != static ; then
2184                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2185                         [define to support dynamic PASSWD backend])
2186                 BUILD_PASSWD=mod
2187                 BUILD_PASSWD_DYNAMIC=shared
2188                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
2189         fi
2190 fi
2191
2192 if test "$ol_enable_shell" != no ; then
2193         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2194         BUILD_SLAPD=yes
2195         BUILD_SHELL=yes
2196         if test "$ol_with_shell_module" != static ; then
2197                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2198                         [define to support dynamic SHELL backend])
2199                 BUILD_SHELL=mod
2200                 BUILD_SHELL_DYNAMIC=shared
2201                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2202         fi
2203 fi
2204
2205 if test "$ol_enable_sql" != no ; then
2206         AC_DEFINE(SLAPD_SQL,1,[define to support SQL backend])
2207         BUILD_SLAPD=yes
2208         BUILD_SQL=yes
2209         if test "$ol_with_sql_module" != static; then
2210                 AC_DEFINE(SLAPD_SQL_DYNAMIC,1,
2211                         [define to support dynamic SQL backend])
2212                 BUILD_SQL=mod
2213                 BUILD_SQL_DYNAMIC=shared
2214                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-sql/back_sql.la"
2215         fi
2216 fi
2217
2218 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2219         $BUILD_SLAPD = yes ; then
2220         BUILD_SLURPD=yes
2221 fi
2222
2223 dnl ----------------------------------------------------------------
2224
2225 if test "$LINK_BINS_DYNAMIC" = yes; then
2226     LIB_LINKAGE=DYN
2227     LT_LIB_LINKAGE=shared
2228 else
2229     LIB_LINKAGE=STAT
2230     LT_LIB_LINKAGE=static
2231 fi
2232
2233 if test "$ac_cv_mingw32" = yes ; then
2234     PLAT=NT
2235     DYN_EXT=dll
2236 else
2237     PLAT=UNIX
2238     DYN_EXT=so
2239 fi
2240
2241 AC_SUBST(LIBSRCS)
2242
2243 AC_SUBST(PLAT)
2244 AC_SUBST(LIB_LINKAGE)
2245 AC_SUBST(LT_LIB_LINKAGE)
2246 AC_SUBST(DYN_EXT)
2247
2248 AC_SUBST(BUILD_SLAPD)
2249   AC_SUBST(BUILD_DNSSRV)
2250   AC_SUBST(BUILD_LDAP)
2251   AC_SUBST(BUILD_LDBM)
2252   AC_SUBST(BUILD_PASSWD)
2253   AC_SUBST(BUILD_SHELL)
2254   AC_SUBST(BUILD_SQL)
2255   AC_SUBST(BUILD_DNSSRV_DYNAMIC)
2256   AC_SUBST(BUILD_LDAP_DYNAMIC)
2257   AC_SUBST(BUILD_LDBM_DYNAMIC)
2258   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2259   AC_SUBST(BUILD_SHELL_DYNAMIC)
2260   AC_SUBST(BUILD_SQL_DYNAMIC)
2261 AC_SUBST(BUILD_SLURPD)
2262
2263 AC_SUBST(LDAP_LIBS)
2264 AC_SUBST(LDIF_LIBS)
2265 AC_SUBST(SLAPD_LIBS)
2266 AC_SUBST(SLURPD_LIBS)
2267 AC_SUBST(LDBM_LIBS)
2268 AC_SUBST(LTHREAD_LIBS)
2269 AC_SUBST(LUTIL_LIBS)
2270 AC_SUBST(WRAP_LIBS)
2271 AC_SUBST(LINK_BINS_DYNAMIC)
2272
2273 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2274 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2275 AC_SUBST(SLAPD_MODULES_LIST)
2276
2277 AC_SUBST(KRB4_LIBS)
2278 AC_SUBST(KRB5_LIBS)
2279 AC_SUBST(READLINE_LIBS)
2280 AC_SUBST(SASL_LIBS)
2281 AC_SUBST(TERMCAP_LIBS)
2282 AC_SUBST(TLS_LIBS)
2283 AC_SUBST(MODULES_LIBS)
2284 AC_SUBST(AUTH_LIBS)
2285
2286 AC_SUBST(SLAPD_SQL_LDFLAGS)
2287 AC_SUBST(SLAPD_SQL_LIBS)
2288 AC_SUBST(SLAPD_SQL_INCLUDES)
2289
2290 dnl ----------------------------------------------------------------
2291 dnl final output
2292 dnl
2293
2294 AC_OUTPUT( \
2295 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2296 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2297 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2298 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2299 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2300 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2301 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2302 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2303 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2304 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2305 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2306 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2307 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2308 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2309 clients/maildap/Makefile:build/top.mk:clients/maildap/Makefile.in:build/rules.mk \
2310 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2311 include/Makefile:build/top.mk:include/Makefile.in \
2312 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2313 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2314 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2315 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2316 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2317 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2318 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2319 libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk  \
2320 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2321 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2322 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2323 servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk \
2324 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2325 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2326 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2327 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2328 servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk \
2329 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2330 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2331 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2332 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2333 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2334 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2335 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2336 ,[
2337 date > stamp-h
2338 echo Please \"make depend\" to build dependencies
2339 ])