git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8
   9 dnl Configure.in for OpenLDAP
  10 AC_INIT(include/ldap.h)dnl
  11 AC_CONFIG_AUX_DIR(build)dnl
  12 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no ac_define])dnl
  13
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_PREREQ(2.10)dnl Required Autoconf version
  18
  19 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  20
  21 dnl
  22 dnl Start Args
  23 AC_MSG_CHECKING(configure arguments)
  24 AC_PREFIX_DEFAULT(/usr/local)
  25
  26 top_builddir=`pwd`
  27 AC_SUBST(top_builddir)dnl
  28
  29 ldap_subdir="openldap"
  30 AC_SUBST(ldap_subdir)dnl
  31
  32 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  33 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  34 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  35 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  36 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  37 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  38 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  39 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  40 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  41         no, [yes no])dnl
  42
  43 dnl General "with" options
  44 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  45         auto, [auto k5 k4 afs yes no])
  46 OL_ARG_WITH(threads,[  --with-threads   use threads],
  47         auto, [auto posix mach lwp yes no manual] )
  48 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  49         auto, [auto yes no manual] )
  50
  51 dnl Server options
  52
  53 dnl LDAPD OPTIONS
  54 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  55 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  56
  57 dnl SLAPD OPTIONS
  58 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  59 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  60 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  61 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  62 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  63 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  64 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  65 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  66 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  67
  68 dnl SLAPD Backend options
  69 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  70 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  71         [auto db2 db gdbm ndbm manual])
  72 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  73         [auto btree hash])
  74
  75 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  76 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  77
  78 dnl SLURPD OPTIONS
  79 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  80 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  81
  82 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
  83 AM_ENABLE_STATIC
  84 dnl AM_DISABLE_SHARED
  85 AM_ENABLE_SHARED
  86
  87 dnl General "enable" options
  88 # validate options
  89 if test $ol_enable_referrals = no ; then
  90         if test $ol_enable_dns = yes ; then
  91                 AC_MSG_WARN([dns disabled, ignoring --enable-dns argument])
  92         fi
  93         ol_enable_dns=no
  94 fi
  95
  96 if test $ol_enable_slapd = no ; then
  97         dnl SLAPD was specificallly disabled
  98         if test $ol_enable_ldbm = yes ; then
  99                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 100         fi
 101         if test $ol_enable_passwd = yes ; then
 102                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 103         fi
 104         if test $ol_enable_shell = yes ; then
 105                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 106         fi
 107         if test $ol_enable_aclgroups = yes ; then
 108                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 109         fi
 110         if test $ol_enable_crypt = yes ; then
 111                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument])
 112         fi
 113         if test $ol_enable_md5 = yes ; then
 114                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument])
 115         fi
 116         if test $ol_enable_sha1 = yes ; then
 117                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument])
 118         fi
 119         if test $ol_enable_wrappers = yes ; then
 120                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 121         fi
 122         if test $ol_enable_phonetic = yes ; then
 123                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 124         fi
 125         if test $ol_enable_rlookups = yes ; then
 126                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 127         fi
 128         if test $ol_with_ldbm_api != auto ; then
 129                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 130         fi
 131         if test $ol_with_ldbm_type != auto ; then
 132                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 133         fi
 134         if test $ol_enable_slurpd = yes ; then
 135                 AC_MSG_ERROR([slurpd requires slapd])
 136         fi
 137
 138         # force settings to no
 139         ol_enable_ldbm=no
 140         ol_enable_shell=no
 141         ol_enable_passwd=no
 142         ol_enable_aclgroups=no
 143         ol_enable_crypt=no
 144         ol_enable_md5=no
 145         ol_enable_sha1=no
 146         ol_enable_wrappers=no
 147         ol_enable_phonetic=no
 148         ol_enable_rlookups=no
 149         ol_with_ldbm_api=no
 150         ol_with_ldbm_type=no
 151         ol_enable_slurpd=no
 152
 153 elif test $ol_enable_ldbm = no ; then
 154         dnl SLAPD without LDBM
 155
 156         if test $ol_with_ldbm_api != auto ; then
 157                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 158         fi
 159
 160         if test $ol_with_ldbm_type != auto ; then
 161                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 162         fi
 163
 164         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 165                 AC_MSG_ERROR([slapd requires a backend])
 166         fi
 167
 168         ol_with_ldbm_api=no
 169         ol_with_ldbm_type=no
 170
 171 else
 172         dnl SLAPD with LDBM
 173
 174         if test $ol_with_ldbm_api = gdbm -a \
 175                 $ol_with_ldbm_type = btree ; then
 176                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 177         fi
 178         if test $ol_with_ldbm_api = ndbm -a \
 179                 $ol_with_ldbm_type = btree ; then
 180                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 181         fi
 182 fi
 183
 184 if test $ol_enable_slurpd = yes ; then
 185         dnl SLURPD was specifically enabled
 186         if test $ol_with_threads = no ; then
 187                 AC_MSG_ERROR([slurpd requires threads])
 188         fi
 189 fi
 190
 191 AC_MSG_RESULT(done)
 192
 193 AC_CANONICAL_HOST
 194
 195 ## Initialize vars
 196 LDAP_LIBS=
 197 LDBM_LIBS=
 198 LTHREAD_LIBS=
 199 LUTIL_LIBS=
 200
 201 LDAPD_LIBS=
 202 SLAPD_LIBS=
 203 SLURPD_LIBS=
 204
 205 BUILD_LDAPD=no
 206 BUILD_SLAPD=no
 207 BUILD_SLURPD=no
 208
 209 BUILD_LDBM=no
 210 BUILD_PASSWD=no
 211 BUILD_SHELL=no
 212 BUILD_THREAD=no
 213
 214 KRB_LIBS=
 215 TERMCAP_LIBS=
 216
 217 dnl ----------------------------------------------------------------
 218 dnl Checks for programs
 219
 220 AC_PROG_INSTALL
 221 AM_PROG_LIBTOOL
 222 dnl AC_PROG_MAKE_SET
 223
 224 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 225         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 226 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 227 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 228
 229 dnl Checks the compiler and UNIX Variants
 230
 231 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 232         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 233
 234 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 235         AC_MSG_WARN([programs compiled here do run here...])
 236         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 237
 238 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 239         AC_MSG_WARN([programs compiled here do not run here...])
 240         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 241 fi
 242
 243 AC_PROG_CPP
 244
 245 AC_AIX
 246 AC_ISC_POSIX
 247 AC_MINIX
 248
 249 dnl OpenLDAP requires STDC features
 250 AM_PROG_CC_STDC
 251 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 252         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 253 fi
 254
 255 dnl AM_C_PROTOTYPES
 256
 257 dnl Checks for libraries
 258
 259 dnl Find socket()
 260 dnl Likely combinations:
 261 dnl             -lsocket [ -lnsl_s | -lnsl ]
 262 dnl             -linet
 263
 264 AC_CHECK_FUNC(socket, [have_socket=yes], [
 265 dnl
 266 dnl hopefully we won't include too many libraries
 267 dnl
 268         AC_CHECK_LIB(socket, main)
 269         AC_CHECK_LIB(net, main)
 270         AC_CHECK_LIB(nsl_s, main)
 271         AC_CHECK_LIB(nsl, main)
 272         AC_CHECK_LIB(inet, socket)
 273         AC_CHECK_LIB(gen, main)
 274 ])
 275
 276 dnl Check for resolv
 277 AC_CHECK_LIB(resolv, res_search)
 278
 279 dnl HP-UX requires -lV3
 280 AC_CHECK_LIB(V3, sigset)
 281
 282 # ISODE tests
 283 ol_link_isode=no
 284 if test $ol_enable_ldapd != no ; then
 285         dnl look for ISODE libraries
 286         AC_CHECK_LIB(xtpp, main, [
 287                 ol_link_isode=yes
 288                 AC_DEFINE(HAVE_XTPP,1)
 289                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 290                 ],:,[-lxtdsap -lxtisode -losi])
 291         AC_CHECK_LIB(dsap, main, [
 292                 ol_link_isode=yes
 293                 AC_DEFINE(HAVE_DSAP,1)
 294                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 295                 ],:,[-lisode])
 296         AC_CHECK_LIB(isode, main, [
 297                 ol_link_isode=yes
 298                 AC_DEFINE(HAVE_ISODE,1)
 299                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 300                 ],:)
 301 fi
 302
 303 if test $ol_link_isode != no; then
 304         AC_CHECK_LIB(pp, main, [
 305                 AC_DEFINE(HAVE_PP,1)
 306                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 307                 ],:)
 308
 309         AC_PATH_PROG(PEPSY, pepsy)
 310 fi
 311
 312 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 313         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 314
 315         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 316                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 317                         [-lkrb5 -ldes425])
 318
 319                 if test $have_k5 = yes ; then
 320                         ol_with_kerberos=found
 321                         ol_link_kerberos=yes
 322
 323                         AC_DEFINE(HAVE_KERBEROS)
 324
 325                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 326                 fi
 327         fi
 328 fi
 329 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 330         AC_CHECK_HEADERS(krb.h des.h)
 331
 332         if test $ac_cv_header_krb_h = yes ; then
 333                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 334
 335                 if test $have_k4 = yes ; then
 336                         ol_with_kerberos=found
 337                         ol_link_kerberos=yes
 338
 339                         AC_DEFINE(HAVE_KERBEROS)
 340                         KRB_LIBS="-lkrb -ldes"
 341
 342                         AC_CHECK_FUNCS(des_string_to_key)
 343                 fi
 344         fi
 345 fi
 346
 347 ol_link_threads=no
 348 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 349         AC_CHECK_HEADERS(pthread.h sched.h)
 350
 351         if test $ac_cv_header_pthread_h = yes ; then
 352                 OL_POSIX_THREAD_VERSION
 353
 354                 if test $ol_cv_pthread_version = final ; then
 355                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 356                 elif test $ol_cv_pthread_version = draft4 ; then
 357                         AC_DEFINE(HAVE_PTHREADS_D4)
 358                 else
 359                         AC_MSG_ERROR([unknown pthread version])
 360                 fi
 361
 362                 # consider threads found
 363                 ol_with_threads=found
 364
 365                 OL_LINUX_THREADS
 366
 367                 if test $ol_cv_linux_threads = yes ; then
 368                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 369                 fi
 370
 371                 dnl Now the hard part, how to link
 372
 373                 dnl Check for pthread support in current $LIBS
 374                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 375
 376                 if test $ol_link_threads = no ; then
 377                         dnl try -pthread
 378                         AC_CACHE_CHECK([for pthread_create with -pthread],
 379                                 [ol_cv_pthread_flag], [
 380                                 dnl save the flags
 381                                 save_LIBS="$LIBS"
 382                                 LIBS="-pthread $LIBS"
 383                                 AC_TRY_LINK([char pthread();],[
 384                                         pthread_create();
 385                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 386                                 dnl restore the LIBS
 387                                 LIBS="$save_LIBS"
 388                         ])
 389
 390                         if test $ol_cv_pthread_flag = yes ; then
 391                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 392                                 ol_link_threads=posix
 393                         fi
 394                 fi
 395
 396                 if test $ol_link_threads = no ; then
 397                         dnl try -thread
 398                         AC_CACHE_CHECK([for pthread_create with -thread],
 399                                 [ol_cv_thread_flag], [
 400                                 dnl save the flags
 401                                 save_LIBS="$LIBS"
 402                                 LIBS="-thread $LIBS"
 403                                 AC_TRY_LINK([char pthread();],[
 404                                         pthread_create();
 405                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 406                                 dnl restore the LIBS
 407                                 LIBS="$save_LIBS"
 408                         ])
 409
 410                         if test $ol_cv_thread_flag = yes ; then
 411                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 412                                 ol_link_threads=posix
 413                         fi
 414                 fi
 415
 416                 if test $ol_link_threads = no ; then
 417                         dnl try DEC Threads -lpthread -lexc
 418                         save_LIBS="$LIBS"
 419                         AC_CHECK_LIB(pthread, pthread_join, [
 420                                 ol_link_threads=posix
 421                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 422                                 if test $ol_with_yielding_select = auto ; then
 423                                         ol_with_yielding_select=yes
 424                                 fi
 425                                 ],,[-lexc])
 426                         LIBS="$save_LIBS"
 427                 fi
 428
 429                 if test $ol_link_threads = no ; then
 430                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 431                         save_LIBS="$LIBS"
 432                         AC_CHECK_LIB(pthreads, pthread_join, [
 433                                 ol_link_threads=posix
 434                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 435                                 if test $ol_with_yielding_select = auto ; then
 436                                         ol_with_yielding_select=yes
 437                                 fi
 438                                 ],,[-lmach -lexc -lc_r])
 439                         LIBS="$save_LIBS"
 440                 fi
 441
 442                 if test $ol_link_threads = no ; then
 443                         dnl try -lpthread
 444                         save_LIBS="$LIBS"
 445                         AC_CHECK_LIB(pthread, pthread_create, [
 446                                 ol_link_threads=posix
 447                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 448                         LIBS="$save_LIBS"
 449                 fi
 450
 451                 if test $ol_link_threads = no ; then
 452                         dnl try -lc_r
 453                         save_LIBS="$LIBS"
 454                         AC_CHECK_LIB(c_r, pthread_create, [
 455                                 ol_link_threads=posix
 456                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 457                         LIBS="$save_LIBS"
 458                 fi
 459
 460                 if test $ol_link_threads != no ; then
 461                         AC_DEFINE(HAVE_PTHREADS)
 462
 463                         dnl save flags
 464                         save_CPPFLAGS="$CPPFLAGS"
 465                         save_LIBS="$LIBS"
 466                         LIBS="$LTHREAD_LIBS $LIBS"
 467
 468                         dnl All POSIX Thread (final) implementations should have
 469                         dnl sched_yield instead of pthread yield.
 470                         dnl check for both
 471                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 472
 473                         if test $ac_cv_func_sched_yield = no -a \
 474                                 $ac_cv_func_pthread_yield = no ; then
 475                                 dnl Digital UNIX has sched_yield() in -lrt
 476                                 AC_CHECK_LIB(rt, sched_yield,
 477                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 478                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 479                                         ac_cv_func_sched_yield=yes],
 480                                         [ac_cv_func_sched_yield=no])
 481                         fi
 482                         if test $ac_cv_func_sched_yield = no -a \
 483                                 $ac_cv_func_pthread_yield = no ; then
 484                                 dnl Solaris has sched_yield() in -lposix4
 485                                 AC_CHECK_LIB(posix4, sched_yield,
 486                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 487                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 488                                         ac_cv_func_sched_yield=yes],
 489                                         [ac_cv_func_sched_yield=no])
 490                         fi
 491                         if test $ac_cv_func_sched_yield = no -a \
 492                                 $ac_cv_func_pthread_yield = no ; then
 493                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 494                                 AC_MSG_ERROR([POSIX Threads are not usable])
 495                         fi
 496
 497                         dnl Check functions for compatibility
 498                         AC_CHECK_FUNCS(pthread_kill)
 499                         AC_CHECK_FUNCS( \
 500                                 pthread_attr_create pthread_attr_init \
 501                                 pthread_attr_destroy pthread_attr_delete \
 502                                 pthread_attr_setdetachstate pthread_attr_setdetach_np \
 503                         )
 504
 505                         dnl Check for setconcurreny functions
 506                         AC_CHECK_FUNCS( \
 507                                 pthread_setconcurrency \
 508                                 thr_setconcurrency \
 509                         )
 510
 511                         dnl Check if select causes an yield
 512                         if test $ol_with_yielding_select = auto ; then
 513                                 AC_MSG_CHECKING([if select yields])
 514                                 AC_TRY_RUN([
 515 #include <sys/types.h>
 516 #include <sys/time.h>
 517 #include <unistd.h>
 518 #include <pthread.h>
 519 #ifndef NULL
 520 #define NULL 0
 521 #endif
 522
 523 int fildes[2];
 524
 525 int task(arg)
 526         int *arg;
 527 {
 528         int i;
 529         struct timeval tv;
 530
 531         fd_set rfds;
 532
 533         tv.tv_sec=10;
 534         tv.tv_usec=0;
 535
 536         FD_ZERO(&rfds);
 537         FD_SET(fildes[0], &rfds);
 538
 539         /* we're not interested in any fds */
 540         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 541
 542         if(i < 0) {
 543                 perror("select");
 544                 exit(0);
 545         }
 546
 547         exit(1); /* if we exit here, the select blocked the whole process */
 548 }
 549
 550 int main(argc, argv)
 551         int argc;
 552         char **argv;
 553 {
 554         pthread_t t;
 555
 556         /* create a pipe to select */
 557         if(pipe(&fildes[0])) {
 558                 perror("select");
 559                 exit(0);
 560         }
 561
 562 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 563         (void) pthread_setconcurrency(2);
 564 #else
 565 #ifdef HAVE_THR_SETCONCURRENCY
 566         /* Set Solaris LWP concurrency to 2 */
 567         thr_setconcurrency(2);
 568 #endif
 569 #endif
 570
 571         pthread_create(&t, NULL, (void *) task, NULL);
 572
 573 #if HAVE_SCHED_YIELD
 574         sched_yield();  /* make sure task runs first */
 575 #else
 576 #ifdef HAVE_PTHREAD_YIELD
 577         pthread_yield();        /* make sure task runs first */
 578 #endif
 579 #endif
 580         exit(0);
 581 }
 582                                 ], [ol_pthread_select_yields=yes], [ol_pthread_select_yields=no], [
 583                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])
 584                                 AC_MSG_RESULT($ol_pthread_select_yields)
 585
 586                                 if test $ol_pthread_select_yields = yes ; then
 587                                         ol_with_yielding_select=yes
 588                                 fi
 589                         fi
 590
 591 dnl                     dnl check for reentrant/threadsafe functions
 592 dnl                     AC_CHECK_FUNCS( \
 593 dnl                             feof_unlocked \
 594 dnl                             unlocked_feof \
 595 dnl                             ftrylockfile \
 596 dnl                             flockfile \
 597 dnl                             putc_unlocked \
 598 dnl                             gmtime_r \
 599 dnl                             strtok_r \
 600 dnl                     )
 601
 602                         dnl restore flags
 603                         CPPFLAGS="$save_CPPFLAGS"
 604                         LIBS="$save_LIBS"
 605                 else
 606                         AC_MSG_ERROR([could not link with POSIX Threads])
 607                 fi
 608         fi
 609
 610         if test $ol_with_threads = posix ; then
 611                 AC_MSG_ERROR([could not locate POSIX Threads])
 612         fi
 613 fi
 614
 615 if test $ol_with_threads = auto -o $ol_with_threads = mach ; then
 616         dnl check for Mach CThreads
 617         AC_CHECK_HEADERS(mach/cthreads.h)
 618         if test $ac_cv_header_mach_cthreads_h = yes ; then
 619                 ol_with_threads=found
 620
 621                 dnl check for cthread support in current $LIBS
 622                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 623
 624                 if test $ol_link_threads = no ; then
 625                         dnl try -all_load
 626                         dnl this test needs work
 627                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 628                                 [ol_cv_cthread_all_load], [
 629                                 dnl save the flags
 630                                 save_LIBS="$LIBS"
 631                                 LIBS="-all_load $LIBS"
 632                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 633                                         cthread_fork((void *)0, (void *)0);
 634                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 635                                 dnl restore the LIBS
 636                                 LIBS="$save_LIBS"
 637                         ])
 638
 639                         if test $ol_cv_cthread_all_load = yes ; then
 640                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 641                                 ol_link_threads=mach
 642                         fi
 643                 fi
 644
 645                 if test $ol_link_threads != no ; then
 646                         : check for cthread specific functionality here
 647                         AC_DEFINE(HAVE_MACH_CTHREADS,1)
 648                 else
 649                         AC_MSG_ERROR([could not link with Mach CThreads])
 650                 fi
 651         fi
 652
 653         if test $ol_with_threads = mach ; then
 654                 AC_MSG_ERROR([could not locate Mach CThreads])
 655         fi
 656 fi
 657
 658 if test $ol_with_threads = auto -o $ol_with_threads = lwp ; then
 659         dnl check for SunOS5 LWP
 660         AC_CHECK_HEADERS(thread.h synch.h)
 661         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 662                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
 663
 664                 if test $have_thr = yes ; then
 665                         AC_DEFINE(HAVE_THR)
 666                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
 667                         ol_link_threads=thr
 668
 669                         if test $ol_with_yielding_select = auto ; then
 670                                 ol_with_yielding_select=yes
 671                         fi
 672                 fi
 673         fi
 674
 675         dnl check for SunOS4 LWP
 676         AC_CHECK_HEADERS(lwp/lwp.h)
 677         if test $ac_cv_header_lwp_lwp_h = yes ; then
 678                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 679
 680                 if test $have_lwp = yes ; then
 681                         AC_DEFINE(HAVE_LWP)
 682                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 683                         ol_link_threads=lwp
 684
 685                         if test $ol_with_yielding_select = auto ; then
 686                                 ol_with_yielding_select=no
 687                         fi
 688                 fi
 689         fi
 690 fi
 691
 692 if test $ol_with_yielding_select = yes ; then
 693         AC_DEFINE(HAVE_YIELDING_SELECT,1)
 694 fi
 695
 696 if test $ol_with_threads = manual ; then
 697         dnl User thinks he can manually configure threads.
 698         ol_link_threads=yes
 699
 700         AC_MSG_WARN([thread defines and link options must be set manually])
 701
 702         AC_CHECK_HEADERS(pthread.h sched.h)
 703         AC_CHECK_FUNCS(sched_yield pthread_yield)
 704         OL_LINUX_THREADS
 705
 706         AC_CHECK_HEADERS(mach/cthreads.h)
 707         AC_CHECK_HEADERS(lwp/lwp.h)
 708         AC_CHECK_HEADERS(thread.h synch.h)
 709 fi
 710
 711 if test $ol_with_threads != no ; then
 712         dnl needed to get reentrant/threadsafe versions
 713         dnl
 714         AC_DEFINE(_REENTRANT,1)
 715         AC_DEFINE(_THREAD_SAFE,1)
 716         AC_DEFINE(_THREADSAFE,1)
 717
 718         dnl this might cause the errno symbol to be
 719         dnl replaced with a function to get a thread specific errno.
 720         dnl check to see if everything needs to be compiled
 721         dnl with the thread libraries
 722         AC_CACHE_CHECK([for thread specific errno],
 723                 [ol_cv_errno_thread_specific], [
 724                 AC_TRY_LINK([
 725 #include <errno.h>
 726                         ], [
 727 int x = errno;
 728                         ],
 729                         [ol_cv_errno_thread_specific=yes],
 730                         [ol_cv_errno_thread_specific=no])
 731         ])
 732
 733         if test $ol_cv_errno_thread_specific != yes ; then
 734                 LIBS="$LTHREAD_LIBS $LIBS"
 735                 LTHREAD_LIBS=""
 736         fi
 737 fi
 738
 739 dnl ----------------------------------------------------------------
 740
 741 if test $ol_link_threads = no ; then
 742         if test $ol_with_threads = yes ; then
 743                 AC_MSG_ERROR([no suitable thread support])
 744         fi
 745
 746         if test $ol_with_threads = auto ; then
 747                 AC_MSG_WARN([no suitable thread support, disabling threads])
 748                 ol_with_threads=no
 749         fi
 750
 751         AC_DEFINE(NO_THREADS,1)
 752         LTHREAD_LIBS=""
 753 fi
 754
 755 ol_link_ldbm=no
 756 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 757         OL_BERKELEY_DB2
 758
 759         if test $ol_cv_berkeley_db2 = yes ; then
 760                 ol_link_ldbm=db2
 761                 ol_with_ldbm_api=db2
 762
 763                 if test $ol_with_ldbm_type = hash ; then
 764                         AC_DEFINE(LDBM_USE_DBHASH,1)
 765                 else
 766                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 767                 fi
 768
 769                 dnl $ol_cv_lib_db2 should be yes or -ldb
 770                 dnl (it could be no, but that would be an error
 771                 if test $ol_cv_lib_db2 != yes ; then
 772                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 773                 fi
 774         fi
 775 fi
 776
 777 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 778         OL_BERKELEY_DB
 779
 780         if test $ol_cv_berkeley_db = yes ; then
 781                 ol_link_ldbm=db
 782                 ol_with_ldbm_api=db
 783
 784                 if test $ol_with_ldbm_type = hash ; then
 785                         AC_DEFINE(LDBM_USE_DBHASH,1)
 786                 else
 787                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 788                 fi
 789
 790                 dnl $ol_cv_lib_db should be yes or -ldb
 791                 dnl (it could be no, but that would be an error
 792                 if test $ol_cv_lib_db != yes ; then
 793                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 794                 fi
 795         fi
 796 fi
 797
 798 if test $ol_with_ldbm_api = manual ; then
 799         dnl User thinks he can manually configure LDBM api.
 800         ol_link_ldbm=yes
 801
 802         AC_MSG_WARN([LDBM defines and link options must be set manually])
 803
 804         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 805 fi
 806
 807 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 808         AC_MSG_WARN(Could not find LDBM with BTREE support)
 809         ol_with_ldbm_api=none
 810 fi
 811
 812 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 813         OL_GDBM
 814
 815         if test $ol_cv_gdbm = yes ; then
 816                 ol_link_ldbm=gdbm
 817                 ol_with_ldbm_api=gdbm
 818
 819                 if test $ol_cv_lib_gdbm != yes ; then
 820                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 821                 fi
 822         fi
 823 fi
 824
 825 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 826         OL_NDBM
 827
 828         if test $ol_cv_ndbm = yes ; then
 829                 if test $ol_with_ldbm_api = auto ; then
 830                         AC_MSG_WARN([Attempting to use NDBM.  Functionality will be limited.])
 831                 fi
 832
 833                 ol_link_ldbm=ndbm
 834                 ol_with_ldbm_api=ndbm
 835
 836                 if test $ol_cv_lib_ndbm != yes ; then
 837                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 838                 fi
 839         fi
 840 fi
 841
 842 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 843         AC_MSG_WARN(could not find suitable LDBM backend)
 844         if test $ol_enable_ldbm = yes ; then
 845                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 846         fi
 847
 848         AC_MSG_WARN(disabling LDBM)
 849         ol_enable_ldbm=no
 850 fi
 851
 852 if test $ol_enable_wrappers = yes ; then
 853         AC_CHECK_LIB(wrap, hosts_access,
 854                 [have_wrappers=yes], [have_wrappers=no])
 855
 856         if test $have_wrappers = yes ; then
 857                 AC_DEFINE(HAVE_TCPD)
 858                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 859         else
 860                 AC_MSG_WARN(could not find -lwrap)
 861                 if test $ol_enable_wrappers = yes ; then
 862                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 863                 fi
 864
 865                 AC_MSG_WARN(disabling wrappers support)
 866                 ol_enable_wrappers=no
 867         fi
 868
 869 fi
 870
 871 # ud needs termcap (should insert check here)
 872 ol_link_termcap=no
 873 AC_CHECK_HEADERS(termcap.h ncurses.h)
 874
 875 if test $ol_link_termcap = no ; then
 876         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 877         if test $have_termcap = yes ; then
 878                 AC_DEFINE(HAVE_TERMCAP)
 879                 ol_link_termcap=yes
 880                 TERMCAP_LIBS=-ltermcap
 881         fi
 882 fi
 883
 884 if test $ol_link_termcap = no ; then
 885         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 886         if test $have_ncurses = yes ; then
 887                 AC_DEFINE(HAVE_NCURSES)
 888                 ol_link_termcap=yes
 889                 TERMCAP_LIBS=-lncurses
 890         fi
 891 fi
 892
 893 if test $ol_link_termcap = no ; then
 894         AC_DEFINE(NO_TERMCAP,1)
 895         TERMCAP_LIBS=
 896 fi
 897
 898 # FreeBSD (and others) have crypt(3) in -lcrypt
 899 if test $ol_enable_crypt != no ; then
 900         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 901                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 902                         have_crypt=yes], [have_crypt=no])])
 903
 904         if test $have_crypt = yes ; then
 905                 AC_DEFINE(HAVE_CRYPT,1)
 906         else
 907                 AC_MSG_WARN(could not find crypt)
 908                 if test $ol_enable_crypt = yes ; then
 909                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 910                 fi
 911
 912                 AC_MSG_WARN(disabling crypt support)
 913                 ol_enable_crypt=no
 914         fi
 915 fi
 916
 917 # FreeBSD (and others) have setproctitle(3) in -lutil
 918 if test $ol_enable_proctitle != no ; then
 919         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 920                 AC_CHECK_LIB(util, setproctitle,
 921                         [have_setproctitle=yes
 922                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 923                         [have_setproctitle=no
 924                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 925
 926         if test $have_setproctitle = yes ; then
 927                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 928         fi
 929 fi
 930
 931 dnl ----------------------------------------------------------------
 932 dnl Checks for header files.
 933 AC_HEADER_STDC
 934
 935 if test $ac_cv_header_stdc != yes; then
 936         AC_MSG_WARN([could not Standard C compliant headers])
 937 fi
 938
 939 AC_HEADER_DIRENT
 940 AC_HEADER_SYS_WAIT
 941 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 942 if test $am_cv_sys_posix_termios = yes ; then
 943         AC_DEFINE(HAVE_POSIX_TERMIOS,1)
 944 fi
 945
 946 AC_CHECK_HEADERS(       \
 947         crypt.h                 \
 948         errno.h                 \
 949         fcntl.h                 \
 950         filio.h                 \
 951         getopt.h                \
 952         libutil.h               \
 953         limits.h                \
 954         malloc.h                \
 955         memory.h                \
 956         regex.h                 \
 957         psap.h                  \
 958         pwd.h                   \
 959         sgtty.h                 \
 960         stdarg.h                \
 961         stddef.h                \
 962         string.h                \
 963         strings.h               \
 964         sys/file.h              \
 965         sys/filio.h             \
 966         sys/errno.h             \
 967         sys/ioctl.h             \
 968         sys/param.h             \
 969         sys/resource.h  \
 970         sys/socket.h    \
 971         sys/syslog.h    \
 972         sys/time.h              \
 973         sys/types.h             \
 974         syslog.h                \
 975         termios.h               \
 976         unistd.h                \
 977 )
 978
 979 dnl ----------------------------------------------------------------
 980 dnl Checks for typedefs, structures, and compiler characteristics.
 981 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
 982 AC_TYPE_MODE_T
 983 AC_TYPE_OFF_T
 984 AC_TYPE_PID_T
 985 AM_TYPE_PTRDIFF_T
 986 AC_TYPE_SIGNAL
 987 AC_TYPE_SIZE_T
 988 AC_STRUCT_ST_BLKSIZE
 989 AC_HEADER_TIME
 990 AC_STRUCT_TM
 991
 992 OL_C_UPPER_LOWER
 993 AC_C_CONST
 994
 995 if test $cross_compiling = yes ; then
 996         AC_DEFINE(CROSS_COMPILING, 1)
 997 else
 998         AC_C_BIGENDIAN
 999         AC_CHECK_SIZEOF(short)
1000         AC_CHECK_SIZEOF(int)
1001         AC_CHECK_SIZEOF(long)
1002 fi
1003
1004 dnl ----------------------------------------------------------------
1005 dnl Checks for library functions.
1006 AC_FUNC_MEMCMP
1007 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1008 AC_FUNC_STRFTIME
1009 dnl AM_FUNC_STRTOD
1010 AC_FUNC_VPRINTF
1011
1012 if test $ac_cv_func_vprintf = yes ; then
1013         dnl check for vsnprintf
1014         AC_CHECK_FUNCS(vsnprintf)
1015 fi
1016
1017 AC_FUNC_WAIT3
1018
1019 AC_CHECK_FUNCS(         \
1020         bcopy                   \
1021         flock                   \
1022         getdtablesize   \
1023         gethostname             \
1024         getpwuid                \
1025         gettimeofday    \
1026         lockf                   \
1027         memcpy                  \
1028         memmove                 \
1029         mkstemp                 \
1030         res_search              \
1031         select                  \
1032         setpwfile               \
1033         setsid                  \
1034         signal                  \
1035         sigset                  \
1036         snprintf                \
1037         socket                  \
1038         strerror                \
1039         strpbrk                 \
1040         strrchr                 \
1041         strsep                  \
1042         strstr                  \
1043         strtok                  \
1044         strtol                  \
1045         strtoul                 \
1046         sysconf                 \
1047         waitpid                 \
1048 )
1049
1050 dnl We actually may need to replace more than this.
1051 AC_REPLACE_FUNCS(getopt strdup tempnam)
1052
1053 dnl ----------------------------------------------------------------
1054 # Check Configuration
1055 OL_SYS_ERRLIST
1056
1057 dnl ----------------------------------------------------------------
1058 dnl Sort out defines
1059
1060 if test $ol_enable_debug != no ; then
1061         AC_DEFINE(LDAP_DEBUG,1)
1062 fi
1063 dnl     if test $ol_enable_syslog != no ; then
1064 dnl             AC_DEFINE(LDAP_SYSLOG,1)
1065 dnl     fi
1066 if test $ol_enable_libui = yes ; then
1067         AC_DEFINE(LDAP_LIBUI,1)
1068 fi
1069 if test $ol_enable_cache = no ; then
1070         AC_DEFINE(LDAP_NOCACHE,1)
1071 fi
1072 if test $ol_enable_dns != no ; then
1073         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_API_VENDOR_VERSION,1)
1074 fi
1075 if test $ol_enable_proctitle != no ; then
1076         AC_DEFINE(LDAP_PROCTITLE,1)
1077 fi
1078 if test $ol_enable_referrals != no ; then
1079         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_API_VENDOR_VERSION,1)
1080 fi
1081 if test $ol_enable_cldap != no ; then
1082         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1083 fi
1084
1085 if test $ol_enable_aclgroups != no ; then
1086         AC_DEFINE(SLAPD_ACLGROUPS,1)
1087 fi
1088 if test $ol_enable_crypt != no ; then
1089         AC_DEFINE(SLAPD_CRYPT,1)
1090 fi
1091 if test $ol_enable_md5 != no ; then
1092         AC_DEFINE(SLAPD_MD5,1)
1093 fi
1094 if test $ol_enable_sha1 != no ; then
1095         AC_DEFINE(SLAPD_SHA1,1)
1096 fi
1097 if test $ol_enable_phonetic != no ; then
1098         AC_DEFINE(SLAPD_PHONETIC,1)
1099 fi
1100 if test $ol_enable_rlookups != no ; then
1101         AC_DEFINE(SLAPD_RLOOKUPS,1)
1102 fi
1103
1104 if test $ol_link_ldbm != no ; then
1105         AC_DEFINE(SLAPD_LDBM,1)
1106         BUILD_SLAPD=yes
1107         BUILD_LDBM=yes
1108 fi
1109
1110 if test $ol_enable_passwd != no ; then
1111         AC_DEFINE(SLAPD_PASSWD,1)
1112         BUILD_SLAPD=yes
1113         BUILD_PASSWD=yes
1114 fi
1115
1116 if test $ol_enable_shell != no ; then
1117         AC_DEFINE(SLAPD_SHELL,1)
1118         BUILD_SLAPD=yes
1119         BUILD_SHELL=yes
1120 fi
1121
1122 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
1123         $BUILD_SLAPD = yes ; then
1124         BUILD_SLURPD=yes
1125 fi
1126
1127 if test $ol_link_isode != no ; then
1128         BUILD_LDAPD=yes
1129 fi
1130
1131 dnl ----------------------------------------------------------------
1132
1133 AC_SUBST(BUILD_LDAPD)
1134 AC_SUBST(BUILD_SLAPD)
1135   AC_SUBST(BUILD_LDBM)
1136   AC_SUBST(BUILD_PASSWD)
1137   AC_SUBST(BUILD_SHELL)
1138 AC_SUBST(BUILD_SLURPD)
1139
1140
1141 AC_SUBST(LDAP_LIBS)
1142 AC_SUBST(LDAPD_LIBS)
1143 AC_SUBST(SLAPD_LIBS)
1144 AC_SUBST(SLURPD_LIBS)
1145 AC_SUBST(LDBM_LIBS)
1146 AC_SUBST(LTHREAD_LIBS)
1147 AC_SUBST(LUTIL_LIBS)
1148
1149 AC_SUBST(KRB_LIBS)
1150 AC_SUBST(TERMCAP_LIBS)
1151
1152 dnl ----------------------------------------------------------------
1153 dnl final output
1154 dnl
1155
1156 AC_OUTPUT( \
1157 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1158 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1159 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1160 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1161 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1162 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1163 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1164 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1165 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1166 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1167 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1168 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1169 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1170 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1171 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1172 include/Makefile:build/top.mk:include/Makefile.in \
1173 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1174 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1175 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1176 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1177 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1178 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1179 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk:build/lib-static.mk    \
1180 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1181 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1182 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1183 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1184 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1185 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1186 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1187 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1188 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1189 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1190 tests/Makefile:build/top.mk:tests/Makefile.in \
1191 ,[
1192 date > stamp-h
1193 echo Please \"make depend\" to build dependencies
1194 ])