git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8
   9 dnl Configure.in for OpenLDAP
  10 AC_INIT(include/ldap.h)dnl
  11 AC_CONFIG_AUX_DIR(build)dnl
  12 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no ac_define])dnl
  13
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_PREREQ(2.10)dnl Required Autoconf version
  18
  19 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  20
  21 dnl
  22 dnl Start Args
  23 AC_MSG_CHECKING(configure arguments)
  24 AC_PREFIX_DEFAULT(/usr/local)
  25
  26 top_builddir=`pwd`
  27 AC_SUBST(top_builddir)dnl
  28
  29 ldap_subdir="openldap"
  30
  31 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  32         if test "$withval" = "no"; then
  33                 ldap_subdir=""
  34         elif test "$withval" != "yes"; then
  35                 ldap_subdir="$withval"
  36         fi
  37 ])dnl
  38
  39 AC_SUBST(ldap_subdir)dnl
  40
  41 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  42 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  43 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  44 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  45 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  46 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  47 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  48 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  49 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  50         no, [yes no])dnl
  51
  52 dnl General "with" options
  53 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  54         auto, [auto k5 k4 afs yes no])
  55 OL_ARG_WITH(threads,[  --with-threads   use threads],
  56         auto, [auto posix mach lwp yes no manual] )
  57 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  58         auto, [auto yes no manual] )
  59
  60 dnl Server options
  61
  62 dnl LDAPD OPTIONS
  63 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  64 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  65
  66 dnl SLAPD OPTIONS
  67 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  68 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  69 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  70 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  71 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  72 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  73 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  74 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  75 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  76
  77 dnl SLAPD Backend options
  78 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  79 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  80         [auto db2 db gdbm ndbm manual])
  81 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  82         [auto btree hash])
  83
  84 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  85 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  86
  87 dnl SLURPD OPTIONS
  88 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  89 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  90
  91 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
  92 AM_ENABLE_STATIC
  93 dnl AM_DISABLE_SHARED
  94 AM_ENABLE_SHARED
  95
  96 dnl General "enable" options
  97 # validate options
  98 if test $ol_enable_referrals = no ; then
  99         if test $ol_enable_dns = yes ; then
 100                 AC_MSG_WARN([dns disabled, ignoring --enable-dns argument])
 101         fi
 102         ol_enable_dns=no
 103 fi
 104
 105 if test $ol_enable_slapd = no ; then
 106         dnl SLAPD was specificallly disabled
 107         if test $ol_enable_ldbm = yes ; then
 108                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 109         fi
 110         if test $ol_enable_passwd = yes ; then
 111                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 112         fi
 113         if test $ol_enable_shell = yes ; then
 114                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 115         fi
 116         if test $ol_enable_aclgroups = yes ; then
 117                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 118         fi
 119         if test $ol_enable_crypt = yes ; then
 120                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument])
 121         fi
 122         if test $ol_enable_md5 = yes ; then
 123                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument])
 124         fi
 125         if test $ol_enable_sha1 = yes ; then
 126                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument])
 127         fi
 128         if test $ol_enable_wrappers = yes ; then
 129                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 130         fi
 131         if test $ol_enable_phonetic = yes ; then
 132                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 133         fi
 134         if test $ol_enable_rlookups = yes ; then
 135                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 136         fi
 137         if test $ol_with_ldbm_api != auto ; then
 138                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 139         fi
 140         if test $ol_with_ldbm_type != auto ; then
 141                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 142         fi
 143         if test $ol_enable_slurpd = yes ; then
 144                 AC_MSG_ERROR([slurpd requires slapd])
 145         fi
 146
 147         # force settings to no
 148         ol_enable_ldbm=no
 149         ol_enable_shell=no
 150         ol_enable_passwd=no
 151         ol_enable_aclgroups=no
 152         ol_enable_crypt=no
 153         ol_enable_md5=no
 154         ol_enable_sha1=no
 155         ol_enable_wrappers=no
 156         ol_enable_phonetic=no
 157         ol_enable_rlookups=no
 158         ol_with_ldbm_api=no
 159         ol_with_ldbm_type=no
 160         ol_enable_slurpd=no
 161
 162 elif test $ol_enable_ldbm = no ; then
 163         dnl SLAPD without LDBM
 164
 165         if test $ol_with_ldbm_api != auto ; then
 166                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 167         fi
 168
 169         if test $ol_with_ldbm_type != auto ; then
 170                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 171         fi
 172
 173         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 174                 AC_MSG_ERROR([slapd requires a backend])
 175         fi
 176
 177         ol_with_ldbm_api=no
 178         ol_with_ldbm_type=no
 179
 180 else
 181         dnl SLAPD with LDBM
 182
 183         if test $ol_with_ldbm_api = gdbm -a \
 184                 $ol_with_ldbm_type = btree ; then
 185                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 186         fi
 187         if test $ol_with_ldbm_api = ndbm -a \
 188                 $ol_with_ldbm_type = btree ; then
 189                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 190         fi
 191 fi
 192
 193 if test $ol_enable_slurpd = yes ; then
 194         dnl SLURPD was specifically enabled
 195         if test $ol_with_threads = no ; then
 196                 AC_MSG_ERROR([slurpd requires threads])
 197         fi
 198 fi
 199
 200 AC_MSG_RESULT(done)
 201
 202 AC_CANONICAL_HOST
 203
 204 ## Initialize vars
 205 LDAP_LIBS=
 206 LDBM_LIBS=
 207 LTHREAD_LIBS=
 208 LUTIL_LIBS=
 209
 210 LDAPD_LIBS=
 211 SLAPD_LIBS=
 212 SLURPD_LIBS=
 213
 214 BUILD_LDAPD=no
 215 BUILD_SLAPD=no
 216 BUILD_SLURPD=no
 217
 218 BUILD_LDBM=no
 219 BUILD_PASSWD=no
 220 BUILD_SHELL=no
 221 BUILD_THREAD=no
 222
 223 KRB_LIBS=
 224 TERMCAP_LIBS=
 225
 226 dnl ----------------------------------------------------------------
 227 dnl Checks for programs
 228
 229 AC_PROG_INSTALL
 230 AM_PROG_LIBTOOL
 231 dnl AC_PROG_MAKE_SET
 232
 233 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 234         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 235 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 236 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 237
 238 dnl Checks the compiler and UNIX Variants
 239
 240 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 241         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 242
 243 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 244         AC_MSG_WARN([programs compiled here do run here...])
 245         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 246
 247 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 248         AC_MSG_WARN([programs compiled here do not run here...])
 249         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 250 fi
 251
 252 AC_PROG_CPP
 253
 254 AC_AIX
 255 AC_ISC_POSIX
 256 AC_MINIX
 257
 258 dnl OpenLDAP requires STDC features
 259 AM_PROG_CC_STDC
 260 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 261         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 262 fi
 263
 264 dnl AM_C_PROTOTYPES
 265
 266 dnl Checks for libraries
 267
 268 dnl Find socket()
 269 dnl Likely combinations:
 270 dnl             -lsocket [ -lnsl_s | -lnsl ]
 271 dnl             -linet
 272
 273 AC_CHECK_FUNC(socket, [have_socket=yes], [
 274 dnl
 275 dnl hopefully we won't include too many libraries
 276 dnl
 277         AC_CHECK_LIB(socket, main)
 278         AC_CHECK_LIB(net, main)
 279         AC_CHECK_LIB(nsl_s, main)
 280         AC_CHECK_LIB(nsl, main)
 281         AC_CHECK_LIB(inet, socket)
 282         AC_CHECK_LIB(gen, main)
 283 ])
 284
 285 dnl Check for resolv
 286 AC_CHECK_LIB(resolv, res_search)
 287
 288 dnl HP-UX requires -lV3
 289 AC_CHECK_LIB(V3, sigset)
 290
 291 # ISODE tests
 292 ol_link_isode=no
 293 if test $ol_enable_ldapd != no ; then
 294         dnl look for ISODE libraries
 295         AC_CHECK_LIB(xtpp, main, [
 296                 ol_link_isode=yes
 297                 AC_DEFINE(HAVE_XTPP,1)
 298                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 299                 ],:,[-lxtdsap -lxtisode -losi])
 300         AC_CHECK_LIB(dsap, main, [
 301                 ol_link_isode=yes
 302                 AC_DEFINE(HAVE_DSAP,1)
 303                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 304                 ],:,[-lisode])
 305         AC_CHECK_LIB(isode, main, [
 306                 ol_link_isode=yes
 307                 AC_DEFINE(HAVE_ISODE,1)
 308                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 309                 ],:)
 310 fi
 311
 312 if test $ol_link_isode != no; then
 313         AC_CHECK_LIB(pp, main, [
 314                 AC_DEFINE(HAVE_PP,1)
 315                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 316                 ],:)
 317
 318         AC_PATH_PROG(PEPSY, pepsy)
 319 fi
 320
 321 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 322         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 323
 324         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 325                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 326                         [-lkrb5 -ldes425])
 327
 328                 if test $have_k5 = yes ; then
 329                         ol_with_kerberos=found
 330                         ol_link_kerberos=yes
 331
 332                         AC_DEFINE(HAVE_KERBEROS)
 333
 334                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 335                 fi
 336         fi
 337 fi
 338 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 339         AC_CHECK_HEADERS(krb.h des.h)
 340
 341         if test $ac_cv_header_krb_h = yes ; then
 342                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 343
 344                 if test $have_k4 = yes ; then
 345                         ol_with_kerberos=found
 346                         ol_link_kerberos=yes
 347
 348                         AC_DEFINE(HAVE_KERBEROS)
 349                         KRB_LIBS="-lkrb -ldes"
 350
 351                         AC_CHECK_FUNCS(des_string_to_key)
 352                 fi
 353         fi
 354 fi
 355
 356 ol_link_threads=no
 357 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 358         AC_CHECK_HEADERS(pthread.h sched.h)
 359
 360         if test $ac_cv_header_pthread_h = yes ; then
 361                 OL_POSIX_THREAD_VERSION
 362
 363                 if test $ol_cv_pthread_version = final ; then
 364                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 365                 elif test $ol_cv_pthread_version = draft4 ; then
 366                         AC_DEFINE(HAVE_PTHREADS_D4)
 367                 else
 368                         AC_MSG_ERROR([unknown pthread version])
 369                 fi
 370
 371                 # consider threads found
 372                 ol_with_threads=found
 373
 374                 OL_LINUX_THREADS
 375
 376                 if test $ol_cv_linux_threads = yes ; then
 377                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 378                 fi
 379
 380                 dnl Now the hard part, how to link
 381
 382                 dnl Check for pthread support in current $LIBS
 383                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 384
 385                 if test $ol_link_threads = no ; then
 386                         dnl try -pthread
 387                         AC_CACHE_CHECK([for pthread_create with -pthread],
 388                                 [ol_cv_pthread_flag], [
 389                                 dnl save the flags
 390                                 save_LIBS="$LIBS"
 391                                 LIBS="-pthread $LIBS"
 392                                 AC_TRY_LINK([char pthread();],[
 393                                         pthread_create();
 394                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 395                                 dnl restore the LIBS
 396                                 LIBS="$save_LIBS"
 397                         ])
 398
 399                         if test $ol_cv_pthread_flag = yes ; then
 400                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 401                                 ol_link_threads=posix
 402                         fi
 403                 fi
 404
 405                 if test $ol_link_threads = no ; then
 406                         dnl try -thread
 407                         AC_CACHE_CHECK([for pthread_create with -thread],
 408                                 [ol_cv_thread_flag], [
 409                                 dnl save the flags
 410                                 save_LIBS="$LIBS"
 411                                 LIBS="-thread $LIBS"
 412                                 AC_TRY_LINK([char pthread();],[
 413                                         pthread_create();
 414                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 415                                 dnl restore the LIBS
 416                                 LIBS="$save_LIBS"
 417                         ])
 418
 419                         if test $ol_cv_thread_flag = yes ; then
 420                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 421                                 ol_link_threads=posix
 422                         fi
 423                 fi
 424
 425                 if test $ol_link_threads = no ; then
 426                         dnl try DEC Threads -lpthread -lexc
 427                         save_LIBS="$LIBS"
 428                         AC_CHECK_LIB(pthread, pthread_join, [
 429                                 ol_link_threads=posix
 430                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 431                                 if test $ol_with_yielding_select = auto ; then
 432                                         ol_with_yielding_select=yes
 433                                 fi
 434                                 ],,[-lexc])
 435                         LIBS="$save_LIBS"
 436                 fi
 437
 438                 if test $ol_link_threads = no ; then
 439                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 440                         save_LIBS="$LIBS"
 441                         AC_CHECK_LIB(pthreads, pthread_join, [
 442                                 ol_link_threads=posix
 443                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 444                                 if test $ol_with_yielding_select = auto ; then
 445                                         ol_with_yielding_select=yes
 446                                 fi
 447                                 ],,[-lmach -lexc -lc_r])
 448                         LIBS="$save_LIBS"
 449                 fi
 450
 451                 if test $ol_link_threads = no ; then
 452                         dnl try -lpthread
 453                         save_LIBS="$LIBS"
 454                         AC_CHECK_LIB(pthread, pthread_create, [
 455                                 ol_link_threads=posix
 456                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 457                         LIBS="$save_LIBS"
 458                 fi
 459
 460                 if test $ol_link_threads = no ; then
 461                         dnl try -lc_r
 462                         save_LIBS="$LIBS"
 463                         AC_CHECK_LIB(c_r, pthread_create, [
 464                                 ol_link_threads=posix
 465                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 466                         LIBS="$save_LIBS"
 467                 fi
 468
 469                 if test $ol_link_threads != no ; then
 470                         AC_DEFINE(HAVE_PTHREADS)
 471
 472                         dnl save flags
 473                         save_CPPFLAGS="$CPPFLAGS"
 474                         save_LIBS="$LIBS"
 475                         LIBS="$LTHREAD_LIBS $LIBS"
 476
 477                         dnl All POSIX Thread (final) implementations should have
 478                         dnl sched_yield instead of pthread yield.
 479                         dnl check for both
 480                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 481
 482                         if test $ac_cv_func_sched_yield = no -a \
 483                                 $ac_cv_func_pthread_yield = no ; then
 484                                 dnl Digital UNIX has sched_yield() in -lrt
 485                                 AC_CHECK_LIB(rt, sched_yield,
 486                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 487                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 488                                         ac_cv_func_sched_yield=yes],
 489                                         [ac_cv_func_sched_yield=no])
 490                         fi
 491                         if test $ac_cv_func_sched_yield = no -a \
 492                                 $ac_cv_func_pthread_yield = no ; then
 493                                 dnl Solaris has sched_yield() in -lposix4
 494                                 AC_CHECK_LIB(posix4, sched_yield,
 495                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 496                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 497                                         ac_cv_func_sched_yield=yes],
 498                                         [ac_cv_func_sched_yield=no])
 499                         fi
 500                         if test $ac_cv_func_sched_yield = no -a \
 501                                 $ac_cv_func_pthread_yield = no ; then
 502                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 503                                 AC_MSG_ERROR([POSIX Threads are not usable])
 504                         fi
 505
 506                         dnl Check functions for compatibility
 507                         AC_CHECK_FUNCS(pthread_kill)
 508                         AC_CHECK_FUNCS( \
 509                                 pthread_attr_create pthread_attr_init \
 510                                 pthread_attr_destroy pthread_attr_delete \
 511                                 pthread_attr_setdetachstate pthread_attr_setdetach_np \
 512                         )
 513
 514                         dnl Check for setconcurreny functions
 515                         AC_CHECK_FUNCS( \
 516                                 pthread_setconcurrency \
 517                                 thr_setconcurrency \
 518                         )
 519
 520                         dnl Check if select causes an yield
 521                         if test $ol_with_yielding_select = auto ; then
 522                                 AC_MSG_CHECKING([if select yields])
 523                                 AC_TRY_RUN([
 524 #include <sys/types.h>
 525 #include <sys/time.h>
 526 #include <unistd.h>
 527 #include <pthread.h>
 528 #ifndef NULL
 529 #define NULL 0
 530 #endif
 531
 532 int fildes[2];
 533
 534 int task(arg)
 535         int *arg;
 536 {
 537         int i;
 538         struct timeval tv;
 539
 540         fd_set rfds;
 541
 542         tv.tv_sec=10;
 543         tv.tv_usec=0;
 544
 545         FD_ZERO(&rfds);
 546         FD_SET(fildes[0], &rfds);
 547
 548         /* we're not interested in any fds */
 549         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 550
 551         if(i < 0) {
 552                 perror("select");
 553                 exit(0);
 554         }
 555
 556         exit(1); /* if we exit here, the select blocked the whole process */
 557 }
 558
 559 int main(argc, argv)
 560         int argc;
 561         char **argv;
 562 {
 563         pthread_t t;
 564
 565         /* create a pipe to select */
 566         if(pipe(&fildes[0])) {
 567                 perror("select");
 568                 exit(0);
 569         }
 570
 571 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 572         (void) pthread_setconcurrency(2);
 573 #else
 574 #ifdef HAVE_THR_SETCONCURRENCY
 575         /* Set Solaris LWP concurrency to 2 */
 576         thr_setconcurrency(2);
 577 #endif
 578 #endif
 579
 580         pthread_create(&t, NULL, (void *) task, NULL);
 581
 582 #if HAVE_SCHED_YIELD
 583         sched_yield();  /* make sure task runs first */
 584 #else
 585 #ifdef HAVE_PTHREAD_YIELD
 586         pthread_yield();        /* make sure task runs first */
 587 #endif
 588 #endif
 589         exit(0);
 590 }
 591                                 ], [ol_pthread_select_yields=yes], [ol_pthread_select_yields=no], [
 592                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])
 593                                 AC_MSG_RESULT($ol_pthread_select_yields)
 594
 595                                 if test $ol_pthread_select_yields = yes ; then
 596                                         ol_with_yielding_select=yes
 597                                 fi
 598                         fi
 599
 600 dnl                     dnl check for reentrant/threadsafe functions
 601 dnl                     AC_CHECK_FUNCS( \
 602 dnl                             feof_unlocked \
 603 dnl                             unlocked_feof \
 604 dnl                             ftrylockfile \
 605 dnl                             flockfile \
 606 dnl                             putc_unlocked \
 607 dnl                             gmtime_r \
 608 dnl                             strtok_r \
 609 dnl                     )
 610
 611                         dnl restore flags
 612                         CPPFLAGS="$save_CPPFLAGS"
 613                         LIBS="$save_LIBS"
 614                 else
 615                         AC_MSG_ERROR([could not link with POSIX Threads])
 616                 fi
 617         fi
 618
 619         if test $ol_with_threads = posix ; then
 620                 AC_MSG_ERROR([could not locate POSIX Threads])
 621         fi
 622 fi
 623
 624 if test $ol_with_threads = auto -o $ol_with_threads = mach ; then
 625         dnl check for Mach CThreads
 626         AC_CHECK_HEADERS(mach/cthreads.h)
 627         if test $ac_cv_header_mach_cthreads_h = yes ; then
 628                 ol_with_threads=found
 629
 630                 dnl check for cthread support in current $LIBS
 631                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 632
 633                 if test $ol_link_threads = no ; then
 634                         dnl try -all_load
 635                         dnl this test needs work
 636                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 637                                 [ol_cv_cthread_all_load], [
 638                                 dnl save the flags
 639                                 save_LIBS="$LIBS"
 640                                 LIBS="-all_load $LIBS"
 641                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 642                                         cthread_fork((void *)0, (void *)0);
 643                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 644                                 dnl restore the LIBS
 645                                 LIBS="$save_LIBS"
 646                         ])
 647
 648                         if test $ol_cv_cthread_all_load = yes ; then
 649                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 650                                 ol_link_threads=mach
 651                         fi
 652                 fi
 653
 654                 if test $ol_link_threads != no ; then
 655                         : check for cthread specific functionality here
 656                         AC_DEFINE(HAVE_MACH_CTHREADS,1)
 657                 else
 658                         AC_MSG_ERROR([could not link with Mach CThreads])
 659                 fi
 660         fi
 661
 662         if test $ol_with_threads = mach ; then
 663                 AC_MSG_ERROR([could not locate Mach CThreads])
 664         fi
 665 fi
 666
 667 if test $ol_with_threads = auto -o $ol_with_threads = lwp ; then
 668         dnl check for SunOS5 LWP
 669         AC_CHECK_HEADERS(thread.h synch.h)
 670         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 671                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
 672
 673                 if test $have_thr = yes ; then
 674                         AC_DEFINE(HAVE_THR)
 675                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
 676                         ol_link_threads=thr
 677
 678                         if test $ol_with_yielding_select = auto ; then
 679                                 ol_with_yielding_select=yes
 680                         fi
 681                 fi
 682         fi
 683
 684         dnl check for SunOS4 LWP
 685         AC_CHECK_HEADERS(lwp/lwp.h)
 686         if test $ac_cv_header_lwp_lwp_h = yes ; then
 687                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 688
 689                 if test $have_lwp = yes ; then
 690                         AC_DEFINE(HAVE_LWP)
 691                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 692                         ol_link_threads=lwp
 693
 694                         if test $ol_with_yielding_select = auto ; then
 695                                 ol_with_yielding_select=no
 696                         fi
 697                 fi
 698         fi
 699 fi
 700
 701 if test $ol_with_yielding_select = yes ; then
 702         AC_DEFINE(HAVE_YIELDING_SELECT,1)
 703 fi
 704
 705 if test $ol_with_threads = manual ; then
 706         dnl User thinks he can manually configure threads.
 707         ol_link_threads=yes
 708
 709         AC_MSG_WARN([thread defines and link options must be set manually])
 710
 711         AC_CHECK_HEADERS(pthread.h sched.h)
 712         AC_CHECK_FUNCS(sched_yield pthread_yield)
 713         OL_LINUX_THREADS
 714
 715         AC_CHECK_HEADERS(mach/cthreads.h)
 716         AC_CHECK_HEADERS(lwp/lwp.h)
 717         AC_CHECK_HEADERS(thread.h synch.h)
 718 fi
 719
 720 if test $ol_with_threads != no ; then
 721         dnl needed to get reentrant/threadsafe versions
 722         dnl
 723         AC_DEFINE(_REENTRANT,1)
 724         AC_DEFINE(_THREAD_SAFE,1)
 725         AC_DEFINE(_THREADSAFE,1)
 726
 727         dnl this might cause the errno symbol to be
 728         dnl replaced with a function to get a thread specific errno.
 729         dnl check to see if everything needs to be compiled
 730         dnl with the thread libraries
 731         AC_CACHE_CHECK([for thread specific errno],
 732                 [ol_cv_errno_thread_specific], [
 733                 AC_TRY_LINK([
 734 #include <errno.h>
 735                         ], [
 736 int x = errno;
 737                         ],
 738                         [ol_cv_errno_thread_specific=yes],
 739                         [ol_cv_errno_thread_specific=no])
 740         ])
 741
 742         if test $ol_cv_errno_thread_specific != yes ; then
 743                 LIBS="$LTHREAD_LIBS $LIBS"
 744                 LTHREAD_LIBS=""
 745         fi
 746 fi
 747
 748 dnl ----------------------------------------------------------------
 749
 750 if test $ol_link_threads = no ; then
 751         if test $ol_with_threads = yes ; then
 752                 AC_MSG_ERROR([no suitable thread support])
 753         fi
 754
 755         if test $ol_with_threads = auto ; then
 756                 AC_MSG_WARN([no suitable thread support, disabling threads])
 757                 ol_with_threads=no
 758         fi
 759
 760         AC_DEFINE(NO_THREADS,1)
 761         LTHREAD_LIBS=""
 762 fi
 763
 764 ol_link_ldbm=no
 765 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 766         OL_BERKELEY_DB2
 767
 768         if test $ol_cv_berkeley_db2 = yes ; then
 769                 ol_link_ldbm=db2
 770                 ol_with_ldbm_api=db2
 771
 772                 if test $ol_with_ldbm_type = hash ; then
 773                         AC_DEFINE(LDBM_USE_DBHASH,1)
 774                 else
 775                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 776                 fi
 777
 778                 dnl $ol_cv_lib_db2 should be yes or -ldb
 779                 dnl (it could be no, but that would be an error
 780                 if test $ol_cv_lib_db2 != yes ; then
 781                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 782                 fi
 783         fi
 784 fi
 785
 786 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 787         OL_BERKELEY_DB
 788
 789         if test $ol_cv_berkeley_db = yes ; then
 790                 ol_link_ldbm=db
 791                 ol_with_ldbm_api=db
 792
 793                 if test $ol_with_ldbm_type = hash ; then
 794                         AC_DEFINE(LDBM_USE_DBHASH,1)
 795                 else
 796                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 797                 fi
 798
 799                 dnl $ol_cv_lib_db should be yes or -ldb
 800                 dnl (it could be no, but that would be an error
 801                 if test $ol_cv_lib_db != yes ; then
 802                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 803                 fi
 804         fi
 805 fi
 806
 807 if test $ol_with_ldbm_api = manual ; then
 808         dnl User thinks he can manually configure LDBM api.
 809         ol_link_ldbm=yes
 810
 811         AC_MSG_WARN([LDBM defines and link options must be set manually])
 812
 813         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 814 fi
 815
 816 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 817         AC_MSG_WARN(Could not find LDBM with BTREE support)
 818         ol_with_ldbm_api=none
 819 fi
 820
 821 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 822         OL_GDBM
 823
 824         if test $ol_cv_gdbm = yes ; then
 825                 ol_link_ldbm=gdbm
 826                 ol_with_ldbm_api=gdbm
 827
 828                 if test $ol_cv_lib_gdbm != yes ; then
 829                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 830                 fi
 831         fi
 832 fi
 833
 834 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 835         OL_NDBM
 836
 837         if test $ol_cv_ndbm = yes ; then
 838                 if test $ol_with_ldbm_api = auto ; then
 839                         AC_MSG_WARN([Attempting to use NDBM.  Functionality will be limited.])
 840                 fi
 841
 842                 ol_link_ldbm=ndbm
 843                 ol_with_ldbm_api=ndbm
 844
 845                 if test $ol_cv_lib_ndbm != yes ; then
 846                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 847                 fi
 848         fi
 849 fi
 850
 851 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 852         AC_MSG_WARN(could not find suitable LDBM backend)
 853         if test $ol_enable_ldbm = yes ; then
 854                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 855         fi
 856
 857         AC_MSG_WARN(disabling LDBM)
 858         ol_enable_ldbm=no
 859 fi
 860
 861 if test $ol_enable_wrappers = yes ; then
 862         AC_CHECK_LIB(wrap, hosts_access,
 863                 [have_wrappers=yes], [have_wrappers=no])
 864
 865         if test $have_wrappers = yes ; then
 866                 AC_DEFINE(HAVE_TCPD)
 867                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 868         else
 869                 AC_MSG_WARN(could not find -lwrap)
 870                 if test $ol_enable_wrappers = yes ; then
 871                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 872                 fi
 873
 874                 AC_MSG_WARN(disabling wrappers support)
 875                 ol_enable_wrappers=no
 876         fi
 877
 878 fi
 879
 880 # ud needs termcap (should insert check here)
 881 ol_link_termcap=no
 882 AC_CHECK_HEADERS(termcap.h ncurses.h)
 883
 884 if test $ol_link_termcap = no ; then
 885         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 886         if test $have_termcap = yes ; then
 887                 AC_DEFINE(HAVE_TERMCAP)
 888                 ol_link_termcap=yes
 889                 TERMCAP_LIBS=-ltermcap
 890         fi
 891 fi
 892
 893 if test $ol_link_termcap = no ; then
 894         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 895         if test $have_ncurses = yes ; then
 896                 AC_DEFINE(HAVE_NCURSES)
 897                 ol_link_termcap=yes
 898                 TERMCAP_LIBS=-lncurses
 899         fi
 900 fi
 901
 902 if test $ol_link_termcap = no ; then
 903         AC_DEFINE(NO_TERMCAP,1)
 904         TERMCAP_LIBS=
 905 fi
 906
 907 # FreeBSD (and others) have crypt(3) in -lcrypt
 908 if test $ol_enable_crypt != no ; then
 909         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 910                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 911                         have_crypt=yes], [have_crypt=no])])
 912
 913         if test $have_crypt = yes ; then
 914                 AC_DEFINE(HAVE_CRYPT,1)
 915         else
 916                 AC_MSG_WARN(could not find crypt)
 917                 if test $ol_enable_crypt = yes ; then
 918                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 919                 fi
 920
 921                 AC_MSG_WARN(disabling crypt support)
 922                 ol_enable_crypt=no
 923         fi
 924 fi
 925
 926 # FreeBSD (and others) have setproctitle(3) in -lutil
 927 if test $ol_enable_proctitle != no ; then
 928         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 929                 AC_CHECK_LIB(util, setproctitle,
 930                         [have_setproctitle=yes
 931                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 932                         [have_setproctitle=no
 933                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 934
 935         if test $have_setproctitle = yes ; then
 936                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 937         fi
 938 fi
 939
 940 dnl ----------------------------------------------------------------
 941 dnl Checks for header files.
 942 AC_HEADER_STDC
 943
 944 if test $ac_cv_header_stdc != yes; then
 945         AC_MSG_WARN([could not Standard C compliant headers])
 946 fi
 947
 948 AC_HEADER_DIRENT
 949 AC_HEADER_SYS_WAIT
 950 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 951 if test $am_cv_sys_posix_termios = yes ; then
 952         AC_DEFINE(HAVE_POSIX_TERMIOS,1)
 953 fi
 954
 955 AC_CHECK_HEADERS(       \
 956         crypt.h                 \
 957         errno.h                 \
 958         fcntl.h                 \
 959         filio.h                 \
 960         getopt.h                \
 961         libutil.h               \
 962         limits.h                \
 963         malloc.h                \
 964         memory.h                \
 965         regex.h                 \
 966         psap.h                  \
 967         pwd.h                   \
 968         sgtty.h                 \
 969         stdarg.h                \
 970         stddef.h                \
 971         string.h                \
 972         strings.h               \
 973         sys/file.h              \
 974         sys/filio.h             \
 975         sys/errno.h             \
 976         sys/ioctl.h             \
 977         sys/param.h             \
 978         sys/resource.h  \
 979         sys/socket.h    \
 980         sys/syslog.h    \
 981         sys/time.h              \
 982         sys/types.h             \
 983         syslog.h                \
 984         termios.h               \
 985         unistd.h                \
 986 )
 987
 988 dnl ----------------------------------------------------------------
 989 dnl Checks for typedefs, structures, and compiler characteristics.
 990 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
 991 AC_TYPE_MODE_T
 992 AC_TYPE_OFF_T
 993 AC_TYPE_PID_T
 994 AM_TYPE_PTRDIFF_T
 995 AC_TYPE_SIGNAL
 996 AC_TYPE_SIZE_T
 997 AC_STRUCT_ST_BLKSIZE
 998 AC_HEADER_TIME
 999 AC_STRUCT_TM
1000
1001 OL_C_UPPER_LOWER
1002 AC_C_CONST
1003
1004 if test $cross_compiling = yes ; then
1005         AC_DEFINE(CROSS_COMPILING, 1)
1006 else
1007         AC_C_BIGENDIAN
1008         AC_CHECK_SIZEOF(short)
1009         AC_CHECK_SIZEOF(int)
1010         AC_CHECK_SIZEOF(long)
1011 fi
1012
1013 dnl ----------------------------------------------------------------
1014 dnl Checks for library functions.
1015 AC_FUNC_MEMCMP
1016 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1017 AC_FUNC_STRFTIME
1018 dnl AM_FUNC_STRTOD
1019 AC_FUNC_VPRINTF
1020
1021 if test $ac_cv_func_vprintf = yes ; then
1022         dnl check for vsnprintf
1023         AC_CHECK_FUNCS(vsnprintf)
1024 fi
1025
1026 AC_FUNC_WAIT3
1027
1028 AC_CHECK_FUNCS(         \
1029         bcopy                   \
1030         flock                   \
1031         getdtablesize   \
1032         gethostname             \
1033         getpwuid                \
1034         gettimeofday    \
1035         lockf                   \
1036         memcpy                  \
1037         memmove                 \
1038         mkstemp                 \
1039         res_search              \
1040         select                  \
1041         setpwfile               \
1042         setsid                  \
1043         signal                  \
1044         sigset                  \
1045         snprintf                \
1046         socket                  \
1047         strerror                \
1048         strpbrk                 \
1049         strrchr                 \
1050         strsep                  \
1051         strstr                  \
1052         strtok                  \
1053         strtol                  \
1054         strtoul                 \
1055         sysconf                 \
1056         waitpid                 \
1057 )
1058
1059 dnl We actually may need to replace more than this.
1060 AC_REPLACE_FUNCS(getopt strdup tempnam)
1061
1062 dnl ----------------------------------------------------------------
1063 # Check Configuration
1064 OL_SYS_ERRLIST
1065
1066 dnl ----------------------------------------------------------------
1067 dnl Sort out defines
1068
1069 if test $ol_enable_debug != no ; then
1070         AC_DEFINE(LDAP_DEBUG,1)
1071 fi
1072 dnl     if test $ol_enable_syslog != no ; then
1073 dnl             AC_DEFINE(LDAP_SYSLOG,1)
1074 dnl     fi
1075 if test $ol_enable_libui = yes ; then
1076         AC_DEFINE(LDAP_LIBUI,1)
1077 fi
1078 if test $ol_enable_cache = no ; then
1079         AC_DEFINE(LDAP_NOCACHE,1)
1080 fi
1081 if test $ol_enable_dns != no ; then
1082         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_API_VENDOR_VERSION,1)
1083 fi
1084 if test $ol_enable_proctitle != no ; then
1085         AC_DEFINE(LDAP_PROCTITLE,1)
1086 fi
1087 if test $ol_enable_referrals != no ; then
1088         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_API_VENDOR_VERSION,1)
1089 fi
1090 if test $ol_enable_cldap != no ; then
1091         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1092 fi
1093
1094 if test $ol_enable_aclgroups != no ; then
1095         AC_DEFINE(SLAPD_ACLGROUPS,1)
1096 fi
1097 if test $ol_enable_crypt != no ; then
1098         AC_DEFINE(SLAPD_CRYPT,1)
1099 fi
1100 if test $ol_enable_md5 != no ; then
1101         AC_DEFINE(SLAPD_MD5,1)
1102 fi
1103 if test $ol_enable_sha1 != no ; then
1104         AC_DEFINE(SLAPD_SHA1,1)
1105 fi
1106 if test $ol_enable_phonetic != no ; then
1107         AC_DEFINE(SLAPD_PHONETIC,1)
1108 fi
1109 if test $ol_enable_rlookups != no ; then
1110         AC_DEFINE(SLAPD_RLOOKUPS,1)
1111 fi
1112
1113 if test $ol_link_ldbm != no ; then
1114         AC_DEFINE(SLAPD_LDBM,1)
1115         BUILD_SLAPD=yes
1116         BUILD_LDBM=yes
1117 fi
1118
1119 if test $ol_enable_passwd != no ; then
1120         AC_DEFINE(SLAPD_PASSWD,1)
1121         BUILD_SLAPD=yes
1122         BUILD_PASSWD=yes
1123 fi
1124
1125 if test $ol_enable_shell != no ; then
1126         AC_DEFINE(SLAPD_SHELL,1)
1127         BUILD_SLAPD=yes
1128         BUILD_SHELL=yes
1129 fi
1130
1131 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
1132         $BUILD_SLAPD = yes ; then
1133         BUILD_SLURPD=yes
1134 fi
1135
1136 if test $ol_link_isode != no ; then
1137         BUILD_LDAPD=yes
1138 fi
1139
1140 dnl ----------------------------------------------------------------
1141
1142 AC_SUBST(BUILD_LDAPD)
1143 AC_SUBST(BUILD_SLAPD)
1144   AC_SUBST(BUILD_LDBM)
1145   AC_SUBST(BUILD_PASSWD)
1146   AC_SUBST(BUILD_SHELL)
1147 AC_SUBST(BUILD_SLURPD)
1148
1149
1150 AC_SUBST(LDAP_LIBS)
1151 AC_SUBST(LDAPD_LIBS)
1152 AC_SUBST(SLAPD_LIBS)
1153 AC_SUBST(SLURPD_LIBS)
1154 AC_SUBST(LDBM_LIBS)
1155 AC_SUBST(LTHREAD_LIBS)
1156 AC_SUBST(LUTIL_LIBS)
1157
1158 AC_SUBST(KRB_LIBS)
1159 AC_SUBST(TERMCAP_LIBS)
1160
1161 dnl ----------------------------------------------------------------
1162 dnl final output
1163 dnl
1164
1165 AC_OUTPUT( \
1166 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1167 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1168 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1169 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1170 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1171 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1172 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1173 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1174 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1175 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1176 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1177 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1178 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1179 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1180 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1181 include/Makefile:build/top.mk:include/Makefile.in \
1182 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1183 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1184 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1185 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1186 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1187 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1188 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk:build/lib-static.mk    \
1189 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1190 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1191 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1192 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1193 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1194 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1195 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1196 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1197 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1198 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1199 tests/Makefile:build/top.mk:tests/Makefile.in \
1200 ,[
1201 date > stamp-h
1202 echo Please \"make depend\" to build dependencies
1203 ])