git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms are permitted only
   6 dnl as authorized by the OpenLDAP Public License.  A copy of this
   7 dnl license is available at http://www.OpenLDAP.org/license.html or
   8 dnl in file LICENSE in the top-level directory of the distribution.
   9 dnl
  10 dnl ----------------------------------------------------------------
  11 dnl Redefine AC_INIT_BINSH to provide RCS IDs and copyright notice
  12 dnl at top of generated configure script.  Prints simple copyright.
  13 define([AC_INIT_BINSH],
  14 [[#! /bin/sh
  15 # $]OpenLDAP[$
  16 # from] translit([$OpenLDAP$], $")] [
  17
  18 # Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
  19 #
  20 # Redistribution and use in source and binary forms are permitted only
  21 # as authorized by the OpenLDAP Public License.  A copy of this
  22 # license is available at http://www.OpenLDAP.org/license.html or
  23 # in file LICENSE in the top-level directory of the distribution.
  24
  25 echo "Copyright 1998-1999 The OpenLDAP Foundation,  All Rights Reserved."
  26 echo "Copying restrictions apply, see COPYRIGHT file."
  27 ])dnl
  28 dnl ----------------------------------------------------------------
  29 dnl Disable config.cache!
  30 define([AC_CACHE_LOAD], )dnl
  31 define([AC_CACHE_SAVE], )dnl
  32 dnl ================================================================
  33 dnl Configure.in for OpenLDAP
  34 AC_INIT(build/version)dnl
  35 AC_CONFIG_AUX_DIR(build)dnl
  36
  37 OL_VERSION=`cat $ac_aux_dir/version`
  38 if test -z "$OL_VERSION"; then
  39         AC_MSG_ERROR([could not determine version])
  40 fi
  41
  42 echo "Configuring OpenLDAP $OL_VERSION ..."
  43
  44 dnl Determine host platform
  45 dnl             we try not to use this for much
  46 AC_CANONICAL_SYSTEM
  47
  48 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  49 AC_SUBST(PACKAGE)
  50 AC_SUBST(VERSION)
  51 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  52 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  53
  54 dnl We use autoconf features new to 2.13.
  55 dnl aclocal.m4 should be built using aclocal from automake 1.4
  56 dnl libtool 1.3.3 should be installed.
  57 AC_PREREQ(2.13)dnl Required Autoconf version
  58
  59 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  60
  61 dnl ================================================================
  62 dnl Start Args
  63 AC_MSG_CHECKING(configure arguments)
  64 AC_PREFIX_DEFAULT(/usr/local)
  65
  66 top_builddir=`pwd`
  67 AC_SUBST(top_builddir)dnl
  68
  69 dnl ----------------------------------------------------------------
  70 dnl --with-subdir
  71 ldap_subdir="/openldap"
  72
  73 AC_ARG_WITH(subdir,
  74 [  --with-subdir=DIR change default subdirectory used for installs],
  75 [case "$withval" in
  76         no) ldap_subdir=""
  77                 ;;
  78         yes)
  79                 ;;
  80         /*|\\*)
  81                 ldap_subdir="$withval"
  82                 ;;
  83         *)
  84                 ldap_subdir="/$withval"
  85                 ;;
  86 esac
  87 ])dnl
  88
  89 AC_SUBST(ldap_subdir)dnl
  90
  91 dnl ----------------------------------------------------------------
  92 dnl General "enable" options
  93 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  94 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  95 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  96 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  97 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DX Referrals extension], no)dnl
  98 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  99 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
 100 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
 101         no, [yes no])dnl
 102
 103 dnl ----------------------------------------------------------------
 104 dnl General "with" options
 105 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
 106
 107 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl     with Cyrus SASL support],
 108         auto, [auto yes no] )
 109 OL_ARG_WITH(fetch,[  --with-fetch               with fetch URL support],
 110         auto, [auto yes no] )
 111 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
 112         auto, [auto k5 kth k4 afs yes no])
 113 OL_ARG_WITH(readline,[  --with-readline with readline support],
 114         auto, [auto yes no] )
 115 OL_ARG_WITH(threads,[  --with-threads   use threads],
 116         auto, [auto nt posix mach pth lwp yes no manual] )
 117 OL_ARG_WITH(tls,[  --with-tls           with TLS/SSL support],
 118         auto, [auto ssleay openssl yes no] )
 119 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
 120         auto, [auto yes no manual] )
 121
 122 dnl ----------------------------------------------------------------
 123 dnl Server options
 124 dnl ----------------------------------------------------------------
 125 dnl LDAPD OPTIONS
 126 AC_ARG_WITH(xxldapdoptions,[LDAPD (X.500-to-LDAP Gateway) Options:])
 127 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
 128
 129 dnl ----------------------------------------------------------------
 130 dnl SLAPD OPTIONS
 131 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 132 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
 133 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
 134 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
 135 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
 136 OL_ARG_ENABLE(multimaster,[    --enable-multimaster     enable multimaster replication], no)dnl
 137 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
 138 OL_ARG_ENABLE(quipu,[    --enable-quipu build quipu migration tools], no)dnl
 139 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
 140 OL_ARG_ENABLE(aci,[    --enable-aci     enable per-object ACIs], no)dnl
 141 OL_ARG_ENABLE(discreteaci,[    --enable-discreteaci     enable discrete rights in ACIs], no)dnl
 142 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
 143 OL_ARG_ENABLE(dynamic,[    --enable-dynamic     enable linking built binaries with dynamic libs], no)dnl
 144
 145 dnl SLAPD Backend options
 146 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 147 OL_ARG_WITH(bdb2_module,[      --with-bdb2-module       module type], static,
 148         [static dynamic])
 149 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 150 OL_ARG_WITH(ldap_module,[      --with-ldap-module       module type], static,
 151         [static dynamic])
 152 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 153 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 154         [auto db2 db mdbm gdbm ndbm manual])
 155 OL_ARG_WITH(ldbm_module,[      --with-ldbm-module       module type], static,
 156         [static dynamic])
 157 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 158         [auto btree hash])
 159
 160 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 161 OL_ARG_WITH(passwd_module,[      --with-passwd-module   module type], static,
 162         [static dynamic])
 163 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 164 OL_ARG_WITH(perl_module,[      --with-perl-module       module type], static,
 165         [static dynamic])
 166 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 167 OL_ARG_WITH(shell_module,[      --with-shell-module     module type], static,
 168         [static dynamic])
 169 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 170 OL_ARG_WITH(tcl_module,[      --with-tcl-module module type], static,
 171         [static dynamic])
 172
 173 dnl ----------------------------------------------------------------
 174 dnl SLURPD OPTIONS
 175 AC_ARG_WITH(xxslurpdoptions,[SLURPD (Replication Daemon) Options:])
 176 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 177
 178 dnl ----------------------------------------------------------------
 179 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 180 AC_ENABLE_STATIC
 181 dnl AC_DISABLE_SHARED
 182 AC_ENABLE_SHARED
 183
 184 dnl ----------------------------------------------------------------
 185
 186 dnl General "enable" options
 187 # validate options
 188 if test $ol_enable_dns = yes ; then
 189         if test $ol_enable_referrals = no ; then
 190                 AC_MSG_ERROR([DNS requires --enable-referrals])
 191         fi
 192         if test $ol_enable_referrals = auto ; then
 193                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 194                 ol_enable_referrals=yes
 195         fi
 196 fi
 197
 198 if test $ol_enable_slapd = no ; then
 199         dnl SLAPD was specificallly disabled
 200         if test $ol_enable_bdb2 = yes ; then
 201                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 202         fi
 203         if test $ol_enable_ldap = yes ; then
 204                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 205         fi
 206         if test $ol_enable_ldbm = yes ; then
 207                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 208         fi
 209         if test $ol_enable_passwd = yes ; then
 210                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 211         fi
 212         if test $ol_enable_perl = yes ; then
 213                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 214         fi
 215         if test $ol_enable_shell = yes ; then
 216                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 217         fi
 218         if test $ol_enable_tcl = yes ; then
 219                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 220         fi
 221         if test $ol_enable_modules = yes ; then
 222                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 223         fi
 224         if test $ol_enable_multimaster = yes ; then
 225                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 226         fi
 227         if test $ol_enable_wrappers = yes ; then
 228                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 229         fi
 230         if test $ol_enable_phonetic = yes ; then
 231                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 232         fi
 233         if test $ol_enable_quipu = yes ; then
 234                 AC_MSG_WARN([slapd disabled, ignoring --enable-quipu argument])
 235         fi
 236         if test $ol_enable_rlookups = yes ; then
 237                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 238         fi
 239         if test $ol_enable_aci = yes ; then
 240                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 241         fi
 242         if test $ol_enable_discreteaci = yes ; then
 243                 AC_MSG_WARN([slapd disabled, ignoring --enable-discreteaci argument])
 244         fi
 245         if test $ol_with_ldbm_api != auto ; then
 246                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 247         fi
 248         if test $ol_with_ldbm_type != auto ; then
 249                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 250         fi
 251         if test $ol_with_bdb2_module != static ; then
 252                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb2-module argument])
 253         fi
 254         if test $ol_with_ldap_module != static ; then
 255                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 256         fi
 257         if test $ol_with_ldbm_module != static ; then
 258                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 259         fi
 260         if test $ol_with_passwd_module != static ; then
 261                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 262         fi
 263         if test $ol_with_perl_module != static ; then
 264                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 265         fi
 266         if test $ol_with_shell_module != static ; then
 267                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 268         fi
 269         if test $ol_with_tcl_module != static ; then
 270                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 271         fi
 272         if test $ol_enable_slurpd = yes ; then
 273                 AC_MSG_ERROR([slurpd requires slapd])
 274         fi
 275
 276         # force settings to no
 277         ol_enable_bdb2=no
 278         ol_enable_ldap=no
 279         ol_enable_ldbm=no
 280         ol_enable_passwd=no
 281         ol_enable_perl=no
 282         ol_enable_shell=no
 283         ol_enable_tcl=no
 284
 285         ol_enable_modules=no
 286         ol_enable_multimaster=no
 287         ol_enable_phonetic=no
 288         ol_enable_quipu=no
 289         ol_enable_rlookups=no
 290         ol_enable_aci=no
 291         ol_enable_discreteaci=no
 292         ol_enable_wrappers=no
 293         ol_enable_dynamic=no
 294
 295         ol_with_ldbm_api=no
 296         ol_with_ldbm_type=no
 297
 298         ol_with_bdb2_module=static
 299         ol_with_ldap_module=static
 300         ol_with_ldbm_module=static
 301         ol_with_passwd_module=static
 302         ol_with_perl_module=static
 303         ol_with_shell_module=static
 304         ol_with_tcl_module=static
 305
 306         ol_enable_slurpd=no
 307
 308 elif test $ol_enable_ldbm = no ; then
 309         dnl SLAPD without LDBM
 310
 311         if test $ol_with_ldbm_api != auto ; then
 312                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 313         fi
 314
 315         if test $ol_with_ldbm_type != auto ; then
 316                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 317         fi
 318
 319         if test $ol_with_ldbm_module != static ; then
 320                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 321         fi
 322
 323         if test $ol_enable_bdb2 = yes ; then
 324                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 325         fi
 326
 327         if test $ol_enable_modules != yes -a \
 328                 $ol_enable_ldap = no -a \
 329                 $ol_enable_passwd = no -a \
 330                 $ol_enable_perl = no -a \
 331                 $ol_enable_shell = no -a \
 332                 $ol_enable_tcl = no ; then
 333                 AC_MSG_ERROR([slapd requires a backend])
 334         fi
 335
 336         ol_with_ldbm_api=no
 337         ol_with_ldbm_type=no
 338         ol_with_ldbm_module=static
 339
 340 elif test $ol_enable_bdb2 = yes ; then
 341         dnl SLAPD with BDB2
 342
 343         if test $ol_with_ldbm_api != auto -a \
 344                 $ol_with_ldbm_api != db2 ; then
 345                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 346         fi
 347
 348         ol_with_ldbm_api=db2
 349
 350 else
 351         dnl SLAPD with LDBM
 352
 353         if test $ol_enable_bdb2 != no ; then
 354                 if test $ol_with_ldbm_api != auto -a \
 355                         $ol_with_ldbm_api != db2 ; then
 356                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 357                         ol_enable_bdb2=no
 358                 fi
 359         fi
 360
 361         if test $ol_with_ldbm_api = gdbm -a \
 362                 $ol_with_ldbm_type = btree ; then
 363                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 364         fi
 365         if test $ol_with_ldbm_api = mdbm -a \
 366                 $ol_with_ldbm_type = btree ; then
 367                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 368         fi
 369         if test $ol_with_ldbm_api = ndbm -a \
 370                 $ol_with_ldbm_type = btree ; then
 371                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 372         fi
 373 fi
 374
 375 if test $ol_enable_slurpd = yes ; then
 376         dnl SLURPD was specifically enabled
 377         if test $ol_with_threads = no ; then
 378                 AC_MSG_ERROR([slurpd requires threads])
 379         fi
 380 fi
 381
 382 AC_MSG_RESULT(done)
 383
 384 dnl ----------------------------------------------------------------
 385 dnl Initialize vars
 386 LDAP_LIBS=
 387 LDIF_LIBS=
 388 LDBM_LIBS=
 389 LTHREAD_LIBS=
 390 LUTIL_LIBS=
 391
 392 LDAPD_LIBS=
 393 SLAPD_LIBS=
 394 SLURPD_LIBS=
 395
 396 BUILD_LDAPD=no
 397 BUILD_SLAPD=no
 398 BUILD_SLURPD=no
 399
 400 BUILD_BDB2=no
 401 BUILD_LDAP=no
 402 BUILD_LDBM=no
 403 BUILD_PASSWD=no
 404 BUILD_PERL=no
 405 BUILD_QUIPU=no
 406 BUILD_SHELL=no
 407 BUILD_TCL=no
 408 BUILD_THREAD=no
 409
 410 BUILD_BDB2_DYNAMIC=static
 411 BUILD_LDAP_DYNAMIC=static
 412 BUILD_LDBM_DYNAMIC=static
 413 BUILD_PASSWD_DYNAMIC=static
 414 BUILD_PERL_DYNAMIC=static
 415 BUILD_SHELL_DYNAMIC=static
 416 BUILD_TCL_DYNAMIC=static
 417
 418 SLAPD_MODULES_LDFLAGS=
 419 SLAPD_MODULES_CPPFLAGS=
 420 SLAPD_MODULES_LIST=
 421
 422 SLAPD_PERL_LDFLAGS=
 423 MOD_PERL_LDFLAGS=
 424 PERL_CPPFLAGS=
 425
 426 MOD_TCL_LIB=
 427 KRB_LIBS=
 428 READLINE_LIBS=
 429 SASL_LIBS=
 430 TERMCAP_LIBS=
 431 TLS_LIBS=
 432 MODULES_LIBS=
 433
 434 dnl ================================================================
 435 dnl Checks for programs
 436
 437 dnl AC_PROG_INSTALL
 438
 439 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 440
 441 dnl ----------------------------------------------------------------
 442 dnl
 443 dnl Determine which C translator to use
 444 dnl
 445
 446 dnl AIX Thread requires we use cc_r or xlc_r.
 447 dnl But only do this IF AIX and CC is not set
 448 dnl and threads are auto|yes|posix.
 449 dnl
 450 dnl If we find cc_r|xlc_r, force pthreads and assume
 451 dnl             pthread_create is in $LIBS (ie: don't bring in
 452 dnl             any additional thread libraries)
 453 dnl If we do not find cc_r|xlc_r, disable threads
 454
 455 ol_aix_threads=no
 456 case "$target" in
 457 *-*-aix*) dnl all AIX is not a good idea.
 458         if test -z "$CC" ; then
 459                 case "$ol_with_threads" in
 460                 auto | yes |  posix) ol_aix_threads=yes ;;
 461                 esac
 462         fi
 463 ;;
 464 esac
 465
 466 if test $ol_aix_threads = yes ; then
 467         if test -z "${CC}" ; then
 468                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 469
 470                 if test "$CC" = cc ; then
 471                         dnl no CC! don't allow --with-threads
 472                         if test $ol_with_threads != auto ; then
 473                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 474                         else
 475                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 476                         fi
 477                         ol_with_threads=no
 478                 fi
 479         fi
 480
 481         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 482                 ol_with_threads=posix
 483                 ol_cv_pthread_create=yes
 484         fi
 485 fi
 486
 487 if test -z "${CC}"; then
 488         AC_CHECK_PROGS(CC,cc)
 489 fi
 490
 491 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 492 dnl (for now, let autoconf sort this out)
 493 dnl CFLAGS=${CFLAGS-""}
 494
 495 AC_LIBTOOL_WIN32_DLL
 496 AC_LIBTOOL_DLOPEN
 497 AC_PROG_LIBTOOL
 498
 499 AC_PROG_AWK
 500 OL_PROG_LN_H
 501 AC_PROG_LN_S
 502
 503 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 504         LN_S="$LN_H"
 505 fi
 506
 507 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 508         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 509 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 510 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 511
 512 dnl ----------------------------------------------------------------
 513 dnl Perl
 514 ol_link_perl=no
 515 if test $ol_enable_perl != no ; then
 516         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 517
 518         if test "no$PERLBIN" = "no" ; then
 519                 if test $ol_enable_perl = yes ; then
 520                         AC_MSG_ERROR([could not locate perl])
 521                 fi
 522
 523         else
 524                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 525                 if test x"$ol_with_perl_module" == "xstatic" ; then
 526                         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 527                 else
 528                         MOD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 529                 fi
 530                 dnl should check perl version
 531                 ol_link_perl=yes
 532         fi
 533 fi
 534
 535 AC_PROG_CPP
 536
 537 dnl ----------------------------------------------------------------
 538 dnl Cross compiling checks
 539 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 540         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 541
 542 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 543         AC_MSG_WARN([programs compiled here do run here...])
 544         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 545
 546 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 547         AC_MSG_WARN([programs compiled here do not run here...])
 548         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 549 fi
 550
 551 dnl ----------------------------------------------------------------
 552 dnl Checks for UNIX Variants
 553 AC_AIX
 554 AC_ISC_POSIX
 555 AC_MINIX
 556
 557 dnl ----------------------------------------------------------------
 558 dnl Checks for system services
 559 AC_CYGWIN
 560 AC_MINGW32
 561 AC_EXEEXT
 562 AC_OBJEXT
 563
 564 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 565
 566 dnl ----------------------------------------------------------------
 567 dnl BeOS requires -lbe -lroot -lnet
 568 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 569
 570 dnl ----------------------------------------------------------------
 571 dnl OpenLDAP requires STDC features
 572 AM_PROG_CC_STDC
 573 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 574         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 575 fi
 576
 577 dnl ----------------------------------------------------------------
 578 dnl Check cc depend flags
 579 OL_MKDEPEND
 580 if test "${ol_cv_mkdep}" = no ; then
 581         # this will soon become an error
 582         AC_MSG_WARN([do not know how to generate dependencies])
 583 fi
 584
 585 dnl ----------------------------------------------------------------
 586 dnl Check for module support
 587 ol_link_modules=no
 588 if test $ol_enable_modules != no ; then
 589         AC_CHECK_HEADERS(ltdl.h)
 590
 591         if test $ac_cv_header_ltdl_h = no ; then
 592                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 593         fi
 594
 595         AC_CHECK_LIB(ltdl, lt_dlinit, [
 596             MODULES_LIBS=-lltdl
 597             AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 598         ])
 599
 600         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 601                 AC_MSG_ERROR([could not locate libtool -lltdl])
 602         fi
 603         ol_link_modules=yes
 604 else
 605         ol_with_bdb2_module=static
 606         ol_with_ldap_module=static
 607         ol_with_ldbm_module=static
 608         ol_with_passwd_module=static
 609         ol_with_perl_module=static
 610         ol_with_shell_module=static
 611         ol_with_tcl_module=static
 612 fi
 613
 614 dnl ----------------------------------------------------------------
 615 dnl Checks for header files.
 616 OL_HEADER_STDC
 617
 618 if test $ol_cv_header_stdc != yes; then
 619         AC_MSG_WARN([could not locate Standard C compliant headers])
 620 fi
 621
 622 AC_HEADER_DIRENT
 623 AC_HEADER_SYS_WAIT
 624 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 625 if test $am_cv_sys_posix_termios = yes ; then
 626         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 627                 [define if you have POSIX termios])
 628 fi
 629
 630 AC_CHECK_HEADERS(       \
 631         arpa/inet.h             \
 632         arpa/nameser.h  \
 633         assert.h                \
 634         conio.h                 \
 635         crypt.h                 \
 636         direct.h                \
 637         errno.h                 \
 638         fcntl.h                 \
 639         filio.h                 \
 640         getopt.h                \
 641         grp.h                   \
 642         io.h                    \
 643         libutil.h               \
 644         limits.h                \
 645         locale.h                \
 646         netinet/tcp.h   \
 647         malloc.h                \
 648         memory.h                \
 649         psap.h                  \
 650         pwd.h                   \
 651         process.h               \
 652         resolv.h                \
 653         sgtty.h                 \
 654         shadow.h                \
 655         stddef.h                \
 656         string.h                \
 657         strings.h               \
 658         sysexits.h              \
 659         sys/file.h              \
 660         sys/filio.h             \
 661         sys/errno.h             \
 662         sys/ioctl.h             \
 663         sys/param.h             \
 664         sys/resource.h  \
 665         sys/select.h    \
 666         sys/socket.h    \
 667         sys/syslog.h    \
 668         sys/time.h              \
 669         sys/types.h             \
 670         syslog.h                \
 671         termios.h               \
 672         unistd.h                \
 673         winsock.h               \
 674 )
 675
 676
 677 dnl ----------------------------------------------------------------
 678 dnl Checks for libraries
 679
 680 dnl HP-UX requires -lV3
 681 AC_CHECK_LIB(V3, sigset)
 682
 683 dnl Gotta check for winsock manually
 684 if test "${ac_cv_header_winsock_h}" = yes; then
 685     AC_MSG_CHECKING(for winsock support)
 686     AC_TRY_LINK([
 687 #include <winsock.h>
 688     ],[
 689 socket(0,0,0);
 690 select(0,NULL,NULL,NULL,NULL);
 691 closesocket(0);
 692 gethostname(NULL,0);
 693     ],[
 694         AC_MSG_RESULT(yes)
 695         AC_DEFINE(HAVE_WINSOCK,1,[define if you have winsock])
 696         ac_cv_func_socket=yes
 697         ac_cv_func_select=yes
 698         ac_cv_func_closesocket=yes
 699         ac_cv_func_gethostname=yes
 700     ],[
 701         AC_MSG_RESULT(no)
 702     ])
 703 fi
 704
 705 dnl Find socket()
 706 dnl Likely combinations:
 707 dnl             -lsocket [ -lnsl_s | -lnsl ]
 708 dnl             -linet
 709
 710 AC_CHECK_FUNC(socket, :, [
 711 dnl hopefully we won't include too many libraries
 712         AC_CHECK_LIB(socket, main)
 713         AC_CHECK_LIB(net, main)
 714         AC_CHECK_LIB(net, socket)
 715         AC_CHECK_LIB(nsl_s, main)
 716         AC_CHECK_LIB(nsl, main)
 717         AC_CHECK_LIB(inet, socket)
 718         AC_CHECK_LIB(gen, main)
 719 ])
 720
 721 dnl require select
 722 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 723 dnl AC_CHECK_FUNCS(socketpair)
 724
 725 if test "${ac_cv_header_winsock_h}" != yes; then
 726     dnl Select arg types
 727     dnl (if this detection becomes permenent, it and the select() detection
 728     dnl should be done before the yielding select test)
 729     AC_FUNC_SELECT_ARGTYPES
 730 fi
 731
 732 dnl check to see if system call automatically restart
 733 dnl AC_SYS_RESTARTABLE_SYSCALLS
 734
 735 dnl ----------------------------------------------------------------
 736 dnl require POSIX regex
 737 AC_CHECK_HEADERS( regex.h )
 738 if test "$ac_cv_header_regex_h" != yes ; then
 739         AC_MSG_ERROR([POSIX regex.h required.])
 740 fi
 741 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 742
 743 OL_POSIX_REGEX
 744 if test "$ol_cv_c_posix_regex" = no ; then
 745         AC_MSG_ERROR([broken POSIX regex!])
 746 fi
 747
 748 dnl ----------------------------------------------------------------
 749 dnl Check for resolver routines
 750 AC_CHECK_FUNC(res_search,:)
 751 if test $ac_cv_func_res_search = no ; then
 752         AC_CHECK_LIB(bind, res_search)
 753         ac_cv_func_res_search=$ac_cv_lib_bind_res_search
 754 fi
 755
 756 if test $ac_cv_func_res_search = no ; then
 757         AC_CHECK_LIB(bind, __res_search)
 758         ac_cv_func_res_search=$ac_cv_lib_bind___res_search
 759 fi
 760
 761 if test $ac_cv_func_res_search = no ; then
 762         AC_CHECK_LIB(resolv, res_search)
 763         ac_cv_func_res_search=$ac_cv_lib_resolv_res_search
 764 fi
 765
 766 if test "$ac_cv_func_res_search" = yes ; then
 767         AC_DEFINE(HAVE_RES_SEARCH,1,
 768                 [define if you have res_search()])
 769 elif test $ol_enable_dns = yes ; then
 770         AC_MSG_ERROR([--enable-dns requires res_search])
 771 elif test $ol_enable_dns != no ; then
 772         AC_MSG_WARN([no res_search, disabling DNS support])
 773 fi
 774
 775
 776 dnl ----------------------------------------------------------------
 777 dnl ISODE tests
 778 ol_link_isode=no
 779 if test $ol_enable_ldapd != no ; then
 780         AC_MSG_WARN([ldapd is not supported and may suffer from bit rot.])
 781
 782         dnl look for ISODE libraries
 783         AC_CHECK_LIB(xtpp, main, [
 784                 ol_link_isode=yes
 785                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 786                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 787                 ],:,[-lxtdsap -lxtisode -losi])
 788         AC_CHECK_LIB(dsap, main, [
 789                 ol_link_isode=yes
 790                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 791                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 792                 ],:,[-lisode])
 793         AC_CHECK_LIB(isode, main, [
 794                 ol_link_isode=yes
 795                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 796                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 797                 ],:)
 798 fi
 799
 800 if test $ol_link_isode != no; then
 801         AC_CHECK_LIB(pp, main, [
 802                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 803                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 804                 ],:)
 805
 806         AC_PATH_PROG(PEPSY, pepsy)
 807 fi
 808
 809 dnl ----------------------------------------------------------------
 810 dnl QUIPU
 811 if test $ol_enable_quipu != no ; then
 812         AC_CHECK_HEADERS(quipu/commonarg.h)
 813
 814         if test $ac_cv_header_quipu_commonarg_h = yes ; then
 815                 BUILD_QUIPU=yes
 816         elif test $ol_enable_quipu = auto ; then
 817                 AC_MSG_WARN([no quipu for --enable-quipu=auto, disabling])
 818         else
 819                 AC_MSG_ERROR(no quipu for --enable-quipu=$ol_enable_quipu)
 820         fi
 821 fi
 822
 823 dnl ----------------------------------------------------------------
 824 dnl Kerberos
 825 ol_link_kerberos=no
 826
 827 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 828         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 829
 830         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 831                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 832                         [-lkrb5 -ldes425])
 833
 834                 if test $have_k5 = yes ; then
 835                         ol_with_kerberos=found
 836                         ol_link_kerberos=yes
 837
 838                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 839
 840                         LIBS="$KRB_LIBS $LIBS"
 841
 842                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 843                                 [ol_cv_var_des_debug], [
 844                                 dnl save the flags
 845                                 save_LIBS="$LIBS"
 846                                 LIBS="$KRB_LIBS $LIBS"
 847                                 AC_TRY_LINK([
 848 #include <kerberosIV/krb.h>
 849 #include <kerberosIV/des.h>
 850 extern int des_debug;
 851 ],[
 852 des_debug = 1;
 853 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 854                                 dnl restore the LIBS
 855                                 LIBS="$save_LIBS"
 856                         ])
 857
 858                         if test $ol_cv_var_des_debug = yes ; then
 859                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 860                                         [define if you have Kerberos des_debug])
 861                         fi
 862
 863                         LIBS="$save_LIBS"
 864                 fi
 865         fi
 866 fi
 867
 868 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 \
 869         -o $ol_with_kerberos = kth ; then
 870
 871         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
 872
 873         if test $ac_cv_header_krb_h = yes ; then
 874                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 875
 876                 if test $have_k4 = yes ; then
 877                         ol_with_kerberos=found
 878                         ol_link_kerberos=yes
 879
 880                         KRB_LIBS="-lkrb -ldes"
 881
 882                         if test $ac_cv_header_krb_archaeology_h = yes ; then
 883                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
 884                                         [define if you have Kth Kerberos])
 885                         fi
 886                 fi
 887         fi
 888 fi
 889
 890 if test $ol_link_kerberos = yes ; then
 891         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 892
 893 elif test $ol_with_kerberos != auto -a $ol_with_kerberos != no ; then
 894         AC_ERROR([Kerberos detection failed.])
 895 fi
 896
 897 dnl ----------------------------------------------------------------
 898 dnl TLS/SSL
 899 ol_link_tls=no
 900 if test $ol_with_tls != no ; then
 901
 902         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 903
 904         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 905                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 906                         [have_ssleay=yes
 907                         need_rsaref=no],
 908                         [have_ssleay=no],
 909                         [-lcrypto])
 910
 911                 if test $have_ssleay = no ; then
 912                         AC_CHECK_LIB(ssl, SSL_library_init,
 913                                 [have_ssleay=yes
 914                                 need_rsaref=no], [have_ssleay=no],
 915                                 [-lcrypto])
 916                 fi
 917
 918                 if test $have_ssleay = no ; then
 919                         AC_CHECK_LIB(ssl, ssl3_accept,
 920                                 [have_ssleay=yes
 921                                 need_rsaref=yes], [have_ssleay=no],
 922                                 [-lcrypto -lRSAglue -lrsaref])
 923                 fi
 924
 925                 if test $have_ssleay = yes ; then
 926                         ol_with_tls=found
 927                         ol_link_tls=yes
 928
 929                         AC_DEFINE(HAVE_SSLEAY, 1,
 930                                 [define if you have SSLeay or OpenSSL])
 931
 932                         if test $need_rsaref = yes; then
 933                                 AC_DEFINE(HAVE_RSAREF, 1,
 934                                         [define if you have RSAref])
 935
 936                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 937                         else
 938                                 TLS_LIBS="-lssl -lcrypto"
 939                         fi
 940                 fi
 941         fi
 942 fi
 943
 944 if test $ol_link_tls = yes ; then
 945         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 946 fi
 947
 948 dnl ----------------------------------------------------------------
 949 dnl Tests for reentrant functions necessary to build a
 950 dnl thread_safe -lldap.
 951 AC_CHECK_FUNCS(         \
 952         ctime_r                 \
 953         gethostbyname_r gethostbyaddr_r \
 954 )
 955
 956 if test "$ac_cv_func_ctime_r" = no ; then
 957         ol_cv_func_ctime_r_nargs=0
 958 else
 959         OL_FUNC_CTIME_R_NARGS
 960 dnl     OL_FUNC_CTIME_R_TYPE
 961 fi
 962
 963 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 964         OL_FUNC_GETHOSTBYNAME_R_NARGS
 965 else
 966         ol_cv_func_gethostbyname_r_nargs=0
 967 fi
 968
 969 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 970         OL_FUNC_GETHOSTBYADDR_R_NARGS
 971 else
 972         ol_cv_func_gethostbyaddr_r_nargs=0
 973 fi
 974
 975 if test "$ac_cv_func_ctime_r" = yes \
 976         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 977         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 978         -a "$ac_cv_func_gethostbyname_r" = yes \
 979         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 980         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 981         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 982         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 983         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 984         ; then
 985
 986         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 987 fi
 988
 989 dnl ----------------------------------------------------------------
 990 dnl Threads?
 991 ol_link_threads=no
 992
 993 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 994         -o $ol_with_threads = nt ; then
 995
 996         OL_NT_THREADS
 997
 998         if test "$ol_cv_nt_threads" = yes ; then
 999         ol_link_threads=nt
1000         ol_with_threads=found
1001         ol_with_yielding_select=yes
1002
1003                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1004                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1005         fi
1006
1007         if test $ol_with_threads = nt ; then
1008                 AC_MSG_ERROR([could not locate NT Threads])
1009         fi
1010 fi
1011
1012 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1013         -o $ol_with_threads = posix ; then
1014
1015         AC_CHECK_HEADERS(pthread.h)
1016
1017         if test $ac_cv_header_pthread_h = yes ; then
1018                 OL_POSIX_THREAD_VERSION
1019
1020                 if test $ol_cv_pthread_version = final ; then
1021                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
1022                                 [define if pthreads API compatible with final spec])
1023                 elif test $ol_cv_pthread_version = draft4 ; then
1024                         AC_DEFINE(HAVE_PTHREADS_D4,1,
1025                                 [define if pthreads API compatible with draft4 spec])
1026                 else
1027                         AC_MSG_ERROR([unknown pthread version])
1028                 fi
1029
1030                 # consider threads found
1031                 ol_with_threads=found
1032
1033                 OL_HEADER_LINUX_THREADS
1034                 OL_HEADER_GNU_PTH_PTHREAD_H
1035
1036                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1037                         AC_CHECK_HEADERS(sched.h)
1038                 fi
1039
1040                 dnl Now the hard part, how to link?
1041                 dnl
1042                 dnl currently supported checks:
1043                 dnl
1044                 dnl Check for no flags
1045                 dnl     pthread_create() in $LIBS
1046                 dnl
1047                 dnl Check special pthread (final) flags
1048                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1049                 dnl     pthread_create() with -kthread (FreeBSD)
1050                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1051                 dnl     pthread_create() with -pthreads (?)
1052                 dnl     pthread_create() with -mthreads (AIX)
1053                 dnl     pthread_create() with -thread (?)
1054                 dnl
1055                 dnl Check pthread (final) libraries
1056                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1057                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1058                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1059                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1060                 dnl     pthread_create() in -lpthread (many)
1061                 dnl     pthread_create() in -lc_r (FreeBSD)
1062                 dnl
1063                 dnl Check pthread (draft4) flags (depreciated)
1064                 dnl     pthread_create() with -threads (OSF/1)
1065                 dnl
1066                 dnl Check pthread (draft4) libraries (depreciated)
1067                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1068                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1069                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1070                 dnl     pthread_create() in -lpthreads (many)
1071                 dnl
1072
1073                 dnl pthread_create in $LIBS
1074                 AC_CACHE_CHECK([for pthread_create in default libraries],
1075                         ol_cv_pthread_create,[
1076                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1077                         [ol_cv_pthread_create=yes],
1078                         [ol_cv_pthread_create=no],
1079                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1080                                 [ol_cv_pthread_create=yes],
1081                                 [ol_cv_pthread_create=no])])])
1082
1083                 if test $ol_cv_pthread_create != no ; then
1084                         ol_link_threads=posix
1085                         ol_link_pthreads=""
1086                 fi
1087
1088 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1089                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1090                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1091                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1092                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1093                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1094
1095                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1096                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1097                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1098                         [ol_cv_pthread_lpthread_lmach_lexc])
1099 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1100 dnl                     [ol_cv_pthread_lpthread_lexc])
1101
1102                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1103                         [ol_cv_pthread_lib_lpthread_woff])
1104
1105                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1106                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1107
1108                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1109
1110                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1111                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1112                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1113                         [ol_cv_pthread_lpthreads_lmach_lexc])
1114                 OL_PTHREAD_TRY([-lpthreads -lexc],
1115                         [ol_cv_pthread_lpthreads_lexc])
1116
1117                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1118
1119                 if test $ol_link_threads != no ; then
1120                         AC_DEFINE(HAVE_PTHREADS,1,
1121                                 [define if you have POSIX Threads])
1122
1123                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1124
1125                         dnl save flags
1126                         save_CPPFLAGS="$CPPFLAGS"
1127                         save_LIBS="$LIBS"
1128                         LIBS="$LTHREAD_LIBS $LIBS"
1129
1130                         dnl All POSIX Thread (final) implementations should have
1131                         dnl sched_yield instead of pthread yield.
1132                         dnl check for both
1133                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1134
1135                         if test $ac_cv_func_sched_yield = no -a \
1136                                 $ac_cv_func_pthread_yield = no ; then
1137                                 dnl Digital UNIX has sched_yield() in -lrt
1138                                 AC_CHECK_LIB(rt, sched_yield,
1139                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1140                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1141                                                 [Define if you have the sched_yield function.])
1142                                         ac_cv_func_sched_yield=yes],
1143                                         [ac_cv_func_sched_yield=no])
1144                         fi
1145                         if test $ac_cv_func_sched_yield = no -a \
1146                                 $ac_cv_func_pthread_yield = no ; then
1147                                 dnl Solaris has sched_yield() stub in -lposix4
1148                                 dnl but we'll use thr_yield instead.
1149                                 AC_CHECK_FUNCS(thr_yield)
1150                         fi
1151                         if test $ac_cv_func_sched_yield = no -a \
1152                                 $ac_cv_func_pthread_yield = no -a \
1153                                 "$ac_cv_func_thr_yield" = no ; then
1154                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1155                         fi
1156
1157                         dnl Check functions for compatibility
1158                         AC_CHECK_FUNCS(pthread_kill)
1159
1160                         dnl Check for pthread_detach with <pthread.h> inclusion
1161                         dnl as it's symbol may have been mangled.
1162                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1163                                 [ol_cv_func_pthread_detach], [
1164                                 dnl save the flags
1165                                 AC_TRY_LINK([
1166 #include <pthread.h>
1167 #ifndef NULL
1168 #define NULL (void*)0
1169 #endif
1170 ],
1171                                         [pthread_detach(NULL);],
1172                                         [ol_cv_func_pthread_detach=yes],
1173                                         [ol_cv_func_pthread_detach=no])
1174                         ])
1175
1176                         if test $ol_cv_func_pthread_detach = no ; then
1177                                 AC_MSG_ERROR([could not locate pthread_detach()])
1178                         fi
1179
1180                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1181                                 [define if you have pthread_detach function])
1182
1183                         dnl Check for setconcurreny functions
1184                         AC_CHECK_FUNCS( \
1185                                 pthread_setconcurrency \
1186                                 pthread_getconcurrency \
1187                                 thr_setconcurrency \
1188                                 thr_getconcurrency \
1189                         )
1190
1191                         OL_SYS_LINUX_THREADS
1192                         OL_LINUX_THREADS
1193
1194                         if test $ol_cv_linux_threads = error; then
1195                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1196                         fi
1197
1198                         AC_CACHE_CHECK([if pthread_create() works],
1199                                 ol_cv_pthread_create_works,[
1200                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1201                                 [ol_cv_pthread_create_works=yes],
1202                                 [ol_cv_pthread_create_works=no],
1203                                 [dnl assume yes
1204                                 ol_cv_pthread_create_works=yes])])
1205
1206                         if test $ol_cv_pthread_create_works = no ; then
1207                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1208                         fi
1209
1210                         dnl Check if select causes an yield
1211                         if test $ol_with_yielding_select = auto ; then
1212                                 AC_CACHE_CHECK([if select yields when using pthreads],
1213                                         ol_cv_pthread_select_yields,[
1214                                 AC_TRY_RUN([
1215 #include <sys/types.h>
1216 #include <sys/time.h>
1217 #include <unistd.h>
1218 #include <pthread.h>
1219 #ifndef NULL
1220 #define NULL (void*) 0
1221 #endif
1222
1223 static int fildes[2];
1224
1225 static void *task(p)
1226         void *p;
1227 {
1228         int i;
1229         struct timeval tv;
1230
1231         fd_set rfds;
1232
1233         tv.tv_sec=10;
1234         tv.tv_usec=0;
1235
1236         FD_ZERO(&rfds);
1237         FD_SET(fildes[0], &rfds);
1238
1239         /* we're not interested in any fds */
1240         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1241
1242         if(i < 0) {
1243                 perror("select");
1244                 exit(10);
1245         }
1246
1247         exit(0); /* if we exit here, the select blocked the whole process */
1248 }
1249
1250 int main(argc, argv)
1251         int argc;
1252         char **argv;
1253 {
1254         pthread_t t;
1255
1256         /* create a pipe to select */
1257         if(pipe(&fildes[0])) {
1258                 perror("select");
1259                 exit(1);
1260         }
1261
1262 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1263         (void) pthread_setconcurrency(2);
1264 #else
1265 #ifdef HAVE_THR_SETCONCURRENCY
1266         /* Set Solaris LWP concurrency to 2 */
1267         thr_setconcurrency(2);
1268 #endif
1269 #endif
1270
1271 #if HAVE_PTHREADS_D4
1272         pthread_create(&t, pthread_attr_default, task, NULL);
1273 #else
1274         pthread_create(&t, NULL, task, NULL);
1275 #endif
1276
1277 #if HAVE_SCHED_YIELD
1278         sched_yield();  /* make sure task runs first */
1279 #else
1280 #ifdef HAVE_PTHREAD_YIELD
1281         pthread_yield();        /* make sure task runs first */
1282 #endif
1283 #endif
1284
1285         exit(2);
1286 }],
1287                                 [ol_cv_pthread_select_yields=no],
1288                                 [ol_cv_pthread_select_yields=yes],
1289                                 [ol_cv_pthread_select_yields=cross])])
1290
1291                                 if test $ol_cv_pthread_select_yields = cross ; then
1292                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1293                                 fi
1294
1295                                 if test $ol_cv_pthread_select_yields = yes ; then
1296                                         ol_with_yielding_select=yes
1297                                 fi
1298                         fi
1299
1300                         dnl restore flags
1301                         CPPFLAGS="$save_CPPFLAGS"
1302                         LIBS="$save_LIBS"
1303                 else
1304                         AC_MSG_ERROR([could not link with POSIX Threads])
1305                 fi
1306         fi
1307
1308         if test $ol_with_threads = posix ; then
1309                 AC_MSG_ERROR([could not locate POSIX Threads])
1310         fi
1311 fi
1312
1313 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1314         -o $ol_with_threads = mach ; then
1315
1316         dnl check for Mach CThreads
1317         AC_CHECK_HEADERS(mach/cthreads.h)
1318         if test $ac_cv_header_mach_cthreads_h = yes ; then
1319                 ol_with_threads=found
1320
1321                 dnl check for cthread support in current $LIBS
1322                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1323
1324                 if test $ol_link_threads = no ; then
1325                         dnl try -all_load
1326                         dnl this test needs work
1327                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1328                                 [ol_cv_cthread_all_load], [
1329                                 dnl save the flags
1330                                 save_LIBS="$LIBS"
1331                                 LIBS="-all_load $LIBS"
1332                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1333                                         cthread_fork((void *)0, (void *)0);
1334                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1335                                 dnl restore the LIBS
1336                                 LIBS="$save_LIBS"
1337                         ])
1338
1339                         if test $ol_cv_cthread_all_load = yes ; then
1340                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1341                                 ol_link_threads=mach
1342                         fi
1343                 fi
1344
1345                 if test $ol_link_threads != no ; then
1346                         : check for cthread specific functionality here
1347                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1348                                 [define if you have Mach Cthreads])
1349                 else
1350                         AC_MSG_ERROR([could not link with Mach CThreads])
1351                 fi
1352         fi
1353
1354         if test $ol_with_threads = mach ; then
1355                 AC_MSG_ERROR([could not locate Mach CThreads])
1356         fi
1357 fi
1358
1359 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1360         -o $ol_with_threads = pth ; then
1361
1362         AC_CHECK_HEADERS(pth.h)
1363
1364         if test $ac_cv_header_pth_h = yes ; then
1365                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1366
1367                 if test $have_pth = yes ; then
1368                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1369                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1370                         ol_link_threads=pth
1371
1372                         if test $ol_with_yielding_select = auto ; then
1373                                 ol_with_yielding_select=yes
1374                         fi
1375                 fi
1376         fi
1377 fi
1378
1379 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1380         -o $ol_with_threads = lwp ; then
1381
1382         dnl check for SunOS5 LWP
1383         AC_CHECK_HEADERS(thread.h synch.h)
1384         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1385                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1386
1387                 if test $have_thr = yes ; then
1388                         AC_DEFINE(HAVE_THR,1,
1389                                 [if you have Solaris LWP (thr) package])
1390                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1391                         ol_link_threads=thr
1392
1393                         if test $ol_with_yielding_select = auto ; then
1394                                 ol_with_yielding_select=yes
1395                         fi
1396
1397                         dnl Check for setconcurreny functions
1398                         AC_CHECK_FUNCS( \
1399                                 thr_setconcurrency \
1400                                 thr_getconcurrency \
1401                         )
1402                 fi
1403         fi
1404
1405         dnl check for SunOS4 LWP
1406         AC_CHECK_HEADERS(lwp/lwp.h)
1407         if test $ac_cv_header_lwp_lwp_h = yes ; then
1408                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1409
1410                 if test $have_lwp = yes ; then
1411                         AC_DEFINE(HAVE_LWP,1,
1412                                 [if you have SunOS LWP package])
1413                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1414                         ol_link_threads=lwp
1415
1416                         if test $ol_with_yielding_select = auto ; then
1417                                 ol_with_yielding_select=no
1418                         fi
1419                 fi
1420         fi
1421 fi
1422
1423 if test $ol_with_yielding_select = yes ; then
1424         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1425                 [define if select implicitly yields])
1426 fi
1427
1428 if test $ol_with_threads = manual ; then
1429         dnl User thinks he can manually configure threads.
1430         ol_link_threads=yes
1431
1432         AC_MSG_WARN([thread defines and link options must be set manually])
1433
1434         AC_CHECK_HEADERS(pthread.h sched.h)
1435         AC_CHECK_FUNCS(sched_yield pthread_yield)
1436         OL_HEADER_LINUX_THREADS
1437
1438         AC_CHECK_HEADERS(mach/cthreads.h)
1439         AC_CHECK_HEADERS(lwp/lwp.h)
1440         AC_CHECK_HEADERS(thread.h synch.h)
1441 fi
1442
1443 if test $ol_link_threads != no -a $ol_link_threads != nt ; then
1444         dnl needed to get reentrant/threadsafe versions
1445         dnl
1446         AC_DEFINE(REENTRANT,1)
1447         AC_DEFINE(_REENTRANT,1)
1448         AC_DEFINE(THREAD_SAFE,1)
1449         AC_DEFINE(_THREAD_SAFE,1)
1450         AC_DEFINE(THREADSAFE,1)
1451         AC_DEFINE(_THREADSAFE,1)
1452         AC_DEFINE(_SGI_MP_SOURCE,1)
1453
1454         dnl The errno declaration may dependent upon _REENTRANT.
1455         dnl If it does, we must link with thread support.
1456         AC_CACHE_CHECK([for thread specific errno],
1457                 [ol_cv_errno_thread_specific], [
1458                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1459                         [ol_cv_errno_thread_specific=yes],
1460                         [ol_cv_errno_thread_specific=no])
1461         ])
1462
1463         dnl The h_errno declaration may dependent upon _REENTRANT.
1464         dnl If it does, we must link with thread support.
1465         AC_CACHE_CHECK([for thread specific h_errno],
1466                 [ol_cv_h_errno_thread_specific], [
1467                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1468                         [ol_cv_h_errno_thread_specific=yes],
1469                         [ol_cv_h_errno_thread_specific=no])
1470         ])
1471
1472         if test $ol_cv_errno_thread_specific != yes \
1473                 -o $ol_cv_h_errno_thread_specific != yes ; then
1474                 LIBS="$LTHREAD_LIBS $LIBS"
1475                 LTHREAD_LIBS=""
1476         fi
1477
1478 dnl When in thread environment, use
1479 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1480 dnl                     || defined( HAVE_FUNC_R )
1481 dnl                     func_r(...);
1482 dnl             #else
1483 dnl             #       if defined( HAVE_THREADS )
1484 dnl                             /* lock */
1485 dnl             #       endif
1486 dnl                             func(...);
1487 dnl             #       if defined( HAVE_THREADS )
1488 dnl                             /* unlock */
1489 dnl             #       endif
1490 dnl             #endif
1491 dnl
1492 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1493 dnl             _POSIX_REENTRANT_FUNCTIONS
1494 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1495 dnl             _POSIX_THREADSAFE_FUNCTIONS
1496 dnl
1497 dnl             and is currently defined in lthread.h
1498 dnl
1499 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1500 dnl
1501 dnl libldap/*.c should only include <lthread.h> iff
1502 dnl LDAP_R_COMPILE is defined.  ie:
1503 dnl             #ifdef LDAP_R_COMPILE
1504 dnl             #       include LDAP_R_COMPILE
1505 dnl             #endif
1506 dnl
1507 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1508 dnl specifically for compiling the threadsafe version of
1509 dnl     the ldap library (-lldap_r).
1510 dnl
1511 dnl     dnl check for reentrant/threadsafe functions
1512 dnl     dnl
1513 dnl     dnl note: these should only be used when linking
1514 dnl     dnl       with $LTHREAD_LIBS
1515 dnl     dnl
1516 dnl     save_CPPFLAGS="$CPPFLAGS"
1517 dnl     save_LIBS="$LIBS"
1518 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1519 dnl     AC_CHECK_FUNCS( \
1520 dnl             gmtime_r \
1521 dnl             gethostbyaddr_r gethostbyname_r \
1522 dnl             feof_unlocked unlocked_feof \
1523 dnl             putc_unlocked unlocked_putc \
1524 dnl             flockfile ftrylockfile \
1525 dnl     )
1526 dnl     CPPFLAGS="$save_CPPFLAGS"
1527 dnl     LIBS="$save_LIBS"
1528 fi
1529
1530 if test $ol_link_threads = no ; then
1531         if test $ol_with_threads = yes ; then
1532                 AC_MSG_ERROR([no suitable thread support])
1533         fi
1534
1535         if test $ol_with_threads = auto ; then
1536                 AC_MSG_WARN([no suitable thread support, disabling threads])
1537                 ol_with_threads=no
1538         fi
1539
1540         AC_DEFINE(NO_THREADS,1,
1541                 [define if you have (or want) no threads])
1542         LTHREAD_LIBS=""
1543 fi
1544
1545 if test $ol_link_threads != no ; then
1546         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1547 fi
1548
1549 dnl ----------------------------------------------------------------
1550
1551 ol_link_ldbm=no
1552 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1553         OL_BERKELEY_DB2
1554
1555         if test $ol_cv_berkeley_db2 = yes ; then
1556                 ol_link_ldbm=db2
1557                 ol_with_ldbm_api=db2
1558
1559                 if test $ol_with_ldbm_type = hash ; then
1560                         AC_DEFINE(LDBM_USE_DBHASH,1,
1561                                 [define this to use DBHASH w/ LDBM backend])
1562                 else
1563                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1564                                 [define this to use DBBTREE w/ LDBM backend])
1565                 fi
1566
1567                 OL_BERKELEY_DB2_DB_THREAD
1568
1569                 dnl $ol_cv_lib_db2 should be yes or -ldb
1570                 dnl (it could be no, but that would be an error
1571                 if test $ol_cv_lib_db2 != yes ; then
1572                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1573                 fi
1574         fi
1575 fi
1576
1577 ol_link_bdb2=no
1578 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1579         if test $ol_cv_berkeley_db2_db_thread != no ; then
1580                 ol_link_bdb2=yes
1581         else
1582                 AC_MSG_WARN([Installed BerkeleyDB does not provide DB_THREAD support.])
1583         fi
1584 fi
1585
1586 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1587         OL_BERKELEY_DB
1588
1589         if test $ol_cv_berkeley_db = yes ; then
1590                 ol_link_ldbm=db
1591                 ol_with_ldbm_api=db
1592
1593                 if test $ol_with_ldbm_type = hash ; then
1594                         AC_DEFINE(LDBM_USE_DBHASH,1,
1595                                 [define this to use DBHASH w/ LDBM backend])
1596                 else
1597                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1598                                 [define this to use DBBTREE w/ LDBM backend])
1599                 fi
1600
1601                 dnl $ol_cv_lib_db should be yes or -ldb
1602                 dnl (it could be no, but that would be an error
1603                 if test $ol_cv_lib_db != yes ; then
1604                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1605                 fi
1606         fi
1607 fi
1608
1609 if test $ol_with_ldbm_api = manual ; then
1610         dnl User thinks he can manually configure LDBM api.
1611         ol_link_ldbm=yes
1612
1613         AC_MSG_WARN([LDBM defines and link options must be set manually])
1614
1615         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1616 fi
1617
1618 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1619         AC_MSG_WARN(Could not find LDBM with BTREE support)
1620         ol_with_ldbm_api=none
1621 fi
1622
1623 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1624         OL_MDBM
1625
1626         if test $ol_cv_mdbm = yes ; then
1627                 ol_link_ldbm=mdbm
1628                 ol_with_ldbm_api=mdbm
1629                 if test $ol_cv_lib_mdbm != yes ; then
1630                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1631                 fi
1632         fi
1633 fi
1634
1635 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1636         OL_GDBM
1637
1638         if test $ol_cv_gdbm = yes ; then
1639                 ol_link_ldbm=gdbm
1640                 ol_with_ldbm_api=gdbm
1641
1642                 if test $ol_cv_lib_gdbm != yes ; then
1643                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1644                 fi
1645         fi
1646 fi
1647
1648 if test $ol_with_ldbm_api = auto ; then
1649         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1650 elif test $ol_with_ldbm_api = ndbm ; then
1651         OL_NDBM
1652
1653         if test $ol_cv_ndbm = yes ; then
1654                 ol_link_ldbm=ndbm
1655                 ol_with_ldbm_api=ndbm
1656
1657                 if test $ol_cv_lib_ndbm != yes ; then
1658                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1659                 fi
1660         fi
1661 fi
1662
1663 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1664         AC_MSG_WARN(could not find suitable LDBM backend)
1665         if test $ol_enable_ldbm = yes ; then
1666                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1667         fi
1668
1669         AC_MSG_WARN(disabling LDBM)
1670         ol_enable_ldbm=no
1671 fi
1672
1673 dnl ----------------------------------------------------------------
1674 if test $ol_enable_dynamic = yes -a $enable_shared = yes ; then
1675         LINK_BINS_DYNAMIC="yes"
1676 else
1677         LINK_BINS_DYNAMIC="no"
1678 fi
1679
1680 dnl ----------------------------------------------------------------
1681 if test $ol_enable_wrappers != no ; then
1682         AC_CHECK_HEADERS(tcpd.h)
1683
1684         if test $ac_cv_header_tcpd_h != yes ; then
1685                 have_wrappers=no
1686         else
1687                 AC_TRY_COMPILE([
1688 int allow_severity = 0;
1689 int deny_severity  = 0;
1690                 ],[hosts_access()],[have_wrappers=yes],[have_wrappers=no])
1691         fi
1692
1693         if test $have_wrappers = yes ; then
1694                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1695                 WRAP_LIBS="-lwrap"
1696
1697                 dnl We add another check for -lnsl since some libwrap's
1698                 dnl need it, but it isn't always included from above
1699                 AC_CHECK_LIB(nsl, main)
1700         else
1701                 AC_MSG_WARN(could not find -lwrap)
1702                 if test $ol_enable_wrappers = yes ; then
1703                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1704                 fi
1705
1706                 AC_MSG_WARN(disabling wrappers support)
1707                 ol_enable_wrappers=no
1708                 WRAP_LIBS=""
1709         fi
1710 fi
1711
1712 dnl ----------------------------------------------------------------
1713 if test $ol_enable_syslog != no ; then
1714         AC_CHECK_FUNC(openlog)
1715         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1716                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1717         fi
1718         ol_enable_syslog=$ac_cv_func_openlog
1719 fi
1720
1721 dnl ----------------------------------------------------------------
1722 if test $ol_enable_dmalloc != no ; then
1723         AC_CHECK_HEADERS(dmalloc.h)
1724         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1725 fi
1726
1727 dnl ----------------------------------------------------------------
1728 dnl TCL
1729 if test $ol_enable_tcl != no ; then
1730         AC_CHECK_HEADERS(tcl.h)
1731
1732         if test $ac_cv_header_tcl_h != yes ; then
1733                 have_tcl=no
1734         else
1735                 for lib in tcl tcl7.6 tcl8.0 tcl8.2 ; do
1736                         AC_CHECK_LIB($lib,main,
1737                           [have_tcl=yes
1738                            if test x"$ol_with_tcl_module" == "xstatic" ; then
1739                                SLAPD_LIBS="$SLAPD_LIBS -l${lib}"
1740                            else
1741                                MOD_TCL_LIB="-l${lib}"
1742                            fi;break],[have_tcl=no])
1743                 done
1744         fi
1745
1746         if test $have_tcl != yes ; then
1747                 AC_MSG_WARN([could not find -ltcl])
1748                 if test $ol_enable_tcl = yes ; then
1749                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1750                 fi
1751
1752                 ol_enable_tcl=no
1753         fi
1754 fi
1755
1756 dnl ----------------------------------------------------------------
1757 dnl ud needs termcap (should insert check here)
1758 ol_link_termcap=no
1759 AC_CHECK_HEADERS(termcap.h ncurses.h)
1760
1761 if test $ol_link_termcap = no ; then
1762         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1763         if test $have_termcap = yes ; then
1764                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1765                 ol_link_termcap=yes
1766                 TERMCAP_LIBS=-ltermcap
1767         fi
1768 fi
1769
1770 if test $ol_link_termcap = no ; then
1771         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1772         if test $have_ncurses = yes ; then
1773                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1774                 ol_link_termcap=yes
1775                 TERMCAP_LIBS=-lncurses
1776         fi
1777 fi
1778
1779 if test $ol_link_termcap = no ; then
1780         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1781         TERMCAP_LIBS=
1782 fi
1783
1784 dnl ----------------------------------------------------------------
1785 dnl
1786 dnl Check for Cyrus SASL
1787 dnl
1788 ol_link_sasl=no
1789 if test $ol_with_cyrus_sasl != no ; then
1790         AC_CHECK_HEADER(sasl.h)
1791
1792         if test $ac_cv_header_sasl_h = yes ; then
1793                 AC_CHECK_LIB(sasl, sasl_client_init,
1794                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1795
1796                 if test $have_cyrus_sasl != no ; then
1797                         SASL_LIBS="-lsasl"
1798                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1799                         ol_link_sasl=yes
1800                 fi
1801         fi
1802
1803         if test $ol_link_sasl = no -a $ol_with_cyrus_sasl = yes ; then
1804                 AC_MSG_ERROR(no suitable API for --with-cyrus-sasl=$ol_with_cyrus_sasl)
1805         fi
1806 fi
1807
1808 dnl ----------------------------------------------------------------
1809 dnl Check for entropy sources
1810 if test $cross_compiling != yes ; then
1811         dev=no
1812         if test -r /dev/urandom ; then
1813                 dev="/dev/urandom";
1814         elif test -r /idev/urandom ; then
1815                 dev="/idev/urandom";
1816         elif test -r /dev/srandom ; then
1817                 dev="/dev/srandom";
1818         elif test -r /dev/random ; then
1819                 dev="/dev/random";
1820         elif test -r /idev/random ; then
1821                 dev="/idev/random";
1822         fi
1823
1824         if test $dev != no ; then
1825                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
1826         fi
1827 fi
1828
1829 dnl ----------------------------------------------------------------
1830 dnl
1831 dnl Check for fetch URL support
1832 dnl             should be extended to support other fetch URL APIs
1833 dnl
1834 ol_link_fetch=no
1835 if test $ol_with_fetch != no ; then
1836         OL_LIB_FETCH
1837
1838         if test $ol_cv_lib_fetch != no ; then
1839                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1840                 ol_link_fetch=freebsd
1841
1842         elif test $ol_with_fetch != auto ; then
1843                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1844         fi
1845 fi
1846
1847 dnl ----------------------------------------------------------------
1848 dnl
1849 dnl Check for GNU readline
1850 dnl
1851 ol_link_readline=no
1852 if test $ol_with_readline != no ; then
1853         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1854
1855         if test $ac_cv_header_readline_readline_h = yes ; then
1856                 save_LIBS="$LIBS"
1857                 LIBS="$TERMCAP_LIBS $LIBS"
1858                 AC_CHECK_LIB(readline, readline,
1859                         [have_readline=yes], [have_readline=no])
1860                 LIBS="$save_LIBS"
1861
1862                 if test $have_readline = yes ; then
1863                         ol_with_readline=found
1864                         ol_link_readline=yes
1865
1866                         READLINE_LIBS="-lreadline"
1867                 fi
1868         fi
1869 fi
1870
1871 if test $ol_link_readline = yes ; then
1872         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1873 fi
1874
1875
1876 dnl ----------------------------------------------------------------
1877 dnl FreeBSD (and others) have crypt(3) in -lcrypt
1878 if test $ol_enable_crypt != no ; then
1879         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1880                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1881                         have_crypt=yes], [have_crypt=no])])
1882
1883         if test $have_crypt = yes ; then
1884                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1885         else
1886                 AC_MSG_WARN(could not find crypt)
1887                 if test $ol_enable_crypt = yes ; then
1888                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1889                 fi
1890
1891                 AC_MSG_WARN(disabling crypt support)
1892                 ol_enable_crypt=no
1893         fi
1894 fi
1895
1896 dnl ----------------------------------------------------------------
1897 dnl FreeBSD (and others) have setproctitle(3) in -lutil
1898 if test $ol_enable_proctitle != no ; then
1899         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1900                 AC_CHECK_LIB(util, setproctitle,
1901                         [have_setproctitle=yes
1902                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1903                         [have_setproctitle=no
1904                         LIBOBJS="$LIBOBJS setproctitle.o"
1905                         LIBSRCS="$LIBSRCS setproctitle.c"])])
1906
1907         if test $have_setproctitle = yes ; then
1908                 AC_DEFINE(HAVE_SETPROCTITLE,1,
1909                         [define if setproctitle(3) is available])
1910         fi
1911 fi
1912
1913 dnl ----------------------------------------------------------------
1914 dnl Checks for typedefs, structures, and compiler characteristics.
1915 AC_TYPE_MODE_T
1916 AC_TYPE_OFF_T
1917 AC_TYPE_PID_T
1918 AM_TYPE_PTRDIFF_T
1919 AC_TYPE_SIGNAL
1920 AC_TYPE_SIZE_T
1921
1922 AC_CHECK_TYPE(ssize_t, [signed int])
1923 AC_CHECK_TYPE(caddr_t,  [char *])
1924
1925 OL_TYPE_SOCKLEN_T
1926 AC_STRUCT_ST_BLKSIZE
1927 AC_HEADER_TIME
1928 AC_STRUCT_TM
1929 AC_TYPE_UID_T
1930 OL_TYPE_SIG_ATOMIC_T
1931
1932 dnl AC_TYPE_GETGROUPS
1933
1934 OL_STRUCT_PASSWD_PW_GECOS
1935 OL_STRUCT_PASSWD_PW_PASSWD
1936
1937 OL_C_UPPER_LOWER
1938 AC_C_CONST
1939 OL_C_VOLATILE
1940
1941 if test $cross_compiling = yes ; then
1942         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1943 else
1944         AC_C_BIGENDIAN
1945 fi
1946
1947 AC_COMPILE_CHECK_SIZEOF(short)
1948 AC_COMPILE_CHECK_SIZEOF(int)
1949 AC_COMPILE_CHECK_SIZEOF(long)
1950
1951 if test "$ac_cv_sizeof_int" -lt 4 ; then
1952         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
1953
1954         AC_DEFINE(LBER_INT_T,long)
1955         AC_DEFINE(LBER_TAG_T,long)
1956         AC_DEFINE(LBER_SOCKET_T,int)
1957 else
1958         AC_DEFINE(LBER_INT_T,int)
1959         AC_DEFINE(LBER_TAG_T,long)
1960         AC_DEFINE(LBER_SOCKET_T,int)
1961 fi
1962
1963 AC_DEFINE(LBER_LEN_T,long)
1964
1965 dnl ----------------------------------------------------------------
1966 dnl Checks for library functions.
1967 AC_FUNC_MEMCMP
1968 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1969 AC_FUNC_STRFTIME
1970 dnl AM_FUNC_STRTOD
1971
1972 OL_FUNC_INET_ATON
1973
1974 dnl Check for NT specific routines
1975 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
1976
1977 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
1978         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
1979 ])
1980
1981 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
1982         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
1983 ])
1984
1985 AC_FUNC_VPRINTF
1986
1987 if test $ac_cv_func_vprintf = yes ; then
1988         dnl check for vsnprintf
1989         AC_CHECK_FUNCS(vsnprintf vsprintf)
1990 fi
1991
1992 AC_CHECK_FUNCS(         \
1993         bcopy                   \
1994         closesocket             \
1995         endgrent                \
1996         endpwent                \
1997         flock                   \
1998         getdtablesize   \
1999         getgrgid                \
2000         gethostname             \
2001         getpass                 \
2002         getpwuid                \
2003         getpwnam                \
2004         getspnam                \
2005         gettimeofday    \
2006         initgroups              \
2007         lockf                   \
2008         memcpy                  \
2009         memmove                 \
2010         mkstemp                 \
2011         pipe                    \
2012         read                    \
2013         recv                    \
2014         recvfrom                \
2015         setpwfile               \
2016         setgid                  \
2017         setegid                 \
2018         setsid                  \
2019         setuid                  \
2020         seteuid                 \
2021         sigaction               \
2022         signal                  \
2023         sigset                  \
2024         snprintf                \
2025         strdup                  \
2026         strerror                \
2027         strpbrk                 \
2028         strrchr                 \
2029         strsep                  \
2030         strstr                  \
2031         strtol                  \
2032         strtoul                 \
2033         strspn                  \
2034         sysconf                 \
2035         waitpid                 \
2036         wait4                   \
2037         write                   \
2038         send                    \
2039         sendto                  \
2040 )
2041
2042 dnl We actually may need to replace more than this.
2043 AC_REPLACE_FUNCS(getopt tempnam)
2044
2045 if test "$ac_cv_func_getopt" != yes; then
2046     LIBSRCS="$LIBSRCS getopt.c"
2047 fi
2048
2049 if test "$ac_cv_func_tempnam" != yes; then
2050     LIBSRCS="$LIBSRCS tempnam.c"
2051 fi
2052
2053 dnl ----------------------------------------------------------------
2054 # Check Configuration
2055 OL_SYS_ERRLIST
2056
2057 dnl ----------------------------------------------------------------
2058 dnl Sort out defines
2059
2060 if test "$ol_enable_debug" != no ; then
2061         AC_DEFINE(LDAP_DEBUG,1,
2062                 [define this to add debugging code])
2063 fi
2064 if test "$ol_enable_syslog" = yes ; then
2065         AC_DEFINE(LDAP_SYSLOG,1,
2066                 [define this to add syslog code])
2067 fi
2068 if test "$ol_enable_libui" = yes ; then
2069         AC_DEFINE(LDAP_LIBUI,1,
2070                 [define this for LDAP User Interface support])
2071 fi
2072 if test "$ol_enable_cache" = no ; then
2073         AC_DEFINE(LDAP_NOCACHE,1,
2074                 [define this to remove -lldap cache support])
2075 fi
2076 if test "$ol_enable_dns" != no ; then
2077         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
2078 fi
2079 if test "$ol_enable_proctitle" != no ; then
2080         AC_DEFINE(LDAP_PROCTITLE,1,
2081                 [define this for LDAP process title support])
2082 fi
2083 if test "$ol_enable_referrals" != no ; then
2084         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
2085 fi
2086 if test "$ol_enable_cldap" != no ; then
2087         AC_DEFINE(LDAP_CONNECTIONLESS,1,[define to support CLDAP])
2088 fi
2089
2090 if test "$ol_enable_crypt" != no ; then
2091         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2092 fi
2093 if test "$ol_enable_cleartext" != no ; then
2094         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2095 fi
2096 if test "$ol_enable_multimaster" != no ; then
2097         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2098 fi
2099 if test "$ol_enable_phonetic" != no ; then
2100         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
2101 fi
2102 if test "$ol_enable_rlookups" != no ; then
2103         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2104 fi
2105 if test "$ol_enable_aci" != no ; then
2106         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2107 fi
2108 if test "$ol_enable_discreteaci" != no ; then
2109         AC_DEFINE(SLAPD_ACI_DISCRETE_RIGHTS,1,[define to support discrete rights in ACIs])
2110 fi
2111
2112 if test "$ol_link_modules" != no ; then
2113         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2114         BUILD_SLAPD=yes
2115         SLAPD_MODULES_LDFLAGS="-dlopen self"
2116 fi
2117
2118 if test "$ol_link_bdb2" != no ; then
2119         AC_DEFINE(SLAPD_BDB2,1,[define to support BDB2 backend])
2120         BUILD_SLAPD=yes
2121         BUILD_BDB2=yes
2122         if test "$ol_with_bdb2_module" != static ; then
2123                 AC_DEFINE(SLAPD_BDB2_DYNAMIC,1,
2124                         [define to support dynamic BDB2 backend])
2125                 BUILD_BDB2=mod
2126                 BUILD_BDB2_DYNAMIC=shared
2127                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-bdb2/back_bdb2.la"
2128         fi
2129 fi
2130
2131 if test "$ol_enable_ldap" != no ; then
2132         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
2133         BUILD_SLAPD=yes
2134         BUILD_LDAP=yes
2135         if test "$ol_with_ldap_module" != static ; then
2136                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
2137                         [define to support dynamic LDAP backend])
2138                 BUILD_LDAP=mod
2139                 BUILD_LDAP_DYNAMIC=shared
2140                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
2141         fi
2142 fi
2143
2144 if test "$ol_link_ldbm" != no ; then
2145         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
2146         BUILD_SLAPD=yes
2147         BUILD_LDBM=yes
2148         if test "$ol_with_ldbm_module" != static ; then
2149                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
2150                         [define to support dynamic LDBM backend])
2151                 BUILD_LDBM=mod
2152                 BUILD_LDBM_DYNAMIC=shared
2153                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
2154         fi
2155 fi
2156
2157 if test "$ol_enable_passwd" != no ; then
2158         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2159         BUILD_SLAPD=yes
2160         BUILD_PASSWD=yes
2161         if test "$ol_with_passwd_module" != static ; then
2162                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2163                         [define to support dynamic PASSWD backend])
2164                 BUILD_PASSWD=mod
2165                 BUILD_PASSWD_DYNAMIC=shared
2166                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
2167         fi
2168 fi
2169
2170 if test "$ol_link_perl" != no ; then
2171         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
2172         BUILD_SLAPD=yes
2173         BUILD_PERL=yes
2174         if test "$ol_with_perl_module" != static ; then
2175                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
2176                         [define to support dynamic PERL backend])
2177                 BUILD_PERL=mod
2178                 BUILD_PERL_DYNAMIC=shared
2179                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-perl/back_perl.la"
2180         fi
2181 fi
2182
2183 if test "$ol_enable_shell" != no ; then
2184         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2185         BUILD_SLAPD=yes
2186         BUILD_SHELL=yes
2187         if test "$ol_with_shell_module" != static ; then
2188                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2189                         [define to support dynamic SHELL backend])
2190                 BUILD_SHELL=mod
2191                 BUILD_SHELL_DYNAMIC=shared
2192                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2193         fi
2194 fi
2195
2196 if test "$ol_enable_tcl" != no ; then
2197         AC_DEFINE(SLAPD_TCL,1,[define to support TCL backend])
2198         BUILD_SLAPD=yes
2199         BUILD_TCL=yes
2200         if test "$ol_with_tcl_module" != static; then
2201                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1,
2202                         [define to support dynamic TCL backend])
2203                 BUILD_TCL=mod
2204                 BUILD_TCL_DYNAMIC=shared
2205                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-tcl/back_tcl.la"
2206         fi
2207 fi
2208
2209 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2210         $BUILD_SLAPD = yes ; then
2211         BUILD_SLURPD=yes
2212 fi
2213
2214 if test "$ol_link_isode" != no ; then
2215         BUILD_LDAPD=yes
2216 fi
2217
2218 dnl ----------------------------------------------------------------
2219
2220 if test "$LINK_BINS_DYNAMIC" = yes; then
2221     LIB_LINKAGE=DYN
2222     LT_LIB_LINKAGE=shared
2223 else
2224     LIB_LINKAGE=STAT
2225     LT_LIB_LINKAGE=static
2226 fi
2227
2228 if test "$ac_cv_mingw32" = yes ; then
2229     PLAT=NT
2230     DYN_EXT=dll
2231 else
2232     PLAT=UNIX
2233     DYN_EXT=so
2234 fi
2235
2236 AC_SUBST(LIBSRCS)
2237
2238 AC_SUBST(PLAT)
2239 AC_SUBST(LIB_LINKAGE)
2240 AC_SUBST(LT_LIB_LINKAGE)
2241 AC_SUBST(DYN_EXT)
2242
2243 AC_SUBST(BUILD_LDAPD)
2244 AC_SUBST(BUILD_SLAPD)
2245   AC_SUBST(BUILD_BDB2)
2246   AC_SUBST(BUILD_LDAP)
2247   AC_SUBST(BUILD_LDBM)
2248   AC_SUBST(BUILD_PASSWD)
2249   AC_SUBST(BUILD_PERL)
2250   AC_SUBST(BUILD_QUIPU)
2251   AC_SUBST(BUILD_SHELL)
2252   AC_SUBST(BUILD_TCL)
2253   AC_SUBST(BUILD_BDB2_DYNAMIC)
2254   AC_SUBST(BUILD_LDAP_DYNAMIC)
2255   AC_SUBST(BUILD_LDBM_DYNAMIC)
2256   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2257   AC_SUBST(BUILD_PERL_DYNAMIC)
2258   AC_SUBST(BUILD_SHELL_DYNAMIC)
2259   AC_SUBST(BUILD_TCL_DYNAMIC)
2260 AC_SUBST(BUILD_SLURPD)
2261
2262 AC_SUBST(LDAP_LIBS)
2263 AC_SUBST(LDAPD_LIBS)
2264 AC_SUBST(LDIF_LIBS)
2265 AC_SUBST(SLAPD_LIBS)
2266 AC_SUBST(SLURPD_LIBS)
2267 AC_SUBST(LDBM_LIBS)
2268 AC_SUBST(LTHREAD_LIBS)
2269 AC_SUBST(LUTIL_LIBS)
2270 AC_SUBST(WRAP_LIBS)
2271 AC_SUBST(MOD_TCL_LIB)
2272 AC_SUBST(LINK_BINS_DYNAMIC)
2273
2274 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2275 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2276 AC_SUBST(SLAPD_MODULES_LIST)
2277
2278 AC_SUBST(PERL_CPPFLAGS)
2279 AC_SUBST(SLAPD_PERL_LDFLAGS)
2280 AC_SUBST(MOD_PERL_LDFLAGS)
2281
2282 AC_SUBST(KRB_LIBS)
2283 AC_SUBST(READLINE_LIBS)
2284 AC_SUBST(SASL_LIBS)
2285 AC_SUBST(TERMCAP_LIBS)
2286 AC_SUBST(TLS_LIBS)
2287 AC_SUBST(MODULES_LIBS)
2288
2289 dnl ----------------------------------------------------------------
2290 dnl final output
2291 dnl
2292
2293 AC_OUTPUT( \
2294 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2295 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2296 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2297 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2298 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2299 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2300 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2301 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2302 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2303 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2304 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2305 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2306 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2307 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2308 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2309 include/Makefile:build/top.mk:include/Makefile.in \
2310 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2311 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2312 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2313 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2314 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2315 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2316 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2317 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2318 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2319 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
2320 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2321 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/mod.mk \
2322 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2323 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2324 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2325 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk \
2326 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2327 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/mod.mk \
2328 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2329 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2330 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2331 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2332 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2333 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2334 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2335 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2336 ,[
2337 date > stamp-h
2338 echo Please \"make depend\" to build dependencies
2339 ])