git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl This work is part of OpenLDAP Software <http://www.openldap.org/>.
   3 dnl
   4 dnl Copyright 1998-2007 The OpenLDAP Foundation.
   5 dnl All rights reserved.
   6 dnl
   7 dnl Redistribution and use in source and binary forms, with or without
   8 dnl modification, are permitted only as authorized by the OpenLDAP
   9 dnl Public License.
  10 dnl
  11 dnl A copy of this license is available in the file LICENSE in the
  12 dnl top-level directory of the distribution or, alternatively, at
  13 dnl <http://www.OpenLDAP.org/license.html>.
  14 dnl
  15 dnl ----------------------------------------------------------------
  16 dnl Disable config.cache!
  17 define([AC_CACHE_LOAD], )dnl
  18 define([AC_CACHE_SAVE], )dnl
  19 dnl ----------------------------------------------------------------
  20 dnl Disable libtool 1.5 support for languages we don't use
  21 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  22 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  23 define([AC_LIBTOOL_LANG_GCJ_CONFIG], [:])dnl
  24 dnl ================================================================
  25 dnl Configure.in for OpenLDAP
  26 AC_COPYRIGHT([[Copyright 1998-2007 The OpenLDAP Foundation. All rights reserved.
  27 Restrictions apply, see COPYRIGHT and LICENSE files.]])
  28 AC_REVISION([$OpenLDAP$])
  29 AC_INIT([OpenLDAP],,[http://www.openldap.org/its/])
  30 m4_define([AC_PACKAGE_BUGREPORT],[<http://www.openldap.org/its/>])
  31 AC_CONFIG_SRCDIR(build/version.sh)dnl
  32 dnl ----------------------------------------------------------------
  33 dnl OpenLDAP Autoconf Macros
  34 builtin(include, build/openldap.m4)dnl
  35 dnl ================================================================
  36
  37 AC_CONFIG_AUX_DIR(build)dnl
  38
  39 eval `$ac_aux_dir/version.sh`
  40 if test -z "$OL_STRING"; then
  41         AC_MSG_ERROR([could not determine version])
  42 fi
  43
  44 if test -f "$ac_aux_dir/shtool" && test ! -d $ac_aux_dir/shtool; then
  45         ac_cv_shtool="$ac_aux_dir/shtool"
  46 else
  47         AC_MSG_ERROR([no shtool found in $ac_aux_dir])
  48 fi
  49
  50 SHTOOL="$ac_cv_shtool"
  51 dnl AC_SUBST(SHTOOL)dnl
  52
  53 TB="" TN=""
  54 if test -t 1; then
  55         TB="`$SHTOOL echo -e '%B' 2>/dev/null`"
  56         TN="`$SHTOOL echo -e '%b' 2>/dev/null`"
  57 fi
  58
  59 OPENLDAP_CVS=""
  60 if test -d $ac_aux_dir/CVS; then
  61         OPENLDAP_CVS="(from CVS sources) "
  62 fi
  63
  64 echo "Configuring ${TB}${OL_STRING}${TN} ${OPENLDAP_CVS}..."
  65
  66 dnl Determine host platform
  67 dnl             we try not to use this for much
  68 AC_CANONICAL_TARGET([])
  69
  70 AM_INIT_AUTOMAKE([$OL_PACKAGE],[$OL_VERSION], [no defines])dnl
  71 AC_SUBST(PACKAGE)dnl
  72 AC_SUBST(VERSION)dnl
  73 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  74 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  75
  76 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION,$OL_API_INC,Version)
  77 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MAJOR,$OL_MAJOR,Major)
  78 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MINOR,$OL_MINOR,Minor)
  79 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_PATCH,$OL_PATCH,Patch)
  80
  81 OPENLDAP_LIBRELEASE=$OL_API_LIB_RELEASE
  82 AC_SUBST(OPENLDAP_LIBRELEASE)dnl
  83
  84 OPENLDAP_LIBVERSION=$OL_API_LIB_VERSION
  85 AC_SUBST(OPENLDAP_LIBVERSION)dnl
  86
  87 OPENLDAP_RELEASE_DATE="$OL_RELEASE_DATE"
  88 AC_SUBST(OPENLDAP_RELEASE_DATE)dnl
  89
  90 dnl We use autoconf features new to 2.59.  Later versions like won't work.
  91 dnl aclocal.m4 should be built using aclocal from automake 1.5
  92 dnl libtool 1.5 should be installed.
  93 AC_PREREQ(2.59)dnl Required Autoconf version
  94
  95 AH_TOP([
  96 /* begin of portable.h.pre */
  97 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
  98  *
  99  * Copyright 1998-2007 The OpenLDAP Foundation
 100  * All rights reserved.
 101  *
 102  * Redistribution and use in source and binary forms, with or without
 103  * modification, are permitted only as authorized by the OpenLDAP
 104  * Public License.
 105  *
 106  * A copy of this license is available in the file LICENSE in the
 107  * top-level directory of the distribution or, alternatively, at
 108  * <http://www.OpenLDAP.org/license.html>.
 109  */
 110
 111 #ifndef _LDAP_PORTABLE_H
 112 #define _LDAP_PORTABLE_H
 113
 114 /* define this if needed to get reentrant functions */
 115 #ifndef REENTRANT
 116 #undef REENTRANT
 117 #endif
 118 #ifndef _REENTRANT
 119 #undef _REENTRANT
 120 #endif
 121
 122 /* define this if needed to get threadsafe functions */
 123 #ifndef THREADSAFE
 124 #undef THREADSAFE
 125 #endif
 126 #ifndef _THREADSAFE
 127 #undef _THREADSAFE
 128 #endif
 129 #ifndef THREAD_SAFE
 130 #undef THREAD_SAFE
 131 #endif
 132 #ifndef _THREAD_SAFE
 133 #undef _THREAD_SAFE
 134 #endif
 135
 136 #ifndef _SGI_MP_SOURCE
 137 #undef _SGI_MP_SOURCE
 138 #endif
 139
 140 /* end of portable.h.pre */
 141 ])
 142 AH_BOTTOM([
 143 /* begin of portable.h.post */
 144
 145 #ifdef _WIN32
 146         /* don't suck in all of the win32 api */
 147 #       define WIN32_LEAN_AND_MEAN 1
 148 #endif
 149
 150 #ifndef LDAP_NEEDS_PROTOTYPES
 151 /* force LDAP_P to always include prototypes */
 152 #define LDAP_NEEDS_PROTOTYPES 1
 153 #endif
 154
 155 #ifndef LDAP_REL_ENG
 156 #if (LDAP_VENDOR_VERSION == 000000) && !defined(LDAP_DEVEL)
 157 #define LDAP_DEVEL
 158 #endif
 159 #if defined(LDAP_DEVEL) && !defined(LDAP_TEST)
 160 #define LDAP_TEST
 161 #endif
 162 #endif
 163
 164 #ifdef HAVE_STDDEF_H
 165 #       include <stddef.h>
 166 #endif
 167
 168 #ifdef HAVE_EBCDIC
 169 /* ASCII/EBCDIC converting replacements for stdio funcs
 170  * vsnprintf and snprintf are used too, but they are already
 171  * checked by the configure script
 172  */
 173 #define fputs ber_pvt_fputs
 174 #define fgets ber_pvt_fgets
 175 #define printf ber_pvt_printf
 176 #define fprintf ber_pvt_fprintf
 177 #define vfprintf ber_pvt_vfprintf
 178 #define vsprintf ber_pvt_vsprintf
 179 #endif
 180
 181 #include "ac/fdset.h"
 182
 183 #include "ldap_cdefs.h"
 184 #include "ldap_features.h"
 185
 186 #include "ac/assert.h"
 187 #include "ac/localize.h"
 188
 189 #endif /* _LDAP_PORTABLE_H */
 190 /* end of portable.h.post */
 191 ])
 192
 193 AC_CONFIG_HEADERS([include/portable.h:include/portable.hin])
 194 AC_CONFIG_HEADERS([include/ldap_features.h:include/ldap_features.hin])
 195 AC_CONFIG_HEADERS([include/lber_types.h:include/lber_types.hin])
 196
 197 dnl ================================================================
 198 dnl Start Args
 199 AC_MSG_CHECKING(configure arguments)
 200 AC_PREFIX_DEFAULT(/usr/local)
 201
 202 top_builddir=`pwd`
 203 AC_SUBST(top_builddir)dnl
 204
 205 dnl ----------------------------------------------------------------
 206 dnl --with-subdir
 207 ldap_subdir="/openldap"
 208
 209 AC_ARG_WITH(subdir,
 210 [  --with-subdir=DIR       change default subdirectory used for installs],
 211 [case "$withval" in
 212         no) ldap_subdir=""
 213                 ;;
 214         yes)
 215                 ;;
 216         /*|\\*)
 217                 ldap_subdir="$withval"
 218                 ;;
 219         *)
 220                 ldap_subdir="/$withval"
 221                 ;;
 222 esac
 223 ])dnl
 224
 225 AC_SUBST(ldap_subdir)dnl
 226
 227 dnl ----------------------------------------------------------------
 228 dnl General "enable" options
 229 dnl set default to traditional to enable the original debug style
 230 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes, [no yes traditional])dnl
 231 OL_ARG_ENABLE(dynamic,[  --enable-dynamic         enable linking built binaries with dynamic libs], no)dnl
 232 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 233 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 234 dnl OL_ARG_ENABLE(referrals,[  --enable-referrals         enable LDAPv2+ Referrals (experimental)], no)dnl
 235 ol_enable_referrals=${ol_enable_referrals-no}
 236 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 237 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 238
 239 dnl ----------------------------------------------------------------
 240 dnl General "with" options
 241 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 242         auto, [auto yes no] )
 243 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch(3) URL support],
 244         auto, [auto yes no] )
 245 OL_ARG_WITH(threads,[  --with-threads     with threads],
 246         auto, [auto nt posix mach pth lwp yes no manual] )
 247 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support auto|openssl|gnutls],
 248         auto, [auto openssl gnutls yes no] )
 249 OL_ARG_WITH(yielding_select,
 250         [  --with-yielding-select  with implicitly yielding select],
 251         auto, [auto yes no manual] )
 252 OL_ARG_WITH(mp,
 253         [  --with-mp               with multiple precision statistics auto|longlong|long|bignum|gmp],
 254         auto, [auto longlong long bignum gmp yes no])
 255 OL_ARG_WITH(odbc,
 256         [  --with-odbc             with specific ODBC support iodbc|unixodbc|auto],
 257         auto, [auto iodbc unixodbc] )
 258
 259 dnl ----------------------------------------------------------------
 260 dnl Server options
 261 dnl ----------------------------------------------------------------
 262
 263 dnl ----------------------------------------------------------------
 264 dnl SLAPD OPTIONS
 265 AC_ARG_ENABLE(xxslapdoptions,[
 266 SLAPD (Standalone LDAP Daemon) Options:])
 267 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 268 OL_ARG_ENABLE(dynacl,[    --enable-dynacl         enable run-time loadable ACL support (experimental)], no)dnl
 269 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs (experimental)], no, [no yes mod])dnl
 270 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 271 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], no)dnl
 272 OL_ARG_ENABLE(lmpasswd,[    --enable-lmpasswd     enable LAN Manager passwords], no)dnl
 273 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 274 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 275 OL_ARG_ENABLE(rewrite,[    --enable-rewrite       enable DN rewriting in back-ldap and rwm overlay], auto)dnl
 276 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups of client hostnames], no)dnl
 277 OL_ARG_ENABLE(slapi,[    --enable-slapi        enable SLAPI support (experimental)], no)dnl
 278 OL_ARG_ENABLE(slp,[    --enable-slp          enable SLPv2 support], no)dnl
 279 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 280
 281 dnl ----------------------------------------------------------------
 282 dnl SLAPD Backend Options
 283 Backends="bdb \
 284         dnssrv \
 285         hdb \
 286         ldap \
 287         meta \
 288         monitor \
 289         null \
 290         passwd \
 291         perl \
 292         relay \
 293         shell \
 294         sql"
 295
 296 AC_ARG_ENABLE(xxslapbackends,[
 297 SLAPD Backend Options:])
 298
 299 OL_ARG_ENABLE(backends,[    --enable-backends     enable all available backends],
 300         --, [no yes mod])dnl
 301 OL_ARG_ENABLE(bdb,[    --enable-bdb       enable Berkeley DB backend],
 302         yes, [no yes mod], ol_enable_backends)dnl
 303 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend],
 304         no, [no yes mod], ol_enable_backends)dnl
 305 OL_ARG_ENABLE(hdb,[    --enable-hdb       enable Hierarchical DB backend],
 306         yes, [no yes mod], ol_enable_backends)dnl
 307 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend],
 308         no, [no yes mod], ol_enable_backends)dnl
 309 OL_ARG_ENABLE(meta,[    --enable-meta     enable metadirectory backend],
 310         no, [no yes mod], ol_enable_backends)dnl
 311 OL_ARG_ENABLE(monitor,[    --enable-monitor       enable monitor backend],
 312         yes, [no yes mod], ol_enable_backends)dnl
 313 OL_ARG_ENABLE(null,[    --enable-null     enable null backend],
 314         no, [no yes mod], ol_enable_backends)dnl
 315 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend],
 316         no, [no yes mod], ol_enable_backends)dnl
 317 OL_ARG_ENABLE(perl,[    --enable-perl     enable perl backend],
 318         no, [no yes mod], ol_enable_backends)dnl
 319 OL_ARG_ENABLE(relay,[    --enable-relay           enable relay backend],
 320         yes, [no yes mod], ol_enable_backends)dnl
 321 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend],
 322         no, [no yes mod], ol_enable_backends)dnl
 323 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend],
 324         no, [no yes mod], ol_enable_backends)dnl
 325
 326 dnl ----------------------------------------------------------------
 327 dnl SLAPD Overlay Options
 328 Overlays="accesslog \
 329         auditlog \
 330         constraint \
 331         dds \
 332         dyngroup \
 333         dynlist \
 334         memberof \
 335         ppolicy \
 336         proxycache \
 337         refint \
 338         retcode \
 339         rwm \
 340         seqmod \
 341         syncprov \
 342         translucent \
 343         unique \
 344         valsort"
 345
 346 AC_ARG_ENABLE(xxslapoverlays,[
 347 SLAPD Overlay Options:])
 348
 349 OL_ARG_ENABLE(overlays,[    --enable-overlays     enable all available overlays],
 350         --, [no yes mod])dnl
 351 OL_ARG_ENABLE(accesslog,[    --enable-accesslog   In-Directory Access Logging overlay],
 352         no, [no yes mod], ol_enable_overlays)
 353 OL_ARG_ENABLE(auditlog,[    --enable-auditlog     Audit Logging overlay],
 354         no, [no yes mod], ol_enable_overlays)
 355 OL_ARG_ENABLE(constraint,[    --enable-constraint         Attribute Constraint overlay],
 356         no, [no yes mod], ol_enable_overlays)
 357 OL_ARG_ENABLE(dds,[    --enable-dds       Dynamic Directory Services overlay],
 358         no, [no yes mod], ol_enable_overlays)
 359 OL_ARG_ENABLE(dyngroup,[    --enable-dyngroup     Dynamic Group overlay],
 360         no, [no yes mod], ol_enable_overlays)
 361 OL_ARG_ENABLE(dynlist,[    --enable-dynlist       Dynamic List overlay],
 362         no, [no yes mod], ol_enable_overlays)
 363 OL_ARG_ENABLE(memberof,[    --enable-memberof     Reverse Group Membership overlay],
 364         no, [no yes mod], ol_enable_overlays)
 365 OL_ARG_ENABLE(ppolicy,[    --enable-ppolicy       Password Policy overlay],
 366         no, [no yes mod], ol_enable_overlays)
 367 OL_ARG_ENABLE(proxycache,[    --enable-proxycache         Proxy Cache overlay],
 368         no, [no yes mod], ol_enable_overlays)
 369 OL_ARG_ENABLE(refint,[    --enable-refint         Referential Integrity overlay],
 370         no, [no yes mod], ol_enable_overlays)
 371 OL_ARG_ENABLE(retcode,[    --enable-retcode       Return Code testing overlay],
 372         no, [no yes mod], ol_enable_overlays)
 373 OL_ARG_ENABLE(rwm,[    --enable-rwm               Rewrite/Remap overlay],
 374         no, [no yes mod], ol_enable_overlays)
 375 OL_ARG_ENABLE(seqmod,[    --enable-seqmod         Sequential Modify overlay],
 376         yes, [no yes mod], ol_enable_overlays)
 377 OL_ARG_ENABLE(syncprov,[    --enable-syncprov     Syncrepl Provider overlay],
 378         yes, [no yes mod], ol_enable_overlays)
 379 OL_ARG_ENABLE(translucent,[    --enable-translucent  Translucent Proxy overlay],
 380         no, [no yes mod], ol_enable_overlays)
 381 OL_ARG_ENABLE(unique,[    --enable-unique       Attribute Uniqueness overlay],
 382         no, [no yes mod], ol_enable_overlays)
 383 OL_ARG_ENABLE(valsort,[    --enable-valsort      Value Sorting overlay],
 384         no, [no yes mod], ol_enable_overlays)
 385
 386 dnl ----------------------------------------------------------------
 387 AC_ARG_ENABLE(xxliboptions,[
 388 Library Generation & Linking Options])
 389 AC_ENABLE_STATIC
 390 AC_ENABLE_SHARED
 391
 392 dnl ----------------------------------------------------------------
 393
 394 # validate options
 395 if test $ol_enable_slapd = no ; then
 396         dnl SLAPD was specificallly disabled
 397         if test $ol_enable_slapi = yes ; then
 398                 AC_MSG_WARN([slapd disabled, ignoring --enable-slapi argument])
 399         fi
 400         case "$ol_enable_backends" in yes | mod)
 401                 AC_MSG_WARN([slapd disabled, ignoring --enable-backends argument])
 402         esac
 403         for i in $Backends; do
 404                 eval "ol_tmp=\$ol_enable_$i"
 405                 if test $ol_tmp != no ; then
 406                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 407                         eval "ol_enable_$i=no"
 408                 fi
 409         done
 410         if test $ol_enable_modules = yes ; then
 411                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 412         fi
 413         if test $ol_enable_wrappers = yes ; then
 414                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 415         fi
 416         if test $ol_enable_rlookups = yes ; then
 417                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 418         fi
 419         if test $ol_enable_dynacl = yes ; then
 420                 AC_MSG_WARN([slapd disabled, ignoring --enable-dynacl argument])
 421         fi
 422         if test $ol_enable_aci != no ; then
 423                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 424         fi
 425         if test $ol_enable_rewrite = yes ; then
 426                 AC_MSG_WARN([slapd disabled, ignoring --enable-rewrite argument])
 427         fi
 428         dnl overlays
 429         case "$ol_enable_overlays" in yes | mod)
 430                 AC_MSG_WARN([slapd disabled, ignoring --enable-overlays argument])
 431         esac
 432         for i in $Overlays; do
 433                 eval "ol_tmp=\$ol_enable_$i"
 434                 if test $ol_tmp != no ; then
 435                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 436                         eval "ol_enable_$i=no"
 437                 fi
 438         done
 439
 440         # force settings to no
 441         ol_enable_slapi=no
 442
 443         ol_enable_backends=
 444         ol_enable_overlays=
 445         ol_enable_modules=no
 446         ol_enable_rlookups=no
 447         ol_enable_dynacl=no
 448         ol_enable_aci=no
 449         ol_enable_wrappers=no
 450
 451         ol_enable_rewrite=no
 452
 453 elif test $ol_enable_modules != yes &&
 454         test $ol_enable_bdb = no &&
 455         test $ol_enable_dnssrv = no &&
 456         test $ol_enable_hdb = no &&
 457         test $ol_enable_ldap = no &&
 458         test $ol_enable_meta = no &&
 459         test $ol_enable_monitor = no &&
 460         test $ol_enable_null = no &&
 461         test $ol_enable_passwd = no &&
 462         test $ol_enable_perl = no &&
 463         test $ol_enable_relay = no &&
 464         test $ol_enable_shell = no &&
 465         test $ol_enable_sql = no ; then
 466         dnl no slapd backend
 467
 468         if test $ol_enable_slapd = yes ; then
 469                 AC_MSG_ERROR([slapd requires a backend])
 470         else
 471                 AC_MSG_WARN([skipping slapd, no backend specified])
 472                 ol_enable_slapd=no
 473         fi
 474 fi
 475
 476 if test $ol_enable_meta/$ol_enable_ldap = yes/no ; then
 477         AC_MSG_ERROR([--enable-meta requires --enable-ldap])
 478 fi
 479
 480 if test $ol_enable_lmpasswd = yes ; then
 481         if test $ol_with_tls = no ; then
 482                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
 483         fi
 484 fi
 485
 486 if test $ol_enable_spasswd = yes ; then
 487         if test $ol_with_cyrus_sasl = no ; then
 488                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 489         fi
 490         ol_with_cyrus_sasl=yes
 491 fi
 492
 493 AC_MSG_RESULT(done)
 494
 495 dnl ----------------------------------------------------------------
 496 dnl Initialize vars
 497 LDAP_LIBS=
 498 BDB_LIBS=
 499 LTHREAD_LIBS=
 500 LUTIL_LIBS=
 501
 502 SLAPD_LIBS=
 503
 504 BUILD_SLAPD=no
 505
 506 BUILD_THREAD=no
 507
 508 BUILD_SLAPI=no
 509 SLAPD_SLAPI_DEPEND=
 510
 511 BUILD_BDB=no
 512 BUILD_DNSSRV=no
 513 BUILD_HDB=no
 514 BUILD_LDAP=no
 515 BUILD_META=no
 516 BUILD_MONITOR=no
 517 BUILD_NULL=no
 518 BUILD_PASSWD=no
 519 BUILD_PERL=no
 520 BUILD_RELAY=no
 521 BUILD_SHELL=no
 522 BUILD_SQL=no
 523
 524 BUILD_ACCESSLOG=no
 525 BUILD_AUDITLOG=no
 526 BUILD_CONSTRAINT=no
 527 BUILD_DDS=no
 528 BUILD_DENYOP=no
 529 BUILD_DYNGROUP=no
 530 BUILD_DYNLIST=no
 531 BUILD_LASTMOD=no
 532 BUILD_MEMBEROF=no
 533 BUILD_PPOLICY=no
 534 BUILD_PROXYCACHE=no
 535 BUILD_REFINT=no
 536 BUILD_RETCODE=no
 537 BUILD_RWM=no
 538 BUILD_SEQMOD=no
 539 BUILD_SYNCPROV=no
 540 BUILD_TRANSLUCENT=no
 541 BUILD_UNIQUE=no
 542 BUILD_VALSORT=no
 543
 544 SLAPD_STATIC_OVERLAYS=
 545 SLAPD_DYNAMIC_OVERLAYS=
 546
 547 SLAPD_MODULES_LDFLAGS=
 548 SLAPD_MODULES_CPPFLAGS=
 549
 550 SLAPD_STATIC_BACKENDS=back-ldif
 551 SLAPD_DYNAMIC_BACKENDS=
 552
 553 SLAPD_PERL_LDFLAGS=
 554 MOD_PERL_LDFLAGS=
 555 PERL_CPPFLAGS=
 556
 557 SLAPD_SQL_LDFLAGS=
 558 SLAPD_SQL_LIBS=
 559 SLAPD_SQL_INCLUDES=
 560
 561 KRB4_LIBS=
 562 KRB5_LIBS=
 563 SASL_LIBS=
 564 TLS_LIBS=
 565 MODULES_LIBS=
 566 SLAPI_LIBS=
 567 LIBSLAPI=
 568 LIBSLAPITOOLS=
 569 AUTH_LIBS=
 570 ICU_LIBS=
 571
 572 SLAPD_SLP_LIBS=
 573 SLAPD_GMP_LIBS=
 574
 575 dnl ================================================================
 576 dnl Checks for programs
 577
 578 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 579
 580 dnl ----------------------------------------------------------------
 581 dnl
 582 dnl Determine which C translator to use
 583 dnl
 584
 585 dnl AIX Thread requires we use cc_r or xlc_r.
 586 dnl But only do this IF AIX and CC is not set
 587 dnl and threads are auto|yes|posix.
 588 dnl
 589 dnl If we find cc_r|xlc_r, force pthreads and assume
 590 dnl             pthread_create is in $LIBS (ie: don't bring in
 591 dnl             any additional thread libraries)
 592 dnl If we do not find cc_r|xlc_r, disable threads
 593
 594 ol_aix_threads=no
 595 case "$target" in
 596 *-*-aix*) dnl all AIX is not a good idea.
 597         if test -z "$CC" ; then
 598                 case "$ol_with_threads" in
 599                 auto | yes |  posix) ol_aix_threads=yes ;;
 600                 esac
 601         fi
 602 ;;
 603 esac
 604
 605 if test $ol_aix_threads = yes ; then
 606         if test -z "${CC}" ; then
 607                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 608
 609                 if test "$CC" = cc ; then
 610                         dnl no CC! don't allow --with-threads
 611                         if test $ol_with_threads != auto ; then
 612                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 613                         else
 614                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 615                         fi
 616                         ol_with_threads=no
 617                 fi
 618         fi
 619
 620         case ${CC} in cc_r | xlc_r)
 621                 ol_with_threads=posix
 622                 ol_cv_pthread_create=yes
 623                 ;;
 624         esac
 625 fi
 626
 627 if test -z "${CC}"; then
 628         AC_CHECK_PROGS(CC,cc gcc,missing)
 629
 630         if test "${CC}" = "missing" ; then
 631                 AC_MSG_ERROR([Unable to locate cc(1) or suitable replacement.  Check PATH or set CC.])
 632         fi
 633 fi
 634
 635 if test -z "${AR}"; then
 636         AC_CHECK_PROGS(AR,ar gar,missing)
 637
 638         if test "${AR}" = "missing" ; then
 639                 AC_MSG_ERROR([Unable to locate ar(1) or suitable replacement.  Check PATH or set AR.])
 640         fi
 641 fi
 642
 643 AC_LIBTOOL_WIN32_DLL
 644 AC_LIBTOOL_DLOPEN
 645 AC_PROG_LIBTOOL
 646
 647 dnl ----------------------------------------------------------------
 648 dnl Perl
 649 ol_link_perl=no
 650 if test $ol_enable_perl != no ; then
 651         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 652
 653         if test "no$PERLBIN" = "no" ; then
 654                 if test $ol_enable_perl = yes ; then
 655                         AC_MSG_ERROR([could not locate perl])
 656                 fi
 657
 658         else
 659                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 660                 PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e 's/ -lc / /' -e 's/ -lc$//'`"
 661
 662                 if test x"$ol_enable_perl" = "xyes" ; then
 663                         SLAPD_PERL_LDFLAGS="$PERL_LDFLAGS"
 664                 else
 665                         MOD_PERL_LDFLAGS="$PERL_LDFLAGS"
 666                 fi
 667                 dnl should check perl version
 668                 ol_link_perl=yes
 669         fi
 670 fi
 671
 672 AC_PROG_CPP
 673
 674 dnl ----------------------------------------------------------------
 675 dnl Checks for Windows NT
 676 case $host_os in
 677   *mingw32* ) ac_cv_mingw32=yes ;;
 678   *cygwin* ) ac_cv_cygwin=yes ;;
 679 esac
 680
 681 dnl ----------------------------------------------------------------
 682 dnl Checks for file extensions
 683 AC_EXEEXT
 684 AC_OBJEXT
 685 AC_DEFINE_UNQUOTED(EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 686
 687 dnl ----------------------------------------------------------------
 688 dnl BeOS requires -lbe -lroot -lnet
 689 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 690
 691 dnl ----------------------------------------------------------------
 692 dnl OpenLDAP requires STDC features
 693 AC_PROG_CC
 694 if test "X${ac_cv_prog_cc_stdc}" = "Xno" ; then
 695         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 696 fi
 697
 698 dnl ----------------------------------------------------------------
 699 dnl Check cc depend flags
 700 OL_MKDEPEND
 701 if test "${ol_cv_mkdep}" = no ; then
 702         # this will soon become an error
 703         AC_MSG_WARN([do not know how to generate dependencies])
 704 fi
 705
 706 dnl ----------------------------------------------------------------
 707 dnl Check for AIX security library
 708 AC_CHECK_LIB(s, afopen, [
 709         AUTH_LIBS=-ls
 710         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 711 ])
 712
 713 dnl ----------------------------------------------------------------
 714 dnl Check for IBM OS/390
 715 case "$target" in
 716 *-ibm-openedition)
 717         ac_cv_func_getopt=no
 718         AC_DEFINE(BOTH_STRINGS_H,1,[define to use both <string.h> and <strings.h>])
 719         ;;
 720 esac
 721
 722 dnl ----------------------------------------------------------------
 723 dnl Check for module support
 724 ol_link_modules=no
 725 WITH_MODULES_ENABLED=no
 726 if test $ol_enable_modules != no ; then
 727         AC_CHECK_HEADERS(ltdl.h)
 728
 729         if test $ac_cv_header_ltdl_h = no ; then
 730                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 731         fi
 732
 733         AC_CHECK_LIB(ltdl, lt_dlinit, [
 734                 MODULES_LIBS=-lltdl
 735                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 736         ])
 737
 738         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 739                 AC_MSG_ERROR([could not locate libtool -lltdl])
 740         fi
 741         ol_link_modules=yes
 742         WITH_MODULES_ENABLED=yes
 743
 744 else
 745         for i in $Backends; do
 746                 eval "ol_tmp=\$ol_enable_$i"
 747                 if test $ol_tmp = mod ; then
 748                         AC_MSG_WARN([building static $i backend])
 749                         eval "ol_enable_$i=yes"
 750                 fi
 751         done
 752         for i in $Overlays; do
 753                 eval "ol_tmp=\$ol_enable_$i"
 754                 if test $ol_tmp = mod ; then
 755                         AC_MSG_WARN([building static $i overlay])
 756                         eval "ol_enable_$i=yes"
 757                 fi
 758         done
 759 fi
 760
 761 dnl ----------------------------------------------------------------
 762 dnl Checks for header files.
 763 OL_HEADER_STDC
 764
 765 if test $ol_cv_header_stdc != yes; then
 766         AC_MSG_WARN([could not locate Standard C compliant headers])
 767 fi
 768
 769 AC_HEADER_DIRENT
 770 AC_HEADER_SYS_WAIT
 771 AC_HEADER_TIOCGWINSZ
 772
 773 AC_CHECK_HEADERS(       \
 774         arpa/inet.h             \
 775         arpa/nameser.h  \
 776         assert.h                \
 777         bits/types.h    \
 778         conio.h                 \
 779         crypt.h                 \
 780         direct.h                \
 781         errno.h                 \
 782         fcntl.h                 \
 783         filio.h                 \
 784         getopt.h                \
 785         grp.h                   \
 786         io.h                    \
 787         libutil.h               \
 788         limits.h                \
 789         locale.h                \
 790         malloc.h                \
 791         memory.h                \
 792         psap.h                  \
 793         pwd.h                   \
 794         process.h               \
 795         sgtty.h                 \
 796         shadow.h                \
 797         stddef.h                \
 798         string.h                \
 799         strings.h               \
 800         sysexits.h              \
 801         sys/file.h              \
 802         sys/filio.h             \
 803         sys/fstyp.h             \
 804         sys/errno.h             \
 805         sys/ioctl.h             \
 806         sys/param.h             \
 807         sys/privgrp.h   \
 808         sys/resource.h  \
 809         sys/select.h    \
 810         sys/socket.h    \
 811         sys/stat.h              \
 812         sys/syslog.h    \
 813         sys/time.h              \
 814         sys/types.h             \
 815         sys/uio.h               \
 816         sys/vmount.h    \
 817         syslog.h                \
 818         termios.h               \
 819         unistd.h                \
 820         utime.h                 \
 821 )
 822
 823 dnl Only check Winsock on MinGW
 824 if test "$ac_cv_mingw32" = yes ; then
 825         AC_CHECK_HEADERS( winsock.h winsock2.h )
 826 fi
 827
 828 AC_CHECK_HEADERS( resolv.h, [], [],
 829 [$ac_includes_default
 830 #include <netinet/in.h>
 831 ])
 832
 833 AC_CHECK_HEADERS( netinet/tcp.h, [], [],
 834 [$ac_includes_default
 835 #include <netinet/in.h>
 836 ])
 837
 838 AC_CHECK_HEADERS( sys/ucred.h, [], [],
 839 [$ac_includes_default
 840 #ifdef HAVE_SYS_PARAM_H
 841 #include <sys/param.h>
 842 #endif
 843 ])
 844
 845 dnl ----------------------------------------------------------------
 846 dnl Checks for libraries
 847
 848 AC_CHECK_FUNCS( sigaction sigset )
 849
 850 dnl HP-UX requires -lV3
 851 dnl this is not needed on newer versions of HP-UX
 852 if test $ac_cv_func_sigaction = no && test $ac_cv_func_sigaction = no ; then
 853         AC_CHECK_LIB(V3, sigset)
 854 fi
 855
 856 dnl The following is INTENTIONALLY scripted out because shell does not
 857 dnl support variable names with the '@' character, which is what
 858 dnl autoconf would try to generate if one merely used AC_SEARCH_LIBS
 859 if test "$ac_cv_header_winsock_h" = yes; then
 860 AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 861 save_LIBS="$LIBS"
 862 for curlib in ws2_32 wsock32; do
 863         LIBS="$LIBS -l$curlib"
 864         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <winsock.h>
 865                         ]], [[
 866                         socket(0,0,0);
 867                         select(0,NULL,NULL,NULL,NULL);
 868                         closesocket(0);
 869                         gethostname(NULL,0);
 870                         ]])],[ol_cv_winsock=yes],[ol_cv_winsock=no])
 871
 872         if test $ol_cv_winsock = yes; then
 873                 AC_DEFINE(HAVE_WINSOCK, 1, [define if you have winsock])
 874                 ac_cv_func_socket=yes
 875                 ac_cv_func_select=yes
 876                 ac_cv_func_closesocket=yes
 877                 ac_cv_func_gethostname=yes
 878                 if test $curlib = ws2_32; then
 879                         ol_cv_winsock=winsock2
 880                         AC_DEFINE(HAVE_WINSOCK2, 1,
 881                                   [define if you have winsock2])
 882                 fi
 883                 break
 884         fi
 885         LIBS="$save_LIBS"
 886 done)
 887 fi
 888
 889 dnl Find socket()
 890 dnl Likely combinations:
 891 dnl             -lsocket [ -lnsl_s | -lnsl ]
 892 dnl             -linet
 893
 894 AC_CHECK_FUNC(socket, :, [
 895 dnl hopefully we won't include too many libraries
 896         AC_CHECK_LIB(socket, main)
 897         AC_CHECK_LIB(net, main)
 898         AC_CHECK_LIB(nsl_s, main)
 899         AC_CHECK_LIB(nsl, main)
 900         AC_CHECK_LIB(inet, socket)
 901         AC_CHECK_LIB(gen, main)
 902 ])
 903
 904 dnl require select
 905 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 906
 907 if test "${ac_cv_header_winsock_h}" != yes; then
 908         dnl Select arg types
 909         dnl (if this detection becomes permenent, it and the select() detection
 910         dnl should be done before the yielding select test)
 911         AC_FUNC_SELECT_ARGTYPES
 912 fi
 913
 914 dnl check to see if system call automatically restart
 915 dnl AC_SYS_RESTARTABLE_SYSCALLS
 916
 917 dnl ----------------------------------------------------------------
 918 AC_CHECK_FUNCS( poll )
 919 if test $ac_cv_func_poll = yes; then
 920 AC_CHECK_HEADERS( poll.h sys/poll.h )
 921 fi
 922
 923 dnl ----------------------------------------------------------------
 924 AC_CHECK_HEADERS( sys/epoll.h )
 925 if test "${ac_cv_header_sys_epoll_h}" = yes; then
 926         AC_MSG_CHECKING(for epoll system call)
 927         AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv)
 928 {
 929         int epfd = epoll_create(256);
 930         exit (epfd == -1 ? 1 : 0);
 931 }]])],[AC_MSG_RESULT(yes)
 932         AC_DEFINE(HAVE_EPOLL,1, [define if your system supports epoll])],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 933 fi
 934
 935 dnl ----------------------------------------------------------------
 936 AC_CHECK_HEADERS( sys/devpoll.h )
 937 dnl "/dev/poll" needs <sys/poll.h> as well...
 938 if test "${ac_cv_header_sys_devpoll_h}" = yes \
 939                 -a "${ac_cv_header_poll_h}" = yes ; \
 940 then
 941         AC_MSG_CHECKING(for /dev/poll)
 942         AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv)
 943 {
 944         int devpollfd = open("/dev/poll", /* O_RDWR */ 2);
 945         exit (devpollfd == -1 ? 1 : 0);
 946 }]])],[AC_MSG_RESULT(yes)
 947         AC_DEFINE(HAVE_DEVPOLL,1, [define if your system supports /dev/poll])],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 948 fi
 949
 950 dnl ----------------------------------------------------------------
 951 # strerror checks
 952 OL_STRERROR
 953
 954 dnl ----------------------------------------------------------------
 955 dnl require POSIX regex
 956 AC_CHECK_HEADERS( regex.h, [], [],
 957 [$ac_includes_default
 958 #ifdef HAVE_SYS_TYPES_H
 959 #include <sys/types.h>
 960 #endif
 961 ])
 962
 963 if test "$ac_cv_header_regex_h" != yes ; then
 964         AC_MSG_ERROR([POSIX regex.h required.])
 965 fi
 966 AC_SEARCH_LIBS(regfree, [regex gnuregex],
 967         :, AC_MSG_ERROR([POSIX regex required.]))
 968
 969 OL_POSIX_REGEX
 970 if test "$ol_cv_c_posix_regex" = no ; then
 971         AC_MSG_ERROR([broken POSIX regex!])
 972 fi
 973
 974 dnl ----------------------------------------------------------------
 975 dnl UUID Support
 976
 977 have_uuid=no
 978 AC_CHECK_HEADERS(sys/uuid.h)
 979 if test $ac_cv_header_sys_uuid_h = yes ; then
 980         save_LIBS="$LIBS"
 981         AC_SEARCH_LIBS([uuid_to_str], [uuid], [have_uuid=yes], :)
 982         LIBS="$save_LIBS"
 983
 984         if test have_uuid = yes ; then
 985                 AC_DEFINE(HAVE_UUID_TO_STR,1,
 986                         [define if you have uuid_to_str()])
 987
 988                 test "$ac_cv_search_uuid_to_str" = "none required" || \
 989                         SLAPD_LIBS="$SLAPD_LIBS $ac_cv_search_uuid_to_str"
 990         fi
 991 fi
 992
 993 dnl Look for uuid_generate
 994 if test $have_uuid = no ; then
 995         AC_CHECK_HEADERS(uuid/uuid.h)
 996         if test $ac_cv_header_uuid_uuid_h = yes ; then
 997                 save_LIBS="$LIBS"
 998                 AC_SEARCH_LIBS([uuid_generate], [uuid], [have_uuid=yes], :)
 999                 LIBS="$save_LIBS"
