git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Configure.in for OpenLDAP
  11 AC_INIT(include/ldap.h)dnl
  12 AC_CONFIG_AUX_DIR(build)dnl
  13 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no ac_define])dnl
  14
  15 dnl Do not use AutoConf 2.12; it produces a configuration script
  16 dnl that causes an "internal 2K buffer" error on HPUX when run
  17 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  18 AC_PREREQ(2.10)dnl Required Autoconf version
  19
  20 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  21
  22 dnl
  23 dnl Start Args
  24 AC_MSG_CHECKING(configure arguments)
  25 AC_PREFIX_DEFAULT(/usr/local)
  26
  27 top_builddir=`pwd`
  28 AC_SUBST(top_builddir)dnl
  29
  30 ldap_subdir="openldap"
  31
  32 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  33         if test "$withval" = "no"; then
  34                 ldap_subdir=""
  35         elif test "$withval" != "yes"; then
  36                 ldap_subdir="$withval"
  37         fi
  38 ])dnl
  39
  40 AC_SUBST(ldap_subdir)dnl
  41
  42 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  43 ol_enable_syslog=no
  44 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  45 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  46 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  47 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  48 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  49 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  50 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  51         no, [yes no])dnl
  52
  53
  54 dnl General "with" options
  55 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  56
  57 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  58         auto, [auto k5 k4 afs yes no])
  59 OL_ARG_WITH(threads,[  --with-threads   use threads],
  60         auto, [auto posix mach lwp yes no manual] )
  61 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  62         auto, [auto yes no manual] )
  63
  64 dnl Server options
  65
  66 dnl LDAPD OPTIONS
  67 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  68 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  69
  70 dnl SLAPD OPTIONS
  71 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  72 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  73 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  74 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  75 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  76 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  77 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  78 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  79
  80 dnl SLAPD Backend options
  81 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  82 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  83         [auto db2 db gdbm ndbm manual])
  84 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  85         [auto btree hash])
  86
  87 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  88 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  89
  90 dnl SLURPD OPTIONS
  91 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  92 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  93
  94 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
  95 AM_ENABLE_STATIC
  96 dnl AM_DISABLE_SHARED
  97 AM_ENABLE_SHARED
  98
  99 dnl General "enable" options
 100 # validate options
 101 if test $ol_enable_referrals = no ; then
 102         if test $ol_enable_dns = yes ; then
 103                 AC_MSG_WARN([dns disabled, ignoring --enable-dns argument])
 104         fi
 105         ol_enable_dns=no
 106 fi
 107
 108 if test $ol_enable_slapd = no ; then
 109         dnl SLAPD was specificallly disabled
 110         if test $ol_enable_ldbm = yes ; then
 111                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 112         fi
 113         if test $ol_enable_passwd = yes ; then
 114                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 115         fi
 116         if test $ol_enable_shell = yes ; then
 117                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 118         fi
 119         if test $ol_enable_aclgroups = yes ; then
 120                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 121         fi
 122         if test $ol_enable_wrappers = yes ; then
 123                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 124         fi
 125         if test $ol_enable_phonetic = yes ; then
 126                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 127         fi
 128         if test $ol_enable_rlookups = yes ; then
 129                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 130         fi
 131         if test $ol_with_ldbm_api != auto ; then
 132                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 133         fi
 134         if test $ol_with_ldbm_type != auto ; then
 135                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 136         fi
 137         if test $ol_enable_slurpd = yes ; then
 138                 AC_MSG_ERROR([slurpd requires slapd])
 139         fi
 140
 141         # force settings to no
 142         ol_enable_ldbm=no
 143         ol_enable_shell=no
 144         ol_enable_passwd=no
 145         ol_enable_aclgroups=no
 146         ol_enable_wrappers=no
 147         ol_enable_phonetic=no
 148         ol_enable_rlookups=no
 149         ol_with_ldbm_api=no
 150         ol_with_ldbm_type=no
 151         ol_enable_slurpd=no
 152
 153 elif test $ol_enable_ldbm = no ; then
 154         dnl SLAPD without LDBM
 155
 156         if test $ol_with_ldbm_api != auto ; then
 157                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 158         fi
 159
 160         if test $ol_with_ldbm_type != auto ; then
 161                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 162         fi
 163
 164         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 165                 AC_MSG_ERROR([slapd requires a backend])
 166         fi
 167
 168         ol_with_ldbm_api=no
 169         ol_with_ldbm_type=no
 170
 171 else
 172         dnl SLAPD with LDBM
 173
 174         if test $ol_with_ldbm_api = gdbm -a \
 175                 $ol_with_ldbm_type = btree ; then
 176                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 177         fi
 178         if test $ol_with_ldbm_api = ndbm -a \
 179                 $ol_with_ldbm_type = btree ; then
 180                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 181         fi
 182 fi
 183
 184 if test $ol_enable_slurpd = yes ; then
 185         dnl SLURPD was specifically enabled
 186         if test $ol_with_threads = no ; then
 187                 AC_MSG_ERROR([slurpd requires threads])
 188         fi
 189 fi
 190
 191 AC_MSG_RESULT(done)
 192
 193 AC_CANONICAL_HOST
 194
 195 ## Initialize vars
 196 LDAP_LIBS=
 197 LDBM_LIBS=
 198 LTHREAD_LIBS=
 199 LUTIL_LIBS=
 200
 201 LDAPD_LIBS=
 202 SLAPD_LIBS=
 203 SLURPD_LIBS=
 204
 205 BUILD_LDAPD=no
 206 BUILD_SLAPD=no
 207 BUILD_SLURPD=no
 208
 209 BUILD_LDBM=no
 210 BUILD_PASSWD=no
 211 BUILD_SHELL=no
 212 BUILD_THREAD=no
 213
 214 KRB_LIBS=
 215 TERMCAP_LIBS=
 216
 217 dnl ----------------------------------------------------------------
 218 dnl Checks for programs
 219
 220 AC_PROG_INSTALL
 221 AM_PROG_LIBTOOL
 222 dnl AC_PROG_MAKE_SET
 223
 224 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 225         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 226 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 227 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 228
 229 dnl Checks the compiler and UNIX Variants
 230
 231 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 232         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 233
 234 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 235         AC_MSG_WARN([programs compiled here do run here...])
 236         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 237
 238 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 239         AC_MSG_WARN([programs compiled here do not run here...])
 240         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 241 fi
 242
 243 AC_PROG_CPP
 244
 245 AC_AIX
 246 AC_ISC_POSIX
 247 AC_MINIX
 248
 249 dnl OpenLDAP requires STDC features
 250 AM_PROG_CC_STDC
 251 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 252         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 253 fi
 254
 255 dnl AM_C_PROTOTYPES
 256
 257 dnl Checks for libraries
 258
 259 dnl Find socket()
 260 dnl Likely combinations:
 261 dnl             -lsocket [ -lnsl_s | -lnsl ]
 262 dnl             -linet
 263
 264 AC_CHECK_FUNC(socket, [have_socket=yes], [
 265 dnl
 266 dnl hopefully we won't include too many libraries
 267 dnl
 268         AC_CHECK_LIB(socket, main)
 269         AC_CHECK_LIB(net, main)
 270         AC_CHECK_LIB(nsl_s, main)
 271         AC_CHECK_LIB(nsl, main)
 272         AC_CHECK_LIB(inet, socket)
 273         AC_CHECK_LIB(gen, main)
 274 ])
 275
 276 dnl Check for resolver routines
 277 AC_CHECK_LIB(bind, res_search)
 278 AC_CHECK_LIB(resolv, res_search)
 279
 280 dnl HP-UX requires -lV3
 281 AC_CHECK_LIB(V3, sigset)
 282
 283 # ISODE tests
 284 ol_link_isode=no
 285 if test $ol_enable_ldapd != no ; then
 286         dnl look for ISODE libraries
 287         AC_CHECK_LIB(xtpp, main, [
 288                 ol_link_isode=yes
 289                 AC_DEFINE(HAVE_XTPP,1)
 290                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 291                 ],:,[-lxtdsap -lxtisode -losi])
 292         AC_CHECK_LIB(dsap, main, [
 293                 ol_link_isode=yes
 294                 AC_DEFINE(HAVE_DSAP,1)
 295                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 296                 ],:,[-lisode])
 297         AC_CHECK_LIB(isode, main, [
 298                 ol_link_isode=yes
 299                 AC_DEFINE(HAVE_ISODE,1)
 300                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 301                 ],:)
 302 fi
 303
 304 if test $ol_link_isode != no; then
 305         AC_CHECK_LIB(pp, main, [
 306                 AC_DEFINE(HAVE_PP,1)
 307                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 308                 ],:)
 309
 310         AC_PATH_PROG(PEPSY, pepsy)
 311 fi
 312
 313 dnl
 314 dnl check for kerberos
 315 dnl
 316 ol_link_kerberos=no
 317
 318 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 319         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 320
 321         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 322                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 323                         [-lkrb5 -ldes425])
 324
 325                 if test $have_k5 = yes ; then
 326                         ol_with_kerberos=found
 327                         ol_link_kerberos=yes
 328
 329                         AC_DEFINE(HAVE_KERBEROS)
 330                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 331                 fi
 332         fi
 333 fi
 334
 335 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 336         AC_CHECK_HEADERS(krb.h des.h)
 337
 338         if test $ac_cv_header_krb_h = yes ; then
 339                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 340
 341                 if test $have_k4 = yes ; then
 342                         ol_with_kerberos=found
 343                         ol_link_kerberos=yes
 344
 345                         AC_DEFINE(HAVE_KERBEROS)
 346                         KRB_LIBS="-lkrb -ldes"
 347                 fi
 348         fi
 349 fi
 350
 351 dnl     if test $ol_link_kerberos = yes ; then
 352 dnl             save_LIBS=$LIBS
 353 dnl             LIBS="$KRB_LIBS $LIBS"
 354 dnl             AC_CHECK_FUNCS(des_string_to_key)
 355 dnl             LIBS=$save_LIBS
 356 dnl fi
 357
 358 ol_link_threads=no
 359 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 360         -o $ol_with_threads = posix ; then
 361
 362         AC_CHECK_HEADERS(pthread.h sched.h)
 363
 364         if test $ac_cv_header_pthread_h = yes ; then
 365                 OL_POSIX_THREAD_VERSION
 366
 367                 if test $ol_cv_pthread_version = final ; then
 368                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 369                 elif test $ol_cv_pthread_version = draft4 ; then
 370                         AC_DEFINE(HAVE_PTHREADS_D4)
 371                 else
 372                         AC_MSG_ERROR([unknown pthread version])
 373                 fi
 374
 375                 # consider threads found
 376                 ol_with_threads=found
 377
 378                 OL_LINUX_THREADS
 379
 380                 if test $ol_cv_linux_threads = yes ; then
 381                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 382                 fi
 383
 384                 dnl Now the hard part, how to link
 385
 386                 dnl Check for pthread support in current $LIBS
 387                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 388
 389                 if test $ol_link_threads = no ; then
 390                         dnl try -pthread
 391                         AC_CACHE_CHECK([for pthread_create with -pthread],
 392                                 [ol_cv_pthread_flag], [
 393                                 dnl save the flags
 394                                 save_LIBS="$LIBS"
 395                                 LIBS="-pthread $LIBS"
 396                                 AC_TRY_LINK([char pthread();],[
 397                                         pthread_create();
 398                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 399                                 dnl restore the LIBS
 400                                 LIBS="$save_LIBS"
 401                         ])
 402
 403                         if test $ol_cv_pthread_flag = yes ; then
 404                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 405                                 ol_link_threads=posix
 406                         fi
 407                 fi
 408
 409                 if test $ol_link_threads = no ; then
 410                         dnl try -pthreads
 411                         AC_CACHE_CHECK([for pthread_create with -pthreads],
 412                                 [ol_cv_pthreads_flag], [
 413                                 dnl save the flags
 414                                 save_LIBS="$LIBS"
 415                                 LIBS="-pthreads $LIBS"
 416                                 AC_TRY_LINK([char pthread();],[
 417                                         pthread_create();
 418                                         ], ol_cv_pthreads_flag=yes, ol_cv_pthreads_flag=no)
 419                                 dnl restore the LIBS
 420                                 LIBS="$save_LIBS"
 421                         ])
 422
 423                         if test $ol_cv_pthreads_flag = yes ; then
 424                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthreads"
 425                                 ol_link_threads=posix
 426                         fi
 427                 fi
 428
 429                 if test $ol_link_threads = no ; then
 430                         dnl try -thread
 431                         AC_CACHE_CHECK([for pthread_create with -thread],
 432                                 [ol_cv_thread_flag], [
 433                                 dnl save the flags
 434                                 save_LIBS="$LIBS"
 435                                 LIBS="-thread $LIBS"
 436                                 AC_TRY_LINK([char pthread();],[
 437                                         pthread_create();
 438                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 439                                 dnl restore the LIBS
 440                                 LIBS="$save_LIBS"
 441                         ])
 442
 443                         if test $ol_cv_thread_flag = yes ; then
 444                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 445                                 ol_link_threads=posix
 446                         fi
 447                 fi
 448
 449                 if test $ol_link_threads = no ; then
 450                         dnl try DEC Threads -lpthread -lexc
 451                         save_LIBS="$LIBS"
 452                         AC_CHECK_LIB(pthread, pthread_mutex_lock, [
 453                                 ol_link_threads=posix
 454                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 455                                 if test $ol_with_yielding_select = auto ; then
 456                                         ol_with_yielding_select=yes
 457                                 fi
 458                                 ],,[-lexc])
 459                         LIBS="$save_LIBS"
 460                 fi
 461
 462                 if test $ol_link_threads = no ; then
 463                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 464                         save_LIBS="$LIBS"
 465                         AC_CHECK_LIB(pthreads, pthread_mutex_unlock, [
 466                                 ol_link_threads=posix
 467                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 468                                 if test $ol_with_yielding_select = auto ; then
 469                                         ol_with_yielding_select=yes
 470                                 fi
 471                                 ],,[-lmach -lexc -lc_r])
 472                         LIBS="$save_LIBS"
 473                 fi
 474
 475                 if test $ol_link_threads = no ; then
 476                         dnl try -lpthread
 477                         save_LIBS="$LIBS"
 478                         AC_CHECK_LIB(pthread, pthread_create, [
 479                                 ol_link_threads=posix
 480                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 481                         LIBS="$save_LIBS"
 482                 fi
 483
 484                 if test $ol_link_threads = no ; then
 485                         dnl try -lc_r
 486                         save_LIBS="$LIBS"
 487                         AC_CHECK_LIB(c_r, pthread_create, [
 488                                 ol_link_threads=posix
 489                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 490                         LIBS="$save_LIBS"
 491                 fi
 492
 493                 if test $ol_link_threads = no ; then
 494                         dnl try -lpthreads
 495                         save_LIBS="$LIBS"
 496                         AC_CHECK_LIB(pthreads, pthread_create, [
 497                                 ol_link_threads=posix
 498                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"])
 499                         LIBS="$save_LIBS"
 500                 fi
 501
 502                 dnl IRIX Pthread check
 503                 if test $ol_link_threads = no ; then
 504                         dnl try IRIX Pthreads -Wl,-woff,85 -lpthreads
 505                         save_LIBS="$LIBS"
 506                         AC_CHECK_LIB(pthreads, pthread_join, [
 507                                 ol_link_threads=posix
 508                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"
 509                                 ],[-Wl,-woff,85])
 510                         LIBS="$save_LIBS"
 511                 fi
 512
 513                 dnl HP-UX 11 Pthread check
 514                 if test $ol_link_threads = no; then
 515                         save_LIBS="$LIBS"
 516                         LIBS="$LIBS -lpthread"
 517                         AC_MSG_CHECKING([for pthread_create() in HP-UX -lpthread])
 518                         ol_try_pthread_hpux_11=no
 519                         AC_CACHE_VAL(ol_cv_pthread_hpux_11,[
 520                                 AC_TRY_LINK([
 521 #include <pthread.h>
 522 #include <elf.h>
 523 #ifndef ELFABI_HPUX_REL11
 524         die horribly
 525 #endif
 526                                 ], [pthread_create(NULL, NULL, NULL, NULL);],
 527                                         ol_try_pthread_hpux_11=yes
 528                                         ol_cv_pthread_hpux_11=yes,
 529                                         ol_cv_pthread_hpux_11=no)])
 530                         AC_MSG_RESULT(yes)
 531                         LIBS="$save_LIBS"
 532
 533                         if test $ol_cv_pthread_hpux_11=yes ; then
 534                                 ol_link_threads=posix
 535                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"
 536                                 if test $ol_try_pthread_hpux_11=yes ; then
 537                                         dnl Some tests below may fail, cause we aint including
 538                                         dnl pthread.h. Force appropriate ones to yes
 539                                         ac_cv_func_pthread_attr_init=yes
 540                                 fi
 541                         fi
 542                 fi
 543
 544                 if test $ol_link_threads != no ; then
 545                         AC_DEFINE(HAVE_PTHREADS)
 546
 547                         dnl save flags
 548                         save_CPPFLAGS="$CPPFLAGS"
 549                         save_LIBS="$LIBS"
 550                         LIBS="$LTHREAD_LIBS $LIBS"
 551
 552                         dnl All POSIX Thread (final) implementations should have
 553                         dnl sched_yield instead of pthread yield.
 554                         dnl check for both
 555                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 556
 557                         if test $ac_cv_func_sched_yield = no -a \
 558                                 $ac_cv_func_pthread_yield = no ; then
 559                                 dnl Digital UNIX has sched_yield() in -lrt
 560                                 AC_CHECK_LIB(rt, sched_yield,
 561                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 562                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 563                                         ac_cv_func_sched_yield=yes],
 564                                         [ac_cv_func_sched_yield=no])
 565                         fi
 566                         if test $ac_cv_func_sched_yield = no -a \
 567                                 $ac_cv_func_pthread_yield = no ; then
 568                                 dnl Solaris has sched_yield() in -lposix4
 569                                 AC_CHECK_LIB(posix4, sched_yield,
 570                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 571                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 572                                         ac_cv_func_sched_yield=yes],
 573                                         [ac_cv_func_sched_yield=no])
 574                         fi
 575                         if test $ac_cv_func_sched_yield = no -a \
 576                                 $ac_cv_func_pthread_yield = no ; then
 577                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 578                                 AC_MSG_ERROR([POSIX Threads are not usable])
 579                         fi
 580
 581                         dnl Check functions for compatibility
 582                         AC_CHECK_FUNCS(pthread_kill)
 583                         AC_CHECK_FUNCS( \
 584                                 pthread_attr_create pthread_attr_init \
 585                                 pthread_attr_destroy pthread_attr_delete \
 586                                 pthread_attr_setdetachstate pthread_attr_setdetach_np \
 587                         )
 588
 589                         dnl Check for setconcurreny functions
 590                         AC_CHECK_FUNCS( \
 591                                 pthread_setconcurrency \
 592                                 thr_setconcurrency \
 593                         )
 594
 595                         AC_MSG_CHECKING([if pthread_create() works])
 596                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 597                         AC_TRY_RUN([
 598 #include <pthread.h>
 599 #ifndef NULL
 600 #define NULL (void*)0
 601 #endif
 602
 603 static void *task(p)
 604         void *p;
 605 {
 606         return (void *) (p == NULL);
 607 }
 608
 609 int main(argc, argv)
 610         int argc;
 611         char **argv;
 612 {
 613         pthread_t t;
 614         exit(pthread_create(&t, NULL, task, NULL));
 615 }
 616 ],
 617                                 [ol_cv_pthread_create_works=yes],
 618                                 [ol_cv_pthread_create_works=no],
 619                                 [dnl assume yes
 620                                 ol_cv_pthread_create_works=yes])])
 621                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 622
 623                         if test $ol_cv_pthread_create_works = no ; then
 624                                 AC_MSG_ERROR([pthread.h and pthread_create are not compatible])
 625                         fi
 626
 627                         dnl Check if select causes an yield
 628                         if test $ol_with_yielding_select = auto ; then
 629                                 AC_MSG_CHECKING([if select yields when using pthreads])
 630                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 631                                 AC_TRY_RUN([
 632 #include <sys/types.h>
 633 #include <sys/time.h>
 634 #include <unistd.h>
 635 #include <pthread.h>
 636 #ifndef NULL
 637 #define NULL (void*) 0
 638 #endif
 639
 640 static int fildes[2];
 641
 642 static void *task(p)
 643         void *p;
 644 {
 645         int i;
 646         struct timeval tv;
 647
 648         fd_set rfds;
 649
 650         tv.tv_sec=10;
 651         tv.tv_usec=0;
 652
 653         FD_ZERO(&rfds);
 654         FD_SET(fildes[0], &rfds);
 655
 656         /* we're not interested in any fds */
 657         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 658
 659         if(i < 0) {
 660                 perror("select");
 661                 exit(10);
 662         }
 663
 664         exit(0); /* if we exit here, the select blocked the whole process */
 665 }
 666
 667 int main(argc, argv)
 668         int argc;
 669         char **argv;
 670 {
 671         pthread_t t;
 672
 673         /* create a pipe to select */
 674         if(pipe(&fildes[0])) {
 675                 perror("select");
 676                 exit(1);
 677         }
 678
 679 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 680         (void) pthread_setconcurrency(2);
 681 #else
 682 #ifdef HAVE_THR_SETCONCURRENCY
 683         /* Set Solaris LWP concurrency to 2 */
 684         thr_setconcurrency(2);
 685 #endif
 686 #endif
 687
 688         pthread_create(&t, NULL, task, NULL);
 689
 690 #if HAVE_SCHED_YIELD
 691         sched_yield();  /* make sure task runs first */
 692 #else
 693 #ifdef HAVE_PTHREAD_YIELD
 694         pthread_yield();        /* make sure task runs first */
 695 #endif
 696 #endif
 697
 698         exit(2);
 699 }],
 700                                 [ol_cv_pthread_select_yields=no],
 701                                 [ol_cv_pthread_select_yields=yes], [
 702                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
 703                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
 704
 705                                 if test $ol_cv_pthread_select_yields = yes ; then
 706                                         ol_with_yielding_select=yes
 707                                 fi
 708                         fi
 709
 710                         dnl restore flags
 711                         CPPFLAGS="$save_CPPFLAGS"
 712                         LIBS="$save_LIBS"
 713                 else
 714                         AC_MSG_ERROR([could not link with POSIX Threads])
 715                 fi
 716         fi
 717
 718         if test $ol_with_threads = posix ; then
 719                 AC_MSG_ERROR([could not locate POSIX Threads])
 720         fi
 721 fi
 722
 723 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 724         -o $ol_with_threads = mach ; then
 725
 726         dnl check for Mach CThreads
 727         AC_CHECK_HEADERS(mach/cthreads.h)
 728         if test $ac_cv_header_mach_cthreads_h = yes ; then
 729                 ol_with_threads=found
 730
 731                 dnl check for cthread support in current $LIBS
 732                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 733
 734                 if test $ol_link_threads = no ; then
 735                         dnl try -all_load
 736                         dnl this test needs work
 737                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 738                                 [ol_cv_cthread_all_load], [
 739                                 dnl save the flags
 740                                 save_LIBS="$LIBS"
 741                                 LIBS="-all_load $LIBS"
 742                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 743                                         cthread_fork((void *)0, (void *)0);
 744                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 745                                 dnl restore the LIBS
 746                                 LIBS="$save_LIBS"
 747                         ])
 748
 749                         if test $ol_cv_cthread_all_load = yes ; then
 750                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 751                                 ol_link_threads=mach
 752                         fi
 753                 fi
 754
 755                 if test $ol_link_threads != no ; then
 756                         : check for cthread specific functionality here
 757                         AC_DEFINE(HAVE_MACH_CTHREADS,1)
 758                 else
 759                         AC_MSG_ERROR([could not link with Mach CThreads])
 760                 fi
 761         fi
 762
 763         if test $ol_with_threads = mach ; then
 764                 AC_MSG_ERROR([could not locate Mach CThreads])
 765         fi
 766 fi
 767
 768 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 769         -o $ol_with_threads = lwp ; then
 770
 771         dnl check for SunOS5 LWP
 772         AC_CHECK_HEADERS(thread.h synch.h)
 773         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 774                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
 775
 776                 if test $have_thr = yes ; then
 777                         AC_DEFINE(HAVE_THR)
 778                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
 779                         ol_link_threads=thr
 780
 781                         if test $ol_with_yielding_select = auto ; then
 782                                 ol_with_yielding_select=yes
 783                         fi
 784                 fi
 785         fi
 786
 787         dnl check for SunOS4 LWP
 788         AC_CHECK_HEADERS(lwp/lwp.h)
 789         if test $ac_cv_header_lwp_lwp_h = yes ; then
 790                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 791
 792                 if test $have_lwp = yes ; then
 793                         AC_DEFINE(HAVE_LWP)
 794                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 795                         ol_link_threads=lwp
 796
 797                         if test $ol_with_yielding_select = auto ; then
 798                                 ol_with_yielding_select=no
 799                         fi
 800                 fi
 801         fi
 802 fi
 803
 804 if test $ol_with_yielding_select = yes ; then
 805         AC_DEFINE(HAVE_YIELDING_SELECT,1)
 806 fi
 807
 808 if test $ol_with_threads = manual ; then
 809         dnl User thinks he can manually configure threads.
 810         ol_link_threads=yes
 811
 812         AC_MSG_WARN([thread defines and link options must be set manually])
 813
 814         AC_CHECK_HEADERS(pthread.h sched.h)
 815         AC_CHECK_FUNCS(sched_yield pthread_yield)
 816         OL_LINUX_THREADS
 817
 818         AC_CHECK_HEADERS(mach/cthreads.h)
 819         AC_CHECK_HEADERS(lwp/lwp.h)
 820         AC_CHECK_HEADERS(thread.h synch.h)
 821 fi
 822
 823 if test $ol_link_threads != no ; then
 824         dnl needed to get reentrant/threadsafe versions
 825         dnl
 826         AC_DEFINE(REENTRANT,1)
 827         AC_DEFINE(_REENTRANT,1)
 828         AC_DEFINE(THREAD_SAFE,1)
 829         AC_DEFINE(_THREAD_SAFE,1)
 830         AC_DEFINE(THREADSAFE,1)
 831         AC_DEFINE(_THREADSAFE,1)
 832
 833         dnl this might cause the errno symbol to be
 834         dnl replaced with a function to get a thread specific errno.
 835         dnl check to see if everything needs to be compiled
 836         dnl with the thread libraries
 837         AC_CACHE_CHECK([for thread specific errno],
 838                 [ol_cv_errno_thread_specific], [
 839                 AC_TRY_LINK([
 840 #include <errno.h>
 841                         ], [
 842 int x = errno;
 843                         ],
 844                         [ol_cv_errno_thread_specific=yes],
 845                         [ol_cv_errno_thread_specific=no])
 846         ])
 847
 848         if test $ol_cv_errno_thread_specific != yes ; then
 849                 LIBS="$LTHREAD_LIBS $LIBS"
 850                 LTHREAD_LIBS=""
 851         fi
 852
 853 dnl When in thread environment, use
 854 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
 855 dnl                     || defined( HAVE_FUNC_R )
 856 dnl                     func_r(...);
 857 dnl             #else
 858 dnl             #       if defined( HAVE_THREADS )
 859 dnl                             /* lock */
 860 dnl             #       endif
 861 dnl                             func(...);
 862 dnl             #       if defined( HAVE_THREADS )
 863 dnl                             /* unlock */
 864 dnl             #       endif
 865 dnl             #endif
 866 dnl
 867 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
 868 dnl             _POSIX_REENTRANT_FUNCTIONS
 869 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
 870 dnl             _POSIX_THREADSAFE_FUNCTIONS
 871 dnl
 872 dnl             and is currently defined in lthread.h
 873 dnl
 874 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
 875 dnl
 876 dnl libldap/*.c should only include <lthread.h> iff
 877 dnl LDAP_R_COMPILE is defined.  ie:
 878 dnl             #ifdef LDAP_R_COMPILE
 879 dnl             #       include LDAP_R_COMPILE
 880 dnl             #endif
 881 dnl
 882 dnl LDAP_R_COMIPLE is defined by libldap_r/Makefile.in
 883 dnl specifically for compiling the threadsafe version of
 884 dnl     the ldap library (-lldap_r).
 885 dnl
 886 dnl     dnl check for reentrant/threadsafe functions
 887 dnl     dnl
 888 dnl     dnl note: these should only be used when linking
 889 dnl     dnl       with $LTHREAD_LIBS
 890 dnl     dnl
 891 dnl     save_CPPFLAGS="$CPPFLAGS"
 892 dnl     save_LIBS="$LIBS"
 893 dnl     LIBS="$LTHREAD_LIBS $LIBS"
 894 dnl     AC_CHECK_FUNCS( \
 895 dnl             strtok_r \
 896 dnl             gmtime_r \
 897 dnl             gethostbyaddr_r gethostbyname_r \
 898 dnl             feof_unlocked unlocked_feof \
 899 dnl             putc_unlocked unlocked_putc \
 900 dnl             flockfile ftrylockfile \
 901 dnl     )
 902 dnl     CPPFLAGS="$save_CPPFLAGS"
 903 dnl     LIBS="$save_LIBS"
 904 fi
 905
 906 dnl ----------------------------------------------------------------
 907
 908 if test $ol_link_threads = no ; then
 909         if test $ol_with_threads = yes ; then
 910                 AC_MSG_ERROR([no suitable thread support])
 911         fi
 912
 913         if test $ol_with_threads = auto ; then
 914                 AC_MSG_WARN([no suitable thread support, disabling threads])
 915                 ol_with_threads=no
 916         fi
 917
 918         AC_DEFINE(NO_THREADS,1)
 919         LTHREAD_LIBS=""
 920 fi
 921
 922 ol_link_ldbm=no
 923 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 924         OL_BERKELEY_DB2
 925
 926         if test $ol_cv_berkeley_db2 = yes ; then
 927                 ol_link_ldbm=db2
 928                 ol_with_ldbm_api=db2
 929
 930                 if test $ol_with_ldbm_type = hash ; then
 931                         AC_DEFINE(LDBM_USE_DBHASH,1)
 932                 else
 933                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 934                 fi
 935
 936                 dnl $ol_cv_lib_db2 should be yes or -ldb
 937                 dnl (it could be no, but that would be an error
 938                 if test $ol_cv_lib_db2 != yes ; then
 939                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 940                 fi
 941         fi
 942 fi
 943
 944 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 945         OL_BERKELEY_DB
 946
 947         if test $ol_cv_berkeley_db = yes ; then
 948                 ol_link_ldbm=db
 949                 ol_with_ldbm_api=db
 950
 951                 if test $ol_with_ldbm_type = hash ; then
 952                         AC_DEFINE(LDBM_USE_DBHASH,1)
 953                 else
 954                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 955                 fi
 956
 957                 dnl $ol_cv_lib_db should be yes or -ldb
 958                 dnl (it could be no, but that would be an error
 959                 if test $ol_cv_lib_db != yes ; then
 960                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 961                 fi
 962         fi
 963 fi
 964
 965 if test $ol_with_ldbm_api = manual ; then
 966         dnl User thinks he can manually configure LDBM api.
 967         ol_link_ldbm=yes
 968
 969         AC_MSG_WARN([LDBM defines and link options must be set manually])
 970
 971         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 972 fi
 973
 974 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 975         AC_MSG_WARN(Could not find LDBM with BTREE support)
 976         ol_with_ldbm_api=none
 977 fi
 978
 979 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 980         OL_GDBM
 981
 982         if test $ol_cv_gdbm = yes ; then
 983                 ol_link_ldbm=gdbm
 984                 ol_with_ldbm_api=gdbm
 985
 986                 if test $ol_cv_lib_gdbm != yes ; then
 987                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 988                 fi
 989         fi
 990 fi
 991
 992 if test $ol_with_ldbm_api = auto ; then
 993         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
 994 elif test $ol_with_ldbm_api = ndbm ; then
 995         OL_NDBM
 996
 997         if test $ol_cv_ndbm = yes ; then
 998                 ol_link_ldbm=ndbm
 999                 ol_with_ldbm_api=ndbm
1000
1001                 if test $ol_cv_lib_ndbm != yes ; then
1002                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1003                 fi
1004         fi
1005 fi
1006
1007 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1008         AC_MSG_WARN(could not find suitable LDBM backend)
1009         if test $ol_enable_ldbm = yes ; then
1010                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1011         fi
1012
1013         AC_MSG_WARN(disabling LDBM)
1014         ol_enable_ldbm=no
1015 fi
1016
1017 if test $ol_enable_wrappers != no ; then
1018         AC_CHECK_LIB(wrap, main,
1019                 [have_wrappers=yes], [have_wrappers=no])
1020
1021         if test $have_wrappers = yes ; then
1022                 AC_DEFINE(HAVE_TCPD)
1023                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1024         else
1025                 AC_MSG_WARN(could not find -lwrap)
1026                 if test $ol_enable_wrappers = yes ; then
1027                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1028                 fi
1029
1030                 AC_MSG_WARN(disabling wrappers support)
1031                 ol_enable_wrappers=no
1032         fi
1033
1034 fi
1035
1036 if test $ol_enable_syslog != no ; then
1037         AC_CHECK_FUNC(openlog)
1038         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1039                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1040         fi
1041         ol_enable_syslog=$ac_cv_func_openlog
1042 fi
1043
1044 if test $ol_enable_dmalloc != no ; then
1045         AC_CHECK_HEADERS(dmalloc.h)
1046         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1047 fi
1048
1049 # ud needs termcap (should insert check here)
1050 ol_link_termcap=no
1051 AC_CHECK_HEADERS(termcap.h ncurses.h)
1052
1053 if test $ol_link_termcap = no ; then
1054         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1055         if test $have_termcap = yes ; then
1056                 AC_DEFINE(HAVE_TERMCAP)
1057                 ol_link_termcap=yes
1058                 TERMCAP_LIBS=-ltermcap
1059         fi
1060 fi
1061
1062 if test $ol_link_termcap = no ; then
1063         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1064         if test $have_ncurses = yes ; then
1065                 AC_DEFINE(HAVE_NCURSES)
1066                 ol_link_termcap=yes
1067                 TERMCAP_LIBS=-lncurses
1068         fi
1069 fi
1070
1071 if test $ol_link_termcap = no ; then
1072         AC_DEFINE(NO_TERMCAP,1)
1073         TERMCAP_LIBS=
1074 fi
1075
1076 # FreeBSD (and others) have crypt(3) in -lcrypt
1077 if test $ol_enable_crypt != no ; then
1078         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1079                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1080                         have_crypt=yes], [have_crypt=no])])
1081
1082         if test $have_crypt = yes ; then
1083                 AC_DEFINE(HAVE_CRYPT,1)
1084         else
1085                 AC_MSG_WARN(could not find crypt)
1086                 if test $ol_enable_crypt = yes ; then
1087                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1088                 fi
1089
1090                 AC_MSG_WARN(disabling crypt support)
1091                 ol_enable_crypt=no
1092         fi
1093 fi
1094
1095 # FreeBSD (and others) have setproctitle(3) in -lutil
1096 if test $ol_enable_proctitle != no ; then
1097         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1098                 AC_CHECK_LIB(util, setproctitle,
1099                         [have_setproctitle=yes
1100                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1101                         [have_setproctitle=no
1102                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1103
1104         if test $have_setproctitle = yes ; then
1105                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1106         fi
1107 fi
1108
1109 dnl ----------------------------------------------------------------
1110 dnl Checks for header files.
1111 AC_HEADER_STDC
1112
1113 if test $ac_cv_header_stdc != yes; then
1114         AC_MSG_WARN([could not Standard C compliant headers])
1115 fi
1116
1117 AC_HEADER_DIRENT
1118 AC_HEADER_SYS_WAIT
1119 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1120 if test $am_cv_sys_posix_termios = yes ; then
1121         AC_DEFINE(HAVE_POSIX_TERMIOS,1)
1122 fi
1123
1124 AC_CHECK_HEADERS(       \
1125         crypt.h                 \
1126         errno.h                 \
1127         fcntl.h                 \
1128         filio.h                 \
1129         getopt.h                \
1130         libutil.h               \
1131         limits.h                \
1132         malloc.h                \
1133         memory.h                \
1134         regex.h                 \
1135         psap.h                  \
1136         pwd.h                   \
1137         sgtty.h                 \
1138         stdarg.h                \
1139         stddef.h                \
1140         string.h                \
1141         strings.h               \
1142         sys/file.h              \
1143         sys/filio.h             \
1144         sys/errno.h             \
1145         sys/ioctl.h             \
1146         sys/param.h             \
1147         sys/resource.h  \
1148         sys/socket.h    \
1149         sys/syslog.h    \
1150         sys/time.h              \
1151         sys/types.h             \
1152         syslog.h                \
1153         termios.h               \
1154         unistd.h                \
1155 )
1156
1157 dnl ----------------------------------------------------------------
1158 dnl Checks for typedefs, structures, and compiler characteristics.
1159 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1160 AC_TYPE_MODE_T
1161 AC_TYPE_OFF_T
1162 AC_TYPE_PID_T
1163 AM_TYPE_PTRDIFF_T
1164 AC_TYPE_SIGNAL
1165 OL_TYPE_SIG_ATOMIC_T
1166 AC_TYPE_SIZE_T
1167 AC_STRUCT_ST_BLKSIZE
1168 AC_HEADER_TIME
1169 AC_STRUCT_TM
1170
1171 OL_C_UPPER_LOWER
1172 AC_C_CONST
1173 OL_C_VOLATILE
1174
1175 if test $cross_compiling = yes ; then
1176         AC_DEFINE(CROSS_COMPILING, 1)
1177 else
1178         AC_C_BIGENDIAN
1179         AC_CHECK_SIZEOF(short)
1180         AC_CHECK_SIZEOF(int)
1181         AC_CHECK_SIZEOF(long)
1182 fi
1183
1184 dnl ----------------------------------------------------------------
1185 dnl Checks for library functions.
1186 AC_FUNC_MEMCMP
1187 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1188 AC_FUNC_STRFTIME
1189 dnl AM_FUNC_STRTOD
1190 AC_FUNC_VPRINTF
1191
1192 if test $ac_cv_func_vprintf = yes ; then
1193         dnl check for vsnprintf
1194         AC_CHECK_FUNCS(vsnprintf vsprintf)
1195 fi
1196
1197 AC_FUNC_WAIT3
1198
1199 AC_CHECK_FUNCS(         \
1200         bcopy                   \
1201         flock                   \
1202         getdtablesize   \
1203         gethostname             \
1204         getpwuid                \
1205         gettimeofday    \
1206         lockf                   \
1207         memcpy                  \
1208         memmove                 \
1209         mkstemp                 \
1210         res_search              \
1211         select                  \
1212         setpwfile               \
1213         setsid                  \
1214         signal                  \
1215         sigset                  \
1216         snprintf                \
1217         socket                  \
1218         strerror                \
1219         strpbrk                 \
1220         strrchr                 \
1221         strsep                  \
1222         strstr                  \
1223         strtok                  \
1224         strtol                  \
1225         strtoul                 \
1226         sysconf                 \
1227         waitpid                 \
1228 )
1229
1230 # these functions are required to build a thread_safe -lldap
1231 AC_CHECK_FUNCS(         \
1232         strtok_r                \
1233         ctime_r                 \
1234         gethostbyaddr_r \
1235         gethostbyname_r \
1236 )
1237
1238 OL_FUNC_CTIME_R_NARGS
1239
1240 if test $ac_cv_func_strtok_r = yes \
1241         -a $ac_cv_func_ctime_r = yes \
1242         -a $ol_cv_func_ctime_r_nargs -ge 2 -a $ol_cv_func_ctime_r_nargs -le 3 \
1243         -a $ac_cv_func_gethostbyaddr_r = yes \
1244         -a $ac_cv_func_gethostbyname_r = yes \
1245         ; then
1246
1247         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT, 1)
1248 fi
1249
1250 if test $ol_link_threads != no ; then
1251         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE, 1)
1252 fi
1253
1254 dnl We actually may need to replace more than this.
1255 AC_REPLACE_FUNCS(getopt strdup tempnam)
1256
1257 dnl ----------------------------------------------------------------
1258 # Check Configuration
1259 OL_SYS_ERRLIST
1260
1261 dnl ----------------------------------------------------------------
1262 dnl Sort out defines
1263
1264 if test "$ol_enable_debug" != no ; then
1265         AC_DEFINE(LDAP_DEBUG,1)
1266 fi
1267 if test "$ol_enable_syslog" = yes ; then
1268         AC_DEFINE(LDAP_SYSLOG,1)
1269 fi
1270 if test "$ol_enable_libui" = yes ; then
1271         AC_DEFINE(LDAP_LIBUI,1)
1272 fi
1273 if test "$ol_enable_cache" = no ; then
1274         AC_DEFINE(LDAP_NOCACHE,1)
1275 fi
1276 if test "$ol_enable_dns" != no ; then
1277         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_API_VENDOR_VERSION,1)
1278 fi
1279 if test "$ol_enable_proctitle" != no ; then
1280         AC_DEFINE(LDAP_PROCTITLE,1)
1281 fi
1282 if test "$ol_enable_referrals" != no ; then
1283         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_API_VENDOR_VERSION,1)
1284 fi
1285 if test "$ol_enable_cldap" != no ; then
1286         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1287 fi
1288
1289 if test "$ol_enable_aclgroups" != no ; then
1290         AC_DEFINE(SLAPD_ACLGROUPS,1)
1291 fi
1292 if test "$ol_enable_crypt" != no ; then
1293         AC_DEFINE(SLAPD_CRYPT,1)
1294 fi
1295 if test "$ol_enable_cleartext" != no ; then
1296         AC_DEFINE(SLAPD_CLEARTEXT,1)
1297 fi
1298 if test "$ol_enable_phonetic" != no ; then
1299         AC_DEFINE(SLAPD_PHONETIC,1)
1300 fi
1301 if test "$ol_enable_rlookups" != no ; then
1302         AC_DEFINE(SLAPD_RLOOKUPS,1)
1303 fi
1304
1305 if test "$ol_link_ldbm" != no ; then
1306         AC_DEFINE(SLAPD_LDBM,1)
1307         BUILD_SLAPD=yes
1308         BUILD_LDBM=yes
1309 fi
1310
1311 if test "$ol_enable_passwd" != no ; then
1312         AC_DEFINE(SLAPD_PASSWD,1)
1313         BUILD_SLAPD=yes
1314         BUILD_PASSWD=yes
1315 fi
1316
1317 if test "$ol_enable_shell" != no ; then
1318         AC_DEFINE(SLAPD_SHELL,1)
1319         BUILD_SLAPD=yes
1320         BUILD_SHELL=yes
1321 fi
1322
1323 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1324         $BUILD_SLAPD = yes ; then
1325         BUILD_SLURPD=yes
1326 fi
1327
1328 if test "$ol_link_isode" != no ; then
1329         BUILD_LDAPD=yes
1330 fi
1331
1332 dnl ----------------------------------------------------------------
1333
1334 AC_SUBST(BUILD_LDAPD)
1335 AC_SUBST(BUILD_SLAPD)
1336   AC_SUBST(BUILD_LDBM)
1337   AC_SUBST(BUILD_PASSWD)
1338   AC_SUBST(BUILD_SHELL)
1339 AC_SUBST(BUILD_SLURPD)
1340
1341 AC_SUBST(LDAP_LIBS)
1342 AC_SUBST(LDAPD_LIBS)
1343 AC_SUBST(SLAPD_LIBS)
1344 AC_SUBST(SLURPD_LIBS)
1345 AC_SUBST(LDBM_LIBS)
1346 AC_SUBST(LTHREAD_LIBS)
1347 AC_SUBST(LUTIL_LIBS)
1348
1349 AC_SUBST(KRB_LIBS)
1350 AC_SUBST(TERMCAP_LIBS)
1351
1352 dnl ----------------------------------------------------------------
1353 dnl final output
1354 dnl
1355
1356 AC_OUTPUT( \
1357 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1358 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1359 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1360 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1361 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1362 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1363 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1364 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1365 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1366 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1367 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1368 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1369 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1370 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1371 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1372 include/Makefile:build/top.mk:include/Makefile.in \
1373 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1374 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1375 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1376 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1377 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1378 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1379 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1380 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk:build/lib-static.mk    \
1381 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1382 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1383 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1384 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1385 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1386 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1387 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1388 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1389 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1390 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1391 tests/Makefile:build/top.mk:tests/Makefile.in \
1392 ,[
1393 date > stamp-h
1394 echo Please \"make depend\" to build dependencies
1395 ])