git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Configure.in for OpenLDAP
  11 AC_INIT(include/ldap.h)dnl
  12 AC_CONFIG_AUX_DIR(build)dnl
  13 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no ac_define])dnl
  14
  15 dnl We use autoconf features new to 2.13.
  16 dnl     aclocal.m4 should be built using aclocal from automake 1.4
  17 AC_PREREQ(2.13)dnl Required Autoconf version
  18
  19 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  20
  21 dnl
  22 dnl Start Args
  23 AC_MSG_CHECKING(configure arguments)
  24 AC_PREFIX_DEFAULT(/usr/local)
  25
  26 top_builddir=`pwd`
  27 AC_SUBST(top_builddir)dnl
  28
  29 ldap_subdir="openldap"
  30
  31 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  32         if test "$withval" = "no"; then
  33                 ldap_subdir=""
  34         elif test "$withval" != "yes"; then
  35                 ldap_subdir="$withval"
  36         fi
  37 ])dnl
  38
  39 AC_SUBST(ldap_subdir)dnl
  40
  41 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  42 ol_enable_syslog=no
  43 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  44 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  45 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  46 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  47 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  48 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  49 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  50         no, [yes no])dnl
  51
  52 dnl General "with" options
  53 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  54
  55 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  56         auto, [auto k5 k4 afs yes no])
  57 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  58         auto, [auto yes no] )
  59 OL_ARG_WITH(threads,[  --with-threads   use threads],
  60         auto, [auto posix mach lwp yes no manual] )
  61 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  62         auto, [auto ssleay openssl yes no] )
  63 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  64         auto, [auto yes no manual] )
  65
  66 dnl Server options
  67
  68 dnl LDAPD OPTIONS
  69 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  70 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  71
  72 dnl SLAPD OPTIONS
  73 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  74 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  75 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  76 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  77 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  78 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  79 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  80 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  81
  82 dnl SLAPD Backend options
  83 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
  84 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  85 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  86         [auto db2 db gdbm ndbm manual])
  87 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  88         [auto btree hash])
  89
  90 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  91 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
  92 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  93 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
  94
  95 dnl SLURPD OPTIONS
  96 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  97 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  98
  99 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 100 AM_ENABLE_STATIC
 101 dnl AM_DISABLE_SHARED
 102 AM_ENABLE_SHARED
 103
 104 dnl General "enable" options
 105 # validate options
 106 if test $ol_enable_dns = yes ; then
 107         if test $ol_enable_referrals = no ; then
 108                 AC_MSG_ERROR([DNS requires --enable-referrals])
 109         fi
 110         if test $ol_enable_referrals = auto ; then
 111                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 112                 ol_enable_referrals=yes
 113         fi
 114 fi
 115
 116 if test $ol_enable_slapd = no ; then
 117         dnl SLAPD was specificallly disabled
 118         if test $ol_enable_bdb2 = yes ; then
 119                 AC_MSG_WARN([slapd disabled, ignoring --enable_bdb2 argument])
 120         fi
 121         if test $ol_enable_ldbm = yes ; then
 122                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 123         fi
 124         if test $ol_enable_passwd = yes ; then
 125                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 126         fi
 127         if test $ol_enable_perl = yes ; then
 128                 AC_MSG_WARN([slapd disabled, ignoring --enable_perl argument])
 129         fi
 130         if test $ol_enable_shell = yes ; then
 131                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 132         fi
 133         if test $ol_enable_tcl = yes ; then
 134                 AC_MSG_WARN([slapd disabled, ignoring --enable_tcl argument])
 135         fi
 136         if test $ol_enable_aclgroups = yes ; then
 137                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 138         fi
 139         if test $ol_enable_wrappers = yes ; then
 140                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 141         fi
 142         if test $ol_enable_phonetic = yes ; then
 143                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 144         fi
 145         if test $ol_enable_rlookups = yes ; then
 146                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 147         fi
 148         if test $ol_with_ldbm_api != auto ; then
 149                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 150         fi
 151         if test $ol_with_ldbm_type != auto ; then
 152                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 153         fi
 154         if test $ol_enable_slurpd = yes ; then
 155                 AC_MSG_ERROR([slurpd requires slapd])
 156         fi
 157
 158         # force settings to no
 159         ol_enable_bdb2=no
 160         ol_enable_ldbm=no
 161         ol_enable_passwd=no
 162         ol_enable_perl=no
 163         ol_enable_shell=no
 164         ol_enable_tcl=no
 165         ol_enable_aclgroups=no
 166         ol_enable_wrappers=no
 167         ol_enable_phonetic=no
 168         ol_enable_rlookups=no
 169         ol_with_ldbm_api=no
 170         ol_with_ldbm_type=no
 171         ol_enable_slurpd=no
 172
 173 elif test $ol_enable_ldbm = no ; then
 174         dnl SLAPD without LDBM
 175
 176         if test $ol_with_ldbm_api != auto ; then
 177                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 178         fi
 179
 180         if test $ol_with_ldbm_type != auto ; then
 181                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 182         fi
 183
 184         if test $ol_enable_bdb2 = yes ; then
 185                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 186         fi
 187
 188         if test $ol_enable_passwd = no -a \
 189                 $ol_enable_perl = no -a \
 190                 $ol_enable_shell = no -a \
 191                 $ol_enable_tcl = no ; then
 192                 AC_MSG_ERROR([slapd requires a backend])
 193         fi
 194
 195         ol_with_ldbm_api=no
 196         ol_with_ldbm_type=no
 197
 198 elif test $ol_enable_bdb2 = yes ; then
 199         dnl SLAPD with BDB2
 200
 201         if test $ol_with_ldbm_api != auto -a \
 202                 $ol_with_ldbm_api != db2 ; then
 203                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 204         fi
 205
 206         ol_with_ldbm_api=db2
 207
 208 else
 209         dnl SLAPD with LDBM
 210
 211         if test $ol_enable_bdb2 != no ; then
 212                 if test $ol_with_ldbm_api != auto -a \
 213                         $ol_with_ldbm_api != db2 ; then
 214                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 215                         ol_enable_bdb2=no
 216                 fi
 217         fi
 218
 219         if test $ol_with_ldbm_api = gdbm -a \
 220                 $ol_with_ldbm_type = btree ; then
 221                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 222         fi
 223         if test $ol_with_ldbm_api = ndbm -a \
 224                 $ol_with_ldbm_type = btree ; then
 225                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 226         fi
 227 fi
 228
 229 if test $ol_enable_slurpd = yes ; then
 230         dnl SLURPD was specifically enabled
 231         if test $ol_with_threads = no ; then
 232                 AC_MSG_ERROR([slurpd requires threads])
 233         fi
 234 fi
 235
 236 AC_MSG_RESULT(done)
 237
 238 ## Initialize vars
 239 LDAP_LIBS=
 240 LDBM_LIBS=
 241 LTHREAD_LIBS=
 242 LUTIL_LIBS=
 243
 244 LDAPD_LIBS=
 245 SLAPD_LIBS=
 246 SLURPD_LIBS=
 247
 248 BUILD_LDAPD=no
 249 BUILD_SLAPD=no
 250 BUILD_SLURPD=no
 251
 252 BUILD_BDB2=no
 253 BUILD_LDBM=no
 254 BUILD_PASSWD=no
 255 BUILD_PERL=no
 256 BUILD_SHELL=no
 257 BUILD_TCL=no
 258 BUILD_THREAD=no
 259
 260 SLAPD_PERL_LDFLAGS=
 261 SLAPD_PERL_CPPFLAGS=
 262
 263 KRB_LIBS=
 264 READLINE_LIBS=
 265 TERMCAP_LIBS=
 266 TLS_LIBS=
 267
 268 dnl ----------------------------------------------------------------
 269 dnl Checks for programs
 270
 271 AC_PROG_INSTALL
 272
 273 dnl The default compiler is cc (NOT gcc)
 274 CC=${CC-"cc"}
 275 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 276 dnl CFLAGS=${CFLAGS-""}
 277
 278 AM_PROG_LIBTOOL
 279 dnl AC_PROG_MAKE_SET
 280
 281 AC_PROG_AWK
 282 OL_PROG_LN_H
 283 AC_PROG_LN_S
 284
 285 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 286         LN_S="$LN_H"
 287 fi
 288
 289 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 290         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 291 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 292 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 293
 294 if test $ol_enable_perl = yes ; then
 295         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 296
 297         if test "no$PERLBIN" = "no" ; then
 298                 ol_enable_perl=no
 299         fi
 300
 301         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 302         SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e perl_inc`"
 303 fi
 304
 305 AC_PROG_CPP
 306
 307 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 308         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 309
 310 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 311         AC_MSG_WARN([programs compiled here do run here...])
 312         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 313
 314 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 315         AC_MSG_WARN([programs compiled here do not run here...])
 316         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 317 fi
 318
 319 dnl Checks for UNIX Variants
 320 AC_AIX
 321 AC_ISC_POSIX
 322 AC_MINIX
 323
 324 dnl BeOS requires -lbe -lroot
 325 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot"], :, [-lroot])
 326
 327 dnl Checks for system services
 328 AC_CYGWIN
 329 AC_MINGW32
 330 AC_EXEEXT
 331 AC_OBJEXT
 332
 333 dnl OpenLDAP requires STDC features
 334 AM_PROG_CC_STDC
 335 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 336         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 337 fi
 338
 339 dnl AM_C_PROTOTYPES
 340
 341 dnl Checks for libraries
 342
 343 dnl Find socket()
 344 dnl Likely combinations:
 345 dnl             -lsocket [ -lnsl_s | -lnsl ]
 346 dnl             -linet
 347
 348 AC_CHECK_FUNC(socket, [have_socket=yes], [
 349 dnl
 350 dnl hopefully we won't include too many libraries
 351 dnl
 352         AC_CHECK_LIB(socket, main)
 353         AC_CHECK_LIB(net, main)
 354         AC_CHECK_LIB(nsl_s, main)
 355         AC_CHECK_LIB(nsl, main)
 356         AC_CHECK_LIB(inet, socket)
 357         AC_CHECK_LIB(gen, main)
 358 ])
 359
 360 dnl Check for resolver routines
 361 AC_CHECK_FUNCS(res_search)
 362 if test $ac_cv_func_res_search = "no" ; then
 363         AC_CHECK_LIB(bind, res_search)
 364         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 365                 AC_DEFINE(HAVE_RES_SEARCH,1)
 366         else
 367                 AC_CHECK_LIB(resolv, res_search)
 368                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 369                         AC_DEFINE(HAVE_RES_SEARCH,1)
 370                 fi
 371         fi
 372 fi
 373
 374 dnl HP-UX requires -lV3
 375 AC_CHECK_LIB(V3, sigset)
 376
 377 # ISODE tests
 378 ol_link_isode=no
 379 if test $ol_enable_ldapd != no ; then
 380         dnl look for ISODE libraries
 381         AC_CHECK_LIB(xtpp, main, [
 382                 ol_link_isode=yes
 383                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 384                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 385                 ],:,[-lxtdsap -lxtisode -losi])
 386         AC_CHECK_LIB(dsap, main, [
 387                 ol_link_isode=yes
 388                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 389                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 390                 ],:,[-lisode])
 391         AC_CHECK_LIB(isode, main, [
 392                 ol_link_isode=yes
 393                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 394                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 395                 ],:)
 396 fi
 397
 398 if test $ol_link_isode != no; then
 399         AC_CHECK_LIB(pp, main, [
 400                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 401                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 402                 ],:)
 403
 404         AC_PATH_PROG(PEPSY, pepsy)
 405 fi
 406
 407 dnl
 408 dnl check for kerberos
 409 dnl
 410 ol_link_kerberos=no
 411
 412 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 413         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 414
 415         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 416                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 417                         [-lkrb5 -ldes425])
 418
 419                 if test $have_k5 = yes ; then
 420                         ol_with_kerberos=found
 421                         ol_link_kerberos=yes
 422
 423                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 424
 425                         LIBS="$KRB_LIBS $LIBS"
 426
 427                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 428                                 [ol_cv_var_des_debug], [
 429                                 dnl save the flags
 430                                 save_LIBS="$LIBS"
 431                                 LIBS="$KRB_LIBS $LIBS"
 432                                 AC_TRY_LINK([
 433 #include <kerberosIV/krb.h>
 434 #include <kerberosIV/des.h>
 435 extern int des_debug;
 436 ],[
 437 des_debug = 1;
 438 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 439                                 dnl restore the LIBS
 440                                 LIBS="$save_LIBS"
 441                         ])
 442
 443                         if test $ol_cv_var_des_debug = yes ; then
 444                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 445                                         [define if you have Kerberos des_debug])
 446                         fi
 447
 448                         LIBS="$save_LIBS"
 449                 fi
 450         fi
 451 fi
 452
 453 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 454         AC_CHECK_HEADERS(krb.h des.h)
 455
 456         if test $ac_cv_header_krb_h = yes ; then
 457                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 458
 459                 if test $have_k4 = yes ; then
 460                         ol_with_kerberos=found
 461                         ol_link_kerberos=yes
 462
 463                         KRB_LIBS="-lkrb -ldes"
 464                 fi
 465         fi
 466 fi
 467
 468 if test $ol_link_kerberos = yes ; then
 469         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 470 fi
 471
 472 dnl
 473 dnl Check for SSL/TLS
 474 dnl
 475 ol_link_tls=no
 476 if test $ol_with_tls != no ; then
 477
 478         AC_CHECK_HEADERS(ssl.h)
 479
 480         if test $ac_cv_header_ssl_h = yes ; then
 481                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 482                         [have_ssleay=yes
 483                         need_rsaref=no],
 484                         [have_ssleay=no],
 485                         [-lcrypto])
 486
 487                 if test $have_ssleay = no ; then
 488                         AC_CHECK_LIB(ssl, ssl3_accept,
 489                                 [have_ssleay=yes
 490                                 need_rsaref=yes], [have_ssleay=no],
 491                                 [-lcrypto -lRSAglue -lrsaref])
 492                 fi
 493
 494                 if test $have_ssleay = yes ; then
 495                         ol_with_tls=found
 496                         ol_link_tls=yes
 497
 498                         AC_DEFINE(HAVE_SSLEAY, 1,
 499                                 [define if you have SSLeay or OpenSSL])
 500
 501                         if test $need_rsaref = yes; then
 502                                 AC_DEFINE(HAVE_RSAREF, 1,
 503                                         [define if you have RSAref])
 504
 505                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 506                         else
 507                                 TLS_LIBS="-lssl -lcrypto"
 508                         fi
 509                 fi
 510         fi
 511 fi
 512
 513 if test $ol_link_tls = yes ; then
 514         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 515 fi
 516
 517 dnl Tests for reentrant functions necessary to build a
 518 dnl thread_safe -lldap.
 519 AC_CHECK_FUNCS(         \
 520         ctime_r                 \
 521         gethostbyname_r gethostbyaddr_r \
 522 )
 523
 524 if test "$ac_cv_func_ctime_r" = no ; then
 525         ol_cv_func_ctime_r_nargs=0
 526 else
 527         OL_FUNC_CTIME_R_NARGS
 528 dnl     OL_FUNC_CTIME_R_TYPE
 529 fi
 530
 531 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 532         OL_FUNC_GETHOSTBYNAME_R_NARGS
 533 else
 534         ol_cv_func_gethostbyname_r_nargs=0
 535 fi
 536
 537 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 538         OL_FUNC_GETHOSTBYADDR_R_NARGS
 539 else
 540         ol_cv_func_gethostbyaddr_r_nargs=0
 541 fi
 542
 543 if test "$ac_cv_func_ctime_r" = yes \
 544         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 545         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 546         -a "$ac_cv_func_gethostbyname_r" = yes \
 547         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 548         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 549         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 550         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 551         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 552         ; then
 553
 554         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 555 fi
 556
 557 ol_link_threads=no
 558 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 559         -o $ol_with_threads = posix ; then
 560
 561         AC_CHECK_HEADERS(pthread.h sched.h)
 562
 563         if test $ac_cv_header_pthread_h = yes ; then
 564                 OL_POSIX_THREAD_VERSION
 565
 566                 if test $ol_cv_pthread_version = final ; then
 567                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 568                                 [define if pthreads API compatible with final spec])
 569                 elif test $ol_cv_pthread_version = draft4 ; then
 570                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 571                                 [define if pthreads API compatible with draft4 spec])
 572                 else
 573                         AC_MSG_ERROR([unknown pthread version])
 574                 fi
 575
 576                 # consider threads found
 577                 ol_with_threads=found
 578
 579                 OL_LINUX_THREADS
 580
 581                 if test $ol_cv_linux_threads = yes ; then
 582                         AC_DEFINE(HAVE_LINUX_THREADS,1,
 583                                 [define if you have LinuxThreads])
 584                 fi
 585
 586                 dnl Now the hard part, how to link?
 587                 dnl
 588                 dnl currently supported checks:
 589                 dnl
 590                 dnl Check for no flags
 591                 dnl     pthread_create() in $LIBS
 592                 dnl
 593                 dnl Check special pthread (final) flags
 594                 dnl     pthread_create() with -mt (Solaris)
 595                 dnl     pthread_create() with -kthread (FreeBSD)
 596                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 597                 dnl     pthread_create() with -pthreads (?)
 598                 dnl     pthread_create() with -thread (?)
 599                 dnl
 600                 dnl Check pthread (final) libraries
 601                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 602                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 603                 dnl     pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 604                 dnl     pthread_create() in -lpthread (many)
 605                 dnl     pthread_create() in -lc_r (FreeBSD)
 606                 dnl     pthread_create() in -lpthreads (many)
 607                 dnl     pthread_join() -Wl,-woff,85 -lpthreads (IRIX)
 608                 dnl
 609                 dnl Check pthread (draft4) flags (depreciated)
 610                 dnl     pthread_create() with -threads (OSF/1)
 611                 dnl
 612                 dnl Check pthread (final) libraries (depreciated)
 613                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 614                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 615                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 616                 dnl
 617
 618                 dnl pthread_create in $LIBS
 619                 AC_MSG_CHECKING([for pthread_create in default libraries])
 620                 AC_CACHE_VAL(ol_cv_pthread_create,[
 621                 AC_TRY_RUN([
 622 #include <pthread.h>
 623 #ifndef NULL
 624 #define NULL (void*)0
 625 #endif
 626
 627 static void *task(p)
 628         void *p;
 629 {
 630         return (void *) (p == NULL);
 631 }
 632
 633 int main(argc, argv)
 634         int argc;
 635         char **argv;
 636 {
 637         pthread_t t;
 638         int status;
 639
 640         /* make sure pthread_create() isn't just a stub */
 641 #if HAVE_PTHREADS_D4
 642         status = pthread_create(&t, pthread_attr_default, task, NULL));
 643 #else
 644         status = pthread_create(&t, NULL, task, NULL);
 645 #endif
 646
 647         if( status ) return status;
 648
 649         /* make sure pthread_detach() isn't just a stub */
 650 #if HAVE_PTHREADS_D4
 651         status = pthread_detach( &t );
 652 #else
 653         status = pthread_detach( t );
 654 #endif
 655
 656         if( status ) return status;
 657
 658         return status;
 659 }
 660 ],
 661                         [ol_cv_pthread_create=yes],
 662                         [ol_cv_pthread_create=no],
 663                         [dnl assume yes
 664                         ol_cv_pthread_create=yes])])
 665                 AC_MSG_RESULT($ol_cv_pthread_create)
 666
 667                 if test $ol_cv_pthread_create != no ; then
 668                         ol_link_threads=posix
 669                 fi
 670
 671                 if test $ol_link_threads = no ; then
 672                         dnl try -mt
 673                         AC_CACHE_CHECK([for pthread_create with -mt],
 674                                 [ol_cv_thread_flag], [
 675                                 dnl save the flags
 676                                 save_LIBS="$LIBS"
 677                                 LIBS="-mt $LIBS"
 678                                 AC_TRY_LINK([char pthread_create();],
 679                                         [pthread_create();],
 680                                         [ol_cv_thread_flag=yes], [ol_cv_thread_flag=no])
 681                                 dnl restore the LIBS
 682                                 LIBS="$save_LIBS"
 683                         ])
 684
 685                         if test $ol_cv_thread_flag = yes ; then
 686                                 LTHREAD_LIBS="$LTHREAD_LIBS -mt"
 687                                 ol_link_threads=posix
 688                         fi
 689                 fi
 690
 691                 if test $ol_link_threads = no ; then
 692                         dnl try -kthread
 693                         AC_CACHE_CHECK([for pthread_create with -kthread],
 694                                 [ol_cv_kthread_flag], [
 695                                 dnl save the flags
 696                                 save_LIBS="$LIBS"
 697                                 LIBS="-kthread $LIBS"
 698                                 AC_TRY_LINK([#include <pthread.h>],[
 699 #if HAVE_PTHREADS_D4
 700         pthread_create(NULL,pthread_attr_default,NULL,NULL);
 701 #else
 702         pthread_t t;
 703         pthread_create(&t,NULL,NULL,NULL);
 704         pthread_detach(t);
 705 #endif
 706 ],
 707                                         [ol_cv_kthread_flag=yes], [ol_cv_kthread_flag=no])
 708                                 dnl restore the LIBS
 709                                 LIBS="$save_LIBS"
 710                         ])
 711
 712                         if test $ol_cv_kthread_flag = yes ; then
 713                                 LTHREAD_LIBS="$LTHREAD_LIBS -kthread"
 714                                 ol_link_threads=posix
 715                         fi
 716                 fi
 717
 718                 if test $ol_link_threads = no ; then
 719                         dnl try -pthread
 720                         AC_CACHE_CHECK([for pthread_create with -pthread],
 721                                 [ol_cv_pthread_flag], [
 722                                 dnl save the flags
 723                                 save_LIBS="$LIBS"
 724                                 LIBS="-pthread $LIBS"
 725                                 AC_TRY_LINK([#include <pthread.h>],[
 726 #if HAVE_PTHREADS_D4
 727         pthread_create(NULL,pthread_attr_default,NULL,NULL);
 728 #else
 729         pthread_create(NULL,NULL,NULL,NULL);
 730 #endif
 731 ],
 732                                         [ol_cv_pthread_flag=yes], [ol_cv_pthread_flag=no])
 733                                 dnl restore the LIBS
 734                                 LIBS="$save_LIBS"
 735                         ])
 736
 737                         if test $ol_cv_pthread_flag = yes ; then
 738                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 739                                 ol_link_threads=posix
 740                         fi
 741                 fi
 742
 743                 if test $ol_link_threads = no ; then
 744                         dnl try -pthreads
 745                         AC_CACHE_CHECK([for pthread_create with -pthreads],
 746                                 [ol_cv_pthreads_flag], [
 747                                 dnl save the flags
 748                                 save_LIBS="$LIBS"
 749                                 LIBS="-pthreads $LIBS"
 750                                 AC_TRY_LINK([#include <pthread.h>],[
 751 #if HAVE_PTHREADS_D4
 752         pthread_create(NULL,pthread_attr_default,NULL,NULL);
 753 #else
 754         pthread_create(NULL,NULL,NULL,NULL);
 755 #endif
 756 ],
 757                                         [ol_cv_pthreads_flag=yes], [ol_cv_pthreads_flag=no])
 758                                 dnl restore the LIBS
 759                                 LIBS="$save_LIBS"
 760                         ])
 761
 762                         if test $ol_cv_pthreads_flag = yes ; then
 763                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthreads"
 764                                 ol_link_threads=posix
 765                         fi
 766                 fi
 767
 768                 if test $ol_link_threads = no ; then
 769                         dnl try -thread
 770                         AC_CACHE_CHECK([for pthread_create with -thread],
 771                                 [ol_cv_thread_flag], [
 772                                 dnl save the flags
 773                                 save_LIBS="$LIBS"
 774                                 LIBS="-thread $LIBS"
 775                                 AC_TRY_LINK([char pthread_create();],
 776                                         [pthread_create();],
 777                                         [ol_cv_thread_flag=yes], [ol_cv_thread_flag=no])
 778                                 dnl restore the LIBS
 779                                 LIBS="$save_LIBS"
 780                         ])
 781
 782                         if test $ol_cv_thread_flag = yes ; then
 783                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 784                                 ol_link_threads=posix
 785                         fi
 786                 fi
 787
 788                 if test $ol_link_threads = no ; then
 789                         dnl try DEC Threads -lpthread -lmach -lexc -lc_r
 790                         save_LIBS="$LIBS"
 791                         AC_CHECK_LIB(pthread, pthread_mutex_unlock, [
 792                                 ol_link_threads=posix
 793                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc -lc_r"
 794                                 if test $ol_with_yielding_select = auto ; then
 795                                         ol_with_yielding_select=yes
 796                                 fi
 797                                 ],:,[-lmach -lexc -lc_r])
 798                         LIBS="$save_LIBS"
 799                 fi
 800
 801                 if test $ol_link_threads = no ; then
 802                         dnl try DEC Threads -lpthread -lmach -lexc
 803                         save_LIBS="$LIBS"
 804                         AC_CHECK_LIB(pthread, pthread_mutex_lock, [
 805                                 ol_link_threads=posix
 806                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc"
 807                                 if test $ol_with_yielding_select = auto ; then
 808                                         ol_with_yielding_select=yes
 809                                 fi
 810                                 ],:,[-lmach -lexc])
 811                         LIBS="$save_LIBS"
 812                 fi
 813
 814                 if test $ol_link_threads = no ; then
 815                         dnl try DEC Threads -lpthread -lexc
 816                         save_LIBS="$LIBS"
 817                         AC_CHECK_LIB(pthread, pthread_mutex_trylock, [
 818                                 ol_link_threads=posix
 819                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 820                                 if test $ol_with_yielding_select = auto ; then
 821                                         ol_with_yielding_select=yes
 822                                 fi
 823                                 ],:,[-lexc])
 824                         LIBS="$save_LIBS"
 825                 fi
 826
 827                 if test $ol_link_threads = no ; then
 828                         dnl try -lpthread
 829                         save_LIBS="$LIBS"
 830                         AC_CHECK_LIB(pthread, pthread_create, [
 831                                 ol_link_threads=posix
 832                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"],:)
 833                         LIBS="$save_LIBS"
 834                 fi
 835
 836                 if test $ol_link_threads = no ; then
 837                         dnl try -lc_r
 838                         save_LIBS="$LIBS"
 839                         AC_CHECK_LIB(c_r, pthread_create, [
 840                                 ol_link_threads=posix
 841                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"],:)
 842                         LIBS="$save_LIBS"
 843                 fi
 844
 845                 if test $ol_link_threads = no ; then
 846                         dnl try -lpthreads
 847                         save_LIBS="$LIBS"
 848                         AC_CHECK_LIB(pthreads, pthread_create, [
 849                                 ol_link_threads=posix
 850                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"],:)
 851                         LIBS="$save_LIBS"
 852                 fi
 853
 854                 dnl IRIX Pthread check
 855                 if test $ol_link_threads = no ; then
 856                         dnl try IRIX Pthreads -Wl,-woff,85 -lpthreads
 857                         save_LIBS="$LIBS"
 858                         AC_CHECK_LIB(pthreads, pthread_join, [
 859                                 ol_link_threads=posix
 860                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"
 861                                 ],:,[-Wl,-woff,85])
 862                         LIBS="$save_LIBS"
 863                 fi
 864
 865                 if test $ol_link_threads = no ; then
 866                         dnl try -threads
 867                         AC_CACHE_CHECK([for pthread_create with -threads],
 868                                 [ol_cv_thread_flag], [
 869                                 dnl save the flags
 870                                 save_LIBS="$LIBS"
 871                                 LIBS="-threads $LIBS"
 872                                 AC_TRY_LINK([char pthread_create();],[
 873                                         pthread_create();
 874                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 875                                 dnl restore the LIBS
 876                                 LIBS="$save_LIBS"
 877                         ])
 878
 879                         if test $ol_cv_thread_flag = yes ; then
 880                                 LTHREAD_LIBS="$LTHREAD_LIBS -threads"
 881                                 ol_link_threads=posix
 882                         fi
 883                 fi
 884
 885                 if test $ol_link_threads = no ; then
 886                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 887                         save_LIBS="$LIBS"
 888                         AC_CHECK_LIB(pthreads, pthread_mutex_unlock, [
 889                                 ol_link_threads=posix
 890                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 891                                 if test $ol_with_yielding_select = auto ; then
 892                                         ol_with_yielding_select=yes
 893                                 fi
 894                                 ],:,[-lmach -lexc -lc_r])
 895                         LIBS="$save_LIBS"
 896                 fi
 897
 898                 if test $ol_link_threads = no ; then
 899                         dnl try DEC Threads -lpthreads -lmach -lexc
 900                         save_LIBS="$LIBS"
 901                         AC_CHECK_LIB(pthreads, pthread_mutex_lock, [
 902                                 ol_link_threads=posix
 903                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc"
 904                                 if test $ol_with_yielding_select = auto ; then
 905                                         ol_with_yielding_select=yes
 906                                 fi
 907                                 ],:,[-lmach -lexc])
 908                         LIBS="$save_LIBS"
 909                 fi
 910
 911                 if test $ol_link_threads = no ; then
 912                         dnl try DEC Threads -lpthreads -lexc
 913                         save_LIBS="$LIBS"
 914                         AC_CHECK_LIB(pthreads, pthread_mutex_trylock, [
 915                                 ol_link_threads=posix
 916                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lexc"
 917                                 if test $ol_with_yielding_select = auto ; then
 918                                         ol_with_yielding_select=yes
 919                                 fi
 920                                 ],:,[-lexc])
 921                         LIBS="$save_LIBS"
 922                 fi
 923
 924                 if test $ol_link_threads != no ; then
 925                         AC_DEFINE(HAVE_PTHREADS,1,
 926                                 [define if you have POSIX Threads])
 927
 928                         dnl save flags
 929                         save_CPPFLAGS="$CPPFLAGS"
 930                         save_LIBS="$LIBS"
 931                         LIBS="$LTHREAD_LIBS $LIBS"
 932
 933                         dnl All POSIX Thread (final) implementations should have
 934                         dnl sched_yield instead of pthread yield.
 935                         dnl check for both
 936                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 937
 938                         if test $ac_cv_func_sched_yield = no -a \
 939                                 $ac_cv_func_pthread_yield = no ; then
 940                                 dnl Digital UNIX has sched_yield() in -lrt
 941                                 AC_CHECK_LIB(rt, sched_yield,
 942                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 943                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 944                                         ac_cv_func_sched_yield=yes],
 945                                         [ac_cv_func_sched_yield=no])
 946                         fi
 947                         if test $ac_cv_func_sched_yield = no -a \
 948                                 $ac_cv_func_pthread_yield = no ; then
 949                                 dnl Solaris has sched_yield() in -lposix4
 950                                 dnl but we'll use thr_yield instead.
 951                                 AC_CHECK_FUNCS(thr_yield)
 952                         fi
 953                         if test $ac_cv_func_sched_yield = no -a \
 954                                 $ac_cv_func_pthread_yield = no -a \
 955                                 "$ac_cv_func_thr_yield" = no ; then
 956                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 957                         fi
 958
 959                         dnl Check functions for compatibility
 960                         AC_CHECK_FUNCS(pthread_kill)
 961
 962                         dnl Check for pthread_detach with <pthread.h> inclusion
 963                         dnl as it's symbol may have been mangled.
 964                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
 965                                 [ol_cv_func_pthread_detach], [
 966                                 dnl save the flags
 967                                 AC_TRY_LINK([
 968 #include <pthread.h>
 969 #ifndef NULL
 970 #define NULL (void*)0
 971 #endif
 972 ],
 973                                         [pthread_detach(NULL);],
 974                                         [ol_cv_func_pthread_detach=yes],
 975                                         [ol_cv_func_pthread_detach=no])
 976                         ])
 977
 978                         if test $ol_cv_func_pthread_detach = no ; then
 979                                 AC_MSG_ERROR([could not locate pthread_detach()])
 980                         fi
 981
 982                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
 983                                 [define if you have pthread_detach function])
 984
 985                         dnl Check for setconcurreny functions
 986                         AC_CHECK_FUNCS( \
 987                                 pthread_setconcurrency \
 988                                 pthread_getconcurrency \
 989                                 thr_setconcurrency \
 990                                 thr_getconcurrency \
 991                         )
 992
 993                         AC_MSG_CHECKING([if pthread_create() works])
 994                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 995                         AC_TRY_RUN([
 996 #include <pthread.h>
 997 #ifndef NULL
 998 #define NULL (void*)0
 999 #endif
1000
1001 static void *task(p)
1002         void *p;
1003 {
1004         return (void *) (p == NULL);
1005 }
1006
1007 int main(argc, argv)
1008         int argc;
1009         char **argv;
1010 {
1011         pthread_t t;
1012 #if HAVE_PTHREADS_D4
1013         exit(pthread_create(&t, pthread_attr_default, task, NULL));
1014 #else
1015         exit(pthread_create(&t, NULL, task, NULL));
1016 #endif
1017 }
1018 ],
1019                                 [ol_cv_pthread_create_works=yes],
1020                                 [ol_cv_pthread_create_works=no],
1021                                 [dnl assume yes
1022                                 ol_cv_pthread_create_works=yes])])
1023                         AC_MSG_RESULT($ol_cv_pthread_create_works)
1024
1025                         if test $ol_cv_pthread_create_works = no ; then
1026                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1027                         fi
1028
1029                         dnl Check if select causes an yield
1030                         if test $ol_with_yielding_select = auto ; then
1031                                 AC_MSG_CHECKING([if select yields when using pthreads])
1032                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
1033                                 AC_TRY_RUN([
1034 #include <sys/types.h>
1035 #include <sys/time.h>
1036 #include <unistd.h>
1037 #include <pthread.h>
1038 #ifndef NULL
1039 #define NULL (void*) 0
1040 #endif
1041
1042 static int fildes[2];
1043
1044 static void *task(p)
1045         void *p;
1046 {
1047         int i;
1048         struct timeval tv;
1049
1050         fd_set rfds;
1051
1052         tv.tv_sec=10;
1053         tv.tv_usec=0;
1054
1055         FD_ZERO(&rfds);
1056         FD_SET(fildes[0], &rfds);
1057
1058         /* we're not interested in any fds */
1059         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1060
1061         if(i < 0) {
1062                 perror("select");
1063                 exit(10);
1064         }
1065
1066         exit(0); /* if we exit here, the select blocked the whole process */
1067 }
1068
1069 int main(argc, argv)
1070         int argc;
1071         char **argv;
1072 {
1073         pthread_t t;
1074
1075         /* create a pipe to select */
1076         if(pipe(&fildes[0])) {
1077                 perror("select");
1078                 exit(1);
1079         }
1080
1081 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1082         (void) pthread_setconcurrency(2);
1083 #else
1084 #ifdef HAVE_THR_SETCONCURRENCY
1085         /* Set Solaris LWP concurrency to 2 */
1086         thr_setconcurrency(2);
1087 #endif
1088 #endif
1089
1090 #if HAVE_PTHREADS_D4
1091         pthread_create(&t, pthread_attr_default, task, NULL);
1092 #else
1093         pthread_create(&t, NULL, task, NULL);
1094 #endif
1095
1096 #if HAVE_SCHED_YIELD
1097         sched_yield();  /* make sure task runs first */
1098 #else
1099 #ifdef HAVE_PTHREAD_YIELD
1100         pthread_yield();        /* make sure task runs first */
1101 #endif
1102 #endif
1103
1104         exit(2);
1105 }],
1106                                 [ol_cv_pthread_select_yields=no],
1107                                 [ol_cv_pthread_select_yields=yes], [
1108                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
1109                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
1110
1111                                 if test $ol_cv_pthread_select_yields = yes ; then
1112                                         ol_with_yielding_select=yes
1113                                 fi
1114                         fi
1115
1116                         dnl restore flags
1117                         CPPFLAGS="$save_CPPFLAGS"
1118                         LIBS="$save_LIBS"
1119                 else
1120                         AC_MSG_ERROR([could not link with POSIX Threads])
1121                 fi
1122         fi
1123
1124         if test $ol_with_threads = posix ; then
1125                 AC_MSG_ERROR([could not locate POSIX Threads])
1126         fi
1127 fi
1128
1129 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1130         -o $ol_with_threads = mach ; then
1131
1132         dnl check for Mach CThreads
1133         AC_CHECK_HEADERS(mach/cthreads.h)
1134         if test $ac_cv_header_mach_cthreads_h = yes ; then
1135                 ol_with_threads=found
1136
1137                 dnl check for cthread support in current $LIBS
1138                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1139
1140                 if test $ol_link_threads = no ; then
1141                         dnl try -all_load
1142                         dnl this test needs work
1143                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1144                                 [ol_cv_cthread_all_load], [
1145                                 dnl save the flags
1146                                 save_LIBS="$LIBS"
1147                                 LIBS="-all_load $LIBS"
1148                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1149                                         cthread_fork((void *)0, (void *)0);
1150                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1151                                 dnl restore the LIBS
1152                                 LIBS="$save_LIBS"
1153                         ])
1154
1155                         if test $ol_cv_cthread_all_load = yes ; then
1156                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1157                                 ol_link_threads=mach
1158                         fi
1159                 fi
1160
1161                 if test $ol_link_threads != no ; then
1162                         : check for cthread specific functionality here
1163                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1164                                 [define if you have Mach Cthreads])
1165                 else
1166                         AC_MSG_ERROR([could not link with Mach CThreads])
1167                 fi
1168         fi
1169
1170         if test $ol_with_threads = mach ; then
1171                 AC_MSG_ERROR([could not locate Mach CThreads])
1172         fi
1173 fi
1174
1175 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1176         -o $ol_with_threads = lwp ; then
1177
1178         dnl check for SunOS5 LWP
1179         AC_CHECK_HEADERS(thread.h synch.h)
1180         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1181                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1182
1183                 if test $have_thr = yes ; then
1184                         AC_DEFINE(HAVE_THR,1,
1185                                 [if you have Solaris LWP (thr) package])
1186                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1187                         ol_link_threads=thr
1188
1189                         if test $ol_with_yielding_select = auto ; then
1190                                 ol_with_yielding_select=yes
1191                         fi
1192
1193                         dnl Check for setconcurreny functions
1194                         AC_CHECK_FUNCS( \
1195                                 thr_setconcurrency \
1196                                 thr_getconcurrency \
1197                         )
1198                 fi
1199         fi
1200
1201         dnl check for SunOS4 LWP
1202         AC_CHECK_HEADERS(lwp/lwp.h)
1203         if test $ac_cv_header_lwp_lwp_h = yes ; then
1204                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1205
1206                 if test $have_lwp = yes ; then
1207                         AC_DEFINE(HAVE_LWP,1,
1208                                 [if you have SunOS LWP package])
1209                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1210                         ol_link_threads=lwp
1211
1212                         if test $ol_with_yielding_select = auto ; then
1213                                 ol_with_yielding_select=no
1214                         fi
1215                 fi
1216         fi
1217 fi
1218
1219 if test $ol_with_yielding_select = yes ; then
1220         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1221                 [define if select implicitly yields])
1222 fi
1223
1224 if test $ol_with_threads = manual ; then
1225         dnl User thinks he can manually configure threads.
1226         ol_link_threads=yes
1227
1228         AC_MSG_WARN([thread defines and link options must be set manually])
1229
1230         AC_CHECK_HEADERS(pthread.h sched.h)
1231         AC_CHECK_FUNCS(sched_yield pthread_yield)
1232         OL_LINUX_THREADS
1233
1234         AC_CHECK_HEADERS(mach/cthreads.h)
1235         AC_CHECK_HEADERS(lwp/lwp.h)
1236         AC_CHECK_HEADERS(thread.h synch.h)
1237 fi
1238
1239 if test $ol_link_threads != no ; then
1240         dnl needed to get reentrant/threadsafe versions
1241         dnl
1242         AC_DEFINE(REENTRANT,1)
1243         AC_DEFINE(_REENTRANT,1)
1244         AC_DEFINE(THREAD_SAFE,1)
1245         AC_DEFINE(_THREAD_SAFE,1)
1246         AC_DEFINE(THREADSAFE,1)
1247         AC_DEFINE(_THREADSAFE,1)
1248
1249         dnl this might cause the errno symbol to be
1250         dnl replaced with a function to get a thread specific errno.
1251         dnl check to see if everything needs to be compiled
1252         dnl with the thread libraries
1253         AC_CACHE_CHECK([for thread specific errno],
1254                 [ol_cv_errno_thread_specific], [
1255                 AC_TRY_LINK([#include <errno.h>], [int x = errno;],
1256                         [ol_cv_errno_thread_specific=yes],
1257                         [ol_cv_errno_thread_specific=no])
1258         ])
1259
1260         if test $ol_cv_errno_thread_specific != yes ; then
1261                 LIBS="$LTHREAD_LIBS $LIBS"
1262                 LTHREAD_LIBS=""
1263         fi
1264
1265 dnl When in thread environment, use
1266 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1267 dnl                     || defined( HAVE_FUNC_R )
1268 dnl                     func_r(...);
1269 dnl             #else
1270 dnl             #       if defined( HAVE_THREADS )
1271 dnl                             /* lock */
1272 dnl             #       endif
1273 dnl                             func(...);
1274 dnl             #       if defined( HAVE_THREADS )
1275 dnl                             /* unlock */
1276 dnl             #       endif
1277 dnl             #endif
1278 dnl
1279 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1280 dnl             _POSIX_REENTRANT_FUNCTIONS
1281 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1282 dnl             _POSIX_THREADSAFE_FUNCTIONS
1283 dnl
1284 dnl             and is currently defined in lthread.h
1285 dnl
1286 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1287 dnl
1288 dnl libldap/*.c should only include <lthread.h> iff
1289 dnl LDAP_R_COMPILE is defined.  ie:
1290 dnl             #ifdef LDAP_R_COMPILE
1291 dnl             #       include LDAP_R_COMPILE
1292 dnl             #endif
1293 dnl
1294 dnl LDAP_R_COMIPLE is defined by libldap_r/Makefile.in
1295 dnl specifically for compiling the threadsafe version of
1296 dnl     the ldap library (-lldap_r).
1297 dnl
1298 dnl     dnl check for reentrant/threadsafe functions
1299 dnl     dnl
1300 dnl     dnl note: these should only be used when linking
1301 dnl     dnl       with $LTHREAD_LIBS
1302 dnl     dnl
1303 dnl     save_CPPFLAGS="$CPPFLAGS"
1304 dnl     save_LIBS="$LIBS"
1305 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1306 dnl     AC_CHECK_FUNCS( \
1307 dnl             gmtime_r \
1308 dnl             gethostbyaddr_r gethostbyname_r \
1309 dnl             feof_unlocked unlocked_feof \
1310 dnl             putc_unlocked unlocked_putc \
1311 dnl             flockfile ftrylockfile \
1312 dnl     )
1313 dnl     CPPFLAGS="$save_CPPFLAGS"
1314 dnl     LIBS="$save_LIBS"
1315 fi
1316
1317 if test $ol_link_threads = no ; then
1318         if test $ol_with_threads = yes ; then
1319                 AC_MSG_ERROR([no suitable thread support])
1320         fi
1321
1322         if test $ol_with_threads = auto ; then
1323                 AC_MSG_WARN([no suitable thread support, disabling threads])
1324                 ol_with_threads=no
1325         fi
1326
1327         AC_DEFINE(NO_THREADS,1,
1328                 [define if you have (or want) no threads])
1329         LTHREAD_LIBS=""
1330 fi
1331
1332 if test $ol_link_threads != no ; then
1333         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1334 fi
1335
1336 dnl ----------------------------------------------------------------
1337
1338 ol_link_ldbm=no
1339 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1340         OL_BERKELEY_DB2
1341
1342         if test $ol_cv_berkeley_db2 = yes ; then
1343                 ol_link_ldbm=db2
1344                 ol_with_ldbm_api=db2
1345
1346                 if test $ol_with_ldbm_type = hash ; then
1347                         AC_DEFINE(LDBM_USE_DBHASH,1)
1348                 else
1349                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1350                 fi
1351
1352                 dnl $ol_cv_lib_db2 should be yes or -ldb
1353                 dnl (it could be no, but that would be an error
1354                 if test $ol_cv_lib_db2 != yes ; then
1355                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1356                 fi
1357         fi
1358 fi
1359
1360 ol_link_bdb2=no
1361 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1362         ol_link_bdb2=yes
1363 fi
1364
1365 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1366         OL_BERKELEY_DB
1367
1368         if test $ol_cv_berkeley_db = yes ; then
1369                 ol_link_ldbm=db
1370                 ol_with_ldbm_api=db
1371
1372                 if test $ol_with_ldbm_type = hash ; then
1373                         AC_DEFINE(LDBM_USE_DBHASH,1)
1374                 else
1375                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1376                 fi
1377
1378                 dnl $ol_cv_lib_db should be yes or -ldb
1379                 dnl (it could be no, but that would be an error
1380                 if test $ol_cv_lib_db != yes ; then
1381                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1382                 fi
1383         fi
1384 fi
1385
1386 if test $ol_with_ldbm_api = manual ; then
1387         dnl User thinks he can manually configure LDBM api.
1388         ol_link_ldbm=yes
1389
1390         AC_MSG_WARN([LDBM defines and link options must be set manually])
1391
1392         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1393 fi
1394
1395 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1396         AC_MSG_WARN(Could not find LDBM with BTREE support)
1397         ol_with_ldbm_api=none
1398 fi
1399
1400 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1401         OL_GDBM
1402
1403         if test $ol_cv_gdbm = yes ; then
1404                 ol_link_ldbm=gdbm
1405                 ol_with_ldbm_api=gdbm
1406
1407                 if test $ol_cv_lib_gdbm != yes ; then
1408                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1409                 fi
1410         fi
1411 fi
1412
1413 if test $ol_with_ldbm_api = auto ; then
1414         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1415 elif test $ol_with_ldbm_api = ndbm ; then
1416         OL_NDBM
1417
1418         if test $ol_cv_ndbm = yes ; then
1419                 ol_link_ldbm=ndbm
1420                 ol_with_ldbm_api=ndbm
1421
1422                 if test $ol_cv_lib_ndbm != yes ; then
1423                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1424                 fi
1425         fi
1426 fi
1427
1428 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1429         AC_MSG_WARN(could not find suitable LDBM backend)
1430         if test $ol_enable_ldbm = yes ; then
1431                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1432         fi
1433
1434         AC_MSG_WARN(disabling LDBM)
1435         ol_enable_ldbm=no
1436 fi
1437
1438 if test $ol_enable_wrappers != no ; then
1439         AC_CHECK_HEADERS(tcpd.h)
1440
1441         if test $ac_cv_header_tcpd_h != yes ; then
1442                 have_wrappers=no
1443         else
1444                 AC_CHECK_LIB(wrap, main,
1445                         [have_wrappers=yes], [have_wrappers=no])
1446         fi
1447
1448         if test $have_wrappers = yes ; then
1449                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1450                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1451         else
1452                 AC_MSG_WARN(could not find -lwrap)
1453                 if test $ol_enable_wrappers = yes ; then
1454                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1455                 fi
1456
1457                 AC_MSG_WARN(disabling wrappers support)
1458                 ol_enable_wrappers=no
1459         fi
1460 fi
1461
1462 if test $ol_enable_syslog != no ; then
1463         AC_CHECK_FUNC(openlog)
1464         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1465                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1466         fi
1467         ol_enable_syslog=$ac_cv_func_openlog
1468 fi
1469
1470 if test $ol_enable_dmalloc != no ; then
1471         AC_CHECK_HEADERS(dmalloc.h)
1472         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1473 fi
1474
1475 if test $ol_enable_tcl != no ; then
1476         AC_CHECK_HEADERS(tcl.h)
1477
1478         if test $ac_cv_header_tcl_h != yes ; then
1479                 have_tcl=no
1480         else
1481                 AC_CHECK_LIB(tcl,main,
1482                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1483                         [have_tcl=no])
1484
1485                 if test $have_tcl != yes; then
1486                         AC_CHECK_LIB(tcl7.6,main,
1487                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1488                                 [have_tcl=no])
1489                 fi
1490
1491                 if test $have_tcl != yes; then
1492                         AC_CHECK_LIB(tcl8.0,main,
1493                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1494                                 [have_tcl=no])
1495                 fi
1496         fi
1497
1498         if test $have_tcl != yes ; then
1499                 AC_MSG_WARN([could not find -ltcl])
1500                 if test $ol_enable_tcl = yes ; then
1501                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1502                 fi
1503
1504                 ol_enable_tcl=no
1505         fi
1506 fi
1507
1508 # ud needs termcap (should insert check here)
1509 ol_link_termcap=no
1510 AC_CHECK_HEADERS(termcap.h ncurses.h)
1511
1512 if test $ol_link_termcap = no ; then
1513         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1514         if test $have_termcap = yes ; then
1515                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1516                 ol_link_termcap=yes
1517                 TERMCAP_LIBS=-ltermcap
1518         fi
1519 fi
1520
1521 if test $ol_link_termcap = no ; then
1522         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1523         if test $have_ncurses = yes ; then
1524                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1525                 ol_link_termcap=yes
1526                 TERMCAP_LIBS=-lncurses
1527         fi
1528 fi
1529
1530 if test $ol_link_termcap = no ; then
1531         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1532         TERMCAP_LIBS=
1533 fi
1534
1535 dnl
1536 dnl Check for GNU readline
1537 dnl
1538 ol_link_readline=no
1539 if test $ol_with_readline != no ; then
1540         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1541
1542         if test $ac_cv_header_readline_readline_h = yes ; then
1543                 save_LIBS="$LIBS"
1544                 LIBS="$TERMCAP_LIBS $LIBS"
1545                 AC_CHECK_LIB(readline, readline,
1546                         [have_readline=yes], [have_readline=no])
1547                 LIBS="$save_LIBS"
1548
1549                 if test $have_readline = yes ; then
1550                         ol_with_readline=found
1551                         ol_link_readline=yes
1552
1553                         READLINE_LIBS="-lreadline"
1554                 fi
1555         fi
1556 fi
1557
1558 if test $ol_link_readline = yes ; then
1559         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1560 fi
1561
1562
1563 # FreeBSD (and others) have crypt(3) in -lcrypt
1564 if test $ol_enable_crypt != no ; then
1565         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1566                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1567                         have_crypt=yes], [have_crypt=no])])
1568
1569         if test $have_crypt = yes ; then
1570                 AC_DEFINE(HAVE_CRYPT,1)
1571         else
1572                 AC_MSG_WARN(could not find crypt)
1573                 if test $ol_enable_crypt = yes ; then
1574                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1575                 fi
1576
1577                 AC_MSG_WARN(disabling crypt support)
1578                 ol_enable_crypt=no
1579         fi
1580 fi
1581
1582 # FreeBSD (and others) have setproctitle(3) in -lutil
1583 if test $ol_enable_proctitle != no ; then
1584         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1585                 AC_CHECK_LIB(util, setproctitle,
1586                         [have_setproctitle=yes
1587                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1588                         [have_setproctitle=no
1589                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1590
1591         if test $have_setproctitle = yes ; then
1592                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1593         fi
1594 fi
1595
1596 dnl ----------------------------------------------------------------
1597 dnl Checks for header files.
1598 OL_HEADER_STDC
1599
1600 if test $ol_cv_header_stdc != yes; then
1601         AC_MSG_WARN([could not Standard C compliant headers])
1602 fi
1603
1604 AC_HEADER_DIRENT
1605 AC_HEADER_SYS_WAIT
1606 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1607 if test $am_cv_sys_posix_termios = yes ; then
1608         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1609                 [define if you have POSIX termios])
1610 fi
1611
1612 AC_CHECK_HEADERS(       \
1613         arpa/inet.h             \
1614         arpa/nameser.h  \
1615         assert.h                \
1616         crypt.h                 \
1617         errno.h                 \
1618         fcntl.h                 \
1619         filio.h                 \
1620         getopt.h                \
1621         libutil.h               \
1622         limits.h                \
1623         locale.h                \
1624         malloc.h                \
1625         memory.h                \
1626         regex.h                 \
1627         psap.h                  \
1628         pwd.h                   \
1629         resolv.h                \
1630         sgtty.h                 \
1631         stdarg.h                \
1632         stddef.h                \
1633         string.h                \
1634         strings.h               \
1635         sysexits.h              \
1636         sys/file.h              \
1637         sys/filio.h             \
1638         sys/errno.h             \
1639         sys/ioctl.h             \
1640         sys/param.h             \
1641         sys/resource.h  \
1642         sys/socket.h    \
1643         sys/syslog.h    \
1644         sys/time.h              \
1645         sys/types.h             \
1646         syslog.h                \
1647         termios.h               \
1648         unistd.h                \
1649 )
1650
1651 dnl ----------------------------------------------------------------
1652 dnl Checks for typedefs, structures, and compiler characteristics.
1653 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1654 AC_TYPE_MODE_T
1655 AC_TYPE_OFF_T
1656 AC_TYPE_PID_T
1657 AM_TYPE_PTRDIFF_T
1658 AC_TYPE_SIGNAL
1659 OL_TYPE_SIG_ATOMIC_T
1660 AC_TYPE_SIZE_T
1661 AC_STRUCT_ST_BLKSIZE
1662 AC_HEADER_TIME
1663 AC_STRUCT_TM
1664 OL_STRUCT_PASSWD_PW_GECOS
1665
1666 OL_C_UPPER_LOWER
1667 AC_C_CONST
1668 OL_C_VOLATILE
1669
1670 if test $cross_compiling = yes ; then
1671         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1672 else
1673         AC_C_BIGENDIAN
1674         AC_CHECK_SIZEOF(short)
1675         AC_CHECK_SIZEOF(int)
1676         AC_CHECK_SIZEOF(long)
1677 fi
1678
1679 dnl ----------------------------------------------------------------
1680 dnl Checks for library functions.
1681 AC_FUNC_MEMCMP
1682 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1683 AC_FUNC_STRFTIME
1684 dnl AM_FUNC_STRTOD
1685 AC_FUNC_VPRINTF
1686
1687 if test $ac_cv_func_vprintf = yes ; then
1688         dnl check for vsnprintf
1689         AC_CHECK_FUNCS(vsnprintf vsprintf)
1690 fi
1691
1692 AC_CHECK_FUNCS(         \
1693         bcopy                   \
1694         flock                   \
1695         getdtablesize           \
1696         gethostname             \
1697         getpass                 \
1698         getpwuid                \
1699         gettimeofday            \
1700         lockf                   \
1701         memcpy                  \
1702         memmove                 \
1703         mkstemp                 \
1704         select                  \
1705         setpwfile               \
1706         setsid                  \
1707         signal                  \
1708         sigset                  \
1709         snprintf                \
1710         socket                  \
1711         strdup                  \
1712         strerror                \
1713         strpbrk                 \
1714         strrchr                 \
1715         strsep                  \
1716         strstr                  \
1717         strtol                  \
1718         strtoul                 \
1719         strspn                  \
1720         sysconf                 \
1721         waitpid                 \
1722         wait4                   \
1723 )
1724
1725 dnl We actually may need to replace more than this.
1726 AC_REPLACE_FUNCS(getopt tempnam)
1727
1728 dnl ----------------------------------------------------------------
1729 # Check Configuration
1730 OL_SYS_ERRLIST
1731
1732 dnl ----------------------------------------------------------------
1733 dnl Check our declaration of strdup()
1734 OL_DECL_STRDUP
1735
1736 dnl ----------------------------------------------------------------
1737 dnl Sort out defines
1738
1739 if test "$ol_enable_debug" != no ; then
1740         AC_DEFINE(LDAP_DEBUG,1)
1741 fi
1742 if test "$ol_enable_syslog" = yes ; then
1743         AC_DEFINE(LDAP_SYSLOG,1)
1744 fi
1745 if test "$ol_enable_libui" = yes ; then
1746         AC_DEFINE(LDAP_LIBUI,1)
1747 fi
1748 if test "$ol_enable_cache" = no ; then
1749         AC_DEFINE(LDAP_NOCACHE,1)
1750 fi
1751 if test "$ol_enable_dns" != no ; then
1752         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1753 fi
1754 if test "$ol_enable_proctitle" != no ; then
1755         AC_DEFINE(LDAP_PROCTITLE,1)
1756 fi
1757 if test "$ol_enable_referrals" != no ; then
1758         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1759 fi
1760 if test "$ol_enable_cldap" != no ; then
1761         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1762 fi
1763
1764 if test "$ol_enable_aclgroups" != no ; then
1765         AC_DEFINE(SLAPD_ACLGROUPS,1)
1766 fi
1767 if test "$ol_enable_crypt" != no ; then
1768         AC_DEFINE(SLAPD_CRYPT,1)
1769 fi
1770 if test "$ol_enable_cleartext" != no ; then
1771         AC_DEFINE(SLAPD_CLEARTEXT,1)
1772 fi
1773 if test "$ol_enable_phonetic" != no ; then
1774         AC_DEFINE(SLAPD_PHONETIC,1)
1775 fi
1776 if test "$ol_enable_rlookups" != no ; then
1777         AC_DEFINE(SLAPD_RLOOKUPS,1)
1778 fi
1779
1780 if test "$ol_link_bdb2" != no ; then
1781         AC_DEFINE(SLAPD_BDB2,1)
1782         BUILD_SLAPD=yes
1783         BUILD_BDB2=yes
1784 fi
1785
1786 if test "$ol_link_ldbm" != no ; then
1787         AC_DEFINE(SLAPD_LDBM,1)
1788         BUILD_SLAPD=yes
1789         BUILD_LDBM=yes
1790 fi
1791
1792 if test "$ol_enable_passwd" != no ; then
1793         AC_DEFINE(SLAPD_PASSWD,1)
1794         BUILD_SLAPD=yes
1795         BUILD_PASSWD=yes
1796 fi
1797
1798 if test "$ol_enable_perl" != no ; then
1799         AC_DEFINE(SLAPD_PERL,1)
1800         BUILD_SLAPD=yes
1801         BUILD_PERL=yes
1802 fi
1803
1804 if test "$ol_enable_shell" != no ; then
1805         AC_DEFINE(SLAPD_SHELL,1)
1806         BUILD_SLAPD=yes
1807         BUILD_SHELL=yes
1808 fi
1809
1810 if test "$ol_enable_tcl" != no ; then
1811         AC_DEFINE(SLAPD_TCL,1)
1812         BUILD_SLAPD=yes
1813         BUILD_TCL=yes
1814 fi
1815
1816 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1817         $BUILD_SLAPD = yes ; then
1818         BUILD_SLURPD=yes
1819 fi
1820
1821 if test "$ol_link_isode" != no ; then
1822         BUILD_LDAPD=yes
1823 fi
1824
1825 dnl ----------------------------------------------------------------
1826
1827 AC_SUBST(BUILD_LDAPD)
1828 AC_SUBST(BUILD_SLAPD)
1829   AC_SUBST(BUILD_BDB2)
1830   AC_SUBST(BUILD_LDBM)
1831   AC_SUBST(BUILD_PASSWD)
1832   AC_SUBST(BUILD_PERL)
1833   AC_SUBST(BUILD_SHELL)
1834   AC_SUBST(BUILD_TCL)
1835 AC_SUBST(BUILD_SLURPD)
1836
1837 AC_SUBST(LDAP_LIBS)
1838 AC_SUBST(LDAPD_LIBS)
1839 AC_SUBST(SLAPD_LIBS)
1840 AC_SUBST(SLURPD_LIBS)
1841 AC_SUBST(LDBM_LIBS)
1842 AC_SUBST(LTHREAD_LIBS)
1843 AC_SUBST(LUTIL_LIBS)
1844
1845 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1846 AC_SUBST(SLAPD_PERL_LDFLAGS)
1847
1848 AC_SUBST(KRB_LIBS)
1849 AC_SUBST(READLINE_LIBS)
1850 AC_SUBST(TERMCAP_LIBS)
1851 AC_SUBST(TLS_LIBS)
1852
1853 dnl ----------------------------------------------------------------
1854 dnl final output
1855 dnl
1856
1857 AC_OUTPUT( \
1858 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1859 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1860 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1861 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1862 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1863 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1864 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1865 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1866 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1867 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1868 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1869 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1870 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1871 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1872 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1873 include/Makefile:build/top.mk:include/Makefile.in \
1874 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1875 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1876 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1877 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1878 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1879 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1880 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1881 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1882 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1883 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1884 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1885 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
1886 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1887 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1888 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
1889 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1890 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
1891 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1892 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1893 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1894 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
1895 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
1896 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
1897 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
1898 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
1899 ,[
1900 date > stamp-h
1901 echo Please \"make depend\" to build dependencies
1902 ])