git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Disable config.cache!
  11 define([AC_CACHE_LOAD], )dnl
  12 define([AC_CACHE_SAVE], )dnl
  13
  14 dnl Configure.in for OpenLDAP
  15 AC_INIT(build/version)dnl
  16 AC_CONFIG_AUX_DIR(build)dnl
  17
  18 OL_VERSION=`cat $ac_aux_dir/version`
  19 if test -z "$OL_VERSION"; then
  20         AC_MSG_ERROR([could not determine version])
  21 fi
  22
  23 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  24 AC_SUBST(PACKAGE)
  25 AC_SUBST(VERSION)
  26 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  27 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  28
  29 dnl We use autoconf features new to 2.13.
  30 dnl     aclocal.m4 should be built using aclocal from automake 1.4
  31 AC_PREREQ(2.13)dnl Required Autoconf version
  32
  33 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  34
  35 dnl
  36 dnl Start Args
  37 AC_MSG_CHECKING(configure arguments)
  38 AC_PREFIX_DEFAULT(/usr/local)
  39
  40 top_builddir=`pwd`
  41 AC_SUBST(top_builddir)dnl
  42
  43 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
  44
  45 ldap_subdir="openldap"
  46
  47 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  48         if test "$withval" = "no"; then
  49                 ldap_subdir=""
  50         elif test "$withval" != "yes"; then
  51                 ldap_subdir="$withval"
  52         fi
  53 ])dnl
  54
  55 AC_SUBST(ldap_subdir)dnl
  56
  57 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  58 dnl ol_enable_syslog=no
  59 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  60 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  61 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  62 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  63 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  64 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  65 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  66         no, [yes no])dnl
  67
  68 dnl General "with" options
  69 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  70
  71 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  72         auto, [auto k5 k4 afs yes no])
  73 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  74         auto, [auto yes no] )
  75 OL_ARG_WITH(threads,[  --with-threads   use threads],
  76         auto, [auto posix mach lwp yes no manual] )
  77 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  78         auto, [auto ssleay openssl yes no] )
  79 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  80         auto, [auto yes no manual] )
  81
  82 dnl Server options
  83
  84 dnl LDAPD OPTIONS
  85 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  86 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  87
  88 dnl SLAPD OPTIONS
  89 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  90 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  91 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  92 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  93 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  94 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
  95 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  96 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  97 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  98
  99 dnl SLAPD Backend options
 100 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 101 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 102 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 103 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 104         [auto db2 db mdbm gdbm ndbm manual])
 105 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 106         [auto btree hash])
 107
 108 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 109 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 110 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 111 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 112
 113 dnl SLURPD OPTIONS
 114 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
 115 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 116
 117 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 118 AM_ENABLE_STATIC
 119 dnl AM_DISABLE_SHARED
 120 AM_ENABLE_SHARED
 121
 122 dnl General "enable" options
 123 # validate options
 124 if test $ol_enable_dns = yes ; then
 125         if test $ol_enable_referrals = no ; then
 126                 AC_MSG_ERROR([DNS requires --enable-referrals])
 127         fi
 128         if test $ol_enable_referrals = auto ; then
 129                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 130                 ol_enable_referrals=yes
 131         fi
 132 fi
 133
 134 if test $ol_enable_slapd = no ; then
 135         dnl SLAPD was specificallly disabled
 136         if test $ol_enable_bdb2 = yes ; then
 137                 AC_MSG_WARN([slapd disabled, ignoring --enable_bdb2 argument])
 138         fi
 139         if test $ol_enable_ldap = yes ; then
 140                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldap argument])
 141         fi
 142         if test $ol_enable_ldbm = yes ; then
 143                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 144         fi
 145         if test $ol_enable_passwd = yes ; then
 146                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 147         fi
 148         if test $ol_enable_perl = yes ; then
 149                 AC_MSG_WARN([slapd disabled, ignoring --enable_perl argument])
 150         fi
 151         if test $ol_enable_shell = yes ; then
 152                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 153         fi
 154         if test $ol_enable_tcl = yes ; then
 155                 AC_MSG_WARN([slapd disabled, ignoring --enable_tcl argument])
 156         fi
 157         if test $ol_enable_aclgroups = yes ; then
 158                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 159         fi
 160         if test $ol_enable_modules = yes ; then
 161                 AC_MSG_WARN([slapd disabled, ignoring --enable_modules argument])
 162         fi
 163         if test $ol_enable_wrappers = yes ; then
 164                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 165         fi
 166         if test $ol_enable_phonetic = yes ; then
 167                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 168         fi
 169         if test $ol_enable_rlookups = yes ; then
 170                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 171         fi
 172         if test $ol_with_ldbm_api != auto ; then
 173                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 174         fi
 175         if test $ol_with_ldbm_type != auto ; then
 176                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 177         fi
 178         if test $ol_enable_slurpd = yes ; then
 179                 AC_MSG_ERROR([slurpd requires slapd])
 180         fi
 181
 182         # force settings to no
 183         ol_enable_bdb2=no
 184         ol_enable_ldap=no
 185         ol_enable_ldbm=no
 186         ol_enable_passwd=no
 187         ol_enable_perl=no
 188         ol_enable_shell=no
 189         ol_enable_tcl=no
 190
 191         ol_enable_aclgroups=no
 192         ol_enable_modules=no
 193         ol_enable_phonetic=no
 194         ol_enable_rlookups=no
 195         ol_enable_wrappers=no
 196
 197         ol_with_ldbm_api=no
 198         ol_with_ldbm_type=no
 199
 200         ol_enable_slurpd=no
 201
 202 elif test $ol_enable_ldbm = no ; then
 203         dnl SLAPD without LDBM
 204
 205         if test $ol_with_ldbm_api != auto ; then
 206                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 207         fi
 208
 209         if test $ol_with_ldbm_type != auto ; then
 210                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 211         fi
 212
 213         if test $ol_enable_bdb2 = yes ; then
 214                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 215         fi
 216
 217         if test $ol_enable_modules != yes -a \
 218                 $ol_enable_ldap = no -a \
 219                 $ol_enable_passwd = no -a \
 220                 $ol_enable_perl = no -a \
 221                 $ol_enable_shell = no -a \
 222                 $ol_enable_tcl = no ; then
 223                 AC_MSG_ERROR([slapd requires a backend])
 224         fi
 225
 226         ol_with_ldbm_api=no
 227         ol_with_ldbm_type=no
 228
 229 elif test $ol_enable_bdb2 = yes ; then
 230         dnl SLAPD with BDB2
 231
 232         if test $ol_with_ldbm_api != auto -a \
 233                 $ol_with_ldbm_api != db2 ; then
 234                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 235         fi
 236
 237         ol_with_ldbm_api=db2
 238
 239 else
 240         dnl SLAPD with LDBM
 241
 242         if test $ol_enable_bdb2 != no ; then
 243                 if test $ol_with_ldbm_api != auto -a \
 244                         $ol_with_ldbm_api != db2 ; then
 245                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 246                         ol_enable_bdb2=no
 247                 fi
 248         fi
 249
 250         if test $ol_with_ldbm_api = gdbm -a \
 251                 $ol_with_ldbm_type = btree ; then
 252                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 253         fi
 254         if test $ol_with_ldbm_api = mdbm -a \
 255                 $ol_with_ldbm_type = btree ; then
 256                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 257         fi
 258         if test $ol_with_ldbm_api = ndbm -a \
 259                 $ol_with_ldbm_type = btree ; then
 260                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 261         fi
 262 fi
 263
 264 if test $ol_enable_slurpd = yes ; then
 265         dnl SLURPD was specifically enabled
 266         if test $ol_with_threads = no ; then
 267                 AC_MSG_ERROR([slurpd requires threads])
 268         fi
 269 fi
 270
 271 AC_MSG_RESULT(done)
 272
 273 ## Initialize vars
 274 LDAP_LIBS=
 275 LDBM_LIBS=
 276 LTHREAD_LIBS=
 277 LUTIL_LIBS=
 278
 279 LDAPD_LIBS=
 280 SLAPD_LIBS=
 281 SLURPD_LIBS=
 282
 283 BUILD_LDAPD=no
 284 BUILD_SLAPD=no
 285 BUILD_SLURPD=no
 286
 287 BUILD_BDB2=no
 288 BUILD_LDAP=no
 289 BUILD_LDBM=no
 290 BUILD_PASSWD=no
 291 BUILD_PERL=no
 292 BUILD_SHELL=no
 293 BUILD_TCL=no
 294 BUILD_THREAD=no
 295
 296 SLAPD_MODULES_LDFLAGS=
 297 SLAPD_MODULES_CPPFLAGS=
 298
 299 SLAPD_PERL_LDFLAGS=
 300 SLAPD_PERL_CPPFLAGS=
 301
 302 KRB_LIBS=
 303 READLINE_LIBS=
 304 TERMCAP_LIBS=
 305 TLS_LIBS=
 306
 307 dnl ----------------------------------------------------------------
 308 dnl Checks for programs
 309
 310 dnl AC_PROG_INSTALL
 311
 312 dnl The default compiler is cc (NOT gcc)
 313 CC=${CC-"cc"}
 314 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 315 dnl CFLAGS=${CFLAGS-""}
 316
 317 AM_PROG_LIBTOOL
 318 dnl AC_PROG_MAKE_SET
 319
 320 AC_PROG_AWK
 321 OL_PROG_LN_H
 322 AC_PROG_LN_S
 323
 324 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 325         LN_S="$LN_H"
 326 fi
 327
 328 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 329         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 330 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 331 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 332
 333 ol_link_modules=no
 334 if test $ol_enable_modules != no ; then
 335         AC_PATH_PROG(GLIBCONFIG, glib-config)
 336
 337         if test "no$GLIBCONFIG" = "no" ; then
 338                 if test $ol_enable_modules = yes ; then
 339                         AC_MSG_ERROR([could not locate glib-config])
 340                 fi
 341
 342         else
 343                 SLAPD_MODULES_VERSION="`$GLIBCONFIG --version gmodule`"
 344                 SLAPD_MODULES_CPPFLAGS="`$GLIBCONFIG --cflags gmodule`"
 345                 SLAPD_MODULES_LDFLAGS="`$GLIBCONFIG --libs gmodule`"
 346
 347                 dnl should check glib version
 348                 ol_link_modules=yes
 349         fi
 350 fi
 351
 352 ol_link_perl=no
 353 if test $ol_enable_perl != no ; then
 354         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 355
 356         if test "no$PERLBIN" = "no" ; then
 357                 if test $ol_enable_perl = yes ; then
 358                         AC_MSG_ERROR([could not locate perl])
 359                 fi
 360
 361         else
 362                 SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 363                 SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 364
 365                 dnl should check perl version
 366                 ol_link_perl=yes
 367         fi
 368 fi
 369
 370 AC_PROG_CPP
 371
 372 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 373         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 374
 375 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 376         AC_MSG_WARN([programs compiled here do run here...])
 377         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 378
 379 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 380         AC_MSG_WARN([programs compiled here do not run here...])
 381         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 382 fi
 383
 384 dnl Checks for UNIX Variants
 385 AC_AIX
 386 AC_ISC_POSIX
 387 AC_MINIX
 388
 389 dnl BeOS requires -lbe -lroot -lnet
 390 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 391
 392 dnl Checks for system services
 393 AC_CYGWIN
 394 AC_MINGW32
 395 AC_EXEEXT
 396 AC_OBJEXT
 397
 398 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 399
 400 dnl OpenLDAP requires STDC features
 401 AM_PROG_CC_STDC
 402 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 403         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 404 fi
 405
 406 dnl AM_C_PROTOTYPES
 407
 408 dnl Checks for libraries
 409
 410 dnl Find socket()
 411 dnl Likely combinations:
 412 dnl             -lsocket [ -lnsl_s | -lnsl ]
 413 dnl             -linet
 414
 415 AC_CHECK_FUNC(socket, :, [
 416 dnl
 417 dnl hopefully we won't include too many libraries
 418 dnl
 419         AC_CHECK_LIB(socket, main)
 420         AC_CHECK_LIB(net, main)
 421         AC_CHECK_LIB(net, socket)
 422         AC_CHECK_LIB(nsl_s, main)
 423         AC_CHECK_LIB(nsl, main)
 424         AC_CHECK_LIB(inet, socket)
 425         AC_CHECK_LIB(gen, main)
 426 ])
 427
 428 dnl Check for resolver routines
 429 AC_CHECK_FUNCS(res_search)
 430 if test $ac_cv_func_res_search = "no" ; then
 431         AC_CHECK_LIB(bind, res_search)
 432         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 433                 AC_DEFINE(HAVE_RES_SEARCH,1)
 434         else
 435                 AC_CHECK_LIB(resolv, res_search)
 436                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 437                         AC_DEFINE(HAVE_RES_SEARCH,1)
 438                 fi
 439         fi
 440 fi
 441
 442 dnl HP-UX requires -lV3
 443 AC_CHECK_LIB(V3, sigset)
 444
 445 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 446
 447 dnl Select arg types
 448 dnl (if this detection becomes permenent, it and the select() detection
 449 dnl should be done before the yielding select test)
 450 AC_FUNC_SELECT_ARGTYPES
 451
 452 # ISODE tests
 453 ol_link_isode=no
 454 if test $ol_enable_ldapd != no ; then
 455         dnl look for ISODE libraries
 456         AC_CHECK_LIB(xtpp, main, [
 457                 ol_link_isode=yes
 458                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 459                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 460                 ],:,[-lxtdsap -lxtisode -losi])
 461         AC_CHECK_LIB(dsap, main, [
 462                 ol_link_isode=yes
 463                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 464                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 465                 ],:,[-lisode])
 466         AC_CHECK_LIB(isode, main, [
 467                 ol_link_isode=yes
 468                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 469                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 470                 ],:)
 471 fi
 472
 473 if test $ol_link_isode != no; then
 474         AC_CHECK_LIB(pp, main, [
 475                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 476                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 477                 ],:)
 478
 479         AC_PATH_PROG(PEPSY, pepsy)
 480 fi
 481
 482 dnl
 483 dnl check for kerberos
 484 dnl
 485 ol_link_kerberos=no
 486
 487 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 488         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 489
 490         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 491                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 492                         [-lkrb5 -ldes425])
 493
 494                 if test $have_k5 = yes ; then
 495                         ol_with_kerberos=found
 496                         ol_link_kerberos=yes
 497
 498                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 499
 500                         LIBS="$KRB_LIBS $LIBS"
 501
 502                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 503                                 [ol_cv_var_des_debug], [
 504                                 dnl save the flags
 505                                 save_LIBS="$LIBS"
 506                                 LIBS="$KRB_LIBS $LIBS"
 507                                 AC_TRY_LINK([
 508 #include <kerberosIV/krb.h>
 509 #include <kerberosIV/des.h>
 510 extern int des_debug;
 511 ],[
 512 des_debug = 1;
 513 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 514                                 dnl restore the LIBS
 515                                 LIBS="$save_LIBS"
 516                         ])
 517
 518                         if test $ol_cv_var_des_debug = yes ; then
 519                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 520                                         [define if you have Kerberos des_debug])
 521                         fi
 522
 523                         LIBS="$save_LIBS"
 524                 fi
 525         fi
 526 fi
 527
 528 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 529         AC_CHECK_HEADERS(krb.h des.h)
 530
 531         if test $ac_cv_header_krb_h = yes ; then
 532                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 533
 534                 if test $have_k4 = yes ; then
 535                         ol_with_kerberos=found
 536                         ol_link_kerberos=yes
 537
 538                         KRB_LIBS="-lkrb -ldes"
 539                 fi
 540         fi
 541 fi
 542
 543 if test $ol_link_kerberos = yes ; then
 544         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 545 fi
 546
 547 dnl
 548 dnl Check for SSL/TLS
 549 dnl
 550 ol_link_tls=no
 551 if test $ol_with_tls != no ; then
 552
 553         AC_CHECK_HEADERS(ssl.h)
 554
 555         if test $ac_cv_header_ssl_h = yes ; then
 556                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 557                         [have_ssleay=yes
 558                         need_rsaref=no],
 559                         [have_ssleay=no],
 560                         [-lcrypto])
 561
 562                 if test $have_ssleay = no ; then
 563                         AC_CHECK_LIB(ssl, ssl3_accept,
 564                                 [have_ssleay=yes
 565                                 need_rsaref=yes], [have_ssleay=no],
 566                                 [-lcrypto -lRSAglue -lrsaref])
 567                 fi
 568
 569                 if test $have_ssleay = yes ; then
 570                         ol_with_tls=found
 571                         ol_link_tls=yes
 572
 573                         AC_DEFINE(HAVE_SSLEAY, 1,
 574                                 [define if you have SSLeay or OpenSSL])
 575
 576                         if test $need_rsaref = yes; then
 577                                 AC_DEFINE(HAVE_RSAREF, 1,
 578                                         [define if you have RSAref])
 579
 580                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 581                         else
 582                                 TLS_LIBS="-lssl -lcrypto"
 583                         fi
 584                 fi
 585         fi
 586 fi
 587
 588 if test $ol_link_tls = yes ; then
 589         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 590 fi
 591
 592 dnl Tests for reentrant functions necessary to build a
 593 dnl thread_safe -lldap.
 594 AC_CHECK_FUNCS(         \
 595         ctime_r                 \
 596         gethostbyname_r gethostbyaddr_r \
 597 )
 598
 599 if test "$ac_cv_func_ctime_r" = no ; then
 600         ol_cv_func_ctime_r_nargs=0
 601 else
 602         OL_FUNC_CTIME_R_NARGS
 603 dnl     OL_FUNC_CTIME_R_TYPE
 604 fi
 605
 606 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 607         OL_FUNC_GETHOSTBYNAME_R_NARGS
 608 else
 609         ol_cv_func_gethostbyname_r_nargs=0
 610 fi
 611
 612 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 613         OL_FUNC_GETHOSTBYADDR_R_NARGS
 614 else
 615         ol_cv_func_gethostbyaddr_r_nargs=0
 616 fi
 617
 618 if test "$ac_cv_func_ctime_r" = yes \
 619         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 620         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 621         -a "$ac_cv_func_gethostbyname_r" = yes \
 622         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 623         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 624         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 625         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 626         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 627         ; then
 628
 629         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 630 fi
 631
 632 ol_link_threads=no
 633 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 634         -o $ol_with_threads = posix ; then
 635
 636         AC_CHECK_HEADERS(pthread.h sched.h)
 637
 638         if test $ac_cv_header_pthread_h = yes ; then
 639                 OL_POSIX_THREAD_VERSION
 640
 641                 if test $ol_cv_pthread_version = final ; then
 642                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 643                                 [define if pthreads API compatible with final spec])
 644                 elif test $ol_cv_pthread_version = draft4 ; then
 645                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 646                                 [define if pthreads API compatible with draft4 spec])
 647                 else
 648                         AC_MSG_ERROR([unknown pthread version])
 649                 fi
 650
 651                 # consider threads found
 652                 ol_with_threads=found
 653
 654                 OL_HEADER_LINUX_THREADS
 655
 656                 dnl Now the hard part, how to link?
 657                 dnl
 658                 dnl currently supported checks:
 659                 dnl
 660                 dnl Check for no flags
 661                 dnl     pthread_create() in $LIBS
 662                 dnl
 663                 dnl Check special pthread (final) flags
 664                 dnl     pthread_create() with -mt (Solaris)
 665                 dnl     pthread_create() with -kthread (FreeBSD)
 666                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 667                 dnl     pthread_create() with -pthreads (?)
 668                 dnl     pthread_create() with -thread (?)
 669                 dnl
 670                 dnl Check pthread (final) libraries
 671                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 672                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 673                 dnl     (skipped) pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 674                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
 675                 dnl     pthread_create() in -lpthread (many)
 676                 dnl     pthread_create() in -lc_r (FreeBSD)
 677                 dnl
 678                 dnl Check pthread (draft4) flags (depreciated)
 679                 dnl     pthread_create() with -threads (OSF/1)
 680                 dnl
 681                 dnl Check pthread (draft4) libraries (depreciated)
 682                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 683                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 684                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 685                 dnl     pthread_create() in -lpthreads (many)
 686                 dnl
 687
 688                 dnl pthread_create in $LIBS
 689                 AC_MSG_CHECKING([for pthread_create in default libraries])
 690                 AC_CACHE_VAL(ol_cv_pthread_create,[
 691                 AC_TRY_RUN([
 692 #include <pthread.h>
 693 #ifndef NULL
 694 #define NULL (void*)0
 695 #endif
 696
 697 static void *task(p)
 698         void *p;
 699 {
 700         return (void *) (p == NULL);
 701 }
 702
 703 int main(argc, argv)
 704         int argc;
 705         char **argv;
 706 {
 707         pthread_t t;
 708         int status;
 709
 710         /* make sure pthread_create() isn't just a stub */
 711 #if HAVE_PTHREADS_D4
 712         status = pthread_create(&t, pthread_attr_default, task, NULL);
 713 #else
 714         status = pthread_create(&t, NULL, task, NULL);
 715 #endif
 716
 717         if( status ) return status;
 718
 719         /* make sure pthread_detach() isn't just a stub */
 720 #if HAVE_PTHREADS_D4
 721         status = pthread_detach( &t );
 722 #else
 723         status = pthread_detach( t );
 724 #endif
 725
 726         if( status ) return status;
 727
 728         return status;
 729 }
 730 ],
 731                         [ol_cv_pthread_create=yes],
 732                         [ol_cv_pthread_create=no],
 733                         [dnl assume yes
 734                         ol_cv_pthread_create=yes])])
 735                 AC_MSG_RESULT($ol_cv_pthread_create)
 736
 737                 if test $ol_cv_pthread_create != no ; then
 738                         ol_link_threads=posix
 739                         ol_link_pthreads=""
 740                 fi
 741
 742                 OL_PTHREAD_TRY_LINK([-mt],              [ol_cv_pthread_mt])
 743                 OL_PTHREAD_TRY_LINK([-kthread], [ol_cv_pthread_kthread])
 744                 OL_PTHREAD_TRY_LINK([-pthread], [ol_cv_pthread_pthread])
 745                 OL_PTHREAD_TRY_LINK([-pthreads],[ol_cv_pthread_pthreads])
 746                 OL_PTHREAD_TRY_LINK([-thread],  [ol_cv_pthread_thread])
 747
 748                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc -lc_r],
 749                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
 750                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc],
 751                         [ol_cv_pthread_lpthread_lmach_lexc])
 752 dnl             OL_PTHREAD_TRY_LINK([-lpthread -lexc],
 753 dnl                     [ol_cv_pthread_lpthread_lexc])
 754
 755                 OL_PTHREAD_TRY_LINK([-lpthread -Wl,-woff,85],
 756                         [ol_cv_pthread_lib_lpthread_woff])
 757
 758                 OL_PTHREAD_TRY_LINK([-lpthread],[ol_cv_pthread_lpthread])
 759                 OL_PTHREAD_TRY_LINK([-lc_r],    [ol_cv_pthread_lc_r])
 760
 761                 OL_PTHREAD_TRY_LINK([-threads], [ol_cv_pthread_threads])
 762
 763                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc -lc_r],
 764                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
 765                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc],
 766                         [ol_cv_pthread_lpthreads_lmach_lexc])
 767                 OL_PTHREAD_TRY_LINK([-lpthreads -lexc],
 768                         [ol_cv_pthread_lpthreads_lexc])
 769
 770                 OL_PTHREAD_TRY_LINK([-lpthreads],       [ol_cv_pthread_lib_lpthreads])
 771
 772                 if test $ol_link_threads != no ; then
 773                         AC_DEFINE(HAVE_PTHREADS,1,
 774                                 [define if you have POSIX Threads])
 775
 776                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
 777
 778                         dnl save flags
 779                         save_CPPFLAGS="$CPPFLAGS"
 780                         save_LIBS="$LIBS"
 781                         LIBS="$LTHREAD_LIBS $LIBS"
 782
 783                         dnl All POSIX Thread (final) implementations should have
 784                         dnl sched_yield instead of pthread yield.
 785                         dnl check for both
 786                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 787
 788                         if test $ac_cv_func_sched_yield = no -a \
 789                                 $ac_cv_func_pthread_yield = no ; then
 790                                 dnl Digital UNIX has sched_yield() in -lrt
 791                                 AC_CHECK_LIB(rt, sched_yield,
 792                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 793                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 794                                         ac_cv_func_sched_yield=yes],
 795                                         [ac_cv_func_sched_yield=no])
 796                         fi
 797                         if test $ac_cv_func_sched_yield = no -a \
 798                                 $ac_cv_func_pthread_yield = no ; then
 799                                 dnl Solaris has sched_yield() stub in -lposix4
 800                                 dnl but we'll use thr_yield instead.
 801                                 AC_CHECK_FUNCS(thr_yield)
 802                         fi
 803                         if test $ac_cv_func_sched_yield = no -a \
 804                                 $ac_cv_func_pthread_yield = no -a \
 805                                 "$ac_cv_func_thr_yield" = no ; then
 806                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 807                         fi
 808
 809                         dnl Check functions for compatibility
 810                         AC_CHECK_FUNCS(pthread_kill)
 811
 812                         dnl Check for pthread_detach with <pthread.h> inclusion
 813                         dnl as it's symbol may have been mangled.
 814                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
 815                                 [ol_cv_func_pthread_detach], [
 816                                 dnl save the flags
 817                                 AC_TRY_LINK([
 818 #include <pthread.h>
 819 #ifndef NULL
 820 #define NULL (void*)0
 821 #endif
 822 ],
 823                                         [pthread_detach(NULL);],
 824                                         [ol_cv_func_pthread_detach=yes],
 825                                         [ol_cv_func_pthread_detach=no])
 826                         ])
 827
 828                         if test $ol_cv_func_pthread_detach = no ; then
 829                                 AC_MSG_ERROR([could not locate pthread_detach()])
 830                         fi
 831
 832                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
 833                                 [define if you have pthread_detach function])
 834
 835                         dnl Check for setconcurreny functions
 836                         AC_CHECK_FUNCS( \
 837                                 pthread_setconcurrency \
 838                                 pthread_getconcurrency \
 839                                 thr_setconcurrency \
 840                                 thr_getconcurrency \
 841                         )
 842
 843                         OL_SYS_LINUX_THREADS
 844                         OL_LINUX_THREADS
 845
 846                         if test $ol_cv_linux_threads = error; then
 847                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
 848                         fi
 849
 850                         AC_MSG_CHECKING([if pthread_create() works])
 851                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 852                         AC_TRY_RUN([
 853 #include <pthread.h>
 854 #ifndef NULL
 855 #define NULL (void*)0
 856 #endif
 857
 858 static void *task(p)
 859         void *p;
 860 {
 861         return (void *) (p == NULL);
 862 }
 863
 864 int main(argc, argv)
 865         int argc;
 866         char **argv;
 867 {
 868         pthread_t t;
 869 #if HAVE_PTHREADS_D4
 870         exit(pthread_create(&t, pthread_attr_default, task, NULL));
 871 #else
 872         exit(pthread_create(&t, NULL, task, NULL));
 873 #endif
 874 }
 875 ],
 876                                 [ol_cv_pthread_create_works=yes],
 877                                 [ol_cv_pthread_create_works=no],
 878                                 [dnl assume yes
 879                                 ol_cv_pthread_create_works=yes])])
 880                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 881
 882                         if test $ol_cv_pthread_create_works = no ; then
 883                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
 884                         fi
 885
 886                         dnl Check if select causes an yield
 887                         if test $ol_with_yielding_select = auto ; then
 888                                 AC_MSG_CHECKING([if select yields when using pthreads])
 889                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 890                                 AC_TRY_RUN([
 891 #include <sys/types.h>
 892 #include <sys/time.h>
 893 #include <unistd.h>
 894 #include <pthread.h>
 895 #ifndef NULL
 896 #define NULL (void*) 0
 897 #endif
 898
 899 static int fildes[2];
 900
 901 static void *task(p)
 902         void *p;
 903 {
 904         int i;
 905         struct timeval tv;
 906
 907         fd_set rfds;
 908
 909         tv.tv_sec=10;
 910         tv.tv_usec=0;
 911
 912         FD_ZERO(&rfds);
 913         FD_SET(fildes[0], &rfds);
 914
 915         /* we're not interested in any fds */
 916         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 917
 918         if(i < 0) {
 919                 perror("select");
 920                 exit(10);
 921         }
 922
 923         exit(0); /* if we exit here, the select blocked the whole process */
 924 }
 925
 926 int main(argc, argv)
 927         int argc;
 928         char **argv;
 929 {
 930         pthread_t t;
 931
 932         /* create a pipe to select */
 933         if(pipe(&fildes[0])) {
 934                 perror("select");
 935                 exit(1);
 936         }
 937
 938 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 939         (void) pthread_setconcurrency(2);
 940 #else
 941 #ifdef HAVE_THR_SETCONCURRENCY
 942         /* Set Solaris LWP concurrency to 2 */
 943         thr_setconcurrency(2);
 944 #endif
 945 #endif
 946
 947 #if HAVE_PTHREADS_D4
 948         pthread_create(&t, pthread_attr_default, task, NULL);
 949 #else
 950         pthread_create(&t, NULL, task, NULL);
 951 #endif
 952
 953 #if HAVE_SCHED_YIELD
 954         sched_yield();  /* make sure task runs first */
 955 #else
 956 #ifdef HAVE_PTHREAD_YIELD
 957         pthread_yield();        /* make sure task runs first */
 958 #endif
 959 #endif
 960
 961         exit(2);
 962 }],
 963                                 [ol_cv_pthread_select_yields=no],
 964                                 [ol_cv_pthread_select_yields=yes], [
 965                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
 966                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
 967
 968                                 if test $ol_cv_pthread_select_yields = yes ; then
 969                                         ol_with_yielding_select=yes
 970                                 fi
 971                         fi
 972
 973                         dnl restore flags
 974                         CPPFLAGS="$save_CPPFLAGS"
 975                         LIBS="$save_LIBS"
 976                 else
 977                         AC_MSG_ERROR([could not link with POSIX Threads])
 978                 fi
 979         fi
 980
 981         if test $ol_with_threads = posix ; then
 982                 AC_MSG_ERROR([could not locate POSIX Threads])
 983         fi
 984 fi
 985
 986 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 987         -o $ol_with_threads = mach ; then
 988
 989         dnl check for Mach CThreads
 990         AC_CHECK_HEADERS(mach/cthreads.h)
 991         if test $ac_cv_header_mach_cthreads_h = yes ; then
 992                 ol_with_threads=found
 993
 994                 dnl check for cthread support in current $LIBS
 995                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 996
 997                 if test $ol_link_threads = no ; then
 998                         dnl try -all_load
 999                         dnl this test needs work
1000                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1001                                 [ol_cv_cthread_all_load], [
1002                                 dnl save the flags
1003                                 save_LIBS="$LIBS"
1004                                 LIBS="-all_load $LIBS"
1005                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1006                                         cthread_fork((void *)0, (void *)0);
1007                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1008                                 dnl restore the LIBS
1009                                 LIBS="$save_LIBS"
1010                         ])
1011
1012                         if test $ol_cv_cthread_all_load = yes ; then
1013                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1014                                 ol_link_threads=mach
1015                         fi
1016                 fi
1017
1018                 if test $ol_link_threads != no ; then
1019                         : check for cthread specific functionality here
1020                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1021                                 [define if you have Mach Cthreads])
1022                 else
1023                         AC_MSG_ERROR([could not link with Mach CThreads])
1024                 fi
1025         fi
1026
1027         if test $ol_with_threads = mach ; then
1028                 AC_MSG_ERROR([could not locate Mach CThreads])
1029         fi
1030 fi
1031
1032 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1033         -o $ol_with_threads = lwp ; then
1034
1035         dnl check for SunOS5 LWP
1036         AC_CHECK_HEADERS(thread.h synch.h)
1037         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1038                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1039
1040                 if test $have_thr = yes ; then
1041                         AC_DEFINE(HAVE_THR,1,
1042                                 [if you have Solaris LWP (thr) package])
1043                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1044                         ol_link_threads=thr
1045
1046                         if test $ol_with_yielding_select = auto ; then
1047                                 ol_with_yielding_select=yes
1048                         fi
1049
1050                         dnl Check for setconcurreny functions
1051                         AC_CHECK_FUNCS( \
1052                                 thr_setconcurrency \
1053                                 thr_getconcurrency \
1054                         )
1055                 fi
1056         fi
1057
1058         dnl check for SunOS4 LWP
1059         AC_CHECK_HEADERS(lwp/lwp.h)
1060         if test $ac_cv_header_lwp_lwp_h = yes ; then
1061                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1062
1063                 if test $have_lwp = yes ; then
1064                         AC_DEFINE(HAVE_LWP,1,
1065                                 [if you have SunOS LWP package])
1066                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1067                         ol_link_threads=lwp
1068
1069                         if test $ol_with_yielding_select = auto ; then
1070                                 ol_with_yielding_select=no
1071                         fi
1072                 fi
1073         fi
1074 fi
1075
1076 if test $ol_with_yielding_select = yes ; then
1077         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1078                 [define if select implicitly yields])
1079 fi
1080
1081 if test $ol_with_threads = manual ; then
1082         dnl User thinks he can manually configure threads.
1083         ol_link_threads=yes
1084
1085         AC_MSG_WARN([thread defines and link options must be set manually])
1086
1087         AC_CHECK_HEADERS(pthread.h sched.h)
1088         AC_CHECK_FUNCS(sched_yield pthread_yield)
1089         OL_HEADER_LINUX_THREADS
1090
1091         AC_CHECK_HEADERS(mach/cthreads.h)
1092         AC_CHECK_HEADERS(lwp/lwp.h)
1093         AC_CHECK_HEADERS(thread.h synch.h)
1094 fi
1095
1096 if test $ol_link_threads != no ; then
1097         dnl needed to get reentrant/threadsafe versions
1098         dnl
1099         AC_DEFINE(REENTRANT,1)
1100         AC_DEFINE(_REENTRANT,1)
1101         AC_DEFINE(THREAD_SAFE,1)
1102         AC_DEFINE(_THREAD_SAFE,1)
1103         AC_DEFINE(THREADSAFE,1)
1104         AC_DEFINE(_THREADSAFE,1)
1105
1106         dnl The errno declaration may dependent upon _REENTRANT.
1107         dnl If it does, we must link with thread support.
1108         AC_CACHE_CHECK([for thread specific errno],
1109                 [ol_cv_errno_thread_specific], [
1110                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1111                         [ol_cv_errno_thread_specific=yes],
1112                         [ol_cv_errno_thread_specific=no])
1113         ])
1114
1115         if test $ol_cv_errno_thread_specific != yes ; then
1116                 LIBS="$LTHREAD_LIBS $LIBS"
1117                 LTHREAD_LIBS=""
1118         fi
1119
1120 dnl When in thread environment, use
1121 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1122 dnl                     || defined( HAVE_FUNC_R )
1123 dnl                     func_r(...);
1124 dnl             #else
1125 dnl             #       if defined( HAVE_THREADS )
1126 dnl                             /* lock */
1127 dnl             #       endif
1128 dnl                             func(...);
1129 dnl             #       if defined( HAVE_THREADS )
1130 dnl                             /* unlock */
1131 dnl             #       endif
1132 dnl             #endif
1133 dnl
1134 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1135 dnl             _POSIX_REENTRANT_FUNCTIONS
1136 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1137 dnl             _POSIX_THREADSAFE_FUNCTIONS
1138 dnl
1139 dnl             and is currently defined in lthread.h
1140 dnl
1141 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1142 dnl
1143 dnl libldap/*.c should only include <lthread.h> iff
1144 dnl LDAP_R_COMPILE is defined.  ie:
1145 dnl             #ifdef LDAP_R_COMPILE
1146 dnl             #       include LDAP_R_COMPILE
1147 dnl             #endif
1148 dnl
1149 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1150 dnl specifically for compiling the threadsafe version of
1151 dnl     the ldap library (-lldap_r).
1152 dnl
1153 dnl     dnl check for reentrant/threadsafe functions
1154 dnl     dnl
1155 dnl     dnl note: these should only be used when linking
1156 dnl     dnl       with $LTHREAD_LIBS
1157 dnl     dnl
1158 dnl     save_CPPFLAGS="$CPPFLAGS"
1159 dnl     save_LIBS="$LIBS"
1160 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1161 dnl     AC_CHECK_FUNCS( \
1162 dnl             gmtime_r \
1163 dnl             gethostbyaddr_r gethostbyname_r \
1164 dnl             feof_unlocked unlocked_feof \
1165 dnl             putc_unlocked unlocked_putc \
1166 dnl             flockfile ftrylockfile \
1167 dnl     )
1168 dnl     CPPFLAGS="$save_CPPFLAGS"
1169 dnl     LIBS="$save_LIBS"
1170 fi
1171
1172 if test $ol_link_threads = no ; then
1173         if test $ol_with_threads = yes ; then
1174                 AC_MSG_ERROR([no suitable thread support])
1175         fi
1176
1177         if test $ol_with_threads = auto ; then
1178                 AC_MSG_WARN([no suitable thread support, disabling threads])
1179                 ol_with_threads=no
1180         fi
1181
1182         AC_DEFINE(NO_THREADS,1,
1183                 [define if you have (or want) no threads])
1184         LTHREAD_LIBS=""
1185 fi
1186
1187 if test $ol_link_threads != no ; then
1188         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1189 fi
1190
1191 dnl ----------------------------------------------------------------
1192
1193 ol_link_ldbm=no
1194 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1195         OL_BERKELEY_DB2
1196
1197         if test $ol_cv_berkeley_db2 = yes ; then
1198                 ol_link_ldbm=db2
1199                 ol_with_ldbm_api=db2
1200
1201                 if test $ol_with_ldbm_type = hash ; then
1202                         AC_DEFINE(LDBM_USE_DBHASH,1)
1203                 else
1204                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1205                 fi
1206
1207                 dnl $ol_cv_lib_db2 should be yes or -ldb
1208                 dnl (it could be no, but that would be an error
1209                 if test $ol_cv_lib_db2 != yes ; then
1210                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1211                 fi
1212         fi
1213 fi
1214
1215 ol_link_bdb2=no
1216 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1217         ol_link_bdb2=yes
1218 fi
1219
1220 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1221         OL_BERKELEY_DB
1222
1223         if test $ol_cv_berkeley_db = yes ; then
1224                 ol_link_ldbm=db
1225                 ol_with_ldbm_api=db
1226
1227                 if test $ol_with_ldbm_type = hash ; then
1228                         AC_DEFINE(LDBM_USE_DBHASH,1)
1229                 else
1230                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1231                 fi
1232
1233                 dnl $ol_cv_lib_db should be yes or -ldb
1234                 dnl (it could be no, but that would be an error
1235                 if test $ol_cv_lib_db != yes ; then
1236                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1237                 fi
1238         fi
1239 fi
1240
1241 if test $ol_with_ldbm_api = manual ; then
1242         dnl User thinks he can manually configure LDBM api.
1243         ol_link_ldbm=yes
1244
1245         AC_MSG_WARN([LDBM defines and link options must be set manually])
1246
1247         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1248 fi
1249
1250 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1251         AC_MSG_WARN(Could not find LDBM with BTREE support)
1252         ol_with_ldbm_api=none
1253 fi
1254
1255 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1256         OL_MDBM
1257
1258         if test $ol_cv_mdbm = yes ; then
1259                 ol_link_ldbm=mdbm
1260                 ol_with_ldbm_api=mdbm
1261                 if test $ol_cv_lib_mdbm != yes ; then
1262                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1263                 fi
1264         fi
1265 fi
1266
1267 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1268         OL_GDBM
1269
1270         if test $ol_cv_gdbm = yes ; then
1271                 ol_link_ldbm=gdbm
1272                 ol_with_ldbm_api=gdbm
1273
1274                 if test $ol_cv_lib_gdbm != yes ; then
1275                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1276                 fi
1277         fi
1278 fi
1279
1280 if test $ol_with_ldbm_api = auto ; then
1281         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1282 elif test $ol_with_ldbm_api = ndbm ; then
1283         OL_NDBM
1284
1285         if test $ol_cv_ndbm = yes ; then
1286                 ol_link_ldbm=ndbm
1287                 ol_with_ldbm_api=ndbm
1288
1289                 if test $ol_cv_lib_ndbm != yes ; then
1290                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1291                 fi
1292         fi
1293 fi
1294
1295 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1296         AC_MSG_WARN(could not find suitable LDBM backend)
1297         if test $ol_enable_ldbm = yes ; then
1298                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1299         fi
1300
1301         AC_MSG_WARN(disabling LDBM)
1302         ol_enable_ldbm=no
1303 fi
1304
1305 if test $ol_enable_wrappers != no ; then
1306         AC_CHECK_HEADERS(tcpd.h)
1307
1308         if test $ac_cv_header_tcpd_h != yes ; then
1309                 have_wrappers=no
1310         else
1311                 AC_CHECK_LIB(wrap, main,
1312                         [have_wrappers=yes], [have_wrappers=no])
1313         fi
1314
1315         if test $have_wrappers = yes ; then
1316                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1317                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1318
1319                 dnl We add another check for -lnsl since some libwrap's
1320                 dnl need it, but it isn't always included from above
1321                 AC_CHECK_LIB(nsl, main)
1322         else
1323                 AC_MSG_WARN(could not find -lwrap)
1324                 if test $ol_enable_wrappers = yes ; then
1325                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1326                 fi
1327
1328                 AC_MSG_WARN(disabling wrappers support)
1329                 ol_enable_wrappers=no
1330         fi
1331 fi
1332
1333 if test $ol_enable_syslog != no ; then
1334         AC_CHECK_FUNC(openlog)
1335         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1336                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1337         fi
1338         ol_enable_syslog=$ac_cv_func_openlog
1339 fi
1340
1341 if test $ol_enable_dmalloc != no ; then
1342         AC_CHECK_HEADERS(dmalloc.h)
1343         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1344 fi
1345
1346 if test $ol_enable_tcl != no ; then
1347         AC_CHECK_HEADERS(tcl.h)
1348
1349         if test $ac_cv_header_tcl_h != yes ; then
1350                 have_tcl=no
1351         else
1352                 AC_CHECK_LIB(tcl,main,
1353                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1354                         [have_tcl=no])
1355
1356                 if test $have_tcl != yes; then
1357                         AC_CHECK_LIB(tcl7.6,main,
1358                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1359                                 [have_tcl=no])
1360                 fi
1361
1362                 if test $have_tcl != yes; then
1363                         AC_CHECK_LIB(tcl8.0,main,
1364                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1365                                 [have_tcl=no])
1366                 fi
1367         fi
1368
1369         if test $have_tcl != yes ; then
1370                 AC_MSG_WARN([could not find -ltcl])
1371                 if test $ol_enable_tcl = yes ; then
1372                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1373                 fi
1374
1375                 ol_enable_tcl=no
1376         fi
1377 fi
1378
1379 # ud needs termcap (should insert check here)
1380 ol_link_termcap=no
1381 AC_CHECK_HEADERS(termcap.h ncurses.h)
1382
1383 if test $ol_link_termcap = no ; then
1384         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1385         if test $have_termcap = yes ; then
1386                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1387                 ol_link_termcap=yes
1388                 TERMCAP_LIBS=-ltermcap
1389         fi
1390 fi
1391
1392 if test $ol_link_termcap = no ; then
1393         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1394         if test $have_ncurses = yes ; then
1395                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1396                 ol_link_termcap=yes
1397                 TERMCAP_LIBS=-lncurses
1398         fi
1399 fi
1400
1401 if test $ol_link_termcap = no ; then
1402         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1403         TERMCAP_LIBS=
1404 fi
1405
1406 dnl
1407 dnl Check for GNU readline
1408 dnl
1409 ol_link_readline=no
1410 if test $ol_with_readline != no ; then
1411         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1412
1413         if test $ac_cv_header_readline_readline_h = yes ; then
1414                 save_LIBS="$LIBS"
1415                 LIBS="$TERMCAP_LIBS $LIBS"
1416                 AC_CHECK_LIB(readline, readline,
1417                         [have_readline=yes], [have_readline=no])
1418                 LIBS="$save_LIBS"
1419
1420                 if test $have_readline = yes ; then
1421                         ol_with_readline=found
1422                         ol_link_readline=yes
1423
1424                         READLINE_LIBS="-lreadline"
1425                 fi
1426         fi
1427 fi
1428
1429 if test $ol_link_readline = yes ; then
1430         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1431 fi
1432
1433
1434 # FreeBSD (and others) have crypt(3) in -lcrypt
1435 if test $ol_enable_crypt != no ; then
1436         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1437                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1438                         have_crypt=yes], [have_crypt=no])])
1439
1440         if test $have_crypt = yes ; then
1441                 AC_DEFINE(HAVE_CRYPT,1)
1442         else
1443                 AC_MSG_WARN(could not find crypt)
1444                 if test $ol_enable_crypt = yes ; then
1445                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1446                 fi
1447
1448                 AC_MSG_WARN(disabling crypt support)
1449                 ol_enable_crypt=no
1450         fi
1451 fi
1452
1453 # FreeBSD (and others) have setproctitle(3) in -lutil
1454 if test $ol_enable_proctitle != no ; then
1455         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1456                 AC_CHECK_LIB(util, setproctitle,
1457                         [have_setproctitle=yes
1458                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1459                         [have_setproctitle=no
1460                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1461
1462         if test $have_setproctitle = yes ; then
1463                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1464         fi
1465 fi
1466
1467 dnl ----------------------------------------------------------------
1468 dnl Checks for header files.
1469 OL_HEADER_STDC
1470
1471 if test $ol_cv_header_stdc != yes; then
1472         AC_MSG_WARN([could not locate Standard C compliant headers])
1473 fi
1474
1475 AC_HEADER_DIRENT
1476 AC_HEADER_SYS_WAIT
1477 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1478 if test $am_cv_sys_posix_termios = yes ; then
1479         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1480                 [define if you have POSIX termios])
1481 fi
1482
1483 AC_CHECK_HEADERS(       \
1484         arpa/inet.h             \
1485         arpa/nameser.h  \
1486         assert.h                \
1487         crypt.h                 \
1488         errno.h                 \
1489         fcntl.h                 \
1490         filio.h                 \
1491         getopt.h                \
1492         grp.h                   \
1493         libutil.h               \
1494         limits.h                \
1495         locale.h                \
1496         malloc.h                \
1497         memory.h                \
1498         regex.h                 \
1499         psap.h                  \
1500         pwd.h                   \
1501         resolv.h                \
1502         sgtty.h                 \
1503         stdarg.h                \
1504         stddef.h                \
1505         string.h                \
1506         strings.h               \
1507         sysexits.h              \
1508         sys/file.h              \
1509         sys/filio.h             \
1510         sys/errno.h             \
1511         sys/ioctl.h             \
1512         sys/param.h             \
1513         sys/resource.h  \
1514         sys/select.h    \
1515         sys/socket.h    \
1516         sys/syslog.h    \
1517         sys/time.h              \
1518         sys/types.h             \
1519         syslog.h                \
1520         termios.h               \
1521         unistd.h                \
1522 )
1523
1524 dnl ----------------------------------------------------------------
1525 dnl Checks for typedefs, structures, and compiler characteristics.
1526 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1527 AC_TYPE_MODE_T
1528 AC_TYPE_OFF_T
1529 AC_TYPE_PID_T
1530 AM_TYPE_PTRDIFF_T
1531 AC_TYPE_SIGNAL
1532 OL_TYPE_SIG_ATOMIC_T
1533 AC_TYPE_SIZE_T
1534 AC_STRUCT_ST_BLKSIZE
1535 AC_HEADER_TIME
1536 AC_STRUCT_TM
1537 OL_STRUCT_PASSWD_PW_GECOS
1538
1539 OL_C_UPPER_LOWER
1540 AC_C_CONST
1541 OL_C_VOLATILE
1542
1543 if test $cross_compiling = yes ; then
1544         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1545 else
1546         AC_C_BIGENDIAN
1547         AC_CHECK_SIZEOF(short)
1548         AC_CHECK_SIZEOF(int)
1549         AC_CHECK_SIZEOF(long)
1550 fi
1551
1552 dnl ----------------------------------------------------------------
1553 dnl Checks for library functions.
1554 AC_FUNC_MEMCMP
1555 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1556 AC_FUNC_STRFTIME
1557 dnl AM_FUNC_STRTOD
1558
1559 dnl we should use vfork instead of fork in a number of places...
1560 dnl AC_FUNC_VFORK
1561 AC_FUNC_VPRINTF
1562
1563 if test $ac_cv_func_vprintf = yes ; then
1564         dnl check for vsnprintf
1565         AC_CHECK_FUNCS(vsnprintf vsprintf)
1566 fi
1567
1568 AC_CHECK_FUNCS(         \
1569         bcopy                   \
1570         endgrent                \
1571         endpwent                \
1572         flock                   \
1573         getdtablesize   \
1574         getgrgid                \
1575         gethostname             \
1576         getpass                 \
1577         getpwuid                \
1578         gettimeofday    \
1579         initgroups              \
1580         lockf                   \
1581         memcpy                  \
1582         memmove                 \
1583         mkstemp                 \
1584         recv                    \
1585         recvfrom                \
1586         setpwfile               \
1587         setgid                  \
1588         setegid                 \
1589         setsid                  \
1590         setuid                  \
1591         seteuid                 \
1592         signal                  \
1593         sigset                  \
1594         snprintf                \
1595         strdup                  \
1596         strerror                \
1597         strpbrk                 \
1598         strrchr                 \
1599         strsep                  \
1600         strstr                  \
1601         strtol                  \
1602         strtoul                 \
1603         strspn                  \
1604         sysconf                 \
1605         waitpid                 \
1606         wait4                   \
1607 )
1608
1609 dnl We actually may need to replace more than this.
1610 AC_REPLACE_FUNCS(getopt tempnam)
1611
1612 dnl ----------------------------------------------------------------
1613 # Check Configuration
1614 OL_SYS_ERRLIST
1615
1616 dnl ----------------------------------------------------------------
1617 dnl Sort out defines
1618
1619 if test "$ol_enable_debug" != no ; then
1620         AC_DEFINE(LDAP_DEBUG,1)
1621 fi
1622 if test "$ol_enable_syslog" = yes ; then
1623         AC_DEFINE(LDAP_SYSLOG,1)
1624 fi
1625 if test "$ol_enable_libui" = yes ; then
1626         AC_DEFINE(LDAP_LIBUI,1)
1627 fi
1628 if test "$ol_enable_cache" = no ; then
1629         AC_DEFINE(LDAP_NOCACHE,1)
1630 fi
1631 if test "$ol_enable_dns" != no ; then
1632         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1633 fi
1634 if test "$ol_enable_proctitle" != no ; then
1635         AC_DEFINE(LDAP_PROCTITLE,1)
1636 fi
1637 if test "$ol_enable_referrals" != no ; then
1638         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1639 fi
1640 if test "$ol_enable_cldap" != no ; then
1641         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1642 fi
1643
1644 if test "$ol_enable_aclgroups" != no ; then
1645         AC_DEFINE(SLAPD_ACLGROUPS,1)
1646 fi
1647 if test "$ol_enable_crypt" != no ; then
1648         AC_DEFINE(SLAPD_CRYPT,1)
1649 fi
1650 if test "$ol_enable_cleartext" != no ; then
1651         AC_DEFINE(SLAPD_CLEARTEXT,1)
1652 fi
1653 if test "$ol_enable_phonetic" != no ; then
1654         AC_DEFINE(SLAPD_PHONETIC,1)
1655 fi
1656 if test "$ol_enable_rlookups" != no ; then
1657         AC_DEFINE(SLAPD_RLOOKUPS,1)
1658 fi
1659
1660 if test "$ol_link_modules" != no ; then
1661         AC_DEFINE(SLAPD_MODULES,1)
1662         BUILD_SLAPD=yes
1663 fi
1664
1665 if test "$ol_link_bdb2" != no ; then
1666         AC_DEFINE(SLAPD_BDB2,1)
1667         BUILD_SLAPD=yes
1668         BUILD_BDB2=yes
1669 fi
1670
1671 if test "$ol_enable_ldap" != no ; then
1672         AC_DEFINE(SLAPD_LDAP,1)
1673         BUILD_SLAPD=yes
1674         BUILD_LDAP=yes
1675 fi
1676
1677 if test "$ol_link_ldbm" != no ; then
1678         AC_DEFINE(SLAPD_LDBM,1)
1679         BUILD_SLAPD=yes
1680         BUILD_LDBM=yes
1681 fi
1682
1683 if test "$ol_enable_passwd" != no ; then
1684         AC_DEFINE(SLAPD_PASSWD,1)
1685         BUILD_SLAPD=yes
1686         BUILD_PASSWD=yes
1687 fi
1688
1689 if test "$ol_link_perl" != no ; then
1690         AC_DEFINE(SLAPD_PERL,1)
1691         BUILD_SLAPD=yes
1692         BUILD_PERL=yes
1693 fi
1694
1695 if test "$ol_enable_shell" != no ; then
1696         AC_DEFINE(SLAPD_SHELL,1)
1697         BUILD_SLAPD=yes
1698         BUILD_SHELL=yes
1699 fi
1700
1701 if test "$ol_enable_tcl" != no ; then
1702         AC_DEFINE(SLAPD_TCL,1)
1703         BUILD_SLAPD=yes
1704         BUILD_TCL=yes
1705 fi
1706
1707 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1708         $BUILD_SLAPD = yes ; then
1709         BUILD_SLURPD=yes
1710 fi
1711
1712 if test "$ol_link_isode" != no ; then
1713         BUILD_LDAPD=yes
1714 fi
1715
1716 dnl ----------------------------------------------------------------
1717
1718 AC_SUBST(BUILD_LDAPD)
1719 AC_SUBST(BUILD_SLAPD)
1720   AC_SUBST(BUILD_BDB2)
1721   AC_SUBST(BUILD_LDAP)
1722   AC_SUBST(BUILD_LDBM)
1723   AC_SUBST(BUILD_PASSWD)
1724   AC_SUBST(BUILD_PERL)
1725   AC_SUBST(BUILD_SHELL)
1726   AC_SUBST(BUILD_TCL)
1727 AC_SUBST(BUILD_SLURPD)
1728
1729 AC_SUBST(LDAP_LIBS)
1730 AC_SUBST(LDAPD_LIBS)
1731 AC_SUBST(SLAPD_LIBS)
1732 AC_SUBST(SLURPD_LIBS)
1733 AC_SUBST(LDBM_LIBS)
1734 AC_SUBST(LTHREAD_LIBS)
1735 AC_SUBST(LUTIL_LIBS)
1736
1737 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
1738 AC_SUBST(SLAPD_MODULES_LDFLAGS)
1739
1740 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1741 AC_SUBST(SLAPD_PERL_LDFLAGS)
1742
1743 AC_SUBST(KRB_LIBS)
1744 AC_SUBST(READLINE_LIBS)
1745 AC_SUBST(TERMCAP_LIBS)
1746 AC_SUBST(TLS_LIBS)
1747
1748 dnl ----------------------------------------------------------------
1749 dnl final output
1750 dnl
1751
1752 AC_OUTPUT( \
1753 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1754 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1755 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1756 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1757 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1758 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1759 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1760 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1761 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1762 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1763 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1764 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1765 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1766 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1767 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1768 include/Makefile:build/top.mk:include/Makefile.in \
1769 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1770 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1771 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1772 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1773 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1774 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1775 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1776 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1777 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1778 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1779 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1780 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
1781 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/srv.mk \
1782 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1783 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1784 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
1785 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1786 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
1787 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1788 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1789 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1790 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
1791 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
1792 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
1793 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
1794 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
1795 ,[
1796 date > stamp-h
1797 echo Please \"make depend\" to build dependencies
1798 ])