git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl This work is part of OpenLDAP Software <http://www.openldap.org/>.
   3 dnl
   4 dnl Copyright 1998-2008 The OpenLDAP Foundation.
   5 dnl All rights reserved.
   6 dnl
   7 dnl Redistribution and use in source and binary forms, with or without
   8 dnl modification, are permitted only as authorized by the OpenLDAP
   9 dnl Public License.
  10 dnl
  11 dnl A copy of this license is available in the file LICENSE in the
  12 dnl top-level directory of the distribution or, alternatively, at
  13 dnl <http://www.OpenLDAP.org/license.html>.
  14 dnl
  15 dnl ----------------------------------------------------------------
  16 dnl Disable config.cache!
  17 define([AC_CACHE_LOAD], )dnl
  18 define([AC_CACHE_SAVE], )dnl
  19 dnl ----------------------------------------------------------------
  20 dnl Disable libtool 1.5 support for languages we don't use
  21 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  22 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  23 define([AC_LIBTOOL_LANG_GCJ_CONFIG], [:])dnl
  24 dnl ================================================================
  25 dnl Configure.in for OpenLDAP
  26 AC_COPYRIGHT([[Copyright 1998-2008 The OpenLDAP Foundation. All rights reserved.
  27 Restrictions apply, see COPYRIGHT and LICENSE files.]])
  28 AC_REVISION([$OpenLDAP$])
  29 AC_INIT([OpenLDAP],,[http://www.openldap.org/its/])
  30 m4_define([AC_PACKAGE_BUGREPORT],[<http://www.openldap.org/its/>])
  31 AC_CONFIG_SRCDIR(build/version.sh)dnl
  32 dnl ----------------------------------------------------------------
  33 dnl OpenLDAP Autoconf Macros
  34 builtin(include, build/openldap.m4)dnl
  35 dnl ================================================================
  36
  37 AC_CONFIG_AUX_DIR(build)dnl
  38
  39 eval `$ac_aux_dir/version.sh`
  40 if test -z "$OL_STRING"; then
  41         AC_MSG_ERROR([could not determine version])
  42 fi
  43
  44 if test -f "$ac_aux_dir/shtool" && test ! -d $ac_aux_dir/shtool; then
  45         ac_cv_shtool="$ac_aux_dir/shtool"
  46 else
  47         AC_MSG_ERROR([no shtool found in $ac_aux_dir])
  48 fi
  49
  50 SHTOOL="$ac_cv_shtool"
  51 dnl AC_SUBST(SHTOOL)dnl
  52
  53 TB="" TN=""
  54 if test -t 1; then
  55         TB="`$SHTOOL echo -e '%B' 2>/dev/null`"
  56         TN="`$SHTOOL echo -e '%b' 2>/dev/null`"
  57 fi
  58
  59 OPENLDAP_CVS=""
  60 if test -d $ac_aux_dir/CVS; then
  61         OPENLDAP_CVS="(from CVS sources) "
  62 fi
  63
  64 echo "Configuring ${TB}${OL_STRING}${TN} ${OPENLDAP_CVS}..."
  65
  66 dnl Determine host platform
  67 dnl             we try not to use this for much
  68 AC_CANONICAL_TARGET([])
  69
  70 AM_INIT_AUTOMAKE([$OL_PACKAGE],[$OL_VERSION], [no defines])dnl
  71 AC_SUBST(PACKAGE)dnl
  72 AC_SUBST(VERSION)dnl
  73 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  74 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  75
  76 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION,$OL_API_INC,Version)
  77 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MAJOR,$OL_MAJOR,Major)
  78 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MINOR,$OL_MINOR,Minor)
  79 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_PATCH,$OL_PATCH,Patch)
  80
  81 OPENLDAP_LIBRELEASE=$OL_API_LIB_RELEASE
  82 AC_SUBST(OPENLDAP_LIBRELEASE)dnl
  83
  84 OPENLDAP_LIBVERSION=$OL_API_LIB_VERSION
  85 AC_SUBST(OPENLDAP_LIBVERSION)dnl
  86
  87 OPENLDAP_RELEASE_DATE="$OL_RELEASE_DATE"
  88 AC_SUBST(OPENLDAP_RELEASE_DATE)dnl
  89
  90 dnl We use autoconf features new to 2.59.  Later versions like won't work.
  91 dnl aclocal.m4 should be built using aclocal from automake 1.5
  92 dnl libtool 1.5 should be installed.
  93 AC_PREREQ(2.59)dnl Required Autoconf version
  94
  95 AH_TOP([
  96 /* begin of portable.h.pre */
  97 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
  98  *
  99  * Copyright 1998-2008 The OpenLDAP Foundation
 100  * All rights reserved.
 101  *
 102  * Redistribution and use in source and binary forms, with or without
 103  * modification, are permitted only as authorized by the OpenLDAP
 104  * Public License.
 105  *
 106  * A copy of this license is available in the file LICENSE in the
 107  * top-level directory of the distribution or, alternatively, at
 108  * <http://www.OpenLDAP.org/license.html>.
 109  */
 110
 111 #ifndef _LDAP_PORTABLE_H
 112 #define _LDAP_PORTABLE_H
 113
 114 /* define this if needed to get reentrant functions */
 115 #ifndef REENTRANT
 116 #undef REENTRANT
 117 #endif
 118 #ifndef _REENTRANT
 119 #undef _REENTRANT
 120 #endif
 121
 122 /* define this if needed to get threadsafe functions */
 123 #ifndef THREADSAFE
 124 #undef THREADSAFE
 125 #endif
 126 #ifndef _THREADSAFE
 127 #undef _THREADSAFE
 128 #endif
 129 #ifndef THREAD_SAFE
 130 #undef THREAD_SAFE
 131 #endif
 132 #ifndef _THREAD_SAFE
 133 #undef _THREAD_SAFE
 134 #endif
 135
 136 #ifndef _SGI_MP_SOURCE
 137 #undef _SGI_MP_SOURCE
 138 #endif
 139
 140 /* end of portable.h.pre */
 141 ])
 142 AH_BOTTOM([
 143 /* begin of portable.h.post */
 144
 145 #ifdef _WIN32
 146         /* don't suck in all of the win32 api */
 147 #       define WIN32_LEAN_AND_MEAN 1
 148 #endif
 149
 150 #ifndef LDAP_NEEDS_PROTOTYPES
 151 /* force LDAP_P to always include prototypes */
 152 #define LDAP_NEEDS_PROTOTYPES 1
 153 #endif
 154
 155 #ifndef LDAP_REL_ENG
 156 #if (LDAP_VENDOR_VERSION == 000000) && !defined(LDAP_DEVEL)
 157 #define LDAP_DEVEL
 158 #endif
 159 #if defined(LDAP_DEVEL) && !defined(LDAP_TEST)
 160 #define LDAP_TEST
 161 #endif
 162 #endif
 163
 164 #ifdef HAVE_STDDEF_H
 165 #       include <stddef.h>
 166 #endif
 167
 168 #ifdef HAVE_EBCDIC
 169 /* ASCII/EBCDIC converting replacements for stdio funcs
 170  * vsnprintf and snprintf are used too, but they are already
 171  * checked by the configure script
 172  */
 173 #define fputs ber_pvt_fputs
 174 #define fgets ber_pvt_fgets
 175 #define printf ber_pvt_printf
 176 #define fprintf ber_pvt_fprintf
 177 #define vfprintf ber_pvt_vfprintf
 178 #define vsprintf ber_pvt_vsprintf
 179 #endif
 180
 181 #include "ac/fdset.h"
 182
 183 #include "ldap_cdefs.h"
 184 #include "ldap_features.h"
 185
 186 #include "ac/assert.h"
 187 #include "ac/localize.h"
 188
 189 #endif /* _LDAP_PORTABLE_H */
 190 /* end of portable.h.post */
 191 ])
 192
 193 AC_CONFIG_HEADERS([include/portable.h:include/portable.hin])
 194 AC_CONFIG_HEADERS([include/ldap_features.h:include/ldap_features.hin])
 195 AC_CONFIG_HEADERS([include/lber_types.h:include/lber_types.hin])
 196
 197 dnl ================================================================
 198 dnl Start Args
 199 AC_MSG_CHECKING(configure arguments)
 200 AC_PREFIX_DEFAULT(/usr/local)
 201
 202 top_builddir=`pwd`
 203 AC_SUBST(top_builddir)dnl
 204
 205 dnl ----------------------------------------------------------------
 206 dnl --with-subdir
 207 ldap_subdir="/openldap"
 208
 209 AC_ARG_WITH(subdir,
 210 [  --with-subdir=DIR       change default subdirectory used for installs],
 211 [case "$withval" in
 212         no) ldap_subdir=""
 213                 ;;
 214         yes)
 215                 ;;
 216         /*|\\*)
 217                 ldap_subdir="$withval"
 218                 ;;
 219         *)
 220                 ldap_subdir="/$withval"
 221                 ;;
 222 esac
 223 ])dnl
 224
 225 AC_SUBST(ldap_subdir)dnl
 226
 227 dnl ----------------------------------------------------------------
 228 dnl General "enable" options
 229 dnl set default to traditional to enable the original debug style
 230 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes, [no yes traditional])dnl
 231 OL_ARG_ENABLE(dynamic,[  --enable-dynamic         enable linking built binaries with dynamic libs], no)dnl
 232 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 233 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 234 dnl OL_ARG_ENABLE(referrals,[  --enable-referrals         enable LDAPv2+ Referrals (experimental)], no)dnl
 235 ol_enable_referrals=${ol_enable_referrals-no}
 236 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 237 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 238
 239 dnl ----------------------------------------------------------------
 240 dnl General "with" options
 241 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 242         auto, [auto yes no] )
 243 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch(3) URL support],
 244         auto, [auto yes no] )
 245 OL_ARG_WITH(threads,[  --with-threads     with threads],
 246         auto, [auto nt posix mach pth lwp yes no manual] )
 247 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support auto|openssl|gnutls],
 248         auto, [auto openssl gnutls yes no] )
 249 OL_ARG_WITH(yielding_select,
 250         [  --with-yielding-select  with implicitly yielding select],
 251         auto, [auto yes no manual] )
 252 OL_ARG_WITH(mp,
 253         [  --with-mp               with multiple precision statistics auto|longlong|long|bignum|gmp],
 254         auto, [auto longlong long bignum gmp yes no])
 255 OL_ARG_WITH(odbc,
 256         [  --with-odbc             with specific ODBC support iodbc|unixodbc|odbc32|auto],
 257         auto, [auto iodbc unixodbc odbc32] )
 258
 259 dnl ----------------------------------------------------------------
 260 dnl Server options
 261 dnl ----------------------------------------------------------------
 262
 263 dnl ----------------------------------------------------------------
 264 dnl SLAPD OPTIONS
 265 AC_ARG_ENABLE(xxslapdoptions,[
 266 SLAPD (Standalone LDAP Daemon) Options:])
 267 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 268 OL_ARG_ENABLE(dynacl,[    --enable-dynacl         enable run-time loadable ACL support (experimental)], no)dnl
 269 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs (experimental)], no, [no yes mod])dnl
 270 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 271 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], no)dnl
 272 OL_ARG_ENABLE(lmpasswd,[    --enable-lmpasswd     enable LAN Manager passwords], no)dnl
 273 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 274 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 275 OL_ARG_ENABLE(rewrite,[    --enable-rewrite       enable DN rewriting in back-ldap and rwm overlay], auto)dnl
 276 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups of client hostnames], no)dnl
 277 OL_ARG_ENABLE(slapi,[    --enable-slapi        enable SLAPI support (experimental)], no)dnl
 278 OL_ARG_ENABLE(slp,[    --enable-slp          enable SLPv2 support], no)dnl
 279 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 280
 281 dnl ----------------------------------------------------------------
 282 dnl SLAPD Backend Options
 283 Backends="bdb \
 284         dnssrv \
 285         hdb \
 286         ldap \
 287         meta \
 288         monitor \
 289         ndb \
 290         null \
 291         passwd \
 292         perl \
 293         relay \
 294         shell \
 295         sock \
 296         sql"
 297
 298 AC_ARG_ENABLE(xxslapbackends,[
 299 SLAPD Backend Options:])
 300
 301 OL_ARG_ENABLE(backends,[    --enable-backends     enable all available backends],
 302         --, [no yes mod])dnl
 303 OL_ARG_ENABLE(bdb,[    --enable-bdb       enable Berkeley DB backend],
 304         yes, [no yes mod], ol_enable_backends)dnl
 305 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend],
 306         no, [no yes mod], ol_enable_backends)dnl
 307 OL_ARG_ENABLE(hdb,[    --enable-hdb       enable Hierarchical DB backend],
 308         yes, [no yes mod], ol_enable_backends)dnl
 309 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend],
 310         no, [no yes mod], ol_enable_backends)dnl
 311 OL_ARG_ENABLE(meta,[    --enable-meta     enable metadirectory backend],
 312         no, [no yes mod], ol_enable_backends)dnl
 313 OL_ARG_ENABLE(monitor,[    --enable-monitor       enable monitor backend],
 314         yes, [no yes mod], ol_enable_backends)dnl
 315 OL_ARG_ENABLE(ndb,[    --enable-ndb       enable MySQL NDB Cluster backend],
 316         no, [no yes mod], ol_enable_backends)dnl
 317 OL_ARG_ENABLE(null,[    --enable-null     enable null backend],
 318         no, [no yes mod], ol_enable_backends)dnl
 319 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend],
 320         no, [no yes mod], ol_enable_backends)dnl
 321 OL_ARG_ENABLE(perl,[    --enable-perl     enable perl backend],
 322         no, [no yes mod], ol_enable_backends)dnl
 323 OL_ARG_ENABLE(relay,[    --enable-relay           enable relay backend],
 324         yes, [no yes mod], ol_enable_backends)dnl
 325 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend],
 326         no, [no yes mod], ol_enable_backends)dnl
 327 OL_ARG_ENABLE(sock,[    --enable-sock     enable sock backend],
 328         no, [no yes mod], ol_enable_backends)dnl
 329 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend],
 330         no, [no yes mod], ol_enable_backends)dnl
 331
 332 dnl ----------------------------------------------------------------
 333 dnl SLAPD Overlay Options
 334 Overlays="accesslog \
 335         auditlog \
 336         collect \
 337         constraint \
 338         dds \
 339         dyngroup \
 340         dynlist \
 341         memberof \
 342         ppolicy \
 343         proxycache \
 344         refint \
 345         retcode \
 346         rwm \
 347         seqmod \
 348         syncprov \
 349         translucent \
 350         unique \
 351         valsort"
 352
 353 AC_ARG_ENABLE(xxslapoverlays,[
 354 SLAPD Overlay Options:])
 355
 356 OL_ARG_ENABLE(overlays,[    --enable-overlays     enable all available overlays],
 357         --, [no yes mod])dnl
 358 OL_ARG_ENABLE(accesslog,[    --enable-accesslog   In-Directory Access Logging overlay],
 359         no, [no yes mod], ol_enable_overlays)
 360 OL_ARG_ENABLE(auditlog,[    --enable-auditlog     Audit Logging overlay],
 361         no, [no yes mod], ol_enable_overlays)
 362 OL_ARG_ENABLE(collect,[    --enable-collect       Collect overlay],
 363         no, [no yes mod], ol_enable_overlays)
 364 OL_ARG_ENABLE(constraint,[    --enable-constraint         Attribute Constraint overlay],
 365         no, [no yes mod], ol_enable_overlays)
 366 OL_ARG_ENABLE(dds,[    --enable-dds       Dynamic Directory Services overlay],
 367         no, [no yes mod], ol_enable_overlays)
 368 OL_ARG_ENABLE(dyngroup,[    --enable-dyngroup     Dynamic Group overlay],
 369         no, [no yes mod], ol_enable_overlays)
 370 OL_ARG_ENABLE(dynlist,[    --enable-dynlist       Dynamic List overlay],
 371         no, [no yes mod], ol_enable_overlays)
 372 OL_ARG_ENABLE(memberof,[    --enable-memberof     Reverse Group Membership overlay],
 373         no, [no yes mod], ol_enable_overlays)
 374 OL_ARG_ENABLE(ppolicy,[    --enable-ppolicy       Password Policy overlay],
 375         no, [no yes mod], ol_enable_overlays)
 376 OL_ARG_ENABLE(proxycache,[    --enable-proxycache         Proxy Cache overlay],
 377         no, [no yes mod], ol_enable_overlays)
 378 OL_ARG_ENABLE(refint,[    --enable-refint         Referential Integrity overlay],
 379         no, [no yes mod], ol_enable_overlays)
 380 OL_ARG_ENABLE(retcode,[    --enable-retcode       Return Code testing overlay],
 381         no, [no yes mod], ol_enable_overlays)
 382 OL_ARG_ENABLE(rwm,[    --enable-rwm               Rewrite/Remap overlay],
 383         no, [no yes mod], ol_enable_overlays)
 384 OL_ARG_ENABLE(seqmod,[    --enable-seqmod         Sequential Modify overlay],
 385         yes, [no yes mod], ol_enable_overlays)
 386 OL_ARG_ENABLE(syncprov,[    --enable-syncprov     Syncrepl Provider overlay],
 387         yes, [no yes mod], ol_enable_overlays)
 388 OL_ARG_ENABLE(translucent,[    --enable-translucent  Translucent Proxy overlay],
 389         no, [no yes mod], ol_enable_overlays)
 390 OL_ARG_ENABLE(unique,[    --enable-unique       Attribute Uniqueness overlay],
 391         no, [no yes mod], ol_enable_overlays)
 392 OL_ARG_ENABLE(valsort,[    --enable-valsort      Value Sorting overlay],
 393         no, [no yes mod], ol_enable_overlays)
 394
 395 dnl ----------------------------------------------------------------
 396 AC_ARG_ENABLE(xxliboptions,[
 397 Library Generation & Linking Options])
 398 AC_ENABLE_STATIC
 399 AC_ENABLE_SHARED
 400
 401 dnl ----------------------------------------------------------------
 402
 403 # validate options
 404 if test $ol_enable_slapd = no ; then
 405         dnl SLAPD was specificallly disabled
 406         if test $ol_enable_slapi = yes ; then
 407                 AC_MSG_WARN([slapd disabled, ignoring --enable-slapi argument])
 408         fi
 409         case "$ol_enable_backends" in yes | mod)
 410                 AC_MSG_WARN([slapd disabled, ignoring --enable-backends argument])
 411         esac
 412         for i in $Backends; do
 413                 eval "ol_tmp=\$ol_enable_$i"
 414                 if test $ol_tmp != no ; then
 415                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 416                         eval "ol_enable_$i=no"
 417                 fi
 418         done
 419         if test $ol_enable_modules = yes ; then
 420                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 421         fi
 422         if test $ol_enable_wrappers = yes ; then
 423                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 424         fi
 425         if test $ol_enable_rlookups = yes ; then
 426                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 427         fi
 428         if test $ol_enable_dynacl = yes ; then
 429                 AC_MSG_WARN([slapd disabled, ignoring --enable-dynacl argument])
 430         fi
 431         if test $ol_enable_aci != no ; then
 432                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 433         fi
 434         if test $ol_enable_rewrite = yes ; then
 435                 AC_MSG_WARN([slapd disabled, ignoring --enable-rewrite argument])
 436         fi
 437         dnl overlays
 438         case "$ol_enable_overlays" in yes | mod)
 439                 AC_MSG_WARN([slapd disabled, ignoring --enable-overlays argument])
 440         esac
 441         for i in $Overlays; do
 442                 eval "ol_tmp=\$ol_enable_$i"
 443                 if test $ol_tmp != no ; then
 444                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 445                         eval "ol_enable_$i=no"
 446                 fi
 447         done
 448
 449         # force settings to no
 450         ol_enable_slapi=no
 451
 452         ol_enable_backends=
 453         ol_enable_overlays=
 454         ol_enable_modules=no
 455         ol_enable_rlookups=no
 456         ol_enable_dynacl=no
 457         ol_enable_aci=no
 458         ol_enable_wrappers=no
 459
 460         ol_enable_rewrite=no
 461
 462 elif test $ol_enable_modules != yes &&
 463         test $ol_enable_bdb = no &&
 464         test $ol_enable_dnssrv = no &&
 465         test $ol_enable_hdb = no &&
 466         test $ol_enable_ldap = no &&
 467         test $ol_enable_meta = no &&
 468         test $ol_enable_monitor = no &&
 469         test $ol_enable_ndb = no &&
 470         test $ol_enable_null = no &&
 471         test $ol_enable_passwd = no &&
 472         test $ol_enable_perl = no &&
 473         test $ol_enable_relay = no &&
 474         test $ol_enable_shell = no &&
 475         test $ol_enable_sock = no &&
 476         test $ol_enable_sql = no ; then
 477         dnl no slapd backend
 478
 479         if test $ol_enable_slapd = yes ; then
 480                 AC_MSG_ERROR([slapd requires a backend])
 481         else
 482                 AC_MSG_WARN([skipping slapd, no backend specified])
 483                 ol_enable_slapd=no
 484         fi
 485 fi
 486
 487 if test $ol_enable_meta/$ol_enable_ldap = yes/no ; then
 488         AC_MSG_ERROR([--enable-meta requires --enable-ldap])
 489 fi
 490
 491 if test $ol_enable_lmpasswd = yes ; then
 492         if test $ol_with_tls = no ; then
 493                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
 494         fi
 495 fi
 496
 497 if test $ol_enable_spasswd = yes ; then
 498         if test $ol_with_cyrus_sasl = no ; then
 499                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 500         fi
 501         ol_with_cyrus_sasl=yes
 502 fi
 503
 504 AC_MSG_RESULT(done)
 505
 506 dnl ----------------------------------------------------------------
 507 dnl Initialize vars
 508 LDAP_LIBS=
 509 BDB_LIBS=
 510 SLAPD_NDB_LIBS=
 511 SLAPD_NDB_INCS=
 512 LTHREAD_LIBS=
 513 LUTIL_LIBS=
 514
 515 SLAPD_LIBS=
 516
 517 BUILD_SLAPD=no
 518
 519 BUILD_THREAD=no
 520
 521 BUILD_SLAPI=no
 522 SLAPD_SLAPI_DEPEND=
 523
 524 BUILD_BDB=no
 525 BUILD_DNSSRV=no
 526 BUILD_HDB=no
 527 BUILD_LDAP=no
 528 BUILD_META=no
 529 BUILD_MONITOR=no
 530 BUILD_NDB=no
 531 BUILD_NULL=no
 532 BUILD_PASSWD=no
 533 BUILD_PERL=no
 534 BUILD_RELAY=no
 535 BUILD_SHELL=no
 536 BUILD_SOCK=no
 537 BUILD_SQL=no
 538
 539 BUILD_ACCESSLOG=no
 540 BUILD_AUDITLOG=no
 541 BUILD_CONSTRAINT=no
 542 BUILD_DDS=no
 543 BUILD_DENYOP=no
 544 BUILD_DYNGROUP=no
 545 BUILD_DYNLIST=no
 546 BUILD_LASTMOD=no
 547 BUILD_MEMBEROF=no
 548 BUILD_PPOLICY=no
 549 BUILD_PROXYCACHE=no
 550 BUILD_REFINT=no
 551 BUILD_RETCODE=no
 552 BUILD_RWM=no
 553 BUILD_SEQMOD=no
 554 BUILD_SYNCPROV=no
 555 BUILD_TRANSLUCENT=no
 556 BUILD_UNIQUE=no
 557 BUILD_VALSORT=no
 558
 559 SLAPD_STATIC_OVERLAYS=
 560 SLAPD_DYNAMIC_OVERLAYS=
 561
 562 SLAPD_MODULES_LDFLAGS=
 563 SLAPD_MODULES_CPPFLAGS=
 564
 565 SLAPD_STATIC_BACKENDS=back-ldif
 566 SLAPD_DYNAMIC_BACKENDS=
 567
 568 SLAPD_PERL_LDFLAGS=
 569 MOD_PERL_LDFLAGS=
 570 PERL_CPPFLAGS=
 571
 572 SLAPD_SQL_LDFLAGS=
 573 SLAPD_SQL_LIBS=
 574 SLAPD_SQL_INCLUDES=
 575
 576 KRB4_LIBS=
 577 KRB5_LIBS=
 578 SASL_LIBS=
 579 TLS_LIBS=
 580 MODULES_LIBS=
 581 SLAPI_LIBS=
 582 LIBSLAPI=
 583 LIBSLAPITOOLS=
 584 AUTH_LIBS=
 585 ICU_LIBS=
 586
 587 SLAPD_SLP_LIBS=
 588 SLAPD_GMP_LIBS=
 589
 590 dnl ================================================================
 591 dnl Checks for programs
 592
 593 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 594
 595 dnl ----------------------------------------------------------------
 596 dnl
 597 dnl Determine which C translator to use
 598 dnl
 599
 600 dnl AIX Thread requires we use cc_r or xlc_r.
 601 dnl But only do this IF AIX and CC is not set
 602 dnl and threads are auto|yes|posix.
 603 dnl
 604 dnl If we find cc_r|xlc_r, force pthreads and assume
 605 dnl             pthread_create is in $LIBS (ie: don't bring in
 606 dnl             any additional thread libraries)
 607 dnl If we do not find cc_r|xlc_r, disable threads
 608
 609 ol_aix_threads=no
 610 case "$target" in
 611 *-*-aix*) dnl all AIX is not a good idea.
 612         if test -z "$CC" ; then
 613                 case "$ol_with_threads" in
 614                 auto | yes |  posix) ol_aix_threads=yes ;;
 615                 esac
 616         fi
 617 ;;
 618 esac
 619
 620 if test $ol_aix_threads = yes ; then
 621         if test -z "${CC}" ; then
 622                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 623
 624                 if test "$CC" = cc ; then
 625                         dnl no CC! don't allow --with-threads
 626                         if test $ol_with_threads != auto ; then
 627                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 628                         else
 629                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 630                         fi
 631                         ol_with_threads=no
 632                 fi
 633         fi
 634
 635         case ${CC} in cc_r | xlc_r)
 636                 ol_with_threads=posix
 637                 ol_cv_pthread_create=yes
 638                 ;;
 639         esac
 640 fi
 641
 642 if test -z "${CC}"; then
 643         AC_CHECK_PROGS(CC,cc gcc,missing)
 644
 645         if test "${CC}" = "missing" ; then
 646                 AC_MSG_ERROR([Unable to locate cc(1) or suitable replacement.  Check PATH or set CC.])
 647         fi
 648 fi
 649
 650 if test -z "${AR}"; then
 651         AC_CHECK_PROGS(AR,ar gar,missing)
 652
 653         if test "${AR}" = "missing" ; then
 654                 AC_MSG_ERROR([Unable to locate ar(1) or suitable replacement.  Check PATH or set AR.])
 655         fi
 656 fi
 657
 658 AC_LIBTOOL_WIN32_DLL
 659 AC_LIBTOOL_DLOPEN
 660 AC_PROG_LIBTOOL
 661
 662 dnl ----------------------------------------------------------------
 663 dnl Perl
 664 ol_link_perl=no
 665 if test $ol_enable_perl != no ; then
 666         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 667
 668         if test "no$PERLBIN" = "no" ; then
 669                 if test $ol_enable_perl = yes ; then
 670                         AC_MSG_ERROR([could not locate perl])
 671                 fi
 672
 673         else
 674                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 675                 PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e 's/ -lc / /' -e 's/ -lc$//'`"
 676
 677                 if test x"$ol_enable_perl" = "xyes" ; then
 678                         SLAPD_PERL_LDFLAGS="$PERL_LDFLAGS"
 679                 else
 680                         MOD_PERL_LDFLAGS="$PERL_LDFLAGS"
 681                 fi
 682                 dnl should check perl version
 683                 ol_link_perl=yes
 684         fi
 685 fi
 686
 687 AC_PROG_CPP
 688
 689 dnl ----------------------------------------------------------------
 690 dnl Checks for Windows NT
 691 case $host_os in
 692   *mingw32* ) ac_cv_mingw32=yes ;;
 693   *cygwin* ) ac_cv_cygwin=yes ;;
 694 esac
 695
 696 dnl ----------------------------------------------------------------
 697 dnl Checks for file extensions
 698 AC_EXEEXT
 699 AC_OBJEXT
 700 AC_DEFINE_UNQUOTED(EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 701
 702 dnl ----------------------------------------------------------------
 703 dnl BeOS requires -lbe -lroot -lnet
 704 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 705
 706 dnl ----------------------------------------------------------------
 707 dnl OpenLDAP requires STDC features
 708 AC_PROG_CC
 709 if test "X${ac_cv_prog_cc_stdc}" = "Xno" ; then
 710         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 711 fi
 712
 713 dnl ----------------------------------------------------------------
 714 dnl Check cc depend flags
 715 OL_MKDEPEND
 716 if test "${ol_cv_mkdep}" = no ; then
 717         # this will soon become an error
 718         AC_MSG_WARN([do not know how to generate dependencies])
 719 fi
 720
 721 dnl ----------------------------------------------------------------
 722 dnl Check for AIX security library
 723 AC_CHECK_LIB(s, afopen, [
 724         AUTH_LIBS=-ls
 725         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 726 ])
 727
 728 dnl ----------------------------------------------------------------
 729 dnl Check for IBM OS/390
 730 case "$target" in
 731 *-ibm-openedition)
 732         ac_cv_func_getopt=no
 733         AC_DEFINE(BOTH_STRINGS_H,1,[define to use both <string.h> and <strings.h>])
 734         ;;
 735 esac
 736
 737 dnl ----------------------------------------------------------------
 738 dnl Check for module support
 739 ol_link_modules=no
 740 WITH_MODULES_ENABLED=no
 741 if test $ol_enable_modules != no ; then
 742         AC_CHECK_HEADERS(ltdl.h)
 743
 744         if test $ac_cv_header_ltdl_h = no ; then
 745                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 746         fi
 747
 748         AC_CHECK_LIB(ltdl, lt_dlinit, [
 749                 MODULES_LIBS=-lltdl
 750                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 751         ])
 752
 753         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 754                 AC_MSG_ERROR([could not locate libtool -lltdl])
 755         fi
 756         ol_link_modules=yes
 757         WITH_MODULES_ENABLED=yes
 758
 759 else
 760         for i in $Backends; do
 761                 eval "ol_tmp=\$ol_enable_$i"
 762                 if test $ol_tmp = mod ; then
 763                         AC_MSG_WARN([building static $i backend])
 764                         eval "ol_enable_$i=yes"
 765                 fi
 766         done
 767         for i in $Overlays; do
 768                 eval "ol_tmp=\$ol_enable_$i"
 769                 if test $ol_tmp = mod ; then
 770                         AC_MSG_WARN([building static $i overlay])
 771                         eval "ol_enable_$i=yes"
 772                 fi
 773         done
 774 fi
 775
 776 dnl ----------------------------------------------------------------
 777 dnl Checks for header files.
 778 OL_HEADER_STDC
 779
 780 if test $ol_cv_header_stdc != yes; then
 781         AC_MSG_WARN([could not locate Standard C compliant headers])
 782 fi
 783
 784 AC_HEADER_DIRENT
 785 AC_HEADER_SYS_WAIT
 786 AC_HEADER_TIOCGWINSZ
 787
 788 AC_CHECK_HEADERS(       \
 789         arpa/inet.h             \
 790         arpa/nameser.h  \
 791         assert.h                \
 792         bits/types.h    \
 793         conio.h                 \
 794         crypt.h                 \
 795         direct.h                \
 796         errno.h                 \
 797         fcntl.h                 \
 798         filio.h                 \
 799         getopt.h                \
 800         grp.h                   \
 801         io.h                    \
 802         libutil.h               \
 803         limits.h                \
 804         locale.h                \
 805         malloc.h                \
 806         memory.h                \
 807         psap.h                  \
 808         pwd.h                   \
 809         process.h               \
 810         sgtty.h                 \
 811         shadow.h                \
 812         stddef.h                \
 813         string.h                \
 814         strings.h               \
 815         sysexits.h              \
 816         sys/file.h              \
 817         sys/filio.h             \
 818         sys/fstyp.h             \
 819         sys/errno.h             \
 820         sys/ioctl.h             \
 821         sys/param.h             \
 822         sys/privgrp.h   \
 823         sys/resource.h  \
 824         sys/select.h    \
 825         sys/socket.h    \
 826         sys/stat.h              \
 827         sys/syslog.h    \
 828         sys/time.h              \
 829         sys/types.h             \
 830         sys/uio.h               \
 831         sys/vmount.h    \
 832         syslog.h                \
 833         termios.h               \
 834         unistd.h                \
 835         utime.h                 \
 836 )
 837
 838 dnl Only check Winsock on MinGW
 839 if test "$ac_cv_mingw32" = yes ; then
 840         AC_CHECK_HEADERS( winsock.h winsock2.h )
 841 fi
 842
 843 AC_CHECK_HEADERS( resolv.h, [], [],
 844 [$ac_includes_default
 845 #include <netinet/in.h>
 846 ])
 847
 848 AC_CHECK_HEADERS( netinet/tcp.h, [], [],
 849 [$ac_includes_default
 850 #include <netinet/in.h>
 851 ])
 852
 853 AC_CHECK_HEADERS( sys/ucred.h, [], [],
 854 [$ac_includes_default
 855 #ifdef HAVE_SYS_PARAM_H
 856 #include <sys/param.h>
 857 #endif
 858 ])
 859
 860 dnl ----------------------------------------------------------------
 861 dnl Checks for libraries
 862
 863 AC_CHECK_FUNCS( sigaction sigset )
 864
 865 dnl HP-UX requires -lV3
 866 dnl this is not needed on newer versions of HP-UX
 867 if test $ac_cv_func_sigaction = no && test $ac_cv_func_sigaction = no ; then
 868         AC_CHECK_LIB(V3, sigset)
 869 fi
 870
 871 dnl The following is INTENTIONALLY scripted out because shell does not
 872 dnl support variable names with the '@' character, which is what
 873 dnl autoconf would try to generate if one merely used AC_SEARCH_LIBS
 874 if test "$ac_cv_header_winsock_h" = yes; then
 875 AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 876 save_LIBS="$LIBS"
 877 for curlib in ws2_32 wsock32; do
 878         LIBS="$LIBS -l$curlib"
 879         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <winsock.h>
 880                         ]], [[
 881                         socket(0,0,0);
 882                         select(0,NULL,NULL,NULL,NULL);
 883                         closesocket(0);
 884                         gethostname(NULL,0);
 885                         ]])],[ol_cv_winsock=yes],[ol_cv_winsock=no])
 886
 887         if test $ol_cv_winsock = yes; then
 888                 AC_DEFINE(HAVE_WINSOCK, 1, [define if you have winsock])
 889                 ac_cv_func_socket=yes
 890                 ac_cv_func_select=yes
 891                 ac_cv_func_closesocket=yes
 892                 ac_cv_func_gethostname=yes
 893                 if test $curlib = ws2_32; then
 894                         ol_cv_winsock=winsock2
 895                         AC_DEFINE(HAVE_WINSOCK2, 1,
 896                                   [define if you have winsock2])
 897                 fi
 898                 break
 899         fi
 900         LIBS="$save_LIBS"
 901 done)
 902 fi
 903
 904 dnl Find socket()
 905 dnl Likely combinations:
 906 dnl             -lsocket [ -lnsl_s | -lnsl ]
 907 dnl             -linet
 908
 909 AC_CHECK_FUNC(socket, :, [
 910 dnl hopefully we won't include too many libraries
 911         AC_CHECK_LIB(socket, main)
 912         AC_CHECK_LIB(net, main)
 913         AC_CHECK_LIB(nsl_s, main)
 914         AC_CHECK_LIB(nsl, main)
 915         AC_CHECK_LIB(inet, socket)
 916         AC_CHECK_LIB(gen, main)
 917 ])
 918
 919 dnl require select
 920 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 921
 922 if test "${ac_cv_header_winsock_h}" != yes; then
 923         dnl Select arg types
 924         dnl (if this detection becomes permenent, it and the select() detection
 925         dnl should be done before the yielding select test)
 926         AC_FUNC_SELECT_ARGTYPES
 927 fi
 928
 929 dnl check to see if system call automatically restart
 930 dnl AC_SYS_RESTARTABLE_SYSCALLS
 931
 932 dnl ----------------------------------------------------------------
 933 AC_CHECK_FUNCS( poll )
 934 if test $ac_cv_func_poll = yes; then
 935 AC_CHECK_HEADERS( poll.h sys/poll.h )
 936 fi
 937
 938 dnl ----------------------------------------------------------------
 939 AC_CHECK_HEADERS( sys/epoll.h )
 940 if test "${ac_cv_header_sys_epoll_h}" = yes; then
 941         AC_MSG_CHECKING(for epoll system call)
 942         AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv)
 943 {
 944         int epfd = epoll_create(256);
 945         exit (epfd == -1 ? 1 : 0);
 946 }]])],[AC_MSG_RESULT(yes)
 947         AC_DEFINE(HAVE_EPOLL,1, [define if your system supports epoll])],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 948 fi
 949
 950 dnl ----------------------------------------------------------------
 951 AC_CHECK_HEADERS( sys/devpoll.h )
 952 dnl "/dev/poll" needs <sys/poll.h> as well...
 953 if test "${ac_cv_header_sys_devpoll_h}" = yes \
 954                 -a "${ac_cv_header_poll_h}" = yes ; \
 955 then
 956         AC_MSG_CHECKING(for /dev/poll)
 957         AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv)
 958 {
 959         int devpollfd = open("/dev/poll", /* O_RDWR */ 2);
 960         exit (devpollfd == -1 ? 1 : 0);
 961 }]])],[AC_MSG_RESULT(yes)
 962         AC_DEFINE(HAVE_DEVPOLL,1, [define if your system supports /dev/poll])],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 963 fi
 964
 965 dnl ----------------------------------------------------------------
 966 # strerror checks
 967 OL_STRERROR
 968
 969 dnl ----------------------------------------------------------------
 970 dnl require POSIX regex
 971 AC_CHECK_HEADERS( regex.h, [], [],
 972 [$ac_includes_default
 973 #ifdef HAVE_SYS_TYPES_H
 974 #include <sys/types.h>
 975 #endif
 976 ])
 977
 978 if test "$ac_cv_header_regex_h" != yes ; then
 979         AC_MSG_ERROR([POSIX regex.h required.])
 980 fi
 981 AC_SEARCH_LIBS(regfree, [regex gnuregex],
 982         :, AC_MSG_ERROR([POSIX regex required.]))
 983
 984 OL_POSIX_REGEX
 985 if test "$ol_cv_c_posix_regex" = no ; then
 986         AC_MSG_ERROR([broken POSIX regex!])
 987 fi
 988
 989 dnl ----------------------------------------------------------------
 990 dnl UUID Support
 991
 992 have_uuid=no
 993 AC_CHECK_HEADERS(sys/uuid.h)
 994 if test $ac_cv_header_sys_uuid_h = yes ; then
 995         save_LIBS="$LIBS"
 996         AC_SEARCH_LIBS([uuid_to_str], [uuid], [have_uuid=yes], :)
 997         LIBS="$save_LIBS"
 998
 999         if test have_uuid = yes ; then
