git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Disable config.cache!
  11 define([AC_CACHE_LOAD], )dnl
  12 define([AC_CACHE_SAVE], )dnl
  13
  14 dnl Configure.in for OpenLDAP
  15 AC_INIT(include/ldap.h)dnl
  16 AC_CONFIG_AUX_DIR(build)dnl
  17 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no defines])dnl
  18 AC_SUBST(PACKAGE)
  19 AC_SUBST(VERSION)
  20 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  21 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  22
  23 dnl We use autoconf features new to 2.13.
  24 dnl     aclocal.m4 should be built using aclocal from automake 1.4
  25 AC_PREREQ(2.13)dnl Required Autoconf version
  26
  27 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  28
  29 dnl
  30 dnl Start Args
  31 AC_MSG_CHECKING(configure arguments)
  32 AC_PREFIX_DEFAULT(/usr/local)
  33
  34 top_builddir=`pwd`
  35 AC_SUBST(top_builddir)dnl
  36
  37 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
  38
  39 ldap_subdir="openldap"
  40
  41 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  42         if test "$withval" = "no"; then
  43                 ldap_subdir=""
  44         elif test "$withval" != "yes"; then
  45                 ldap_subdir="$withval"
  46         fi
  47 ])dnl
  48
  49 AC_SUBST(ldap_subdir)dnl
  50
  51 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  52 dnl ol_enable_syslog=no
  53 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  54 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  55 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  56 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  57 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  58 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  59 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  60         no, [yes no])dnl
  61
  62 dnl General "with" options
  63 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  64
  65 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  66         auto, [auto k5 k4 afs yes no])
  67 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  68         auto, [auto yes no] )
  69 OL_ARG_WITH(threads,[  --with-threads   use threads],
  70         auto, [auto posix mach lwp yes no manual] )
  71 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  72         auto, [auto ssleay openssl yes no] )
  73 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  74         auto, [auto yes no manual] )
  75
  76 dnl Server options
  77
  78 dnl LDAPD OPTIONS
  79 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  80 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  81
  82 dnl SLAPD OPTIONS
  83 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  84 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  85 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  86 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  87 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  88 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
  89 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  90 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  91 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  92
  93 dnl SLAPD Backend options
  94 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
  95 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  96 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  97         [auto db2 db mdbm gdbm ndbm manual])
  98 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  99         [auto btree hash])
 100
 101 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 102 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 103 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 104 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 105
 106 dnl SLURPD OPTIONS
 107 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
 108 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 109
 110 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 111 AM_ENABLE_STATIC
 112 dnl AM_DISABLE_SHARED
 113 AM_ENABLE_SHARED
 114
 115 dnl General "enable" options
 116 # validate options
 117 if test $ol_enable_dns = yes ; then
 118         if test $ol_enable_referrals = no ; then
 119                 AC_MSG_ERROR([DNS requires --enable-referrals])
 120         fi
 121         if test $ol_enable_referrals = auto ; then
 122                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 123                 ol_enable_referrals=yes
 124         fi
 125 fi
 126
 127 if test $ol_enable_slapd = no ; then
 128         dnl SLAPD was specificallly disabled
 129         if test $ol_enable_bdb2 = yes ; then
 130                 AC_MSG_WARN([slapd disabled, ignoring --enable_bdb2 argument])
 131         fi
 132         if test $ol_enable_ldbm = yes ; then
 133                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 134         fi
 135         if test $ol_enable_passwd = yes ; then
 136                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 137         fi
 138         if test $ol_enable_perl = yes ; then
 139                 AC_MSG_WARN([slapd disabled, ignoring --enable_perl argument])
 140         fi
 141         if test $ol_enable_shell = yes ; then
 142                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 143         fi
 144         if test $ol_enable_tcl = yes ; then
 145                 AC_MSG_WARN([slapd disabled, ignoring --enable_tcl argument])
 146         fi
 147         if test $ol_enable_aclgroups = yes ; then
 148                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 149         fi
 150         if test $ol_enable_modules = yes ; then
 151                 AC_MSG_WARN([slapd disabled, ignoring --enable_modules argument])
 152         fi
 153         if test $ol_enable_wrappers = yes ; then
 154                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 155         fi
 156         if test $ol_enable_phonetic = yes ; then
 157                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 158         fi
 159         if test $ol_enable_rlookups = yes ; then
 160                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 161         fi
 162         if test $ol_with_ldbm_api != auto ; then
 163                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 164         fi
 165         if test $ol_with_ldbm_type != auto ; then
 166                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 167         fi
 168         if test $ol_enable_slurpd = yes ; then
 169                 AC_MSG_ERROR([slurpd requires slapd])
 170         fi
 171
 172         # force settings to no
 173         ol_enable_bdb2=no
 174         ol_enable_ldbm=no
 175         ol_enable_passwd=no
 176         ol_enable_perl=no
 177         ol_enable_shell=no
 178         ol_enable_tcl=no
 179
 180         ol_enable_aclgroups=no
 181         ol_enable_modules=no
 182         ol_enable_phonetic=no
 183         ol_enable_rlookups=no
 184         ol_enable_wrappers=no
 185
 186         ol_with_ldbm_api=no
 187         ol_with_ldbm_type=no
 188
 189         ol_enable_slurpd=no
 190
 191 elif test $ol_enable_ldbm = no ; then
 192         dnl SLAPD without LDBM
 193
 194         if test $ol_with_ldbm_api != auto ; then
 195                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 196         fi
 197
 198         if test $ol_with_ldbm_type != auto ; then
 199                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 200         fi
 201
 202         if test $ol_enable_bdb2 = yes ; then
 203                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 204         fi
 205
 206         if test $ol_enable_modules != yes -a \
 207                 $ol_enable_passwd = no -a \
 208                 $ol_enable_perl = no -a \
 209                 $ol_enable_shell = no -a \
 210                 $ol_enable_tcl = no ; then
 211                 AC_MSG_ERROR([slapd requires a backend])
 212         fi
 213
 214         ol_with_ldbm_api=no
 215         ol_with_ldbm_type=no
 216
 217 elif test $ol_enable_bdb2 = yes ; then
 218         dnl SLAPD with BDB2
 219
 220         if test $ol_with_ldbm_api != auto -a \
 221                 $ol_with_ldbm_api != db2 ; then
 222                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 223         fi
 224
 225         ol_with_ldbm_api=db2
 226
 227 else
 228         dnl SLAPD with LDBM
 229
 230         if test $ol_enable_bdb2 != no ; then
 231                 if test $ol_with_ldbm_api != auto -a \
 232                         $ol_with_ldbm_api != db2 ; then
 233                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 234                         ol_enable_bdb2=no
 235                 fi
 236         fi
 237
 238         if test $ol_with_ldbm_api = gdbm -a \
 239                 $ol_with_ldbm_type = btree ; then
 240                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 241         fi
 242         if test $ol_with_ldbm_api = mdbm -a \
 243                 $ol_with_ldbm_type = btree ; then
 244                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 245         fi
 246         if test $ol_with_ldbm_api = ndbm -a \
 247                 $ol_with_ldbm_type = btree ; then
 248                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 249         fi
 250 fi
 251
 252 if test $ol_enable_slurpd = yes ; then
 253         dnl SLURPD was specifically enabled
 254         if test $ol_with_threads = no ; then
 255                 AC_MSG_ERROR([slurpd requires threads])
 256         fi
 257 fi
 258
 259 AC_MSG_RESULT(done)
 260
 261 ## Initialize vars
 262 LDAP_LIBS=
 263 LDBM_LIBS=
 264 LTHREAD_LIBS=
 265 LUTIL_LIBS=
 266
 267 LDAPD_LIBS=
 268 SLAPD_LIBS=
 269 SLURPD_LIBS=
 270
 271 BUILD_LDAPD=no
 272 BUILD_SLAPD=no
 273 BUILD_SLURPD=no
 274
 275 BUILD_BDB2=no
 276 BUILD_LDBM=no
 277 BUILD_PASSWD=no
 278 BUILD_PERL=no
 279 BUILD_SHELL=no
 280 BUILD_TCL=no
 281 BUILD_THREAD=no
 282
 283 SLAPD_MODULES_LDFLAGS=
 284 SLAPD_MODULES_CPPFLAGS=
 285
 286 SLAPD_PERL_LDFLAGS=
 287 SLAPD_PERL_CPPFLAGS=
 288
 289 KRB_LIBS=
 290 READLINE_LIBS=
 291 TERMCAP_LIBS=
 292 TLS_LIBS=
 293
 294 dnl ----------------------------------------------------------------
 295 dnl Checks for programs
 296
 297 AC_PROG_INSTALL
 298
 299 dnl The default compiler is cc (NOT gcc)
 300 CC=${CC-"cc"}
 301 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 302 dnl CFLAGS=${CFLAGS-""}
 303
 304 AM_PROG_LIBTOOL
 305 dnl AC_PROG_MAKE_SET
 306
 307 AC_PROG_AWK
 308 OL_PROG_LN_H
 309 AC_PROG_LN_S
 310
 311 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 312         LN_S="$LN_H"
 313 fi
 314
 315 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 316         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 317 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 318 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 319
 320 ol_link_modules=no
 321 if test $ol_enable_modules != no ; then
 322         AC_PATH_PROG(GLIBCONFIG, glib-config)
 323
 324         if test "no$GLIBCONFIG" = "no" ; then
 325                 if test $ol_enable_modules = yes ; then
 326                         AC_MSG_ERROR([could not locate glib-config])
 327                 fi
 328
 329         else
 330                 SLAPD_MODULES_VERSION="`$GLIBCONFIG --version gmodule`"
 331                 SLAPD_MODULES_CPPFLAGS="`$GLIBCONFIG --cflags gmodule`"
 332                 SLAPD_MODULES_LDFLAGS="`$GLIBCONFIG --libs gmodule`"
 333
 334                 dnl should check glib version
 335                 ol_link_modules=yes
 336         fi
 337 fi
 338
 339 ol_link_perl=no
 340 if test $ol_enable_perl != no ; then
 341         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 342
 343         if test "no$PERLBIN" = "no" ; then
 344                 if test $ol_enable_perl = yes ; then
 345                         AC_MSG_ERROR([could not locate perl])
 346                 fi
 347
 348         else
 349                 SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 350                 SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 351
 352                 dnl should check perl version
 353                 ol_link_perl=yes
 354         fi
 355 fi
 356
 357 AC_PROG_CPP
 358
 359 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 360         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 361
 362 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 363         AC_MSG_WARN([programs compiled here do run here...])
 364         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 365
 366 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 367         AC_MSG_WARN([programs compiled here do not run here...])
 368         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 369 fi
 370
 371 dnl Checks for UNIX Variants
 372 AC_AIX
 373 AC_ISC_POSIX
 374 AC_MINIX
 375
 376 dnl BeOS requires -lbe -lroot -lnet
 377 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot"], :, [-lroot])
 378
 379 dnl Checks for system services
 380 AC_CYGWIN
 381 AC_MINGW32
 382 AC_EXEEXT
 383 AC_OBJEXT
 384
 385 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 386
 387 dnl OpenLDAP requires STDC features
 388 AM_PROG_CC_STDC
 389 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 390         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 391 fi
 392
 393 dnl AM_C_PROTOTYPES
 394
 395 dnl Checks for libraries
 396
 397 dnl Find socket()
 398 dnl Likely combinations:
 399 dnl             -lsocket [ -lnsl_s | -lnsl ]
 400 dnl             -linet
 401
 402 AC_CHECK_FUNC(socket, :, [
 403 dnl
 404 dnl hopefully we won't include too many libraries
 405 dnl
 406         AC_CHECK_LIB(socket, main)
 407         AC_CHECK_LIB(net, main)
 408         AC_CHECK_LIB(net, socket)
 409         AC_CHECK_LIB(nsl_s, main)
 410         AC_CHECK_LIB(nsl, main)
 411         AC_CHECK_LIB(inet, socket)
 412         AC_CHECK_LIB(gen, main)
 413 ])
 414
 415 dnl Check for resolver routines
 416 AC_CHECK_FUNCS(res_search)
 417 if test $ac_cv_func_res_search = "no" ; then
 418         AC_CHECK_LIB(bind, res_search)
 419         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 420                 AC_DEFINE(HAVE_RES_SEARCH,1)
 421         else
 422                 AC_CHECK_LIB(resolv, res_search)
 423                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 424                         AC_DEFINE(HAVE_RES_SEARCH,1)
 425                 fi
 426         fi
 427 fi
 428
 429 dnl HP-UX requires -lV3
 430 AC_CHECK_LIB(V3, sigset)
 431
 432 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 433
 434 dnl Select arg types
 435 dnl (if this detection becomes permenent, it and the select() detection
 436 dnl should be done before the yielding select test)
 437 AC_FUNC_SELECT_ARGTYPES
 438
 439 # ISODE tests
 440 ol_link_isode=no
 441 if test $ol_enable_ldapd != no ; then
 442         dnl look for ISODE libraries
 443         AC_CHECK_LIB(xtpp, main, [
 444                 ol_link_isode=yes
 445                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 446                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 447                 ],:,[-lxtdsap -lxtisode -losi])
 448         AC_CHECK_LIB(dsap, main, [
 449                 ol_link_isode=yes
 450                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 451                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 452                 ],:,[-lisode])
 453         AC_CHECK_LIB(isode, main, [
 454                 ol_link_isode=yes
 455                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 456                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 457                 ],:)
 458 fi
 459
 460 if test $ol_link_isode != no; then
 461         AC_CHECK_LIB(pp, main, [
 462                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 463                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 464                 ],:)
 465
 466         AC_PATH_PROG(PEPSY, pepsy)
 467 fi
 468
 469 dnl
 470 dnl check for kerberos
 471 dnl
 472 ol_link_kerberos=no
 473
 474 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 475         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 476
 477         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 478                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 479                         [-lkrb5 -ldes425])
 480
 481                 if test $have_k5 = yes ; then
 482                         ol_with_kerberos=found
 483                         ol_link_kerberos=yes
 484
 485                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 486
 487                         LIBS="$KRB_LIBS $LIBS"
 488
 489                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 490                                 [ol_cv_var_des_debug], [
 491                                 dnl save the flags
 492                                 save_LIBS="$LIBS"
 493                                 LIBS="$KRB_LIBS $LIBS"
 494                                 AC_TRY_LINK([
 495 #include <kerberosIV/krb.h>
 496 #include <kerberosIV/des.h>
 497 extern int des_debug;
 498 ],[
 499 des_debug = 1;
 500 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 501                                 dnl restore the LIBS
 502                                 LIBS="$save_LIBS"
 503                         ])
 504
 505                         if test $ol_cv_var_des_debug = yes ; then
 506                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 507                                         [define if you have Kerberos des_debug])
 508                         fi
 509
 510                         LIBS="$save_LIBS"
 511                 fi
 512         fi
 513 fi
 514
 515 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 516         AC_CHECK_HEADERS(krb.h des.h)
 517
 518         if test $ac_cv_header_krb_h = yes ; then
 519                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 520
 521                 if test $have_k4 = yes ; then
 522                         ol_with_kerberos=found
 523                         ol_link_kerberos=yes
 524
 525                         KRB_LIBS="-lkrb -ldes"
 526                 fi
 527         fi
 528 fi
 529
 530 if test $ol_link_kerberos = yes ; then
 531         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 532 fi
 533
 534 dnl
 535 dnl Check for SSL/TLS
 536 dnl
 537 ol_link_tls=no
 538 if test $ol_with_tls != no ; then
 539
 540         AC_CHECK_HEADERS(ssl.h)
 541
 542         if test $ac_cv_header_ssl_h = yes ; then
 543                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 544                         [have_ssleay=yes
 545                         need_rsaref=no],
 546                         [have_ssleay=no],
 547                         [-lcrypto])
 548
 549                 if test $have_ssleay = no ; then
 550                         AC_CHECK_LIB(ssl, ssl3_accept,
 551                                 [have_ssleay=yes
 552                                 need_rsaref=yes], [have_ssleay=no],
 553                                 [-lcrypto -lRSAglue -lrsaref])
 554                 fi
 555
 556                 if test $have_ssleay = yes ; then
 557                         ol_with_tls=found
 558                         ol_link_tls=yes
 559
 560                         AC_DEFINE(HAVE_SSLEAY, 1,
 561                                 [define if you have SSLeay or OpenSSL])
 562
 563                         if test $need_rsaref = yes; then
 564                                 AC_DEFINE(HAVE_RSAREF, 1,
 565                                         [define if you have RSAref])
 566
 567                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 568                         else
 569                                 TLS_LIBS="-lssl -lcrypto"
 570                         fi
 571                 fi
 572         fi
 573 fi
 574
 575 if test $ol_link_tls = yes ; then
 576         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 577 fi
 578
 579 dnl Tests for reentrant functions necessary to build a
 580 dnl thread_safe -lldap.
 581 AC_CHECK_FUNCS(         \
 582         ctime_r                 \
 583         gethostbyname_r gethostbyaddr_r \
 584 )
 585
 586 if test "$ac_cv_func_ctime_r" = no ; then
 587         ol_cv_func_ctime_r_nargs=0
 588 else
 589         OL_FUNC_CTIME_R_NARGS
 590 dnl     OL_FUNC_CTIME_R_TYPE
 591 fi
 592
 593 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 594         OL_FUNC_GETHOSTBYNAME_R_NARGS
 595 else
 596         ol_cv_func_gethostbyname_r_nargs=0
 597 fi
 598
 599 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 600         OL_FUNC_GETHOSTBYADDR_R_NARGS
 601 else
 602         ol_cv_func_gethostbyaddr_r_nargs=0
 603 fi
 604
 605 if test "$ac_cv_func_ctime_r" = yes \
 606         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 607         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 608         -a "$ac_cv_func_gethostbyname_r" = yes \
 609         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 610         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 611         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 612         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 613         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 614         ; then
 615
 616         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 617 fi
 618
 619 ol_link_threads=no
 620 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 621         -o $ol_with_threads = posix ; then
 622
 623         AC_CHECK_HEADERS(pthread.h sched.h)
 624
 625         if test $ac_cv_header_pthread_h = yes ; then
 626                 OL_POSIX_THREAD_VERSION
 627
 628                 if test $ol_cv_pthread_version = final ; then
 629                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 630                                 [define if pthreads API compatible with final spec])
 631                 elif test $ol_cv_pthread_version = draft4 ; then
 632                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 633                                 [define if pthreads API compatible with draft4 spec])
 634                 else
 635                         AC_MSG_ERROR([unknown pthread version])
 636                 fi
 637
 638                 # consider threads found
 639                 ol_with_threads=found
 640
 641                 OL_HEADER_LINUX_THREADS
 642
 643                 dnl Now the hard part, how to link?
 644                 dnl
 645                 dnl currently supported checks:
 646                 dnl
 647                 dnl Check for no flags
 648                 dnl     pthread_create() in $LIBS
 649                 dnl
 650                 dnl Check special pthread (final) flags
 651                 dnl     pthread_create() with -mt (Solaris)
 652                 dnl     pthread_create() with -kthread (FreeBSD)
 653                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 654                 dnl     pthread_create() with -pthreads (?)
 655                 dnl     pthread_create() with -thread (?)
 656                 dnl
 657                 dnl Check pthread (final) libraries
 658                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 659                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 660                 dnl     (skipped) pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 661                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
 662                 dnl     pthread_create() in -lpthread (many)
 663                 dnl     pthread_create() in -lc_r (FreeBSD)
 664                 dnl
 665                 dnl Check pthread (draft4) flags (depreciated)
 666                 dnl     pthread_create() with -threads (OSF/1)
 667                 dnl
 668                 dnl Check pthread (draft4) libraries (depreciated)
 669                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 670                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 671                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 672                 dnl     pthread_create() in -lpthreads (many)
 673                 dnl
 674
 675                 dnl pthread_create in $LIBS
 676                 AC_MSG_CHECKING([for pthread_create in default libraries])
 677                 AC_CACHE_VAL(ol_cv_pthread_create,[
 678                 AC_TRY_RUN([
 679 #include <pthread.h>
 680 #ifndef NULL
 681 #define NULL (void*)0
 682 #endif
 683
 684 static void *task(p)
 685         void *p;
 686 {
 687         return (void *) (p == NULL);
 688 }
 689
 690 int main(argc, argv)
 691         int argc;
 692         char **argv;
 693 {
 694         pthread_t t;
 695         int status;
 696
 697         /* make sure pthread_create() isn't just a stub */
 698 #if HAVE_PTHREADS_D4
 699         status = pthread_create(&t, pthread_attr_default, task, NULL);
 700 #else
 701         status = pthread_create(&t, NULL, task, NULL);
 702 #endif
 703
 704         if( status ) return status;
 705
 706         /* make sure pthread_detach() isn't just a stub */
 707 #if HAVE_PTHREADS_D4
 708         status = pthread_detach( &t );
 709 #else
 710         status = pthread_detach( t );
 711 #endif
 712
 713         if( status ) return status;
 714
 715         return status;
 716 }
 717 ],
 718                         [ol_cv_pthread_create=yes],
 719                         [ol_cv_pthread_create=no],
 720                         [dnl assume yes
 721                         ol_cv_pthread_create=yes])])
 722                 AC_MSG_RESULT($ol_cv_pthread_create)
 723
 724                 if test $ol_cv_pthread_create != no ; then
 725                         ol_link_threads=posix
 726                         ol_link_pthreads=""
 727                 fi
 728
 729                 OL_PTHREAD_TRY_LINK([-mt],              [ol_cv_pthread_mt])
 730                 OL_PTHREAD_TRY_LINK([-kthread], [ol_cv_pthread_kthread])
 731                 OL_PTHREAD_TRY_LINK([-pthread], [ol_cv_pthread_pthread])
 732                 OL_PTHREAD_TRY_LINK([-pthreads],[ol_cv_pthread_pthreads])
 733                 OL_PTHREAD_TRY_LINK([-thread],  [ol_cv_pthread_thread])
 734
 735                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc -lc_r],
 736                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
 737                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc],
 738                         [ol_cv_pthread_lpthread_lmach_lexc])
 739 dnl             OL_PTHREAD_TRY_LINK([-lpthread -lexc],
 740 dnl                     [ol_cv_pthread_lpthread_lexc])
 741
 742                 OL_PTHREAD_TRY_LINK([-lpthread -Wl,-woff,85],
 743                         [ol_cv_pthread_lib_lpthread_woff])
 744
 745                 OL_PTHREAD_TRY_LINK([-lpthread],[ol_cv_pthread_lpthread])
 746                 OL_PTHREAD_TRY_LINK([-lc_r],    [ol_cv_pthread_lc_r])
 747
 748                 OL_PTHREAD_TRY_LINK([-threads], [ol_cv_pthread_threads])
 749
 750                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc -lc_r],
 751                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
 752                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc],
 753                         [ol_cv_pthread_lpthreads_lmach_lexc])
 754                 OL_PTHREAD_TRY_LINK([-lpthreads -lexc],
 755                         [ol_cv_pthread_lpthreads_lexc])
 756
 757                 OL_PTHREAD_TRY_LINK([-lpthreads],       [ol_cv_pthread_lib_lpthreads])
 758
 759                 if test $ol_link_threads != no ; then
 760                         AC_DEFINE(HAVE_PTHREADS,1,
 761                                 [define if you have POSIX Threads])
 762
 763                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
 764
 765                         dnl save flags
 766                         save_CPPFLAGS="$CPPFLAGS"
 767                         save_LIBS="$LIBS"
 768                         LIBS="$LTHREAD_LIBS $LIBS"
 769
 770                         dnl All POSIX Thread (final) implementations should have
 771                         dnl sched_yield instead of pthread yield.
 772                         dnl check for both
 773                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 774
 775                         if test $ac_cv_func_sched_yield = no -a \
 776                                 $ac_cv_func_pthread_yield = no ; then
 777                                 dnl Digital UNIX has sched_yield() in -lrt
 778                                 AC_CHECK_LIB(rt, sched_yield,
 779                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 780                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 781                                         ac_cv_func_sched_yield=yes],
 782                                         [ac_cv_func_sched_yield=no])
 783                         fi
 784                         if test $ac_cv_func_sched_yield = no -a \
 785                                 $ac_cv_func_pthread_yield = no ; then
 786                                 dnl Solaris has sched_yield() stub in -lposix4
 787                                 dnl but we'll use thr_yield instead.
 788                                 AC_CHECK_FUNCS(thr_yield)
 789                         fi
 790                         if test $ac_cv_func_sched_yield = no -a \
 791                                 $ac_cv_func_pthread_yield = no -a \
 792                                 "$ac_cv_func_thr_yield" = no ; then
 793                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 794                         fi
 795
 796                         dnl Check functions for compatibility
 797                         AC_CHECK_FUNCS(pthread_kill)
 798
 799                         dnl Check for pthread_detach with <pthread.h> inclusion
 800                         dnl as it's symbol may have been mangled.
 801                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
 802                                 [ol_cv_func_pthread_detach], [
 803                                 dnl save the flags
 804                                 AC_TRY_LINK([
 805 #include <pthread.h>
 806 #ifndef NULL
 807 #define NULL (void*)0
 808 #endif
 809 ],
 810                                         [pthread_detach(NULL);],
 811                                         [ol_cv_func_pthread_detach=yes],
 812                                         [ol_cv_func_pthread_detach=no])
 813                         ])
 814
 815                         if test $ol_cv_func_pthread_detach = no ; then
 816                                 AC_MSG_ERROR([could not locate pthread_detach()])
 817                         fi
 818
 819                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
 820                                 [define if you have pthread_detach function])
 821
 822                         dnl Check for setconcurreny functions
 823                         AC_CHECK_FUNCS( \
 824                                 pthread_setconcurrency \
 825                                 pthread_getconcurrency \
 826                                 thr_setconcurrency \
 827                                 thr_getconcurrency \
 828                         )
 829
 830                         OL_SYS_LINUX_THREADS
 831                         OL_LINUX_THREADS
 832
 833                         if test $ol_cv_linux_threads = error; then
 834                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
 835                         fi
 836
 837                         AC_MSG_CHECKING([if pthread_create() works])
 838                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 839                         AC_TRY_RUN([
 840 #include <pthread.h>
 841 #ifndef NULL
 842 #define NULL (void*)0
 843 #endif
 844
 845 static void *task(p)
 846         void *p;
 847 {
 848         return (void *) (p == NULL);
 849 }
 850
 851 int main(argc, argv)
 852         int argc;
 853         char **argv;
 854 {
 855         pthread_t t;
 856 #if HAVE_PTHREADS_D4
 857         exit(pthread_create(&t, pthread_attr_default, task, NULL));
 858 #else
 859         exit(pthread_create(&t, NULL, task, NULL));
 860 #endif
 861 }
 862 ],
 863                                 [ol_cv_pthread_create_works=yes],
 864                                 [ol_cv_pthread_create_works=no],
 865                                 [dnl assume yes
 866                                 ol_cv_pthread_create_works=yes])])
 867                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 868
 869                         if test $ol_cv_pthread_create_works = no ; then
 870                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
 871                         fi
 872
 873                         dnl Check if select causes an yield
 874                         if test $ol_with_yielding_select = auto ; then
 875                                 AC_MSG_CHECKING([if select yields when using pthreads])
 876                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 877                                 AC_TRY_RUN([
 878 #include <sys/types.h>
 879 #include <sys/time.h>
 880 #include <unistd.h>
 881 #include <pthread.h>
 882 #ifndef NULL
 883 #define NULL (void*) 0
 884 #endif
 885
 886 static int fildes[2];
 887
 888 static void *task(p)
 889         void *p;
 890 {
 891         int i;
 892         struct timeval tv;
 893
 894         fd_set rfds;
 895
 896         tv.tv_sec=10;
 897         tv.tv_usec=0;
 898
 899         FD_ZERO(&rfds);
 900         FD_SET(fildes[0], &rfds);
 901
 902         /* we're not interested in any fds */
 903         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 904
 905         if(i < 0) {
 906                 perror("select");
 907                 exit(10);
 908         }
 909
 910         exit(0); /* if we exit here, the select blocked the whole process */
 911 }
 912
 913 int main(argc, argv)
 914         int argc;
 915         char **argv;
 916 {
 917         pthread_t t;
 918
 919         /* create a pipe to select */
 920         if(pipe(&fildes[0])) {
 921                 perror("select");
 922                 exit(1);
 923         }
 924
 925 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 926         (void) pthread_setconcurrency(2);
 927 #else
 928 #ifdef HAVE_THR_SETCONCURRENCY
 929         /* Set Solaris LWP concurrency to 2 */
 930         thr_setconcurrency(2);
 931 #endif
 932 #endif
 933
 934 #if HAVE_PTHREADS_D4
 935         pthread_create(&t, pthread_attr_default, task, NULL);
 936 #else
 937         pthread_create(&t, NULL, task, NULL);
 938 #endif
 939
 940 #if HAVE_SCHED_YIELD
 941         sched_yield();  /* make sure task runs first */
 942 #else
 943 #ifdef HAVE_PTHREAD_YIELD
 944         pthread_yield();        /* make sure task runs first */
 945 #endif
 946 #endif
 947
 948         exit(2);
 949 }],
 950                                 [ol_cv_pthread_select_yields=no],
 951                                 [ol_cv_pthread_select_yields=yes], [
 952                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
 953                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
 954
 955                                 if test $ol_cv_pthread_select_yields = yes ; then
 956                                         ol_with_yielding_select=yes
 957                                 fi
 958                         fi
 959
 960                         dnl restore flags
 961                         CPPFLAGS="$save_CPPFLAGS"
 962                         LIBS="$save_LIBS"
 963                 else
 964                         AC_MSG_ERROR([could not link with POSIX Threads])
 965                 fi
 966         fi
 967
 968         if test $ol_with_threads = posix ; then
 969                 AC_MSG_ERROR([could not locate POSIX Threads])
 970         fi
 971 fi
 972
 973 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 974         -o $ol_with_threads = mach ; then
 975
 976         dnl check for Mach CThreads
 977         AC_CHECK_HEADERS(mach/cthreads.h)
 978         if test $ac_cv_header_mach_cthreads_h = yes ; then
 979                 ol_with_threads=found
 980
 981                 dnl check for cthread support in current $LIBS
 982                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 983
 984                 if test $ol_link_threads = no ; then
 985                         dnl try -all_load
 986                         dnl this test needs work
 987                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 988                                 [ol_cv_cthread_all_load], [
 989                                 dnl save the flags
 990                                 save_LIBS="$LIBS"
 991                                 LIBS="-all_load $LIBS"
 992                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 993                                         cthread_fork((void *)0, (void *)0);
 994                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 995                                 dnl restore the LIBS
 996                                 LIBS="$save_LIBS"
 997                         ])
 998
 999                         if test $ol_cv_cthread_all_load = yes ; then
1000                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1001                                 ol_link_threads=mach
1002                         fi
1003                 fi
1004
1005                 if test $ol_link_threads != no ; then
1006                         : check for cthread specific functionality here
1007                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1008                                 [define if you have Mach Cthreads])
1009                 else
1010                         AC_MSG_ERROR([could not link with Mach CThreads])
1011                 fi
1012         fi
1013
1014         if test $ol_with_threads = mach ; then
1015                 AC_MSG_ERROR([could not locate Mach CThreads])
1016         fi
1017 fi
1018
1019 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1020         -o $ol_with_threads = lwp ; then
1021
1022         dnl check for SunOS5 LWP
1023         AC_CHECK_HEADERS(thread.h synch.h)
1024         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1025                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1026
1027                 if test $have_thr = yes ; then
1028                         AC_DEFINE(HAVE_THR,1,
1029                                 [if you have Solaris LWP (thr) package])
1030                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1031                         ol_link_threads=thr
1032
1033                         if test $ol_with_yielding_select = auto ; then
1034                                 ol_with_yielding_select=yes
1035                         fi
1036
1037                         dnl Check for setconcurreny functions
1038                         AC_CHECK_FUNCS( \
1039                                 thr_setconcurrency \
1040                                 thr_getconcurrency \
1041                         )
1042                 fi
1043         fi
1044
1045         dnl check for SunOS4 LWP
1046         AC_CHECK_HEADERS(lwp/lwp.h)
1047         if test $ac_cv_header_lwp_lwp_h = yes ; then
1048                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1049
1050                 if test $have_lwp = yes ; then
1051                         AC_DEFINE(HAVE_LWP,1,
1052                                 [if you have SunOS LWP package])
1053                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1054                         ol_link_threads=lwp
1055
1056                         if test $ol_with_yielding_select = auto ; then
1057                                 ol_with_yielding_select=no
1058                         fi
1059                 fi
1060         fi
1061 fi
1062
1063 if test $ol_with_yielding_select = yes ; then
1064         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1065                 [define if select implicitly yields])
1066 fi
1067
1068 if test $ol_with_threads = manual ; then
1069         dnl User thinks he can manually configure threads.
1070         ol_link_threads=yes
1071
1072         AC_MSG_WARN([thread defines and link options must be set manually])
1073
1074         AC_CHECK_HEADERS(pthread.h sched.h)
1075         AC_CHECK_FUNCS(sched_yield pthread_yield)
1076         OL_HEADER_LINUX_THREADS
1077
1078         AC_CHECK_HEADERS(mach/cthreads.h)
1079         AC_CHECK_HEADERS(lwp/lwp.h)
1080         AC_CHECK_HEADERS(thread.h synch.h)
1081 fi
1082
1083 if test $ol_link_threads != no ; then
1084         dnl needed to get reentrant/threadsafe versions
1085         dnl
1086         AC_DEFINE(REENTRANT,1)
1087         AC_DEFINE(_REENTRANT,1)
1088         AC_DEFINE(THREAD_SAFE,1)
1089         AC_DEFINE(_THREAD_SAFE,1)
1090         AC_DEFINE(THREADSAFE,1)
1091         AC_DEFINE(_THREADSAFE,1)
1092
1093         dnl The errno declaration may dependent upon _REENTRANT.
1094         dnl If it does, we must link with thread support.
1095         AC_CACHE_CHECK([for thread specific errno],
1096                 [ol_cv_errno_thread_specific], [
1097                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1098                         [ol_cv_errno_thread_specific=yes],
1099                         [ol_cv_errno_thread_specific=no])
1100         ])
1101
1102         if test $ol_cv_errno_thread_specific != yes ; then
1103                 LIBS="$LTHREAD_LIBS $LIBS"
1104                 LTHREAD_LIBS=""
1105         fi
1106
1107 dnl When in thread environment, use
1108 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1109 dnl                     || defined( HAVE_FUNC_R )
1110 dnl                     func_r(...);
1111 dnl             #else
1112 dnl             #       if defined( HAVE_THREADS )
1113 dnl                             /* lock */
1114 dnl             #       endif
1115 dnl                             func(...);
1116 dnl             #       if defined( HAVE_THREADS )
1117 dnl                             /* unlock */
1118 dnl             #       endif
1119 dnl             #endif
1120 dnl
1121 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1122 dnl             _POSIX_REENTRANT_FUNCTIONS
1123 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1124 dnl             _POSIX_THREADSAFE_FUNCTIONS
1125 dnl
1126 dnl             and is currently defined in lthread.h
1127 dnl
1128 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1129 dnl
1130 dnl libldap/*.c should only include <lthread.h> iff
1131 dnl LDAP_R_COMPILE is defined.  ie:
1132 dnl             #ifdef LDAP_R_COMPILE
1133 dnl             #       include LDAP_R_COMPILE
1134 dnl             #endif
1135 dnl
1136 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1137 dnl specifically for compiling the threadsafe version of
1138 dnl     the ldap library (-lldap_r).
1139 dnl
1140 dnl     dnl check for reentrant/threadsafe functions
1141 dnl     dnl
1142 dnl     dnl note: these should only be used when linking
1143 dnl     dnl       with $LTHREAD_LIBS
1144 dnl     dnl
1145 dnl     save_CPPFLAGS="$CPPFLAGS"
1146 dnl     save_LIBS="$LIBS"
1147 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1148 dnl     AC_CHECK_FUNCS( \
1149 dnl             gmtime_r \
1150 dnl             gethostbyaddr_r gethostbyname_r \
1151 dnl             feof_unlocked unlocked_feof \
1152 dnl             putc_unlocked unlocked_putc \
1153 dnl             flockfile ftrylockfile \
1154 dnl     )
1155 dnl     CPPFLAGS="$save_CPPFLAGS"
1156 dnl     LIBS="$save_LIBS"
1157 fi
1158
1159 if test $ol_link_threads = no ; then
1160         if test $ol_with_threads = yes ; then
1161                 AC_MSG_ERROR([no suitable thread support])
1162         fi
1163
1164         if test $ol_with_threads = auto ; then
1165                 AC_MSG_WARN([no suitable thread support, disabling threads])
1166                 ol_with_threads=no
1167         fi
1168
1169         AC_DEFINE(NO_THREADS,1,
1170                 [define if you have (or want) no threads])
1171         LTHREAD_LIBS=""
1172 fi
1173
1174 if test $ol_link_threads != no ; then
1175         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1176 fi
1177
1178 dnl ----------------------------------------------------------------
1179
1180 ol_link_ldbm=no
1181 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1182         OL_BERKELEY_DB2
1183
1184         if test $ol_cv_berkeley_db2 = yes ; then
1185                 ol_link_ldbm=db2
1186                 ol_with_ldbm_api=db2
1187
1188                 if test $ol_with_ldbm_type = hash ; then
1189                         AC_DEFINE(LDBM_USE_DBHASH,1)
1190                 else
1191                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1192                 fi
1193
1194                 dnl $ol_cv_lib_db2 should be yes or -ldb
1195                 dnl (it could be no, but that would be an error
1196                 if test $ol_cv_lib_db2 != yes ; then
1197                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1198                 fi
1199         fi
1200 fi
1201
1202 ol_link_bdb2=no
1203 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1204         ol_link_bdb2=yes
1205 fi
1206
1207 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1208         OL_BERKELEY_DB
1209
1210         if test $ol_cv_berkeley_db = yes ; then
1211                 ol_link_ldbm=db
1212                 ol_with_ldbm_api=db
1213
1214                 if test $ol_with_ldbm_type = hash ; then
1215                         AC_DEFINE(LDBM_USE_DBHASH,1)
1216                 else
1217                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1218                 fi
1219
1220                 dnl $ol_cv_lib_db should be yes or -ldb
1221                 dnl (it could be no, but that would be an error
1222                 if test $ol_cv_lib_db != yes ; then
1223                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1224                 fi
1225         fi
1226 fi
1227
1228 if test $ol_with_ldbm_api = manual ; then
1229         dnl User thinks he can manually configure LDBM api.
1230         ol_link_ldbm=yes
1231
1232         AC_MSG_WARN([LDBM defines and link options must be set manually])
1233
1234         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1235 fi
1236
1237 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1238         AC_MSG_WARN(Could not find LDBM with BTREE support)
1239         ol_with_ldbm_api=none
1240 fi
1241
1242 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1243         OL_MDBM
1244
1245         if test $ol_cv_mdbm = yes ; then
1246                 ol_link_ldbm=mdbm
1247                 ol_with_ldbm_api=mdbm
1248                 if test $ol_cv_lib_mdbm != yes ; then
1249                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1250                 fi
1251         fi
1252 fi
1253
1254 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1255         OL_GDBM
1256
1257         if test $ol_cv_gdbm = yes ; then
1258                 ol_link_ldbm=gdbm
1259                 ol_with_ldbm_api=gdbm
1260
1261                 if test $ol_cv_lib_gdbm != yes ; then
1262                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1263                 fi
1264         fi
1265 fi
1266
1267 if test $ol_with_ldbm_api = auto ; then
1268         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1269 elif test $ol_with_ldbm_api = ndbm ; then
1270         OL_NDBM
1271
1272         if test $ol_cv_ndbm = yes ; then
1273                 ol_link_ldbm=ndbm
1274                 ol_with_ldbm_api=ndbm
1275
1276                 if test $ol_cv_lib_ndbm != yes ; then
1277                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1278                 fi
1279         fi
1280 fi
1281
1282 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1283         AC_MSG_WARN(could not find suitable LDBM backend)
1284         if test $ol_enable_ldbm = yes ; then
1285                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1286         fi
1287
1288         AC_MSG_WARN(disabling LDBM)
1289         ol_enable_ldbm=no
1290 fi
1291
1292 if test $ol_enable_wrappers != no ; then
1293         AC_CHECK_HEADERS(tcpd.h)
1294
1295         if test $ac_cv_header_tcpd_h != yes ; then
1296                 have_wrappers=no
1297         else
1298                 AC_CHECK_LIB(wrap, main,
1299                         [have_wrappers=yes], [have_wrappers=no])
1300         fi
1301
1302         if test $have_wrappers = yes ; then
1303                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1304                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1305
1306                 dnl We add another check for -lnsl since some libwrap's
1307                 dnl need it, but it isn't always included from above
1308                 AC_CHECK_LIB(nsl, main)
1309         else
1310                 AC_MSG_WARN(could not find -lwrap)
1311                 if test $ol_enable_wrappers = yes ; then
1312                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1313                 fi
1314
1315                 AC_MSG_WARN(disabling wrappers support)
1316                 ol_enable_wrappers=no
1317         fi
1318 fi
1319
1320 if test $ol_enable_syslog != no ; then
1321         AC_CHECK_FUNC(openlog)
1322         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1323                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1324         fi
1325         ol_enable_syslog=$ac_cv_func_openlog
1326 fi
1327
1328 if test $ol_enable_dmalloc != no ; then
1329         AC_CHECK_HEADERS(dmalloc.h)
1330         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1331 fi
1332
1333 if test $ol_enable_tcl != no ; then
1334         AC_CHECK_HEADERS(tcl.h)
1335
1336         if test $ac_cv_header_tcl_h != yes ; then
1337                 have_tcl=no
1338         else
1339                 AC_CHECK_LIB(tcl,main,
1340                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1341                         [have_tcl=no])
1342
1343                 if test $have_tcl != yes; then
1344                         AC_CHECK_LIB(tcl7.6,main,
1345                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1346                                 [have_tcl=no])
1347                 fi
1348
1349                 if test $have_tcl != yes; then
1350                         AC_CHECK_LIB(tcl8.0,main,
1351                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1352                                 [have_tcl=no])
1353                 fi
1354         fi
1355
1356         if test $have_tcl != yes ; then
1357                 AC_MSG_WARN([could not find -ltcl])
1358                 if test $ol_enable_tcl = yes ; then
1359                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1360                 fi
1361
1362                 ol_enable_tcl=no
1363         fi
1364 fi
1365
1366 # ud needs termcap (should insert check here)
1367 ol_link_termcap=no
1368 AC_CHECK_HEADERS(termcap.h ncurses.h)
1369
1370 if test $ol_link_termcap = no ; then
1371         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1372         if test $have_termcap = yes ; then
1373                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1374                 ol_link_termcap=yes
1375                 TERMCAP_LIBS=-ltermcap
1376         fi
1377 fi
1378
1379 if test $ol_link_termcap = no ; then
1380         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1381         if test $have_ncurses = yes ; then
1382                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1383                 ol_link_termcap=yes
1384                 TERMCAP_LIBS=-lncurses
1385         fi
1386 fi
1387
1388 if test $ol_link_termcap = no ; then
1389         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1390         TERMCAP_LIBS=
1391 fi
1392
1393 dnl
1394 dnl Check for GNU readline
1395 dnl
1396 ol_link_readline=no
1397 if test $ol_with_readline != no ; then
1398         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1399
1400         if test $ac_cv_header_readline_readline_h = yes ; then
1401                 save_LIBS="$LIBS"
1402                 LIBS="$TERMCAP_LIBS $LIBS"
1403                 AC_CHECK_LIB(readline, readline,
1404                         [have_readline=yes], [have_readline=no])
1405                 LIBS="$save_LIBS"
1406
1407                 if test $have_readline = yes ; then
1408                         ol_with_readline=found
1409                         ol_link_readline=yes
1410
1411                         READLINE_LIBS="-lreadline"
1412                 fi
1413         fi
1414 fi
1415
1416 if test $ol_link_readline = yes ; then
1417         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1418 fi
1419
1420
1421 # FreeBSD (and others) have crypt(3) in -lcrypt
1422 if test $ol_enable_crypt != no ; then
1423         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1424                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1425                         have_crypt=yes], [have_crypt=no])])
1426
1427         if test $have_crypt = yes ; then
1428                 AC_DEFINE(HAVE_CRYPT,1)
1429         else
1430                 AC_MSG_WARN(could not find crypt)
1431                 if test $ol_enable_crypt = yes ; then
1432                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1433                 fi
1434
1435                 AC_MSG_WARN(disabling crypt support)
1436                 ol_enable_crypt=no
1437         fi
1438 fi
1439
1440 # FreeBSD (and others) have setproctitle(3) in -lutil
1441 if test $ol_enable_proctitle != no ; then
1442         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1443                 AC_CHECK_LIB(util, setproctitle,
1444                         [have_setproctitle=yes
1445                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1446                         [have_setproctitle=no
1447                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1448
1449         if test $have_setproctitle = yes ; then
1450                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1451         fi
1452 fi
1453
1454 dnl ----------------------------------------------------------------
1455 dnl Checks for header files.
1456 OL_HEADER_STDC
1457
1458 if test $ol_cv_header_stdc != yes; then
1459         AC_MSG_WARN([could not locate Standard C compliant headers])
1460 fi
1461
1462 AC_HEADER_DIRENT
1463 AC_HEADER_SYS_WAIT
1464 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1465 if test $am_cv_sys_posix_termios = yes ; then
1466         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1467                 [define if you have POSIX termios])
1468 fi
1469
1470 AC_CHECK_HEADERS(       \
1471         arpa/inet.h             \
1472         arpa/nameser.h  \
1473         assert.h                \
1474         crypt.h                 \
1475         errno.h                 \
1476         fcntl.h                 \
1477         filio.h                 \
1478         getopt.h                \
1479         grp.h                   \
1480         libutil.h               \
1481         limits.h                \
1482         locale.h                \
1483         malloc.h                \
1484         memory.h                \
1485         regex.h                 \
1486         psap.h                  \
1487         pwd.h                   \
1488         resolv.h                \
1489         sgtty.h                 \
1490         stdarg.h                \
1491         stddef.h                \
1492         string.h                \
1493         strings.h               \
1494         sysexits.h              \
1495         sys/file.h              \
1496         sys/filio.h             \
1497         sys/errno.h             \
1498         sys/ioctl.h             \
1499         sys/param.h             \
1500         sys/resource.h  \
1501         sys/select.h    \
1502         sys/socket.h    \
1503         sys/syslog.h    \
1504         sys/time.h              \
1505         sys/types.h             \
1506         syslog.h                \
1507         termios.h               \
1508         unistd.h                \
1509 )
1510
1511 dnl ----------------------------------------------------------------
1512 dnl Checks for typedefs, structures, and compiler characteristics.
1513 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1514 AC_TYPE_MODE_T
1515 AC_TYPE_OFF_T
1516 AC_TYPE_PID_T
1517 AM_TYPE_PTRDIFF_T
1518 AC_TYPE_SIGNAL
1519 OL_TYPE_SIG_ATOMIC_T
1520 AC_TYPE_SIZE_T
1521 AC_STRUCT_ST_BLKSIZE
1522 AC_HEADER_TIME
1523 AC_STRUCT_TM
1524 OL_STRUCT_PASSWD_PW_GECOS
1525
1526 OL_C_UPPER_LOWER
1527 AC_C_CONST
1528 OL_C_VOLATILE
1529
1530 if test $cross_compiling = yes ; then
1531         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1532 else
1533         AC_C_BIGENDIAN
1534         AC_CHECK_SIZEOF(short)
1535         AC_CHECK_SIZEOF(int)
1536         AC_CHECK_SIZEOF(long)
1537 fi
1538
1539 dnl ----------------------------------------------------------------
1540 dnl Checks for library functions.
1541 AC_FUNC_MEMCMP
1542 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1543 AC_FUNC_STRFTIME
1544 dnl AM_FUNC_STRTOD
1545
1546 dnl we should use vfork instead of fork in a number of places...
1547 dnl AC_FUNC_VFORK
1548 AC_FUNC_VPRINTF
1549
1550 if test $ac_cv_func_vprintf = yes ; then
1551         dnl check for vsnprintf
1552         AC_CHECK_FUNCS(vsnprintf vsprintf)
1553 fi
1554
1555 AC_CHECK_FUNCS(         \
1556         bcopy                   \
1557         endgrent                \
1558         endpwent                \
1559         flock                   \
1560         getdtablesize   \
1561         getgrgid                \
1562         gethostname             \
1563         getpass                 \
1564         getpwuid                \
1565         gettimeofday    \
1566         initgroups              \
1567         lockf                   \
1568         memcpy                  \
1569         memmove                 \
1570         mkstemp                 \
1571         recv                    \
1572         recvfrom                \
1573         setpwfile               \
1574         setgid                  \
1575         setegid                 \
1576         setsid                  \
1577         setuid                  \
1578         seteuid                 \
1579         signal                  \
1580         sigset                  \
1581         snprintf                \
1582         strdup                  \
1583         strerror                \
1584         strpbrk                 \
1585         strrchr                 \
1586         strsep                  \
1587         strstr                  \
1588         strtol                  \
1589         strtoul                 \
1590         strspn                  \
1591         sysconf                 \
1592         waitpid                 \
1593         wait4                   \
1594 )
1595
1596 dnl We actually may need to replace more than this.
1597 AC_REPLACE_FUNCS(getopt tempnam)
1598
1599 dnl ----------------------------------------------------------------
1600 # Check Configuration
1601 OL_SYS_ERRLIST
1602
1603 dnl ----------------------------------------------------------------
1604 dnl Check our declaration of strdup()
1605 OL_DECL_STRDUP
1606
1607 dnl ----------------------------------------------------------------
1608 dnl Sort out defines
1609
1610 if test "$ol_enable_debug" != no ; then
1611         AC_DEFINE(LDAP_DEBUG,1)
1612 fi
1613 if test "$ol_enable_syslog" = yes ; then
1614         AC_DEFINE(LDAP_SYSLOG,1)
1615 fi
1616 if test "$ol_enable_libui" = yes ; then
1617         AC_DEFINE(LDAP_LIBUI,1)
1618 fi
1619 if test "$ol_enable_cache" = no ; then
1620         AC_DEFINE(LDAP_NOCACHE,1)
1621 fi
1622 if test "$ol_enable_dns" != no ; then
1623         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1624 fi
1625 if test "$ol_enable_proctitle" != no ; then
1626         AC_DEFINE(LDAP_PROCTITLE,1)
1627 fi
1628 if test "$ol_enable_referrals" != no ; then
1629         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1630 fi
1631 if test "$ol_enable_cldap" != no ; then
1632         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1633 fi
1634
1635 if test "$ol_enable_aclgroups" != no ; then
1636         AC_DEFINE(SLAPD_ACLGROUPS,1)
1637 fi
1638 if test "$ol_enable_crypt" != no ; then
1639         AC_DEFINE(SLAPD_CRYPT,1)
1640 fi
1641 if test "$ol_enable_cleartext" != no ; then
1642         AC_DEFINE(SLAPD_CLEARTEXT,1)
1643 fi
1644 if test "$ol_enable_phonetic" != no ; then
1645         AC_DEFINE(SLAPD_PHONETIC,1)
1646 fi
1647 if test "$ol_enable_rlookups" != no ; then
1648         AC_DEFINE(SLAPD_RLOOKUPS,1)
1649 fi
1650
1651 if test "$ol_link_modules" != no ; then
1652         AC_DEFINE(SLAPD_MODULES,1)
1653         BUILD_SLAPD=yes
1654 fi
1655
1656 if test "$ol_link_bdb2" != no ; then
1657         AC_DEFINE(SLAPD_BDB2,1)
1658         BUILD_SLAPD=yes
1659         BUILD_BDB2=yes
1660 fi
1661
1662 if test "$ol_link_ldbm" != no ; then
1663         AC_DEFINE(SLAPD_LDBM,1)
1664         BUILD_SLAPD=yes
1665         BUILD_LDBM=yes
1666 fi
1667
1668 if test "$ol_enable_passwd" != no ; then
1669         AC_DEFINE(SLAPD_PASSWD,1)
1670         BUILD_SLAPD=yes
1671         BUILD_PASSWD=yes
1672 fi
1673
1674 if test "$ol_link_perl" != no ; then
1675         AC_DEFINE(SLAPD_PERL,1)
1676         BUILD_SLAPD=yes
1677         BUILD_PERL=yes
1678 fi
1679
1680 if test "$ol_enable_shell" != no ; then
1681         AC_DEFINE(SLAPD_SHELL,1)
1682         BUILD_SLAPD=yes
1683         BUILD_SHELL=yes
1684 fi
1685
1686 if test "$ol_enable_tcl" != no ; then
1687         AC_DEFINE(SLAPD_TCL,1)
1688         BUILD_SLAPD=yes
1689         BUILD_TCL=yes
1690 fi
1691
1692 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1693         $BUILD_SLAPD = yes ; then
1694         BUILD_SLURPD=yes
1695 fi
1696
1697 if test "$ol_link_isode" != no ; then
1698         BUILD_LDAPD=yes
1699 fi
1700
1701 dnl ----------------------------------------------------------------
1702
1703 AC_SUBST(BUILD_LDAPD)
1704 AC_SUBST(BUILD_SLAPD)
1705   AC_SUBST(BUILD_BDB2)
1706   AC_SUBST(BUILD_LDBM)
1707   AC_SUBST(BUILD_PASSWD)
1708   AC_SUBST(BUILD_PERL)
1709   AC_SUBST(BUILD_SHELL)
1710   AC_SUBST(BUILD_TCL)
1711 AC_SUBST(BUILD_SLURPD)
1712
1713 AC_SUBST(LDAP_LIBS)
1714 AC_SUBST(LDAPD_LIBS)
1715 AC_SUBST(SLAPD_LIBS)
1716 AC_SUBST(SLURPD_LIBS)
1717 AC_SUBST(LDBM_LIBS)
1718 AC_SUBST(LTHREAD_LIBS)
1719 AC_SUBST(LUTIL_LIBS)
1720
1721 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
1722 AC_SUBST(SLAPD_MODULES_LDFLAGS)
1723
1724 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1725 AC_SUBST(SLAPD_PERL_LDFLAGS)
1726
1727 AC_SUBST(KRB_LIBS)
1728 AC_SUBST(READLINE_LIBS)
1729 AC_SUBST(TERMCAP_LIBS)
1730 AC_SUBST(TLS_LIBS)
1731
1732 dnl ----------------------------------------------------------------
1733 dnl final output
1734 dnl
1735
1736 AC_OUTPUT( \
1737 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1738 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1739 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1740 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1741 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1742 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1743 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1744 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1745 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1746 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1747 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1748 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1749 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1750 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1751 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1752 include/Makefile:build/top.mk:include/Makefile.in \
1753 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1754 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1755 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1756 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1757 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1758 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1759 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1760 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1761 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1762 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1763 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1764 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
1765 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1766 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1767 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
1768 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1769 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
1770 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1771 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1772 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1773 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
1774 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
1775 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
1776 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
1777 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
1778 ,[
1779 date > stamp-h
1780 echo Please \"make depend\" to build dependencies
1781 ])