git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Configure.in for OpenLDAP
  11 AC_INIT(include/ldap.h)dnl
  12 AC_CONFIG_AUX_DIR(build)dnl
  13 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no ac_define])dnl
  14
  15 dnl We use autoconf features new to 2.13.
  16 dnl     aclocal.m4 should be built using aclocal from automake 1.4
  17 AC_PREREQ(2.13)dnl Required Autoconf version
  18
  19 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  20
  21 dnl
  22 dnl Start Args
  23 AC_MSG_CHECKING(configure arguments)
  24 AC_PREFIX_DEFAULT(/usr/local)
  25
  26 top_builddir=`pwd`
  27 AC_SUBST(top_builddir)dnl
  28
  29 ldap_subdir="openldap"
  30
  31 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  32         if test "$withval" = "no"; then
  33                 ldap_subdir=""
  34         elif test "$withval" != "yes"; then
  35                 ldap_subdir="$withval"
  36         fi
  37 ])dnl
  38
  39 AC_SUBST(ldap_subdir)dnl
  40
  41 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  42 ol_enable_syslog=no
  43 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  44 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  45 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  46 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  47 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  48 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  49 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  50         no, [yes no])dnl
  51
  52 dnl General "with" options
  53 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  54
  55 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  56         auto, [auto k5 k4 afs yes no])
  57 OL_ARG_WITH(threads,[  --with-threads   use threads],
  58         auto, [auto posix mach lwp yes no manual] )
  59 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  60         auto, [auto yes no manual] )
  61 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  62         auto, [auto ssleay openssl yes no] )
  63
  64 dnl Server options
  65
  66 dnl LDAPD OPTIONS
  67 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  68 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  69
  70 dnl SLAPD OPTIONS
  71 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  72 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  73 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  74 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  75 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  76 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  77 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  78 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  79
  80 dnl SLAPD Backend options
  81 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
  82 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  83 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  84         [auto db2 db gdbm ndbm manual])
  85 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  86         [auto btree hash])
  87
  88 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  89 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
  90 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  91 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
  92
  93 dnl SLURPD OPTIONS
  94 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  95 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  96
  97 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
  98 AM_ENABLE_STATIC
  99 dnl AM_DISABLE_SHARED
 100 AM_ENABLE_SHARED
 101
 102 dnl General "enable" options
 103 # validate options
 104 if test $ol_enable_dns = yes ; then
 105         if test $ol_enable_referrals = no ; then
 106                 AC_MSG_ERROR([DNS requires --enable-referrals])
 107         fi
 108         if test $ol_enable_referrals = auto ; then
 109                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 110                 ol_enable_referrals=yes
 111         fi
 112 fi
 113
 114 if test $ol_enable_slapd = no ; then
 115         dnl SLAPD was specificallly disabled
 116         if test $ol_enable_bdb2 = yes ; then
 117                 AC_MSG_WARN([slapd disabled, ignoring --enable_bdb2 argument])
 118         fi
 119         if test $ol_enable_ldbm = yes ; then
 120                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 121         fi
 122         if test $ol_enable_passwd = yes ; then
 123                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 124         fi
 125         if test $ol_enable_perl = yes ; then
 126                 AC_MSG_WARN([slapd disabled, ignoring --enable_perl argument])
 127         fi
 128         if test $ol_enable_shell = yes ; then
 129                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 130         fi
 131         if test $ol_enable_tcl = yes ; then
 132                 AC_MSG_WARN([slapd disabled, ignoring --enable_tcl argument])
 133         fi
 134         if test $ol_enable_aclgroups = yes ; then
 135                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 136         fi
 137         if test $ol_enable_wrappers = yes ; then
 138                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 139         fi
 140         if test $ol_enable_phonetic = yes ; then
 141                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 142         fi
 143         if test $ol_enable_rlookups = yes ; then
 144                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 145         fi
 146         if test $ol_with_ldbm_api != auto ; then
 147                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 148         fi
 149         if test $ol_with_ldbm_type != auto ; then
 150                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 151         fi
 152         if test $ol_enable_slurpd = yes ; then
 153                 AC_MSG_ERROR([slurpd requires slapd])
 154         fi
 155
 156         # force settings to no
 157         ol_enable_bdb2=no
 158         ol_enable_ldbm=no
 159         ol_enable_passwd=no
 160         ol_enable_perl=no
 161         ol_enable_shell=no
 162         ol_enable_tcl=no
 163         ol_enable_aclgroups=no
 164         ol_enable_wrappers=no
 165         ol_enable_phonetic=no
 166         ol_enable_rlookups=no
 167         ol_with_ldbm_api=no
 168         ol_with_ldbm_type=no
 169         ol_enable_slurpd=no
 170
 171 elif test $ol_enable_ldbm = no ; then
 172         dnl SLAPD without LDBM
 173
 174         if test $ol_with_ldbm_api != auto ; then
 175                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 176         fi
 177
 178         if test $ol_with_ldbm_type != auto ; then
 179                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 180         fi
 181
 182         if test $ol_enable_bdb2 = yes ; then
 183                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 184         fi
 185
 186         if test $ol_enable_passwd = no -a \
 187                 $ol_enable_perl = no -a \
 188                 $ol_enable_shell = no -a \
 189                 $ol_enable_tcl = no ; then
 190                 AC_MSG_ERROR([slapd requires a backend])
 191         fi
 192
 193         ol_with_ldbm_api=no
 194         ol_with_ldbm_type=no
 195
 196 elif test $ol_enable_bdb2 = yes ; then
 197         dnl SLAPD with BDB2
 198
 199         if test $ol_with_ldbm_api != auto -a \
 200                 $ol_with_ldbm_api != db2 ; then
 201                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 202         fi
 203
 204         ol_with_ldbm_api=db2
 205
 206 else
 207         dnl SLAPD with LDBM
 208
 209         if test $ol_enable_bdb2 != no ; then
 210                 if test $ol_with_ldbm_api != auto -a \
 211                         $ol_with_ldbm_api != db2 ; then
 212                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 213                         ol_enable_bdb2=no
 214                 fi
 215         fi
 216
 217         if test $ol_with_ldbm_api = gdbm -a \
 218                 $ol_with_ldbm_type = btree ; then
 219                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 220         fi
 221         if test $ol_with_ldbm_api = ndbm -a \
 222                 $ol_with_ldbm_type = btree ; then
 223                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 224         fi
 225 fi
 226
 227 if test $ol_enable_slurpd = yes ; then
 228         dnl SLURPD was specifically enabled
 229         if test $ol_with_threads = no ; then
 230                 AC_MSG_ERROR([slurpd requires threads])
 231         fi
 232 fi
 233
 234 AC_MSG_RESULT(done)
 235
 236 AC_CANONICAL_HOST
 237
 238 ## Initialize vars
 239 LDAP_LIBS=
 240 LDBM_LIBS=
 241 LTHREAD_LIBS=
 242 LUTIL_LIBS=
 243
 244 LDAPD_LIBS=
 245 SLAPD_LIBS=
 246 SLURPD_LIBS=
 247
 248 BUILD_LDAPD=no
 249 BUILD_SLAPD=no
 250 BUILD_SLURPD=no
 251
 252 BUILD_BDB2=no
 253 BUILD_LDBM=no
 254 BUILD_PASSWD=no
 255 BUILD_PERL=no
 256 BUILD_SHELL=no
 257 BUILD_TCL=no
 258 BUILD_THREAD=no
 259
 260 SLAPD_PERL_LDFLAGS=
 261 SLAPD_PERL_CPPFLAGS=
 262
 263 KRB_LIBS=
 264 TERMCAP_LIBS=
 265 TLS_LIBS=
 266
 267 dnl ----------------------------------------------------------------
 268 dnl Checks for programs
 269
 270 AC_PROG_INSTALL
 271 AM_PROG_LIBTOOL
 272 dnl AC_PROG_MAKE_SET
 273
 274 AC_PROG_AWK
 275 AC_PROG_LN_S
 276
 277 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 278         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 279 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 280 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 281
 282 if test $ol_enable_perl = yes ; then
 283         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 284
 285         if test "no$PERLBIN" = "no" ; then
 286                 ol_enable_perl=no
 287         fi
 288
 289         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 290         SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e perl_inc`"
 291 fi
 292
 293 AC_PROG_CPP
 294
 295 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 296         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 297
 298 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 299         AC_MSG_WARN([programs compiled here do run here...])
 300         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 301
 302 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 303         AC_MSG_WARN([programs compiled here do not run here...])
 304         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 305 fi
 306
 307 dnl Checks for UNIX Variants
 308 AC_AIX
 309 AC_ISC_POSIX
 310 AC_MINIX
 311
 312 dnl Checks for system services
 313 AC_CYGWIN
 314 AC_MINGW32
 315 AC_EXEEXT
 316 AC_OBJEXT
 317
 318 dnl OpenLDAP requires STDC features
 319 AM_PROG_CC_STDC
 320 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 321         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 322 fi
 323
 324 dnl AM_C_PROTOTYPES
 325
 326 dnl Checks for libraries
 327
 328 dnl Find socket()
 329 dnl Likely combinations:
 330 dnl             -lsocket [ -lnsl_s | -lnsl ]
 331 dnl             -linet
 332
 333 AC_CHECK_FUNC(socket, [have_socket=yes], [
 334 dnl
 335 dnl hopefully we won't include too many libraries
 336 dnl
 337         AC_CHECK_LIB(socket, main)
 338         AC_CHECK_LIB(net, main)
 339         AC_CHECK_LIB(nsl_s, main)
 340         AC_CHECK_LIB(nsl, main)
 341         AC_CHECK_LIB(inet, socket)
 342         AC_CHECK_LIB(gen, main)
 343 ])
 344
 345 dnl Check for resolver routines
 346 AC_CHECK_FUNCS(res_search)
 347 if test $ac_cv_func_res_search = "no" ; then
 348         AC_CHECK_LIB(bind, res_search)
 349         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 350                 AC_DEFINE(HAVE_RES_SEARCH,1)
 351         else
 352                 AC_CHECK_LIB(resolv, res_search)
 353                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 354                         AC_DEFINE(HAVE_RES_SEARCH,1)
 355                 fi
 356         fi
 357 fi
 358
 359 dnl HP-UX requires -lV3
 360 AC_CHECK_LIB(V3, sigset)
 361
 362 # ISODE tests
 363 ol_link_isode=no
 364 if test $ol_enable_ldapd != no ; then
 365         dnl look for ISODE libraries
 366         AC_CHECK_LIB(xtpp, main, [
 367                 ol_link_isode=yes
 368                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 369                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 370                 ],:,[-lxtdsap -lxtisode -losi])
 371         AC_CHECK_LIB(dsap, main, [
 372                 ol_link_isode=yes
 373                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 374                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 375                 ],:,[-lisode])
 376         AC_CHECK_LIB(isode, main, [
 377                 ol_link_isode=yes
 378                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 379                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 380                 ],:)
 381 fi
 382
 383 if test $ol_link_isode != no; then
 384         AC_CHECK_LIB(pp, main, [
 385                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 386                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 387                 ],:)
 388
 389         AC_PATH_PROG(PEPSY, pepsy)
 390 fi
 391
 392 dnl
 393 dnl check for kerberos
 394 dnl
 395 ol_link_kerberos=no
 396
 397 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 398         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 399
 400         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 401                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 402                         [-lkrb5 -ldes425])
 403
 404                 if test $have_k5 = yes ; then
 405                         ol_with_kerberos=found
 406                         ol_link_kerberos=yes
 407
 408                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 409
 410                         LIBS="$KRB_LIBS $LIBS"
 411
 412                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 413                                 [ol_cv_var_des_debug], [
 414                                 dnl save the flags
 415                                 save_LIBS="$LIBS"
 416                                 LIBS="$KRB_LIBS $LIBS"
 417                                 AC_TRY_LINK([
 418 #include <kerberosIV/krb.h>
 419 #include <kerberosIV/des.h>
 420 extern int des_debug;
 421 ],[
 422 des_debug = 1;
 423 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 424                                 dnl restore the LIBS
 425                                 LIBS="$save_LIBS"
 426                         ])
 427
 428                         if test $ol_cv_var_des_debug= yes ; then
 429                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 430                                         [define if you have Kerberos des_debug])
 431                         fi
 432
 433                         LIBS="$save_LIBS"
 434                 fi
 435         fi
 436 fi
 437
 438 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 439         AC_CHECK_HEADERS(krb.h des.h)
 440
 441         if test $ac_cv_header_krb_h = yes ; then
 442                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 443
 444                 if test $have_k4 = yes ; then
 445                         ol_with_kerberos=found
 446                         ol_link_kerberos=yes
 447
 448                         KRB_LIBS="-lkrb -ldes"
 449                 fi
 450         fi
 451 fi
 452
 453 if test $ol_link_kerberos = yes ; then
 454         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 455 fi
 456
 457 dnl
 458 dnl Check for SSL/TLS
 459 dnl
 460 ol_link_tls=no
 461 if test $ol_with_tls != no ; then
 462
 463         AC_CHECK_HEADERS(ssl.h)
 464
 465         if test $ac_cv_header_ssl_h = yes ; then
 466                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 467                         [have_ssleay=yes
 468                         need_rsaref=no],
 469                         [have_ssleay=no],
 470                         [-lcrypto])
 471
 472                 if test $have_ssleay = no ; then
 473                         AC_CHECK_LIB(ssl, ssl3_accept,
 474                                 [have_ssleay=yes
 475                                 need_rsaref=yes], [have_ssleay=no],
 476                                 [-lcrypto -lRSAglue -lrsaref])
 477                 fi
 478
 479                 if test $have_ssleay = yes ; then
 480                         ol_with_tls=found
 481                         ol_link_tls=yes
 482
 483                         AC_DEFINE(HAVE_SSLEAY, 1,
 484                                 [define if you have SSLeay or OpenSSL])
 485
 486                         if test $need_rsaref = yes; then
 487                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 488                         else
 489                                 TLS_LIBS="-lssl -lcrypto"
 490                         fi
 491                 fi
 492         fi
 493 fi
 494
 495 if test $ol_link_tls = yes ; then
 496         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 497 fi
 498
 499 ol_link_threads=no
 500 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 501         -o $ol_with_threads = posix ; then
 502
 503         AC_CHECK_HEADERS(pthread.h sched.h)
 504
 505         if test $ac_cv_header_pthread_h = yes ; then
 506                 OL_POSIX_THREAD_VERSION
 507
 508                 if test $ol_cv_pthread_version = final ; then
 509                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 510                                 [define if pthreads API compatible with final spec])
 511                 elif test $ol_cv_pthread_version = draft4 ; then
 512                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 513                                 [define if pthreads API compatible with draft4 spec])
 514                 else
 515                         AC_MSG_ERROR([unknown pthread version])
 516                 fi
 517
 518                 # consider threads found
 519                 ol_with_threads=found
 520
 521                 OL_LINUX_THREADS
 522
 523                 if test $ol_cv_linux_threads = yes ; then
 524                         AC_DEFINE(HAVE_LINUX_THREADS,1,
 525                                 [define if you have LinuxThreads])
 526                 fi
 527
 528                 dnl Now the hard part, how to link?
 529                 dnl
 530                 dnl currently supported checks:
 531                 dnl
 532                 dnl Check for no flags
 533                 dnl     pthread_create() in $LIBS
 534                 dnl
 535                 dnl Check special pthread (final) flags
 536                 dnl     pthread_create() with -kthread (FreeBSD)
 537                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 538                 dnl     pthread_create() with -pthreads (?)
 539                 dnl     pthread_create() with -thread (?)
 540                 dnl     pthread_create() with -mt (Solaris)
 541                 dnl
 542                 dnl Check pthread (final) libraries
 543                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 544                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 545                 dnl     pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 546                 dnl     pthread_create() in -lpthread (many)
 547                 dnl     pthread_create() in -lc_r (FreeBSD)
 548                 dnl     pthread_create() in -lpthreads (many)
 549                 dnl     pthread_join() -Wl,-woff,85 -lpthreads (IRIX)
 550                 dnl
 551                 dnl Check pthread (draft4) flags (depreciated)
 552                 dnl     pthread_create() with -threads (OSF/1)
 553                 dnl
 554                 dnl Check pthread (final) libraries (depreciated)
 555                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 556                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 557                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 558                 dnl
 559
 560                 dnl pthread_create in $LIBS
 561                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 562
 563                 if test $ol_link_threads = no ; then
 564                         dnl try -kthread
 565                         AC_CACHE_CHECK([for pthread_create with -kthread],
 566                                 [ol_cv_kthread_flag], [
 567                                 dnl save the flags
 568                                 save_LIBS="$LIBS"
 569                                 LIBS="-kthread $LIBS"
 570                                 AC_TRY_LINK([#include <pthread.h>],[
 571 #if HAVE_PTHREADS_D4
 572         pthread_create(NULL,pthread_attr_default,NULL,NULL);
 573 #else
 574         pthread_create(NULL,NULL,NULL,NULL);
 575 #endif
 576 ],
 577                                         [ol_cv_kthread_flag=yes], [ol_cv_kthread_flag=no])
 578                                 dnl restore the LIBS
 579                                 LIBS="$save_LIBS"
 580                         ])
 581
 582                         if test $ol_cv_kthread_flag = yes ; then
 583                                 LTHREAD_LIBS="$LTHREAD_LIBS -kthread"
 584                                 ol_link_threads=posix
 585                         fi
 586                 fi
 587
 588                 if test $ol_link_threads = no ; then
 589                         dnl try -pthread
 590                         AC_CACHE_CHECK([for pthread_create with -pthread],
 591                                 [ol_cv_pthread_flag], [
 592                                 dnl save the flags
 593                                 save_LIBS="$LIBS"
 594                                 LIBS="-pthread $LIBS"
 595                                 AC_TRY_LINK([#include <pthread.h>],[
 596 #if HAVE_PTHREADS_D4
 597         pthread_create(NULL,pthread_attr_default,NULL,NULL);
 598 #else
 599         pthread_create(NULL,NULL,NULL,NULL);
 600 #endif
 601 ],
 602                                         [ol_cv_pthread_flag=yes], [ol_cv_pthread_flag=no])
 603                                 dnl restore the LIBS
 604                                 LIBS="$save_LIBS"
 605                         ])
 606
 607                         if test $ol_cv_pthread_flag = yes ; then
 608                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 609                                 ol_link_threads=posix
 610                         fi
 611                 fi
 612
 613                 if test $ol_link_threads = no ; then
 614                         dnl try -pthreads
 615                         AC_CACHE_CHECK([for pthread_create with -pthreads],
 616                                 [ol_cv_pthreads_flag], [
 617                                 dnl save the flags
 618                                 save_LIBS="$LIBS"
 619                                 LIBS="-pthreads $LIBS"
 620                                 AC_TRY_LINK([#include <pthread.h>],[
 621 #if HAVE_PTHREADS_D4
 622         pthread_create(NULL,pthread_attr_default,NULL,NULL);
 623 #else
 624         pthread_create(NULL,NULL,NULL,NULL);
 625 #endif
 626 ],
 627                                         [ol_cv_pthreads_flag=yes], [ol_cv_pthreads_flag=no])
 628                                 dnl restore the LIBS
 629                                 LIBS="$save_LIBS"
 630                         ])
 631
 632                         if test $ol_cv_pthreads_flag = yes ; then
 633                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthreads"
 634                                 ol_link_threads=posix
 635                         fi
 636                 fi
 637
 638                 if test $ol_link_threads = no ; then
 639                         dnl try -thread
 640                         AC_CACHE_CHECK([for pthread_create with -thread],
 641                                 [ol_cv_thread_flag], [
 642                                 dnl save the flags
 643                                 save_LIBS="$LIBS"
 644                                 LIBS="-thread $LIBS"
 645                                 AC_TRY_LINK([char pthread_create();],
 646                                         [pthread_create();],
 647                                         [ol_cv_thread_flag=yes], [ol_cv_thread_flag=no])
 648                                 dnl restore the LIBS
 649                                 LIBS="$save_LIBS"
 650                         ])
 651
 652                         if test $ol_cv_thread_flag = yes ; then
 653                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 654                                 ol_link_threads=posix
 655                         fi
 656                 fi
 657
 658                 if test $ol_link_threads = no ; then
 659                         dnl try -mt
 660                         AC_CACHE_CHECK([for pthread_create with -mt],
 661                                 [ol_cv_thread_flag], [
 662                                 dnl save the flags
 663                                 save_LIBS="$LIBS"
 664                                 LIBS="-mt $LIBS"
 665                                 AC_TRY_LINK([char pthread_create();],
 666                                         [pthread_create();],
 667                                         [ol_cv_thread_flag=yes], [ol_cv_thread_flag=no])
 668                                 dnl restore the LIBS
 669                                 LIBS="$save_LIBS"
 670                         ])
 671
 672                         if test $ol_cv_thread_flag = yes ; then
 673                                 LTHREAD_LIBS="$LTHREAD_LIBS -mt"
 674                                 ol_link_threads=posix
 675                         fi
 676                 fi
 677
 678                 if test $ol_link_threads = no ; then
 679                         dnl try DEC Threads -lpthread -lmach -lexc -lc_r
 680                         save_LIBS="$LIBS"
 681                         AC_CHECK_LIB(pthread, pthread_mutex_unlock, [
 682                                 ol_link_threads=posix
 683                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc -lc_r"
 684                                 if test $ol_with_yielding_select = auto ; then
 685                                         ol_with_yielding_select=yes
 686                                 fi
 687                                 ],:,[-lmach -lexc -lc_r])
 688                         LIBS="$save_LIBS"
 689                 fi
 690
 691                 if test $ol_link_threads = no ; then
 692                         dnl try DEC Threads -lpthread -lmach -lexc
 693                         save_LIBS="$LIBS"
 694                         AC_CHECK_LIB(pthread, pthread_mutex_lock, [
 695                                 ol_link_threads=posix
 696                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc"
 697                                 if test $ol_with_yielding_select = auto ; then
 698                                         ol_with_yielding_select=yes
 699                                 fi
 700                                 ],:,[-lmach -lexc])
 701                         LIBS="$save_LIBS"
 702                 fi
 703
 704                 if test $ol_link_threads = no ; then
 705                         dnl try DEC Threads -lpthread -lexc
 706                         save_LIBS="$LIBS"
 707                         AC_CHECK_LIB(pthread, pthread_mutex_trylock, [
 708                                 ol_link_threads=posix
 709                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 710                                 if test $ol_with_yielding_select = auto ; then
 711                                         ol_with_yielding_select=yes
 712                                 fi
 713                                 ],:,[-lexc])
 714                         LIBS="$save_LIBS"
 715                 fi
 716
 717                 if test $ol_link_threads = no ; then
 718                         dnl try -lpthread
 719                         save_LIBS="$LIBS"
 720                         AC_CHECK_LIB(pthread, pthread_create, [
 721                                 ol_link_threads=posix
 722                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"],:)
 723                         LIBS="$save_LIBS"
 724                 fi
 725
 726                 if test $ol_link_threads = no ; then
 727                         dnl try -lc_r
 728                         save_LIBS="$LIBS"
 729                         AC_CHECK_LIB(c_r, pthread_create, [
 730                                 ol_link_threads=posix
 731                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"],:)
 732                         LIBS="$save_LIBS"
 733                 fi
 734
 735                 if test $ol_link_threads = no ; then
 736                         dnl try -lpthreads
 737                         save_LIBS="$LIBS"
 738                         AC_CHECK_LIB(pthreads, pthread_create, [
 739                                 ol_link_threads=posix
 740                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"],:)
 741                         LIBS="$save_LIBS"
 742                 fi
 743
 744                 dnl IRIX Pthread check
 745                 if test $ol_link_threads = no ; then
 746                         dnl try IRIX Pthreads -Wl,-woff,85 -lpthreads
 747                         save_LIBS="$LIBS"
 748                         AC_CHECK_LIB(pthreads, pthread_join, [
 749                                 ol_link_threads=posix
 750                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"
 751                                 ],:,[-Wl,-woff,85])
 752                         LIBS="$save_LIBS"
 753                 fi
 754
 755                 if test $ol_link_threads = no ; then
 756                         dnl try -threads
 757                         AC_CACHE_CHECK([for pthread_create with -threads],
 758                                 [ol_cv_thread_flag], [
 759                                 dnl save the flags
 760                                 save_LIBS="$LIBS"
 761                                 LIBS="-threads $LIBS"
 762                                 AC_TRY_LINK([char pthread_create();],[
 763                                         pthread_create();
 764                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 765                                 dnl restore the LIBS
 766                                 LIBS="$save_LIBS"
 767                         ])
 768
 769                         if test $ol_cv_thread_flag = yes ; then
 770                                 LTHREAD_LIBS="$LTHREAD_LIBS -threads"
 771                                 ol_link_threads=posix
 772                         fi
 773                 fi
 774
 775                 if test $ol_link_threads = no ; then
 776                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 777                         save_LIBS="$LIBS"
 778                         AC_CHECK_LIB(pthreads, pthread_mutex_unlock, [
 779                                 ol_link_threads=posix
 780                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 781                                 if test $ol_with_yielding_select = auto ; then
 782                                         ol_with_yielding_select=yes
 783                                 fi
 784                                 ],:,[-lmach -lexc -lc_r])
 785                         LIBS="$save_LIBS"
 786                 fi
 787
 788                 if test $ol_link_threads = no ; then
 789                         dnl try DEC Threads -lpthreads -lmach -lexc
 790                         save_LIBS="$LIBS"
 791                         AC_CHECK_LIB(pthreads, pthread_mutex_lock, [
 792                                 ol_link_threads=posix
 793                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc"
 794                                 if test $ol_with_yielding_select = auto ; then
 795                                         ol_with_yielding_select=yes
 796                                 fi
 797                                 ],:,[-lmach -lexc])
 798                         LIBS="$save_LIBS"
 799                 fi
 800
 801                 if test $ol_link_threads = no ; then
 802                         dnl try DEC Threads -lpthreads -lexc
 803                         save_LIBS="$LIBS"
 804                         AC_CHECK_LIB(pthreads, pthread_mutex_trylock, [
 805                                 ol_link_threads=posix
 806                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lexc"
 807                                 if test $ol_with_yielding_select = auto ; then
 808                                         ol_with_yielding_select=yes
 809                                 fi
 810                                 ],:,[-lexc])
 811                         LIBS="$save_LIBS"
 812                 fi
 813
 814                 if test $ol_link_threads != no ; then
 815                         AC_DEFINE(HAVE_PTHREADS,1,
 816                                 [define if you have POSIX Threads])
 817
 818                         dnl save flags
 819                         save_CPPFLAGS="$CPPFLAGS"
 820                         save_LIBS="$LIBS"
 821                         LIBS="$LTHREAD_LIBS $LIBS"
 822
 823                         dnl All POSIX Thread (final) implementations should have
 824                         dnl sched_yield instead of pthread yield.
 825                         dnl check for both
 826                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 827
 828                         if test $ac_cv_func_sched_yield = no -a \
 829                                 $ac_cv_func_pthread_yield = no ; then
 830                                 dnl Digital UNIX has sched_yield() in -lrt
 831                                 AC_CHECK_LIB(rt, sched_yield,
 832                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 833                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 834                                         ac_cv_func_sched_yield=yes],
 835                                         [ac_cv_func_sched_yield=no])
 836                         fi
 837                         if test $ac_cv_func_sched_yield = no -a \
 838                                 $ac_cv_func_pthread_yield = no ; then
 839                                 dnl Solaris has sched_yield() in -lposix4
 840                                 dnl but we'll use thr_yield instead.
 841                                 AC_CHECK_FUNCS(thr_yield)
 842                         fi
 843                         if test $ac_cv_func_sched_yield = no -a \
 844                                 $ac_cv_func_pthread_yield = no -a \
 845                                 "$ac_cv_func_thr_yield" = no ; then
 846                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 847                         fi
 848
 849                         dnl Check functions for compatibility
 850                         AC_CHECK_FUNCS(pthread_kill)
 851
 852                         dnl Check for pthread_detach with <pthread.h> inclusion
 853                         dnl as it's symbol may have been mangled.
 854                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
 855                                 [ol_cv_func_pthread_detach], [
 856                                 dnl save the flags
 857                                 AC_TRY_LINK([#include <pthread.h>],
 858                                         [pthread_detach(NULL);],
 859                                         [ol_cv_func_pthread_detach=yes],
 860                                         [ol_cv_func_pthread_detach=no])
 861                         ])
 862
 863                         if test $ol_cv_func_pthread_detach = no ; then
 864                                 AC_MSG_ERROR([could not locate pthread_detach()])
 865                         fi
 866
 867                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
 868                                 [define if you have pthread_detach function])
 869
 870                         dnl Check for setconcurreny functions
 871                         AC_CHECK_FUNCS( \
 872                                 pthread_setconcurrency \
 873                                 pthread_getconcurrency \
 874                                 thr_setconcurrency \
 875                                 thr_getconcurrency \
 876                         )
 877
 878                         AC_MSG_CHECKING([if pthread_create() works])
 879                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 880                         AC_TRY_RUN([
 881 #include <pthread.h>
 882 #ifndef NULL
 883 #define NULL (void*)0
 884 #endif
 885
 886 static void *task(p)
 887         void *p;
 888 {
 889         return (void *) (p == NULL);
 890 }
 891
 892 int main(argc, argv)
 893         int argc;
 894         char **argv;
 895 {
 896         pthread_t t;
 897 #if HAVE_PTHREADS_D4
 898         exit(pthread_create(&t, pthread_attr_default, task, NULL));
 899 #else
 900         exit(pthread_create(&t, NULL, task, NULL));
 901 #endif
 902 }
 903 ],
 904                                 [ol_cv_pthread_create_works=yes],
 905                                 [ol_cv_pthread_create_works=no],
 906                                 [dnl assume yes
 907                                 ol_cv_pthread_create_works=yes])])
 908                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 909
 910                         if test $ol_cv_pthread_create_works = no ; then
 911                                 AC_MSG_ERROR([pthread.h and pthread_create are not compatible])
 912                         fi
 913
 914                         dnl Check if select causes an yield
 915                         if test $ol_with_yielding_select = auto ; then
 916                                 AC_MSG_CHECKING([if select yields when using pthreads])
 917                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 918                                 AC_TRY_RUN([
 919 #include <sys/types.h>
 920 #include <sys/time.h>
 921 #include <unistd.h>
 922 #include <pthread.h>
 923 #ifndef NULL
 924 #define NULL (void*) 0
 925 #endif
 926
 927 static int fildes[2];
 928
 929 static void *task(p)
 930         void *p;
 931 {
 932         int i;
 933         struct timeval tv;
 934
 935         fd_set rfds;
 936
 937         tv.tv_sec=10;
 938         tv.tv_usec=0;
 939
 940         FD_ZERO(&rfds);
 941         FD_SET(fildes[0], &rfds);
 942
 943         /* we're not interested in any fds */
 944         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 945
 946         if(i < 0) {
 947                 perror("select");
 948                 exit(10);
 949         }
 950
 951         exit(0); /* if we exit here, the select blocked the whole process */
 952 }
 953
 954 int main(argc, argv)
 955         int argc;
 956         char **argv;
 957 {
 958         pthread_t t;
 959
 960         /* create a pipe to select */
 961         if(pipe(&fildes[0])) {
 962                 perror("select");
 963                 exit(1);
 964         }
 965
 966 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 967         (void) pthread_setconcurrency(2);
 968 #else
 969 #ifdef HAVE_THR_SETCONCURRENCY
 970         /* Set Solaris LWP concurrency to 2 */
 971         thr_setconcurrency(2);
 972 #endif
 973 #endif
 974
 975 #if HAVE_PTHREADS_D4
 976         pthread_create(&t, pthread_attr_default, task, NULL);
 977 #else
 978         pthread_create(&t, NULL, task, NULL);
 979 #endif
 980
 981 #if HAVE_SCHED_YIELD
 982         sched_yield();  /* make sure task runs first */
 983 #else
 984 #ifdef HAVE_PTHREAD_YIELD
 985         pthread_yield();        /* make sure task runs first */
 986 #endif
 987 #endif
 988
 989         exit(2);
 990 }],
 991                                 [ol_cv_pthread_select_yields=no],
 992                                 [ol_cv_pthread_select_yields=yes], [
 993                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
 994                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
 995
 996                                 if test $ol_cv_pthread_select_yields = yes ; then
 997                                         ol_with_yielding_select=yes
 998                                 fi
 999                         fi
1000
1001                         dnl restore flags
1002                         CPPFLAGS="$save_CPPFLAGS"
1003                         LIBS="$save_LIBS"
1004                 else
1005                         AC_MSG_ERROR([could not link with POSIX Threads])
1006                 fi
1007         fi
1008
1009         if test $ol_with_threads = posix ; then
1010                 AC_MSG_ERROR([could not locate POSIX Threads])
1011         fi
1012 fi
1013
1014 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1015         -o $ol_with_threads = mach ; then
1016
1017         dnl check for Mach CThreads
1018         AC_CHECK_HEADERS(mach/cthreads.h)
1019         if test $ac_cv_header_mach_cthreads_h = yes ; then
1020                 ol_with_threads=found
1021
1022                 dnl check for cthread support in current $LIBS
1023                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1024
1025                 if test $ol_link_threads = no ; then
1026                         dnl try -all_load
1027                         dnl this test needs work
1028                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1029                                 [ol_cv_cthread_all_load], [
1030                                 dnl save the flags
1031                                 save_LIBS="$LIBS"
1032                                 LIBS="-all_load $LIBS"
1033                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1034                                         cthread_fork((void *)0, (void *)0);
1035                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1036                                 dnl restore the LIBS
1037                                 LIBS="$save_LIBS"
1038                         ])
1039
1040                         if test $ol_cv_cthread_all_load = yes ; then
1041                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1042                                 ol_link_threads=mach
1043                         fi
1044                 fi
1045
1046                 if test $ol_link_threads != no ; then
1047                         : check for cthread specific functionality here
1048                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1049                                 [define if you have Mach Cthreads])
1050                 else
1051                         AC_MSG_ERROR([could not link with Mach CThreads])
1052                 fi
1053         fi
1054
1055         if test $ol_with_threads = mach ; then
1056                 AC_MSG_ERROR([could not locate Mach CThreads])
1057         fi
1058 fi
1059
1060 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1061         -o $ol_with_threads = lwp ; then
1062
1063         dnl check for SunOS5 LWP
1064         AC_CHECK_HEADERS(thread.h synch.h)
1065         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1066                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1067
1068                 if test $have_thr = yes ; then
1069                         AC_DEFINE(HAVE_THR,1,
1070                                 [if you have Solaris LWP (thr) package])
1071                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1072                         ol_link_threads=thr
1073
1074                         if test $ol_with_yielding_select = auto ; then
1075                                 ol_with_yielding_select=yes
1076                         fi
1077
1078                         dnl Check for setconcurreny functions
1079                         AC_CHECK_FUNCS( \
1080                                 thr_setconcurrency \
1081                                 thr_getconcurrency \
1082                         )
1083                 fi
1084         fi
1085
1086         dnl check for SunOS4 LWP
1087         AC_CHECK_HEADERS(lwp/lwp.h)
1088         if test $ac_cv_header_lwp_lwp_h = yes ; then
1089                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1090
1091                 if test $have_lwp = yes ; then
1092                         AC_DEFINE(HAVE_LWP,1,
1093                                 [if you have SunOS LWP package])
1094                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1095                         ol_link_threads=lwp
1096
1097                         if test $ol_with_yielding_select = auto ; then
1098                                 ol_with_yielding_select=no
1099                         fi
1100                 fi
1101         fi
1102 fi
1103
1104 if test $ol_with_yielding_select = yes ; then
1105         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1106                 [define if select implicitly yields])
1107 fi
1108
1109 if test $ol_with_threads = manual ; then
1110         dnl User thinks he can manually configure threads.
1111         ol_link_threads=yes
1112
1113         AC_MSG_WARN([thread defines and link options must be set manually])
1114
1115         AC_CHECK_HEADERS(pthread.h sched.h)
1116         AC_CHECK_FUNCS(sched_yield pthread_yield)
1117         OL_LINUX_THREADS
1118
1119         AC_CHECK_HEADERS(mach/cthreads.h)
1120         AC_CHECK_HEADERS(lwp/lwp.h)
1121         AC_CHECK_HEADERS(thread.h synch.h)
1122 fi
1123
1124 if test $ol_link_threads != no ; then
1125         dnl needed to get reentrant/threadsafe versions
1126         dnl
1127         AC_DEFINE(REENTRANT,1)
1128         AC_DEFINE(_REENTRANT,1)
1129         AC_DEFINE(THREAD_SAFE,1)
1130         AC_DEFINE(_THREAD_SAFE,1)
1131         AC_DEFINE(THREADSAFE,1)
1132         AC_DEFINE(_THREADSAFE,1)
1133
1134         dnl this might cause the errno symbol to be
1135         dnl replaced with a function to get a thread specific errno.
1136         dnl check to see if everything needs to be compiled
1137         dnl with the thread libraries
1138         AC_CACHE_CHECK([for thread specific errno],
1139                 [ol_cv_errno_thread_specific], [
1140                 AC_TRY_LINK([#include <errno.h>], [int x = errno;],
1141                         [ol_cv_errno_thread_specific=yes],
1142                         [ol_cv_errno_thread_specific=no])
1143         ])
1144
1145         if test $ol_cv_errno_thread_specific != yes ; then
1146                 LIBS="$LTHREAD_LIBS $LIBS"
1147                 LTHREAD_LIBS=""
1148         fi
1149
1150 dnl When in thread environment, use
1151 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1152 dnl                     || defined( HAVE_FUNC_R )
1153 dnl                     func_r(...);
1154 dnl             #else
1155 dnl             #       if defined( HAVE_THREADS )
1156 dnl                             /* lock */
1157 dnl             #       endif
1158 dnl                             func(...);
1159 dnl             #       if defined( HAVE_THREADS )
1160 dnl                             /* unlock */
1161 dnl             #       endif
1162 dnl             #endif
1163 dnl
1164 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1165 dnl             _POSIX_REENTRANT_FUNCTIONS
1166 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1167 dnl             _POSIX_THREADSAFE_FUNCTIONS
1168 dnl
1169 dnl             and is currently defined in lthread.h
1170 dnl
1171 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1172 dnl
1173 dnl libldap/*.c should only include <lthread.h> iff
1174 dnl LDAP_R_COMPILE is defined.  ie:
1175 dnl             #ifdef LDAP_R_COMPILE
1176 dnl             #       include LDAP_R_COMPILE
1177 dnl             #endif
1178 dnl
1179 dnl LDAP_R_COMIPLE is defined by libldap_r/Makefile.in
1180 dnl specifically for compiling the threadsafe version of
1181 dnl     the ldap library (-lldap_r).
1182 dnl
1183 dnl     dnl check for reentrant/threadsafe functions
1184 dnl     dnl
1185 dnl     dnl note: these should only be used when linking
1186 dnl     dnl       with $LTHREAD_LIBS
1187 dnl     dnl
1188 dnl     save_CPPFLAGS="$CPPFLAGS"
1189 dnl     save_LIBS="$LIBS"
1190 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1191 dnl     AC_CHECK_FUNCS( \
1192 dnl             gmtime_r \
1193 dnl             gethostbyaddr_r gethostbyname_r \
1194 dnl             feof_unlocked unlocked_feof \
1195 dnl             putc_unlocked unlocked_putc \
1196 dnl             flockfile ftrylockfile \
1197 dnl     )
1198 dnl     CPPFLAGS="$save_CPPFLAGS"
1199 dnl     LIBS="$save_LIBS"
1200 fi
1201
1202 dnl ----------------------------------------------------------------
1203
1204 if test $ol_link_threads = no ; then
1205         if test $ol_with_threads = yes ; then
1206                 AC_MSG_ERROR([no suitable thread support])
1207         fi
1208
1209         if test $ol_with_threads = auto ; then
1210                 AC_MSG_WARN([no suitable thread support, disabling threads])
1211                 ol_with_threads=no
1212         fi
1213
1214         AC_DEFINE(NO_THREADS,1,
1215                 [define if you have (or want) no threads])
1216         LTHREAD_LIBS=""
1217 fi
1218
1219 ol_link_ldbm=no
1220 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1221         OL_BERKELEY_DB2
1222
1223         if test $ol_cv_berkeley_db2 = yes ; then
1224                 ol_link_ldbm=db2
1225                 ol_with_ldbm_api=db2
1226
1227                 if test $ol_with_ldbm_type = hash ; then
1228                         AC_DEFINE(LDBM_USE_DBHASH,1)
1229                 else
1230                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1231                 fi
1232
1233                 dnl $ol_cv_lib_db2 should be yes or -ldb
1234                 dnl (it could be no, but that would be an error
1235                 if test $ol_cv_lib_db2 != yes ; then
1236                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1237                 fi
1238         fi
1239 fi
1240
1241 ol_link_bdb2=no
1242 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1243         ol_link_bdb2=yes
1244 fi
1245
1246 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1247         OL_BERKELEY_DB
1248
1249         if test $ol_cv_berkeley_db = yes ; then
1250                 ol_link_ldbm=db
1251                 ol_with_ldbm_api=db
1252
1253                 if test $ol_with_ldbm_type = hash ; then
1254                         AC_DEFINE(LDBM_USE_DBHASH,1)
1255                 else
1256                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1257                 fi
1258
1259                 dnl $ol_cv_lib_db should be yes or -ldb
1260                 dnl (it could be no, but that would be an error
1261                 if test $ol_cv_lib_db != yes ; then
1262                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1263                 fi
1264         fi
1265 fi
1266
1267 if test $ol_with_ldbm_api = manual ; then
1268         dnl User thinks he can manually configure LDBM api.
1269         ol_link_ldbm=yes
1270
1271         AC_MSG_WARN([LDBM defines and link options must be set manually])
1272
1273         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1274 fi
1275
1276 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1277         AC_MSG_WARN(Could not find LDBM with BTREE support)
1278         ol_with_ldbm_api=none
1279 fi
1280
1281 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1282         OL_GDBM
1283
1284         if test $ol_cv_gdbm = yes ; then
1285                 ol_link_ldbm=gdbm
1286                 ol_with_ldbm_api=gdbm
1287
1288                 if test $ol_cv_lib_gdbm != yes ; then
1289                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1290                 fi
1291         fi
1292 fi
1293
1294 if test $ol_with_ldbm_api = auto ; then
1295         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1296 elif test $ol_with_ldbm_api = ndbm ; then
1297         OL_NDBM
1298
1299         if test $ol_cv_ndbm = yes ; then
1300                 ol_link_ldbm=ndbm
1301                 ol_with_ldbm_api=ndbm
1302
1303                 if test $ol_cv_lib_ndbm != yes ; then
1304                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1305                 fi
1306         fi
1307 fi
1308
1309 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1310         AC_MSG_WARN(could not find suitable LDBM backend)
1311         if test $ol_enable_ldbm = yes ; then
1312                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1313         fi
1314
1315         AC_MSG_WARN(disabling LDBM)
1316         ol_enable_ldbm=no
1317 fi
1318
1319 if test $ol_enable_wrappers != no ; then
1320         AC_CHECK_HEADERS(tcpd.h)
1321
1322         if test $ac_cv_header_tcpd_h != yes ; then
1323                 have_wrappers=no
1324         else
1325                 AC_CHECK_LIB(wrap, main,
1326                         [have_wrappers=yes], [have_wrappers=no])
1327         fi
1328
1329         if test $have_wrappers = yes ; then
1330                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1331                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1332         else
1333                 AC_MSG_WARN(could not find -lwrap)
1334                 if test $ol_enable_wrappers = yes ; then
1335                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1336                 fi
1337
1338                 AC_MSG_WARN(disabling wrappers support)
1339                 ol_enable_wrappers=no
1340         fi
1341 fi
1342
1343 if test $ol_enable_syslog != no ; then
1344         AC_CHECK_FUNC(openlog)
1345         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1346                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1347         fi
1348         ol_enable_syslog=$ac_cv_func_openlog
1349 fi
1350
1351 if test $ol_enable_dmalloc != no ; then
1352         AC_CHECK_HEADERS(dmalloc.h)
1353         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1354 fi
1355
1356 if test $ol_enable_tcl != no ; then
1357         AC_CHECK_HEADERS(tcl.h)
1358
1359         if test $ac_cv_header_tcl_h != yes ; then
1360                 have_tcl=no
1361         else
1362                 AC_CHECK_LIB(tcl,main,
1363                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1364                         [have_tcl=no])
1365
1366                 if test $have_tcl != yes; then
1367                         AC_CHECK_LIB(tcl7.6,main,
1368                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1369                                 [have_tcl=no])
1370                 fi
1371
1372                 if test $have_tcl != yes; then
1373                         AC_CHECK_LIB(tcl8.0,main,
1374                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1375                                 [have_tcl=no])
1376                 fi
1377         fi
1378
1379         if test $have_tcl != yes ; then
1380                 AC_MSG_WARN([could not find -ltcl])
1381                 if test $ol_enable_tcl = yes ; then
1382                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1383                 fi
1384
1385                 ol_enable_tcl=no
1386         fi
1387 fi
1388
1389 # ud needs termcap (should insert check here)
1390 ol_link_termcap=no
1391 AC_CHECK_HEADERS(termcap.h ncurses.h)
1392
1393 if test $ol_link_termcap = no ; then
1394         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1395         if test $have_termcap = yes ; then
1396                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1397                 ol_link_termcap=yes
1398                 TERMCAP_LIBS=-ltermcap
1399         fi
1400 fi
1401
1402 if test $ol_link_termcap = no ; then
1403         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1404         if test $have_ncurses = yes ; then
1405                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1406                 ol_link_termcap=yes
1407                 TERMCAP_LIBS=-lncurses
1408         fi
1409 fi
1410
1411 if test $ol_link_termcap = no ; then
1412         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1413         TERMCAP_LIBS=
1414 fi
1415
1416 # FreeBSD (and others) have crypt(3) in -lcrypt
1417 if test $ol_enable_crypt != no ; then
1418         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1419                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1420                         have_crypt=yes], [have_crypt=no])])
1421
1422         if test $have_crypt = yes ; then
1423                 AC_DEFINE(HAVE_CRYPT,1)
1424         else
1425                 AC_MSG_WARN(could not find crypt)
1426                 if test $ol_enable_crypt = yes ; then
1427                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1428                 fi
1429
1430                 AC_MSG_WARN(disabling crypt support)
1431                 ol_enable_crypt=no
1432         fi
1433 fi
1434
1435 # FreeBSD (and others) have setproctitle(3) in -lutil
1436 if test $ol_enable_proctitle != no ; then
1437         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1438                 AC_CHECK_LIB(util, setproctitle,
1439                         [have_setproctitle=yes
1440                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1441                         [have_setproctitle=no
1442                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1443
1444         if test $have_setproctitle = yes ; then
1445                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1446         fi
1447 fi
1448
1449 dnl ----------------------------------------------------------------
1450 dnl Checks for header files.
1451 AC_HEADER_STDC
1452
1453 if test $ac_cv_header_stdc != yes; then
1454         AC_MSG_WARN([could not Standard C compliant headers])
1455 fi
1456
1457 AC_HEADER_DIRENT
1458 AC_HEADER_SYS_WAIT
1459 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1460 if test $am_cv_sys_posix_termios = yes ; then
1461         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1462                 [define if you have POSIX termios])
1463 fi
1464
1465 AC_CHECK_HEADERS(       \
1466         arpa/nameser.h  \
1467         crypt.h                 \
1468         errno.h                 \
1469         fcntl.h                 \
1470         filio.h                 \
1471         getopt.h                \
1472         libutil.h               \
1473         limits.h                \
1474         locale.h                \
1475         malloc.h                \
1476         memory.h                \
1477         regex.h                 \
1478         psap.h                  \
1479         pwd.h                   \
1480         resolv.h                \
1481         sgtty.h                 \
1482         stdarg.h                \
1483         stddef.h                \
1484         string.h                \
1485         strings.h               \
1486         sysexits.h              \
1487         sys/file.h              \
1488         sys/filio.h             \
1489         sys/errno.h             \
1490         sys/ioctl.h             \
1491         sys/param.h             \
1492         sys/resource.h  \
1493         sys/socket.h    \
1494         sys/syslog.h    \
1495         sys/time.h              \
1496         sys/types.h             \
1497         syslog.h                \
1498         termios.h               \
1499         unistd.h                \
1500 )
1501
1502 dnl ----------------------------------------------------------------
1503 dnl Checks for typedefs, structures, and compiler characteristics.
1504 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1505 AC_TYPE_MODE_T
1506 AC_TYPE_OFF_T
1507 AC_TYPE_PID_T
1508 AM_TYPE_PTRDIFF_T
1509 AC_TYPE_SIGNAL
1510 OL_TYPE_SIG_ATOMIC_T
1511 AC_TYPE_SIZE_T
1512 AC_STRUCT_ST_BLKSIZE
1513 AC_HEADER_TIME
1514 AC_STRUCT_TM
1515
1516 OL_C_UPPER_LOWER
1517 AC_C_CONST
1518 OL_C_VOLATILE
1519
1520 if test $cross_compiling = yes ; then
1521         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1522 else
1523         AC_C_BIGENDIAN
1524         AC_CHECK_SIZEOF(short)
1525         AC_CHECK_SIZEOF(int)
1526         AC_CHECK_SIZEOF(long)
1527 fi
1528
1529 dnl ----------------------------------------------------------------
1530 dnl Checks for library functions.
1531 AC_FUNC_MEMCMP
1532 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1533 AC_FUNC_STRFTIME
1534 dnl AM_FUNC_STRTOD
1535 AC_FUNC_VPRINTF
1536
1537 if test $ac_cv_func_vprintf = yes ; then
1538         dnl check for vsnprintf
1539         AC_CHECK_FUNCS(vsnprintf vsprintf)
1540 fi
1541
1542 AC_CHECK_FUNCS(         \
1543         bcopy                   \
1544         flock                   \
1545         getdtablesize   \
1546         gethostname             \
1547         getpwuid                \
1548         gettimeofday    \
1549         lockf                   \
1550         memcpy                  \
1551         memmove                 \
1552         mkstemp                 \
1553         select                  \
1554         setpwfile               \
1555         setsid                  \
1556         signal                  \
1557         sigset                  \
1558         snprintf                \
1559         socket                  \
1560         strdup                  \
1561         strerror                \
1562         strpbrk                 \
1563         strrchr                 \
1564         strsep                  \
1565         strstr                  \
1566         strtol                  \
1567         strtoul                 \
1568         strspn                  \
1569         sysconf                 \
1570         waitpid                 \
1571 )
1572
1573 # these functions are required to build a thread_safe -lldap
1574 AC_CHECK_FUNCS(         \
1575         ctime_r                 \
1576         gethostbyaddr_r \
1577         gethostbyname_r \
1578 )
1579
1580 if test "$ac_cv_func_ctime_r" = yes ; then
1581         OL_FUNC_CTIME_R_NARGS
1582         OL_FUNC_CTIME_R_TYPE
1583 else
1584         ol_cv_func_ctime_r_nargs=0
1585 fi
1586
1587 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1588         OL_FUNC_GETHOSTBYNAME_R_NARGS
1589 else
1590         ol_cv_func_gethostbyname_r=0
1591 fi
1592
1593 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1594         OL_FUNC_GETHOSTBYADDR_R_NARGS
1595 else
1596         ol_cv_func_gethostbyaddr_r=0
1597 fi
1598
1599 if test "$ac_cv_func_ctime_r" = yes \
1600         -a "$ol_cv_func_ctime_r_nargs" -ge 2 -a "$ol_cv_func_ctime_r_nargs" -le 3 \
1601         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
1602         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
1603         -a "$ac_cv_func_gethostbyaddr_r" = yes \
1604         -a "$ac_cv_func_gethostbyname_r" = yes \
1605         ; then
1606
1607         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT, 1)
1608 fi
1609
1610 if test $ol_link_threads != no ; then
1611         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE, 1)
1612 fi
1613
1614 dnl We actually may need to replace more than this.
1615 AC_REPLACE_FUNCS(getopt tempnam)
1616
1617 dnl ----------------------------------------------------------------
1618 # Check Configuration
1619 OL_SYS_ERRLIST
1620
1621 dnl ----------------------------------------------------------------
1622 dnl Sort out defines
1623
1624 if test "$ol_enable_debug" != no ; then
1625         AC_DEFINE(LDAP_DEBUG,1)
1626 fi
1627 if test "$ol_enable_syslog" = yes ; then
1628         AC_DEFINE(LDAP_SYSLOG,1)
1629 fi
1630 if test "$ol_enable_libui" = yes ; then
1631         AC_DEFINE(LDAP_LIBUI,1)
1632 fi
1633 if test "$ol_enable_cache" = no ; then
1634         AC_DEFINE(LDAP_NOCACHE,1)
1635 fi
1636 if test "$ol_enable_dns" != no ; then
1637         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1638 fi
1639 if test "$ol_enable_proctitle" != no ; then
1640         AC_DEFINE(LDAP_PROCTITLE,1)
1641 fi
1642 if test "$ol_enable_referrals" != no ; then
1643         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1644 fi
1645 if test "$ol_enable_cldap" != no ; then
1646         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1647 fi
1648
1649 if test "$ol_enable_aclgroups" != no ; then
1650         AC_DEFINE(SLAPD_ACLGROUPS,1)
1651 fi
1652 if test "$ol_enable_crypt" != no ; then
1653         AC_DEFINE(SLAPD_CRYPT,1)
1654 fi
1655 if test "$ol_enable_cleartext" != no ; then
1656         AC_DEFINE(SLAPD_CLEARTEXT,1)
1657 fi
1658 if test "$ol_enable_phonetic" != no ; then
1659         AC_DEFINE(SLAPD_PHONETIC,1)
1660 fi
1661 if test "$ol_enable_rlookups" != no ; then
1662         AC_DEFINE(SLAPD_RLOOKUPS,1)
1663 fi
1664
1665 if test "$ol_link_bdb2" != no ; then
1666         AC_DEFINE(SLAPD_BDB2,1)
1667         BUILD_SLAPD=yes
1668         BUILD_BDB2=yes
1669 fi
1670
1671 if test "$ol_link_ldbm" != no ; then
1672         AC_DEFINE(SLAPD_LDBM,1)
1673         BUILD_SLAPD=yes
1674         BUILD_LDBM=yes
1675 fi
1676
1677 if test "$ol_enable_passwd" != no ; then
1678         AC_DEFINE(SLAPD_PASSWD,1)
1679         BUILD_SLAPD=yes
1680         BUILD_PASSWD=yes
1681 fi
1682
1683 if test "$ol_enable_perl" != no ; then
1684         AC_DEFINE(SLAPD_PERL,1)
1685         BUILD_SLAPD=yes
1686         BUILD_PERL=yes
1687 fi
1688
1689 if test "$ol_enable_shell" != no ; then
1690         AC_DEFINE(SLAPD_SHELL,1)
1691         BUILD_SLAPD=yes
1692         BUILD_SHELL=yes
1693 fi
1694
1695 if test "$ol_enable_tcl" != no ; then
1696         AC_DEFINE(SLAPD_TCL,1)
1697         BUILD_SLAPD=yes
1698         BUILD_TCL=yes
1699 fi
1700
1701 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1702         $BUILD_SLAPD = yes ; then
1703         BUILD_SLURPD=yes
1704 fi
1705
1706 if test "$ol_link_isode" != no ; then
1707         BUILD_LDAPD=yes
1708 fi
1709
1710 dnl ----------------------------------------------------------------
1711
1712 AC_SUBST(BUILD_LDAPD)
1713 AC_SUBST(BUILD_SLAPD)
1714   AC_SUBST(BUILD_BDB2)
1715   AC_SUBST(BUILD_LDBM)
1716   AC_SUBST(BUILD_PASSWD)
1717   AC_SUBST(BUILD_PERL)
1718   AC_SUBST(BUILD_SHELL)
1719   AC_SUBST(BUILD_TCL)
1720 AC_SUBST(BUILD_SLURPD)
1721
1722 AC_SUBST(LDAP_LIBS)
1723 AC_SUBST(LDAPD_LIBS)
1724 AC_SUBST(SLAPD_LIBS)
1725 AC_SUBST(SLURPD_LIBS)
1726 AC_SUBST(LDBM_LIBS)
1727 AC_SUBST(LTHREAD_LIBS)
1728 AC_SUBST(LUTIL_LIBS)
1729
1730 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1731 AC_SUBST(SLAPD_PERL_LDFLAGS)
1732
1733 AC_SUBST(KRB_LIBS)
1734 AC_SUBST(TERMCAP_LIBS)
1735 AC_SUBST(TLS_LIBS)
1736
1737 dnl ----------------------------------------------------------------
1738 dnl final output
1739 dnl
1740
1741 AC_OUTPUT( \
1742 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1743 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1744 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1745 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1746 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1747 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1748 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1749 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1750 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1751 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1752 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1753 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1754 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1755 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1756 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1757 include/Makefile:build/top.mk:include/Makefile.in \
1758 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1759 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1760 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1761 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1762 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1763 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1764 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1765 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1766 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1767 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1768 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1769 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
1770 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1771 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1772 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
1773 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1774 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
1775 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1776 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1777 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1778 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
1779 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
1780 ,[
1781 date > stamp-h
1782 echo Please \"make depend\" to build dependencies
1783 ])