git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms are permitted only
   6 dnl as authorized by the OpenLDAP Public License.  A copy of this
   7 dnl license is available at http://www.OpenLDAP.org/license.html or
   8 dnl in file LICENSE in the top-level directory of the distribution.
   9 dnl
  10 define([AC_INIT_BINSH],
  11 [[#! /bin/sh
  12 # $]OpenLDAP[$
  13 # from] translit([$OpenLDAP$], $")] [
  14
  15 # Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
  16 #
  17 # Redistribution and use in source and binary forms are permitted only
  18 # as authorized by the OpenLDAP Public License.  A copy of this
  19 # license is available at http://www.OpenLDAP.org/license.html or
  20 # in file LICENSE in the top-level directory of the distribution.
  21 ])dnl
  22
  23 dnl Disable config.cache!
  24 define([AC_CACHE_LOAD], )dnl
  25 define([AC_CACHE_SAVE], )dnl
  26
  27 dnl Configure.in for OpenLDAP
  28 AC_INIT(build/version)dnl
  29 AC_CONFIG_AUX_DIR(build)dnl
  30
  31 OL_VERSION=`cat $ac_aux_dir/version`
  32 if test -z "$OL_VERSION"; then
  33         AC_MSG_ERROR([could not determine version])
  34 fi
  35
  36 dnl ----------------------------------------------------------------
  37 dnl Determine host platform
  38 dnl             we try not to use this for much
  39 AC_CANONICAL_SYSTEM
  40
  41 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  42 AC_SUBST(PACKAGE)
  43 AC_SUBST(VERSION)
  44 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  45 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  46
  47 dnl require: dnl autoconf 2.13.1
  48 dnl also:
  49 dnl aclocal.m4 should be built using aclocal from automake 1.4
  50 dnl libtool 1.3.3 should be installed.
  51 AC_PREREQ(2.13.1)dnl Required Autoconf version
  52
  53 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  54
  55 dnl ----------------------------------------------------------------
  56 dnl Start Args
  57 AC_MSG_CHECKING(configure arguments)
  58 AC_PREFIX_DEFAULT(/usr/local)
  59
  60 top_builddir=`pwd`
  61 AC_SUBST(top_builddir)dnl
  62
  63 ldap_subdir="/openldap"
  64
  65 AC_ARG_WITH(subdir,
  66 [  --with-subdir=DIR change default subdirectory used for installs],
  67 [case "$withval" in
  68         no) ldap_subdir=""
  69                 ;;
  70         yes)
  71                 ;;
  72         /*|\\*)
  73                 ldap_subdir="$withval"
  74                 ;;
  75         *)
  76                 ldap_subdir="/$withval"
  77                 ;;
  78 esac
  79 ])dnl
  80
  81 AC_SUBST(ldap_subdir)dnl
  82
  83 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  84 dnl ol_enable_syslog=no
  85 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  86 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  87 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  88 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DX Referrals extension], no)dnl
  89 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  90 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  91 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  92         no, [yes no])dnl
  93
  94 dnl General "with" options
  95 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  96
  97 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl     with Cyrus SASL support],
  98         auto, [auto yes no] )
  99 OL_ARG_WITH(fetch,[  --with-fetch               with fetch URL support],
 100         auto, [auto yes no] )
 101 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
 102         auto, [auto k5 k4 afs yes no])
 103 OL_ARG_WITH(readline,[  --with-readline with readline support],
 104         auto, [auto yes no] )
 105 OL_ARG_WITH(threads,[  --with-threads   use threads],
 106         auto, [auto posix mach pth lwp yes no manual] )
 107 OL_ARG_WITH(tls,[  --with-tls           with TLS/SSL support],
 108         auto, [auto ssleay openssl yes no] )
 109 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
 110         auto, [auto yes no manual] )
 111
 112 dnl Server options
 113
 114 dnl SLAPD OPTIONS
 115 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 116 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
 117 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
 118 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
 119 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
 120 OL_ARG_ENABLE(multimaster,[    --enable-multimaster     enable multimaster replication], no)dnl
 121 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
 122 OL_ARG_ENABLE(quipu,[    --enable-quipu build quipu migration tools], no)dnl
 123 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
 124 OL_ARG_ENABLE(aci,[    --enable-aci     enable per-object ACIs], no)dnl
 125 OL_ARG_ENABLE(discreteaci,[    --enable-discreteaci     enable discrete rights in ACIs], no)dnl
 126 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
 127
 128 dnl SLAPD Backend options
 129 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 130 OL_ARG_WITH(bdb2_module,[      --with-bdb2-module       module type], static,
 131         [static dynamic])
 132 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 133 OL_ARG_WITH(ldap_module,[      --with-ldap-module       module type], static,
 134         [static dynamic])
 135 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 136 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 137         [auto db2 db mdbm gdbm ndbm manual])
 138 OL_ARG_WITH(ldbm_module,[      --with-ldbm-module       module type], static,
 139         [static dynamic])
 140 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 141         [auto btree hash])
 142
 143 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 144 OL_ARG_WITH(passwd_module,[      --with-passwd-module   module type], static,
 145         [static dynamic])
 146 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 147 OL_ARG_WITH(perl_module,[      --with-perl-module       module type], static,
 148         [static dynamic])
 149 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 150 OL_ARG_WITH(shell_module,[      --with-shell-module     module type], static,
 151         [static dynamic])
 152 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 153 OL_ARG_WITH(tcl_module,[      --with-tcl-module module type], static,
 154         [static dynamic])
 155
 156 dnl SLURPD OPTIONS
 157 AC_ARG_WITH(xxslurpdoptions,[SLURPD (Replication Daemon) Options:])
 158 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 159
 160 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 161 AC_ENABLE_STATIC
 162 dnl AC_DISABLE_SHARED
 163 AC_ENABLE_SHARED
 164
 165 dnl General "enable" options
 166 # validate options
 167 if test $ol_enable_dns = yes ; then
 168         if test $ol_enable_referrals = no ; then
 169                 AC_MSG_ERROR([DNS requires --enable-referrals])
 170         fi
 171         if test $ol_enable_referrals = auto ; then
 172                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 173                 ol_enable_referrals=yes
 174         fi
 175 fi
 176
 177 if test $ol_enable_slapd = no ; then
 178         dnl SLAPD was specificallly disabled
 179         if test $ol_enable_bdb2 = yes ; then
 180                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 181         fi
 182         if test $ol_enable_ldap = yes ; then
 183                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 184         fi
 185         if test $ol_enable_ldbm = yes ; then
 186                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 187         fi
 188         if test $ol_enable_passwd = yes ; then
 189                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 190         fi
 191         if test $ol_enable_perl = yes ; then
 192                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 193         fi
 194         if test $ol_enable_shell = yes ; then
 195                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 196         fi
 197         if test $ol_enable_tcl = yes ; then
 198                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 199         fi
 200         if test $ol_enable_modules = yes ; then
 201                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 202         fi
 203         if test $ol_enable_multimaster = yes ; then
 204                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 205         fi
 206         if test $ol_enable_wrappers = yes ; then
 207                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 208         fi
 209         if test $ol_enable_phonetic = yes ; then
 210                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 211         fi
 212         if test $ol_enable_quipu = yes ; then
 213                 AC_MSG_WARN([slapd disabled, ignoring --enable-quipu argument])
 214         fi
 215         if test $ol_enable_rlookups = yes ; then
 216                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 217         fi
 218         if test $ol_enable_aci = yes ; then
 219                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 220         fi
 221         if test $ol_enable_discreteaci = yes ; then
 222                 AC_MSG_WARN([slapd disabled, ignoring --enable-discreteaci argument])
 223         fi
 224         if test $ol_with_ldbm_api != auto ; then
 225                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 226         fi
 227         if test $ol_with_ldbm_type != auto ; then
 228                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 229         fi
 230         if test $ol_with_bdb2_module != static ; then
 231                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb2-module argument])
 232         fi
 233         if test $ol_with_ldap_module != static ; then
 234                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 235         fi
 236         if test $ol_with_ldbm_module != static ; then
 237                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 238         fi
 239         if test $ol_with_passwd_module != static ; then
 240                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 241         fi
 242         if test $ol_with_perl_module != static ; then
 243                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 244         fi
 245         if test $ol_with_shell_module != static ; then
 246                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 247         fi
 248         if test $ol_with_tcl_module != static ; then
 249                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 250         fi
 251         if test $ol_enable_slurpd = yes ; then
 252                 AC_MSG_ERROR([slurpd requires slapd])
 253         fi
 254
 255         # force settings to no
 256         ol_enable_bdb2=no
 257         ol_enable_ldap=no
 258         ol_enable_ldbm=no
 259         ol_enable_passwd=no
 260         ol_enable_perl=no
 261         ol_enable_shell=no
 262         ol_enable_tcl=no
 263
 264         ol_enable_modules=no
 265         ol_enable_multimaster=no
 266         ol_enable_phonetic=no
 267         ol_enable_quipu=no
 268         ol_enable_rlookups=no
 269         ol_enable_aci=no
 270         ol_enable_discreteaci=no
 271         ol_enable_wrappers=no
 272
 273         ol_with_ldbm_api=no
 274         ol_with_ldbm_type=no
 275
 276         ol_with_bdb2_module=static
 277         ol_with_ldap_module=static
 278         ol_with_ldbm_module=static
 279         ol_with_passwd_module=static
 280         ol_with_perl_module=static
 281         ol_with_shell_module=static
 282         ol_with_tcl_module=static
 283
 284         ol_enable_slurpd=no
 285
 286 elif test $ol_enable_ldbm = no ; then
 287         dnl SLAPD without LDBM
 288
 289         if test $ol_with_ldbm_api != auto ; then
 290                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 291         fi
 292
 293         if test $ol_with_ldbm_type != auto ; then
 294                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 295         fi
 296
 297         if test $ol_with_ldbm_module != static ; then
 298                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 299         fi
 300
 301         if test $ol_enable_bdb2 = yes ; then
 302                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 303         fi
 304
 305         if test $ol_enable_modules != yes -a \
 306                 $ol_enable_ldap = no -a \
 307                 $ol_enable_passwd = no -a \
 308                 $ol_enable_perl = no -a \
 309                 $ol_enable_shell = no -a \
 310                 $ol_enable_tcl = no ; then
 311                 AC_MSG_ERROR([slapd requires a backend])
 312         fi
 313
 314         ol_with_ldbm_api=no
 315         ol_with_ldbm_type=no
 316         ol_with_ldbm_module=static
 317
 318 elif test $ol_enable_bdb2 = yes ; then
 319         dnl SLAPD with BDB2
 320
 321         if test $ol_with_ldbm_api != auto -a \
 322                 $ol_with_ldbm_api != db2 ; then
 323                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 324         fi
 325
 326         ol_with_ldbm_api=db2
 327
 328 else
 329         dnl SLAPD with LDBM
 330
 331         if test $ol_enable_bdb2 != no ; then
 332                 if test $ol_with_ldbm_api != auto -a \
 333                         $ol_with_ldbm_api != db2 ; then
 334                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 335                         ol_enable_bdb2=no
 336                 fi
 337         fi
 338
 339         if test $ol_with_ldbm_api = gdbm -a \
 340                 $ol_with_ldbm_type = btree ; then
 341                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 342         fi
 343         if test $ol_with_ldbm_api = mdbm -a \
 344                 $ol_with_ldbm_type = btree ; then
 345                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 346         fi
 347         if test $ol_with_ldbm_api = ndbm -a \
 348                 $ol_with_ldbm_type = btree ; then
 349                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 350         fi
 351 fi
 352
 353 if test $ol_enable_slurpd = yes ; then
 354         dnl SLURPD was specifically enabled
 355         if test $ol_with_threads = no ; then
 356                 AC_MSG_ERROR([slurpd requires threads])
 357         fi
 358 fi
 359
 360 AC_MSG_RESULT(done)
 361
 362 ## Initialize vars
 363 LDAP_LIBS=
 364 LDIF_LIBS=
 365 LDBM_LIBS=
 366 LTHREAD_LIBS=
 367 LUTIL_LIBS=
 368
 369 SLAPD_LIBS=
 370 SLURPD_LIBS=
 371
 372 BUILD_SLAPD=no
 373 BUILD_SLURPD=no
 374
 375 BUILD_BDB2=no
 376 BUILD_LDAP=no
 377 BUILD_LDBM=no
 378 BUILD_PASSWD=no
 379 BUILD_PERL=no
 380 BUILD_QUIPU=no
 381 BUILD_SHELL=no
 382 BUILD_TCL=no
 383 BUILD_THREAD=no
 384
 385 BUILD_BDB2_DYNAMIC=static
 386 BUILD_LDAP_DYNAMIC=static
 387 BUILD_LDBM_DYNAMIC=static
 388 BUILD_PASSWD_DYNAMIC=static
 389 BUILD_PERL_DYNAMIC=static
 390 BUILD_SHELL_DYNAMIC=static
 391 BUILD_TCL_DYNAMIC=static
 392
 393 SLAPD_MODULES_LDFLAGS=
 394 SLAPD_MODULES_CPPFLAGS=
 395 SLAPD_MODULES_LIST=
 396
 397 SLAPD_PERL_LDFLAGS=
 398 SLAPD_PERL_CPPFLAGS=
 399
 400 KRB_LIBS=
 401 READLINE_LIBS=
 402 SASL_LIBS=
 403 TERMCAP_LIBS=
 404 TLS_LIBS=
 405 MODULES_LIBS=
 406
 407 dnl ----------------------------------------------------------------
 408 dnl Checks for programs
 409
 410 dnl AC_PROG_INSTALL
 411
 412 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 413
 414 dnl
 415 dnl Determine which C translator to use
 416 dnl
 417
 418 dnl AIX Thread requires we use cc_r or xlc_r.
 419 dnl But only do this IF AIX and CC is not set
 420 dnl and threads are auto|yes|posix.
 421 dnl
 422 dnl If we find cc_r|xlc_r, force pthreads and assume
 423 dnl             pthread_create is in $LIBS (ie: don't bring in
 424 dnl             any additional thread libraries)
 425 dnl If we do not find cc_r|xlc_r, disable threads
 426
 427 ol_aix_threads=no
 428 case "$target" in
 429 *-*-aix*) dnl all AIX is not a good idea.
 430         if test -z "$CC" ; then
 431                 case "$ol_with_threads" in
 432                 auto | yes |  posix) ol_aix_threads=yes ;;
 433                 esac
 434         fi
 435 ;;
 436 esac
 437
 438 if test $ol_aix_threads = yes ; then
 439         if test -z "${CC}" ; then
 440                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 441
 442                 if test "$CC" = cc ; then
 443                         dnl no CC! don't allow --with-threads
 444                         if test $ol_with_threads != auto ; then
 445                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 446                         else
 447                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 448                         fi
 449                         ol_with_threads=no
 450                 fi
 451         fi
 452
 453         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 454                 ol_with_threads=posix
 455                 ol_cv_pthread_create=yes
 456         fi
 457 fi
 458
 459 if test -z "${CC}"; then
 460         AC_CHECK_PROGS(CC,cc)
 461 fi
 462
 463 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 464 dnl (for now, let autoconf sort this out)
 465 dnl CFLAGS=${CFLAGS-""}
 466
 467 AC_LIBTOOL_DLOPEN
 468 AC_PROG_LIBTOOL
 469 dnl AC_PROG_MAKE_SET
 470
 471 AC_PROG_AWK
 472 OL_PROG_LN_H
 473 AC_PROG_LN_S
 474
 475 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 476         LN_S="$LN_H"
 477 fi
 478
 479 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 480         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 481 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 482 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 483
 484 ol_link_perl=no
 485 if test $ol_enable_perl != no ; then
 486         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 487
 488         if test "no$PERLBIN" = "no" ; then
 489                 if test $ol_enable_perl = yes ; then
 490                         AC_MSG_ERROR([could not locate perl])
 491                 fi
 492
 493         else
 494                 SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 495                 SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 496
 497                 dnl should check perl version
 498                 ol_link_perl=yes
 499         fi
 500 fi
 501
 502 AC_PROG_CPP
 503
 504 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 505         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 506
 507 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 508         AC_MSG_WARN([programs compiled here do run here...])
 509         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 510
 511 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 512         AC_MSG_WARN([programs compiled here do not run here...])
 513         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 514 fi
 515
 516 dnl Checks for UNIX Variants
 517 AC_AIX
 518 AC_ISC_POSIX
 519 AC_MINIX
 520
 521 dnl Checks for system services
 522 AC_CYGWIN
 523 AC_MINGW32
 524 AC_EXEEXT
 525 AC_OBJEXT
 526
 527 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 528
 529 dnl BeOS requires -lbe -lroot -lnet
 530 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 531
 532 dnl OpenLDAP requires STDC features
 533 AM_PROG_CC_STDC
 534 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 535         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 536 fi
 537
 538 dnl Check cc depend flags
 539 OL_MKDEPEND
 540 if test "${ol_cv_mkdep}" = no ; then
 541         # this will soon become an error
 542         AC_MSG_WARN([do not know how to generate dependencies])
 543 fi
 544
 545 dnl
 546 dnl Check for module support
 547 dnl
 548 ol_link_modules=no
 549 if test $ol_enable_modules != no ; then
 550         AC_CHECK_HEADERS(ltdl.h)
 551
 552         if test $ac_cv_header_ltdl_h = no ; then
 553                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 554
 555         fi
 556
 557         AC_CHECK_LIB(ltdl, lt_dlinit)
 558         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 559                 AC_MSG_ERROR([could not locate libtool -lltdl])
 560         fi
 561         ol_link_modules=yes
 562 else
 563         ol_with_bdb2_module=static
 564         ol_with_ldap_module=static
 565         ol_with_ldbm_module=static
 566         ol_with_passwd_module=static
 567         ol_with_perl_module=static
 568         ol_with_shell_module=static
 569         ol_with_tcl_module=static
 570 fi
 571
 572 dnl ----------------------------------------------------------------
 573 dnl Checks for header files.
 574 OL_HEADER_STDC
 575
 576 if test $ol_cv_header_stdc != yes; then
 577         AC_MSG_WARN([could not locate Standard C compliant headers])
 578 fi
 579
 580 AC_HEADER_DIRENT
 581 AC_HEADER_SYS_WAIT
 582 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 583 if test $am_cv_sys_posix_termios = yes ; then
 584         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 585                 [define if you have POSIX termios])
 586 fi
 587
 588 AC_CHECK_HEADERS(       \
 589         arpa/inet.h             \
 590         arpa/nameser.h  \
 591         assert.h                \
 592         crypt.h                 \
 593         errno.h                 \
 594         fcntl.h                 \
 595         filio.h                 \
 596         getopt.h                \
 597         grp.h                   \
 598         libutil.h               \
 599         limits.h                \
 600         locale.h                \
 601         netinet/tcp.h   \
 602         malloc.h                \
 603         memory.h                \
 604         psap.h                  \
 605         pwd.h                   \
 606         resolv.h                \
 607         sgtty.h                 \
 608         shadow.h                \
 609         stddef.h                \
 610         string.h                \
 611         strings.h               \
 612         sysexits.h              \
 613         sys/file.h              \
 614         sys/filio.h             \
 615         sys/errno.h             \
 616         sys/ioctl.h             \
 617         sys/param.h             \
 618         sys/resource.h  \
 619         sys/select.h    \
 620         sys/socket.h    \
 621         sys/syslog.h    \
 622         sys/time.h              \
 623         sys/types.h             \
 624         syslog.h                \
 625         termios.h               \
 626         unistd.h                \
 627 )
 628
 629 dnl ----------------------------------------------------------------
 630 dnl Checks for libraries
 631
 632 dnl Find socket()
 633 dnl Likely combinations:
 634 dnl             -lsocket [ -lnsl_s | -lnsl ]
 635 dnl             -linet
 636
 637 AC_CHECK_FUNC(socket, :, [
 638 dnl hopefully we won't include too many libraries
 639         AC_CHECK_LIB(socket, main)
 640         AC_CHECK_LIB(net, main)
 641         AC_CHECK_LIB(net, socket)
 642         AC_CHECK_LIB(nsl_s, main)
 643         AC_CHECK_LIB(nsl, main)
 644         AC_CHECK_LIB(inet, socket)
 645         AC_CHECK_LIB(gen, main)
 646 ])
 647
 648 dnl require select
 649 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 650 dnl AC_CHECK_FUNCS(socketpair)
 651
 652 dnl Select arg types
 653 dnl (if this detection becomes permenent, it and the select() detection
 654 dnl should be done before the yielding select test)
 655 AC_FUNC_SELECT_ARGTYPES
 656
 657 dnl check to see if system call automatically restart
 658 dnl AC_SYS_RESTARTABLE_SYSCALLS
 659
 660 dnl require POSIX regex
 661 AC_CHECK_HEADERS( regex.h )
 662 if test "$ac_cv_header_regex_h" != yes ; then
 663         AC_MSG_ERROR([POSIX regex.h required.])
 664 fi
 665 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 666
 667 OL_POSIX_REGEX
 668 if test "$ol_cv_c_posix_regex" = no ; then
 669         AC_MSG_ERROR([broken POSIX regex!])
 670 fi
 671
 672 dnl HP-UX requires -lV3
 673 AC_CHECK_LIB(V3, sigset)
 674
 675 dnl Check for resolver routines
 676 AC_CHECK_FUNC(res_search,:)
 677 if test $ac_cv_func_res_search = no ; then
 678         AC_CHECK_LIB(bind, res_search)
 679         ac_cv_func_res_search=$ac_cv_lib_bind_res_search
 680 fi
 681
 682 if test $ac_cv_func_res_search = no ; then
 683         AC_CHECK_LIB(bind, __res_search)
 684         ac_cv_func_res_search=$ac_cv_lib_bind___res_search
 685 fi
 686
 687 if test $ac_cv_func_res_search = no ; then
 688         AC_CHECK_LIB(resolv, res_search)
 689         ac_cv_func_res_search=$ac_cv_lib_resolv_res_search
 690 fi
 691
 692 if test "$ac_cv_func_res_search" = yes ; then
 693         AC_DEFINE(HAVE_RES_SEARCH,1,
 694                 [define if you have res_search()])
 695 elif test $ol_enable_dns = yes ; then
 696         AC_MSG_ERROR([--enable-dns requires res_search])
 697 elif test $ol_enable_dns != no ; then
 698         AC_MSG_WARN([no res_search, disabling DNS support])
 699 fi
 700
 701
 702 # QUIPU
 703 if test $ol_enable_quipu != no ; then
 704         AC_CHECK_HEADERS(quipu/commonarg.h)
 705
 706         if test $ac_cv_header_quipu_commonarg_h = yes ; then
 707                 BUILD_QUIPU=yes
 708         elif test $ol_enable_quipu = auto ; then
 709                 AC_MSG_WARN([no quipu for --enable-quipu=auto, disabling])
 710         else
 711                 AC_MSG_ERROR(no quipu for --enable-quipu=$ol_enable_quipu)
 712         fi
 713 fi
 714
 715 dnl
 716 dnl check for kerberos
 717 dnl
 718 ol_link_kerberos=no
 719
 720 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 721         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 722
 723         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 724                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 725                         [-lkrb5 -ldes425])
 726
 727                 if test $have_k5 = yes ; then
 728                         ol_with_kerberos=found
 729                         ol_link_kerberos=yes
 730
 731                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 732
 733                         LIBS="$KRB_LIBS $LIBS"
 734
 735                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 736                                 [ol_cv_var_des_debug], [
 737                                 dnl save the flags
 738                                 save_LIBS="$LIBS"
 739                                 LIBS="$KRB_LIBS $LIBS"
 740                                 AC_TRY_LINK([
 741 #include <kerberosIV/krb.h>
 742 #include <kerberosIV/des.h>
 743 extern int des_debug;
 744 ],[
 745 des_debug = 1;
 746 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 747                                 dnl restore the LIBS
 748                                 LIBS="$save_LIBS"
 749                         ])
 750
 751                         if test $ol_cv_var_des_debug = yes ; then
 752                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 753                                         [define if you have Kerberos des_debug])
 754                         fi
 755
 756                         LIBS="$save_LIBS"
 757                 fi
 758         fi
 759 fi
 760
 761 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 762         AC_CHECK_HEADERS(krb.h des.h)
 763
 764         if test $ac_cv_header_krb_h = yes ; then
 765                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 766
 767                 if test $have_k4 = yes ; then
 768                         ol_with_kerberos=found
 769                         ol_link_kerberos=yes
 770
 771                         KRB_LIBS="-lkrb -ldes"
 772                 fi
 773         fi
 774 fi
 775
 776 if test $ol_link_kerberos = yes ; then
 777         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 778 fi
 779
 780 dnl
 781 dnl Check for SSL/TLS
 782 dnl
 783 ol_link_tls=no
 784 if test $ol_with_tls != no ; then
 785
 786         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 787
 788         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 789                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 790                         [have_ssleay=yes
 791                         need_rsaref=no],
 792                         [have_ssleay=no],
 793                         [-lcrypto])
 794
 795                 if test $have_ssleay = no ; then
 796                         AC_CHECK_LIB(ssl, SSL_library_init,
 797                                 [have_ssleay=yes
 798                                 need_rsaref=no], [have_ssleay=no],
 799                                 [-lcrypto])
 800                 fi
 801
 802                 if test $have_ssleay = no ; then
 803                         AC_CHECK_LIB(ssl, ssl3_accept,
 804                                 [have_ssleay=yes
 805                                 need_rsaref=yes], [have_ssleay=no],
 806                                 [-lcrypto -lRSAglue -lrsaref])
 807                 fi
 808
 809                 if test $have_ssleay = yes ; then
 810                         ol_with_tls=found
 811                         ol_link_tls=yes
 812
 813                         AC_DEFINE(HAVE_SSLEAY, 1,
 814                                 [define if you have SSLeay or OpenSSL])
 815
 816                         if test $need_rsaref = yes; then
 817                                 AC_DEFINE(HAVE_RSAREF, 1,
 818                                         [define if you have RSAref])
 819
 820                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 821                         else
 822                                 TLS_LIBS="-lssl -lcrypto"
 823                         fi
 824                 fi
 825         fi
 826 fi
 827
 828 if test $ol_link_tls = yes ; then
 829         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 830 fi
 831
 832 dnl Tests for reentrant functions necessary to build a
 833 dnl thread_safe -lldap.
 834 AC_CHECK_FUNCS(         \
 835         ctime_r                 \
 836         gethostbyname_r gethostbyaddr_r \
 837 )
 838
 839 if test "$ac_cv_func_ctime_r" = no ; then
 840         ol_cv_func_ctime_r_nargs=0
 841 else
 842         OL_FUNC_CTIME_R_NARGS
 843 dnl     OL_FUNC_CTIME_R_TYPE
 844 fi
 845
 846 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 847         OL_FUNC_GETHOSTBYNAME_R_NARGS
 848 else
 849         ol_cv_func_gethostbyname_r_nargs=0
 850 fi
 851
 852 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 853         OL_FUNC_GETHOSTBYADDR_R_NARGS
 854 else
 855         ol_cv_func_gethostbyaddr_r_nargs=0
 856 fi
 857
 858 if test "$ac_cv_func_ctime_r" = yes \
 859         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 860         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 861         -a "$ac_cv_func_gethostbyname_r" = yes \
 862         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 863         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 864         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 865         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 866         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 867         ; then
 868
 869         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 870 fi
 871
 872 ol_link_threads=no
 873 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 874         -o $ol_with_threads = posix ; then
 875
 876         AC_CHECK_HEADERS(pthread.h)
 877
 878         if test $ac_cv_header_pthread_h = yes ; then
 879                 OL_POSIX_THREAD_VERSION
 880
 881                 if test $ol_cv_pthread_version = final ; then
 882                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 883                                 [define if pthreads API compatible with final spec])
 884                 elif test $ol_cv_pthread_version = draft4 ; then
 885                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 886                                 [define if pthreads API compatible with draft4 spec])
 887                 else
 888                         AC_MSG_ERROR([unknown pthread version])
 889                 fi
 890
 891                 # consider threads found
 892                 ol_with_threads=found
 893
 894                 OL_HEADER_LINUX_THREADS
 895                 OL_HEADER_GNU_PTH_PTHREAD_H
 896
 897                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
 898                         AC_CHECK_HEADERS(sched.h)
 899                 fi
 900
 901                 dnl Now the hard part, how to link?
 902                 dnl
 903                 dnl currently supported checks:
 904                 dnl
 905                 dnl Check for no flags
 906                 dnl     pthread_create() in $LIBS
 907                 dnl
 908                 dnl Check special pthread (final) flags
 909                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
 910                 dnl     pthread_create() with -kthread (FreeBSD)
 911                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 912                 dnl     pthread_create() with -pthreads (?)
 913                 dnl     pthread_create() with -mthreads (AIX)
 914                 dnl     pthread_create() with -thread (?)
 915                 dnl
 916                 dnl Check pthread (final) libraries
 917                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 918                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 919                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 920                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
 921                 dnl     pthread_create() in -lpthread (many)
 922                 dnl     pthread_create() in -lc_r (FreeBSD)
 923                 dnl
 924                 dnl Check pthread (draft4) flags (depreciated)
 925                 dnl     pthread_create() with -threads (OSF/1)
 926                 dnl
 927                 dnl Check pthread (draft4) libraries (depreciated)
 928                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 929                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 930                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 931                 dnl     pthread_create() in -lpthreads (many)
 932                 dnl
 933
 934                 dnl pthread_create in $LIBS
 935                 AC_CACHE_CHECK([for pthread_create in default libraries],
 936                         ol_cv_pthread_create,[
 937                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
 938                         [ol_cv_pthread_create=yes],
 939                         [ol_cv_pthread_create=no],
 940                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
 941                                 [ol_cv_pthread_create=yes],
 942                                 [ol_cv_pthread_create=no])])])
 943
 944                 if test $ol_cv_pthread_create != no ; then
 945                         ol_link_threads=posix
 946                         ol_link_pthreads=""
 947                 fi
 948
 949 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
 950                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
 951                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
 952                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
 953                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
 954                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
 955
 956                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
 957                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
 958                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
 959                         [ol_cv_pthread_lpthread_lmach_lexc])
 960 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
 961 dnl                     [ol_cv_pthread_lpthread_lexc])
 962
 963                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
 964                         [ol_cv_pthread_lib_lpthread_woff])
 965
 966                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
 967                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
 968
 969                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
 970
 971                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
 972                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
 973                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
 974                         [ol_cv_pthread_lpthreads_lmach_lexc])
 975                 OL_PTHREAD_TRY([-lpthreads -lexc],
 976                         [ol_cv_pthread_lpthreads_lexc])
 977
 978                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
 979
 980                 if test $ol_link_threads != no ; then
 981                         AC_DEFINE(HAVE_PTHREADS,1,
 982                                 [define if you have POSIX Threads])
 983
 984                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
 985
 986                         dnl save flags
 987                         save_CPPFLAGS="$CPPFLAGS"
 988                         save_LIBS="$LIBS"
 989                         LIBS="$LTHREAD_LIBS $LIBS"
 990
 991                         dnl All POSIX Thread (final) implementations should have
 992                         dnl sched_yield instead of pthread yield.
 993                         dnl check for both
 994                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 995
 996                         if test $ac_cv_func_sched_yield = no -a \
 997                                 $ac_cv_func_pthread_yield = no ; then
 998                                 dnl Digital UNIX has sched_yield() in -lrt
 999                                 AC_CHECK_LIB(rt, sched_yield,
1000                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1001                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1002                                                 [Define if you have the sched_yield function.])
1003                                         ac_cv_func_sched_yield=yes],
1004                                         [ac_cv_func_sched_yield=no])
1005                         fi
1006                         if test $ac_cv_func_sched_yield = no -a \
1007                                 $ac_cv_func_pthread_yield = no ; then
1008                                 dnl Solaris has sched_yield() stub in -lposix4
1009                                 dnl but we'll use thr_yield instead.
1010                                 AC_CHECK_FUNCS(thr_yield)
1011                         fi
1012                         if test $ac_cv_func_sched_yield = no -a \
1013                                 $ac_cv_func_pthread_yield = no -a \
1014                                 "$ac_cv_func_thr_yield" = no ; then
1015                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1016                         fi
1017
1018                         dnl Check functions for compatibility
1019                         AC_CHECK_FUNCS(pthread_kill)
1020
1021                         dnl Check for pthread_detach with <pthread.h> inclusion
1022                         dnl as it's symbol may have been mangled.
1023                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1024                                 [ol_cv_func_pthread_detach], [
1025                                 dnl save the flags
1026                                 AC_TRY_LINK([
1027 #include <pthread.h>
1028 #ifndef NULL
1029 #define NULL (void*)0
1030 #endif
1031 ],
1032                                         [pthread_detach(NULL);],
1033                                         [ol_cv_func_pthread_detach=yes],
1034                                         [ol_cv_func_pthread_detach=no])
1035                         ])
1036
1037                         if test $ol_cv_func_pthread_detach = no ; then
1038                                 AC_MSG_ERROR([could not locate pthread_detach()])
1039                         fi
1040
1041                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1042                                 [define if you have pthread_detach function])
1043
1044                         dnl Check for setconcurreny functions
1045                         AC_CHECK_FUNCS( \
1046                                 pthread_setconcurrency \
1047                                 pthread_getconcurrency \
1048                                 thr_setconcurrency \
1049                                 thr_getconcurrency \
1050                         )
1051
1052                         OL_SYS_LINUX_THREADS
1053                         OL_LINUX_THREADS
1054
1055                         if test $ol_cv_linux_threads = error; then
1056                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1057                         fi
1058
1059                         AC_CACHE_CHECK([if pthread_create() works],
1060                                 ol_cv_pthread_create_works,[
1061                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1062                                 [ol_cv_pthread_create_works=yes],
1063                                 [ol_cv_pthread_create_works=no],
1064                                 [dnl assume yes
1065                                 ol_cv_pthread_create_works=yes])])
1066
1067                         if test $ol_cv_pthread_create_works = no ; then
1068                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1069                         fi
1070
1071                         dnl Check if select causes an yield
1072                         if test $ol_with_yielding_select = auto ; then
1073                                 AC_CACHE_CHECK([if select yields when using pthreads],
1074                                         ol_cv_pthread_select_yields,[
1075                                 AC_TRY_RUN([
1076 #include <sys/types.h>
1077 #include <sys/time.h>
1078 #include <unistd.h>
1079 #include <pthread.h>
1080 #ifndef NULL
1081 #define NULL (void*) 0
1082 #endif
1083
1084 static int fildes[2];
1085
1086 static void *task(p)
1087         void *p;
1088 {
1089         int i;
1090         struct timeval tv;
1091
1092         fd_set rfds;
1093
1094         tv.tv_sec=10;
1095         tv.tv_usec=0;
1096
1097         FD_ZERO(&rfds);
1098         FD_SET(fildes[0], &rfds);
1099
1100         /* we're not interested in any fds */
1101         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1102
1103         if(i < 0) {
1104                 perror("select");
1105                 exit(10);
1106         }
1107
1108         exit(0); /* if we exit here, the select blocked the whole process */
1109 }
1110
1111 int main(argc, argv)
1112         int argc;
1113         char **argv;
1114 {
1115         pthread_t t;
1116
1117         /* create a pipe to select */
1118         if(pipe(&fildes[0])) {
1119                 perror("select");
1120                 exit(1);
1121         }
1122
1123 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1124         (void) pthread_setconcurrency(2);
1125 #else
1126 #ifdef HAVE_THR_SETCONCURRENCY
1127         /* Set Solaris LWP concurrency to 2 */
1128         thr_setconcurrency(2);
1129 #endif
1130 #endif
1131
1132 #if HAVE_PTHREADS_D4
1133         pthread_create(&t, pthread_attr_default, task, NULL);
1134 #else
1135         pthread_create(&t, NULL, task, NULL);
1136 #endif
1137
1138 #if HAVE_SCHED_YIELD
1139         sched_yield();  /* make sure task runs first */
1140 #else
1141 #ifdef HAVE_PTHREAD_YIELD
1142         pthread_yield();        /* make sure task runs first */
1143 #endif
1144 #endif
1145
1146         exit(2);
1147 }],
1148                                 [ol_cv_pthread_select_yields=no],
1149                                 [ol_cv_pthread_select_yields=yes],
1150                                 [ol_cv_pthread_select_yields=cross])])
1151
1152                                 if test $ol_cv_pthread_select_yields = cross ; then
1153                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1154                                 fi
1155
1156                                 if test $ol_cv_pthread_select_yields = yes ; then
1157                                         ol_with_yielding_select=yes
1158                                 fi
1159                         fi
1160
1161                         dnl restore flags
1162                         CPPFLAGS="$save_CPPFLAGS"
1163                         LIBS="$save_LIBS"
1164                 else
1165                         AC_MSG_ERROR([could not link with POSIX Threads])
1166                 fi
1167         fi
1168
1169         if test $ol_with_threads = posix ; then
1170                 AC_MSG_ERROR([could not locate POSIX Threads])
1171         fi
1172 fi
1173
1174 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1175         -o $ol_with_threads = mach ; then
1176
1177         dnl check for Mach CThreads
1178         AC_CHECK_HEADERS(mach/cthreads.h)
1179         if test $ac_cv_header_mach_cthreads_h = yes ; then
1180                 ol_with_threads=found
1181
1182                 dnl check for cthread support in current $LIBS
1183                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1184
1185                 if test $ol_link_threads = no ; then
1186                         dnl try -all_load
1187                         dnl this test needs work
1188                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1189                                 [ol_cv_cthread_all_load], [
1190                                 dnl save the flags
1191                                 save_LIBS="$LIBS"
1192                                 LIBS="-all_load $LIBS"
1193                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1194                                         cthread_fork((void *)0, (void *)0);
1195                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1196                                 dnl restore the LIBS
1197                                 LIBS="$save_LIBS"
1198                         ])
1199
1200                         if test $ol_cv_cthread_all_load = yes ; then
1201                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1202                                 ol_link_threads=mach
1203                         fi
1204                 fi
1205
1206                 if test $ol_link_threads != no ; then
1207                         : check for cthread specific functionality here
1208                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1209                                 [define if you have Mach Cthreads])
1210                 else
1211                         AC_MSG_ERROR([could not link with Mach CThreads])
1212                 fi
1213         fi
1214
1215         if test $ol_with_threads = mach ; then
1216                 AC_MSG_ERROR([could not locate Mach CThreads])
1217         fi
1218 fi
1219
1220 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1221         -o $ol_with_threads = pth ; then
1222
1223         AC_CHECK_HEADERS(pth.h)
1224
1225         if test $ac_cv_header_pth_h = yes ; then
1226                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1227
1228                 if test $have_pth = yes ; then
1229                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1230                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1231                         ol_link_threads=pth
1232
1233                         if test $ol_with_yielding_select = auto ; then
1234                                 ol_with_yielding_select=yes
1235                         fi
1236                 fi
1237         fi
1238 fi
1239
1240 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1241         -o $ol_with_threads = lwp ; then
1242
1243         dnl check for SunOS5 LWP
1244         AC_CHECK_HEADERS(thread.h synch.h)
1245         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1246                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1247
1248                 if test $have_thr = yes ; then
1249                         AC_DEFINE(HAVE_THR,1,
1250                                 [if you have Solaris LWP (thr) package])
1251                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1252                         ol_link_threads=thr
1253
1254                         if test $ol_with_yielding_select = auto ; then
1255                                 ol_with_yielding_select=yes
1256                         fi
1257
1258                         dnl Check for setconcurreny functions
1259                         AC_CHECK_FUNCS( \
1260                                 thr_setconcurrency \
1261                                 thr_getconcurrency \
1262                         )
1263                 fi
1264         fi
1265
1266         dnl check for SunOS4 LWP
1267         AC_CHECK_HEADERS(lwp/lwp.h)
1268         if test $ac_cv_header_lwp_lwp_h = yes ; then
1269                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1270
1271                 if test $have_lwp = yes ; then
1272                         AC_DEFINE(HAVE_LWP,1,
1273                                 [if you have SunOS LWP package])
1274                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1275                         ol_link_threads=lwp
1276
1277                         if test $ol_with_yielding_select = auto ; then
1278                                 ol_with_yielding_select=no
1279                         fi
1280                 fi
1281         fi
1282 fi
1283
1284 if test $ol_with_yielding_select = yes ; then
1285         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1286                 [define if select implicitly yields])
1287 fi
1288
1289 if test $ol_with_threads = manual ; then
1290         dnl User thinks he can manually configure threads.
1291         ol_link_threads=yes
1292
1293         AC_MSG_WARN([thread defines and link options must be set manually])
1294
1295         AC_CHECK_HEADERS(pthread.h sched.h)
1296         AC_CHECK_FUNCS(sched_yield pthread_yield)
1297         OL_HEADER_LINUX_THREADS
1298
1299         AC_CHECK_HEADERS(mach/cthreads.h)
1300         AC_CHECK_HEADERS(lwp/lwp.h)
1301         AC_CHECK_HEADERS(thread.h synch.h)
1302 fi
1303
1304 if test $ol_link_threads != no ; then
1305         dnl needed to get reentrant/threadsafe versions
1306         dnl
1307         AC_DEFINE(REENTRANT,1)
1308         AC_DEFINE(_REENTRANT,1)
1309         AC_DEFINE(THREAD_SAFE,1)
1310         AC_DEFINE(_THREAD_SAFE,1)
1311         AC_DEFINE(THREADSAFE,1)
1312         AC_DEFINE(_THREADSAFE,1)
1313         AC_DEFINE(_SGI_MP_SOURCE,1)
1314
1315         dnl The errno declaration may dependent upon _REENTRANT.
1316         dnl If it does, we must link with thread support.
1317         AC_CACHE_CHECK([for thread specific errno],
1318                 [ol_cv_errno_thread_specific], [
1319                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1320                         [ol_cv_errno_thread_specific=yes],
1321                         [ol_cv_errno_thread_specific=no])
1322         ])
1323
1324         dnl The h_errno declaration may dependent upon _REENTRANT.
1325         dnl If it does, we must link with thread support.
1326         AC_CACHE_CHECK([for thread specific h_errno],
1327                 [ol_cv_h_errno_thread_specific], [
1328                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1329                         [ol_cv_h_errno_thread_specific=yes],
1330                         [ol_cv_h_errno_thread_specific=no])
1331         ])
1332
1333         if test $ol_cv_errno_thread_specific != yes \
1334                 -o $ol_cv_h_errno_thread_specific != yes ; then
1335                 LIBS="$LTHREAD_LIBS $LIBS"
1336                 LTHREAD_LIBS=""
1337         fi
1338
1339 dnl When in thread environment, use
1340 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1341 dnl                     || defined( HAVE_FUNC_R )
1342 dnl                     func_r(...);
1343 dnl             #else
1344 dnl             #       if defined( HAVE_THREADS )
1345 dnl                             /* lock */
1346 dnl             #       endif
1347 dnl                             func(...);
1348 dnl             #       if defined( HAVE_THREADS )
1349 dnl                             /* unlock */
1350 dnl             #       endif
1351 dnl             #endif
1352 dnl
1353 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1354 dnl             _POSIX_REENTRANT_FUNCTIONS
1355 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1356 dnl             _POSIX_THREADSAFE_FUNCTIONS
1357 dnl
1358 dnl             and is currently defined in lthread.h
1359 dnl
1360 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1361 dnl
1362 dnl libldap/*.c should only include <lthread.h> iff
1363 dnl LDAP_R_COMPILE is defined.  ie:
1364 dnl             #ifdef LDAP_R_COMPILE
1365 dnl             #       include LDAP_R_COMPILE
1366 dnl             #endif
1367 dnl
1368 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1369 dnl specifically for compiling the threadsafe version of
1370 dnl     the ldap library (-lldap_r).
1371 dnl
1372 dnl     dnl check for reentrant/threadsafe functions
1373 dnl     dnl
1374 dnl     dnl note: these should only be used when linking
1375 dnl     dnl       with $LTHREAD_LIBS
1376 dnl     dnl
1377 dnl     save_CPPFLAGS="$CPPFLAGS"
1378 dnl     save_LIBS="$LIBS"
1379 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1380 dnl     AC_CHECK_FUNCS( \
1381 dnl             gmtime_r \
1382 dnl             gethostbyaddr_r gethostbyname_r \
1383 dnl             feof_unlocked unlocked_feof \
1384 dnl             putc_unlocked unlocked_putc \
1385 dnl             flockfile ftrylockfile \
1386 dnl     )
1387 dnl     CPPFLAGS="$save_CPPFLAGS"
1388 dnl     LIBS="$save_LIBS"
1389 fi
1390
1391 if test $ol_link_threads = no ; then
1392         if test $ol_with_threads = yes ; then
1393                 AC_MSG_ERROR([no suitable thread support])
1394         fi
1395
1396         if test $ol_with_threads = auto ; then
1397                 AC_MSG_WARN([no suitable thread support, disabling threads])
1398                 ol_with_threads=no
1399         fi
1400
1401         AC_DEFINE(NO_THREADS,1,
1402                 [define if you have (or want) no threads])
1403         LTHREAD_LIBS=""
1404 fi
1405
1406 if test $ol_link_threads != no ; then
1407         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1408 fi
1409
1410 dnl ----------------------------------------------------------------
1411
1412 ol_link_ldbm=no
1413 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1414         OL_BERKELEY_DB2
1415
1416         if test $ol_cv_berkeley_db2 = yes ; then
1417                 ol_link_ldbm=db2
1418                 ol_with_ldbm_api=db2
1419
1420                 if test $ol_with_ldbm_type = hash ; then
1421                         AC_DEFINE(LDBM_USE_DBHASH,1,
1422                                 [define this to use DBHASH w/ LDBM backend])
1423                 else
1424                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1425                                 [define this to use DBBTREE w/ LDBM backend])
1426                 fi
1427
1428                 dnl $ol_cv_lib_db2 should be yes or -ldb
1429                 dnl (it could be no, but that would be an error
1430                 if test $ol_cv_lib_db2 != yes ; then
1431                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1432                 fi
1433         fi
1434 fi
1435
1436 ol_link_bdb2=no
1437 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1438         ol_link_bdb2=yes
1439 fi
1440
1441 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1442         OL_BERKELEY_DB
1443
1444         if test $ol_cv_berkeley_db = yes ; then
1445                 ol_link_ldbm=db
1446                 ol_with_ldbm_api=db
1447
1448                 if test $ol_with_ldbm_type = hash ; then
1449                         AC_DEFINE(LDBM_USE_DBHASH,1,
1450                                 [define this to use DBHASH w/ LDBM backend])
1451                 else
1452                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1453                                 [define this to use DBBTREE w/ LDBM backend])
1454                 fi
1455
1456                 dnl $ol_cv_lib_db should be yes or -ldb
1457                 dnl (it could be no, but that would be an error
1458                 if test $ol_cv_lib_db != yes ; then
1459                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1460                 fi
1461         fi
1462 fi
1463
1464 if test $ol_with_ldbm_api = manual ; then
1465         dnl User thinks he can manually configure LDBM api.
1466         ol_link_ldbm=yes
1467
1468         AC_MSG_WARN([LDBM defines and link options must be set manually])
1469
1470         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1471 fi
1472
1473 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1474         AC_MSG_WARN(Could not find LDBM with BTREE support)
1475         ol_with_ldbm_api=none
1476 fi
1477
1478 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1479         OL_MDBM
1480
1481         if test $ol_cv_mdbm = yes ; then
1482                 ol_link_ldbm=mdbm
1483                 ol_with_ldbm_api=mdbm
1484                 if test $ol_cv_lib_mdbm != yes ; then
1485                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1486                 fi
1487         fi
1488 fi
1489
1490 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1491         OL_GDBM
1492
1493         if test $ol_cv_gdbm = yes ; then
1494                 ol_link_ldbm=gdbm
1495                 ol_with_ldbm_api=gdbm
1496
1497                 if test $ol_cv_lib_gdbm != yes ; then
1498                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1499                 fi
1500         fi
1501 fi
1502
1503 if test $ol_with_ldbm_api = auto ; then
1504         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1505 elif test $ol_with_ldbm_api = ndbm ; then
1506         OL_NDBM
1507
1508         if test $ol_cv_ndbm = yes ; then
1509                 ol_link_ldbm=ndbm
1510                 ol_with_ldbm_api=ndbm
1511
1512                 if test $ol_cv_lib_ndbm != yes ; then
1513                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1514                 fi
1515         fi
1516 fi
1517
1518 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1519         AC_MSG_WARN(could not find suitable LDBM backend)
1520         if test $ol_enable_ldbm = yes ; then
1521                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1522         fi
1523
1524         AC_MSG_WARN(disabling LDBM)
1525         ol_enable_ldbm=no
1526 fi
1527
1528 if test $ol_enable_wrappers != no ; then
1529         AC_CHECK_HEADERS(tcpd.h)
1530
1531         if test $ac_cv_header_tcpd_h != yes ; then
1532                 have_wrappers=no
1533         else
1534                 AC_CHECK_LIB(wrap, main,
1535                         [have_wrappers=yes], [have_wrappers=no])
1536         fi
1537
1538         if test $have_wrappers = yes ; then
1539                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1540                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1541
1542                 dnl We add another check for -lnsl since some libwrap's
1543                 dnl need it, but it isn't always included from above
1544                 AC_CHECK_LIB(nsl, main)
1545         else
1546                 AC_MSG_WARN(could not find -lwrap)
1547                 if test $ol_enable_wrappers = yes ; then
1548                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1549                 fi
1550
1551                 AC_MSG_WARN(disabling wrappers support)
1552                 ol_enable_wrappers=no
1553         fi
1554 fi
1555
1556 if test $ol_enable_syslog != no ; then
1557         AC_CHECK_FUNC(openlog)
1558         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1559                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1560         fi
1561         ol_enable_syslog=$ac_cv_func_openlog
1562 fi
1563
1564 if test $ol_enable_dmalloc != no ; then
1565         AC_CHECK_HEADERS(dmalloc.h)
1566         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1567 fi
1568
1569 if test $ol_enable_tcl != no ; then
1570         AC_CHECK_HEADERS(tcl.h)
1571
1572         if test $ac_cv_header_tcl_h != yes ; then
1573                 have_tcl=no
1574         else
1575                 AC_CHECK_LIB(tcl,main,
1576                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1577                         [have_tcl=no])
1578
1579                 if test $have_tcl != yes; then
1580                         AC_CHECK_LIB(tcl7.6,main,
1581                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1582                                 [have_tcl=no])
1583                 fi
1584
1585                 if test $have_tcl != yes; then
1586                         AC_CHECK_LIB(tcl8.0,main,
1587                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1588                                 [have_tcl=no])
1589                 fi
1590         fi
1591
1592         if test $have_tcl != yes ; then
1593                 AC_MSG_WARN([could not find -ltcl])
1594                 if test $ol_enable_tcl = yes ; then
1595                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1596                 fi
1597
1598                 ol_enable_tcl=no
1599         fi
1600 fi
1601
1602 # ud needs termcap (should insert check here)
1603 ol_link_termcap=no
1604 AC_CHECK_HEADERS(termcap.h ncurses.h)
1605
1606 if test $ol_link_termcap = no ; then
1607         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1608         if test $have_termcap = yes ; then
1609                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1610                 ol_link_termcap=yes
1611                 TERMCAP_LIBS=-ltermcap
1612         fi
1613 fi
1614
1615 if test $ol_link_termcap = no ; then
1616         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1617         if test $have_ncurses = yes ; then
1618                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1619                 ol_link_termcap=yes
1620                 TERMCAP_LIBS=-lncurses
1621         fi
1622 fi
1623
1624 if test $ol_link_termcap = no ; then
1625         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1626         TERMCAP_LIBS=
1627 fi
1628
1629 dnl
1630 dnl Check for fetch URL support
1631 dnl             should be extended to support other fetch URL APIs
1632 dnl
1633 ol_link_sasl=no
1634 if test $ol_with_cyrus_sasl != no ; then
1635         AC_CHECK_HEADER(sasl.h)
1636
1637         if test $ac_cv_header_sasl_h = yes ; then
1638                 AC_CHECK_LIB(sasl, sasl_client_init,
1639                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1640
1641                 if test $have_cyrus_sasl != no ; then
1642                         SASL_LIBS="-lsasl"
1643                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1644                         ol_link_sasl=yes
1645                 fi
1646         fi
1647
1648         if test $ol_link_sasl = no -a $ol_with_cyrus_sasl = yes ; then
1649                 AC_MSG_ERROR(no suitable API for --with-cyrus-sasl=$ol_with_cyrus_sasl)
1650         fi
1651 fi
1652
1653 dnl
1654 dnl Check for fetch URL support
1655 dnl             should be extended to support other fetch URL APIs
1656 dnl
1657 ol_link_fetch=no
1658 if test $ol_with_fetch != no ; then
1659         OL_LIB_FETCH
1660
1661         if test $ol_cv_lib_fetch != no ; then
1662                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1663                 ol_link_fetch=freebsd
1664
1665         elif test $ol_with_fetch != auto ; then
1666                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1667         fi
1668 fi
1669
1670 dnl
1671 dnl Check for GNU readline
1672 dnl
1673 ol_link_readline=no
1674 if test $ol_with_readline != no ; then
1675         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1676
1677         if test $ac_cv_header_readline_readline_h = yes ; then
1678                 save_LIBS="$LIBS"
1679                 LIBS="$TERMCAP_LIBS $LIBS"
1680                 AC_CHECK_LIB(readline, readline,
1681                         [have_readline=yes], [have_readline=no])
1682                 LIBS="$save_LIBS"
1683
1684                 if test $have_readline = yes ; then
1685                         ol_with_readline=found
1686                         ol_link_readline=yes
1687
1688                         READLINE_LIBS="-lreadline"
1689                 fi
1690         fi
1691 fi
1692
1693 if test $ol_link_readline = yes ; then
1694         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1695 fi
1696
1697
1698 # FreeBSD (and others) have crypt(3) in -lcrypt
1699 if test $ol_enable_crypt != no ; then
1700         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1701                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1702                         have_crypt=yes], [have_crypt=no])])
1703
1704         if test $have_crypt = yes ; then
1705                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1706         else
1707                 AC_MSG_WARN(could not find crypt)
1708                 if test $ol_enable_crypt = yes ; then
1709                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1710                 fi
1711
1712                 AC_MSG_WARN(disabling crypt support)
1713                 ol_enable_crypt=no
1714         fi
1715 fi
1716
1717 # FreeBSD (and others) have setproctitle(3) in -lutil
1718 if test $ol_enable_proctitle != no ; then
1719         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1720                 AC_CHECK_LIB(util, setproctitle,
1721                         [have_setproctitle=yes
1722                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1723                         [have_setproctitle=no
1724                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1725
1726         if test $have_setproctitle = yes ; then
1727                 AC_DEFINE(HAVE_SETPROCTITLE,1,
1728                         [define if setproctitle(3) is available])
1729         fi
1730 fi
1731
1732 dnl ----------------------------------------------------------------
1733 dnl Checks for typedefs, structures, and compiler characteristics.
1734 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1735 AC_TYPE_MODE_T
1736 AC_TYPE_OFF_T
1737 AC_TYPE_PID_T
1738 AM_TYPE_PTRDIFF_T
1739 AC_TYPE_SIGNAL
1740 OL_TYPE_SIG_ATOMIC_T
1741 AC_TYPE_SIZE_T
1742 OL_TYPE_SOCKLEN_T
1743 AC_STRUCT_ST_BLKSIZE
1744 AC_HEADER_TIME
1745 AC_STRUCT_TM
1746 OL_STRUCT_PASSWD_PW_GECOS
1747 OL_STRUCT_PASSWD_PW_PASSWD
1748
1749 OL_C_UPPER_LOWER
1750 AC_C_CONST
1751 OL_C_VOLATILE
1752
1753 if test $cross_compiling = yes ; then
1754         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1755
1756         AC_DEFINE(LBER_INT_T,long)
1757         AC_DEFINE(LBER_TAG_T,long)
1758         AC_DEFINE(LBER_SOCKET_T,int)
1759
1760 else
1761         AC_C_BIGENDIAN
1762         AC_CHECK_SIZEOF(short)
1763         AC_CHECK_SIZEOF(int)
1764         AC_CHECK_SIZEOF(long)
1765
1766         if test "$ac_cv_sizeof_int" -lt 4 ; then
1767                 AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
1768
1769                 AC_DEFINE(LBER_INT_T,long)
1770                 AC_DEFINE(LBER_TAG_T,long)
1771                 AC_DEFINE(LBER_SOCKET_T,int)
1772         else
1773                 AC_DEFINE(LBER_INT_T,int)
1774                 AC_DEFINE(LBER_TAG_T,long)
1775                 AC_DEFINE(LBER_SOCKET_T,int)
1776         fi
1777 fi
1778
1779 AC_DEFINE(LBER_LEN_T,long)
1780
1781 dnl ----------------------------------------------------------------
1782 dnl Checks for library functions.
1783 AC_FUNC_MEMCMP
1784 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1785 AC_FUNC_STRFTIME
1786 dnl AM_FUNC_STRTOD
1787
1788 OL_FUNC_INET_ATON
1789
1790 dnl we should use vfork instead of fork in a number of places...
1791 dnl AC_FUNC_VFORK
1792 AC_FUNC_VPRINTF
1793
1794 if test $ac_cv_func_vprintf = yes ; then
1795         dnl check for vsnprintf
1796         AC_CHECK_FUNCS(vsnprintf vsprintf)
1797 fi
1798
1799 AC_CHECK_FUNCS(         \
1800         bcopy                   \
1801         closesocket             \
1802         endgrent                \
1803         endpwent                \
1804         flock                   \
1805         getdtablesize   \
1806         getgrgid                \
1807         gethostname             \
1808         getpass                 \
1809         getpwuid                \
1810         getpwnam                \
1811         getspnam                \
1812         gettimeofday    \
1813         initgroups              \
1814         lockf                   \
1815         memcpy                  \
1816         memmove                 \
1817         mkstemp                 \
1818         pipe                    \
1819         read                    \
1820         recv                    \
1821         recvfrom                \
1822         setpwfile               \
1823         setgid                  \
1824         setegid                 \
1825         setsid                  \
1826         setuid                  \
1827         seteuid                 \
1828         sigaction               \
1829         signal                  \
1830         sigset                  \
1831         snprintf                \
1832         strdup                  \
1833         strerror                \
1834         strpbrk                 \
1835         strrchr                 \
1836         strsep                  \
1837         strstr                  \
1838         strtol                  \
1839         strtoul                 \
1840         strspn                  \
1841         sysconf                 \
1842         waitpid                 \
1843         wait4                   \
1844         write                   \
1845         send                    \
1846         sendto                  \
1847 )
1848
1849 dnl We actually may need to replace more than this.
1850 AC_REPLACE_FUNCS(getopt tempnam)
1851
1852 dnl ----------------------------------------------------------------
1853 # Check Configuration
1854 OL_SYS_ERRLIST
1855
1856 dnl ----------------------------------------------------------------
1857 dnl Sort out defines
1858
1859 if test "$ol_enable_debug" != no ; then
1860         AC_DEFINE(LDAP_DEBUG,1,
1861                 [define this to add debugging code])
1862 fi
1863 if test "$ol_enable_syslog" = yes ; then
1864         AC_DEFINE(LDAP_SYSLOG,1,
1865                 [define this to add syslog code])
1866 fi
1867 if test "$ol_enable_libui" = yes ; then
1868         AC_DEFINE(LDAP_LIBUI,1,
1869                 [define this for LDAP User Interface support])
1870 fi
1871 if test "$ol_enable_cache" = no ; then
1872         AC_DEFINE(LDAP_NOCACHE,1,
1873                 [define this to remove -lldap cache support])
1874 fi
1875 if test "$ol_enable_dns" != no ; then
1876         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1877 fi
1878 if test "$ol_enable_proctitle" != no ; then
1879         AC_DEFINE(LDAP_PROCTITLE,1,
1880                 [define this for LDAP process title support])
1881 fi
1882 if test "$ol_enable_referrals" != no ; then
1883         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1884 fi
1885 if test "$ol_enable_cldap" != no ; then
1886         AC_DEFINE(LDAP_CONNECTIONLESS,1,[define to support CLDAP])
1887 fi
1888
1889 if test "$ol_enable_crypt" != no ; then
1890         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
1891 fi
1892 if test "$ol_enable_cleartext" != no ; then
1893         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
1894 fi
1895 if test "$ol_enable_multimaster" != no ; then
1896         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
1897 fi
1898 if test "$ol_enable_phonetic" != no ; then
1899         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
1900 fi
1901 if test "$ol_enable_rlookups" != no ; then
1902         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
1903 fi
1904 if test "$ol_enable_aci" != no ; then
1905         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
1906 fi
1907 if test "$ol_enable_discreteaci" != no ; then
1908         AC_DEFINE(SLAPD_ACI_DISCRETE_RIGHTS,1,[define to support discrete rights in ACIs])
1909 fi
1910
1911 if test "$ol_link_modules" != no ; then
1912         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
1913         BUILD_SLAPD=yes
1914         MODULES_LIBS=-lltdl
1915         SLAPD_MODULES_LDFLAGS="-dlopen self"
1916 fi
1917
1918 if test "$ol_link_bdb2" != no ; then
1919         AC_DEFINE(SLAPD_BDB2,1,[define to support BDB2 backend])
1920         BUILD_SLAPD=yes
1921         BUILD_BDB2=yes
1922         if test "$ol_with_bdb2_module" != static ; then
1923                 AC_DEFINE(SLAPD_BDB2_DYNAMIC,1,
1924                         [define to support dynamic BDB2 backend])
1925                 BUILD_BDB2=mod
1926                 BUILD_BDB2_DYNAMIC=shared
1927                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-bdb2/back_bdb2.la"
1928         fi
1929 fi
1930
1931 if test "$ol_enable_ldap" != no ; then
1932         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
1933         BUILD_SLAPD=yes
1934         BUILD_LDAP=yes
1935         if test "$ol_with_ldap_module" != static ; then
1936                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
1937                         [define to support dynamic LDAP backend])
1938                 BUILD_LDAP=mod
1939                 BUILD_LDAP_DYNAMIC=shared
1940                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
1941         fi
1942 fi
1943
1944 if test "$ol_link_ldbm" != no ; then
1945         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
1946         BUILD_SLAPD=yes
1947         BUILD_LDBM=yes
1948         if test "$ol_with_ldbm_module" != static ; then
1949                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
1950                         [define to support dynamic LDBM backend])
1951                 BUILD_LDBM=mod
1952                 BUILD_LDBM_DYNAMIC=shared
1953                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
1954         fi
1955 fi
1956
1957 if test "$ol_enable_passwd" != no ; then
1958         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
1959         BUILD_SLAPD=yes
1960         BUILD_PASSWD=yes
1961         if test "$ol_with_passwd_module" != static ; then
1962                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
1963                         [define to support dynamic PASSWD backend])
1964                 BUILD_PASSWD=mod
1965                 BUILD_PASSWD_DYNAMIC=shared
1966                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
1967         fi
1968 fi
1969
1970 if test "$ol_link_perl" != no ; then
1971         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
1972         BUILD_SLAPD=yes
1973         BUILD_PERL=yes
1974         if test "$ol_with_perl_module" != static ; then
1975                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
1976                         [define to support dynamic PERL backend])
1977                 BUILD_PERL=mod
1978                 BUILD_PERL_DYNAMIC=shared
1979                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-perl/back_perl.la"
1980         fi
1981 fi
1982
1983 if test "$ol_enable_shell" != no ; then
1984         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
1985         BUILD_SLAPD=yes
1986         BUILD_SHELL=yes
1987         if test "$ol_with_shell_module" != static ; then
1988                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
1989                         [define to support dynamic SHELL backend])
1990                 BUILD_SHELL=mod
1991                 BUILD_SHELL_DYNAMIC=shared
1992                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
1993         fi
1994 fi
1995
1996 if test "$ol_enable_tcl" != no ; then
1997         AC_DEFINE(SLAPD_TCL,1,[define to support TCL backend])
1998         BUILD_SLAPD=yes
1999         BUILD_TCL=yes
2000         if test "$ol_with_tcl_module" != static; then
2001                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1,
2002                         [define to support dynamic TCL backend])
2003                 BUILD_TCL=mod
2004                 BUILD_TCL_DYNAMIC=shared
2005                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-tcl/back_tcl.la"
2006         fi
2007 fi
2008
2009 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2010         $BUILD_SLAPD = yes ; then
2011         BUILD_SLURPD=yes
2012 fi
2013
2014 dnl ----------------------------------------------------------------
2015
2016 AC_SUBST(BUILD_SLAPD)
2017   AC_SUBST(BUILD_BDB2)
2018   AC_SUBST(BUILD_LDAP)
2019   AC_SUBST(BUILD_LDBM)
2020   AC_SUBST(BUILD_PASSWD)
2021   AC_SUBST(BUILD_PERL)
2022   AC_SUBST(BUILD_QUIPU)
2023   AC_SUBST(BUILD_SHELL)
2024   AC_SUBST(BUILD_TCL)
2025   AC_SUBST(BUILD_BDB2_DYNAMIC)
2026   AC_SUBST(BUILD_LDAP_DYNAMIC)
2027   AC_SUBST(BUILD_LDBM_DYNAMIC)
2028   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2029   AC_SUBST(BUILD_PERL_DYNAMIC)
2030   AC_SUBST(BUILD_SHELL_DYNAMIC)
2031   AC_SUBST(BUILD_TCL_DYNAMIC)
2032 AC_SUBST(BUILD_SLURPD)
2033
2034 AC_SUBST(LDAP_LIBS)
2035 AC_SUBST(LDIF_LIBS)
2036 AC_SUBST(SLAPD_LIBS)
2037 AC_SUBST(SLURPD_LIBS)
2038 AC_SUBST(LDBM_LIBS)
2039 AC_SUBST(LTHREAD_LIBS)
2040 AC_SUBST(LUTIL_LIBS)
2041
2042 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2043 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2044 AC_SUBST(SLAPD_MODULES_LIST)
2045
2046 AC_SUBST(SLAPD_PERL_CPPFLAGS)
2047 AC_SUBST(SLAPD_PERL_LDFLAGS)
2048
2049 AC_SUBST(KRB_LIBS)
2050 AC_SUBST(READLINE_LIBS)
2051 AC_SUBST(SASL_LIBS)
2052 AC_SUBST(TERMCAP_LIBS)
2053 AC_SUBST(TLS_LIBS)
2054 AC_SUBST(MODULES_LIBS)
2055
2056 dnl ----------------------------------------------------------------
2057 dnl final output
2058 dnl
2059
2060 AC_OUTPUT( \
2061 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2062 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2063 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2064 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2065 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2066 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2067 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2068 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2069 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2070 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2071 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2072 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2073 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2074 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2075 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2076 include/Makefile:build/top.mk:include/Makefile.in \
2077 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2078 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2079 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2080 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2081 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2082 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2083 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2084 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2085 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2086 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2087 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/mod.mk \
2088 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2089 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2090 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2091 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk \
2092 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2093 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/mod.mk \
2094 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2095 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2096 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2097 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2098 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2099 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2100 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2101 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2102 ,[
2103 date > stamp-h
2104 echo Please \"make depend\" to build dependencies
2105 ])