git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Configure.in for OpenLDAP
  11 AC_INIT(include/ldap.h)dnl
  12 AC_CONFIG_AUX_DIR(build)dnl
  13 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no ac_define])dnl
  14
  15 dnl We use autoconf features new to 2.13.
  16 dnl     aclocal.m4 should be built using aclocal from automake 1.4
  17 AC_PREREQ(2.13)dnl Required Autoconf version
  18
  19 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  20
  21 dnl
  22 dnl Start Args
  23 AC_MSG_CHECKING(configure arguments)
  24 AC_PREFIX_DEFAULT(/usr/local)
  25
  26 top_builddir=`pwd`
  27 AC_SUBST(top_builddir)dnl
  28
  29 ldap_subdir="openldap"
  30
  31 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  32         if test "$withval" = "no"; then
  33                 ldap_subdir=""
  34         elif test "$withval" != "yes"; then
  35                 ldap_subdir="$withval"
  36         fi
  37 ])dnl
  38
  39 AC_SUBST(ldap_subdir)dnl
  40
  41 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  42 ol_enable_syslog=no
  43 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  44 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  45 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  46 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  47 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  48 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  49 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  50         no, [yes no])dnl
  51
  52 dnl General "with" options
  53 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  54
  55 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  56         auto, [auto k5 k4 afs yes no])
  57 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  58         auto, [auto yes no] )
  59 OL_ARG_WITH(threads,[  --with-threads   use threads],
  60         auto, [auto posix mach lwp yes no manual] )
  61 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  62         auto, [auto ssleay openssl yes no] )
  63 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  64         auto, [auto yes no manual] )
  65
  66 dnl Server options
  67
  68 dnl LDAPD OPTIONS
  69 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  70 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  71
  72 dnl SLAPD OPTIONS
  73 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  74 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  75 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  76 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  77 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  78 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  79 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  80 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  81
  82 dnl SLAPD Backend options
  83 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
  84 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  85 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  86         [auto db2 db gdbm ndbm manual])
  87 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  88         [auto btree hash])
  89
  90 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  91 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
  92 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  93 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
  94
  95 dnl SLURPD OPTIONS
  96 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  97 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  98
  99 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 100 AM_ENABLE_STATIC
 101 dnl AM_DISABLE_SHARED
 102 AM_ENABLE_SHARED
 103
 104 dnl General "enable" options
 105 # validate options
 106 if test $ol_enable_dns = yes ; then
 107         if test $ol_enable_referrals = no ; then
 108                 AC_MSG_ERROR([DNS requires --enable-referrals])
 109         fi
 110         if test $ol_enable_referrals = auto ; then
 111                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 112                 ol_enable_referrals=yes
 113         fi
 114 fi
 115
 116 if test $ol_enable_slapd = no ; then
 117         dnl SLAPD was specificallly disabled
 118         if test $ol_enable_bdb2 = yes ; then
 119                 AC_MSG_WARN([slapd disabled, ignoring --enable_bdb2 argument])
 120         fi
 121         if test $ol_enable_ldbm = yes ; then
 122                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 123         fi
 124         if test $ol_enable_passwd = yes ; then
 125                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 126         fi
 127         if test $ol_enable_perl = yes ; then
 128                 AC_MSG_WARN([slapd disabled, ignoring --enable_perl argument])
 129         fi
 130         if test $ol_enable_shell = yes ; then
 131                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 132         fi
 133         if test $ol_enable_tcl = yes ; then
 134                 AC_MSG_WARN([slapd disabled, ignoring --enable_tcl argument])
 135         fi
 136         if test $ol_enable_aclgroups = yes ; then
 137                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 138         fi
 139         if test $ol_enable_wrappers = yes ; then
 140                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 141         fi
 142         if test $ol_enable_phonetic = yes ; then
 143                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 144         fi
 145         if test $ol_enable_rlookups = yes ; then
 146                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 147         fi
 148         if test $ol_with_ldbm_api != auto ; then
 149                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 150         fi
 151         if test $ol_with_ldbm_type != auto ; then
 152                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 153         fi
 154         if test $ol_enable_slurpd = yes ; then
 155                 AC_MSG_ERROR([slurpd requires slapd])
 156         fi
 157
 158         # force settings to no
 159         ol_enable_bdb2=no
 160         ol_enable_ldbm=no
 161         ol_enable_passwd=no
 162         ol_enable_perl=no
 163         ol_enable_shell=no
 164         ol_enable_tcl=no
 165         ol_enable_aclgroups=no
 166         ol_enable_wrappers=no
 167         ol_enable_phonetic=no
 168         ol_enable_rlookups=no
 169         ol_with_ldbm_api=no
 170         ol_with_ldbm_type=no
 171         ol_enable_slurpd=no
 172
 173 elif test $ol_enable_ldbm = no ; then
 174         dnl SLAPD without LDBM
 175
 176         if test $ol_with_ldbm_api != auto ; then
 177                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 178         fi
 179
 180         if test $ol_with_ldbm_type != auto ; then
 181                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 182         fi
 183
 184         if test $ol_enable_bdb2 = yes ; then
 185                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 186         fi
 187
 188         if test $ol_enable_passwd = no -a \
 189                 $ol_enable_perl = no -a \
 190                 $ol_enable_shell = no -a \
 191                 $ol_enable_tcl = no ; then
 192                 AC_MSG_ERROR([slapd requires a backend])
 193         fi
 194
 195         ol_with_ldbm_api=no
 196         ol_with_ldbm_type=no
 197
 198 elif test $ol_enable_bdb2 = yes ; then
 199         dnl SLAPD with BDB2
 200
 201         if test $ol_with_ldbm_api != auto -a \
 202                 $ol_with_ldbm_api != db2 ; then
 203                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 204         fi
 205
 206         ol_with_ldbm_api=db2
 207
 208 else
 209         dnl SLAPD with LDBM
 210
 211         if test $ol_enable_bdb2 != no ; then
 212                 if test $ol_with_ldbm_api != auto -a \
 213                         $ol_with_ldbm_api != db2 ; then
 214                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 215                         ol_enable_bdb2=no
 216                 fi
 217         fi
 218
 219         if test $ol_with_ldbm_api = gdbm -a \
 220                 $ol_with_ldbm_type = btree ; then
 221                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 222         fi
 223         if test $ol_with_ldbm_api = ndbm -a \
 224                 $ol_with_ldbm_type = btree ; then
 225                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 226         fi
 227 fi
 228
 229 if test $ol_enable_slurpd = yes ; then
 230         dnl SLURPD was specifically enabled
 231         if test $ol_with_threads = no ; then
 232                 AC_MSG_ERROR([slurpd requires threads])
 233         fi
 234 fi
 235
 236 AC_MSG_RESULT(done)
 237
 238 AC_CANONICAL_HOST
 239
 240 ## Initialize vars
 241 LDAP_LIBS=
 242 LDBM_LIBS=
 243 LTHREAD_LIBS=
 244 LUTIL_LIBS=
 245
 246 LDAPD_LIBS=
 247 SLAPD_LIBS=
 248 SLURPD_LIBS=
 249
 250 BUILD_LDAPD=no
 251 BUILD_SLAPD=no
 252 BUILD_SLURPD=no
 253
 254 BUILD_BDB2=no
 255 BUILD_LDBM=no
 256 BUILD_PASSWD=no
 257 BUILD_PERL=no
 258 BUILD_SHELL=no
 259 BUILD_TCL=no
 260 BUILD_THREAD=no
 261
 262 SLAPD_PERL_LDFLAGS=
 263 SLAPD_PERL_CPPFLAGS=
 264
 265 KRB_LIBS=
 266 READLINE_LIBS=
 267 TERMCAP_LIBS=
 268 TLS_LIBS=
 269
 270 dnl ----------------------------------------------------------------
 271 dnl Checks for programs
 272
 273 AC_PROG_INSTALL
 274
 275 dnl The default compiler is cc (NOT gcc)
 276 CC=${CC-"cc"}
 277 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 278 CFLAGS=${CFLAGS-""}
 279
 280 AM_PROG_LIBTOOL
 281 dnl AC_PROG_MAKE_SET
 282
 283 AC_PROG_AWK
 284 AC_PROG_LN_S
 285
 286 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 287         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 288 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 289 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 290
 291 if test $ol_enable_perl = yes ; then
 292         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 293
 294         if test "no$PERLBIN" = "no" ; then
 295                 ol_enable_perl=no
 296         fi
 297
 298         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 299         SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e perl_inc`"
 300 fi
 301
 302 AC_PROG_CPP
 303
 304 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 305         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 306
 307 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 308         AC_MSG_WARN([programs compiled here do run here...])
 309         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 310
 311 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 312         AC_MSG_WARN([programs compiled here do not run here...])
 313         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 314 fi
 315
 316 dnl Checks for UNIX Variants
 317 AC_AIX
 318 AC_ISC_POSIX
 319 AC_MINIX
 320
 321 dnl Checks for system services
 322 AC_CYGWIN
 323 AC_MINGW32
 324 AC_EXEEXT
 325 AC_OBJEXT
 326
 327 dnl OpenLDAP requires STDC features
 328 AM_PROG_CC_STDC
 329 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 330         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 331 fi
 332
 333 dnl AM_C_PROTOTYPES
 334
 335 dnl Checks for libraries
 336
 337 dnl Find socket()
 338 dnl Likely combinations:
 339 dnl             -lsocket [ -lnsl_s | -lnsl ]
 340 dnl             -linet
 341
 342 AC_CHECK_FUNC(socket, [have_socket=yes], [
 343 dnl
 344 dnl hopefully we won't include too many libraries
 345 dnl
 346         AC_CHECK_LIB(socket, main)
 347         AC_CHECK_LIB(net, main)
 348         AC_CHECK_LIB(nsl_s, main)
 349         AC_CHECK_LIB(nsl, main)
 350         AC_CHECK_LIB(inet, socket)
 351         AC_CHECK_LIB(gen, main)
 352 ])
 353
 354 dnl Check for resolver routines
 355 AC_CHECK_FUNCS(res_search)
 356 if test $ac_cv_func_res_search = "no" ; then
 357         AC_CHECK_LIB(bind, res_search)
 358         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 359                 AC_DEFINE(HAVE_RES_SEARCH,1)
 360         else
 361                 AC_CHECK_LIB(resolv, res_search)
 362                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 363                         AC_DEFINE(HAVE_RES_SEARCH,1)
 364                 fi
 365         fi
 366 fi
 367
 368 dnl HP-UX requires -lV3
 369 AC_CHECK_LIB(V3, sigset)
 370
 371 # ISODE tests
 372 ol_link_isode=no
 373 if test $ol_enable_ldapd != no ; then
 374         dnl look for ISODE libraries
 375         AC_CHECK_LIB(xtpp, main, [
 376                 ol_link_isode=yes
 377                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 378                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 379                 ],:,[-lxtdsap -lxtisode -losi])
 380         AC_CHECK_LIB(dsap, main, [
 381                 ol_link_isode=yes
 382                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 383                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 384                 ],:,[-lisode])
 385         AC_CHECK_LIB(isode, main, [
 386                 ol_link_isode=yes
 387                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 388                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 389                 ],:)
 390 fi
 391
 392 if test $ol_link_isode != no; then
 393         AC_CHECK_LIB(pp, main, [
 394                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 395                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 396                 ],:)
 397
 398         AC_PATH_PROG(PEPSY, pepsy)
 399 fi
 400
 401 dnl
 402 dnl check for kerberos
 403 dnl
 404 ol_link_kerberos=no
 405
 406 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 407         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 408
 409         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 410                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 411                         [-lkrb5 -ldes425])
 412
 413                 if test $have_k5 = yes ; then
 414                         ol_with_kerberos=found
 415                         ol_link_kerberos=yes
 416
 417                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 418
 419                         LIBS="$KRB_LIBS $LIBS"
 420
 421                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 422                                 [ol_cv_var_des_debug], [
 423                                 dnl save the flags
 424                                 save_LIBS="$LIBS"
 425                                 LIBS="$KRB_LIBS $LIBS"
 426                                 AC_TRY_LINK([
 427 #include <kerberosIV/krb.h>
 428 #include <kerberosIV/des.h>
 429 extern int des_debug;
 430 ],[
 431 des_debug = 1;
 432 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 433                                 dnl restore the LIBS
 434                                 LIBS="$save_LIBS"
 435                         ])
 436
 437                         if test $ol_cv_var_des_debug= yes ; then
 438                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 439                                         [define if you have Kerberos des_debug])
 440                         fi
 441
 442                         LIBS="$save_LIBS"
 443                 fi
 444         fi
 445 fi
 446
 447 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 448         AC_CHECK_HEADERS(krb.h des.h)
 449
 450         if test $ac_cv_header_krb_h = yes ; then
 451                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 452
 453                 if test $have_k4 = yes ; then
 454                         ol_with_kerberos=found
 455                         ol_link_kerberos=yes
 456
 457                         KRB_LIBS="-lkrb -ldes"
 458                 fi
 459         fi
 460 fi
 461
 462 if test $ol_link_kerberos = yes ; then
 463         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 464 fi
 465
 466 dnl
 467 dnl Check for SSL/TLS
 468 dnl
 469 ol_link_tls=no
 470 if test $ol_with_tls != no ; then
 471
 472         AC_CHECK_HEADERS(ssl.h)
 473
 474         if test $ac_cv_header_ssl_h = yes ; then
 475                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 476                         [have_ssleay=yes
 477                         need_rsaref=no],
 478                         [have_ssleay=no],
 479                         [-lcrypto])
 480
 481                 if test $have_ssleay = no ; then
 482                         AC_CHECK_LIB(ssl, ssl3_accept,
 483                                 [have_ssleay=yes
 484                                 need_rsaref=yes], [have_ssleay=no],
 485                                 [-lcrypto -lRSAglue -lrsaref])
 486                 fi
 487
 488                 if test $have_ssleay = yes ; then
 489                         ol_with_tls=found
 490                         ol_link_tls=yes
 491
 492                         AC_DEFINE(HAVE_SSLEAY, 1,
 493                                 [define if you have SSLeay or OpenSSL])
 494
 495                         if test $need_rsaref = yes; then
 496                                 AC_DEFINE(HAVE_RSAREF, 1,
 497                                         [define if you have RSAref])
 498
 499                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 500                         else
 501                                 TLS_LIBS="-lssl -lcrypto"
 502                         fi
 503                 fi
 504         fi
 505 fi
 506
 507 if test $ol_link_tls = yes ; then
 508         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 509 fi
 510
 511 dnl Tests for reentrant functions necessary to build a
 512 dnl thread_safe -lldap.
 513 AC_CHECK_FUNCS(         \
 514         ctime_r                 \
 515         gethostbyname_r gethostbyaddr_r \
 516 )
 517
 518 if test "$ac_cv_func_ctime_r" = no ; then
 519         ol_cv_func_ctime_r_nargs=0
 520 else
 521         OL_FUNC_CTIME_R_NARGS
 522 dnl     OL_FUNC_CTIME_R_TYPE
 523 fi
 524
 525 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 526         OL_FUNC_GETHOSTBYNAME_R_NARGS
 527 else
 528         ol_cv_func_gethostbyname_r_nargs=0
 529 fi
 530
 531 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 532         OL_FUNC_GETHOSTBYADDR_R_NARGS
 533 else
 534         ol_cv_func_gethostbyaddr_r_nargs=0
 535 fi
 536
 537 if test "$ac_cv_func_ctime_r" = yes \
 538         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 539         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 540         -a "$ac_cv_func_gethostbyname_r" = yes \
 541         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 542         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 543         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 544         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 545         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 546         ; then
 547
 548         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 549 fi
 550
 551 ol_link_threads=no
 552 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 553         -o $ol_with_threads = posix ; then
 554
 555         AC_CHECK_HEADERS(pthread.h sched.h)
 556
 557         if test $ac_cv_header_pthread_h = yes ; then
 558                 OL_POSIX_THREAD_VERSION
 559
 560                 if test $ol_cv_pthread_version = final ; then
 561                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 562                                 [define if pthreads API compatible with final spec])
 563                 elif test $ol_cv_pthread_version = draft4 ; then
 564                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 565                                 [define if pthreads API compatible with draft4 spec])
 566                 else
 567                         AC_MSG_ERROR([unknown pthread version])
 568                 fi
 569
 570                 # consider threads found
 571                 ol_with_threads=found
 572
 573                 OL_LINUX_THREADS
 574
 575                 if test $ol_cv_linux_threads = yes ; then
 576                         AC_DEFINE(HAVE_LINUX_THREADS,1,
 577                                 [define if you have LinuxThreads])
 578                 fi
 579
 580                 dnl Now the hard part, how to link?
 581                 dnl
 582                 dnl currently supported checks:
 583                 dnl
 584                 dnl Check for no flags
 585                 dnl     pthread_create() in $LIBS
 586                 dnl
 587                 dnl Check special pthread (final) flags
 588                 dnl     pthread_create() with -kthread (FreeBSD)
 589                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 590                 dnl     pthread_create() with -pthreads (?)
 591                 dnl     pthread_create() with -thread (?)
 592                 dnl     pthread_create() with -mt (Solaris)
 593                 dnl
 594                 dnl Check pthread (final) libraries
 595                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 596                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 597                 dnl     pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 598                 dnl     pthread_create() in -lpthread (many)
 599                 dnl     pthread_create() in -lc_r (FreeBSD)
 600                 dnl     pthread_create() in -lpthreads (many)
 601                 dnl     pthread_join() -Wl,-woff,85 -lpthreads (IRIX)
 602                 dnl
 603                 dnl Check pthread (draft4) flags (depreciated)
 604                 dnl     pthread_create() with -threads (OSF/1)
 605                 dnl
 606                 dnl Check pthread (final) libraries (depreciated)
 607                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 608                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 609                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 610                 dnl
 611
 612                 dnl pthread_create in $LIBS
 613                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 614
 615                 if test $ol_link_threads = no ; then
 616                         dnl try -kthread
 617                         AC_CACHE_CHECK([for pthread_create with -kthread],
 618                                 [ol_cv_kthread_flag], [
 619                                 dnl save the flags
 620                                 save_LIBS="$LIBS"
 621                                 LIBS="-kthread $LIBS"
 622                                 AC_TRY_LINK([#include <pthread.h>],[
 623 #if HAVE_PTHREADS_D4
 624         pthread_create(NULL,pthread_attr_default,NULL,NULL);
 625 #else
 626         pthread_create(NULL,NULL,NULL,NULL);
 627 #endif
 628 ],
 629                                         [ol_cv_kthread_flag=yes], [ol_cv_kthread_flag=no])
 630                                 dnl restore the LIBS
 631                                 LIBS="$save_LIBS"
 632                         ])
 633
 634                         if test $ol_cv_kthread_flag = yes ; then
 635                                 LTHREAD_LIBS="$LTHREAD_LIBS -kthread"
 636                                 ol_link_threads=posix
 637                         fi
 638                 fi
 639
 640                 if test $ol_link_threads = no ; then
 641                         dnl try -pthread
 642                         AC_CACHE_CHECK([for pthread_create with -pthread],
 643                                 [ol_cv_pthread_flag], [
 644                                 dnl save the flags
 645                                 save_LIBS="$LIBS"
 646                                 LIBS="-pthread $LIBS"
 647                                 AC_TRY_LINK([#include <pthread.h>],[
 648 #if HAVE_PTHREADS_D4
 649         pthread_create(NULL,pthread_attr_default,NULL,NULL);
 650 #else
 651         pthread_create(NULL,NULL,NULL,NULL);
 652 #endif
 653 ],
 654                                         [ol_cv_pthread_flag=yes], [ol_cv_pthread_flag=no])
 655                                 dnl restore the LIBS
 656                                 LIBS="$save_LIBS"
 657                         ])
 658
 659                         if test $ol_cv_pthread_flag = yes ; then
 660                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 661                                 ol_link_threads=posix
 662                         fi
 663                 fi
 664
 665                 if test $ol_link_threads = no ; then
 666                         dnl try -pthreads
 667                         AC_CACHE_CHECK([for pthread_create with -pthreads],
 668                                 [ol_cv_pthreads_flag], [
 669                                 dnl save the flags
 670                                 save_LIBS="$LIBS"
 671                                 LIBS="-pthreads $LIBS"
 672                                 AC_TRY_LINK([#include <pthread.h>],[
 673 #if HAVE_PTHREADS_D4
 674         pthread_create(NULL,pthread_attr_default,NULL,NULL);
 675 #else
 676         pthread_create(NULL,NULL,NULL,NULL);
 677 #endif
 678 ],
 679                                         [ol_cv_pthreads_flag=yes], [ol_cv_pthreads_flag=no])
 680                                 dnl restore the LIBS
 681                                 LIBS="$save_LIBS"
 682                         ])
 683
 684                         if test $ol_cv_pthreads_flag = yes ; then
 685                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthreads"
 686                                 ol_link_threads=posix
 687                         fi
 688                 fi
 689
 690                 if test $ol_link_threads = no ; then
 691                         dnl try -thread
 692                         AC_CACHE_CHECK([for pthread_create with -thread],
 693                                 [ol_cv_thread_flag], [
 694                                 dnl save the flags
 695                                 save_LIBS="$LIBS"
 696                                 LIBS="-thread $LIBS"
 697                                 AC_TRY_LINK([char pthread_create();],
 698                                         [pthread_create();],
 699                                         [ol_cv_thread_flag=yes], [ol_cv_thread_flag=no])
 700                                 dnl restore the LIBS
 701                                 LIBS="$save_LIBS"
 702                         ])
 703
 704                         if test $ol_cv_thread_flag = yes ; then
 705                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 706                                 ol_link_threads=posix
 707                         fi
 708                 fi
 709
 710                 if test $ol_link_threads = no ; then
 711                         dnl try -mt
 712                         AC_CACHE_CHECK([for pthread_create with -mt],
 713                                 [ol_cv_thread_flag], [
 714                                 dnl save the flags
 715                                 save_LIBS="$LIBS"
 716                                 LIBS="-mt $LIBS"
 717                                 AC_TRY_LINK([char pthread_create();],
 718                                         [pthread_create();],
 719                                         [ol_cv_thread_flag=yes], [ol_cv_thread_flag=no])
 720                                 dnl restore the LIBS
 721                                 LIBS="$save_LIBS"
 722                         ])
 723
 724                         if test $ol_cv_thread_flag = yes ; then
 725                                 LTHREAD_LIBS="$LTHREAD_LIBS -mt"
 726                                 ol_link_threads=posix
 727                         fi
 728                 fi
 729
 730                 if test $ol_link_threads = no ; then
 731                         dnl try DEC Threads -lpthread -lmach -lexc -lc_r
 732                         save_LIBS="$LIBS"
 733                         AC_CHECK_LIB(pthread, pthread_mutex_unlock, [
 734                                 ol_link_threads=posix
 735                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc -lc_r"
 736                                 if test $ol_with_yielding_select = auto ; then
 737                                         ol_with_yielding_select=yes
 738                                 fi
 739                                 ],:,[-lmach -lexc -lc_r])
 740                         LIBS="$save_LIBS"
 741                 fi
 742
 743                 if test $ol_link_threads = no ; then
 744                         dnl try DEC Threads -lpthread -lmach -lexc
 745                         save_LIBS="$LIBS"
 746                         AC_CHECK_LIB(pthread, pthread_mutex_lock, [
 747                                 ol_link_threads=posix
 748                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc"
 749                                 if test $ol_with_yielding_select = auto ; then
 750                                         ol_with_yielding_select=yes
 751                                 fi
 752                                 ],:,[-lmach -lexc])
 753                         LIBS="$save_LIBS"
 754                 fi
 755
 756                 if test $ol_link_threads = no ; then
 757                         dnl try DEC Threads -lpthread -lexc
 758                         save_LIBS="$LIBS"
 759                         AC_CHECK_LIB(pthread, pthread_mutex_trylock, [
 760                                 ol_link_threads=posix
 761                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 762                                 if test $ol_with_yielding_select = auto ; then
 763                                         ol_with_yielding_select=yes
 764                                 fi
 765                                 ],:,[-lexc])
 766                         LIBS="$save_LIBS"
 767                 fi
 768
 769                 if test $ol_link_threads = no ; then
 770                         dnl try -lpthread
 771                         save_LIBS="$LIBS"
 772                         AC_CHECK_LIB(pthread, pthread_create, [
 773                                 ol_link_threads=posix
 774                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"],:)
 775                         LIBS="$save_LIBS"
 776                 fi
 777
 778                 if test $ol_link_threads = no ; then
 779                         dnl try -lc_r
 780                         save_LIBS="$LIBS"
 781                         AC_CHECK_LIB(c_r, pthread_create, [
 782                                 ol_link_threads=posix
 783                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"],:)
 784                         LIBS="$save_LIBS"
 785                 fi
 786
 787                 if test $ol_link_threads = no ; then
 788                         dnl try -lpthreads
 789                         save_LIBS="$LIBS"
 790                         AC_CHECK_LIB(pthreads, pthread_create, [
 791                                 ol_link_threads=posix
 792                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"],:)
 793                         LIBS="$save_LIBS"
 794                 fi
 795
 796                 dnl IRIX Pthread check
 797                 if test $ol_link_threads = no ; then
 798                         dnl try IRIX Pthreads -Wl,-woff,85 -lpthreads
 799                         save_LIBS="$LIBS"
 800                         AC_CHECK_LIB(pthreads, pthread_join, [
 801                                 ol_link_threads=posix
 802                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"
 803                                 ],:,[-Wl,-woff,85])
 804                         LIBS="$save_LIBS"
 805                 fi
 806
 807                 if test $ol_link_threads = no ; then
 808                         dnl try -threads
 809                         AC_CACHE_CHECK([for pthread_create with -threads],
 810                                 [ol_cv_thread_flag], [
 811                                 dnl save the flags
 812                                 save_LIBS="$LIBS"
 813                                 LIBS="-threads $LIBS"
 814                                 AC_TRY_LINK([char pthread_create();],[
 815                                         pthread_create();
 816                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 817                                 dnl restore the LIBS
 818                                 LIBS="$save_LIBS"
 819                         ])
 820
 821                         if test $ol_cv_thread_flag = yes ; then
 822                                 LTHREAD_LIBS="$LTHREAD_LIBS -threads"
 823                                 ol_link_threads=posix
 824                         fi
 825                 fi
 826
 827                 if test $ol_link_threads = no ; then
 828                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 829                         save_LIBS="$LIBS"
 830                         AC_CHECK_LIB(pthreads, pthread_mutex_unlock, [
 831                                 ol_link_threads=posix
 832                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 833                                 if test $ol_with_yielding_select = auto ; then
 834                                         ol_with_yielding_select=yes
 835                                 fi
 836                                 ],:,[-lmach -lexc -lc_r])
 837                         LIBS="$save_LIBS"
 838                 fi
 839
 840                 if test $ol_link_threads = no ; then
 841                         dnl try DEC Threads -lpthreads -lmach -lexc
 842                         save_LIBS="$LIBS"
 843                         AC_CHECK_LIB(pthreads, pthread_mutex_lock, [
 844                                 ol_link_threads=posix
 845                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc"
 846                                 if test $ol_with_yielding_select = auto ; then
 847                                         ol_with_yielding_select=yes
 848                                 fi
 849                                 ],:,[-lmach -lexc])
 850                         LIBS="$save_LIBS"
 851                 fi
 852
 853                 if test $ol_link_threads = no ; then
 854                         dnl try DEC Threads -lpthreads -lexc
 855                         save_LIBS="$LIBS"
 856                         AC_CHECK_LIB(pthreads, pthread_mutex_trylock, [
 857                                 ol_link_threads=posix
 858                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lexc"
 859                                 if test $ol_with_yielding_select = auto ; then
 860                                         ol_with_yielding_select=yes
 861                                 fi
 862                                 ],:,[-lexc])
 863                         LIBS="$save_LIBS"
 864                 fi
 865
 866                 if test $ol_link_threads != no ; then
 867                         AC_DEFINE(HAVE_PTHREADS,1,
 868                                 [define if you have POSIX Threads])
 869
 870                         dnl save flags
 871                         save_CPPFLAGS="$CPPFLAGS"
 872                         save_LIBS="$LIBS"
 873                         LIBS="$LTHREAD_LIBS $LIBS"
 874
 875                         dnl All POSIX Thread (final) implementations should have
 876                         dnl sched_yield instead of pthread yield.
 877                         dnl check for both
 878                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 879
 880                         if test $ac_cv_func_sched_yield = no -a \
 881                                 $ac_cv_func_pthread_yield = no ; then
 882                                 dnl Digital UNIX has sched_yield() in -lrt
 883                                 AC_CHECK_LIB(rt, sched_yield,
 884                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 885                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 886                                         ac_cv_func_sched_yield=yes],
 887                                         [ac_cv_func_sched_yield=no])
 888                         fi
 889                         if test $ac_cv_func_sched_yield = no -a \
 890                                 $ac_cv_func_pthread_yield = no ; then
 891                                 dnl Solaris has sched_yield() in -lposix4
 892                                 dnl but we'll use thr_yield instead.
 893                                 AC_CHECK_FUNCS(thr_yield)
 894                         fi
 895                         if test $ac_cv_func_sched_yield = no -a \
 896                                 $ac_cv_func_pthread_yield = no -a \
 897                                 "$ac_cv_func_thr_yield" = no ; then
 898                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 899                         fi
 900
 901                         dnl Check functions for compatibility
 902                         AC_CHECK_FUNCS(pthread_kill)
 903
 904                         dnl Check for pthread_detach with <pthread.h> inclusion
 905                         dnl as it's symbol may have been mangled.
 906                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
 907                                 [ol_cv_func_pthread_detach], [
 908                                 dnl save the flags
 909                                 AC_TRY_LINK([#include <pthread.h>],
 910                                         [pthread_detach(NULL);],
 911                                         [ol_cv_func_pthread_detach=yes],
 912                                         [ol_cv_func_pthread_detach=no])
 913                         ])
 914
 915                         if test $ol_cv_func_pthread_detach = no ; then
 916                                 AC_MSG_ERROR([could not locate pthread_detach()])
 917                         fi
 918
 919                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
 920                                 [define if you have pthread_detach function])
 921
 922                         dnl Check for setconcurreny functions
 923                         AC_CHECK_FUNCS( \
 924                                 pthread_setconcurrency \
 925                                 pthread_getconcurrency \
 926                                 thr_setconcurrency \
 927                                 thr_getconcurrency \
 928                         )
 929
 930                         AC_MSG_CHECKING([if pthread_create() works])
 931                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 932                         AC_TRY_RUN([
 933 #include <pthread.h>
 934 #ifndef NULL
 935 #define NULL (void*)0
 936 #endif
 937
 938 static void *task(p)
 939         void *p;
 940 {
 941         return (void *) (p == NULL);
 942 }
 943
 944 int main(argc, argv)
 945         int argc;
 946         char **argv;
 947 {
 948         pthread_t t;
 949 #if HAVE_PTHREADS_D4
 950         exit(pthread_create(&t, pthread_attr_default, task, NULL));
 951 #else
 952         exit(pthread_create(&t, NULL, task, NULL));
 953 #endif
 954 }
 955 ],
 956                                 [ol_cv_pthread_create_works=yes],
 957                                 [ol_cv_pthread_create_works=no],
 958                                 [dnl assume yes
 959                                 ol_cv_pthread_create_works=yes])])
 960                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 961
 962                         if test $ol_cv_pthread_create_works = no ; then
 963                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
 964                         fi
 965
 966                         dnl Check if select causes an yield
 967                         if test $ol_with_yielding_select = auto ; then
 968                                 AC_MSG_CHECKING([if select yields when using pthreads])
 969                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 970                                 AC_TRY_RUN([
 971 #include <sys/types.h>
 972 #include <sys/time.h>
 973 #include <unistd.h>
 974 #include <pthread.h>
 975 #ifndef NULL
 976 #define NULL (void*) 0
 977 #endif
 978
 979 static int fildes[2];
 980
 981 static void *task(p)
 982         void *p;
 983 {
 984         int i;
 985         struct timeval tv;
 986
 987         fd_set rfds;
 988
 989         tv.tv_sec=10;
 990         tv.tv_usec=0;
 991
 992         FD_ZERO(&rfds);
 993         FD_SET(fildes[0], &rfds);
 994
 995         /* we're not interested in any fds */
 996         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 997
 998         if(i < 0) {
 999                 perror("select");
1000                 exit(10);
1001         }
1002
1003         exit(0); /* if we exit here, the select blocked the whole process */
1004 }
1005
1006 int main(argc, argv)
1007         int argc;
1008         char **argv;
1009 {
1010         pthread_t t;
1011
1012         /* create a pipe to select */
1013         if(pipe(&fildes[0])) {
1014                 perror("select");
1015                 exit(1);
1016         }
1017
1018 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1019         (void) pthread_setconcurrency(2);
1020 #else
1021 #ifdef HAVE_THR_SETCONCURRENCY
1022         /* Set Solaris LWP concurrency to 2 */
1023         thr_setconcurrency(2);
1024 #endif
1025 #endif
1026
1027 #if HAVE_PTHREADS_D4
1028         pthread_create(&t, pthread_attr_default, task, NULL);
1029 #else
1030         pthread_create(&t, NULL, task, NULL);
1031 #endif
1032
1033 #if HAVE_SCHED_YIELD
1034         sched_yield();  /* make sure task runs first */
1035 #else
1036 #ifdef HAVE_PTHREAD_YIELD
1037         pthread_yield();        /* make sure task runs first */
1038 #endif
1039 #endif
1040
1041         exit(2);
1042 }],
1043                                 [ol_cv_pthread_select_yields=no],
1044                                 [ol_cv_pthread_select_yields=yes], [
1045                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
1046                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
1047
1048                                 if test $ol_cv_pthread_select_yields = yes ; then
1049                                         ol_with_yielding_select=yes
1050                                 fi
1051                         fi
1052
1053                         dnl restore flags
1054                         CPPFLAGS="$save_CPPFLAGS"
1055                         LIBS="$save_LIBS"
1056                 else
1057                         AC_MSG_ERROR([could not link with POSIX Threads])
1058                 fi
1059         fi
1060
1061         if test $ol_with_threads = posix ; then
1062                 AC_MSG_ERROR([could not locate POSIX Threads])
1063         fi
1064 fi
1065
1066 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1067         -o $ol_with_threads = mach ; then
1068
1069         dnl check for Mach CThreads
1070         AC_CHECK_HEADERS(mach/cthreads.h)
1071         if test $ac_cv_header_mach_cthreads_h = yes ; then
1072                 ol_with_threads=found
1073
1074                 dnl check for cthread support in current $LIBS
1075                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1076
1077                 if test $ol_link_threads = no ; then
1078                         dnl try -all_load
1079                         dnl this test needs work
1080                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1081                                 [ol_cv_cthread_all_load], [
1082                                 dnl save the flags
1083                                 save_LIBS="$LIBS"
1084                                 LIBS="-all_load $LIBS"
1085                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1086                                         cthread_fork((void *)0, (void *)0);
1087                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1088                                 dnl restore the LIBS
1089                                 LIBS="$save_LIBS"
1090                         ])
1091
1092                         if test $ol_cv_cthread_all_load = yes ; then
1093                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1094                                 ol_link_threads=mach
1095                         fi
1096                 fi
1097
1098                 if test $ol_link_threads != no ; then
1099                         : check for cthread specific functionality here
1100                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1101                                 [define if you have Mach Cthreads])
1102                 else
1103                         AC_MSG_ERROR([could not link with Mach CThreads])
1104                 fi
1105         fi
1106
1107         if test $ol_with_threads = mach ; then
1108                 AC_MSG_ERROR([could not locate Mach CThreads])
1109         fi
1110 fi
1111
1112 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1113         -o $ol_with_threads = lwp ; then
1114
1115         dnl check for SunOS5 LWP
1116         AC_CHECK_HEADERS(thread.h synch.h)
1117         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1118                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1119
1120                 if test $have_thr = yes ; then
1121                         AC_DEFINE(HAVE_THR,1,
1122                                 [if you have Solaris LWP (thr) package])
1123                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1124                         ol_link_threads=thr
1125
1126                         if test $ol_with_yielding_select = auto ; then
1127                                 ol_with_yielding_select=yes
1128                         fi
1129
1130                         dnl Check for setconcurreny functions
1131                         AC_CHECK_FUNCS( \
1132                                 thr_setconcurrency \
1133                                 thr_getconcurrency \
1134                         )
1135                 fi
1136         fi
1137
1138         dnl check for SunOS4 LWP
1139         AC_CHECK_HEADERS(lwp/lwp.h)
1140         if test $ac_cv_header_lwp_lwp_h = yes ; then
1141                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1142
1143                 if test $have_lwp = yes ; then
1144                         AC_DEFINE(HAVE_LWP,1,
1145                                 [if you have SunOS LWP package])
1146                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1147                         ol_link_threads=lwp
1148
1149                         if test $ol_with_yielding_select = auto ; then
1150                                 ol_with_yielding_select=no
1151                         fi
1152                 fi
1153         fi
1154 fi
1155
1156 if test $ol_with_yielding_select = yes ; then
1157         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1158                 [define if select implicitly yields])
1159 fi
1160
1161 if test $ol_with_threads = manual ; then
1162         dnl User thinks he can manually configure threads.
1163         ol_link_threads=yes
1164
1165         AC_MSG_WARN([thread defines and link options must be set manually])
1166
1167         AC_CHECK_HEADERS(pthread.h sched.h)
1168         AC_CHECK_FUNCS(sched_yield pthread_yield)
1169         OL_LINUX_THREADS
1170
1171         AC_CHECK_HEADERS(mach/cthreads.h)
1172         AC_CHECK_HEADERS(lwp/lwp.h)
1173         AC_CHECK_HEADERS(thread.h synch.h)
1174 fi
1175
1176 if test $ol_link_threads != no ; then
1177         dnl needed to get reentrant/threadsafe versions
1178         dnl
1179         AC_DEFINE(REENTRANT,1)
1180         AC_DEFINE(_REENTRANT,1)
1181         AC_DEFINE(THREAD_SAFE,1)
1182         AC_DEFINE(_THREAD_SAFE,1)
1183         AC_DEFINE(THREADSAFE,1)
1184         AC_DEFINE(_THREADSAFE,1)
1185
1186         dnl this might cause the errno symbol to be
1187         dnl replaced with a function to get a thread specific errno.
1188         dnl check to see if everything needs to be compiled
1189         dnl with the thread libraries
1190         AC_CACHE_CHECK([for thread specific errno],
1191                 [ol_cv_errno_thread_specific], [
1192                 AC_TRY_LINK([#include <errno.h>], [int x = errno;],
1193                         [ol_cv_errno_thread_specific=yes],
1194                         [ol_cv_errno_thread_specific=no])
1195         ])
1196
1197         if test $ol_cv_errno_thread_specific != yes ; then
1198                 LIBS="$LTHREAD_LIBS $LIBS"
1199                 LTHREAD_LIBS=""
1200         fi
1201
1202 dnl When in thread environment, use
1203 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1204 dnl                     || defined( HAVE_FUNC_R )
1205 dnl                     func_r(...);
1206 dnl             #else
1207 dnl             #       if defined( HAVE_THREADS )
1208 dnl                             /* lock */
1209 dnl             #       endif
1210 dnl                             func(...);
1211 dnl             #       if defined( HAVE_THREADS )
1212 dnl                             /* unlock */
1213 dnl             #       endif
1214 dnl             #endif
1215 dnl
1216 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1217 dnl             _POSIX_REENTRANT_FUNCTIONS
1218 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1219 dnl             _POSIX_THREADSAFE_FUNCTIONS
1220 dnl
1221 dnl             and is currently defined in lthread.h
1222 dnl
1223 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1224 dnl
1225 dnl libldap/*.c should only include <lthread.h> iff
1226 dnl LDAP_R_COMPILE is defined.  ie:
1227 dnl             #ifdef LDAP_R_COMPILE
1228 dnl             #       include LDAP_R_COMPILE
1229 dnl             #endif
1230 dnl
1231 dnl LDAP_R_COMIPLE is defined by libldap_r/Makefile.in
1232 dnl specifically for compiling the threadsafe version of
1233 dnl     the ldap library (-lldap_r).
1234 dnl
1235 dnl     dnl check for reentrant/threadsafe functions
1236 dnl     dnl
1237 dnl     dnl note: these should only be used when linking
1238 dnl     dnl       with $LTHREAD_LIBS
1239 dnl     dnl
1240 dnl     save_CPPFLAGS="$CPPFLAGS"
1241 dnl     save_LIBS="$LIBS"
1242 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1243 dnl     AC_CHECK_FUNCS( \
1244 dnl             gmtime_r \
1245 dnl             gethostbyaddr_r gethostbyname_r \
1246 dnl             feof_unlocked unlocked_feof \
1247 dnl             putc_unlocked unlocked_putc \
1248 dnl             flockfile ftrylockfile \
1249 dnl     )
1250 dnl     CPPFLAGS="$save_CPPFLAGS"
1251 dnl     LIBS="$save_LIBS"
1252 fi
1253
1254 if test $ol_link_threads = no ; then
1255         if test $ol_with_threads = yes ; then
1256                 AC_MSG_ERROR([no suitable thread support])
1257         fi
1258
1259         if test $ol_with_threads = auto ; then
1260                 AC_MSG_WARN([no suitable thread support, disabling threads])
1261                 ol_with_threads=no
1262         fi
1263
1264         AC_DEFINE(NO_THREADS,1,
1265                 [define if you have (or want) no threads])
1266         LTHREAD_LIBS=""
1267 fi
1268
1269 if test $ol_link_threads != no ; then
1270         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1271 fi
1272
1273 dnl ----------------------------------------------------------------
1274
1275 ol_link_ldbm=no
1276 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1277         OL_BERKELEY_DB2
1278
1279         if test $ol_cv_berkeley_db2 = yes ; then
1280                 ol_link_ldbm=db2
1281                 ol_with_ldbm_api=db2
1282
1283                 if test $ol_with_ldbm_type = hash ; then
1284                         AC_DEFINE(LDBM_USE_DBHASH,1)
1285                 else
1286                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1287                 fi
1288
1289                 dnl $ol_cv_lib_db2 should be yes or -ldb
1290                 dnl (it could be no, but that would be an error
1291                 if test $ol_cv_lib_db2 != yes ; then
1292                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1293                 fi
1294         fi
1295 fi
1296
1297 ol_link_bdb2=no
1298 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1299         ol_link_bdb2=yes
1300 fi
1301
1302 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1303         OL_BERKELEY_DB
1304
1305         if test $ol_cv_berkeley_db = yes ; then
1306                 ol_link_ldbm=db
1307                 ol_with_ldbm_api=db
1308
1309                 if test $ol_with_ldbm_type = hash ; then
1310                         AC_DEFINE(LDBM_USE_DBHASH,1)
1311                 else
1312                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1313                 fi
1314
1315                 dnl $ol_cv_lib_db should be yes or -ldb
1316                 dnl (it could be no, but that would be an error
1317                 if test $ol_cv_lib_db != yes ; then
1318                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1319                 fi
1320         fi
1321 fi
1322
1323 if test $ol_with_ldbm_api = manual ; then
1324         dnl User thinks he can manually configure LDBM api.
1325         ol_link_ldbm=yes
1326
1327         AC_MSG_WARN([LDBM defines and link options must be set manually])
1328
1329         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1330 fi
1331
1332 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1333         AC_MSG_WARN(Could not find LDBM with BTREE support)
1334         ol_with_ldbm_api=none
1335 fi
1336
1337 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1338         OL_GDBM
1339
1340         if test $ol_cv_gdbm = yes ; then
1341                 ol_link_ldbm=gdbm
1342                 ol_with_ldbm_api=gdbm
1343
1344                 if test $ol_cv_lib_gdbm != yes ; then
1345                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1346                 fi
1347         fi
1348 fi
1349
1350 if test $ol_with_ldbm_api = auto ; then
1351         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1352 elif test $ol_with_ldbm_api = ndbm ; then
1353         OL_NDBM
1354
1355         if test $ol_cv_ndbm = yes ; then
1356                 ol_link_ldbm=ndbm
1357                 ol_with_ldbm_api=ndbm
1358
1359                 if test $ol_cv_lib_ndbm != yes ; then
1360                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1361                 fi
1362         fi
1363 fi
1364
1365 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1366         AC_MSG_WARN(could not find suitable LDBM backend)
1367         if test $ol_enable_ldbm = yes ; then
1368                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1369         fi
1370
1371         AC_MSG_WARN(disabling LDBM)
1372         ol_enable_ldbm=no
1373 fi
1374
1375 if test $ol_enable_wrappers != no ; then
1376         AC_CHECK_HEADERS(tcpd.h)
1377
1378         if test $ac_cv_header_tcpd_h != yes ; then
1379                 have_wrappers=no
1380         else
1381                 AC_CHECK_LIB(wrap, main,
1382                         [have_wrappers=yes], [have_wrappers=no])
1383         fi
1384
1385         if test $have_wrappers = yes ; then
1386                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1387                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1388         else
1389                 AC_MSG_WARN(could not find -lwrap)
1390                 if test $ol_enable_wrappers = yes ; then
1391                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1392                 fi
1393
1394                 AC_MSG_WARN(disabling wrappers support)
1395                 ol_enable_wrappers=no
1396         fi
1397 fi
1398
1399 if test $ol_enable_syslog != no ; then
1400         AC_CHECK_FUNC(openlog)
1401         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1402                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1403         fi
1404         ol_enable_syslog=$ac_cv_func_openlog
1405 fi
1406
1407 if test $ol_enable_dmalloc != no ; then
1408         AC_CHECK_HEADERS(dmalloc.h)
1409         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1410 fi
1411
1412 if test $ol_enable_tcl != no ; then
1413         AC_CHECK_HEADERS(tcl.h)
1414
1415         if test $ac_cv_header_tcl_h != yes ; then
1416                 have_tcl=no
1417         else
1418                 AC_CHECK_LIB(tcl,main,
1419                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1420                         [have_tcl=no])
1421
1422                 if test $have_tcl != yes; then
1423                         AC_CHECK_LIB(tcl7.6,main,
1424                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1425                                 [have_tcl=no])
1426                 fi
1427
1428                 if test $have_tcl != yes; then
1429                         AC_CHECK_LIB(tcl8.0,main,
1430                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1431                                 [have_tcl=no])
1432                 fi
1433         fi
1434
1435         if test $have_tcl != yes ; then
1436                 AC_MSG_WARN([could not find -ltcl])
1437                 if test $ol_enable_tcl = yes ; then
1438                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1439                 fi
1440
1441                 ol_enable_tcl=no
1442         fi
1443 fi
1444
1445 # ud needs termcap (should insert check here)
1446 ol_link_termcap=no
1447 AC_CHECK_HEADERS(termcap.h ncurses.h)
1448
1449 if test $ol_link_termcap = no ; then
1450         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1451         if test $have_termcap = yes ; then
1452                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1453                 ol_link_termcap=yes
1454                 TERMCAP_LIBS=-ltermcap
1455         fi
1456 fi
1457
1458 if test $ol_link_termcap = no ; then
1459         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1460         if test $have_ncurses = yes ; then
1461                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1462                 ol_link_termcap=yes
1463                 TERMCAP_LIBS=-lncurses
1464         fi
1465 fi
1466
1467 if test $ol_link_termcap = no ; then
1468         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1469         TERMCAP_LIBS=
1470 fi
1471
1472 dnl
1473 dnl Check for GNU readline
1474 dnl
1475 ol_link_readline=no
1476 if test $ol_with_readline != no ; then
1477         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1478
1479         if test $ac_cv_header_readline_readline_h = yes ; then
1480                 save_LIBS="$LIBS"
1481                 LIBS="$TERMCAP_LIBS $LIBS"
1482                 AC_CHECK_LIB(readline, readline,
1483                         [have_readline=yes], [have_readline=no])
1484                 LIBS="$save_LIBS"
1485
1486                 if test $have_readline = yes ; then
1487                         ol_with_readline=found
1488                         ol_link_readline=yes
1489
1490                         READLINE_LIBS="-lreadline"
1491                 fi
1492         fi
1493 fi
1494
1495 if test $ol_link_readline = yes ; then
1496         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1497 fi
1498
1499
1500 # FreeBSD (and others) have crypt(3) in -lcrypt
1501 if test $ol_enable_crypt != no ; then
1502         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1503                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1504                         have_crypt=yes], [have_crypt=no])])
1505
1506         if test $have_crypt = yes ; then
1507                 AC_DEFINE(HAVE_CRYPT,1)
1508         else
1509                 AC_MSG_WARN(could not find crypt)
1510                 if test $ol_enable_crypt = yes ; then
1511                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1512                 fi
1513
1514                 AC_MSG_WARN(disabling crypt support)
1515                 ol_enable_crypt=no
1516         fi
1517 fi
1518
1519 # FreeBSD (and others) have setproctitle(3) in -lutil
1520 if test $ol_enable_proctitle != no ; then
1521         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1522                 AC_CHECK_LIB(util, setproctitle,
1523                         [have_setproctitle=yes
1524                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1525                         [have_setproctitle=no
1526                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1527
1528         if test $have_setproctitle = yes ; then
1529                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1530         fi
1531 fi
1532
1533 dnl ----------------------------------------------------------------
1534 dnl Checks for header files.
1535 AC_HEADER_STDC
1536
1537 if test $ac_cv_header_stdc != yes; then
1538         AC_MSG_WARN([could not Standard C compliant headers])
1539 fi
1540
1541 AC_HEADER_DIRENT
1542 AC_HEADER_SYS_WAIT
1543 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1544 if test $am_cv_sys_posix_termios = yes ; then
1545         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1546                 [define if you have POSIX termios])
1547 fi
1548
1549 AC_CHECK_HEADERS(       \
1550         arpa/nameser.h  \
1551         crypt.h                 \
1552         errno.h                 \
1553         fcntl.h                 \
1554         filio.h                 \
1555         getopt.h                \
1556         libutil.h               \
1557         limits.h                \
1558         locale.h                \
1559         malloc.h                \
1560         memory.h                \
1561         regex.h                 \
1562         psap.h                  \
1563         pwd.h                   \
1564         resolv.h                \
1565         sgtty.h                 \
1566         stdarg.h                \
1567         stddef.h                \
1568         string.h                \
1569         strings.h               \
1570         sysexits.h              \
1571         sys/file.h              \
1572         sys/filio.h             \
1573         sys/errno.h             \
1574         sys/ioctl.h             \
1575         sys/param.h             \
1576         sys/resource.h  \
1577         sys/socket.h    \
1578         sys/syslog.h    \
1579         sys/time.h              \
1580         sys/types.h             \
1581         syslog.h                \
1582         termios.h               \
1583         unistd.h                \
1584 )
1585
1586 dnl ----------------------------------------------------------------
1587 dnl Checks for typedefs, structures, and compiler characteristics.
1588 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1589 AC_TYPE_MODE_T
1590 AC_TYPE_OFF_T
1591 AC_TYPE_PID_T
1592 AM_TYPE_PTRDIFF_T
1593 AC_TYPE_SIGNAL
1594 OL_TYPE_SIG_ATOMIC_T
1595 AC_TYPE_SIZE_T
1596 AC_STRUCT_ST_BLKSIZE
1597 AC_HEADER_TIME
1598 AC_STRUCT_TM
1599
1600 OL_C_UPPER_LOWER
1601 AC_C_CONST
1602 OL_C_VOLATILE
1603
1604 if test $cross_compiling = yes ; then
1605         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1606 else
1607         AC_C_BIGENDIAN
1608         AC_CHECK_SIZEOF(short)
1609         AC_CHECK_SIZEOF(int)
1610         AC_CHECK_SIZEOF(long)
1611 fi
1612
1613 dnl ----------------------------------------------------------------
1614 dnl Checks for library functions.
1615 AC_FUNC_MEMCMP
1616 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1617 AC_FUNC_STRFTIME
1618 dnl AM_FUNC_STRTOD
1619 AC_FUNC_VPRINTF
1620
1621 if test $ac_cv_func_vprintf = yes ; then
1622         dnl check for vsnprintf
1623         AC_CHECK_FUNCS(vsnprintf vsprintf)
1624 fi
1625
1626 AC_CHECK_FUNCS(         \
1627         bcopy                   \
1628         flock                   \
1629         getdtablesize   \
1630         gethostname             \
1631         getpwuid                \
1632         gettimeofday    \
1633         lockf                   \
1634         memcpy                  \
1635         memmove                 \
1636         mkstemp                 \
1637         select                  \
1638         setpwfile               \
1639         setsid                  \
1640         signal                  \
1641         sigset                  \
1642         snprintf                \
1643         socket                  \
1644         strdup                  \
1645         strerror                \
1646         strpbrk                 \
1647         strrchr                 \
1648         strsep                  \
1649         strstr                  \
1650         strtol                  \
1651         strtoul                 \
1652         strspn                  \
1653         sysconf                 \
1654         waitpid                 \
1655 )
1656
1657 dnl We actually may need to replace more than this.
1658 AC_REPLACE_FUNCS(getopt tempnam)
1659
1660 dnl ----------------------------------------------------------------
1661 # Check Configuration
1662 OL_SYS_ERRLIST
1663
1664 dnl ----------------------------------------------------------------
1665 dnl Sort out defines
1666
1667 if test "$ol_enable_debug" != no ; then
1668         AC_DEFINE(LDAP_DEBUG,1)
1669 fi
1670 if test "$ol_enable_syslog" = yes ; then
1671         AC_DEFINE(LDAP_SYSLOG,1)
1672 fi
1673 if test "$ol_enable_libui" = yes ; then
1674         AC_DEFINE(LDAP_LIBUI,1)
1675 fi
1676 if test "$ol_enable_cache" = no ; then
1677         AC_DEFINE(LDAP_NOCACHE,1)
1678 fi
1679 if test "$ol_enable_dns" != no ; then
1680         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1681 fi
1682 if test "$ol_enable_proctitle" != no ; then
1683         AC_DEFINE(LDAP_PROCTITLE,1)
1684 fi
1685 if test "$ol_enable_referrals" != no ; then
1686         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1687 fi
1688 if test "$ol_enable_cldap" != no ; then
1689         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1690 fi
1691
1692 if test "$ol_enable_aclgroups" != no ; then
1693         AC_DEFINE(SLAPD_ACLGROUPS,1)
1694 fi
1695 if test "$ol_enable_crypt" != no ; then
1696         AC_DEFINE(SLAPD_CRYPT,1)
1697 fi
1698 if test "$ol_enable_cleartext" != no ; then
1699         AC_DEFINE(SLAPD_CLEARTEXT,1)
1700 fi
1701 if test "$ol_enable_phonetic" != no ; then
1702         AC_DEFINE(SLAPD_PHONETIC,1)
1703 fi
1704 if test "$ol_enable_rlookups" != no ; then
1705         AC_DEFINE(SLAPD_RLOOKUPS,1)
1706 fi
1707
1708 if test "$ol_link_bdb2" != no ; then
1709         AC_DEFINE(SLAPD_BDB2,1)
1710         BUILD_SLAPD=yes
1711         BUILD_BDB2=yes
1712 fi
1713
1714 if test "$ol_link_ldbm" != no ; then
1715         AC_DEFINE(SLAPD_LDBM,1)
1716         BUILD_SLAPD=yes
1717         BUILD_LDBM=yes
1718 fi
1719
1720 if test "$ol_enable_passwd" != no ; then
1721         AC_DEFINE(SLAPD_PASSWD,1)
1722         BUILD_SLAPD=yes
1723         BUILD_PASSWD=yes
1724 fi
1725
1726 if test "$ol_enable_perl" != no ; then
1727         AC_DEFINE(SLAPD_PERL,1)
1728         BUILD_SLAPD=yes
1729         BUILD_PERL=yes
1730 fi
1731
1732 if test "$ol_enable_shell" != no ; then
1733         AC_DEFINE(SLAPD_SHELL,1)
1734         BUILD_SLAPD=yes
1735         BUILD_SHELL=yes
1736 fi
1737
1738 if test "$ol_enable_tcl" != no ; then
1739         AC_DEFINE(SLAPD_TCL,1)
1740         BUILD_SLAPD=yes
1741         BUILD_TCL=yes
1742 fi
1743
1744 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1745         $BUILD_SLAPD = yes ; then
1746         BUILD_SLURPD=yes
1747 fi
1748
1749 if test "$ol_link_isode" != no ; then
1750         BUILD_LDAPD=yes
1751 fi
1752
1753 dnl ----------------------------------------------------------------
1754
1755 AC_SUBST(BUILD_LDAPD)
1756 AC_SUBST(BUILD_SLAPD)
1757   AC_SUBST(BUILD_BDB2)
1758   AC_SUBST(BUILD_LDBM)
1759   AC_SUBST(BUILD_PASSWD)
1760   AC_SUBST(BUILD_PERL)
1761   AC_SUBST(BUILD_SHELL)
1762   AC_SUBST(BUILD_TCL)
1763 AC_SUBST(BUILD_SLURPD)
1764
1765 AC_SUBST(LDAP_LIBS)
1766 AC_SUBST(LDAPD_LIBS)
1767 AC_SUBST(SLAPD_LIBS)
1768 AC_SUBST(SLURPD_LIBS)
1769 AC_SUBST(LDBM_LIBS)
1770 AC_SUBST(LTHREAD_LIBS)
1771 AC_SUBST(LUTIL_LIBS)
1772
1773 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1774 AC_SUBST(SLAPD_PERL_LDFLAGS)
1775
1776 AC_SUBST(KRB_LIBS)
1777 AC_SUBST(READLINE_LIBS)
1778 AC_SUBST(TERMCAP_LIBS)
1779 AC_SUBST(TLS_LIBS)
1780
1781 dnl ----------------------------------------------------------------
1782 dnl final output
1783 dnl
1784
1785 AC_OUTPUT( \
1786 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1787 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1788 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1789 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1790 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1791 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1792 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1793 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1794 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1795 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1796 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1797 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1798 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1799 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1800 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1801 include/Makefile:build/top.mk:include/Makefile.in \
1802 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1803 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1804 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1805 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1806 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1807 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1808 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1809 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1810 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1811 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1812 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1813 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
1814 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1815 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1816 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
1817 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1818 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
1819 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1820 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1821 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1822 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
1823 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
1824 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
1825 ,[
1826 date > stamp-h
1827 echo Please \"make depend\" to build dependencies
1828 ])