git.sur5r.net Git - glabels/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.52)
   4
   5 AC_INIT(glabels, 2.3.pre0svn, http://sourceforge.net/tracker/?func=add&group_id=46122&atid=445116)
   6 AC_CONFIG_SRCDIR(src/glabels.c)
   7
   8 AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
   9
  10 AM_MAINTAINER_MODE
  11 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  12
  13 AC_CONFIG_HEADERS(config.h)
  14
  15 IT_PROG_INTLTOOL([0.21])
  16
  17 PKG_PROG_PKG_CONFIG
  18
  19 AC_PROG_LIBTOOL
  20
  21 GNOME_DOC_INIT
  22 GTK_DOC_CHECK(1.0)
  23
  24 AC_ISC_POSIX
  25 AC_PROG_CC
  26 AC_PROG_INSTALL
  27
  28 GNOME_COMPILE_WARNINGS
  29
  30 AC_PATH_PROG(GLIB_GENMARSHAL,    glib-genmarshal)
  31 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource)
  32
  33
  34 dnl ---------------------------------------------------------------------------
  35 dnl - LIBGLABELS API versioning
  36 dnl ---------------------------------------------------------------------------
  37 dnl From the libtool manual:
  38 dnl 1. Start with version information of `0:0:0' for each libtool library.
  39 dnl 2. Update the version information only immediately before a public release.
  40 dnl    More frequent updates are unnecessary, and only guarantee that the current
  41 dnl    interface number gets larger faster.
  42 dnl 3. If the library source code has changed at all since the last update, then increment
  43 dnl    revision (`c:r:a' becomes `c:r+1:a').
  44 dnl 4. If any interfaces have been added, removed, or changed since the last update,
  45 dnl    increment current, and set revision to 0.
  46 dnl 5. If any interfaces have been added since the last public release, then increment age.
  47 dnl 6. If any interfaces have been removed since the last public release, then set age
  48 dnl    to 0.
  49 LIBGLABELS_C=5
  50 LIBGLABELS_R=1
  51 LIBGLABELS_A=0
  52
  53 LIBGLABELS_VERSION_INFO=${LIBGLABELS_C}:${LIBGLABELS_R}:${LIBGLABELS_A}
  54 AC_SUBST(LIBGLABELS_VERSION_INFO)
  55
  56
  57 dnl ---------------------------------------------------------------------------
  58 dnl - Library dependencies
  59 dnl ---------------------------------------------------------------------------
  60 dnl Required dependencies
  61 GLIB_REQUIRED=2.22.0
  62 GTK_REQUIRED=2.18.0
  63 GCONF_REQUIRED=2.28.0
  64 LIBXML_REQUIRED=2.7.0
  65
  66 dnl Optional dependencies
  67 LIBEBOOK_REQUIRED=2.28.0
  68 LIBBARCODE_REQUIRED=0.98
  69 LIBQRENCODE_REQUIRED=3.1.0
  70 LIBIEC16022_REQUIRED=0.2.4
  71
  72 dnl Make above strings available for packaging files (e.g. rpm spec files)
  73 AC_SUBST(GLIB_REQUIRED)
  74 AC_SUBST(GTK_REQUIRED)
  75 AC_SUBST(GCONF_REQUIRED)
  76 AC_SUBST(LIBXML_REQUIRED)
  77 AC_SUBST(LIBEBOOK_REQUIRED)
  78 AC_SUBST(LIBBARCODE_REQUIRED)
  79 AC_SUBST(LIBQRENCODE_REQUIRED)
  80 AC_SUBST(LIBIEC16022_REQUIRED)
  81
  82
  83 dnl ---------------------------------------------------------------------------
  84 dnl - GLABELS prerequisites
  85 dnl ---------------------------------------------------------------------------
  86 PKG_CHECK_MODULES(GLABELS, \
  87 glib-2.0 >= $GLIB_REQUIRED \
  88 gtk+-2.0 >= $GTK_REQUIRED \
  89 gconf-2.0 >= $GCONF_REQUIRED \
  90 libxml-2.0 >= $LIBXML_REQUIRED \
  91 )
  92
  93 AC_SUBST(GLABELS_CFLAGS)
  94 AC_SUBST(GLABELS_LIBS)
  95
  96
  97 dnl ---------------------------------------------------------------------------
  98 dnl - LIBGLABELS more modest prerequisites
  99 dnl ---------------------------------------------------------------------------
 100 PKG_CHECK_MODULES(LIBGLABELS, \
 101 glib-2.0 >= $GLIB_REQUIRED \
 102 gconf-2.0 >= $GCONF_REQUIRED \
 103 libxml-2.0 >= $LIBXML_REQUIRED \
 104 )
 105
 106 AC_SUBST(LIBGLABELS_CFLAGS)
 107 AC_SUBST(LIBGLABELS_LIBS)
 108
 109
 110 dnl ---------------------------------------------------------------------------
 111 dnl - Check for optional evolution data server
 112 dnl ---------------------------------------------------------------------------
 113 AC_ARG_WITH(libebook,
 114             [AC_HELP_STRING([--without-libebook],
 115                             [build without Evolution Data Server support])])
 116 have_libebook=no
 117 if test "x$with_libebook" != xno; then
 118         PKG_CHECK_MODULES(LIBEBOOK, libebook-1.2 >= $LIBEBOOK_REQUIRED,
 119                           [have_libebook=yes], [have_libebook=no])
 120 fi
 121
 122 if test "x$have_libebook" = "xyes"; then
 123         AC_DEFINE(HAVE_LIBEBOOK,1,[Define to 1 for EDS support])
 124         AC_SUBST(LIBEBOOK_CFLAGS)
 125         AC_SUBST(LIBEBOOK_LIBS)
 126 fi
 127
 128
 129 dnl ---------------------------------------------------------------------------
 130 dnl - Check for optional GNU Barcode backend
 131 dnl ---------------------------------------------------------------------------
 132 AC_ARG_WITH(libbarcode,
 133             [AC_HELP_STRING([--without-libbarcode],
 134                             [build without GNU Barcode support])])
 135 have_libbarcode=no
 136 if test "x$with_libbarcode" != xno; then
 137    AC_CHECK_LIB(barcode, Barcode_Create,
 138                 [have_libbarcode=yes], [have_libbarcode=no])
 139 fi
 140
 141 if test "x$have_libbarcode" = "xyes"; then
 142         AC_DEFINE(HAVE_LIBBARCODE,1,[Define to 1 for GNU Barcode support])
 143         LIBBARCODE_CFLAGS=""
 144         LIBBARCODE_LIBS="-lbarcode"
 145         AC_SUBST(LIBBARCODE_CFLAGS)
 146         AC_SUBST(LIBBARCODE_LIBS)
 147 else
 148         help_libbarcode="(See http://www.gnu.org/software/barcode/barcode.html)"
 149 fi
 150
 151
 152 dnl ---------------------------------------------------------------------------
 153 dnl - Check for optional QRencode Barcode backend
 154 dnl ---------------------------------------------------------------------------
 155 AC_ARG_WITH(libqrencode,
 156             [AC_HELP_STRING([--without-libqrencode],
 157                             [build without QR code support])])
 158 have_libqrencode=no
 159 if test "x$with_libqrencode" != xno; then
 160         PKG_CHECK_MODULES(LIBQRENCODE, libqrencode >= $LIBQRENCODE_REQUIRED,
 161                           [have_libqrencode=yes], [have_libqrencode=no])
 162 fi
 163
 164 if test "x$have_libqrencode" = "xyes"; then
 165         AC_DEFINE(HAVE_LIBQRENCODE,1,[Define to 1 for QR code support])
 166         AC_SUBST(LIBQRENCODE_CFLAGS)
 167         AC_SUBST(LIBQRENCODE_LIBS)
 168 else
 169         help_libqrencode="(See http://megaui.net/fukuchi/works/qrencode/index.en.html)"
 170 fi
 171
 172
 173 dnl ---------------------------------------------------------------------------
 174 dnl - Check for IEC16022 Barcode backend
 175 dnl ---------------------------------------------------------------------------
 176 AC_ARG_WITH(libiec16022,
 177             [AC_HELP_STRING([--without-libiec16022],
 178                             [build without IEC 16022 support])])
 179 have_libiec16022=no
 180 if test "x$with_libiec16022" != xno; then
 181         PKG_CHECK_MODULES(LIBIEC16022, libiec16022 >= $LIBIEC16022_REQUIRED,
 182                           [have_libiec16022=yes], [have_libiec16022=no])
 183 fi
 184
 185 if test "x$have_libiec16022" = "xyes"; then
 186         AC_DEFINE(HAVE_LIBIEC16022,1,[Define to 1 for IEC 16022 support])
 187         AC_SUBST(LIBIEC16022_CFLAGS)
 188         AC_SUBST(LIBIEC16022_LIBS)
 189 else
 190         help_libiec16022="(See http://datenfreihafen.org/projects/iec16022.html)"
 191 fi
 192
 193
 194 dnl ---------------------------------------------------------------------------
 195 dnl - Enable deprecation testing
 196 dnl ---------------------------------------------------------------------------
 197 AC_ARG_ENABLE(deprecations,
 198               [AC_HELP_STRING([--enable-deprecations],
 199                               [warn about deprecated usages [default=no]])],,
 200               [enable_deprecations=no])
 201
 202 if test "x$enable_deprecations" = "xyes"; then
 203    DISABLE_DEPRECATED_CFLAGS="\
 204 -DG_DISABLE_DEPRECATED \
 205 -DGDK_DISABLE_DEPRECATED \
 206 -DGTK_DISABLE_DEPRECATED \
 207 -DGDK_PIXBUF_DISABLE_DEPRECATED \
 208 "
 209    AC_SUBST(DISABLE_DEPRECATED_CFLAGS)
 210 fi
 211
 212
 213 dnl ---------------------------------------------------------------------------
 214 dnl - Is freedesktop mime dbase available?
 215 dnl ---------------------------------------------------------------------------
 216 AC_PATH_PROG(UPDATE_MIME_DATABASE, update-mime-database, no)
 217 AM_CONDITIONAL(HAVE_NEW_MIME, test x$UPDATE_MIME_DATABASE != xno)
 218
 219 AC_PATH_PROG(UPDATE_DESKTOP_DATABASE, update-desktop-database, no)
 220 AM_CONDITIONAL(HAVE_NEWER_MIME, test x$UPDATE_DESKTOP_DATABASE != xno)
 221
 222 AC_ARG_ENABLE(update-mimedb, AC_HELP_STRING([--disable-update-mimedb],
 223               [disable the update-mime-database after install [default=no]]),,
 224               enable_update_mimedb=yes)
 225 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x$enable_update_mimedb = xyes)
 226
 227 AC_ARG_ENABLE(update-desktopdb, AC_HELP_STRING([--disable-update-desktopdb],
 228               [disable the update-desktop-database after install [default=no]]),,
 229               enable_update_desktopdb=yes)
 230 AM_CONDITIONAL(ENABLE_UPDATE_DESKTOPDB, test x$enable_update_desktopdb = xyes)
 231
 232
 233 dnl ---------------------------------------------------------------------------
 234 dnl - Supported languages
 235 dnl ---------------------------------------------------------------------------
 236 GETTEXT_PACKAGE=glabels
 237 AC_SUBST(GETTEXT_PACKAGE)
 238 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext package])
 239
 240 AM_GLIB_GNU_GETTEXT
 241
 242
 243 dnl ---------------------------------------------------------------------------
 244 dnl - Makefiles, etc.
 245 dnl ---------------------------------------------------------------------------
 246 AC_OUTPUT([
 247 Makefile
 248 libglabels/Makefile
 249 libglabels/libglabels.pc
 250 src/Makefile
 251 src/pixmaps/Makefile
 252 src/stock-pixmaps/Makefile
 253 data/Makefile
 254 data/pixmaps/Makefile
 255 data/mime/Makefile
 256 data/builder/Makefile
 257 data/desktop/Makefile
 258 data/man/Makefile
 259 templates/Makefile
 260 po/Makefile.in
 261 help/Makefile
 262 docs/Makefile
 263 docs/libglabels/Makefile
 264 glabels.spec
 265 ])
 266
 267
 268 dnl ---------------------------------------------------------------------------
 269 dnl - Print configuration information
 270 dnl ---------------------------------------------------------------------------
 271 echo "
 272
 273 Configuration:
 274
 275         Package ................. ${PACKAGE}-${VERSION}
 276         Installation prefix ..... ${prefix}
 277         Source code location .... ${srcdir}
 278         Compiler ................ ${CC}
 279
 280
 281 Optional data merge backends:
 282
 283         Evolution Data Server ... ${have_libebook}
 284
 285
 286 Optional barcode backends:
 287
 288         GNU Barcode ............. ${have_libbarcode} ${help_libbarcode}
 289         QR Code ................. ${have_libqrencode} ${help_libqrencode}
 290         IEC 16022 ............... ${have_libiec16022} ${help_libiec16022}
 291
 292
 293 "
 294
 295
 296 cat ${srcdir}/MESSAGE-OF-DOOM
 297