git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms are permitted only
   6 dnl as authorized by the OpenLDAP Public License.  A copy of this
   7 dnl license is available at http://www.OpenLDAP.org/license.html or
   8 dnl in file LICENSE in the top-level directory of the distribution.
   9 dnl
  10 dnl ----------------------------------------------------------------
  11 dnl Redefine AC_INIT_BINSH to provide RCS IDs and copyright notice
  12 dnl at top of generated configure script.  Prints simple copyright.
  13 define([AC_INIT_BINSH],
  14 [[#! /bin/sh
  15 # $]OpenLDAP[$
  16 # from] translit([$OpenLDAP$], $")] [
  17
  18 # Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
  19 #
  20 # Redistribution and use in source and binary forms are permitted only
  21 # as authorized by the OpenLDAP Public License.  A copy of this
  22 # license is available at http://www.OpenLDAP.org/license.html or
  23 # in file LICENSE in the top-level directory of the distribution.
  24
  25 echo "Copyright 1998-2000 The OpenLDAP Foundation,  All Rights Reserved."
  26 echo "Restrictions apply, see COPYRIGHT and LICENSE files."
  27 ])dnl
  28 dnl ----------------------------------------------------------------
  29 dnl Disable config.cache!
  30 define([AC_CACHE_LOAD], )dnl
  31 define([AC_CACHE_SAVE], )dnl
  32 dnl ================================================================
  33 dnl Configure.in for OpenLDAP
  34 AC_INIT(build/version.sh)dnl
  35
  36 # set unset (borrowed from autoconf 2.14a)
  37 if (unset FOO) >/dev/null 2>&1; then
  38   ol_unset=unset
  39 else
  40   ol_unset=false
  41 fi
  42 # unset CDPATH
  43 $ol_unset CDPATH || test "${CDPATH+set}" != set || CDPATH=: && export CDPATH
  44
  45 AC_CONFIG_AUX_DIR(build)dnl
  46
  47 eval `$ac_aux_dir/version.sh`
  48 if test -z "$OL_STRING"; then
  49         AC_MSG_ERROR([could not determine version])
  50 fi
  51
  52 echo "Configuring $OL_STRING ..."
  53
  54 dnl Determine host platform
  55 dnl             we try not to use this for much
  56 AC_CANONICAL_SYSTEM
  57
  58 AM_INIT_AUTOMAKE([$OL_PACKAGE],[$OL_VERSION], [no defines])dnl
  59 AC_SUBST(PACKAGE)
  60 AC_SUBST(VERSION)
  61 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  62 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  63
  64 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION,$OL_API_INC,Version)
  65 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MAJOR,$OL_MAJOR,Major)
  66 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MINOR,$OL_MINOR,Minor)
  67 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_PATCH,$OL_PATCH,Patch)
  68
  69 OPENLDAP_LIBVERSION=$OL_API_LIB
  70 AC_SUBST(OPENLDAP_LIBVERSION)
  71
  72 dnl We use autoconf features new to 2.13.
  73 dnl aclocal.m4 should be built using aclocal from automake 1.4
  74 dnl libtool 1.3.3 should be installed.
  75 AC_PREREQ(2.13)dnl Required Autoconf version
  76
  77 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  78
  79 dnl ================================================================
  80 dnl Start Args
  81 AC_MSG_CHECKING(configure arguments)
  82 AC_PREFIX_DEFAULT(/usr/local)
  83
  84 top_builddir=`pwd`
  85 AC_SUBST(top_builddir)dnl
  86
  87 dnl ----------------------------------------------------------------
  88 dnl --with-subdir
  89 ldap_subdir="/openldap"
  90
  91 AC_ARG_WITH(subdir,
  92 [  --with-subdir=DIR change default subdirectory used for installs],
  93 [case "$withval" in
  94         no) ldap_subdir=""
  95                 ;;
  96         yes)
  97                 ;;
  98         /*|\\*)
  99                 ldap_subdir="$withval"
 100                 ;;
 101         *)
 102                 ldap_subdir="/$withval"
 103                 ;;
 104 esac
 105 ])dnl
 106
 107 AC_SUBST(ldap_subdir)dnl
 108
 109 dnl ----------------------------------------------------------------
 110 dnl General "enable" options
 111 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes)dnl
 112 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 113 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 114 OL_ARG_ENABLE(cache,[  --enable-cache     enable caching], yes)dnl
 115 OL_ARG_ENABLE(referrals,[  --enable-referrals     enable V2 Referrals extension], yes)dnl
 116 OL_ARG_ENABLE(kbind,[  --enable-kbind     enable V2 Kerberos IV bind], no)dnl
 117 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 118 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 119 OL_ARG_ENABLE(x_compile,[  --enable-x-compile     enable cross compiling],
 120         no, [yes no])dnl
 121
 122 dnl ----------------------------------------------------------------
 123 dnl General "with" options
 124 dnl OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc     enable debug malloc support], no)dnl
 125
 126 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 127         auto, [auto yes no] )
 128 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch URL support],
 129         auto, [auto yes no] )
 130 OL_ARG_WITH(kerberos,[  --with-kerberos   with support],
 131         auto, [auto k5 k5only k425 kth k4 afs yes no])
 132 OL_ARG_WITH(readline,[  --with-readline   with readline support],
 133         auto, [auto yes no] )
 134 OL_ARG_WITH(threads,[  --with-threads     with threads],
 135         auto, [auto nt posix mach pth lwp yes no manual] )
 136 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support],
 137         auto, [auto ssleay openssl yes no] )
 138 OL_ARG_WITH(yielding_select,[  --with-yielding-select  with implicitly yielding select],
 139         auto, [auto yes no manual] )
 140
 141 dnl ----------------------------------------------------------------
 142 dnl Server options
 143 dnl ----------------------------------------------------------------
 144
 145 dnl ----------------------------------------------------------------
 146 dnl SLAPD OPTIONS
 147 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 148 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 149 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 150 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], auto)dnl
 151 OL_ARG_ENABLE(kpasswd,[    --enable-kpasswd       enable Kerberos password verification], no)dnl
 152 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 153 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 154 OL_ARG_ENABLE(multimaster,[    --enable-multimaster  enable multimaster replication], no)dnl
 155 OL_ARG_ENABLE(phonetic,[    --enable-phonetic     enable phonetic/soundex], no)dnl
 156 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups], auto)dnl
 157 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs], no)dnl
 158 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 159 OL_ARG_ENABLE(dynamic,[    --enable-dynamic       enable linking built binaries with dynamic libs], no)dnl
 160
 161 dnl SLAPD Backend options
 162 OL_ARG_ENABLE(bdb,[    --enable-bdb       enable Berkeley DB backend], no)dnl
 163 OL_ARG_WITH(bdb_module,[    --with-bdb-module  module type], static,
 164         [static dynamic])
 165 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend], no)dnl
 166 OL_ARG_WITH(dnssrv_module,[    --with-dnssrv-module  module type], static,
 167         [static dynamic])
 168 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend], no)dnl
 169 OL_ARG_WITH(ldap_module,[    --with-ldap-module   module type], static,
 170         [static dynamic])
 171 OL_ARG_ENABLE(ldbm,[    --enable-ldbm     enable ldbm backend], yes)dnl
 172 OL_ARG_WITH(ldbm_api,[    --with-ldbm-api       with LDBM API], auto,
 173         [auto berkeley bcompat mdbm gdbm])
 174 OL_ARG_WITH(ldbm_module,[    --with-ldbm-module   module type], static,
 175         [static dynamic])
 176 OL_ARG_WITH(ldbm_type,[    --with-ldbm-type       use LDBM type], auto,
 177         [auto btree hash])
 178 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend], no)dnl
 179 OL_ARG_WITH(passwd_module,[    --with-passwd-module  module type], static,
 180         [static dynamic])
 181 OL_ARG_ENABLE(perl,[    --enable-perl     enable perl backend], no)dnl
 182 OL_ARG_WITH(perl_module,[    --with-perl-module   module type], static,
 183         [static dynamic])
 184 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend], no)dnl
 185 OL_ARG_WITH(shell_module,[    --with-shell-module         module type], static,
 186         [static dynamic])
 187 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend], no)dnl
 188 OL_ARG_WITH(sql_module,[    --with-sql-module     module type], static,
 189         [static dynamic])
 190 OL_ARG_ENABLE(tcl,[    --enable-tcl       enable tcl backend], no)dnl
 191 OL_ARG_WITH(tcl_module,[    --with-tcl-module     module type], static,
 192         [static dynamic])
 193
 194 dnl ----------------------------------------------------------------
 195 dnl SLURPD OPTIONS
 196 AC_ARG_WITH(xxslurpdoptions,[SLURPD (Replication Daemon) Options:])
 197 OL_ARG_ENABLE(slurpd,[  --enable-slurpd   enable building slurpd], auto)dnl
 198
 199 dnl ----------------------------------------------------------------
 200 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 201 AC_ENABLE_STATIC
 202 dnl AC_DISABLE_SHARED
 203 AC_ENABLE_SHARED
 204
 205 dnl ----------------------------------------------------------------
 206
 207 dnl General "enable" options
 208 # validate options
 209 if test $ol_enable_slapd = no ; then
 210         dnl SLAPD was specificallly disabled
 211         if test $ol_enable_bdb = yes ; then
 212                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb argument])
 213         fi
 214         if test $ol_enable_dnssrv = yes ; then
 215                 AC_MSG_WARN([slapd disabled, ignoring --enable-dnssrv argument])
 216         fi
 217         if test $ol_enable_ldap = yes ; then
 218                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 219         fi
 220         if test $ol_enable_ldbm = yes ; then
 221                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 222         fi
 223         if test $ol_enable_passwd = yes ; then
 224                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 225         fi
 226         if test $ol_enable_perl = yes ; then
 227                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 228         fi
 229         if test $ol_enable_shell = yes ; then
 230                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 231         fi
 232         if test $ol_enable_tcl = yes ; then
 233                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 234         fi
 235         if test $ol_enable_sql = yes ; then
 236                 AC_MSG_WARN([slapd disabled, ignoring --enable-sql argument])
 237         fi
 238         if test $ol_enable_modules = yes ; then
 239                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 240         fi
 241         if test $ol_enable_multimaster = yes ; then
 242                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 243         fi
 244         if test $ol_enable_wrappers = yes ; then
 245                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 246         fi
 247         if test $ol_enable_phonetic = yes ; then
 248                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 249         fi
 250         if test $ol_enable_rlookups = yes ; then
 251                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 252         fi
 253         if test $ol_enable_aci = yes ; then
 254                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 255         fi
 256         if test $ol_with_ldbm_api != auto ; then
 257                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 258         fi
 259         if test $ol_with_ldbm_type != auto ; then
 260                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 261         fi
 262         if test $ol_with_bdb_module != static ; then
 263                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb-module argument])
 264         fi
 265         if test $ol_with_dnssrv_module != static ; then
 266                 AC_MSG_WARN([slapd disabled, ignoring --with-dnssrv-module argument])
 267         fi
 268         if test $ol_with_ldap_module != static ; then
 269                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 270         fi
 271         if test $ol_with_ldbm_module != static ; then
 272                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 273         fi
 274         if test $ol_with_passwd_module != static ; then
 275                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 276         fi
 277         if test $ol_with_perl_module != static ; then
 278                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 279         fi
 280         if test $ol_with_shell_module != static ; then
 281                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 282         fi
 283         if test $ol_with_tcl_module != static ; then
 284                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 285         fi
 286         if test $ol_with_sql_module != static ; then
 287                 AC_MSG_WARN([slapd disabled, ignoring --with-sql-module argument])
 288         fi
 289         if test $ol_enable_slurpd = yes ; then
 290                 AC_MSG_ERROR([slurpd requires slapd])
 291         fi
 292
 293         # force settings to no
 294         ol_enable_bdb=no
 295         ol_enable_dnssrv=no
 296         ol_enable_ldap=no
 297         ol_enable_ldbm=no
 298         ol_enable_passwd=no
 299         ol_enable_perl=no
 300         ol_enable_shell=no
 301         ol_enable_tcl=no
 302         ol_enable_sql=no
 303
 304         ol_enable_modules=no
 305         ol_enable_multimaster=no
 306         ol_enable_phonetic=no
 307         ol_enable_rlookups=no
 308         ol_enable_aci=no
 309         ol_enable_wrappers=no
 310         ol_enable_dynamic=no
 311
 312         ol_with_ldbm_api=no
 313         ol_with_ldbm_type=no
 314
 315         ol_with_bdb_module=static
 316         ol_with_dnssrv_module=static
 317         ol_with_ldap_module=static
 318         ol_with_ldbm_module=static
 319         ol_with_passwd_module=static
 320         ol_with_perl_module=static
 321         ol_with_shell_module=static
 322         ol_with_tcl_module=static
 323         ol_with_sql_module=static
 324
 325         ol_enable_slurpd=no
 326
 327 elif test $ol_enable_ldbm = no ; then
 328         dnl SLAPD without LDBM
 329
 330         if test $ol_with_ldbm_api != auto ; then
 331                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 332         fi
 333
 334         if test $ol_with_ldbm_type != auto ; then
 335                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 336         fi
 337
 338         if test $ol_with_ldbm_module != static ; then
 339                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 340         fi
 341
 342         if test $ol_enable_modules != yes -a \
 343                 $ol_enable_bdb = no -a \
 344                 $ol_enable_dnssrv = no -a \
 345                 $ol_enable_ldap = no -a \
 346                 $ol_enable_passwd = no -a \
 347                 $ol_enable_perl = no -a \
 348                 $ol_enable_shell = no -a \
 349                 $ol_enable_sql = no -a \
 350                 $ol_enable_tcl = no ; then
 351                 AC_MSG_ERROR([slapd requires a backend])
 352         fi
 353
 354         ol_with_ldbm_api=no
 355         ol_with_ldbm_type=no
 356         ol_with_ldbm_module=static
 357
 358 else
 359         dnl SLAPD with LDBM
 360         if test $ol_with_ldbm_api = gdbm -a \
 361                 $ol_with_ldbm_type = btree ; then
 362                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 363         fi
 364         if test $ol_with_ldbm_api = mdbm -a \
 365                 $ol_with_ldbm_type = btree ; then
 366                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 367         fi
 368         if test $ol_with_ldbm_api = ndbm -a \
 369                 $ol_with_ldbm_type = btree ; then
 370                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 371         fi
 372 fi
 373
 374 if test $ol_enable_slurpd = yes ; then
 375         dnl SLURPD was specifically enabled
 376         if test $ol_with_threads = no ; then
 377                 AC_MSG_ERROR([slurpd requires threads])
 378         fi
 379 fi
 380
 381 if test $ol_enable_kbind = yes -o $ol_enable_kpasswd = yes ; then
 382         if test $ol_with_kerberos = no ; then
 383                 AC_MSG_ERROR([options require --with-kerberos])
 384         fi
 385         ol_with_kerberos=yes
 386 elif test $ol_enable_kbind = no -o $ol_enable_kpasswd = no ; then
 387         if test $ol_with_kerberos != no -a $ol_with_kerberos != auto ; then
 388                 AC_MSG_WARN([Kerberos detection enabled unnecessarily]);
 389         fi
 390         ol_with_kerberos=no
 391 fi
 392
 393 if test $ol_enable_spasswd = yes ; then
 394         if test $ol_with_cyrus_sasl = no ; then
 395                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 396         fi
 397         ol_with_cyrus_sasl=yes
 398 fi
 399
 400 AC_MSG_RESULT(done)
 401
 402 dnl ----------------------------------------------------------------
 403 dnl Initialize vars
 404 LDAP_LIBS=
 405 LDIF_LIBS=
 406 LDBM_LIBS=
 407 LTHREAD_LIBS=
 408 LUTIL_LIBS=
 409
 410 SLAPD_LIBS=
 411 SLURPD_LIBS=
 412
 413 BUILD_SLAPD=no
 414 BUILD_SLURPD=no
 415
 416 BUILD_THREAD=no
 417
 418 BUILD_BDB=no
 419 BUILD_DNSSRV=no
 420 BUILD_LDAP=no
 421 BUILD_LDBM=no
 422 BUILD_PASSWD=no
 423 BUILD_PERL=no
 424 BUILD_SHELL=no
 425 BUILD_SQL=no
 426 BUILD_TCL=no
 427
 428 BUILD_BDB_DYNAMIC=static
 429 BUILD_DNSSRV_DYNAMIC=static
 430 BUILD_LDAP_DYNAMIC=static
 431 BUILD_LDBM_DYNAMIC=static
 432 BUILD_PASSWD_DYNAMIC=static
 433 BUILD_PERL_DYNAMIC=static
 434 BUILD_SHELL_DYNAMIC=static
 435 BUILD_TCL_DYNAMIC=static
 436 BUILD_SQL_DYNAMIC=static
 437
 438 SLAPD_MODULES_LDFLAGS=
 439 SLAPD_MODULES_CPPFLAGS=
 440 SLAPD_MODULES_LIST=
 441
 442 SLAPD_PERL_LDFLAGS=
 443 MOD_PERL_LDFLAGS=
 444 PERL_CPPFLAGS=
 445
 446 SLAPD_SQL_LDFLAGS=
 447 SLAPD_SQL_LIBS=
 448 SLAPD_SQL_INCLUDES=
 449
 450 MOD_TCL_LIB=
 451 KRB4_LIBS=
 452 KRB5_LIBS=
 453 READLINE_LIBS=
 454 SASL_LIBS=
 455 TERMCAP_LIBS=
 456 TLS_LIBS=
 457 MODULES_LIBS=
 458 AUTH_LIBS=
 459
 460 dnl ================================================================
 461 dnl Checks for programs
 462
 463 dnl AC_PROG_INSTALL
 464
 465 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 466
 467 dnl ----------------------------------------------------------------
 468 dnl
 469 dnl Determine which C translator to use
 470 dnl
 471
 472 dnl AIX Thread requires we use cc_r or xlc_r.
 473 dnl But only do this IF AIX and CC is not set
 474 dnl and threads are auto|yes|posix.
 475 dnl
 476 dnl If we find cc_r|xlc_r, force pthreads and assume
 477 dnl             pthread_create is in $LIBS (ie: don't bring in
 478 dnl             any additional thread libraries)
 479 dnl If we do not find cc_r|xlc_r, disable threads
 480
 481 ol_aix_threads=no
 482 case "$target" in
 483 *-*-aix*) dnl all AIX is not a good idea.
 484         if test -z "$CC" ; then
 485                 case "$ol_with_threads" in
 486                 auto | yes |  posix) ol_aix_threads=yes ;;
 487                 esac
 488         fi
 489 ;;
 490 esac
 491
 492 if test $ol_aix_threads = yes ; then
 493         if test -z "${CC}" ; then
 494                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 495
 496                 if test "$CC" = cc ; then
 497                         dnl no CC! don't allow --with-threads
 498                         if test $ol_with_threads != auto ; then
 499                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 500                         else
 501                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 502                         fi
 503                         ol_with_threads=no
 504                 fi
 505         fi
 506
 507         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 508                 ol_with_threads=posix
 509                 ol_cv_pthread_create=yes
 510         fi
 511 fi
 512
 513 if test -z "${CC}"; then
 514         AC_CHECK_PROGS(CC,cc)
 515 fi
 516
 517 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 518 dnl (for now, let autoconf sort this out)
 519 dnl CFLAGS=${CFLAGS-""}
 520
 521 AC_LIBTOOL_WIN32_DLL
 522 AC_LIBTOOL_DLOPEN
 523 AC_PROG_LIBTOOL
 524
 525 AC_PROG_AWK
 526 OL_PROG_LN_H
 527 AC_PROG_LN_S
 528
 529 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 530         LN_S="$LN_H"
 531 fi
 532
 533 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 534         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 535 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 536 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 537
 538 dnl ----------------------------------------------------------------
 539 dnl Perl
 540 ol_link_perl=no
 541 if test $ol_enable_perl != no ; then
 542         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 543
 544         if test "no$PERLBIN" = "no" ; then
 545                 if test $ol_enable_perl = yes ; then
 546                         AC_MSG_ERROR([could not locate perl])
 547                 fi
 548
 549         else
 550                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 551                 if test x"$ol_with_perl_module" = "xstatic" ; then
 552                         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 553                 else
 554                         MOD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 555                 fi
 556                 dnl should check perl version
 557                 ol_link_perl=yes
 558         fi
 559 fi
 560
 561 AC_PROG_CPP
 562
 563 dnl ----------------------------------------------------------------
 564 dnl Cross compiling checks
 565 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 566         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 567
 568 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 569         AC_MSG_WARN([programs compiled here do run here...])
 570         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 571
 572 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 573         AC_MSG_WARN([programs compiled here do not run here...])
 574         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 575 fi
 576
 577 dnl ----------------------------------------------------------------
 578 dnl Checks for UNIX Variants
 579 AC_AIX
 580 AC_ISC_POSIX
 581 AC_MINIX
 582
 583 dnl ----------------------------------------------------------------
 584 dnl Checks for system services
 585 AC_CYGWIN
 586 AC_MINGW32
 587 AC_EXEEXT
 588 AC_OBJEXT
 589
 590 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 591
 592 dnl ----------------------------------------------------------------
 593 dnl BeOS requires -lbe -lroot -lnet
 594 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 595
 596 dnl ----------------------------------------------------------------
 597 dnl OpenLDAP requires STDC features
 598 AM_PROG_CC_STDC
 599 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 600         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 601 fi
 602
 603 dnl ----------------------------------------------------------------
 604 dnl Check cc depend flags
 605 OL_MKDEPEND
 606 if test "${ol_cv_mkdep}" = no ; then
 607         # this will soon become an error
 608         AC_MSG_WARN([do not know how to generate dependencies])
 609 fi
 610
 611 dnl ----------------------------------------------------------------
 612 dnl Check for AIX security library
 613 AC_CHECK_LIB(s, afopen, [
 614         AUTH_LIBS=-ls
 615         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 616 ])
 617
 618
 619 dnl ----------------------------------------------------------------
 620 dnl Check for module support
 621 ol_link_modules=no
 622 if test $ol_enable_modules != no ; then
 623         AC_CHECK_HEADERS(ltdl.h)
 624
 625         if test $ac_cv_header_ltdl_h = no ; then
 626                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 627         fi
 628
 629         AC_CHECK_LIB(ltdl, lt_dlinit, [
 630             MODULES_LIBS=-lltdl
 631             AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 632         ])
 633
 634         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 635                 AC_MSG_ERROR([could not locate libtool -lltdl])
 636         fi
 637         ol_link_modules=yes
 638 else
 639         ol_with_bdb_module=static
 640         ol_with_dnssrv_module=static
 641         ol_with_ldap_module=static
 642         ol_with_ldbm_module=static
 643         ol_with_passwd_module=static
 644         ol_with_perl_module=static
 645         ol_with_shell_module=static
 646         ol_with_tcl_module=static
 647         ol_with_sql_module=static
 648 fi
 649
 650 dnl ----------------------------------------------------------------
 651 dnl Checks for header files.
 652 OL_HEADER_STDC
 653
 654 if test $ol_cv_header_stdc != yes; then
 655         AC_MSG_WARN([could not locate Standard C compliant headers])
 656 fi
 657
 658 AC_HEADER_DIRENT
 659 AC_HEADER_SYS_WAIT
 660 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 661 if test $am_cv_sys_posix_termios = yes ; then
 662         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 663                 [define if you have POSIX termios])
 664 fi
 665
 666 AC_CHECK_HEADERS(       \
 667         arpa/inet.h             \
 668         arpa/nameser.h  \
 669         assert.h                \
 670         conio.h                 \
 671         crypt.h                 \
 672         direct.h                \
 673         errno.h                 \
 674         fcntl.h                 \
 675         filio.h                 \
 676         getopt.h                \
 677         grp.h                   \
 678         io.h                    \
 679         libutil.h               \
 680         limits.h                \
 681         locale.h                \
 682         netinet/tcp.h   \
 683         malloc.h                \
 684         memory.h                \
 685         psap.h                  \
 686         pwd.h                   \
 687         process.h               \
 688         resolv.h                \
 689         sgtty.h                 \
 690         shadow.h                \
 691         stddef.h                \
 692         string.h                \
 693         strings.h               \
 694         sysexits.h              \
 695         sys/file.h              \
 696         sys/filio.h             \
 697         sys/errno.h             \
 698         sys/ioctl.h             \
 699         sys/param.h             \
 700         sys/resource.h  \
 701         sys/select.h    \
 702         sys/socket.h    \
 703         sys/syslog.h    \
 704         sys/time.h              \
 705         sys/types.h             \
 706         syslog.h                \
 707         termios.h               \
 708         unistd.h                \
 709         winsock.h               \
 710 )
 711
 712
 713 dnl ----------------------------------------------------------------
 714 dnl Checks for libraries
 715
 716 dnl HP-UX requires -lV3
 717 AC_CHECK_LIB(V3, sigset)
 718
 719 dnl Gotta check for winsock manually
 720 if test $ac_cv_header_winsock_h = yes; then
 721         AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 722         AC_TRY_LINK([#include <winsock.h>],[
 723                         socket(0,0,0);
 724                         select(0,NULL,NULL,NULL,NULL);
 725                         closesocket(0);
 726                         gethostname(NULL,0);
 727         ],[ol_cv_winsock=yes],[ol_cv_winsock=no])])
 728
 729         if test $ol_cv_winsock = yes ; then
 730                 AC_DEFINE(HAVE_WINSOCK,1,[define if you have winsock])
 731                 ac_cv_func_socket=yes
 732                 ac_cv_func_select=yes
 733                 ac_cv_func_closesocket=yes
 734                 ac_cv_func_gethostname=yes
 735         fi
 736 fi
 737
 738 dnl Find socket()
 739 dnl Likely combinations:
 740 dnl             -lsocket [ -lnsl_s | -lnsl ]
 741 dnl             -linet
 742
 743 AC_CHECK_FUNC(socket, :, [
 744 dnl hopefully we won't include too many libraries
 745         AC_CHECK_LIB(socket, main)
 746         AC_CHECK_LIB(net, main)
 747         AC_CHECK_LIB(nsl_s, main)
 748         AC_CHECK_LIB(nsl, main)
 749         AC_CHECK_LIB(inet, socket)
 750         AC_CHECK_LIB(gen, main)
 751 ])
 752
 753 dnl require select
 754 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 755
 756 if test "${ac_cv_header_winsock_h}" != yes; then
 757     dnl Select arg types
 758     dnl (if this detection becomes permenent, it and the select() detection
 759     dnl should be done before the yielding select test)
 760     AC_FUNC_SELECT_ARGTYPES
 761 fi
 762
 763 dnl check to see if system call automatically restart
 764 dnl AC_SYS_RESTARTABLE_SYSCALLS
 765
 766 dnl ----------------------------------------------------------------
 767 dnl require POSIX regex
 768 AC_CHECK_HEADERS( regex.h )
 769 if test "$ac_cv_header_regex_h" != yes ; then
 770         AC_MSG_ERROR([POSIX regex.h required.])
 771 fi
 772 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 773
 774 OL_POSIX_REGEX
 775 if test "$ol_cv_c_posix_regex" = no ; then
 776         AC_MSG_ERROR([broken POSIX regex!])
 777 fi
 778
 779 dnl ----------------------------------------------------------------
 780 dnl Check for resolver routines
 781 ol_link_dnssrv=no
 782 AC_CHECK_FUNC(res_query,:)
 783 if test $ac_cv_func_res_query = no ; then
 784         AC_CHECK_LIB(bind, res_query)
 785         ac_cv_func_res_query=$ac_cv_lib_bind_res_query
 786 fi
 787
 788 if test $ac_cv_func_res_query = no ; then
 789         AC_CHECK_LIB(bind, __res_query)
 790         ac_cv_func_res_query=$ac_cv_lib_bind___res_query
 791 fi
 792
 793 if test $ac_cv_func_res_query = no ; then
 794         AC_CHECK_LIB(resolv, res_query)
 795         ac_cv_func_res_query=$ac_cv_lib_resolv_res_query
 796 fi
 797
 798 if test "$ac_cv_func_res_query" = yes ; then
 799         AC_DEFINE(HAVE_RES_QUERY,1,
 800                 [define if you have res_query()])
 801
 802         if test $ol_enable_dnssrv != no ; then
 803                 ol_link_dnssrv=yes
 804         fi
 805 fi
 806
 807 if test "$ol_enable_dnssrv" = yes -a "$ol_link_dnssrv" = no ; then
 808         AC_MSG_ERROR([DNSSRV requires res_query()])
 809 fi
 810
 811 dnl ----------------------------------------------------------------
 812 dnl PF_INET6 support requires getaddrinfo and INET6_ADDRSTRLEN
 813 dnl PF_LOCAL may use getaddrinfo in available
 814 AC_CHECK_FUNCS( getaddrinfo )
 815
 816 ol_link_ipv6=no
 817 if test $ac_cv_func_getaddrinfo = no ; then
 818         if test $ol_enable_ipv6 = yes ; then
 819                 AC_MSG_ERROR([IPv6 support requires getaddrinfo()])
 820         fi
 821 else
 822         AC_CACHE_CHECK([INET6_ADDRSTRLEN],[ol_cv_inet6_addrstrlen],[
 823                 AC_EGREP_CPP(__has_inet6_addrstrlen__,[
 824 #                       include <netinet/in.h>
 825 #                       ifdef INET6_ADDRSTRLEN
 826                                 __has_inet6_addrstrlen__;
 827 #                       endif
 828                 ], [ol_cv_inet6_addrstrlen=yes], [ol_cv_inet6_addrstrlen=no])])
 829
 830         if test $ol_cv_inet6_addrstrlen = yes ; then
 831                 ol_link_ipv6=yes
 832         elif test $ol_enable_ipv6 = yes ; then
 833                 AC_MSG_ERROR([IPv6 support requires INET6_ADDRSTRLEN])
 834         fi
 835 fi
 836
 837 if test $ol_enable_local != no ; then
 838         AC_CHECK_HEADERS( sys/un.h )
 839
 840         if test $ol_enable_local = auto ; then
 841                 ol_enable_local=$ac_cv_header_sys_un_h
 842         elif test $ac_cv_header_sys_un_h = no ; then
 843                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
 844         fi
 845 fi
 846
 847 dnl ----------------------------------------------------------------
 848 dnl Kerberos
 849 ol_link_kbind=no
 850 ol_link_kpasswd=no
 851 ol_link_krb5=no
 852 ol_link_krb4=no
 853
 854 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
 855         -o $ol_with_kerberos = k5 -o $ol_with_kerberos = k5only \
 856         -o $ol_with_kerberos = k425 ; then
 857
 858         AC_CHECK_HEADERS(krb5.h)
 859
 860         if test $ac_cv_header_krb5_h = yes ; then
 861                 dnl lazy check for Heimdal Kerberos
 862                 AC_CHECK_HEADERS(heim_err.h)
 863                 if test $ac_cv_header_heim_err_h = yes ; then
 864                         krb5_impl=heimdal
 865                 else
 866                         krb5_impl=mit
 867                 fi
 868
 869                 if test $krb5_impl = mit; then
 870                         AC_CHECK_LIB(krb5, main,
 871                                 [have_krb5=yes
 872                                 KRB5_LIBS="-lkrb5 -lcrypto -lcom_err"],
 873                                 [have_krb5=no],
 874                                 [-lcrypto -lcom_err])
 875
 876                 elif test $krb5_impl = heimdal; then
 877                         AC_CHECK_LIB(krb5, main,
 878                                 [have_krb5=yes
 879                                 KRB5_LIBS="-lkrb5 -ldes -lasn1 -lroken -lcom_err"],
 880                                 [have_krb5=no],
 881                                 [-ldes -lasn1 -lroken -lcom_err])
 882
 883                         AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1,
 884                                 [define if you have HEIMDAL Kerberos])
 885                 else
 886                         have_krb5=no
 887                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 888                 fi
 889
 890                 if test $have_krb5 = yes ; then
 891                         ol_link_krb5=yes
 892
 893                         AC_DEFINE(HAVE_KRB5, 1,
 894                                 [define if you have Kerberos V])
 895
 896                         if test $ol_enable_kpasswd != no ; then
 897                                 ol_link_kpasswd=yes;
 898                         fi
 899
 900                         if test $ol_with_kerberos = k5only ; then
 901                                 ol_with_kerberos=found
 902                         fi
 903
 904                 elif test $ol_with_kerberos != auto ; then
 905                         AC_MSG_ERROR([Required Kerberos 5 support not available])
 906                 fi
 907
 908         fi
 909 fi
 910
 911 if test $ol_link_krb5 = yes -a \( $ol_with_kerberos = yes -o \
 912         $ol_with_kerberos = auto -o $ol_with_kerberos = k425 \) ; then
 913
 914         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 915
 916         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 917                 if test $krb5_impl = mit; then
 918                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 919                                 KRB4_LIBS="-lkrb4 -ldes425"], [have_k425=no],
 920                                 [-ldes425 -lkrb5 -lcrypto -lcom_err])
 921
 922                 elif test $krb5_impl = heimdal; then
 923                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 924                                 KRB4_LIBS="-lkrb4"], [have_k425=no],
 925                                 [-lkrb5 -ldes -lasn1 -lroken -lcom_err])
 926
 927                 else
 928                         have_425=no
 929                         AC_MSG_WARN([Unrecongized Kerberos V Implementation])
 930                 fi
 931
 932                 if test $have_k425 = yes ; then
 933                         ol_with_kerberos=found
 934                         ol_link_krb4=yes
 935
 936                         AC_DEFINE(HAVE_KRB425, 1,
 937                                 [define if you have Kerberos V with IV support])
 938                         AC_DEFINE(HAVE_KRB4, 1,
 939                                 [define if you have Kerberos IV])
 940
 941                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 942                                 [ol_cv_var_des_debug], [
 943                                 dnl save the flags
 944                                 save_LIBS="$LIBS"
 945                                 LIBS="$KRB4_LIBS $KRB5_LIBS $LIBS"
 946                                 AC_TRY_LINK([
 947 #include <kerberosIV/krb.h>
 948 #include <kerberosIV/des.h>
 949 extern int des_debug;
 950 ],[
 951 des_debug = 1;
 952 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 953                                 dnl restore the LIBS
 954                                 LIBS="$save_LIBS"
 955                         ])
 956
 957                         if test $ol_cv_var_des_debug = yes ; then
 958                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 959                                         [define if you have Kerberos des_debug])
 960                         fi
 961
 962                         LIBS="$save_LIBS"
 963                 fi
 964         fi
 965 fi
 966
 967 if test $ol_link_krb5 = yes ; then
 968         ol_with_kerberos=found
 969 fi
 970
 971 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
 972         -o $ol_with_kerberos = k4 -o $ol_with_kerberos = kth ; then
 973
 974         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
 975
 976         if test $ac_cv_header_krb_h = yes ; then
 977                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 978
 979                 if test $have_k4 = yes ; then
 980                         ol_with_kerberos=found
 981                         ol_link_krb4=yes
 982
 983                         AC_DEFINE(HAVE_KRB4, 1,
 984                                 [define if you have Kerberos IV])
 985
 986                         KRB4_LIBS="-lkrb -ldes"
 987
 988                         if test $ac_cv_header_krb_archaeology_h = yes ; then
 989                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
 990                                         [define if you have Kth Kerberos])
 991                         fi
 992                 fi
 993         fi
 994 fi
 995
 996 if test $ol_link_krb4 = yes -a $ol_enable_kpasswd != no ; then
 997         ol_link_kpasswd=yes
 998 fi
 999
1000 if test $ol_link_krb4 = yes -a $ol_enable_kbind != no ; then
1001         ol_link_kbind=yes
1002
1003 elif test $ol_enable_kbind = yes ; then
1004         AC_MSG_ERROR([Kerberos IV detection failed])
1005 fi
1006
1007 if test $ol_link_krb4 = yes -o $ol_link_krb5 = yes ; then
1008         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
1009
1010 elif test $ol_with_kerberos != auto -a $ol_with_kerberos != no ; then
1011         AC_MSG_ERROR([Kerberos detection failed])
1012 fi
1013
1014 dnl ----------------------------------------------------------------
1015 dnl TLS/SSL
1016 ol_link_tls=no
1017 if test $ol_with_tls != no ; then
1018         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
1019
1020         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
1021                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
1022                         [have_ssleay=yes
1023                         need_rsaref=no],
1024                         [have_ssleay=no],
1025                         [-lcrypto])
1026
1027                 if test $have_ssleay = no ; then
1028                         AC_CHECK_LIB(ssl, SSL_library_init,
1029                                 [have_ssleay=yes
1030                                 need_rsaref=no], [have_ssleay=no],
1031                                 [-lcrypto])
1032                 fi
1033
1034                 if test $have_ssleay = no ; then
1035                         AC_CHECK_LIB(ssl, ssl3_accept,
1036                                 [have_ssleay=yes
1037                                 need_rsaref=yes], [have_ssleay=no],
1038                                 [-lcrypto -lRSAglue -lrsaref])
1039                 fi
1040
1041                 if test $have_ssleay = yes ; then
1042                         ol_with_tls=found
1043                         ol_link_tls=yes
1044
1045                         AC_DEFINE(HAVE_SSLEAY, 1,
1046                                 [define if you have SSLeay or OpenSSL])
1047
1048                         if test $need_rsaref = yes; then
1049                                 AC_DEFINE(HAVE_RSAREF, 1,
1050                                         [define if you have RSAref])
1051
1052                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1053                         else
1054                                 TLS_LIBS="-lssl -lcrypto"
1055                         fi
1056                 fi
1057         fi
1058
1059 else
1060         AC_WARN([TLS privacy protection not supported!])
1061 fi
1062
1063 if test $ol_link_tls = yes ; then
1064         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1065
1066 elif test $ol_with_tls = auto ; then
1067         AC_WARN([Could not locate TLS/SSL package])
1068         AC_WARN([TLS privacy protection not supported!])
1069
1070 elif test $ol_with_tls != no ; then
1071         AC_ERROR([Could not locate TLS/SSL package])
1072 fi
1073
1074 dnl ----------------------------------------------------------------
1075 dnl Tests for reentrant functions necessary to build a
1076 dnl thread_safe -lldap.
1077 AC_CHECK_FUNCS(         \
1078         ctime_r                 \
1079         gethostbyname_r gethostbyaddr_r \
1080 )
1081
1082 if test "$ac_cv_func_ctime_r" = no ; then
1083         ol_cv_func_ctime_r_nargs=0
1084 else
1085         OL_FUNC_CTIME_R_NARGS
1086 dnl     OL_FUNC_CTIME_R_TYPE
1087 fi
1088
1089 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1090         OL_FUNC_GETHOSTBYNAME_R_NARGS
1091 else
1092         ol_cv_func_gethostbyname_r_nargs=0
1093 fi
1094
1095 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1096         OL_FUNC_GETHOSTBYADDR_R_NARGS
1097 else
1098         ol_cv_func_gethostbyaddr_r_nargs=0
1099 fi
1100
1101 if test "$ac_cv_func_ctime_r" = yes \
1102         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
1103         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
1104         -a "$ac_cv_func_gethostbyname_r" = yes \
1105         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
1106         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
1107         -a "$ac_cv_func_gethostbyaddr_r" = yes \
1108         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
1109         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
1110         ; then
1111
1112         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
1113 fi
1114
1115 dnl ----------------------------------------------------------------
1116 dnl Threads?
1117 ol_link_threads=no
1118
1119 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1120         -o $ol_with_threads = nt ; then
1121
1122         OL_NT_THREADS
1123
1124         if test "$ol_cv_nt_threads" = yes ; then
1125         ol_link_threads=nt
1126         ol_with_threads=found
1127         ol_with_yielding_select=yes
1128
1129                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1130                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1131         fi
1132
1133         if test $ol_with_threads = nt ; then
1134                 AC_MSG_ERROR([could not locate NT Threads])
1135         fi
1136 fi
1137
1138 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1139         -o $ol_with_threads = posix ; then
1140
1141         AC_CHECK_HEADERS(pthread.h)
1142
1143         if test $ac_cv_header_pthread_h = yes ; then
1144                 OL_POSIX_THREAD_VERSION
1145
1146                 if test $ol_cv_pthread_version = final ; then
1147                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
1148                                 [define if pthreads API compatible with final spec])
1149                 elif test $ol_cv_pthread_version = draft4 ; then
1150                         AC_DEFINE(HAVE_PTHREADS_D4,1,
1151                                 [define if pthreads API compatible with draft4 spec])
1152                 else
1153                         AC_MSG_ERROR([unknown pthread version])
1154                 fi
1155
1156                 # consider threads found
1157                 ol_with_threads=found
1158
1159                 OL_HEADER_LINUX_THREADS
1160                 OL_HEADER_GNU_PTH_PTHREAD_H
1161
1162                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1163                         AC_CHECK_HEADERS(sched.h)
1164                 fi
1165
1166                 dnl Now the hard part, how to link?
1167                 dnl
1168                 dnl currently supported checks:
1169                 dnl
1170                 dnl Check for no flags
1171                 dnl     pthread_create() in $LIBS
1172                 dnl
1173                 dnl Check special pthread (final) flags
1174                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1175                 dnl     pthread_create() with -kthread (FreeBSD)
1176                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1177                 dnl     pthread_create() with -pthreads (?)
1178                 dnl     pthread_create() with -mthreads (AIX)
1179                 dnl     pthread_create() with -thread (?)
1180                 dnl
1181                 dnl Check pthread (final) libraries
1182                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1183                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1184                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1185                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1186                 dnl     pthread_create() in -lpthread (many)
1187                 dnl     pthread_create() in -lc_r (FreeBSD)
1188                 dnl
1189                 dnl Check pthread (draft4) flags (depreciated)
1190                 dnl     pthread_create() with -threads (OSF/1)
1191                 dnl
1192                 dnl Check pthread (draft4) libraries (depreciated)
1193                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1194                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1195                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1196                 dnl     pthread_create() in -lpthreads (many)
1197                 dnl
1198
1199                 dnl pthread_create in $LIBS
1200                 AC_CACHE_CHECK([for pthread_create in default libraries],
1201                         ol_cv_pthread_create,[
1202                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1203                         [ol_cv_pthread_create=yes],
1204                         [ol_cv_pthread_create=no],
1205                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1206                                 [ol_cv_pthread_create=yes],
1207                                 [ol_cv_pthread_create=no])])])
1208
1209                 if test $ol_cv_pthread_create != no ; then
1210                         ol_link_threads=posix
1211                         ol_link_pthreads=""
1212                 fi
1213
1214 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1215                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1216                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1217                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1218                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1219                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1220
1221                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1222                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1223                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1224                         [ol_cv_pthread_lpthread_lmach_lexc])
1225 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1226 dnl                     [ol_cv_pthread_lpthread_lexc])
1227
1228                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1229                         [ol_cv_pthread_lib_lpthread_woff])
1230
1231                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1232                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1233
1234                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1235
1236                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1237                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1238                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1239                         [ol_cv_pthread_lpthreads_lmach_lexc])
1240                 OL_PTHREAD_TRY([-lpthreads -lexc],
1241                         [ol_cv_pthread_lpthreads_lexc])
1242
1243                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1244
1245                 if test $ol_link_threads != no ; then
1246                         AC_DEFINE(HAVE_PTHREADS,1,
1247                                 [define if you have POSIX Threads])
1248
1249                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1250
1251                         dnl save flags
1252                         save_CPPFLAGS="$CPPFLAGS"
1253                         save_LIBS="$LIBS"
1254                         LIBS="$LTHREAD_LIBS $LIBS"
1255
1256                         dnl All POSIX Thread (final) implementations should have
1257                         dnl sched_yield instead of pthread yield.
1258                         dnl check for both
1259                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1260
1261                         if test $ac_cv_func_sched_yield = no -a \
1262                                 $ac_cv_func_pthread_yield = no ; then
1263                                 dnl Digital UNIX has sched_yield() in -lrt
1264                                 AC_CHECK_LIB(rt, sched_yield,
1265                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1266                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1267                                                 [Define if you have the sched_yield function.])
1268                                         ac_cv_func_sched_yield=yes],
1269                                         [ac_cv_func_sched_yield=no])
1270                         fi
1271                         if test $ac_cv_func_sched_yield = no -a \
1272                                 $ac_cv_func_pthread_yield = no ; then
1273                                 dnl Solaris has sched_yield() stub in -lposix4
1274                                 dnl but we'll use thr_yield instead.
1275                                 AC_CHECK_FUNCS(thr_yield)
1276                         fi
1277                         if test $ac_cv_func_sched_yield = no -a \
1278                                 $ac_cv_func_pthread_yield = no -a \
1279                                 "$ac_cv_func_thr_yield" = no ; then
1280                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1281                         fi
1282
1283                         dnl Check functions for compatibility
1284                         AC_CHECK_FUNCS(pthread_kill pthread_rwlock_destroy)
1285
1286                         dnl Check for pthread_detach with <pthread.h> inclusion
1287                         dnl as it's symbol may have been mangled.
1288                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1289                                 [ol_cv_func_pthread_detach], [
1290                                 dnl save the flags
1291                                 AC_TRY_LINK([
1292 #include <pthread.h>
1293 #ifndef NULL
1294 #define NULL (void*)0
1295 #endif
1296 ],
1297                                         [pthread_detach(NULL);],
1298                                         [ol_cv_func_pthread_detach=yes],
1299                                         [ol_cv_func_pthread_detach=no])
1300                         ])
1301
1302                         if test $ol_cv_func_pthread_detach = no ; then
1303                                 AC_MSG_ERROR([could not locate pthread_detach()])
1304                         fi
1305
1306                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1307                                 [define if you have pthread_detach function])
1308
1309                         dnl Check for setconcurreny functions
1310                         AC_CHECK_FUNCS( \
1311                                 pthread_setconcurrency \
1312                                 pthread_getconcurrency \
1313                                 thr_setconcurrency \
1314                                 thr_getconcurrency \
1315                         )
1316
1317                         OL_SYS_LINUX_THREADS
1318                         OL_LINUX_THREADS
1319
1320                         if test $ol_cv_linux_threads = error; then
1321                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1322                         fi
1323
1324                         AC_CACHE_CHECK([if pthread_create() works],
1325                                 ol_cv_pthread_create_works,[
1326                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1327                                 [ol_cv_pthread_create_works=yes],
1328                                 [ol_cv_pthread_create_works=no],
1329                                 [dnl assume yes
1330                                 ol_cv_pthread_create_works=yes])])
1331
1332                         if test $ol_cv_pthread_create_works = no ; then
1333                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1334                         fi
1335
1336                         dnl Check if select causes an yield
1337                         if test $ol_with_yielding_select = auto ; then
1338                                 AC_CACHE_CHECK([if select yields when using pthreads],
1339                                         ol_cv_pthread_select_yields,[
1340                                 AC_TRY_RUN([
1341 #include <sys/types.h>
1342 #include <sys/time.h>
1343 #include <unistd.h>
1344 #include <pthread.h>
1345 #ifndef NULL
1346 #define NULL (void*) 0
1347 #endif
1348
1349 static int fildes[2];
1350
1351 static void *task(p)
1352         void *p;
1353 {
1354         int i;
1355         struct timeval tv;
1356
1357         fd_set rfds;
1358
1359         tv.tv_sec=10;
1360         tv.tv_usec=0;
1361
1362         FD_ZERO(&rfds);
1363         FD_SET(fildes[0], &rfds);
1364
1365         /* we're not interested in any fds */
1366         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1367
1368         if(i < 0) {
1369                 perror("select");
1370                 exit(10);
1371         }
1372
1373         exit(0); /* if we exit here, the select blocked the whole process */
1374 }
1375
1376 int main(argc, argv)
1377         int argc;
1378         char **argv;
1379 {
1380         pthread_t t;
1381
1382         /* create a pipe to select */
1383         if(pipe(&fildes[0])) {
1384                 perror("select");
1385                 exit(1);
1386         }
1387
1388 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1389         (void) pthread_setconcurrency(2);
1390 #else
1391 #ifdef HAVE_THR_SETCONCURRENCY
1392         /* Set Solaris LWP concurrency to 2 */
1393         thr_setconcurrency(2);
1394 #endif
1395 #endif
1396
1397 #if HAVE_PTHREADS_D4
1398         pthread_create(&t, pthread_attr_default, task, NULL);
1399 #else
1400         pthread_create(&t, NULL, task, NULL);
1401 #endif
1402
1403 #if HAVE_SCHED_YIELD
1404         sched_yield();  /* make sure task runs first */
1405 #else
1406 #ifdef HAVE_PTHREAD_YIELD
1407         pthread_yield();        /* make sure task runs first */
1408 #endif
1409 #endif
1410
1411         exit(2);
1412 }],
1413                                 [ol_cv_pthread_select_yields=no],
1414                                 [ol_cv_pthread_select_yields=yes],
1415                                 [ol_cv_pthread_select_yields=cross])])
1416
1417                                 if test $ol_cv_pthread_select_yields = cross ; then
1418                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1419                                 fi
1420
1421                                 if test $ol_cv_pthread_select_yields = yes ; then
1422                                         ol_with_yielding_select=yes
1423                                 fi
1424                         fi
1425
1426                         dnl restore flags
1427                         CPPFLAGS="$save_CPPFLAGS"
1428                         LIBS="$save_LIBS"
1429                 else
1430                         AC_MSG_ERROR([could not link with POSIX Threads])
1431                 fi
1432         fi
1433
1434         if test $ol_with_threads = posix ; then
1435                 AC_MSG_ERROR([could not locate POSIX Threads])
1436         fi
1437 fi
1438
1439 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1440         -o $ol_with_threads = mach ; then
1441
1442         dnl check for Mach CThreads
1443         AC_CHECK_HEADERS(mach/cthreads.h)
1444         if test $ac_cv_header_mach_cthreads_h = yes ; then
1445                 ol_with_threads=found
1446
1447                 dnl check for cthread support in current $LIBS
1448                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1449
1450                 if test $ol_link_threads = no ; then
1451                         dnl try -all_load
1452                         dnl this test needs work
1453                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1454                                 [ol_cv_cthread_all_load], [
1455                                 dnl save the flags
1456                                 save_LIBS="$LIBS"
1457                                 LIBS="-all_load $LIBS"
1458                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1459                                         cthread_fork((void *)0, (void *)0);
1460                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1461                                 dnl restore the LIBS
1462                                 LIBS="$save_LIBS"
1463                         ])
1464
1465                         if test $ol_cv_cthread_all_load = yes ; then
1466                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1467                                 ol_link_threads=mach
1468                         fi
1469                 fi
1470
1471                 if test $ol_link_threads != no ; then
1472                         : check for cthread specific functionality here
1473                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1474                                 [define if you have Mach Cthreads])
1475                 else
1476                         AC_MSG_ERROR([could not link with Mach CThreads])
1477                 fi
1478         fi
1479
1480         if test $ol_with_threads = mach ; then
1481                 AC_MSG_ERROR([could not locate Mach CThreads])
1482         fi
1483 fi
1484
1485 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1486         -o $ol_with_threads = pth ; then
1487
1488         AC_CHECK_HEADERS(pth.h)
1489
1490         if test $ac_cv_header_pth_h = yes ; then
1491                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1492
1493                 if test $have_pth = yes ; then
1494                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1495                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1496                         ol_link_threads=pth
1497
1498                         if test $ol_with_yielding_select = auto ; then
1499                                 ol_with_yielding_select=yes
1500                         fi
1501                 fi
1502         fi
1503 fi
1504
1505 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1506         -o $ol_with_threads = lwp ; then
1507
1508         dnl check for SunOS5 LWP
1509         AC_CHECK_HEADERS(thread.h synch.h)
1510         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1511                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1512
1513                 if test $have_thr = yes ; then
1514                         AC_DEFINE(HAVE_THR,1,
1515                                 [if you have Solaris LWP (thr) package])
1516                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1517                         ol_link_threads=thr
1518
1519                         if test $ol_with_yielding_select = auto ; then
1520                                 ol_with_yielding_select=yes
1521                         fi
1522
1523                         dnl Check for setconcurreny functions
1524                         AC_CHECK_FUNCS( \
1525                                 thr_setconcurrency \
1526                                 thr_getconcurrency \
1527                         )
1528                 fi
1529         fi
1530
1531         dnl check for SunOS4 LWP
1532         AC_CHECK_HEADERS(lwp/lwp.h)
1533         if test $ac_cv_header_lwp_lwp_h = yes ; then
1534                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1535
1536                 if test $have_lwp = yes ; then
1537                         AC_DEFINE(HAVE_LWP,1,
1538                                 [if you have SunOS LWP package])
1539                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1540                         ol_link_threads=lwp
1541
1542                         if test $ol_with_yielding_select = auto ; then
1543                                 ol_with_yielding_select=no
1544                         fi
1545                 fi
1546         fi
1547 fi
1548
1549 if test $ol_with_yielding_select = yes ; then
1550         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1551                 [define if select implicitly yields])
1552 fi
1553
1554 if test $ol_with_threads = manual ; then
1555         dnl User thinks he can manually configure threads.
1556         ol_link_threads=yes
1557
1558         AC_MSG_WARN([thread defines and link options must be set manually])
1559
1560         AC_CHECK_HEADERS(pthread.h sched.h)
1561         AC_CHECK_FUNCS(sched_yield pthread_yield)
1562         OL_HEADER_LINUX_THREADS
1563
1564         AC_CHECK_HEADERS(mach/cthreads.h)
1565         AC_CHECK_HEADERS(lwp/lwp.h)
1566         AC_CHECK_HEADERS(thread.h synch.h)
1567 fi
1568
1569 if test $ol_link_threads != no -a $ol_link_threads != nt ; then
1570         dnl needed to get reentrant/threadsafe versions
1571         dnl
1572         AC_DEFINE(REENTRANT,1)
1573         AC_DEFINE(_REENTRANT,1)
1574         AC_DEFINE(THREAD_SAFE,1)
1575         AC_DEFINE(_THREAD_SAFE,1)
1576         AC_DEFINE(THREADSAFE,1)
1577         AC_DEFINE(_THREADSAFE,1)
1578         AC_DEFINE(_SGI_MP_SOURCE,1)
1579
1580         dnl The errno declaration may dependent upon _REENTRANT.
1581         dnl If it does, we must link with thread support.
1582         AC_CACHE_CHECK([for thread specific errno],
1583                 [ol_cv_errno_thread_specific], [
1584                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1585                         [ol_cv_errno_thread_specific=yes],
1586                         [ol_cv_errno_thread_specific=no])
1587         ])
1588
1589         dnl The h_errno declaration may dependent upon _REENTRANT.
1590         dnl If it does, we must link with thread support.
1591         AC_CACHE_CHECK([for thread specific h_errno],
1592                 [ol_cv_h_errno_thread_specific], [
1593                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1594                         [ol_cv_h_errno_thread_specific=yes],
1595                         [ol_cv_h_errno_thread_specific=no])
1596         ])
1597
1598         if test $ol_cv_errno_thread_specific != yes \
1599                 -o $ol_cv_h_errno_thread_specific != yes ; then
1600                 LIBS="$LTHREAD_LIBS $LIBS"
1601                 LTHREAD_LIBS=""
1602         fi
1603
1604 dnl When in thread environment, use
1605 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1606 dnl                     || defined( HAVE_FUNC_R )
1607 dnl                     func_r(...);
1608 dnl             #else
1609 dnl             #       if defined( HAVE_THREADS )
1610 dnl                             /* lock */
1611 dnl             #       endif
1612 dnl                             func(...);
1613 dnl             #       if defined( HAVE_THREADS )
1614 dnl                             /* unlock */
1615 dnl             #       endif
1616 dnl             #endif
1617 dnl
1618 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1619 dnl             _POSIX_REENTRANT_FUNCTIONS
1620 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1621 dnl             _POSIX_THREADSAFE_FUNCTIONS
1622 dnl
1623 dnl             and is currently defined in lthread.h
1624 dnl
1625 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1626 dnl
1627 dnl libldap/*.c should only include <lthread.h> iff
1628 dnl LDAP_R_COMPILE is defined.  ie:
1629 dnl             #ifdef LDAP_R_COMPILE
1630 dnl             #       include LDAP_R_COMPILE
1631 dnl             #endif
1632 dnl
1633 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1634 dnl specifically for compiling the threadsafe version of
1635 dnl     the ldap library (-lldap_r).
1636 dnl
1637 dnl     dnl check for reentrant/threadsafe functions
1638 dnl     dnl
1639 dnl     dnl note: these should only be used when linking
1640 dnl     dnl       with $LTHREAD_LIBS
1641 dnl     dnl
1642 dnl     save_CPPFLAGS="$CPPFLAGS"
1643 dnl     save_LIBS="$LIBS"
1644 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1645 dnl     AC_CHECK_FUNCS( \
1646 dnl             gmtime_r \
1647 dnl             gethostbyaddr_r gethostbyname_r \
1648 dnl             feof_unlocked unlocked_feof \
1649 dnl             putc_unlocked unlocked_putc \
1650 dnl             flockfile ftrylockfile \
1651 dnl     )
1652 dnl     CPPFLAGS="$save_CPPFLAGS"
1653 dnl     LIBS="$save_LIBS"
1654 fi
1655
1656 if test $ol_link_threads = no ; then
1657         if test $ol_with_threads = yes ; then
1658                 AC_MSG_ERROR([no suitable thread support])
1659         fi
1660
1661         if test $ol_with_threads = auto ; then
1662                 AC_MSG_WARN([no suitable thread support, disabling threads])
1663                 ol_with_threads=no
1664         fi
1665
1666         AC_DEFINE(NO_THREADS,1,
1667                 [define if you have (or want) no threads])
1668         LTHREAD_LIBS=""
1669 fi
1670
1671 if test $ol_link_threads != no ; then
1672         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1673 fi
1674
1675 dnl ----------------------------------------------------------------
1676 ol_link_ldbm=no
1677
1678 if test $ol_with_ldbm_api = auto \
1679         -o $ol_with_ldbm_api = berkeley \
1680         -o $ol_with_ldbm_api = bcompat ; then
1681
1682         if test $ol_with_ldbm_api = bcompat; then \
1683                 OL_BERKELEY_COMPAT_DB
1684         else
1685                 OL_BERKELEY_DB
1686         fi
1687
1688         if test $ol_cv_berkeley_db != no ; then
1689                 AC_DEFINE(HAVE_BERKELEY_DB,1,
1690                         [define this if Berkeley DB is available])
1691
1692                 ol_link_ldbm=berkeley
1693                 ol_with_ldbm_api=db
1694
1695                 if test $ol_with_ldbm_type = hash ; then
1696                         AC_DEFINE(LDBM_USE_DBHASH,1,
1697                                 [define this to use DBHASH w/ LDBM backend])
1698                 else
1699                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1700                                 [define this to use DBBTREE w/ LDBM backend])
1701                 fi
1702
1703                 dnl $ol_cv_lib_db should be yes or -ldb
1704                 dnl (it could be no, but that would be an error
1705                 if test $ol_cv_lib_db != yes ; then
1706                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1707                 fi
1708         fi
1709 fi
1710
1711 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1712         AC_MSG_WARN(Could not find LDBM with BTREE support)
1713         ol_with_ldbm_api=none
1714 fi
1715
1716 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1717         OL_MDBM
1718
1719         if test $ol_cv_mdbm = yes ; then
1720                 ol_link_ldbm=mdbm
1721                 ol_with_ldbm_api=mdbm
1722                 if test $ol_cv_lib_mdbm != yes ; then
1723                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1724                 fi
1725         fi
1726 fi
1727
1728 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1729         OL_GDBM
1730
1731         if test $ol_cv_gdbm = yes ; then
1732                 ol_link_ldbm=gdbm
1733                 ol_with_ldbm_api=gdbm
1734
1735                 if test $ol_cv_lib_gdbm != yes ; then
1736                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1737                 fi
1738         fi
1739 fi
1740
1741 if test $ol_with_ldbm_api = ndbm ; then
1742         OL_NDBM
1743
1744         if test $ol_cv_ndbm = yes ; then
1745                 ol_link_ldbm=ndbm
1746                 ol_with_ldbm_api=ndbm
1747
1748                 if test $ol_cv_lib_ndbm != yes ; then
1749                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1750                 fi
1751         fi
1752 fi
1753
1754 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1755         AC_MSG_WARN(could not find suitable LDBM backend)
1756         if test $ol_enable_ldbm = yes ; then
1757                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1758         fi
1759
1760         AC_MSG_WARN(disabling LDBM)
1761         ol_enable_ldbm=no
1762 fi
1763
1764 dnl ----------------------------------------------------------------
1765 if test $ol_enable_dynamic = yes -a $enable_shared = yes ; then
1766         LINK_BINS_DYNAMIC="yes"
1767 else
1768         LINK_BINS_DYNAMIC="no"
1769 fi
1770
1771 dnl ----------------------------------------------------------------
1772 if test $ol_enable_wrappers != no ; then
1773         AC_CHECK_HEADERS(tcpd.h)
1774
1775         if test $ac_cv_header_tcpd_h != yes ; then
1776                 have_wrappers=no
1777         else
1778                 AC_TRY_COMPILE([
1779 int allow_severity = 0;
1780 int deny_severity  = 0;
1781                 ],[hosts_access()],[have_wrappers=yes],[have_wrappers=no])
1782         fi
1783
1784         if test $have_wrappers = yes ; then
1785                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1786                 WRAP_LIBS="-lwrap"
1787
1788                 dnl We add another check for -lnsl since some libwrap's
1789                 dnl need it, but it isn't always included from above
1790                 AC_CHECK_LIB(nsl, main)
1791         else
1792                 AC_MSG_WARN(could not find -lwrap)
1793                 if test $ol_enable_wrappers = yes ; then
1794                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1795                 fi
1796
1797                 AC_MSG_WARN(disabling wrappers support)
1798                 ol_enable_wrappers=no
1799                 WRAP_LIBS=""
1800         fi
1801 fi
1802
1803 dnl ----------------------------------------------------------------
1804 if test $ol_enable_syslog != no ; then
1805         AC_CHECK_FUNC(openlog)
1806         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1807                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1808         fi
1809         ol_enable_syslog=$ac_cv_func_openlog
1810 fi
1811
1812 dnl ----------------------------------------------------------------
1813 dnl dmalloc support (deprecated in favor of -DCSRIMALLOC support)
1814 dnl if test $ol_enable_dmalloc != no ; then
1815 dnl     AC_CHECK_HEADERS(dmalloc.h)
1816 dnl     AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1817 dnl fi
1818
1819 dnl ----------------------------------------------------------------
1820 dnl SQL
1821 ol_link_sql=no
1822 if test $ol_enable_sql != no ; then
1823         AC_CHECK_LIB(iodbc,SQLDriverConnect,[have_iodbc=yes],[have_iodbc=no])
1824         if test $have_iodbc = yes ; then
1825                 ol_link_sql="-liodbc"
1826         else
1827                 AC_CHECK_LIB(odbc,SQLDriverConnect,[have_odbc=yes],[have_odbc=no])
1828                 if test $have_odbc = yes ; then
1829                         ol_link_sql="-lodbc"
1830                 fi
1831         fi
1832
1833         if test $ol_link_sql != no ; then
1834                 SLAPD_SQL_LIBS="$ol_link_sql"
1835
1836         elif test $ol_enable_sql != auto ; then
1837                 AC_MSG_ERROR([could not locate suitable ODBC library])
1838         fi
1839 fi
1840
1841 dnl ----------------------------------------------------------------
1842 dnl TCL
1843 if test $ol_enable_tcl != no ; then
1844         AC_CHECK_HEADERS(tcl.h)
1845
1846         if test $ac_cv_header_tcl_h != yes ; then
1847                 have_tcl=no
1848         else
1849                 for lib in tcl tcl7.6 tcl8.0 tcl8.2 ; do
1850                         AC_CHECK_LIB($lib,main,
1851                           [have_tcl=yes
1852                            if test x"$ol_with_tcl_module" = "xstatic" ; then
1853                                SLAPD_LIBS="$SLAPD_LIBS -l${lib}"
1854                            else
1855                                MOD_TCL_LIB="-l${lib}"
1856                            fi;break],[have_tcl=no])
1857                 done
1858         fi
1859
1860         if test $have_tcl != yes ; then
1861                 AC_MSG_WARN([could not find -ltcl])
1862                 if test $ol_enable_tcl = yes ; then
1863                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1864                 fi
1865
1866                 ol_enable_tcl=no
1867         fi
1868 fi
1869
1870 dnl ----------------------------------------------------------------
1871 dnl ud needs termcap (should insert check here)
1872 ol_link_termcap=no
1873 AC_CHECK_HEADERS(termcap.h ncurses.h)
1874
1875 if test $ol_link_termcap = no ; then
1876         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1877         if test $have_termcap = yes ; then
1878                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1879                 ol_link_termcap=yes
1880                 TERMCAP_LIBS=-ltermcap
1881         fi
1882 fi
1883
1884 if test $ol_link_termcap = no ; then
1885         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1886         if test $have_ncurses = yes ; then
1887                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1888                 ol_link_termcap=yes
1889                 TERMCAP_LIBS=-lncurses
1890         fi
1891 fi
1892
1893 if test $ol_link_termcap = no ; then
1894         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1895         TERMCAP_LIBS=
1896 fi
1897
1898 dnl ----------------------------------------------------------------
1899 dnl
1900 dnl Check for Cyrus SASL
1901 dnl
1902 ol_link_sasl=no
1903 ol_link_spasswd=no
1904 if test $ol_with_cyrus_sasl != no ; then
1905         AC_CHECK_HEADERS(sasl.h)
1906
1907         if test $ac_cv_header_sasl_h = yes ; then
1908                 AC_CHECK_LIB(sasl, sasl_client_init,
1909                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1910
1911                 if test $have_cyrus_sasl != no ; then
1912                         SASL_LIBS="-lsasl"
1913                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1914                         ol_link_sasl=yes
1915                 fi
1916         fi
1917
1918         if test $ol_link_sasl = no ; then
1919                 if test $ol_with_cyrus_sasl != auto ; then
1920                         AC_MSG_ERROR([Could not locate Cyrus SASL])
1921                 else
1922                         AC_MSG_WARN([Could not locate Cyrus SASL])
1923                         AC_MSG_WARN([SASL authentication not supported!])
1924                         if test $ol_link_tls = no ; then
1925                                 AC_MSG_WARN([Strong authentication not supported!])
1926                         fi
1927                 fi
1928
1929         elif test $ol_enable_spasswd != no ; then
1930                 ol_link_spasswd=yes
1931         fi
1932
1933 else
1934         AC_MSG_WARN([SASL authentication not supported!])
1935         if test $ol_link_tls = no ; then
1936                 AC_MSG_WARN([Strong authentication not supported!])
1937         fi
1938 fi
1939
1940 dnl ----------------------------------------------------------------
1941 dnl Check for entropy sources
1942 if test $cross_compiling != yes ; then
1943         dev=no
1944         if test -r /dev/urandom ; then
1945                 dev="/dev/urandom";
1946         elif test -r /idev/urandom ; then
1947                 dev="/idev/urandom";
1948         elif test -r /dev/srandom ; then
1949                 dev="/dev/srandom";
1950         elif test -r /dev/random ; then
1951                 dev="/dev/random";
1952         elif test -r /idev/random ; then
1953                 dev="/idev/random";
1954         fi
1955
1956         if test $dev != no ; then
1957                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
1958         fi
1959 fi
1960
1961 dnl ----------------------------------------------------------------
1962 dnl
1963 dnl Check for fetch URL support
1964 dnl             should be extended to support other fetch URL APIs
1965 dnl
1966 ol_link_fetch=no
1967 if test $ol_with_fetch != no ; then
1968         OL_LIB_FETCH
1969
1970         if test $ol_cv_lib_fetch != no ; then
1971                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1972                 ol_link_fetch=freebsd
1973
1974         elif test $ol_with_fetch != auto ; then
1975                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1976         fi
1977 fi
1978
1979 dnl ----------------------------------------------------------------
1980 dnl
1981 dnl Check for GNU readline
1982 dnl
1983 ol_link_readline=no
1984 if test $ol_with_readline != no ; then
1985         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1986
1987         if test $ac_cv_header_readline_readline_h = yes ; then
1988                 save_LIBS="$LIBS"
1989                 LIBS="$TERMCAP_LIBS $LIBS"
1990                 AC_CHECK_LIB(readline, readline,
1991                         [have_readline=yes], [have_readline=no])
1992                 LIBS="$save_LIBS"
1993
1994                 if test $have_readline = yes ; then
1995                         ol_with_readline=found
1996                         ol_link_readline=yes
1997
1998                         READLINE_LIBS="-lreadline"
1999                 fi
2000         fi
2001 fi
2002
2003 if test $ol_link_readline = yes ; then
2004         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
2005 fi
2006
2007
2008 dnl ----------------------------------------------------------------
2009 dnl FreeBSD (and others) have crypt(3) in -lcrypt
2010 if test $ol_enable_crypt != no ; then
2011         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
2012                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
2013                         have_crypt=yes], [have_crypt=no])])
2014
2015         if test $have_crypt = yes ; then
2016                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
2017         else
2018                 AC_MSG_WARN(could not find crypt)
2019                 if test $ol_enable_crypt = yes ; then
2020                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
2021                 fi
2022
2023                 AC_MSG_WARN(disabling crypt support)
2024                 ol_enable_crypt=no
2025         fi
2026 fi
2027
2028 dnl ----------------------------------------------------------------
2029 dnl FreeBSD (and others) have setproctitle(3) in -lutil
2030 if test $ol_enable_proctitle != no ; then
2031         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
2032                 AC_CHECK_LIB(util, setproctitle,
2033                         [have_setproctitle=yes
2034                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
2035                         [have_setproctitle=no
2036                         LIBOBJS="$LIBOBJS setproctitle.o"
2037                         LIBSRCS="$LIBSRCS setproctitle.c"])])
2038
2039         if test $have_setproctitle = yes ; then
2040                 AC_DEFINE(HAVE_SETPROCTITLE,1,
2041                         [define if setproctitle(3) is available])
2042         fi
2043 fi
2044
2045 dnl ----------------------------------------------------------------
2046 dnl Checks for typedefs, structures, and compiler characteristics.
2047 AC_TYPE_MODE_T
2048 AC_TYPE_OFF_T
2049 AC_TYPE_PID_T
2050 AM_TYPE_PTRDIFF_T
2051 AC_TYPE_SIGNAL
2052 AC_TYPE_SIZE_T
2053
2054 AC_CHECK_TYPE(ssize_t, [signed int])
2055 AC_CHECK_TYPE(caddr_t,  [char *])
2056
2057 OL_TYPE_SOCKLEN_T
2058 AC_STRUCT_ST_BLKSIZE
2059 AC_HEADER_TIME
2060 AC_STRUCT_TM
2061 AC_TYPE_UID_T
2062 OL_TYPE_SIG_ATOMIC_T
2063
2064 dnl AC_TYPE_GETGROUPS
2065
2066 OL_STRUCT_PASSWD_PW_GECOS
2067 OL_STRUCT_PASSWD_PW_PASSWD
2068
2069 OL_C_UPPER_LOWER
2070 AC_C_CONST
2071 OL_C_VOLATILE
2072
2073 if test $cross_compiling = yes ; then
2074         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2075 else
2076         AC_C_BIGENDIAN
2077 fi
2078
2079 AC_COMPILE_CHECK_SIZEOF(short)
2080 AC_COMPILE_CHECK_SIZEOF(int)
2081 AC_COMPILE_CHECK_SIZEOF(long)
2082
2083 if test "$ac_cv_sizeof_int" -lt 4 ; then
2084         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2085
2086         AC_DEFINE(LBER_INT_T,long)
2087 else
2088         AC_DEFINE(LBER_INT_T,int)
2089 fi
2090
2091 AC_DEFINE(LBER_LEN_T,long)
2092 AC_DEFINE(LBER_SOCKET_T,int)
2093 AC_DEFINE(LBER_TAG_T,long)
2094
2095 dnl ----------------------------------------------------------------
2096 dnl Checks for library functions.
2097 AC_FUNC_MEMCMP
2098 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
2099 AC_FUNC_STRFTIME
2100 dnl AM_FUNC_STRTOD
2101
2102 OL_FUNC_INET_ATON
2103
2104 dnl Check for NT specific routines
2105 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2106
2107 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2108         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2109 ])
2110
2111 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2112         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2113 ])
2114
2115 AC_FUNC_VPRINTF
2116
2117 if test $ac_cv_func_vprintf = yes ; then
2118         dnl check for vsnprintf
2119         AC_CHECK_FUNCS(vsnprintf vsprintf)
2120 fi
2121
2122 AC_CHECK_FUNCS(         \
2123         bcopy                   \
2124         closesocket             \
2125         chroot                  \
2126         endgrent                \
2127         endpwent                \
2128         flock                   \
2129         getdtablesize   \
2130         getgrgid                \
2131         gethostname             \
2132         getpass                 \
2133         getpassphrase   \
2134         getpwuid                \
2135         getpwnam                \
2136         getspnam                \
2137         gettimeofday    \
2138         initgroups              \
2139         lockf                   \
2140         memcpy                  \
2141         memmove                 \
2142         mkstemp                 \
2143         pipe                    \
2144         read                    \
2145         recv                    \
2146         recvfrom                \
2147         setpwfile               \
2148         setgid                  \
2149         setegid                 \
2150         setsid                  \
2151         setuid                  \
2152         seteuid                 \
2153         sigaction               \
2154         signal                  \
2155         sigset                  \
2156         snprintf                \
2157         strdup                  \
2158         strerror                \
2159         strpbrk                 \
2160         strrchr                 \
2161         strsep                  \
2162         strstr                  \
2163         strtol                  \
2164         strtoul                 \
2165         strspn                  \
2166         sysconf                 \
2167         waitpid                 \
2168         wait4                   \
2169         write                   \
2170         send                    \
2171         sendto                  \
2172 )
2173
2174 dnl We actually may need to replace more than this.
2175 AC_REPLACE_FUNCS(getopt tempnam)
2176
2177 if test "$ac_cv_func_getopt" != yes; then
2178     LIBSRCS="$LIBSRCS getopt.c"
2179 fi
2180
2181 if test "$ac_cv_func_tempnam" != yes; then
2182     LIBSRCS="$LIBSRCS tempnam.c"
2183 fi
2184
2185 dnl ----------------------------------------------------------------
2186 # Check Configuration
2187 OL_SYS_ERRLIST
2188
2189 dnl ----------------------------------------------------------------
2190 dnl Sort out defines
2191
2192 if test "$ol_enable_debug" != no ; then
2193         AC_DEFINE(LDAP_DEBUG,1,
2194                 [define this to add debugging code])
2195 fi
2196 if test "$ol_enable_syslog" = yes ; then
2197         AC_DEFINE(LDAP_SYSLOG,1,
2198                 [define this to add syslog code])
2199 fi
2200 if test "$ol_enable_cache" = no ; then
2201         AC_DEFINE(LDAP_NOCACHE,1,
2202                 [define this to remove -lldap cache support])
2203 fi
2204 if test "$ol_link_kbind" != no ; then
2205         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_KBIND,LDAP_VENDOR_VERSION)
2206 fi
2207 if test "$ol_enable_proctitle" != no ; then
2208         AC_DEFINE(LDAP_PROCTITLE,1,
2209                 [define this for LDAP process title support])
2210 fi
2211 if test "$ol_enable_referrals" != no ; then
2212         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
2213 fi
2214 if test "$ol_enable_local" != no; then
2215         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2216 fi
2217 if test "$ol_link_ipv6" != no; then
2218         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2219 fi
2220 if test "$ol_enable_cleartext" != no ; then
2221         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2222 fi
2223 if test "$ol_enable_crypt" != no ; then
2224         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2225 fi
2226 if test "$ol_link_kpasswd" != no ; then
2227         AC_DEFINE(SLAPD_KPASSWD,1,[define to support Kerberos passwords])
2228 fi
2229 if test "$ol_link_spasswd" != no ; then
2230         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2231 fi
2232 if test "$ol_enable_multimaster" != no ; then
2233         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2234 fi
2235 if test "$ol_enable_phonetic" != no ; then
2236         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
2237 fi
2238 if test "$ol_enable_rlookups" != no ; then
2239         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2240 fi
2241 if test "$ol_enable_aci" != no ; then
2242         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2243 fi
2244
2245 if test "$ol_link_modules" != no ; then
2246         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2247         BUILD_SLAPD=yes
2248         SLAPD_MODULES_LDFLAGS="-dlopen self"
2249 fi
2250
2251 if test "$ol_enable_bdb" != no ; then
2252         AC_DEFINE(SLAPD_BDB,1,[define to support BDB backend])
2253         BUILD_SLAPD=yes
2254         BUILD_BDB=yes
2255         if test "$ol_with_bdb_module" != static ; then
2256                 AC_DEFINE(SLAPD_BDB_DYNAMIC,1,
2257                         [define to support dynamic BDB backend])
2258                 BUILD_BDB=mod
2259                 BUILD_BDB_DYNAMIC=shared
2260                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-bdb/back_bdb.la"
2261         fi
2262 fi
2263
2264 if test "$ol_link_dnssrv" != no ; then
2265         AC_DEFINE(SLAPD_DNSSRV,1,[define to support DNS SRV backend])
2266         BUILD_SLAPD=yes
2267         BUILD_DNSSRV=yes
2268         if test "$ol_with_dnssrv_module" != static ; then
2269                 AC_DEFINE(SLAPD_DNSSRV_DYNAMIC,1,
2270                         [define to support dynamic DNS SRV backend])
2271                 BUILD_DNSSRV=mod
2272                 BUILD_DNSSRV_DYNAMIC=shared
2273                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-dnssrv/back_dnssrv.la"
2274         fi
2275 fi
2276
2277 if test "$ol_enable_ldap" != no ; then
2278         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
2279         BUILD_SLAPD=yes
2280         BUILD_LDAP=yes
2281         if test "$ol_with_ldap_module" != static ; then
2282                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
2283                         [define to support dynamic LDAP backend])
2284                 BUILD_LDAP=mod
2285                 BUILD_LDAP_DYNAMIC=shared
2286                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
2287         fi
2288 fi
2289
2290 if test "$ol_link_ldbm" != no ; then
2291         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
2292         BUILD_SLAPD=yes
2293         BUILD_LDBM=yes
2294         if test "$ol_with_ldbm_module" != static ; then
2295                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
2296                         [define to support dynamic LDBM backend])
2297                 BUILD_LDBM=mod
2298                 BUILD_LDBM_DYNAMIC=shared
2299                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
2300         fi
2301 fi
2302
2303 if test "$ol_enable_passwd" != no ; then
2304         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2305         BUILD_SLAPD=yes
2306         BUILD_PASSWD=yes
2307         if test "$ol_with_passwd_module" != static ; then
2308                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2309                         [define to support dynamic PASSWD backend])
2310                 BUILD_PASSWD=mod
2311                 BUILD_PASSWD_DYNAMIC=shared
2312                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
2313         fi
2314 fi
2315
2316 if test "$ol_link_perl" != no ; then
2317         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
2318         BUILD_SLAPD=yes
2319         BUILD_PERL=yes
2320         if test "$ol_with_perl_module" != static ; then
2321                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
2322                         [define to support dynamic PERL backend])
2323                 BUILD_PERL=mod
2324                 BUILD_PERL_DYNAMIC=shared
2325                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-perl/back_perl.la"
2326         fi
2327 fi
2328
2329 if test "$ol_enable_shell" != no ; then
2330         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2331         BUILD_SLAPD=yes
2332         BUILD_SHELL=yes
2333         if test "$ol_with_shell_module" != static ; then
2334                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2335                         [define to support dynamic SHELL backend])
2336                 BUILD_SHELL=mod
2337                 BUILD_SHELL_DYNAMIC=shared
2338                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2339         fi
2340 fi
2341
2342 if test "$ol_enable_tcl" != no ; then
2343         AC_DEFINE(SLAPD_TCL,1,[define to support TCL backend])
2344         BUILD_SLAPD=yes
2345         BUILD_TCL=yes
2346         if test "$ol_with_tcl_module" != static; then
2347                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1,
2348                         [define to support dynamic TCL backend])
2349                 BUILD_TCL=mod
2350                 BUILD_TCL_DYNAMIC=shared
2351                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-tcl/back_tcl.la"
2352         fi
2353 fi
2354
2355 if test "$ol_link_sql" != no ; then
2356         AC_DEFINE(SLAPD_SQL,1,[define to support SQL backend])
2357         BUILD_SLAPD=yes
2358         BUILD_SQL=yes
2359         if test "$ol_with_sql_module" != static; then
2360                 AC_DEFINE(SLAPD_SQL_DYNAMIC,1,
2361                         [define to support dynamic SQL backend])
2362                 BUILD_SQL=mod
2363                 BUILD_SQL_DYNAMIC=shared
2364                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-sql/back_sql.la"
2365         fi
2366 fi
2367
2368 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2369         $BUILD_SLAPD = yes ; then
2370         BUILD_SLURPD=yes
2371 fi
2372
2373 dnl ----------------------------------------------------------------
2374
2375 if test "$LINK_BINS_DYNAMIC" = yes; then
2376     LIB_LINKAGE=DYN
2377     LT_LIB_LINKAGE=shared
2378 else
2379     LIB_LINKAGE=STAT
2380     LT_LIB_LINKAGE=static
2381 fi
2382
2383 if test "$ac_cv_mingw32" = yes ; then
2384     PLAT=NT
2385     DYN_EXT=dll
2386 else
2387     PLAT=UNIX
2388     DYN_EXT=so
2389 fi
2390
2391 AC_SUBST(LIBSRCS)
2392
2393 AC_SUBST(PLAT)
2394 AC_SUBST(LIB_LINKAGE)
2395 AC_SUBST(LT_LIB_LINKAGE)
2396 AC_SUBST(DYN_EXT)
2397
2398 AC_SUBST(BUILD_SLAPD)
2399   AC_SUBST(BUILD_BDB)
2400   AC_SUBST(BUILD_DNSSRV)
2401   AC_SUBST(BUILD_LDAP)
2402   AC_SUBST(BUILD_LDBM)
2403   AC_SUBST(BUILD_PASSWD)
2404   AC_SUBST(BUILD_PERL)
2405   AC_SUBST(BUILD_SHELL)
2406   AC_SUBST(BUILD_SQL)
2407   AC_SUBST(BUILD_TCL)
2408   AC_SUBST(BUILD_BDB_DYNAMIC)
2409   AC_SUBST(BUILD_DNSSRV_DYNAMIC)
2410   AC_SUBST(BUILD_LDAP_DYNAMIC)
2411   AC_SUBST(BUILD_LDBM_DYNAMIC)
2412   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2413   AC_SUBST(BUILD_PERL_DYNAMIC)
2414   AC_SUBST(BUILD_SHELL_DYNAMIC)
2415   AC_SUBST(BUILD_SQL_DYNAMIC)
2416   AC_SUBST(BUILD_TCL_DYNAMIC)
2417 AC_SUBST(BUILD_SLURPD)
2418
2419 AC_SUBST(LDAP_LIBS)
2420 AC_SUBST(LDIF_LIBS)
2421 AC_SUBST(SLAPD_LIBS)
2422 AC_SUBST(SLURPD_LIBS)
2423 AC_SUBST(LDBM_LIBS)
2424 AC_SUBST(LTHREAD_LIBS)
2425 AC_SUBST(LUTIL_LIBS)
2426 AC_SUBST(WRAP_LIBS)
2427 AC_SUBST(MOD_TCL_LIB)
2428 AC_SUBST(LINK_BINS_DYNAMIC)
2429
2430 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2431 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2432 AC_SUBST(SLAPD_MODULES_LIST)
2433
2434 AC_SUBST(PERL_CPPFLAGS)
2435 AC_SUBST(SLAPD_PERL_LDFLAGS)
2436 AC_SUBST(MOD_PERL_LDFLAGS)
2437
2438 AC_SUBST(KRB4_LIBS)
2439 AC_SUBST(KRB5_LIBS)
2440 AC_SUBST(READLINE_LIBS)
2441 AC_SUBST(SASL_LIBS)
2442 AC_SUBST(TERMCAP_LIBS)
2443 AC_SUBST(TLS_LIBS)
2444 AC_SUBST(MODULES_LIBS)
2445 AC_SUBST(AUTH_LIBS)
2446
2447 AC_SUBST(SLAPD_SQL_LDFLAGS)
2448 AC_SUBST(SLAPD_SQL_LIBS)
2449 AC_SUBST(SLAPD_SQL_INCLUDES)
2450
2451 dnl ----------------------------------------------------------------
2452 dnl final output
2453 dnl
2454
2455 AC_OUTPUT( \
2456 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2457 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2458 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2459 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2460 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2461 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2462 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2463 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2464 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2465 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2466 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2467 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2468 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2469 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2470 clients/maildap/Makefile:build/top.mk:clients/maildap/Makefile.in:build/rules.mk \
2471 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2472 include/Makefile:build/top.mk:include/Makefile.in \
2473 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2474 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2475 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2476 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2477 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2478 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2479 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2480 libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk  \
2481 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2482 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2483 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2484 servers/slapd/back-bdb/Makefile:build/top.mk:servers/slapd/back-bdb/Makefile.in:build/mod.mk \
2485 servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk \
2486 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2487 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2488 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2489 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk \
2490 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2491 servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk \
2492 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/mod.mk \
2493 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2494 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2495 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2496 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2497 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2498 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2499 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2500 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2501 ,[
2502 date > stamp-h
2503 echo Please \"make depend\" to build dependencies
2504 ])