git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8 dnl Configure.in for OpenLDAP
   9 dnl
  10 AC_INIT(include/ldap.h)
  11 dnl
  12 dnl
  13 AC_PREREQ(2.10)dnl Required Autoconf version
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_CONFIG_AUX_DIR(build)
  18 AC_CONFIG_HEADER(include/portable.h)dnl
  19 dnl
  20 dnl Start Args
  21 AC_MSG_CHECKING(arguments)
  22 AC_PREFIX_DEFAULT(/usr/local)
  23
  24 dnl General "enable" options
  25 CF_ARG_OPTION(debug,[  --enable-debug   enable debugging (yes)],[
  26         LDAP_DEBUG=no],[LDAP_DEBUG=yes],yes)dnl
  27 CF_ARG_OPTION(libui,[  --enable-libui   enable library user interface (yes)],[
  28         LDAP_LIBUI=no],[LDAP_LIBUI=yes],yes)dnl
  29 CF_ARG_OPTION(cache,[  --enable-cache   enable caching (yes)],[
  30         LDAP_CACHE=no],[LDAP_CACHE=yes],yes)dnl
  31 CF_ARG_OPTION(referrals,[  --enable-referrals   enable referrals (yes)],[
  32         LDAP_REFERRALS=no],[LDAP_REFERRALS=yes],yes)dnl
  33
  34 CF_ARG_OPTION(cldap,[  --enable-clapd   enable connectionless ldap (no)],[
  35         LDAP_CLDAP=yes],[LDAP_CLDAP=no],no)dnl
  36
  37 dnl General "with" options
  38 AC_ARG_WITH(kerberos,[  --with-kerberos use Kerberos (no)],[
  39         opt_kerberos=yes],[opt_kerberos=no])
  40 AC_ARG_WITH(kerberos-afs,[  --with-kerberos-afs use AFS Kerberos (no)],[
  41         opt_kerberos_afs=yes],[opt_kerberos_afs=no])
  42 AC_ARG_WITH(threads,[  --with-threads   use threads (yes)],[
  43         opt_threads=yes],[opt_threads=no])
  44
  45 dnl Server options
  46
  47 dnl LDAPD OPTIONS
  48 CF_ARG_OPTION(ldapd,[  --enable-ldapd   enable building ldapd (no)],[
  49         BUILD_LDAPD=yes],[BUILD_LDAPD=no],no)dnl
  50
  51 dnl SLAPD OPTIONS
  52 CF_ARG_OPTION(slapd,[  --enable-slapd   enable building slapd (yes)],[
  53         BUILD_SLAPD=no],[BUILD_SLAPD=yes],yes)dnl
  54 CF_ARG_OPTION(aclgroup,[    --enable-aclgroup   enable ACL group support (yes)],[
  55         SLAPD_ACLGROUP=no],[SLAPD_ALCGROUP=yes],yes)dnl
  56 CF_ARG_OPTION(crypt,[    --enable-crypt enable crypt(3) passwords (yes)],[
  57         SLAPD_CRYPT=no],[SLAPD_CRYPT=yes],yes)dnl
  58 CF_ARG_OPTION(md5,[    --enable-md5     enable MD5 passwords (yes)],[
  59         SLAPD_MD5=no],[SLAPD_MD5=yes],yes)dnl
  60 CF_ARG_OPTION(sha1,[    --enable-sha1   enable SHA1 passwords (yes)],[
  61         SLAPD_SHA1=no],[SLAPD_SHA1=yes],yes)dnl
  62 CF_ARG_OPTION(wrappers,[    --enable-wrappers   enable tcp wrapper support (no)],[
  63         SLAPD_TCP_WRAPPERS=yes],[SLAPD_TCP_WRAPPERS=no],no)dnl
  64 CF_ARG_OPTION(phonetic,[    --enable-phonetic   enable phonetic/soundex  (no)],[
  65         SLAPD_PHONETIC=yes],[SLAPD_PHONETIC=no],no)dnl
  66 CF_ARG_OPTION(rlookups,[    --enable-rlookups   enable reverse lookups (yes)],[
  67         SLAPD_RLOOKUP=no],[SLAPD_RLOOKUP=yes],yes)dnl
  68
  69 dnl SLAPD Backend options
  70 CF_ARG_OPTION(ldbm,[    --enable-ldbm   enable ldbm backend (yes)],[
  71         SLAPD_LDBM=no],[SLAPD_LDBM=yes],yes)dnl
  72 CF_ARG_OPTION(passwd,[    --enable-passwd       enable passwd backend (yes)],[
  73         SLAPD_PASSWD=no],[SLAPD_PASSWD=yes],yes)dnl
  74 CF_ARG_OPTION(shell,[    --enable-shell enable shell backend (yes)],[
  75         SLAPD_SHELL=no],[SLAPD_SHELL=yes],yes)dnl
  76
  77 AC_ARG_WITH(ndbm,[    --with-ndbm               use NDB for LDBM backend (any)],[
  78         opt_ndbm=yes],[opt_ndbm=no])
  79 AC_ARG_WITH(gdbm,[    --with-gdbm               use GDBM for LDBM backend (any)],[
  80         opt_gdbm=yes],[opt_gdbm=no])
  81 AC_ARG_WITH(dbhash,[    --with-dbhash   use Berkeley DB Hash for LDBM backend (any)],[
  82         opt_dbhash=yes],[opt_dbhash=no])
  83 AC_ARG_WITH(dbbtree,[    --with-dbbtree use Berkeley DB Btrees for LDBM backend (any)],[
  84         opt_dbbtree=yes],[opt_dbbtree=no])
  85 AC_ARG_WITH(db2,[    --with-db2         use Berkeley DB2 API (any)],[
  86         opt_db2=yes],[opt_db2=no])
  87
  88 dnl SLURPD OPTIONS
  89 CF_ARG_OPTION(slurpd,[  --enable-slurpd enable building slurpd (yes)],[
  90         BUILD_SLURPD=no],[BUILD_SLURPD=yes],yes)dnl
  91
  92 AC_MSG_RESULT(done)
  93
  94 AC_MSG_CHECKING(LDBM preferences)
  95 ldbm_prefer=any
  96
  97 if test "$opt_ndbm" = yes ; then
  98         ldbm_prefer=ndbm
  99 fi
 100 if test "$opt_gdbm" = yes ; then
 101         ldbm_prefer=gdbm
 102 fi
 103 if test "$opt_dbhash" = yes ; then
 104         ldbm_prefer=dbhash
 105 fi
 106 if test "$opt_dbbtree" = yes ; then
 107         ldbm_prefer=dbbtree
 108 fi
 109 AC_MSG_RESULT($ldbm_prefer)
 110
 111 if test "$BUILD_SLAPD" != "yes" ; then
 112         BUILD_SLURPD="no"
 113         SLAPD_LDBM="no"
 114         SLAPD_PASSWD="no"
 115         SLAPD_SHELL="no"
 116         ldbm_prefer="none"
 117 fi
 118
 119 ## general LDAP arguments
 120 LDAP_DEFS=
 121 LDAP_LIBS=
 122
 123 if test "$LDAP_DEBUG" = "yes" ; then
 124         LDAP_DEFS="$LDAP_DEFS -DLDAP_DEBUG"
 125 fi
 126 if test "$LDAP_REFERRALS" = "yes" ; then
 127         AC_DEFINE(LDAP_REFERRALS,1)
 128         LDAP_DEFS="$LDAP_DEFS -DLDAP_REFERRALS"
 129 fi
 130 if test "$LDAP_CACHE" = "no" ; then
 131         AC_DEFINE(LDAP_NOCACHE,1)
 132         LDAP_DEFS="$LDAP_DEFS -DNO_CACHE"
 133 fi
 134 if test "$LDAP_CLDAP" = "yes" ; then
 135         AC_DEFINE(LDAP_CONNECTIONLESS,1)
 136         LDAP_DEFS="$LDAP_DEFS -DCLDAP"
 137 fi
 138
 139 ## ldapd arguments
 140 LDAPD_DEFS=
 141 LDAPD_LIBS=
 142
 143 ## slapd arguments
 144 SLAPD_DEFS=
 145 SLAPD_LIBS=
 146 LUTIL_DEFS=
 147 if test "$SLAPD_PHONETIC" = "yes" ; then
 148         AC_DEFINE(SLAPD_PHONETIC,1)
 149         SLAPD_DEFS="$SLAPD_DEFS -DSOUNDEX"
 150 fi
 151
 152 if test "$SLAPD_MD5" = "yes" ; then
 153 dnl     AC_DEFINE(SLAPD_MD5,1)
 154         LUTIL_DEFS="$LUTIL_DEFS -DLDAP_MD5"
 155 fi
 156
 157 if test "$SLAPD_SHA1" = "yes" ; then
 158 dnl     AC_DEFINE(SLAPD_SHA1,1)
 159         LUTIL_DEFS="$LUTIL_DEFS -DLDAP_SHA1"
 160 fi
 161
 162 if test "$SLAPD_LDBM" = "yes" ; then
 163 dnl     AC_DEFINE(SLAPD_LDBM,1)
 164         SLAPD_DEFS="$SLAPD_DEFS -DLDAP_LDBM"
 165 fi
 166 if test "$SLAPD_PASSWD" = "yes" ; then
 167 dnl     AC_DEFINE(SLAPD_PASSWD,1)
 168         SLAPD_DEFS="$SLAPD_DEFS -DLDAP_PASSWD"
 169 fi
 170 if test "$SLAPD_SHELL" = "yes" ; then
 171 dnl     AC_DEFINE(SLAPD_SHELL,1)
 172         SLAPD_DEFS="$SLAPD_DEFS -DLDAP_SHELL"
 173 fi
 174
 175 dnl slurpd arguments
 176 SLURPD_DEFS=
 177 SLURPD_LIBS=
 178
 179 dnl End Args
 180
 181 dnl ----------------------------------------------------------------
 182 dnl Checks for programs
 183 AC_PROG_CC
 184 AC_PROG_GCC_TRADITIONAL
 185
 186 AC_PROG_LN_S
 187 AC_PROG_INSTALL
 188 AC_PROG_RANLIB
 189 AC_PROG_MAKE_SET
 190
 191 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 192         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 193 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 194 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 195
 196 dnl ----------------------------------------------------------------
 197 dnl Checks for libraries
 198
 199 LTHREAD_LIBS=
 200 if test "$opt_thread" = "no" ; then
 201         LTHREAD_DEFS="-DNO_THREADS"
 202         BUILD_SLURPD=no
 203 else
 204         AC_CHECK_HEADERS(pthread.h sched.h)
 205
 206         if test "$ac_cv_header_pthread_h" = yes ; then
 207                 dnl We have some form of pthreads
 208                 AC_CACHE_CHECK([POSIX thread version],cf_cv_pthread_version,[
 209                         AC_EGREP_CPP(final,[
 210 #include <pthread.h>
 211 /* this check could be improved */
 212 #ifdef PTHREAD_ONCE_INIT
 213         final
 214 #endif
 215                         ], pthread_final=yes, pthread_final=no)
 216
 217                         AC_EGREP_CPP(draft4,[
 218 #include <pthread.h>
 219 /* this check could be improved */
 220 #ifdef pthread_once_init
 221         draft4
 222 #endif
 223                         ], pthread_draft4=yes, pthread_draft4=no)
 224
 225                         if test $pthread_final = yes -a $pthread_draft4 = no; then
 226                                 cf_cv_pthread_version=final
 227                         elif test $pthread_final = no -a $pthread_draft4 = yes; then
 228                                 cf_cv_pthread_version=draft4
 229                         else
 230                                 cf_cv_pthread_version=unknown
 231                         fi
 232                 ])
 233
 234                 if test $cf_cv_pthread_version = final ; then
 235                         LTHREAD_DEFS="$LTHREAD_DEFS -DPOSIX_THREADS"
 236                 elif test $cf_cv_pthread_version = draft4 ; then
 237                         LTHREAD_DEFS="$LTHREAD_DEFS -DTHREAD_MIT_PTHREADS"
 238                 else
 239                         AC_MSG_ERROR(unknown pthread version)
 240                 fi
 241
 242                 dnl Now the hard part, how to link
 243
 244                 AC_CACHE_CHECK([compiler for -pthread option], cf_cv_pthread_flag,[
 245                         dnl save the CPPFLAGS
 246                         save_CPPFLAGS=$CPPFLAGS
 247                         CPPFLAGS="-pthread $CPPFLAGS"
 248                         AC_TRY_LINK([#include <pthread.h>],[
 249                                 if(0) pthread_create((pthread_t*) 0,(pthread_attr_t*) 0, 0, 0);
 250                                 ], cf_cv_pthread_flag=yes, cf_cv_pthread_flag=no)
 251                         dnl restore the CPPFLAGS
 252                         CPPFLAGS=$save_CPPFLAGS
 253                 ])
 254
 255                 if test $cf_cv_pthread_flag = yes ; then
 256                         LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 257                 fi
 258
 259         else
 260                 LTHREAD_DEFS="-DNO_THREADS"
 261         fi
 262 fi
 263
 264
 265 ldbm_use="none"
 266 LDBM_DEFS=
 267 LDBM_LIBS=
 268
 269 if test "$SLAPD_LDBM" = "yes" ; then
 270         if test $ldbm_prefer = any -o $ldbm_prefer = dbbtree \
 271                         -o $ldbm_prefer = dbhash ; then
 272                 AC_CHECK_FUNC(dbopen,[
 273                         ldbm_use=$ldbm_prefer
 274                         ldbm_prefer=found],[
 275                         AC_CHECK_LIB(db,dbopen,[
 276                                 ldbm_use=$ldbm_prefer
 277                                 ldbm_prefer=found
 278                                 LDBM_LIBS="$LDBM_LIBS -ldb"
 279                         ])
 280                 ])
 281
 282                 if test $ldbm_prefer = found ; then
 283                         if test $ldbm_use = dbhash ; then
 284 dnl                             AC_DEFINE(LDBM_USE_DBHASH,1)
 285                                 LDBM_DEFS="$LDBM_DEFS -DLDBM_USE_DBHASH"
 286                         else
 287 dnl                             AC_DEFINE(LDBM_USE_DBBTREE,1)
 288                                 LDBM_DEFS="$LDBM_DEFS -DLDBM_USE_DBBTREE"
 289                         fi
 290                 fi
 291
 292                 AC_CACHE_CHECK(for db2, cf_cv_db2,[
 293                         AC_EGREP_CPP(__db_version_2,[
 294 #include <db.h>
 295 /* this check could be improved */
 296 #ifdef DB_VERSION_MAJOR
 297 #if DB_VERSION_MAJOR == 2
 298         __db_version_2
 299 #endif
 300 #endif
 301                         ], cf_cv_db2=yes, cf_cv_db2=no)])
 302
 303                 if test $cf_cv_db2 = yes ; then
 304                         if test $opt_db2 = yes ; then
 305                                 LDBM_DEFS="$LDBM_DEFS -DLDBM_USE_DB2"
 306                         else
 307                                 AC_CHECK_HEADERS(db_185.h)
 308                                 if test $ac_cv_header_db_185_h = no ; then
 309                                         AC_MSG_ERROR([select --with-db2 or install db2 with 1.85 compatibility])
 310                                 fi
 311
 312                                 LDBM_DEFS="$LDBM_DEFS -DLDBM_USE_DB2_COMPAT185"
 313                         fi
 314                 else
 315                         if test $opt_db2 = yes ; then
 316                                 AC_MSG_ERROR(could not local DB2)
 317                         fi
 318                 fi
 319         fi
 320
 321         if test $ldbm_prefer = any -o $ldbm_prefer = gdbm ; then
 322                 AC_CHECK_LIB(gdbm, gdbm_open,[
 323                         ldbm_use=$ldbm_prefer
 324                         ldbm_prefer=found
 325                         LDBM_LIBS="$LDBM_LIBS -lgdbm"
 326 dnl                     AC_DEFINE(LDBM_USE_GDBM,1)
 327                         LDBM_DEFS="$LDBM_DEFS -DLDBM_USE_GDBM"
 328                 ])
 329         fi
 330         if test $ldbm_prefer = any -o $ldbm_prefer = ndbm ; then
 331                 AC_CHECK_LIB(dbm,dbm_open,[
 332                         ldbm_use=ndbm
 333                         ldbm_prefer=found
 334                         LDBM_LIBS="$LDBM_LIBS -ldbm"
 335 dnl                     AC_DEFINE(LDBM_USE_NDBM,1)
 336                         LDBM_DEFS="$LDBM_DEFS -DLDBM_USE_NDBM"
 337                 ])
 338         fi
 339
 340         if test $ldbm_prefer != found ; then
 341                 AC_MSG_ERROR(could not find suitable db for $ldbm_prefer backend)
 342         fi
 343
 344         if test $ldbm_use = ndbm ; then
 345                 AC_MSG_WARN(LDBM using NDBM, functionality will be limited)
 346         fi
 347 fi
 348
 349 if test "$SLAPD_TCP_WRAPPERS" = "yes" ; then
 350         AC_CHECK_LIB(wrap, hosts_access, [
 351 dnl             LIBTCPD="-lwrap"
 352 dnl             AC_DEFINE(HAVE_TCPD)
 353                 SLAPD_DEFS="$SLAPD_DEFS -DTCP_WRAPPERS"
 354                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 355         ])
 356 fi
 357
 358 # ud needs termcap (should insert check here)
 359 LIBTERMCAP="-ltermcap"
 360 AC_SUBST(LIBTERMCAP)
 361
 362 # FreeBSD (and others) have crypt(3) in -lcrypt
 363 if test "$SLAPD_CRYPT" = "yes" ; then
 364         AC_CHECK_FUNC(crypt, have_crypt=yes, [
 365                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 366                         have_crypt=yes], [have_crypt=no])])
 367
 368         if test $have_crypt = yes ; then
 369 dnl             AC_DEFINE(SLAPD_CRYPT,1)
 370                 LUTIL_DEFS="$LUTIL_DEFS -DLDAP_CRYPT"
 371         else
 372                 AC_MSG_WARN(could not find crypt, disabling crypt support)
 373         fi
 374 fi
 375
 376 dnl ----------------------------------------------------------------
 377 dnl Checks for header files.
 378 AC_HEADER_DIRENT
 379 AC_HEADER_STDC
 380 AC_HEADER_SYS_WAIT
 381 AC_CHECK_HEADERS( \
 382         stddef.h        \
 383         fcntl.h         \
 384         limits.h        \
 385         malloc.h        \
 386         sgtty.h         \
 387         sys/file.h      \
 388         sys/ioctl.h     \
 389         sys/time.h      \
 390         syslog.h        \
 391         termio.h        \
 392         unistd.h        \
 393 )
 394
 395 dnl ----------------------------------------------------------------
 396 dnl Checks for typedefs, structures, and compiler characteristics.
 397 AC_TYPE_GETGROUPS
 398 AC_TYPE_MODE_T
 399 AC_TYPE_OFF_T
 400 AC_TYPE_PID_T
 401 AC_TYPE_SIGNAL
 402 AC_TYPE_SIZE_T
 403 AC_TYPE_UID_T
 404 AC_STRUCT_ST_BLKSIZE
 405 AC_HEADER_TIME
 406 AC_STRUCT_TM
 407
 408 dnl AC_C_BIGENDIAN
 409 AC_C_CONST
 410
 411 dnl ----------------------------------------------------------------
 412 dnl Checks for library functions.
 413 AC_FUNC_MEMCMP
 414 AC_TYPE_SIGNAL
 415 AC_FUNC_STRFTIME
 416 AC_FUNC_VPRINTF
 417 AC_FUNC_WAIT3
 418
 419 AC_CHECK_FUNCS(         \
 420         gethostname             \
 421         gettimeofday    \
 422         mktime                  \
 423         select                  \
 424         socket                  \
 425         strdup                  \
 426         strerror                \
 427         strstr                  \
 428         strrchr                 \
 429         strtod                  \
 430         strtol                  \
 431         strtoul                 \
 432         memcpy                  \
 433 )
 434
 435 AC_REPLACE_FUNCS(strdup)
 436
 437 dnl ----------------------------------------------------------------
 438 # Check Configuration
 439 CF_SYS_ERRLIST
 440
 441 AC_SUBST(BUILD_LDAPD)
 442
 443 AC_SUBST(BUILD_SLAPD)
 444   AC_SUBST(SLAPD_LDBM)
 445   AC_SUBST(SLAPD_PASSWD)
 446   AC_SUBST(SLAPD_SHELL)
 447
 448 AC_SUBST(BUILD_SLURPD)
 449
 450 AC_SUBST(LDAP_DEFS)
 451 AC_SUBST(LDAP_LIBS)
 452 AC_SUBST(LDAPD_DEFS)
 453 AC_SUBST(LDAPD_LIBS)
 454 AC_SUBST(SLAPD_DEFS)
 455 AC_SUBST(SLAPD_LIBS)
 456 AC_SUBST(SLURPD_DEFS)
 457 AC_SUBST(SLURPD_LIBS)
 458 AC_SUBST(LDBM_DEFS)
 459 AC_SUBST(LDBM_LIBS)
 460 AC_SUBST(LTHREAD_DEFS)
 461 AC_SUBST(LTHREAD_LIBS)
 462 AC_SUBST(LUTIL_DEFS)
 463 AC_SUBST(LUTIL_LIBS)
 464
 465 dnl AC_OUTPUT( \
 466 dnl contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
 467 dnl contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
 468 dnl contrib/whois++/Makefile:build/top.mk:contrib/whois++/Makefile.in:build/rules.mk \
 469 dnl [date > stamp-h])
 470
 471 AC_OUTPUT( \
 472 Makefile:build/top.mk:Makefile.in:build/dir.mk \
 473 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
 474 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
 475 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
 476 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
 477 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
 478 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
 479 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
 480 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
 481 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
 482 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
 483 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
 484 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
 485 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
 486 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
 487 include/Makefile:build/top.mk:include/Makefile.in \
 488 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
 489 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk \
 490 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk \
 491 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk \
 492 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk \
 493 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk \
 494 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk \
 495 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk \
 496 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
 497 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
 498 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
 499 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
 500 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
 501 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
 502 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
 503 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
 504 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
 505 tests/Makefile:build/top.mk:tests/Makefile.in \
 506 ,[date > stamp-h])