git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl This work is part of OpenLDAP Software <http://www.openldap.org/>.
   3 dnl
   4 dnl Copyright 1998-2005 The OpenLDAP Foundation.
   5 dnl All rights reserved.
   6 dnl
   7 dnl Redistribution and use in source and binary forms, with or without
   8 dnl modification, are permitted only as authorized by the OpenLDAP
   9 dnl Public License.
  10 dnl
  11 dnl A copy of this license is available in the file LICENSE in the
  12 dnl top-level directory of the distribution or, alternatively, at
  13 dnl <http://www.OpenLDAP.org/license.html>.
  14 dnl
  15 dnl ----------------------------------------------------------------
  16 dnl Disable config.cache!
  17 define([AC_CACHE_LOAD], )dnl
  18 define([AC_CACHE_SAVE], )dnl
  19 dnl ================================================================
  20 dnl Configure.in for OpenLDAP
  21 AC_COPYRIGHT([[Copyright 1998-2005 The OpenLDAP Foundation. All rights reserved.
  22 Restrictions apply, see COPYRIGHT and LICENSE files.]])
  23 AC_REVISION([$OpenLDAP$])
  24 AC_INIT([OpenLDAP],,[http://www.openldap.org/its/])
  25 AC_CONFIG_SRCDIR(build/version.sh)dnl
  26 dnl ----------------------------------------------------------------
  27 dnl OpenLDAP Autoconf Macros
  28 builtin(include, build/openldap.m4)dnl
  29 dnl ================================================================
  30
  31 AC_CONFIG_AUX_DIR(build)dnl
  32
  33 eval `$ac_aux_dir/version.sh`
  34 if test -z "$OL_STRING"; then
  35         AC_MSG_ERROR([could not determine version])
  36 fi
  37
  38 if test -f "$ac_aux_dir/shtool" -a ! -d $ac_aux_dir/shtool; then
  39         ac_cv_shtool="$ac_aux_dir/shtool"
  40 else
  41         AC_MSG_ERROR([no shtool found in $ac_aux_dir])
  42 fi
  43
  44 SHTOOL="$ac_cv_shtool"
  45 dnl AC_SUBST(SHTOOL)dnl
  46
  47 TB="`$SHTOOL echo -e '%B' 2>/dev/null`"
  48 TN="`$SHTOOL echo -e '%b' 2>/dev/null`"
  49
  50 OPENLDAP_CVS=""
  51 if test -d $ac_aux_dir/CVS; then
  52         OPENLDAP_CVS="(from CVS sources) "
  53 fi
  54
  55 echo "Configuring ${TB}${OL_STRING}${TN} ${OPENLDAP_CVS}..."
  56
  57 dnl Determine host platform
  58 dnl             we try not to use this for much
  59 AC_CANONICAL_TARGET([])
  60
  61 AM_INIT_AUTOMAKE([$OL_PACKAGE],[$OL_VERSION], [no defines])dnl
  62 AC_SUBST(PACKAGE)dnl
  63 AC_SUBST(VERSION)dnl
  64 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  65 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  66
  67 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION,$OL_API_INC,Version)
  68 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MAJOR,$OL_MAJOR,Major)
  69 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MINOR,$OL_MINOR,Minor)
  70 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_PATCH,$OL_PATCH,Patch)
  71
  72 OPENLDAP_LIBRELEASE=$OL_API_LIB_RELEASE
  73 AC_SUBST(OPENLDAP_LIBRELEASE)dnl
  74
  75 OPENLDAP_LIBVERSION=$OL_API_LIB_VERSION
  76 AC_SUBST(OPENLDAP_LIBVERSION)dnl
  77
  78 OPENLDAP_RELEASE_DATE="$OL_RELEASE_DATE"
  79 AC_SUBST(OPENLDAP_RELEASE_DATE)dnl
  80
  81 dnl We use autoconf features new to 2.59.  Later versions like won't work.
  82 dnl aclocal.m4 should be built using aclocal from automake 1.5
  83 dnl libtool 1.5 should be installed.
  84 AC_PREREQ(2.59)dnl Required Autoconf version
  85
  86 AH_TOP([
  87 /* begin of portable.h.pre */
  88 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
  89  *
  90  * Copyright 1998-2005 The OpenLDAP Foundation
  91  * All rights reserved.
  92  *
  93  * Redistribution and use in source and binary forms, with or without
  94  * modification, are permitted only as authorized by the OpenLDAP
  95  * Public License.
  96  *
  97  * A copy of this license is available in the file LICENSE in the
  98  * top-level directory of the distribution or, alternatively, at
  99  * <http://www.OpenLDAP.org/license.html>.
 100  */
 101
 102 #ifndef _LDAP_PORTABLE_H
 103 #define _LDAP_PORTABLE_H
 104
 105 /* define this if needed to get reentrant functions */
 106 #ifndef REENTRANT
 107 #undef REENTRANT
 108 #endif
 109 #ifndef _REENTRANT
 110 #undef _REENTRANT
 111 #endif
 112
 113 /* define this if needed to get threadsafe functions */
 114 #ifndef THREADSAFE
 115 #undef THREADSAFE
 116 #endif
 117 #ifndef _THREADSAFE
 118 #undef _THREADSAFE
 119 #endif
 120 #ifndef THREAD_SAFE
 121 #undef THREAD_SAFE
 122 #endif
 123 #ifndef _THREAD_SAFE
 124 #undef _THREAD_SAFE
 125 #endif
 126
 127 #ifndef _SGI_MP_SOURCE
 128 #undef _SGI_MP_SOURCE
 129 #endif
 130
 131 /* end of portable.h.pre */
 132 ])
 133 AH_BOTTOM([
 134 /* begin of portable.h.post */
 135
 136 #ifdef _WIN32
 137         /* don't suck in all of the win32 api */
 138 #       define WIN32_LEAN_AND_MEAN 1
 139 #endif
 140
 141 #ifndef LDAP_NEEDS_PROTOTYPES
 142 /* force LDAP_P to always include prototypes */
 143 #define LDAP_NEEDS_PROTOTYPES 1
 144 #endif
 145
 146 #ifndef LDAP_REL_ENG
 147 #if (LDAP_VENDOR_VERSION == 000000) && !defined(LDAP_DEVEL)
 148 #define LDAP_DEVEL
 149 #endif
 150 #if defined(LDAP_DEVEL) && !defined(LDAP_TEST)
 151 #define LDAP_TEST
 152 #endif
 153 #endif
 154
 155 #ifdef HAVE_STDDEF_H
 156 #       include <stddef.h>
 157 #endif
 158
 159 #ifdef HAVE_EBCDIC
 160 /* ASCII/EBCDIC converting replacements for stdio funcs
 161  * vsnprintf and snprintf are used too, but they are already
 162  * checked by the configure script
 163  */
 164 #define fputs ber_pvt_fputs
 165 #define fgets ber_pvt_fgets
 166 #define printf ber_pvt_printf
 167 #define fprintf ber_pvt_fprintf
 168 #define vfprintf ber_pvt_vfprintf
 169 #define vsprintf ber_pvt_vsprintf
 170 #endif
 171
 172 #include "ac/fdset.h"
 173
 174 #include "ldap_cdefs.h"
 175 #include "ldap_features.h"
 176
 177 #include "ac/assert.h"
 178 #include "ac/localize.h"
 179
 180 #endif /* _LDAP_PORTABLE_H */
 181 /* end of portable.h.post */
 182 ])
 183
 184 AC_CONFIG_HEADERS([include/portable.h:include/portable.hin])
 185 AC_CONFIG_HEADERS([include/ldap_features.h:include/ldap_features.hin])
 186 AC_CONFIG_HEADERS([include/lber_types.h:include/lber_types.hin])
 187
 188 dnl ================================================================
 189 dnl Start Args
 190 AC_MSG_CHECKING(configure arguments)
 191 AC_PREFIX_DEFAULT(/usr/local)
 192
 193 top_builddir=`pwd`
 194 AC_SUBST(top_builddir)dnl
 195
 196 dnl ----------------------------------------------------------------
 197 dnl --with-subdir
 198 ldap_subdir="/openldap"
 199
 200 AC_ARG_WITH(subdir,
 201 [  --with-subdir=DIR       change default subdirectory used for installs],
 202 [case "$withval" in
 203         no) ldap_subdir=""
 204                 ;;
 205         yes)
 206                 ;;
 207         /*|\\*)
 208                 ldap_subdir="$withval"
 209                 ;;
 210         *)
 211                 ldap_subdir="/$withval"
 212                 ;;
 213 esac
 214 ])dnl
 215
 216 AC_SUBST(ldap_subdir)dnl
 217
 218 dnl ----------------------------------------------------------------
 219 dnl General "enable" options
 220 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes)dnl
 221 OL_ARG_ENABLE(dynamic,[  --enable-dynamic         enable linking built binaries with dynamic libs], no)dnl
 222 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 223 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 224 dnl OL_ARG_ENABLE(referrals,[  --enable-referrals         enable LDAPv2+ Referrals (experimental)], no)dnl
 225 ol_enable_referrals=${ol_enable_referrals-no}
 226 dnl OL_ARG_ENABLE(kbind,[  --enable-kbind         enable LDAPv2+ Kerberos IV bind (deprecated)], no)dnl
 227 ol_enable_kbind=${ol_enable_kbind-no}
 228 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 229 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 230
 231 dnl ----------------------------------------------------------------
 232 dnl General "with" options
 233 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 234         auto, [auto yes no] )
 235 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch(3) URL support],
 236         auto, [auto yes no] )
 237 dnl     OL_ARG_WITH(kerberos,[  --with-kerberos   with Kerberos support],
 238 dnl             auto, [auto k5 k5only k425 kth k4 afs yes no])
 239 ol_with_kerberos=${ol_with_kerberos-auto}
 240 OL_ARG_WITH(threads,[  --with-threads     with threads],
 241         auto, [auto nt posix mach pth lwp yes no manual] )
 242 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support],
 243         auto, [auto ssleay openssl yes no] )
 244 OL_ARG_WITH(yielding_select,[  --with-yielding-select  with implicitly yielding select],
 245         auto, [auto yes no manual] )
 246 OL_ARG_WITH(multiple_precision,[  --with-multiple-precision
 247                           multiple precision support for statistics
 248                           auto|bignum|gmp],
 249         auto, [auto bignum gmp yes no] )
 250
 251 dnl ----------------------------------------------------------------
 252 dnl Server options
 253 dnl ----------------------------------------------------------------
 254
 255 dnl ----------------------------------------------------------------
 256 dnl SLAPD OPTIONS
 257 AC_ARG_ENABLE(xxslapdoptions,[
 258 SLAPD (Standalone LDAP Daemon) Options:])
 259 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 260 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs (experimental)], no)dnl
 261 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 262 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], no)dnl
 263 OL_ARG_ENABLE(lmpasswd,[    --enable-lmpasswd     enable LAN Manager passwords], no)dnl
 264 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 265 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 266 dnl OL_ARG_ENABLE(multimaster,[    --enable-multimaster  enable multimaster replication], no)dnl
 267 ol_enable_multimaster=${ol_enable_multimaster-no}
 268 OL_ARG_ENABLE(rewrite,[    --enable-rewrite       enable DN rewriting in back-ldap and rwm overlay], auto)dnl
 269 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups of client hostnames], no)dnl
 270 OL_ARG_ENABLE(slapi,[    --enable-slapi        enable SLAPI support (experimental)], no)dnl
 271 OL_ARG_ENABLE(slp,[    --enable-slp          enable SLPv2 support], no)dnl
 272 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 273
 274 dnl ----------------------------------------------------------------
 275 dnl SLAPD Backend Options
 276 Backends="bdb dnssrv hdb ldap ldbm meta monitor null \
 277         passwd perl relay shell sql"
 278
 279 AC_ARG_ENABLE(xxslapbackends,[
 280 SLAPD Backend Options:])
 281
 282 OL_ARG_ENABLE(backends,[    --enable-backends     enable all available backends],
 283         --, [no yes mod])dnl
 284 OL_ARG_ENABLE(bdb,[    --enable-bdb       enable Berkeley DB backend],
 285         yes, [no yes mod], ol_enable_backends)dnl
 286 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend],
 287         no, [no yes mod], ol_enable_backends)dnl
 288 OL_ARG_ENABLE(hdb,[    --enable-hdb       enable Hierarchical DB backend],
 289         yes, [no yes mod], ol_enable_backends)dnl
 290 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend],
 291         no, [no yes mod], ol_enable_backends)dnl
 292 OL_ARG_ENABLE(ldbm,[    --enable-ldbm     enable ldbm backend],
 293         no, [no yes mod], ol_enable_backends)dnl
 294 OL_ARG_ENABLE(ldbm_api,[      --enable-ldbm-api   use LDBM API],
 295         auto, [auto berkeley bcompat mdbm gdbm])
 296 OL_ARG_ENABLE(ldbm_type,[      --enable-ldbm-type  use LDBM type],
 297         auto, [auto btree hash])
 298 OL_ARG_ENABLE(meta,[    --enable-meta     enable metadirectory backend],
 299         no, [no yes mod], ol_enable_backends)dnl
 300 OL_ARG_ENABLE(monitor,[    --enable-monitor       enable monitor backend],
 301         yes, [no yes mod], ol_enable_backends)dnl
 302 OL_ARG_ENABLE(null,[    --enable-null     enable null backend],
 303         no, [no yes mod], ol_enable_backends)dnl
 304 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend],
 305         no, [no yes mod], ol_enable_backends)dnl
 306 OL_ARG_ENABLE(perl,[    --enable-perl     enable perl backend],
 307         no, [no yes mod], ol_enable_backends)dnl
 308 OL_ARG_ENABLE(relay,[    --enable-relay           enable relay backend],
 309         yes, [no yes mod], ol_enable_backends)dnl
 310 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend],
 311         no, [no yes mod], ol_enable_backends)dnl
 312 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend],
 313         no, [no yes mod], ol_enable_backends)dnl
 314
 315 dnl ----------------------------------------------------------------
 316 dnl SLAPD Overlay Options
 317 Overlays="accesslog \
 318         denyop \
 319         dyngroup \
 320         dynlist \
 321         glue \
 322         lastmod \
 323         ppolicy \
 324         proxycache \
 325         refint \
 326         retcode \
 327         rwm \
 328         syncprov \
 329         translucent \
 330         unique \
 331         valsort"
 332
 333 AC_ARG_ENABLE(xxslapoverlays,[
 334 SLAPD Overlay Options:])
 335
 336 OL_ARG_ENABLE(overlays,[    --enable-overlays     enable all available overlays],
 337         --, [no yes mod])dnl
 338 OL_ARG_ENABLE(accesslog,[    --enable-accesslog   In-Directory Access Logging overlay],
 339         no, [no yes mod], ol_enable_overlays)
 340 OL_ARG_ENABLE(denyop,[    --enable-denyop         Deny Operation overlay],
 341         no, [no yes mod], ol_enable_overlays)
 342 OL_ARG_ENABLE(dyngroup,[    --enable-dyngroup     Dynamic Group overlay],
 343         no, [no yes mod], ol_enable_overlays)
 344 OL_ARG_ENABLE(dynlist,[    --enable-dynlist       Dynamic List overlay],
 345         no, [no yes mod], ol_enable_overlays)
 346 OL_ARG_ENABLE(glue,[    --enable-glue     Backend Glue overlay],
 347         yes, [no yes mod], ol_enable_overlays)
 348 OL_ARG_ENABLE(lastmod,[    --enable-lastmod       Last Modification overlay],
 349         no, [no yes mod], ol_enable_overlays)
 350 OL_ARG_ENABLE(ppolicy,[    --enable-ppolicy       Password Policy overlay],
 351         no, [no yes mod], ol_enable_overlays)
 352 OL_ARG_ENABLE(proxycache,[    --enable-proxycache         Proxy Cache overlay],
 353         no, [no yes mod], ol_enable_overlays)
 354 OL_ARG_ENABLE(refint,[    --enable-refint         Referential Integrity overlay],
 355         no, [no yes mod], ol_enable_overlays)
 356 OL_ARG_ENABLE(retcode,[    --enable-retcode       Return Code testing overlay],
 357         no, [no yes mod], ol_enable_overlays)
 358 OL_ARG_ENABLE(rwm,[    --enable-rwm               Rewrite/Remap overlay],
 359         no, [no yes mod], ol_enable_overlays)
 360 OL_ARG_ENABLE(syncprov,[    --enable-syncprov     Syncrepl Provider overlay],
 361         yes, [no yes mod], ol_enable_overlays)
 362 OL_ARG_ENABLE(translucent,[    --enable-translucent  Translucent Proxy overlay],
 363         no, [no yes mod], ol_enable_overlays)
 364 OL_ARG_ENABLE(unique,[    --enable-unique       Attribute Uniqueness overlay],
 365         no, [no yes mod], ol_enable_overlays)
 366 OL_ARG_ENABLE(unique,[    --enable-valsort      Value Sorting overlay],
 367         no, [no yes mod], ol_enable_overlays)
 368
 369 dnl ----------------------------------------------------------------
 370 dnl SLURPD OPTIONS
 371 AC_ARG_ENABLE(xxslurpdoptions,[
 372 SLURPD (Replication Daemon) Options:])
 373 OL_ARG_ENABLE(slurpd,[  --enable-slurpd   enable building slurpd], auto)dnl
 374
 375 dnl ----------------------------------------------------------------
 376 AC_ARG_ENABLE(xxliboptions,[
 377 Library Generation & Linking Options])
 378 AC_ENABLE_STATIC
 379 AC_ENABLE_SHARED
 380
 381 dnl ----------------------------------------------------------------
 382
 383 # validate options
 384 if test $ol_enable_slapd = no ; then
 385         dnl SLAPD was specificallly disabled
 386         if test $ol_enable_slapi = yes ; then
 387                 AC_MSG_WARN([slapd disabled, ignoring --enable-slapi argument])
 388         fi
 389         case "$ol_enable_backends" in yes | mod)
 390                 AC_MSG_WARN([slapd disabled, ignoring --enable-backends argument])
 391         esac
 392         for i in $Backends; do
 393                 eval "ol_tmp=\$ol_enable_$i"
 394                 if test $ol_tmp != no ; then
 395                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 396                         eval "ol_enable_$i=no"
 397                 fi
 398         done
 399         if test $ol_enable_modules = yes ; then
 400                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 401         fi
 402         if test $ol_enable_multimaster = yes ; then
 403                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 404         fi
 405         if test $ol_enable_wrappers = yes ; then
 406                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 407         fi
 408         if test $ol_enable_rlookups = yes ; then
 409                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 410         fi
 411         if test $ol_enable_aci = yes ; then
 412                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 413         fi
 414         if test $ol_enable_ldbm_api != auto ; then
 415                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm-api argument])
 416         fi
 417         if test $ol_enable_ldbm_type != auto ; then
 418                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm-type argument])
 419         fi
 420         if test $ol_enable_slurpd = yes ; then
 421                 AC_MSG_ERROR([slurpd requires slapd])
 422         fi
 423         if test $ol_enable_rewrite = yes ; then
 424                 AC_MSG_WARN([slapd disabled, ignoring --enable-rewrite argument])
 425         fi
 426         dnl overlays
 427         case "$ol_enable_overlays" in yes | mod)
 428                 AC_MSG_WARN([slapd disabled, ignoring --enable-overlays argument])
 429         esac
 430         for i in $Overlays; do
 431                 eval "ol_tmp=\$ol_enable_$i"
 432                 if test $ol_tmp != no ; then
 433                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 434                         eval "ol_enable_$i=no"
 435                 fi
 436         done
 437
 438         # force settings to no
 439         ol_enable_slapi=no
 440
 441         ol_enable_backends=
 442         ol_enable_overlays=
 443         ol_enable_modules=no
 444         ol_enable_multimaster=no
 445         ol_enable_rlookups=no
 446         ol_enable_aci=no
 447         ol_enable_wrappers=no
 448
 449         ol_enable_ldbm_api=no
 450         ol_enable_ldbm_type=no
 451
 452         ol_enable_slurpd=no
 453
 454         ol_enable_rewrite=no
 455
 456 elif test $ol_enable_ldbm = no ; then
 457         dnl SLAPD without LDBM
 458
 459         if test $ol_enable_ldbm_api != auto ; then
 460                 AC_MSG_WARN([LDBM disabled, ignoring --enable-ldbm-api argument])
 461         fi
 462
 463         if test $ol_enable_ldbm_type != auto ; then
 464                 AC_MSG_WARN([LDBM disabled, ignoring --enable-ldbm-type argument])
 465         fi
 466
 467         if test $ol_enable_modules != yes -a \
 468                 $ol_enable_bdb = no -a \
 469                 $ol_enable_dnssrv = no -a \
 470                 $ol_enable_hdb = no -a \
 471                 $ol_enable_ldap = no -a \
 472                 $ol_enable_meta = no -a \
 473                 $ol_enable_monitor = no -a \
 474                 $ol_enable_null = no -a \
 475                 $ol_enable_passwd = no -a \
 476                 $ol_enable_perl = no -a \
 477                 $ol_enable_relay = no -a \
 478                 $ol_enable_shell = no -a \
 479                 $ol_enable_sql = no ; then
 480
 481                 if test $ol_enable_slapd = yes ; then
 482                         AC_MSG_ERROR([slapd requires a backend])
 483                 else
 484                         AC_MSG_WARN([skipping slapd, no backend specified])
 485                         ol_enable_slapd=no
 486                 fi
 487         fi
 488
 489         ol_enable_ldbm_api=no
 490         ol_enable_ldbm_type=no
 491
 492         if test $ol_enable_bdb != no -o $ol_enable_hdb != no; then
 493                 ol_enable_ldbm_api=berkeley
 494         fi
 495
 496 else
 497         dnl SLAPD with LDBM
 498         if test $ol_enable_ldbm_api = gdbm -a \
 499                 $ol_enable_ldbm_type = btree ; then
 500                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 501         fi
 502         if test $ol_enable_ldbm_api = mdbm -a \
 503                 $ol_enable_ldbm_type = btree ; then
 504                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 505         fi
 506         if test $ol_enable_ldbm_api = ndbm -a \
 507                 $ol_enable_ldbm_type = btree ; then
 508                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 509         fi
 510
 511         if test $ol_enable_bdb != no -o $ol_enable_hdb != no ; then
 512                 if test $ol_enable_ldbm_api = auto ; then
 513                         ol_enable_ldbm_api=berkeley
 514                 elif test $ol_enable_ldbm_api != berkeley ; then
 515                         AC_MSG_ERROR([LDBM API not compatible with BDB/HDB])
 516                 fi
 517         fi
 518 fi
 519
 520 if test $ol_enable_meta = yes -a $ol_enable_ldap = no ; then
 521         AC_MSG_ERROR([--enable-meta requires --enable-ldap])
 522 fi
 523
 524 if test $ol_enable_slurpd = yes ; then
 525         dnl SLURPD was specifically enabled
 526         if test $ol_with_threads = no ; then
 527                 AC_MSG_ERROR([slurpd requires threads])
 528         fi
 529 fi
 530
 531 if test $ol_enable_lmpasswd = yes ; then
 532         if test $ol_with_tls = no ; then
 533                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
 534         fi
 535 fi
 536
 537 if test $ol_enable_kbind = yes ; then
 538         if test $ol_with_kerberos = no ; then
 539                 AC_MSG_ERROR([options require --with-kerberos])
 540         elif test $ol_with_kerberos = auto ; then
 541                 ol_with_kerberos=yes
 542         fi
 543
 544 elif test $ol_enable_kbind = no ; then
 545         if test $ol_with_kerberos = auto ; then
 546                 ol_with_kerberos=no
 547         elif test $ol_with_kerberos != no ; then
 548                 AC_MSG_WARN([Kerberos detection enabled unnecessarily]);
 549                 ol_with_kerberos=no
 550         fi
 551 fi
 552
 553 if test $ol_enable_spasswd = yes ; then
 554         if test $ol_with_cyrus_sasl = no ; then
 555                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 556         fi
 557         ol_with_cyrus_sasl=yes
 558 fi
 559
 560 AC_MSG_RESULT(done)
 561
 562 dnl ----------------------------------------------------------------
 563 dnl Initialize vars
 564 LDAP_LIBS=
 565 LDBM_LIBS=
 566 LTHREAD_LIBS=
 567 LUTIL_LIBS=
 568
 569 SLAPD_LIBS=
 570 SLURPD_LIBS=
 571
 572 BUILD_SLAPD=no
 573 BUILD_SLURPD=no
 574
 575 BUILD_THREAD=no
 576
 577 BUILD_SLAPI=no
 578 SLAPD_SLAPI_DEPEND=
 579
 580 BUILD_BDB=no
 581 BUILD_DNSSRV=no
 582 BUILD_HDB=no
 583 BUILD_LDAP=no
 584 BUILD_LDBM=no
 585 BUILD_META=no
 586 BUILD_MONITOR=no
 587 BUILD_NULL=no
 588 BUILD_PASSWD=no
 589 BUILD_PERL=no
 590 BUILD_RELAY=no
 591 BUILD_SHELL=no
 592 BUILD_SQL=no
 593
 594 BUILD_ACCESSLOG=no
 595 BUILD_DENYOP=no
 596 BUILD_DYNGROUP=no
 597 BUILD_DYNLIST=no
 598 BUILD_GLUE=no
 599 BUILD_LASTMOD=no
 600 BUILD_PPOLICY=no
 601 BUILD_PROXYCACHE=no
 602 BUILD_REFINT=no
 603 BUILD_RETCODE=no
 604 BUILD_RWM=no
 605 BUILD_SYNCPROV=no
 606 BUILD_TRANSLUCENT=no
 607 BUILD_UNIQUE=no
 608 BUILD_VALSORT=no
 609
 610 SLAPD_STATIC_OVERLAYS=
 611 SLAPD_DYNAMIC_OVERLAYS=
 612
 613 SLAPD_MODULES_LDFLAGS=
 614 SLAPD_MODULES_CPPFLAGS=
 615
 616 SLAPD_STATIC_BACKENDS=back-ldif
 617 SLAPD_DYNAMIC_BACKENDS=
 618
 619 SLAPD_PERL_LDFLAGS=
 620 MOD_PERL_LDFLAGS=
 621 PERL_CPPFLAGS=
 622
 623 SLAPD_SQL_LDFLAGS=
 624 SLAPD_SQL_LIBS=
 625 SLAPD_SQL_INCLUDES=
 626
 627 KRB4_LIBS=
 628 KRB5_LIBS=
 629 SASL_LIBS=
 630 TLS_LIBS=
 631 MODULES_LIBS=
 632 SLAPI_LIBS=
 633 LIBSLAPI=
 634 LIBSLAPITOOLS=
 635 AUTH_LIBS=
 636
 637 SLAPD_SLP_LIBS=
 638 SLAPD_GMP_LIBS=
 639
 640 dnl ================================================================
 641 dnl Checks for programs
 642
 643 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 644
 645 dnl ----------------------------------------------------------------
 646 dnl
 647 dnl Determine which C translator to use
 648 dnl
 649
 650 dnl AIX Thread requires we use cc_r or xlc_r.
 651 dnl But only do this IF AIX and CC is not set
 652 dnl and threads are auto|yes|posix.
 653 dnl
 654 dnl If we find cc_r|xlc_r, force pthreads and assume
 655 dnl             pthread_create is in $LIBS (ie: don't bring in
 656 dnl             any additional thread libraries)
 657 dnl If we do not find cc_r|xlc_r, disable threads
 658
 659 ol_aix_threads=no
 660 case "$target" in
 661 *-*-aix*) dnl all AIX is not a good idea.
 662         if test -z "$CC" ; then
 663                 case "$ol_with_threads" in
 664                 auto | yes |  posix) ol_aix_threads=yes ;;
 665                 esac
 666         fi
 667 ;;
 668 esac
 669
 670 if test $ol_aix_threads = yes ; then
 671         if test -z "${CC}" ; then
 672                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 673
 674                 if test "$CC" = cc ; then
 675                         dnl no CC! don't allow --with-threads
 676                         if test $ol_with_threads != auto ; then
 677                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 678                         else
 679                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 680                         fi
 681                         ol_with_threads=no
 682                 fi
 683         fi
 684
 685         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 686                 ol_with_threads=posix
 687                 ol_cv_pthread_create=yes
 688         fi
 689 fi
 690
 691 if test -z "${CC}"; then
 692         AC_CHECK_PROGS(CC,cc gcc,missing)
 693
 694         if test "${CC}" = "missing" ; then
 695                 AC_MSG_ERROR([Unable to locate cc(1) or suitable replacement.  Check PATH or set CC.])
 696         fi
 697 fi
 698
 699 if test -z "${AR}"; then
 700         AC_CHECK_PROGS(AR,ar gar,missing)
 701
 702         if test "${AR}" = "missing" ; then
 703                 AC_MSG_ERROR([Unable to locate ar(1) or suitable replacement.  Check PATH or set AR.])
 704         fi
 705 fi
 706
 707 AC_LIBTOOL_WIN32_DLL
 708 AC_LIBTOOL_DLOPEN
 709 AC_PROG_LIBTOOL
 710
 711 dnl ----------------------------------------------------------------
 712 dnl Perl
 713 ol_link_perl=no
 714 if test $ol_enable_perl != no ; then
 715         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 716
 717         if test "no$PERLBIN" = "no" ; then
 718                 if test $ol_enable_perl = yes ; then
 719                         AC_MSG_ERROR([could not locate perl])
 720                 fi
 721
 722         else
 723                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 724                 PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e 's/ -lc / /' -e 's/ -lc$//'`"
 725
 726                 if test x"$ol_enable_perl" = "xyes" ; then
 727                         SLAPD_PERL_LDFLAGS="$PERL_LDFLAGS"
 728                 else
 729                         MOD_PERL_LDFLAGS="$PERL_LDFLAGS"
 730                 fi
 731                 dnl should check perl version
 732                 ol_link_perl=yes
 733         fi
 734 fi
 735
 736 AC_PROG_CPP
 737
 738 dnl ----------------------------------------------------------------
 739 dnl Checks for file extensions
 740 AC_EXEEXT
 741 AC_OBJEXT
 742 AC_DEFINE_UNQUOTED(EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 743
 744 dnl ----------------------------------------------------------------
 745 dnl BeOS requires -lbe -lroot -lnet
 746 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 747
 748 dnl ----------------------------------------------------------------
 749 dnl OpenLDAP requires STDC features
 750 AC_PROG_CC
 751 if test "X${ac_cv_prog_cc_stdc}" = "Xno" ; then
 752         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 753 fi
 754
 755 dnl ----------------------------------------------------------------
 756 dnl Check cc depend flags
 757 OL_MKDEPEND
 758 if test "${ol_cv_mkdep}" = no ; then
 759         # this will soon become an error
 760         AC_MSG_WARN([do not know how to generate dependencies])
 761 fi
 762
 763 dnl ----------------------------------------------------------------
 764 dnl Check for AIX security library
 765 AC_CHECK_LIB(s, afopen, [
 766         AUTH_LIBS=-ls
 767         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 768 ])
 769
 770 dnl ----------------------------------------------------------------
 771 dnl Check for IBM OS/390
 772 case "$target" in
 773 *-ibm-openedition)
 774         ac_cv_func_getopt=no
 775         AC_DEFINE(BOTH_STRINGS_H,1,[define to use both <string.h> and <strings.h>])
 776         ;;
 777 esac
 778
 779 dnl ----------------------------------------------------------------
 780 dnl Check for module support
 781 ol_link_modules=no
 782 WITH_MODULES_ENABLED=no
 783 if test $ol_enable_modules != no ; then
 784         AC_CHECK_HEADERS(ltdl.h)
 785
 786         if test $ac_cv_header_ltdl_h = no ; then
 787                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 788         fi
 789
 790         AC_CHECK_LIB(ltdl, lt_dlinit, [
 791                 MODULES_LIBS=-lltdl
 792                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 793         ])
 794
 795         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 796                 AC_MSG_ERROR([could not locate libtool -lltdl])
 797         fi
 798         ol_link_modules=yes
 799         WITH_MODULES_ENABLED=yes
 800
 801 else
 802         for i in $Backends; do
 803                 eval "ol_tmp=\$ol_enable_$i"
 804                 if test $ol_tmp = mod ; then
 805                         AC_MSG_WARN([building static $i backend])
 806                         eval "ol_enable_$i=yes"
 807                 fi
 808         done
 809         for i in $Overlays; do
 810                 eval "ol_tmp=\$ol_enable_$i"
 811                 if test $ol_tmp = mod ; then
 812                         AC_MSG_WARN([building static $i overlay])
 813                         eval "ol_enable_$i=yes"
 814                 fi
 815         done
 816 fi
 817
 818 dnl ----------------------------------------------------------------
 819 dnl Checks for header files.
 820 OL_HEADER_STDC
 821
 822 if test $ol_cv_header_stdc != yes; then
 823         AC_MSG_WARN([could not locate Standard C compliant headers])
 824 fi
 825
 826 AC_HEADER_DIRENT
 827 AC_HEADER_SYS_WAIT
 828 AC_HEADER_TIOCGWINSZ
 829
 830 AC_CHECK_HEADERS(               \
 831         arpa/inet.h             \
 832         arpa/nameser.h          \
 833         assert.h                \
 834         bits/types.h            \
 835         conio.h                 \
 836         crypt.h                 \
 837         direct.h                \
 838         errno.h                 \
 839         fcntl.h                 \
 840         filio.h                 \
 841         getopt.h                \
 842         grp.h                   \
 843         io.h                    \
 844         libutil.h               \
 845         limits.h                \
 846         locale.h                \
 847         netinet/tcp.h           \
 848         malloc.h                \
 849         memory.h                \
 850         psap.h                  \
 851         pwd.h                   \
 852         process.h               \
 853         sgtty.h                 \
 854         shadow.h                \
 855         stddef.h                \
 856         string.h                \
 857         strings.h               \
 858         sysexits.h              \
 859         sys/file.h              \
 860         sys/filio.h             \
 861         sys/errno.h             \
 862         sys/ioctl.h             \
 863         sys/param.h             \
 864         sys/resource.h          \
 865         sys/select.h            \
 866         sys/socket.h            \
 867         sys/stat.h              \
 868         sys/syslog.h            \
 869         sys/time.h              \
 870         sys/types.h             \
 871         sys/uio.h               \
 872         syslog.h                \
 873         termios.h               \
 874         unistd.h                \
 875         utime.h                 \
 876         winsock.h               \
 877         winsock2.h              \
 878 )
 879
 880 AC_CHECK_HEADERS( resolv.h, [], [],
 881 [$ac_includes_default]
 882 #include <netinet/in.h>
 883 )
 884
 885 AC_CHECK_HEADERS(sys/ucred.h, [], [],
 886 [$ac_includes_default
 887 #ifdef HAVE_SYS_PARAM_H
 888 #include <sys/param.h>
 889 #endif
 890 ])
 891
 892 dnl ----------------------------------------------------------------
 893 dnl Checks for libraries
 894
 895 AC_CHECK_FUNCS( sigaction sigset )
 896
 897 dnl HP-UX requires -lV3
 898 dnl this is not needed on newer versions of HP-UX
 899 if test $ac_cv_func_sigaction = no && test $ac_cv_func_sigaction = no ; then
 900         AC_CHECK_LIB(V3, sigset)
 901 fi
 902
 903 dnl The following is INTENTIONALLY scripted out because shell does not
 904 dnl support variable names with the '@' character, which is what
 905 dnl autoconf would try to generate if one merely used AC_SEARCH_LIBS
 906 dnl
 907 dnl Skip Winsock tests on Cygwin
 908 if test "$ac_cv_cygwin" != yes && test "$ac_cv_header_winsock_h" = yes; then
 909 AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 910 save_LIBS="$LIBS"
 911 for curlib in ws2_32 wsock32; do
 912         LIBS="$LIBS -l$curlib"
 913         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <winsock.h>
 914                         ]], [[
 915                         socket(0,0,0);
 916                         select(0,NULL,NULL,NULL,NULL);
 917                         closesocket(0);
 918                         gethostname(NULL,0);
 919                         ]])],[ol_cv_winsock=yes],[ol_cv_winsock=no])
 920
 921         if test $ol_cv_winsock = yes; then
 922                 AC_DEFINE(HAVE_WINSOCK, 1, [define if you have winsock])
 923                 ac_cv_func_socket=yes
 924                 ac_cv_func_select=yes
 925                 ac_cv_func_closesocket=yes
 926                 ac_cv_func_gethostname=yes
 927                 if test $curlib = ws2_32; then
 928                         ol_cv_winsock=winsock2
 929                         AC_DEFINE(HAVE_WINSOCK2, 1,
 930                                   [define if you have winsock2])
 931                 fi
 932                 break
 933         fi
 934         LIBS="$save_LIBS"
 935 done)
 936 fi
 937
 938 dnl Find socket()
 939 dnl Likely combinations:
 940 dnl             -lsocket [ -lnsl_s | -lnsl ]
 941 dnl             -linet
 942
 943 AC_CHECK_FUNC(socket, :, [
 944 dnl hopefully we won't include too many libraries
 945         AC_CHECK_LIB(socket, main)
 946         AC_CHECK_LIB(net, main)
 947         AC_CHECK_LIB(nsl_s, main)
 948         AC_CHECK_LIB(nsl, main)
 949         AC_CHECK_LIB(inet, socket)
 950         AC_CHECK_LIB(gen, main)
 951 ])
 952
 953 dnl require select
 954 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 955
 956 if test "${ac_cv_header_winsock_h}" != yes; then
 957         dnl Select arg types
 958         dnl (if this detection becomes permenent, it and the select() detection
 959         dnl should be done before the yielding select test)
 960         AC_FUNC_SELECT_ARGTYPES
 961 fi
 962
 963 dnl check to see if system call automatically restart
 964 dnl AC_SYS_RESTARTABLE_SYSCALLS
 965
 966 dnl ----------------------------------------------------------------
 967 AC_CHECK_FUNCS( poll )
 968 AC_CHECK_HEADERS( poll.h )
 969
 970 dnl ----------------------------------------------------------------
 971 AC_CHECK_HEADERS( sys/epoll.h )
 972 if test "${ac_cv_header_sys_epoll_h}" = yes; then
 973 AC_MSG_CHECKING(for epoll system call)
 974 AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(int argc, char *argv)
 975 {
 976         int epfd = epoll_create(256);
 977         exit (epfd == -1 ? 1 : 0);
 978 }]])],[AC_MSG_RESULT(yes)
 979 AC_DEFINE(HAVE_EPOLL,1, [define if your system supports epoll])],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 980 fi
 981
 982 dnl ----------------------------------------------------------------
 983 # strerror checks
 984 OL_STRERROR
 985
 986 dnl ----------------------------------------------------------------
 987 dnl require POSIX regex
 988 AC_CHECK_HEADERS( regex.h )
 989 if test "$ac_cv_header_regex_h" != yes ; then
 990         AC_MSG_ERROR([POSIX regex.h required.])
 991 fi
 992 AC_SEARCH_LIBS(regfree, [regex gnuregex],
 993         :, AC_MSG_ERROR([POSIX regex required.]))
 994
 995 OL_POSIX_REGEX
 996 if test "$ol_cv_c_posix_regex" = no ; then
 997         AC_MSG_ERROR([broken POSIX regex!])
 998 fi
 999
1000 dnl ----------------------------------------------------------------
1001 dnl UUID Support
1002
1003 have_uuid=no
1004 AC_CHECK_HEADERS(sys/uuid.h)
1005 if test $ac_cv_header_sys_uuid_h = yes ; then
1006         save_LIBS="$LIBS"
1007         AC_SEARCH_LIBS(uuid_to_str, uuid, [have_uuid=yes], :)
1008         LIBS="$save_LIBS"
1009
1010         if test have_uuid = yes ; then
1011                 AC_DEFINE(HAVE_UUID_TO_STR,1,
1012                         [define if you have uuid_to_str()])
1013
1014                 test "$ac_cv_search_uuid_to_str" = "none required" || \
1015                         SLAPD_LIBS="$SLAPD_LIBS $ac_cv_search_uuid_to_str"
1016         fi
1017 fi
1018
1019 dnl For windows, check for the need of RPCRT for UUID function support
1020 if test $have_uuid = no ; then
1021         AC_MSG_CHECKING(to see if -lrpcrt4 is needed for win32 UUID support)
1022         save_LIBS="$LIBS"
1023         LIBS="$LIBS -lrpcrt4"
1024         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1025                 int __stdcall UuidCreate(void *);
1026                 int __stdcall UuidToStringA(void *,void **);
1027                 ]], [[
1028                 UuidCreate(0);
1029                 UuidToStringA(0,0);
1030                 ]])],[need_rpcrt=yes],[need_rpcrt=no])
1031         if test $need_rpcrt = yes; then
1032                 SLAPD_LIBS="$SLAPD_LIBS -lrpcrt4"
1033         fi
1034         LIBS="$save_LIBS"
1035         AC_MSG_RESULT($need_rpcrt)
1036 fi
1037
1038 dnl ----------------------------------------------------------------
1039 dnl Check for resolver routines
1040 OL_RESOLVER_LINK
1041
1042 ol_link_dnssrv=no
1043 if test "$ol_cv_lib_resolver" != no ; then
1044         AC_DEFINE(HAVE_RES_QUERY,1,
1045                 [define if you have res_query()])
1046
1047         if test "$ol_enable_dnssrv" != no ; then
1048                 ol_link_dnssrv=yes
1049         fi
1050
1051         if test "$ol_cv_lib_resolver" != yes ; then
1052                 LIBS="$ol_cv_lib_resolver $LIBS"
1053         fi
1054 fi
1055
1056 if test "$ol_enable_dnssrv" = yes -o "$ol_enable_dnssrv" = mod ; then
1057         if test "$ol_link_dnssrv" = no ; then
1058                 AC_MSG_ERROR([DNSSRV requires res_query()])
1059         fi
1060 else
1061         ol_enable_dnssrv=no
1062 fi
1063
1064 AC_CHECK_FUNCS( hstrerror )
1065
1066 dnl ----------------------------------------------------------------
1067 dnl PF_INET6 support requires getaddrinfo and INET6_ADDRSTRLEN
1068 dnl PF_LOCAL may use getaddrinfo in available
1069 AC_CHECK_FUNCS( getaddrinfo getnameinfo gai_strerror inet_ntop )
1070
1071 ol_link_ipv6=no
1072 if test $ac_cv_func_getaddrinfo = no -o $ac_cv_func_inet_ntop = no ; then
1073         if test $ol_enable_ipv6 = yes ; then
1074                 AC_MSG_ERROR([IPv6 support requires getaddrinfo() and inet_ntop()])
1075         fi
1076 elif test $ol_enable_ipv6 != no ; then
1077         AC_CACHE_CHECK([INET6_ADDRSTRLEN],[ol_cv_inet6_addrstrlen],[
1078                 AC_EGREP_CPP(__has_inet6_addrstrlen__,[
1079 #                       include <netinet/in.h>
1080 #                       ifdef INET6_ADDRSTRLEN
1081                                 __has_inet6_addrstrlen__;
1082 #                       endif
1083                 ], [ol_cv_inet6_addrstrlen=yes], [ol_cv_inet6_addrstrlen=no])])
1084
1085
1086         AC_CACHE_CHECK([struct sockaddr_storage],ol_cv_struct_sockaddr_storage,[
1087                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1088 #include <sys/types.h>
1089 #include <sys/socket.h>
1090 ]], [[
1091                         struct sockaddr_storage ss;
1092 ]])],[ol_cv_struct_sockaddr_storage=yes],[ol_cv_struct_sockaddr_storage=no])])
1093
1094         if test $ol_cv_inet6_addrstrlen = yes \
1095                 -a $ol_cv_struct_sockaddr_storage = yes ; then
1096                 ol_link_ipv6=yes
1097         elif test $ol_enable_ipv6 = yes \
1098                         -a $ol_cv_inet6_addrstrlen = no ; then
1099                 AC_MSG_ERROR([IPv6 support requires INET6_ADDRSTRLEN])
1100         elif test $ol_enable_ipv6 = yes \
1101                         -a $ol_cv_struct_sockaddr_storage = no ; then
1102                 AC_MSG_ERROR([IPv6 support requires struct sockaddr_storage])
1103         fi
1104 fi
1105
1106 if test $ol_enable_local != no ; then
1107         AC_CHECK_HEADERS( sys/un.h )
1108
1109         if test $ol_enable_local = auto ; then
1110                 ol_enable_local=$ac_cv_header_sys_un_h
1111         elif test $ac_cv_header_sys_un_h = no ; then
1112                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
1113         fi
1114 fi
1115
1116 dnl ----------------------------------------------------------------
1117 dnl Kerberos
1118 ol_link_kbind=no
1119 ol_link_krb5=no
1120 ol_link_krb4=no
1121
1122 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
1123         -o $ol_with_kerberos = k5 -o $ol_with_kerberos = k5only \
1124         -o $ol_with_kerberos = k425 ; then
1125
1126         AC_CHECK_HEADERS(krb5.h)
1127
1128         if test $ac_cv_header_krb5_h = yes ; then
1129                 dnl lazy check for Heimdal Kerberos
1130                 AC_CHECK_HEADERS(heim_err.h)
1131                 if test $ac_cv_header_heim_err_h = yes ; then
1132                         krb5_impl=heimdal
1133                 else
1134                         krb5_impl=mit
1135                 fi
1136
1137                 if test $krb5_impl = mit; then
1138                         AC_CHECK_LIB(k5crypto, main,
1139                                 [krb5crypto=k5crypto],
1140                                 [krb5crypto=crypto])
1141
1142                         AC_CHECK_LIB(krb5, main,
1143                                 [have_krb5=yes
1144                                 KRB5_LIBS="-lkrb5 -l$krb5crypto -lcom_err"],
1145                                 [have_krb5=no],
1146                                 [-l$krb5crypto -lcom_err])
1147
1148                 elif test $krb5_impl = heimdal; then
1149                         AC_CHECK_LIB(des, main,
1150                                 [krb5crypto=des],
1151                                 [krb5crypto=crypto])
1152
1153                         AC_CHECK_LIB(krb5, main,
1154                                 [have_krb5=yes
1155                                 KRB5_LIBS="-lkrb5 -l$krb5crypto -lasn1 -lroken -lcom_err"],
1156                                 [have_krb5=no],
1157                                 [-l$krb5crypto -lasn1 -lroken -lcom_err])
1158
1159                         AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1,
1160                                 [define if you have HEIMDAL Kerberos])
1161
1162                 else
1163                         have_krb5=no
1164                         AC_MSG_WARN([Unrecognized Kerberos5 Implementation])
1165                 fi
1166
1167                 if test $have_krb5 = yes ; then
1168                         ol_link_krb5=yes
1169
1170                         AC_DEFINE(HAVE_KRB5, 1,
1171                                 [define if you have Kerberos V])
1172
1173                         if test $ol_with_kerberos = k5only ; then
1174                                 ol_with_kerberos=found
1175                         fi
1176
1177                 elif test $ol_with_kerberos != auto ; then
1178                         AC_MSG_ERROR([Required Kerberos 5 support not available])
1179                 fi
1180
1181         fi
1182 fi
1183
1184 if test $ol_link_krb5 = yes -a \( $ol_with_kerberos = yes -o \
1185         $ol_with_kerberos = auto -o $ol_with_kerberos = k425 \) ; then
1186
1187         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
1188
1189         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
1190                 if test $krb5_impl = mit; then
1191                         AC_CHECK_LIB(krb4, main, [have_k425=yes
1192                                 KRB4_LIBS="-lkrb4 -ldes425"], [have_k425=no],
1193                                 [-ldes425 -lkrb5 -l$krb5crypto -lcom_err])
1194
1195                 elif test $krb5_impl = heimdal; then
1196                         AC_CHECK_LIB(krb4, main, [have_k425=yes
1197                                 KRB4_LIBS="-lkrb4"], [have_k425=no],
1198                                 [-lkrb5 -l$krb5crypto -lasn1 -lroken -lcom_err])
1199
1200                 else
1201                         have_425=no
1202                         AC_MSG_WARN([Unrecongized Kerberos V Implementation])
1203                 fi
1204
1205                 if test $have_k425 = yes ; then
1206                         ol_with_kerberos=found
1207                         ol_link_krb4=yes
1208
1209                         AC_DEFINE(HAVE_KRB425, 1,
1210                                 [define if you have Kerberos V with IV support])
1211                         AC_DEFINE(HAVE_KRB4, 1,
1212                                 [define if you have Kerberos IV])
1213
1214                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
1215                                 [ol_cv_var_des_debug], [
1216                                 dnl save the flags
1217                                 save_LIBS="$LIBS"
1218                                 LIBS="$KRB4_LIBS $KRB5_LIBS $LIBS"
1219                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1220 #include <kerberosIV/krb.h>
1221 #include <kerberosIV/des.h>
1222 extern int des_debug;
1223 ]], [[
1224 des_debug = 1;
1225 ]])],[ol_cv_var_des_debug=yes],[ol_cv_var_des_debug=no])
1226                                 dnl restore the LIBS
1227                                 LIBS="$save_LIBS"
1228                         ])
1229
1230                         if test $ol_cv_var_des_debug = yes ; then
1231                                 AC_DEFINE(HAVE_DES_DEBUG,1,
1232                                         [define if you have Kerberos des_debug])
1233                         fi
1234
1235                         LIBS="$save_LIBS"
1236                 fi
1237         fi
1238 fi
1239
1240 if test $ol_link_krb5 = yes ; then
1241         ol_with_kerberos=found
1242 fi
1243
1244 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
1245         -o $ol_with_kerberos = k4 -o $ol_with_kerberos = kth ; then
1246
1247         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
1248
1249         if test $ac_cv_header_krb_h = yes ; then
1250                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
1251
1252                 if test $have_k4 = yes ; then
1253                         ol_with_kerberos=found
1254                         ol_link_krb4=yes
1255
1256                         AC_DEFINE(HAVE_KRB4, 1,
1257                                 [define if you have Kerberos IV])
1258
1259                         KRB4_LIBS="-lkrb -ldes"
1260
1261                         if test $ac_cv_header_krb_archaeology_h = yes ; then
1262                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
1263                                         [define if you have Kth Kerberos])
1264                         fi
1265                 fi
1266         fi
1267 fi
1268
1269 if test $ol_link_krb4 = yes -a $ol_enable_kbind != no ; then
1270         ol_link_kbind=yes
1271
1272 elif test $ol_enable_kbind = yes ; then
1273         AC_MSG_ERROR([Kerberos IV detection failed])
1274 fi
1275
1276 if test $ol_link_krb4 = yes -o $ol_link_krb5 = yes ; then
1277         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
1278
1279 elif test $ol_with_kerberos != auto -a $ol_with_kerberos != no ; then
1280         AC_MSG_ERROR([Kerberos detection failed])
1281 fi
1282
1283 dnl ----------------------------------------------------------------
1284 dnl TLS/SSL
1285
1286 ol_link_tls=no
1287 if test $ol_with_tls != no ; then
1288         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
1289
1290         if test $ac_cv_header_openssl_ssl_h = yes \
1291                 -o $ac_cv_header_ssl_h = yes ; then
1292                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
1293                         [have_ssleay=yes
1294                         need_rsaref=no],
1295                         [have_ssleay=no],
1296                         [-lcrypto])
1297
1298                 if test $have_ssleay = no ; then
1299                         AC_CHECK_LIB(ssl, SSL_library_init,
1300                                 [have_ssleay=yes
1301                                 need_rsaref=no], [have_ssleay=no],
1302                                 [-lcrypto])
1303                 fi
1304
1305                 if test $have_ssleay = no ; then
1306                         AC_CHECK_LIB(ssl, ssl3_accept,
1307                                 [have_ssleay=yes
1308                                 need_rsaref=yes], [have_ssleay=no],
1309                                 [-lcrypto -lRSAglue -lrsaref])
1310                 fi
1311
1312                 if test $have_ssleay = yes ; then
1313                         ol_with_tls=found
1314                         ol_link_tls=yes
1315
1316                         AC_DEFINE(HAVE_SSLEAY, 1,
1317                                 [define if you have SSLeay or OpenSSL])
1318
1319                         if test $need_rsaref = yes; then
1320                                 AC_DEFINE(HAVE_RSAREF, 1,
1321                                         [define if you have RSAref])
1322
1323                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1324                         else
1325                                 TLS_LIBS="-lssl -lcrypto"
1326                         fi
1327                 fi
1328                 OL_SSL_COMPAT
1329                 if test $ol_cv_ssl_crl_compat = no ; then
1330                         ol_link_ssl=no
1331                 else
1332                         AC_DEFINE(HAVE_OPENSSL_CRL, 1,
1333                                 [define if you have OpenSSL with CRL checking capability])
1334                 fi
1335         fi
1336
1337 else
1338         AC_MSG_WARN([TLS data protection not supported!])
1339 fi
1340
1341 WITH_TLS=no
1342 if test $ol_link_tls = yes ; then
1343         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1344         WITH_TLS=yes
1345
1346 elif test $ol_with_tls = auto ; then
1347         AC_MSG_WARN([Could not locate TLS/SSL package])
1348         AC_MSG_WARN([TLS data protection not supported!])
1349
1350 elif test $ol_with_tls != no ; then
1351         AC_MSG_ERROR([Could not locate TLS/SSL package])
1352 fi
1353
1354 dnl ----------------------------------------------------------------
1355 dnl LAN Manger password checking requires DES from OpenSSL
1356 if test $ol_enable_lmpasswd != no; then
1357         if test $ol_link_tls != yes ; then
1358                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
1359         fi
1360
1361         AC_DEFINE(SLAPD_LMHASH, 1, [define to support LAN Manager passwords])
1362 fi
1363
1364 dnl ----------------------------------------------------------------
1365 dnl Threads?
1366 ol_link_threads=no
1367
1368 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1369         -o $ol_with_threads = nt ; then
1370
1371         OL_NT_THREADS
1372
1373         if test "$ol_cv_nt_threads" = yes ; then
1374                 ol_link_threads=nt
1375                 ol_with_threads=found
1376                 ol_with_yielding_select=yes
1377
1378                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1379                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1380         fi
1381
1382         if test $ol_with_threads = nt ; then
1383                 AC_MSG_ERROR([could not locate NT Threads])
1384         fi
1385 fi
1386
1387 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1388         -o $ol_with_threads = posix ; then
1389
1390         AC_CHECK_HEADERS(pthread.h)
1391
1392         if test $ac_cv_header_pthread_h = yes ; then
1393                 OL_POSIX_THREAD_VERSION
1394
1395                 if test $ol_cv_pthread_version != 0 ; then
1396                         AC_DEFINE_UNQUOTED(HAVE_PTHREADS,$ol_cv_pthread_version,
1397                                 [define to pthreads API spec revision])
1398                 else
1399                         AC_MSG_ERROR([unknown pthread version])
1400                 fi
1401
1402                 # consider threads found
1403                 ol_with_threads=found
1404
1405                 OL_HEADER_LINUX_THREADS
1406                 OL_HEADER_GNU_PTH_PTHREAD_H
1407
1408                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1409                         AC_CHECK_HEADERS(sched.h)
1410                 fi
1411
1412                 dnl Now the hard part, how to link?
1413                 dnl
1414                 dnl currently supported checks:
1415                 dnl
1416                 dnl Check for no flags
1417                 dnl     pthread_create() in $LIBS
1418                 dnl
1419                 dnl Check special pthread (final) flags
1420                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1421                 dnl     pthread_create() with -kthread (FreeBSD)
1422                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1423                 dnl     pthread_create() with -pthreads (?)
1424                 dnl     pthread_create() with -mthreads (AIX)
1425                 dnl     pthread_create() with -thread (?)
1426                 dnl
1427                 dnl Check pthread (final) libraries
1428                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1429                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1430                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1431                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1432                 dnl     pthread_create() in -lpthread (many)
1433                 dnl     pthread_create() in -lc_r (FreeBSD)
1434                 dnl
1435                 dnl Check pthread (draft4) flags (depreciated)
1436                 dnl     pthread_create() with -threads (OSF/1)
1437                 dnl
1438                 dnl Check pthread (draft4) libraries (depreciated)
1439                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1440                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1441                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1442                 dnl     pthread_create() in -lpthreads (many)
1443                 dnl
1444
1445                 dnl pthread_create in $LIBS
1446                 AC_CACHE_CHECK([for pthread_create in default libraries],
1447                         ol_cv_pthread_create,[
1448                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1449                                 [ol_cv_pthread_create=yes],
1450                                 [ol_cv_pthread_create=no],
1451                                 [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1452                                         [ol_cv_pthread_create=yes],
1453                                         [ol_cv_pthread_create=no])])])
1454
1455                 if test $ol_cv_pthread_create != no ; then
1456                         ol_link_threads=posix
1457                         ol_link_pthreads=""
1458                 fi
1459
1460 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1461                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1462                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1463                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1464                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1465                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1466
1467                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1468                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1469                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1470                         [ol_cv_pthread_lpthread_lmach_lexc])
1471 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1472 dnl                     [ol_cv_pthread_lpthread_lexc])
1473
1474                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1475                         [ol_cv_pthread_lib_lpthread_woff])
1476
1477                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1478                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1479
1480                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1481
1482                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1483                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1484                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1485                         [ol_cv_pthread_lpthreads_lmach_lexc])
1486                 OL_PTHREAD_TRY([-lpthreads -lexc],
1487                         [ol_cv_pthread_lpthreads_lexc])
1488
1489                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1490
1491                 if test $ol_link_threads != no ; then
1492                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1493
1494                         dnl save flags
1495                         save_CPPFLAGS="$CPPFLAGS"
1496                         save_LIBS="$LIBS"
1497                         LIBS="$LTHREAD_LIBS $LIBS"
1498
1499                         dnl All POSIX Thread (final) implementations should have
1500                         dnl sched_yield instead of pthread yield.
1501                         dnl check for both, and thr_yield for Solaris
1502                         AC_CHECK_FUNCS(sched_yield pthread_yield thr_yield)
1503
1504                         if test $ac_cv_func_sched_yield = no -a \
1505                                 $ac_cv_func_pthread_yield = no -a \
1506                                 $ac_cv_func_thr_yield = no ; then
1507                                 dnl Digital UNIX has sched_yield() in -lrt
1508                                 AC_CHECK_LIB(rt, sched_yield,
1509                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1510                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1511                                                 [Define if you have the sched_yield function.])
1512                                         ac_cv_func_sched_yield=yes],
1513                                         [ac_cv_func_sched_yield=no])
1514                         fi
1515                         if test $ac_cv_func_sched_yield = no -a \
1516                                 $ac_cv_func_pthread_yield = no -a \
1517                                 "$ac_cv_func_thr_yield" = no ; then
1518                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1519                         fi
1520
1521                         dnl Check functions for compatibility
1522                         AC_CHECK_FUNCS(pthread_kill pthread_rwlock_destroy)
1523
1524                         dnl Check for pthread_detach with <pthread.h> inclusion
1525                         dnl as it's symbol may have been mangled.
1526                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1527                                 [ol_cv_func_pthread_detach], [
1528                                 dnl save the flags
1529                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1530 #include <pthread.h>
1531 #ifndef NULL
1532 #define NULL (void*)0
1533 #endif
1534 ]], [[pthread_detach(NULL);]])],[ol_cv_func_pthread_detach=yes],[ol_cv_func_pthread_detach=no])
1535                         ])
1536
1537                         if test $ol_cv_func_pthread_detach = no ; then
1538                                 AC_MSG_ERROR([could not locate pthread_detach()])
1539                         fi
1540
1541                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1542                                 [define if you have pthread_detach function])
1543
1544                         dnl Check for setconcurreny functions
1545                         AC_CHECK_FUNCS( \
1546                                 pthread_setconcurrency \
1547                                 pthread_getconcurrency \
1548                                 thr_setconcurrency \
1549                                 thr_getconcurrency \
1550                         )
1551
1552                         OL_SYS_LINUX_THREADS
1553                         OL_LINUX_THREADS
1554
1555                         if test $ol_cv_linux_threads = error; then
1556                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1557                         fi
1558
1559                         AC_CACHE_CHECK([if pthread_create() works],
1560                                 ol_cv_pthread_create_works,[
1561                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1562                                 [ol_cv_pthread_create_works=yes],
1563                                 [ol_cv_pthread_create_works=no],
1564                                 [dnl assume yes
1565                                 ol_cv_pthread_create_works=yes])])
1566
1567                         if test $ol_cv_pthread_create_works = no ; then
1568                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1569                         fi
1570
1571                         dnl Check if select causes an yield
1572                         if test $ol_with_yielding_select = auto ; then
1573                                 AC_CACHE_CHECK([if select yields when using pthreads],
1574                                         ol_cv_pthread_select_yields,[
1575                                 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1576 #include <sys/types.h>
1577 #include <sys/time.h>
1578 #include <unistd.h>
1579 #include <pthread.h>
1580 #ifndef NULL
1581 #define NULL (void*) 0
1582 #endif
1583
1584 static int fildes[2];
1585
1586 static void *task(p)
1587         void *p;
1588 {
1589         int i;
1590         struct timeval tv;
1591
1592         fd_set rfds;
1593
1594         tv.tv_sec=10;
1595         tv.tv_usec=0;
1596
1597         FD_ZERO(&rfds);
1598         FD_SET(fildes[0], &rfds);
1599
1600         /* we're not interested in any fds */
1601         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1602
1603         if(i < 0) {
1604                 perror("select");
1605                 exit(10);
1606         }
1607
1608         exit(0); /* if we exit here, the select blocked the whole process */
1609 }
1610
1611 int main(argc, argv)
1612         int argc;
1613         char **argv;
1614 {
1615         pthread_t t;
1616
1617         /* create a pipe to select */
1618         if(pipe(&fildes[0])) {
1619                 perror("select");
1620                 exit(1);
1621         }
1622
1623 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1624         (void) pthread_setconcurrency(2);
1625 #else
1626 #ifdef HAVE_THR_SETCONCURRENCY
1627         /* Set Solaris LWP concurrency to 2 */
1628         thr_setconcurrency(2);
1629 #endif
1630 #endif
1631
1632 #if HAVE_PTHREADS < 6
1633         pthread_create(&t, pthread_attr_default, task, NULL);
1634 #else
1635         pthread_create(&t, NULL, task, NULL);
1636 #endif
1637
1638         /* make sure task runs first */
1639 #if HAVE_THR_YIELD
1640         thr_yield();
1641 #elif defined( HAVE_SCHED_YIELD )
1642         sched_yield();
1643 #elif defined( HAVE_PTHREAD_YIELD )
1644         pthread_yield();
1645 #endif
1646
1647         exit(2);
1648 }]])],[ol_cv_pthread_select_yields=no],[ol_cv_pthread_select_yields=yes],[ol_cv_pthread_select_yields=cross])])
1649
1650                                 if test $ol_cv_pthread_select_yields = cross ; then
1651                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1652                                 fi
1653
1654                                 if test $ol_cv_pthread_select_yields = yes ; then
1655                                         ol_with_yielding_select=yes
1656                                 fi
1657                         fi
1658
1659                         dnl restore flags
1660                         CPPFLAGS="$save_CPPFLAGS"
1661                         LIBS="$save_LIBS"
1662                 else
1663                         AC_MSG_ERROR([could not locate usable POSIX Threads])
1664                 fi
1665         fi
1666
1667         if test $ol_with_threads = posix ; then
1668                 AC_MSG_ERROR([could not locate POSIX Threads])
1669         fi
1670 fi
1671
1672 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1673         -o $ol_with_threads = mach ; then
1674
1675         dnl check for Mach CThreads
1676         AC_CHECK_HEADERS(mach/cthreads.h cthreads.h)
1677         if test $ac_cv_header_mach_cthreads_h = yes ; then
1678                 ol_with_threads=found
1679
1680                 dnl check for cthreads support in current $LIBS
1681                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1682
1683                 if test $ol_link_threads = no ; then
1684                         dnl try -all_load
1685                         dnl this test needs work
1686                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1687                                 [ol_cv_cthread_all_load], [
1688                                 dnl save the flags
1689                                 save_LIBS="$LIBS"
1690                                 LIBS="-all_load $LIBS"
1691                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <mach/cthreads.h>]], [[
1692                                         cthread_fork((void *)0, (void *)0);
1693                                         ]])],[ol_cv_cthread_all_load=yes],[ol_cv_cthread_all_load=no])
1694                                 dnl restore the LIBS
1695                                 LIBS="$save_LIBS"
1696                         ])
1697
1698                         if test $ol_cv_cthread_all_load = yes ; then
1699                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1700                                 ol_link_threads=mach
1701                                 ol_with_threads=found
1702                         fi
1703                 fi
1704
1705         elif test $ac_cv_header_cthreads_h = yes ; then
1706                 dnl Hurd variant of Mach Cthreads
1707                 dnl uses <cthreads.h> and -lthreads
1708
1709                 ol_with_threads=found
1710
1711                 dnl save the flags
1712                 save_LIBS="$LIBS"
1713                 LIBS="$LIBS -lthreads"
1714                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1715                 LIBS="$save_LIBS"
1716
1717                 if test $ol_link_threads = yes ; then
1718                         LTHREAD_LIBS="-lthreads"
1719                         ol_link_threads=mach
1720                         ol_with_threads=found
1721                 else
1722                         AC_MSG_ERROR([could not link with Mach CThreads])
1723                 fi
1724
1725         elif test $ol_with_threads = mach ; then
1726                 AC_MSG_ERROR([could not locate Mach CThreads])
1727         fi
1728
1729         if test $ol_link_threads = mach ; then
1730                 AC_DEFINE(HAVE_MACH_CTHREADS,1,
1731                         [define if you have Mach Cthreads])
1732         elif test $ol_with_threads = found ; then
1733                 AC_MSG_ERROR([could not link with Mach CThreads])
1734         fi
1735 fi
1736
1737 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1738         -o $ol_with_threads = pth ; then
1739
1740         AC_CHECK_HEADERS(pth.h)
1741
1742         if test $ac_cv_header_pth_h = yes ; then
1743                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1744
1745                 if test $have_pth = yes ; then
1746                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1747                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1748                         ol_link_threads=pth
1749                         ol_with_threads=found
1750
1751                         if test $ol_with_yielding_select = auto ; then
1752                                 ol_with_yielding_select=yes
1753                         fi
1754                 fi
1755         fi
1756 fi
1757
1758 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1759         -o $ol_with_threads = lwp ; then
1760
1761         dnl check for SunOS5 LWP
1762         AC_CHECK_HEADERS(thread.h synch.h)
1763         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1764                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1765
1766                 if test $have_thr = yes ; then
1767                         AC_DEFINE(HAVE_THR,1,
1768                                 [if you have Solaris LWP (thr) package])
1769                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1770                         ol_link_threads=thr
1771
1772                         if test $ol_with_yielding_select = auto ; then
1773                                 ol_with_yielding_select=yes
1774                         fi
1775
1776                         dnl Check for setconcurreny functions
1777                         AC_CHECK_FUNCS( \
1778                                 thr_setconcurrency \
1779                                 thr_getconcurrency \
1780                         )
1781                 fi
1782         fi
1783
1784         dnl check for SunOS4 LWP
1785         AC_CHECK_HEADERS(lwp/lwp.h)
1786         if test $ac_cv_header_lwp_lwp_h = yes ; then
1787                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1788
1789                 if test $have_lwp = yes ; then
1790                         AC_DEFINE(HAVE_LWP,1,
1791                                 [if you have SunOS LWP package])
1792                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1793                         ol_link_threads=lwp
1794
1795                         if test $ol_with_yielding_select = auto ; then
1796                                 ol_with_yielding_select=no
1797                         fi
1798                 fi
1799         fi
1800 fi
1801
1802 if test $ol_with_yielding_select = yes ; then
1803         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1804                 [define if select implicitly yields])
1805 fi
1806
1807 if test $ol_with_threads = manual ; then
1808         dnl User thinks he can manually configure threads.
1809         ol_link_threads=yes
1810
1811         AC_MSG_WARN([thread defines and link options must be set manually])
1812
1813         AC_CHECK_HEADERS(pthread.h sched.h)
1814         AC_CHECK_FUNCS(sched_yield pthread_yield)
1815         OL_HEADER_LINUX_THREADS
1816
1817         AC_CHECK_HEADERS(mach/cthreads.h)
1818         AC_CHECK_HEADERS(lwp/lwp.h)
1819         AC_CHECK_HEADERS(thread.h synch.h)
1820 fi
1821
1822 if test $ol_link_threads != no -a $ol_link_threads != nt ; then
1823         dnl needed to get reentrant/threadsafe versions
1824         dnl
1825         AC_DEFINE(REENTRANT,1)
1826         AC_DEFINE(_REENTRANT,1)
1827         AC_DEFINE(THREAD_SAFE,1)
1828         AC_DEFINE(_THREAD_SAFE,1)
1829         AC_DEFINE(THREADSAFE,1)
1830         AC_DEFINE(_THREADSAFE,1)
1831         AC_DEFINE(_SGI_MP_SOURCE,1)
1832
1833         dnl The errno declaration may dependent upon _REENTRANT.
1834         dnl If it does, we must link with thread support.
1835         AC_CACHE_CHECK([for thread specific errno],
1836                 [ol_cv_errno_thread_specific], [
1837                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[errno = 0;]])],[ol_cv_errno_thread_specific=yes],[ol_cv_errno_thread_specific=no])
1838         ])
1839
1840         dnl The h_errno declaration may dependent upon _REENTRANT.
1841         dnl If it does, we must link with thread support.
1842         AC_CACHE_CHECK([for thread specific h_errno],
1843                 [ol_cv_h_errno_thread_specific], [
1844                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[h_errno = 0;]])],[ol_cv_h_errno_thread_specific=yes],[ol_cv_h_errno_thread_specific=no])
1845         ])
1846
1847         if test $ol_cv_errno_thread_specific != yes \
1848                 -o $ol_cv_h_errno_thread_specific != yes ; then
1849                 LIBS="$LTHREAD_LIBS $LIBS"
1850                 LTHREAD_LIBS=""
1851         fi
1852
1853 dnl When in thread environment, use
1854 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) || defined( HAVE_FUNC_R )
1855 dnl                     func_r(...);
1856 dnl             #else
1857 dnl             #       if defined( HAVE_THREADS )
1858 dnl                             /* lock */
1859 dnl             #       endif
1860 dnl                             func(...);
1861 dnl             #       if defined( HAVE_THREADS )
1862 dnl                             /* unlock */
1863 dnl             #       endif
1864 dnl             #endif
1865 dnl
1866 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1867 dnl             _POSIX_REENTRANT_FUNCTIONS
1868 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1869 dnl             _POSIX_THREADSAFE_FUNCTIONS
1870 dnl
1871 dnl             and is currently defined in <ldap_pvt_thread.h>
1872 dnl
1873 dnl HAVE_THREADS is defined by <ldap_pvt_thread.h> iff -UNO_THREADS
1874 dnl
1875 dnl libldap/*.c should only include <ldap_pvt_thread.h> iff
1876 dnl LDAP_R_COMPILE is defined.  ie:
1877 dnl             #ifdef LDAP_R_COMPILE
1878 dnl             #       include <ldap_pvt_thread.h>
1879 dnl             #endif
1880 dnl
1881 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1882 dnl specifically for compiling the threadsafe version of
1883 dnl     the ldap library (-lldap_r).
1884 dnl
1885 dnl     dnl check for reentrant/threadsafe functions
1886 dnl     dnl
1887 dnl     dnl note: these should only be used when linking
1888 dnl     dnl             with $LTHREAD_LIBS
1889 dnl     dnl
1890 dnl     save_CPPFLAGS="$CPPFLAGS"
1891 dnl     save_LIBS="$LIBS"
1892 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1893 dnl     AC_CHECK_FUNCS( \
1894 dnl             gmtime_r \
1895 dnl             gethostbyaddr_r gethostbyname_r \
1896 dnl             feof_unlocked unlocked_feof \
1897 dnl             putc_unlocked unlocked_putc \
1898 dnl             flockfile ftrylockfile \
1899 dnl     )
1900 dnl     CPPFLAGS="$save_CPPFLAGS"
1901 dnl     LIBS="$save_LIBS"
1902 fi
1903
1904 if test $ol_link_threads = no ; then
1905         if test $ol_with_threads = yes ; then
1906                 AC_MSG_ERROR([no suitable thread support])
1907         fi
1908
1909         if test $ol_with_threads = auto ; then
1910                 AC_MSG_WARN([no suitable thread support, disabling threads])
1911                 ol_with_threads=no
1912         fi
1913
1914         AC_DEFINE(NO_THREADS,1,
1915                 [define if you have (or want) no threads])
1916         LTHREAD_LIBS=""
1917 fi
1918
1919 if test $ol_link_threads != no ; then
1920         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1,
1921                 [define to 1 if library is thread safe])
1922 fi
1923
1924 dnl ----------------------------------------------------------------
1925 dnl Tests for reentrant functions necessary to build -lldap_r
1926 AC_CHECK_FUNCS(         \
1927         ctime_r                 \
1928         gethostbyname_r gethostbyaddr_r \
1929 )
1930
1931 if test "$ac_cv_func_ctime_r" = no ; then
1932         ol_cv_func_ctime_r_nargs=0
1933 else
1934         OL_FUNC_CTIME_R_NARGS
1935 dnl     OL_FUNC_CTIME_R_TYPE
1936 fi
1937
1938 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1939         OL_FUNC_GETHOSTBYNAME_R_NARGS
1940 else
1941         ol_cv_func_gethostbyname_r_nargs=0
1942 fi
1943
1944 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1945         OL_FUNC_GETHOSTBYADDR_R_NARGS
1946 else
1947         ol_cv_func_gethostbyaddr_r_nargs=0
1948 fi
1949
1950 dnl ----------------------------------------------------------------
1951 ol_link_ldbm=no
1952
1953 if test $ol_enable_ldbm_api = auto \
1954         -o $ol_enable_ldbm_api = berkeley \
1955         -o $ol_enable_ldbm_api = bcompat ; then
1956
1957         if test $ol_enable_ldbm_api = bcompat; then \
1958                 OL_BERKELEY_COMPAT_DB
1959         else
1960                 OL_BERKELEY_DB
1961         fi
1962
1963         if test $ol_cv_berkeley_db != no ; then
1964                 AC_DEFINE(HAVE_BERKELEY_DB,1,
1965                         [define this if Berkeley DB is available])
1966
1967                 ol_link_ldbm=berkeley
1968                 ol_enable_ldbm_api=berkeley
1969
1970                 if test $ol_enable_ldbm_type = hash ; then
1971                         AC_DEFINE(LDBM_USE_DBHASH,1,
1972                                 [define this to use DBHASH w/ LDBM backend])
1973                 else
1974                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1975                                 [define this to use DBBTREE w/ LDBM backend])
1976                 fi
1977
1978                 dnl $ol_cv_lib_db should be yes or -ldb
1979                 dnl (it could be no, but that would be an error
1980                 if test $ol_cv_lib_db != yes ; then
1981                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1982                 fi
1983         fi
1984 fi
1985
1986 if test $ol_enable_bdb != no -o $ol_enable_hdb != no; then
1987         if test $ol_link_ldbm != berkeley ; then
1988                 AC_MSG_ERROR(BDB/HDB: BerkeleyDB not available)
1989         else
1990                 OL_BDB_COMPAT
1991
1992                 if test $ol_cv_bdb_compat != yes ; then
1993                         AC_MSG_ERROR([BDB/HDB: BerkeleyDB version incompatible])
1994                 fi
1995         fi
1996 fi
1997
1998 if test $ol_link_ldbm = no -a $ol_enable_ldbm_type = btree ; then
1999         AC_MSG_WARN([Could not find LDBM with BTREE support])
2000         ol_enable_ldbm_api=none
2001 fi
2002
2003 if test $ol_enable_ldbm_api = auto -o $ol_enable_ldbm_api = mdbm ; then
2004         OL_MDBM
2005
2006         if test $ol_cv_mdbm = yes ; then
2007                 ol_link_ldbm=mdbm
2008                 ol_enable_ldbm_api=mdbm
2009                 if test $ol_cv_lib_mdbm != yes ; then
2010                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
2011                 fi
2012         fi
2013 fi
2014
2015 if test $ol_enable_ldbm_api = auto -o $ol_enable_ldbm_api = gdbm ; then
2016         OL_GDBM
2017
2018         if test $ol_cv_gdbm = yes ; then
2019                 ol_link_ldbm=gdbm
2020                 ol_enable_ldbm_api=gdbm
2021
2022                 if test $ol_cv_lib_gdbm != yes ; then
2023                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
2024                 fi
2025         fi
2026 fi
2027
2028 if test $ol_enable_ldbm_api = ndbm ; then
2029         OL_NDBM
2030
2031         if test $ol_cv_ndbm = yes ; then
2032                 ol_link_ldbm=ndbm
2033                 ol_enable_ldbm_api=ndbm
2034
2035                 if test $ol_cv_lib_ndbm != yes ; then
2036                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
2037                 fi
2038         fi
2039 fi
2040
2041 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
2042         AC_MSG_ERROR([could not find suitable LDBM backend])
2043 fi
2044
2045 if test $ol_enable_bdb = yes -o \
2046         $ol_enable_hdb = yes -o \
2047         $ol_enable_ldbm = yes ; then
2048         SLAPD_LIBS="$SLAPD_LIBS \$(LDBM_LIBS)"
2049 fi
2050
2051 dnl ----------------------------------------------------------------
2052
2053 if test $ol_enable_dynamic = yes -a $enable_shared = yes ; then
2054         BUILD_LIBS_DYNAMIC=shared
2055         AC_DEFINE(LDAP_LIBS_DYNAMIC, 1, [define if LDAP libs are dynamic])
2056         LTSTATIC=""
2057 else
2058         BUILD_LIBS_DYNAMIC=static
2059         LTSTATIC="-static"
2060 fi
2061 AC_SUBST(LTSTATIC)dnl
2062
2063 dnl ----------------------------------------------------------------
2064 if test $ol_enable_wrappers != no ; then
2065         AC_CHECK_HEADERS(tcpd.h,[
2066                 AC_MSG_CHECKING([for TCP wrappers library])
2067                 save_LIBS="$LIBS"
2068                 LIBS="$LIBS -lwrap"
2069                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2070 #include <tcpd.h>
2071 int allow_severity = 0;
2072 int deny_severity  = 0;
2073
2074 struct request_info *req;
2075                 ]], [[
2076 hosts_access(req)
2077                 ]])],[AC_MSG_RESULT([-lwrap])
2078                 have_wrappers=yes
2079                 LIBS="$save_LIBS"],[
2080                 dnl try with -lnsl
2081                 LIBS="$LIBS -lnsl"
2082                 AC_TRY_LINK([
2083 #include <tcpd.h>
2084 int allow_severity = 0;
2085 int deny_severity  = 0;
2086
2087 struct request_info *req;
2088                 ],[
2089 hosts_access(req)
2090                 ],[AC_MSG_RESULT([-lwrap -lnsl])
2091                 have_wrappers=yes
2092                 LIBS="$save_LIBS -lnsl"],[
2093                 AC_MSG_RESULT(no)
2094                 have_wrappers=no
2095                 LIBS=$save_LIBS])])],[have_wrappers=no])
2096
2097         if test $have_wrappers = yes ; then
2098                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
2099                 WRAP_LIBS="-lwrap"
2100         elif test $ol_enable_wrappers = yes ; then
2101                 AC_MSG_ERROR([could not find TCP wrappers, select apppropriate options or disable])
2102         else
2103                 AC_MSG_WARN([could not find TCP wrappers, support disabled])
2104                 WRAP_LIBS=""
2105         fi
2106 fi
2107
2108 dnl ----------------------------------------------------------------
2109 if test $ol_enable_syslog != no ; then
2110         AC_CHECK_FUNC(openlog)
2111         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
2112                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
2113         fi
2114         ol_enable_syslog=$ac_cv_func_openlog
2115 fi
2116
2117 dnl ----------------------------------------------------------------
2118 dnl SQL
2119 ol_link_sql=no
2120 if test $ol_enable_sql != no ; then
2121         AC_CHECK_HEADERS(sql.h sqlext.h,[],[
2122                 AC_MSG_ERROR([could not locate SQL headers])
2123         ])
2124
2125         sql_LIBS="$LIBS"
2126         LIBS="$LTHREAD_LIBS"
2127
2128         AC_CHECK_LIB(iodbc,SQLDriverConnect,[have_iodbc=yes],[have_iodbc=no])
2129         if test $have_iodbc = yes ; then
2130                 ol_link_sql="-liodbc"
2131         else
2132                 AC_CHECK_LIB(odbc,SQLDriverConnect,[have_odbc=yes],[have_odbc=no])
2133                 if test $have_odbc = yes ; then
2134                         ol_link_sql="-lodbc"
2135                 fi
2136         fi
2137
2138         LIBS="$sql_LIBS"
2139
2140         if test $ol_link_sql != no ; then
2141                 SLAPD_SQL_LIBS="$ol_link_sql"
2142
2143         elif test $ol_enable_sql != auto ; then
2144                 AC_MSG_ERROR([could not locate suitable ODBC library])
2145         fi
2146 fi
2147
2148 dnl ----------------------------------------------------------------
2149 dnl
2150 dnl Check for Cyrus SASL
2151 dnl
2152 WITH_SASL=no
2153 ol_link_sasl=no
2154 ol_link_spasswd=no
2155 if test $ol_with_cyrus_sasl != no ; then
2156         AC_CHECK_HEADERS(sasl/sasl.h sasl.h)
2157
2158         if test $ac_cv_header_sasl_sasl_h = yes -o $ac_cv_header_sasl_h = yes; then
2159                 AC_CHECK_LIB(sasl2, sasl_client_init,
2160                         [ol_link_sasl="-lsasl2"],
2161                         [AC_CHECK_LIB(sasl, sasl_client_init,
2162                                 [ol_link_sasl="-lsasl"])])
2163         fi
2164
2165         if test $ol_link_sasl = no ; then
2166                 if test $ol_with_cyrus_sasl != auto ; then
2167                         AC_MSG_ERROR([Could not locate Cyrus SASL])
2168                 else
2169                         AC_MSG_WARN([Could not locate Cyrus SASL])
2170                         AC_MSG_WARN([SASL authentication not supported!])
2171                         if test $ol_link_tls = no ; then
2172                                 AC_MSG_WARN([Strong authentication not supported!])
2173                         fi
2174                 fi
2175         else
2176                 OL_SASL_COMPAT
2177                 if test $ol_cv_sasl_compat = no ; then
2178                         ol_link_sasl=no
2179                         AC_MSG_ERROR([Cyrus SASL library located but is incompatible])
2180                 fi
2181
2182                 AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
2183                 SASL_LIBS="$ol_link_sasl"
2184                 if test $ol_enable_spasswd != no ; then
2185                         ol_link_spasswd=yes
2186                 fi
2187
2188                 ac_save_LIBS="$LIBS"
2189                 LIBS="$LIBS $ol_link_sasl"
2190                 AC_CHECK_FUNC(sasl_version, [AC_DEFINE(HAVE_SASL_VERSION,1,
2191                         [define if your SASL library has sasl_version()])])
2192                 LIBS="$ac_save_LIBS"
2193
2194                 WITH_SASL=yes
2195         fi
2196
2197 else
2198         AC_MSG_WARN([SASL authentication not supported!])
2199         if test $ol_link_tls = no ; then
2200                 AC_MSG_WARN([Strong authentication not supported!])
2201         fi
2202 fi
2203
2204 dnl ----------------------------------------------------------------
2205 dnl Check for entropy sources
2206 if test $cross_compiling != yes -a "$ac_cv_mingw32" != yes ; then
2207         dev=no
2208         if test -r /dev/urandom ; then
2209                 dev="/dev/urandom";
2210         elif test -r /idev/urandom ; then
2211                 dev="/idev/urandom";
2212         elif test -r /dev/srandom ; then
2213                 dev="/dev/srandom";
2214         elif test -r /dev/random ; then
2215                 dev="/dev/random";
2216         elif test -r /idev/random ; then
2217                 dev="/idev/random";
2218         fi
2219
2220         if test $dev != no ; then
2221                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
2222         fi
2223 fi
2224
2225 dnl ----------------------------------------------------------------
2226 dnl
2227 dnl Check for fetch URL support
2228 dnl             should be extended to support other fetch URL APIs
2229 dnl
2230 ol_link_fetch=no
2231 if test $ol_with_fetch != no ; then
2232         OL_LIB_FETCH
2233
2234         if test $ol_cv_lib_fetch != no ; then
2235                 LUTIL_LIBS="$LUTIL_LIBS $ol_link_fetch"
2236                 ol_link_fetch=freebsd
2237
2238         elif test $ol_with_fetch != auto ; then
2239                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
2240         fi
2241 fi
2242
2243 dnl ----------------------------------------------------------------
2244 dnl FreeBSD (and others) have crypt(3) in -lcrypt
2245 if test $ol_enable_crypt != no ; then
2246         save_LIBS="$LIBS"
2247         LIBS="$TLS_LIBS $LIBS"
2248
2249         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
2250                 LIBS="$save_LIBS"
2251                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
2252                         have_crypt=yes], [have_crypt=no])])
2253
2254         LIBS="$save_LIBS"
2255
2256         if test $have_crypt = yes ; then
2257                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
2258         else
2259                 AC_MSG_WARN([could not find crypt])
2260                 if test $ol_enable_crypt = yes ; then
2261                         AC_MSG_ERROR([could not find crypt, select appropriate options or disable])
2262                 fi
2263
2264                 AC_MSG_WARN([disabling crypt support])
2265                 ol_enable_crypt=no
2266         fi
2267 fi
2268
2269 dnl ----------------------------------------------------------------
2270 dnl FreeBSD (and others) have setproctitle(3) in -lutil
2271 if test $ol_enable_proctitle != no ; then
2272         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
2273                 AC_CHECK_LIB(util, setproctitle,
2274                         [have_setproctitle=yes
2275                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
2276                         [have_setproctitle=no
2277                         AC_LIBOBJ(setproctitle)
2278                         LIBSRCS="$LIBSRCS setproctitle.c"])])
2279
2280         if test $have_setproctitle = yes ; then
2281                 AC_DEFINE(HAVE_SETPROCTITLE,1,
2282                         [define if setproctitle(3) is available])
2283         fi
2284 fi
2285
2286 dnl ----------------------------------------------------------------
2287 dnl Check for SLPv2 Compliant API Library
2288 if test $ol_enable_slp != no ; then
2289         AC_CHECK_HEADERS( slp.h )
2290
2291         if test $ac_cv_header_slp_h = yes ; then
2292                 AC_CHECK_LIB(slp, SLPOpen, [have_slp=yes], [have_slp=no])
2293                 if test $have_slp = yes ; then
2294                         AC_DEFINE(HAVE_SLP, 1, [define if you have -lslp])
2295                         SLAPD_SLP_LIBS=-lslp
2296                 fi
2297
2298         elif test $ol_enable_slp = yes ; then
2299                 AC_MSG_ERROR([SLP not found])
2300         fi
2301 fi
2302
2303 dnl ----------------------------------------------------------------
2304 dnl Check for multiple precision support
2305 if test "$ol_with_multiple_precision" != "no" ; then
2306         ol_have_bignum=no
2307         ol_have_gmp=no
2308
2309         AC_CHECK_HEADERS(openssl/bn.h bn.h)
2310         AC_CHECK_HEADERS(openssl/crypto.h crypto.h)
2311         AC_CHECK_HEADERS( gmp.h )
2312
2313         if test "$ol_with_tls" = "found" ; then
2314                 ol_have_bn_h=no
2315                 ol_have_crypto_h=no
2316
2317                 if test "$ac_cv_header_openssl_bn_h" = "yes" \
2318                                 -o "$ac_cv_header_bn_h" = "yes" ; then
2319                         ol_have_bn_h=yes
2320                 fi
2321
2322                 if test "$ac_cv_header_openssl_crypto_h" = "yes" \
2323                                 -o "$ac_cv_header_crypto_h" = "yes" ; then
2324                         ol_have_crypto_h=yes
2325                 fi
2326
2327                 if test "$ol_have_bn_h" = "yes" \
2328                                 -a "$ol_have_crypto_h" = "yes" ; then
2329                         ol_have_bignum=yes
2330                 fi
2331         fi
2332
2333         if test $ac_cv_header_gmp_h = yes ; then
2334                 AC_CHECK_LIB(gmp, __gmpz_add_ui, [have_gmp=yes], [have_gmp=no])
2335                 if test $have_gmp = yes ; then
2336                         ol_have_gmp=yes
2337                 fi
2338         fi
2339
2340         AC_MSG_CHECKING([for multiple precision support])
2341
2342         ol_mp_support="none"
2343         case "$ol_with_multiple_precision" in
2344         auto)
2345                 dnl preferred sequence:
2346                 dnl - OpenSSL's BIGNUM (if libssl is already linked)
2347                 dnl - GNU's MP
2348                 dnl - unsigned long
2349                 if test "$ol_have_bignum" = "yes" ; then
2350                         ol_mp_support="bignum"
2351                 else
2352                         if test "$ol_have_gmp" = "yes" ; then
2353                                 ol_mp_support="gmp"
2354                         fi
2355                 fi
2356                 ;;
2357         bignum)
2358                 if test "$ol_have_bignum" != "yes" ; then
2359                         AC_MSG_ERROR([OpenSSL's BIGNUM not available])
2360                 fi
2361                 ol_mp_support="bignum"
2362                 ;;
2363         gmp)
2364                 if test "$ol_have_gmp" != "yes" ; then
2365                         AC_MSG_ERROR([GMP not available])
2366                 fi
2367                 ol_mp_support="gmp"
2368                 ;;
2369         yes)
2370                 if test "$ol_have_bignum" = "yes" ; then
2371                         ol_mp_support="bignum"
2372                 elif test "$ol_have_gmp" = "yes" ; then
2373                         ol_mp_support="gmp"
2374                 else
2375                         AC_MSG_ERROR([not available])
2376                 fi
2377                 ;;
2378         esac
2379
2380         case "$ol_mp_support" in
2381         bignum)
2382                 AC_DEFINE(HAVE_BIGNUM, 1,
2383                         [define if you have SSLeay or OpenSSL's BIGNUM])
2384                 ;;
2385         gmp)
2386                 AC_DEFINE(HAVE_GMP, 1, [define if you have -lgmp])
2387                 SLAPD_GMP_LIBS=-lgmp
2388                 ;;
2389         none)
2390                 ;;
2391         esac
2392
2393         AC_MSG_RESULT($ol_mp_support)
2394 fi
2395
2396 dnl ----------------------------------------------------------------
2397 dnl Checks for typedefs, structures, and compiler characteristics.
2398
2399 AC_CHECK_TYPE(mode_t, int)
2400 AC_CHECK_TYPE(off_t, long)
2401 AC_CHECK_TYPE(pid_t, int)
2402 AC_CHECK_TYPE(ssize_t, [signed int])
2403 AC_CHECK_TYPE(caddr_t,  [char *])
2404 AC_CHECK_TYPE(size_t, unsigned)
2405
2406 AC_CHECK_TYPES([long long])
2407 AC_CHECK_TYPES([ptrdiff_t])
2408
2409 AC_CHECK_TYPE([socklen_t],,
2410         [AC_DEFINE_UNQUOTED([socklen_t], [int],
2411                 [Define to `int' if <sys/socket.h> does not define.])],
2412         [$ac_includes_default
2413 #ifdef HAVE_SYS_SOCKET_H
2414 #include <sys/socket.h>
2415 #endif
2416         ])
2417
2418 AC_TYPE_SIGNAL
2419
2420 AC_CHECK_TYPE([sig_atomic_t],,
2421         [AC_DEFINE_UNQUOTED([sig_atomic_t], [int],
2422                 [Define to `int' if <signal.h> does not define.])],
2423         [$ac_includes_default
2424 #include <signal.h>
2425         ])
2426
2427 AC_TYPE_UID_T
2428
2429 AC_HEADER_TIME
2430 AC_STRUCT_TM
2431 AC_CHECK_MEMBERS([struct stat.st_blksize])
2432 AC_CHECK_MEMBERS([struct passwd.pw_gecos],,,[$ac_includes_default
2433 #include <pwd.h>])
2434 AC_CHECK_MEMBERS([struct passwd.pw_passwd],,,[$ac_includes_default
2435 #include <pwd.h>])
2436
2437 OL_C_UPPER_LOWER
2438 AC_C_CONST
2439 OL_C_VOLATILE
2440
2441 if test $cross_compiling = yes ; then
2442         AC_MSG_WARN([Crossing compiling... all bets are off!])
2443         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2444 else
2445         AC_C_BIGENDIAN
2446 fi
2447
2448 AC_CHECK_SIZEOF(short)
2449 AC_CHECK_SIZEOF(int)
2450 AC_CHECK_SIZEOF(long)
2451 AC_CHECK_SIZEOF(wchar_t)
2452
2453 if test "$ac_cv_sizeof_int" -lt 4 ; then
2454         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2455
2456         AC_DEFINE(LBER_INT_T,long,[define to 32-bit or greater integer type])
2457 else
2458         AC_DEFINE(LBER_INT_T,int,[define to 32-bit or greater integer type])
2459 fi
2460
2461 AC_DEFINE(LBER_LEN_T,long,[define to large integer type])
2462 AC_DEFINE(LBER_SOCKET_T,int,[define to socket descriptor type])
2463 AC_DEFINE(LBER_TAG_T,long,[define to large integer type])
2464
2465 dnl ----------------------------------------------------------------
2466 dnl Checks for library functions.
2467 AC_FUNC_MEMCMP
2468
2469 if test $ac_cv_func_memcmp_working = no ; then
2470         AC_DEFINE(NEED_MEMCMP_REPLACEMENT,1,
2471                 [define if memcmp is not 8-bit clean or is otherwise broken])
2472 fi
2473
2474 AC_FUNC_STRFTIME
2475
2476 OL_FUNC_INET_ATON
2477
2478 dnl Check for NT specific routines
2479 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2480
2481 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2482         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2483 ])
2484
2485 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2486         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2487 ])
2488
2489 AC_FUNC_VPRINTF
2490
2491 if test $ac_cv_func_vprintf = yes ; then
2492         dnl check for vsnprintf
2493         AC_CHECK_FUNCS(snprintf vsnprintf)
2494 fi
2495
2496 AC_CHECK_FUNCS(         \
2497         bcopy                   \
2498         closesocket             \
2499         chroot                  \
2500         endgrent                \
2501         endpwent                \
2502         fcntl                   \
2503         flock                   \
2504         fstat                   \
2505         getdtablesize   \
2506         getgrgid                \
2507         gethostname             \
2508         getpass                 \
2509         getpassphrase   \
2510         getpwuid                \
2511         getpwnam                \
2512         getspnam                \
2513         gettimeofday    \
2514         initgroups              \
2515         lockf                   \
2516         memcpy                  \
2517         memmove                 \
2518         mkstemp                 \
2519         mktemp                  \
2520         pipe                    \
2521         read                    \
2522         recv                    \
2523         recvfrom                \
2524         setpwfile               \
2525         setgid                  \
2526         setegid                 \
2527         setsid                  \
2528         setuid                  \
2529         seteuid                 \
2530         signal                  \
2531         strdup                  \
2532         strpbrk                 \
2533         strrchr                 \
2534         strsep                  \
2535         strstr                  \
2536         strtol                  \
2537         strtoul                 \
2538         strtoq                  \
2539         strtouq                 \
2540         strtoll                 \
2541         strspn                  \
2542         sysconf                 \
2543         usleep                  \
2544         waitpid                 \
2545         wait4                   \
2546         write                   \
2547         send                    \
2548         sendmsg                 \
2549         sendto                  \
2550 )
2551
2552 dnl We actually may need to replace more than this.
2553 AC_REPLACE_FUNCS(getopt getpeereid)
2554
2555 if test "$ac_cv_func_getopt" != yes; then
2556         LIBSRCS="$LIBSRCS getopt.c"
2557 fi
2558 if test "$ac_cv_func_getpeereid" != yes; then
2559         AC_CHECK_MEMBERS([struct msghdr.msg_accrightslen],,,
2560                 [$ac_includes_default
2561 #ifdef HAVE_SYS_SOCKET_H
2562 #include <sys/socket.h>
2563 #endif])
2564         if test "$ac_cv_member_struct_msghdr_msg_accrightslen" != yes; then
2565                 AC_CHECK_MEMBERS([struct msghdr.msg_control],,,
2566                         [$ac_includes_default
2567 #ifdef HAVE_SYS_SOCKET_H
2568 #include <sys/socket.h>
2569 #endif])
2570         fi
2571         LIBSRCS="$LIBSRCS getpeereid.c"
2572 fi
2573 if test "$ac_cv_func_snprintf" != yes -o "$ac_cv_func_vsnprintf" != yes; then
2574         if test "$ac_cv_func_snprintf" != yes; then
2575                 AC_DEFINE(snprintf, ber_pvt_snprintf, [define to snprintf routine])
2576         fi
2577         if test "$ac_cv_func_vsnprintf" != yes; then
2578                 AC_DEFINE(vsnprintf, ber_pvt_vsnprintf, [define to snprintf routine])
2579         fi
2580 fi
2581
2582 dnl ----------------------------------------------------------------
2583 dnl Sort out defines
2584
2585 if test "$ol_enable_slapi" != no ; then
2586         dnl This check is done also if --enable-modules is used;
2587         dnl it is duplicated here, 'cause it'd be cached anyway
2588         AC_CHECK_HEADERS(ltdl.h)
2589
2590         if test $ac_cv_header_ltdl_h != yes ; then
2591                 AC_MSG_ERROR([could not locate <ltdl.h>])
2592         fi
2593         AC_CHECK_LIB(ltdl, lt_dlinit, [
2594                 SLAPI_LIBS=-lltdl
2595                 LIBSLAPI=libslapi.a
2596                 LIBSLAPITOOLS=../libslapi.a
2597                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
2598         ],[AC_MSG_ERROR([could not locate libtool -lltdl])])
2599
2600         AC_DEFINE(LDAP_SLAPI,1, [define this to add SLAPI code])
2601 fi
2602
2603 if test "$ol_enable_debug" != no ; then
2604         AC_DEFINE(LDAP_DEBUG,1,
2605                 [define this to add debugging code])
2606 fi
2607 if test "$ol_enable_syslog" = yes ; then
2608         AC_DEFINE(LDAP_SYSLOG,1,
2609                 [define this to add syslog code])
2610 fi
2611 if test "$ol_link_kbind" != no ; then
2612         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_KBIND,LDAP_VENDOR_VERSION,
2613                 [define to LDAP VENDOR VERSION])
2614 fi
2615 if test "$ol_enable_proctitle" != no ; then
2616         AC_DEFINE(LDAP_PROCTITLE,1,
2617                 [define this for LDAP process title support])
2618 fi
2619 if test "$ol_enable_referrals" != no ; then
2620         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION,
2621                 [define to LDAP VENDOR VERSION])
2622 fi
2623 if test "$ol_enable_local" != no; then
2624         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2625 fi
2626 if test "$ol_link_ipv6" != no; then
2627         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2628 fi
2629 if test "$ol_enable_cleartext" != no ; then
2630         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2631 fi
2632 if test "$ol_enable_crypt" != no ; then
2633         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2634 fi
2635 if test "$ol_link_spasswd" != no ; then
2636         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2637 fi
2638 if test "$ol_enable_multimaster" != no ; then
2639         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2640 fi
2641 if test "$ol_enable_rlookups" != no ; then
2642         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2643 fi
2644 if test "$ol_enable_aci" != no ; then
2645         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2646 fi
2647
2648 if test "$ol_link_modules" != no ; then
2649         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2650         BUILD_SLAPD=yes
2651         SLAPD_MODULES_LDFLAGS="-dlopen self"
2652 fi
2653
2654 AC_DEFINE(SLAPD_MOD_STATIC,1,[statically linked module])
2655 AC_DEFINE(SLAPD_MOD_DYNAMIC,2,[dynamically linked module])
2656
2657 if test "$ol_enable_bdb" != no ; then
2658         BUILD_SLAPD=yes
2659         BUILD_BDB=$ol_enable_bdb
2660         if test "$ol_enable_bdb" = mod ; then
2661                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-bdb"
2662                 MFLAG=SLAPD_MOD_DYNAMIC
2663         else
2664                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-bdb"
2665                 MFLAG=SLAPD_MOD_STATIC
2666         fi
2667         AC_DEFINE_UNQUOTED(SLAPD_BDB,$MFLAG,[define to support BDB backend])
2668 fi
2669
2670 if test "$ol_enable_dnssrv" != no ; then
2671         BUILD_SLAPD=yes
2672         BUILD_DNSSRV=$ol_enable_dnssrv
2673         if test "$ol_enable_dnssrv" = mod ; then
2674                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-dnssrv"
2675                 MFLAG=SLAPD_MOD_DYNAMIC
2676         else
2677                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-dnssrv"
2678                 MFLAG=SLAPD_MOD_STATIC
2679         fi
2680         AC_DEFINE_UNQUOTED(SLAPD_DNSSRV,$MFLAG,[define to support DNS SRV backend])
2681 fi
2682
2683 if test "$ol_enable_hdb" != no ; then
2684         BUILD_SLAPD=yes
2685         BUILD_HDB=$ol_enable_hdb
2686         if test "$ol_enable_hdb" = mod ; then
2687                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-hdb"
2688                 MFLAG=SLAPD_MOD_DYNAMIC
2689         else
2690                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-hdb"
2691                 MFLAG=SLAPD_MOD_STATIC
2692         fi
2693         AC_DEFINE_UNQUOTED(SLAPD_HDB,$MFLAG,[define to support HDB backend])
2694 fi
2695
2696 if test "$ol_enable_ldap" != no ; then
2697         BUILD_SLAPD=yes
2698         BUILD_LDAP=$ol_enable_ldap
2699         if test "$ol_enable_ldap" = mod ; then
2700                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ldap"
2701                 MFLAG=SLAPD_MOD_DYNAMIC
2702         else
2703                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ldap"
2704                 MFLAG=SLAPD_MOD_STATIC
2705         fi
2706         AC_DEFINE_UNQUOTED(SLAPD_LDAP,$MFLAG,[define to support LDAP backend])
2707 fi
2708
2709 if test "$ol_link_ldbm" != no -a $ol_enable_ldbm != no; then
2710         BUILD_SLAPD=yes
2711         BUILD_LDBM=$ol_enable_ldbm
2712         if test "$ol_enable_ldbm" = mod ; then
2713                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ldbm"
2714                 MFLAG=SLAPD_MOD_DYNAMIC
2715         else
2716                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ldbm"
2717                 MFLAG=SLAPD_MOD_STATIC
2718         fi
2719         AC_DEFINE_UNQUOTED(SLAPD_LDBM,$MFLAG,[define to support LDBM backend])
2720 fi
2721
2722 if test "$ol_enable_meta" != no ; then
2723         BUILD_SLAPD=yes
2724         BUILD_META=$ol_enable_meta
2725         BUILD_REWRITE=yes
2726         if test "$ol_enable_meta" = mod ; then
2727                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-meta"
2728                 MFLAG=SLAPD_MOD_DYNAMIC
2729         else
2730                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-meta"
2731                 MFLAG=SLAPD_MOD_STATIC
2732         fi
2733         AC_DEFINE_UNQUOTED(SLAPD_META,$MFLAG,[define to support LDAP Metadirectory backend])
2734 fi
2735
2736 if test "$ol_enable_monitor" != no ; then
2737         BUILD_SLAPD=yes
2738         BUILD_MONITOR=$ol_enable_monitor
2739         if test "$ol_enable_monitor" = mod ; then
2740                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-monitor"
2741                 MFLAG=SLAPD_MOD_DYNAMIC
2742         else
2743                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-monitor"
2744                 MFLAG=SLAPD_MOD_STATIC
2745         fi
2746         AC_DEFINE_UNQUOTED(SLAPD_MONITOR,$MFLAG,[define to support cn=Monitor backend])
2747 fi
2748
2749 if test "$ol_enable_null" != no ; then
2750         BUILD_SLAPD=yes
2751         BUILD_NULL=$ol_enable_null
2752         if test "$ol_enable_null" = mod ; then
2753                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-null"
2754                 MFLAG=SLAPD_MOD_DYNAMIC
2755         else
2756                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-null"
2757                 MFLAG=SLAPD_MOD_STATIC
2758         fi
2759         AC_DEFINE_UNQUOTED(SLAPD_NULL,$MFLAG,[define to support NULL backend])
2760 fi
2761
2762 if test "$ol_enable_passwd" != no ; then
2763         BUILD_SLAPD=yes
2764         BUILD_PASSWD=$ol_enable_passwd
2765         if test "$ol_enable_passwd" = mod ; then
2766                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-passwd"
2767                 MFLAG=SLAPD_MOD_DYNAMIC
2768         else
2769                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-passwd"
2770                 MFLAG=SLAPD_MOD_STATIC
2771         fi
2772         AC_DEFINE_UNQUOTED(SLAPD_PASSWD,$MFLAG,[define to support PASSWD backend])
2773 fi
2774
2775 if test "$ol_link_perl" != no ; then
2776         BUILD_SLAPD=yes
2777         BUILD_PERL=$ol_enable_perl
2778         if test "$ol_enable_perl" = mod ; then
2779                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-perl"
2780                 MFLAG=SLAPD_MOD_DYNAMIC
2781         else
2782                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-perl"
2783                 MFLAG=SLAPD_MOD_STATIC
2784         fi
2785         AC_DEFINE_UNQUOTED(SLAPD_PERL,$MFLAG,[define to support PERL backend])
2786 fi
2787
2788 if test "$ol_enable_relay" != no ; then
2789         BUILD_SLAPD=yes
2790         BUILD_RELAY=$ol_enable_relay
2791         if test "$ol_enable_relay" = mod ; then
2792                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-relay"
2793                 MFLAG=SLAPD_MOD_DYNAMIC
2794         else
2795                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-relay"
2796                 MFLAG=SLAPD_MOD_STATIC
2797         fi
2798         AC_DEFINE_UNQUOTED(SLAPD_RELAY,$MFLAG,[define to support relay backend])
2799 fi
2800
2801 if test "$ol_enable_shell" != no ; then
2802         if test "$ol_link_threads" != no ; then
2803                 AC_MSG_WARN([Use of --without-threads is recommended with back-shell])
2804         fi
2805         BUILD_SLAPD=yes
2806         BUILD_SHELL=$ol_enable_shell
2807         if test "$ol_enable_shell" = mod ; then
2808                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-shell"
2809                 MFLAG=SLAPD_MOD_DYNAMIC
2810         else
2811                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-shell"
2812                 MFLAG=SLAPD_MOD_STATIC
2813         fi
2814         AC_DEFINE_UNQUOTED(SLAPD_SHELL,$MFLAG,[define to support SHELL backend])
2815 fi
2816
2817 if test "$ol_link_sql" != no ; then
2818         BUILD_SLAPD=yes
2819         BUILD_SQL=$ol_enable_sql
2820         if test "$ol_enable_sql" = mod; then
2821                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-sql"
2822                 MFLAG=SLAPD_MOD_DYNAMIC
2823         else
2824                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-sql"
2825                 MFLAG=SLAPD_MOD_STATIC
2826         fi
2827         AC_DEFINE_UNQUOTED(SLAPD_SQL,$MFLAG,[define to support SQL backend])
2828 fi
2829
2830 if test "$ol_enable_accesslog" != no ; then
2831         BUILD_ACCESSLOG=$ol_enable_accesslog
2832         if test "$ol_enable_accesslog" = mod ; then
2833                 MFLAG=SLAPD_MOD_DYNAMIC
2834                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS accesslog.la"
2835         else
2836                 MFLAG=SLAPD_MOD_STATIC
2837                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS accesslog.o"
2838         fi
2839         AC_DEFINE_UNQUOTED(SLAPD_OVER_ACCESSLOG,$MFLAG,[define for In-Directory Access Logging overlay])
2840 fi
2841
2842 if test "$ol_enable_denyop" != no ; then
2843         BUILD_DENYOP=$ol_enable_denyop
2844         if test "$ol_enable_denyop" = mod ; then
2845                 MFLAG=SLAPD_MOD_DYNAMIC
2846                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS denyop.la"
2847         else
2848                 MFLAG=SLAPD_MOD_STATIC
2849                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS denyop.o"
2850         fi
2851         AC_DEFINE_UNQUOTED(SLAPD_OVER_DENYOP,$MFLAG,[define for Dynamic Group overlay])
2852 fi
2853
2854 if test "$ol_enable_dyngroup" != no ; then
2855         BUILD_DYNGROUP=$ol_enable_dyngroup
2856         if test "$ol_enable_dyngroup" = mod ; then
2857                 MFLAG=SLAPD_MOD_DYNAMIC
2858                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dyngroup.la"
2859         else
2860                 MFLAG=SLAPD_MOD_STATIC
2861                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dyngroup.o"
2862         fi
2863         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNGROUP,$MFLAG,[define for Dynamic Group overlay])
2864 fi
2865
2866 if test "$ol_enable_dynlist" != no ; then
2867         BUILD_DYNLIST=$ol_enable_dynlist
2868         if test "$ol_enable_dynlist" = mod ; then
2869                 MFLAG=SLAPD_MOD_DYNAMIC
2870                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dynlist.la"
2871         else
2872                 MFLAG=SLAPD_MOD_STATIC
2873                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dynlist.o"
2874         fi
2875         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNLIST,$MFLAG,[define for Dynamic List overlay])
2876 fi
2877
2878 if test "$ol_enable_glue" != no ; then
2879         BUILD_GLUE=$ol_enable_glue
2880         if test "$ol_enable_glue" = mod ; then
2881                 MFLAG=SLAPD_MOD_DYNAMIC
2882                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS glue.la"
2883         else
2884                 MFLAG=SLAPD_MOD_STATIC
2885                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS glue.o"
2886         fi
2887         AC_DEFINE_UNQUOTED(SLAPD_OVER_GLUE,$MFLAG,[define for Backend Glue overlay])
2888 fi
2889
2890 if test "$ol_enable_lastmod" != no ; then
2891         BUILD_LASTMOD=$ol_enable_lastmod
2892         if test "$ol_enable_lastmod" = mod ; then
2893                 MFLAG=SLAPD_MOD_DYNAMIC
2894                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS lastmod.la"
2895         else
2896                 MFLAG=SLAPD_MOD_STATIC
2897                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS lastmod.o"
2898         fi
2899         AC_DEFINE_UNQUOTED(SLAPD_OVER_LASTMOD,$MFLAG,[define for Last Modification overlay])
2900 fi
2901
2902 if test "$ol_enable_ppolicy" != no ; then
2903         BUILD_PPOLICY=$ol_enable_ppolicy
2904         if test "$ol_enable_ppolicy" = mod ; then
2905                 MFLAG=SLAPD_MOD_DYNAMIC
2906                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS ppolicy.la"
2907         else
2908                 MFLAG=SLAPD_MOD_STATIC
2909                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS ppolicy.o"
2910         fi
2911         AC_DEFINE_UNQUOTED(SLAPD_OVER_PPOLICY,$MFLAG,[define for Password Policy overlay])
2912 fi
2913
2914 if test "$ol_enable_proxycache" != no ; then
2915         BUILD_PROXYCACHE=$ol_enable_proxycache
2916         if test "$ol_enable_proxycache" = mod ; then
2917                 MFLAG=SLAPD_MOD_DYNAMIC
2918                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS pcache.la"
2919         else
2920                 MFLAG=SLAPD_MOD_STATIC
2921                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS pcache.o"
2922         fi
2923         AC_DEFINE_UNQUOTED(SLAPD_OVER_PROXYCACHE,$MFLAG,[define for Proxy Cache overlay])
2924 fi
2925
2926 if test "$ol_enable_refint" != no ; then
2927         BUILD_REFINT=$ol_enable_refint
2928         if test "$ol_enable_refint" = mod ; then
2929                 MFLAG=SLAPD_MOD_DYNAMIC
2930                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS refint.la"
2931         else
2932                 MFLAG=SLAPD_MOD_STATIC
2933                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS refint.o"
2934         fi
2935         AC_DEFINE_UNQUOTED(SLAPD_OVER_REFINT,$MFLAG,[define for Referential Integrity overlay])
2936 fi
2937
2938 if test "$ol_enable_retcode" != no ; then
2939         BUILD_RETCODE=$ol_enable_retcode
2940         if test "$ol_enable_retcode" = mod ; then
2941                 MFLAG=SLAPD_MOD_DYNAMIC
2942                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS retcode.la"
2943         else
2944                 MFLAG=SLAPD_MOD_STATIC
2945                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS retcode.o"
2946         fi
2947         AC_DEFINE_UNQUOTED(SLAPD_OVER_RETCODE,$MFLAG,[define for Referential Integrity overlay])
2948 fi
2949
2950 if test "$ol_enable_rwm" != no ; then
2951         BUILD_REWRITE=yes
2952         BUILD_RWM=$ol_enable_rwm
2953         if test "$ol_enable_rwm" = mod ; then
2954                 MFLAG=SLAPD_MOD_DYNAMIC
2955                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS rwm.la"
2956         else
2957                 MFLAG=SLAPD_MOD_STATIC
2958                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS rwm_x.o"
2959         fi
2960         AC_DEFINE_UNQUOTED(SLAPD_OVER_RWM,$MFLAG,[define for Rewrite/Remap overlay])
2961 fi
2962
2963 if test "$ol_enable_syncprov" != no ; then
2964         BUILD_SYNCPROV=$ol_enable_syncprov
2965         if test "$ol_enable_syncprov" = mod ; then
2966                 MFLAG=SLAPD_MOD_DYNAMIC
2967                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS syncprov.la"
2968         else
2969                 MFLAG=SLAPD_MOD_STATIC
2970                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS syncprov.o"
2971         fi
2972         AC_DEFINE_UNQUOTED(SLAPD_OVER_SYNCPROV,$MFLAG,[define for Syncrepl Provider overlay])
2973 fi
2974
2975 if test "$ol_enable_translucent" != no ; then
2976         BUILD_TRANSLUCENT=$ol_enable_translucent
2977         if test "$ol_enable_translucent" = mod ; then
2978                 MFLAG=SLAPD_MOD_DYNAMIC
2979                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS translucent.la"
2980         else
2981                 MFLAG=SLAPD_MOD_STATIC
2982                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS translucent.o"
2983         fi
2984         AC_DEFINE_UNQUOTED(SLAPD_OVER_TRANSLUCENT,$MFLAG,[define for Translucent Proxy overlay])
2985 fi
2986
2987 if test "$ol_enable_unique" != no ; then
2988         BUILD_UNIQUE=$ol_enable_unique
2989         if test "$ol_enable_unique" = mod ; then
2990                 MFLAG=SLAPD_MOD_DYNAMIC
2991                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS unique.la"
2992         else
2993                 MFLAG=SLAPD_MOD_STATIC
2994                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS unique.o"
2995         fi
2996         AC_DEFINE_UNQUOTED(SLAPD_OVER_UNIQUE,$MFLAG,[define for Attribute Uniqueness overlay])
2997 fi
2998
2999 if test "$ol_enable_valsort" != no ; then
3000         BUILD_VALSORT=$ol_enable_valsort
3001         if test "$ol_enable_valsort" = mod ; then
3002                 MFLAG=SLAPD_MOD_DYNAMIC
3003                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS valsort.la"
3004         else
3005                 MFLAG=SLAPD_MOD_STATIC
3006                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS valsort.o"
3007         fi
3008         AC_DEFINE_UNQUOTED(SLAPD_OVER_VALSORT,$MFLAG,[define for Value Sorting overlay])
3009 fi
3010
3011 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
3012         $BUILD_SLAPD = yes ; then
3013         BUILD_SLURPD=yes
3014 fi
3015
3016 if test "$ol_enable_rewrite" != no ; then
3017         AC_DEFINE(ENABLE_REWRITE,1,[define to enable rewriting in back-ldap and back-meta])
3018         BUILD_REWRITE=yes
3019 fi
3020
3021 if test "$ol_enable_slapi" != no ; then
3022         AC_DEFINE(ENABLE_SLAPI,1,[define to enable slapi library])
3023         BUILD_SLAPI=yes
3024         SLAPD_SLAPI_DEPEND=libslapi.a
3025 fi
3026
3027 dnl ----------------------------------------------------------------
3028
3029 dnl
3030 dnl For Windows build, we don't want to include -dlopen flags.
3031 dnl They hurt more than they help.
3032 dnl
3033
3034 if test "$ac_cv_mingw32" = yes ; then
3035         PLAT=NT
3036         SLAPD_MODULES_LDFLAGS=
3037 else
3038         PLAT=UNIX
3039 fi
3040
3041 AC_SUBST(LIBSRCS)
3042 AC_SUBST(PLAT)
3043 AC_SUBST(WITH_SASL)
3044 AC_SUBST(WITH_TLS)
3045 AC_SUBST(WITH_MODULES_ENABLED)
3046 AC_SUBST(BUILD_LIBS_DYNAMIC)
3047
3048 AC_SUBST(BUILD_SLAPD)
3049 dnl slapi
3050   AC_SUBST(BUILD_SLAPI)
3051   AC_SUBST(SLAPD_SLAPI_DEPEND)
3052 dnl backends
3053   AC_SUBST(BUILD_BDB)
3054   AC_SUBST(BUILD_DNSSRV)
3055   AC_SUBST(BUILD_HDB)
3056   AC_SUBST(BUILD_LDAP)
3057   AC_SUBST(BUILD_LDBM)
3058   AC_SUBST(BUILD_META)
3059   AC_SUBST(BUILD_MONITOR)
3060   AC_SUBST(BUILD_NULL)
3061   AC_SUBST(BUILD_PASSWD)
3062   AC_SUBST(BUILD_RELAY)
3063   AC_SUBST(BUILD_PERL)
3064   AC_SUBST(BUILD_SHELL)
3065   AC_SUBST(BUILD_SQL)
3066 dnl overlays
3067   AC_SUBST(BUILD_ACCESSLOG)
3068   AC_SUBST(BUILD_DENYOP)
3069   AC_SUBST(BUILD_DYNGROUP)
3070   AC_SUBST(BUILD_DYNLIST)
3071   AC_SUBST(BUILD_GLUE)
3072   AC_SUBST(BUILD_LASTMOD)
3073   AC_SUBST(BUILD_PPOLICY)
3074   AC_SUBST(BUILD_PROXYCACHE)
3075   AC_SUBST(BUILD_REFINT)
3076   AC_SUBST(BUILD_RETCODE)
3077   AC_SUBST(BUILD_RWM)
3078   AC_SUBST(BUILD_SYNCPROV)
3079   AC_SUBST(BUILD_TRANSLUCENT)
3080   AC_SUBST(BUILD_UNIQUE)
3081   AC_SUBST(BUILD_VALSORT)
3082 AC_SUBST(BUILD_SLURPD)
3083
3084 AC_SUBST(LDAP_LIBS)
3085 AC_SUBST(SLAPD_LIBS)
3086 AC_SUBST(SLURPD_LIBS)
3087 AC_SUBST(LDBM_LIBS)
3088 AC_SUBST(LTHREAD_LIBS)
3089 AC_SUBST(LUTIL_LIBS)
3090 AC_SUBST(WRAP_LIBS)
3091
3092 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
3093 AC_SUBST(SLAPD_MODULES_LDFLAGS)
3094
3095 AC_SUBST(SLAPD_NO_STATIC)
3096 AC_SUBST(SLAPD_STATIC_BACKENDS)
3097 AC_SUBST(SLAPD_DYNAMIC_BACKENDS)
3098 AC_SUBST(SLAPD_STATIC_OVERLAYS)
3099 AC_SUBST(SLAPD_DYNAMIC_OVERLAYS)
3100
3101 AC_SUBST(PERL_CPPFLAGS)
3102 AC_SUBST(SLAPD_PERL_LDFLAGS)
3103 AC_SUBST(MOD_PERL_LDFLAGS)
3104
3105 AC_SUBST(KRB4_LIBS)
3106 AC_SUBST(KRB5_LIBS)
3107 AC_SUBST(SASL_LIBS)
3108 AC_SUBST(TLS_LIBS)
3109 AC_SUBST(MODULES_LIBS)
3110 AC_SUBST(SLAPI_LIBS)
3111 AC_SUBST(LIBSLAPI)
3112 AC_SUBST(LIBSLAPITOOLS)
3113 AC_SUBST(AUTH_LIBS)
3114
3115 AC_SUBST(SLAPD_SLP_LIBS)
3116 AC_SUBST(SLAPD_GMP_LIBS)
3117
3118 AC_SUBST(SLAPD_SQL_LDFLAGS)
3119 AC_SUBST(SLAPD_SQL_LIBS)
3120 AC_SUBST(SLAPD_SQL_INCLUDES)
3121
3122 dnl ----------------------------------------------------------------
3123 dnl final help output
3124 AC_ARG_WITH(xxinstall,[
3125 See INSTALL file for further details.])
3126
3127 dnl ----------------------------------------------------------------
3128 dnl final output
3129 dnl
3130
3131 AC_CONFIG_FILES([Makefile:build/top.mk:Makefile.in:build/dir.mk]
3132 [doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk]
3133 [doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk]
3134 [doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk]
3135 [doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk]
3136 [doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk]
3137 [doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk]
3138 [clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk]
3139 [clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk]
3140 [include/Makefile:build/top.mk:include/Makefile.in]
3141 [libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk]
3142 [libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk]
3143 [libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk]
3144 [libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk]
3145 [libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk]
3146 [libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk]
3147 [libraries/librewrite/Makefile:build/top.mk:libraries/librewrite/Makefile.in:build/lib.mk:build/lib-shared.mk]
3148 [servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk]
3149 [servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk]
3150 [servers/slapd/back-bdb/Makefile:build/top.mk:servers/slapd/back-bdb/Makefile.in:build/mod.mk]
3151 [servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk]
3152 [servers/slapd/back-hdb/Makefile:build/top.mk:servers/slapd/back-hdb/Makefile.in:build/mod.mk]
3153 [servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk]
3154 [servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk]
3155 [servers/slapd/back-ldif/Makefile:build/top.mk:servers/slapd/back-ldif/Makefile.in:build/mod.mk]
3156 [servers/slapd/back-meta/Makefile:build/top.mk:servers/slapd/back-meta/Makefile.in:build/mod.mk]
3157 [servers/slapd/back-monitor/Makefile:build/top.mk:servers/slapd/back-monitor/Makefile.in:build/mod.mk]
3158 [servers/slapd/back-null/Makefile:build/top.mk:servers/slapd/back-null/Makefile.in:build/mod.mk]
3159 [servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk]
3160 [servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk]
3161 [servers/slapd/back-relay/Makefile:build/top.mk:servers/slapd/back-relay/Makefile.in:build/mod.mk]
3162 [servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk]
3163 [servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk]
3164 [servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk]
3165 [servers/slapd/slapi/Makefile:build/top.mk:servers/slapd/slapi/Makefile.in:build/lib.mk:build/lib-shared.mk]
3166 [servers/slapd/overlays/Makefile:build/top.mk:servers/slapd/overlays/Makefile.in:build/lib.mk]
3167 [servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk]
3168 [tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk]
3169 [tests/run]
3170 [tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk])
3171
3172 AC_CONFIG_COMMANDS([default],[[
3173 chmod +x tests/run
3174 date > stamp-h
3175 BACKENDSC="servers/slapd/backends.c"
3176 echo "Making $BACKENDSC"
3177 rm -f $BACKENDSC
3178 cat > $BACKENDSC << ENDX
3179 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
3180  *
3181  * Copyright 1998-2005 The OpenLDAP Foundation.
3182  * All rights reserved.
3183  *
3184  * Redistribution and use in source and binary forms, with or without
3185  * modification, are permitted only as authorized by the OpenLDAP
3186  * Public License.
3187  *
3188  * A copy of this license is available in the file LICENSE in the
3189  * top-level directory of the distribution or, alternatively, at
3190  * <http://www.OpenLDAP.org/license.html>.
3191  */
3192 /* This file is automatically generated by configure; please do not edit. */
3193
3194 #include "portable.h"
3195 #include "slap.h"
3196
3197 ENDX
3198 if test "${STATIC_BACKENDS}"; then
3199         for b in config ${STATIC_BACKENDS}; do
3200                 bb=`echo "${b}" | sed -e 's/back-//'`
3201                 cat >> $BACKENDSC << ENDX
3202 extern BI_init ${bb}_back_initialize;
3203 ENDX
3204         done
3205
3206         cat >> $BACKENDSC << ENDX
3207
3208 BackendInfo slap_binfo[] = {
3209 ENDX
3210
3211         for b in config ${STATIC_BACKENDS}; do
3212                 bb=`echo "${b}" | sed -e 's/back-//'`
3213                 echo "    Add ${bb} ..."
3214                 cat >> $BACKENDSC << ENDX
3215         { "${bb}", ${bb}_back_initialize },
3216 ENDX
3217         done
3218
3219         cat >> $BACKENDSC << ENDX
3220         { NULL, NULL },
3221 };
3222
3223 /* end of generated file */
3224 ENDX
3225 fi
3226
3227 echo Please run \"make depend\" to build dependencies
3228 ]],[[STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS"]])
3229 AC_OUTPUT