git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms are permitted only
   6 dnl as authorized by the OpenLDAP Public License.  A copy of this
   7 dnl license is available at http://www.OpenLDAP.org/license.html or
   8 dnl in file LICENSE in the top-level directory of the distribution.
   9 dnl
  10 dnl ----------------------------------------------------------------
  11 dnl Redefine AC_INIT_BINSH to provide RCS IDs and copyright notice
  12 dnl at top of generated configure script.  Prints simple copyright.
  13 define([AC_INIT_BINSH],
  14 [[#! /bin/sh
  15 # $]OpenLDAP[$
  16 # from] translit([$OpenLDAP$], $")] [
  17
  18 # Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
  19 #
  20 # Redistribution and use in source and binary forms are permitted only
  21 # as authorized by the OpenLDAP Public License.  A copy of this
  22 # license is available at http://www.OpenLDAP.org/license.html or
  23 # in file LICENSE in the top-level directory of the distribution.
  24
  25 echo "Copyright 1998-2000 The OpenLDAP Foundation,  All Rights Reserved."
  26 echo "Copying restrictions apply, see COPYRIGHT file."
  27 ])dnl
  28 dnl ----------------------------------------------------------------
  29 dnl Disable config.cache!
  30 define([AC_CACHE_LOAD], )dnl
  31 define([AC_CACHE_SAVE], )dnl
  32 dnl ================================================================
  33 dnl Configure.in for OpenLDAP
  34 AC_INIT(build/version)dnl
  35 AC_CONFIG_AUX_DIR(build)dnl
  36
  37 OL_VERSION=`cat $ac_aux_dir/version`
  38 if test -z "$OL_VERSION"; then
  39         AC_MSG_ERROR([could not determine version])
  40 fi
  41
  42 echo "Configuring OpenLDAP $OL_VERSION ..."
  43
  44 dnl Determine host platform
  45 dnl             we try not to use this for much
  46 AC_CANONICAL_SYSTEM
  47
  48 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  49 AC_SUBST(PACKAGE)
  50 AC_SUBST(VERSION)
  51 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  52 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  53
  54 dnl We use autoconf features new to 2.13.
  55 dnl aclocal.m4 should be built using aclocal from automake 1.4
  56 dnl libtool 1.3.3 should be installed.
  57 AC_PREREQ(2.13)dnl Required Autoconf version
  58
  59 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  60
  61 dnl ================================================================
  62 dnl Start Args
  63 AC_MSG_CHECKING(configure arguments)
  64 AC_PREFIX_DEFAULT(/usr/local)
  65
  66 top_builddir=`pwd`
  67 AC_SUBST(top_builddir)dnl
  68
  69 dnl ----------------------------------------------------------------
  70 dnl --with-subdir
  71 ldap_subdir="/openldap"
  72
  73 AC_ARG_WITH(subdir,
  74 [  --with-subdir=DIR change default subdirectory used for installs],
  75 [case "$withval" in
  76         no) ldap_subdir=""
  77                 ;;
  78         yes)
  79                 ;;
  80         /*|\\*)
  81                 ldap_subdir="$withval"
  82                 ;;
  83         *)
  84                 ldap_subdir="/$withval"
  85                 ;;
  86 esac
  87 ])dnl
  88
  89 AC_SUBST(ldap_subdir)dnl
  90
  91 dnl ----------------------------------------------------------------
  92 dnl General "enable" options
  93 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  94 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  95 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  96 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  97 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DX Referrals extension], no)dnl
  98 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  99 OL_ARG_ENABLE(kbind,[  --enable-kbind   enable V2 Kerberos IV bind], auto)dnl
 100 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
 101 OL_ARG_ENABLE(ldapi,[  --enable-ldapi   enable domain socket (PF_LOCAL) ldap], no)dnl
 102 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
 103         no, [yes no])dnl
 104
 105 dnl ----------------------------------------------------------------
 106 dnl General "with" options
 107 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
 108
 109 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl     with Cyrus SASL support],
 110         auto, [auto yes no] )
 111 OL_ARG_WITH(fetch,[  --with-fetch               with fetch URL support],
 112         auto, [auto yes no] )
 113 OL_ARG_WITH(kerberos,[  --with-kerberos with support],
 114         auto, [auto k5 k5only k425 kth k4 afs yes no])
 115 OL_ARG_WITH(readline,[  --with-readline with readline support],
 116         auto, [auto yes no] )
 117 OL_ARG_WITH(threads,[  --with-threads   use threads],
 118         auto, [auto nt posix mach pth lwp yes no manual] )
 119 OL_ARG_WITH(tls,[  --with-tls           with TLS/SSL support],
 120         auto, [auto ssleay openssl yes no] )
 121 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
 122         auto, [auto yes no manual] )
 123
 124 dnl ----------------------------------------------------------------
 125 dnl Server options
 126 dnl ----------------------------------------------------------------
 127 dnl LDAPD OPTIONS
 128 AC_ARG_WITH(xxldapdoptions,[LDAPD (X.500-to-LDAP Gateway) Options:])
 129 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
 130
 131 dnl ----------------------------------------------------------------
 132 dnl SLAPD OPTIONS
 133 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 134 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
 135 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
 136 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
 137 OL_ARG_ENABLE(kpasswd,[    --enable-kpasswd     enable kerberos password verification], no)dnl
 138 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
 139 OL_ARG_ENABLE(multimaster,[    --enable-multimaster     enable multimaster replication], no)dnl
 140 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
 141 OL_ARG_ENABLE(quipu,[    --enable-quipu build quipu migration tools], no)dnl
 142 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
 143 OL_ARG_ENABLE(aci,[    --enable-aci     enable per-object ACIs], no)dnl
 144 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
 145 OL_ARG_ENABLE(dynamic,[    --enable-dynamic     enable linking built binaries with dynamic libs], no)dnl
 146
 147 dnl SLAPD Backend options
 148 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 149 OL_ARG_WITH(bdb2_module,[      --with-bdb2-module       module type], static,
 150         [static dynamic])
 151 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 152 OL_ARG_WITH(ldap_module,[      --with-ldap-module       module type], static,
 153         [static dynamic])
 154 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 155 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 156         [auto db2 db mdbm gdbm manual])
 157 OL_ARG_WITH(ldbm_module,[      --with-ldbm-module       module type], static,
 158         [static dynamic])
 159 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 160         [auto btree hash])
 161
 162 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 163 OL_ARG_WITH(passwd_module,[      --with-passwd-module   module type], static,
 164         [static dynamic])
 165 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 166 OL_ARG_WITH(perl_module,[      --with-perl-module       module type], static,
 167         [static dynamic])
 168 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 169 OL_ARG_WITH(shell_module,[      --with-shell-module     module type], static,
 170         [static dynamic])
 171 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 172 OL_ARG_WITH(tcl_module,[      --with-tcl-module module type], static,
 173         [static dynamic])
 174 OL_ARG_ENABLE(sql,[    --enable-sql     enable sql backend], no)dnl
 175 OL_ARG_WITH(sql_module,[      --with-sql-module module type], static,
 176         [static dynamic])
 177
 178 dnl ----------------------------------------------------------------
 179 dnl SLURPD OPTIONS
 180 AC_ARG_WITH(xxslurpdoptions,[SLURPD (Replication Daemon) Options:])
 181 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 182
 183 dnl ----------------------------------------------------------------
 184 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 185 AC_ENABLE_STATIC
 186 dnl AC_DISABLE_SHARED
 187 AC_ENABLE_SHARED
 188
 189 dnl ----------------------------------------------------------------
 190
 191 dnl General "enable" options
 192 # validate options
 193 if test $ol_enable_dns = yes ; then
 194         if test $ol_enable_referrals = no ; then
 195                 AC_MSG_ERROR([DNS requires --enable-referrals])
 196         fi
 197         if test $ol_enable_referrals = auto ; then
 198                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 199                 ol_enable_referrals=yes
 200         fi
 201 fi
 202
 203 if test $ol_enable_slapd = no ; then
 204         dnl SLAPD was specificallly disabled
 205         if test $ol_enable_bdb2 = yes ; then
 206                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 207         fi
 208         if test $ol_enable_ldap = yes ; then
 209                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 210         fi
 211         if test $ol_enable_ldbm = yes ; then
 212                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 213         fi
 214         if test $ol_enable_passwd = yes ; then
 215                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 216         fi
 217         if test $ol_enable_perl = yes ; then
 218                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 219         fi
 220         if test $ol_enable_shell = yes ; then
 221                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 222         fi
 223         if test $ol_enable_tcl = yes ; then
 224                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 225         fi
 226         if test $ol_enable_sql = yes ; then
 227                 AC_MSG_WARN([slapd disabled, ignoring --enable-sql argument])
 228         fi
 229         if test $ol_enable_modules = yes ; then
 230                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 231         fi
 232         if test $ol_enable_multimaster = yes ; then
 233                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 234         fi
 235         if test $ol_enable_wrappers = yes ; then
 236                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 237         fi
 238         if test $ol_enable_phonetic = yes ; then
 239                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 240         fi
 241         if test $ol_enable_quipu = yes ; then
 242                 AC_MSG_WARN([slapd disabled, ignoring --enable-quipu argument])
 243         fi
 244         if test $ol_enable_rlookups = yes ; then
 245                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 246         fi
 247         if test $ol_enable_aci = yes ; then
 248                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 249         fi
 250         if test $ol_with_ldbm_api != auto ; then
 251                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 252         fi
 253         if test $ol_with_ldbm_type != auto ; then
 254                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 255         fi
 256         if test $ol_with_bdb2_module != static ; then
 257                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb2-module argument])
 258         fi
 259         if test $ol_with_ldap_module != static ; then
 260                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 261         fi
 262         if test $ol_with_ldbm_module != static ; then
 263                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 264         fi
 265         if test $ol_with_passwd_module != static ; then
 266                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 267         fi
 268         if test $ol_with_perl_module != static ; then
 269                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 270         fi
 271         if test $ol_with_shell_module != static ; then
 272                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 273         fi
 274         if test $ol_with_tcl_module != static ; then
 275                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 276         fi
 277         if test $ol_with_sql_module != static ; then
 278                 AC_MSG_WARN([slapd disabled, ignoring --with-sql-module argument])
 279         fi
 280         if test $ol_enable_slurpd = yes ; then
 281                 AC_MSG_ERROR([slurpd requires slapd])
 282         fi
 283
 284         # force settings to no
 285         ol_enable_bdb2=no
 286         ol_enable_ldap=no
 287         ol_enable_ldbm=no
 288         ol_enable_passwd=no
 289         ol_enable_perl=no
 290         ol_enable_shell=no
 291         ol_enable_tcl=no
 292         ol_enable_sql=no
 293
 294         ol_enable_modules=no
 295         ol_enable_multimaster=no
 296         ol_enable_phonetic=no
 297         ol_enable_quipu=no
 298         ol_enable_rlookups=no
 299         ol_enable_aci=no
 300         ol_enable_wrappers=no
 301         ol_enable_dynamic=no
 302
 303         ol_with_ldbm_api=no
 304         ol_with_ldbm_type=no
 305
 306         ol_with_bdb2_module=static
 307         ol_with_ldap_module=static
 308         ol_with_ldbm_module=static
 309         ol_with_passwd_module=static
 310         ol_with_perl_module=static
 311         ol_with_shell_module=static
 312         ol_with_tcl_module=static
 313         ol_with_sql_module=static
 314
 315         ol_enable_slurpd=no
 316
 317 elif test $ol_enable_ldbm = no ; then
 318         dnl SLAPD without LDBM
 319
 320         if test $ol_with_ldbm_api != auto ; then
 321                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 322         fi
 323
 324         if test $ol_with_ldbm_type != auto ; then
 325                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 326         fi
 327
 328         if test $ol_with_ldbm_module != static ; then
 329                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 330         fi
 331
 332         if test $ol_enable_bdb2 = yes ; then
 333                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 334         fi
 335
 336         if test $ol_enable_modules != yes -a \
 337                 $ol_enable_ldap = no -a \
 338                 $ol_enable_passwd = no -a \
 339                 $ol_enable_perl = no -a \
 340                 $ol_enable_shell = no -a \
 341                 $ol_enable_tcl = no -a \
 342                 $ol_enable_sql = no ; then
 343                 AC_MSG_ERROR([slapd requires a backend])
 344         fi
 345
 346         ol_with_ldbm_api=no
 347         ol_with_ldbm_type=no
 348         ol_with_ldbm_module=static
 349
 350 elif test $ol_enable_bdb2 = yes ; then
 351         dnl SLAPD with BDB2
 352
 353         if test $ol_with_ldbm_api != auto -a \
 354                 $ol_with_ldbm_api != db2 ; then
 355                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 356         fi
 357
 358         ol_with_ldbm_api=db2
 359
 360 else
 361         dnl SLAPD with LDBM
 362
 363         if test $ol_enable_bdb2 != no ; then
 364                 if test $ol_with_ldbm_api != auto -a \
 365                         $ol_with_ldbm_api != db2 ; then
 366                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 367                         ol_enable_bdb2=no
 368                 fi
 369         fi
 370
 371         if test $ol_with_ldbm_api = gdbm -a \
 372                 $ol_with_ldbm_type = btree ; then
 373                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 374         fi
 375         if test $ol_with_ldbm_api = mdbm -a \
 376                 $ol_with_ldbm_type = btree ; then
 377                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 378         fi
 379         if test $ol_with_ldbm_api = ndbm -a \
 380                 $ol_with_ldbm_type = btree ; then
 381                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 382         fi
 383 fi
 384
 385 if test $ol_enable_slurpd = yes ; then
 386         dnl SLURPD was specifically enabled
 387         if test $ol_with_threads = no ; then
 388                 AC_MSG_ERROR([slurpd requires threads])
 389         fi
 390 fi
 391
 392 if test $ol_enable_kbind = yes -o $ol_enable_kpasswd = yes ; then
 393         if test $ol_with_kerberos = no ; then
 394                 AC_MSG_ERROR([options require --with-kerberos])
 395         fi
 396 elif test $ol_enable_kbind = no -o $ol_enable_kpasswd = no ; then
 397         if test $ol_with_kerberos != auto ; then
 398                 AC_MSG_WARN([Kerberos detection enabled unnecessarily]);
 399         else
 400                 ol_with_kerberos=no
 401         fi
 402 fi
 403
 404 AC_MSG_RESULT(done)
 405
 406 dnl ----------------------------------------------------------------
 407 dnl Initialize vars
 408 LDAP_LIBS=
 409 LDIF_LIBS=
 410 LDBM_LIBS=
 411 LTHREAD_LIBS=
 412 LUTIL_LIBS=
 413
 414 LDAPD_LIBS=
 415 SLAPD_LIBS=
 416 SLURPD_LIBS=
 417
 418 BUILD_LDAPD=no
 419 BUILD_SLAPD=no
 420 BUILD_SLURPD=no
 421
 422 BUILD_BDB2=no
 423 BUILD_LDAP=no
 424 BUILD_LDBM=no
 425 BUILD_PASSWD=no
 426 BUILD_PERL=no
 427 BUILD_QUIPU=no
 428 BUILD_SHELL=no
 429 BUILD_TCL=no
 430 BUILD_SQL=no
 431 BUILD_THREAD=no
 432
 433 BUILD_BDB2_DYNAMIC=static
 434 BUILD_LDAP_DYNAMIC=static
 435 BUILD_LDBM_DYNAMIC=static
 436 BUILD_PASSWD_DYNAMIC=static
 437 BUILD_PERL_DYNAMIC=static
 438 BUILD_SHELL_DYNAMIC=static
 439 BUILD_TCL_DYNAMIC=static
 440 BUILD_SQL_DYNAMIC=static
 441
 442 SLAPD_MODULES_LDFLAGS=
 443 SLAPD_MODULES_CPPFLAGS=
 444 SLAPD_MODULES_LIST=
 445
 446 SLAPD_PERL_LDFLAGS=
 447 MOD_PERL_LDFLAGS=
 448 PERL_CPPFLAGS=
 449
 450 SLAPD_SQL_LDFLAGS=
 451 SLAPD_SQL_LIBS=
 452 SLAPD_SQL_INCLUDES=
 453
 454 MOD_TCL_LIB=
 455 KRB4_LIBS=
 456 KRB5_LIBS=
 457 READLINE_LIBS=
 458 SASL_LIBS=
 459 TERMCAP_LIBS=
 460 TLS_LIBS=
 461 MODULES_LIBS=
 462
 463 dnl ================================================================
 464 dnl Checks for programs
 465
 466 dnl AC_PROG_INSTALL
 467
 468 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 469
 470 dnl ----------------------------------------------------------------
 471 dnl
 472 dnl Determine which C translator to use
 473 dnl
 474
 475 dnl AIX Thread requires we use cc_r or xlc_r.
 476 dnl But only do this IF AIX and CC is not set
 477 dnl and threads are auto|yes|posix.
 478 dnl
 479 dnl If we find cc_r|xlc_r, force pthreads and assume
 480 dnl             pthread_create is in $LIBS (ie: don't bring in
 481 dnl             any additional thread libraries)
 482 dnl If we do not find cc_r|xlc_r, disable threads
 483
 484 ol_aix_threads=no
 485 case "$target" in
 486 *-*-aix*) dnl all AIX is not a good idea.
 487         if test -z "$CC" ; then
 488                 case "$ol_with_threads" in
 489                 auto | yes |  posix) ol_aix_threads=yes ;;
 490                 esac
 491         fi
 492 ;;
 493 esac
 494
 495 if test $ol_aix_threads = yes ; then
 496         if test -z "${CC}" ; then
 497                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 498
 499                 if test "$CC" = cc ; then
 500                         dnl no CC! don't allow --with-threads
 501                         if test $ol_with_threads != auto ; then
 502                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 503                         else
 504                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 505                         fi
 506                         ol_with_threads=no
 507                 fi
 508         fi
 509
 510         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 511                 ol_with_threads=posix
 512                 ol_cv_pthread_create=yes
 513         fi
 514 fi
 515
 516 if test -z "${CC}"; then
 517         AC_CHECK_PROGS(CC,cc)
 518 fi
 519
 520 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 521 dnl (for now, let autoconf sort this out)
 522 dnl CFLAGS=${CFLAGS-""}
 523
 524 AC_LIBTOOL_WIN32_DLL
 525 AC_LIBTOOL_DLOPEN
 526 AC_PROG_LIBTOOL
 527
 528 AC_PROG_AWK
 529 OL_PROG_LN_H
 530 AC_PROG_LN_S
 531
 532 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 533         LN_S="$LN_H"
 534 fi
 535
 536 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 537         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 538 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 539 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 540
 541 dnl ----------------------------------------------------------------
 542 dnl Perl
 543 ol_link_perl=no
 544 if test $ol_enable_perl != no ; then
 545         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 546
 547         if test "no$PERLBIN" = "no" ; then
 548                 if test $ol_enable_perl = yes ; then
 549                         AC_MSG_ERROR([could not locate perl])
 550                 fi
 551
 552         else
 553                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 554                 if test x"$ol_with_perl_module" = "xstatic" ; then
 555                         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 556                 else
 557                         MOD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 558                 fi
 559                 dnl should check perl version
 560                 ol_link_perl=yes
 561         fi
 562 fi
 563
 564 AC_PROG_CPP
 565
 566 dnl ----------------------------------------------------------------
 567 dnl Cross compiling checks
 568 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 569         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 570
 571 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 572         AC_MSG_WARN([programs compiled here do run here...])
 573         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 574
 575 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 576         AC_MSG_WARN([programs compiled here do not run here...])
 577         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 578 fi
 579
 580 dnl ----------------------------------------------------------------
 581 dnl Checks for UNIX Variants
 582 AC_AIX
 583 AC_ISC_POSIX
 584 AC_MINIX
 585
 586 dnl ----------------------------------------------------------------
 587 dnl Checks for system services
 588 AC_CYGWIN
 589 AC_MINGW32
 590 AC_EXEEXT
 591 AC_OBJEXT
 592
 593 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 594
 595 dnl ----------------------------------------------------------------
 596 dnl BeOS requires -lbe -lroot -lnet
 597 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 598
 599 dnl ----------------------------------------------------------------
 600 dnl OpenLDAP requires STDC features
 601 AM_PROG_CC_STDC
 602 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 603         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 604 fi
 605
 606 dnl ----------------------------------------------------------------
 607 dnl Check cc depend flags
 608 OL_MKDEPEND
 609 if test "${ol_cv_mkdep}" = no ; then
 610         # this will soon become an error
 611         AC_MSG_WARN([do not know how to generate dependencies])
 612 fi
 613
 614 dnl ----------------------------------------------------------------
 615 dnl Check for module support
 616 ol_link_modules=no
 617 if test $ol_enable_modules != no ; then
 618         AC_CHECK_HEADERS(ltdl.h)
 619
 620         if test $ac_cv_header_ltdl_h = no ; then
 621                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 622         fi
 623
 624         AC_CHECK_LIB(ltdl, lt_dlinit, [
 625             MODULES_LIBS=-lltdl
 626             AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 627         ])
 628
 629         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 630                 AC_MSG_ERROR([could not locate libtool -lltdl])
 631         fi
 632         ol_link_modules=yes
 633 else
 634         ol_with_bdb2_module=static
 635         ol_with_ldap_module=static
 636         ol_with_ldbm_module=static
 637         ol_with_passwd_module=static
 638         ol_with_perl_module=static
 639         ol_with_shell_module=static
 640         ol_with_tcl_module=static
 641         ol_with_sql_module=static
 642 fi
 643
 644 dnl ----------------------------------------------------------------
 645 dnl Checks for header files.
 646 OL_HEADER_STDC
 647
 648 if test $ol_cv_header_stdc != yes; then
 649         AC_MSG_WARN([could not locate Standard C compliant headers])
 650 fi
 651
 652 AC_HEADER_DIRENT
 653 AC_HEADER_SYS_WAIT
 654 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 655 if test $am_cv_sys_posix_termios = yes ; then
 656         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 657                 [define if you have POSIX termios])
 658 fi
 659
 660 AC_CHECK_HEADERS(       \
 661         arpa/inet.h             \
 662         arpa/nameser.h  \
 663         assert.h                \
 664         conio.h                 \
 665         crypt.h                 \
 666         direct.h                \
 667         errno.h                 \
 668         fcntl.h                 \
 669         filio.h                 \
 670         getopt.h                \
 671         grp.h                   \
 672         io.h                    \
 673         libutil.h               \
 674         limits.h                \
 675         locale.h                \
 676         netinet/tcp.h   \
 677         malloc.h                \
 678         memory.h                \
 679         psap.h                  \
 680         pwd.h                   \
 681         process.h               \
 682         resolv.h                \
 683         sgtty.h                 \
 684         shadow.h                \
 685         stddef.h                \
 686         string.h                \
 687         strings.h               \
 688         sysexits.h              \
 689         sys/file.h              \
 690         sys/filio.h             \
 691         sys/errno.h             \
 692         sys/ioctl.h             \
 693         sys/param.h             \
 694         sys/resource.h  \
 695         sys/select.h    \
 696         sys/socket.h    \
 697         sys/syslog.h    \
 698         sys/time.h              \
 699         sys/types.h             \
 700         syslog.h                \
 701         termios.h               \
 702         unistd.h                \
 703         winsock.h               \
 704 )
 705
 706
 707 dnl ----------------------------------------------------------------
 708 dnl Checks for libraries
 709
 710 dnl HP-UX requires -lV3
 711 AC_CHECK_LIB(V3, sigset)
 712
 713 dnl Gotta check for winsock manually
 714 if test $ac_cv_header_winsock_h = yes; then
 715         AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 716         AC_TRY_LINK([#include <winsock.h>],[
 717                         socket(0,0,0);
 718                         select(0,NULL,NULL,NULL,NULL);
 719                         closesocket(0);
 720                         gethostname(NULL,0);
 721         ],[ol_cv_winsock=yes],[ol_cv_winsock=no])])
 722
 723         if test $ol_cv_winsock = yes ; then
 724                 AC_DEFINE(HAVE_WINSOCK,1,[define if you have winsock])
 725                 ac_cv_func_socket=yes
 726                 ac_cv_func_select=yes
 727                 ac_cv_func_closesocket=yes
 728                 ac_cv_func_gethostname=yes
 729         fi
 730 fi
 731
 732 dnl Find socket()
 733 dnl Likely combinations:
 734 dnl             -lsocket [ -lnsl_s | -lnsl ]
 735 dnl             -linet
 736
 737 AC_CHECK_FUNC(socket, :, [
 738 dnl hopefully we won't include too many libraries
 739         AC_CHECK_LIB(socket, main)
 740         AC_CHECK_LIB(net, main)
 741         AC_CHECK_LIB(nsl_s, main)
 742         AC_CHECK_LIB(nsl, main)
 743         AC_CHECK_LIB(inet, socket)
 744         AC_CHECK_LIB(gen, main)
 745 ])
 746
 747 dnl require select
 748 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 749
 750 if test "${ac_cv_header_winsock_h}" != yes; then
 751     dnl Select arg types
 752     dnl (if this detection becomes permenent, it and the select() detection
 753     dnl should be done before the yielding select test)
 754     AC_FUNC_SELECT_ARGTYPES
 755 fi
 756
 757 dnl check to see if system call automatically restart
 758 dnl AC_SYS_RESTARTABLE_SYSCALLS
 759
 760 dnl ----------------------------------------------------------------
 761 dnl require POSIX regex
 762 AC_CHECK_HEADERS( regex.h )
 763 if test "$ac_cv_header_regex_h" != yes ; then
 764         AC_MSG_ERROR([POSIX regex.h required.])
 765 fi
 766 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 767
 768 OL_POSIX_REGEX
 769 if test "$ol_cv_c_posix_regex" = no ; then
 770         AC_MSG_ERROR([broken POSIX regex!])
 771 fi
 772
 773 dnl ----------------------------------------------------------------
 774 dnl Check for resolver routines
 775 AC_CHECK_FUNC(res_search,:)
 776 if test $ac_cv_func_res_search = no ; then
 777         AC_CHECK_LIB(bind, res_search)
 778         ac_cv_func_res_search=$ac_cv_lib_bind_res_search
 779 fi
 780
 781 if test $ac_cv_func_res_search = no ; then
 782         AC_CHECK_LIB(bind, __res_search)
 783         ac_cv_func_res_search=$ac_cv_lib_bind___res_search
 784 fi
 785
 786 if test $ac_cv_func_res_search = no ; then
 787         AC_CHECK_LIB(resolv, res_search)
 788         ac_cv_func_res_search=$ac_cv_lib_resolv_res_search
 789 fi
 790
 791 if test "$ac_cv_func_res_search" = yes ; then
 792         AC_DEFINE(HAVE_RES_SEARCH,1,
 793                 [define if you have res_search()])
 794 elif test $ol_enable_dns = yes ; then
 795         AC_MSG_ERROR([--enable-dns requires res_search])
 796 elif test $ol_enable_dns != no ; then
 797         AC_MSG_WARN([no res_search, disabling DNS support])
 798 fi
 799
 800
 801 dnl ----------------------------------------------------------------
 802 dnl ISODE tests
 803 ol_link_isode=no
 804 if test $ol_enable_ldapd != no ; then
 805         AC_MSG_WARN([ldapd is not supported and may suffer from bit rot.])
 806
 807         dnl look for ISODE libraries
 808         AC_CHECK_LIB(xtpp, main, [
 809                 ol_link_isode=yes
 810                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 811                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 812                 ],:,[-lxtdsap -lxtisode -losi])
 813         AC_CHECK_LIB(dsap, main, [
 814                 ol_link_isode=yes
 815                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 816                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 817                 ],:,[-lisode])
 818         AC_CHECK_LIB(isode, main, [
 819                 ol_link_isode=yes
 820                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 821                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 822                 ],:)
 823 fi
 824
 825 if test $ol_link_isode != no; then
 826         AC_CHECK_LIB(pp, main, [
 827                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 828                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 829                 ],:)
 830
 831         AC_PATH_PROG(PEPSY, pepsy)
 832 fi
 833
 834 dnl ----------------------------------------------------------------
 835 dnl QUIPU
 836 if test $ol_enable_quipu != no ; then
 837         AC_CHECK_HEADERS(quipu/commonarg.h)
 838
 839         if test $ac_cv_header_quipu_commonarg_h = yes ; then
 840                 BUILD_QUIPU=yes
 841         elif test $ol_enable_quipu = auto ; then
 842                 AC_MSG_WARN([no quipu for --enable-quipu=auto, disabling])
 843         else
 844                 AC_MSG_ERROR(no quipu for --enable-quipu=$ol_enable_quipu)
 845         fi
 846 fi
 847
 848 dnl ----------------------------------------------------------------
 849 dnl Kerberos
 850 ol_link_kbind=no
 851 ol_link_kpasswd=no
 852 ol_link_krb5=no
 853 ol_link_krb4=no
 854
 855 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 \
 856         -o $ol_with_kerberos = k5only -o $ol_with_kerberos = k425 ; then
 857
 858         AC_CHECK_HEADERS(krb5.h)
 859
 860         if test $ac_cv_header_krb5_h = yes ; then
 861                 dnl lazy check for Heimdal Kerberos
 862                 AC_CHECK_HEADERS(heim_err.h)
 863                 if test $ac_cv_header_heim_err_h = yes ; then
 864                         krb5_impl=heimdal
 865                 else
 866                         krb5_impl=mit
 867                 fi
 868
 869                 if test $krb5_impl = mit; then
 870                         AC_CHECK_LIB(krb5, main,
 871                                 [have_krb5=yes
 872                                 KRB5_LIBS="-lkrb5 -lcrypto -lcom_err"],
 873                                 [have_krb5=no],
 874                                 [-lcrypto -lcom_err])
 875
 876                 elif test $krb5_impl = heimdal; then
 877                         AC_CHECK_LIB(krb5, main,
 878                                 [have_krb5=yes
 879                                 KRB5_LIBS="-lkrb5 -ldes -lasn1 -lroken -lcom_err"],
 880                                 [have_krb5=no],
 881                                 [-ldes -lasn1 -lroken -lcom_err])
 882
 883                         AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1,
 884                                 [define if you have HEIMDAL Kerberos])
 885                 else
 886                         have_krb5=no
 887                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 888                 fi
 889
 890                 if test $have_krb5 = yes ; then
 891                         ol_link_krb5=yes
 892
 893                         AC_DEFINE(HAVE_KRB5, 1,
 894                                 [define if you have Kerberos V])
 895
 896                         if test $ol_enable_kpasswd != no ; then
 897                                 ol_link_kpasswd=yes;
 898                         fi
 899
 900                         if test $ol_with_kerberos = k5only ; then
 901                                 ol_with_kerberos=found
 902                         fi
 903
 904                 elif test $ol_with_kerberos != auto ; then
 905                         AC_MSG_ERROR([Required Kerberos 5 support not available])
 906                 fi
 907
 908         fi
 909 fi
 910
 911 if test $ol_link_krb5 = yes -a \
 912         \( $ol_with_kerberos = auto -o $ol_with_kerberos = k425 \) ; then
 913
 914         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 915
 916         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 917                 if test $krb5_impl = mit; then
 918                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 919                                 KRB4_LIBS="-lkrb4 -ldes425"], [have_k425=no],
 920                                 [-ldes425 -lkrb5 -lcrypto -lcom_err])
 921
 922                 elif test $krb5_impl = heimdal; then
 923                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 924                                 KRB4_LIBS="-lkrb4"], [have_k425=no],
 925                                 [-lkrb5 -ldes -lasn1 -lroken -lcom_err])
 926
 927                 else
 928                         have_425=no
 929                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 930                 fi
 931
 932                 if test $have_k425 = yes ; then
 933                         ol_with_kerberos=found
 934                         ol_link_krb4=yes
 935
 936                         AC_DEFINE(HAVE_KRB425, 1,
 937                                 [define if you have Kerberos V with IV support])
 938                         AC_DEFINE(HAVE_KRB4, 1,
 939                                 [define if you have Kerberos IV])
 940
 941                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 942                                 [ol_cv_var_des_debug], [
 943                                 dnl save the flags
 944                                 save_LIBS="$LIBS"
 945                                 LIBS="$KRB4_LIBS $KRB5_LIBS $LIBS"
 946                                 AC_TRY_LINK([
 947 #include <kerberosIV/krb.h>
 948 #include <kerberosIV/des.h>
 949 extern int des_debug;
 950 ],[
 951 des_debug = 1;
 952 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 953                                 dnl restore the LIBS
 954                                 LIBS="$save_LIBS"
 955                         ])
 956
 957                         if test $ol_cv_var_des_debug = yes ; then
 958                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 959                                         [define if you have Kerberos des_debug])
 960                         fi
 961
 962                         LIBS="$save_LIBS"
 963                 fi
 964         fi
 965 fi
 966
 967 if test $ol_link_krb5 = yes ; then
 968         ol_with_kerberos=found
 969 fi
 970
 971 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 \
 972         -o $ol_with_kerberos = kth ; then
 973
 974         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
 975
 976         if test $ac_cv_header_krb_h = yes ; then
 977                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 978
 979                 if test $have_k4 = yes ; then
 980                         ol_with_kerberos=found
 981                         ol_link_krb4=yes
 982
 983                         AC_DEFINE(HAVE_KRB4, 1,
 984                                 [define if you have Kerberos IV])
 985
 986                         KRB4_LIBS="-lkrb -ldes"
 987
 988                         if test $ac_cv_header_krb_archaeology_h = yes ; then
 989                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
 990                                         [define if you have Kth Kerberos])
 991                         fi
 992                 fi
 993         fi
 994 fi
 995
 996 if test $ol_link_krb4 = yes -a $ol_enable_kpasswd != no ; then
 997         ol_link_kpasswd=yes;
 998 fi
 999
1000 if test $ol_link_krb4 = yes -o $ol_link_krb5 = yes ; then
1001         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
1002
1003 elif test $ol_with_kerberos != auto -a $ol_with_kerberos != no ; then
1004         AC_MSG_ERROR([Kerberos detection failed.])
1005 fi
1006
1007 dnl ----------------------------------------------------------------
1008 dnl TLS/SSL
1009 ol_link_tls=no
1010 if test $ol_with_tls != no ; then
1011
1012         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
1013
1014         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
1015                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
1016                         [have_ssleay=yes
1017                         need_rsaref=no],
1018                         [have_ssleay=no],
1019                         [-lcrypto])
1020
1021                 if test $have_ssleay = no ; then
1022                         AC_CHECK_LIB(ssl, SSL_library_init,
1023                                 [have_ssleay=yes
1024                                 need_rsaref=no], [have_ssleay=no],
1025                                 [-lcrypto])
1026                 fi
1027
1028                 if test $have_ssleay = no ; then
1029                         AC_CHECK_LIB(ssl, ssl3_accept,
1030                                 [have_ssleay=yes
1031                                 need_rsaref=yes], [have_ssleay=no],
1032                                 [-lcrypto -lRSAglue -lrsaref])
1033                 fi
1034
1035                 if test $have_ssleay = yes ; then
1036                         ol_with_tls=found
1037                         ol_link_tls=yes
1038
1039                         AC_DEFINE(HAVE_SSLEAY, 1,
1040                                 [define if you have SSLeay or OpenSSL])
1041
1042                         if test $need_rsaref = yes; then
1043                                 AC_DEFINE(HAVE_RSAREF, 1,
1044                                         [define if you have RSAref])
1045
1046                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1047                         else
1048                                 TLS_LIBS="-lssl -lcrypto"
1049                         fi
1050                 fi
1051         fi
1052 fi
1053
1054 if test $ol_link_tls = yes ; then
1055         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1056 fi
1057
1058 dnl ----------------------------------------------------------------
1059 dnl Tests for reentrant functions necessary to build a
1060 dnl thread_safe -lldap.
1061 AC_CHECK_FUNCS(         \
1062         ctime_r                 \
1063         gethostbyname_r gethostbyaddr_r \
1064 )
1065
1066 if test "$ac_cv_func_ctime_r" = no ; then
1067         ol_cv_func_ctime_r_nargs=0
1068 else
1069         OL_FUNC_CTIME_R_NARGS
1070 dnl     OL_FUNC_CTIME_R_TYPE
1071 fi
1072
1073 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1074         OL_FUNC_GETHOSTBYNAME_R_NARGS
1075 else
1076         ol_cv_func_gethostbyname_r_nargs=0
1077 fi
1078
1079 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1080         OL_FUNC_GETHOSTBYADDR_R_NARGS
1081 else
1082         ol_cv_func_gethostbyaddr_r_nargs=0
1083 fi
1084
1085 if test "$ac_cv_func_ctime_r" = yes \
1086         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
1087         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
1088         -a "$ac_cv_func_gethostbyname_r" = yes \
1089         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
1090         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
1091         -a "$ac_cv_func_gethostbyaddr_r" = yes \
1092         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
1093         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
1094         ; then
1095
1096         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
1097 fi
1098
1099 dnl ----------------------------------------------------------------
1100 dnl Threads?
1101 ol_link_threads=no
1102
1103 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1104         -o $ol_with_threads = nt ; then
1105
1106         OL_NT_THREADS
1107
1108         if test "$ol_cv_nt_threads" = yes ; then
1109         ol_link_threads=nt
1110         ol_with_threads=found
1111         ol_with_yielding_select=yes
1112
1113                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1114                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1115         fi
1116
1117         if test $ol_with_threads = nt ; then
1118                 AC_MSG_ERROR([could not locate NT Threads])
1119         fi
1120 fi
1121
1122 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1123         -o $ol_with_threads = posix ; then
1124
1125         AC_CHECK_HEADERS(pthread.h)
1126
1127         if test $ac_cv_header_pthread_h = yes ; then
1128                 OL_POSIX_THREAD_VERSION
1129
1130                 if test $ol_cv_pthread_version = final ; then
1131                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
1132                                 [define if pthreads API compatible with final spec])
1133                 elif test $ol_cv_pthread_version = draft4 ; then
1134                         AC_DEFINE(HAVE_PTHREADS_D4,1,
1135                                 [define if pthreads API compatible with draft4 spec])
1136                 else
1137                         AC_MSG_ERROR([unknown pthread version])
1138                 fi
1139
1140                 # consider threads found
1141                 ol_with_threads=found
1142
1143                 OL_HEADER_LINUX_THREADS
1144                 OL_HEADER_GNU_PTH_PTHREAD_H
1145
1146                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1147                         AC_CHECK_HEADERS(sched.h)
1148                 fi
1149
1150                 dnl Now the hard part, how to link?
1151                 dnl
1152                 dnl currently supported checks:
1153                 dnl
1154                 dnl Check for no flags
1155                 dnl     pthread_create() in $LIBS
1156                 dnl
1157                 dnl Check special pthread (final) flags
1158                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1159                 dnl     pthread_create() with -kthread (FreeBSD)
1160                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1161                 dnl     pthread_create() with -pthreads (?)
1162                 dnl     pthread_create() with -mthreads (AIX)
1163                 dnl     pthread_create() with -thread (?)
1164                 dnl
1165                 dnl Check pthread (final) libraries
1166                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1167                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1168                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1169                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1170                 dnl     pthread_create() in -lpthread (many)
1171                 dnl     pthread_create() in -lc_r (FreeBSD)
1172                 dnl
1173                 dnl Check pthread (draft4) flags (depreciated)
1174                 dnl     pthread_create() with -threads (OSF/1)
1175                 dnl
1176                 dnl Check pthread (draft4) libraries (depreciated)
1177                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1178                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1179                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1180                 dnl     pthread_create() in -lpthreads (many)
1181                 dnl
1182
1183                 dnl pthread_create in $LIBS
1184                 AC_CACHE_CHECK([for pthread_create in default libraries],
1185                         ol_cv_pthread_create,[
1186                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1187                         [ol_cv_pthread_create=yes],
1188                         [ol_cv_pthread_create=no],
1189                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1190                                 [ol_cv_pthread_create=yes],
1191                                 [ol_cv_pthread_create=no])])])
1192
1193                 if test $ol_cv_pthread_create != no ; then
1194                         ol_link_threads=posix
1195                         ol_link_pthreads=""
1196                 fi
1197
1198 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1199                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1200                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1201                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1202                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1203                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1204
1205                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1206                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1207                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1208                         [ol_cv_pthread_lpthread_lmach_lexc])
1209 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1210 dnl                     [ol_cv_pthread_lpthread_lexc])
1211
1212                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1213                         [ol_cv_pthread_lib_lpthread_woff])
1214
1215                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1216                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1217
1218                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1219
1220                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1221                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1222                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1223                         [ol_cv_pthread_lpthreads_lmach_lexc])
1224                 OL_PTHREAD_TRY([-lpthreads -lexc],
1225                         [ol_cv_pthread_lpthreads_lexc])
1226
1227                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1228
1229                 if test $ol_link_threads != no ; then
1230                         AC_DEFINE(HAVE_PTHREADS,1,
1231                                 [define if you have POSIX Threads])
1232
1233                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1234
1235                         dnl save flags
1236                         save_CPPFLAGS="$CPPFLAGS"
1237                         save_LIBS="$LIBS"
1238                         LIBS="$LTHREAD_LIBS $LIBS"
1239
1240                         dnl All POSIX Thread (final) implementations should have
1241                         dnl sched_yield instead of pthread yield.
1242                         dnl check for both
1243                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1244
1245                         if test $ac_cv_func_sched_yield = no -a \
1246                                 $ac_cv_func_pthread_yield = no ; then
1247                                 dnl Digital UNIX has sched_yield() in -lrt
1248                                 AC_CHECK_LIB(rt, sched_yield,
1249                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1250                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1251                                                 [Define if you have the sched_yield function.])
1252                                         ac_cv_func_sched_yield=yes],
1253                                         [ac_cv_func_sched_yield=no])
1254                         fi
1255                         if test $ac_cv_func_sched_yield = no -a \
1256                                 $ac_cv_func_pthread_yield = no ; then
1257                                 dnl Solaris has sched_yield() stub in -lposix4
1258                                 dnl but we'll use thr_yield instead.
1259                                 AC_CHECK_FUNCS(thr_yield)
1260                         fi
1261                         if test $ac_cv_func_sched_yield = no -a \
1262                                 $ac_cv_func_pthread_yield = no -a \
1263                                 "$ac_cv_func_thr_yield" = no ; then
1264                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1265                         fi
1266
1267                         dnl Check functions for compatibility
1268                         AC_CHECK_FUNCS(pthread_kill)
1269
1270                         dnl Check for pthread_detach with <pthread.h> inclusion
1271                         dnl as it's symbol may have been mangled.
1272                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1273                                 [ol_cv_func_pthread_detach], [
1274                                 dnl save the flags
1275                                 AC_TRY_LINK([
1276 #include <pthread.h>
1277 #ifndef NULL
1278 #define NULL (void*)0
1279 #endif
1280 ],
1281                                         [pthread_detach(NULL);],
1282                                         [ol_cv_func_pthread_detach=yes],
1283                                         [ol_cv_func_pthread_detach=no])
1284                         ])
1285
1286                         if test $ol_cv_func_pthread_detach = no ; then
1287                                 AC_MSG_ERROR([could not locate pthread_detach()])
1288                         fi
1289
1290                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1291                                 [define if you have pthread_detach function])
1292
1293                         dnl Check for setconcurreny functions
1294                         AC_CHECK_FUNCS( \
1295                                 pthread_setconcurrency \
1296                                 pthread_getconcurrency \
1297                                 thr_setconcurrency \
1298                                 thr_getconcurrency \
1299                         )
1300
1301                         OL_SYS_LINUX_THREADS
1302                         OL_LINUX_THREADS
1303
1304                         if test $ol_cv_linux_threads = error; then
1305                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1306                         fi
1307
1308                         AC_CACHE_CHECK([if pthread_create() works],
1309                                 ol_cv_pthread_create_works,[
1310                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1311                                 [ol_cv_pthread_create_works=yes],
1312                                 [ol_cv_pthread_create_works=no],
1313                                 [dnl assume yes
1314                                 ol_cv_pthread_create_works=yes])])
1315
1316                         if test $ol_cv_pthread_create_works = no ; then
1317                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1318                         fi
1319
1320                         dnl Check if select causes an yield
1321                         if test $ol_with_yielding_select = auto ; then
1322                                 AC_CACHE_CHECK([if select yields when using pthreads],
1323                                         ol_cv_pthread_select_yields,[
1324                                 AC_TRY_RUN([
1325 #include <sys/types.h>
1326 #include <sys/time.h>
1327 #include <unistd.h>
1328 #include <pthread.h>
1329 #ifndef NULL
1330 #define NULL (void*) 0
1331 #endif
1332
1333 static int fildes[2];
1334
1335 static void *task(p)
1336         void *p;
1337 {
1338         int i;
1339         struct timeval tv;
1340
1341         fd_set rfds;
1342
1343         tv.tv_sec=10;
1344         tv.tv_usec=0;
1345
1346         FD_ZERO(&rfds);
1347         FD_SET(fildes[0], &rfds);
1348
1349         /* we're not interested in any fds */
1350         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1351
1352         if(i < 0) {
1353                 perror("select");
1354                 exit(10);
1355         }
1356
1357         exit(0); /* if we exit here, the select blocked the whole process */
1358 }
1359
1360 int main(argc, argv)
1361         int argc;
1362         char **argv;
1363 {
1364         pthread_t t;
1365
1366         /* create a pipe to select */
1367         if(pipe(&fildes[0])) {
1368                 perror("select");
1369                 exit(1);
1370         }
1371
1372 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1373         (void) pthread_setconcurrency(2);
1374 #else
1375 #ifdef HAVE_THR_SETCONCURRENCY
1376         /* Set Solaris LWP concurrency to 2 */
1377         thr_setconcurrency(2);
1378 #endif
1379 #endif
1380
1381 #if HAVE_PTHREADS_D4
1382         pthread_create(&t, pthread_attr_default, task, NULL);
1383 #else
1384         pthread_create(&t, NULL, task, NULL);
1385 #endif
1386
1387 #if HAVE_SCHED_YIELD
1388         sched_yield();  /* make sure task runs first */
1389 #else
1390 #ifdef HAVE_PTHREAD_YIELD
1391         pthread_yield();        /* make sure task runs first */
1392 #endif
1393 #endif
1394
1395         exit(2);
1396 }],
1397                                 [ol_cv_pthread_select_yields=no],
1398                                 [ol_cv_pthread_select_yields=yes],
1399                                 [ol_cv_pthread_select_yields=cross])])
1400
1401                                 if test $ol_cv_pthread_select_yields = cross ; then
1402                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1403                                 fi
1404
1405                                 if test $ol_cv_pthread_select_yields = yes ; then
1406                                         ol_with_yielding_select=yes
1407                                 fi
1408                         fi
1409
1410                         dnl restore flags
1411                         CPPFLAGS="$save_CPPFLAGS"
1412                         LIBS="$save_LIBS"
1413                 else
1414                         AC_MSG_ERROR([could not link with POSIX Threads])
1415                 fi
1416         fi
1417
1418         if test $ol_with_threads = posix ; then
1419                 AC_MSG_ERROR([could not locate POSIX Threads])
1420         fi
1421 fi
1422
1423 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1424         -o $ol_with_threads = mach ; then
1425
1426         dnl check for Mach CThreads
1427         AC_CHECK_HEADERS(mach/cthreads.h)
1428         if test $ac_cv_header_mach_cthreads_h = yes ; then
1429                 ol_with_threads=found
1430
1431                 dnl check for cthread support in current $LIBS
1432                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1433
1434                 if test $ol_link_threads = no ; then
1435                         dnl try -all_load
1436                         dnl this test needs work
1437                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1438                                 [ol_cv_cthread_all_load], [
1439                                 dnl save the flags
1440                                 save_LIBS="$LIBS"
1441                                 LIBS="-all_load $LIBS"
1442                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1443                                         cthread_fork((void *)0, (void *)0);
1444                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1445                                 dnl restore the LIBS
1446                                 LIBS="$save_LIBS"
1447                         ])
1448
1449                         if test $ol_cv_cthread_all_load = yes ; then
1450                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1451                                 ol_link_threads=mach
1452                         fi
1453                 fi
1454
1455                 if test $ol_link_threads != no ; then
1456                         : check for cthread specific functionality here
1457                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1458                                 [define if you have Mach Cthreads])
1459                 else
1460                         AC_MSG_ERROR([could not link with Mach CThreads])
1461                 fi
1462         fi
1463
1464         if test $ol_with_threads = mach ; then
1465                 AC_MSG_ERROR([could not locate Mach CThreads])
1466         fi
1467 fi
1468
1469 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1470         -o $ol_with_threads = pth ; then
1471
1472         AC_CHECK_HEADERS(pth.h)
1473
1474         if test $ac_cv_header_pth_h = yes ; then
1475                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1476
1477                 if test $have_pth = yes ; then
1478                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1479                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1480                         ol_link_threads=pth
1481
1482                         if test $ol_with_yielding_select = auto ; then
1483                                 ol_with_yielding_select=yes
1484                         fi
1485                 fi
1486         fi
1487 fi
1488
1489 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1490         -o $ol_with_threads = lwp ; then
1491
1492         dnl check for SunOS5 LWP
1493         AC_CHECK_HEADERS(thread.h synch.h)
1494         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1495                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1496
1497                 if test $have_thr = yes ; then
1498                         AC_DEFINE(HAVE_THR,1,
1499                                 [if you have Solaris LWP (thr) package])
1500                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1501                         ol_link_threads=thr
1502
1503                         if test $ol_with_yielding_select = auto ; then
1504                                 ol_with_yielding_select=yes
1505                         fi
1506
1507                         dnl Check for setconcurreny functions
1508                         AC_CHECK_FUNCS( \
1509                                 thr_setconcurrency \
1510                                 thr_getconcurrency \
1511                         )
1512                 fi
1513         fi
1514
1515         dnl check for SunOS4 LWP
1516         AC_CHECK_HEADERS(lwp/lwp.h)
1517         if test $ac_cv_header_lwp_lwp_h = yes ; then
1518                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1519
1520                 if test $have_lwp = yes ; then
1521                         AC_DEFINE(HAVE_LWP,1,
1522                                 [if you have SunOS LWP package])
1523                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1524                         ol_link_threads=lwp
1525
1526                         if test $ol_with_yielding_select = auto ; then
1527                                 ol_with_yielding_select=no
1528                         fi
1529                 fi
1530         fi
1531 fi
1532
1533 if test $ol_with_yielding_select = yes ; then
1534         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1535                 [define if select implicitly yields])
1536 fi
1537
1538 if test $ol_with_threads = manual ; then
1539         dnl User thinks he can manually configure threads.
1540         ol_link_threads=yes
1541
1542         AC_MSG_WARN([thread defines and link options must be set manually])
1543
1544         AC_CHECK_HEADERS(pthread.h sched.h)
1545         AC_CHECK_FUNCS(sched_yield pthread_yield)
1546         OL_HEADER_LINUX_THREADS
1547
1548         AC_CHECK_HEADERS(mach/cthreads.h)
1549         AC_CHECK_HEADERS(lwp/lwp.h)
1550         AC_CHECK_HEADERS(thread.h synch.h)
1551 fi
1552
1553 if test $ol_link_threads != no -a $ol_link_threads != nt ; then
1554         dnl needed to get reentrant/threadsafe versions
1555         dnl
1556         AC_DEFINE(REENTRANT,1)
1557         AC_DEFINE(_REENTRANT,1)
1558         AC_DEFINE(THREAD_SAFE,1)
1559         AC_DEFINE(_THREAD_SAFE,1)
1560         AC_DEFINE(THREADSAFE,1)
1561         AC_DEFINE(_THREADSAFE,1)
1562         AC_DEFINE(_SGI_MP_SOURCE,1)
1563
1564         dnl The errno declaration may dependent upon _REENTRANT.
1565         dnl If it does, we must link with thread support.
1566         AC_CACHE_CHECK([for thread specific errno],
1567                 [ol_cv_errno_thread_specific], [
1568                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1569                         [ol_cv_errno_thread_specific=yes],
1570                         [ol_cv_errno_thread_specific=no])
1571         ])
1572
1573         dnl The h_errno declaration may dependent upon _REENTRANT.
1574         dnl If it does, we must link with thread support.
1575         AC_CACHE_CHECK([for thread specific h_errno],
1576                 [ol_cv_h_errno_thread_specific], [
1577                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1578                         [ol_cv_h_errno_thread_specific=yes],
1579                         [ol_cv_h_errno_thread_specific=no])
1580         ])
1581
1582         if test $ol_cv_errno_thread_specific != yes \
1583                 -o $ol_cv_h_errno_thread_specific != yes ; then
1584                 LIBS="$LTHREAD_LIBS $LIBS"
1585                 LTHREAD_LIBS=""
1586         fi
1587
1588 dnl When in thread environment, use
1589 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1590 dnl                     || defined( HAVE_FUNC_R )
1591 dnl                     func_r(...);
1592 dnl             #else
1593 dnl             #       if defined( HAVE_THREADS )
1594 dnl                             /* lock */
1595 dnl             #       endif
1596 dnl                             func(...);
1597 dnl             #       if defined( HAVE_THREADS )
1598 dnl                             /* unlock */
1599 dnl             #       endif
1600 dnl             #endif
1601 dnl
1602 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1603 dnl             _POSIX_REENTRANT_FUNCTIONS
1604 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1605 dnl             _POSIX_THREADSAFE_FUNCTIONS
1606 dnl
1607 dnl             and is currently defined in lthread.h
1608 dnl
1609 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1610 dnl
1611 dnl libldap/*.c should only include <lthread.h> iff
1612 dnl LDAP_R_COMPILE is defined.  ie:
1613 dnl             #ifdef LDAP_R_COMPILE
1614 dnl             #       include LDAP_R_COMPILE
1615 dnl             #endif
1616 dnl
1617 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1618 dnl specifically for compiling the threadsafe version of
1619 dnl     the ldap library (-lldap_r).
1620 dnl
1621 dnl     dnl check for reentrant/threadsafe functions
1622 dnl     dnl
1623 dnl     dnl note: these should only be used when linking
1624 dnl     dnl       with $LTHREAD_LIBS
1625 dnl     dnl
1626 dnl     save_CPPFLAGS="$CPPFLAGS"
1627 dnl     save_LIBS="$LIBS"
1628 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1629 dnl     AC_CHECK_FUNCS( \
1630 dnl             gmtime_r \
1631 dnl             gethostbyaddr_r gethostbyname_r \
1632 dnl             feof_unlocked unlocked_feof \
1633 dnl             putc_unlocked unlocked_putc \
1634 dnl             flockfile ftrylockfile \
1635 dnl     )
1636 dnl     CPPFLAGS="$save_CPPFLAGS"
1637 dnl     LIBS="$save_LIBS"
1638 fi
1639
1640 if test $ol_link_threads = no ; then
1641         if test $ol_with_threads = yes ; then
1642                 AC_MSG_ERROR([no suitable thread support])
1643         fi
1644
1645         if test $ol_with_threads = auto ; then
1646                 AC_MSG_WARN([no suitable thread support, disabling threads])
1647                 ol_with_threads=no
1648         fi
1649
1650         AC_DEFINE(NO_THREADS,1,
1651                 [define if you have (or want) no threads])
1652         LTHREAD_LIBS=""
1653 fi
1654
1655 if test $ol_link_threads != no ; then
1656         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1657 fi
1658
1659 dnl ----------------------------------------------------------------
1660
1661 ol_link_ldbm=no
1662 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1663         OL_BERKELEY_DB2
1664
1665         if test $ol_cv_berkeley_db2 = yes ; then
1666                 ol_link_ldbm=db2
1667                 ol_with_ldbm_api=db2
1668
1669                 if test $ol_with_ldbm_type = hash ; then
1670                         AC_DEFINE(LDBM_USE_DBHASH,1,
1671                                 [define this to use DBHASH w/ LDBM backend])
1672                 else
1673                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1674                                 [define this to use DBBTREE w/ LDBM backend])
1675                 fi
1676
1677                 OL_BERKELEY_DB2_DB_THREAD
1678
1679                 dnl $ol_cv_lib_db2 should be yes or -ldb
1680                 dnl (it could be no, but that would be an error
1681                 if test $ol_cv_lib_db2 != yes ; then
1682                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1683                 fi
1684         fi
1685 fi
1686
1687 ol_link_bdb2=no
1688 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1689         if test $ol_cv_berkeley_db2_db_thread != no ; then
1690                 ol_link_bdb2=yes
1691         else
1692                 AC_MSG_WARN([Installed BerkeleyDB does not provide DB_THREAD support.])
1693         fi
1694 fi
1695
1696 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1697         OL_BERKELEY_DB
1698
1699         if test $ol_cv_berkeley_db = yes ; then
1700                 ol_link_ldbm=db
1701                 ol_with_ldbm_api=db
1702
1703                 if test $ol_with_ldbm_type = hash ; then
1704                         AC_DEFINE(LDBM_USE_DBHASH,1,
1705                                 [define this to use DBHASH w/ LDBM backend])
1706                 else
1707                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1708                                 [define this to use DBBTREE w/ LDBM backend])
1709                 fi
1710
1711                 dnl $ol_cv_lib_db should be yes or -ldb
1712                 dnl (it could be no, but that would be an error
1713                 if test $ol_cv_lib_db != yes ; then
1714                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1715                 fi
1716         fi
1717 fi
1718
1719 if test $ol_with_ldbm_api = manual ; then
1720         dnl User thinks he can manually configure LDBM api.
1721         ol_link_ldbm=yes
1722
1723         AC_MSG_WARN([LDBM defines and link options must be set manually])
1724
1725         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1726 fi
1727
1728 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1729         AC_MSG_WARN(Could not find LDBM with BTREE support)
1730         ol_with_ldbm_api=none
1731 fi
1732
1733 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1734         OL_MDBM
1735
1736         if test $ol_cv_mdbm = yes ; then
1737                 ol_link_ldbm=mdbm
1738                 ol_with_ldbm_api=mdbm
1739                 if test $ol_cv_lib_mdbm != yes ; then
1740                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1741                 fi
1742         fi
1743 fi
1744
1745 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1746         OL_GDBM
1747
1748         if test $ol_cv_gdbm = yes ; then
1749                 ol_link_ldbm=gdbm
1750                 ol_with_ldbm_api=gdbm
1751
1752                 if test $ol_cv_lib_gdbm != yes ; then
1753                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1754                 fi
1755         fi
1756 fi
1757
1758 if test $ol_with_ldbm_api = ndbm ; then
1759         OL_NDBM
1760
1761         if test $ol_cv_ndbm = yes ; then
1762                 ol_link_ldbm=ndbm
1763                 ol_with_ldbm_api=ndbm
1764
1765                 if test $ol_cv_lib_ndbm != yes ; then
1766                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1767                 fi
1768         fi
1769 fi
1770
1771 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1772         AC_MSG_WARN(could not find suitable LDBM backend)
1773         if test $ol_enable_ldbm = yes ; then
1774                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1775         fi
1776
1777         AC_MSG_WARN(disabling LDBM)
1778         ol_enable_ldbm=no
1779 fi
1780
1781 dnl ----------------------------------------------------------------
1782 if test $ol_enable_dynamic = yes -a $enable_shared = yes ; then
1783         LINK_BINS_DYNAMIC="yes"
1784 else
1785         LINK_BINS_DYNAMIC="no"
1786 fi
1787
1788 dnl ----------------------------------------------------------------
1789 if test $ol_enable_wrappers != no ; then
1790         AC_CHECK_HEADERS(tcpd.h)
1791
1792         if test $ac_cv_header_tcpd_h != yes ; then
1793                 have_wrappers=no
1794         else
1795                 AC_TRY_COMPILE([
1796 int allow_severity = 0;
1797 int deny_severity  = 0;
1798                 ],[hosts_access()],[have_wrappers=yes],[have_wrappers=no])
1799         fi
1800
1801         if test $have_wrappers = yes ; then
1802                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1803                 WRAP_LIBS="-lwrap"
1804
1805                 dnl We add another check for -lnsl since some libwrap's
1806                 dnl need it, but it isn't always included from above
1807                 AC_CHECK_LIB(nsl, main)
1808         else
1809                 AC_MSG_WARN(could not find -lwrap)
1810                 if test $ol_enable_wrappers = yes ; then
1811                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1812                 fi
1813
1814                 AC_MSG_WARN(disabling wrappers support)
1815                 ol_enable_wrappers=no
1816                 WRAP_LIBS=""
1817         fi
1818 fi
1819
1820 dnl ----------------------------------------------------------------
1821 if test $ol_enable_syslog != no ; then
1822         AC_CHECK_FUNC(openlog)
1823         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1824                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1825         fi
1826         ol_enable_syslog=$ac_cv_func_openlog
1827 fi
1828
1829 dnl ----------------------------------------------------------------
1830 if test $ol_enable_dmalloc != no ; then
1831         AC_CHECK_HEADERS(dmalloc.h)
1832         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1833 fi
1834
1835 dnl ----------------------------------------------------------------
1836 dnl TCL
1837 if test $ol_enable_tcl != no ; then
1838         AC_CHECK_HEADERS(tcl.h)
1839
1840         if test $ac_cv_header_tcl_h != yes ; then
1841                 have_tcl=no
1842         else
1843                 for lib in tcl tcl7.6 tcl8.0 tcl8.2 ; do
1844                         AC_CHECK_LIB($lib,main,
1845                           [have_tcl=yes
1846                            if test x"$ol_with_tcl_module" = "xstatic" ; then
1847                                SLAPD_LIBS="$SLAPD_LIBS -l${lib}"
1848                            else
1849                                MOD_TCL_LIB="-l${lib}"
1850                            fi;break],[have_tcl=no])
1851                 done
1852         fi
1853
1854         if test $have_tcl != yes ; then
1855                 AC_MSG_WARN([could not find -ltcl])
1856                 if test $ol_enable_tcl = yes ; then
1857                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1858                 fi
1859
1860                 ol_enable_tcl=no
1861         fi
1862 fi
1863
1864 dnl ----------------------------------------------------------------
1865 dnl ud needs termcap (should insert check here)
1866 ol_link_termcap=no
1867 AC_CHECK_HEADERS(termcap.h ncurses.h)
1868
1869 if test $ol_link_termcap = no ; then
1870         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1871         if test $have_termcap = yes ; then
1872                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1873                 ol_link_termcap=yes
1874                 TERMCAP_LIBS=-ltermcap
1875         fi
1876 fi
1877
1878 if test $ol_link_termcap = no ; then
1879         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1880         if test $have_ncurses = yes ; then
1881                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1882                 ol_link_termcap=yes
1883                 TERMCAP_LIBS=-lncurses
1884         fi
1885 fi
1886
1887 if test $ol_link_termcap = no ; then
1888         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1889         TERMCAP_LIBS=
1890 fi
1891
1892 dnl ----------------------------------------------------------------
1893 dnl
1894 dnl Check for Cyrus SASL
1895 dnl
1896 ol_link_sasl=no
1897 if test $ol_with_cyrus_sasl != no ; then
1898         AC_CHECK_HEADER(sasl.h)
1899
1900         if test $ac_cv_header_sasl_h = yes ; then
1901                 AC_CHECK_LIB(sasl, sasl_client_init,
1902                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1903
1904                 if test $have_cyrus_sasl != no ; then
1905                         SASL_LIBS="-lsasl"
1906                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1907                         ol_link_sasl=yes
1908                 fi
1909         fi
1910
1911         if test $ol_link_sasl = no -a $ol_with_cyrus_sasl = yes ; then
1912                 AC_MSG_ERROR(no suitable API for --with-cyrus-sasl=$ol_with_cyrus_sasl)
1913         fi
1914 fi
1915
1916 dnl ----------------------------------------------------------------
1917 dnl Check for entropy sources
1918 if test $cross_compiling != yes ; then
1919         dev=no
1920         if test -r /dev/urandom ; then
1921                 dev="/dev/urandom";
1922         elif test -r /idev/urandom ; then
1923                 dev="/idev/urandom";
1924         elif test -r /dev/srandom ; then
1925                 dev="/dev/srandom";
1926         elif test -r /dev/random ; then
1927                 dev="/dev/random";
1928         elif test -r /idev/random ; then
1929                 dev="/idev/random";
1930         fi
1931
1932         if test $dev != no ; then
1933                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
1934         fi
1935 fi
1936
1937 dnl ----------------------------------------------------------------
1938 dnl
1939 dnl Check for fetch URL support
1940 dnl             should be extended to support other fetch URL APIs
1941 dnl
1942 ol_link_fetch=no
1943 if test $ol_with_fetch != no ; then
1944         OL_LIB_FETCH
1945
1946         if test $ol_cv_lib_fetch != no ; then
1947                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1948                 ol_link_fetch=freebsd
1949
1950         elif test $ol_with_fetch != auto ; then
1951                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1952         fi
1953 fi
1954
1955 dnl ----------------------------------------------------------------
1956 dnl
1957 dnl Check for GNU readline
1958 dnl
1959 ol_link_readline=no
1960 if test $ol_with_readline != no ; then
1961         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1962
1963         if test $ac_cv_header_readline_readline_h = yes ; then
1964                 save_LIBS="$LIBS"
1965                 LIBS="$TERMCAP_LIBS $LIBS"
1966                 AC_CHECK_LIB(readline, readline,
1967                         [have_readline=yes], [have_readline=no])
1968                 LIBS="$save_LIBS"
1969
1970                 if test $have_readline = yes ; then
1971                         ol_with_readline=found
1972                         ol_link_readline=yes
1973
1974                         READLINE_LIBS="-lreadline"
1975                 fi
1976         fi
1977 fi
1978
1979 if test $ol_link_readline = yes ; then
1980         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1981 fi
1982
1983
1984 dnl ----------------------------------------------------------------
1985 dnl FreeBSD (and others) have crypt(3) in -lcrypt
1986 if test $ol_enable_crypt != no ; then
1987         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1988                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1989                         have_crypt=yes], [have_crypt=no])])
1990
1991         if test $have_crypt = yes ; then
1992                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1993         else
1994                 AC_MSG_WARN(could not find crypt)
1995                 if test $ol_enable_crypt = yes ; then
1996                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1997                 fi
1998
1999                 AC_MSG_WARN(disabling crypt support)
2000                 ol_enable_crypt=no
2001         fi
2002 fi
2003
2004 dnl ----------------------------------------------------------------
2005 dnl FreeBSD (and others) have setproctitle(3) in -lutil
2006 if test $ol_enable_proctitle != no ; then
2007         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
2008                 AC_CHECK_LIB(util, setproctitle,
2009                         [have_setproctitle=yes
2010                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
2011                         [have_setproctitle=no
2012                         LIBOBJS="$LIBOBJS setproctitle.o"
2013                         LIBSRCS="$LIBSRCS setproctitle.c"])])
2014
2015         if test $have_setproctitle = yes ; then
2016                 AC_DEFINE(HAVE_SETPROCTITLE,1,
2017                         [define if setproctitle(3) is available])
2018         fi
2019 fi
2020
2021 dnl ----------------------------------------------------------------
2022 dnl Checks for typedefs, structures, and compiler characteristics.
2023 AC_TYPE_MODE_T
2024 AC_TYPE_OFF_T
2025 AC_TYPE_PID_T
2026 AM_TYPE_PTRDIFF_T
2027 AC_TYPE_SIGNAL
2028 AC_TYPE_SIZE_T
2029
2030 AC_CHECK_TYPE(ssize_t, [signed int])
2031 AC_CHECK_TYPE(caddr_t,  [char *])
2032
2033 OL_TYPE_SOCKLEN_T
2034 AC_STRUCT_ST_BLKSIZE
2035 AC_HEADER_TIME
2036 AC_STRUCT_TM
2037 AC_TYPE_UID_T
2038 OL_TYPE_SIG_ATOMIC_T
2039
2040 dnl AC_TYPE_GETGROUPS
2041
2042 OL_STRUCT_PASSWD_PW_GECOS
2043 OL_STRUCT_PASSWD_PW_PASSWD
2044
2045 OL_C_UPPER_LOWER
2046 AC_C_CONST
2047 OL_C_VOLATILE
2048
2049 if test $cross_compiling = yes ; then
2050         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2051 else
2052         AC_C_BIGENDIAN
2053 fi
2054
2055 AC_COMPILE_CHECK_SIZEOF(short)
2056 AC_COMPILE_CHECK_SIZEOF(int)
2057 AC_COMPILE_CHECK_SIZEOF(long)
2058
2059 if test "$ac_cv_sizeof_int" -lt 4 ; then
2060         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2061
2062         AC_DEFINE(LBER_INT_T,long)
2063 else
2064         AC_DEFINE(LBER_INT_T,int)
2065 fi
2066
2067 AC_DEFINE(LBER_LEN_T,long)
2068 AC_DEFINE(LBER_SOCKET_T,int)
2069 AC_DEFINE(LBER_TAG_T,long)
2070
2071 dnl ----------------------------------------------------------------
2072 dnl Checks for library functions.
2073 AC_FUNC_MEMCMP
2074 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
2075 AC_FUNC_STRFTIME
2076 dnl AM_FUNC_STRTOD
2077
2078 OL_FUNC_INET_ATON
2079
2080 dnl Check for NT specific routines
2081 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2082
2083 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2084         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2085 ])
2086
2087 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2088         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2089 ])
2090
2091 AC_FUNC_VPRINTF
2092
2093 if test $ac_cv_func_vprintf = yes ; then
2094         dnl check for vsnprintf
2095         AC_CHECK_FUNCS(vsnprintf vsprintf)
2096 fi
2097
2098 AC_CHECK_FUNCS(         \
2099         bcopy                   \
2100         closesocket             \
2101         endgrent                \
2102         endpwent                \
2103         flock                   \
2104         getdtablesize   \
2105         getgrgid                \
2106         gethostname             \
2107         getpass                 \
2108         getpwuid                \
2109         getpwnam                \
2110         getspnam                \
2111         gettimeofday    \
2112         initgroups              \
2113         lockf                   \
2114         memcpy                  \
2115         memmove                 \
2116         mkstemp                 \
2117         pipe                    \
2118         read                    \
2119         recv                    \
2120         recvfrom                \
2121         setpwfile               \
2122         setgid                  \
2123         setegid                 \
2124         setsid                  \
2125         setuid                  \
2126         seteuid                 \
2127         sigaction               \
2128         signal                  \
2129         sigset                  \
2130         snprintf                \
2131         strdup                  \
2132         strerror                \
2133         strpbrk                 \
2134         strrchr                 \
2135         strsep                  \
2136         strstr                  \
2137         strtol                  \
2138         strtoul                 \
2139         strspn                  \
2140         sysconf                 \
2141         waitpid                 \
2142         wait4                   \
2143         write                   \
2144         send                    \
2145         sendto                  \
2146 )
2147
2148 dnl We actually may need to replace more than this.
2149 AC_REPLACE_FUNCS(getopt tempnam)
2150
2151 if test "$ac_cv_func_getopt" != yes; then
2152     LIBSRCS="$LIBSRCS getopt.c"
2153 fi
2154
2155 if test "$ac_cv_func_tempnam" != yes; then
2156     LIBSRCS="$LIBSRCS tempnam.c"
2157 fi
2158
2159 dnl ----------------------------------------------------------------
2160 # Check Configuration
2161 OL_SYS_ERRLIST
2162
2163 dnl ----------------------------------------------------------------
2164 dnl Sort out defines
2165
2166 if test "$ol_enable_debug" != no ; then
2167         AC_DEFINE(LDAP_DEBUG,1,
2168                 [define this to add debugging code])
2169 fi
2170 if test "$ol_enable_syslog" = yes ; then
2171         AC_DEFINE(LDAP_SYSLOG,1,
2172                 [define this to add syslog code])
2173 fi
2174 if test "$ol_enable_libui" = yes ; then
2175         AC_DEFINE(LDAP_LIBUI,1,
2176                 [define this for LDAP User Interface support])
2177 fi
2178 if test "$ol_enable_cache" = no ; then
2179         AC_DEFINE(LDAP_NOCACHE,1,
2180                 [define this to remove -lldap cache support])
2181 fi
2182 if test "$ol_link_kbind" != no ; then
2183         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_KBIND,LDAP_VENDOR_VERSION)
2184 fi
2185 if test "$ol_enable_dns" != no ; then
2186         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
2187 fi
2188 if test "$ol_enable_proctitle" != no ; then
2189         AC_DEFINE(LDAP_PROCTITLE,1,
2190                 [define this for LDAP process title support])
2191 fi
2192 if test "$ol_enable_referrals" != no ; then
2193         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
2194 fi
2195 if test "$ol_enable_cldap" != no ; then
2196         AC_DEFINE(LDAP_CONNECTIONLESS,1,[define to support CLDAP])
2197 fi
2198 if test "$ol_enable_ldapi" != no; then
2199         AC_DEFINE(USE_PF_LOCAL,1,[define to support PF_LOCAL transport])
2200 fi
2201
2202 if test "$ol_enable_cleartext" != no ; then
2203         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2204 fi
2205 if test "$ol_enable_crypt" != no ; then
2206         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2207 fi
2208 if test "$ol_link_kpasswd" != no ; then
2209         AC_DEFINE(SLAPD_KPASSWD,1,[define to support Kerberos passwords])
2210 fi
2211 if test "$ol_enable_multimaster" != no ; then
2212         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2213 fi
2214 if test "$ol_enable_phonetic" != no ; then
2215         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
2216 fi
2217 if test "$ol_enable_rlookups" != no ; then
2218         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2219 fi
2220 if test "$ol_enable_aci" != no ; then
2221         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2222 fi
2223
2224 if test "$ol_link_modules" != no ; then
2225         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2226         BUILD_SLAPD=yes
2227         SLAPD_MODULES_LDFLAGS="-dlopen self"
2228 fi
2229
2230 if test "$ol_link_bdb2" != no ; then
2231         AC_DEFINE(SLAPD_BDB2,1,[define to support BDB2 backend])
2232         BUILD_SLAPD=yes
2233         BUILD_BDB2=yes
2234         if test "$ol_with_bdb2_module" != static ; then
2235                 AC_DEFINE(SLAPD_BDB2_DYNAMIC,1,
2236                         [define to support dynamic BDB2 backend])
2237                 BUILD_BDB2=mod
2238                 BUILD_BDB2_DYNAMIC=shared
2239                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-bdb2/back_bdb2.la"
2240         fi
2241 fi
2242
2243 if test "$ol_enable_ldap" != no ; then
2244         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
2245         BUILD_SLAPD=yes
2246         BUILD_LDAP=yes
2247         if test "$ol_with_ldap_module" != static ; then
2248                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
2249                         [define to support dynamic LDAP backend])
2250                 BUILD_LDAP=mod
2251                 BUILD_LDAP_DYNAMIC=shared
2252                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
2253         fi
2254 fi
2255
2256 if test "$ol_link_ldbm" != no ; then
2257         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
2258         BUILD_SLAPD=yes
2259         BUILD_LDBM=yes
2260         if test "$ol_with_ldbm_module" != static ; then
2261                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
2262                         [define to support dynamic LDBM backend])
2263                 BUILD_LDBM=mod
2264                 BUILD_LDBM_DYNAMIC=shared
2265                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
2266         fi
2267 fi
2268
2269 if test "$ol_enable_passwd" != no ; then
2270         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2271         BUILD_SLAPD=yes
2272         BUILD_PASSWD=yes
2273         if test "$ol_with_passwd_module" != static ; then
2274                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2275                         [define to support dynamic PASSWD backend])
2276                 BUILD_PASSWD=mod
2277                 BUILD_PASSWD_DYNAMIC=shared
2278                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
2279         fi
2280 fi
2281
2282 if test "$ol_link_perl" != no ; then
2283         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
2284         BUILD_SLAPD=yes
2285         BUILD_PERL=yes
2286         if test "$ol_with_perl_module" != static ; then
2287                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
2288                         [define to support dynamic PERL backend])
2289                 BUILD_PERL=mod
2290                 BUILD_PERL_DYNAMIC=shared
2291                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-perl/back_perl.la"
2292         fi
2293 fi
2294
2295 if test "$ol_enable_shell" != no ; then
2296         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2297         BUILD_SLAPD=yes
2298         BUILD_SHELL=yes
2299         if test "$ol_with_shell_module" != static ; then
2300                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2301                         [define to support dynamic SHELL backend])
2302                 BUILD_SHELL=mod
2303                 BUILD_SHELL_DYNAMIC=shared
2304                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2305         fi
2306 fi
2307
2308 if test "$ol_enable_tcl" != no ; then
2309         AC_DEFINE(SLAPD_TCL,1,[define to support TCL backend])
2310         BUILD_SLAPD=yes
2311         BUILD_TCL=yes
2312         if test "$ol_with_tcl_module" != static; then
2313                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1,
2314                         [define to support dynamic TCL backend])
2315                 BUILD_TCL=mod
2316                 BUILD_TCL_DYNAMIC=shared
2317                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-tcl/back_tcl.la"
2318         fi
2319 fi
2320
2321 if test "$ol_enable_sql" != no ; then
2322         AC_DEFINE(SLAPD_SQL,1,[define to support SQL backend])
2323         BUILD_SLAPD=yes
2324         BUILD_SQL=yes
2325         SLAPD_SQL_LIBS=-liodbc
2326         if test "$ol_with_sql_module" != static; then
2327                 AC_DEFINE(SLAPD_SQL_DYNAMIC,1,
2328                         [define to support dynamic SQL backend])
2329                 BUILD_SQL=mod
2330                 BUILD_SQL_DYNAMIC=shared
2331                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-sql/back_sql.la"
2332         fi
2333 fi
2334
2335 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2336         $BUILD_SLAPD = yes ; then
2337         BUILD_SLURPD=yes
2338 fi
2339
2340 if test "$ol_link_isode" != no ; then
2341         BUILD_LDAPD=yes
2342 fi
2343
2344 dnl ----------------------------------------------------------------
2345
2346 if test "$LINK_BINS_DYNAMIC" = yes; then
2347     LIB_LINKAGE=DYN
2348     LT_LIB_LINKAGE=shared
2349 else
2350     LIB_LINKAGE=STAT
2351     LT_LIB_LINKAGE=static
2352 fi
2353
2354 if test "$ac_cv_mingw32" = yes ; then
2355     PLAT=NT
2356     DYN_EXT=dll
2357 else
2358     PLAT=UNIX
2359     DYN_EXT=so
2360 fi
2361
2362 AC_SUBST(LIBSRCS)
2363
2364 AC_SUBST(PLAT)
2365 AC_SUBST(LIB_LINKAGE)
2366 AC_SUBST(LT_LIB_LINKAGE)
2367 AC_SUBST(DYN_EXT)
2368
2369 AC_SUBST(BUILD_LDAPD)
2370 AC_SUBST(BUILD_SLAPD)
2371   AC_SUBST(BUILD_BDB2)
2372   AC_SUBST(BUILD_LDAP)
2373   AC_SUBST(BUILD_LDBM)
2374   AC_SUBST(BUILD_PASSWD)
2375   AC_SUBST(BUILD_PERL)
2376   AC_SUBST(BUILD_QUIPU)
2377   AC_SUBST(BUILD_SHELL)
2378   AC_SUBST(BUILD_TCL)
2379   AC_SUBST(BUILD_SQL)
2380   AC_SUBST(BUILD_BDB2_DYNAMIC)
2381   AC_SUBST(BUILD_LDAP_DYNAMIC)
2382   AC_SUBST(BUILD_LDBM_DYNAMIC)
2383   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2384   AC_SUBST(BUILD_PERL_DYNAMIC)
2385   AC_SUBST(BUILD_SHELL_DYNAMIC)
2386   AC_SUBST(BUILD_TCL_DYNAMIC)
2387   AC_SUBST(BUILD_SQL_DYNAMIC)
2388 AC_SUBST(BUILD_SLURPD)
2389
2390 AC_SUBST(LDAP_LIBS)
2391 AC_SUBST(LDAPD_LIBS)
2392 AC_SUBST(LDIF_LIBS)
2393 AC_SUBST(SLAPD_LIBS)
2394 AC_SUBST(SLURPD_LIBS)
2395 AC_SUBST(LDBM_LIBS)
2396 AC_SUBST(LTHREAD_LIBS)
2397 AC_SUBST(LUTIL_LIBS)
2398 AC_SUBST(WRAP_LIBS)
2399 AC_SUBST(MOD_TCL_LIB)
2400 AC_SUBST(LINK_BINS_DYNAMIC)
2401
2402 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2403 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2404 AC_SUBST(SLAPD_MODULES_LIST)
2405
2406 AC_SUBST(PERL_CPPFLAGS)
2407 AC_SUBST(SLAPD_PERL_LDFLAGS)
2408 AC_SUBST(MOD_PERL_LDFLAGS)
2409
2410 AC_SUBST(KRB4_LIBS)
2411 AC_SUBST(KRB5_LIBS)
2412 AC_SUBST(READLINE_LIBS)
2413 AC_SUBST(SASL_LIBS)
2414 AC_SUBST(TERMCAP_LIBS)
2415 AC_SUBST(TLS_LIBS)
2416 AC_SUBST(MODULES_LIBS)
2417
2418 AC_SUBST(SLAPD_SQL_LDFLAGS)
2419 AC_SUBST(SLAPD_SQL_LIBS)
2420 AC_SUBST(SLAPD_SQL_INCLUDES)
2421
2422 dnl ----------------------------------------------------------------
2423 dnl final output
2424 dnl
2425
2426 AC_OUTPUT( \
2427 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2428 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2429 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2430 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2431 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2432 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2433 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2434 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2435 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2436 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2437 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2438 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2439 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2440 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2441 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2442 include/Makefile:build/top.mk:include/Makefile.in \
2443 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2444 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2445 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2446 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2447 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2448 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2449 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2450 libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk  \
2451 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2452 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2453 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
2454 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2455 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/mod.mk \
2456 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2457 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2458 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2459 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk \
2460 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2461 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/mod.mk \
2462 servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk \
2463 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2464 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2465 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2466 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2467 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2468 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2469 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2470 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2471 ,[
2472 date > stamp-h
2473 echo Please \"make depend\" to build dependencies
2474 ])