git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998-2001 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms are permitted only
   6 dnl as authorized by the OpenLDAP Public License.  A copy of this
   7 dnl license is available at http://www.OpenLDAP.org/license.html or
   8 dnl in file LICENSE in the top-level directory of the distribution.
   9 dnl
  10 dnl ----------------------------------------------------------------
  11 dnl Redefine AC_INIT_BINSH to provide RCS IDs and copyright notice
  12 dnl at top of generated configure script.  Prints simple copyright.
  13 define([AC_INIT_BINSH],
  14 [[#! /bin/sh
  15 # $]OpenLDAP[$
  16 # from] translit([$OpenLDAP$], $")] [
  17
  18 # Copyright 1998-2001 The OpenLDAP Foundation.  All Rights Reserved.
  19 #
  20 # Redistribution and use in source and binary forms are permitted only
  21 # as authorized by the OpenLDAP Public License.  A copy of this
  22 # license is available at http://www.OpenLDAP.org/license.html or
  23 # in file LICENSE in the top-level directory of the distribution.
  24
  25 echo "Copyright 1998-2001 The OpenLDAP Foundation,  All Rights Reserved."
  26 echo "Restrictions apply, see COPYRIGHT and LICENSE files."
  27 ])dnl
  28 dnl ----------------------------------------------------------------
  29 dnl Disable config.cache!
  30 define([AC_CACHE_LOAD], )dnl
  31 define([AC_CACHE_SAVE], )dnl
  32 dnl ================================================================
  33 dnl Configure.in for OpenLDAP
  34 AC_INIT(build/version)dnl
  35
  36 # set unset (borrowed from autoconf 2.49c)
  37 if (OL_FOO=OL_FOO; unset OL_FOO) >/dev/null 2>&1; then
  38   ol_unset=unset
  39 else
  40   ol_unset=false
  41 fi
  42 # unset CDPATH
  43 $ol_unset CDPATH || test "${CDPATH+set}" != set || { CDPATH=:; export CDPATH; }
  44
  45 AC_CONFIG_AUX_DIR(build)dnl
  46
  47 OL_VERSION=`cat $ac_aux_dir/version`
  48 if test -z "$OL_VERSION"; then
  49         AC_MSG_ERROR([could not determine version])
  50 fi
  51
  52 echo "Configuring OpenLDAP $OL_VERSION ..."
  53
  54 dnl Determine host platform
  55 dnl             we try not to use this for much
  56 AC_CANONICAL_SYSTEM
  57
  58 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  59 AC_SUBST(PACKAGE)dnl
  60 AC_SUBST(VERSION)dnl
  61 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  62 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  63
  64 dnl We use autoconf features new to 2.13.
  65 dnl aclocal.m4 should be built using aclocal from automake 1.4
  66 dnl libtool 1.3.3 should be installed.
  67 AC_PREREQ(2.13)dnl Required Autoconf version
  68
  69 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  70
  71 dnl ================================================================
  72 dnl Start Args
  73 AC_MSG_CHECKING(configure arguments)
  74 AC_PREFIX_DEFAULT(/usr/local)
  75
  76 top_builddir=`pwd`
  77 AC_SUBST(top_builddir)dnl
  78
  79 dnl ----------------------------------------------------------------
  80 dnl --with-subdir
  81 ldap_subdir="/openldap"
  82
  83 AC_ARG_WITH(subdir,
  84 [  --with-subdir=DIR      change default subdirectory used for installs],
  85 [case "$withval" in
  86         no) ldap_subdir=""
  87                 ;;
  88         yes)
  89                 ;;
  90         /*|\\*)
  91                 ldap_subdir="$withval"
  92                 ;;
  93         *)
  94                 ldap_subdir="/$withval"
  95                 ;;
  96 esac
  97 ])dnl
  98
  99 AC_SUBST(ldap_subdir)dnl
 100
 101 dnl ----------------------------------------------------------------
 102 dnl General "enable" options
 103 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes)dnl
 104 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 105 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 106 OL_ARG_ENABLE(cache,[  --enable-cache     enable caching], yes)dnl
 107 OL_ARG_ENABLE(referrals,[  --enable-referrals     enable V2 Referrals extension], yes)dnl
 108 OL_ARG_ENABLE(kbind,[  --enable-kbind     enable V2 Kerberos IV bind], no)dnl
 109 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 110 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 111 OL_ARG_ENABLE(x_compile,[  --enable-x-compile     enable cross compiling],
 112         no, [yes no])dnl
 113
 114 dnl ----------------------------------------------------------------
 115 dnl General "with" options
 116 dnl OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc     enable debug malloc support], no)dnl
 117
 118 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 119         auto, [auto yes no] )
 120 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch URL support],
 121         auto, [auto yes no] )
 122 OL_ARG_WITH(kerberos,[  --with-kerberos   with support],
 123         auto, [auto k5 k5only k425 kth k4 afs yes no])
 124 OL_ARG_WITH(readline,[  --with-readline   with readline support],
 125         auto, [auto yes no] )
 126 OL_ARG_WITH(threads,[  --with-threads     with threads],
 127         auto, [auto nt posix mach pth lwp yes no manual] )
 128 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support],
 129         auto, [auto ssleay openssl yes no] )
 130 OL_ARG_WITH(yielding_select,[  --with-yielding-select  with implicitly yielding select],
 131         auto, [auto yes no manual] )
 132
 133 dnl ----------------------------------------------------------------
 134 dnl Server options
 135 dnl ----------------------------------------------------------------
 136
 137 dnl ----------------------------------------------------------------
 138 dnl SLAPD OPTIONS
 139 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 140 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 141 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 142 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], auto)dnl
 143 OL_ARG_ENABLE(kpasswd,[    --enable-kpasswd       enable kerberos password verification], no)dnl
 144 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 145 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 146 dnl OL_ARG_ENABLE(multimaster,[    --enable-multimaster  enable multimaster replication], no)dnl
 147 OL_ARG_ENABLE(phonetic,[    --enable-phonetic     enable phonetic/soundex], no)dnl
 148 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups], no)dnl
 149 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs], no)dnl
 150 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 151 OL_ARG_ENABLE(dynamic,[    --enable-dynamic       enable linking built binaries with dynamic libs], no)dnl
 152
 153 dnl SLAPD Backend options
 154 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend], no)dnl
 155 OL_ARG_WITH(dnssrv_module,[    --with-dnssrv-module  module type], static,
 156         [static dynamic])
 157 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend], no)dnl
 158 OL_ARG_WITH(ldap_module,[    --with-ldap-module   module type], static,
 159         [static dynamic])
 160 OL_ARG_ENABLE(ldbm,[    --enable-ldbm     enable ldbm backend], yes)dnl
 161 OL_ARG_WITH(ldbm_api,[    --with-ldbm-api       with LDBM API], auto,
 162         [auto berkeley bcompat mdbm gdbm])
 163 OL_ARG_WITH(ldbm_module,[    --with-ldbm-module   module type], static,
 164         [static dynamic])
 165 OL_ARG_WITH(ldbm_type,[    --with-ldbm-type       use LDBM type], auto,
 166         [auto btree hash])
 167 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend], no)dnl
 168 OL_ARG_WITH(passwd_module,[    --with-passwd-module  module type], static,
 169         [static dynamic])
 170 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend], no)dnl
 171 OL_ARG_WITH(shell_module,[    --with-shell-module         module type], static,
 172         [static dynamic])
 173 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend], no)dnl
 174 OL_ARG_WITH(sql_module,[    --with-sql-module     module type], static,
 175         [static dynamic])
 176
 177 dnl ----------------------------------------------------------------
 178 dnl SLURPD OPTIONS
 179 AC_ARG_WITH(xxslurpdoptions,[SLURPD (Replication Daemon) Options:])
 180 OL_ARG_ENABLE(slurpd,[  --enable-slurpd   enable building slurpd], auto)dnl
 181
 182 dnl ----------------------------------------------------------------
 183 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 184 AC_ENABLE_STATIC
 185 dnl AC_DISABLE_SHARED
 186 AC_ENABLE_SHARED
 187
 188 dnl ----------------------------------------------------------------
 189
 190 dnl General "enable" options
 191 # validate options
 192 if test $ol_enable_slapd = no ; then
 193         dnl SLAPD was specificallly disabled
 194         if test $ol_enable_dnssrv = yes ; then
 195                 AC_MSG_WARN([slapd disabled, ignoring --enable-dnssrv argument])
 196         fi
 197         if test $ol_enable_ldap = yes ; then
 198                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 199         fi
 200         if test $ol_enable_ldbm = yes ; then
 201                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 202         fi
 203         if test $ol_enable_passwd = yes ; then
 204                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 205         fi
 206         if test $ol_enable_shell = yes ; then
 207                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 208         fi
 209         if test $ol_enable_sql = yes ; then
 210                 AC_MSG_WARN([slapd disabled, ignoring --enable-sql argument])
 211         fi
 212         if test $ol_enable_modules = yes ; then
 213                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 214         fi
 215         if test $ol_enable_multimaster = yes ; then
 216                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 217         fi
 218 dnl     if test $ol_enable_multimaster = yes ; then
 219 dnl             AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 220 dnl     fi
 221         if test $ol_enable_wrappers = yes ; then
 222                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 223         fi
 224         if test $ol_enable_phonetic = yes ; then
 225                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 226         fi
 227         if test $ol_enable_rlookups = yes ; then
 228                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 229         fi
 230         if test $ol_enable_aci = yes ; then
 231                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 232         fi
 233         if test $ol_with_ldbm_api != auto ; then
 234                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 235         fi
 236         if test $ol_with_ldbm_type != auto ; then
 237                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 238         fi
 239         if test $ol_with_dnssrv_module != static ; then
 240                 AC_MSG_WARN([slapd disabled, ignoring --with-dnssrv-module argument])
 241         fi
 242         if test $ol_with_ldap_module != static ; then
 243                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 244         fi
 245         if test $ol_with_ldbm_module != static ; then
 246                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 247         fi
 248         if test $ol_with_passwd_module != static ; then
 249                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 250         fi
 251         if test $ol_with_shell_module != static ; then
 252                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 253         fi
 254         if test $ol_with_sql_module != static ; then
 255                 AC_MSG_WARN([slapd disabled, ignoring --with-sql-module argument])
 256         fi
 257         if test $ol_enable_slurpd = yes ; then
 258                 AC_MSG_ERROR([slurpd requires slapd])
 259         fi
 260
 261         # force settings to no
 262         ol_enable_dnssrv=no
 263         ol_enable_ldap=no
 264         ol_enable_ldbm=no
 265         ol_enable_passwd=no
 266         ol_enable_shell=no
 267         ol_enable_sql=no
 268
 269         ol_enable_modules=no
 270 dnl     ol_enable_multimaster=no
 271         ol_enable_phonetic=no
 272         ol_enable_rlookups=no
 273         ol_enable_aci=no
 274         ol_enable_wrappers=no
 275         ol_enable_dynamic=no
 276
 277         ol_with_ldbm_api=no
 278         ol_with_ldbm_type=no
 279
 280         ol_with_dnssrv_module=static
 281         ol_with_ldap_module=static
 282         ol_with_ldbm_module=static
 283         ol_with_passwd_module=static
 284         ol_with_shell_module=static
 285         ol_with_sql_module=static
 286
 287         ol_enable_slurpd=no
 288
 289 elif test $ol_enable_ldbm = no ; then
 290         dnl SLAPD without LDBM
 291
 292         if test $ol_with_ldbm_api != auto ; then
 293                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 294         fi
 295
 296         if test $ol_with_ldbm_type != auto ; then
 297                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 298         fi
 299
 300         if test $ol_with_ldbm_module != static ; then
 301                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 302         fi
 303
 304         if test $ol_enable_modules != yes -a \
 305                 $ol_enable_dnssrv = no -a \
 306                 $ol_enable_ldap = no -a \
 307                 $ol_enable_passwd = no -a \
 308                 $ol_enable_shell = no -a \
 309                 $ol_enable_sql = no ; then
 310                 AC_MSG_ERROR([slapd requires a backend])
 311         fi
 312
 313         ol_with_ldbm_api=no
 314         ol_with_ldbm_type=no
 315         ol_with_ldbm_module=static
 316
 317 else
 318         dnl SLAPD with LDBM
 319         if test $ol_with_ldbm_api = gdbm -a \
 320                 $ol_with_ldbm_type = btree ; then
 321                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 322         fi
 323         if test $ol_with_ldbm_api = mdbm -a \
 324                 $ol_with_ldbm_type = btree ; then
 325                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 326         fi
 327         if test $ol_with_ldbm_api = ndbm -a \
 328                 $ol_with_ldbm_type = btree ; then
 329                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 330         fi
 331 fi
 332
 333 if test $ol_enable_slurpd = yes ; then
 334         dnl SLURPD was specifically enabled
 335         if test $ol_with_threads = no ; then
 336                 AC_MSG_ERROR([slurpd requires threads])
 337         fi
 338 fi
 339
 340 if test $ol_enable_kbind = yes -o $ol_enable_kpasswd = yes ; then
 341         if test $ol_with_kerberos = no ; then
 342                 AC_MSG_ERROR([options require --with-kerberos])
 343         fi
 344         ol_with_kerberos=yes
 345 elif test $ol_enable_kbind = no -o $ol_enable_kpasswd = no ; then
 346         if test $ol_with_kerberos != no -a $ol_with_kerberos != auto ; then
 347                 AC_MSG_WARN([Kerberos detection enabled unnecessarily]);
 348         fi
 349         ol_with_kerberos=no
 350 fi
 351
 352 if test $ol_enable_spasswd = yes ; then
 353         if test $ol_with_cyrus_sasl = no ; then
 354                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 355         fi
 356         ol_with_cyrus_sasl=yes
 357 fi
 358
 359 AC_MSG_RESULT(done)
 360
 361 dnl ----------------------------------------------------------------
 362 dnl Initialize vars
 363 LDAP_LIBS=
 364 LDIF_LIBS=
 365 LDBM_LIBS=
 366 LTHREAD_LIBS=
 367 LUTIL_LIBS=
 368
 369 SLAPD_LIBS=
 370 SLURPD_LIBS=
 371
 372 BUILD_SLAPD=no
 373 BUILD_SLURPD=no
 374
 375 BUILD_THREAD=no
 376
 377 BUILD_DNSSRV=no
 378 BUILD_LDAP=no
 379 BUILD_LDBM=no
 380 BUILD_PASSWD=no
 381 BUILD_SHELL=no
 382 BUILD_SQL=no
 383
 384 BUILD_DNSSRV_DYNAMIC=static
 385 BUILD_LDAP_DYNAMIC=static
 386 BUILD_LDBM_DYNAMIC=static
 387 BUILD_PASSWD_DYNAMIC=static
 388 BUILD_SHELL_DYNAMIC=static
 389 BUILD_SQL_DYNAMIC=static
 390
 391 SLAPD_MODULES_LDFLAGS=
 392 SLAPD_MODULES_CPPFLAGS=
 393 SLAPD_MODULES_LIST=
 394
 395 SLAPD_SQL_LDFLAGS=
 396 SLAPD_SQL_LIBS=
 397 SLAPD_SQL_INCLUDES=
 398
 399 KRB4_LIBS=
 400 KRB5_LIBS=
 401 READLINE_LIBS=
 402 SASL_LIBS=
 403 TERMCAP_LIBS=
 404 TLS_LIBS=
 405 MODULES_LIBS=
 406 AUTH_LIBS=
 407
 408 dnl ================================================================
 409 dnl Checks for programs
 410
 411 dnl AC_PROG_INSTALL
 412
 413 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 414
 415 dnl ----------------------------------------------------------------
 416 dnl
 417 dnl Determine which C translator to use
 418 dnl
 419
 420 dnl AIX Thread requires we use cc_r or xlc_r.
 421 dnl But only do this IF AIX and CC is not set
 422 dnl and threads are auto|yes|posix.
 423 dnl
 424 dnl If we find cc_r|xlc_r, force pthreads and assume
 425 dnl             pthread_create is in $LIBS (ie: don't bring in
 426 dnl             any additional thread libraries)
 427 dnl If we do not find cc_r|xlc_r, disable threads
 428
 429 ol_aix_threads=no
 430 case "$target" in
 431 *-*-aix*) dnl all AIX is not a good idea.
 432         if test -z "$CC" ; then
 433                 case "$ol_with_threads" in
 434                 auto | yes |  posix) ol_aix_threads=yes ;;
 435                 esac
 436         fi
 437 ;;
 438 esac
 439
 440 if test $ol_aix_threads = yes ; then
 441         if test -z "${CC}" ; then
 442                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 443
 444                 if test "$CC" = cc ; then
 445                         dnl no CC! don't allow --with-threads
 446                         if test $ol_with_threads != auto ; then
 447                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 448                         else
 449                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 450                         fi
 451                         ol_with_threads=no
 452                 fi
 453         fi
 454
 455         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 456                 ol_with_threads=posix
 457                 ol_cv_pthread_create=yes
 458         fi
 459 fi
 460
 461 if test -z "${CC}"; then
 462         AC_CHECK_PROGS(CC,cc)
 463 fi
 464
 465 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 466 dnl (for now, let autoconf sort this out)
 467 dnl CFLAGS=${CFLAGS-""}
 468
 469 AC_LIBTOOL_WIN32_DLL
 470 AC_LIBTOOL_DLOPEN
 471 AC_PROG_LIBTOOL
 472
 473 AC_PROG_AWK
 474 OL_PROG_LN_H
 475 AC_PROG_LN_S
 476
 477 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 478         LN_S="$LN_H"
 479 fi
 480
 481 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 482         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 483 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 484 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 485
 486 AC_PROG_CPP
 487
 488 dnl ----------------------------------------------------------------
 489 dnl Cross compiling checks
 490 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 491         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 492
 493 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 494         AC_MSG_WARN([programs compiled here do run here...])
 495         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 496
 497 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 498         AC_MSG_WARN([programs compiled here do not run here...])
 499         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 500 fi
 501
 502 dnl ----------------------------------------------------------------
 503 dnl Checks for UNIX Variants
 504 AC_AIX
 505 AC_ISC_POSIX
 506 AC_MINIX
 507
 508 dnl ----------------------------------------------------------------
 509 dnl Checks for system services
 510 AC_CYGWIN
 511 AC_MINGW32
 512 AC_EXEEXT
 513 AC_OBJEXT
 514
 515 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 516
 517 dnl ----------------------------------------------------------------
 518 dnl BeOS requires -lbe -lroot -lnet
 519 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 520
 521 dnl ----------------------------------------------------------------
 522 dnl OpenLDAP requires STDC features
 523 AM_PROG_CC_STDC
 524 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 525         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 526 fi
 527
 528 dnl ----------------------------------------------------------------
 529 dnl Check cc depend flags
 530 OL_MKDEPEND
 531 if test "${ol_cv_mkdep}" = no ; then
 532         # this will soon become an error
 533         AC_MSG_WARN([do not know how to generate dependencies])
 534 fi
 535
 536 dnl ----------------------------------------------------------------
 537 dnl Check for AIX security library
 538 AC_CHECK_LIB(s, afopen, [
 539         AUTH_LIBS=-ls
 540         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 541 ])
 542
 543
 544 dnl ----------------------------------------------------------------
 545 dnl Check for module support
 546 ol_link_modules=no
 547 if test $ol_enable_modules != no ; then
 548         AC_CHECK_HEADERS(ltdl.h)
 549
 550         if test $ac_cv_header_ltdl_h = no ; then
 551                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 552         fi
 553
 554         AC_CHECK_LIB(ltdl, lt_dlinit, [
 555             MODULES_LIBS=-lltdl
 556             AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 557         ])
 558
 559         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 560                 AC_MSG_ERROR([could not locate libtool -lltdl])
 561         fi
 562         ol_link_modules=yes
 563 else
 564         ol_with_dnssrv_module=static
 565         ol_with_ldap_module=static
 566         ol_with_ldbm_module=static
 567         ol_with_passwd_module=static
 568         ol_with_shell_module=static
 569         ol_with_sql_module=static
 570 fi
 571
 572 dnl ----------------------------------------------------------------
 573 dnl Checks for header files.
 574 OL_HEADER_STDC
 575
 576 if test $ol_cv_header_stdc != yes; then
 577         AC_MSG_WARN([could not locate Standard C compliant headers])
 578 fi
 579
 580 AC_HEADER_DIRENT
 581 AC_HEADER_SYS_WAIT
 582 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 583 if test $am_cv_sys_posix_termios = yes ; then
 584         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 585                 [define if you have POSIX termios])
 586 fi
 587
 588 AC_CHECK_HEADERS(       \
 589         arpa/inet.h             \
 590         arpa/nameser.h  \
 591         assert.h                \
 592         conio.h                 \
 593         crypt.h                 \
 594         direct.h                \
 595         errno.h                 \
 596         fcntl.h                 \
 597         filio.h                 \
 598         getopt.h                \
 599         grp.h                   \
 600         io.h                    \
 601         libutil.h               \
 602         limits.h                \
 603         locale.h                \
 604         netinet/tcp.h   \
 605         malloc.h                \
 606         memory.h                \
 607         psap.h                  \
 608         pwd.h                   \
 609         process.h               \
 610         resolv.h                \
 611         sgtty.h                 \
 612         shadow.h                \
 613         stddef.h                \
 614         string.h                \
 615         strings.h               \
 616         sysexits.h              \
 617         sys/file.h              \
 618         sys/filio.h             \
 619         sys/errno.h             \
 620         sys/ioctl.h             \
 621         sys/param.h             \
 622         sys/resource.h  \
 623         sys/select.h    \
 624         sys/socket.h    \
 625         sys/syslog.h    \
 626         sys/time.h              \
 627         sys/types.h             \
 628         syslog.h                \
 629         termios.h               \
 630         unistd.h                \
 631         winsock.h               \
 632 )
 633
 634
 635 dnl ----------------------------------------------------------------
 636 dnl Checks for libraries
 637
 638 dnl SASL and SSL need dlopen on some platforms
 639 AC_CHECK_FUNC(dlopen, :, [AC_CHECK_LIB(dl, dlopen)])
 640
 641 dnl HP-UX requires -lV3
 642 AC_CHECK_LIB(V3, sigset)
 643
 644 dnl Gotta check for winsock manually
 645 if test $ac_cv_header_winsock_h = yes; then
 646         AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 647         AC_TRY_LINK([#include <winsock.h>],[
 648                         socket(0,0,0);
 649                         select(0,NULL,NULL,NULL,NULL);
 650                         closesocket(0);
 651                         gethostname(NULL,0);
 652         ],[ol_cv_winsock=yes],[ol_cv_winsock=no])])
 653
 654         if test $ol_cv_winsock = yes ; then
 655                 AC_DEFINE(HAVE_WINSOCK,1,[define if you have winsock])
 656                 ac_cv_func_socket=yes
 657                 ac_cv_func_select=yes
 658                 ac_cv_func_closesocket=yes
 659                 ac_cv_func_gethostname=yes
 660         fi
 661 fi
 662
 663 dnl Find socket()
 664 dnl Likely combinations:
 665 dnl             -lsocket [ -lnsl_s | -lnsl ]
 666 dnl             -linet
 667
 668 AC_CHECK_FUNC(socket, :, [
 669 dnl hopefully we won't include too many libraries
 670         AC_CHECK_LIB(socket, main)
 671         AC_CHECK_LIB(net, main)
 672         AC_CHECK_LIB(nsl_s, main)
 673         AC_CHECK_LIB(nsl, main)
 674         AC_CHECK_LIB(inet, socket)
 675         AC_CHECK_LIB(gen, main)
 676 ])
 677
 678 dnl require select
 679 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 680
 681 if test "${ac_cv_header_winsock_h}" != yes; then
 682     dnl Select arg types
 683     dnl (if this detection becomes permenent, it and the select() detection
 684     dnl should be done before the yielding select test)
 685     AC_FUNC_SELECT_ARGTYPES
 686 fi
 687
 688 dnl check to see if system call automatically restart
 689 dnl AC_SYS_RESTARTABLE_SYSCALLS
 690
 691 dnl ----------------------------------------------------------------
 692 dnl require POSIX regex
 693 AC_CHECK_HEADERS( regex.h )
 694 if test "$ac_cv_header_regex_h" != yes ; then
 695         AC_MSG_ERROR([POSIX regex.h required.])
 696 fi
 697 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 698
 699 OL_POSIX_REGEX
 700 if test "$ol_cv_c_posix_regex" = no ; then
 701         AC_MSG_ERROR([broken POSIX regex!])
 702 fi
 703
 704 dnl ----------------------------------------------------------------
 705 dnl Check for resolver routines
 706 ol_link_dnssrv=no
 707 AC_CHECK_FUNC(res_query,:)
 708 if test $ac_cv_func_res_query = no ; then
 709         AC_CHECK_LIB(bind, res_query)
 710         ac_cv_func_res_query=$ac_cv_lib_bind_res_query
 711 fi
 712
 713 if test $ac_cv_func_res_query = no ; then
 714         AC_CHECK_LIB(bind, __res_query)
 715         ac_cv_func_res_query=$ac_cv_lib_bind___res_query
 716 fi
 717
 718 if test $ac_cv_func_res_query = no ; then
 719         AC_CHECK_LIB(resolv, res_query)
 720         ac_cv_func_res_query=$ac_cv_lib_resolv_res_query
 721 fi
 722
 723 if test "$ac_cv_func_res_query" = yes ; then
 724         AC_DEFINE(HAVE_RES_QUERY,1,
 725                 [define if you have res_query()])
 726
 727         if test $ol_enable_dnssrv != no ; then
 728                 ol_link_dnssrv=yes
 729         fi
 730 fi
 731
 732 if test "$ol_enable_dnssrv" = yes -a "$ol_link_dnssrv" = no ; then
 733         AC_MSG_ERROR([DNSSRV requires res_query()])
 734 fi
 735
 736 dnl ----------------------------------------------------------------
 737 dnl PF_INET6 support requires getaddrinfo and INET6_ADDRSTRLEN
 738 dnl PF_LOCAL may use getaddrinfo in available
 739 AC_CHECK_FUNCS( getaddrinfo inet_ntop )
 740
 741 ol_link_ipv6=no
 742 if test $ac_cv_func_getaddrinfo = no -o $ac_cv_func_inet_ntop ; then
 743         if test $ol_enable_ipv6 = yes ; then
 744                 AC_MSG_ERROR([IPv6 support requires getaddrinfo() and inet_ntop()])
 745         fi
 746 else
 747         AC_CHECK_FUNCS( gai_strerror )
 748
 749         AC_CACHE_CHECK([INET6_ADDRSTRLEN],[ol_cv_inet6_addrstrlen],[
 750                 AC_EGREP_CPP(__has_inet6_addrstrlen__,[
 751 #                       include <netinet/in.h>
 752 #                       ifdef INET6_ADDRSTRLEN
 753                                 __has_inet6_addrstrlen__;
 754 #                       endif
 755                 ], [ol_cv_inet6_addrstrlen=yes], [ol_cv_inet6_addrstrlen=no])])
 756
 757         if test $ol_cv_inet6_addrstrlen = yes ; then
 758                 ol_link_ipv6=yes
 759         elif test $ol_enable_ipv6 = yes ; then
 760                 AC_MSG_ERROR([IPv6 support requires INET6_ADDRSTRLEN])
 761         fi
 762 fi
 763
 764 if test $ol_enable_local != no ; then
 765         AC_CHECK_HEADERS( sys/un.h )
 766
 767         if test $ol_enable_local = auto ; then
 768                 ol_enable_local=$ac_cv_header_sys_un_h
 769         elif test $ac_cv_header_sys_un_h = no ; then
 770                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
 771         fi
 772 fi
 773
 774 dnl ----------------------------------------------------------------
 775 dnl Kerberos
 776 ol_link_kbind=no
 777 ol_link_kpasswd=no
 778 ol_link_krb5=no
 779 ol_link_krb4=no
 780
 781 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
 782         -o $ol_with_kerberos = k5 -o $ol_with_kerberos = k5only \
 783         -o $ol_with_kerberos = k425 ; then
 784
 785         AC_CHECK_HEADERS(krb5.h)
 786
 787         if test $ac_cv_header_krb5_h = yes ; then
 788                 dnl lazy check for Heimdal Kerberos
 789                 AC_CHECK_HEADERS(heim_err.h)
 790                 if test $ac_cv_header_heim_err_h = yes ; then
 791                         krb5_impl=heimdal
 792                 else
 793                         krb5_impl=mit
 794                 fi
 795
 796                 if test $krb5_impl = mit; then
 797                         AC_CHECK_LIB(krb5, main,
 798                                 [have_krb5=yes
 799                                 KRB5_LIBS="-lkrb5 -lcrypto -lcom_err"],
 800                                 [have_krb5=no],
 801                                 [-lcrypto -lcom_err])
 802
 803                 elif test $krb5_impl = heimdal; then
 804                         AC_CHECK_LIB(krb5, main,
 805                                 [have_krb5=yes
 806                                 KRB5_LIBS="-lkrb5 -ldes -lasn1 -lroken -lcom_err"],
 807                                 [have_krb5=no],
 808                                 [-ldes -lasn1 -lroken -lcom_err])
 809
 810                         AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1,
 811                                 [define if you have HEIMDAL Kerberos])
 812                 else
 813                         have_krb5=no
 814                         AC_MSG_WARN([Unrecongized Kerberos V Implementation])
 815                 fi
 816
 817                 if test $have_krb5 = yes ; then
 818                         ol_link_krb5=yes
 819
 820                         AC_DEFINE(HAVE_KRB5, 1,
 821                                 [define if you have Kerberos V])
 822
 823                         if test $ol_enable_kpasswd != no ; then
 824                                 ol_link_kpasswd=yes;
 825                         fi
 826
 827                         if test $ol_with_kerberos = k5only ; then
 828                                 ol_with_kerberos=found
 829                         fi
 830
 831                 elif test $ol_with_kerberos != auto ; then
 832                         AC_MSG_ERROR([Required Kerberos 5 support not available])
 833                 fi
 834
 835         fi
 836 fi
 837
 838 if test $ol_link_krb5 = yes -a \( $ol_with_kerberos = yes -o \
 839         $ol_with_kerberos = auto -o $ol_with_kerberos = k425 \) ; then
 840
 841         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 842
 843         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 844                 if test $krb5_impl = mit; then
 845                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 846                                 KRB4_LIBS="-lkrb4 -ldes425"], [have_k425=no],
 847                                 [-ldes425 -lkrb5 -lcrypto -lcom_err])
 848
 849                 elif test $krb5_impl = heimdal; then
 850                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 851                                 KRB4_LIBS="-lkrb4"], [have_k425=no],
 852                                 [-lkrb5 -ldes -lasn1 -lroken -lcom_err])
 853
 854                 else
 855                         have_425=no
 856                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 857                 fi
 858
 859                 if test $have_k425 = yes ; then
 860                         ol_with_kerberos=found
 861                         ol_link_krb4=yes
 862
 863                         AC_DEFINE(HAVE_KRB425, 1,
 864                                 [define if you have Kerberos V with IV support])
 865                         AC_DEFINE(HAVE_KRB4, 1,
 866                                 [define if you have Kerberos IV])
 867
 868                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 869                                 [ol_cv_var_des_debug], [
 870                                 dnl save the flags
 871                                 save_LIBS="$LIBS"
 872                                 LIBS="$KRB4_LIBS $KRB5_LIBS $LIBS"
 873                                 AC_TRY_LINK([
 874 #include <kerberosIV/krb.h>
 875 #include <kerberosIV/des.h>
 876 extern int des_debug;
 877 ],[
 878 des_debug = 1;
 879 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 880                                 dnl restore the LIBS
 881                                 LIBS="$save_LIBS"
 882                         ])
 883
 884                         if test $ol_cv_var_des_debug = yes ; then
 885                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 886                                         [define if you have Kerberos des_debug])
 887                         fi
 888
 889                         LIBS="$save_LIBS"
 890                 fi
 891         fi
 892 fi
 893
 894 if test $ol_link_krb5 = yes ; then
 895         ol_with_kerberos=found
 896 fi
 897
 898 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
 899         -o $ol_with_kerberos = k4 -o $ol_with_kerberos = kth ; then
 900
 901         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
 902
 903         if test $ac_cv_header_krb_h = yes ; then
 904                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 905
 906                 if test $have_k4 = yes ; then
 907                         ol_with_kerberos=found
 908                         ol_link_krb4=yes
 909
 910                         AC_DEFINE(HAVE_KRB4, 1,
 911                                 [define if you have Kerberos IV])
 912
 913                         KRB4_LIBS="-lkrb -ldes"
 914
 915                         if test $ac_cv_header_krb_archaeology_h = yes ; then
 916                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
 917                                         [define if you have Kth Kerberos])
 918                         fi
 919                 fi
 920         fi
 921 fi
 922
 923 if test $ol_link_krb4 = yes -a $ol_enable_kpasswd != no ; then
 924         ol_link_kpasswd=yes
 925 fi
 926
 927 if test $ol_link_krb4 = yes -a $ol_enable_kbind != no ; then
 928         ol_link_kbind=yes
 929
 930 elif test $ol_enable_kbind = yes ; then
 931         AC_MSG_ERROR([Kerberos IV detection failed])
 932 fi
 933
 934 if test $ol_link_krb4 = yes -o $ol_link_krb5 = yes ; then
 935         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 936
 937 elif test $ol_with_kerberos != auto -a $ol_with_kerberos != no ; then
 938         AC_MSG_ERROR([Kerberos detection failed])
 939 fi
 940
 941 dnl ----------------------------------------------------------------
 942 dnl TLS/SSL
 943 ol_link_tls=no
 944 if test $ol_with_tls != no ; then
 945         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 946
 947         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 948                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 949                         [have_ssleay=yes
 950                         need_rsaref=no],
 951                         [have_ssleay=no],
 952                         [-lcrypto])
 953
 954                 if test $have_ssleay = no ; then
 955                         AC_CHECK_LIB(ssl, SSL_library_init,
 956                                 [have_ssleay=yes
 957                                 need_rsaref=no], [have_ssleay=no],
 958                                 [-lcrypto])
 959                 fi
 960
 961                 if test $have_ssleay = no ; then
 962                         AC_CHECK_LIB(ssl, ssl3_accept,
 963                                 [have_ssleay=yes
 964                                 need_rsaref=yes], [have_ssleay=no],
 965                                 [-lcrypto -lRSAglue -lrsaref])
 966                 fi
 967
 968                 if test $have_ssleay = yes ; then
 969                         ol_with_tls=found
 970                         ol_link_tls=yes
 971
 972                         AC_DEFINE(HAVE_SSLEAY, 1,
 973                                 [define if you have SSLeay or OpenSSL])
 974
 975                         if test $need_rsaref = yes; then
 976                                 AC_DEFINE(HAVE_RSAREF, 1,
 977                                         [define if you have RSAref])
 978
 979                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 980                         else
 981                                 TLS_LIBS="-lssl -lcrypto"
 982                         fi
 983                 fi
 984         fi
 985
 986 else
 987         AC_WARN([TLS privacy protection not supported!])
 988 fi
 989
 990 if test $ol_link_tls = yes ; then
 991         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 992
 993 elif test $ol_with_tls = auto ; then
 994         AC_WARN([Could not locate TLS/SSL package])
 995         AC_WARN([TLS privacy protection not supported!])
 996
 997 elif test $ol_with_tls != no ; then
 998         AC_ERROR([Could not locate TLS/SSL package])
 999 fi
1000
1001 dnl ----------------------------------------------------------------
1002 dnl Tests for reentrant functions necessary to build a
1003 dnl thread_safe -lldap.
1004 AC_CHECK_FUNCS(         \
1005         ctime_r                 \
1006         gethostbyname_r gethostbyaddr_r \
1007 )
1008
1009 if test "$ac_cv_func_ctime_r" = no ; then
1010         ol_cv_func_ctime_r_nargs=0
1011 else
1012         OL_FUNC_CTIME_R_NARGS
1013 dnl     OL_FUNC_CTIME_R_TYPE
1014 fi
1015
1016 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1017         OL_FUNC_GETHOSTBYNAME_R_NARGS
1018 else
1019         ol_cv_func_gethostbyname_r_nargs=0
1020 fi
1021
1022 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1023         OL_FUNC_GETHOSTBYADDR_R_NARGS
1024 else
1025         ol_cv_func_gethostbyaddr_r_nargs=0
1026 fi
1027
1028 if test "$ac_cv_func_ctime_r" = yes \
1029         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
1030         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
1031         -a "$ac_cv_func_gethostbyname_r" = yes \
1032         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
1033         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
1034         -a "$ac_cv_func_gethostbyaddr_r" = yes \
1035         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
1036         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
1037         ; then
1038
1039         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
1040 fi
1041
1042 dnl ----------------------------------------------------------------
1043 dnl Threads?
1044 ol_link_threads=no
1045
1046 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1047         -o $ol_with_threads = nt ; then
1048
1049         OL_NT_THREADS
1050
1051         if test "$ol_cv_nt_threads" = yes ; then
1052         ol_link_threads=nt
1053         ol_with_threads=found
1054         ol_with_yielding_select=yes
1055
1056                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1057                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1058         fi
1059
1060         if test $ol_with_threads = nt ; then
1061                 AC_MSG_ERROR([could not locate NT Threads])
1062         fi
1063 fi
1064
1065 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1066         -o $ol_with_threads = posix ; then
1067
1068         AC_CHECK_HEADERS(pthread.h)
1069
1070         if test $ac_cv_header_pthread_h = yes ; then
1071                 OL_POSIX_THREAD_VERSION
1072
1073                 if test $ol_cv_pthread_version = final ; then
1074                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
1075                                 [define if pthreads API compatible with final spec])
1076                 elif test $ol_cv_pthread_version = draft4 ; then
1077                         AC_DEFINE(HAVE_PTHREADS_D4,1,
1078                                 [define if pthreads API compatible with draft4 spec])
1079                 else
1080                         AC_MSG_ERROR([unknown pthread version])
1081                 fi
1082
1083                 # consider threads found
1084                 ol_with_threads=found
1085
1086                 OL_HEADER_LINUX_THREADS
1087                 OL_HEADER_GNU_PTH_PTHREAD_H
1088
1089                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1090                         AC_CHECK_HEADERS(sched.h)
1091                 fi
1092
1093                 dnl Now the hard part, how to link?
1094                 dnl
1095                 dnl currently supported checks:
1096                 dnl
1097                 dnl Check for no flags
1098                 dnl     pthread_create() in $LIBS
1099                 dnl
1100                 dnl Check special pthread (final) flags
1101                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1102                 dnl     pthread_create() with -kthread (FreeBSD)
1103                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1104                 dnl     pthread_create() with -pthreads (?)
1105                 dnl     pthread_create() with -mthreads (AIX)
1106                 dnl     pthread_create() with -thread (?)
1107                 dnl
1108                 dnl Check pthread (final) libraries
1109                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1110                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1111                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1112                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1113                 dnl     pthread_create() in -lpthread (many)
1114                 dnl     pthread_create() in -lc_r (FreeBSD)
1115                 dnl
1116                 dnl Check pthread (draft4) flags (depreciated)
1117                 dnl     pthread_create() with -threads (OSF/1)
1118                 dnl
1119                 dnl Check pthread (draft4) libraries (depreciated)
1120                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1121                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1122                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1123                 dnl     pthread_create() in -lpthreads (many)
1124                 dnl
1125
1126                 dnl pthread_create in $LIBS
1127                 AC_CACHE_CHECK([for pthread_create in default libraries],
1128                         ol_cv_pthread_create,[
1129                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1130                         [ol_cv_pthread_create=yes],
1131                         [ol_cv_pthread_create=no],
1132                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1133                                 [ol_cv_pthread_create=yes],
1134                                 [ol_cv_pthread_create=no])])])
1135
1136                 if test $ol_cv_pthread_create != no ; then
1137                         ol_link_threads=posix
1138                         ol_link_pthreads=""
1139                 fi
1140
1141 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1142                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1143                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1144                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1145                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1146                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1147
1148                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1149                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1150                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1151                         [ol_cv_pthread_lpthread_lmach_lexc])
1152 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1153 dnl                     [ol_cv_pthread_lpthread_lexc])
1154
1155                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1156                         [ol_cv_pthread_lib_lpthread_woff])
1157
1158                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1159                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1160
1161                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1162
1163                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1164                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1165                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1166                         [ol_cv_pthread_lpthreads_lmach_lexc])
1167                 OL_PTHREAD_TRY([-lpthreads -lexc],
1168                         [ol_cv_pthread_lpthreads_lexc])
1169
1170                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1171
1172                 if test $ol_link_threads != no ; then
1173                         AC_DEFINE(HAVE_PTHREADS,1,
1174                                 [define if you have POSIX Threads])
1175
1176                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1177
1178                         dnl save flags
1179                         save_CPPFLAGS="$CPPFLAGS"
1180                         save_LIBS="$LIBS"
1181                         LIBS="$LTHREAD_LIBS $LIBS"
1182
1183                         dnl All POSIX Thread (final) implementations should have
1184                         dnl sched_yield instead of pthread yield.
1185                         dnl check for both
1186                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1187
1188                         if test $ac_cv_func_sched_yield = no -a \
1189                                 $ac_cv_func_pthread_yield = no ; then
1190                                 dnl Digital UNIX has sched_yield() in -lrt
1191                                 AC_CHECK_LIB(rt, sched_yield,
1192                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1193                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1194                                                 [Define if you have the sched_yield function.])
1195                                         ac_cv_func_sched_yield=yes],
1196                                         [ac_cv_func_sched_yield=no])
1197                         fi
1198                         if test $ac_cv_func_sched_yield = no -a \
1199                                 $ac_cv_func_pthread_yield = no ; then
1200                                 dnl Solaris has sched_yield() stub in -lposix4
1201                                 dnl but we'll use thr_yield instead.
1202                                 AC_CHECK_FUNCS(thr_yield)
1203                         fi
1204                         if test $ac_cv_func_sched_yield = no -a \
1205                                 $ac_cv_func_pthread_yield = no -a \
1206                                 "$ac_cv_func_thr_yield" = no ; then
1207                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1208                         fi
1209
1210                         dnl Check functions for compatibility
1211                         AC_CHECK_FUNCS(pthread_kill pthread_rwlock_destroy)
1212
1213                         dnl Check for pthread_detach with <pthread.h> inclusion
1214                         dnl as it's symbol may have been mangled.
1215                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1216                                 [ol_cv_func_pthread_detach], [
1217                                 dnl save the flags
1218                                 AC_TRY_LINK([
1219 #include <pthread.h>
1220 #ifndef NULL
1221 #define NULL (void*)0
1222 #endif
1223 ],
1224                                         [pthread_detach(NULL);],
1225                                         [ol_cv_func_pthread_detach=yes],
1226                                         [ol_cv_func_pthread_detach=no])
1227                         ])
1228
1229                         if test $ol_cv_func_pthread_detach = no ; then
1230                                 AC_MSG_ERROR([could not locate pthread_detach()])
1231                         fi
1232
1233                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1234                                 [define if you have pthread_detach function])
1235
1236                         dnl Check for setconcurreny functions
1237                         AC_CHECK_FUNCS( \
1238                                 pthread_setconcurrency \
1239                                 pthread_getconcurrency \
1240                                 thr_setconcurrency \
1241                                 thr_getconcurrency \
1242                         )
1243
1244                         OL_SYS_LINUX_THREADS
1245                         OL_LINUX_THREADS
1246
1247                         if test $ol_cv_linux_threads = error; then
1248                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1249                         fi
1250
1251                         AC_CACHE_CHECK([if pthread_create() works],
1252                                 ol_cv_pthread_create_works,[
1253                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1254                                 [ol_cv_pthread_create_works=yes],
1255                                 [ol_cv_pthread_create_works=no],
1256                                 [dnl assume yes
1257                                 ol_cv_pthread_create_works=yes])])
1258
1259                         if test $ol_cv_pthread_create_works = no ; then
1260                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1261                         fi
1262
1263                         dnl Check if select causes an yield
1264                         if test $ol_with_yielding_select = auto ; then
1265                                 AC_CACHE_CHECK([if select yields when using pthreads],
1266                                         ol_cv_pthread_select_yields,[
1267                                 AC_TRY_RUN([
1268 #include <sys/types.h>
1269 #include <sys/time.h>
1270 #include <unistd.h>
1271 #include <pthread.h>
1272 #ifndef NULL
1273 #define NULL (void*) 0
1274 #endif
1275
1276 static int fildes[2];
1277
1278 static void *task(p)
1279         void *p;
1280 {
1281         int i;
1282         struct timeval tv;
1283
1284         fd_set rfds;
1285
1286         tv.tv_sec=10;
1287         tv.tv_usec=0;
1288
1289         FD_ZERO(&rfds);
1290         FD_SET(fildes[0], &rfds);
1291
1292         /* we're not interested in any fds */
1293         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1294
1295         if(i < 0) {
1296                 perror("select");
1297                 exit(10);
1298         }
1299
1300         exit(0); /* if we exit here, the select blocked the whole process */
1301 }
1302
1303 int main(argc, argv)
1304         int argc;
1305         char **argv;
1306 {
1307         pthread_t t;
1308
1309         /* create a pipe to select */
1310         if(pipe(&fildes[0])) {
1311                 perror("select");
1312                 exit(1);
1313         }
1314
1315 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1316         (void) pthread_setconcurrency(2);
1317 #else
1318 #ifdef HAVE_THR_SETCONCURRENCY
1319         /* Set Solaris LWP concurrency to 2 */
1320         thr_setconcurrency(2);
1321 #endif
1322 #endif
1323
1324 #if HAVE_PTHREADS_D4
1325         pthread_create(&t, pthread_attr_default, task, NULL);
1326 #else
1327         pthread_create(&t, NULL, task, NULL);
1328 #endif
1329
1330 #if HAVE_SCHED_YIELD
1331         sched_yield();  /* make sure task runs first */
1332 #else
1333 #ifdef HAVE_PTHREAD_YIELD
1334         pthread_yield();        /* make sure task runs first */
1335 #endif
1336 #endif
1337
1338         exit(2);
1339 }],
1340                                 [ol_cv_pthread_select_yields=no],
1341                                 [ol_cv_pthread_select_yields=yes],
1342                                 [ol_cv_pthread_select_yields=cross])])
1343
1344                                 if test $ol_cv_pthread_select_yields = cross ; then
1345                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1346                                 fi
1347
1348                                 if test $ol_cv_pthread_select_yields = yes ; then
1349                                         ol_with_yielding_select=yes
1350                                 fi
1351                         fi
1352
1353                         dnl restore flags
1354                         CPPFLAGS="$save_CPPFLAGS"
1355                         LIBS="$save_LIBS"
1356                 else
1357                         AC_MSG_ERROR([could not link with POSIX Threads])
1358                 fi
1359         fi
1360
1361         if test $ol_with_threads = posix ; then
1362                 AC_MSG_ERROR([could not locate POSIX Threads])
1363         fi
1364 fi
1365
1366 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1367         -o $ol_with_threads = mach ; then
1368
1369         dnl check for Mach CThreads
1370         AC_CHECK_HEADERS(mach/cthreads.h)
1371         if test $ac_cv_header_mach_cthreads_h = yes ; then
1372                 ol_with_threads=found
1373
1374                 dnl check for cthread support in current $LIBS
1375                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1376
1377                 if test $ol_link_threads = no ; then
1378                         dnl try -all_load
1379                         dnl this test needs work
1380                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1381                                 [ol_cv_cthread_all_load], [
1382                                 dnl save the flags
1383                                 save_LIBS="$LIBS"
1384                                 LIBS="-all_load $LIBS"
1385                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1386                                         cthread_fork((void *)0, (void *)0);
1387                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1388                                 dnl restore the LIBS
1389                                 LIBS="$save_LIBS"
1390                         ])
1391
1392                         if test $ol_cv_cthread_all_load = yes ; then
1393                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1394                                 ol_link_threads=mach
1395                         fi
1396                 fi
1397
1398                 if test $ol_link_threads != no ; then
1399                         : check for cthread specific functionality here
1400                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1401                                 [define if you have Mach Cthreads])
1402                 else
1403                         AC_MSG_ERROR([could not link with Mach CThreads])
1404                 fi
1405         fi
1406
1407         if test $ol_with_threads = mach ; then
1408                 AC_MSG_ERROR([could not locate Mach CThreads])
1409         fi
1410 fi
1411
1412 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1413         -o $ol_with_threads = pth ; then
1414
1415         AC_CHECK_HEADERS(pth.h)
1416
1417         if test $ac_cv_header_pth_h = yes ; then
1418                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1419
1420                 if test $have_pth = yes ; then
1421                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1422                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1423                         ol_link_threads=pth
1424
1425                         if test $ol_with_yielding_select = auto ; then
1426                                 ol_with_yielding_select=yes
1427                         fi
1428                 fi
1429         fi
1430 fi
1431
1432 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1433         -o $ol_with_threads = lwp ; then
1434
1435         dnl check for SunOS5 LWP
1436         AC_CHECK_HEADERS(thread.h synch.h)
1437         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1438                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1439
1440                 if test $have_thr = yes ; then
1441                         AC_DEFINE(HAVE_THR,1,
1442                                 [if you have Solaris LWP (thr) package])
1443                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1444                         ol_link_threads=thr
1445
1446                         if test $ol_with_yielding_select = auto ; then
1447                                 ol_with_yielding_select=yes
1448                         fi
1449
1450                         dnl Check for setconcurreny functions
1451                         AC_CHECK_FUNCS( \
1452                                 thr_setconcurrency \
1453                                 thr_getconcurrency \
1454                         )
1455                 fi
1456         fi
1457
1458         dnl check for SunOS4 LWP
1459         AC_CHECK_HEADERS(lwp/lwp.h)
1460         if test $ac_cv_header_lwp_lwp_h = yes ; then
1461                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1462
1463                 if test $have_lwp = yes ; then
1464                         AC_DEFINE(HAVE_LWP,1,
1465                                 [if you have SunOS LWP package])
1466                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1467                         ol_link_threads=lwp
1468
1469                         if test $ol_with_yielding_select = auto ; then
1470                                 ol_with_yielding_select=no
1471                         fi
1472                 fi
1473         fi
1474 fi
1475
1476 if test $ol_with_yielding_select = yes ; then
1477         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1478                 [define if select implicitly yields])
1479 fi
1480
1481 if test $ol_with_threads = manual ; then
1482         dnl User thinks he can manually configure threads.
1483         ol_link_threads=yes
1484
1485         AC_MSG_WARN([thread defines and link options must be set manually])
1486
1487         AC_CHECK_HEADERS(pthread.h sched.h)
1488         AC_CHECK_FUNCS(sched_yield pthread_yield)
1489         OL_HEADER_LINUX_THREADS
1490
1491         AC_CHECK_HEADERS(mach/cthreads.h)
1492         AC_CHECK_HEADERS(lwp/lwp.h)
1493         AC_CHECK_HEADERS(thread.h synch.h)
1494 fi
1495
1496 if test $ol_link_threads != no -a $ol_link_threads != nt ; then
1497         dnl needed to get reentrant/threadsafe versions
1498         dnl
1499         AC_DEFINE(REENTRANT,1)
1500         AC_DEFINE(_REENTRANT,1)
1501         AC_DEFINE(THREAD_SAFE,1)
1502         AC_DEFINE(_THREAD_SAFE,1)
1503         AC_DEFINE(THREADSAFE,1)
1504         AC_DEFINE(_THREADSAFE,1)
1505         AC_DEFINE(_SGI_MP_SOURCE,1)
1506
1507         dnl The errno declaration may dependent upon _REENTRANT.
1508         dnl If it does, we must link with thread support.
1509         AC_CACHE_CHECK([for thread specific errno],
1510                 [ol_cv_errno_thread_specific], [
1511                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1512                         [ol_cv_errno_thread_specific=yes],
1513                         [ol_cv_errno_thread_specific=no])
1514         ])
1515
1516         dnl The h_errno declaration may dependent upon _REENTRANT.
1517         dnl If it does, we must link with thread support.
1518         AC_CACHE_CHECK([for thread specific h_errno],
1519                 [ol_cv_h_errno_thread_specific], [
1520                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1521                         [ol_cv_h_errno_thread_specific=yes],
1522                         [ol_cv_h_errno_thread_specific=no])
1523         ])
1524
1525         if test $ol_cv_errno_thread_specific != yes \
1526                 -o $ol_cv_h_errno_thread_specific != yes ; then
1527                 LIBS="$LTHREAD_LIBS $LIBS"
1528                 LTHREAD_LIBS=""
1529         fi
1530
1531 dnl When in thread environment, use
1532 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1533 dnl                     || defined( HAVE_FUNC_R )
1534 dnl                     func_r(...);
1535 dnl             #else
1536 dnl             #       if defined( HAVE_THREADS )
1537 dnl                             /* lock */
1538 dnl             #       endif
1539 dnl                             func(...);
1540 dnl             #       if defined( HAVE_THREADS )
1541 dnl                             /* unlock */
1542 dnl             #       endif
1543 dnl             #endif
1544 dnl
1545 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1546 dnl             _POSIX_REENTRANT_FUNCTIONS
1547 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1548 dnl             _POSIX_THREADSAFE_FUNCTIONS
1549 dnl
1550 dnl             and is currently defined in lthread.h
1551 dnl
1552 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1553 dnl
1554 dnl libldap/*.c should only include <lthread.h> iff
1555 dnl LDAP_R_COMPILE is defined.  ie:
1556 dnl             #ifdef LDAP_R_COMPILE
1557 dnl             #       include LDAP_R_COMPILE
1558 dnl             #endif
1559 dnl
1560 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1561 dnl specifically for compiling the threadsafe version of
1562 dnl     the ldap library (-lldap_r).
1563 dnl
1564 dnl     dnl check for reentrant/threadsafe functions
1565 dnl     dnl
1566 dnl     dnl note: these should only be used when linking
1567 dnl     dnl       with $LTHREAD_LIBS
1568 dnl     dnl
1569 dnl     save_CPPFLAGS="$CPPFLAGS"
1570 dnl     save_LIBS="$LIBS"
1571 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1572 dnl     AC_CHECK_FUNCS( \
1573 dnl             gmtime_r \
1574 dnl             gethostbyaddr_r gethostbyname_r \
1575 dnl             feof_unlocked unlocked_feof \
1576 dnl             putc_unlocked unlocked_putc \
1577 dnl             flockfile ftrylockfile \
1578 dnl     )
1579 dnl     CPPFLAGS="$save_CPPFLAGS"
1580 dnl     LIBS="$save_LIBS"
1581 fi
1582
1583 if test $ol_link_threads = no ; then
1584         if test $ol_with_threads = yes ; then
1585                 AC_MSG_ERROR([no suitable thread support])
1586         fi
1587
1588         if test $ol_with_threads = auto ; then
1589                 AC_MSG_WARN([no suitable thread support, disabling threads])
1590                 ol_with_threads=no
1591         fi
1592
1593         AC_DEFINE(NO_THREADS,1,
1594                 [define if you have (or want) no threads])
1595         LTHREAD_LIBS=""
1596 fi
1597
1598 if test $ol_link_threads != no ; then
1599         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1600 fi
1601
1602 dnl ----------------------------------------------------------------
1603 ol_link_ldbm=no
1604
1605 if test $ol_with_ldbm_api = auto \
1606         -o $ol_with_ldbm_api = berkeley \
1607         -o $ol_with_ldbm_api = bcompat ; then
1608
1609         if test $ol_with_ldbm_api = bcompat; then \
1610                 OL_BERKELEY_COMPAT_DB
1611         else
1612                 OL_BERKELEY_DB
1613         fi
1614
1615         if test $ol_cv_berkeley_db != no ; then
1616                 AC_DEFINE(HAVE_BERKELEY_DB,1,
1617                         [define this if Berkeley DB is available])
1618
1619                 ol_link_ldbm=berkeley
1620                 ol_with_ldbm_api=db
1621
1622                 if test $ol_with_ldbm_type = hash ; then
1623                         AC_DEFINE(LDBM_USE_DBHASH,1,
1624                                 [define this to use DBHASH w/ LDBM backend])
1625                 else
1626                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1627                                 [define this to use DBBTREE w/ LDBM backend])
1628                 fi
1629
1630                 dnl $ol_cv_lib_db should be yes or -ldb
1631                 dnl (it could be no, but that would be an error
1632                 if test $ol_cv_lib_db != yes ; then
1633                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1634                 fi
1635         fi
1636 fi
1637
1638 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1639         AC_MSG_WARN(Could not find LDBM with BTREE support)
1640         ol_with_ldbm_api=none
1641 fi
1642
1643 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1644         OL_MDBM
1645
1646         if test $ol_cv_mdbm = yes ; then
1647                 ol_link_ldbm=mdbm
1648                 ol_with_ldbm_api=mdbm
1649                 if test $ol_cv_lib_mdbm != yes ; then
1650                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1651                 fi
1652         fi
1653 fi
1654
1655 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1656         OL_GDBM
1657
1658         if test $ol_cv_gdbm = yes ; then
1659                 ol_link_ldbm=gdbm
1660                 ol_with_ldbm_api=gdbm
1661
1662                 if test $ol_cv_lib_gdbm != yes ; then
1663                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1664                 fi
1665         fi
1666 fi
1667
1668 if test $ol_with_ldbm_api = ndbm ; then
1669         OL_NDBM
1670
1671         if test $ol_cv_ndbm = yes ; then
1672                 ol_link_ldbm=ndbm
1673                 ol_with_ldbm_api=ndbm
1674
1675                 if test $ol_cv_lib_ndbm != yes ; then
1676                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1677                 fi
1678         fi
1679 fi
1680
1681 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1682         AC_MSG_WARN(could not find suitable LDBM backend)
1683         if test $ol_enable_ldbm = yes ; then
1684                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1685         fi
1686
1687         AC_MSG_WARN(disabling LDBM)
1688         ol_enable_ldbm=no
1689 fi
1690
1691 dnl ----------------------------------------------------------------
1692 if test $ol_enable_dynamic = yes -a $enable_shared = yes ; then
1693         LINK_BINS_DYNAMIC="yes"
1694 else
1695         LINK_BINS_DYNAMIC="no"
1696 fi
1697
1698 dnl ----------------------------------------------------------------
1699 if test $ol_enable_wrappers != no ; then
1700         AC_CHECK_HEADERS(tcpd.h)
1701
1702         if test $ac_cv_header_tcpd_h != yes ; then
1703                 have_wrappers=no
1704         else
1705                 AC_TRY_COMPILE([
1706 int allow_severity = 0;
1707 int deny_severity  = 0;
1708                 ],[hosts_access()],[have_wrappers=yes],[have_wrappers=no])
1709         fi
1710
1711         if test $have_wrappers = yes ; then
1712                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1713                 WRAP_LIBS="-lwrap"
1714
1715                 dnl We add another check for -lnsl since some libwrap's
1716                 dnl need it, but it isn't always included from above
1717                 AC_CHECK_LIB(nsl, main)
1718         else
1719                 AC_MSG_WARN(could not find -lwrap)
1720                 if test $ol_enable_wrappers = yes ; then
1721                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1722                 fi
1723
1724                 AC_MSG_WARN(disabling wrappers support)
1725                 ol_enable_wrappers=no
1726                 WRAP_LIBS=""
1727         fi
1728 fi
1729
1730 dnl ----------------------------------------------------------------
1731 if test $ol_enable_syslog != no ; then
1732         AC_CHECK_FUNC(openlog)
1733         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1734                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1735         fi
1736         ol_enable_syslog=$ac_cv_func_openlog
1737 fi
1738
1739 dnl ----------------------------------------------------------------
1740 dnl SQL
1741 ol_link_sql=no
1742 if test $ol_enable_sql != no ; then
1743         AC_CHECK_LIB(iodbc,SQLDriverConnect,[have_iodbc=yes],[have_iodbc=no])
1744         if test $have_iodbc = yes ; then
1745                 ol_link_sql="-liodbc"
1746         else
1747                 AC_CHECK_LIB(odbc,SQLDriverConnect,[have_odbc=yes],[have_odbc=no])
1748                 if test $have_odbc = yes ; then
1749                         ol_link_sql="-lodbc"
1750                 fi
1751         fi
1752
1753         if test $ol_link_sql != no ; then
1754                 SLAPD_SQL_LIBS="$ol_link_sql"
1755
1756         elif test $ol_enable_sql != auto ; then
1757                 AC_MSG_ERROR([could not locate suitable ODBC library])
1758         fi
1759 fi
1760
1761 dnl ----------------------------------------------------------------
1762 dnl ud needs termcap (should insert check here)
1763 ol_link_termcap=no
1764 AC_CHECK_HEADERS(termcap.h ncurses.h)
1765
1766 if test $ol_link_termcap = no ; then
1767         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1768         if test $have_termcap = yes ; then
1769                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1770                 ol_link_termcap=yes
1771                 TERMCAP_LIBS=-ltermcap
1772         fi
1773 fi
1774
1775 if test $ol_link_termcap = no ; then
1776         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1777         if test $have_ncurses = yes ; then
1778                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1779                 ol_link_termcap=yes
1780                 TERMCAP_LIBS=-lncurses
1781         fi
1782 fi
1783
1784 if test $ol_link_termcap = no ; then
1785         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1786         TERMCAP_LIBS=
1787 fi
1788
1789 dnl ----------------------------------------------------------------
1790 dnl
1791 dnl Check for Cyrus SASL
1792 dnl
1793 ol_link_sasl=no
1794 ol_link_spasswd=no
1795 if test $ol_with_cyrus_sasl != no ; then
1796         AC_CHECK_HEADERS(sasl.h)
1797
1798         if test $ac_cv_header_sasl_h = yes ; then
1799                 AC_CHECK_LIB(sasl, sasl_client_init,
1800                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1801
1802                 if test $have_cyrus_sasl != no ; then
1803                         SASL_LIBS="-lsasl"
1804                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1805                         ol_link_sasl=yes
1806                 fi
1807         fi
1808
1809         if test $ol_link_sasl = no ; then
1810                 if test $ol_with_cyrus_sasl != auto ; then
1811                         AC_MSG_ERROR([Could not locate Cyrus SASL])
1812                 else
1813                         AC_MSG_WARN([Could not locate Cyrus SASL])
1814                         AC_MSG_WARN([SASL authentication not supported!])
1815                         if test $ol_link_tls = no ; then
1816                                 AC_MSG_WARN([Strong authentication not supported!])
1817                         fi
1818                 fi
1819
1820         elif test $ol_enable_spasswd != no ; then
1821                 ol_link_spasswd=yes
1822         fi
1823
1824 else
1825         AC_MSG_WARN([SASL authentication not supported!])
1826         if test $ol_link_tls = no ; then
1827                 AC_MSG_WARN([Strong authentication not supported!])
1828         fi
1829 fi
1830
1831 dnl ----------------------------------------------------------------
1832 dnl Check for entropy sources
1833 if test $cross_compiling != yes ; then
1834         dev=no
1835         if test -r /dev/urandom ; then
1836                 dev="/dev/urandom";
1837         elif test -r /idev/urandom ; then
1838                 dev="/idev/urandom";
1839         elif test -r /dev/srandom ; then
1840                 dev="/dev/srandom";
1841         elif test -r /dev/random ; then
1842                 dev="/dev/random";
1843         elif test -r /idev/random ; then
1844                 dev="/idev/random";
1845         fi
1846
1847         if test $dev != no ; then
1848                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
1849         fi
1850 fi
1851
1852 dnl ----------------------------------------------------------------
1853 dnl
1854 dnl Check for fetch URL support
1855 dnl             should be extended to support other fetch URL APIs
1856 dnl
1857 ol_link_fetch=no
1858 if test $ol_with_fetch != no ; then
1859         OL_LIB_FETCH
1860
1861         if test $ol_cv_lib_fetch != no ; then
1862                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1863                 ol_link_fetch=freebsd
1864
1865         elif test $ol_with_fetch != auto ; then
1866                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1867         fi
1868 fi
1869
1870 dnl ----------------------------------------------------------------
1871 dnl
1872 dnl Check for GNU readline
1873 dnl
1874 ol_link_readline=no
1875 if test $ol_with_readline != no ; then
1876         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1877
1878         if test $ac_cv_header_readline_readline_h = yes ; then
1879                 save_LIBS="$LIBS"
1880                 LIBS="$TERMCAP_LIBS $LIBS"
1881                 AC_CHECK_LIB(readline, readline,
1882                         [have_readline=yes], [have_readline=no])
1883                 LIBS="$save_LIBS"
1884
1885                 if test $have_readline = yes ; then
1886                         ol_with_readline=found
1887                         ol_link_readline=yes
1888
1889                         READLINE_LIBS="-lreadline"
1890                 fi
1891         fi
1892 fi
1893
1894 if test $ol_link_readline = yes ; then
1895         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1896 fi
1897
1898
1899 dnl ----------------------------------------------------------------
1900 dnl FreeBSD (and others) have crypt(3) in -lcrypt
1901 if test $ol_enable_crypt != no ; then
1902         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1903                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1904                         have_crypt=yes], [have_crypt=no])])
1905
1906         if test $have_crypt = yes ; then
1907                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1908         else
1909                 AC_MSG_WARN(could not find crypt)
1910                 if test $ol_enable_crypt = yes ; then
1911                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1912                 fi
1913
1914                 AC_MSG_WARN(disabling crypt support)
1915                 ol_enable_crypt=no
1916         fi
1917 fi
1918
1919 dnl ----------------------------------------------------------------
1920 dnl FreeBSD (and others) have setproctitle(3) in -lutil
1921 if test $ol_enable_proctitle != no ; then
1922         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1923                 AC_CHECK_LIB(util, setproctitle,
1924                         [have_setproctitle=yes
1925                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1926                         [have_setproctitle=no
1927                         LIBOBJS="$LIBOBJS setproctitle.o"
1928                         LIBSRCS="$LIBSRCS setproctitle.c"])])
1929
1930         if test $have_setproctitle = yes ; then
1931                 AC_DEFINE(HAVE_SETPROCTITLE,1,
1932                         [define if setproctitle(3) is available])
1933         fi
1934 fi
1935
1936 dnl ----------------------------------------------------------------
1937 dnl Checks for typedefs, structures, and compiler characteristics.
1938 AC_TYPE_MODE_T
1939 AC_TYPE_OFF_T
1940 AC_TYPE_PID_T
1941 AM_TYPE_PTRDIFF_T
1942 AC_TYPE_SIGNAL
1943 AC_TYPE_SIZE_T
1944
1945 AC_CHECK_TYPE(ssize_t, [signed int])
1946 AC_CHECK_TYPE(caddr_t,  [char *])
1947
1948 OL_TYPE_SOCKLEN_T
1949 AC_STRUCT_ST_BLKSIZE
1950 AC_HEADER_TIME
1951 AC_STRUCT_TM
1952 AC_TYPE_UID_T
1953 OL_TYPE_SIG_ATOMIC_T
1954
1955 dnl AC_TYPE_GETGROUPS
1956
1957 OL_STRUCT_PASSWD_PW_GECOS
1958 OL_STRUCT_PASSWD_PW_PASSWD
1959
1960 OL_C_UPPER_LOWER
1961 AC_C_CONST
1962 OL_C_VOLATILE
1963
1964 if test $cross_compiling = yes ; then
1965         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1966 else
1967         AC_C_BIGENDIAN
1968 fi
1969
1970 AC_COMPILE_CHECK_SIZEOF(short)
1971 AC_COMPILE_CHECK_SIZEOF(int)
1972 AC_COMPILE_CHECK_SIZEOF(long)
1973
1974 if test "$ac_cv_sizeof_int" -lt 4 ; then
1975         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
1976
1977         AC_DEFINE(LBER_INT_T,long)
1978 else
1979         AC_DEFINE(LBER_INT_T,int)
1980 fi
1981
1982 AC_DEFINE(LBER_LEN_T,long)
1983 AC_DEFINE(LBER_SOCKET_T,int)
1984 AC_DEFINE(LBER_TAG_T,long)
1985
1986 dnl ----------------------------------------------------------------
1987 dnl Checks for library functions.
1988 AC_FUNC_MEMCMP
1989 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1990 AC_FUNC_STRFTIME
1991 dnl AM_FUNC_STRTOD
1992
1993 OL_FUNC_INET_ATON
1994
1995 dnl Check for NT specific routines
1996 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
1997
1998 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
1999         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2000 ])
2001
2002 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2003         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2004 ])
2005
2006 AC_FUNC_VPRINTF
2007
2008 if test $ac_cv_func_vprintf = yes ; then
2009         dnl check for vsnprintf
2010         AC_CHECK_FUNCS(vsnprintf vsprintf)
2011 fi
2012
2013 AC_CHECK_FUNCS(         \
2014         bcopy                   \
2015         closesocket             \
2016         chroot                  \
2017         endgrent                \
2018         endpwent                \
2019         fcntl                   \
2020         flock                   \
2021         getdtablesize   \
2022         getgrgid                \
2023         gethostname             \
2024         getpass                 \
2025         getpassphrase   \
2026         getpwuid                \
2027         getpwnam                \
2028         getspnam                \
2029         gettimeofday    \
2030         initgroups              \
2031         lockf                   \
2032         memcpy                  \
2033         memmove                 \
2034         mkstemp                 \
2035         pipe                    \
2036         read                    \
2037         recv                    \
2038         recvfrom                \
2039         setpwfile               \
2040         setgid                  \
2041         setegid                 \
2042         setsid                  \
2043         setuid                  \
2044         seteuid                 \
2045         sigaction               \
2046         signal                  \
2047         sigset                  \
2048         snprintf                \
2049         strdup                  \
2050         strerror                \
2051         strpbrk                 \
2052         strrchr                 \
2053         strsep                  \
2054         strstr                  \
2055         strtol                  \
2056         strtoul                 \
2057         strspn                  \
2058         sysconf                 \
2059         waitpid                 \
2060         wait4                   \
2061         write                   \
2062         send                    \
2063         sendto                  \
2064 )
2065
2066 dnl We actually may need to replace more than this.
2067 AC_REPLACE_FUNCS(getopt tempnam)
2068
2069 if test "$ac_cv_func_getopt" != yes; then
2070     LIBSRCS="$LIBSRCS getopt.c"
2071 fi
2072
2073 if test "$ac_cv_func_tempnam" != yes; then
2074     LIBSRCS="$LIBSRCS tempnam.c"
2075 fi
2076
2077 dnl ----------------------------------------------------------------
2078 # Check Configuration
2079 OL_SYS_ERRLIST
2080
2081 dnl ----------------------------------------------------------------
2082 dnl Sort out defines
2083
2084 if test "$ol_enable_debug" != no ; then
2085         AC_DEFINE(LDAP_DEBUG,1,
2086                 [define this to add debugging code])
2087 fi
2088 if test "$ol_enable_syslog" = yes ; then
2089         AC_DEFINE(LDAP_SYSLOG,1,
2090                 [define this to add syslog code])
2091 fi
2092 if test "$ol_enable_cache" = no ; then
2093         AC_DEFINE(LDAP_NOCACHE,1,
2094                 [define this to remove -lldap cache support])
2095 fi
2096 if test "$ol_link_kbind" != no ; then
2097         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_KBIND,LDAP_VENDOR_VERSION)
2098 fi
2099 if test "$ol_enable_proctitle" != no ; then
2100         AC_DEFINE(LDAP_PROCTITLE,1,
2101                 [define this for LDAP process title support])
2102 fi
2103 if test "$ol_enable_referrals" != no ; then
2104         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
2105 fi
2106 if test "$ol_enable_local" != no; then
2107         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2108 fi
2109 if test "$ol_link_ipv6" != no; then
2110         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2111 fi
2112 if test "$ol_enable_cleartext" != no ; then
2113         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2114 fi
2115 if test "$ol_enable_crypt" != no ; then
2116         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2117 fi
2118 if test "$ol_link_kpasswd" != no ; then
2119         AC_DEFINE(SLAPD_KPASSWD,1,[define to support Kerberos passwords])
2120 fi
2121 if test "$ol_link_spasswd" != no ; then
2122         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2123 fi
2124 dnl if test "$ol_enable_multimaster" != no ; then
2125 dnl     AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2126 dnl fi
2127 if test "$ol_enable_phonetic" != no ; then
2128         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
2129 fi
2130 if test "$ol_enable_rlookups" != no ; then
2131         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2132 fi
2133 if test "$ol_enable_aci" != no ; then
2134         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2135 fi
2136
2137 if test "$ol_link_modules" != no ; then
2138         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2139         BUILD_SLAPD=yes
2140         SLAPD_MODULES_LDFLAGS="-dlopen self"
2141 fi
2142
2143 if test "$ol_link_dnssrv" != no ; then
2144         AC_DEFINE(SLAPD_DNSSRV,1,[define to support DNS SRV backend])
2145         BUILD_SLAPD=yes
2146         BUILD_DNSSRV=yes
2147         if test "$ol_with_dnssrv_module" != static ; then
2148                 AC_DEFINE(SLAPD_DNSSRV_DYNAMIC,1,
2149                         [define to support dynamic DNS SRV backend])
2150                 BUILD_DNSSRV=mod
2151                 BUILD_DNSSRV_DYNAMIC=shared
2152                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-dnssrv/back_dnssrv.la"
2153         fi
2154 fi
2155
2156 if test "$ol_enable_ldap" != no ; then
2157         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
2158         BUILD_SLAPD=yes
2159         BUILD_LDAP=yes
2160         if test "$ol_with_ldap_module" != static ; then
2161                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
2162                         [define to support dynamic LDAP backend])
2163                 BUILD_LDAP=mod
2164                 BUILD_LDAP_DYNAMIC=shared
2165                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
2166         fi
2167 fi
2168
2169 if test "$ol_link_ldbm" != no ; then
2170         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
2171         BUILD_SLAPD=yes
2172         BUILD_LDBM=yes
2173         if test "$ol_with_ldbm_module" != static ; then
2174                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
2175                         [define to support dynamic LDBM backend])
2176                 BUILD_LDBM=mod
2177                 BUILD_LDBM_DYNAMIC=shared
2178                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
2179         fi
2180 fi
2181
2182 if test "$ol_enable_passwd" != no ; then
2183         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2184         BUILD_SLAPD=yes
2185         BUILD_PASSWD=yes
2186         if test "$ol_with_passwd_module" != static ; then
2187                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2188                         [define to support dynamic PASSWD backend])
2189                 BUILD_PASSWD=mod
2190                 BUILD_PASSWD_DYNAMIC=shared
2191                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
2192         fi
2193 fi
2194
2195 if test "$ol_enable_shell" != no ; then
2196         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2197         BUILD_SLAPD=yes
2198         BUILD_SHELL=yes
2199         if test "$ol_with_shell_module" != static ; then
2200                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2201                         [define to support dynamic SHELL backend])
2202                 BUILD_SHELL=mod
2203                 BUILD_SHELL_DYNAMIC=shared
2204                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2205         fi
2206 fi
2207
2208 if test "$ol_enable_sql" != no ; then
2209         AC_DEFINE(SLAPD_SQL,1,[define to support SQL backend])
2210         BUILD_SLAPD=yes
2211         BUILD_SQL=yes
2212         if test "$ol_with_sql_module" != static; then
2213                 AC_DEFINE(SLAPD_SQL_DYNAMIC,1,
2214                         [define to support dynamic SQL backend])
2215                 BUILD_SQL=mod
2216                 BUILD_SQL_DYNAMIC=shared
2217                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-sql/back_sql.la"
2218         fi
2219 fi
2220
2221 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2222         $BUILD_SLAPD = yes ; then
2223         BUILD_SLURPD=yes
2224 fi
2225
2226 dnl ----------------------------------------------------------------
2227
2228 if test "$LINK_BINS_DYNAMIC" = yes; then
2229     LIB_LINKAGE=DYN
2230     LT_LIB_LINKAGE=shared
2231 else
2232     LIB_LINKAGE=STAT
2233     LT_LIB_LINKAGE=static
2234 fi
2235
2236 if test "$ac_cv_mingw32" = yes ; then
2237     PLAT=NT
2238     DYN_EXT=dll
2239 else
2240     PLAT=UNIX
2241     DYN_EXT=so
2242 fi
2243
2244 AC_SUBST(LIBSRCS)
2245
2246 AC_SUBST(PLAT)
2247 AC_SUBST(LIB_LINKAGE)
2248 AC_SUBST(LT_LIB_LINKAGE)
2249 AC_SUBST(DYN_EXT)
2250
2251 AC_SUBST(BUILD_SLAPD)
2252   AC_SUBST(BUILD_DNSSRV)
2253   AC_SUBST(BUILD_LDAP)
2254   AC_SUBST(BUILD_LDBM)
2255   AC_SUBST(BUILD_PASSWD)
2256   AC_SUBST(BUILD_SHELL)
2257   AC_SUBST(BUILD_SQL)
2258   AC_SUBST(BUILD_DNSSRV_DYNAMIC)
2259   AC_SUBST(BUILD_LDAP_DYNAMIC)
2260   AC_SUBST(BUILD_LDBM_DYNAMIC)
2261   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2262   AC_SUBST(BUILD_SHELL_DYNAMIC)
2263   AC_SUBST(BUILD_SQL_DYNAMIC)
2264 AC_SUBST(BUILD_SLURPD)
2265
2266 AC_SUBST(LDAP_LIBS)
2267 AC_SUBST(LDIF_LIBS)
2268 AC_SUBST(SLAPD_LIBS)
2269 AC_SUBST(SLURPD_LIBS)
2270 AC_SUBST(LDBM_LIBS)
2271 AC_SUBST(LTHREAD_LIBS)
2272 AC_SUBST(LUTIL_LIBS)
2273 AC_SUBST(WRAP_LIBS)
2274 AC_SUBST(LINK_BINS_DYNAMIC)
2275
2276 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2277 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2278 AC_SUBST(SLAPD_MODULES_LIST)
2279
2280 AC_SUBST(KRB4_LIBS)
2281 AC_SUBST(KRB5_LIBS)
2282 AC_SUBST(READLINE_LIBS)
2283 AC_SUBST(SASL_LIBS)
2284 AC_SUBST(TERMCAP_LIBS)
2285 AC_SUBST(TLS_LIBS)
2286 AC_SUBST(MODULES_LIBS)
2287 AC_SUBST(AUTH_LIBS)
2288
2289 AC_SUBST(SLAPD_SQL_LDFLAGS)
2290 AC_SUBST(SLAPD_SQL_LIBS)
2291 AC_SUBST(SLAPD_SQL_INCLUDES)
2292
2293 dnl ----------------------------------------------------------------
2294 dnl final output
2295 dnl
2296
2297 AC_OUTPUT( \
2298 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2299 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2300 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2301 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2302 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2303 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2304 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2305 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2306 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2307 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2308 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2309 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2310 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2311 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2312 clients/maildap/Makefile:build/top.mk:clients/maildap/Makefile.in:build/rules.mk \
2313 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2314 include/Makefile:build/top.mk:include/Makefile.in \
2315 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2316 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2317 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2318 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2319 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2320 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2321 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2322 libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk  \
2323 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2324 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2325 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2326 servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk \
2327 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2328 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2329 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2330 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2331 servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk \
2332 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2333 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2334 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2335 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2336 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2337 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2338 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2339 ,[
2340 date > stamp-h
2341 echo Please \"make depend\" to build dependencies
2342 ])