git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $Id$
   2 dnl
   3 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms are permitted only
   6 dnl as authorized by the OpenLDAP Public License.  A copy of this
   7 dnl license is available at http://www.OpenLDAP.org/license.html or
   8 dnl in file LICENSE in the top-level directory of the distribution.
   9 dnl
  10
  11 dnl Disable config.cache!
  12 define([AC_CACHE_LOAD], )dnl
  13 define([AC_CACHE_SAVE], )dnl
  14
  15 dnl Configure.in for OpenLDAP
  16 AC_INIT(build/version)dnl
  17 AC_CONFIG_AUX_DIR(build)dnl
  18
  19 OL_VERSION=`cat $ac_aux_dir/version`
  20 if test -z "$OL_VERSION"; then
  21         AC_MSG_ERROR([could not determine version])
  22 fi
  23
  24 dnl ----------------------------------------------------------------
  25 dnl Determine host platform
  26 dnl             we try not to use this for much
  27 AC_CANONICAL_SYSTEM
  28
  29 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  30 AC_SUBST(PACKAGE)
  31 AC_SUBST(VERSION)
  32 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  33 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  34
  35 dnl We use autoconf features new to 2.13.
  36 dnl aclocal.m4 should be built using aclocal from automake 1.4
  37 dnl libtool 1.3.3 should be installed.
  38 AC_PREREQ(2.13)dnl Required Autoconf version
  39
  40 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  41
  42 dnl ----------------------------------------------------------------
  43 dnl Start Args
  44 AC_MSG_CHECKING(configure arguments)
  45 AC_PREFIX_DEFAULT(/usr/local)
  46
  47 top_builddir=`pwd`
  48 AC_SUBST(top_builddir)dnl
  49
  50 ldap_subdir="/openldap"
  51
  52 AC_ARG_WITH(subdir,
  53 [  --with-subdir=DIR change default subdirectory used for installs],
  54 [case "$withval" in
  55         no) ldap_subdir=""
  56                 ;;
  57         yes)
  58                 ;;
  59         /*|\\*)
  60                 ldap_subdir="$withval"
  61                 ;;
  62         *)
  63                 ldap_subdir="/$withval"
  64                 ;;
  65 esac
  66 ])dnl
  67
  68 AC_SUBST(ldap_subdir)dnl
  69
  70 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  71 dnl ol_enable_syslog=no
  72 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  73 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  74 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  75 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DX Referrals extension], no)dnl
  76 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  77 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  78 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  79         no, [yes no])dnl
  80
  81 dnl General "with" options
  82 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  83
  84 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl     with Cyrus SASL support],
  85         auto, [auto yes no] )
  86 OL_ARG_WITH(fetch,[  --with-fetch               with fetch URL support],
  87         auto, [auto yes no] )
  88 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  89         auto, [auto k5 k4 afs yes no])
  90 OL_ARG_WITH(readline,[  --with-readline with readline support],
  91         auto, [auto yes no] )
  92 OL_ARG_WITH(threads,[  --with-threads   use threads],
  93         auto, [auto posix mach pth lwp yes no manual] )
  94 OL_ARG_WITH(tls,[  --with-tls           with TLS/SSL support],
  95         auto, [auto ssleay openssl yes no] )
  96 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  97         auto, [auto yes no manual] )
  98
  99 dnl Server options
 100
 101 dnl LDAPD OPTIONS
 102 AC_ARG_WITH(xxldapdoptions,[LDAPD (X.500-to-LDAP Gateway) Options:])
 103 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
 104
 105 dnl SLAPD OPTIONS
 106 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 107 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
 108 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
 109 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
 110 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
 111 OL_ARG_ENABLE(multimaster,[    --enable-multimaster     enable multimaster replication], no)dnl
 112 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
 113 OL_ARG_ENABLE(quipu,[    --enable-quipu build quipu migration tools], no)dnl
 114 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
 115 OL_ARG_ENABLE(aci,[    --enable-aci     enable per-object ACIs], no)dnl
 116 OL_ARG_ENABLE(discreteaci,[    --enable-discreteaci     enable discrete rights in ACIs], no)dnl
 117 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
 118
 119 dnl SLAPD Backend options
 120 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 121 OL_ARG_WITH(bdb2_module,[      --with-bdb2-module       module type], static,
 122         [static dynamic])
 123 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 124 OL_ARG_WITH(ldap_module,[      --with-ldap-module       module type], static,
 125         [static dynamic])
 126 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 127 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 128         [auto db2 db mdbm gdbm ndbm manual])
 129 OL_ARG_WITH(ldbm_module,[      --with-ldbm-module       module type], static,
 130         [static dynamic])
 131 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 132         [auto btree hash])
 133
 134 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 135 OL_ARG_WITH(passwd_module,[      --with-passwd-module   module type], static,
 136         [static dynamic])
 137 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 138 OL_ARG_WITH(perl_module,[      --with-perl-module       module type], static,
 139         [static dynamic])
 140 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 141 OL_ARG_WITH(shell_module,[      --with-shell-module     module type], static,
 142         [static dynamic])
 143 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 144 OL_ARG_WITH(tcl_module,[      --with-tcl-module module type], static,
 145         [static dynamic])
 146
 147 dnl SLURPD OPTIONS
 148 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
 149 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 150
 151 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 152 AC_ENABLE_STATIC
 153 dnl AC_DISABLE_SHARED
 154 AC_ENABLE_SHARED
 155
 156 dnl General "enable" options
 157 # validate options
 158 if test $ol_enable_dns = yes ; then
 159         if test $ol_enable_referrals = no ; then
 160                 AC_MSG_ERROR([DNS requires --enable-referrals])
 161         fi
 162         if test $ol_enable_referrals = auto ; then
 163                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 164                 ol_enable_referrals=yes
 165         fi
 166 fi
 167
 168 if test $ol_enable_slapd = no ; then
 169         dnl SLAPD was specificallly disabled
 170         if test $ol_enable_bdb2 = yes ; then
 171                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 172         fi
 173         if test $ol_enable_ldap = yes ; then
 174                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 175         fi
 176         if test $ol_enable_ldbm = yes ; then
 177                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 178         fi
 179         if test $ol_enable_passwd = yes ; then
 180                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 181         fi
 182         if test $ol_enable_perl = yes ; then
 183                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 184         fi
 185         if test $ol_enable_shell = yes ; then
 186                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 187         fi
 188         if test $ol_enable_tcl = yes ; then
 189                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 190         fi
 191         if test $ol_enable_modules = yes ; then
 192                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 193         fi
 194         if test $ol_enable_multimaster = yes ; then
 195                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 196         fi
 197         if test $ol_enable_wrappers = yes ; then
 198                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 199         fi
 200         if test $ol_enable_phonetic = yes ; then
 201                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 202         fi
 203         if test $ol_enable_quipu = yes ; then
 204                 AC_MSG_WARN([slapd disabled, ignoring --enable-quipu argument])
 205         fi
 206         if test $ol_enable_rlookups = yes ; then
 207                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 208         fi
 209         if test $ol_enable_aci = yes ; then
 210                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 211         fi
 212         if test $ol_enable_discreteaci = yes ; then
 213                 AC_MSG_WARN([slapd disabled, ignoring --enable-discreteaci argument])
 214         fi
 215         if test $ol_with_ldbm_api != auto ; then
 216                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 217         fi
 218         if test $ol_with_ldbm_type != auto ; then
 219                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 220         fi
 221         if test $ol_with_bdb2_module != static ; then
 222                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb2-module argument])
 223         fi
 224         if test $ol_with_ldap_module != static ; then
 225                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 226         fi
 227         if test $ol_with_ldbm_module != static ; then
 228                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 229         fi
 230         if test $ol_with_passwd_module != static ; then
 231                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 232         fi
 233         if test $ol_with_perl_module != static ; then
 234                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 235         fi
 236         if test $ol_with_shell_module != static ; then
 237                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 238         fi
 239         if test $ol_with_tcl_module != static ; then
 240                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 241         fi
 242         if test $ol_enable_slurpd = yes ; then
 243                 AC_MSG_ERROR([slurpd requires slapd])
 244         fi
 245
 246         # force settings to no
 247         ol_enable_bdb2=no
 248         ol_enable_ldap=no
 249         ol_enable_ldbm=no
 250         ol_enable_passwd=no
 251         ol_enable_perl=no
 252         ol_enable_shell=no
 253         ol_enable_tcl=no
 254
 255         ol_enable_modules=no
 256         ol_enable_multimaster=no
 257         ol_enable_phonetic=no
 258         ol_enable_quipu=no
 259         ol_enable_rlookups=no
 260         ol_enable_aci=no
 261         ol_enable_discreteaci=no
 262         ol_enable_wrappers=no
 263
 264         ol_with_ldbm_api=no
 265         ol_with_ldbm_type=no
 266
 267         ol_with_bdb2_module=static
 268         ol_with_ldap_module=static
 269         ol_with_ldbm_module=static
 270         ol_with_passwd_module=static
 271         ol_with_perl_module=static
 272         ol_with_shell_module=static
 273         ol_with_tcl_module=static
 274
 275         ol_enable_slurpd=no
 276
 277 elif test $ol_enable_ldbm = no ; then
 278         dnl SLAPD without LDBM
 279
 280         if test $ol_with_ldbm_api != auto ; then
 281                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 282         fi
 283
 284         if test $ol_with_ldbm_type != auto ; then
 285                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 286         fi
 287
 288         if test $ol_with_ldbm_module != static ; then
 289                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 290         fi
 291
 292         if test $ol_enable_bdb2 = yes ; then
 293                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 294         fi
 295
 296         if test $ol_enable_modules != yes -a \
 297                 $ol_enable_ldap = no -a \
 298                 $ol_enable_passwd = no -a \
 299                 $ol_enable_perl = no -a \
 300                 $ol_enable_shell = no -a \
 301                 $ol_enable_tcl = no ; then
 302                 AC_MSG_ERROR([slapd requires a backend])
 303         fi
 304
 305         ol_with_ldbm_api=no
 306         ol_with_ldbm_type=no
 307         ol_with_ldbm_module=static
 308
 309 elif test $ol_enable_bdb2 = yes ; then
 310         dnl SLAPD with BDB2
 311
 312         if test $ol_with_ldbm_api != auto -a \
 313                 $ol_with_ldbm_api != db2 ; then
 314                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 315         fi
 316
 317         ol_with_ldbm_api=db2
 318
 319 else
 320         dnl SLAPD with LDBM
 321
 322         if test $ol_enable_bdb2 != no ; then
 323                 if test $ol_with_ldbm_api != auto -a \
 324                         $ol_with_ldbm_api != db2 ; then
 325                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 326                         ol_enable_bdb2=no
 327                 fi
 328         fi
 329
 330         if test $ol_with_ldbm_api = gdbm -a \
 331                 $ol_with_ldbm_type = btree ; then
 332                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 333         fi
 334         if test $ol_with_ldbm_api = mdbm -a \
 335                 $ol_with_ldbm_type = btree ; then
 336                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 337         fi
 338         if test $ol_with_ldbm_api = ndbm -a \
 339                 $ol_with_ldbm_type = btree ; then
 340                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 341         fi
 342 fi
 343
 344 if test $ol_enable_slurpd = yes ; then
 345         dnl SLURPD was specifically enabled
 346         if test $ol_with_threads = no ; then
 347                 AC_MSG_ERROR([slurpd requires threads])
 348         fi
 349 fi
 350
 351 AC_MSG_RESULT(done)
 352
 353 ## Initialize vars
 354 LDAP_LIBS=
 355 LDIF_LIBS=
 356 LDBM_LIBS=
 357 LTHREAD_LIBS=
 358 LUTIL_LIBS=
 359
 360 LDAPD_LIBS=
 361 SLAPD_LIBS=
 362 SLURPD_LIBS=
 363
 364 BUILD_LDAPD=no
 365 BUILD_SLAPD=no
 366 BUILD_SLURPD=no
 367
 368 BUILD_BDB2=no
 369 BUILD_LDAP=no
 370 BUILD_LDBM=no
 371 BUILD_PASSWD=no
 372 BUILD_PERL=no
 373 BUILD_QUIPU=no
 374 BUILD_SHELL=no
 375 BUILD_TCL=no
 376 BUILD_THREAD=no
 377
 378 BUILD_BDB2_DYNAMIC=static
 379 BUILD_LDAP_DYNAMIC=static
 380 BUILD_LDBM_DYNAMIC=static
 381 BUILD_PASSWD_DYNAMIC=static
 382 BUILD_PERL_DYNAMIC=static
 383 BUILD_SHELL_DYNAMIC=static
 384 BUILD_TCL_DYNAMIC=static
 385
 386 SLAPD_MODULES_LDFLAGS=
 387 SLAPD_MODULES_CPPFLAGS=
 388 SLAPD_MODULES_LIST=
 389
 390 SLAPD_PERL_LDFLAGS=
 391 SLAPD_PERL_CPPFLAGS=
 392
 393 KRB_LIBS=
 394 READLINE_LIBS=
 395 SASL_LIBS=
 396 TERMCAP_LIBS=
 397 TLS_LIBS=
 398 MODULES_LIBS=
 399
 400 dnl ----------------------------------------------------------------
 401 dnl Checks for programs
 402
 403 dnl AC_PROG_INSTALL
 404
 405 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 406
 407
 408 dnl
 409 dnl Determine which C translator to use
 410 dnl
 411
 412 dnl AIX Thread requires we use cc_r or xlc_r.
 413 dnl But only do this IF AIX and CC is not set
 414 dnl and threads are auto|yes|posix.
 415 dnl
 416 dnl If we find cc_r|xlc_r, force pthreads and assume
 417 dnl             pthread_create is in $LIBS (ie: don't bring in
 418 dnl             any additional thread libraries)
 419 dnl If we do not find cc_r|xlc_r, disable threads
 420
 421 ol_aix_threads=no
 422 case "$target" in
 423 *-*-aix*) dnl all AIX is not a good idea.
 424         if test -z "$CC" ; then
 425                 case "$ol_with_threads" in
 426                 auto | yes |  posix) ol_aix_threads=yes ;;
 427                 esac
 428         fi
 429 ;;
 430 esac
 431
 432 if test $ol_aix_threads = yes ; then
 433         if test -z "${CC}" ; then
 434                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 435
 436                 if test "$CC" = cc ; then
 437                         dnl no CC! don't allow --with-threads
 438                         if test $ol_with_threads != auto ; then
 439                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 440                         else
 441                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 442                         fi
 443                         ol_with_threads=no
 444                 fi
 445         fi
 446
 447         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 448                 ol_with_threads=posix
 449                 ol_cv_pthread_create=yes
 450         fi
 451 fi
 452
 453 if test -z "${CC}"; then
 454         AC_CHECK_PROGS(CC,cc)
 455 fi
 456
 457 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 458 dnl (for now, let autoconf sort this out)
 459 dnl CFLAGS=${CFLAGS-""}
 460
 461 AC_LIBTOOL_DLOPEN
 462 AC_PROG_LIBTOOL
 463 dnl AC_PROG_MAKE_SET
 464
 465 AC_PROG_AWK
 466 OL_PROG_LN_H
 467 AC_PROG_LN_S
 468
 469 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 470         LN_S="$LN_H"
 471 fi
 472
 473 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 474         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 475 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 476 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 477
 478 ol_link_perl=no
 479 if test $ol_enable_perl != no ; then
 480         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 481
 482         if test "no$PERLBIN" = "no" ; then
 483                 if test $ol_enable_perl = yes ; then
 484                         AC_MSG_ERROR([could not locate perl])
 485                 fi
 486
 487         else
 488                 SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 489                 SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 490
 491                 dnl should check perl version
 492                 ol_link_perl=yes
 493         fi
 494 fi
 495
 496 AC_PROG_CPP
 497
 498 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 499         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 500
 501 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 502         AC_MSG_WARN([programs compiled here do run here...])
 503         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 504
 505 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 506         AC_MSG_WARN([programs compiled here do not run here...])
 507         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 508 fi
 509
 510 dnl Checks for UNIX Variants
 511 AC_AIX
 512 AC_ISC_POSIX
 513 AC_MINIX
 514
 515 dnl Checks for system services
 516 AC_CYGWIN
 517 AC_MINGW32
 518 AC_EXEEXT
 519 AC_OBJEXT
 520
 521 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 522
 523 dnl BeOS requires -lbe -lroot -lnet
 524 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 525
 526 dnl OpenLDAP requires STDC features
 527 AM_PROG_CC_STDC
 528 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 529         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 530 fi
 531
 532 dnl Check cc depend flags
 533 OL_MKDEPEND
 534 if test "${ol_cv_mkdep}" = no ; then
 535         # this will soon become an error
 536         AC_MSG_WARN([do not know how to generate dependencies])
 537 fi
 538
 539 dnl
 540 dnl Check for module support
 541 dnl
 542 ol_link_modules=no
 543 if test $ol_enable_modules != no ; then
 544         AC_CHECK_HEADERS(ltdl.h)
 545
 546         if test $ac_cv_header_ltdl_h = no ; then
 547                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 548
 549         fi
 550
 551         AC_CHECK_LIB(ltdl, lt_dlinit)
 552         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 553                 AC_MSG_ERROR([could not locate libtool -lltdl])
 554         fi
 555         ol_link_modules=yes
 556 else
 557         ol_with_bdb2_module=static
 558         ol_with_ldap_module=static
 559         ol_with_ldbm_module=static
 560         ol_with_passwd_module=static
 561         ol_with_perl_module=static
 562         ol_with_shell_module=static
 563         ol_with_tcl_module=static
 564 fi
 565
 566 dnl ----------------------------------------------------------------
 567 dnl Checks for header files.
 568 OL_HEADER_STDC
 569
 570 if test $ol_cv_header_stdc != yes; then
 571         AC_MSG_WARN([could not locate Standard C compliant headers])
 572 fi
 573
 574 AC_HEADER_DIRENT
 575 AC_HEADER_SYS_WAIT
 576 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 577 if test $am_cv_sys_posix_termios = yes ; then
 578         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 579                 [define if you have POSIX termios])
 580 fi
 581
 582 AC_CHECK_HEADERS(       \
 583         arpa/inet.h             \
 584         arpa/nameser.h  \
 585         assert.h                \
 586         crypt.h                 \
 587         errno.h                 \
 588         fcntl.h                 \
 589         filio.h                 \
 590         getopt.h                \
 591         grp.h                   \
 592         libutil.h               \
 593         limits.h                \
 594         locale.h                \
 595         netinet/tcp.h   \
 596         malloc.h                \
 597         memory.h                \
 598         psap.h                  \
 599         pwd.h                   \
 600         resolv.h                \
 601         sgtty.h                 \
 602         shadow.h                \
 603         stddef.h                \
 604         string.h                \
 605         strings.h               \
 606         sysexits.h              \
 607         sys/file.h              \
 608         sys/filio.h             \
 609         sys/errno.h             \
 610         sys/ioctl.h             \
 611         sys/param.h             \
 612         sys/resource.h  \
 613         sys/select.h    \
 614         sys/socket.h    \
 615         sys/syslog.h    \
 616         sys/time.h              \
 617         sys/types.h             \
 618         syslog.h                \
 619         termios.h               \
 620         unistd.h                \
 621 )
 622
 623 dnl ----------------------------------------------------------------
 624 dnl Checks for libraries
 625
 626 dnl Find socket()
 627 dnl Likely combinations:
 628 dnl             -lsocket [ -lnsl_s | -lnsl ]
 629 dnl             -linet
 630
 631 AC_CHECK_FUNC(socket, :, [
 632 dnl
 633 dnl hopefully we won't include too many libraries
 634 dnl
 635         AC_CHECK_LIB(socket, main)
 636         AC_CHECK_LIB(net, main)
 637         AC_CHECK_LIB(net, socket)
 638         AC_CHECK_LIB(nsl_s, main)
 639         AC_CHECK_LIB(nsl, main)
 640         AC_CHECK_LIB(inet, socket)
 641         AC_CHECK_LIB(gen, main)
 642 ])
 643
 644 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 645
 646 dnl Select arg types
 647 dnl (if this detection becomes permenent, it and the select() detection
 648 dnl should be done before the yielding select test)
 649 AC_FUNC_SELECT_ARGTYPES
 650
 651
 652 AC_CHECK_HEADERS( regex.h )
 653 if test "$ac_cv_header_regex_h" != yes ; then
 654         AC_MSG_ERROR([POSIX regex.h required.])
 655 fi
 656 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 657
 658 OL_POSIX_REGEX
 659 if test "$ol_cv_c_posix_regex" = no ; then
 660         AC_MSG_ERROR([broken POSIX regex!])
 661 fi
 662
 663
 664 dnl HP-UX requires -lV3
 665 AC_CHECK_LIB(V3, sigset)
 666
 667 dnl Check for resolver routines
 668 AC_CHECK_FUNC(res_search,:)
 669 if test $ac_cv_func_res_search = no ; then
 670         AC_CHECK_LIB(bind, res_search)
 671         ac_cv_func_res_search=$ac_cv_lib_bind_res_search
 672 fi
 673
 674 if test $ac_cv_func_res_search = no ; then
 675         AC_CHECK_LIB(bind, __res_search)
 676         ac_cv_func_res_search=$ac_cv_lib_bind___res_search
 677 fi
 678
 679 if test $ac_cv_func_res_search = no ; then
 680         AC_CHECK_LIB(resolv, res_search)
 681         ac_cv_func_res_search=$ac_cv_lib_resolv_res_search
 682 fi
 683
 684 if test "$ac_cv_func_res_search" = yes ; then
 685         AC_DEFINE(HAVE_RES_SEARCH,1,
 686                 [define if you have res_search()])
 687 elif test $ol_enable_dns = yes ; then
 688         AC_MSG_ERROR([--enable-dns requires res_search])
 689 elif test $ol_enable_dns != no ; then
 690         AC_MSG_WARN([no res_search, disabling DNS support])
 691 fi
 692
 693
 694 # ISODE tests
 695 ol_link_isode=no
 696 if test $ol_enable_ldapd != no ; then
 697         AC_MSG_WARN([ldapd is not supported and may suffer from bit rot.])
 698
 699         dnl look for ISODE libraries
 700         AC_CHECK_LIB(xtpp, main, [
 701                 ol_link_isode=yes
 702                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 703                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 704                 ],:,[-lxtdsap -lxtisode -losi])
 705         AC_CHECK_LIB(dsap, main, [
 706                 ol_link_isode=yes
 707                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 708                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 709                 ],:,[-lisode])
 710         AC_CHECK_LIB(isode, main, [
 711                 ol_link_isode=yes
 712                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 713                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 714                 ],:)
 715 fi
 716
 717 if test $ol_link_isode != no; then
 718         AC_CHECK_LIB(pp, main, [
 719                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 720                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 721                 ],:)
 722
 723         AC_PATH_PROG(PEPSY, pepsy)
 724 fi
 725
 726 if test $ol_enable_quipu != no ; then
 727         AC_CHECK_HEADERS(quipu/commonarg.h)
 728
 729         if test $ac_cv_header_quipu_commonarg_h = yes ; then
 730                 BUILD_QUIPU=yes
 731         elif test $ol_enable_quipu = auto ; then
 732                 AC_MSG_WARN([no quipu for --enable-quipu=auto, disabling])
 733         else
 734                 AC_MSG_ERROR(no quipu for --enable-quipu=$ol_enable_quipu)
 735         fi
 736 fi
 737
 738 dnl
 739 dnl check for kerberos
 740 dnl
 741 ol_link_kerberos=no
 742
 743 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 744         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 745
 746         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 747                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 748                         [-lkrb5 -ldes425])
 749
 750                 if test $have_k5 = yes ; then
 751                         ol_with_kerberos=found
 752                         ol_link_kerberos=yes
 753
 754                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 755
 756                         LIBS="$KRB_LIBS $LIBS"
 757
 758                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 759                                 [ol_cv_var_des_debug], [
 760                                 dnl save the flags
 761                                 save_LIBS="$LIBS"
 762                                 LIBS="$KRB_LIBS $LIBS"
 763                                 AC_TRY_LINK([
 764 #include <kerberosIV/krb.h>
 765 #include <kerberosIV/des.h>
 766 extern int des_debug;
 767 ],[
 768 des_debug = 1;
 769 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 770                                 dnl restore the LIBS
 771                                 LIBS="$save_LIBS"
 772                         ])
 773
 774                         if test $ol_cv_var_des_debug = yes ; then
 775                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 776                                         [define if you have Kerberos des_debug])
 777                         fi
 778
 779                         LIBS="$save_LIBS"
 780                 fi
 781         fi
 782 fi
 783
 784 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 785         AC_CHECK_HEADERS(krb.h des.h)
 786
 787         if test $ac_cv_header_krb_h = yes ; then
 788                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 789
 790                 if test $have_k4 = yes ; then
 791                         ol_with_kerberos=found
 792                         ol_link_kerberos=yes
 793
 794                         KRB_LIBS="-lkrb -ldes"
 795                 fi
 796         fi
 797 fi
 798
 799 if test $ol_link_kerberos = yes ; then
 800         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 801 fi
 802
 803 dnl
 804 dnl Check for SSL/TLS
 805 dnl
 806 ol_link_tls=no
 807 if test $ol_with_tls != no ; then
 808
 809         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 810
 811         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 812                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 813                         [have_ssleay=yes
 814                         need_rsaref=no],
 815                         [have_ssleay=no],
 816                         [-lcrypto])
 817
 818                 if test $have_ssleay = no ; then
 819                         AC_CHECK_LIB(ssl, SSL_library_init,
 820                                 [have_ssleay=yes
 821                                 need_rsaref=no], [have_ssleay=no],
 822                                 [-lcrypto])
 823                 fi
 824
 825                 if test $have_ssleay = no ; then
 826                         AC_CHECK_LIB(ssl, ssl3_accept,
 827                                 [have_ssleay=yes
 828                                 need_rsaref=yes], [have_ssleay=no],
 829                                 [-lcrypto -lRSAglue -lrsaref])
 830                 fi
 831
 832                 if test $have_ssleay = yes ; then
 833                         ol_with_tls=found
 834                         ol_link_tls=yes
 835
 836                         AC_DEFINE(HAVE_SSLEAY, 1,
 837                                 [define if you have SSLeay or OpenSSL])
 838
 839                         if test $need_rsaref = yes; then
 840                                 AC_DEFINE(HAVE_RSAREF, 1,
 841                                         [define if you have RSAref])
 842
 843                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 844                         else
 845                                 TLS_LIBS="-lssl -lcrypto"
 846                         fi
 847                 fi
 848         fi
 849 fi
 850
 851 if test $ol_link_tls = yes ; then
 852         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 853 fi
 854
 855 dnl Tests for reentrant functions necessary to build a
 856 dnl thread_safe -lldap.
 857 AC_CHECK_FUNCS(         \
 858         ctime_r                 \
 859         gethostbyname_r gethostbyaddr_r \
 860 )
 861
 862 if test "$ac_cv_func_ctime_r" = no ; then
 863         ol_cv_func_ctime_r_nargs=0
 864 else
 865         OL_FUNC_CTIME_R_NARGS
 866 dnl     OL_FUNC_CTIME_R_TYPE
 867 fi
 868
 869 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 870         OL_FUNC_GETHOSTBYNAME_R_NARGS
 871 else
 872         ol_cv_func_gethostbyname_r_nargs=0
 873 fi
 874
 875 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 876         OL_FUNC_GETHOSTBYADDR_R_NARGS
 877 else
 878         ol_cv_func_gethostbyaddr_r_nargs=0
 879 fi
 880
 881 if test "$ac_cv_func_ctime_r" = yes \
 882         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 883         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 884         -a "$ac_cv_func_gethostbyname_r" = yes \
 885         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 886         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 887         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 888         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 889         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 890         ; then
 891
 892         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 893 fi
 894
 895 ol_link_threads=no
 896 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 897         -o $ol_with_threads = posix ; then
 898
 899         AC_CHECK_HEADERS(pthread.h)
 900
 901         if test $ac_cv_header_pthread_h = yes ; then
 902                 OL_POSIX_THREAD_VERSION
 903
 904                 if test $ol_cv_pthread_version = final ; then
 905                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 906                                 [define if pthreads API compatible with final spec])
 907                 elif test $ol_cv_pthread_version = draft4 ; then
 908                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 909                                 [define if pthreads API compatible with draft4 spec])
 910                 else
 911                         AC_MSG_ERROR([unknown pthread version])
 912                 fi
 913
 914                 # consider threads found
 915                 ol_with_threads=found
 916
 917                 OL_HEADER_LINUX_THREADS
 918                 OL_HEADER_GNU_PTH_PTHREAD_H
 919
 920                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
 921                         AC_CHECK_HEADERS(sched.h)
 922                 fi
 923
 924                 dnl Now the hard part, how to link?
 925                 dnl
 926                 dnl currently supported checks:
 927                 dnl
 928                 dnl Check for no flags
 929                 dnl     pthread_create() in $LIBS
 930                 dnl
 931                 dnl Check special pthread (final) flags
 932                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
 933                 dnl     pthread_create() with -kthread (FreeBSD)
 934                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 935                 dnl     pthread_create() with -pthreads (?)
 936                 dnl     pthread_create() with -mthreads (AIX)
 937                 dnl     pthread_create() with -thread (?)
 938                 dnl
 939                 dnl Check pthread (final) libraries
 940                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 941                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 942                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 943                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
 944                 dnl     pthread_create() in -lpthread (many)
 945                 dnl     pthread_create() in -lc_r (FreeBSD)
 946                 dnl
 947                 dnl Check pthread (draft4) flags (depreciated)
 948                 dnl     pthread_create() with -threads (OSF/1)
 949                 dnl
 950                 dnl Check pthread (draft4) libraries (depreciated)
 951                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 952                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 953                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 954                 dnl     pthread_create() in -lpthreads (many)
 955                 dnl
 956
 957                 dnl pthread_create in $LIBS
 958                 AC_CACHE_CHECK([for pthread_create in default libraries],
 959                         ol_cv_pthread_create,[
 960                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
 961                         [ol_cv_pthread_create=yes],
 962                         [ol_cv_pthread_create=no],
 963                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
 964                                 [ol_cv_pthread_create=yes],
 965                                 [ol_cv_pthread_create=no])])])
 966
 967                 if test $ol_cv_pthread_create != no ; then
 968                         ol_link_threads=posix
 969                         ol_link_pthreads=""
 970                 fi
 971
 972 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
 973                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
 974                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
 975                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
 976                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
 977                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
 978
 979                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
 980                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
 981                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
 982                         [ol_cv_pthread_lpthread_lmach_lexc])
 983 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
 984 dnl                     [ol_cv_pthread_lpthread_lexc])
 985
 986                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
 987                         [ol_cv_pthread_lib_lpthread_woff])
 988
 989                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
 990                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
 991
 992                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
 993
 994                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
 995                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
 996                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
 997                         [ol_cv_pthread_lpthreads_lmach_lexc])
 998                 OL_PTHREAD_TRY([-lpthreads -lexc],
 999                         [ol_cv_pthread_lpthreads_lexc])
1000
1001                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1002
1003                 if test $ol_link_threads != no ; then
1004                         AC_DEFINE(HAVE_PTHREADS,1,
1005                                 [define if you have POSIX Threads])
1006
1007                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1008
1009                         dnl save flags
1010                         save_CPPFLAGS="$CPPFLAGS"
1011                         save_LIBS="$LIBS"
1012                         LIBS="$LTHREAD_LIBS $LIBS"
1013
1014                         dnl All POSIX Thread (final) implementations should have
1015                         dnl sched_yield instead of pthread yield.
1016                         dnl check for both
1017                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1018
1019                         if test $ac_cv_func_sched_yield = no -a \
1020                                 $ac_cv_func_pthread_yield = no ; then
1021                                 dnl Digital UNIX has sched_yield() in -lrt
1022                                 AC_CHECK_LIB(rt, sched_yield,
1023                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1024                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1025                                                 [Define if you have the sched_yield function.])
1026                                         ac_cv_func_sched_yield=yes],
1027                                         [ac_cv_func_sched_yield=no])
1028                         fi
1029                         if test $ac_cv_func_sched_yield = no -a \
1030                                 $ac_cv_func_pthread_yield = no ; then
1031                                 dnl Solaris has sched_yield() stub in -lposix4
1032                                 dnl but we'll use thr_yield instead.
1033                                 AC_CHECK_FUNCS(thr_yield)
1034                         fi
1035                         if test $ac_cv_func_sched_yield = no -a \
1036                                 $ac_cv_func_pthread_yield = no -a \
1037                                 "$ac_cv_func_thr_yield" = no ; then
1038                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1039                         fi
1040
1041                         dnl Check functions for compatibility
1042                         AC_CHECK_FUNCS(pthread_kill)
1043
1044                         dnl Check for pthread_detach with <pthread.h> inclusion
1045                         dnl as it's symbol may have been mangled.
1046                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1047                                 [ol_cv_func_pthread_detach], [
1048                                 dnl save the flags
1049                                 AC_TRY_LINK([
1050 #include <pthread.h>
1051 #ifndef NULL
1052 #define NULL (void*)0
1053 #endif
1054 ],
1055                                         [pthread_detach(NULL);],
1056                                         [ol_cv_func_pthread_detach=yes],
1057                                         [ol_cv_func_pthread_detach=no])
1058                         ])
1059
1060                         if test $ol_cv_func_pthread_detach = no ; then
1061                                 AC_MSG_ERROR([could not locate pthread_detach()])
1062                         fi
1063
1064                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1065                                 [define if you have pthread_detach function])
1066
1067                         dnl Check for setconcurreny functions
1068                         AC_CHECK_FUNCS( \
1069                                 pthread_setconcurrency \
1070                                 pthread_getconcurrency \
1071                                 thr_setconcurrency \
1072                                 thr_getconcurrency \
1073                         )
1074
1075                         OL_SYS_LINUX_THREADS
1076                         OL_LINUX_THREADS
1077
1078                         if test $ol_cv_linux_threads = error; then
1079                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1080                         fi
1081
1082                         AC_CACHE_CHECK([if pthread_create() works],
1083                                 ol_cv_pthread_create_works,[
1084                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1085                                 [ol_cv_pthread_create_works=yes],
1086                                 [ol_cv_pthread_create_works=no],
1087                                 [dnl assume yes
1088                                 ol_cv_pthread_create_works=yes])])
1089
1090                         if test $ol_cv_pthread_create_works = no ; then
1091                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1092                         fi
1093
1094                         dnl Check if select causes an yield
1095                         if test $ol_with_yielding_select = auto ; then
1096                                 AC_CACHE_CHECK([if select yields when using pthreads],
1097                                         ol_cv_pthread_select_yields,[
1098                                 AC_TRY_RUN([
1099 #include <sys/types.h>
1100 #include <sys/time.h>
1101 #include <unistd.h>
1102 #include <pthread.h>
1103 #ifndef NULL
1104 #define NULL (void*) 0
1105 #endif
1106
1107 static int fildes[2];
1108
1109 static void *task(p)
1110         void *p;
1111 {
1112         int i;
1113         struct timeval tv;
1114
1115         fd_set rfds;
1116
1117         tv.tv_sec=10;
1118         tv.tv_usec=0;
1119
1120         FD_ZERO(&rfds);
1121         FD_SET(fildes[0], &rfds);
1122
1123         /* we're not interested in any fds */
1124         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1125
1126         if(i < 0) {
1127                 perror("select");
1128                 exit(10);
1129         }
1130
1131         exit(0); /* if we exit here, the select blocked the whole process */
1132 }
1133
1134 int main(argc, argv)
1135         int argc;
1136         char **argv;
1137 {
1138         pthread_t t;
1139
1140         /* create a pipe to select */
1141         if(pipe(&fildes[0])) {
1142                 perror("select");
1143                 exit(1);
1144         }
1145
1146 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1147         (void) pthread_setconcurrency(2);
1148 #else
1149 #ifdef HAVE_THR_SETCONCURRENCY
1150         /* Set Solaris LWP concurrency to 2 */
1151         thr_setconcurrency(2);
1152 #endif
1153 #endif
1154
1155 #if HAVE_PTHREADS_D4
1156         pthread_create(&t, pthread_attr_default, task, NULL);
1157 #else
1158         pthread_create(&t, NULL, task, NULL);
1159 #endif
1160
1161 #if HAVE_SCHED_YIELD
1162         sched_yield();  /* make sure task runs first */
1163 #else
1164 #ifdef HAVE_PTHREAD_YIELD
1165         pthread_yield();        /* make sure task runs first */
1166 #endif
1167 #endif
1168
1169         exit(2);
1170 }],
1171                                 [ol_cv_pthread_select_yields=no],
1172                                 [ol_cv_pthread_select_yields=yes],
1173                                 [ol_cv_pthread_select_yields=cross])])
1174
1175                                 if test $ol_cv_pthread_select_yields = cross ; then
1176                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1177                                 fi
1178
1179                                 if test $ol_cv_pthread_select_yields = yes ; then
1180                                         ol_with_yielding_select=yes
1181                                 fi
1182                         fi
1183
1184                         dnl restore flags
1185                         CPPFLAGS="$save_CPPFLAGS"
1186                         LIBS="$save_LIBS"
1187                 else
1188                         AC_MSG_ERROR([could not link with POSIX Threads])
1189                 fi
1190         fi
1191
1192         if test $ol_with_threads = posix ; then
1193                 AC_MSG_ERROR([could not locate POSIX Threads])
1194         fi
1195 fi
1196
1197 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1198         -o $ol_with_threads = mach ; then
1199
1200         dnl check for Mach CThreads
1201         AC_CHECK_HEADERS(mach/cthreads.h)
1202         if test $ac_cv_header_mach_cthreads_h = yes ; then
1203                 ol_with_threads=found
1204
1205                 dnl check for cthread support in current $LIBS
1206                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1207
1208                 if test $ol_link_threads = no ; then
1209                         dnl try -all_load
1210                         dnl this test needs work
1211                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1212                                 [ol_cv_cthread_all_load], [
1213                                 dnl save the flags
1214                                 save_LIBS="$LIBS"
1215                                 LIBS="-all_load $LIBS"
1216                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1217                                         cthread_fork((void *)0, (void *)0);
1218                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1219                                 dnl restore the LIBS
1220                                 LIBS="$save_LIBS"
1221                         ])
1222
1223                         if test $ol_cv_cthread_all_load = yes ; then
1224                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1225                                 ol_link_threads=mach
1226                         fi
1227                 fi
1228
1229                 if test $ol_link_threads != no ; then
1230                         : check for cthread specific functionality here
1231                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1232                                 [define if you have Mach Cthreads])
1233                 else
1234                         AC_MSG_ERROR([could not link with Mach CThreads])
1235                 fi
1236         fi
1237
1238         if test $ol_with_threads = mach ; then
1239                 AC_MSG_ERROR([could not locate Mach CThreads])
1240         fi
1241 fi
1242
1243 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1244         -o $ol_with_threads = pth ; then
1245
1246         AC_CHECK_HEADERS(pth.h)
1247
1248         if test $ac_cv_header_pth_h = yes ; then
1249                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1250
1251                 if test $have_pth = yes ; then
1252                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1253                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1254                         ol_link_threads=pth
1255
1256                         if test $ol_with_yielding_select = auto ; then
1257                                 ol_with_yielding_select=yes
1258                         fi
1259                 fi
1260         fi
1261 fi
1262
1263 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1264         -o $ol_with_threads = lwp ; then
1265
1266         dnl check for SunOS5 LWP
1267         AC_CHECK_HEADERS(thread.h synch.h)
1268         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1269                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1270
1271                 if test $have_thr = yes ; then
1272                         AC_DEFINE(HAVE_THR,1,
1273                                 [if you have Solaris LWP (thr) package])
1274                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1275                         ol_link_threads=thr
1276
1277                         if test $ol_with_yielding_select = auto ; then
1278                                 ol_with_yielding_select=yes
1279                         fi
1280
1281                         dnl Check for setconcurreny functions
1282                         AC_CHECK_FUNCS( \
1283                                 thr_setconcurrency \
1284                                 thr_getconcurrency \
1285                         )
1286                 fi
1287         fi
1288
1289         dnl check for SunOS4 LWP
1290         AC_CHECK_HEADERS(lwp/lwp.h)
1291         if test $ac_cv_header_lwp_lwp_h = yes ; then
1292                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1293
1294                 if test $have_lwp = yes ; then
1295                         AC_DEFINE(HAVE_LWP,1,
1296                                 [if you have SunOS LWP package])
1297                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1298                         ol_link_threads=lwp
1299
1300                         if test $ol_with_yielding_select = auto ; then
1301                                 ol_with_yielding_select=no
1302                         fi
1303                 fi
1304         fi
1305 fi
1306
1307 if test $ol_with_yielding_select = yes ; then
1308         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1309                 [define if select implicitly yields])
1310 fi
1311
1312 if test $ol_with_threads = manual ; then
1313         dnl User thinks he can manually configure threads.
1314         ol_link_threads=yes
1315
1316         AC_MSG_WARN([thread defines and link options must be set manually])
1317
1318         AC_CHECK_HEADERS(pthread.h sched.h)
1319         AC_CHECK_FUNCS(sched_yield pthread_yield)
1320         OL_HEADER_LINUX_THREADS
1321
1322         AC_CHECK_HEADERS(mach/cthreads.h)
1323         AC_CHECK_HEADERS(lwp/lwp.h)
1324         AC_CHECK_HEADERS(thread.h synch.h)
1325 fi
1326
1327 if test $ol_link_threads != no ; then
1328         dnl needed to get reentrant/threadsafe versions
1329         dnl
1330         AC_DEFINE(REENTRANT,1)
1331         AC_DEFINE(_REENTRANT,1)
1332         AC_DEFINE(THREAD_SAFE,1)
1333         AC_DEFINE(_THREAD_SAFE,1)
1334         AC_DEFINE(THREADSAFE,1)
1335         AC_DEFINE(_THREADSAFE,1)
1336         AC_DEFINE(_SGI_MP_SOURCE,1)
1337
1338         dnl The errno declaration may dependent upon _REENTRANT.
1339         dnl If it does, we must link with thread support.
1340         AC_CACHE_CHECK([for thread specific errno],
1341                 [ol_cv_errno_thread_specific], [
1342                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1343                         [ol_cv_errno_thread_specific=yes],
1344                         [ol_cv_errno_thread_specific=no])
1345         ])
1346
1347         dnl The h_errno declaration may dependent upon _REENTRANT.
1348         dnl If it does, we must link with thread support.
1349         AC_CACHE_CHECK([for thread specific h_errno],
1350                 [ol_cv_h_errno_thread_specific], [
1351                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1352                         [ol_cv_h_errno_thread_specific=yes],
1353                         [ol_cv_h_errno_thread_specific=no])
1354         ])
1355
1356         if test $ol_cv_errno_thread_specific != yes \
1357                 -o $ol_cv_h_errno_thread_specific != yes ; then
1358                 LIBS="$LTHREAD_LIBS $LIBS"
1359                 LTHREAD_LIBS=""
1360         fi
1361
1362 dnl When in thread environment, use
1363 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1364 dnl                     || defined( HAVE_FUNC_R )
1365 dnl                     func_r(...);
1366 dnl             #else
1367 dnl             #       if defined( HAVE_THREADS )
1368 dnl                             /* lock */
1369 dnl             #       endif
1370 dnl                             func(...);
1371 dnl             #       if defined( HAVE_THREADS )
1372 dnl                             /* unlock */
1373 dnl             #       endif
1374 dnl             #endif
1375 dnl
1376 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1377 dnl             _POSIX_REENTRANT_FUNCTIONS
1378 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1379 dnl             _POSIX_THREADSAFE_FUNCTIONS
1380 dnl
1381 dnl             and is currently defined in lthread.h
1382 dnl
1383 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1384 dnl
1385 dnl libldap/*.c should only include <lthread.h> iff
1386 dnl LDAP_R_COMPILE is defined.  ie:
1387 dnl             #ifdef LDAP_R_COMPILE
1388 dnl             #       include LDAP_R_COMPILE
1389 dnl             #endif
1390 dnl
1391 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1392 dnl specifically for compiling the threadsafe version of
1393 dnl     the ldap library (-lldap_r).
1394 dnl
1395 dnl     dnl check for reentrant/threadsafe functions
1396 dnl     dnl
1397 dnl     dnl note: these should only be used when linking
1398 dnl     dnl       with $LTHREAD_LIBS
1399 dnl     dnl
1400 dnl     save_CPPFLAGS="$CPPFLAGS"
1401 dnl     save_LIBS="$LIBS"
1402 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1403 dnl     AC_CHECK_FUNCS( \
1404 dnl             gmtime_r \
1405 dnl             gethostbyaddr_r gethostbyname_r \
1406 dnl             feof_unlocked unlocked_feof \
1407 dnl             putc_unlocked unlocked_putc \
1408 dnl             flockfile ftrylockfile \
1409 dnl     )
1410 dnl     CPPFLAGS="$save_CPPFLAGS"
1411 dnl     LIBS="$save_LIBS"
1412 fi
1413
1414 if test $ol_link_threads = no ; then
1415         if test $ol_with_threads = yes ; then
1416                 AC_MSG_ERROR([no suitable thread support])
1417         fi
1418
1419         if test $ol_with_threads = auto ; then
1420                 AC_MSG_WARN([no suitable thread support, disabling threads])
1421                 ol_with_threads=no
1422         fi
1423
1424         AC_DEFINE(NO_THREADS,1,
1425                 [define if you have (or want) no threads])
1426         LTHREAD_LIBS=""
1427 fi
1428
1429 if test $ol_link_threads != no ; then
1430         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1431 fi
1432
1433 dnl ----------------------------------------------------------------
1434
1435 ol_link_ldbm=no
1436 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1437         OL_BERKELEY_DB2
1438
1439         if test $ol_cv_berkeley_db2 = yes ; then
1440                 ol_link_ldbm=db2
1441                 ol_with_ldbm_api=db2
1442
1443                 if test $ol_with_ldbm_type = hash ; then
1444                         AC_DEFINE(LDBM_USE_DBHASH,1,
1445                                 [define this to use DBHASH w/ LDBM backend])
1446                 else
1447                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1448                                 [define this to use DBBTREE w/ LDBM backend])
1449                 fi
1450
1451                 dnl $ol_cv_lib_db2 should be yes or -ldb
1452                 dnl (it could be no, but that would be an error
1453                 if test $ol_cv_lib_db2 != yes ; then
1454                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1455                 fi
1456         fi
1457 fi
1458
1459 ol_link_bdb2=no
1460 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1461         ol_link_bdb2=yes
1462 fi
1463
1464 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1465         OL_BERKELEY_DB
1466
1467         if test $ol_cv_berkeley_db = yes ; then
1468                 ol_link_ldbm=db
1469                 ol_with_ldbm_api=db
1470
1471                 if test $ol_with_ldbm_type = hash ; then
1472                         AC_DEFINE(LDBM_USE_DBHASH,1,
1473                                 [define this to use DBHASH w/ LDBM backend])
1474                 else
1475                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1476                                 [define this to use DBBTREE w/ LDBM backend])
1477                 fi
1478
1479                 dnl $ol_cv_lib_db should be yes or -ldb
1480                 dnl (it could be no, but that would be an error
1481                 if test $ol_cv_lib_db != yes ; then
1482                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1483                 fi
1484         fi
1485 fi
1486
1487 if test $ol_with_ldbm_api = manual ; then
1488         dnl User thinks he can manually configure LDBM api.
1489         ol_link_ldbm=yes
1490
1491         AC_MSG_WARN([LDBM defines and link options must be set manually])
1492
1493         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1494 fi
1495
1496 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1497         AC_MSG_WARN(Could not find LDBM with BTREE support)
1498         ol_with_ldbm_api=none
1499 fi
1500
1501 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1502         OL_MDBM
1503
1504         if test $ol_cv_mdbm = yes ; then
1505                 ol_link_ldbm=mdbm
1506                 ol_with_ldbm_api=mdbm
1507                 if test $ol_cv_lib_mdbm != yes ; then
1508                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1509                 fi
1510         fi
1511 fi
1512
1513 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1514         OL_GDBM
1515
1516         if test $ol_cv_gdbm = yes ; then
1517                 ol_link_ldbm=gdbm
1518                 ol_with_ldbm_api=gdbm
1519
1520                 if test $ol_cv_lib_gdbm != yes ; then
1521                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1522                 fi
1523         fi
1524 fi
1525
1526 if test $ol_with_ldbm_api = auto ; then
1527         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1528 elif test $ol_with_ldbm_api = ndbm ; then
1529         OL_NDBM
1530
1531         if test $ol_cv_ndbm = yes ; then
1532                 ol_link_ldbm=ndbm
1533                 ol_with_ldbm_api=ndbm
1534
1535                 if test $ol_cv_lib_ndbm != yes ; then
1536                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1537                 fi
1538         fi
1539 fi
1540
1541 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1542         AC_MSG_WARN(could not find suitable LDBM backend)
1543         if test $ol_enable_ldbm = yes ; then
1544                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1545         fi
1546
1547         AC_MSG_WARN(disabling LDBM)
1548         ol_enable_ldbm=no
1549 fi
1550
1551 if test $ol_enable_wrappers != no ; then
1552         AC_CHECK_HEADERS(tcpd.h)
1553
1554         if test $ac_cv_header_tcpd_h != yes ; then
1555                 have_wrappers=no
1556         else
1557                 AC_CHECK_LIB(wrap, main,
1558                         [have_wrappers=yes], [have_wrappers=no])
1559         fi
1560
1561         if test $have_wrappers = yes ; then
1562                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1563                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1564
1565                 dnl We add another check for -lnsl since some libwrap's
1566                 dnl need it, but it isn't always included from above
1567                 AC_CHECK_LIB(nsl, main)
1568         else
1569                 AC_MSG_WARN(could not find -lwrap)
1570                 if test $ol_enable_wrappers = yes ; then
1571                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1572                 fi
1573
1574                 AC_MSG_WARN(disabling wrappers support)
1575                 ol_enable_wrappers=no
1576         fi
1577 fi
1578
1579 if test $ol_enable_syslog != no ; then
1580         AC_CHECK_FUNC(openlog)
1581         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1582                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1583         fi
1584         ol_enable_syslog=$ac_cv_func_openlog
1585 fi
1586
1587 if test $ol_enable_dmalloc != no ; then
1588         AC_CHECK_HEADERS(dmalloc.h)
1589         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1590 fi
1591
1592 if test $ol_enable_tcl != no ; then
1593         AC_CHECK_HEADERS(tcl.h)
1594
1595         if test $ac_cv_header_tcl_h != yes ; then
1596                 have_tcl=no
1597         else
1598                 AC_CHECK_LIB(tcl,main,
1599                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1600                         [have_tcl=no])
1601
1602                 if test $have_tcl != yes; then
1603                         AC_CHECK_LIB(tcl7.6,main,
1604                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1605                                 [have_tcl=no])
1606                 fi
1607
1608                 if test $have_tcl != yes; then
1609                         AC_CHECK_LIB(tcl8.0,main,
1610                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1611                                 [have_tcl=no])
1612                 fi
1613         fi
1614
1615         if test $have_tcl != yes ; then
1616                 AC_MSG_WARN([could not find -ltcl])
1617                 if test $ol_enable_tcl = yes ; then
1618                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1619                 fi
1620
1621                 ol_enable_tcl=no
1622         fi
1623 fi
1624
1625 # ud needs termcap (should insert check here)
1626 ol_link_termcap=no
1627 AC_CHECK_HEADERS(termcap.h ncurses.h)
1628
1629 if test $ol_link_termcap = no ; then
1630         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1631         if test $have_termcap = yes ; then
1632                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1633                 ol_link_termcap=yes
1634                 TERMCAP_LIBS=-ltermcap
1635         fi
1636 fi
1637
1638 if test $ol_link_termcap = no ; then
1639         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1640         if test $have_ncurses = yes ; then
1641                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1642                 ol_link_termcap=yes
1643                 TERMCAP_LIBS=-lncurses
1644         fi
1645 fi
1646
1647 if test $ol_link_termcap = no ; then
1648         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1649         TERMCAP_LIBS=
1650 fi
1651
1652 dnl
1653 dnl Check for fetch URL support
1654 dnl             should be extended to support other fetch URL APIs
1655 dnl
1656 ol_link_sasl=no
1657 if test $ol_with_cyrus_sasl != no ; then
1658         AC_CHECK_HEADER(sasl.h)
1659
1660         if test $ac_cv_header_sasl_h = yes ; then
1661                 AC_CHECK_LIB(sasl, sasl_client_init,
1662                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1663
1664                 if test $have_cyrus_sasl != no ; then
1665                         SASL_LIBS="-lsasl"
1666                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1667                         ol_link_sasl=yes
1668                 fi
1669         fi
1670
1671         if test $ol_link_sasl = no -a $ol_with_cyrus_sasl = yes ; then
1672                 AC_MSG_ERROR(no suitable API for --with-cyrus-sasl=$ol_with_cyrus_sasl)
1673         fi
1674 fi
1675
1676 dnl
1677 dnl Check for fetch URL support
1678 dnl             should be extended to support other fetch URL APIs
1679 dnl
1680 ol_link_fetch=no
1681 if test $ol_with_fetch != no ; then
1682         OL_LIB_FETCH
1683
1684         if test $ol_cv_lib_fetch != no ; then
1685                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1686                 ol_link_fetch=freebsd
1687
1688         elif test $ol_with_fetch != auto ; then
1689                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1690         fi
1691 fi
1692
1693 dnl
1694 dnl Check for GNU readline
1695 dnl
1696 ol_link_readline=no
1697 if test $ol_with_readline != no ; then
1698         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1699
1700         if test $ac_cv_header_readline_readline_h = yes ; then
1701                 save_LIBS="$LIBS"
1702                 LIBS="$TERMCAP_LIBS $LIBS"
1703                 AC_CHECK_LIB(readline, readline,
1704                         [have_readline=yes], [have_readline=no])
1705                 LIBS="$save_LIBS"
1706
1707                 if test $have_readline = yes ; then
1708                         ol_with_readline=found
1709                         ol_link_readline=yes
1710
1711                         READLINE_LIBS="-lreadline"
1712                 fi
1713         fi
1714 fi
1715
1716 if test $ol_link_readline = yes ; then
1717         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1718 fi
1719
1720
1721 # FreeBSD (and others) have crypt(3) in -lcrypt
1722 if test $ol_enable_crypt != no ; then
1723         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1724                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1725                         have_crypt=yes], [have_crypt=no])])
1726
1727         if test $have_crypt = yes ; then
1728                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1729         else
1730                 AC_MSG_WARN(could not find crypt)
1731                 if test $ol_enable_crypt = yes ; then
1732                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1733                 fi
1734
1735                 AC_MSG_WARN(disabling crypt support)
1736                 ol_enable_crypt=no
1737         fi
1738 fi
1739
1740 # FreeBSD (and others) have setproctitle(3) in -lutil
1741 if test $ol_enable_proctitle != no ; then
1742         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1743                 AC_CHECK_LIB(util, setproctitle,
1744                         [have_setproctitle=yes
1745                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1746                         [have_setproctitle=no
1747                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1748
1749         if test $have_setproctitle = yes ; then
1750                 AC_DEFINE(HAVE_SETPROCTITLE,1,
1751                         [define if setproctitle(3) is available])
1752         fi
1753 fi
1754
1755 dnl ----------------------------------------------------------------
1756 dnl Checks for typedefs, structures, and compiler characteristics.
1757 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1758 AC_TYPE_MODE_T
1759 AC_TYPE_OFF_T
1760 AC_TYPE_PID_T
1761 AM_TYPE_PTRDIFF_T
1762 AC_TYPE_SIGNAL
1763 OL_TYPE_SIG_ATOMIC_T
1764 AC_TYPE_SIZE_T
1765 OL_TYPE_SOCKLEN_T
1766 AC_STRUCT_ST_BLKSIZE
1767 AC_HEADER_TIME
1768 AC_STRUCT_TM
1769 OL_STRUCT_PASSWD_PW_GECOS
1770 OL_STRUCT_PASSWD_PW_PASSWD
1771
1772 OL_C_UPPER_LOWER
1773 AC_C_CONST
1774 OL_C_VOLATILE
1775
1776 if test $cross_compiling = yes ; then
1777         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1778
1779         AC_DEFINE(LBER_INT_T,long)
1780         AC_DEFINE(LBER_TAG_T,long)
1781         AC_DEFINE(LBER_SOCKET_T,int)
1782
1783 else
1784         AC_C_BIGENDIAN
1785         AC_CHECK_SIZEOF(short)
1786         AC_CHECK_SIZEOF(int)
1787         AC_CHECK_SIZEOF(long)
1788
1789         if test "$ac_cv_sizeof_int" -lt 4 ; then
1790                 AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
1791
1792                 AC_DEFINE(LBER_INT_T,long)
1793                 AC_DEFINE(LBER_TAG_T,long)
1794                 AC_DEFINE(LBER_SOCKET_T,int)
1795         else
1796                 AC_DEFINE(LBER_INT_T,int)
1797                 AC_DEFINE(LBER_TAG_T,long)
1798                 AC_DEFINE(LBER_SOCKET_T,int)
1799         fi
1800 fi
1801
1802 AC_DEFINE(LBER_LEN_T,long)
1803
1804 dnl ----------------------------------------------------------------
1805 dnl Checks for library functions.
1806 AC_FUNC_MEMCMP
1807 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1808 AC_FUNC_STRFTIME
1809 dnl AM_FUNC_STRTOD
1810
1811 OL_FUNC_INET_ATON
1812
1813 dnl we should use vfork instead of fork in a number of places...
1814 dnl AC_FUNC_VFORK
1815 AC_FUNC_VPRINTF
1816
1817 if test $ac_cv_func_vprintf = yes ; then
1818         dnl check for vsnprintf
1819         AC_CHECK_FUNCS(vsnprintf vsprintf)
1820 fi
1821
1822 AC_CHECK_FUNCS(         \
1823         bcopy                   \
1824         closesocket             \
1825         endgrent                \
1826         endpwent                \
1827         flock                   \
1828         getdtablesize   \
1829         getgrgid                \
1830         gethostname             \
1831         getpass                 \
1832         getpwuid                \
1833         getpwnam                \
1834         getspnam                \
1835         gettimeofday    \
1836         initgroups              \
1837         lockf                   \
1838         memcpy                  \
1839         memmove                 \
1840         mkstemp                 \
1841         read                    \
1842         recv                    \
1843         recvfrom                \
1844         setpwfile               \
1845         setgid                  \
1846         setegid                 \
1847         setsid                  \
1848         setuid                  \
1849         seteuid                 \
1850         signal                  \
1851         sigset                  \
1852         snprintf                \
1853         strdup                  \
1854         strerror                \
1855         strpbrk                 \
1856         strrchr                 \
1857         strsep                  \
1858         strstr                  \
1859         strtol                  \
1860         strtoul                 \
1861         strspn                  \
1862         sysconf                 \
1863         waitpid                 \
1864         wait4                   \
1865         write                   \
1866         send                    \
1867         sendto                  \
1868 )
1869
1870 dnl We actually may need to replace more than this.
1871 AC_REPLACE_FUNCS(getopt tempnam)
1872
1873 dnl ----------------------------------------------------------------
1874 # Check Configuration
1875 OL_SYS_ERRLIST
1876
1877 dnl ----------------------------------------------------------------
1878 dnl Sort out defines
1879
1880 if test "$ol_enable_debug" != no ; then
1881         AC_DEFINE(LDAP_DEBUG,1,
1882                 [define this to add debugging code])
1883 fi
1884 if test "$ol_enable_syslog" = yes ; then
1885         AC_DEFINE(LDAP_SYSLOG,1,
1886                 [define this to add syslog code])
1887 fi
1888 if test "$ol_enable_libui" = yes ; then
1889         AC_DEFINE(LDAP_LIBUI,1,
1890                 [define this for LDAP User Interface support])
1891 fi
1892 if test "$ol_enable_cache" = no ; then
1893         AC_DEFINE(LDAP_NOCACHE,1,
1894                 [define this to remove -lldap cache support])
1895 fi
1896 if test "$ol_enable_dns" != no ; then
1897         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1898 fi
1899 if test "$ol_enable_proctitle" != no ; then
1900         AC_DEFINE(LDAP_PROCTITLE,1,
1901                 [define this for LDAP process title support])
1902 fi
1903 if test "$ol_enable_referrals" != no ; then
1904         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1905 fi
1906 if test "$ol_enable_cldap" != no ; then
1907         AC_DEFINE(LDAP_CONNECTIONLESS,1,[define to support CLDAP])
1908 fi
1909
1910 if test "$ol_enable_crypt" != no ; then
1911         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
1912 fi
1913 if test "$ol_enable_cleartext" != no ; then
1914         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
1915 fi
1916 if test "$ol_enable_multimaster" != no ; then
1917         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
1918 fi
1919 if test "$ol_enable_phonetic" != no ; then
1920         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
1921 fi
1922 if test "$ol_enable_rlookups" != no ; then
1923         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
1924 fi
1925 if test "$ol_enable_aci" != no ; then
1926         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
1927 fi
1928 if test "$ol_enable_discreteaci" != no ; then
1929         AC_DEFINE(SLAPD_ACI_DISCRETE_RIGHTS,1,[define to support discrete rights in ACIs])
1930 fi
1931
1932 if test "$ol_link_modules" != no ; then
1933         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
1934         BUILD_SLAPD=yes
1935         MODULES_LIBS=-lltdl
1936         SLAPD_MODULES_LDFLAGS="-dlopen self"
1937 fi
1938
1939 if test "$ol_link_bdb2" != no ; then
1940         AC_DEFINE(SLAPD_BDB2,1,[define to support BDB2 backend])
1941         BUILD_SLAPD=yes
1942         BUILD_BDB2=yes
1943         if test "$ol_with_bdb2_module" != static ; then
1944                 AC_DEFINE(SLAPD_BDB2_DYNAMIC,1,
1945                         [define to support dynamic BDB2 backend])
1946                 BUILD_BDB2=mod
1947                 BUILD_BDB2_DYNAMIC=shared
1948                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-bdb2/back_bdb2.la"
1949         fi
1950 fi
1951
1952 if test "$ol_enable_ldap" != no ; then
1953         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
1954         BUILD_SLAPD=yes
1955         BUILD_LDAP=yes
1956         if test "$ol_with_ldap_module" != static ; then
1957                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
1958                         [define to support dynamic LDAP backend])
1959                 BUILD_LDAP=mod
1960                 BUILD_LDAP_DYNAMIC=shared
1961                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
1962         fi
1963 fi
1964
1965 if test "$ol_link_ldbm" != no ; then
1966         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
1967         BUILD_SLAPD=yes
1968         BUILD_LDBM=yes
1969         if test "$ol_with_ldbm_module" != static ; then
1970                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
1971                         [define to support dynamic LDBM backend])
1972                 BUILD_LDBM=mod
1973                 BUILD_LDBM_DYNAMIC=shared
1974                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
1975         fi
1976 fi
1977
1978 if test "$ol_enable_passwd" != no ; then
1979         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
1980         BUILD_SLAPD=yes
1981         BUILD_PASSWD=yes
1982         if test "$ol_with_passwd_module" != static ; then
1983                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
1984                         [define to support dynamic PASSWD backend])
1985                 BUILD_PASSWD=mod
1986                 BUILD_PASSWD_DYNAMIC=shared
1987                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
1988         fi
1989 fi
1990
1991 if test "$ol_link_perl" != no ; then
1992         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
1993         BUILD_SLAPD=yes
1994         BUILD_PERL=yes
1995         if test "$ol_with_perl_module" != static ; then
1996                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
1997                         [define to support dynamic PERL backend])
1998                 BUILD_PERL=mod
1999                 BUILD_PERL_DYNAMIC=shared
2000                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-perl/back_perl.la"
2001         fi
2002 fi
2003
2004 if test "$ol_enable_shell" != no ; then
2005         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2006         BUILD_SLAPD=yes
2007         BUILD_SHELL=yes
2008         if test "$ol_with_shell_module" != static ; then
2009                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2010                         [define to support dynamic SHELL backend])
2011                 BUILD_SHELL=mod
2012                 BUILD_SHELL_DYNAMIC=shared
2013                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2014         fi
2015 fi
2016
2017 if test "$ol_enable_tcl" != no ; then
2018         AC_DEFINE(SLAPD_TCL,1,[define to support TCL backend])
2019         BUILD_SLAPD=yes
2020         BUILD_TCL=yes
2021         if test "$ol_with_tcl_module" != static; then
2022                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1,
2023                         [define to support dynamic TCL backend])
2024                 BUILD_TCL=mod
2025                 BUILD_TCL_DYNAMIC=shared
2026                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-tcl/back_tcl.la"
2027         fi
2028 fi
2029
2030 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2031         $BUILD_SLAPD = yes ; then
2032         BUILD_SLURPD=yes
2033 fi
2034
2035 if test "$ol_link_isode" != no ; then
2036         BUILD_LDAPD=yes
2037 fi
2038
2039 dnl ----------------------------------------------------------------
2040
2041 AC_SUBST(BUILD_LDAPD)
2042 AC_SUBST(BUILD_SLAPD)
2043   AC_SUBST(BUILD_BDB2)
2044   AC_SUBST(BUILD_LDAP)
2045   AC_SUBST(BUILD_LDBM)
2046   AC_SUBST(BUILD_PASSWD)
2047   AC_SUBST(BUILD_PERL)
2048   AC_SUBST(BUILD_QUIPU)
2049   AC_SUBST(BUILD_SHELL)
2050   AC_SUBST(BUILD_TCL)
2051   AC_SUBST(BUILD_BDB2_DYNAMIC)
2052   AC_SUBST(BUILD_LDAP_DYNAMIC)
2053   AC_SUBST(BUILD_LDBM_DYNAMIC)
2054   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2055   AC_SUBST(BUILD_PERL_DYNAMIC)
2056   AC_SUBST(BUILD_SHELL_DYNAMIC)
2057   AC_SUBST(BUILD_TCL_DYNAMIC)
2058 AC_SUBST(BUILD_SLURPD)
2059
2060 AC_SUBST(LDAP_LIBS)
2061 AC_SUBST(LDAPD_LIBS)
2062 AC_SUBST(LDIF_LIBS)
2063 AC_SUBST(SLAPD_LIBS)
2064 AC_SUBST(SLURPD_LIBS)
2065 AC_SUBST(LDBM_LIBS)
2066 AC_SUBST(LTHREAD_LIBS)
2067 AC_SUBST(LUTIL_LIBS)
2068
2069 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2070 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2071 AC_SUBST(SLAPD_MODULES_LIST)
2072
2073 AC_SUBST(SLAPD_PERL_CPPFLAGS)
2074 AC_SUBST(SLAPD_PERL_LDFLAGS)
2075
2076 AC_SUBST(KRB_LIBS)
2077 AC_SUBST(READLINE_LIBS)
2078 AC_SUBST(SASL_LIBS)
2079 AC_SUBST(TERMCAP_LIBS)
2080 AC_SUBST(TLS_LIBS)
2081 AC_SUBST(MODULES_LIBS)
2082
2083 dnl ----------------------------------------------------------------
2084 dnl final output
2085 dnl
2086
2087 AC_OUTPUT( \
2088 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2089 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2090 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2091 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2092 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2093 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2094 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2095 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2096 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2097 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2098 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2099 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2100 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2101 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2102 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2103 include/Makefile:build/top.mk:include/Makefile.in \
2104 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2105 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2106 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2107 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2108 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2109 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2110 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2111 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2112 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2113 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
2114 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2115 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/mod.mk \
2116 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2117 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2118 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2119 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk \
2120 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2121 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/mod.mk \
2122 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2123 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2124 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2125 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2126 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2127 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2128 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2129 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2130 ,[
2131 date > stamp-h
2132 echo Please \"make depend\" to build dependencies
2133 ])