git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Disable config.cache!
  11 define([AC_CACHE_LOAD], )dnl
  12 define([AC_CACHE_SAVE], )dnl
  13
  14 dnl Configure.in for OpenLDAP
  15 AC_INIT(build/version)dnl
  16 AC_CONFIG_AUX_DIR(build)dnl
  17
  18 OL_VERSION=`cat $ac_aux_dir/version`
  19 if test -z "$OL_VERSION"; then
  20         AC_MSG_ERROR([could not determine version])
  21 fi
  22
  23 dnl ----------------------------------------------------------------
  24 dnl Determine host platform
  25 dnl             we try not to use this for much
  26 AC_CANONICAL_SYSTEM
  27
  28 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  29 AC_SUBST(PACKAGE)
  30 AC_SUBST(VERSION)
  31 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  32 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  33
  34 dnl We use autoconf features new to 2.13.
  35 dnl     aclocal.m4 should be built using aclocal from automake 1.4
  36 AC_PREREQ(2.13)dnl Required Autoconf version
  37
  38 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  39
  40 dnl
  41 dnl Start Args
  42 AC_MSG_CHECKING(configure arguments)
  43 AC_PREFIX_DEFAULT(/usr/local)
  44
  45 top_builddir=`pwd`
  46 AC_SUBST(top_builddir)dnl
  47
  48 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
  49
  50 ldap_subdir="openldap"
  51
  52 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  53         if test "$withval" = "no"; then
  54                 ldap_subdir=""
  55         elif test "$withval" != "yes"; then
  56                 ldap_subdir="$withval"
  57         fi
  58 ])dnl
  59
  60 AC_SUBST(ldap_subdir)dnl
  61
  62 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  63 dnl ol_enable_syslog=no
  64 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  65 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  66 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  67 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  68 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  69 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  70 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  71         no, [yes no])dnl
  72
  73 dnl General "with" options
  74 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  75
  76 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  77         auto, [auto k5 k4 afs yes no])
  78 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  79         auto, [auto yes no] )
  80 OL_ARG_WITH(threads,[  --with-threads   use threads],
  81         auto, [auto posix mach lwp yes no manual] )
  82 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  83         auto, [auto ssleay openssl yes no] )
  84 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  85         auto, [auto yes no manual] )
  86
  87 dnl Server options
  88
  89 dnl LDAPD OPTIONS
  90 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  91 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  92
  93 dnl SLAPD OPTIONS
  94 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  95 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  96 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  97 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  98 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  99 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
 100 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
 101 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
 102 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
 103
 104 dnl SLAPD Backend options
 105 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 106 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 107 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 108 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 109         [auto db2 db mdbm gdbm ndbm manual])
 110 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 111         [auto btree hash])
 112
 113 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 114 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 115 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 116 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 117
 118 dnl SLURPD OPTIONS
 119 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
 120 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 121
 122 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 123 AM_ENABLE_STATIC
 124 dnl AM_DISABLE_SHARED
 125 AM_ENABLE_SHARED
 126
 127 dnl General "enable" options
 128 # validate options
 129 if test $ol_enable_dns = yes ; then
 130         if test $ol_enable_referrals = no ; then
 131                 AC_MSG_ERROR([DNS requires --enable-referrals])
 132         fi
 133         if test $ol_enable_referrals = auto ; then
 134                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 135                 ol_enable_referrals=yes
 136         fi
 137 fi
 138
 139 if test $ol_enable_slapd = no ; then
 140         dnl SLAPD was specificallly disabled
 141         if test $ol_enable_bdb2 = yes ; then
 142                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 143         fi
 144         if test $ol_enable_ldap = yes ; then
 145                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 146         fi
 147         if test $ol_enable_ldbm = yes ; then
 148                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 149         fi
 150         if test $ol_enable_passwd = yes ; then
 151                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 152         fi
 153         if test $ol_enable_perl = yes ; then
 154                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 155         fi
 156         if test $ol_enable_shell = yes ; then
 157                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 158         fi
 159         if test $ol_enable_tcl = yes ; then
 160                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 161         fi
 162         if test $ol_enable_aclgroups = yes ; then
 163                 AC_MSG_WARN([slapd disabled, ignoring --enable-aclgroups argument])
 164         fi
 165         if test $ol_enable_modules = yes ; then
 166                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 167         fi
 168         if test $ol_enable_wrappers = yes ; then
 169                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 170         fi
 171         if test $ol_enable_phonetic = yes ; then
 172                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 173         fi
 174         if test $ol_enable_rlookups = yes ; then
 175                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 176         fi
 177         if test $ol_with_ldbm_api != auto ; then
 178                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 179         fi
 180         if test $ol_with_ldbm_type != auto ; then
 181                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 182         fi
 183         if test $ol_enable_slurpd = yes ; then
 184                 AC_MSG_ERROR([slurpd requires slapd])
 185         fi
 186
 187         # force settings to no
 188         ol_enable_bdb2=no
 189         ol_enable_ldap=no
 190         ol_enable_ldbm=no
 191         ol_enable_passwd=no
 192         ol_enable_perl=no
 193         ol_enable_shell=no
 194         ol_enable_tcl=no
 195
 196         ol_enable_aclgroups=no
 197         ol_enable_modules=no
 198         ol_enable_phonetic=no
 199         ol_enable_rlookups=no
 200         ol_enable_wrappers=no
 201
 202         ol_with_ldbm_api=no
 203         ol_with_ldbm_type=no
 204
 205         ol_enable_slurpd=no
 206
 207 elif test $ol_enable_ldbm = no ; then
 208         dnl SLAPD without LDBM
 209
 210         if test $ol_with_ldbm_api != auto ; then
 211                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 212         fi
 213
 214         if test $ol_with_ldbm_type != auto ; then
 215                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 216         fi
 217
 218         if test $ol_enable_bdb2 = yes ; then
 219                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 220         fi
 221
 222         if test $ol_enable_modules != yes -a \
 223                 $ol_enable_ldap = no -a \
 224                 $ol_enable_passwd = no -a \
 225                 $ol_enable_perl = no -a \
 226                 $ol_enable_shell = no -a \
 227                 $ol_enable_tcl = no ; then
 228                 AC_MSG_ERROR([slapd requires a backend])
 229         fi
 230
 231         ol_with_ldbm_api=no
 232         ol_with_ldbm_type=no
 233
 234 elif test $ol_enable_bdb2 = yes ; then
 235         dnl SLAPD with BDB2
 236
 237         if test $ol_with_ldbm_api != auto -a \
 238                 $ol_with_ldbm_api != db2 ; then
 239                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 240         fi
 241
 242         ol_with_ldbm_api=db2
 243
 244 else
 245         dnl SLAPD with LDBM
 246
 247         if test $ol_enable_bdb2 != no ; then
 248                 if test $ol_with_ldbm_api != auto -a \
 249                         $ol_with_ldbm_api != db2 ; then
 250                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 251                         ol_enable_bdb2=no
 252                 fi
 253         fi
 254
 255         if test $ol_with_ldbm_api = gdbm -a \
 256                 $ol_with_ldbm_type = btree ; then
 257                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 258         fi
 259         if test $ol_with_ldbm_api = mdbm -a \
 260                 $ol_with_ldbm_type = btree ; then
 261                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 262         fi
 263         if test $ol_with_ldbm_api = ndbm -a \
 264                 $ol_with_ldbm_type = btree ; then
 265                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 266         fi
 267 fi
 268
 269 if test $ol_enable_slurpd = yes ; then
 270         dnl SLURPD was specifically enabled
 271         if test $ol_with_threads = no ; then
 272                 AC_MSG_ERROR([slurpd requires threads])
 273         fi
 274 fi
 275
 276 AC_MSG_RESULT(done)
 277
 278 ## Initialize vars
 279 LDAP_LIBS=
 280 LDBM_LIBS=
 281 LTHREAD_LIBS=
 282 LUTIL_LIBS=
 283
 284 LDAPD_LIBS=
 285 SLAPD_LIBS=
 286 SLURPD_LIBS=
 287
 288 BUILD_LDAPD=no
 289 BUILD_SLAPD=no
 290 BUILD_SLURPD=no
 291
 292 BUILD_BDB2=no
 293 BUILD_LDAP=no
 294 BUILD_LDBM=no
 295 BUILD_PASSWD=no
 296 BUILD_PERL=no
 297 BUILD_SHELL=no
 298 BUILD_TCL=no
 299 BUILD_THREAD=no
 300
 301 SLAPD_MODULES_LDFLAGS=
 302 SLAPD_MODULES_CPPFLAGS=
 303
 304 SLAPD_PERL_LDFLAGS=
 305 SLAPD_PERL_CPPFLAGS=
 306
 307 KRB_LIBS=
 308 READLINE_LIBS=
 309 TERMCAP_LIBS=
 310 TLS_LIBS=
 311
 312 dnl ----------------------------------------------------------------
 313 dnl Checks for programs
 314
 315 dnl AC_PROG_INSTALL
 316
 317 dnl AIX Thread requires we use cc_r or xlc_r.
 318 dnl But only do this IF AIX and CC is not set
 319 dnl and threads are auto|yes|posix.
 320 dnl
 321 dnl If we find cc_r|xlc_r, force pthreads and assume
 322 dnl             pthread_create is in $LIBS (ie: don't bring in
 323 dnl             any additional thread libraries)
 324 dnl If we do not find cc_r|xlc_r, disable threads
 325
 326 ol_aix_threads=no
 327 case "$target" in
 328 *-*-aix*) dnl all AIX is not a good idea.
 329         if test -z "CC" ; then
 330                 case "$ol_with_threads" in
 331                 auto | yes |  posix) ol_aix_threads=yes ;;
 332                 esac
 333         fi
 334 ;;
 335 esac
 336
 337 if test $ol_aix_threads = yes ; then
 338         if test -z "${CC}" ; then
 339                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 340
 341                 if test "$CC" = cc ; then
 342                         dnl no CC! don't allow --with-threads
 343                         if test $ol_with_threads != auto ; then
 344                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 345                         else
 346                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 347                         fi
 348                         ol_with_threads=no
 349                 fi
 350         fi
 351
 352         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 353                 ol_with_threads=posix
 354                 ol_cv_pthread_create=yes
 355         fi
 356 fi
 357
 358 if test -z "${CC}"; then
 359         AC_CHECK_PROGS(CC,cc)
 360 fi
 361
 362 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 363 dnl (for now, let autoconf sort this out)
 364 dnl CFLAGS=${CFLAGS-""}
 365
 366 AM_PROG_LIBTOOL
 367 dnl AC_PROG_MAKE_SET
 368
 369 AC_PROG_AWK
 370 OL_PROG_LN_H
 371 AC_PROG_LN_S
 372
 373 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 374         LN_S="$LN_H"
 375 fi
 376
 377 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 378         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 379 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 380 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 381
 382 ol_link_modules=no
 383 if test $ol_enable_modules != no ; then
 384         AC_PATH_PROG(GLIBCONFIG, glib-config)
 385
 386         if test "no$GLIBCONFIG" = "no" ; then
 387                 if test $ol_enable_modules = yes ; then
 388                         AC_MSG_ERROR([could not locate glib-config])
 389                 fi
 390
 391         else
 392                 SLAPD_MODULES_VERSION="`$GLIBCONFIG --version gmodule`"
 393                 SLAPD_MODULES_CPPFLAGS="`$GLIBCONFIG --cflags gmodule`"
 394                 SLAPD_MODULES_LDFLAGS="`$GLIBCONFIG --libs gmodule`"
 395
 396                 dnl should check glib version
 397                 ol_link_modules=yes
 398         fi
 399 fi
 400
 401 ol_link_perl=no
 402 if test $ol_enable_perl != no ; then
 403         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 404
 405         if test "no$PERLBIN" = "no" ; then
 406                 if test $ol_enable_perl = yes ; then
 407                         AC_MSG_ERROR([could not locate perl])
 408                 fi
 409
 410         else
 411                 SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 412                 SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 413
 414                 dnl should check perl version
 415                 ol_link_perl=yes
 416         fi
 417 fi
 418
 419 AC_PROG_CPP
 420
 421 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 422         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 423
 424 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 425         AC_MSG_WARN([programs compiled here do run here...])
 426         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 427
 428 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 429         AC_MSG_WARN([programs compiled here do not run here...])
 430         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 431 fi
 432
 433 dnl Checks for UNIX Variants
 434 AC_AIX
 435 AC_ISC_POSIX
 436 AC_MINIX
 437
 438 dnl BeOS requires -lbe -lroot -lnet
 439 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 440
 441 dnl Checks for system services
 442 AC_CYGWIN
 443 AC_MINGW32
 444 AC_EXEEXT
 445 AC_OBJEXT
 446
 447 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 448
 449 dnl OpenLDAP requires STDC features
 450 AM_PROG_CC_STDC
 451 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 452         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 453 fi
 454
 455 dnl AM_C_PROTOTYPES
 456
 457 dnl Check cc depend flags
 458 OL_MKDEPEND
 459 if test "${ol_cv_mkdep}" = no ; then
 460         # this will soon become an error
 461         AC_MSG_WARN([do not know how to generate dependencies])
 462 fi
 463
 464 dnl Checks for libraries
 465
 466 dnl Find socket()
 467 dnl Likely combinations:
 468 dnl             -lsocket [ -lnsl_s | -lnsl ]
 469 dnl             -linet
 470
 471 AC_CHECK_FUNC(socket, :, [
 472 dnl
 473 dnl hopefully we won't include too many libraries
 474 dnl
 475         AC_CHECK_LIB(socket, main)
 476         AC_CHECK_LIB(net, main)
 477         AC_CHECK_LIB(net, socket)
 478         AC_CHECK_LIB(nsl_s, main)
 479         AC_CHECK_LIB(nsl, main)
 480         AC_CHECK_LIB(inet, socket)
 481         AC_CHECK_LIB(gen, main)
 482 ])
 483
 484 dnl Check for resolver routines
 485 AC_CHECK_FUNCS(res_search)
 486 if test $ac_cv_func_res_search = "no" ; then
 487         AC_CHECK_LIB(bind, res_search)
 488         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 489                 AC_DEFINE(HAVE_RES_SEARCH,1)
 490         else
 491                 AC_CHECK_LIB(resolv, res_search)
 492                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 493                         AC_DEFINE(HAVE_RES_SEARCH,1)
 494                 fi
 495         fi
 496 fi
 497
 498 dnl HP-UX requires -lV3
 499 AC_CHECK_LIB(V3, sigset)
 500
 501 AC_CHECK_HEADERS( regex.h )
 502 if test "$ac_cv_header_regex_h" != yes ; then
 503         AC_MSG_ERROR([POSIX regex.h required.])
 504 fi
 505 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 506
 507 OL_POSIX_REGEX
 508 if test "$ol_cv_c_posix_regex" = no ; then
 509         AC_MSG_ERROR([broken POSIX regex!])
 510 fi
 511
 512 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 513
 514 dnl Select arg types
 515 dnl (if this detection becomes permenent, it and the select() detection
 516 dnl should be done before the yielding select test)
 517 AC_FUNC_SELECT_ARGTYPES
 518
 519 # ISODE tests
 520 ol_link_isode=no
 521 if test $ol_enable_ldapd != no ; then
 522         AC_MSG_WARN([ldapd is not supported and may suffer from bit rot.])
 523
 524         dnl look for ISODE libraries
 525         AC_CHECK_LIB(xtpp, main, [
 526                 ol_link_isode=yes
 527                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 528                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 529                 ],:,[-lxtdsap -lxtisode -losi])
 530         AC_CHECK_LIB(dsap, main, [
 531                 ol_link_isode=yes
 532                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 533                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 534                 ],:,[-lisode])
 535         AC_CHECK_LIB(isode, main, [
 536                 ol_link_isode=yes
 537                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 538                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 539                 ],:)
 540 fi
 541
 542 if test $ol_link_isode != no; then
 543         AC_CHECK_LIB(pp, main, [
 544                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 545                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 546                 ],:)
 547
 548         AC_PATH_PROG(PEPSY, pepsy)
 549 fi
 550
 551 dnl
 552 dnl check for kerberos
 553 dnl
 554 ol_link_kerberos=no
 555
 556 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 557         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 558
 559         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 560                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 561                         [-lkrb5 -ldes425])
 562
 563                 if test $have_k5 = yes ; then
 564                         ol_with_kerberos=found
 565                         ol_link_kerberos=yes
 566
 567                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 568
 569                         LIBS="$KRB_LIBS $LIBS"
 570
 571                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 572                                 [ol_cv_var_des_debug], [
 573                                 dnl save the flags
 574                                 save_LIBS="$LIBS"
 575                                 LIBS="$KRB_LIBS $LIBS"
 576                                 AC_TRY_LINK([
 577 #include <kerberosIV/krb.h>
 578 #include <kerberosIV/des.h>
 579 extern int des_debug;
 580 ],[
 581 des_debug = 1;
 582 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 583                                 dnl restore the LIBS
 584                                 LIBS="$save_LIBS"
 585                         ])
 586
 587                         if test $ol_cv_var_des_debug = yes ; then
 588                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 589                                         [define if you have Kerberos des_debug])
 590                         fi
 591
 592                         LIBS="$save_LIBS"
 593                 fi
 594         fi
 595 fi
 596
 597 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 598         AC_CHECK_HEADERS(krb.h des.h)
 599
 600         if test $ac_cv_header_krb_h = yes ; then
 601                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 602
 603                 if test $have_k4 = yes ; then
 604                         ol_with_kerberos=found
 605                         ol_link_kerberos=yes
 606
 607                         KRB_LIBS="-lkrb -ldes"
 608                 fi
 609         fi
 610 fi
 611
 612 if test $ol_link_kerberos = yes ; then
 613         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 614 fi
 615
 616 dnl
 617 dnl Check for SSL/TLS
 618 dnl
 619 ol_link_tls=no
 620 if test $ol_with_tls != no ; then
 621
 622         AC_CHECK_HEADERS(ssl.h)
 623
 624         if test $ac_cv_header_ssl_h = yes ; then
 625                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 626                         [have_ssleay=yes
 627                         need_rsaref=no],
 628                         [have_ssleay=no],
 629                         [-lcrypto])
 630
 631                 if test $have_ssleay = no ; then
 632                         AC_CHECK_LIB(ssl, ssl3_accept,
 633                                 [have_ssleay=yes
 634                                 need_rsaref=yes], [have_ssleay=no],
 635                                 [-lcrypto -lRSAglue -lrsaref])
 636                 fi
 637
 638                 if test $have_ssleay = yes ; then
 639                         ol_with_tls=found
 640                         ol_link_tls=yes
 641
 642                         AC_DEFINE(HAVE_SSLEAY, 1,
 643                                 [define if you have SSLeay or OpenSSL])
 644
 645                         if test $need_rsaref = yes; then
 646                                 AC_DEFINE(HAVE_RSAREF, 1,
 647                                         [define if you have RSAref])
 648
 649                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 650                         else
 651                                 TLS_LIBS="-lssl -lcrypto"
 652                         fi
 653                 fi
 654         fi
 655 fi
 656
 657 if test $ol_link_tls = yes ; then
 658         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 659 fi
 660
 661 dnl Tests for reentrant functions necessary to build a
 662 dnl thread_safe -lldap.
 663 AC_CHECK_FUNCS(         \
 664         ctime_r                 \
 665         gethostbyname_r gethostbyaddr_r \
 666 )
 667
 668 if test "$ac_cv_func_ctime_r" = no ; then
 669         ol_cv_func_ctime_r_nargs=0
 670 else
 671         OL_FUNC_CTIME_R_NARGS
 672 dnl     OL_FUNC_CTIME_R_TYPE
 673 fi
 674
 675 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 676         OL_FUNC_GETHOSTBYNAME_R_NARGS
 677 else
 678         ol_cv_func_gethostbyname_r_nargs=0
 679 fi
 680
 681 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 682         OL_FUNC_GETHOSTBYADDR_R_NARGS
 683 else
 684         ol_cv_func_gethostbyaddr_r_nargs=0
 685 fi
 686
 687 if test "$ac_cv_func_ctime_r" = yes \
 688         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 689         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 690         -a "$ac_cv_func_gethostbyname_r" = yes \
 691         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 692         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 693         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 694         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 695         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 696         ; then
 697
 698         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 699 fi
 700
 701 ol_link_threads=no
 702 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 703         -o $ol_with_threads = posix ; then
 704
 705         AC_CHECK_HEADERS(pthread.h sched.h)
 706
 707         if test $ac_cv_header_pthread_h = yes ; then
 708                 OL_POSIX_THREAD_VERSION
 709
 710                 if test $ol_cv_pthread_version = final ; then
 711                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 712                                 [define if pthreads API compatible with final spec])
 713                 elif test $ol_cv_pthread_version = draft4 ; then
 714                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 715                                 [define if pthreads API compatible with draft4 spec])
 716                 else
 717                         AC_MSG_ERROR([unknown pthread version])
 718                 fi
 719
 720                 # consider threads found
 721                 ol_with_threads=found
 722
 723                 OL_HEADER_LINUX_THREADS
 724
 725                 dnl Now the hard part, how to link?
 726                 dnl
 727                 dnl currently supported checks:
 728                 dnl
 729                 dnl Check for no flags
 730                 dnl     pthread_create() in $LIBS
 731                 dnl
 732                 dnl Check special pthread (final) flags
 733                 dnl     pthread_create() with -mt (Solaris)
 734                 dnl     pthread_create() with -kthread (FreeBSD)
 735                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 736                 dnl     pthread_create() with -pthreads (?)
 737                 dnl     pthread_create() with -thread (?)
 738                 dnl
 739                 dnl Check pthread (final) libraries
 740                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 741                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 742                 dnl     (skipped) pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 743                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
 744                 dnl     pthread_create() in -lpthread (many)
 745                 dnl     pthread_create() in -lc_r (FreeBSD)
 746                 dnl
 747                 dnl Check pthread (draft4) flags (depreciated)
 748                 dnl     pthread_create() with -threads (OSF/1)
 749                 dnl
 750                 dnl Check pthread (draft4) libraries (depreciated)
 751                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 752                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 753                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 754                 dnl     pthread_create() in -lpthreads (many)
 755                 dnl
 756
 757                 dnl pthread_create in $LIBS
 758                 AC_MSG_CHECKING([for pthread_create in default libraries])
 759                 AC_CACHE_VAL(ol_cv_pthread_create,[
 760                 AC_TRY_RUN([
 761 #include <pthread.h>
 762 #ifndef NULL
 763 #define NULL (void*)0
 764 #endif
 765
 766 static void *task(p)
 767         void *p;
 768 {
 769         return (void *) (p == NULL);
 770 }
 771
 772 int main(argc, argv)
 773         int argc;
 774         char **argv;
 775 {
 776         pthread_t t;
 777         int status;
 778
 779         /* make sure pthread_create() isn't just a stub */
 780 #if HAVE_PTHREADS_D4
 781         status = pthread_create(&t, pthread_attr_default, task, NULL);
 782 #else
 783         status = pthread_create(&t, NULL, task, NULL);
 784 #endif
 785
 786         if( status ) return status;
 787
 788         /* make sure pthread_detach() isn't just a stub */
 789 #if HAVE_PTHREADS_D4
 790         status = pthread_detach( &t );
 791 #else
 792         status = pthread_detach( t );
 793 #endif
 794
 795         if( status ) return status;
 796
 797         return status;
 798 }
 799 ],
 800                         [ol_cv_pthread_create=yes],
 801                         [ol_cv_pthread_create=no],
 802                         [dnl assume yes
 803                         ol_cv_pthread_create=yes])])
 804                 AC_MSG_RESULT($ol_cv_pthread_create)
 805
 806                 if test $ol_cv_pthread_create != no ; then
 807                         ol_link_threads=posix
 808                         ol_link_pthreads=""
 809                 fi
 810
 811                 OL_PTHREAD_TRY_LINK([-mt],              [ol_cv_pthread_mt])
 812                 OL_PTHREAD_TRY_LINK([-kthread], [ol_cv_pthread_kthread])
 813                 OL_PTHREAD_TRY_LINK([-pthread], [ol_cv_pthread_pthread])
 814                 OL_PTHREAD_TRY_LINK([-pthreads],[ol_cv_pthread_pthreads])
 815                 OL_PTHREAD_TRY_LINK([-thread],  [ol_cv_pthread_thread])
 816
 817                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc -lc_r],
 818                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
 819                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc],
 820                         [ol_cv_pthread_lpthread_lmach_lexc])
 821 dnl             OL_PTHREAD_TRY_LINK([-lpthread -lexc],
 822 dnl                     [ol_cv_pthread_lpthread_lexc])
 823
 824                 OL_PTHREAD_TRY_LINK([-lpthread -Wl,-woff,85],
 825                         [ol_cv_pthread_lib_lpthread_woff])
 826
 827                 OL_PTHREAD_TRY_LINK([-lpthread],[ol_cv_pthread_lpthread])
 828                 OL_PTHREAD_TRY_LINK([-lc_r],    [ol_cv_pthread_lc_r])
 829
 830                 OL_PTHREAD_TRY_LINK([-threads], [ol_cv_pthread_threads])
 831
 832                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc -lc_r],
 833                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
 834                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc],
 835                         [ol_cv_pthread_lpthreads_lmach_lexc])
 836                 OL_PTHREAD_TRY_LINK([-lpthreads -lexc],
 837                         [ol_cv_pthread_lpthreads_lexc])
 838
 839                 OL_PTHREAD_TRY_LINK([-lpthreads],       [ol_cv_pthread_lib_lpthreads])
 840
 841                 if test $ol_link_threads != no ; then
 842                         AC_DEFINE(HAVE_PTHREADS,1,
 843                                 [define if you have POSIX Threads])
 844
 845                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
 846
 847                         dnl save flags
 848                         save_CPPFLAGS="$CPPFLAGS"
 849                         save_LIBS="$LIBS"
 850                         LIBS="$LTHREAD_LIBS $LIBS"
 851
 852                         dnl All POSIX Thread (final) implementations should have
 853                         dnl sched_yield instead of pthread yield.
 854                         dnl check for both
 855                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 856
 857                         if test $ac_cv_func_sched_yield = no -a \
 858                                 $ac_cv_func_pthread_yield = no ; then
 859                                 dnl Digital UNIX has sched_yield() in -lrt
 860                                 AC_CHECK_LIB(rt, sched_yield,
 861                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 862                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 863                                         ac_cv_func_sched_yield=yes],
 864                                         [ac_cv_func_sched_yield=no])
 865                         fi
 866                         if test $ac_cv_func_sched_yield = no -a \
 867                                 $ac_cv_func_pthread_yield = no ; then
 868                                 dnl Solaris has sched_yield() stub in -lposix4
 869                                 dnl but we'll use thr_yield instead.
 870                                 AC_CHECK_FUNCS(thr_yield)
 871                         fi
 872                         if test $ac_cv_func_sched_yield = no -a \
 873                                 $ac_cv_func_pthread_yield = no -a \
 874                                 "$ac_cv_func_thr_yield" = no ; then
 875                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 876                         fi
 877
 878                         dnl Check functions for compatibility
 879                         AC_CHECK_FUNCS(pthread_kill)
 880
 881                         dnl Check for pthread_detach with <pthread.h> inclusion
 882                         dnl as it's symbol may have been mangled.
 883                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
 884                                 [ol_cv_func_pthread_detach], [
 885                                 dnl save the flags
 886                                 AC_TRY_LINK([
 887 #include <pthread.h>
 888 #ifndef NULL
 889 #define NULL (void*)0
 890 #endif
 891 ],
 892                                         [pthread_detach(NULL);],
 893                                         [ol_cv_func_pthread_detach=yes],
 894                                         [ol_cv_func_pthread_detach=no])
 895                         ])
 896
 897                         if test $ol_cv_func_pthread_detach = no ; then
 898                                 AC_MSG_ERROR([could not locate pthread_detach()])
 899                         fi
 900
 901                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
 902                                 [define if you have pthread_detach function])
 903
 904                         dnl Check for setconcurreny functions
 905                         AC_CHECK_FUNCS( \
 906                                 pthread_setconcurrency \
 907                                 pthread_getconcurrency \
 908                                 thr_setconcurrency \
 909                                 thr_getconcurrency \
 910                         )
 911
 912                         OL_SYS_LINUX_THREADS
 913                         OL_LINUX_THREADS
 914
 915                         if test $ol_cv_linux_threads = error; then
 916                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
 917                         fi
 918
 919                         AC_MSG_CHECKING([if pthread_create() works])
 920                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 921                         AC_TRY_RUN([
 922 #include <pthread.h>
 923 #ifndef NULL
 924 #define NULL (void*)0
 925 #endif
 926
 927 static void *task(p)
 928         void *p;
 929 {
 930         return (void *) (p == NULL);
 931 }
 932
 933 int main(argc, argv)
 934         int argc;
 935         char **argv;
 936 {
 937         pthread_t t;
 938 #if HAVE_PTHREADS_D4
 939         exit(pthread_create(&t, pthread_attr_default, task, NULL));
 940 #else
 941         exit(pthread_create(&t, NULL, task, NULL));
 942 #endif
 943 }
 944 ],
 945                                 [ol_cv_pthread_create_works=yes],
 946                                 [ol_cv_pthread_create_works=no],
 947                                 [dnl assume yes
 948                                 ol_cv_pthread_create_works=yes])])
 949                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 950
 951                         if test $ol_cv_pthread_create_works = no ; then
 952                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
 953                         fi
 954
 955                         dnl Check if select causes an yield
 956                         if test $ol_with_yielding_select = auto ; then
 957                                 AC_MSG_CHECKING([if select yields when using pthreads])
 958                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 959                                 AC_TRY_RUN([
 960 #include <sys/types.h>
 961 #include <sys/time.h>
 962 #include <unistd.h>
 963 #include <pthread.h>
 964 #ifndef NULL
 965 #define NULL (void*) 0
 966 #endif
 967
 968 static int fildes[2];
 969
 970 static void *task(p)
 971         void *p;
 972 {
 973         int i;
 974         struct timeval tv;
 975
 976         fd_set rfds;
 977
 978         tv.tv_sec=10;
 979         tv.tv_usec=0;
 980
 981         FD_ZERO(&rfds);
 982         FD_SET(fildes[0], &rfds);
 983
 984         /* we're not interested in any fds */
 985         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 986
 987         if(i < 0) {
 988                 perror("select");
 989                 exit(10);
 990         }
 991
 992         exit(0); /* if we exit here, the select blocked the whole process */
 993 }
 994
 995 int main(argc, argv)
 996         int argc;
 997         char **argv;
 998 {
 999         pthread_t t;
1000
1001         /* create a pipe to select */
1002         if(pipe(&fildes[0])) {
1003                 perror("select");
1004                 exit(1);
1005         }
1006
1007 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1008         (void) pthread_setconcurrency(2);
1009 #else
1010 #ifdef HAVE_THR_SETCONCURRENCY
1011         /* Set Solaris LWP concurrency to 2 */
1012         thr_setconcurrency(2);
1013 #endif
1014 #endif
1015
1016 #if HAVE_PTHREADS_D4
1017         pthread_create(&t, pthread_attr_default, task, NULL);
1018 #else
1019         pthread_create(&t, NULL, task, NULL);
1020 #endif
1021
1022 #if HAVE_SCHED_YIELD
1023         sched_yield();  /* make sure task runs first */
1024 #else
1025 #ifdef HAVE_PTHREAD_YIELD
1026         pthread_yield();        /* make sure task runs first */
1027 #endif
1028 #endif
1029
1030         exit(2);
1031 }],
1032                                 [ol_cv_pthread_select_yields=no],
1033                                 [ol_cv_pthread_select_yields=yes], [
1034                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
1035                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
1036
1037                                 if test $ol_cv_pthread_select_yields = yes ; then
1038                                         ol_with_yielding_select=yes
1039                                 fi
1040                         fi
1041
1042                         dnl restore flags
1043                         CPPFLAGS="$save_CPPFLAGS"
1044                         LIBS="$save_LIBS"
1045                 else
1046                         AC_MSG_ERROR([could not link with POSIX Threads])
1047                 fi
1048         fi
1049
1050         if test $ol_with_threads = posix ; then
1051                 AC_MSG_ERROR([could not locate POSIX Threads])
1052         fi
1053 fi
1054
1055 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1056         -o $ol_with_threads = mach ; then
1057
1058         dnl check for Mach CThreads
1059         AC_CHECK_HEADERS(mach/cthreads.h)
1060         if test $ac_cv_header_mach_cthreads_h = yes ; then
1061                 ol_with_threads=found
1062
1063                 dnl check for cthread support in current $LIBS
1064                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1065
1066                 if test $ol_link_threads = no ; then
1067                         dnl try -all_load
1068                         dnl this test needs work
1069                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1070                                 [ol_cv_cthread_all_load], [
1071                                 dnl save the flags
1072                                 save_LIBS="$LIBS"
1073                                 LIBS="-all_load $LIBS"
1074                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1075                                         cthread_fork((void *)0, (void *)0);
1076                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1077                                 dnl restore the LIBS
1078                                 LIBS="$save_LIBS"
1079                         ])
1080
1081                         if test $ol_cv_cthread_all_load = yes ; then
1082                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1083                                 ol_link_threads=mach
1084                         fi
1085                 fi
1086
1087                 if test $ol_link_threads != no ; then
1088                         : check for cthread specific functionality here
1089                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1090                                 [define if you have Mach Cthreads])
1091                 else
1092                         AC_MSG_ERROR([could not link with Mach CThreads])
1093                 fi
1094         fi
1095
1096         if test $ol_with_threads = mach ; then
1097                 AC_MSG_ERROR([could not locate Mach CThreads])
1098         fi
1099 fi
1100
1101 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1102         -o $ol_with_threads = lwp ; then
1103
1104         dnl check for SunOS5 LWP
1105         AC_CHECK_HEADERS(thread.h synch.h)
1106         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1107                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1108
1109                 if test $have_thr = yes ; then
1110                         AC_DEFINE(HAVE_THR,1,
1111                                 [if you have Solaris LWP (thr) package])
1112                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1113                         ol_link_threads=thr
1114
1115                         if test $ol_with_yielding_select = auto ; then
1116                                 ol_with_yielding_select=yes
1117                         fi
1118
1119                         dnl Check for setconcurreny functions
1120                         AC_CHECK_FUNCS( \
1121                                 thr_setconcurrency \
1122                                 thr_getconcurrency \
1123                         )
1124                 fi
1125         fi
1126
1127         dnl check for SunOS4 LWP
1128         AC_CHECK_HEADERS(lwp/lwp.h)
1129         if test $ac_cv_header_lwp_lwp_h = yes ; then
1130                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1131
1132                 if test $have_lwp = yes ; then
1133                         AC_DEFINE(HAVE_LWP,1,
1134                                 [if you have SunOS LWP package])
1135                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1136                         ol_link_threads=lwp
1137
1138                         if test $ol_with_yielding_select = auto ; then
1139                                 ol_with_yielding_select=no
1140                         fi
1141                 fi
1142         fi
1143 fi
1144
1145 if test $ol_with_yielding_select = yes ; then
1146         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1147                 [define if select implicitly yields])
1148 fi
1149
1150 if test $ol_with_threads = manual ; then
1151         dnl User thinks he can manually configure threads.
1152         ol_link_threads=yes
1153
1154         AC_MSG_WARN([thread defines and link options must be set manually])
1155
1156         AC_CHECK_HEADERS(pthread.h sched.h)
1157         AC_CHECK_FUNCS(sched_yield pthread_yield)
1158         OL_HEADER_LINUX_THREADS
1159
1160         AC_CHECK_HEADERS(mach/cthreads.h)
1161         AC_CHECK_HEADERS(lwp/lwp.h)
1162         AC_CHECK_HEADERS(thread.h synch.h)
1163 fi
1164
1165 if test $ol_link_threads != no ; then
1166         dnl needed to get reentrant/threadsafe versions
1167         dnl
1168         AC_DEFINE(REENTRANT,1)
1169         AC_DEFINE(_REENTRANT,1)
1170         AC_DEFINE(THREAD_SAFE,1)
1171         AC_DEFINE(_THREAD_SAFE,1)
1172         AC_DEFINE(THREADSAFE,1)
1173         AC_DEFINE(_THREADSAFE,1)
1174         AC_DEFINE(_SGI_MP_SOURCE,1)
1175
1176         dnl The errno declaration may dependent upon _REENTRANT.
1177         dnl If it does, we must link with thread support.
1178         AC_CACHE_CHECK([for thread specific errno],
1179                 [ol_cv_errno_thread_specific], [
1180                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1181                         [ol_cv_errno_thread_specific=yes],
1182                         [ol_cv_errno_thread_specific=no])
1183         ])
1184
1185         dnl The h_errno declaration may dependent upon _REENTRANT.
1186         dnl If it does, we must link with thread support.
1187         AC_CACHE_CHECK([for thread specific h_errno],
1188                 [ol_cv_h_errno_thread_specific], [
1189                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1190                         [ol_cv_h_errno_thread_specific=yes],
1191                         [ol_cv_h_errno_thread_specific=no])
1192         ])
1193
1194         if test $ol_cv_errno_thread_specific != yes \
1195                 -o $ol_cv_h_errno_thread_specific != yes ; then
1196                 LIBS="$LTHREAD_LIBS $LIBS"
1197                 LTHREAD_LIBS=""
1198         fi
1199
1200 dnl When in thread environment, use
1201 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1202 dnl                     || defined( HAVE_FUNC_R )
1203 dnl                     func_r(...);
1204 dnl             #else
1205 dnl             #       if defined( HAVE_THREADS )
1206 dnl                             /* lock */
1207 dnl             #       endif
1208 dnl                             func(...);
1209 dnl             #       if defined( HAVE_THREADS )
1210 dnl                             /* unlock */
1211 dnl             #       endif
1212 dnl             #endif
1213 dnl
1214 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1215 dnl             _POSIX_REENTRANT_FUNCTIONS
1216 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1217 dnl             _POSIX_THREADSAFE_FUNCTIONS
1218 dnl
1219 dnl             and is currently defined in lthread.h
1220 dnl
1221 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1222 dnl
1223 dnl libldap/*.c should only include <lthread.h> iff
1224 dnl LDAP_R_COMPILE is defined.  ie:
1225 dnl             #ifdef LDAP_R_COMPILE
1226 dnl             #       include LDAP_R_COMPILE
1227 dnl             #endif
1228 dnl
1229 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1230 dnl specifically for compiling the threadsafe version of
1231 dnl     the ldap library (-lldap_r).
1232 dnl
1233 dnl     dnl check for reentrant/threadsafe functions
1234 dnl     dnl
1235 dnl     dnl note: these should only be used when linking
1236 dnl     dnl       with $LTHREAD_LIBS
1237 dnl     dnl
1238 dnl     save_CPPFLAGS="$CPPFLAGS"
1239 dnl     save_LIBS="$LIBS"
1240 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1241 dnl     AC_CHECK_FUNCS( \
1242 dnl             gmtime_r \
1243 dnl             gethostbyaddr_r gethostbyname_r \
1244 dnl             feof_unlocked unlocked_feof \
1245 dnl             putc_unlocked unlocked_putc \
1246 dnl             flockfile ftrylockfile \
1247 dnl     )
1248 dnl     CPPFLAGS="$save_CPPFLAGS"
1249 dnl     LIBS="$save_LIBS"
1250 fi
1251
1252 if test $ol_link_threads = no ; then
1253         if test $ol_with_threads = yes ; then
1254                 AC_MSG_ERROR([no suitable thread support])
1255         fi
1256
1257         if test $ol_with_threads = auto ; then
1258                 AC_MSG_WARN([no suitable thread support, disabling threads])
1259                 ol_with_threads=no
1260         fi
1261
1262         AC_DEFINE(NO_THREADS,1,
1263                 [define if you have (or want) no threads])
1264         LTHREAD_LIBS=""
1265 fi
1266
1267 if test $ol_link_threads != no ; then
1268         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1269 fi
1270
1271 dnl ----------------------------------------------------------------
1272
1273 ol_link_ldbm=no
1274 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1275         OL_BERKELEY_DB2
1276
1277         if test $ol_cv_berkeley_db2 = yes ; then
1278                 ol_link_ldbm=db2
1279                 ol_with_ldbm_api=db2
1280
1281                 if test $ol_with_ldbm_type = hash ; then
1282                         AC_DEFINE(LDBM_USE_DBHASH,1)
1283                 else
1284                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1285                 fi
1286
1287                 dnl $ol_cv_lib_db2 should be yes or -ldb
1288                 dnl (it could be no, but that would be an error
1289                 if test $ol_cv_lib_db2 != yes ; then
1290                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1291                 fi
1292         fi
1293 fi
1294
1295 ol_link_bdb2=no
1296 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1297         ol_link_bdb2=yes
1298 fi
1299
1300 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1301         OL_BERKELEY_DB
1302
1303         if test $ol_cv_berkeley_db = yes ; then
1304                 ol_link_ldbm=db
1305                 ol_with_ldbm_api=db
1306
1307                 if test $ol_with_ldbm_type = hash ; then
1308                         AC_DEFINE(LDBM_USE_DBHASH,1)
1309                 else
1310                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1311                 fi
1312
1313                 dnl $ol_cv_lib_db should be yes or -ldb
1314                 dnl (it could be no, but that would be an error
1315                 if test $ol_cv_lib_db != yes ; then
1316                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1317                 fi
1318         fi
1319 fi
1320
1321 if test $ol_with_ldbm_api = manual ; then
1322         dnl User thinks he can manually configure LDBM api.
1323         ol_link_ldbm=yes
1324
1325         AC_MSG_WARN([LDBM defines and link options must be set manually])
1326
1327         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1328 fi
1329
1330 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1331         AC_MSG_WARN(Could not find LDBM with BTREE support)
1332         ol_with_ldbm_api=none
1333 fi
1334
1335 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1336         OL_MDBM
1337
1338         if test $ol_cv_mdbm = yes ; then
1339                 ol_link_ldbm=mdbm
1340                 ol_with_ldbm_api=mdbm
1341                 if test $ol_cv_lib_mdbm != yes ; then
1342                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1343                 fi
1344         fi
1345 fi
1346
1347 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1348         OL_GDBM
1349
1350         if test $ol_cv_gdbm = yes ; then
1351                 ol_link_ldbm=gdbm
1352                 ol_with_ldbm_api=gdbm
1353
1354                 if test $ol_cv_lib_gdbm != yes ; then
1355                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1356                 fi
1357         fi
1358 fi
1359
1360 if test $ol_with_ldbm_api = auto ; then
1361         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1362 elif test $ol_with_ldbm_api = ndbm ; then
1363         OL_NDBM
1364
1365         if test $ol_cv_ndbm = yes ; then
1366                 ol_link_ldbm=ndbm
1367                 ol_with_ldbm_api=ndbm
1368
1369                 if test $ol_cv_lib_ndbm != yes ; then
1370                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1371                 fi
1372         fi
1373 fi
1374
1375 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1376         AC_MSG_WARN(could not find suitable LDBM backend)
1377         if test $ol_enable_ldbm = yes ; then
1378                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1379         fi
1380
1381         AC_MSG_WARN(disabling LDBM)
1382         ol_enable_ldbm=no
1383 fi
1384
1385 if test $ol_enable_wrappers != no ; then
1386         AC_CHECK_HEADERS(tcpd.h)
1387
1388         if test $ac_cv_header_tcpd_h != yes ; then
1389                 have_wrappers=no
1390         else
1391                 AC_CHECK_LIB(wrap, main,
1392                         [have_wrappers=yes], [have_wrappers=no])
1393         fi
1394
1395         if test $have_wrappers = yes ; then
1396                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1397                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1398
1399                 dnl We add another check for -lnsl since some libwrap's
1400                 dnl need it, but it isn't always included from above
1401                 AC_CHECK_LIB(nsl, main)
1402         else
1403                 AC_MSG_WARN(could not find -lwrap)
1404                 if test $ol_enable_wrappers = yes ; then
1405                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1406                 fi
1407
1408                 AC_MSG_WARN(disabling wrappers support)
1409                 ol_enable_wrappers=no
1410         fi
1411 fi
1412
1413 if test $ol_enable_syslog != no ; then
1414         AC_CHECK_FUNC(openlog)
1415         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1416                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1417         fi
1418         ol_enable_syslog=$ac_cv_func_openlog
1419 fi
1420
1421 if test $ol_enable_dmalloc != no ; then
1422         AC_CHECK_HEADERS(dmalloc.h)
1423         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1424 fi
1425
1426 if test $ol_enable_tcl != no ; then
1427         AC_CHECK_HEADERS(tcl.h)
1428
1429         if test $ac_cv_header_tcl_h != yes ; then
1430                 have_tcl=no
1431         else
1432                 AC_CHECK_LIB(tcl,main,
1433                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1434                         [have_tcl=no])
1435
1436                 if test $have_tcl != yes; then
1437                         AC_CHECK_LIB(tcl7.6,main,
1438                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1439                                 [have_tcl=no])
1440                 fi
1441
1442                 if test $have_tcl != yes; then
1443                         AC_CHECK_LIB(tcl8.0,main,
1444                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1445                                 [have_tcl=no])
1446                 fi
1447         fi
1448
1449         if test $have_tcl != yes ; then
1450                 AC_MSG_WARN([could not find -ltcl])
1451                 if test $ol_enable_tcl = yes ; then
1452                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1453                 fi
1454
1455                 ol_enable_tcl=no
1456         fi
1457 fi
1458
1459 # ud needs termcap (should insert check here)
1460 ol_link_termcap=no
1461 AC_CHECK_HEADERS(termcap.h ncurses.h)
1462
1463 if test $ol_link_termcap = no ; then
1464         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1465         if test $have_termcap = yes ; then
1466                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1467                 ol_link_termcap=yes
1468                 TERMCAP_LIBS=-ltermcap
1469         fi
1470 fi
1471
1472 if test $ol_link_termcap = no ; then
1473         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1474         if test $have_ncurses = yes ; then
1475                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1476                 ol_link_termcap=yes
1477                 TERMCAP_LIBS=-lncurses
1478         fi
1479 fi
1480
1481 if test $ol_link_termcap = no ; then
1482         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1483         TERMCAP_LIBS=
1484 fi
1485
1486 dnl
1487 dnl Check for GNU readline
1488 dnl
1489 ol_link_readline=no
1490 if test $ol_with_readline != no ; then
1491         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1492
1493         if test $ac_cv_header_readline_readline_h = yes ; then
1494                 save_LIBS="$LIBS"
1495                 LIBS="$TERMCAP_LIBS $LIBS"
1496                 AC_CHECK_LIB(readline, readline,
1497                         [have_readline=yes], [have_readline=no])
1498                 LIBS="$save_LIBS"
1499
1500                 if test $have_readline = yes ; then
1501                         ol_with_readline=found
1502                         ol_link_readline=yes
1503
1504                         READLINE_LIBS="-lreadline"
1505                 fi
1506         fi
1507 fi
1508
1509 if test $ol_link_readline = yes ; then
1510         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1511 fi
1512
1513
1514 # FreeBSD (and others) have crypt(3) in -lcrypt
1515 if test $ol_enable_crypt != no ; then
1516         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1517                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1518                         have_crypt=yes], [have_crypt=no])])
1519
1520         if test $have_crypt = yes ; then
1521                 AC_DEFINE(HAVE_CRYPT,1)
1522         else
1523                 AC_MSG_WARN(could not find crypt)
1524                 if test $ol_enable_crypt = yes ; then
1525                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1526                 fi
1527
1528                 AC_MSG_WARN(disabling crypt support)
1529                 ol_enable_crypt=no
1530         fi
1531 fi
1532
1533 # FreeBSD (and others) have setproctitle(3) in -lutil
1534 if test $ol_enable_proctitle != no ; then
1535         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1536                 AC_CHECK_LIB(util, setproctitle,
1537                         [have_setproctitle=yes
1538                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1539                         [have_setproctitle=no
1540                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1541
1542         if test $have_setproctitle = yes ; then
1543                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1544         fi
1545 fi
1546
1547 dnl ----------------------------------------------------------------
1548 dnl Checks for header files.
1549 OL_HEADER_STDC
1550
1551 if test $ol_cv_header_stdc != yes; then
1552         AC_MSG_WARN([could not locate Standard C compliant headers])
1553 fi
1554
1555 AC_HEADER_DIRENT
1556 AC_HEADER_SYS_WAIT
1557 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1558 if test $am_cv_sys_posix_termios = yes ; then
1559         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1560                 [define if you have POSIX termios])
1561 fi
1562
1563 AC_CHECK_HEADERS(       \
1564         arpa/inet.h             \
1565         arpa/nameser.h  \
1566         assert.h                \
1567         crypt.h                 \
1568         errno.h                 \
1569         fcntl.h                 \
1570         filio.h                 \
1571         getopt.h                \
1572         grp.h                   \
1573         libutil.h               \
1574         limits.h                \
1575         locale.h                \
1576         malloc.h                \
1577         memory.h                \
1578         psap.h                  \
1579         pwd.h                   \
1580         resolv.h                \
1581         sgtty.h                 \
1582         stdarg.h                \
1583         stddef.h                \
1584         string.h                \
1585         strings.h               \
1586         sysexits.h              \
1587         sys/file.h              \
1588         sys/filio.h             \
1589         sys/errno.h             \
1590         sys/ioctl.h             \
1591         sys/param.h             \
1592         sys/resource.h  \
1593         sys/select.h    \
1594         sys/socket.h    \
1595         sys/syslog.h    \
1596         sys/time.h              \
1597         sys/types.h             \
1598         syslog.h                \
1599         termios.h               \
1600         unistd.h                \
1601 )
1602
1603 dnl ----------------------------------------------------------------
1604 dnl Checks for typedefs, structures, and compiler characteristics.
1605 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1606 AC_TYPE_MODE_T
1607 AC_TYPE_OFF_T
1608 AC_TYPE_PID_T
1609 AM_TYPE_PTRDIFF_T
1610 AC_TYPE_SIGNAL
1611 OL_TYPE_SIG_ATOMIC_T
1612 AC_TYPE_SIZE_T
1613 AC_STRUCT_ST_BLKSIZE
1614 AC_HEADER_TIME
1615 AC_STRUCT_TM
1616 OL_STRUCT_PASSWD_PW_GECOS
1617
1618 OL_C_UPPER_LOWER
1619 AC_C_CONST
1620 OL_C_VOLATILE
1621
1622 if test $cross_compiling = yes ; then
1623         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1624
1625         AC_DEFINE(LBER_INT_T,long)
1626         AC_DEFINE(LBER_TAG_T,long)
1627         AC_DEFINE(LBER_SOCKET_T,int)
1628
1629 else
1630         AC_C_BIGENDIAN
1631         AC_CHECK_SIZEOF(short)
1632         AC_CHECK_SIZEOF(int)
1633         AC_CHECK_SIZEOF(long)
1634
1635         if test "$ac_cv_sizeof_int" -lt 4 ; then
1636                 AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
1637
1638                 AC_DEFINE(LBER_INT_T,long)
1639                 AC_DEFINE(LBER_TAG_T,long)
1640                 AC_DEFINE(LBER_SOCKET_T,int)
1641         else
1642                 AC_DEFINE(LBER_INT_T,int)
1643                 AC_DEFINE(LBER_TAG_T,long)
1644                 AC_DEFINE(LBER_SOCKET_T,int)
1645         fi
1646 fi
1647
1648 AC_DEFINE(LBER_LEN_T,long)
1649
1650 dnl ----------------------------------------------------------------
1651 dnl Checks for library functions.
1652 AC_FUNC_MEMCMP
1653 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1654 AC_FUNC_STRFTIME
1655 dnl AM_FUNC_STRTOD
1656
1657 dnl we should use vfork instead of fork in a number of places...
1658 dnl AC_FUNC_VFORK
1659 AC_FUNC_VPRINTF
1660
1661 if test $ac_cv_func_vprintf = yes ; then
1662         dnl check for vsnprintf
1663         AC_CHECK_FUNCS(vsnprintf vsprintf)
1664 fi
1665
1666 AC_CHECK_FUNCS(         \
1667         bcopy                   \
1668         closesocket             \
1669         endgrent                \
1670         endpwent                \
1671         flock                   \
1672         getdtablesize   \
1673         getgrgid                \
1674         gethostname             \
1675         getpass                 \
1676         getpwuid                \
1677         gettimeofday    \
1678         initgroups              \
1679         lockf                   \
1680         memcpy                  \
1681         memmove                 \
1682         mkstemp                 \
1683         recv                    \
1684         recvfrom                \
1685         setpwfile               \
1686         setgid                  \
1687         setegid                 \
1688         setsid                  \
1689         setuid                  \
1690         seteuid                 \
1691         signal                  \
1692         sigset                  \
1693         snprintf                \
1694         strdup                  \
1695         strerror                \
1696         strpbrk                 \
1697         strrchr                 \
1698         strsep                  \
1699         strstr                  \
1700         strtol                  \
1701         strtoul                 \
1702         strspn                  \
1703         sysconf                 \
1704         waitpid                 \
1705         wait4                   \
1706 )
1707
1708 dnl We actually may need to replace more than this.
1709 AC_REPLACE_FUNCS(getopt tempnam)
1710
1711 dnl ----------------------------------------------------------------
1712 # Check Configuration
1713 OL_SYS_ERRLIST
1714
1715 dnl ----------------------------------------------------------------
1716 dnl Sort out defines
1717
1718 if test "$ol_enable_debug" != no ; then
1719         AC_DEFINE(LDAP_DEBUG,1)
1720 fi
1721 if test "$ol_enable_syslog" = yes ; then
1722         AC_DEFINE(LDAP_SYSLOG,1)
1723 fi
1724 if test "$ol_enable_libui" = yes ; then
1725         AC_DEFINE(LDAP_LIBUI,1)
1726 fi
1727 if test "$ol_enable_cache" = no ; then
1728         AC_DEFINE(LDAP_NOCACHE,1)
1729 fi
1730 if test "$ol_enable_dns" != no ; then
1731         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1732 fi
1733 if test "$ol_enable_proctitle" != no ; then
1734         AC_DEFINE(LDAP_PROCTITLE,1)
1735 fi
1736 if test "$ol_enable_referrals" != no ; then
1737         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1738 fi
1739 if test "$ol_enable_cldap" != no ; then
1740         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1741 fi
1742
1743 if test "$ol_enable_aclgroups" != no ; then
1744         AC_DEFINE(SLAPD_ACLGROUPS,1)
1745 fi
1746 if test "$ol_enable_crypt" != no ; then
1747         AC_DEFINE(SLAPD_CRYPT,1)
1748 fi
1749 if test "$ol_enable_cleartext" != no ; then
1750         AC_DEFINE(SLAPD_CLEARTEXT,1)
1751 fi
1752 if test "$ol_enable_phonetic" != no ; then
1753         AC_DEFINE(SLAPD_PHONETIC,1)
1754 fi
1755 if test "$ol_enable_rlookups" != no ; then
1756         AC_DEFINE(SLAPD_RLOOKUPS,1)
1757 fi
1758
1759 if test "$ol_link_modules" != no ; then
1760         AC_DEFINE(SLAPD_MODULES,1)
1761         BUILD_SLAPD=yes
1762 fi
1763
1764 if test "$ol_link_bdb2" != no ; then
1765         AC_DEFINE(SLAPD_BDB2,1)
1766         BUILD_SLAPD=yes
1767         BUILD_BDB2=yes
1768 fi
1769
1770 if test "$ol_enable_ldap" != no ; then
1771         AC_DEFINE(SLAPD_LDAP,1)
1772         BUILD_SLAPD=yes
1773         BUILD_LDAP=yes
1774 fi
1775
1776 if test "$ol_link_ldbm" != no ; then
1777         AC_DEFINE(SLAPD_LDBM,1)
1778         BUILD_SLAPD=yes
1779         BUILD_LDBM=yes
1780 fi
1781
1782 if test "$ol_enable_passwd" != no ; then
1783         AC_DEFINE(SLAPD_PASSWD,1)
1784         BUILD_SLAPD=yes
1785         BUILD_PASSWD=yes
1786 fi
1787
1788 if test "$ol_link_perl" != no ; then
1789         AC_DEFINE(SLAPD_PERL,1)
1790         BUILD_SLAPD=yes
1791         BUILD_PERL=yes
1792 fi
1793
1794 if test "$ol_enable_shell" != no ; then
1795         AC_DEFINE(SLAPD_SHELL,1)
1796         BUILD_SLAPD=yes
1797         BUILD_SHELL=yes
1798 fi
1799
1800 if test "$ol_enable_tcl" != no ; then
1801         AC_DEFINE(SLAPD_TCL,1)
1802         BUILD_SLAPD=yes
1803         BUILD_TCL=yes
1804 fi
1805
1806 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1807         $BUILD_SLAPD = yes ; then
1808         BUILD_SLURPD=yes
1809 fi
1810
1811 if test "$ol_link_isode" != no ; then
1812         BUILD_LDAPD=yes
1813 fi
1814
1815 dnl ----------------------------------------------------------------
1816
1817 AC_SUBST(BUILD_LDAPD)
1818 AC_SUBST(BUILD_SLAPD)
1819   AC_SUBST(BUILD_BDB2)
1820   AC_SUBST(BUILD_LDAP)
1821   AC_SUBST(BUILD_LDBM)
1822   AC_SUBST(BUILD_PASSWD)
1823   AC_SUBST(BUILD_PERL)
1824   AC_SUBST(BUILD_SHELL)
1825   AC_SUBST(BUILD_TCL)
1826 AC_SUBST(BUILD_SLURPD)
1827
1828 AC_SUBST(LDAP_LIBS)
1829 AC_SUBST(LDAPD_LIBS)
1830 AC_SUBST(SLAPD_LIBS)
1831 AC_SUBST(SLURPD_LIBS)
1832 AC_SUBST(LDBM_LIBS)
1833 AC_SUBST(LTHREAD_LIBS)
1834 AC_SUBST(LUTIL_LIBS)
1835
1836 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
1837 AC_SUBST(SLAPD_MODULES_LDFLAGS)
1838
1839 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1840 AC_SUBST(SLAPD_PERL_LDFLAGS)
1841
1842 AC_SUBST(KRB_LIBS)
1843 AC_SUBST(READLINE_LIBS)
1844 AC_SUBST(TERMCAP_LIBS)
1845 AC_SUBST(TLS_LIBS)
1846
1847 dnl ----------------------------------------------------------------
1848 dnl final output
1849 dnl
1850
1851 AC_OUTPUT( \
1852 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1853 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1854 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1855 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1856 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1857 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1858 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1859 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1860 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1861 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1862 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1863 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1864 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1865 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1866 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1867 include/Makefile:build/top.mk:include/Makefile.in \
1868 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1869 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1870 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1871 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1872 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1873 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1874 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1875 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1876 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1877 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1878 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1879 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
1880 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/srv.mk \
1881 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1882 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1883 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
1884 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1885 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
1886 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1887 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1888 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1889 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
1890 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
1891 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
1892 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
1893 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
1894 ,[
1895 date > stamp-h
1896 echo Please \"make depend\" to build dependencies
1897 ])