git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8
   9 dnl Configure.in for OpenLDAP
  10 AC_INIT(include/ldap.h)dnl
  11 AC_CONFIG_AUX_DIR(build)dnl
  12 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no ac_define])dnl
  13
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_PREREQ(2.10)dnl Required Autoconf version
  18
  19 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  20
  21 dnl
  22 dnl Start Args
  23 AC_MSG_CHECKING(configure arguments)
  24 AC_PREFIX_DEFAULT(/usr/local)
  25
  26 top_builddir=`pwd`
  27 AC_SUBST(top_builddir)dnl
  28
  29 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  30 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  31 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  32 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  33 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  34 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  35 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  36 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  37 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  38         no, [yes no])dnl
  39
  40 dnl General "with" options
  41 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  42         auto, [auto k5 k4 afs yes no])
  43 OL_ARG_WITH(threads,[  --with-threads   use threads],
  44         auto, [auto posix mach lwp yes no manual] )
  45 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  46         auto, [auto yes no manual] )
  47
  48 dnl Server options
  49
  50 dnl LDAPD OPTIONS
  51 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  52 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  53
  54 dnl SLAPD OPTIONS
  55 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  56 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  57 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  58 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  59 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  60 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  61 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  62 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  63 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  64
  65 dnl SLAPD Backend options
  66 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  67 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  68         [auto db2 db gdbm ndbm manual])
  69 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  70         [auto btree hash])
  71
  72 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  73 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  74
  75 dnl SLURPD OPTIONS
  76 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  77 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  78
  79 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
  80 AM_ENABLE_STATIC
  81 dnl AM_DISABLE_SHARED
  82 AM_ENABLE_SHARED
  83
  84 dnl General "enable" options
  85 # validate options
  86 if test $ol_enable_referrals = no ; then
  87         if test $ol_enable_dns = yes ; then
  88                 AC_MSG_WARN([dns disabled, ignoring --enable-dns argument])
  89         fi
  90         ol_enable_dns=no
  91 fi
  92
  93 if test $ol_enable_slapd = no ; then
  94         dnl SLAPD was specificallly disabled
  95         if test $ol_enable_ldbm = yes ; then
  96                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
  97         fi
  98         if test $ol_enable_passwd = yes ; then
  99                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 100         fi
 101         if test $ol_enable_shell = yes ; then
 102                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 103         fi
 104         if test $ol_enable_aclgroups = yes ; then
 105                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 106         fi
 107         if test $ol_enable_crypt = yes ; then
 108                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument])
 109         fi
 110         if test $ol_enable_md5 = yes ; then
 111                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument])
 112         fi
 113         if test $ol_enable_sha1 = yes ; then
 114                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument])
 115         fi
 116         if test $ol_enable_wrappers = yes ; then
 117                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 118         fi
 119         if test $ol_enable_phonetic = yes ; then
 120                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 121         fi
 122         if test $ol_enable_rlookups = yes ; then
 123                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 124         fi
 125         if test $ol_with_ldbm_api != auto ; then
 126                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 127         fi
 128         if test $ol_with_ldbm_type != auto ; then
 129                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 130         fi
 131         if test $ol_enable_slurpd = yes ; then
 132                 AC_MSG_ERROR([slurpd requires slapd])
 133         fi
 134
 135         # force settings to no
 136         ol_enable_ldbm=no
 137         ol_enable_shell=no
 138         ol_enable_passwd=no
 139         ol_enable_aclgroups=no
 140         ol_enable_crypt=no
 141         ol_enable_md5=no
 142         ol_enable_sha1=no
 143         ol_enable_wrappers=no
 144         ol_enable_phonetic=no
 145         ol_enable_rlookups=no
 146         ol_with_ldbm_api=no
 147         ol_with_ldbm_type=no
 148         ol_enable_slurpd=no
 149
 150 elif test $ol_enable_ldbm = no ; then
 151         dnl SLAPD without LDBM
 152
 153         if test $ol_with_ldbm_api != auto ; then
 154                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 155         fi
 156
 157         if test $ol_with_ldbm_type != auto ; then
 158                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 159         fi
 160
 161         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 162                 AC_MSG_ERROR([slapd requires a backend])
 163         fi
 164
 165         ol_with_ldbm_api=no
 166         ol_with_ldbm_type=no
 167
 168 else
 169         dnl SLAPD with LDBM
 170
 171         if test $ol_with_ldbm_api = gdbm -a \
 172                 $ol_with_ldbm_type = btree ; then
 173                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 174         fi
 175         if test $ol_with_ldbm_api = ndbm -a \
 176                 $ol_with_ldbm_type = btree ; then
 177                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 178         fi
 179 fi
 180
 181 if test $ol_enable_slurpd = yes ; then
 182         dnl SLURPD was specifically enabled
 183         if test $ol_with_threads = no ; then
 184                 AC_MSG_ERROR([slurpd requires threads])
 185         fi
 186 fi
 187
 188 AC_MSG_RESULT(done)
 189
 190 AC_CANONICAL_HOST
 191
 192 ## Initialize vars
 193 LDAP_LIBS=
 194 LDBM_LIBS=
 195 LTHREAD_LIBS=
 196 LUTIL_LIBS=
 197
 198 LDAPD_LIBS=
 199 SLAPD_LIBS=
 200 SLURPD_LIBS=
 201
 202 BUILD_LDAPD=no
 203 BUILD_SLAPD=no
 204 BUILD_SLURPD=no
 205
 206 BUILD_LDBM=no
 207 BUILD_PASSWD=no
 208 BUILD_SHELL=no
 209 BUILD_THREAD=no
 210
 211 KRB_LIBS=
 212 TERMCAP_LIBS=
 213
 214 dnl ----------------------------------------------------------------
 215 dnl Checks for programs
 216
 217 AC_PROG_INSTALL
 218 AM_PROG_LIBTOOL
 219 dnl AC_PROG_MAKE_SET
 220
 221 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 222         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 223 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 224 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 225
 226 dnl Checks the compiler and UNIX Variants
 227
 228 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 229         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 230
 231 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 232         AC_MSG_WARN([programs compiled here do run here...])
 233         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 234
 235 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 236         AC_MSG_WARN([programs compiled here do not run here...])
 237         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 238 fi
 239
 240 AC_PROG_CPP
 241
 242 AC_AIX
 243 AC_ISC_POSIX
 244 AC_MINIX
 245
 246 dnl OpenLDAP requires STDC features
 247 AM_PROG_CC_STDC
 248 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 249         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 250 fi
 251
 252 dnl AM_C_PROTOTYPES
 253
 254 dnl Checks for libraries
 255
 256 dnl Find socket()
 257 dnl Likely combinations:
 258 dnl             -lsocket [ -lnsl_s | -lnsl ]
 259 dnl             -linet
 260
 261 AC_CHECK_FUNC(socket, [have_socket=yes], [
 262 dnl
 263 dnl hopefully we won't include too many libraries
 264 dnl
 265         AC_CHECK_LIB(socket, main)
 266         AC_CHECK_LIB(net, main)
 267         AC_CHECK_LIB(nsl_s, main)
 268         AC_CHECK_LIB(nsl, main)
 269         AC_CHECK_LIB(inet, socket)
 270         AC_CHECK_LIB(gen, main)
 271 ])
 272
 273 dnl Check for resolv
 274 AC_CHECK_LIB(resolv, res_search)
 275
 276 dnl HP-UX requires -lV3
 277 AC_CHECK_LIB(V3, sigset)
 278
 279 # ISODE tests
 280 ol_link_isode=no
 281 if test $ol_enable_ldapd != no ; then
 282         dnl look for ISODE libraries
 283         AC_CHECK_LIB(xtpp, main, [
 284                 ol_link_isode=yes
 285                 AC_DEFINE(HAVE_XTPP,1)
 286                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 287                 ],:,[-lxtdsap -lxtisode -losi])
 288         AC_CHECK_LIB(dsap, main, [
 289                 ol_link_isode=yes
 290                 AC_DEFINE(HAVE_DSAP,1)
 291                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 292                 ],:,[-lisode])
 293         AC_CHECK_LIB(isode, main, [
 294                 ol_link_isode=yes
 295                 AC_DEFINE(HAVE_ISODE,1)
 296                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 297                 ],:)
 298 fi
 299
 300 if test $ol_link_isode != no; then
 301         AC_CHECK_LIB(pp, main, [
 302                 AC_DEFINE(HAVE_PP,1)
 303                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 304                 ],:)
 305
 306         AC_PATH_PROG(PEPSY, pepsy)
 307 fi
 308
 309 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 310         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 311
 312         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 313                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 314                         [-lkrb5 -ldes425])
 315
 316                 if test $have_k5 = yes ; then
 317                         ol_with_kerberos=found
 318                         ol_link_kerberos=yes
 319
 320                         AC_DEFINE(HAVE_KERBEROS)
 321
 322                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 323                 fi
 324         fi
 325 fi
 326 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 327         AC_CHECK_HEADERS(krb.h des.h)
 328
 329         if test $ac_cv_header_krb_h = yes ; then
 330                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 331
 332                 if test $have_k4 = yes ; then
 333                         ol_with_kerberos=found
 334                         ol_link_kerberos=yes
 335
 336                         AC_DEFINE(HAVE_KERBEROS)
 337
 338                         KRB_LIBS="-lkrb -ldes"
 339                 fi
 340         fi
 341 fi
 342
 343 ol_link_threads=no
 344 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 345         AC_CHECK_HEADERS(pthread.h sched.h)
 346
 347         if test $ac_cv_header_pthread_h = yes ; then
 348                 OL_POSIX_THREAD_VERSION
 349
 350                 if test $ol_cv_pthread_version = final ; then
 351                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 352                 elif test $ol_cv_pthread_version = draft4 ; then
 353                         AC_DEFINE(HAVE_PTHREADS_D4)
 354                 else
 355                         AC_MSG_ERROR([unknown pthread version])
 356                 fi
 357
 358                 # consider threads found
 359                 ol_with_threads=found
 360
 361                 OL_LINUX_THREADS
 362
 363                 if test $ol_cv_linux_threads = yes ; then
 364                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 365                 fi
 366
 367                 dnl Now the hard part, how to link
 368
 369                 dnl Check for pthread support in current $LIBS
 370                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 371
 372                 if test $ol_link_threads = no ; then
 373                         dnl try -pthread
 374                         AC_CACHE_CHECK([for pthread_create with -pthread],
 375                                 [ol_cv_pthread_flag], [
 376                                 dnl save the flags
 377                                 save_LIBS="$LIBS"
 378                                 LIBS="-pthread $LIBS"
 379                                 AC_TRY_LINK([char pthread();],[
 380                                         pthread_create();
 381                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 382                                 dnl restore the LIBS
 383                                 LIBS="$save_LIBS"
 384                         ])
 385
 386                         if test $ol_cv_pthread_flag = yes ; then
 387                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 388                                 ol_link_threads=posix
 389                         fi
 390                 fi
 391
 392                 if test $ol_link_threads = no ; then
 393                         dnl try -thread
 394                         AC_CACHE_CHECK([for pthread_create with -thread],
 395                                 [ol_cv_thread_flag], [
 396                                 dnl save the flags
 397                                 save_LIBS="$LIBS"
 398                                 LIBS="-thread $LIBS"
 399                                 AC_TRY_LINK([char pthread();],[
 400                                         pthread_create();
 401                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 402                                 dnl restore the LIBS
 403                                 LIBS="$save_LIBS"
 404                         ])
 405
 406                         if test $ol_cv_thread_flag = yes ; then
 407                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 408                                 ol_link_threads=posix
 409                         fi
 410                 fi
 411
 412                 if test $ol_link_threads = no ; then
 413                         dnl try DEC Threads -lpthread -lexc
 414                         save_LIBS="$LIBS"
 415                         AC_CHECK_LIB(pthread, pthread_join, [
 416                                 ol_link_threads=posix
 417                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 418                                 if test $ol_with_yielding_select = auto ; then
 419                                         ol_with_yielding_select=yes
 420                                 fi
 421                                 ],,[-lexc])
 422                         LIBS="$save_LIBS"
 423                 fi
 424
 425                 if test $ol_link_threads = no ; then
 426                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 427                         save_LIBS="$LIBS"
 428                         AC_CHECK_LIB(pthreads, pthread_join, [
 429                                 ol_link_threads=posix
 430                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 431                                 if test $ol_with_yielding_select = auto ; then
 432                                         ol_with_yielding_select=yes
 433                                 fi
 434                                 ],,[-lmach -lexc -lc_r])
 435                         LIBS="$save_LIBS"
 436                 fi
 437
 438                 if test $ol_link_threads = no ; then
 439                         dnl try -lpthread
 440                         save_LIBS="$LIBS"
 441                         AC_CHECK_LIB(pthread, pthread_create, [
 442                                 ol_link_threads=posix
 443                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 444                         LIBS="$save_LIBS"
 445                 fi
 446
 447                 if test $ol_link_threads = no ; then
 448                         dnl try -lc_r
 449                         save_LIBS="$LIBS"
 450                         AC_CHECK_LIB(c_r, pthread_create, [
 451                                 ol_link_threads=posix
 452                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 453                         LIBS="$save_LIBS"
 454                 fi
 455
 456                 if test $ol_link_threads != no ; then
 457                         AC_DEFINE(HAVE_PTHREADS)
 458
 459                         dnl save flags
 460                         save_CPPFLAGS="$CPPFLAGS"
 461                         save_LIBS="$LIBS"
 462                         LIBS="$LTHREAD_LIBS $LIBS"
 463
 464                         dnl All POSIX Thread (final) implementations should have
 465                         dnl sched_yield instead of pthread yield.
 466                         dnl check for both
 467                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 468
 469                         if test $ac_cv_func_sched_yield = no -a \
 470                                 $ac_cv_func_pthread_yield = no ; then
 471                                 dnl Digital UNIX has sched_yield() in -lrt
 472                                 AC_CHECK_LIB(rt, sched_yield,
 473                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 474                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 475                                         ac_cv_func_sched_yield=yes],
 476                                         [ac_cv_func_sched_yield=no])
 477                         fi
 478                         if test $ac_cv_func_sched_yield = no -a \
 479                                 $ac_cv_func_pthread_yield = no ; then
 480                                 dnl Solaris has sched_yield() in -lposix4
 481                                 AC_CHECK_LIB(posix4, sched_yield,
 482                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 483                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 484                                         ac_cv_func_sched_yield=yes],
 485                                         [ac_cv_func_sched_yield=no])
 486                         fi
 487                         if test $ac_cv_func_sched_yield = no -a \
 488                                 $ac_cv_func_pthread_yield = no ; then
 489                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 490                                 AC_MSG_ERROR([POSIX Threads are not usable])
 491                         fi
 492
 493                         dnl Check functions for compatibility
 494                         AC_CHECK_FUNCS(pthread_kill)
 495                         AC_CHECK_FUNCS( \
 496                                 pthread_attr_create pthread_attr_init \
 497                                 pthread_attr_destroy pthread_attr_delete \
 498                                 pthread_attr_setdetachstate pthread_attr_setdetach_np \
 499                         )
 500
 501                         dnl Check for setconcurreny functions
 502                         AC_CHECK_FUNCS( \
 503                                 pthread_setconcurrency \
 504                                 thr_setconcurrency \
 505                         )
 506
 507                         dnl Check if select causes an yield
 508                         if test $ol_with_yielding_select = auto ; then
 509                                 AC_MSG_CHECKING([if select yields])
 510                                 AC_TRY_RUN([
 511 #include <sys/types.h>
 512 #include <sys/time.h>
 513 #include <unistd.h>
 514 #include <pthread.h>
 515 #ifndef NULL
 516 #define NULL 0
 517 #endif
 518
 519 int fildes[2];
 520
 521 int task(arg)
 522         int *arg;
 523 {
 524         int i;
 525         struct timeval tv;
 526
 527         fd_set rfds;
 528
 529         tv.tv_sec=10;
 530         tv.tv_usec=0;
 531
 532         FD_ZERO(&rfds);
 533         FD_SET(fildes[0], &rfds);
 534
 535         /* we're not interested in any fds */
 536         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 537
 538         if(i < 0) {
 539                 perror("select");
 540                 exit(0);
 541         }
 542
 543         exit(1); /* if we exit here, the select blocked the whole process */
 544 }
 545
 546 int main(argc, argv)
 547         int argc;
 548         char **argv;
 549 {
 550         pthread_t t;
 551
 552         /* create a pipe to select */
 553         if(pipe(&fildes[0])) {
 554                 perror("select");
 555                 exit(0);
 556         }
 557
 558 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 559         (void) pthread_setconcurrency(2);
 560 #else
 561 #ifdef HAVE_THR_SETCONCURRENCY
 562         /* Set Solaris LWP concurrency to 2 */
 563         thr_setconcurrency(2);
 564 #endif
 565 #endif
 566
 567         pthread_create(&t, NULL, (void *) task, NULL);
 568
 569 #if HAVE_SCHED_YIELD
 570         sched_yield();  /* make sure task runs first */
 571 #else
 572 #ifdef HAVE_PTHREAD_YIELD
 573         pthread_yield();        /* make sure task runs first */
 574 #endif
 575 #endif
 576         exit(0);
 577 }
 578                                 ], [ol_pthread_select_yields=yes], [ol_pthread_select_yields=no], [
 579                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])
 580                                 AC_MSG_RESULT($ol_pthread_select_yields)
 581
 582                                 if test $ol_pthread_select_yields = yes ; then
 583                                         ol_with_yielding_select=yes
 584                                 fi
 585                         fi
 586
 587 dnl                     dnl check for reentrant/threadsafe functions
 588 dnl                     AC_CHECK_FUNCS( \
 589 dnl                             feof_unlocked \
 590 dnl                             unlocked_feof \
 591 dnl                             ftrylockfile \
 592 dnl                             flockfile \
 593 dnl                             putc_unlocked \
 594 dnl                             gmtime_r \
 595 dnl                             strtok_r \
 596 dnl                     )
 597
 598                         dnl restore flags
 599                         CPPFLAGS="$save_CPPFLAGS"
 600                         LIBS="$save_LIBS"
 601                 else
 602                         AC_MSG_ERROR([could not link with POSIX Threads])
 603                 fi
 604         fi
 605
 606         if test $ol_with_threads = posix ; then
 607                 AC_MSG_ERROR([could not locate POSIX Threads])
 608         fi
 609 fi
 610
 611 if test $ol_with_threads = auto -o $ol_with_threads = mach ; then
 612         dnl check for Mach CThreads
 613         AC_CHECK_HEADERS(mach/cthreads.h)
 614         if test $ac_cv_header_mach_cthreads_h = yes ; then
 615                 ol_with_threads=found
 616
 617                 dnl check for cthread support in current $LIBS
 618                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 619
 620                 if test $ol_link_threads = no ; then
 621                         dnl try -all_load
 622                         dnl this test needs work
 623                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 624                                 [ol_cv_cthread_all_load], [
 625                                 dnl save the flags
 626                                 save_LIBS="$LIBS"
 627                                 LIBS="-all_load $LIBS"
 628                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 629                                         cthread_fork((void *)0, (void *)0);
 630                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 631                                 dnl restore the LIBS
 632                                 LIBS="$save_LIBS"
 633                         ])
 634
 635                         if test $ol_cv_cthread_all_load = yes ; then
 636                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 637                                 ol_link_threads=mach
 638                         fi
 639                 fi
 640
 641                 if test $ol_link_threads != no ; then
 642                         : check for cthread specific functionality here
 643                         AC_DEFINE(HAVE_MACH_CTHREADS,1)
 644                 else
 645                         AC_MSG_ERROR([could not link with Mach CThreads])
 646                 fi
 647         fi
 648
 649         if test $ol_with_threads = mach ; then
 650                 AC_MSG_ERROR([could not locate Mach CThreads])
 651         fi
 652 fi
 653
 654 if test $ol_with_threads = auto -o $ol_with_threads = lwp ; then
 655         dnl check for SunOS5 LWP
 656         AC_CHECK_HEADERS(thread.h synch.h)
 657         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 658                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
 659
 660                 if test $have_thr = yes ; then
 661                         AC_DEFINE(HAVE_THR)
 662                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
 663                         ol_link_threads=thr
 664
 665                         if test $ol_with_yielding_select = auto ; then
 666                                 ol_with_yielding_select=yes
 667                         fi
 668                 fi
 669         fi
 670
 671         dnl check for SunOS4 LWP
 672         AC_CHECK_HEADERS(lwp/lwp.h)
 673         if test $ac_cv_header_lwp_lwp_h = yes ; then
 674                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 675
 676                 if test $have_lwp = yes ; then
 677                         AC_DEFINE(HAVE_LWP)
 678                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 679                         ol_link_threads=lwp
 680
 681                         if test $ol_with_yielding_select = auto ; then
 682                                 ol_with_yielding_select=no
 683                         fi
 684                 fi
 685         fi
 686 fi
 687
 688 if test $ol_with_yielding_select = yes ; then
 689         AC_DEFINE(HAVE_YIELDING_SELECT,1)
 690 fi
 691
 692 if test $ol_with_threads = manual ; then
 693         dnl User thinks he can manually configure threads.
 694         ol_link_threads=yes
 695
 696         AC_MSG_WARN([thread defines and link options must be set manually])
 697
 698         AC_CHECK_HEADERS(pthread.h sched.h)
 699         AC_CHECK_FUNCS(sched_yield pthread_yield)
 700         OL_LINUX_THREADS
 701
 702         AC_CHECK_HEADERS(mach/cthreads.h)
 703         AC_CHECK_HEADERS(lwp/lwp.h)
 704         AC_CHECK_HEADERS(thread.h synch.h)
 705 fi
 706
 707 if test $ol_with_threads != no ; then
 708         dnl needed to get reentrant/threadsafe versions
 709         dnl
 710         AC_DEFINE(_REENTRANT,1)
 711         AC_DEFINE(_THREAD_SAFE,1)
 712         AC_DEFINE(_THREADSAFE,1)
 713
 714         dnl this might cause the errno symbol to be
 715         dnl replaced with a function to get a thread specific errno.
 716         dnl check to see if everything needs to be compiled
 717         dnl with the thread libraries
 718         AC_CACHE_CHECK([for thread specific errno],
 719                 [ol_cv_errno_thread_specific], [
 720                 AC_TRY_LINK([
 721 #include <errno.h>
 722                         ], [
 723 int x = errno;
 724                         ],
 725                         [ol_cv_errno_thread_specific=yes],
 726                         [ol_cv_errno_thread_specific=no])
 727         ])
 728
 729         if test $ol_cv_errno_thread_specific != yes ; then
 730                 LIBS="$LTHREAD_LIBS $LIBS"
 731                 LTHREAD_LIBS=""
 732         fi
 733 fi
 734
 735 dnl ----------------------------------------------------------------
 736
 737 if test $ol_link_threads = no ; then
 738         if test $ol_with_threads = yes ; then
 739                 AC_MSG_ERROR([no suitable thread support])
 740         fi
 741
 742         if test $ol_with_threads = auto ; then
 743                 AC_MSG_WARN([no suitable thread support, disabling threads])
 744                 ol_with_threads=no
 745         fi
 746
 747         AC_DEFINE(NO_THREADS,1)
 748         LTHREAD_LIBS=""
 749 fi
 750
 751 ol_link_ldbm=no
 752 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 753         OL_BERKELEY_DB2
 754
 755         if test $ol_cv_berkeley_db2 = yes ; then
 756                 ol_link_ldbm=db2
 757                 ol_with_ldbm_api=db2
 758
 759                 if test $ol_with_ldbm_type = hash ; then
 760                         AC_DEFINE(LDBM_USE_DBHASH,1)
 761                 else
 762                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 763                 fi
 764
 765                 dnl $ol_cv_lib_db2 should be yes or -ldb
 766                 dnl (it could be no, but that would be an error
 767                 if test $ol_cv_lib_db2 != yes ; then
 768                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 769                 fi
 770         fi
 771 fi
 772
 773 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 774         OL_BERKELEY_DB
 775
 776         if test $ol_cv_berkeley_db = yes ; then
 777                 ol_link_ldbm=db
 778                 ol_with_ldbm_api=db
 779
 780                 if test $ol_with_ldbm_type = hash ; then
 781                         AC_DEFINE(LDBM_USE_DBHASH,1)
 782                 else
 783                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 784                 fi
 785
 786                 dnl $ol_cv_lib_db should be yes or -ldb
 787                 dnl (it could be no, but that would be an error
 788                 if test $ol_cv_lib_db != yes ; then
 789                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 790                 fi
 791         fi
 792 fi
 793
 794 if test $ol_with_ldbm_api = manual ; then
 795         dnl User thinks he can manually configure LDBM api.
 796         ol_link_ldbm=yes
 797
 798         AC_MSG_WARN([LDBM defines and link options must be set manually])
 799
 800         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 801 fi
 802
 803 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 804         AC_MSG_WARN(Could not find LDBM with BTREE support)
 805         ol_with_ldbm_api=none
 806 fi
 807
 808 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 809         OL_GDBM
 810
 811         if test $ol_cv_gdbm = yes ; then
 812                 ol_link_ldbm=gdbm
 813                 ol_with_ldbm_api=gdbm
 814
 815                 if test $ol_cv_lib_gdbm != yes ; then
 816                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 817                 fi
 818         fi
 819 fi
 820
 821 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 822         OL_NDBM
 823
 824         if test $ol_cv_ndbm = yes ; then
 825                 if test $ol_with_ldbm_api = auto ; then
 826                         AC_MSG_WARN([Attempting to use NDBM.  Functionality will be limited.])
 827                 fi
 828
 829                 ol_link_ldbm=ndbm
 830                 ol_with_ldbm_api=ndbm
 831
 832                 if test $ol_cv_lib_ndbm != yes ; then
 833                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 834                 fi
 835         fi
 836 fi
 837
 838 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 839         AC_MSG_WARN(could not find suitable LDBM backend)
 840         if test $ol_enable_ldbm = yes ; then
 841                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 842         fi
 843
 844         AC_MSG_WARN(disabling LDBM)
 845         ol_enable_ldbm=no
 846 fi
 847
 848 if test $ol_enable_wrappers = yes ; then
 849         AC_CHECK_LIB(wrap, hosts_access,
 850                 [have_wrappers=yes], [have_wrappers=no])
 851
 852         if test $have_wrappers = yes ; then
 853                 AC_DEFINE(HAVE_TCPD)
 854                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 855         else
 856                 AC_MSG_WARN(could not find -lwrap)
 857                 if test $ol_enable_wrappers = yes ; then
 858                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 859                 fi
 860
 861                 AC_MSG_WARN(disabling wrappers support)
 862                 ol_enable_wrappers=no
 863         fi
 864
 865 fi
 866
 867 # ud needs termcap (should insert check here)
 868 ol_link_termcap=no
 869 AC_CHECK_HEADERS(termcap.h ncurses.h)
 870
 871 if test $ol_link_termcap = no ; then
 872         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 873         if test $have_termcap = yes ; then
 874                 AC_DEFINE(HAVE_TERMCAP)
 875                 ol_link_termcap=yes
 876                 TERMCAP_LIBS=-ltermcap
 877         fi
 878 fi
 879
 880 if test $ol_link_termcap = no ; then
 881         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 882         if test $have_ncurses = yes ; then
 883                 AC_DEFINE(HAVE_NCURSES)
 884                 ol_link_termcap=yes
 885                 TERMCAP_LIBS=-lncurses
 886         fi
 887 fi
 888
 889 if test $ol_link_termcap = no ; then
 890         AC_DEFINE(NO_TERMCAP,1)
 891         TERMCAP_LIBS=
 892 fi
 893
 894 # FreeBSD (and others) have crypt(3) in -lcrypt
 895 if test $ol_enable_crypt != no ; then
 896         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 897                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 898                         have_crypt=yes], [have_crypt=no])])
 899
 900         if test $have_crypt = yes ; then
 901                 AC_DEFINE(HAVE_CRYPT,1)
 902         else
 903                 AC_MSG_WARN(could not find crypt)
 904                 if test $ol_enable_crypt = yes ; then
 905                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 906                 fi
 907
 908                 AC_MSG_WARN(disabling crypt support)
 909                 ol_enable_crypt=no
 910         fi
 911 fi
 912
 913 # FreeBSD (and others) have setproctitle(3) in -lutil
 914 if test $ol_enable_proctitle != no ; then
 915         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 916                 AC_CHECK_LIB(util, setproctitle,
 917                         [have_setproctitle=yes
 918                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 919                         [have_setproctitle=no
 920                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 921
 922         if test $have_setproctitle = yes ; then
 923                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 924         fi
 925 fi
 926
 927 dnl ----------------------------------------------------------------
 928 dnl Checks for header files.
 929 AC_HEADER_STDC
 930
 931 if test $ac_cv_header_stdc != yes; then
 932         AC_MSG_WARN([could not Standard C compliant headers])
 933 fi
 934
 935 AC_HEADER_DIRENT
 936 AC_HEADER_SYS_WAIT
 937 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 938 if test $am_cv_sys_posix_termios = yes ; then
 939         AC_DEFINE(HAVE_POSIX_TERMIOS,1)
 940 fi
 941
 942 AC_CHECK_HEADERS(       \
 943         crypt.h                 \
 944         errno.h                 \
 945         fcntl.h                 \
 946         filio.h                 \
 947         getopt.h                \
 948         libutil.h               \
 949         limits.h                \
 950         malloc.h                \
 951         memory.h                \
 952         regex.h                 \
 953         psap.h                  \
 954         pwd.h                   \
 955         sgtty.h                 \
 956         stdarg.h                \
 957         stddef.h                \
 958         string.h                \
 959         strings.h               \
 960         sys/file.h              \
 961         sys/filio.h             \
 962         sys/errno.h             \
 963         sys/ioctl.h             \
 964         sys/param.h             \
 965         sys/resource.h  \
 966         sys/socket.h    \
 967         sys/syslog.h    \
 968         sys/types.h             \
 969         syslog.h                \
 970         termios.h               \
 971 )
 972
 973 dnl ----------------------------------------------------------------
 974 dnl Checks for typedefs, structures, and compiler characteristics.
 975 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
 976 AC_TYPE_MODE_T
 977 AC_TYPE_OFF_T
 978 AC_TYPE_PID_T
 979 AM_TYPE_PTRDIFF_T
 980 AC_TYPE_SIGNAL
 981 AC_TYPE_SIZE_T
 982 AC_STRUCT_ST_BLKSIZE
 983 AC_HEADER_TIME
 984 AC_STRUCT_TM
 985
 986 OL_C_UPPER_LOWER
 987 AC_C_CONST
 988
 989 if test $cross_compiling = yes ; then
 990         AC_DEFINE(CROSS_COMPILING, 1)
 991 else
 992         AC_C_BIGENDIAN
 993         AC_CHECK_SIZEOF(short)
 994         AC_CHECK_SIZEOF(int)
 995         AC_CHECK_SIZEOF(long)
 996 fi
 997
 998 dnl ----------------------------------------------------------------
 999 dnl Checks for library functions.
1000 AC_FUNC_MEMCMP
1001 AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1002 AC_FUNC_STRFTIME
1003 AM_FUNC_STRTOD
1004 AC_FUNC_VPRINTF
1005
1006 if test $ac_cv_func_vprintf = yes ; then
1007         dnl check for vsnprintf
1008         AC_CHECK_FUNCS(vsnprintf)
1009 fi
1010
1011 AC_FUNC_WAIT3
1012
1013 AC_CHECK_FUNCS(         \
1014         bcopy                   \
1015         flock                   \
1016         getdtablesize   \
1017         gethostname             \
1018         getpwuid                \
1019         gettimeofday    \
1020         lockf                   \
1021         memcpy                  \
1022         memmove                 \
1023         mkstemp                 \
1024         res_search              \
1025         select                  \
1026         setpwfile               \
1027         setsid                  \
1028         signal                  \
1029         sigset                  \
1030         snprintf                \
1031         socket                  \
1032         strerror                \
1033         strpbrk                 \
1034         strrchr                 \
1035         strsep                  \
1036         strstr                  \
1037         strtok                  \
1038         strtol                  \
1039         strtoul                 \
1040         sysconf                 \
1041         waitpid                 \
1042 )
1043
1044 dnl We actually may need to replace more than this.
1045 AC_REPLACE_FUNCS(getopt strdup tempnam)
1046
1047 dnl ----------------------------------------------------------------
1048 # Check Configuration
1049 OL_SYS_ERRLIST
1050
1051 dnl ----------------------------------------------------------------
1052 dnl Sort out defines
1053
1054 if test $ol_enable_debug != no ; then
1055         AC_DEFINE(LDAP_DEBUG,1)
1056 fi
1057 dnl     if test $ol_enable_syslog != no ; then
1058 dnl             AC_DEFINE(LDAP_SYSLOG,1)
1059 dnl     fi
1060 if test $ol_enable_libui = yes ; then
1061         AC_DEFINE(LDAP_LIBUI,1)
1062 fi
1063 if test $ol_enable_cache = no ; then
1064         AC_DEFINE(LDAP_NOCACHE,1)
1065 fi
1066 if test $ol_enable_dns != no ; then
1067         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_API_VENDOR_VERSION,1)
1068 fi
1069 if test $ol_enable_proctitle != no ; then
1070         AC_DEFINE(LDAP_PROCTITLE,1)
1071 fi
1072 if test $ol_enable_referrals != no ; then
1073         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_API_VENDOR_VERSION,1)
1074 fi
1075 if test $ol_enable_cldap != no ; then
1076         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1077 fi
1078
1079 if test $ol_enable_aclgroups != no ; then
1080         AC_DEFINE(SLAPD_ACLGROUPS,1)
1081 fi
1082 if test $ol_enable_crypt != no ; then
1083         AC_DEFINE(SLAPD_CRYPT,1)
1084 fi
1085 if test $ol_enable_md5 != no ; then
1086         AC_DEFINE(SLAPD_MD5,1)
1087 fi
1088 if test $ol_enable_sha1 != no ; then
1089         AC_DEFINE(SLAPD_SHA1,1)
1090 fi
1091 if test $ol_enable_phonetic != no ; then
1092         AC_DEFINE(SLAPD_PHONETIC,1)
1093 fi
1094 if test $ol_enable_rlookups != no ; then
1095         AC_DEFINE(SLAPD_RLOOKUPS,1)
1096 fi
1097
1098 if test $ol_link_ldbm != no ; then
1099         AC_DEFINE(SLAPD_LDBM,1)
1100         BUILD_SLAPD=yes
1101         BUILD_LDBM=yes
1102 fi
1103
1104 if test $ol_enable_passwd != no ; then
1105         AC_DEFINE(SLAPD_PASSWD,1)
1106         BUILD_SLAPD=yes
1107         BUILD_PASSWD=yes
1108 fi
1109
1110 if test $ol_enable_shell != no ; then
1111         AC_DEFINE(SLAPD_SHELL,1)
1112         BUILD_SLAPD=yes
1113         BUILD_SHELL=yes
1114 fi
1115
1116 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
1117         $BUILD_SLAPD = yes ; then
1118         BUILD_SLURPD=yes
1119 fi
1120
1121 if test $ol_link_isode != no ; then
1122         BUILD_LDAPD=yes
1123 fi
1124
1125 dnl ----------------------------------------------------------------
1126
1127 AC_SUBST(BUILD_LDAPD)
1128 AC_SUBST(BUILD_SLAPD)
1129   AC_SUBST(BUILD_LDBM)
1130   AC_SUBST(BUILD_PASSWD)
1131   AC_SUBST(BUILD_SHELL)
1132 AC_SUBST(BUILD_SLURPD)
1133
1134
1135 AC_SUBST(LDAP_LIBS)
1136 AC_SUBST(LDAPD_LIBS)
1137 AC_SUBST(SLAPD_LIBS)
1138 AC_SUBST(SLURPD_LIBS)
1139 AC_SUBST(LDBM_LIBS)
1140 AC_SUBST(LTHREAD_LIBS)
1141 AC_SUBST(LUTIL_LIBS)
1142
1143 AC_SUBST(KRB_LIBS)
1144 AC_SUBST(TERMCAP_LIBS)
1145
1146 dnl ----------------------------------------------------------------
1147 dnl final output
1148 dnl
1149
1150 AC_OUTPUT( \
1151 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1152 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1153 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1154 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1155 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1156 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1157 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1158 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1159 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1160 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1161 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1162 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1163 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1164 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1165 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1166 include/Makefile:build/top.mk:include/Makefile.in \
1167 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1168 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1169 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1170 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1171 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1172 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1173 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk:build/lib-static.mk    \
1174 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1175 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1176 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1177 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1178 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1179 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1180 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1181 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1182 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1183 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1184 tests/Makefile:build/top.mk:tests/Makefile.in \
1185 ,[
1186 date > stamp-h
1187 echo Please \"make depend\" to build dependencies
1188 ])