1000
1001                 if test have_uuid = yes ; then
1002                         AC_DEFINE(HAVE_UUID_GENERATE,1,
1003                                 [define if you have uuid_generate()])
1004
1005                         test "$ac_cv_search_uuid_generate" = "none required" || \
1006                                 SLAPD_LIBS="$SLAPD_LIBS $ac_cv_search_uuid_generate"
1007                 fi
1008         fi
1009 fi
1010
1011 dnl For windows, check for the need of RPCRT for UUID function support
1012 if test $have_uuid = no ; then
1013         AC_MSG_CHECKING(to see if -lrpcrt4 is needed for win32 UUID support)
1014         save_LIBS="$LIBS"
1015         LIBS="$LIBS -lrpcrt4"
1016         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1017                 int __stdcall UuidCreate(void *);
1018                 int __stdcall UuidToStringA(void *,void **);
1019                 ]], [[
1020                 UuidCreate(0);
1021                 UuidToStringA(0,0);
1022                 ]])],[need_rpcrt=yes],[need_rpcrt=no])
1023         if test $need_rpcrt = yes; then
1024                 SLAPD_LIBS="$SLAPD_LIBS -lrpcrt4"
1025         fi
1026         LIBS="$save_LIBS"
1027         AC_MSG_RESULT($need_rpcrt)
1028 fi
1029
1030 dnl ----------------------------------------------------------------
1031 dnl Check for resolver routines
1032 OL_RESOLVER_LINK
1033
1034 ol_link_dnssrv=no
1035 if test "$ol_cv_lib_resolver" != no ; then
1036         AC_DEFINE(HAVE_RES_QUERY,1,
1037                 [define if you have res_query()])
1038
1039         if test "$ol_enable_dnssrv" != no ; then
1040                 ol_link_dnssrv=yes
1041         fi
1042
1043         if test "$ol_cv_lib_resolver" != yes ; then
1044                 LIBS="$ol_cv_lib_resolver $LIBS"
1045         fi
1046 fi
1047
1048 if test "$ol_enable_dnssrv" = yes || test "$ol_enable_dnssrv" = mod ; then
1049         if test "$ol_link_dnssrv" = no ; then
1050                 AC_MSG_ERROR([DNSSRV requires res_query()])
1051         fi
1052 else
1053         ol_enable_dnssrv=no
1054 fi
1055
1056 AC_CHECK_FUNCS( hstrerror )
1057
1058 dnl ----------------------------------------------------------------
1059 dnl PF_INET6 support requires getaddrinfo and INET6_ADDRSTRLEN
1060 dnl PF_LOCAL may use getaddrinfo in available
1061 AC_CHECK_FUNCS( getaddrinfo getnameinfo gai_strerror inet_ntop )
1062
1063 ol_link_ipv6=no
1064 if test $ac_cv_func_getaddrinfo = no || test $ac_cv_func_inet_ntop = no ; then
1065         if test $ol_enable_ipv6 = yes ; then
1066                 AC_MSG_ERROR([IPv6 support requires getaddrinfo() and inet_ntop()])
1067         fi
1068 elif test $ol_enable_ipv6 != no ; then
1069         AC_CACHE_CHECK([INET6_ADDRSTRLEN],[ol_cv_inet6_addrstrlen],[
1070                 AC_EGREP_CPP(__has_inet6_addrstrlen__,[
1071 #                       include <netinet/in.h>
1072 #                       ifdef INET6_ADDRSTRLEN
1073                                 __has_inet6_addrstrlen__;
1074 #                       endif
1075                 ], [ol_cv_inet6_addrstrlen=yes], [ol_cv_inet6_addrstrlen=no])])
1076
1077
1078         AC_CACHE_CHECK([struct sockaddr_storage],ol_cv_struct_sockaddr_storage,[
1079                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1080 #include <sys/types.h>
1081 #include <sys/socket.h>
1082 ]], [[
1083                         struct sockaddr_storage ss;
1084 ]])],[ol_cv_struct_sockaddr_storage=yes],[ol_cv_struct_sockaddr_storage=no])])
1085
1086         if test $ol_cv_inet6_addrstrlen = yes &&
1087            test $ol_cv_struct_sockaddr_storage = yes ; then
1088                 ol_link_ipv6=yes
1089         elif test $ol_enable_ipv6 = yes &&
1090              test $ol_cv_inet6_addrstrlen = no ; then
1091                 AC_MSG_ERROR([IPv6 support requires INET6_ADDRSTRLEN])
1092         elif test $ol_enable_ipv6 = yes &&
1093              test $ol_cv_struct_sockaddr_storage = no ; then
1094                 AC_MSG_ERROR([IPv6 support requires struct sockaddr_storage])
1095         fi
1096 fi
1097
1098 if test $ol_enable_local != no ; then
1099         AC_CHECK_HEADERS( sys/un.h )
1100
1101         if test $ol_enable_local = auto ; then
1102                 ol_enable_local=$ac_cv_header_sys_un_h
1103         elif test $ac_cv_header_sys_un_h = no ; then
1104                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
1105         fi
1106 fi
1107
1108 dnl ----------------------------------------------------------------
1109 dnl TLS/SSL
1110
1111 if test $ol_with_tls = yes ; then
1112         ol_with_tls=auto
1113 fi
1114
1115 ol_link_tls=no
1116 if test $ol_with_tls = openssl || test $ol_with_tls = auto ; then
1117         AC_CHECK_HEADERS(openssl/ssl.h)
1118
1119         if test $ac_cv_header_openssl_ssl_h = yes ; then
1120                 AC_CHECK_LIB(ssl, SSL_library_init,
1121                         [have_openssl=yes
1122                         need_rsaref=no], [have_openssl=no],
1123                         [-lcrypto])
1124
1125                 if test $have_openssl = no ; then
1126                         AC_CHECK_LIB(ssl, ssl3_accept,
1127                                 [have_openssl=yes
1128                                 need_rsaref=yes], [have_openssl=no],
1129                                 [-lcrypto -lRSAglue -lrsaref])
1130                 fi
1131
1132                 if test $have_openssl = yes ; then
1133                         ol_with_tls=openssl
1134                         ol_link_tls=yes
1135
1136                         AC_DEFINE(HAVE_OPENSSL, 1,
1137                                 [define if you have OpenSSL])
1138
1139                         if test $need_rsaref = yes; then
1140                                 AC_DEFINE(HAVE_RSAREF, 1,
1141                                         [define if OpenSSL needs RSAref])
1142
1143                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1144                         else
1145                                 TLS_LIBS="-lssl -lcrypto"
1146                         fi
1147
1148                         OL_SSL_COMPAT
1149                         if test $ol_cv_ssl_crl_compat = yes ; then
1150                                 AC_DEFINE(HAVE_OPENSSL_CRL, 1,
1151                                         [define if you have OpenSSL with CRL checking capability])
1152                         fi
1153                 fi
1154         fi
1155 fi
1156
1157 if test $ol_link_tls = no ; then
1158         if test $ol_with_tls = gnutls || test $ol_with_tls = auto ; then
1159                 AC_CHECK_HEADERS(gnutls/gnutls.h)
1160
1161                 if test $ac_cv_header_gnutls_gnutls_h = yes ; then
1162                         AC_CHECK_LIB(gnutls, gnutls_init,
1163                                 [have_gnutls=yes], [have_gnutls=no])
1164
1165                         if test $have_gnutls = yes ; then
1166                                 ol_with_tls=gnutls
1167                                 ol_link_tls=yes
1168
1169                                 TLS_LIBS="-lgnutls"
1170
1171                                 AC_DEFINE(HAVE_GNUTLS, 1,
1172                                         [define if you have GNUtls])
1173                         fi
1174                 fi
1175         fi
1176 fi
1177
1178 WITH_TLS=no
1179 if test $ol_link_tls = yes ; then
1180         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1181         WITH_TLS=yes
1182 elif test $ol_with_tls = auto ; then
1183         AC_MSG_WARN([Could not locate TLS/SSL package])
1184         AC_MSG_WARN([TLS data protection not supported!])
1185 elif test $ol_with_tls != no ; then
1186         AC_MSG_ERROR([Could not locate TLS/SSL package])
1187 else
1188         AC_MSG_WARN([TLS data protection not supported!])
1189 fi
1190
1191 dnl ----------------------------------------------------------------
1192 dnl LAN Manger password checking requires DES from OpenSSL
1193 if test $ol_enable_lmpasswd != no; then
1194         if test $ol_link_tls != yes ; then
1195                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
1196         fi
1197
1198         AC_DEFINE(SLAPD_LMHASH, 1, [define to support LAN Manager passwords])
1199 fi
1200
1201 dnl ----------------------------------------------------------------
1202 dnl Threads?
1203 ol_link_threads=no
1204
1205 case $ol_with_threads in auto | yes | nt)
1206
1207         OL_NT_THREADS
1208
1209         if test "$ol_cv_nt_threads" = yes ; then
1210                 ol_link_threads=nt
1211                 ol_with_threads=found
1212                 ol_with_yielding_select=yes
1213
1214                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1215                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1216         fi
1217
1218         if test $ol_with_threads = nt ; then
1219                 AC_MSG_ERROR([could not locate NT Threads])
1220         fi
1221         ;;
1222 esac
1223
1224 case $ol_with_threads in auto | yes | posix)
1225
1226         AC_CHECK_HEADERS(pthread.h)
1227
1228         if test $ac_cv_header_pthread_h = yes ; then
1229                 OL_POSIX_THREAD_VERSION
1230
1231                 if test $ol_cv_pthread_version != 0 ; then
1232                         AC_DEFINE_UNQUOTED(HAVE_PTHREADS,$ol_cv_pthread_version,
1233                                 [define to pthreads API spec revision])
1234                 else
1235                         AC_MSG_ERROR([unknown pthread version])
1236                 fi
1237
1238                 # consider threads found
1239                 ol_with_threads=found
1240
1241                 OL_HEADER_LINUX_THREADS
1242                 OL_HEADER_GNU_PTH_PTHREAD_H
1243
1244                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1245                         AC_CHECK_HEADERS(sched.h)
1246                 fi
1247
1248                 dnl Now the hard part, how to link?
1249                 dnl
1250                 dnl currently supported checks:
1251                 dnl
1252                 dnl Check for no flags
1253                 dnl     pthread_create() in $LIBS
1254                 dnl
1255                 dnl Check special pthread (final) flags
1256                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1257                 dnl     pthread_create() with -kthread (FreeBSD)
1258                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1259                 dnl     pthread_create() with -pthreads (?)
1260                 dnl     pthread_create() with -mthreads (AIX)
1261                 dnl     pthread_create() with -thread (?)
1262                 dnl
1263                 dnl Check pthread (final) libraries
1264                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1265                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1266                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1267                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1268                 dnl     pthread_create() in -lpthread (many)
1269                 dnl     pthread_create() in -lc_r (FreeBSD)
1270                 dnl
1271                 dnl Check pthread (draft4) flags (depreciated)
1272                 dnl     pthread_create() with -threads (OSF/1)
1273                 dnl
1274                 dnl Check pthread (draft4) libraries (depreciated)
1275                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1276                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1277                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1278                 dnl     pthread_create() in -lpthreads (many)
1279                 dnl
1280
1281                 dnl pthread_create in $LIBS
1282                 AC_CACHE_CHECK([for pthread_create in default libraries],
1283                         ol_cv_pthread_create,[
1284                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1285                                 [ol_cv_pthread_create=yes],
1286                                 [ol_cv_pthread_create=no],
1287                                 [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1288                                         [ol_cv_pthread_create=yes],
1289                                         [ol_cv_pthread_create=no])])])
1290
1291                 if test $ol_cv_pthread_create != no ; then
1292                         ol_link_threads=posix
1293                         ol_link_pthreads=""
1294                 fi
1295
1296 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1297                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1298                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1299                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1300                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1301                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1302
1303                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1304                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1305                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1306                         [ol_cv_pthread_lpthread_lmach_lexc])
1307 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1308 dnl                     [ol_cv_pthread_lpthread_lexc])
1309
1310                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1311                         [ol_cv_pthread_lib_lpthread_woff])
1312
1313                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1314                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1315
1316                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1317
1318                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1319                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1320                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1321                         [ol_cv_pthread_lpthreads_lmach_lexc])
1322                 OL_PTHREAD_TRY([-lpthreads -lexc],
1323                         [ol_cv_pthread_lpthreads_lexc])
1324
1325                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1326
1327                 if test $ol_link_threads != no ; then
1328                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1329
1330                         dnl save flags
1331                         save_CPPFLAGS="$CPPFLAGS"
1332                         save_LIBS="$LIBS"
1333                         LIBS="$LTHREAD_LIBS $LIBS"
1334
1335                         dnl All POSIX Thread (final) implementations should have
1336                         dnl sched_yield instead of pthread yield.
1337                         dnl check for both, and thr_yield for Solaris
1338                         AC_CHECK_FUNCS(sched_yield pthread_yield thr_yield)
1339
1340                         if test $ac_cv_func_sched_yield = no &&
1341                            test $ac_cv_func_pthread_yield = no &&
1342                            test $ac_cv_func_thr_yield = no ; then
1343                                 dnl Digital UNIX has sched_yield() in -lrt
1344                                 AC_CHECK_LIB(rt, sched_yield,
1345                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1346                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1347                                                 [Define if you have the sched_yield function.])
1348                                         ac_cv_func_sched_yield=yes],
1349                                         [ac_cv_func_sched_yield=no])
1350                         fi
1351                         if test $ac_cv_func_sched_yield = no &&
1352                            test $ac_cv_func_pthread_yield = no &&
1353                            test "$ac_cv_func_thr_yield" = no ; then
1354                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1355                         fi
1356
1357                         dnl Check functions for compatibility
1358                         AC_CHECK_FUNCS(pthread_kill)
1359
1360                         dnl Check for pthread_rwlock_destroy with <pthread.h>
1361                         dnl as pthread_rwlock_t may not be defined.
1362                         AC_CACHE_CHECK([for pthread_rwlock_destroy with <pthread.h>],
1363                                 [ol_cv_func_pthread_rwlock_destroy], [
1364                                 dnl save the flags
1365                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1366 #include <pthread.h>
1367 pthread_rwlock_t rwlock;
1368 ]], [[pthread_rwlock_destroy(&rwlock);]])],[ol_cv_func_pthread_rwlock_destroy=yes],[ol_cv_func_pthread_rwlock_destroy=no])
1369                         ])
1370                         if test $ol_cv_func_pthread_rwlock_destroy = yes ; then
1371                                 AC_DEFINE(HAVE_PTHREAD_RWLOCK_DESTROY,1,
1372                                         [define if you have pthread_rwlock_destroy function])
1373                         fi
1374
1375                         dnl Check for pthread_detach with <pthread.h> inclusion
1376                         dnl as it's symbol may have been mangled.
1377                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1378                                 [ol_cv_func_pthread_detach], [
1379                                 dnl save the flags
1380                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1381 #include <pthread.h>
1382 #ifndef NULL
1383 #define NULL (void*)0
1384 #endif
1385 ]], [[pthread_detach(NULL);]])],[ol_cv_func_pthread_detach=yes],[ol_cv_func_pthread_detach=no])
1386                         ])
1387
1388                         if test $ol_cv_func_pthread_detach = no ; then
1389                                 AC_MSG_ERROR([could not locate pthread_detach()])
1390                         fi
1391
1392                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1393                                 [define if you have pthread_detach function])
1394
1395                         dnl Check for setconcurreny functions
1396                         AC_CHECK_FUNCS( \
1397                                 pthread_setconcurrency \
1398                                 pthread_getconcurrency \
1399                                 thr_setconcurrency \
1400                                 thr_getconcurrency \
1401                         )
1402
1403                         OL_SYS_LINUX_THREADS
1404                         OL_LINUX_THREADS
1405
1406                         if test $ol_cv_linux_threads = error; then
1407                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1408                         fi
1409
1410                         AC_CACHE_CHECK([if pthread_create() works],
1411                                 ol_cv_pthread_create_works,[
1412                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1413                                 [ol_cv_pthread_create_works=yes],
1414                                 [ol_cv_pthread_create_works=no],
1415                                 [dnl assume yes
1416                                 ol_cv_pthread_create_works=yes])])
1417
1418                         if test $ol_cv_pthread_create_works = no ; then
1419                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1420                         fi
1421
1422                         ol_replace_broken_yield=no
1423 dnl                     case "$target" in
1424 dnl                     *-*-linux*)
1425 dnl                             AC_CHECK_FUNCS(nanosleep)
1426 dnl                             ol_replace_broken_yield=yes
1427 dnl                     ;;
1428 dnl                     esac
1429
1430                         if test $ol_replace_broken_yield = yes ; then
1431                                 AC_DEFINE([REPLACE_BROKEN_YIELD],1,
1432                                         [define if sched_yield yields the entire process])
1433                         fi
1434
1435                         dnl Check if select causes an yield
1436                         if test $ol_with_yielding_select = auto ; then
1437                                 AC_CACHE_CHECK([if select yields when using pthreads],
1438                                         ol_cv_pthread_select_yields,[
1439                                 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1440 #include <sys/types.h>
1441 #include <sys/time.h>
1442 #include <unistd.h>
1443 #include <pthread.h>
1444 #ifndef NULL
1445 #define NULL (void*) 0
1446 #endif
1447
1448 static int fildes[2];
1449
1450 static void *task(p)
1451         void *p;
1452 {
1453         int i;
1454         struct timeval tv;
1455
1456         fd_set rfds;
1457
1458         tv.tv_sec=10;
1459         tv.tv_usec=0;
1460
1461         FD_ZERO(&rfds);
1462         FD_SET(fildes[0], &rfds);
1463
1464         /* we're not interested in any fds */
1465         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1466
1467         if(i < 0) {
1468                 perror("select");
1469                 exit(10);
1470         }
1471
1472         exit(0); /* if we exit here, the select blocked the whole process */
1473 }
1474
1475 int main(argc, argv)
1476         int argc;
1477         char **argv;
1478 {
1479         pthread_t t;
1480
1481         /* create a pipe to select */
1482         if(pipe(&fildes[0])) {
1483                 perror("select");
1484                 exit(1);
1485         }
1486
1487 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1488         (void) pthread_setconcurrency(2);
1489 #else
1490 #ifdef HAVE_THR_SETCONCURRENCY
1491         /* Set Solaris LWP concurrency to 2 */
1492         thr_setconcurrency(2);
1493 #endif
1494 #endif
1495
1496 #if HAVE_PTHREADS < 6
1497         pthread_create(&t, pthread_attr_default, task, NULL);
1498 #else
1499         pthread_create(&t, NULL, task, NULL);
1500 #endif
1501
1502         /* make sure task runs first */
1503 #ifdef HAVE_THR_YIELD
1504         thr_yield();
1505 #elif defined( HAVE_SCHED_YIELD )
1506         sched_yield();
1507 #elif defined( HAVE_PTHREAD_YIELD )
1508         pthread_yield();
1509 #endif
1510
1511         exit(2);
1512 }]])],[ol_cv_pthread_select_yields=no],[ol_cv_pthread_select_yields=yes],[ol_cv_pthread_select_yields=cross])])
1513
1514                                 if test $ol_cv_pthread_select_yields = cross ; then
1515                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1516                                 fi
1517
1518                                 if test $ol_cv_pthread_select_yields = yes ; then
1519                                         ol_with_yielding_select=yes
1520                                 fi
1521                         fi
1522
1523                         dnl restore flags
1524                         CPPFLAGS="$save_CPPFLAGS"
1525                         LIBS="$save_LIBS"
1526                 else
1527                         AC_MSG_ERROR([could not locate usable POSIX Threads])
1528                 fi
1529         fi
1530
1531         if test $ol_with_threads = posix ; then
1532                 AC_MSG_ERROR([could not locate POSIX Threads])
1533         fi
1534         ;;
1535 esac
1536
1537 case $ol_with_threads in auto | yes | mach)
1538
1539         dnl check for Mach CThreads
1540         AC_CHECK_HEADERS(mach/cthreads.h cthreads.h)
1541         if test $ac_cv_header_mach_cthreads_h = yes ; then
1542                 ol_with_threads=found
1543
1544                 dnl check for cthreads support in current $LIBS
1545                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1546
1547                 if test $ol_link_threads = no ; then
1548                         dnl try -all_load
1549                         dnl this test needs work
1550                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1551                                 [ol_cv_cthread_all_load], [
1552                                 dnl save the flags
1553                                 save_LIBS="$LIBS"
1554                                 LIBS="-all_load $LIBS"
1555                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <mach/cthreads.h>]], [[
1556                                         cthread_fork((void *)0, (void *)0);
1557                                         ]])],[ol_cv_cthread_all_load=yes],[ol_cv_cthread_all_load=no])
1558                                 dnl restore the LIBS
1559                                 LIBS="$save_LIBS"
1560                         ])
1561
1562                         if test $ol_cv_cthread_all_load = yes ; then
1563                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1564                                 ol_link_threads=mach
1565                                 ol_with_threads=found
1566                         fi
1567                 fi
1568
1569         elif test $ac_cv_header_cthreads_h = yes ; then
1570                 dnl Hurd variant of Mach Cthreads
1571                 dnl uses <cthreads.h> and -lthreads
1572
1573                 ol_with_threads=found
1574
1575                 dnl save the flags
1576                 save_LIBS="$LIBS"
1577                 LIBS="$LIBS -lthreads"
1578                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1579                 LIBS="$save_LIBS"
1580
1581                 if test $ol_link_threads = yes ; then
1582                         LTHREAD_LIBS="-lthreads"
1583                         ol_link_threads=mach
1584                         ol_with_threads=found
1585                 else
1586                         AC_MSG_ERROR([could not link with Mach CThreads])
1587                 fi
1588
1589         elif test $ol_with_threads = mach ; then
1590                 AC_MSG_ERROR([could not locate Mach CThreads])
1591         fi
1592
1593         if test $ol_link_threads = mach ; then
1594                 AC_DEFINE(HAVE_MACH_CTHREADS,1,
1595                         [define if you have Mach Cthreads])
1596         elif test $ol_with_threads = found ; then
1597                 AC_MSG_ERROR([could not link with Mach CThreads])
1598         fi
1599         ;;
1600 esac
1601
1602 case $ol_with_threads in auto | yes | pth)
1603
1604         AC_CHECK_HEADERS(pth.h)
1605
1606         if test $ac_cv_header_pth_h = yes ; then
1607                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1608
1609                 if test $have_pth = yes ; then
1610                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1611                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1612                         ol_link_threads=pth
1613                         ol_with_threads=found
1614
1615                         if test $ol_with_yielding_select = auto ; then
1616                                 ol_with_yielding_select=yes
1617                         fi
1618                 fi
1619         fi
1620         ;;
1621 esac
1622
1623 case $ol_with_threads in auto | yes | lwp)
1624
1625         dnl check for SunOS5 LWP
1626         AC_CHECK_HEADERS(thread.h synch.h)
1627         if test $ac_cv_header_thread_h = yes &&
1628            test $ac_cv_header_synch_h = yes ; then
1629                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1630
1631                 if test $have_thr = yes ; then
1632                         AC_DEFINE(HAVE_THR,1,
1633                                 [if you have Solaris LWP (thr) package])
1634                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1635                         ol_link_threads=thr
1636
1637                         if test $ol_with_yielding_select = auto ; then
1638                                 ol_with_yielding_select=yes
1639                         fi
1640
1641                         dnl Check for setconcurreny functions
1642                         AC_CHECK_FUNCS( \
1643                                 thr_setconcurrency \
1644                                 thr_getconcurrency \
1645                         )
1646                 fi
1647         fi
1648
1649         dnl check for SunOS4 LWP
1650         AC_CHECK_HEADERS(lwp/lwp.h)
1651         if test $ac_cv_header_lwp_lwp_h = yes ; then
1652                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1653
1654                 if test $have_lwp = yes ; then
1655                         AC_DEFINE(HAVE_LWP,1,
1656                                 [if you have SunOS LWP package])
1657                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1658                         ol_link_threads=lwp
1659
1660                         if test $ol_with_yielding_select = auto ; then
1661                                 ol_with_yielding_select=no
1662                         fi
1663                 fi
1664         fi
1665         ;;
1666 esac
1667
1668 if test $ol_with_yielding_select = yes ; then
1669         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1670                 [define if select implicitly yields])
1671 fi
1672
1673 if test $ol_with_threads = manual ; then
1674         dnl User thinks he can manually configure threads.
1675         ol_link_threads=yes
1676
1677         AC_MSG_WARN([thread defines and link options must be set manually])
1678
1679         AC_CHECK_HEADERS(pthread.h sched.h)
1680         AC_CHECK_FUNCS(sched_yield pthread_yield)
1681         OL_HEADER_LINUX_THREADS
1682
1683         AC_CHECK_HEADERS(mach/cthreads.h)
1684         AC_CHECK_HEADERS(lwp/lwp.h)
1685         AC_CHECK_HEADERS(thread.h synch.h)
1686 fi
1687
1688 if test $ol_link_threads != no && test $ol_link_threads != nt ; then
1689         dnl needed to get reentrant/threadsafe versions
1690         dnl
1691         AC_DEFINE(REENTRANT,1)
1692         AC_DEFINE(_REENTRANT,1)
1693         AC_DEFINE(THREAD_SAFE,1)
1694         AC_DEFINE(_THREAD_SAFE,1)
1695         AC_DEFINE(THREADSAFE,1)
1696         AC_DEFINE(_THREADSAFE,1)
1697         AC_DEFINE(_SGI_MP_SOURCE,1)
1698
1699         dnl The errno declaration may dependent upon _REENTRANT.
1700         dnl If it does, we must link with thread support.
1701         AC_CACHE_CHECK([for thread specific errno],
1702                 [ol_cv_errno_thread_specific], [
1703                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[errno = 0;]])],[ol_cv_errno_thread_specific=yes],[ol_cv_errno_thread_specific=no])
1704         ])
1705
1706         dnl The h_errno declaration may dependent upon _REENTRANT.
1707         dnl If it does, we must link with thread support.
1708         AC_CACHE_CHECK([for thread specific h_errno],
1709                 [ol_cv_h_errno_thread_specific], [
1710                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[h_errno = 0;]])],[ol_cv_h_errno_thread_specific=yes],[ol_cv_h_errno_thread_specific=no])
1711         ])
1712
1713         if test $ol_cv_errno_thread_specific != yes ||
1714            test $ol_cv_h_errno_thread_specific != yes ; then
1715                 LIBS="$LTHREAD_LIBS $LIBS"
1716                 LTHREAD_LIBS=""
1717         fi
1718
1719 dnl When in thread environment, use
1720 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) || defined( HAVE_FUNC_R )
1721 dnl                     func_r(...);
1722 dnl             #else
1723 dnl             #       if defined( HAVE_THREADS )
1724 dnl                             /* lock */
1725 dnl             #       endif
1726 dnl                             func(...);
1727 dnl             #       if defined( HAVE_THREADS )
1728 dnl                             /* unlock */
1729 dnl             #       endif
1730 dnl             #endif
1731 dnl
1732 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1733 dnl             _POSIX_REENTRANT_FUNCTIONS
1734 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1735 dnl             _POSIX_THREADSAFE_FUNCTIONS
1736 dnl
1737 dnl             and is currently defined in <ldap_pvt_thread.h>
1738 dnl
1739 dnl HAVE_THREADS is defined by <ldap_pvt_thread.h> iff -UNO_THREADS
1740 dnl
1741 dnl libldap/*.c should only include <ldap_pvt_thread.h> iff
1742 dnl LDAP_R_COMPILE is defined.  ie:
1743 dnl             #ifdef LDAP_R_COMPILE
1744 dnl             #       include <ldap_pvt_thread.h>
1745 dnl             #endif
1746 dnl
1747 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1748 dnl specifically for compiling the threadsafe version of
1749 dnl     the ldap library (-lldap_r).
1750 dnl
1751 dnl     dnl check for reentrant/threadsafe functions
1752 dnl     dnl
1753 dnl     dnl note: these should only be used when linking
1754 dnl     dnl             with $LTHREAD_LIBS
1755 dnl     dnl
1756 dnl     save_CPPFLAGS="$CPPFLAGS"
1757 dnl     save_LIBS="$LIBS"
1758 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1759 dnl     AC_CHECK_FUNCS( \
1760 dnl             gmtime_r \
1761 dnl             gethostbyaddr_r gethostbyname_r \
1762 dnl             feof_unlocked unlocked_feof \
1763 dnl             putc_unlocked unlocked_putc \
1764 dnl             flockfile ftrylockfile \
1765 dnl     )
1766 dnl     CPPFLAGS="$save_CPPFLAGS"
1767 dnl     LIBS="$save_LIBS"
1768 fi
1769
1770 if test $ol_link_threads = no ; then
1771         if test $ol_with_threads = yes ; then
1772                 AC_MSG_ERROR([no suitable thread support])
1773         fi
1774
1775         if test $ol_with_threads = auto ; then
1776                 AC_MSG_WARN([no suitable thread support, disabling threads])
1777                 ol_with_threads=no
1778         fi
1779
1780         AC_DEFINE(NO_THREADS,1,
1781                 [define if you have (or want) no threads])
1782         LTHREAD_LIBS=""
1783         BUILD_THREAD=no
1784 else
1785         BUILD_THREAD=yes
1786 fi
1787
1788 if test $ol_link_threads != no ; then
1789         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1,
1790                 [define to 1 if library is thread safe])
1791 fi
1792
1793 dnl ----------------------------------------------------------------
1794 dnl Tests for reentrant functions necessary to build -lldap_r
1795 AC_CHECK_FUNCS(         \
1796         ctime_r                 \
1797         gethostbyname_r gethostbyaddr_r \
1798 )
1799
1800 if test "$ac_cv_func_ctime_r" = no ; then
1801         ol_cv_func_ctime_r_nargs=0
1802 else
1803         OL_FUNC_CTIME_R_NARGS
1804 dnl     OL_FUNC_CTIME_R_TYPE
1805 fi
1806
1807 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1808         OL_FUNC_GETHOSTBYNAME_R_NARGS
1809 else
1810         ol_cv_func_gethostbyname_r_nargs=0
1811 fi
1812
1813 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1814         OL_FUNC_GETHOSTBYADDR_R_NARGS
1815 else
1816         ol_cv_func_gethostbyaddr_r_nargs=0
1817 fi
1818
1819 dnl ----------------------------------------------------------------
1820 ol_link_bdb=no
1821
1822 if test $ol_enable_bdb/$ol_enable_hdb != no/no; then
1823         OL_BERKELEY_DB
1824
1825         if test $ol_cv_berkeley_db = no ; then
1826                 AC_MSG_ERROR(BDB/HDB: BerkeleyDB not available)
1827         fi
1828
1829         AC_DEFINE(HAVE_BERKELEY_DB,1,
1830                 [define this if Berkeley DB is available])
1831
1832         dnl $ol_cv_lib_db should be yes or -ldb
1833         dnl (it could be no, but that would be an error
1834         if test $ol_cv_lib_db != yes ; then
1835                 BDB_LIBS="$BDB_LIBS $ol_cv_lib_db"
1836         fi
1837
1838         OL_BDB_COMPAT
1839
1840         if test $ol_cv_bdb_compat != yes ; then
1841                 AC_MSG_ERROR([BDB/HDB: BerkeleyDB version incompatible])
1842         fi
1843
1844         SLAPD_LIBS="$SLAPD_LIBS \$(BDB_LIBS)"
1845
1846         ol_link_bdb=yes
1847 fi
1848
1849 dnl ----------------------------------------------------------------
1850
1851 if test $ol_enable_dynamic = yes && test $enable_shared = yes ; then
1852         BUILD_LIBS_DYNAMIC=shared
1853         AC_DEFINE(LDAP_LIBS_DYNAMIC, 1, [define if LDAP libs are dynamic])
1854         LTSTATIC=""
1855 else
1856         BUILD_LIBS_DYNAMIC=static
1857         LTSTATIC="-static"
1858 fi
1859 AC_SUBST(LTSTATIC)dnl
1860
1861 dnl ----------------------------------------------------------------
1862 if test $ol_enable_wrappers != no ; then
1863         AC_CHECK_HEADERS(tcpd.h,[
1864                 AC_MSG_CHECKING([for TCP wrappers library])
1865                 save_LIBS="$LIBS"
1866                 LIBS="$LIBS -lwrap"
1867                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1868 #include <tcpd.h>
1869 int allow_severity = 0;
1870 int deny_severity  = 0;
1871
1872 struct request_info *req;
1873                 ]], [[
1874 hosts_access(req)
1875                 ]])],[AC_MSG_RESULT([-lwrap])
1876                 have_wrappers=yes
1877                 LIBS="$save_LIBS"],[
1878                 dnl try with -lnsl
1879                 LIBS="$LIBS -lnsl"
1880                 AC_TRY_LINK([
1881 #include <tcpd.h>
1882 int allow_severity = 0;
1883 int deny_severity  = 0;
1884
1885 struct request_info *req;
1886                 ],[
1887 hosts_access(req)
1888                 ],[AC_MSG_RESULT([-lwrap -lnsl])
1889                 have_wrappers=yes
1890                 LIBS="$save_LIBS -lnsl"],[
1891                 AC_MSG_RESULT(no)
1892                 have_wrappers=no
1893                 LIBS=$save_LIBS])])],[have_wrappers=no])
1894
1895         if test $have_wrappers = yes ; then
1896                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1897                 WRAP_LIBS="-lwrap"
1898         elif test $ol_enable_wrappers = yes ; then
1899                 AC_MSG_ERROR([could not find TCP wrappers, select apppropriate options or disable])
1900         else
1901                 AC_MSG_WARN([could not find TCP wrappers, support disabled])
1902                 WRAP_LIBS=""
1903         fi
1904 fi
1905
1906 dnl ----------------------------------------------------------------
1907 if test $ol_enable_syslog != no ; then
1908         AC_CHECK_FUNC(openlog)
1909         if test $ac_cv_func_openlog = no && test $ol_enable_syslog = yes; then
1910                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1911         fi
1912         ol_enable_syslog=$ac_cv_func_openlog
1913 fi
1914
1915 dnl ----------------------------------------------------------------
1916 dnl SQL
1917 ol_link_sql=no
1918 if test $ol_enable_sql != no ; then
1919         AC_CHECK_HEADERS(sql.h sqlext.h,[],[
1920                 AC_MSG_ERROR([could not locate SQL headers])
1921         ])
1922
1923         sql_LIBS="$LIBS"
1924         LIBS="$LTHREAD_LIBS"
1925
1926         if test $ol_with_odbc = auto ; then
1927                 ol_with_odbc="iodbc unixodbc"
1928         fi
1929
1930         for odbc in $ol_with_odbc ; do
1931                 if test $ol_link_sql = no ; then
1932                         case $odbc in
1933                         iodbc)
1934                                 AC_CHECK_LIB(iodbc, SQLDriverConnect, [have_iodbc=yes], [have_iodbc=no])
1935                                 if test $have_iodbc = yes ; then
1936                                         ol_link_sql="-liodbc"
1937                                 fi
1938                                 ;;
1939
1940                         unixodbc)
1941                                 AC_CHECK_LIB(odbc, SQLDriverConnect, [have_odbc=yes], [have_odbc=no])
1942                                 if test $have_odbc = yes ; then
1943                                         ol_link_sql="-lodbc"
1944                                 fi
1945                                 ;;
1946
1947                         *)
1948                                 AC_MSG_ERROR([unknown ODBC library])
1949                                 ;;
1950                         esac
1951                 fi
1952         done
1953
1954         LIBS="$sql_LIBS"
1955
1956         if test $ol_link_sql != no ; then
1957                 SLAPD_SQL_LIBS="$ol_link_sql"
1958
1959         elif test $ol_enable_sql != auto ; then
1960                 AC_MSG_ERROR([could not locate suitable ODBC library])
1961         fi
1962 fi
1963
1964 dnl ----------------------------------------------------------------
1965 dnl International Components for Unicode
1966 OL_ICU
1967 if test "$ol_icu" = no ; then
1968         AC_MSG_WARN([ICU not available])
1969 else
1970         ICU_LIBS="$ol_icu"
1971 fi
1972 dnl ----------------------------------------------------------------
1973 dnl
1974 dnl Check for Cyrus SASL
1975 dnl
1976 WITH_SASL=no
1977 ol_link_sasl=no
1978 ol_link_spasswd=no
1979 if test $ol_with_cyrus_sasl != no ; then
1980         AC_CHECK_HEADERS(sasl/sasl.h sasl.h)
1981
1982         if test $ac_cv_header_sasl_sasl_h = yes ||
1983            test $ac_cv_header_sasl_h = yes; then
1984                 AC_CHECK_LIB(sasl2, sasl_client_init,
1985                         [ol_link_sasl="-lsasl2"],
1986                         [AC_CHECK_LIB(sasl, sasl_client_init,
1987                                 [ol_link_sasl="-lsasl"])])
1988         fi
1989
1990         if test $ol_link_sasl = no ; then
1991                 if test $ol_with_cyrus_sasl != auto ; then
1992                         AC_MSG_ERROR([Could not locate Cyrus SASL])
1993                 else
1994                         AC_MSG_WARN([Could not locate Cyrus SASL])
1995                         AC_MSG_WARN([SASL authentication not supported!])
1996                         if test $ol_link_tls = no ; then
1997                                 AC_MSG_WARN([Strong authentication not supported!])
1998                         fi
1999                 fi
2000         else
2001                 OL_SASL_COMPAT
2002                 if test $ol_cv_sasl_compat = no ; then
2003                         ol_link_sasl=no
2004                         AC_MSG_ERROR([Cyrus SASL library located but is incompatible])
2005                 fi
2006
2007                 AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
2008                 SASL_LIBS="$ol_link_sasl"
2009                 if test $ol_enable_spasswd != no ; then
2010                         ol_link_spasswd=yes
2011                 fi
2012
2013                 ac_save_LIBS="$LIBS"
2014                 LIBS="$LIBS $ol_link_sasl"
2015                 AC_CHECK_FUNC(sasl_version, [AC_DEFINE(HAVE_SASL_VERSION,1,
2016                         [define if your SASL library has sasl_version()])])
2017                 LIBS="$ac_save_LIBS"
2018
2019                 WITH_SASL=yes
2020         fi
2021
2022 else
2023         AC_MSG_WARN([SASL authentication not supported!])
2024         if test $ol_link_tls = no ; then
2025                 AC_MSG_WARN([Strong authentication not supported!])
2026         fi
2027 fi
2028
2029 dnl ----------------------------------------------------------------
2030 dnl Check for entropy sources
2031 if test $cross_compiling != yes && test "$ac_cv_mingw32" != yes ; then
2032         dev=no
2033         if test -r /dev/urandom ; then
2034                 dev="/dev/urandom";
2035         elif test -r /idev/urandom ; then
2036                 dev="/idev/urandom";
2037         elif test -r /dev/srandom ; then
2038                 dev="/dev/srandom";
2039         elif test -r /dev/random ; then
2040                 dev="/dev/random";
2041         elif test -r /idev/random ; then
2042                 dev="/idev/random";
2043         fi
2044
2045         if test $dev != no ; then
2046                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
2047         fi
2048 fi
2049
2050 dnl ----------------------------------------------------------------
2051 dnl
2052 dnl Check for fetch URL support
2053 dnl             should be extended to support other fetch URL APIs
2054 dnl
2055 ol_link_fetch=no
2056 if test $ol_with_fetch != no ; then
2057         OL_LIB_FETCH
2058
2059         if test $ol_cv_lib_fetch != no ; then
2060                 LUTIL_LIBS="$LUTIL_LIBS $ol_link_fetch"
2061                 ol_link_fetch=freebsd
2062
2063         elif test $ol_with_fetch != auto ; then
2064                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
2065         fi
2066 fi
2067
2068 dnl ----------------------------------------------------------------
2069 dnl FreeBSD (and others) have crypt(3) in -lcrypt
2070 if test $ol_enable_crypt != no ; then
2071         save_LIBS="$LIBS"
2072         LIBS="$TLS_LIBS $LIBS"
2073
2074         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
2075                 LIBS="$save_LIBS"
2076                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
2077                         have_crypt=yes], [have_crypt=no])])
2078
2079         LIBS="$save_LIBS"
2080
2081         if test $have_crypt = yes ; then
2082                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
2083         else
2084                 AC_MSG_WARN([could not find crypt])
2085                 if test $ol_enable_crypt = yes ; then
2086                         AC_MSG_ERROR([could not find crypt, select appropriate options or disable])
2087                 fi
2088
2089                 AC_MSG_WARN([disabling crypt support])
2090                 ol_enable_crypt=no
2091         fi
2092 fi
2093
2094 dnl ----------------------------------------------------------------
2095 dnl FreeBSD (and others) have setproctitle(3) in -lutil
2096 if test $ol_enable_proctitle != no ; then
2097         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
2098                 AC_CHECK_LIB(util, setproctitle,
2099                         [have_setproctitle=yes
2100                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
2101                         [have_setproctitle=no
2102                         AC_LIBOBJ(setproctitle)
2103                         LIBSRCS="$LIBSRCS setproctitle.c"])])
2104
2105         if test $have_setproctitle = yes ; then
2106                 AC_DEFINE(HAVE_SETPROCTITLE,1,
2107                         [define if setproctitle(3) is available])
2108         fi
2109 fi
2110
2111 dnl ----------------------------------------------------------------
2112 if test $ol_enable_slp != no ; then
2113         AC_CHECK_HEADERS( slp.h )
2114
2115         if test $ac_cv_header_slp_h = yes ; then
2116                 AC_CHECK_LIB(slp, SLPOpen, [have_slp=yes], [have_slp=no])
2117                 if test $have_slp = yes ; then
2118                         AC_DEFINE(HAVE_SLP, 1, [define if you have -lslp])
2119                         SLAPD_SLP_LIBS=-lslp
2120                 fi
2121
2122         elif test $ol_enable_slp = yes ; then
2123                 AC_MSG_ERROR([SLP not found])
2124         fi
2125 fi
2126
2127 dnl ----------------------------------------------------------------
2128 dnl Checks for typedefs, structures, and compiler characteristics.
2129
2130 AC_CHECK_TYPE(mode_t, int)
2131 AC_CHECK_TYPE(off_t, long)
2132 AC_CHECK_TYPE(pid_t, int)
2133 AC_CHECK_TYPE(ssize_t, [signed int])
2134 AC_CHECK_TYPE(caddr_t,  [char *])
2135 AC_CHECK_TYPE(size_t, unsigned)
2136
2137 AC_CHECK_TYPES([long long])
2138 AC_CHECK_TYPES([ptrdiff_t])
2139
2140
2141 AC_CHECK_TYPE([socklen_t],,, [$ac_includes_default
2142 #ifdef HAVE_SYS_SOCKET_H
2143 #include <sys/socket.h>
2144 #endif])
2145
2146 dnl socklen_t-like type in accept(), default socklen_t or int:
2147 dnl - The OS might define socklen_t without using it.  POSIX moved from
2148 dnl   int to size_t to socklen_t, hoping to stay at a 32-bit type, and
2149 dnl   HP-UX now has selectors for what to use.
2150 dnl - On Solaris 2.8 the prototype has void *len, but the default is OK.
2151 AC_MSG_CHECKING([the type of arg 3 to accept()])
2152 AC_CACHE_VAL(ol_cv_type_ber_socklen_t, [
2153         set socklen_t int unsigned "unsigned long" long size_t
2154         test "$ac_cv_type_socklen_t" = yes || shift
2155         ol_cv_type_ber_socklen_t=$1 guessing="guessing "
2156         for lentype in "$@" ; do for addrtype in "struct sockaddr" void ; do
2157                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([$ac_includes_default
2158 #ifdef HAVE_SYS_SOCKET_H
2159 #include <sys/socket.h>
2160 #endif
2161 extern int accept(int s, $addrtype *ap, $lentype *lp);
2162 ], [
2163 accept(0, (struct sockaddr *) 0, ($lentype *) 0);
2164 ])], [ol_cv_type_ber_socklen_t=$lentype guessing= ; break 2])
2165         done ; done])
2166 AC_MSG_RESULT([$guessing$ol_cv_type_ber_socklen_t *])
2167 AC_DEFINE_UNQUOTED(ber_socklen_t, $ol_cv_type_ber_socklen_t,
2168         [Define to the type of arg 3 for `accept'.])
2169
2170 dnl Modules should use ber_socklen_t, not socklen_t.  Define socklen_t
2171 dnl for the time being anyway, for backwards compatibility.
2172 if test "$ac_cv_type_socklen_t" != yes; then
2173         AC_DEFINE_UNQUOTED([socklen_t], [$ol_cv_type_ber_socklen_t],
2174                 [Define like ber_socklen_t if <sys/socket.h> does not define.])
2175 fi
2176
2177
2178 AC_TYPE_SIGNAL
2179
2180 AC_CHECK_TYPE([sig_atomic_t],,
2181         [AC_DEFINE_UNQUOTED([sig_atomic_t], [int],
2182                 [Define to `int' if <signal.h> does not define.])],
2183         [$ac_includes_default
2184 #include <signal.h>
2185         ])
2186
2187 AC_TYPE_UID_T
2188
2189 AC_HEADER_TIME
2190 AC_STRUCT_TM
2191 AC_CHECK_MEMBERS([struct stat.st_blksize])
2192 AC_CHECK_MEMBERS([struct passwd.pw_gecos],,,[$ac_includes_default
2193 #include <pwd.h>])
2194 AC_CHECK_MEMBERS([struct passwd.pw_passwd],,,[$ac_includes_default
2195 #include <pwd.h>])
2196
2197 OL_C_UPPER_LOWER
2198 AC_C_CONST
2199 OL_C_VOLATILE
2200
2201 if test $cross_compiling = yes ; then
2202         AC_MSG_WARN([Crossing compiling... all bets are off!])
2203         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2204 else
2205         AC_C_BIGENDIAN
2206 fi
2207
2208 AC_CHECK_SIZEOF(short)
2209 AC_CHECK_SIZEOF(int)
2210 AC_CHECK_SIZEOF(long)
2211 AC_CHECK_SIZEOF(long long)
2212 AC_CHECK_SIZEOF(wchar_t)
2213
2214 if test "$ac_cv_sizeof_int" -lt 4 ; then
2215         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2216
2217         AC_DEFINE(LBER_INT_T,long,[define to 32-bit or greater integer type])
2218 else
2219         AC_DEFINE(LBER_INT_T,int,[define to 32-bit or greater integer type])
2220 fi
2221
2222 AC_DEFINE(LBER_LEN_T,long,[define to large integer type])
2223 AC_DEFINE(LBER_SOCKET_T,int,[define to socket descriptor type])
2224 AC_DEFINE(LBER_TAG_T,long,[define to large integer type])
2225
2226 dnl ----------------------------------------------------------------
2227 dnl Check for multiple precision support
2228 if test $ol_with_mp = longlong || test $ol_with_mp = auto ; then
2229         if test $ac_cv_sizeof_long_long -gt 4 ; then
2230                 ol_with_mp=longlong
2231                 AC_DEFINE(USE_MP_LONG_LONG,1,[define to use 'long long' for MP])
2232         elif test $ol_with_mp = longlong ; then
2233                 AC_MSG_ERROR([long long unusable for multiple precision])
2234         fi
2235 fi
2236 if test $ol_with_mp = long || test $ol_with_mp = auto ; then
2237         if test $ac_cv_sizeof_long -gt 4 ; then
2238                 ol_with_mp=long
2239                 AC_DEFINE(USE_MP_LONG,1,[define to use 'long' for MP])
2240         elif test $ol_with_mp = long ; then
2241                 AC_MSG_ERROR([long unusable for multiple precision])
2242         fi
2243 fi
2244 if test $ol_with_mp = bignum || test $ol_with_mp = auto ; then
2245         AC_CHECK_HEADERS(openssl/bn.h)
2246         AC_CHECK_HEADERS(openssl/crypto.h)
2247         if test "$ac_cv_header_openssl_bn_h" = "yes" &&
2248                 test "$ac_cv_header_openssl_crypto_h" = "yes" &&
2249                 test "$ol_with_tls" = "found" ; then
2250                 ol_with_mp=bignum
2251                 AC_DEFINE(USE_MP_BIGNUM,1,[define to use OpenSSL BIGNUM for MP])
2252         elif test $ol_with_mp = bignum ; then
2253                 AC_MSG_ERROR([bignum not available])
2254         fi
2255 fi
2256 if test $ol_with_mp = gmp || test $ol_with_mp = auto ; then
2257         AC_CHECK_HEADERS(gmp.h)
2258         AC_CHECK_LIB(gmp, __gmpz_add_ui)
2259         if test $ac_cv_header_gmp_h = yes && test $ac_cv_lib_gmp___gmpz_add_ui = yes ; then
2260                 AC_DEFINE(USE_MP_GMP,1,[define to use GMP for MP])
2261                 ol_with_mp=gmp
2262         elif test $ol_with_mp = gmp ; then
2263                 AC_MSG_ERROR([gmp not available])
2264         fi
2265 fi
2266 if test $ol_with_mp = auto ; then
2267         ol_with_mp=no
2268 fi
2269
2270 dnl ----------------------------------------------------------------
2271 dnl Checks for library functions.
2272 AC_FUNC_MEMCMP
2273
2274 if test $ac_cv_func_memcmp_working = no ; then
2275         AC_DEFINE(NEED_MEMCMP_REPLACEMENT,1,
2276                 [define if memcmp is not 8-bit clean or is otherwise broken])
2277 fi
2278
2279 AC_FUNC_STRFTIME
2280
2281 OL_FUNC_INET_ATON
2282
2283 dnl Check for NT specific routines
2284 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2285
2286 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2287         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2288 ])
2289
2290 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2291         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2292 ])
2293
2294 AC_FUNC_VPRINTF
2295
2296 if test $ac_cv_func_vprintf = yes ; then
2297         dnl check for vsnprintf
2298         AC_CHECK_FUNCS(snprintf vsnprintf)
2299 fi
2300
2301 AC_CHECK_FUNCS(                 \
2302         bcopy                   \
2303         closesocket             \
2304         chroot                  \
2305         endgrent                \
2306         endpwent                \
2307         fcntl                   \
2308         flock                   \
2309         fstat                   \
2310         getdtablesize           \
2311         getgrgid                \
2312         gethostname             \
2313         getpass                 \
2314         getpassphrase           \
2315         getpwuid                \
2316         getpwnam                \
2317         getspnam                \
2318         gettimeofday            \
2319         initgroups              \
2320         inet_ntoa_b             \
2321         ioctl                   \
2322         lockf                   \
2323         memcpy                  \
2324         memmove                 \
2325         memrchr                 \
2326         mkstemp                 \
2327         mktemp                  \
2328         pipe                    \
2329         read                    \
2330         recv                    \
2331         recvfrom                \
2332         setpwfile               \
2333         setgid                  \
2334         setegid                 \
2335         setsid                  \
2336         setuid                  \
2337         seteuid                 \
2338         signal                  \
2339         strdup                  \
2340         strpbrk                 \
2341         strrchr                 \
2342         strsep                  \
2343         strstr                  \
2344         strtol                  \
2345         strtoul                 \
2346         strtoq                  \
2347         strtouq                 \
2348         strtoll                 \
2349         strspn                  \
2350         sysconf                 \
2351         waitpid                 \
2352         wait4                   \
2353         write                   \
2354         send                    \
2355         sendmsg                 \
2356         sendto                  \
2357 )
2358
2359 dnl We actually may need to replace more than this.
2360 AC_REPLACE_FUNCS(getopt getpeereid)
2361
2362 if test "$ac_cv_func_getopt" != yes; then
2363         LIBSRCS="$LIBSRCS getopt.c"
2364 fi
2365
2366 if test "$ac_cv_func_getpeereid" != yes; then
2367         AC_CHECK_FUNCS( getpeerucred )
2368         if test "$ac_cv_func_getpeerucred" != yes ; then
2369                 AC_CHECK_MEMBERS([struct msghdr.msg_accrightslen],,,
2370                         [$ac_includes_default
2371 #ifdef HAVE_SYS_SOCKET_H
2372 #include <sys/socket.h>
2373 #endif])
2374                 if test "$ac_cv_member_struct_msghdr_msg_accrightslen" != yes; then
2375                         AC_CHECK_MEMBERS([struct msghdr.msg_control],,,
2376                                 [$ac_includes_default
2377 #ifdef HAVE_SYS_SOCKET_H
2378 #include <sys/socket.h>
2379 #endif])
2380                 fi
2381                 AC_CHECK_MEMBERS([struct stat.st_fstype, struct stat.st_vfstype])
2382                 if test "$ac_cv_member_struct_stat_st_fstype" = yes; then
2383                         AC_COMPILE_IFELSE([struct stat st; char *ptr=st.st_fstype;],
2384                                 AC_DEFINE([HAVE_STRUCT_STAT_ST_FSTYPE_CHAR],1,[define to 1 if st_fstype is char *]),
2385                                 AC_DEFINE([HAVE_STRUCT_STAT_ST_FSTYPE_INT],1,[define to 1 if st_fstype is int]))
2386                 fi
2387         fi
2388         LIBSRCS="$LIBSRCS getpeereid.c"
2389 fi
2390
2391 if test "$ac_cv_func_snprintf" != yes ||
2392    test "$ac_cv_func_vsnprintf" != yes; then
2393         if test "$ac_cv_func_snprintf" != yes; then
2394                 AC_DEFINE(snprintf, ber_pvt_snprintf, [define to snprintf routine])
2395         fi
2396         if test "$ac_cv_func_vsnprintf" != yes; then
2397                 AC_DEFINE(vsnprintf, ber_pvt_vsnprintf, [define to snprintf routine])
2398         fi
2399 fi
2400
2401 dnl ----------------------------------------------------------------
2402 dnl Sort out defines
2403
2404 if test "$ol_enable_slapi" != no ; then
2405         dnl This check is done also if --enable-modules is used;
2406         dnl it is duplicated here, 'cause it'd be cached anyway
2407         AC_CHECK_HEADERS(ltdl.h)
2408
2409         if test $ac_cv_header_ltdl_h != yes ; then
2410                 AC_MSG_ERROR([could not locate <ltdl.h>])
2411         fi
2412         AC_CHECK_LIB(ltdl, lt_dlinit, [
2413                 SLAPI_LIBS=-lltdl
2414                 LIBSLAPI=libslapi.a
2415                 LIBSLAPITOOLS=../libslapi.a
2416                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
2417         ],[AC_MSG_ERROR([could not locate libtool -lltdl])])
2418
2419         AC_DEFINE(LDAP_SLAPI,1, [define this to add SLAPI code])
2420 fi
2421
2422 if test "$ol_enable_debug" != no ; then
2423         if test "$ol_enable_debug" = traditional; then
2424                 AC_DEFINE(OLD_DEBUG,1,
2425                         [define to use the original debug style])
2426         fi
2427         AC_DEFINE(LDAP_DEBUG,1,
2428                 [define this to add debugging code])
2429 fi
2430 if test "$ol_enable_syslog" = yes ; then
2431         AC_DEFINE(LDAP_SYSLOG,1,
2432                 [define this to add syslog code])
2433 fi
2434 if test "$ol_enable_proctitle" != no ; then
2435         AC_DEFINE(LDAP_PROCTITLE,1,
2436                 [define this for LDAP process title support])
2437 fi
2438 if test "$ol_enable_referrals" != no ; then
2439         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION,
2440                 [define to LDAP VENDOR VERSION])
2441 fi
2442 if test "$ol_enable_local" != no; then
2443         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2444 fi
2445 if test "$ol_link_ipv6" != no; then
2446         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2447 fi
2448 if test "$ol_enable_cleartext" != no ; then
2449         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2450 fi
2451 if test "$ol_enable_crypt" != no ; then
2452         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2453 fi
2454 if test "$ol_link_spasswd" != no ; then
2455         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2456 fi
2457 if test "$ol_enable_rlookups" != no ; then
2458         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2459 fi
2460 if test "$ol_enable_aci" != no ; then
2461         if test $ol_enable_dynacl = no ; then
2462                 ol_enable_dynacl=yes
2463                 AC_MSG_WARN([ACIs need dynacl])
2464         fi
2465         if test "$ol_enable_aci" = mod ; then
2466                 MFLAG=SLAPD_MOD_DYNAMIC
2467                 dnl remove this after moving servers/slapd/aci.c in contrib/slapd-modules/acl
2468                 AC_MSG_ERROR([ACI build as dynamic module not supported (yet)])
2469         else
2470                 MFLAG=SLAPD_MOD_STATIC
2471         fi
2472         WITH_ACI_ENABLED=$ol_enable_aci
2473         AC_DEFINE_UNQUOTED(SLAPD_ACI_ENABLED,$MFLAG,[define to support per-object ACIs])
2474 else
2475         WITH_ACI_ENABLED=no
2476 fi
2477 if test "$ol_enable_dynacl" != no ; then
2478         AC_DEFINE(SLAP_DYNACL,1,[define to support run-time loadable ACL])
2479 fi
2480
2481 if test "$ol_link_modules" != no ; then
2482         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2483         BUILD_SLAPD=yes
2484         SLAPD_MODULES_LDFLAGS="-dlopen self"
2485 fi
2486
2487 AC_DEFINE(SLAPD_MOD_STATIC,1,[statically linked module])
2488 AC_DEFINE(SLAPD_MOD_DYNAMIC,2,[dynamically linked module])
2489
2490 dnl back-monitor goes first (well, after back-config)
2491 if test "$ol_enable_monitor" != no ; then
2492         BUILD_SLAPD=yes
2493         BUILD_MONITOR=$ol_enable_monitor
2494         if test "$ol_enable_monitor" = mod ; then
2495                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-monitor"
2496                 MFLAG=SLAPD_MOD_DYNAMIC
2497         else
2498                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-monitor"
2499                 MFLAG=SLAPD_MOD_STATIC
2500         fi
2501         AC_DEFINE_UNQUOTED(SLAPD_MONITOR,$MFLAG,[define to support cn=Monitor backend])
2502 fi
2503
2504 if test "$ol_enable_bdb" != no ; then
2505         BUILD_SLAPD=yes
2506         BUILD_BDB=$ol_enable_bdb
2507         if test "$ol_enable_bdb" = mod ; then
2508                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-bdb"
2509                 MFLAG=SLAPD_MOD_DYNAMIC
2510         else
2511                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-bdb"
2512                 MFLAG=SLAPD_MOD_STATIC
2513         fi
2514         AC_DEFINE_UNQUOTED(SLAPD_BDB,$MFLAG,[define to support BDB backend])
2515 fi
2516
2517 if test "$ol_enable_dnssrv" != no ; then
2518         BUILD_SLAPD=yes
2519         BUILD_DNSSRV=$ol_enable_dnssrv
2520         if test "$ol_enable_dnssrv" = mod ; then
2521                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-dnssrv"
2522                 MFLAG=SLAPD_MOD_DYNAMIC
2523         else
2524                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-dnssrv"
2525                 MFLAG=SLAPD_MOD_STATIC
2526         fi
2527         AC_DEFINE_UNQUOTED(SLAPD_DNSSRV,$MFLAG,[define to support DNS SRV backend])
2528 fi
2529
2530 if test "$ol_enable_hdb" != no ; then
2531         BUILD_SLAPD=yes
2532         BUILD_HDB=$ol_enable_hdb
2533         if test "$ol_enable_hdb" = mod ; then
2534                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-hdb"
2535                 MFLAG=SLAPD_MOD_DYNAMIC
2536         else
2537                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-hdb"
2538                 MFLAG=SLAPD_MOD_STATIC
2539         fi
2540         AC_DEFINE_UNQUOTED(SLAPD_HDB,$MFLAG,[define to support HDB backend])
2541 fi
2542
2543 if test "$ol_enable_ldap" != no ; then
2544         BUILD_SLAPD=yes
2545         BUILD_LDAP=$ol_enable_ldap
2546         if test "$ol_enable_ldap" = mod ; then
2547                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ldap"
2548                 MFLAG=SLAPD_MOD_DYNAMIC
2549         else
2550                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ldap"
2551                 MFLAG=SLAPD_MOD_STATIC
2552         fi
2553         AC_DEFINE_UNQUOTED(SLAPD_LDAP,$MFLAG,[define to support LDAP backend])
2554 fi
2555
2556 if test "$ol_enable_meta" != no ; then
2557         BUILD_SLAPD=yes
2558         BUILD_META=$ol_enable_meta
2559         BUILD_REWRITE=yes
2560         if test "$ol_enable_meta" = mod ; then
2561                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-meta"
2562                 MFLAG=SLAPD_MOD_DYNAMIC
2563         else
2564                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-meta"
2565                 MFLAG=SLAPD_MOD_STATIC
2566         fi
2567         AC_DEFINE_UNQUOTED(SLAPD_META,$MFLAG,[define to support LDAP Metadirectory backend])
2568 fi
2569
2570 if test "$ol_enable_null" != no ; then
2571         BUILD_SLAPD=yes
2572         BUILD_NULL=$ol_enable_null
2573         if test "$ol_enable_null" = mod ; then
2574                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-null"
2575                 MFLAG=SLAPD_MOD_DYNAMIC
2576         else
2577                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-null"
2578                 MFLAG=SLAPD_MOD_STATIC
2579         fi
2580         AC_DEFINE_UNQUOTED(SLAPD_NULL,$MFLAG,[define to support NULL backend])
2581 fi
2582
2583 if test "$ol_enable_passwd" != no ; then
2584         BUILD_SLAPD=yes
2585         BUILD_PASSWD=$ol_enable_passwd
2586         if test "$ol_enable_passwd" = mod ; then
2587                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-passwd"
2588                 MFLAG=SLAPD_MOD_DYNAMIC
2589         else
2590                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-passwd"
2591                 MFLAG=SLAPD_MOD_STATIC
2592         fi
2593         AC_DEFINE_UNQUOTED(SLAPD_PASSWD,$MFLAG,[define to support PASSWD backend])
2594 fi
2595
2596 if test "$ol_link_perl" != no ; then
2597         BUILD_SLAPD=yes
2598         BUILD_PERL=$ol_enable_perl
2599         if test "$ol_enable_perl" = mod ; then
2600                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-perl"
2601                 MFLAG=SLAPD_MOD_DYNAMIC
2602         else
2603                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-perl"
2604                 MFLAG=SLAPD_MOD_STATIC
2605         fi
2606         AC_DEFINE_UNQUOTED(SLAPD_PERL,$MFLAG,[define to support PERL backend])
2607 fi
2608
2609 if test "$ol_enable_relay" != no ; then
2610         BUILD_SLAPD=yes
2611         BUILD_RELAY=$ol_enable_relay
2612         if test "$ol_enable_relay" = mod ; then
2613                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-relay"
2614                 MFLAG=SLAPD_MOD_DYNAMIC
2615         else
2616                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-relay"
2617                 MFLAG=SLAPD_MOD_STATIC
2618         fi
2619         AC_DEFINE_UNQUOTED(SLAPD_RELAY,$MFLAG,[define to support relay backend])
2620 fi
2621
2622 if test "$ol_enable_shell" != no ; then
2623         if test "$ol_link_threads" != no ; then
2624                 AC_MSG_WARN([Use of --without-threads is recommended with back-shell])
2625         fi
2626         BUILD_SLAPD=yes
2627         BUILD_SHELL=$ol_enable_shell
2628         if test "$ol_enable_shell" = mod ; then
2629                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-shell"
2630                 MFLAG=SLAPD_MOD_DYNAMIC
2631         else
2632                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-shell"
2633                 MFLAG=SLAPD_MOD_STATIC
2634         fi
2635         AC_DEFINE_UNQUOTED(SLAPD_SHELL,$MFLAG,[define to support SHELL backend])
2636 fi
2637
2638 if test "$ol_link_sql" != no ; then
2639         BUILD_SLAPD=yes
2640         BUILD_SQL=$ol_enable_sql
2641         if test "$ol_enable_sql" = mod; then
2642                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-sql"
2643                 MFLAG=SLAPD_MOD_DYNAMIC
2644         else
2645                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-sql"
2646                 MFLAG=SLAPD_MOD_STATIC
2647         fi
2648         AC_DEFINE_UNQUOTED(SLAPD_SQL,$MFLAG,[define to support SQL backend])
2649 fi
2650
2651 if test "$ol_enable_accesslog" != no ; then
2652         BUILD_ACCESSLOG=$ol_enable_accesslog
2653         if test "$ol_enable_accesslog" = mod ; then
2654                 MFLAG=SLAPD_MOD_DYNAMIC
2655                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS accesslog.la"
2656         else
2657                 MFLAG=SLAPD_MOD_STATIC
2658                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS accesslog.o"
2659         fi
2660         AC_DEFINE_UNQUOTED(SLAPD_OVER_ACCESSLOG,$MFLAG,[define for In-Directory Access Logging overlay])
2661 fi
2662
2663 if test "$ol_enable_auditlog" != no ; then
2664         BUILD_AUDITLOG=$ol_enable_auditlog
2665         if test "$ol_enable_auditlog" = mod ; then
2666                 MFLAG=SLAPD_MOD_DYNAMIC
2667                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS auditlog.la"
2668         else
2669                 MFLAG=SLAPD_MOD_STATIC
2670                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS auditlog.o"
2671         fi
2672         AC_DEFINE_UNQUOTED(SLAPD_OVER_AUDITLOG,$MFLAG,[define for Audit Logging overlay])
2673 fi
2674
2675 if test "$ol_enable_constraint" != no ; then
2676         BUILD_CONSTRAINT=$ol_enable_constraint
2677         if test "$ol_enable_constraint" = mod ; then
2678                 MFLAG=SLAPD_MOD_DYNAMIC
2679                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS constraint.la"
2680         else
2681                 MFLAG=SLAPD_MOD_STATIC
2682                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS constraint.o"
2683         fi
2684         AC_DEFINE_UNQUOTED(SLAPD_OVER_CONSTRAINT,$MFLAG,[define for Attribute Constraint overlay])
2685 fi
2686
2687 if test "$ol_enable_dds" != no ; then
2688         BUILD_DDS=$ol_enable_dds
2689         if test "$ol_enable_dds" = mod ; then
2690                 MFLAG=SLAPD_MOD_DYNAMIC
2691                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dds.la"
2692         else
2693                 MFLAG=SLAPD_MOD_STATIC
2694                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dds.o"
2695         fi
2696         AC_DEFINE_UNQUOTED(SLAPD_OVER_DDS,$MFLAG,[define for Dynamic Directory Services overlay])
2697 fi
2698
2699 if test "$ol_enable_dyngroup" != no ; then
2700         BUILD_DYNGROUP=$ol_enable_dyngroup
2701         if test "$ol_enable_dyngroup" = mod ; then
2702                 MFLAG=SLAPD_MOD_DYNAMIC
2703                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dyngroup.la"
2704         else
2705                 MFLAG=SLAPD_MOD_STATIC
2706                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dyngroup.o"
2707         fi
2708         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNGROUP,$MFLAG,[define for Dynamic Group overlay])
2709 fi
2710
2711 if test "$ol_enable_dynlist" != no ; then
2712         BUILD_DYNLIST=$ol_enable_dynlist
2713         if test "$ol_enable_dynlist" = mod ; then
2714                 MFLAG=SLAPD_MOD_DYNAMIC
2715                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dynlist.la"
2716         else
2717                 MFLAG=SLAPD_MOD_STATIC
2718                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dynlist.o"
2719         fi
2720         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNLIST,$MFLAG,[define for Dynamic List overlay])
2721 fi
2722
2723 if test "$ol_enable_memberof" != no ; then
2724         BUILD_MEMBEROF=$ol_enable_memberof
2725         if test "$ol_enable_memberof" = mod ; then
2726                 MFLAG=SLAPD_MOD_DYNAMIC
2727                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS memberof.la"
2728         else
2729                 MFLAG=SLAPD_MOD_STATIC
2730                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS memberof.o"
2731         fi
2732         AC_DEFINE_UNQUOTED(SLAPD_OVER_MEMBEROF,$MFLAG,[define for Reverse Group Membership overlay])
2733 fi
2734
2735 if test "$ol_enable_ppolicy" != no ; then
2736         BUILD_PPOLICY=$ol_enable_ppolicy
2737         if test "$ol_enable_ppolicy" = mod ; then
2738                 MFLAG=SLAPD_MOD_DYNAMIC
2739                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS ppolicy.la"
2740         else
2741                 MFLAG=SLAPD_MOD_STATIC
2742                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS ppolicy.o"
2743         fi
2744         AC_DEFINE_UNQUOTED(SLAPD_OVER_PPOLICY,$MFLAG,[define for Password Policy overlay])
2745 fi
2746
2747 if test "$ol_enable_proxycache" != no ; then
2748         BUILD_PROXYCACHE=$ol_enable_proxycache
2749         if test "$ol_enable_proxycache" = mod ; then
2750                 MFLAG=SLAPD_MOD_DYNAMIC
2751                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS pcache.la"
2752         else
2753                 MFLAG=SLAPD_MOD_STATIC
2754                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS pcache.o"
2755         fi
2756         AC_DEFINE_UNQUOTED(SLAPD_OVER_PROXYCACHE,$MFLAG,[define for Proxy Cache overlay])
2757 fi
2758
2759 if test "$ol_enable_refint" != no ; then
2760         BUILD_REFINT=$ol_enable_refint
2761         if test "$ol_enable_refint" = mod ; then
2762                 MFLAG=SLAPD_MOD_DYNAMIC
2763                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS refint.la"
2764         else
2765                 MFLAG=SLAPD_MOD_STATIC
2766                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS refint.o"
2767         fi
2768         AC_DEFINE_UNQUOTED(SLAPD_OVER_REFINT,$MFLAG,[define for Referential Integrity overlay])
2769 fi
2770
2771 if test "$ol_enable_retcode" != no ; then
2772         BUILD_RETCODE=$ol_enable_retcode
2773         if test "$ol_enable_retcode" = mod ; then
2774                 MFLAG=SLAPD_MOD_DYNAMIC
2775                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS retcode.la"
2776         else
2777                 MFLAG=SLAPD_MOD_STATIC
2778                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS retcode.o"
2779         fi
2780         AC_DEFINE_UNQUOTED(SLAPD_OVER_RETCODE,$MFLAG,[define for Referential Integrity overlay])
2781 fi
2782
2783 if test "$ol_enable_rwm" != no ; then
2784         BUILD_REWRITE=yes
2785         BUILD_RWM=$ol_enable_rwm
2786         if test "$ol_enable_rwm" = mod ; then
2787                 MFLAG=SLAPD_MOD_DYNAMIC
2788                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS rwm.la"
2789         else
2790                 MFLAG=SLAPD_MOD_STATIC
2791                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS rwm_x.o"
2792         fi
2793         AC_DEFINE_UNQUOTED(SLAPD_OVER_RWM,$MFLAG,[define for Rewrite/Remap overlay])
2794 fi
2795
2796 if test "$ol_enable_seqmod" != no ; then
2797         BUILD_SEQMOD=$ol_enable_seqmod
2798         if test "$ol_enable_seqmod" = mod ; then
2799                 MFLAG=SLAPD_MOD_DYNAMIC
2800                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS seqmod.la"
2801         else
2802                 MFLAG=SLAPD_MOD_STATIC
2803                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS seqmod.o"
2804         fi
2805         AC_DEFINE_UNQUOTED(SLAPD_OVER_SEQMOD,$MFLAG,[define for Sequential Modify overlay])
2806 fi
2807
2808 if test "$ol_enable_syncprov" != no ; then
2809         BUILD_SYNCPROV=$ol_enable_syncprov
2810         if test "$ol_enable_syncprov" = mod ; then
2811                 MFLAG=SLAPD_MOD_DYNAMIC
2812                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS syncprov.la"
2813         else
2814                 MFLAG=SLAPD_MOD_STATIC
2815                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS syncprov.o"
2816         fi
2817         AC_DEFINE_UNQUOTED(SLAPD_OVER_SYNCPROV,$MFLAG,[define for Syncrepl Provider overlay])
2818 fi
2819
2820 if test "$ol_enable_translucent" != no ; then
2821         BUILD_TRANSLUCENT=$ol_enable_translucent
2822         if test "$ol_enable_translucent" = mod ; then
2823                 MFLAG=SLAPD_MOD_DYNAMIC
2824                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS translucent.la"
2825         else
2826                 MFLAG=SLAPD_MOD_STATIC
2827                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS translucent.o"
2828         fi
2829         AC_DEFINE_UNQUOTED(SLAPD_OVER_TRANSLUCENT,$MFLAG,[define for Translucent Proxy overlay])
2830 fi
2831
2832 if test "$ol_enable_unique" != no ; then
2833         BUILD_UNIQUE=$ol_enable_unique
2834         if test "$ol_enable_unique" = mod ; then
2835                 MFLAG=SLAPD_MOD_DYNAMIC
2836                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS unique.la"
2837         else
2838                 MFLAG=SLAPD_MOD_STATIC
2839                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS unique.o"
2840         fi
2841         AC_DEFINE_UNQUOTED(SLAPD_OVER_UNIQUE,$MFLAG,[define for Attribute Uniqueness overlay])
2842 fi
2843
2844 if test "$ol_enable_valsort" != no ; then
2845         BUILD_VALSORT=$ol_enable_valsort
2846         if test "$ol_enable_valsort" = mod ; then
2847                 MFLAG=SLAPD_MOD_DYNAMIC
2848                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS valsort.la"
2849         else
2850                 MFLAG=SLAPD_MOD_STATIC
2851                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS valsort.o"
2852         fi
2853         AC_DEFINE_UNQUOTED(SLAPD_OVER_VALSORT,$MFLAG,[define for Value Sorting overlay])
2854 fi
2855
2856 if test "$ol_enable_rewrite" != no ; then
2857         AC_DEFINE(ENABLE_REWRITE,1,[define to enable rewriting in back-ldap and back-meta])
2858         BUILD_REWRITE=yes
2859 fi
2860
2861 if test "$ol_enable_slapi" != no ; then
2862         AC_DEFINE(ENABLE_SLAPI,1,[define to enable slapi library])
2863         BUILD_SLAPI=yes
2864         SLAPD_SLAPI_DEPEND=libslapi.a
2865 fi
2866
2867 dnl ----------------------------------------------------------------
2868
2869 dnl
2870 dnl For Windows build, we don't want to include -dlopen flags.
2871 dnl They hurt more than they help.
2872 dnl
2873
2874 if test "$ac_cv_mingw32" = yes ; then
2875         PLAT=NT
2876         SLAPD_MODULES_LDFLAGS=
2877 else
2878         PLAT=UNIX
2879 fi
2880
2881 AC_SUBST(LIBSRCS)
2882 AC_SUBST(PLAT)
2883 AC_SUBST(WITH_SASL)
2884 AC_SUBST(WITH_TLS)
2885 AC_SUBST(WITH_MODULES_ENABLED)
2886 AC_SUBST(WITH_ACI_ENABLED)
2887 AC_SUBST(BUILD_THREAD)
2888 AC_SUBST(BUILD_LIBS_DYNAMIC)
2889
2890 AC_SUBST(BUILD_SLAPD)
2891 dnl slapi
2892   AC_SUBST(BUILD_SLAPI)
2893   AC_SUBST(SLAPD_SLAPI_DEPEND)
2894 dnl backends
2895   AC_SUBST(BUILD_BDB)
2896   AC_SUBST(BUILD_DNSSRV)
2897   AC_SUBST(BUILD_HDB)
2898   AC_SUBST(BUILD_LDAP)
2899   AC_SUBST(BUILD_META)
2900   AC_SUBST(BUILD_MONITOR)
2901   AC_SUBST(BUILD_NULL)
2902   AC_SUBST(BUILD_PASSWD)
2903   AC_SUBST(BUILD_RELAY)
2904   AC_SUBST(BUILD_PERL)
2905   AC_SUBST(BUILD_SHELL)
2906   AC_SUBST(BUILD_SQL)
2907 dnl overlays
2908   AC_SUBST(BUILD_ACCESSLOG)
2909   AC_SUBST(BUILD_AUDITLOG)
2910   AC_SUBST(BUILD_CONSTRAINT)
2911   AC_SUBST(BUILD_DDS)
2912   AC_SUBST(BUILD_DENYOP)
2913   AC_SUBST(BUILD_DYNGROUP)
2914   AC_SUBST(BUILD_DYNLIST)
2915   AC_SUBST(BUILD_LASTMOD)
2916   AC_SUBST(BUILD_MEMBEROF)
2917   AC_SUBST(BUILD_PPOLICY)
2918   AC_SUBST(BUILD_PROXYCACHE)
2919   AC_SUBST(BUILD_REFINT)
2920   AC_SUBST(BUILD_RETCODE)
2921   AC_SUBST(BUILD_RWM)
2922   AC_SUBST(BUILD_SEQMOD)
2923   AC_SUBST(BUILD_SYNCPROV)
2924   AC_SUBST(BUILD_TRANSLUCENT)
2925   AC_SUBST(BUILD_UNIQUE)
2926   AC_SUBST(BUILD_VALSORT)
2927
2928 AC_SUBST(LDAP_LIBS)
2929 AC_SUBST(SLAPD_LIBS)
2930 AC_SUBST(BDB_LIBS)
2931 AC_SUBST(LTHREAD_LIBS)
2932 AC_SUBST(LUTIL_LIBS)
2933 AC_SUBST(WRAP_LIBS)
2934
2935 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2936 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2937
2938 AC_SUBST(SLAPD_NO_STATIC)
2939 AC_SUBST(SLAPD_STATIC_BACKENDS)
2940 AC_SUBST(SLAPD_DYNAMIC_BACKENDS)
2941 AC_SUBST(SLAPD_STATIC_OVERLAYS)
2942 AC_SUBST(SLAPD_DYNAMIC_OVERLAYS)
2943
2944 AC_SUBST(PERL_CPPFLAGS)
2945 AC_SUBST(SLAPD_PERL_LDFLAGS)
2946 AC_SUBST(MOD_PERL_LDFLAGS)
2947
2948 AC_SUBST(KRB4_LIBS)
2949 AC_SUBST(KRB5_LIBS)
2950 AC_SUBST(SASL_LIBS)
2951 AC_SUBST(TLS_LIBS)
2952 AC_SUBST(MODULES_LIBS)
2953 AC_SUBST(SLAPI_LIBS)
2954 AC_SUBST(LIBSLAPI)
2955 AC_SUBST(LIBSLAPITOOLS)
2956 AC_SUBST(AUTH_LIBS)
2957 AC_SUBST(ICU_LIBS)
2958
2959 AC_SUBST(SLAPD_SLP_LIBS)
2960 AC_SUBST(SLAPD_GMP_LIBS)
2961
2962 AC_SUBST(SLAPD_SQL_LDFLAGS)
2963 AC_SUBST(SLAPD_SQL_LIBS)
2964 AC_SUBST(SLAPD_SQL_INCLUDES)
2965
2966 dnl ----------------------------------------------------------------
2967 dnl final help output
2968 AC_ARG_WITH(xxinstall,[
2969 See INSTALL file for further details.])
2970
2971 dnl ----------------------------------------------------------------
2972 dnl final output
2973 dnl
2974
2975 AC_CONFIG_FILES([Makefile:build/top.mk:Makefile.in:build/dir.mk]
2976 [doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk]
2977 [doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk]
2978 [doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk]
2979 [doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk]
2980 [doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk]
2981 [doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk]
2982 [clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk]
2983 [clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk]
2984 [include/Makefile:build/top.mk:include/Makefile.in]
2985 [libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk]
2986 [libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk]
2987 [libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk]
2988 [libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk]
2989 [libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk]
2990 [libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk]
2991 [libraries/librewrite/Makefile:build/top.mk:libraries/librewrite/Makefile.in:build/lib.mk:build/lib-static.mk]
2992 [servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk]
2993 [servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk]
2994 [servers/slapd/back-bdb/Makefile:build/top.mk:servers/slapd/back-bdb/Makefile.in:build/mod.mk]
2995 [servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk]
2996 [servers/slapd/back-hdb/Makefile:build/top.mk:servers/slapd/back-hdb/Makefile.in:build/mod.mk]
2997 [servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk]
2998 [servers/slapd/back-ldif/Makefile:build/top.mk:servers/slapd/back-ldif/Makefile.in:build/mod.mk]
2999 [servers/slapd/back-meta/Makefile:build/top.mk:servers/slapd/back-meta/Makefile.in:build/mod.mk]
3000 [servers/slapd/back-monitor/Makefile:build/top.mk:servers/slapd/back-monitor/Makefile.in:build/mod.mk]
3001 [servers/slapd/back-null/Makefile:build/top.mk:servers/slapd/back-null/Makefile.in:build/mod.mk]
3002 [servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk]
3003 [servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk]
3004 [servers/slapd/back-relay/Makefile:build/top.mk:servers/slapd/back-relay/Makefile.in:build/mod.mk]
3005 [servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk]
3006 [servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk]
3007 [servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk]
3008 [servers/slapd/slapi/Makefile:build/top.mk:servers/slapd/slapi/Makefile.in:build/lib.mk:build/lib-shared.mk]
3009 [servers/slapd/overlays/Makefile:build/top.mk:servers/slapd/overlays/Makefile.in:build/lib.mk]
3010 [tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk]
3011 [tests/run]
3012 [tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk])
3013
3014 AC_CONFIG_COMMANDS([default],[[
3015 chmod +x tests/run
3016 date > stamp-h
3017 BACKENDSC="servers/slapd/backends.c"
3018 echo "Making $BACKENDSC"
3019 rm -f $BACKENDSC
3020 cat > $BACKENDSC << ENDX
3021 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
3022  *
3023  * Copyright 1998-2007 The OpenLDAP Foundation.
3024  * All rights reserved.
3025  *
3026  * Redistribution and use in source and binary forms, with or without
3027  * modification, are permitted only as authorized by the OpenLDAP
3028  * Public License.
3029  *
3030  * A copy of this license is available in the file LICENSE in the
3031  * top-level directory of the distribution or, alternatively, at
3032  * <http://www.OpenLDAP.org/license.html>.
3033  */
3034 /* This file is automatically generated by configure; please do not edit. */
3035
3036 #include "portable.h"
3037 #include "slap.h"
3038
3039 ENDX
3040 if test "${STATIC_BACKENDS}"; then
3041         for b in config ${STATIC_BACKENDS}; do
3042                 bb=`echo "${b}" | sed -e 's/back-//'`
3043                 cat >> $BACKENDSC << ENDX
3044 extern BI_init ${bb}_back_initialize;
3045 ENDX
3046         done
3047
3048         cat >> $BACKENDSC << ENDX
3049
3050 BackendInfo slap_binfo[] = {
3051 ENDX
3052
3053         for b in config ${STATIC_BACKENDS}; do
3054                 bb=`echo "${b}" | sed -e 's/back-//'`
3055                 echo "    Add ${bb} ..."
3056                 cat >> $BACKENDSC << ENDX
3057         { "${bb}", ${bb}_back_initialize },
3058 ENDX
3059         done
3060
3061         cat >> $BACKENDSC << ENDX
3062         { NULL, NULL },
3063 };
3064
3065 /* end of generated file */
3066 ENDX
3067 fi
3068 OVERLAYSC="servers/slapd/overlays/statover.c"
3069 echo "Making $OVERLAYSC"
3070 rm -f $OVERLAYSC
3071 cat > $OVERLAYSC << ENDX
3072 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
3073  *
3074  * Copyright 1998-2007 The OpenLDAP Foundation.
3075  * All rights reserved.
3076  *
3077  * Redistribution and use in source and binary forms, with or without
3078  * modification, are permitted only as authorized by the OpenLDAP
3079  * Public License.
3080  *
3081  * A copy of this license is available in the file LICENSE in the
3082  * top-level directory of the distribution or, alternatively, at
3083  * <http://www.OpenLDAP.org/license.html>.
3084  */
3085 /* This file is automatically generated by configure; please do not edit. */
3086
3087 #include "portable.h"
3088 #include "slap.h"
3089
3090 ENDX
3091 if test "${STATIC_OVERLAYS}"; then
3092         for o in ${STATIC_OVERLAYS}; do
3093                 oo=`echo "${o}" | sed -e 's/.o$//' -e 's/_x$//'`
3094                 cat >> $OVERLAYSC << ENDX
3095 extern OV_init ${oo}_initialize;
3096 ENDX
3097         done
3098 fi
3099
3100 cat >> $OVERLAYSC << ENDX
3101
3102 OverlayInit slap_oinfo[] = {
3103 ENDX
3104
3105 if test "${STATIC_OVERLAYS}"; then
3106         for o in ${STATIC_OVERLAYS}; do
3107                 oo=`echo "${o}" | sed -e 's/.o$//' -e 's/_x$//'`
3108                 echo "    Add ${oo} ..."
3109                 cat >> $OVERLAYSC << ENDX
3110         { "${oo}", ${oo}_initialize },
3111 ENDX
3112         done
3113 fi
3114
3115         cat >> $OVERLAYSC << ENDX
3116         { NULL, NULL },
3117 };
3118
3119 /* end of generated file */
3120 ENDX
3121
3122 if test "${ol_cv_mkdep}" = no; then
3123         echo '(Do not "make depend"; we do not know how to build dependencies)'
3124 else
3125         echo 'Please run "make depend" to build dependencies'
3126 fi
3127 ]],[[
3128 STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS"
3129 STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS"
3130 ]])
3131 AC_OUTPUT