git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Configure.in for OpenLDAP
  11 AC_INIT(include/ldap.h)dnl
  12 AC_CONFIG_AUX_DIR(build)dnl
  13 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no ac_define])dnl
  14
  15 dnl We use autoconf features new to 2.13.
  16 dnl     aclocal.m4 should be built using aclocal from automake 1.4
  17 AC_PREREQ(2.13)dnl Required Autoconf version
  18
  19 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  20
  21 dnl
  22 dnl Start Args
  23 AC_MSG_CHECKING(configure arguments)
  24 AC_PREFIX_DEFAULT(/usr/local)
  25
  26 top_builddir=`pwd`
  27 AC_SUBST(top_builddir)dnl
  28
  29 ldap_subdir="openldap"
  30
  31 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  32         if test "$withval" = "no"; then
  33                 ldap_subdir=""
  34         elif test "$withval" != "yes"; then
  35                 ldap_subdir="$withval"
  36         fi
  37 ])dnl
  38
  39 AC_SUBST(ldap_subdir)dnl
  40
  41 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  42 ol_enable_syslog=no
  43 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  44 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  45 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  46 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  47 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  48 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  49 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  50         no, [yes no])dnl
  51
  52 dnl General "with" options
  53 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  54
  55 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  56         auto, [auto k5 k4 afs yes no])
  57 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  58         auto, [auto yes no] )
  59 OL_ARG_WITH(threads,[  --with-threads   use threads],
  60         auto, [auto posix mach lwp yes no manual] )
  61 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  62         auto, [auto ssleay openssl yes no] )
  63 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  64         auto, [auto yes no manual] )
  65
  66 dnl Server options
  67
  68 dnl LDAPD OPTIONS
  69 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  70 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  71
  72 dnl SLAPD OPTIONS
  73 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  74 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  75 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  76 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  77 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  78 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  79 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  80 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  81
  82 dnl SLAPD Backend options
  83 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
  84 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  85 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  86         [auto db2 db gdbm ndbm manual])
  87 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  88         [auto btree hash])
  89
  90 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  91 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
  92 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  93 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
  94
  95 dnl SLURPD OPTIONS
  96 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  97 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  98
  99 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 100 AM_ENABLE_STATIC
 101 dnl AM_DISABLE_SHARED
 102 AM_ENABLE_SHARED
 103
 104 dnl General "enable" options
 105 # validate options
 106 if test $ol_enable_dns = yes ; then
 107         if test $ol_enable_referrals = no ; then
 108                 AC_MSG_ERROR([DNS requires --enable-referrals])
 109         fi
 110         if test $ol_enable_referrals = auto ; then
 111                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 112                 ol_enable_referrals=yes
 113         fi
 114 fi
 115
 116 if test $ol_enable_slapd = no ; then
 117         dnl SLAPD was specificallly disabled
 118         if test $ol_enable_bdb2 = yes ; then
 119                 AC_MSG_WARN([slapd disabled, ignoring --enable_bdb2 argument])
 120         fi
 121         if test $ol_enable_ldbm = yes ; then
 122                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 123         fi
 124         if test $ol_enable_passwd = yes ; then
 125                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 126         fi
 127         if test $ol_enable_perl = yes ; then
 128                 AC_MSG_WARN([slapd disabled, ignoring --enable_perl argument])
 129         fi
 130         if test $ol_enable_shell = yes ; then
 131                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 132         fi
 133         if test $ol_enable_tcl = yes ; then
 134                 AC_MSG_WARN([slapd disabled, ignoring --enable_tcl argument])
 135         fi
 136         if test $ol_enable_aclgroups = yes ; then
 137                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 138         fi
 139         if test $ol_enable_wrappers = yes ; then
 140                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 141         fi
 142         if test $ol_enable_phonetic = yes ; then
 143                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 144         fi
 145         if test $ol_enable_rlookups = yes ; then
 146                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 147         fi
 148         if test $ol_with_ldbm_api != auto ; then
 149                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 150         fi
 151         if test $ol_with_ldbm_type != auto ; then
 152                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 153         fi
 154         if test $ol_enable_slurpd = yes ; then
 155                 AC_MSG_ERROR([slurpd requires slapd])
 156         fi
 157
 158         # force settings to no
 159         ol_enable_bdb2=no
 160         ol_enable_ldbm=no
 161         ol_enable_passwd=no
 162         ol_enable_perl=no
 163         ol_enable_shell=no
 164         ol_enable_tcl=no
 165         ol_enable_aclgroups=no
 166         ol_enable_wrappers=no
 167         ol_enable_phonetic=no
 168         ol_enable_rlookups=no
 169         ol_with_ldbm_api=no
 170         ol_with_ldbm_type=no
 171         ol_enable_slurpd=no
 172
 173 elif test $ol_enable_ldbm = no ; then
 174         dnl SLAPD without LDBM
 175
 176         if test $ol_with_ldbm_api != auto ; then
 177                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 178         fi
 179
 180         if test $ol_with_ldbm_type != auto ; then
 181                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 182         fi
 183
 184         if test $ol_enable_bdb2 = yes ; then
 185                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 186         fi
 187
 188         if test $ol_enable_passwd = no -a \
 189                 $ol_enable_perl = no -a \
 190                 $ol_enable_shell = no -a \
 191                 $ol_enable_tcl = no ; then
 192                 AC_MSG_ERROR([slapd requires a backend])
 193         fi
 194
 195         ol_with_ldbm_api=no
 196         ol_with_ldbm_type=no
 197
 198 elif test $ol_enable_bdb2 = yes ; then
 199         dnl SLAPD with BDB2
 200
 201         if test $ol_with_ldbm_api != auto -a \
 202                 $ol_with_ldbm_api != db2 ; then
 203                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 204         fi
 205
 206         ol_with_ldbm_api=db2
 207
 208 else
 209         dnl SLAPD with LDBM
 210
 211         if test $ol_enable_bdb2 != no ; then
 212                 if test $ol_with_ldbm_api != auto -a \
 213                         $ol_with_ldbm_api != db2 ; then
 214                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 215                         ol_enable_bdb2=no
 216                 fi
 217         fi
 218
 219         if test $ol_with_ldbm_api = gdbm -a \
 220                 $ol_with_ldbm_type = btree ; then
 221                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 222         fi
 223         if test $ol_with_ldbm_api = ndbm -a \
 224                 $ol_with_ldbm_type = btree ; then
 225                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 226         fi
 227 fi
 228
 229 if test $ol_enable_slurpd = yes ; then
 230         dnl SLURPD was specifically enabled
 231         if test $ol_with_threads = no ; then
 232                 AC_MSG_ERROR([slurpd requires threads])
 233         fi
 234 fi
 235
 236 AC_MSG_RESULT(done)
 237
 238 ## Initialize vars
 239 LDAP_LIBS=
 240 LDBM_LIBS=
 241 LTHREAD_LIBS=
 242 LUTIL_LIBS=
 243
 244 LDAPD_LIBS=
 245 SLAPD_LIBS=
 246 SLURPD_LIBS=
 247
 248 BUILD_LDAPD=no
 249 BUILD_SLAPD=no
 250 BUILD_SLURPD=no
 251
 252 BUILD_BDB2=no
 253 BUILD_LDBM=no
 254 BUILD_PASSWD=no
 255 BUILD_PERL=no
 256 BUILD_SHELL=no
 257 BUILD_TCL=no
 258 BUILD_THREAD=no
 259
 260 SLAPD_PERL_LDFLAGS=
 261 SLAPD_PERL_CPPFLAGS=
 262
 263 KRB_LIBS=
 264 READLINE_LIBS=
 265 TERMCAP_LIBS=
 266 TLS_LIBS=
 267
 268 dnl ----------------------------------------------------------------
 269 dnl Checks for programs
 270
 271 AC_PROG_INSTALL
 272
 273 dnl The default compiler is cc (NOT gcc)
 274 CC=${CC-"cc"}
 275 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 276 dnl CFLAGS=${CFLAGS-""}
 277
 278 AM_PROG_LIBTOOL
 279 dnl AC_PROG_MAKE_SET
 280
 281 AC_PROG_AWK
 282 OL_PROG_LN_H
 283 AC_PROG_LN_S
 284
 285 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 286         LN_S="$LN_H"
 287 fi
 288
 289 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 290         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 291 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 292 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 293
 294 if test $ol_enable_perl = yes ; then
 295         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 296
 297         if test "no$PERLBIN" = "no" ; then
 298                 ol_enable_perl=no
 299         fi
 300
 301         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 302         SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e perl_inc`"
 303 fi
 304
 305 AC_PROG_CPP
 306
 307 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 308         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 309
 310 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 311         AC_MSG_WARN([programs compiled here do run here...])
 312         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 313
 314 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 315         AC_MSG_WARN([programs compiled here do not run here...])
 316         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 317 fi
 318
 319 dnl Checks for UNIX Variants
 320 AC_AIX
 321 AC_ISC_POSIX
 322 AC_MINIX
 323
 324 dnl BeOS requires -lbe -lroot
 325 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot"], :, [-lroot])
 326
 327 dnl Checks for system services
 328 AC_CYGWIN
 329 AC_MINGW32
 330 AC_EXEEXT
 331 AC_OBJEXT
 332
 333 dnl OpenLDAP requires STDC features
 334 AM_PROG_CC_STDC
 335 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 336         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 337 fi
 338
 339 dnl AM_C_PROTOTYPES
 340
 341 dnl Checks for libraries
 342
 343 dnl Find socket()
 344 dnl Likely combinations:
 345 dnl             -lsocket [ -lnsl_s | -lnsl ]
 346 dnl             -linet
 347
 348 AC_CHECK_FUNC(socket, [have_socket=yes], [
 349 dnl
 350 dnl hopefully we won't include too many libraries
 351 dnl
 352         AC_CHECK_LIB(socket, main)
 353         AC_CHECK_LIB(net, main)
 354         AC_CHECK_LIB(nsl_s, main)
 355         AC_CHECK_LIB(nsl, main)
 356         AC_CHECK_LIB(inet, socket)
 357         AC_CHECK_LIB(gen, main)
 358 ])
 359
 360 dnl Check for resolver routines
 361 AC_CHECK_FUNCS(res_search)
 362 if test $ac_cv_func_res_search = "no" ; then
 363         AC_CHECK_LIB(bind, res_search)
 364         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 365                 AC_DEFINE(HAVE_RES_SEARCH,1)
 366         else
 367                 AC_CHECK_LIB(resolv, res_search)
 368                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 369                         AC_DEFINE(HAVE_RES_SEARCH,1)
 370                 fi
 371         fi
 372 fi
 373
 374 dnl HP-UX requires -lV3
 375 AC_CHECK_LIB(V3, sigset)
 376
 377 # ISODE tests
 378 ol_link_isode=no
 379 if test $ol_enable_ldapd != no ; then
 380         dnl look for ISODE libraries
 381         AC_CHECK_LIB(xtpp, main, [
 382                 ol_link_isode=yes
 383                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 384                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 385                 ],:,[-lxtdsap -lxtisode -losi])
 386         AC_CHECK_LIB(dsap, main, [
 387                 ol_link_isode=yes
 388                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 389                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 390                 ],:,[-lisode])
 391         AC_CHECK_LIB(isode, main, [
 392                 ol_link_isode=yes
 393                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 394                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 395                 ],:)
 396 fi
 397
 398 if test $ol_link_isode != no; then
 399         AC_CHECK_LIB(pp, main, [
 400                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 401                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 402                 ],:)
 403
 404         AC_PATH_PROG(PEPSY, pepsy)
 405 fi
 406
 407 dnl
 408 dnl check for kerberos
 409 dnl
 410 ol_link_kerberos=no
 411
 412 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 413         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 414
 415         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 416                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 417                         [-lkrb5 -ldes425])
 418
 419                 if test $have_k5 = yes ; then
 420                         ol_with_kerberos=found
 421                         ol_link_kerberos=yes
 422
 423                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 424
 425                         LIBS="$KRB_LIBS $LIBS"
 426
 427                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 428                                 [ol_cv_var_des_debug], [
 429                                 dnl save the flags
 430                                 save_LIBS="$LIBS"
 431                                 LIBS="$KRB_LIBS $LIBS"
 432                                 AC_TRY_LINK([
 433 #include <kerberosIV/krb.h>
 434 #include <kerberosIV/des.h>
 435 extern int des_debug;
 436 ],[
 437 des_debug = 1;
 438 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 439                                 dnl restore the LIBS
 440                                 LIBS="$save_LIBS"
 441                         ])
 442
 443                         if test $ol_cv_var_des_debug = yes ; then
 444                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 445                                         [define if you have Kerberos des_debug])
 446                         fi
 447
 448                         LIBS="$save_LIBS"
 449                 fi
 450         fi
 451 fi
 452
 453 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 454         AC_CHECK_HEADERS(krb.h des.h)
 455
 456         if test $ac_cv_header_krb_h = yes ; then
 457                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 458
 459                 if test $have_k4 = yes ; then
 460                         ol_with_kerberos=found
 461                         ol_link_kerberos=yes
 462
 463                         KRB_LIBS="-lkrb -ldes"
 464                 fi
 465         fi
 466 fi
 467
 468 if test $ol_link_kerberos = yes ; then
 469         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 470 fi
 471
 472 dnl
 473 dnl Check for SSL/TLS
 474 dnl
 475 ol_link_tls=no
 476 if test $ol_with_tls != no ; then
 477
 478         AC_CHECK_HEADERS(ssl.h)
 479
 480         if test $ac_cv_header_ssl_h = yes ; then
 481                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 482                         [have_ssleay=yes
 483                         need_rsaref=no],
 484                         [have_ssleay=no],
 485                         [-lcrypto])
 486
 487                 if test $have_ssleay = no ; then
 488                         AC_CHECK_LIB(ssl, ssl3_accept,
 489                                 [have_ssleay=yes
 490                                 need_rsaref=yes], [have_ssleay=no],
 491                                 [-lcrypto -lRSAglue -lrsaref])
 492                 fi
 493
 494                 if test $have_ssleay = yes ; then
 495                         ol_with_tls=found
 496                         ol_link_tls=yes
 497
 498                         AC_DEFINE(HAVE_SSLEAY, 1,
 499                                 [define if you have SSLeay or OpenSSL])
 500
 501                         if test $need_rsaref = yes; then
 502                                 AC_DEFINE(HAVE_RSAREF, 1,
 503                                         [define if you have RSAref])
 504
 505                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 506                         else
 507                                 TLS_LIBS="-lssl -lcrypto"
 508                         fi
 509                 fi
 510         fi
 511 fi
 512
 513 if test $ol_link_tls = yes ; then
 514         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 515 fi
 516
 517 dnl Tests for reentrant functions necessary to build a
 518 dnl thread_safe -lldap.
 519 AC_CHECK_FUNCS(         \
 520         ctime_r                 \
 521         gethostbyname_r gethostbyaddr_r \
 522 )
 523
 524 if test "$ac_cv_func_ctime_r" = no ; then
 525         ol_cv_func_ctime_r_nargs=0
 526 else
 527         OL_FUNC_CTIME_R_NARGS
 528 dnl     OL_FUNC_CTIME_R_TYPE
 529 fi
 530
 531 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 532         OL_FUNC_GETHOSTBYNAME_R_NARGS
 533 else
 534         ol_cv_func_gethostbyname_r_nargs=0
 535 fi
 536
 537 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 538         OL_FUNC_GETHOSTBYADDR_R_NARGS
 539 else
 540         ol_cv_func_gethostbyaddr_r_nargs=0
 541 fi
 542
 543 if test "$ac_cv_func_ctime_r" = yes \
 544         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 545         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 546         -a "$ac_cv_func_gethostbyname_r" = yes \
 547         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 548         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 549         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 550         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 551         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 552         ; then
 553
 554         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 555 fi
 556
 557 ol_link_threads=no
 558 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 559         -o $ol_with_threads = posix ; then
 560
 561         AC_CHECK_HEADERS(pthread.h sched.h)
 562
 563         if test $ac_cv_header_pthread_h = yes ; then
 564                 OL_POSIX_THREAD_VERSION
 565
 566                 if test $ol_cv_pthread_version = final ; then
 567                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 568                                 [define if pthreads API compatible with final spec])
 569                 elif test $ol_cv_pthread_version = draft4 ; then
 570                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 571                                 [define if pthreads API compatible with draft4 spec])
 572                 else
 573                         AC_MSG_ERROR([unknown pthread version])
 574                 fi
 575
 576                 # consider threads found
 577                 ol_with_threads=found
 578
 579                 OL_LINUX_THREADS
 580
 581                 if test $ol_cv_linux_threads = yes ; then
 582                         AC_DEFINE(HAVE_LINUX_THREADS,1,
 583                                 [define if you have LinuxThreads])
 584                 fi
 585
 586                 dnl Now the hard part, how to link?
 587                 dnl
 588                 dnl currently supported checks:
 589                 dnl
 590                 dnl Check for no flags
 591                 dnl     pthread_create() in $LIBS
 592                 dnl
 593                 dnl Check special pthread (final) flags
 594                 dnl     pthread_create() with -mt (Solaris)
 595                 dnl     pthread_create() with -kthread (FreeBSD)
 596                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 597                 dnl     pthread_create() with -pthreads (?)
 598                 dnl     pthread_create() with -thread (?)
 599                 dnl
 600                 dnl Check pthread (final) libraries
 601                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 602                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 603                 dnl     pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 604                 dnl     pthread_create() in -lpthread (many)
 605                 dnl     pthread_create() in -lc_r (FreeBSD)
 606                 dnl     pthread_create() in -lpthreads (many)
 607                 dnl     pthread_join() -Wl,-woff,85 -lpthreads (IRIX)
 608                 dnl
 609                 dnl Check pthread (draft4) flags (depreciated)
 610                 dnl     pthread_create() with -threads (OSF/1)
 611                 dnl
 612                 dnl Check pthread (final) libraries (depreciated)
 613                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 614                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 615                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 616                 dnl
 617
 618                 dnl pthread_create in $LIBS
 619                 AC_MSG_CHECKING([for pthread_create in default libraries])
 620                 AC_CACHE_VAL(ol_cv_pthread_create,[
 621                 AC_TRY_RUN([
 622 #include <pthread.h>
 623 #ifndef NULL
 624 #define NULL (void*)0
 625 #endif
 626
 627 static void *task(p)
 628         void *p;
 629 {
 630         return (void *) (p == NULL);
 631 }
 632
 633 int main(argc, argv)
 634         int argc;
 635         char **argv;
 636 {
 637         pthread_t t;
 638 #if HAVE_PTHREADS_D4
 639         exit(pthread_create(&t, pthread_attr_default, task, NULL));
 640 #else
 641         exit(pthread_create(&t, NULL, task, NULL));
 642 #endif
 643 }
 644 ],
 645                         [ol_cv_pthread_create=yes],
 646                         [ol_cv_pthread_create=no],
 647                         [dnl assume yes
 648                         ol_cv_pthread_create=yes])])
 649                 AC_MSG_RESULT($ol_cv_pthread_create)
 650
 651                 if test $ol_cv_pthread_create != no ; then
 652                         ol_link_threads=posix
 653                 fi
 654
 655                 if test $ol_link_threads = no ; then
 656                         dnl try -mt
 657                         AC_CACHE_CHECK([for pthread_create with -mt],
 658                                 [ol_cv_thread_flag], [
 659                                 dnl save the flags
 660                                 save_LIBS="$LIBS"
 661                                 LIBS="-mt $LIBS"
 662                                 AC_TRY_LINK([char pthread_create();],
 663                                         [pthread_create();],
 664                                         [ol_cv_thread_flag=yes], [ol_cv_thread_flag=no])
 665                                 dnl restore the LIBS
 666                                 LIBS="$save_LIBS"
 667                         ])
 668
 669                         if test $ol_cv_thread_flag = yes ; then
 670                                 LTHREAD_LIBS="$LTHREAD_LIBS -mt"
 671                                 ol_link_threads=posix
 672                         fi
 673                 fi
 674
 675                 if test $ol_link_threads = no ; then
 676                         dnl try -kthread
 677                         AC_CACHE_CHECK([for pthread_create with -kthread],
 678                                 [ol_cv_kthread_flag], [
 679                                 dnl save the flags
 680                                 save_LIBS="$LIBS"
 681                                 LIBS="-kthread $LIBS"
 682                                 AC_TRY_LINK([#include <pthread.h>],[
 683 #if HAVE_PTHREADS_D4
 684         pthread_create(NULL,pthread_attr_default,NULL,NULL);
 685 #else
 686         pthread_create(NULL,NULL,NULL,NULL);
 687 #endif
 688 ],
 689                                         [ol_cv_kthread_flag=yes], [ol_cv_kthread_flag=no])
 690                                 dnl restore the LIBS
 691                                 LIBS="$save_LIBS"
 692                         ])
 693
 694                         if test $ol_cv_kthread_flag = yes ; then
 695                                 LTHREAD_LIBS="$LTHREAD_LIBS -kthread"
 696                                 ol_link_threads=posix
 697                         fi
 698                 fi
 699
 700                 if test $ol_link_threads = no ; then
 701                         dnl try -pthread
 702                         AC_CACHE_CHECK([for pthread_create with -pthread],
 703                                 [ol_cv_pthread_flag], [
 704                                 dnl save the flags
 705                                 save_LIBS="$LIBS"
 706                                 LIBS="-pthread $LIBS"
 707                                 AC_TRY_LINK([#include <pthread.h>],[
 708 #if HAVE_PTHREADS_D4
 709         pthread_create(NULL,pthread_attr_default,NULL,NULL);
 710 #else
 711         pthread_create(NULL,NULL,NULL,NULL);
 712 #endif
 713 ],
 714                                         [ol_cv_pthread_flag=yes], [ol_cv_pthread_flag=no])
 715                                 dnl restore the LIBS
 716                                 LIBS="$save_LIBS"
 717                         ])
 718
 719                         if test $ol_cv_pthread_flag = yes ; then
 720                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 721                                 ol_link_threads=posix
 722                         fi
 723                 fi
 724
 725                 if test $ol_link_threads = no ; then
 726                         dnl try -pthreads
 727                         AC_CACHE_CHECK([for pthread_create with -pthreads],
 728                                 [ol_cv_pthreads_flag], [
 729                                 dnl save the flags
 730                                 save_LIBS="$LIBS"
 731                                 LIBS="-pthreads $LIBS"
 732                                 AC_TRY_LINK([#include <pthread.h>],[
 733 #if HAVE_PTHREADS_D4
 734         pthread_create(NULL,pthread_attr_default,NULL,NULL);
 735 #else
 736         pthread_create(NULL,NULL,NULL,NULL);
 737 #endif
 738 ],
 739                                         [ol_cv_pthreads_flag=yes], [ol_cv_pthreads_flag=no])
 740                                 dnl restore the LIBS
 741                                 LIBS="$save_LIBS"
 742                         ])
 743
 744                         if test $ol_cv_pthreads_flag = yes ; then
 745                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthreads"
 746                                 ol_link_threads=posix
 747                         fi
 748                 fi
 749
 750                 if test $ol_link_threads = no ; then
 751                         dnl try -thread
 752                         AC_CACHE_CHECK([for pthread_create with -thread],
 753                                 [ol_cv_thread_flag], [
 754                                 dnl save the flags
 755                                 save_LIBS="$LIBS"
 756                                 LIBS="-thread $LIBS"
 757                                 AC_TRY_LINK([char pthread_create();],
 758                                         [pthread_create();],
 759                                         [ol_cv_thread_flag=yes], [ol_cv_thread_flag=no])
 760                                 dnl restore the LIBS
 761                                 LIBS="$save_LIBS"
 762                         ])
 763
 764                         if test $ol_cv_thread_flag = yes ; then
 765                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 766                                 ol_link_threads=posix
 767                         fi
 768                 fi
 769
 770                 if test $ol_link_threads = no ; then
 771                         dnl try DEC Threads -lpthread -lmach -lexc -lc_r
 772                         save_LIBS="$LIBS"
 773                         AC_CHECK_LIB(pthread, pthread_mutex_unlock, [
 774                                 ol_link_threads=posix
 775                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc -lc_r"
 776                                 if test $ol_with_yielding_select = auto ; then
 777                                         ol_with_yielding_select=yes
 778                                 fi
 779                                 ],:,[-lmach -lexc -lc_r])
 780                         LIBS="$save_LIBS"
 781                 fi
 782
 783                 if test $ol_link_threads = no ; then
 784                         dnl try DEC Threads -lpthread -lmach -lexc
 785                         save_LIBS="$LIBS"
 786                         AC_CHECK_LIB(pthread, pthread_mutex_lock, [
 787                                 ol_link_threads=posix
 788                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc"
 789                                 if test $ol_with_yielding_select = auto ; then
 790                                         ol_with_yielding_select=yes
 791                                 fi
 792                                 ],:,[-lmach -lexc])
 793                         LIBS="$save_LIBS"
 794                 fi
 795
 796                 if test $ol_link_threads = no ; then
 797                         dnl try DEC Threads -lpthread -lexc
 798                         save_LIBS="$LIBS"
 799                         AC_CHECK_LIB(pthread, pthread_mutex_trylock, [
 800                                 ol_link_threads=posix
 801                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 802                                 if test $ol_with_yielding_select = auto ; then
 803                                         ol_with_yielding_select=yes
 804                                 fi
 805                                 ],:,[-lexc])
 806                         LIBS="$save_LIBS"
 807                 fi
 808
 809                 if test $ol_link_threads = no ; then
 810                         dnl try -lpthread
 811                         save_LIBS="$LIBS"
 812                         AC_CHECK_LIB(pthread, pthread_create, [
 813                                 ol_link_threads=posix
 814                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"],:)
 815                         LIBS="$save_LIBS"
 816                 fi
 817
 818                 if test $ol_link_threads = no ; then
 819                         dnl try -lc_r
 820                         save_LIBS="$LIBS"
 821                         AC_CHECK_LIB(c_r, pthread_create, [
 822                                 ol_link_threads=posix
 823                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"],:)
 824                         LIBS="$save_LIBS"
 825                 fi
 826
 827                 if test $ol_link_threads = no ; then
 828                         dnl try -lpthreads
 829                         save_LIBS="$LIBS"
 830                         AC_CHECK_LIB(pthreads, pthread_create, [
 831                                 ol_link_threads=posix
 832                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"],:)
 833                         LIBS="$save_LIBS"
 834                 fi
 835
 836                 dnl IRIX Pthread check
 837                 if test $ol_link_threads = no ; then
 838                         dnl try IRIX Pthreads -Wl,-woff,85 -lpthreads
 839                         save_LIBS="$LIBS"
 840                         AC_CHECK_LIB(pthreads, pthread_join, [
 841                                 ol_link_threads=posix
 842                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"
 843                                 ],:,[-Wl,-woff,85])
 844                         LIBS="$save_LIBS"
 845                 fi
 846
 847                 if test $ol_link_threads = no ; then
 848                         dnl try -threads
 849                         AC_CACHE_CHECK([for pthread_create with -threads],
 850                                 [ol_cv_thread_flag], [
 851                                 dnl save the flags
 852                                 save_LIBS="$LIBS"
 853                                 LIBS="-threads $LIBS"
 854                                 AC_TRY_LINK([char pthread_create();],[
 855                                         pthread_create();
 856                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 857                                 dnl restore the LIBS
 858                                 LIBS="$save_LIBS"
 859                         ])
 860
 861                         if test $ol_cv_thread_flag = yes ; then
 862                                 LTHREAD_LIBS="$LTHREAD_LIBS -threads"
 863                                 ol_link_threads=posix
 864                         fi
 865                 fi
 866
 867                 if test $ol_link_threads = no ; then
 868                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 869                         save_LIBS="$LIBS"
 870                         AC_CHECK_LIB(pthreads, pthread_mutex_unlock, [
 871                                 ol_link_threads=posix
 872                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 873                                 if test $ol_with_yielding_select = auto ; then
 874                                         ol_with_yielding_select=yes
 875                                 fi
 876                                 ],:,[-lmach -lexc -lc_r])
 877                         LIBS="$save_LIBS"
 878                 fi
 879
 880                 if test $ol_link_threads = no ; then
 881                         dnl try DEC Threads -lpthreads -lmach -lexc
 882                         save_LIBS="$LIBS"
 883                         AC_CHECK_LIB(pthreads, pthread_mutex_lock, [
 884                                 ol_link_threads=posix
 885                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc"
 886                                 if test $ol_with_yielding_select = auto ; then
 887                                         ol_with_yielding_select=yes
 888                                 fi
 889                                 ],:,[-lmach -lexc])
 890                         LIBS="$save_LIBS"
 891                 fi
 892
 893                 if test $ol_link_threads = no ; then
 894                         dnl try DEC Threads -lpthreads -lexc
 895                         save_LIBS="$LIBS"
 896                         AC_CHECK_LIB(pthreads, pthread_mutex_trylock, [
 897                                 ol_link_threads=posix
 898                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lexc"
 899                                 if test $ol_with_yielding_select = auto ; then
 900                                         ol_with_yielding_select=yes
 901                                 fi
 902                                 ],:,[-lexc])
 903                         LIBS="$save_LIBS"
 904                 fi
 905
 906                 if test $ol_link_threads != no ; then
 907                         AC_DEFINE(HAVE_PTHREADS,1,
 908                                 [define if you have POSIX Threads])
 909
 910                         dnl save flags
 911                         save_CPPFLAGS="$CPPFLAGS"
 912                         save_LIBS="$LIBS"
 913                         LIBS="$LTHREAD_LIBS $LIBS"
 914
 915                         dnl All POSIX Thread (final) implementations should have
 916                         dnl sched_yield instead of pthread yield.
 917                         dnl check for both
 918                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 919
 920                         if test $ac_cv_func_sched_yield = no -a \
 921                                 $ac_cv_func_pthread_yield = no ; then
 922                                 dnl Digital UNIX has sched_yield() in -lrt
 923                                 AC_CHECK_LIB(rt, sched_yield,
 924                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 925                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 926                                         ac_cv_func_sched_yield=yes],
 927                                         [ac_cv_func_sched_yield=no])
 928                         fi
 929                         if test $ac_cv_func_sched_yield = no -a \
 930                                 $ac_cv_func_pthread_yield = no ; then
 931                                 dnl Solaris has sched_yield() in -lposix4
 932                                 dnl but we'll use thr_yield instead.
 933                                 AC_CHECK_FUNCS(thr_yield)
 934                         fi
 935                         if test $ac_cv_func_sched_yield = no -a \
 936                                 $ac_cv_func_pthread_yield = no -a \
 937                                 "$ac_cv_func_thr_yield" = no ; then
 938                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 939                         fi
 940
 941                         dnl Check functions for compatibility
 942                         AC_CHECK_FUNCS(pthread_kill)
 943
 944                         dnl Check for pthread_detach with <pthread.h> inclusion
 945                         dnl as it's symbol may have been mangled.
 946                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
 947                                 [ol_cv_func_pthread_detach], [
 948                                 dnl save the flags
 949                                 AC_TRY_LINK([
 950 #include <pthread.h>
 951 #ifndef NULL
 952 #define NULL (void*)0
 953 #endif
 954 ],
 955                                         [pthread_detach(NULL);],
 956                                         [ol_cv_func_pthread_detach=yes],
 957                                         [ol_cv_func_pthread_detach=no])
 958                         ])
 959
 960                         if test $ol_cv_func_pthread_detach = no ; then
 961                                 AC_MSG_ERROR([could not locate pthread_detach()])
 962                         fi
 963
 964                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
 965                                 [define if you have pthread_detach function])
 966
 967                         dnl Check for setconcurreny functions
 968                         AC_CHECK_FUNCS( \
 969                                 pthread_setconcurrency \
 970                                 pthread_getconcurrency \
 971                                 thr_setconcurrency \
 972                                 thr_getconcurrency \
 973                         )
 974
 975                         AC_MSG_CHECKING([if pthread_create() works])
 976                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 977                         AC_TRY_RUN([
 978 #include <pthread.h>
 979 #ifndef NULL
 980 #define NULL (void*)0
 981 #endif
 982
 983 static void *task(p)
 984         void *p;
 985 {
 986         return (void *) (p == NULL);
 987 }
 988
 989 int main(argc, argv)
 990         int argc;
 991         char **argv;
 992 {
 993         pthread_t t;
 994 #if HAVE_PTHREADS_D4
 995         exit(pthread_create(&t, pthread_attr_default, task, NULL));
 996 #else
 997         exit(pthread_create(&t, NULL, task, NULL));
 998 #endif
 999 }
1000 ],
1001                                 [ol_cv_pthread_create_works=yes],
1002                                 [ol_cv_pthread_create_works=no],
1003                                 [dnl assume yes
1004                                 ol_cv_pthread_create_works=yes])])
1005                         AC_MSG_RESULT($ol_cv_pthread_create_works)
1006
1007                         if test $ol_cv_pthread_create_works = no ; then
1008                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1009                         fi
1010
1011                         dnl Check if select causes an yield
1012                         if test $ol_with_yielding_select = auto ; then
1013                                 AC_MSG_CHECKING([if select yields when using pthreads])
1014                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
1015                                 AC_TRY_RUN([
1016 #include <sys/types.h>
1017 #include <sys/time.h>
1018 #include <unistd.h>
1019 #include <pthread.h>
1020 #ifndef NULL
1021 #define NULL (void*) 0
1022 #endif
1023
1024 static int fildes[2];
1025
1026 static void *task(p)
1027         void *p;
1028 {
1029         int i;
1030         struct timeval tv;
1031
1032         fd_set rfds;
1033
1034         tv.tv_sec=10;
1035         tv.tv_usec=0;
1036
1037         FD_ZERO(&rfds);
1038         FD_SET(fildes[0], &rfds);
1039
1040         /* we're not interested in any fds */
1041         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1042
1043         if(i < 0) {
1044                 perror("select");
1045                 exit(10);
1046         }
1047
1048         exit(0); /* if we exit here, the select blocked the whole process */
1049 }
1050
1051 int main(argc, argv)
1052         int argc;
1053         char **argv;
1054 {
1055         pthread_t t;
1056
1057         /* create a pipe to select */
1058         if(pipe(&fildes[0])) {
1059                 perror("select");
1060                 exit(1);
1061         }
1062
1063 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1064         (void) pthread_setconcurrency(2);
1065 #else
1066 #ifdef HAVE_THR_SETCONCURRENCY
1067         /* Set Solaris LWP concurrency to 2 */
1068         thr_setconcurrency(2);
1069 #endif
1070 #endif
1071
1072 #if HAVE_PTHREADS_D4
1073         pthread_create(&t, pthread_attr_default, task, NULL);
1074 #else
1075         pthread_create(&t, NULL, task, NULL);
1076 #endif
1077
1078 #if HAVE_SCHED_YIELD
1079         sched_yield();  /* make sure task runs first */
1080 #else
1081 #ifdef HAVE_PTHREAD_YIELD
1082         pthread_yield();        /* make sure task runs first */
1083 #endif
1084 #endif
1085
1086         exit(2);
1087 }],
1088                                 [ol_cv_pthread_select_yields=no],
1089                                 [ol_cv_pthread_select_yields=yes], [
1090                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
1091                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
1092
1093                                 if test $ol_cv_pthread_select_yields = yes ; then
1094                                         ol_with_yielding_select=yes
1095                                 fi
1096                         fi
1097
1098                         dnl restore flags
1099                         CPPFLAGS="$save_CPPFLAGS"
1100                         LIBS="$save_LIBS"
1101                 else
1102                         AC_MSG_ERROR([could not link with POSIX Threads])
1103                 fi
1104         fi
1105
1106         if test $ol_with_threads = posix ; then
1107                 AC_MSG_ERROR([could not locate POSIX Threads])
1108         fi
1109 fi
1110
1111 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1112         -o $ol_with_threads = mach ; then
1113
1114         dnl check for Mach CThreads
1115         AC_CHECK_HEADERS(mach/cthreads.h)
1116         if test $ac_cv_header_mach_cthreads_h = yes ; then
1117                 ol_with_threads=found
1118
1119                 dnl check for cthread support in current $LIBS
1120                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1121
1122                 if test $ol_link_threads = no ; then
1123                         dnl try -all_load
1124                         dnl this test needs work
1125                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1126                                 [ol_cv_cthread_all_load], [
1127                                 dnl save the flags
1128                                 save_LIBS="$LIBS"
1129                                 LIBS="-all_load $LIBS"
1130                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1131                                         cthread_fork((void *)0, (void *)0);
1132                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1133                                 dnl restore the LIBS
1134                                 LIBS="$save_LIBS"
1135                         ])
1136
1137                         if test $ol_cv_cthread_all_load = yes ; then
1138                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1139                                 ol_link_threads=mach
1140                         fi
1141                 fi
1142
1143                 if test $ol_link_threads != no ; then
1144                         : check for cthread specific functionality here
1145                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1146                                 [define if you have Mach Cthreads])
1147                 else
1148                         AC_MSG_ERROR([could not link with Mach CThreads])
1149                 fi
1150         fi
1151
1152         if test $ol_with_threads = mach ; then
1153                 AC_MSG_ERROR([could not locate Mach CThreads])
1154         fi
1155 fi
1156
1157 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1158         -o $ol_with_threads = lwp ; then
1159
1160         dnl check for SunOS5 LWP
1161         AC_CHECK_HEADERS(thread.h synch.h)
1162         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1163                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1164
1165                 if test $have_thr = yes ; then
1166                         AC_DEFINE(HAVE_THR,1,
1167                                 [if you have Solaris LWP (thr) package])
1168                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1169                         ol_link_threads=thr
1170
1171                         if test $ol_with_yielding_select = auto ; then
1172                                 ol_with_yielding_select=yes
1173                         fi
1174
1175                         dnl Check for setconcurreny functions
1176                         AC_CHECK_FUNCS( \
1177                                 thr_setconcurrency \
1178                                 thr_getconcurrency \
1179                         )
1180                 fi
1181         fi
1182
1183         dnl check for SunOS4 LWP
1184         AC_CHECK_HEADERS(lwp/lwp.h)
1185         if test $ac_cv_header_lwp_lwp_h = yes ; then
1186                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1187
1188                 if test $have_lwp = yes ; then
1189                         AC_DEFINE(HAVE_LWP,1,
1190                                 [if you have SunOS LWP package])
1191                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1192                         ol_link_threads=lwp
1193
1194                         if test $ol_with_yielding_select = auto ; then
1195                                 ol_with_yielding_select=no
1196                         fi
1197                 fi
1198         fi
1199 fi
1200
1201 if test $ol_with_yielding_select = yes ; then
1202         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1203                 [define if select implicitly yields])
1204 fi
1205
1206 if test $ol_with_threads = manual ; then
1207         dnl User thinks he can manually configure threads.
1208         ol_link_threads=yes
1209
1210         AC_MSG_WARN([thread defines and link options must be set manually])
1211
1212         AC_CHECK_HEADERS(pthread.h sched.h)
1213         AC_CHECK_FUNCS(sched_yield pthread_yield)
1214         OL_LINUX_THREADS
1215
1216         AC_CHECK_HEADERS(mach/cthreads.h)
1217         AC_CHECK_HEADERS(lwp/lwp.h)
1218         AC_CHECK_HEADERS(thread.h synch.h)
1219 fi
1220
1221 if test $ol_link_threads != no ; then
1222         dnl needed to get reentrant/threadsafe versions
1223         dnl
1224         AC_DEFINE(REENTRANT,1)
1225         AC_DEFINE(_REENTRANT,1)
1226         AC_DEFINE(THREAD_SAFE,1)
1227         AC_DEFINE(_THREAD_SAFE,1)
1228         AC_DEFINE(THREADSAFE,1)
1229         AC_DEFINE(_THREADSAFE,1)
1230
1231         dnl this might cause the errno symbol to be
1232         dnl replaced with a function to get a thread specific errno.
1233         dnl check to see if everything needs to be compiled
1234         dnl with the thread libraries
1235         AC_CACHE_CHECK([for thread specific errno],
1236                 [ol_cv_errno_thread_specific], [
1237                 AC_TRY_LINK([#include <errno.h>], [int x = errno;],
1238                         [ol_cv_errno_thread_specific=yes],
1239                         [ol_cv_errno_thread_specific=no])
1240         ])
1241
1242         if test $ol_cv_errno_thread_specific != yes ; then
1243                 LIBS="$LTHREAD_LIBS $LIBS"
1244                 LTHREAD_LIBS=""
1245         fi
1246
1247 dnl When in thread environment, use
1248 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1249 dnl                     || defined( HAVE_FUNC_R )
1250 dnl                     func_r(...);
1251 dnl             #else
1252 dnl             #       if defined( HAVE_THREADS )
1253 dnl                             /* lock */
1254 dnl             #       endif
1255 dnl                             func(...);
1256 dnl             #       if defined( HAVE_THREADS )
1257 dnl                             /* unlock */
1258 dnl             #       endif
1259 dnl             #endif
1260 dnl
1261 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1262 dnl             _POSIX_REENTRANT_FUNCTIONS
1263 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1264 dnl             _POSIX_THREADSAFE_FUNCTIONS
1265 dnl
1266 dnl             and is currently defined in lthread.h
1267 dnl
1268 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1269 dnl
1270 dnl libldap/*.c should only include <lthread.h> iff
1271 dnl LDAP_R_COMPILE is defined.  ie:
1272 dnl             #ifdef LDAP_R_COMPILE
1273 dnl             #       include LDAP_R_COMPILE
1274 dnl             #endif
1275 dnl
1276 dnl LDAP_R_COMIPLE is defined by libldap_r/Makefile.in
1277 dnl specifically for compiling the threadsafe version of
1278 dnl     the ldap library (-lldap_r).
1279 dnl
1280 dnl     dnl check for reentrant/threadsafe functions
1281 dnl     dnl
1282 dnl     dnl note: these should only be used when linking
1283 dnl     dnl       with $LTHREAD_LIBS
1284 dnl     dnl
1285 dnl     save_CPPFLAGS="$CPPFLAGS"
1286 dnl     save_LIBS="$LIBS"
1287 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1288 dnl     AC_CHECK_FUNCS( \
1289 dnl             gmtime_r \
1290 dnl             gethostbyaddr_r gethostbyname_r \
1291 dnl             feof_unlocked unlocked_feof \
1292 dnl             putc_unlocked unlocked_putc \
1293 dnl             flockfile ftrylockfile \
1294 dnl     )
1295 dnl     CPPFLAGS="$save_CPPFLAGS"
1296 dnl     LIBS="$save_LIBS"
1297 fi
1298
1299 if test $ol_link_threads = no ; then
1300         if test $ol_with_threads = yes ; then
1301                 AC_MSG_ERROR([no suitable thread support])
1302         fi
1303
1304         if test $ol_with_threads = auto ; then
1305                 AC_MSG_WARN([no suitable thread support, disabling threads])
1306                 ol_with_threads=no
1307         fi
1308
1309         AC_DEFINE(NO_THREADS,1,
1310                 [define if you have (or want) no threads])
1311         LTHREAD_LIBS=""
1312 fi
1313
1314 if test $ol_link_threads != no ; then
1315         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1316 fi
1317
1318 dnl ----------------------------------------------------------------
1319
1320 ol_link_ldbm=no
1321 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1322         OL_BERKELEY_DB2
1323
1324         if test $ol_cv_berkeley_db2 = yes ; then
1325                 ol_link_ldbm=db2
1326                 ol_with_ldbm_api=db2
1327
1328                 if test $ol_with_ldbm_type = hash ; then
1329                         AC_DEFINE(LDBM_USE_DBHASH,1)
1330                 else
1331                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1332                 fi
1333
1334                 dnl $ol_cv_lib_db2 should be yes or -ldb
1335                 dnl (it could be no, but that would be an error
1336                 if test $ol_cv_lib_db2 != yes ; then
1337                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1338                 fi
1339         fi
1340 fi
1341
1342 ol_link_bdb2=no
1343 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1344         ol_link_bdb2=yes
1345 fi
1346
1347 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1348         OL_BERKELEY_DB
1349
1350         if test $ol_cv_berkeley_db = yes ; then
1351                 ol_link_ldbm=db
1352                 ol_with_ldbm_api=db
1353
1354                 if test $ol_with_ldbm_type = hash ; then
1355                         AC_DEFINE(LDBM_USE_DBHASH,1)
1356                 else
1357                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1358                 fi
1359
1360                 dnl $ol_cv_lib_db should be yes or -ldb
1361                 dnl (it could be no, but that would be an error
1362                 if test $ol_cv_lib_db != yes ; then
1363                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1364                 fi
1365         fi
1366 fi
1367
1368 if test $ol_with_ldbm_api = manual ; then
1369         dnl User thinks he can manually configure LDBM api.
1370         ol_link_ldbm=yes
1371
1372         AC_MSG_WARN([LDBM defines and link options must be set manually])
1373
1374         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1375 fi
1376
1377 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1378         AC_MSG_WARN(Could not find LDBM with BTREE support)
1379         ol_with_ldbm_api=none
1380 fi
1381
1382 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1383         OL_GDBM
1384
1385         if test $ol_cv_gdbm = yes ; then
1386                 ol_link_ldbm=gdbm
1387                 ol_with_ldbm_api=gdbm
1388
1389                 if test $ol_cv_lib_gdbm != yes ; then
1390                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1391                 fi
1392         fi
1393 fi
1394
1395 if test $ol_with_ldbm_api = auto ; then
1396         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1397 elif test $ol_with_ldbm_api = ndbm ; then
1398         OL_NDBM
1399
1400         if test $ol_cv_ndbm = yes ; then
1401                 ol_link_ldbm=ndbm
1402                 ol_with_ldbm_api=ndbm
1403
1404                 if test $ol_cv_lib_ndbm != yes ; then
1405                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1406                 fi
1407         fi
1408 fi
1409
1410 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1411         AC_MSG_WARN(could not find suitable LDBM backend)
1412         if test $ol_enable_ldbm = yes ; then
1413                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1414         fi
1415
1416         AC_MSG_WARN(disabling LDBM)
1417         ol_enable_ldbm=no
1418 fi
1419
1420 if test $ol_enable_wrappers != no ; then
1421         AC_CHECK_HEADERS(tcpd.h)
1422
1423         if test $ac_cv_header_tcpd_h != yes ; then
1424                 have_wrappers=no
1425         else
1426                 AC_CHECK_LIB(wrap, main,
1427                         [have_wrappers=yes], [have_wrappers=no])
1428         fi
1429
1430         if test $have_wrappers = yes ; then
1431                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1432                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1433         else
1434                 AC_MSG_WARN(could not find -lwrap)
1435                 if test $ol_enable_wrappers = yes ; then
1436                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1437                 fi
1438
1439                 AC_MSG_WARN(disabling wrappers support)
1440                 ol_enable_wrappers=no
1441         fi
1442 fi
1443
1444 if test $ol_enable_syslog != no ; then
1445         AC_CHECK_FUNC(openlog)
1446         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1447                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1448         fi
1449         ol_enable_syslog=$ac_cv_func_openlog
1450 fi
1451
1452 if test $ol_enable_dmalloc != no ; then
1453         AC_CHECK_HEADERS(dmalloc.h)
1454         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1455 fi
1456
1457 if test $ol_enable_tcl != no ; then
1458         AC_CHECK_HEADERS(tcl.h)
1459
1460         if test $ac_cv_header_tcl_h != yes ; then
1461                 have_tcl=no
1462         else
1463                 AC_CHECK_LIB(tcl,main,
1464                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1465                         [have_tcl=no])
1466
1467                 if test $have_tcl != yes; then
1468                         AC_CHECK_LIB(tcl7.6,main,
1469                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1470                                 [have_tcl=no])
1471                 fi
1472
1473                 if test $have_tcl != yes; then
1474                         AC_CHECK_LIB(tcl8.0,main,
1475                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1476                                 [have_tcl=no])
1477                 fi
1478         fi
1479
1480         if test $have_tcl != yes ; then
1481                 AC_MSG_WARN([could not find -ltcl])
1482                 if test $ol_enable_tcl = yes ; then
1483                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1484                 fi
1485
1486                 ol_enable_tcl=no
1487         fi
1488 fi
1489
1490 # ud needs termcap (should insert check here)
1491 ol_link_termcap=no
1492 AC_CHECK_HEADERS(termcap.h ncurses.h)
1493
1494 if test $ol_link_termcap = no ; then
1495         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1496         if test $have_termcap = yes ; then
1497                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1498                 ol_link_termcap=yes
1499                 TERMCAP_LIBS=-ltermcap
1500         fi
1501 fi
1502
1503 if test $ol_link_termcap = no ; then
1504         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1505         if test $have_ncurses = yes ; then
1506                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1507                 ol_link_termcap=yes
1508                 TERMCAP_LIBS=-lncurses
1509         fi
1510 fi
1511
1512 if test $ol_link_termcap = no ; then
1513         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1514         TERMCAP_LIBS=
1515 fi
1516
1517 dnl
1518 dnl Check for GNU readline
1519 dnl
1520 ol_link_readline=no
1521 if test $ol_with_readline != no ; then
1522         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1523
1524         if test $ac_cv_header_readline_readline_h = yes ; then
1525                 save_LIBS="$LIBS"
1526                 LIBS="$TERMCAP_LIBS $LIBS"
1527                 AC_CHECK_LIB(readline, readline,
1528                         [have_readline=yes], [have_readline=no])
1529                 LIBS="$save_LIBS"
1530
1531                 if test $have_readline = yes ; then
1532                         ol_with_readline=found
1533                         ol_link_readline=yes
1534
1535                         READLINE_LIBS="-lreadline"
1536                 fi
1537         fi
1538 fi
1539
1540 if test $ol_link_readline = yes ; then
1541         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1542 fi
1543
1544
1545 # FreeBSD (and others) have crypt(3) in -lcrypt
1546 if test $ol_enable_crypt != no ; then
1547         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1548                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1549                         have_crypt=yes], [have_crypt=no])])
1550
1551         if test $have_crypt = yes ; then
1552                 AC_DEFINE(HAVE_CRYPT,1)
1553         else
1554                 AC_MSG_WARN(could not find crypt)
1555                 if test $ol_enable_crypt = yes ; then
1556                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1557                 fi
1558
1559                 AC_MSG_WARN(disabling crypt support)
1560                 ol_enable_crypt=no
1561         fi
1562 fi
1563
1564 # FreeBSD (and others) have setproctitle(3) in -lutil
1565 if test $ol_enable_proctitle != no ; then
1566         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1567                 AC_CHECK_LIB(util, setproctitle,
1568                         [have_setproctitle=yes
1569                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1570                         [have_setproctitle=no
1571                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1572
1573         if test $have_setproctitle = yes ; then
1574                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1575         fi
1576 fi
1577
1578 dnl ----------------------------------------------------------------
1579 dnl Checks for header files.
1580 OL_HEADER_STDC
1581
1582 if test $ol_cv_header_stdc != yes; then
1583         AC_MSG_WARN([could not Standard C compliant headers])
1584 fi
1585
1586 AC_HEADER_DIRENT
1587 AC_HEADER_SYS_WAIT
1588 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1589 if test $am_cv_sys_posix_termios = yes ; then
1590         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1591                 [define if you have POSIX termios])
1592 fi
1593
1594 AC_CHECK_HEADERS(       \
1595         arpa/inet.h             \
1596         arpa/nameser.h  \
1597         assert.h                \
1598         crypt.h                 \
1599         errno.h                 \
1600         fcntl.h                 \
1601         filio.h                 \
1602         getopt.h                \
1603         libutil.h               \
1604         limits.h                \
1605         locale.h                \
1606         malloc.h                \
1607         memory.h                \
1608         regex.h                 \
1609         psap.h                  \
1610         pwd.h                   \
1611         resolv.h                \
1612         sgtty.h                 \
1613         stdarg.h                \
1614         stddef.h                \
1615         string.h                \
1616         strings.h               \
1617         sysexits.h              \
1618         sys/file.h              \
1619         sys/filio.h             \
1620         sys/errno.h             \
1621         sys/ioctl.h             \
1622         sys/param.h             \
1623         sys/resource.h  \
1624         sys/socket.h    \
1625         sys/syslog.h    \
1626         sys/time.h              \
1627         sys/types.h             \
1628         syslog.h                \
1629         termios.h               \
1630         unistd.h                \
1631 )
1632
1633 dnl ----------------------------------------------------------------
1634 dnl Checks for typedefs, structures, and compiler characteristics.
1635 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1636 AC_TYPE_MODE_T
1637 AC_TYPE_OFF_T
1638 AC_TYPE_PID_T
1639 AM_TYPE_PTRDIFF_T
1640 AC_TYPE_SIGNAL
1641 OL_TYPE_SIG_ATOMIC_T
1642 AC_TYPE_SIZE_T
1643 AC_STRUCT_ST_BLKSIZE
1644 AC_HEADER_TIME
1645 AC_STRUCT_TM
1646 OL_STRUCT_PASSWD_PW_GECOS
1647
1648 OL_C_UPPER_LOWER
1649 AC_C_CONST
1650 OL_C_VOLATILE
1651
1652 if test $cross_compiling = yes ; then
1653         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1654 else
1655         AC_C_BIGENDIAN
1656         AC_CHECK_SIZEOF(short)
1657         AC_CHECK_SIZEOF(int)
1658         AC_CHECK_SIZEOF(long)
1659 fi
1660
1661 dnl ----------------------------------------------------------------
1662 dnl Checks for library functions.
1663 AC_FUNC_MEMCMP
1664 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1665 AC_FUNC_STRFTIME
1666 dnl AM_FUNC_STRTOD
1667 AC_FUNC_VPRINTF
1668
1669 if test $ac_cv_func_vprintf = yes ; then
1670         dnl check for vsnprintf
1671         AC_CHECK_FUNCS(vsnprintf vsprintf)
1672 fi
1673
1674 AC_CHECK_FUNCS(         \
1675         bcopy                   \
1676         flock                   \
1677         getdtablesize           \
1678         gethostname             \
1679         getpass                 \
1680         getpwuid                \
1681         gettimeofday            \
1682         lockf                   \
1683         memcpy                  \
1684         memmove                 \
1685         mkstemp                 \
1686         select                  \
1687         setpwfile               \
1688         setsid                  \
1689         signal                  \
1690         sigset                  \
1691         snprintf                \
1692         socket                  \
1693         strdup                  \
1694         strerror                \
1695         strpbrk                 \
1696         strrchr                 \
1697         strsep                  \
1698         strstr                  \
1699         strtol                  \
1700         strtoul                 \
1701         strspn                  \
1702         sysconf                 \
1703         waitpid                 \
1704 )
1705
1706 dnl We actually may need to replace more than this.
1707 AC_REPLACE_FUNCS(getopt tempnam)
1708
1709 dnl ----------------------------------------------------------------
1710 # Check Configuration
1711 OL_SYS_ERRLIST
1712
1713 dnl ----------------------------------------------------------------
1714 dnl Check our declaration of strdup()
1715 OL_DECL_STRDUP
1716
1717 dnl ----------------------------------------------------------------
1718 dnl Sort out defines
1719
1720 if test "$ol_enable_debug" != no ; then
1721         AC_DEFINE(LDAP_DEBUG,1)
1722 fi
1723 if test "$ol_enable_syslog" = yes ; then
1724         AC_DEFINE(LDAP_SYSLOG,1)
1725 fi
1726 if test "$ol_enable_libui" = yes ; then
1727         AC_DEFINE(LDAP_LIBUI,1)
1728 fi
1729 if test "$ol_enable_cache" = no ; then
1730         AC_DEFINE(LDAP_NOCACHE,1)
1731 fi
1732 if test "$ol_enable_dns" != no ; then
1733         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1734 fi
1735 if test "$ol_enable_proctitle" != no ; then
1736         AC_DEFINE(LDAP_PROCTITLE,1)
1737 fi
1738 if test "$ol_enable_referrals" != no ; then
1739         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1740 fi
1741 if test "$ol_enable_cldap" != no ; then
1742         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1743 fi
1744
1745 if test "$ol_enable_aclgroups" != no ; then
1746         AC_DEFINE(SLAPD_ACLGROUPS,1)
1747 fi
1748 if test "$ol_enable_crypt" != no ; then
1749         AC_DEFINE(SLAPD_CRYPT,1)
1750 fi
1751 if test "$ol_enable_cleartext" != no ; then
1752         AC_DEFINE(SLAPD_CLEARTEXT,1)
1753 fi
1754 if test "$ol_enable_phonetic" != no ; then
1755         AC_DEFINE(SLAPD_PHONETIC,1)
1756 fi
1757 if test "$ol_enable_rlookups" != no ; then
1758         AC_DEFINE(SLAPD_RLOOKUPS,1)
1759 fi
1760
1761 if test "$ol_link_bdb2" != no ; then
1762         AC_DEFINE(SLAPD_BDB2,1)
1763         BUILD_SLAPD=yes
1764         BUILD_BDB2=yes
1765 fi
1766
1767 if test "$ol_link_ldbm" != no ; then
1768         AC_DEFINE(SLAPD_LDBM,1)
1769         BUILD_SLAPD=yes
1770         BUILD_LDBM=yes
1771 fi
1772
1773 if test "$ol_enable_passwd" != no ; then
1774         AC_DEFINE(SLAPD_PASSWD,1)
1775         BUILD_SLAPD=yes
1776         BUILD_PASSWD=yes
1777 fi
1778
1779 if test "$ol_enable_perl" != no ; then
1780         AC_DEFINE(SLAPD_PERL,1)
1781         BUILD_SLAPD=yes
1782         BUILD_PERL=yes
1783 fi
1784
1785 if test "$ol_enable_shell" != no ; then
1786         AC_DEFINE(SLAPD_SHELL,1)
1787         BUILD_SLAPD=yes
1788         BUILD_SHELL=yes
1789 fi
1790
1791 if test "$ol_enable_tcl" != no ; then
1792         AC_DEFINE(SLAPD_TCL,1)
1793         BUILD_SLAPD=yes
1794         BUILD_TCL=yes
1795 fi
1796
1797 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1798         $BUILD_SLAPD = yes ; then
1799         BUILD_SLURPD=yes
1800 fi
1801
1802 if test "$ol_link_isode" != no ; then
1803         BUILD_LDAPD=yes
1804 fi
1805
1806 dnl ----------------------------------------------------------------
1807
1808 AC_SUBST(BUILD_LDAPD)
1809 AC_SUBST(BUILD_SLAPD)
1810   AC_SUBST(BUILD_BDB2)
1811   AC_SUBST(BUILD_LDBM)
1812   AC_SUBST(BUILD_PASSWD)
1813   AC_SUBST(BUILD_PERL)
1814   AC_SUBST(BUILD_SHELL)
1815   AC_SUBST(BUILD_TCL)
1816 AC_SUBST(BUILD_SLURPD)
1817
1818 AC_SUBST(LDAP_LIBS)
1819 AC_SUBST(LDAPD_LIBS)
1820 AC_SUBST(SLAPD_LIBS)
1821 AC_SUBST(SLURPD_LIBS)
1822 AC_SUBST(LDBM_LIBS)
1823 AC_SUBST(LTHREAD_LIBS)
1824 AC_SUBST(LUTIL_LIBS)
1825
1826 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1827 AC_SUBST(SLAPD_PERL_LDFLAGS)
1828
1829 AC_SUBST(KRB_LIBS)
1830 AC_SUBST(READLINE_LIBS)
1831 AC_SUBST(TERMCAP_LIBS)
1832 AC_SUBST(TLS_LIBS)
1833
1834 dnl ----------------------------------------------------------------
1835 dnl final output
1836 dnl
1837
1838 AC_OUTPUT( \
1839 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1840 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1841 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1842 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1843 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1844 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1845 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1846 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1847 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1848 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1849 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1850 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1851 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1852 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1853 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1854 include/Makefile:build/top.mk:include/Makefile.in \
1855 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1856 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1857 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1858 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1859 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1860 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1861 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1862 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1863 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1864 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1865 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1866 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
1867 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1868 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1869 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
1870 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1871 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
1872 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1873 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1874 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1875 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
1876 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
1877 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
1878 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
1879 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
1880 ,[
1881 date > stamp-h
1882 echo Please \"make depend\" to build dependencies
1883 ])