git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8 dnl Configure.in for OpenLDAP
   9 dnl
  10 AC_INIT(include/ldap.h)
  11 dnl
  12 dnl
  13 AC_PREREQ(2.10)dnl Required Autoconf version
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_CONFIG_AUX_DIR(build)
  18 AC_CONFIG_HEADER(include/portable.h)dnl
  19 dnl
  20 dnl Start Args
  21 AC_MSG_CHECKING(configure arguments)
  22 AC_PREFIX_DEFAULT(/usr/local)
  23
  24 dnl General "enable" options
  25 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  26 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  27 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  28 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  29 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  30 OL_ARG_ENABLE(dns,[  --enable-dns               enable dns support], no)dnl
  31 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable referrals], yes)dnl
  32 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  33
  34 dnl General "with" options
  35 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  36         auto, [auto k5 k4 afs yes no])
  37 OL_ARG_WITH(threads,[  --with-threads   use threads],
  38         auto, [auto posix mach lwp yes no manual] )
  39 OL_ARG_WITH(preemptive,[  --with-preemptive     thread implementation is preemptive],
  40         auto, [auto yes no manual] )
  41
  42 dnl Server options
  43
  44 dnl LDAPD OPTIONS
  45 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  46
  47 dnl SLAPD OPTIONS
  48 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  49 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  50 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  51 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  52 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  53 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  54 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  55 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  56
  57 dnl SLAPD Backend options
  58 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  59 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  60         [auto db2 db gdbm ndbm manual])
  61 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  62         [auto btree hash])
  63
  64 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  65 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  66
  67 dnl SLURPD OPTIONS
  68 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  69
  70 if test $ol_enable_slapd = no ; then
  71         dnl SLAPD was specificallly disabled
  72         if test $ol_enable_ldbm = yes ; then
  73                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
  74         fi
  75         if test $ol_enable_passwd = yes ; then
  76                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
  77         fi
  78         if test $ol_enable_shell = yes ; then
  79                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
  80         fi
  81         if test $ol_enable_aclgroups = yes ; then
  82                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
  83         fi
  84         if test $ol_enable_crypt = yes ; then
  85                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument])
  86         fi
  87         if test $ol_enable_md5 = yes ; then
  88                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument])
  89         fi
  90         if test $ol_enable_sha1 = yes ; then
  91                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument])
  92         fi
  93         if test $ol_enable_wrappers = yes ; then
  94                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
  95         fi
  96         if test $ol_enable_phonetic = yes ; then
  97                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
  98         fi
  99         if test $ol_enable_rlookups = yes ; then
 100                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 101         fi
 102         if test $ol_with_ldbm_api != auto ; then
 103                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 104         fi
 105         if test $ol_with_ldbm_type != auto ; then
 106                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 107         fi
 108         if test $ol_enable_slurpd = yes ; then
 109                 AC_MSG_ERROR([slurpd requires slapd])
 110         fi
 111
 112         # force settings to no
 113         ol_enable_ldbm=no
 114         ol_enable_shell=no
 115         ol_enable_passwd=no
 116         ol_enable_aclgroups=no
 117         ol_enable_crypt=no
 118         ol_enable_md5=no
 119         ol_enable_sha1=no
 120         ol_enable_wrappers=no
 121         ol_enable_phonetic=no
 122         ol_enable_rlookups=no
 123         ol_with_ldbm_api=no
 124         ol_with_ldbm_type=no
 125         ol_enable_slurpd=no
 126
 127 elif test $ol_enable_ldbm = no ; then
 128         dnl SLAPD without LDBM
 129
 130         if test $ol_with_ldbm_api != auto ; then
 131                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 132         fi
 133
 134         if test $ol_with_ldbm_type != auto ; then
 135                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 136         fi
 137
 138         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 139                 AC_MSG_ERROR([slapd requires a backend])
 140         fi
 141
 142         ol_with_ldbm_api=no
 143         ol_with_ldbm_type=no
 144
 145 else
 146         dnl SLAPD with LDBM
 147
 148         if test $ol_with_ldbm_api = gdbm -a \
 149                 $ol_with_ldbm_type = btree ; then
 150                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 151         fi
 152         if test $ol_with_ldbm_api = ndbm -a \
 153                 $ol_with_ldbm_type = btree ; then
 154                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 155         fi
 156 fi
 157
 158 if test $ol_enable_slurpd = yes ; then
 159         dnl SLURPD was specifically enabled
 160         if test $ol_with_threads = no ; then
 161                 AC_MSG_ERROR([slurpd requires threads])
 162         fi
 163 fi
 164
 165 AC_MSG_RESULT(done)
 166
 167 ## Initialize vars
 168 LDAP_LIBS=
 169 LDBM_LIBS=
 170 LTHREAD_LIBS=
 171 LUTIL_LIBS=
 172
 173 LDAPD_LIBS=
 174 SLAPD_LIBS=
 175 SLURPD_LIBS=
 176
 177 BUILD_LDAPD=no
 178 BUILD_SLAPD=no
 179 BUILD_SLURPD=no
 180
 181 BUILD_LDBM=no
 182 BUILD_PASSWD=no
 183 BUILD_SHELL=no
 184
 185 KRB_LIBS=
 186 TERMCAP_LIBS=
 187
 188 dnl ----------------------------------------------------------------
 189 dnl Checks for programs
 190
 191 AC_PROG_LN_S
 192 AC_PROG_INSTALL
 193 AC_PROG_RANLIB
 194 AC_PROG_MAKE_SET
 195
 196 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 197         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 198 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 199 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 200
 201 dnl Checks the compiler and UNIX Variants
 202 AC_PROG_CC
 203 AC_PROG_GCC_TRADITIONAL
 204 AC_PROG_CPP
 205
 206 AC_AIX
 207 AC_ISC_POSIX
 208 AC_MINIX
 209
 210 dnl ----------------------------------------------------------------
 211 dnl Checks for libraries
 212
 213 dnl Find socket()
 214 dnl Likely combinations:
 215 dnl             -lsocket [ -lnsl_s | -lnsl ]
 216 dnl             -linet
 217
 218 AC_CHECK_FUNC(socket, :, [
 219 dnl
 220 dnl hopefully we won't include too many libraries
 221 dnl
 222         AC_CHECK_LIB(socket, main)
 223         AC_CHECK_LIB(net, main)
 224         AC_CHECK_LIB(nsl_s, main)
 225         AC_CHECK_LIB(nsl, main)
 226         AC_CHECK_LIB(inet, socket)
 227         AC_CHECK_LIB(gen, main)
 228 ])
 229
 230 dnl HP-UX requires -lV3
 231 AC_CHECK_LIB(V3, sigset)
 232
 233 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 234         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 235
 236         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 237                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 238                         [-lkrb5 -ldes425])
 239
 240                 if test $have_k5 = yes ; then
 241                         ol_with_kerberos=found
 242                         ol_link_kerberos=yes
 243
 244                         AC_DEFINE(HAVE_KERBEROS)
 245
 246                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 247                 fi
 248         fi
 249 fi
 250 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 251         AC_CHECK_HEADERS(krb.h des.h)
 252
 253         if test $ac_cv_header_krb_h = yes ; then
 254                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 255
 256                 if test $have_k4 = yes ; then
 257                         ol_with_kerberos=found
 258                         ol_link_kerberos=yes
 259
 260                         AC_DEFINE(HAVE_KERBEROS)
 261
 262                         KRB_LIBS="-lkrb -ldes"
 263                 fi
 264         fi
 265 fi
 266
 267
 268 ol_link_threads=no
 269 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 270         AC_CHECK_HEADERS(pthread.h sched.h)
 271
 272         if test $ac_cv_header_pthread_h = yes ; then
 273                 OL_POSIX_THREAD_VERSION
 274
 275                 if test $ol_cv_pthread_version = final ; then
 276                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 277                 elif test $ol_cv_pthread_version = draft4 ; then
 278                         AC_DEFINE(HAVE_PTHREADS_D4)
 279                 else
 280                         AC_MSG_ERROR([unknown pthread version])
 281                 fi
 282
 283                 # consider threads found
 284                 ol_with_threads=found
 285
 286                 OL_LINUX_THREADS
 287
 288                 if test $ol_cv_linux_threads = yes ; then
 289                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 290                 fi
 291
 292                 dnl Now the hard part, how to link
 293
 294                 dnl A few platforms have pthread support in standard libraries
 295                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 296
 297                 if test $ol_link_threads = no ; then
 298                         dnl try -pthread
 299                         AC_CACHE_CHECK([for pthread_create with -pthread],
 300                                 [ol_cv_pthread_flag], [
 301                                 dnl save the CPPFLAGS
 302                                 save_LIBS="$LIBS"
 303                                 LIBS="-pthread $LIBS"
 304                                 AC_TRY_LINK([#include <pthread.h>],[
 305                                         pthread_create((pthread_t*) 0,
 306                                                 (pthread_attr_t*) 0, 0, 0);
 307                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 308                                 dnl restore the LIBS
 309                                 LIBS="$save_LIBS"
 310                         ])
 311
 312                         if test $ol_cv_pthread_flag = yes ; then
 313                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 314                                 ol_link_threads=posix
 315                         fi
 316                 fi
 317
 318                 if test $ol_link_threads = no ; then
 319                         dnl try -lpthread
 320                         save_LIBS="$LIBS"
 321                         AC_CHECK_LIB(pthread, pthread_create, [
 322                                 ol_link_threads=posix
 323                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 324                         LIBS="$save_LIBS"
 325                 fi
 326
 327                 if test $ol_link_threads = no ; then
 328                         dnl try -lc_r
 329                         save_LIBS="$LIBS"
 330                         AC_CHECK_LIB(c_r, pthread_create, [
 331                                 ol_link_threads=posix
 332                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 333                         LIBS="$save_LIBS"
 334                 fi
 335
 336                 if test $ol_link_threads = no ; then
 337                         dnl try DEC Threads
 338                         save_LIBS="$LIBS"
 339                         AC_CHECK_LIB(pthread, pthread_create, [
 340                                 AC_DEFINE(HAVE_DCE)
 341                                 ol_link_threads=posix
 342                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc -lc"
 343                                 if test $ol_with_preemptive = auto ; then
 344                                         ol_with_preemptive=yes
 345                                 fi
 346                                 ],,[-lmach -lexc -lc])
 347                         LIBS="$save_LIBS"
 348                 fi
 349
 350                 if test $ol_link_threads != no ; then
 351                         AC_DEFINE(HAVE_PTHREADS)
 352
 353                         dnl save DEFS/LIBS
 354                         save_CPPFLAGS="$CPPFLAGS"
 355                         save_LIBS="$LIBS"
 356                         LIBS="$LTHREAD_LIBS $LIBS"
 357
 358                         dnl All POSIX Thread (final) implementations should have
 359                         dnl sched_yield instead of pthread yield.
 360                         dnl check for both
 361                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 362
 363                         if test $ac_cv_func_sched_yield = no -a \
 364                                 $ac_cv_func_pthread_yield = no ; then
 365                                 dnl Digital UNIX has sched_yield() in -lrt
 366                                 AC_CHECK_LIB(rt, sched_yield,
 367                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 368                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 369                                         ac_cv_func_sched_yield=yes],
 370                                         [ac_cv_func_sched_yield=no])
 371                         fi
 372                         if test $ac_cv_func_sched_yield = no -a \
 373                                 $ac_cv_func_pthread_yield = no ; then
 374                                 dnl Solaris has sched_yield() in -lposix4
 375                                 AC_CHECK_LIB(posix4, sched_yield,
 376                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 377                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 378                                         ac_cv_func_sched_yield=yes],
 379                                         [ac_cv_func_sched_yield=no])
 380                         fi
 381                         if test $ac_cv_func_sched_yield = no -a \
 382                                 $ac_cv_func_pthread_yield = no ; then
 383                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 384                                 AC_MSG_ERROR([POSIX Threads are not usable])
 385                         fi
 386
 387                         dnl Check functions for compatibility
 388                         AC_CHECK_FUNCS(pthread_kill)
 389 dnl                     AC_CHECK_FUNCS(
 390 dnl                             pthread_attr_create pthread_attr_init \
 391 dnl                             pthread_attr_destroy pthread_attr_delete \
 392 dnl                             pthread_attr_setdetachstate pthread_attr_setdetach_np \
 393 dnl                     )
 394
 395                         dnl Check PREEMPTIVE Implementation
 396                         if test $ol_with_preemptive = auto ; then
 397                                 AC_MSG_CHECKING([for preemptive Pthread implementation])
 398                                 AC_TRY_RUN([
 399 #include <sys/types.h>
 400 #include <sys/time.h>
 401 #include <unistd.h>
 402 #include <pthread.h>
 403 #ifndef NULL
 404 #define NULL 0
 405 #endif
 406
 407 int task(arg)
 408         int *arg;
 409 {
 410         struct timeval tv;
 411
 412         tv.tv_sec=4;
 413         tv.tv_usec=0;
 414         select(0, NULL, NULL, NULL, &tv);
 415
 416         tv.tv_sec=6;
 417         tv.tv_usec=0;
 418         select(0, NULL, NULL, NULL, &tv);
 419
 420         exit(1); /* if we exit here, the select blocked the whole process */
 421 }
 422
 423 main(argc, argv)
 424 int argc; char **argv;
 425 {
 426         pthread_t t;
 427         pthread_create(&t, NULL, (void *) task, NULL);
 428
 429 #if HAVE_SCHED_YIELD
 430         sched_yield();  /* make sure task runs first */
 431 #else
 432 #if defined(HAVE_PTHREAD_YIELD)
 433         pthread_yield();        /* make sure task runs first */
 434 #endif
 435 #endif
 436         exit(0);
 437 }
 438                                 ], [ol_pthread_preemptive=yes], [ol_pthread_preemptive=no], [
 439                                 AC_MSG_ERROR([crossing compiling: use --with-preemptive=yes|no|manual])])
 440                                 AC_MSG_RESULT($ol_pthread_preemptive)
 441
 442                                 if test $ol_pthread_preemptive = yes ; then
 443                                         AC_DEFINE(HAVE_PREEMPTIVE_PTHREADS)
 444                                         ol_with_preemptive=yes
 445                                 fi
 446                         fi
 447
 448                         dnl restore DEFS/LIBS
 449                         CPPFLAGS="$save_CPPFLAGS"
 450                         LIBS="$save_LIBS"
 451                 else
 452                         AC_MSG_ERROR([could not link with POSIX Threads])
 453                 fi
 454         fi
 455
 456         if test $ol_with_threads = posix ; then
 457                 AC_MSG_ERROR([could not locate POSIX Threads])
 458         fi
 459 fi
 460
 461 if test $ol_with_threads = auto -o $ol_with_threads = mach ; then
 462         dnl check for Mach CThreads
 463         AC_CHECK_HEADERS(mach/cthreads.h)
 464         if test $ac_cv_header_mach_cthreads_h = yes ; then
 465                 ol_with_threads=found
 466
 467                 dnl A few platforms have cthread support in standard libraries
 468                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 469
 470                 if test $ol_link_threads = no ; then
 471                         dnl try -all_load
 472                         dnl this test needs work
 473                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 474                                 [ol_cv_cthread_all_load], [
 475                                 dnl save the CPPFLAGS
 476                                 save_LIBS="$LIBS"
 477                                 LIBS="-all_load $LIBS"
 478                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 479                                         cthread_fork((void *)0, (void *)0);
 480                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 481                                 dnl restore the LIBS
 482                                 LIBS="$save_LIBS"
 483                         ])
 484
 485                         if test $ol_cv_cthread_all_load = yes ; then
 486                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 487                                 ol_link_threads=mach
 488                         fi
 489                 fi
 490
 491                 if test $ol_link_threads != no ; then
 492                         : check for cthread specific functionality here
 493                 else
 494                         AC_MSG_ERROR([could not link with Mach CThreads])
 495                 fi
 496         fi
 497
 498         if test $ol_with_threads = mach ; then
 499                 AC_MSG_ERROR([could not locate Mach CThreads])
 500         fi
 501 fi
 502
 503 if test $ol_with_threads = auto -o $ol_with_threads = lwp ; then
 504         dnl check for SunOS5 LWP
 505         AC_CHECK_HEADERS(thread.h synch.h)
 506         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 507                 AC_CHECK_LIB(thread, thr_create, [have_lwp=yes], [have_lwp=no])
 508
 509                 if test $have_lwp = yes ; then
 510                         AC_DEFINE(HAVE_THR)
 511                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 512
 513                         if test $ol_with_preemptive = auto ; then
 514                                 ol_with_preemptive=yes
 515                         fi
 516                 fi
 517         fi
 518
 519         dnl check for SunOS4 LWP
 520         AC_CHECK_HEADERS(lwp/lwp.h)
 521         if test $ac_cv_header_lwp_lwp_h = yes ; then
 522                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 523
 524                 if test $have_lwp = yes ; then
 525                         AC_DEFINE(HAVE_LWP)
 526                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 527
 528                         if test $ol_with_preemptive = auto ; then
 529                                 ol_with_preemptive=no
 530                         fi
 531                 fi
 532         fi
 533 fi
 534
 535 if test $ol_with_preemptive = yes ; then
 536         AC_DEFINE(PREEMPTIVE_THREADS,1)
 537 fi
 538
 539 if test $ol_with_threads = manual ; then
 540         dnl User thinks he can manually configure threads.
 541         ol_link_threads=yes
 542
 543         AC_MSG_WARN([thread defines and link options must be set manually])
 544
 545         AC_CHECK_HEADERS(pthread.h sched.h)
 546         AC_CHECK_FUNCS(sched_yield pthread_yield)
 547         OL_LINUX_THREADS
 548
 549         AC_CHECK_HEADERS(mach/cthreads.h)
 550         AC_CHECK_HEADERS(lwp/lwp.h)
 551         AC_CHECK_HEADERS(thread.h synch.h)
 552 fi
 553
 554 if test $ol_link_threads = no ; then
 555         if test $ol_with_threads = yes ; then
 556                 AC_MSG_ERROR([no suitable thread support])
 557         fi
 558
 559         if test $ol_with_threads = auto ; then
 560                 AC_MSG_WARN([no suitable thread support, disabling threads])
 561                 ol_with_threads=no
 562         fi
 563
 564         AC_DEFINE(NO_THREADS,1)
 565         AC_DEFINE(PREEMPTIVE_THREADS,1)
 566         LTHREAD_LIBS=""
 567 fi
 568
 569 ol_link_ldbm=no
 570 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 571         OL_BERKELEY_DB2
 572
 573         if test $ol_cv_berkeley_db2 = yes ; then
 574                 ol_link_ldbm=db2
 575                 ol_with_ldbm_api=db2
 576
 577                 if test $ol_with_ldbm_type = hash ; then
 578                         AC_DEFINE(LDBM_USE_DBHASH,1)
 579                 else
 580                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 581                 fi
 582
 583                 dnl $ol_cv_lib_db2 should be yes or -ldb
 584                 dnl (it could be no, but that would be an error
 585                 if test $ol_cv_lib_db2 != yes ; then
 586                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 587                 fi
 588         fi
 589 fi
 590
 591 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 592         OL_BERKELEY_DB
 593
 594         if test $ol_cv_berkeley_db = yes ; then
 595                 ol_link_ldbm=db
 596                 ol_with_ldbm_api=db
 597
 598                 if test $ol_with_ldbm_type = hash ; then
 599                         AC_DEFINE(LDBM_USE_DBHASH,1)
 600                 else
 601                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 602                 fi
 603
 604                 dnl $ol_cv_lib_db should be yes or -ldb
 605                 dnl (it could be no, but that would be an error
 606                 if test $ol_cv_lib_db != yes ; then
 607                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 608                 fi
 609         fi
 610 fi
 611
 612 if test $ol_with_ldbm_api = manual ; then
 613         dnl User thinks he can manually configure LDBM api.
 614         ol_link_ldbm=yes
 615
 616         AC_MSG_WARN([LDBM defines and link options must be set manually])
 617
 618         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 619 fi
 620
 621 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 622         AC_MSG_WARN(Could not find LDBM with BTREE support)
 623         ol_with_ldbm_api=none
 624 fi
 625
 626 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 627         OL_GDBM
 628
 629         if test $ol_cv_gdbm = yes ; then
 630                 ol_link_ldbm=gdbm
 631                 ol_with_ldbm_api=gdbm
 632
 633                 if test $ol_cv_lib_gdbm != yes ; then
 634                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 635                 fi
 636         fi
 637 fi
 638
 639 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 640         OL_NDBM
 641
 642         if test $ol_cv_ndbm = yes ; then
 643                 ol_link_ldbm=ndbm
 644                 ol_with_ldbm_api=ndbm
 645
 646                 if test $ol_with_ldbm_api = ndbm ; then
 647                         AC_WARN([Attempting to use NDBM.  Functionality will be limited.])
 648                 fi
 649
 650                 if test $ol_cv_lib_ndbm != yes ; then
 651                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 652                 fi
 653         fi
 654 fi
 655
 656 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 657         AC_MSG_WARN(could not find suitable LDBM backend)
 658         if test $ol_enable_ldbm = yes ; then
 659                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 660         fi
 661
 662         AC_MSG_WARN(disabling LDBM)
 663         ol_enable_ldbm=no
 664 fi
 665
 666 if test $ol_enable_wrappers = yes ; then
 667         AC_CHECK_LIB(wrap, hosts_access,
 668                 [have_wrappers=yes], [have_wrappers=no])
 669
 670         if test $have_wrappers = yes ; then
 671                 AC_DEFINE(HAVE_TCPD)
 672                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 673         else
 674                 AC_MSG_WARN(could not find -lwrap)
 675                 if test $ol_enable_wrappers = yes ; then
 676                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 677                 fi
 678
 679                 AC_MSG_WARN(disabling wrappers support)
 680                 ol_enable_wrappers=no
 681         fi
 682
 683 fi
 684
 685 # ud needs termcap (should insert check here)
 686 ol_link_termcap=no
 687 AC_CHECK_HEADERS(termcap.h ncurses.h)
 688
 689 if test $ol_link_termcap = no ; then
 690         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 691         if test $have_termcap = yes ; then
 692                 AC_DEFINE(HAVE_TERMCAP)
 693                 ol_link_termcap=yes
 694                 TERMCAP_LIBS=-ltermcap
 695         fi
 696 fi
 697
 698 if test $ol_link_termcap = no ; then
 699         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 700         if test $have_ncurses = yes ; then
 701                 AC_DEFINE(HAVE_NCURSES)
 702                 ol_link_termcap=yes
 703                 TERMCAP_LIBS=-lncurses
 704         fi
 705 fi
 706
 707 if test $ol_link_termcap = no ; then
 708         AC_DEFINE(NO_TERMCAP,1)
 709         TERMCAP_LIBS=
 710 fi
 711
 712 # FreeBSD (and others) have crypt(3) in -lcrypt
 713 if test $ol_enable_crypt != no ; then
 714         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 715                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 716                         have_crypt=yes], [have_crypt=no])])
 717
 718         if test $have_crypt = yes ; then
 719                 AC_DEFINE(HAVE_CRYPT,1)
 720         else
 721                 AC_MSG_WARN(could not find crypt)
 722                 if test $ol_enable_crypt = yes ; then
 723                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 724                 fi
 725
 726                 AC_MSG_WARN(disabling crypt support)
 727                 ol_enable_crypt=no
 728         fi
 729 fi
 730
 731 # FreeBSD (and others) have setproctitle(3) in -lutil
 732 if test $ol_enable_proctitle != no ; then
 733         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 734                 AC_CHECK_LIB(util, setproctitle,
 735                         [have_setproctitle=yes
 736                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 737                         [have_setproctitle=no
 738                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 739
 740         if test $have_setproctitle = yes ; then
 741                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 742         fi
 743 fi
 744
 745 dnl ----------------------------------------------------------------
 746 dnl Checks for header files.
 747 AC_HEADER_STDC
 748
 749 if test $ac_cv_header_stdc != yes; then
 750         AC_MSG_WARN([could not locate Standard C headers])
 751 fi
 752
 753 AC_HEADER_DIRENT
 754 AC_HEADER_SYS_WAIT
 755 AC_CHECK_HEADERS(       \
 756         stdarg.h                \
 757         stddef.h                \
 758         errno.h                 \
 759         fcntl.h                 \
 760         filio.h                 \
 761         getopt.h                \
 762         libutil.h               \
 763         limits.h                \
 764         malloc.h                \
 765         regex.h                 \
 766         sgtty.h                 \
 767         sys/file.h              \
 768         sys/filio.h             \
 769         sys/errno.h             \
 770         sys/ioctl.h             \
 771         sys/param.h             \
 772         sys/socket.h    \
 773         sys/syslog.h    \
 774         sys/time.h              \
 775         sys/types.h             \
 776         syslog.h                \
 777         termios.h               \
 778         unistd.h                \
 779 )
 780
 781 dnl ----------------------------------------------------------------
 782 dnl Checks for typedefs, structures, and compiler characteristics.
 783 AC_TYPE_GETGROUPS
 784 AC_TYPE_MODE_T
 785 AC_TYPE_OFF_T
 786 AC_TYPE_PID_T
 787 AC_TYPE_SIGNAL
 788 AC_TYPE_SIZE_T
 789 AC_TYPE_UID_T
 790 AC_STRUCT_ST_BLKSIZE
 791 AC_HEADER_TIME
 792 AC_STRUCT_TM
 793
 794 OL_C_UPPER_LOWER
 795 AC_C_CONST
 796
 797 dnl AC_CHECK_SIZEOF(short)
 798 dnl AC_CHECK_SIZEOF(int)
 799 dnl AC_CHECK_SIZEOF(long)
 800
 801 dnl ----------------------------------------------------------------
 802 dnl Checks for library functions.
 803 AC_FUNC_MEMCMP
 804 AC_FUNC_STRFTIME
 805 AC_FUNC_VPRINTF
 806 AC_FUNC_WAIT3
 807
 808 AC_CHECK_FUNCS(         \
 809         bcopy                   \
 810         getopt                  \
 811         flock                   \
 812         gethostname             \
 813         gettimeofday    \
 814         getdtablesize   \
 815         lockf                   \
 816         memcpy                  \
 817         memmove                 \
 818         mkstemp                 \
 819         mktime                  \
 820         select                  \
 821         setpwfile               \
 822         setsid                  \
 823         signal                  \
 824         sigset                  \
 825         socket                  \
 826         strerror                \
 827         strstr                  \
 828         strrchr                 \
 829         strsep                  \
 830         strtod                  \
 831         strtol                  \
 832         strtoul                 \
 833         sysconf                 \
 834         tempnam                 \
 835         waitpid                 \
 836 )
 837
 838 AC_REPLACE_FUNCS(getopt strdup tempnam)
 839
 840 dnl ----------------------------------------------------------------
 841 # Check Configuration
 842 OL_SYS_ERRLIST
 843
 844 dnl ----------------------------------------------------------------
 845 dnl Sort out defines
 846
 847 if test $ol_enable_debug != no ; then
 848         AC_DEFINE(LDAP_DEBUG,1)
 849 fi
 850 dnl     if test $ol_enable_syslog != no ; then
 851 dnl             AC_DEFINE(LDAP_SYSLOG,1)
 852 dnl     fi
 853 if test $ol_enable_libui = yes ; then
 854         AC_DEFINE(LDAP_LIBUI,1)
 855 fi
 856 if test $ol_enable_cache = no ; then
 857         AC_DEFINE(LDAP_NOCACHE,1)
 858 fi
 859 if test $ol_enable_dns != no ; then
 860         AC_DEFINE(LDAP_DNS,1)
 861 fi
 862 if test $ol_enable_proctitle != no ; then
 863         AC_DEFINE(LDAP_PROCTITLE,1)
 864 fi
 865 if test $ol_enable_referrals != no ; then
 866         AC_DEFINE(LDAP_REFERRALS,1)
 867 fi
 868 if test $ol_enable_cldap != no ; then
 869         AC_DEFINE(LDAP_CONNECTIONLESS,1)
 870 fi
 871
 872 if test $ol_enable_aclgroups != no ; then
 873         AC_DEFINE(SLAPD_ACLGROUPS,1)
 874 fi
 875 if test $ol_enable_crypt != no ; then
 876         AC_DEFINE(SLAPD_CRYPT,1)
 877 fi
 878 if test $ol_enable_md5 != no ; then
 879         AC_DEFINE(SLAPD_MD5,1)
 880 fi
 881 if test $ol_enable_sha1 != no ; then
 882         AC_DEFINE(SLAPD_SHA1,1)
 883 fi
 884 if test $ol_enable_phonetic != no ; then
 885         AC_DEFINE(SLAPD_PHONETIC,1)
 886 fi
 887 if test $ol_enable_rlookups != no ; then
 888         AC_DEFINE(SLAPD_RLOOKUPS,1)
 889 fi
 890
 891 if test $ol_link_ldbm != no ; then
 892         AC_DEFINE(SLAPD_LDBM,1)
 893         BUILD_SLAPD=yes
 894         BUILD_LDBM=yes
 895 fi
 896
 897 if test $ol_enable_passwd != no ; then
 898         AC_DEFINE(SLAPD_PASSWD,1)
 899         BUILD_SLAPD=yes
 900         BUILD_PASSWD=yes
 901 fi
 902
 903 if test $ol_enable_shell != no ; then
 904         AC_DEFINE(SLAPD_SHELL,1)
 905         BUILD_SLAPD=yes
 906         BUILD_SHELL=yes
 907 fi
 908
 909 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
 910         $BUILD_SLAPD = yes ; then
 911         BUILD_SLURPD=yes
 912 fi
 913
 914 dnl ----------------------------------------------------------------
 915
 916 AC_SUBST(BUILD_LDAPD)
 917 AC_SUBST(BUILD_SLAPD)
 918   AC_SUBST(BUILD_LDBM)
 919   AC_SUBST(BUILD_PASSWD)
 920   AC_SUBST(BUILD_SHELL)
 921 AC_SUBST(BUILD_SLURPD)
 922
 923
 924 AC_SUBST(LDAP_LIBS)
 925 AC_SUBST(LDAPD_LIBS)
 926 AC_SUBST(SLAPD_LIBS)
 927 AC_SUBST(SLURPD_LIBS)
 928 AC_SUBST(LDBM_LIBS)
 929 AC_SUBST(LTHREAD_LIBS)
 930 AC_SUBST(LUTIL_LIBS)
 931
 932 AC_SUBST(KRB_LIBS)
 933 AC_SUBST(TERMCAP_LIBS)
 934
 935 dnl ----------------------------------------------------------------
 936 dnl final output
 937 dnl
 938
 939 dnl AC_OUTPUT( \
 940 dnl contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
 941 dnl contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
 942 dnl contrib/whois++/Makefile:build/top.mk:contrib/whois++/Makefile.in:build/rules.mk \
 943 dnl [date > stamp-h])
 944
 945 AC_OUTPUT( \
 946 Makefile:build/top.mk:Makefile.in:build/dir.mk \
 947 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
 948 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
 949 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
 950 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
 951 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
 952 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
 953 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
 954 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
 955 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
 956 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
 957 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
 958 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
 959 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
 960 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
 961 include/Makefile:build/top.mk:include/Makefile.in \
 962 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
 963 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk \
 964 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk \
 965 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk \
 966 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk \
 967 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk \
 968 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk \
 969 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk \
 970 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
 971 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
 972 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
 973 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
 974 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
 975 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
 976 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
 977 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
 978 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
 979 tests/Makefile:build/top.mk:tests/Makefile.in \
 980 ,[
 981 date > stamp-h
 982 echo Please \"make depend\" to build dependencies
 983 ])