1000                 AC_DEFINE(HAVE_UUID_TO_STR,1,
1001                         [define if you have uuid_to_str()])
1002
1003                 test "$ac_cv_search_uuid_to_str" = "none required" || \
1004                         SLAPD_LIBS="$SLAPD_LIBS $ac_cv_search_uuid_to_str"
1005         fi
1006 fi
1007
1008 dnl Look for uuid_generate
1009 if test $have_uuid = no ; then
1010         AC_CHECK_HEADERS(uuid/uuid.h)
1011         if test $ac_cv_header_uuid_uuid_h = yes ; then
1012                 save_LIBS="$LIBS"
1013                 AC_SEARCH_LIBS([uuid_generate], [uuid], [have_uuid=yes], :)
1014                 LIBS="$save_LIBS"
1015
1016                 if test have_uuid = yes ; then
1017                         AC_DEFINE(HAVE_UUID_GENERATE,1,
1018                                 [define if you have uuid_generate()])
1019
1020                         test "$ac_cv_search_uuid_generate" = "none required" || \
1021                                 SLAPD_LIBS="$SLAPD_LIBS $ac_cv_search_uuid_generate"
1022                 fi
1023         fi
1024 fi
1025
1026 dnl For windows, check for the need of RPCRT for UUID function support
1027 if test $have_uuid = no ; then
1028         AC_MSG_CHECKING(to see if -lrpcrt4 is needed for win32 UUID support)
1029         save_LIBS="$LIBS"
1030         LIBS="$LIBS -lrpcrt4"
1031         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1032                 int __stdcall UuidCreate(void *);
1033                 int __stdcall UuidToStringA(void *,void **);
1034                 ]], [[
1035                 UuidCreate(0);
1036                 UuidToStringA(0,0);
1037                 ]])],[need_rpcrt=yes],[need_rpcrt=no])
1038         if test $need_rpcrt = yes; then
1039                 SLAPD_LIBS="$SLAPD_LIBS -lrpcrt4"
1040         fi
1041         LIBS="$save_LIBS"
1042         AC_MSG_RESULT($need_rpcrt)
1043 fi
1044
1045 dnl ----------------------------------------------------------------
1046 dnl Check for resolver routines
1047 OL_RESOLVER_LINK
1048
1049 ol_link_dnssrv=no
1050 if test "$ol_cv_lib_resolver" != no ; then
1051         AC_DEFINE(HAVE_RES_QUERY,1,
1052                 [define if you have res_query()])
1053
1054         if test "$ol_enable_dnssrv" != no ; then
1055                 ol_link_dnssrv=yes
1056         fi
1057
1058         if test "$ol_cv_lib_resolver" != yes ; then
1059                 LIBS="$ol_cv_lib_resolver $LIBS"
1060         fi
1061 fi
1062
1063 if test "$ol_enable_dnssrv" = yes || test "$ol_enable_dnssrv" = mod ; then
1064         if test "$ol_link_dnssrv" = no ; then
1065                 AC_MSG_ERROR([DNSSRV requires res_query()])
1066         fi
1067 else
1068         ol_enable_dnssrv=no
1069 fi
1070
1071 AC_CHECK_FUNCS( hstrerror )
1072
1073 dnl ----------------------------------------------------------------
1074 dnl PF_INET6 support requires getaddrinfo and INET6_ADDRSTRLEN
1075 dnl PF_LOCAL may use getaddrinfo in available
1076 AC_CHECK_FUNCS( getaddrinfo getnameinfo gai_strerror inet_ntop )
1077
1078 ol_link_ipv6=no
1079 if test $ac_cv_func_getaddrinfo = no || test $ac_cv_func_inet_ntop = no ; then
1080         if test $ol_enable_ipv6 = yes ; then
1081                 AC_MSG_ERROR([IPv6 support requires getaddrinfo() and inet_ntop()])
1082         fi
1083 elif test $ol_enable_ipv6 != no ; then
1084         AC_CACHE_CHECK([INET6_ADDRSTRLEN],[ol_cv_inet6_addrstrlen],[
1085                 AC_EGREP_CPP(__has_inet6_addrstrlen__,[
1086 #                       include <netinet/in.h>
1087 #                       ifdef INET6_ADDRSTRLEN
1088                                 __has_inet6_addrstrlen__;
1089 #                       endif
1090                 ], [ol_cv_inet6_addrstrlen=yes], [ol_cv_inet6_addrstrlen=no])])
1091
1092
1093         AC_CACHE_CHECK([struct sockaddr_storage],ol_cv_struct_sockaddr_storage,[
1094                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1095 #include <sys/types.h>
1096 #include <sys/socket.h>
1097 ]], [[
1098                         struct sockaddr_storage ss;
1099 ]])],[ol_cv_struct_sockaddr_storage=yes],[ol_cv_struct_sockaddr_storage=no])])
1100
1101         if test $ol_cv_inet6_addrstrlen = yes &&
1102            test $ol_cv_struct_sockaddr_storage = yes ; then
1103                 ol_link_ipv6=yes
1104         elif test $ol_enable_ipv6 = yes &&
1105              test $ol_cv_inet6_addrstrlen = no ; then
1106                 AC_MSG_ERROR([IPv6 support requires INET6_ADDRSTRLEN])
1107         elif test $ol_enable_ipv6 = yes &&
1108              test $ol_cv_struct_sockaddr_storage = no ; then
1109                 AC_MSG_ERROR([IPv6 support requires struct sockaddr_storage])
1110         fi
1111 fi
1112
1113 if test $ol_enable_local != no ; then
1114         AC_CHECK_HEADERS( sys/un.h )
1115
1116         if test $ol_enable_local = auto ; then
1117                 ol_enable_local=$ac_cv_header_sys_un_h
1118         elif test $ac_cv_header_sys_un_h = no ; then
1119                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
1120         fi
1121 fi
1122
1123 dnl ----------------------------------------------------------------
1124 dnl TLS/SSL
1125
1126 if test $ol_with_tls = yes ; then
1127         ol_with_tls=auto
1128 fi
1129
1130 ol_link_tls=no
1131 if test $ol_with_tls = openssl || test $ol_with_tls = auto ; then
1132         AC_CHECK_HEADERS(openssl/ssl.h)
1133
1134         if test $ac_cv_header_openssl_ssl_h = yes ; then
1135                 AC_CHECK_LIB(ssl, SSL_library_init,
1136                         [have_openssl=yes
1137                         need_rsaref=no], [have_openssl=no],
1138                         [-lcrypto])
1139
1140                 if test $have_openssl = no ; then
1141                         AC_CHECK_LIB(ssl, ssl3_accept,
1142                                 [have_openssl=yes
1143                                 need_rsaref=yes], [have_openssl=no],
1144                                 [-lcrypto -lRSAglue -lrsaref])
1145                 fi
1146
1147                 if test $have_openssl = yes ; then
1148                         ol_with_tls=openssl
1149                         ol_link_tls=yes
1150
1151                         AC_DEFINE(HAVE_OPENSSL, 1,
1152                                 [define if you have OpenSSL])
1153
1154                         if test $need_rsaref = yes; then
1155                                 AC_DEFINE(HAVE_RSAREF, 1,
1156                                         [define if OpenSSL needs RSAref])
1157
1158                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1159                         else
1160                                 TLS_LIBS="-lssl -lcrypto"
1161                         fi
1162
1163                         OL_SSL_COMPAT
1164                         if test $ol_cv_ssl_crl_compat = yes ; then
1165                                 AC_DEFINE(HAVE_OPENSSL_CRL, 1,
1166                                         [define if you have OpenSSL with CRL checking capability])
1167                         fi
1168                 fi
1169         fi
1170 fi
1171
1172 if test $ol_link_tls = no ; then
1173         if test $ol_with_tls = gnutls || test $ol_with_tls = auto ; then
1174                 AC_CHECK_HEADERS(gnutls/gnutls.h)
1175
1176                 if test $ac_cv_header_gnutls_gnutls_h = yes ; then
1177                         AC_CHECK_LIB(gnutls, gnutls_init,
1178                                 [have_gnutls=yes], [have_gnutls=no])
1179
1180                         if test $have_gnutls = yes ; then
1181                                 ol_with_tls=gnutls
1182                                 ol_link_tls=yes
1183
1184                                 TLS_LIBS="-lgnutls"
1185
1186                                 AC_DEFINE(HAVE_GNUTLS, 1,
1187                                         [define if you have GNUtls])
1188                         fi
1189                 fi
1190         fi
1191 fi
1192
1193 WITH_TLS=no
1194 if test $ol_link_tls = yes ; then
1195         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1196         WITH_TLS=yes
1197 elif test $ol_with_tls = auto ; then
1198         AC_MSG_WARN([Could not locate TLS/SSL package])
1199         AC_MSG_WARN([TLS data protection not supported!])
1200 elif test $ol_with_tls != no ; then
1201         AC_MSG_ERROR([Could not locate TLS/SSL package])
1202 else
1203         AC_MSG_WARN([TLS data protection not supported!])
1204 fi
1205
1206 dnl ----------------------------------------------------------------
1207 dnl LAN Manger password checking requires DES from OpenSSL
1208 if test $ol_enable_lmpasswd != no; then
1209         if test $ol_link_tls != yes ; then
1210                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
1211         fi
1212
1213         AC_DEFINE(SLAPD_LMHASH, 1, [define to support LAN Manager passwords])
1214 fi
1215
1216 dnl ----------------------------------------------------------------
1217 dnl Threads?
1218 ol_link_threads=no
1219
1220 case $ol_with_threads in auto | yes | nt)
1221
1222         OL_NT_THREADS
1223
1224         if test "$ol_cv_nt_threads" = yes ; then
1225                 ol_link_threads=nt
1226                 ol_with_threads=found
1227                 ol_with_yielding_select=yes
1228
1229                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1230                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1231         fi
1232
1233         if test $ol_with_threads = nt ; then
1234                 AC_MSG_ERROR([could not locate NT Threads])
1235         fi
1236         ;;
1237 esac
1238
1239 case $ol_with_threads in auto | yes | posix)
1240
1241         AC_CHECK_HEADERS(pthread.h)
1242
1243         if test $ac_cv_header_pthread_h = yes ; then
1244                 OL_POSIX_THREAD_VERSION
1245
1246                 if test $ol_cv_pthread_version != 0 ; then
1247                         AC_DEFINE_UNQUOTED(HAVE_PTHREADS,$ol_cv_pthread_version,
1248                                 [define to pthreads API spec revision])
1249                 else
1250                         AC_MSG_ERROR([unknown pthread version])
1251                 fi
1252
1253                 # consider threads found
1254                 ol_with_threads=found
1255
1256                 OL_HEADER_LINUX_THREADS
1257                 OL_HEADER_GNU_PTH_PTHREAD_H
1258
1259                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1260                         AC_CHECK_HEADERS(sched.h)
1261                 fi
1262
1263                 dnl Now the hard part, how to link?
1264                 dnl
1265                 dnl currently supported checks:
1266                 dnl
1267                 dnl Check for no flags
1268                 dnl     pthread_create() in $LIBS
1269                 dnl
1270                 dnl Check special pthread (final) flags
1271                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1272                 dnl     pthread_create() with -kthread (FreeBSD)
1273                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1274                 dnl     pthread_create() with -pthreads (?)
1275                 dnl     pthread_create() with -mthreads (AIX)
1276                 dnl     pthread_create() with -thread (?)
1277                 dnl
1278                 dnl Check pthread (final) libraries
1279                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1280                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1281                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1282                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1283                 dnl     pthread_create() in -lpthread (many)
1284                 dnl     pthread_create() in -lc_r (FreeBSD)
1285                 dnl
1286                 dnl Check pthread (draft4) flags (depreciated)
1287                 dnl     pthread_create() with -threads (OSF/1)
1288                 dnl
1289                 dnl Check pthread (draft4) libraries (depreciated)
1290                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1291                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1292                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1293                 dnl     pthread_create() in -lpthreads (many)
1294                 dnl
1295
1296                 dnl pthread_create in $LIBS
1297                 AC_CACHE_CHECK([for pthread_create in default libraries],
1298                         ol_cv_pthread_create,[
1299                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1300                                 [ol_cv_pthread_create=yes],
1301                                 [ol_cv_pthread_create=no],
1302                                 [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1303                                         [ol_cv_pthread_create=yes],
1304                                         [ol_cv_pthread_create=no])])])
1305
1306                 if test $ol_cv_pthread_create != no ; then
1307                         ol_link_threads=posix
1308                         ol_link_pthreads=""
1309                 fi
1310
1311 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1312                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1313                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1314                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1315                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1316                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1317
1318                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1319                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1320                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1321                         [ol_cv_pthread_lpthread_lmach_lexc])
1322 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1323 dnl                     [ol_cv_pthread_lpthread_lexc])
1324
1325                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1326                         [ol_cv_pthread_lib_lpthread_woff])
1327
1328                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1329                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1330
1331                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1332
1333                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1334                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1335                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1336                         [ol_cv_pthread_lpthreads_lmach_lexc])
1337                 OL_PTHREAD_TRY([-lpthreads -lexc],
1338                         [ol_cv_pthread_lpthreads_lexc])
1339
1340                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1341
1342                 if test $ol_link_threads != no ; then
1343                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1344
1345                         dnl save flags
1346                         save_CPPFLAGS="$CPPFLAGS"
1347                         save_LIBS="$LIBS"
1348                         LIBS="$LTHREAD_LIBS $LIBS"
1349
1350                         dnl All POSIX Thread (final) implementations should have
1351                         dnl sched_yield instead of pthread yield.
1352                         dnl check for both, and thr_yield for Solaris
1353                         AC_CHECK_FUNCS(sched_yield pthread_yield thr_yield)
1354
1355                         if test $ac_cv_func_sched_yield = no &&
1356                            test $ac_cv_func_pthread_yield = no &&
1357                            test $ac_cv_func_thr_yield = no ; then
1358                                 dnl Digital UNIX has sched_yield() in -lrt
1359                                 AC_CHECK_LIB(rt, sched_yield,
1360                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1361                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1362                                                 [Define if you have the sched_yield function.])
1363                                         ac_cv_func_sched_yield=yes],
1364                                         [ac_cv_func_sched_yield=no])
1365                         fi
1366                         if test $ac_cv_func_sched_yield = no &&
1367                            test $ac_cv_func_pthread_yield = no &&
1368                            test "$ac_cv_func_thr_yield" = no ; then
1369                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1370                         fi
1371
1372                         dnl Check functions for compatibility
1373                         AC_CHECK_FUNCS(pthread_kill)
1374
1375                         dnl Check for pthread_rwlock_destroy with <pthread.h>
1376                         dnl as pthread_rwlock_t may not be defined.
1377                         AC_CACHE_CHECK([for pthread_rwlock_destroy with <pthread.h>],
1378                                 [ol_cv_func_pthread_rwlock_destroy], [
1379                                 dnl save the flags
1380                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1381 #include <pthread.h>
1382 pthread_rwlock_t rwlock;
1383 ]], [[pthread_rwlock_destroy(&rwlock);]])],[ol_cv_func_pthread_rwlock_destroy=yes],[ol_cv_func_pthread_rwlock_destroy=no])
1384                         ])
1385                         if test $ol_cv_func_pthread_rwlock_destroy = yes ; then
1386                                 AC_DEFINE(HAVE_PTHREAD_RWLOCK_DESTROY,1,
1387                                         [define if you have pthread_rwlock_destroy function])
1388                         fi
1389
1390                         dnl Check for pthread_detach with <pthread.h> inclusion
1391                         dnl as it's symbol may have been mangled.
1392                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1393                                 [ol_cv_func_pthread_detach], [
1394                                 dnl save the flags
1395                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1396 #include <pthread.h>
1397 #ifndef NULL
1398 #define NULL (void*)0
1399 #endif
1400 ]], [[pthread_detach(NULL);]])],[ol_cv_func_pthread_detach=yes],[ol_cv_func_pthread_detach=no])
1401                         ])
1402
1403                         if test $ol_cv_func_pthread_detach = no ; then
1404                                 AC_MSG_ERROR([could not locate pthread_detach()])
1405                         fi
1406
1407                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1408                                 [define if you have pthread_detach function])
1409
1410                         dnl Check for setconcurreny functions
1411                         AC_CHECK_FUNCS( \
1412                                 pthread_setconcurrency \
1413                                 pthread_getconcurrency \
1414                                 thr_setconcurrency \
1415                                 thr_getconcurrency \
1416                         )
1417
1418                         OL_SYS_LINUX_THREADS
1419                         OL_LINUX_THREADS
1420
1421                         if test $ol_cv_linux_threads = error; then
1422                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1423                         fi
1424
1425                         AC_CACHE_CHECK([if pthread_create() works],
1426                                 ol_cv_pthread_create_works,[
1427                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1428                                 [ol_cv_pthread_create_works=yes],
1429                                 [ol_cv_pthread_create_works=no],
1430                                 [dnl assume yes
1431                                 ol_cv_pthread_create_works=yes])])
1432
1433                         if test $ol_cv_pthread_create_works = no ; then
1434                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1435                         fi
1436
1437                         ol_replace_broken_yield=no
1438 dnl                     case "$target" in
1439 dnl                     *-*-linux*)
1440 dnl                             AC_CHECK_FUNCS(nanosleep)
1441 dnl                             ol_replace_broken_yield=yes
1442 dnl                     ;;
1443 dnl                     esac
1444
1445                         if test $ol_replace_broken_yield = yes ; then
1446                                 AC_DEFINE([REPLACE_BROKEN_YIELD],1,
1447                                         [define if sched_yield yields the entire process])
1448                         fi
1449
1450                         dnl Check if select causes an yield
1451                         if test $ol_with_yielding_select = auto ; then
1452                                 AC_CACHE_CHECK([if select yields when using pthreads],
1453                                         ol_cv_pthread_select_yields,[
1454                                 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1455 #include <sys/types.h>
1456 #include <sys/time.h>
1457 #include <unistd.h>
1458 #include <pthread.h>
1459 #ifndef NULL
1460 #define NULL (void*) 0
1461 #endif
1462
1463 static int fildes[2];
1464
1465 static void *task(p)
1466         void *p;
1467 {
1468         int i;
1469         struct timeval tv;
1470
1471         fd_set rfds;
1472
1473         tv.tv_sec=10;
1474         tv.tv_usec=0;
1475
1476         FD_ZERO(&rfds);
1477         FD_SET(fildes[0], &rfds);
1478
1479         /* we're not interested in any fds */
1480         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1481
1482         if(i < 0) {
1483                 perror("select");
1484                 exit(10);
1485         }
1486
1487         exit(0); /* if we exit here, the select blocked the whole process */
1488 }
1489
1490 int main(argc, argv)
1491         int argc;
1492         char **argv;
1493 {
1494         pthread_t t;
1495
1496         /* create a pipe to select */
1497         if(pipe(&fildes[0])) {
1498                 perror("select");
1499                 exit(1);
1500         }
1501
1502 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1503         (void) pthread_setconcurrency(2);
1504 #else
1505 #ifdef HAVE_THR_SETCONCURRENCY
1506         /* Set Solaris LWP concurrency to 2 */
1507         thr_setconcurrency(2);
1508 #endif
1509 #endif
1510
1511 #if HAVE_PTHREADS < 6
1512         pthread_create(&t, pthread_attr_default, task, NULL);
1513 #else
1514         pthread_create(&t, NULL, task, NULL);
1515 #endif
1516
1517         /* make sure task runs first */
1518 #ifdef HAVE_THR_YIELD
1519         thr_yield();
1520 #elif defined( HAVE_SCHED_YIELD )
1521         sched_yield();
1522 #elif defined( HAVE_PTHREAD_YIELD )
1523         pthread_yield();
1524 #endif
1525
1526         exit(2);
1527 }]])],[ol_cv_pthread_select_yields=no],[ol_cv_pthread_select_yields=yes],[ol_cv_pthread_select_yields=cross])])
1528
1529                                 if test $ol_cv_pthread_select_yields = cross ; then
1530                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1531                                 fi
1532
1533                                 if test $ol_cv_pthread_select_yields = yes ; then
1534                                         ol_with_yielding_select=yes
1535                                 fi
1536                         fi
1537
1538                         dnl restore flags
1539                         CPPFLAGS="$save_CPPFLAGS"
1540                         LIBS="$save_LIBS"
1541                 else
1542                         AC_MSG_ERROR([could not locate usable POSIX Threads])
1543                 fi
1544         fi
1545
1546         if test $ol_with_threads = posix ; then
1547                 AC_MSG_ERROR([could not locate POSIX Threads])
1548         fi
1549         ;;
1550 esac
1551
1552 case $ol_with_threads in auto | yes | mach)
1553
1554         dnl check for Mach CThreads
1555         AC_CHECK_HEADERS(mach/cthreads.h cthreads.h)
1556         if test $ac_cv_header_mach_cthreads_h = yes ; then
1557                 ol_with_threads=found
1558
1559                 dnl check for cthreads support in current $LIBS
1560                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1561
1562                 if test $ol_link_threads = no ; then
1563                         dnl try -all_load
1564                         dnl this test needs work
1565                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1566                                 [ol_cv_cthread_all_load], [
1567                                 dnl save the flags
1568                                 save_LIBS="$LIBS"
1569                                 LIBS="-all_load $LIBS"
1570                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <mach/cthreads.h>]], [[
1571                                         cthread_fork((void *)0, (void *)0);
1572                                         ]])],[ol_cv_cthread_all_load=yes],[ol_cv_cthread_all_load=no])
1573                                 dnl restore the LIBS
1574                                 LIBS="$save_LIBS"
1575                         ])
1576
1577                         if test $ol_cv_cthread_all_load = yes ; then
1578                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1579                                 ol_link_threads=mach
1580                                 ol_with_threads=found
1581                         fi
1582                 fi
1583
1584         elif test $ac_cv_header_cthreads_h = yes ; then
1585                 dnl Hurd variant of Mach Cthreads
1586                 dnl uses <cthreads.h> and -lthreads
1587
1588                 ol_with_threads=found
1589
1590                 dnl save the flags
1591                 save_LIBS="$LIBS"
1592                 LIBS="$LIBS -lthreads"
1593                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1594                 LIBS="$save_LIBS"
1595
1596                 if test $ol_link_threads = yes ; then
1597                         LTHREAD_LIBS="-lthreads"
1598                         ol_link_threads=mach
1599                         ol_with_threads=found
1600                 else
1601                         AC_MSG_ERROR([could not link with Mach CThreads])
1602                 fi
1603
1604         elif test $ol_with_threads = mach ; then
1605                 AC_MSG_ERROR([could not locate Mach CThreads])
1606         fi
1607
1608         if test $ol_link_threads = mach ; then
1609                 AC_DEFINE(HAVE_MACH_CTHREADS,1,
1610                         [define if you have Mach Cthreads])
1611         elif test $ol_with_threads = found ; then
1612                 AC_MSG_ERROR([could not link with Mach CThreads])
1613         fi
1614         ;;
1615 esac
1616
1617 case $ol_with_threads in auto | yes | pth)
1618
1619         AC_CHECK_HEADERS(pth.h)
1620
1621         if test $ac_cv_header_pth_h = yes ; then
1622                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1623
1624                 if test $have_pth = yes ; then
1625                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1626                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1627                         ol_link_threads=pth
1628                         ol_with_threads=found
1629
1630                         if test $ol_with_yielding_select = auto ; then
1631                                 ol_with_yielding_select=yes
1632                         fi
1633                 fi
1634         fi
1635         ;;
1636 esac
1637
1638 case $ol_with_threads in auto | yes | lwp)
1639
1640         dnl check for SunOS5 LWP
1641         AC_CHECK_HEADERS(thread.h synch.h)
1642         if test $ac_cv_header_thread_h = yes &&
1643            test $ac_cv_header_synch_h = yes ; then
1644                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1645
1646                 if test $have_thr = yes ; then
1647                         AC_DEFINE(HAVE_THR,1,
1648                                 [if you have Solaris LWP (thr) package])
1649                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1650                         ol_link_threads=thr
1651
1652                         if test $ol_with_yielding_select = auto ; then
1653                                 ol_with_yielding_select=yes
1654                         fi
1655
1656                         dnl Check for setconcurreny functions
1657                         AC_CHECK_FUNCS( \
1658                                 thr_setconcurrency \
1659                                 thr_getconcurrency \
1660                         )
1661                 fi
1662         fi
1663
1664         dnl check for SunOS4 LWP
1665         AC_CHECK_HEADERS(lwp/lwp.h)
1666         if test $ac_cv_header_lwp_lwp_h = yes ; then
1667                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1668
1669                 if test $have_lwp = yes ; then
1670                         AC_DEFINE(HAVE_LWP,1,
1671                                 [if you have SunOS LWP package])
1672                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1673                         ol_link_threads=lwp
1674
1675                         if test $ol_with_yielding_select = auto ; then
1676                                 ol_with_yielding_select=no
1677                         fi
1678                 fi
1679         fi
1680         ;;
1681 esac
1682
1683 if test $ol_with_yielding_select = yes ; then
1684         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1685                 [define if select implicitly yields])
1686 fi
1687
1688 if test $ol_with_threads = manual ; then
1689         dnl User thinks he can manually configure threads.
1690         ol_link_threads=yes
1691
1692         AC_MSG_WARN([thread defines and link options must be set manually])
1693
1694         AC_CHECK_HEADERS(pthread.h sched.h)
1695         AC_CHECK_FUNCS(sched_yield pthread_yield)
1696         OL_HEADER_LINUX_THREADS
1697
1698         AC_CHECK_HEADERS(mach/cthreads.h)
1699         AC_CHECK_HEADERS(lwp/lwp.h)
1700         AC_CHECK_HEADERS(thread.h synch.h)
1701 fi
1702
1703 if test $ol_link_threads != no && test $ol_link_threads != nt ; then
1704         dnl needed to get reentrant/threadsafe versions
1705         dnl
1706         AC_DEFINE(REENTRANT,1)
1707         AC_DEFINE(_REENTRANT,1)
1708         AC_DEFINE(THREAD_SAFE,1)
1709         AC_DEFINE(_THREAD_SAFE,1)
1710         AC_DEFINE(THREADSAFE,1)
1711         AC_DEFINE(_THREADSAFE,1)
1712         AC_DEFINE(_SGI_MP_SOURCE,1)
1713
1714         dnl The errno declaration may dependent upon _REENTRANT.
1715         dnl If it does, we must link with thread support.
1716         AC_CACHE_CHECK([for thread specific errno],
1717                 [ol_cv_errno_thread_specific], [
1718                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[errno = 0;]])],[ol_cv_errno_thread_specific=yes],[ol_cv_errno_thread_specific=no])
1719         ])
1720
1721         dnl The h_errno declaration may dependent upon _REENTRANT.
1722         dnl If it does, we must link with thread support.
1723         AC_CACHE_CHECK([for thread specific h_errno],
1724                 [ol_cv_h_errno_thread_specific], [
1725                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[h_errno = 0;]])],[ol_cv_h_errno_thread_specific=yes],[ol_cv_h_errno_thread_specific=no])
1726         ])
1727
1728         if test $ol_cv_errno_thread_specific != yes ||
1729            test $ol_cv_h_errno_thread_specific != yes ; then
1730                 LIBS="$LTHREAD_LIBS $LIBS"
1731                 LTHREAD_LIBS=""
1732         fi
1733
1734 dnl When in thread environment, use
1735 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) || defined( HAVE_FUNC_R )
1736 dnl                     func_r(...);
1737 dnl             #else
1738 dnl             #       if defined( HAVE_THREADS )
1739 dnl                             /* lock */
1740 dnl             #       endif
1741 dnl                             func(...);
1742 dnl             #       if defined( HAVE_THREADS )
1743 dnl                             /* unlock */
1744 dnl             #       endif
1745 dnl             #endif
1746 dnl
1747 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1748 dnl             _POSIX_REENTRANT_FUNCTIONS
1749 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1750 dnl             _POSIX_THREADSAFE_FUNCTIONS
1751 dnl
1752 dnl             and is currently defined in <ldap_pvt_thread.h>
1753 dnl
1754 dnl HAVE_THREADS is defined by <ldap_pvt_thread.h> iff -UNO_THREADS
1755 dnl
1756 dnl libldap/*.c should only include <ldap_pvt_thread.h> iff
1757 dnl LDAP_R_COMPILE is defined.  ie:
1758 dnl             #ifdef LDAP_R_COMPILE
1759 dnl             #       include <ldap_pvt_thread.h>
1760 dnl             #endif
1761 dnl
1762 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1763 dnl specifically for compiling the threadsafe version of
1764 dnl     the ldap library (-lldap_r).
1765 dnl
1766 dnl     dnl check for reentrant/threadsafe functions
1767 dnl     dnl
1768 dnl     dnl note: these should only be used when linking
1769 dnl     dnl             with $LTHREAD_LIBS
1770 dnl     dnl
1771 dnl     save_CPPFLAGS="$CPPFLAGS"
1772 dnl     save_LIBS="$LIBS"
1773 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1774 dnl     AC_CHECK_FUNCS( \
1775 dnl             gmtime_r \
1776 dnl             gethostbyaddr_r gethostbyname_r \
1777 dnl             feof_unlocked unlocked_feof \
1778 dnl             putc_unlocked unlocked_putc \
1779 dnl             flockfile ftrylockfile \
1780 dnl     )
1781 dnl     CPPFLAGS="$save_CPPFLAGS"
1782 dnl     LIBS="$save_LIBS"
1783 fi
1784
1785 if test $ol_link_threads = no ; then
1786         if test $ol_with_threads = yes ; then
1787                 AC_MSG_ERROR([no suitable thread support])
1788         fi
1789
1790         if test $ol_with_threads = auto ; then
1791                 AC_MSG_WARN([no suitable thread support, disabling threads])
1792                 ol_with_threads=no
1793         fi
1794
1795         AC_DEFINE(NO_THREADS,1,
1796                 [define if you have (or want) no threads])
1797         LTHREAD_LIBS=""
1798         BUILD_THREAD=no
1799 else
1800         BUILD_THREAD=yes
1801 fi
1802
1803 if test $ol_link_threads != no ; then
1804         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1,
1805                 [define to 1 if library is thread safe])
1806 fi
1807
1808 dnl ----------------------------------------------------------------
1809 dnl Tests for reentrant functions necessary to build -lldap_r
1810 AC_CHECK_FUNCS(         \
1811         ctime_r                 \
1812         gethostbyname_r gethostbyaddr_r \
1813 )
1814
1815 if test "$ac_cv_func_ctime_r" = no ; then
1816         ol_cv_func_ctime_r_nargs=0
1817 else
1818         OL_FUNC_CTIME_R_NARGS
1819 dnl     OL_FUNC_CTIME_R_TYPE
1820 fi
1821
1822 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1823         OL_FUNC_GETHOSTBYNAME_R_NARGS
1824 else
1825         ol_cv_func_gethostbyname_r_nargs=0
1826 fi
1827
1828 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1829         OL_FUNC_GETHOSTBYADDR_R_NARGS
1830 else
1831         ol_cv_func_gethostbyaddr_r_nargs=0
1832 fi
1833
1834 dnl ----------------------------------------------------------------
1835 ol_link_bdb=no
1836
1837 if test $ol_enable_bdb/$ol_enable_hdb != no/no; then
1838         OL_BERKELEY_DB
1839
1840         if test $ol_cv_berkeley_db = no ; then
1841                 AC_MSG_ERROR(BDB/HDB: BerkeleyDB not available)
1842         fi
1843
1844         AC_DEFINE(HAVE_BERKELEY_DB,1,
1845                 [define this if Berkeley DB is available])
1846
1847         dnl $ol_cv_lib_db should be yes or -ldb
1848         dnl (it could be no, but that would be an error
1849         if test $ol_cv_lib_db != yes ; then
1850                 BDB_LIBS="$BDB_LIBS $ol_cv_lib_db"
1851         fi
1852
1853         OL_BDB_COMPAT
1854
1855         if test $ol_cv_bdb_compat != yes ; then
1856                 AC_MSG_ERROR([BDB/HDB: BerkeleyDB version incompatible])
1857         fi
1858
1859         SLAPD_LIBS="$SLAPD_LIBS \$(BDB_LIBS)"
1860
1861         ol_link_bdb=yes
1862 fi
1863
1864 dnl ----------------------------------------------------------------
1865
1866 if test $ol_enable_dynamic = yes && test $enable_shared = yes ; then
1867         BUILD_LIBS_DYNAMIC=shared
1868         AC_DEFINE(LDAP_LIBS_DYNAMIC, 1, [define if LDAP libs are dynamic])
1869         LTSTATIC=""
1870 else
1871         BUILD_LIBS_DYNAMIC=static
1872         LTSTATIC="-static"
1873 fi
1874 AC_SUBST(LTSTATIC)dnl
1875
1876 dnl ----------------------------------------------------------------
1877 if test $ol_enable_wrappers != no ; then
1878         AC_CHECK_HEADERS(tcpd.h,[
1879                 AC_MSG_CHECKING([for TCP wrappers library])
1880                 save_LIBS="$LIBS"
1881                 LIBS="$LIBS -lwrap"
1882                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1883 #include <tcpd.h>
1884 int allow_severity = 0;
1885 int deny_severity  = 0;
1886
1887 struct request_info *req;
1888                 ]], [[
1889 hosts_access(req)
1890                 ]])],[AC_MSG_RESULT([-lwrap])
1891                 have_wrappers=yes
1892                 LIBS="$save_LIBS"],[
1893                 dnl try with -lnsl
1894                 LIBS="$LIBS -lnsl"
1895                 AC_TRY_LINK([
1896 #include <tcpd.h>
1897 int allow_severity = 0;
1898 int deny_severity  = 0;
1899
1900 struct request_info *req;
1901                 ],[
1902 hosts_access(req)
1903                 ],[AC_MSG_RESULT([-lwrap -lnsl])
1904                 have_wrappers=yes
1905                 LIBS="$save_LIBS -lnsl"],[
1906                 AC_MSG_RESULT(no)
1907                 have_wrappers=no
1908                 LIBS=$save_LIBS])])],[have_wrappers=no])
1909
1910         if test $have_wrappers = yes ; then
1911                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1912                 WRAP_LIBS="-lwrap"
1913         elif test $ol_enable_wrappers = yes ; then
1914                 AC_MSG_ERROR([could not find TCP wrappers, select apppropriate options or disable])
1915         else
1916                 AC_MSG_WARN([could not find TCP wrappers, support disabled])
1917                 WRAP_LIBS=""
1918         fi
1919 fi
1920
1921 dnl ----------------------------------------------------------------
1922 if test $ol_enable_syslog != no ; then
1923         AC_CHECK_FUNC(openlog)
1924         if test $ac_cv_func_openlog = no && test $ol_enable_syslog = yes; then
1925                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1926         fi
1927         ol_enable_syslog=$ac_cv_func_openlog
1928 fi
1929
1930 dnl ----------------------------------------------------------------
1931 dnl SQL
1932 ol_link_sql=no
1933 if test $ol_enable_sql != no ; then
1934         AC_CHECK_HEADERS(sql.h sqlext.h,[],[
1935                 AC_MSG_ERROR([could not locate SQL headers])
1936         ])
1937
1938         sql_LIBS="$LIBS"
1939         LIBS="$LTHREAD_LIBS"
1940
1941         if test $ol_with_odbc = auto ; then
1942                 ol_with_odbc="iodbc unixodbc odbc32"
1943         fi
1944
1945         for odbc in $ol_with_odbc ; do
1946                 if test $ol_link_sql = no ; then
1947                         case $odbc in
1948                         iodbc)
1949                                 AC_CHECK_LIB(iodbc, SQLDriverConnect, [have_iodbc=yes], [have_iodbc=no])
1950                                 if test $have_iodbc = yes ; then
1951                                         ol_link_sql="-liodbc"
1952                                 fi
1953                                 ;;
1954
1955                         unixodbc)
1956                                 AC_CHECK_LIB(odbc, SQLDriverConnect, [have_odbc=yes], [have_odbc=no])
1957                                 if test $have_odbc = yes ; then
1958                                         ol_link_sql="-lodbc"
1959                                 fi
1960                                 ;;
1961
1962                         odbc32)
1963                                 AC_CHECK_LIB(odbc32, SQLDriverConnect, [have_odbc32=yes], [have_odbc32=no])
1964                                 if test $have_odbc32 = yes ; then
1965                                         ol_link_sql="-lodbc32"
1966                                 fi
1967                                 ;;
1968
1969                         *)
1970                                 AC_MSG_ERROR([unknown ODBC library])
1971                                 ;;
1972                         esac
1973                 fi
1974         done
1975
1976         LIBS="$sql_LIBS"
1977
1978         if test $ol_link_sql != no ; then
1979                 SLAPD_SQL_LIBS="$ol_link_sql"
1980
1981         elif test $ol_enable_sql != auto ; then
1982                 AC_MSG_ERROR([could not locate suitable ODBC library])
1983         fi
1984 fi
1985
1986 dnl ----------------------------------------------------------------
1987 dnl MySQL NDBapi
1988 dnl Note: uses C++, but we don't want to add C++ test overhead to
1989 dnl the rest of the libtool machinery.
1990 ol_link_ndb=no
1991 if test $ol_enable_ndb != no ; then
1992         AC_CHECK_PROG(MYSQL,mysql_config,yes)
1993         if test "$MYSQL" != yes ; then
1994                 AC_MSG_ERROR([could not locate mysql_config])
1995         fi
1996
1997         SQL_INC=`mysql_config --include`
1998         SLAPD_NDB_INCS="$SQL_INC $SQL_INC/storage/ndb $SQL_INC/storage/ndb/ndbapi"
1999
2000         save_CPPFLAGS="$CPPFLAGS"
2001         CPPFLAGS="$SLAPD_NDB_INCS"
2002         AC_MSG_CHECKING(for NdbApi.hpp)
2003         AC_PREPROC_IFELSE(
2004                 [AC_LANG_SOURCE([[#include <NdbApi.hpp>]])],
2005                         AC_MSG_RESULT(yes),
2006                         AC_MSG_ERROR([could not locate NdbApi headers])
2007         )
2008         CPPFLAGS="$save_CPPFLAGS"
2009
2010         SQL_LIB=`mysql_config --libs_r`
2011         SLAPD_NDB_LIBS="$SQL_LIB -lndbclient -lstdc++"
2012
2013         save_LDFLAGS="$LDFLAGS"
2014         save_LIBS="$LIBS"
2015         LDFLAGS="$SQL_LIB"
2016         AC_CHECK_LIB(ndbclient,ndb_init,[: ok],[
2017                 AC_MSG_ERROR([could not locate ndbclient library])
2018         ],[-lstdc++])
2019         LIBS="$save_LIBS"
2020         LDFLAGS="$save_LDFLAGS"
2021
2022         if test "$ol_enable_ndb" = yes ; then
2023                 SLAPD_LIBS="$SLAPD_LIBS \$(SLAPD_NDB_LIBS)"
2024         fi
2025 fi
2026
2027 dnl ----------------------------------------------------------------
2028 dnl International Components for Unicode
2029 OL_ICU
2030 if test "$ol_icu" = no ; then
2031         AC_MSG_WARN([ICU not available])
2032 else
2033         ICU_LIBS="$ol_icu"
2034 fi
2035 dnl ----------------------------------------------------------------
2036 dnl
2037 dnl Check for Cyrus SASL
2038 dnl
2039 WITH_SASL=no
2040 ol_link_sasl=no
2041 ol_link_spasswd=no
2042 if test $ol_with_cyrus_sasl != no ; then
2043         AC_CHECK_HEADERS(sasl/sasl.h sasl.h)
2044
2045         if test $ac_cv_header_sasl_sasl_h = yes ||
2046            test $ac_cv_header_sasl_h = yes; then
2047                 AC_CHECK_LIB(sasl2, sasl_client_init,
2048                         [ol_link_sasl="-lsasl2"],
2049                         [AC_CHECK_LIB(sasl, sasl_client_init,
2050                                 [ol_link_sasl="-lsasl"])])
2051         fi
2052
2053         if test $ol_link_sasl = no ; then
2054                 if test $ol_with_cyrus_sasl != auto ; then
2055                         AC_MSG_ERROR([Could not locate Cyrus SASL])
2056                 else
2057                         AC_MSG_WARN([Could not locate Cyrus SASL])
2058                         AC_MSG_WARN([SASL authentication not supported!])
2059                         if test $ol_link_tls = no ; then
2060                                 AC_MSG_WARN([Strong authentication not supported!])
2061                         fi
2062                 fi
2063         else
2064                 OL_SASL_COMPAT
2065                 if test $ol_cv_sasl_compat = no ; then
2066                         ol_link_sasl=no
2067                         AC_MSG_ERROR([Cyrus SASL library located but is incompatible])
2068                 fi
2069
2070                 AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
2071                 SASL_LIBS="$ol_link_sasl"
2072                 if test $ol_enable_spasswd != no ; then
2073                         ol_link_spasswd=yes
2074                 fi
2075
2076                 ac_save_LIBS="$LIBS"
2077                 LIBS="$LIBS $ol_link_sasl"
2078                 AC_CHECK_FUNC(sasl_version, [AC_DEFINE(HAVE_SASL_VERSION,1,
2079                         [define if your SASL library has sasl_version()])])
2080                 LIBS="$ac_save_LIBS"
2081
2082                 WITH_SASL=yes
2083         fi
2084
2085 else
2086         AC_MSG_WARN([SASL authentication not supported!])
2087         if test $ol_link_tls = no ; then
2088                 AC_MSG_WARN([Strong authentication not supported!])
2089         fi
2090 fi
2091
2092 dnl ----------------------------------------------------------------
2093 dnl Check for entropy sources
2094 if test $cross_compiling != yes && test "$ac_cv_mingw32" != yes ; then
2095         dev=no
2096         if test -r /dev/urandom ; then
2097                 dev="/dev/urandom";
2098         elif test -r /idev/urandom ; then
2099                 dev="/idev/urandom";
2100         elif test -r /dev/srandom ; then
2101                 dev="/dev/srandom";
2102         elif test -r /dev/random ; then
2103                 dev="/dev/random";
2104         elif test -r /idev/random ; then
2105                 dev="/idev/random";
2106         fi
2107
2108         if test $dev != no ; then
2109                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
2110         fi
2111 fi
2112
2113 dnl ----------------------------------------------------------------
2114 dnl
2115 dnl Check for fetch URL support
2116 dnl             should be extended to support other fetch URL APIs
2117 dnl
2118 ol_link_fetch=no
2119 if test $ol_with_fetch != no ; then
2120         OL_LIB_FETCH
2121
2122         if test $ol_cv_lib_fetch != no ; then
2123                 LUTIL_LIBS="$LUTIL_LIBS $ol_link_fetch"
2124                 ol_link_fetch=freebsd
2125
2126         elif test $ol_with_fetch != auto ; then
2127                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
2128         fi
2129 fi
2130
2131 dnl ----------------------------------------------------------------
2132 dnl FreeBSD (and others) have crypt(3) in -lcrypt
2133 if test $ol_enable_crypt != no ; then
2134         save_LIBS="$LIBS"
2135         LIBS="$TLS_LIBS $LIBS"
2136
2137         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
2138                 LIBS="$save_LIBS"
2139                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
2140                         have_crypt=yes], [have_crypt=no])])
2141
2142         LIBS="$save_LIBS"
2143
2144         if test $have_crypt = yes ; then
2145                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
2146         else
2147                 AC_MSG_WARN([could not find crypt])
2148                 if test $ol_enable_crypt = yes ; then
2149                         AC_MSG_ERROR([could not find crypt, select appropriate options or disable])
2150                 fi
2151
2152                 AC_MSG_WARN([disabling crypt support])
2153                 ol_enable_crypt=no
2154         fi
2155 fi
2156
2157 dnl ----------------------------------------------------------------
2158 dnl FreeBSD (and others) have setproctitle(3) in -lutil
2159 if test $ol_enable_proctitle != no ; then
2160         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
2161                 AC_CHECK_LIB(util, setproctitle,
2162                         [have_setproctitle=yes
2163                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
2164                         [have_setproctitle=no
2165                         AC_LIBOBJ(setproctitle)
2166                         LIBSRCS="$LIBSRCS setproctitle.c"])])
2167
2168         if test $have_setproctitle = yes ; then
2169                 AC_DEFINE(HAVE_SETPROCTITLE,1,
2170                         [define if setproctitle(3) is available])
2171         fi
2172 fi
2173
2174 dnl ----------------------------------------------------------------
2175 if test $ol_enable_slp != no ; then
2176         AC_CHECK_HEADERS( slp.h )
2177
2178         if test $ac_cv_header_slp_h = yes ; then
2179                 AC_CHECK_LIB(slp, SLPOpen, [have_slp=yes], [have_slp=no])
2180                 if test $have_slp = yes ; then
2181                         AC_DEFINE(HAVE_SLP, 1, [define if you have -lslp])
2182                         SLAPD_SLP_LIBS=-lslp
2183                 fi
2184
2185         elif test $ol_enable_slp = yes ; then
2186                 AC_MSG_ERROR([SLP not found])
2187         fi
2188 fi
2189
2190 dnl ----------------------------------------------------------------
2191 dnl Checks for typedefs, structures, and compiler characteristics.
2192
2193 AC_CHECK_TYPE(mode_t, int)
2194 AC_CHECK_TYPE(off_t, long)
2195 AC_CHECK_TYPE(pid_t, int)
2196 AC_CHECK_TYPE(ssize_t, [signed int])
2197 AC_CHECK_TYPE(caddr_t,  [char *])
2198 AC_CHECK_TYPE(size_t, unsigned)
2199
2200 AC_CHECK_TYPES([long long])
2201 AC_CHECK_TYPES([ptrdiff_t])
2202
2203
2204 AC_CHECK_TYPE([socklen_t],,, [$ac_includes_default
2205 #ifdef HAVE_SYS_SOCKET_H
2206 #include <sys/socket.h>
2207 #endif])
2208
2209 dnl socklen_t-like type in accept(), default socklen_t or int:
2210 dnl - The OS might define socklen_t without using it.  POSIX moved from
2211 dnl   int to size_t to socklen_t, hoping to stay at a 32-bit type, and
2212 dnl   HP-UX now has selectors for what to use.
2213 dnl - On Solaris 2.8 the prototype has void *len, but the default is OK.
2214 AC_MSG_CHECKING([the type of arg 3 to accept()])
2215 AC_CACHE_VAL(ol_cv_type_ber_socklen_t, [
2216         set socklen_t int unsigned "unsigned long" long size_t
2217         test "$ac_cv_type_socklen_t" = yes || shift
2218         ol_cv_type_ber_socklen_t=$1 guessing="guessing "
2219         for lentype in "$@" ; do for addrtype in "struct sockaddr" void ; do
2220                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([$ac_includes_default
2221 #ifdef HAVE_SYS_SOCKET_H
2222 #include <sys/socket.h>
2223 #endif
2224 extern int accept(int s, $addrtype *ap, $lentype *lp);
2225 ], [
2226 accept(0, (struct sockaddr *) 0, ($lentype *) 0);
2227 ])], [ol_cv_type_ber_socklen_t=$lentype guessing= ; break 2])
2228         done ; done])
2229 AC_MSG_RESULT([$guessing$ol_cv_type_ber_socklen_t *])
2230 AC_DEFINE_UNQUOTED(ber_socklen_t, $ol_cv_type_ber_socklen_t,
2231         [Define to the type of arg 3 for `accept'.])
2232
2233 dnl Modules should use ber_socklen_t, not socklen_t.  Define socklen_t
2234 dnl for the time being anyway, for backwards compatibility.
2235 if test "$ac_cv_type_socklen_t" != yes; then
2236         AC_DEFINE_UNQUOTED([socklen_t], [$ol_cv_type_ber_socklen_t],
2237                 [Define like ber_socklen_t if <sys/socket.h> does not define.])
2238 fi
2239
2240
2241 AC_TYPE_SIGNAL
2242
2243 AC_CHECK_TYPE([sig_atomic_t],,
2244         [AC_DEFINE_UNQUOTED([sig_atomic_t], [int],
2245                 [Define to `int' if <signal.h> does not define.])],
2246         [$ac_includes_default
2247 #include <signal.h>
2248         ])
2249
2250 AC_TYPE_UID_T
2251
2252 AC_HEADER_TIME
2253 AC_STRUCT_TM
2254 AC_CHECK_MEMBERS([struct stat.st_blksize])
2255 AC_CHECK_MEMBERS([struct passwd.pw_gecos],,,[$ac_includes_default
2256 #include <pwd.h>])
2257 AC_CHECK_MEMBERS([struct passwd.pw_passwd],,,[$ac_includes_default
2258 #include <pwd.h>])
2259
2260 OL_C_UPPER_LOWER
2261 AC_C_CONST
2262 OL_C_VOLATILE
2263
2264 if test $cross_compiling = yes ; then
2265         AC_MSG_WARN([Crossing compiling... all bets are off!])
2266         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2267 else
2268         AC_C_BIGENDIAN
2269 fi
2270
2271 AC_CHECK_SIZEOF(short)
2272 AC_CHECK_SIZEOF(int)
2273 AC_CHECK_SIZEOF(long)
2274 AC_CHECK_SIZEOF(long long)
2275 AC_CHECK_SIZEOF(wchar_t)
2276
2277 if test "$ac_cv_sizeof_int" -lt 4 ; then
2278         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2279
2280         AC_DEFINE(LBER_INT_T,long,[define to 32-bit or greater integer type])
2281 else
2282         AC_DEFINE(LBER_INT_T,int,[define to 32-bit or greater integer type])
2283 fi
2284
2285 AC_DEFINE(LBER_LEN_T,long,[define to large integer type])
2286 AC_DEFINE(LBER_SOCKET_T,int,[define to socket descriptor type])
2287 AC_DEFINE(LBER_TAG_T,long,[define to large integer type])
2288
2289 dnl ----------------------------------------------------------------
2290 dnl Check for multiple precision support
2291 if test $ol_with_mp = longlong || test $ol_with_mp = auto ; then
2292         if test $ac_cv_sizeof_long_long -gt 4 ; then
2293                 ol_with_mp=longlong
2294                 AC_DEFINE(USE_MP_LONG_LONG,1,[define to use 'long long' for MP])
2295         elif test $ol_with_mp = longlong ; then
2296                 AC_MSG_ERROR([long long unusable for multiple precision])
2297         fi
2298 fi
2299 if test $ol_with_mp = long || test $ol_with_mp = auto ; then
2300         if test $ac_cv_sizeof_long -gt 4 ; then
2301                 ol_with_mp=long
2302                 AC_DEFINE(USE_MP_LONG,1,[define to use 'long' for MP])
2303         elif test $ol_with_mp = long ; then
2304                 AC_MSG_ERROR([long unusable for multiple precision])
2305         fi
2306 fi
2307 if test $ol_with_mp = bignum || test $ol_with_mp = auto ; then
2308         AC_CHECK_HEADERS(openssl/bn.h)
2309         AC_CHECK_HEADERS(openssl/crypto.h)
2310         if test "$ac_cv_header_openssl_bn_h" = "yes" &&
2311                 test "$ac_cv_header_openssl_crypto_h" = "yes" &&
2312                 test "$ol_with_tls" = "found" ; then
2313                 ol_with_mp=bignum
2314                 AC_DEFINE(USE_MP_BIGNUM,1,[define to use OpenSSL BIGNUM for MP])
2315         elif test $ol_with_mp = bignum ; then
2316                 AC_MSG_ERROR([bignum not available])
2317         fi
2318 fi
2319 if test $ol_with_mp = gmp || test $ol_with_mp = auto ; then
2320         AC_CHECK_HEADERS(gmp.h)
2321         AC_CHECK_LIB(gmp, __gmpz_add_ui)
2322         if test $ac_cv_header_gmp_h = yes && test $ac_cv_lib_gmp___gmpz_add_ui = yes ; then
2323                 AC_DEFINE(USE_MP_GMP,1,[define to use GMP for MP])
2324                 ol_with_mp=gmp
2325         elif test $ol_with_mp = gmp ; then
2326                 AC_MSG_ERROR([gmp not available])
2327         fi
2328 fi
2329 if test $ol_with_mp = auto ; then
2330         ol_with_mp=no
2331 fi
2332
2333 dnl ----------------------------------------------------------------
2334 dnl Checks for library functions.
2335 AC_FUNC_MEMCMP
2336
2337 if test $ac_cv_func_memcmp_working = no ; then
2338         AC_DEFINE(NEED_MEMCMP_REPLACEMENT,1,
2339                 [define if memcmp is not 8-bit clean or is otherwise broken])
2340 fi
2341
2342 AC_FUNC_STRFTIME
2343
2344 OL_FUNC_INET_ATON
2345
2346 dnl Check for NT specific routines
2347 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2348
2349 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2350         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2351 ])
2352
2353 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2354         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2355 ])
2356
2357 AC_FUNC_VPRINTF
2358
2359 if test $ac_cv_func_vprintf = yes ; then
2360         dnl check for vsnprintf
2361         AC_CHECK_FUNCS(snprintf vsnprintf)
2362 fi
2363
2364 AC_CHECK_FUNCS(                 \
2365         bcopy                   \
2366         closesocket             \
2367         chroot                  \
2368         endgrent                \
2369         endpwent                \
2370         fcntl                   \
2371         flock                   \
2372         fstat                   \
2373         getdtablesize           \
2374         getgrgid                \
2375         gethostname             \
2376         getpass                 \
2377         getpassphrase           \
2378         getpwuid                \
2379         getpwnam                \
2380         getspnam                \
2381         gettimeofday            \
2382         initgroups              \
2383         inet_ntoa_b             \
2384         ioctl                   \
2385         lockf                   \
2386         memcpy                  \
2387         memmove                 \
2388         memrchr                 \
2389         mkstemp                 \
2390         mktemp                  \
2391         pipe                    \
2392         read                    \
2393         recv                    \
2394         recvfrom                \
2395         setpwfile               \
2396         setgid                  \
2397         setegid                 \
2398         setsid                  \
2399         setuid                  \
2400         seteuid                 \
2401         signal                  \
2402         strdup                  \
2403         strpbrk                 \
2404         strrchr                 \
2405         strsep                  \
2406         strstr                  \
2407         strtol                  \
2408         strtoul                 \
2409         strtoq                  \
2410         strtouq                 \
2411         strtoll                 \
2412         strspn                  \
2413         sysconf                 \
2414         waitpid                 \
2415         wait4                   \
2416         write                   \
2417         send                    \
2418         sendmsg                 \
2419         sendto                  \
2420 )
2421
2422 dnl We actually may need to replace more than this.
2423 AC_REPLACE_FUNCS(getopt getpeereid)
2424
2425 if test "$ac_cv_func_getopt" != yes; then
2426         LIBSRCS="$LIBSRCS getopt.c"
2427 fi
2428
2429 if test "$ac_cv_func_getpeereid" != yes; then
2430         AC_CHECK_FUNCS( getpeerucred )
2431         if test "$ac_cv_func_getpeerucred" != yes ; then
2432                 AC_CHECK_MEMBERS([struct msghdr.msg_accrightslen],,,
2433                         [$ac_includes_default
2434 #ifdef HAVE_SYS_SOCKET_H
2435 #include <sys/socket.h>
2436 #endif])
2437                 if test "$ac_cv_member_struct_msghdr_msg_accrightslen" != yes; then
2438                         AC_CHECK_MEMBERS([struct msghdr.msg_control],,,
2439                                 [$ac_includes_default
2440 #ifdef HAVE_SYS_SOCKET_H
2441 #include <sys/socket.h>
2442 #endif])
2443                 fi
2444                 AC_CHECK_MEMBERS([struct stat.st_fstype, struct stat.st_vfstype])
2445                 if test "$ac_cv_member_struct_stat_st_fstype" = yes; then
2446                         AC_COMPILE_IFELSE([struct stat st; char *ptr=st.st_fstype;],
2447                                 AC_DEFINE([HAVE_STRUCT_STAT_ST_FSTYPE_CHAR],1,[define to 1 if st_fstype is char *]),
2448                                 AC_DEFINE([HAVE_STRUCT_STAT_ST_FSTYPE_INT],1,[define to 1 if st_fstype is int]))
2449                 fi
2450         fi
2451         LIBSRCS="$LIBSRCS getpeereid.c"
2452 fi
2453
2454 if test "$ac_cv_func_snprintf" != yes ||
2455    test "$ac_cv_func_vsnprintf" != yes; then
2456         if test "$ac_cv_func_snprintf" != yes; then
2457                 AC_DEFINE(snprintf, ber_pvt_snprintf, [define to snprintf routine])
2458         fi
2459         if test "$ac_cv_func_vsnprintf" != yes; then
2460                 AC_DEFINE(vsnprintf, ber_pvt_vsnprintf, [define to snprintf routine])
2461         fi
2462 fi
2463
2464 dnl ----------------------------------------------------------------
2465 dnl Sort out defines
2466
2467 if test "$ol_enable_slapi" != no ; then
2468         dnl This check is done also if --enable-modules is used;
2469         dnl it is duplicated here, 'cause it'd be cached anyway
2470         AC_CHECK_HEADERS(ltdl.h)
2471
2472         if test $ac_cv_header_ltdl_h != yes ; then
2473                 AC_MSG_ERROR([could not locate <ltdl.h>])
2474         fi
2475         AC_CHECK_LIB(ltdl, lt_dlinit, [
2476                 SLAPI_LIBS=-lltdl
2477                 LIBSLAPI=libslapi.a
2478                 LIBSLAPITOOLS=../libslapi.a
2479                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
2480         ],[AC_MSG_ERROR([could not locate libtool -lltdl])])
2481
2482         AC_DEFINE(LDAP_SLAPI,1, [define this to add SLAPI code])
2483 fi
2484
2485 if test "$ol_enable_debug" != no ; then
2486         if test "$ol_enable_debug" = traditional; then
2487                 AC_DEFINE(OLD_DEBUG,1,
2488                         [define to use the original debug style])
2489         fi
2490         AC_DEFINE(LDAP_DEBUG,1,
2491                 [define this to add debugging code])
2492 fi
2493 if test "$ol_enable_syslog" = yes ; then
2494         AC_DEFINE(LDAP_SYSLOG,1,
2495                 [define this to add syslog code])
2496 fi
2497 if test "$ol_enable_proctitle" != no ; then
2498         AC_DEFINE(LDAP_PROCTITLE,1,
2499                 [define this for LDAP process title support])
2500 fi
2501 if test "$ol_enable_referrals" != no ; then
2502         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION,
2503                 [define to LDAP VENDOR VERSION])
2504 fi
2505 if test "$ol_enable_local" != no; then
2506         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2507 fi
2508 if test "$ol_link_ipv6" != no; then
2509         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2510 fi
2511 if test "$ol_enable_cleartext" != no ; then
2512         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2513 fi
2514 if test "$ol_enable_crypt" != no ; then
2515         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2516 fi
2517 if test "$ol_link_spasswd" != no ; then
2518         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2519 fi
2520 if test "$ol_enable_rlookups" != no ; then
2521         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2522 fi
2523 if test "$ol_enable_aci" != no ; then
2524         if test $ol_enable_dynacl = no ; then
2525                 ol_enable_dynacl=yes
2526                 AC_MSG_WARN([ACIs need dynacl])
2527         fi
2528         if test "$ol_enable_aci" = mod ; then
2529                 MFLAG=SLAPD_MOD_DYNAMIC
2530                 dnl remove this after moving servers/slapd/aci.c in contrib/slapd-modules/acl
2531                 AC_MSG_ERROR([ACI build as dynamic module not supported (yet)])
2532         else
2533                 MFLAG=SLAPD_MOD_STATIC
2534         fi
2535         WITH_ACI_ENABLED=$ol_enable_aci
2536         AC_DEFINE_UNQUOTED(SLAPD_ACI_ENABLED,$MFLAG,[define to support per-object ACIs])
2537 else
2538         WITH_ACI_ENABLED=no
2539 fi
2540 if test "$ol_enable_dynacl" != no ; then
2541         AC_DEFINE(SLAP_DYNACL,1,[define to support run-time loadable ACL])
2542 fi
2543
2544 if test "$ol_link_modules" != no ; then
2545         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2546         BUILD_SLAPD=yes
2547         SLAPD_MODULES_LDFLAGS="-dlopen self"
2548 fi
2549
2550 AC_DEFINE(SLAPD_MOD_STATIC,1,[statically linked module])
2551 AC_DEFINE(SLAPD_MOD_DYNAMIC,2,[dynamically linked module])
2552
2553 dnl back-monitor goes first (well, after back-config)
2554 if test "$ol_enable_monitor" != no ; then
2555         BUILD_SLAPD=yes
2556         BUILD_MONITOR=$ol_enable_monitor
2557         if test "$ol_enable_monitor" = mod ; then
2558                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-monitor"
2559                 MFLAG=SLAPD_MOD_DYNAMIC
2560         else
2561                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-monitor"
2562                 MFLAG=SLAPD_MOD_STATIC
2563         fi
2564         AC_DEFINE_UNQUOTED(SLAPD_MONITOR,$MFLAG,[define to support cn=Monitor backend])
2565 fi
2566
2567 if test "$ol_enable_bdb" != no ; then
2568         BUILD_SLAPD=yes
2569         BUILD_BDB=$ol_enable_bdb
2570         if test "$ol_enable_bdb" = mod ; then
2571                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-bdb"
2572                 MFLAG=SLAPD_MOD_DYNAMIC
2573         else
2574                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-bdb"
2575                 MFLAG=SLAPD_MOD_STATIC
2576         fi
2577         AC_DEFINE_UNQUOTED(SLAPD_BDB,$MFLAG,[define to support BDB backend])
2578 fi
2579
2580 if test "$ol_enable_dnssrv" != no ; then
2581         BUILD_SLAPD=yes
2582         BUILD_DNSSRV=$ol_enable_dnssrv
2583         if test "$ol_enable_dnssrv" = mod ; then
2584                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-dnssrv"
2585                 MFLAG=SLAPD_MOD_DYNAMIC
2586         else
2587                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-dnssrv"
2588                 MFLAG=SLAPD_MOD_STATIC
2589         fi
2590         AC_DEFINE_UNQUOTED(SLAPD_DNSSRV,$MFLAG,[define to support DNS SRV backend])
2591 fi
2592
2593 if test "$ol_enable_hdb" != no ; then
2594         BUILD_SLAPD=yes
2595         BUILD_HDB=$ol_enable_hdb
2596         if test "$ol_enable_hdb" = mod ; then
2597                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-hdb"
2598                 MFLAG=SLAPD_MOD_DYNAMIC
2599         else
2600                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-hdb"
2601                 MFLAG=SLAPD_MOD_STATIC
2602         fi
2603         AC_DEFINE_UNQUOTED(SLAPD_HDB,$MFLAG,[define to support HDB backend])
2604 fi
2605
2606 if test "$ol_enable_ldap" != no ; then
2607         BUILD_SLAPD=yes
2608         BUILD_LDAP=$ol_enable_ldap
2609         if test "$ol_enable_ldap" = mod ; then
2610                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ldap"
2611                 MFLAG=SLAPD_MOD_DYNAMIC
2612         else
2613                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ldap"
2614                 MFLAG=SLAPD_MOD_STATIC
2615         fi
2616         AC_DEFINE_UNQUOTED(SLAPD_LDAP,$MFLAG,[define to support LDAP backend])
2617 fi
2618
2619 if test "$ol_enable_meta" != no ; then
2620         BUILD_SLAPD=yes
2621         BUILD_META=$ol_enable_meta
2622         BUILD_REWRITE=yes
2623         if test "$ol_enable_meta" = mod ; then
2624                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-meta"
2625                 MFLAG=SLAPD_MOD_DYNAMIC
2626         else
2627                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-meta"
2628                 MFLAG=SLAPD_MOD_STATIC
2629         fi
2630         AC_DEFINE_UNQUOTED(SLAPD_META,$MFLAG,[define to support LDAP Metadirectory backend])
2631 fi
2632
2633 if test "$ol_enable_ndb" != no ; then
2634         BUILD_SLAPD=yes
2635         BUILD_NDB=$ol_enable_ndb
2636         if test "$ol_enable_ndb" = mod ; then
2637                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ndb"
2638                 MFLAG=SLAPD_MOD_DYNAMIC
2639         else
2640                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ndb"
2641                 MFLAG=SLAPD_MOD_STATIC
2642         fi
2643         AC_DEFINE_UNQUOTED(SLAPD_NDB,$MFLAG,[define to support NDB backend])
2644 fi
2645
2646 if test "$ol_enable_null" != no ; then
2647         BUILD_SLAPD=yes
2648         BUILD_NULL=$ol_enable_null
2649         if test "$ol_enable_null" = mod ; then
2650                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-null"
2651                 MFLAG=SLAPD_MOD_DYNAMIC
2652         else
2653                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-null"
2654                 MFLAG=SLAPD_MOD_STATIC
2655         fi
2656         AC_DEFINE_UNQUOTED(SLAPD_NULL,$MFLAG,[define to support NULL backend])
2657 fi
2658
2659 if test "$ol_enable_passwd" != no ; then
2660         BUILD_SLAPD=yes
2661         BUILD_PASSWD=$ol_enable_passwd
2662         if test "$ol_enable_passwd" = mod ; then
2663                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-passwd"
2664                 MFLAG=SLAPD_MOD_DYNAMIC
2665         else
2666                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-passwd"
2667                 MFLAG=SLAPD_MOD_STATIC
2668         fi
2669         AC_DEFINE_UNQUOTED(SLAPD_PASSWD,$MFLAG,[define to support PASSWD backend])
2670 fi
2671
2672 if test "$ol_link_perl" != no ; then
2673         BUILD_SLAPD=yes
2674         BUILD_PERL=$ol_enable_perl
2675         if test "$ol_enable_perl" = mod ; then
2676                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-perl"
2677                 MFLAG=SLAPD_MOD_DYNAMIC
2678         else
2679                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-perl"
2680                 MFLAG=SLAPD_MOD_STATIC
2681         fi
2682         AC_DEFINE_UNQUOTED(SLAPD_PERL,$MFLAG,[define to support PERL backend])
2683 fi
2684
2685 if test "$ol_enable_relay" != no ; then
2686         BUILD_SLAPD=yes
2687         BUILD_RELAY=$ol_enable_relay
2688         if test "$ol_enable_relay" = mod ; then
2689                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-relay"
2690                 MFLAG=SLAPD_MOD_DYNAMIC
2691         else
2692                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-relay"
2693                 MFLAG=SLAPD_MOD_STATIC
2694         fi
2695         AC_DEFINE_UNQUOTED(SLAPD_RELAY,$MFLAG,[define to support relay backend])
2696 fi
2697
2698 if test "$ol_enable_shell" != no ; then
2699         if test "$ol_link_threads" != no ; then
2700                 AC_MSG_WARN([Use of --without-threads is recommended with back-shell])
2701         fi
2702         BUILD_SLAPD=yes
2703         BUILD_SHELL=$ol_enable_shell
2704         if test "$ol_enable_shell" = mod ; then
2705                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-shell"
2706                 MFLAG=SLAPD_MOD_DYNAMIC
2707         else
2708                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-shell"
2709                 MFLAG=SLAPD_MOD_STATIC
2710         fi
2711         AC_DEFINE_UNQUOTED(SLAPD_SHELL,$MFLAG,[define to support SHELL backend])
2712 fi
2713
2714 if test "$ol_enable_sock" != no ; then
2715         BUILD_SLAPD=yes
2716         BUILD_SOCK=$ol_enable_sock
2717         if test "$ol_enable_sock" = mod ; then
2718                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-sock"
2719                 MFLAG=SLAPD_MOD_DYNAMIC
2720         else
2721                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-sock"
2722                 MFLAG=SLAPD_MOD_STATIC
2723         fi
2724         AC_DEFINE_UNQUOTED(SLAPD_SOCK,$MFLAG,[define to support SOCK backend])
2725 fi
2726
2727 if test "$ol_link_sql" != no ; then
2728         BUILD_SLAPD=yes
2729         BUILD_SQL=$ol_enable_sql
2730         if test "$ol_enable_sql" = mod; then
2731                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-sql"
2732                 MFLAG=SLAPD_MOD_DYNAMIC
2733         else
2734                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-sql"
2735                 MFLAG=SLAPD_MOD_STATIC
2736         fi
2737         AC_DEFINE_UNQUOTED(SLAPD_SQL,$MFLAG,[define to support SQL backend])
2738 fi
2739
2740 if test "$ol_enable_accesslog" != no ; then
2741         BUILD_ACCESSLOG=$ol_enable_accesslog
2742         if test "$ol_enable_accesslog" = mod ; then
2743                 MFLAG=SLAPD_MOD_DYNAMIC
2744                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS accesslog.la"
2745         else
2746                 MFLAG=SLAPD_MOD_STATIC
2747                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS accesslog.o"
2748         fi
2749         AC_DEFINE_UNQUOTED(SLAPD_OVER_ACCESSLOG,$MFLAG,[define for In-Directory Access Logging overlay])
2750 fi
2751
2752 if test "$ol_enable_auditlog" != no ; then
2753         BUILD_AUDITLOG=$ol_enable_auditlog
2754         if test "$ol_enable_auditlog" = mod ; then
2755                 MFLAG=SLAPD_MOD_DYNAMIC
2756                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS auditlog.la"
2757         else
2758                 MFLAG=SLAPD_MOD_STATIC
2759                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS auditlog.o"
2760         fi
2761         AC_DEFINE_UNQUOTED(SLAPD_OVER_AUDITLOG,$MFLAG,[define for Audit Logging overlay])
2762 fi
2763
2764 if test "$ol_enable_collect" != no ; then
2765         BUILD_COLLECT=$ol_enable_collect
2766         if test "$ol_enable_collect" = mod ; then
2767                 MFLAG=SLAPD_MOD_DYNAMIC
2768                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS collect.la"
2769         else
2770                 MFLAG=SLAPD_MOD_STATIC
2771                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS collect.o"
2772         fi
2773         AC_DEFINE_UNQUOTED(SLAPD_OVER_COLLECT,$MFLAG,[define for Collect overlay])
2774 fi
2775
2776 if test "$ol_enable_constraint" != no ; then
2777         BUILD_CONSTRAINT=$ol_enable_constraint
2778         if test "$ol_enable_constraint" = mod ; then
2779                 MFLAG=SLAPD_MOD_DYNAMIC
2780                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS constraint.la"
2781         else
2782                 MFLAG=SLAPD_MOD_STATIC
2783                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS constraint.o"
2784         fi
2785         AC_DEFINE_UNQUOTED(SLAPD_OVER_CONSTRAINT,$MFLAG,[define for Attribute Constraint overlay])
2786 fi
2787
2788 if test "$ol_enable_dds" != no ; then
2789         BUILD_DDS=$ol_enable_dds
2790         if test "$ol_enable_dds" = mod ; then
2791                 MFLAG=SLAPD_MOD_DYNAMIC
2792                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dds.la"
2793         else
2794                 MFLAG=SLAPD_MOD_STATIC
2795                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dds.o"
2796         fi
2797         AC_DEFINE_UNQUOTED(SLAPD_OVER_DDS,$MFLAG,[define for Dynamic Directory Services overlay])
2798 fi
2799
2800 if test "$ol_enable_dyngroup" != no ; then
2801         BUILD_DYNGROUP=$ol_enable_dyngroup
2802         if test "$ol_enable_dyngroup" = mod ; then
2803                 MFLAG=SLAPD_MOD_DYNAMIC
2804                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dyngroup.la"
2805         else
2806                 MFLAG=SLAPD_MOD_STATIC
2807                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dyngroup.o"
2808         fi
2809         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNGROUP,$MFLAG,[define for Dynamic Group overlay])
2810 fi
2811
2812 if test "$ol_enable_dynlist" != no ; then
2813         BUILD_DYNLIST=$ol_enable_dynlist
2814         if test "$ol_enable_dynlist" = mod ; then
2815                 MFLAG=SLAPD_MOD_DYNAMIC
2816                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dynlist.la"
2817         else
2818                 MFLAG=SLAPD_MOD_STATIC
2819                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dynlist.o"
2820         fi
2821         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNLIST,$MFLAG,[define for Dynamic List overlay])
2822 fi
2823
2824 if test "$ol_enable_memberof" != no ; then
2825         BUILD_MEMBEROF=$ol_enable_memberof
2826         if test "$ol_enable_memberof" = mod ; then
2827                 MFLAG=SLAPD_MOD_DYNAMIC
2828                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS memberof.la"
2829         else
2830                 MFLAG=SLAPD_MOD_STATIC
2831                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS memberof.o"
2832         fi
2833         AC_DEFINE_UNQUOTED(SLAPD_OVER_MEMBEROF,$MFLAG,[define for Reverse Group Membership overlay])
2834 fi
2835
2836 if test "$ol_enable_ppolicy" != no ; then
2837         BUILD_PPOLICY=$ol_enable_ppolicy
2838         if test "$ol_enable_ppolicy" = mod ; then
2839                 MFLAG=SLAPD_MOD_DYNAMIC
2840                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS ppolicy.la"
2841         else
2842                 MFLAG=SLAPD_MOD_STATIC
2843                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS ppolicy.o"
2844         fi
2845         AC_DEFINE_UNQUOTED(SLAPD_OVER_PPOLICY,$MFLAG,[define for Password Policy overlay])
2846 fi
2847
2848 if test "$ol_enable_proxycache" != no ; then
2849         BUILD_PROXYCACHE=$ol_enable_proxycache
2850         if test "$ol_enable_proxycache" = mod ; then
2851                 MFLAG=SLAPD_MOD_DYNAMIC
2852                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS pcache.la"
2853         else
2854                 MFLAG=SLAPD_MOD_STATIC
2855                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS pcache.o"
2856         fi
2857         AC_DEFINE_UNQUOTED(SLAPD_OVER_PROXYCACHE,$MFLAG,[define for Proxy Cache overlay])
2858 fi
2859
2860 if test "$ol_enable_refint" != no ; then
2861         BUILD_REFINT=$ol_enable_refint
2862         if test "$ol_enable_refint" = mod ; then
2863                 MFLAG=SLAPD_MOD_DYNAMIC
2864                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS refint.la"
2865         else
2866                 MFLAG=SLAPD_MOD_STATIC
2867                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS refint.o"
2868         fi
2869         AC_DEFINE_UNQUOTED(SLAPD_OVER_REFINT,$MFLAG,[define for Referential Integrity overlay])
2870 fi
2871
2872 if test "$ol_enable_retcode" != no ; then
2873         BUILD_RETCODE=$ol_enable_retcode
2874         if test "$ol_enable_retcode" = mod ; then
2875                 MFLAG=SLAPD_MOD_DYNAMIC
2876                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS retcode.la"
2877         else
2878                 MFLAG=SLAPD_MOD_STATIC
2879                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS retcode.o"
2880         fi
2881         AC_DEFINE_UNQUOTED(SLAPD_OVER_RETCODE,$MFLAG,[define for Referential Integrity overlay])
2882 fi
2883
2884 if test "$ol_enable_rwm" != no ; then
2885         BUILD_REWRITE=yes
2886         BUILD_RWM=$ol_enable_rwm
2887         if test "$ol_enable_rwm" = mod ; then
2888                 MFLAG=SLAPD_MOD_DYNAMIC
2889                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS rwm.la"
2890         else
2891                 MFLAG=SLAPD_MOD_STATIC
2892                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS rwm_x.o"
2893         fi
2894         AC_DEFINE_UNQUOTED(SLAPD_OVER_RWM,$MFLAG,[define for Rewrite/Remap overlay])
2895 fi
2896
2897 if test "$ol_enable_seqmod" != no ; then
2898         BUILD_SEQMOD=$ol_enable_seqmod
2899         if test "$ol_enable_seqmod" = mod ; then
2900                 MFLAG=SLAPD_MOD_DYNAMIC
2901                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS seqmod.la"
2902         else
2903                 MFLAG=SLAPD_MOD_STATIC
2904                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS seqmod.o"
2905         fi
2906         AC_DEFINE_UNQUOTED(SLAPD_OVER_SEQMOD,$MFLAG,[define for Sequential Modify overlay])
2907 fi
2908
2909 if test "$ol_enable_syncprov" != no ; then
2910         BUILD_SYNCPROV=$ol_enable_syncprov
2911         if test "$ol_enable_syncprov" = mod ; then
2912                 MFLAG=SLAPD_MOD_DYNAMIC
2913                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS syncprov.la"
2914         else
2915                 MFLAG=SLAPD_MOD_STATIC
2916                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS syncprov.o"
2917         fi
2918         AC_DEFINE_UNQUOTED(SLAPD_OVER_SYNCPROV,$MFLAG,[define for Syncrepl Provider overlay])
2919 fi
2920
2921 if test "$ol_enable_translucent" != no ; then
2922         BUILD_TRANSLUCENT=$ol_enable_translucent
2923         if test "$ol_enable_translucent" = mod ; then
2924                 MFLAG=SLAPD_MOD_DYNAMIC
2925                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS translucent.la"
2926         else
2927                 MFLAG=SLAPD_MOD_STATIC
2928                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS translucent.o"
2929         fi
2930         AC_DEFINE_UNQUOTED(SLAPD_OVER_TRANSLUCENT,$MFLAG,[define for Translucent Proxy overlay])
2931 fi
2932
2933 if test "$ol_enable_unique" != no ; then
2934         BUILD_UNIQUE=$ol_enable_unique
2935         if test "$ol_enable_unique" = mod ; then
2936                 MFLAG=SLAPD_MOD_DYNAMIC
2937                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS unique.la"
2938         else
2939                 MFLAG=SLAPD_MOD_STATIC
2940                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS unique.o"
2941         fi
2942         AC_DEFINE_UNQUOTED(SLAPD_OVER_UNIQUE,$MFLAG,[define for Attribute Uniqueness overlay])
2943 fi
2944
2945 if test "$ol_enable_valsort" != no ; then
2946         BUILD_VALSORT=$ol_enable_valsort
2947         if test "$ol_enable_valsort" = mod ; then
2948                 MFLAG=SLAPD_MOD_DYNAMIC
2949                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS valsort.la"
2950         else
2951                 MFLAG=SLAPD_MOD_STATIC
2952                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS valsort.o"
2953         fi
2954         AC_DEFINE_UNQUOTED(SLAPD_OVER_VALSORT,$MFLAG,[define for Value Sorting overlay])
2955 fi
2956
2957 if test "$ol_enable_rewrite" != no ; then
2958         AC_DEFINE(ENABLE_REWRITE,1,[define to enable rewriting in back-ldap and back-meta])
2959         BUILD_REWRITE=yes
2960 fi
2961
2962 if test "$ol_enable_slapi" != no ; then
2963         AC_DEFINE(ENABLE_SLAPI,1,[define to enable slapi library])
2964         BUILD_SLAPI=yes
2965         SLAPD_SLAPI_DEPEND=libslapi.a
2966 fi
2967
2968 dnl ----------------------------------------------------------------
2969
2970 dnl
2971 dnl For Windows build, we don't want to include -dlopen flags.
2972 dnl They hurt more than they help.
2973 dnl
2974
2975 if test "$ac_cv_mingw32" = yes ; then
2976         PLAT=NT
2977         SLAPD_MODULES_LDFLAGS=
2978 else
2979         PLAT=UNIX
2980 fi
2981
2982 AC_SUBST(LIBSRCS)
2983 AC_SUBST(PLAT)
2984 AC_SUBST(WITH_SASL)
2985 AC_SUBST(WITH_TLS)
2986 AC_SUBST(WITH_MODULES_ENABLED)
2987 AC_SUBST(WITH_ACI_ENABLED)
2988 AC_SUBST(BUILD_THREAD)
2989 AC_SUBST(BUILD_LIBS_DYNAMIC)
2990
2991 AC_SUBST(BUILD_SLAPD)
2992 dnl slapi
2993   AC_SUBST(BUILD_SLAPI)
2994   AC_SUBST(SLAPD_SLAPI_DEPEND)
2995 dnl backends
2996   AC_SUBST(BUILD_BDB)
2997   AC_SUBST(BUILD_DNSSRV)
2998   AC_SUBST(BUILD_HDB)
2999   AC_SUBST(BUILD_LDAP)
3000   AC_SUBST(BUILD_META)
3001   AC_SUBST(BUILD_MONITOR)
3002   AC_SUBST(BUILD_NDB)
3003   AC_SUBST(BUILD_NULL)
3004   AC_SUBST(BUILD_PASSWD)
3005   AC_SUBST(BUILD_RELAY)
3006   AC_SUBST(BUILD_PERL)
3007   AC_SUBST(BUILD_SHELL)
3008   AC_SUBST(BUILD_SOCK)
3009   AC_SUBST(BUILD_SQL)
3010 dnl overlays
3011   AC_SUBST(BUILD_ACCESSLOG)
3012   AC_SUBST(BUILD_AUDITLOG)
3013   AC_SUBST(BUILD_COLLECT)
3014   AC_SUBST(BUILD_CONSTRAINT)
3015   AC_SUBST(BUILD_DDS)
3016   AC_SUBST(BUILD_DENYOP)
3017   AC_SUBST(BUILD_DYNGROUP)
3018   AC_SUBST(BUILD_DYNLIST)
3019   AC_SUBST(BUILD_LASTMOD)
3020   AC_SUBST(BUILD_MEMBEROF)
3021   AC_SUBST(BUILD_PPOLICY)
3022   AC_SUBST(BUILD_PROXYCACHE)
3023   AC_SUBST(BUILD_REFINT)
3024   AC_SUBST(BUILD_RETCODE)
3025   AC_SUBST(BUILD_RWM)
3026   AC_SUBST(BUILD_SEQMOD)
3027   AC_SUBST(BUILD_SYNCPROV)
3028   AC_SUBST(BUILD_TRANSLUCENT)
3029   AC_SUBST(BUILD_UNIQUE)
3030   AC_SUBST(BUILD_VALSORT)
3031
3032 AC_SUBST(LDAP_LIBS)
3033 AC_SUBST(SLAPD_LIBS)
3034 AC_SUBST(BDB_LIBS)
3035 AC_SUBST(SLAPD_NDB_LIBS)
3036 AC_SUBST(SLAPD_NDB_INCS)
3037 AC_SUBST(LTHREAD_LIBS)
3038 AC_SUBST(LUTIL_LIBS)
3039 AC_SUBST(WRAP_LIBS)
3040
3041 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
3042 AC_SUBST(SLAPD_MODULES_LDFLAGS)
3043
3044 AC_SUBST(SLAPD_NO_STATIC)
3045 AC_SUBST(SLAPD_STATIC_BACKENDS)
3046 AC_SUBST(SLAPD_DYNAMIC_BACKENDS)
3047 AC_SUBST(SLAPD_STATIC_OVERLAYS)
3048 AC_SUBST(SLAPD_DYNAMIC_OVERLAYS)
3049
3050 AC_SUBST(PERL_CPPFLAGS)
3051 AC_SUBST(SLAPD_PERL_LDFLAGS)
3052 AC_SUBST(MOD_PERL_LDFLAGS)
3053
3054 AC_SUBST(KRB4_LIBS)
3055 AC_SUBST(KRB5_LIBS)
3056 AC_SUBST(SASL_LIBS)
3057 AC_SUBST(TLS_LIBS)
3058 AC_SUBST(MODULES_LIBS)
3059 AC_SUBST(SLAPI_LIBS)
3060 AC_SUBST(LIBSLAPI)
3061 AC_SUBST(LIBSLAPITOOLS)
3062 AC_SUBST(AUTH_LIBS)
3063 AC_SUBST(ICU_LIBS)
3064
3065 AC_SUBST(SLAPD_SLP_LIBS)
3066 AC_SUBST(SLAPD_GMP_LIBS)
3067
3068 AC_SUBST(SLAPD_SQL_LDFLAGS)
3069 AC_SUBST(SLAPD_SQL_LIBS)
3070 AC_SUBST(SLAPD_SQL_INCLUDES)
3071
3072 dnl ----------------------------------------------------------------
3073 dnl final help output
3074 AC_ARG_WITH(xxinstall,[
3075 See INSTALL file for further details.])
3076
3077 dnl ----------------------------------------------------------------
3078 dnl final output
3079 dnl
3080
3081 AC_CONFIG_FILES([Makefile:build/top.mk:Makefile.in:build/dir.mk]
3082 [doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk]
3083 [doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk]
3084 [doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk]
3085 [doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk]
3086 [doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk]
3087 [doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk]
3088 [clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk]
3089 [clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk]
3090 [include/Makefile:build/top.mk:include/Makefile.in]
3091 [libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk]
3092 [libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk]
3093 [libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk]
3094 [libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk]
3095 [libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk]
3096 [libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk]
3097 [libraries/librewrite/Makefile:build/top.mk:libraries/librewrite/Makefile.in:build/lib.mk:build/lib-static.mk]
3098 [servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk]
3099 [servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk]
3100 [servers/slapd/back-bdb/Makefile:build/top.mk:servers/slapd/back-bdb/Makefile.in:build/mod.mk]
3101 [servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk]
3102 [servers/slapd/back-hdb/Makefile:build/top.mk:servers/slapd/back-hdb/Makefile.in:build/mod.mk]
3103 [servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk]
3104 [servers/slapd/back-ldif/Makefile:build/top.mk:servers/slapd/back-ldif/Makefile.in:build/mod.mk]
3105 [servers/slapd/back-meta/Makefile:build/top.mk:servers/slapd/back-meta/Makefile.in:build/mod.mk]
3106 [servers/slapd/back-monitor/Makefile:build/top.mk:servers/slapd/back-monitor/Makefile.in:build/mod.mk]
3107 [servers/slapd/back-ndb/Makefile:build/top.mk:servers/slapd/back-ndb/Makefile.in:build/mod.mk]
3108 [servers/slapd/back-null/Makefile:build/top.mk:servers/slapd/back-null/Makefile.in:build/mod.mk]
3109 [servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk]
3110 [servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk]
3111 [servers/slapd/back-relay/Makefile:build/top.mk:servers/slapd/back-relay/Makefile.in:build/mod.mk]
3112 [servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk]
3113 [servers/slapd/back-sock/Makefile:build/top.mk:servers/slapd/back-sock/Makefile.in:build/mod.mk]
3114 [servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk]
3115 [servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk]
3116 [servers/slapd/slapi/Makefile:build/top.mk:servers/slapd/slapi/Makefile.in:build/lib.mk:build/lib-shared.mk]
3117 [servers/slapd/overlays/Makefile:build/top.mk:servers/slapd/overlays/Makefile.in:build/lib.mk]
3118 [tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk]
3119 [tests/run]
3120 [tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk])
3121
3122 AC_CONFIG_COMMANDS([default],[[
3123 chmod +x tests/run
3124 date > stamp-h
3125 BACKENDSC="servers/slapd/backends.c"
3126 echo "Making $BACKENDSC"
3127 rm -f $BACKENDSC
3128 cat > $BACKENDSC << ENDX
3129 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
3130  *
3131  * Copyright 1998-2008 The OpenLDAP Foundation.
3132  * All rights reserved.
3133  *
3134  * Redistribution and use in source and binary forms, with or without
3135  * modification, are permitted only as authorized by the OpenLDAP
3136  * Public License.
3137  *
3138  * A copy of this license is available in the file LICENSE in the
3139  * top-level directory of the distribution or, alternatively, at
3140  * <http://www.OpenLDAP.org/license.html>.
3141  */
3142 /* This file is automatically generated by configure; please do not edit. */
3143
3144 #include "portable.h"
3145 #include "slap.h"
3146
3147 ENDX
3148 if test "${STATIC_BACKENDS}"; then
3149         for b in config ${STATIC_BACKENDS}; do
3150                 bb=`echo "${b}" | sed -e 's/back-//'`
3151                 cat >> $BACKENDSC << ENDX
3152 extern BI_init ${bb}_back_initialize;
3153 ENDX
3154         done
3155
3156         cat >> $BACKENDSC << ENDX
3157
3158 BackendInfo slap_binfo[] = {
3159 ENDX
3160
3161         for b in config ${STATIC_BACKENDS}; do
3162                 bb=`echo "${b}" | sed -e 's/back-//'`
3163                 echo "    Add ${bb} ..."
3164                 cat >> $BACKENDSC << ENDX
3165         { "${bb}", ${bb}_back_initialize },
3166 ENDX
3167         done
3168
3169         cat >> $BACKENDSC << ENDX
3170         { NULL, NULL },
3171 };
3172
3173 /* end of generated file */
3174 ENDX
3175 fi
3176 OVERLAYSC="servers/slapd/overlays/statover.c"
3177 echo "Making $OVERLAYSC"
3178 rm -f $OVERLAYSC
3179 cat > $OVERLAYSC << ENDX
3180 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
3181  *
3182  * Copyright 1998-2008 The OpenLDAP Foundation.
3183  * All rights reserved.
3184  *
3185  * Redistribution and use in source and binary forms, with or without
3186  * modification, are permitted only as authorized by the OpenLDAP
3187  * Public License.
3188  *
3189  * A copy of this license is available in the file LICENSE in the
3190  * top-level directory of the distribution or, alternatively, at
3191  * <http://www.OpenLDAP.org/license.html>.
3192  */
3193 /* This file is automatically generated by configure; please do not edit. */
3194
3195 #include "portable.h"
3196 #include "slap.h"
3197
3198 ENDX
3199 if test "${STATIC_OVERLAYS}"; then
3200         for o in ${STATIC_OVERLAYS}; do
3201                 oo=`echo "${o}" | sed -e 's/.o$//' -e 's/_x$//'`
3202                 cat >> $OVERLAYSC << ENDX
3203 extern OV_init ${oo}_initialize;
3204 ENDX
3205         done
3206 fi
3207
3208 cat >> $OVERLAYSC << ENDX
3209
3210 OverlayInit slap_oinfo[] = {
3211 ENDX
3212
3213 if test "${STATIC_OVERLAYS}"; then
3214         for o in ${STATIC_OVERLAYS}; do
3215                 oo=`echo "${o}" | sed -e 's/.o$//' -e 's/_x$//'`
3216                 echo "    Add ${oo} ..."
3217                 cat >> $OVERLAYSC << ENDX
3218         { "${oo}", ${oo}_initialize },
3219 ENDX
3220         done
3221 fi
3222
3223         cat >> $OVERLAYSC << ENDX
3224         { NULL, NULL },
3225 };
3226
3227 /* end of generated file */
3228 ENDX
3229
3230 if test "${ol_cv_mkdep}" = no; then
3231         echo '(Do not "make depend"; we do not know how to build dependencies)'
3232 else
3233         echo 'Please run "make depend" to build dependencies'
3234 fi
3235 ]],[[
3236 STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS"
3237 STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS"
3238 ]])
3239 AC_OUTPUT