git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl This work is part of OpenLDAP Software <http://www.openldap.org/>.
   3 dnl
   4 dnl Copyright 1998-2010 The OpenLDAP Foundation.
   5 dnl All rights reserved.
   6 dnl
   7 dnl Redistribution and use in source and binary forms, with or without
   8 dnl modification, are permitted only as authorized by the OpenLDAP
   9 dnl Public License.
  10 dnl
  11 dnl A copy of this license is available in the file LICENSE in the
  12 dnl top-level directory of the distribution or, alternatively, at
  13 dnl <http://www.OpenLDAP.org/license.html>.
  14 dnl
  15 dnl ----------------------------------------------------------------
  16 dnl Disable config.cache!
  17 define([AC_CACHE_LOAD], )dnl
  18 define([AC_CACHE_SAVE], )dnl
  19 dnl ----------------------------------------------------------------
  20 dnl Disable libtool 1.5 support for languages we don't use
  21 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  22 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  23 define([AC_LIBTOOL_LANG_GCJ_CONFIG], [:])dnl
  24 dnl ================================================================
  25 dnl Configure.in for OpenLDAP
  26 AC_COPYRIGHT([[Copyright 1998-2010 The OpenLDAP Foundation. All rights reserved.
  27 Restrictions apply, see COPYRIGHT and LICENSE files.]])
  28 AC_REVISION([$OpenLDAP$])
  29 AC_INIT([OpenLDAP],,[http://www.openldap.org/its/])
  30 m4_define([AC_PACKAGE_BUGREPORT],[<http://www.openldap.org/its/>])
  31 AC_CONFIG_SRCDIR(build/version.sh)dnl
  32 dnl ----------------------------------------------------------------
  33 dnl OpenLDAP Autoconf Macros
  34 builtin(include, build/openldap.m4)dnl
  35 dnl ================================================================
  36
  37 AC_CONFIG_AUX_DIR(build)dnl
  38
  39 eval `$ac_aux_dir/version.sh`
  40 if test -z "$OL_STRING"; then
  41         AC_MSG_ERROR([could not determine version])
  42 fi
  43
  44 if test -f "$ac_aux_dir/shtool" && test ! -d $ac_aux_dir/shtool; then
  45         ac_cv_shtool="$ac_aux_dir/shtool"
  46 else
  47         AC_MSG_ERROR([no shtool found in $ac_aux_dir])
  48 fi
  49
  50 SHTOOL="$ac_cv_shtool"
  51 dnl AC_SUBST(SHTOOL)dnl
  52
  53 TB="" TN=""
  54 if test -t 1; then
  55         TB="`$SHTOOL echo -e '%B' 2>/dev/null`"
  56         TN="`$SHTOOL echo -e '%b' 2>/dev/null`"
  57 fi
  58
  59 OPENLDAP_CVS=""
  60 if test -d $ac_aux_dir/CVS; then
  61         OPENLDAP_CVS="(from CVS sources) "
  62 fi
  63
  64 echo "Configuring ${TB}${OL_STRING}${TN} ${OPENLDAP_CVS}..."
  65
  66 dnl Determine host platform
  67 dnl             we try not to use this for much
  68 AC_CANONICAL_TARGET([])
  69
  70 AM_INIT_AUTOMAKE([$OL_PACKAGE],[$OL_VERSION], [no defines])dnl
  71 AC_SUBST(PACKAGE)dnl
  72 AC_SUBST(VERSION)dnl
  73 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  74 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  75
  76 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION,$OL_API_INC,Version)
  77 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MAJOR,$OL_MAJOR,Major)
  78 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MINOR,$OL_MINOR,Minor)
  79 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_PATCH,$OL_PATCH,Patch)
  80
  81 OPENLDAP_LIBRELEASE=$OL_API_LIB_RELEASE
  82 AC_SUBST(OPENLDAP_LIBRELEASE)dnl
  83
  84 OPENLDAP_LIBVERSION=$OL_API_LIB_VERSION
  85 AC_SUBST(OPENLDAP_LIBVERSION)dnl
  86
  87 OPENLDAP_RELEASE_DATE="$OL_RELEASE_DATE"
  88 AC_SUBST(OPENLDAP_RELEASE_DATE)dnl
  89
  90 dnl We use autoconf features new to 2.59.  Later versions like won't work.
  91 dnl aclocal.m4 should be built using aclocal from automake 1.5
  92 dnl libtool 1.5 should be installed.
  93 AC_PREREQ(2.59)dnl Required Autoconf version
  94
  95 AH_TOP([
  96 /* begin of portable.h.pre */
  97 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
  98  *
  99  * Copyright 1998-2010 The OpenLDAP Foundation
 100  * All rights reserved.
 101  *
 102  * Redistribution and use in source and binary forms, with or without
 103  * modification, are permitted only as authorized by the OpenLDAP
 104  * Public License.
 105  *
 106  * A copy of this license is available in the file LICENSE in the
 107  * top-level directory of the distribution or, alternatively, at
 108  * <http://www.OpenLDAP.org/license.html>.
 109  */
 110
 111 #ifndef _LDAP_PORTABLE_H
 112 #define _LDAP_PORTABLE_H
 113
 114 /* define this if needed to get reentrant functions */
 115 #ifndef REENTRANT
 116 #undef REENTRANT
 117 #endif
 118 #ifndef _REENTRANT
 119 #undef _REENTRANT
 120 #endif
 121
 122 /* define this if needed to get threadsafe functions */
 123 #ifndef THREADSAFE
 124 #undef THREADSAFE
 125 #endif
 126 #ifndef _THREADSAFE
 127 #undef _THREADSAFE
 128 #endif
 129 #ifndef THREAD_SAFE
 130 #undef THREAD_SAFE
 131 #endif
 132 #ifndef _THREAD_SAFE
 133 #undef _THREAD_SAFE
 134 #endif
 135
 136 #ifndef _SGI_MP_SOURCE
 137 #undef _SGI_MP_SOURCE
 138 #endif
 139
 140 /* end of portable.h.pre */
 141 ])
 142 AH_BOTTOM([
 143 /* begin of portable.h.post */
 144
 145 #ifdef _WIN32
 146         /* don't suck in all of the win32 api */
 147 #       define WIN32_LEAN_AND_MEAN 1
 148 #endif
 149
 150 #ifndef LDAP_NEEDS_PROTOTYPES
 151 /* force LDAP_P to always include prototypes */
 152 #define LDAP_NEEDS_PROTOTYPES 1
 153 #endif
 154
 155 #ifndef LDAP_REL_ENG
 156 #if (LDAP_VENDOR_VERSION == 000000) && !defined(LDAP_DEVEL)
 157 #define LDAP_DEVEL
 158 #endif
 159 #if defined(LDAP_DEVEL) && !defined(LDAP_TEST)
 160 #define LDAP_TEST
 161 #endif
 162 #endif
 163
 164 #ifdef HAVE_STDDEF_H
 165 #       include <stddef.h>
 166 #endif
 167
 168 #ifdef HAVE_EBCDIC
 169 /* ASCII/EBCDIC converting replacements for stdio funcs
 170  * vsnprintf and snprintf are used too, but they are already
 171  * checked by the configure script
 172  */
 173 #define fputs ber_pvt_fputs
 174 #define fgets ber_pvt_fgets
 175 #define printf ber_pvt_printf
 176 #define fprintf ber_pvt_fprintf
 177 #define vfprintf ber_pvt_vfprintf
 178 #define vsprintf ber_pvt_vsprintf
 179 #endif
 180
 181 #include "ac/fdset.h"
 182
 183 #include "ldap_cdefs.h"
 184 #include "ldap_features.h"
 185
 186 #include "ac/assert.h"
 187 #include "ac/localize.h"
 188
 189 #endif /* _LDAP_PORTABLE_H */
 190 /* end of portable.h.post */
 191 ])
 192
 193 AC_CONFIG_HEADERS([include/portable.h:include/portable.hin])
 194 AC_CONFIG_HEADERS([include/ldap_features.h:include/ldap_features.hin])
 195 AC_CONFIG_HEADERS([include/lber_types.h:include/lber_types.hin])
 196
 197 dnl ================================================================
 198 dnl Start Args
 199 AC_MSG_CHECKING(configure arguments)
 200 AC_PREFIX_DEFAULT(/usr/local)
 201
 202 top_builddir=`pwd`
 203 AC_SUBST(top_builddir)dnl
 204
 205 dnl ----------------------------------------------------------------
 206 dnl --with-subdir
 207 ldap_subdir="/openldap"
 208
 209 AC_ARG_WITH(subdir,
 210 [  --with-subdir=DIR       change default subdirectory used for installs],
 211 [case "$withval" in
 212         no) ldap_subdir=""
 213                 ;;
 214         yes)
 215                 ;;
 216         /*|\\*)
 217                 ldap_subdir="$withval"
 218                 ;;
 219         *)
 220                 ldap_subdir="/$withval"
 221                 ;;
 222 esac
 223 ])dnl
 224
 225 AC_SUBST(ldap_subdir)dnl
 226
 227 dnl ----------------------------------------------------------------
 228 dnl General "enable" options
 229 dnl set default to traditional to enable the original debug style
 230 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes, [no yes traditional])dnl
 231 OL_ARG_ENABLE(dynamic,[  --enable-dynamic         enable linking built binaries with dynamic libs], no)dnl
 232 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 233 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 234 dnl OL_ARG_ENABLE(referrals,[  --enable-referrals         enable LDAPv2+ Referrals (experimental)], no)dnl
 235 ol_enable_referrals=${ol_enable_referrals-no}
 236 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 237 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 238
 239 dnl ----------------------------------------------------------------
 240 dnl General "with" options
 241 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 242         auto, [auto yes no] )
 243 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch(3) URL support],
 244         auto, [auto yes no] )
 245 OL_ARG_WITH(threads,[  --with-threads     with threads],
 246         auto, [auto nt posix mach pth lwp yes no manual] )
 247 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support auto|openssl|gnutls|moznss],
 248         auto, [auto openssl gnutls moznss yes no] )
 249 OL_ARG_WITH(yielding_select,
 250         [  --with-yielding-select  with implicitly yielding select],
 251         auto, [auto yes no manual] )
 252 OL_ARG_WITH(mp,
 253         [  --with-mp               with multiple precision statistics auto|longlong|long|bignum|gmp],
 254         auto, [auto longlong long bignum gmp yes no])
 255 OL_ARG_WITH(odbc,
 256         [  --with-odbc             with specific ODBC support iodbc|unixodbc|odbc32|auto],
 257         auto, [auto iodbc unixodbc odbc32] )
 258
 259 dnl ----------------------------------------------------------------
 260 dnl Server options
 261 dnl ----------------------------------------------------------------
 262
 263 dnl ----------------------------------------------------------------
 264 dnl SLAPD OPTIONS
 265 AC_ARG_ENABLE(xxslapdoptions,[
 266 SLAPD (Standalone LDAP Daemon) Options:])
 267 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 268 OL_ARG_ENABLE(dynacl,[    --enable-dynacl         enable run-time loadable ACL support (experimental)], no)dnl
 269 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs (experimental)], no, [no yes mod])dnl
 270 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 271 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], no)dnl
 272 OL_ARG_ENABLE(lmpasswd,[    --enable-lmpasswd     enable LAN Manager passwords], no)dnl
 273 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 274 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 275 OL_ARG_ENABLE(rewrite,[    --enable-rewrite       enable DN rewriting in back-ldap and rwm overlay], auto)dnl
 276 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups of client hostnames], no)dnl
 277 OL_ARG_ENABLE(slapi,[    --enable-slapi        enable SLAPI support (experimental)], no)dnl
 278 OL_ARG_ENABLE(slp,[    --enable-slp          enable SLPv2 support], no)dnl
 279 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 280
 281 dnl ----------------------------------------------------------------
 282 dnl SLAPD Backend Options
 283 Backends="bdb \
 284         dnssrv \
 285         hdb \
 286         ldap \
 287         meta \
 288         monitor \
 289         ndb \
 290         null \
 291         passwd \
 292         perl \
 293         relay \
 294         shell \
 295         sock \
 296         sql"
 297
 298 AC_ARG_ENABLE(xxslapbackends,[
 299 SLAPD Backend Options:])
 300
 301 OL_ARG_ENABLE(backends,[    --enable-backends     enable all available backends],
 302         --, [no yes mod])dnl
 303 OL_ARG_ENABLE(bdb,[    --enable-bdb       enable Berkeley DB backend],
 304         no, [no yes mod], ol_enable_backends)dnl
 305 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend],
 306         no, [no yes mod], ol_enable_backends)dnl
 307 OL_ARG_ENABLE(hdb,[    --enable-hdb       enable Hierarchical DB backend],
 308         yes, [no yes mod], ol_enable_backends)dnl
 309 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend],
 310         no, [no yes mod], ol_enable_backends)dnl
 311 OL_ARG_ENABLE(meta,[    --enable-meta     enable metadirectory backend],
 312         no, [no yes mod], ol_enable_backends)dnl
 313 OL_ARG_ENABLE(monitor,[    --enable-monitor       enable monitor backend],
 314         yes, [no yes mod], ol_enable_backends)dnl
 315 OL_ARG_ENABLE(ndb,[    --enable-ndb       enable MySQL NDB Cluster backend],
 316         no, [no yes mod], ol_enable_backends)dnl
 317 OL_ARG_ENABLE(null,[    --enable-null     enable null backend],
 318         no, [no yes mod], ol_enable_backends)dnl
 319 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend],
 320         no, [no yes mod], ol_enable_backends)dnl
 321 OL_ARG_ENABLE(perl,[    --enable-perl     enable perl backend],
 322         no, [no yes mod], ol_enable_backends)dnl
 323 OL_ARG_ENABLE(relay,[    --enable-relay           enable relay backend],
 324         yes, [no yes mod], ol_enable_backends)dnl
 325 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend],
 326         no, [no yes mod], ol_enable_backends)dnl
 327 OL_ARG_ENABLE(sock,[    --enable-sock     enable sock backend],
 328         no, [no yes mod], ol_enable_backends)dnl
 329 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend],
 330         no, [no yes mod], ol_enable_backends)dnl
 331
 332 dnl ----------------------------------------------------------------
 333 dnl SLAPD Overlay Options
 334 Overlays="accesslog \
 335         auditlog \
 336         collect \
 337         constraint \
 338         dds \
 339         deref \
 340         dyngroup \
 341         dynlist \
 342         memberof \
 343         ppolicy \
 344         proxycache \
 345         refint \
 346         retcode \
 347         rwm \
 348         seqmod \
 349         sssvlv \
 350         syncprov \
 351         translucent \
 352         unique \
 353         valsort"
 354
 355 AC_ARG_ENABLE(xxslapoverlays,[
 356 SLAPD Overlay Options:])
 357
 358 OL_ARG_ENABLE(overlays,[    --enable-overlays     enable all available overlays],
 359         --, [no yes mod])dnl
 360 OL_ARG_ENABLE(accesslog,[    --enable-accesslog   In-Directory Access Logging overlay],
 361         no, [no yes mod], ol_enable_overlays)
 362 OL_ARG_ENABLE(auditlog,[    --enable-auditlog     Audit Logging overlay],
 363         no, [no yes mod], ol_enable_overlays)
 364 OL_ARG_ENABLE(collect,[    --enable-collect       Collect overlay],
 365         no, [no yes mod], ol_enable_overlays)
 366 OL_ARG_ENABLE(constraint,[    --enable-constraint         Attribute Constraint overlay],
 367         no, [no yes mod], ol_enable_overlays)
 368 OL_ARG_ENABLE(dds,[    --enable-dds       Dynamic Directory Services overlay],
 369         no, [no yes mod], ol_enable_overlays)
 370 OL_ARG_ENABLE(deref,[    --enable-deref   Dereference overlay],
 371         no, [no yes mod], ol_enable_overlays)
 372 OL_ARG_ENABLE(dyngroup,[    --enable-dyngroup     Dynamic Group overlay],
 373         no, [no yes mod], ol_enable_overlays)
 374 OL_ARG_ENABLE(dynlist,[    --enable-dynlist       Dynamic List overlay],
 375         no, [no yes mod], ol_enable_overlays)
 376 OL_ARG_ENABLE(memberof,[    --enable-memberof     Reverse Group Membership overlay],
 377         no, [no yes mod], ol_enable_overlays)
 378 OL_ARG_ENABLE(ppolicy,[    --enable-ppolicy       Password Policy overlay],
 379         no, [no yes mod], ol_enable_overlays)
 380 OL_ARG_ENABLE(proxycache,[    --enable-proxycache         Proxy Cache overlay],
 381         no, [no yes mod], ol_enable_overlays)
 382 OL_ARG_ENABLE(refint,[    --enable-refint         Referential Integrity overlay],
 383         no, [no yes mod], ol_enable_overlays)
 384 OL_ARG_ENABLE(retcode,[    --enable-retcode       Return Code testing overlay],
 385         no, [no yes mod], ol_enable_overlays)
 386 OL_ARG_ENABLE(rwm,[    --enable-rwm               Rewrite/Remap overlay],
 387         no, [no yes mod], ol_enable_overlays)
 388 OL_ARG_ENABLE(seqmod,[    --enable-seqmod         Sequential Modify overlay],
 389         no, [no yes mod], ol_enable_overlays)
 390 OL_ARG_ENABLE(sssvlv,[    --enable-sssvlv         ServerSideSort/VLV overlay],
 391         no, [no yes mod], ol_enable_overlays)
 392 OL_ARG_ENABLE(syncprov,[    --enable-syncprov     Syncrepl Provider overlay],
 393         yes, [no yes mod], ol_enable_overlays)
 394 OL_ARG_ENABLE(translucent,[    --enable-translucent  Translucent Proxy overlay],
 395         no, [no yes mod], ol_enable_overlays)
 396 OL_ARG_ENABLE(unique,[    --enable-unique       Attribute Uniqueness overlay],
 397         no, [no yes mod], ol_enable_overlays)
 398 OL_ARG_ENABLE(valsort,[    --enable-valsort      Value Sorting overlay],
 399         no, [no yes mod], ol_enable_overlays)
 400
 401 dnl ----------------------------------------------------------------
 402 AC_ARG_ENABLE(xxliboptions,[
 403 Library Generation & Linking Options])
 404 AC_ENABLE_STATIC
 405 AC_ENABLE_SHARED
 406
 407 dnl ----------------------------------------------------------------
 408
 409 # validate options
 410 if test $ol_enable_slapd = no ; then
 411         dnl SLAPD was specificallly disabled
 412         if test $ol_enable_slapi = yes ; then
 413                 AC_MSG_WARN([slapd disabled, ignoring --enable-slapi argument])
 414         fi
 415         case "$ol_enable_backends" in yes | mod)
 416                 AC_MSG_WARN([slapd disabled, ignoring --enable-backends argument])
 417         esac
 418         for i in $Backends; do
 419                 eval "ol_tmp=\$ol_enable_$i"
 420                 if test $ol_tmp != no ; then
 421                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 422                         eval "ol_enable_$i=no"
 423                 fi
 424         done
 425         if test $ol_enable_modules = yes ; then
 426                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 427         fi
 428         if test $ol_enable_wrappers = yes ; then
 429                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 430         fi
 431         if test $ol_enable_rlookups = yes ; then
 432                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 433         fi
 434         if test $ol_enable_dynacl = yes ; then
 435                 AC_MSG_WARN([slapd disabled, ignoring --enable-dynacl argument])
 436         fi
 437         if test $ol_enable_aci != no ; then
 438                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 439         fi
 440         if test $ol_enable_rewrite = yes ; then
 441                 AC_MSG_WARN([slapd disabled, ignoring --enable-rewrite argument])
 442         fi
 443         dnl overlays
 444         case "$ol_enable_overlays" in yes | mod)
 445                 AC_MSG_WARN([slapd disabled, ignoring --enable-overlays argument])
 446         esac
 447         for i in $Overlays; do
 448                 eval "ol_tmp=\$ol_enable_$i"
 449                 if test $ol_tmp != no ; then
 450                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 451                         eval "ol_enable_$i=no"
 452                 fi
 453         done
 454
 455         # force settings to no
 456         ol_enable_slapi=no
 457
 458         ol_enable_backends=
 459         ol_enable_overlays=
 460         ol_enable_modules=no
 461         ol_enable_rlookups=no
 462         ol_enable_dynacl=no
 463         ol_enable_aci=no
 464         ol_enable_wrappers=no
 465
 466         ol_enable_rewrite=no
 467
 468 elif test $ol_enable_modules != yes &&
 469         test $ol_enable_bdb = no &&
 470         test $ol_enable_dnssrv = no &&
 471         test $ol_enable_hdb = no &&
 472         test $ol_enable_ldap = no &&
 473         test $ol_enable_meta = no &&
 474         test $ol_enable_monitor = no &&
 475         test $ol_enable_ndb = no &&
 476         test $ol_enable_null = no &&
 477         test $ol_enable_passwd = no &&
 478         test $ol_enable_perl = no &&
 479         test $ol_enable_relay = no &&
 480         test $ol_enable_shell = no &&
 481         test $ol_enable_sock = no &&
 482         test $ol_enable_sql = no ; then
 483         dnl no slapd backend
 484
 485         if test $ol_enable_slapd = yes ; then
 486                 AC_MSG_ERROR([slapd requires a backend])
 487         else
 488                 AC_MSG_WARN([skipping slapd, no backend specified])
 489                 ol_enable_slapd=no
 490         fi
 491 fi
 492
 493 if test $ol_enable_meta/$ol_enable_ldap = yes/no ; then
 494         AC_MSG_ERROR([--enable-meta requires --enable-ldap])
 495 fi
 496
 497 if test $ol_enable_lmpasswd = yes ; then
 498         if test $ol_with_tls = no ; then
 499                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
 500         fi
 501 fi
 502
 503 if test $ol_enable_spasswd = yes ; then
 504         if test $ol_with_cyrus_sasl = no ; then
 505                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 506         fi
 507         ol_with_cyrus_sasl=yes
 508 fi
 509
 510 AC_MSG_RESULT(done)
 511
 512 dnl ----------------------------------------------------------------
 513 dnl Initialize vars
 514 LDAP_LIBS=
 515 BDB_LIBS=
 516 SLAPD_NDB_LIBS=
 517 SLAPD_NDB_INCS=
 518 LTHREAD_LIBS=
 519 LUTIL_LIBS=
 520
 521 SLAPD_LIBS=
 522
 523 BUILD_SLAPD=no
 524
 525 BUILD_THREAD=no
 526
 527 BUILD_SLAPI=no
 528 SLAPD_SLAPI_DEPEND=
 529
 530 BUILD_BDB=no
 531 BUILD_DNSSRV=no
 532 BUILD_HDB=no
 533 BUILD_LDAP=no
 534 BUILD_META=no
 535 BUILD_MONITOR=no
 536 BUILD_NDB=no
 537 BUILD_NULL=no
 538 BUILD_PASSWD=no
 539 BUILD_PERL=no
 540 BUILD_RELAY=no
 541 BUILD_SHELL=no
 542 BUILD_SOCK=no
 543 BUILD_SQL=no
 544
 545 BUILD_ACCESSLOG=no
 546 BUILD_AUDITLOG=no
 547 BUILD_CONSTRAINT=no
 548 BUILD_DDS=no
 549 BUILD_DENYOP=no
 550 BUILD_DEREF=no
 551 BUILD_DYNGROUP=no
 552 BUILD_DYNLIST=no
 553 BUILD_LASTMOD=no
 554 BUILD_MEMBEROF=no
 555 BUILD_PPOLICY=no
 556 BUILD_PROXYCACHE=no
 557 BUILD_REFINT=no
 558 BUILD_RETCODE=no
 559 BUILD_RWM=no
 560 BUILD_SEQMOD=no
 561 BUILD_SSSVLV=no
 562 BUILD_SYNCPROV=no
 563 BUILD_TRANSLUCENT=no
 564 BUILD_UNIQUE=no
 565 BUILD_VALSORT=no
 566
 567 SLAPD_STATIC_OVERLAYS=
 568 SLAPD_DYNAMIC_OVERLAYS=
 569
 570 SLAPD_MODULES_LDFLAGS=
 571 SLAPD_MODULES_CPPFLAGS=
 572
 573 SLAPD_STATIC_BACKENDS=back-ldif
 574 SLAPD_DYNAMIC_BACKENDS=
 575
 576 SLAPD_PERL_LDFLAGS=
 577 MOD_PERL_LDFLAGS=
 578 PERL_CPPFLAGS=
 579
 580 SLAPD_SQL_LDFLAGS=
 581 SLAPD_SQL_LIBS=
 582 SLAPD_SQL_INCLUDES=
 583
 584 KRB4_LIBS=
 585 KRB5_LIBS=
 586 SASL_LIBS=
 587 TLS_LIBS=
 588 MODULES_LIBS=
 589 SLAPI_LIBS=
 590 LIBSLAPI=
 591 LIBSLAPITOOLS=
 592 AUTH_LIBS=
 593 ICU_LIBS=
 594
 595 SLAPD_SLP_LIBS=
 596 SLAPD_GMP_LIBS=
 597
 598 dnl ================================================================
 599 dnl Checks for programs
 600
 601 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 602
 603 dnl ----------------------------------------------------------------
 604 dnl
 605 dnl Determine which C translator to use
 606 dnl
 607
 608 dnl AIX Thread requires we use cc_r or xlc_r.
 609 dnl But only do this IF AIX and CC is not set
 610 dnl and threads are auto|yes|posix.
 611 dnl
 612 dnl If we find cc_r|xlc_r, force pthreads and assume
 613 dnl             pthread_create is in $LIBS (ie: don't bring in
 614 dnl             any additional thread libraries)
 615 dnl If we do not find cc_r|xlc_r, disable threads
 616
 617 ol_aix_threads=no
 618 case "$target" in
 619 *-*-aix*) dnl all AIX is not a good idea.
 620         if test -z "$CC" ; then
 621                 case "$ol_with_threads" in
 622                 auto | yes |  posix) ol_aix_threads=yes ;;
 623                 esac
 624         fi
 625 ;;
 626 esac
 627
 628 if test $ol_aix_threads = yes ; then
 629         if test -z "${CC}" ; then
 630                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 631
 632                 if test "$CC" = cc ; then
 633                         dnl no CC! don't allow --with-threads
 634                         if test $ol_with_threads != auto ; then
 635                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 636                         else
 637                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 638                         fi
 639                         ol_with_threads=no
 640                 fi
 641         fi
 642
 643         case ${CC} in cc_r | xlc_r)
 644                 ol_with_threads=posix
 645                 ol_cv_pthread_create=yes
 646                 ;;
 647         esac
 648 fi
 649
 650 if test -z "${CC}"; then
 651         AC_CHECK_PROGS(CC,cc gcc,missing)
 652
 653         if test "${CC}" = "missing" ; then
 654                 AC_MSG_ERROR([Unable to locate cc(1) or suitable replacement.  Check PATH or set CC.])
 655         fi
 656 fi
 657
 658 if test -z "${AR}"; then
 659         AC_CHECK_PROGS(AR,ar gar,missing)
 660
 661         if test "${AR}" = "missing" ; then
 662                 AC_MSG_ERROR([Unable to locate ar(1) or suitable replacement.  Check PATH or set AR.])
 663         fi
 664 fi
 665
 666 AC_LIBTOOL_WIN32_DLL
 667 AC_LIBTOOL_DLOPEN
 668 AC_PROG_LIBTOOL
 669
 670 dnl ----------------------------------------------------------------
 671 dnl Perl
 672 ol_link_perl=no
 673 if test $ol_enable_perl != no ; then
 674         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 675
 676         if test "no$PERLBIN" = "no" ; then
 677                 if test $ol_enable_perl = yes ; then
 678                         AC_MSG_ERROR([could not locate perl])
 679                 fi
 680
 681         else
 682                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 683                 PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e 's/ -lc / /' -e 's/ -lc$//'`"
 684
 685                 if test x"$ol_enable_perl" = "xyes" ; then
 686                         SLAPD_PERL_LDFLAGS="$PERL_LDFLAGS"
 687                 else
 688                         MOD_PERL_LDFLAGS="$PERL_LDFLAGS"
 689                 fi
 690                 dnl should check perl version
 691                 ol_link_perl=yes
 692         fi
 693 fi
 694
 695 AC_PROG_CPP
 696 OL_MSVC
 697
 698 dnl ----------------------------------------------------------------
 699 dnl Checks for Windows NT
 700 case $host_os in
 701   *mingw32* ) ac_cv_mingw32=yes ;;
 702   *cygwin* ) ac_cv_cygwin=yes ;;
 703   *interix* ) ac_cv_interix=yes ;;
 704 esac
 705
 706 dnl ----------------------------------------------------------------
 707 dnl Checks for file extensions
 708 AC_EXEEXT
 709 AC_OBJEXT
 710 AC_DEFINE_UNQUOTED(EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 711
 712 dnl ----------------------------------------------------------------
 713 dnl BeOS requires -lbe -lroot -lnet
 714 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 715
 716 dnl ----------------------------------------------------------------
 717 dnl OpenLDAP requires STDC features
 718 AC_PROG_CC
 719 if test "X${ac_cv_prog_cc_stdc}" = "Xno" ; then
 720         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 721 fi
 722
 723 dnl ----------------------------------------------------------------
 724 dnl Check cc depend flags
 725 OL_MKDEPEND
 726 if test "${ol_cv_mkdep}" = no ; then
 727         # this will soon become an error
 728         AC_MSG_WARN([do not know how to generate dependencies])
 729 fi
 730
 731 dnl ----------------------------------------------------------------
 732 dnl Check for AIX security library
 733 AC_CHECK_LIB(s, afopen, [
 734         AUTH_LIBS=-ls
 735         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 736 ])
 737
 738 dnl ----------------------------------------------------------------
 739 dnl Check for IBM OS/390
 740 case "$target" in
 741 *-ibm-openedition)
 742         ac_cv_func_getopt=no
 743         AC_DEFINE(BOTH_STRINGS_H,1,[define to use both <string.h> and <strings.h>])
 744         ;;
 745 esac
 746
 747 dnl ----------------------------------------------------------------
 748 dnl Check for module support
 749 ol_link_modules=no
 750 WITH_MODULES_ENABLED=no
 751 if test $ol_enable_modules != no ; then
 752         AC_CHECK_HEADERS(ltdl.h)
 753
 754         if test $ac_cv_header_ltdl_h = no ; then
 755                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 756         fi
 757
 758         AC_CHECK_LIB(ltdl, lt_dlinit, [
 759                 MODULES_LIBS=-lltdl
 760                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 761         ])
 762
 763         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 764                 AC_MSG_ERROR([could not locate libtool -lltdl])
 765         fi
 766         ol_link_modules=yes
 767         WITH_MODULES_ENABLED=yes
 768
 769 else
 770         for i in $Backends; do
 771                 eval "ol_tmp=\$ol_enable_$i"
 772                 if test $ol_tmp = mod ; then
 773                         AC_MSG_WARN([building static $i backend])
 774                         eval "ol_enable_$i=yes"
 775                 fi
 776         done
 777         for i in $Overlays; do
 778                 eval "ol_tmp=\$ol_enable_$i"
 779                 if test $ol_tmp = mod ; then
 780                         AC_MSG_WARN([building static $i overlay])
 781                         eval "ol_enable_$i=yes"
 782                 fi
 783         done
 784 fi
 785
 786 dnl ----------------------------------------------------------------
 787 dnl Checks for header files.
 788 OL_HEADER_STDC
 789
 790 if test $ol_cv_header_stdc != yes; then
 791         AC_MSG_WARN([could not locate Standard C compliant headers])
 792 fi
 793
 794 AC_HEADER_DIRENT
 795 AC_HEADER_SYS_WAIT
 796 AC_HEADER_TIOCGWINSZ
 797
 798 AC_CHECK_HEADERS(       \
 799         arpa/inet.h             \
 800         arpa/nameser.h  \
 801         assert.h                \
 802         bits/types.h    \
 803         conio.h                 \
 804         crypt.h                 \
 805         direct.h                \
 806         errno.h                 \
 807         fcntl.h                 \
 808         filio.h                 \
 809         getopt.h                \
 810         grp.h                   \
 811         io.h                    \
 812         libutil.h               \
 813         limits.h                \
 814         locale.h                \
 815         malloc.h                \
 816         memory.h                \
 817         psap.h                  \
 818         pwd.h                   \
 819         process.h               \
 820         sgtty.h                 \
 821         shadow.h                \
 822         stddef.h                \
 823         string.h                \
 824         strings.h               \
 825         sysexits.h              \
 826         sys/file.h              \
 827         sys/filio.h             \
 828         sys/fstyp.h             \
 829         sys/errno.h             \
 830         sys/ioctl.h             \
 831         sys/param.h             \
 832         sys/privgrp.h   \
 833         sys/resource.h  \
 834         sys/select.h    \
 835         sys/socket.h    \
 836         sys/stat.h              \
 837         sys/syslog.h    \
 838         sys/time.h              \
 839         sys/types.h             \
 840         sys/uio.h               \
 841         sys/vmount.h    \
 842         syslog.h                \
 843         termios.h               \
 844         unistd.h                \
 845         utime.h                 \
 846 )
 847
 848 dnl Only check Winsock on MinGW
 849 if test "$ac_cv_mingw32" = yes \
 850         -o "$ac_cv_interix" = yes \
 851         -o "$ol_cv_msvc" = yes
 852 then
 853         AC_CHECK_HEADERS( winsock.h winsock2.h )
 854 fi
 855
 856 AC_CHECK_HEADERS( resolv.h, [], [],
 857 [$ac_includes_default
 858 #include <netinet/in.h>
 859 ])
 860
 861 AC_CHECK_HEADERS( netinet/tcp.h, [], [],
 862 [$ac_includes_default
 863 #include <netinet/in.h>
 864 ])
 865
 866 AC_CHECK_HEADERS( sys/ucred.h, [], [],
 867 [$ac_includes_default
 868 #ifdef HAVE_SYS_PARAM_H
 869 #include <sys/param.h>
 870 #endif
 871 ])
 872
 873 dnl ----------------------------------------------------------------
 874 dnl Checks for libraries
 875
 876 AC_CHECK_FUNCS( sigaction sigset )
 877
 878 dnl HP-UX requires -lV3
 879 dnl this is not needed on newer versions of HP-UX
 880 if test $ac_cv_func_sigaction = no && test $ac_cv_func_sigaction = no ; then
 881         AC_CHECK_LIB(V3, sigset)
 882 fi
 883
 884 if test $ol_cv_msvc = yes ; then
 885    ol_cv_winsock=yes
 886 fi
 887
 888 dnl The following is INTENTIONALLY scripted out because shell does not
 889 dnl support variable names with the '@' character, which is what
 890 dnl autoconf would try to generate if one merely used AC_SEARCH_LIBS
 891 if test "$ac_cv_header_winsock_h" = yes; then
 892         AC_CACHE_CHECK([for winsock], [ol_cv_winsock],[
 893         save_LIBS="$LIBS"
 894         for curlib in none ws2_32 wsock32; do
 895                 if test $curlib != none ; then
 896                 LIBS="$save_LIBS -l$curlib"
 897                 fi
 898                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <winsock.h>
 899                         ]], [[
 900                         socket(0,0,0);
 901                         select(0,NULL,NULL,NULL,NULL);
 902                         closesocket(0);
 903                         gethostname(NULL,0);
 904                         ]])],[ol_cv_winsock=$curlib],[ol_cv_winsock=no])
 905
 906                 test "$ol_cv_winsock" != no && break
 907         done
 908         LIBS="$save_LIBS"
 909         ])
 910
 911         if test $ol_cv_winsock != no ; then
 912         AC_DEFINE(HAVE_WINSOCK, 1, [define if you have winsock])
 913         ac_cv_func_socket=yes
 914         ac_cv_func_select=yes
 915         ac_cv_func_closesocket=yes
 916         ac_cv_func_gethostname=yes
 917
 918                 if test $ol_cv_winsock != none -a $ol_cv_winsock != yes ; then
 919                 LIBS="$LIBS -l$ol_cv_winsock"
 920                 fi
 921
 922         if test $ol_cv_winsock = ws2_32 -o $ol_cv_winsock = yes ; then
 923                         AC_DEFINE(HAVE_WINSOCK2, 1, [define if you have winsock2])
 924         fi
 925         fi
 926 fi
 927
 928 dnl Find socket()
 929 dnl Likely combinations:
 930 dnl             -lsocket [ -lnsl_s | -lnsl ]
 931 dnl             -linet
 932
 933 AC_CHECK_FUNC(socket, :, [
 934 dnl hopefully we won't include too many libraries
 935         AC_CHECK_LIB(socket, main)
 936         AC_CHECK_LIB(net, main)
 937         AC_CHECK_LIB(nsl_s, main)
 938         AC_CHECK_LIB(nsl, main)
 939         AC_CHECK_LIB(inet, socket)
 940         AC_CHECK_LIB(gen, main)
 941 ])
 942
 943 dnl require select
 944 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 945
 946 if test "${ac_cv_header_winsock_h}" != yes; then
 947         dnl Select arg types
 948         dnl (if this detection becomes permenent, it and the select() detection
 949         dnl should be done before the yielding select test)
 950         AC_FUNC_SELECT_ARGTYPES
 951 fi
 952
 953 dnl check to see if system call automatically restart
 954 dnl AC_SYS_RESTARTABLE_SYSCALLS
 955
 956 dnl ----------------------------------------------------------------
 957 AC_CHECK_FUNCS( poll )
 958 if test $ac_cv_func_poll = yes; then
 959 AC_CHECK_HEADERS( poll.h sys/poll.h )
 960 fi
 961
 962 dnl ----------------------------------------------------------------
 963 AC_CHECK_HEADERS( sys/epoll.h )
 964 if test "${ac_cv_header_sys_epoll_h}" = yes; then
 965         AC_MSG_CHECKING(for epoll system call)
 966         AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv)
 967 {
 968         int epfd = epoll_create(256);
 969         exit (epfd == -1 ? 1 : 0);
 970 }]])],[AC_MSG_RESULT(yes)
 971         AC_DEFINE(HAVE_EPOLL,1, [define if your system supports epoll])],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 972 fi
 973
 974 dnl ----------------------------------------------------------------
 975 AC_CHECK_HEADERS( sys/devpoll.h )
 976 dnl "/dev/poll" needs <sys/poll.h> as well...
 977 if test "${ac_cv_header_sys_devpoll_h}" = yes \
 978                 -a "${ac_cv_header_poll_h}" = yes ; \
 979 then
 980         AC_MSG_CHECKING(for /dev/poll)
 981         AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv)
 982 {
 983         int devpollfd = open("/dev/poll", /* O_RDWR */ 2);
 984         exit (devpollfd == -1 ? 1 : 0);
 985 }]])],[AC_MSG_RESULT(yes)
 986         AC_DEFINE(HAVE_DEVPOLL,1, [define if your system supports /dev/poll])],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 987 fi
 988
 989 dnl ----------------------------------------------------------------
 990 OL_STRERROR
 991
 992 dnl ----------------------------------------------------------------
 993 dnl require POSIX regex
 994 AC_CHECK_HEADERS( regex.h, [], [],
 995 [$ac_includes_default
 996 #ifdef HAVE_SYS_TYPES_H
 997 #include <sys/types.h>
 998 #endif
 999 ])
1000
1001 if test "$ac_cv_header_regex_h" != yes ; then
1002         AC_MSG_ERROR([POSIX regex.h required.])
1003 fi
1004 AC_SEARCH_LIBS(regfree, [regex gnuregex],
1005         :, AC_MSG_ERROR([POSIX regex required.]))
1006
1007 OL_POSIX_REGEX
1008 if test "$ol_cv_c_posix_regex" = no ; then
1009         AC_MSG_ERROR([broken POSIX regex!])
1010 fi
1011
1012 dnl ----------------------------------------------------------------
1013 dnl UUID Support
1014
1015 have_uuid=no
1016 AC_CHECK_HEADERS(sys/uuid.h)
1017 dnl The HAVE_UUID_TO_STR code path also needs uuid_create
1018 if test $ac_cv_header_sys_uuid_h = yes ; then
1019         save_LIBS="$LIBS"
1020         AC_SEARCH_LIBS([uuid_to_str], [uuid], [have_uuid=yes], :)
1021         AC_SEARCH_LIBS([uuid_create], [uuid], :, [have_uuid=no])
1022         LIBS="$save_LIBS"
1023
1024         if test $have_uuid = yes ; then
1025                 AC_DEFINE(HAVE_UUID_TO_STR,1,
1026                         [define if you have uuid_to_str()])
1027
1028                 test "$ac_cv_search_uuid_to_str" = "none required" || \
1029                         SLAPD_LIBS="$SLAPD_LIBS $ac_cv_search_uuid_to_str"
1030         fi
1031 fi
1032
1033 dnl Look for uuid_generate
1034 dnl The HAVE_UUID_GENERATE code path also needs uuid_unparse_lower
1035 if test $have_uuid = no ; then
1036         AC_CHECK_HEADERS(uuid/uuid.h)
1037         if test $ac_cv_header_uuid_uuid_h = yes ; then
1038                 save_LIBS="$LIBS"
1039                 AC_SEARCH_LIBS([uuid_generate], [uuid], [have_uuid=yes], :)
1040                 AC_SEARCH_LIBS([uuid_unparse_lower], [uuid], :, [have_uuid=no])
1041                 LIBS="$save_LIBS"
1042
1043                 if test $have_uuid = yes ; then
1044                         AC_DEFINE(HAVE_UUID_GENERATE,1,
1045                                 [define if you have uuid_generate()])
1046
1047                         test "$ac_cv_search_uuid_generate" = "none required" || \
1048                                 SLAPD_LIBS="$SLAPD_LIBS $ac_cv_search_uuid_generate"
1049                 fi
1050         fi
1051 fi
1052
1053 dnl For windows, check for the need of RPCRT for UUID function support
1054 if test $have_uuid = no ; then
1055         AC_MSG_CHECKING(to see if -lrpcrt4 is needed for win32 UUID support)
1056         save_LIBS="$LIBS"
1057         LIBS="$LIBS -lrpcrt4"
1058         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1059                 int __stdcall UuidCreate(void *);
1060                 int __stdcall UuidToStringA(void *,void **);
1061                 ]], [[
1062                 UuidCreate(0);
1063                 UuidToStringA(0,0);
1064                 ]])],[need_rpcrt=yes],[need_rpcrt=no])
1065         if test $need_rpcrt = yes; then
1066                 SLAPD_LIBS="$SLAPD_LIBS -lrpcrt4"
1067         fi
1068         LIBS="$save_LIBS"
1069         AC_MSG_RESULT($need_rpcrt)
1070 fi
1071
1072 dnl ----------------------------------------------------------------
1073 dnl Check for resolver routines
1074 OL_RESOLVER_LINK
1075
1076 ol_link_dnssrv=no
1077 if test "$ol_cv_lib_resolver" != no ; then
1078         AC_DEFINE(HAVE_RES_QUERY,1,
1079                 [define if you have res_query()])
1080
1081         if test "$ol_enable_dnssrv" != no ; then
1082                 ol_link_dnssrv=yes
1083         fi
1084
1085         if test "$ol_cv_lib_resolver" != yes ; then
1086                 LIBS="$ol_cv_lib_resolver $LIBS"
1087         fi
1088 fi
1089
1090 if test "$ol_enable_dnssrv" = yes || test "$ol_enable_dnssrv" = mod ; then
1091         if test "$ol_link_dnssrv" = no ; then
1092                 AC_MSG_ERROR([DNSSRV requires res_query()])
1093         fi
1094 else
1095         ol_enable_dnssrv=no
1096 fi
1097
1098 AC_CHECK_FUNCS( hstrerror )
1099
1100 dnl ----------------------------------------------------------------
1101 dnl PF_INET6 support requires getaddrinfo and INET6_ADDRSTRLEN
1102 dnl PF_LOCAL may use getaddrinfo in available
1103 AC_CHECK_FUNCS( getaddrinfo getnameinfo gai_strerror inet_ntop )
1104
1105 ol_link_ipv6=no
1106 if test $ac_cv_func_getaddrinfo = no || test $ac_cv_func_inet_ntop = no ; then
1107         if test $ol_enable_ipv6 = yes ; then
1108                 AC_MSG_ERROR([IPv6 support requires getaddrinfo() and inet_ntop()])
1109         fi
1110 elif test $ol_enable_ipv6 != no ; then
1111         AC_CACHE_CHECK([INET6_ADDRSTRLEN],[ol_cv_inet6_addrstrlen],[
1112                 AC_EGREP_CPP(__has_inet6_addrstrlen__,[
1113 #                       include <netinet/in.h>
1114 #                       ifdef INET6_ADDRSTRLEN
1115                                 __has_inet6_addrstrlen__;
1116 #                       endif
1117                 ], [ol_cv_inet6_addrstrlen=yes], [ol_cv_inet6_addrstrlen=no])])
1118
1119
1120         AC_CACHE_CHECK([struct sockaddr_storage],ol_cv_struct_sockaddr_storage,[
1121                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1122 #include <sys/types.h>
1123 #include <sys/socket.h>
1124 ]], [[
1125                         struct sockaddr_storage ss;
1126 ]])],[ol_cv_struct_sockaddr_storage=yes],[ol_cv_struct_sockaddr_storage=no])])
1127
1128         if test $ol_cv_inet6_addrstrlen = yes &&
1129            test $ol_cv_struct_sockaddr_storage = yes ; then
1130                 ol_link_ipv6=yes
1131         elif test $ol_enable_ipv6 = yes &&
1132              test $ol_cv_inet6_addrstrlen = no ; then
1133                 AC_MSG_ERROR([IPv6 support requires INET6_ADDRSTRLEN])
1134         elif test $ol_enable_ipv6 = yes &&
1135              test $ol_cv_struct_sockaddr_storage = no ; then
1136                 AC_MSG_ERROR([IPv6 support requires struct sockaddr_storage])
1137         fi
1138 fi
1139
1140 if test $ol_enable_local != no ; then
1141         AC_CHECK_HEADERS( sys/un.h )
1142
1143         if test $ol_enable_local = auto ; then
1144                 ol_enable_local=$ac_cv_header_sys_un_h
1145         elif test $ac_cv_header_sys_un_h = no ; then
1146                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
1147         fi
1148 fi
1149
1150 dnl ----------------------------------------------------------------
1151 dnl TLS/SSL
1152
1153 if test $ol_with_tls = yes ; then
1154         ol_with_tls=auto
1155 fi
1156
1157 ol_link_tls=no
1158 if test $ol_with_tls = openssl || test $ol_with_tls = auto ; then
1159         AC_CHECK_HEADERS(openssl/ssl.h)
1160
1161         if test $ac_cv_header_openssl_ssl_h = yes ; then
1162                 AC_CHECK_LIB(ssl, SSL_library_init,
1163                         [have_openssl=yes
1164                         need_rsaref=no], [have_openssl=no],
1165                         [-lcrypto])
1166
1167                 if test $have_openssl = no ; then
1168                         AC_CHECK_LIB(ssl, ssl3_accept,
1169                                 [have_openssl=yes
1170                                 need_rsaref=yes], [have_openssl=no],
1171                                 [-lcrypto -lRSAglue -lrsaref])
1172                 fi
1173
1174                 if test $have_openssl = yes ; then
1175                         ol_with_tls=openssl
1176                         ol_link_tls=yes
1177
1178                         AC_DEFINE(HAVE_OPENSSL, 1,
1179                                 [define if you have OpenSSL])
1180
1181                         if test $need_rsaref = yes; then
1182                                 AC_DEFINE(HAVE_RSAREF, 1,
1183                                         [define if OpenSSL needs RSAref])
1184
1185                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1186                         else
1187                                 TLS_LIBS="-lssl -lcrypto"
1188                         fi
1189
1190                         OL_SSL_COMPAT
1191                         if test $ol_cv_ssl_crl_compat = yes ; then
1192                                 AC_DEFINE(HAVE_OPENSSL_CRL, 1,
1193                                         [define if you have OpenSSL with CRL checking capability])
1194                         fi
1195                 fi
1196         fi
1197 fi
1198
1199 if test $ol_link_tls = no ; then
1200         if test $ol_with_tls = gnutls || test $ol_with_tls = auto ; then
1201                 AC_CHECK_HEADERS(gnutls/gnutls.h)
1202
1203                 if test $ac_cv_header_gnutls_gnutls_h = yes ; then
1204                         AC_CHECK_LIB(gnutls, gnutls_init,
1205                                 [have_gnutls=yes], [have_gnutls=no])
1206
1207                         if test $have_gnutls = yes ; then
1208                                 ol_with_tls=gnutls
1209                                 ol_link_tls=yes
1210
1211                                 TLS_LIBS="-lgnutls"
1212
1213                                 AC_DEFINE(HAVE_GNUTLS, 1,
1214                                         [define if you have GNUtls])
1215                         fi
1216                 fi
1217         fi
1218 fi
1219
1220 dnl NOTE: caller must specify -I/path/to/nspr4 and -I/path/to/nss3
1221 dnl and -L/path/to/nspr4 libs and -L/path/to/nss3 libs if those libs
1222 dnl are not in the default system location
1223 if test $ol_link_tls = no ; then
1224         if test $ol_with_tls = moznss || test $ol_with_tls = auto ; then
1225                 have_moznss=no
1226                 AC_CHECK_HEADERS([nssutil.h])
1227                 if test "$ac_cv_header_nssutil_h" = yes ; then
1228                         AC_CHECK_LIB([nss3], [NSS_Initialize],
1229                                                  [ have_moznss=yes ], [ have_moznss=no ])
1230                 fi
1231
1232                 if test "$have_moznss" = yes ; then
1233                         ol_with_tls=moznss
1234                         ol_link_tls=yes
1235                         AC_DEFINE(HAVE_MOZNSS, 1,
1236                                           [define if you have MozNSS])
1237                         TLS_LIBS="-lssl3 -lsmime3 -lnss3 -lnssutil3 -lplds4 -lplc4 -lnspr4"
1238                 else
1239                         AC_MSG_ERROR([MozNSS not found - please specify the location to the NSPR and NSS header files in CPPFLAGS and the location to the NSPR and NSS libraries in LDFLAGS (if not in the system location)])
1240                 fi
1241         fi
1242 fi
1243
1244 WITH_TLS=no
1245 if test $ol_link_tls = yes ; then
1246         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1247         WITH_TLS=yes
1248 elif test $ol_with_tls = auto ; then
1249         AC_MSG_WARN([Could not locate TLS/SSL package])
1250         AC_MSG_WARN([TLS data protection not supported!])
1251 elif test $ol_with_tls != no ; then
1252         AC_MSG_ERROR([Could not locate TLS/SSL package])
1253 else
1254         AC_MSG_WARN([TLS data protection not supported!])
1255 fi
1256
1257 dnl ----------------------------------------------------------------
1258 dnl LAN Manger password checking requires DES from OpenSSL
1259 if test $ol_enable_lmpasswd != no; then
1260         if test $ol_link_tls != yes ; then
1261                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
1262         fi
1263
1264         AC_DEFINE(SLAPD_LMHASH, 1, [define to support LAN Manager passwords])
1265 fi
1266
1267 dnl ----------------------------------------------------------------
1268 dnl Threads?
1269 ol_link_threads=no
1270
1271 case $ol_with_threads in auto | yes | nt)
1272
1273         OL_NT_THREADS
1274
1275         if test "$ol_cv_nt_threads" = yes ; then
1276                 ol_link_threads=nt
1277                 ol_with_threads=found
1278                 ol_with_yielding_select=yes
1279
1280                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1281                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1282         fi
1283
1284         if test $ol_with_threads = nt ; then
1285                 AC_MSG_ERROR([could not locate NT Threads])
1286         fi
1287         ;;
1288 esac
1289
1290 case $ol_with_threads in auto | yes | posix)
1291
1292         AC_CHECK_HEADERS(pthread.h)
1293
1294         if test $ac_cv_header_pthread_h = yes ; then
1295                 OL_POSIX_THREAD_VERSION
1296
1297                 if test $ol_cv_pthread_version != 0 ; then
1298                         AC_DEFINE_UNQUOTED(HAVE_PTHREADS,$ol_cv_pthread_version,
1299                                 [define to pthreads API spec revision])
1300                 else
1301                         AC_MSG_ERROR([unknown pthread version])
1302                 fi
1303
1304                 # consider threads found
1305                 ol_with_threads=found
1306
1307                 OL_HEADER_LINUX_THREADS
1308                 OL_HEADER_GNU_PTH_PTHREAD_H
1309
1310                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1311                         AC_CHECK_HEADERS(sched.h)
1312                 fi
1313
1314                 dnl Now the hard part, how to link?
1315                 dnl
1316                 dnl currently supported checks:
1317                 dnl
1318                 dnl Check for no flags
1319                 dnl     pthread_create() in $LIBS
1320                 dnl
1321                 dnl Check special pthread (final) flags
1322                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1323                 dnl     pthread_create() with -kthread (FreeBSD)
1324                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1325                 dnl     pthread_create() with -pthreads (?)
1326                 dnl     pthread_create() with -mthreads (AIX)
1327                 dnl     pthread_create() with -thread (?)
1328                 dnl
1329                 dnl Check pthread (final) libraries
1330                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1331                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1332                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1333                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1334                 dnl     pthread_create() in -lpthread (many)
1335                 dnl     pthread_create() in -lc_r (FreeBSD)
1336                 dnl
1337                 dnl Check pthread (draft4) flags (depreciated)
1338                 dnl     pthread_create() with -threads (OSF/1)
1339                 dnl
1340                 dnl Check pthread (draft4) libraries (depreciated)
1341                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1342                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1343                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1344                 dnl     pthread_create() in -lpthreads (many)
1345                 dnl
1346
1347                 dnl pthread_create in $LIBS
1348                 AC_CACHE_CHECK([for pthread_create in default libraries],
1349                         ol_cv_pthread_create,[
1350                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1351                                 [ol_cv_pthread_create=yes],
1352                                 [ol_cv_pthread_create=no],
1353                                 [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1354                                         [ol_cv_pthread_create=yes],
1355                                         [ol_cv_pthread_create=no])])])
1356
1357                 if test $ol_cv_pthread_create != no ; then
1358                         ol_link_threads=posix
1359                         ol_link_pthreads=""
1360                 fi
1361
1362 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1363                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1364                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1365                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1366                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1367                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1368
1369                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1370                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1371                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1372                         [ol_cv_pthread_lpthread_lmach_lexc])
1373 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1374 dnl                     [ol_cv_pthread_lpthread_lexc])
1375
1376                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1377                         [ol_cv_pthread_lib_lpthread_woff])
1378
1379                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1380                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1381
1382                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1383
1384                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1385                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1386                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1387                         [ol_cv_pthread_lpthreads_lmach_lexc])
1388                 OL_PTHREAD_TRY([-lpthreads -lexc],
1389                         [ol_cv_pthread_lpthreads_lexc])
1390
1391                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1392
1393                 if test $ol_link_threads != no ; then
1394                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1395
1396                         dnl save flags
1397                         save_CPPFLAGS="$CPPFLAGS"
1398                         save_LIBS="$LIBS"
1399                         LIBS="$LTHREAD_LIBS $LIBS"
1400
1401                         dnl All POSIX Thread (final) implementations should have
1402                         dnl sched_yield instead of pthread yield.
1403                         dnl check for both, and thr_yield for Solaris
1404                         AC_CHECK_FUNCS(sched_yield pthread_yield thr_yield)
1405
1406                         if test $ac_cv_func_sched_yield = no &&
1407                            test $ac_cv_func_pthread_yield = no &&
1408                            test $ac_cv_func_thr_yield = no ; then
1409                                 dnl Digital UNIX has sched_yield() in -lrt
1410                                 AC_CHECK_LIB(rt, sched_yield,
1411                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1412                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1413                                                 [Define if you have the sched_yield function.])
1414                                         ac_cv_func_sched_yield=yes],
1415                                         [ac_cv_func_sched_yield=no])
1416                         fi
1417                         if test $ac_cv_func_sched_yield = no &&
1418                            test $ac_cv_func_pthread_yield = no &&
1419                            test "$ac_cv_func_thr_yield" = no ; then
1420                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1421                         fi
1422
1423                         dnl Check functions for compatibility
1424                         AC_CHECK_FUNCS(pthread_kill)
1425
1426                         dnl Check for pthread_rwlock_destroy with <pthread.h>
1427                         dnl as pthread_rwlock_t may not be defined.
1428                         AC_CACHE_CHECK([for pthread_rwlock_destroy with <pthread.h>],
1429                                 [ol_cv_func_pthread_rwlock_destroy], [
1430                                 dnl save the flags
1431                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1432 #include <pthread.h>
1433 pthread_rwlock_t rwlock;
1434 ]], [[pthread_rwlock_destroy(&rwlock);]])],[ol_cv_func_pthread_rwlock_destroy=yes],[ol_cv_func_pthread_rwlock_destroy=no])
1435                         ])
1436                         if test $ol_cv_func_pthread_rwlock_destroy = yes ; then
1437                                 AC_DEFINE(HAVE_PTHREAD_RWLOCK_DESTROY,1,
1438                                         [define if you have pthread_rwlock_destroy function])
1439                         fi
1440
1441                         dnl Check for pthread_detach with <pthread.h> inclusion
1442                         dnl as it's symbol may have been mangled.
1443                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1444                                 [ol_cv_func_pthread_detach], [
1445                                 dnl save the flags
1446                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1447 #include <pthread.h>
1448 #ifndef NULL
1449 #define NULL (void*)0
1450 #endif
1451 ]], [[pthread_detach(NULL);]])],[ol_cv_func_pthread_detach=yes],[ol_cv_func_pthread_detach=no])
1452                         ])
1453
1454                         if test $ol_cv_func_pthread_detach = no ; then
1455                                 AC_MSG_ERROR([could not locate pthread_detach()])
1456                         fi
1457
1458                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1459                                 [define if you have pthread_detach function])
1460
1461                         dnl Check for setconcurreny functions
1462                         AC_CHECK_FUNCS( \
1463                                 pthread_setconcurrency \
1464                                 pthread_getconcurrency \
1465                                 thr_setconcurrency \
1466                                 thr_getconcurrency \
1467                         )
1468
1469                         OL_SYS_LINUX_THREADS
1470                         OL_LINUX_THREADS
1471
1472                         if test $ol_cv_linux_threads = error; then
1473                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1474                         fi
1475
1476                         AC_CACHE_CHECK([if pthread_create() works],
1477                                 ol_cv_pthread_create_works,[
1478                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1479                                 [ol_cv_pthread_create_works=yes],
1480                                 [ol_cv_pthread_create_works=no],
1481                                 [dnl assume yes
1482                                 ol_cv_pthread_create_works=yes])])
1483
1484                         if test $ol_cv_pthread_create_works = no ; then
1485                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1486                         fi
1487
1488                         ol_replace_broken_yield=no
1489 dnl                     case "$target" in
1490 dnl                     *-*-linux*)
1491 dnl                             AC_CHECK_FUNCS(nanosleep)
1492 dnl                             ol_replace_broken_yield=yes
1493 dnl                     ;;
1494 dnl                     esac
1495
1496                         if test $ol_replace_broken_yield = yes ; then
1497                                 AC_DEFINE([REPLACE_BROKEN_YIELD],1,
1498                                         [define if sched_yield yields the entire process])
1499                         fi
1500
1501                         dnl Check if select causes an yield
1502                         if test $ol_with_yielding_select = auto ; then
1503                                 AC_CACHE_CHECK([if select yields when using pthreads],
1504                                         ol_cv_pthread_select_yields,[
1505                                 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1506 #include <sys/types.h>
1507 #include <sys/time.h>
1508 #include <unistd.h>
1509 #include <pthread.h>
1510 #ifndef NULL
1511 #define NULL (void*) 0
1512 #endif
1513
1514 static int fildes[2];
1515
1516 static void *task(p)
1517         void *p;
1518 {
1519         int i;
1520         struct timeval tv;
1521
1522         fd_set rfds;
1523
1524         tv.tv_sec=10;
1525         tv.tv_usec=0;
1526
1527         FD_ZERO(&rfds);
1528         FD_SET(fildes[0], &rfds);
1529
1530         /* we're not interested in any fds */
1531         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1532
1533         if(i < 0) {
1534                 perror("select");
1535                 exit(10);
1536         }
1537
1538         exit(0); /* if we exit here, the select blocked the whole process */
1539 }
1540
1541 int main(argc, argv)
1542         int argc;
1543         char **argv;
1544 {
1545         pthread_t t;
1546
1547         /* create a pipe to select */
1548         if(pipe(&fildes[0])) {
1549                 perror("select");
1550                 exit(1);
1551         }
1552
1553 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1554         (void) pthread_setconcurrency(2);
1555 #else
1556 #ifdef HAVE_THR_SETCONCURRENCY
1557         /* Set Solaris LWP concurrency to 2 */
1558         thr_setconcurrency(2);
1559 #endif
1560 #endif
1561
1562 #if HAVE_PTHREADS < 6
1563         pthread_create(&t, pthread_attr_default, task, NULL);
1564 #else
1565         pthread_create(&t, NULL, task, NULL);
1566 #endif
1567
1568         /* make sure task runs first */
1569 #ifdef HAVE_THR_YIELD
1570         thr_yield();
1571 #elif defined( HAVE_SCHED_YIELD )
1572         sched_yield();
1573 #elif defined( HAVE_PTHREAD_YIELD )
1574         pthread_yield();
1575 #endif
1576
1577         exit(2);
1578 }]])],[ol_cv_pthread_select_yields=no],[ol_cv_pthread_select_yields=yes],[ol_cv_pthread_select_yields=cross])])
1579
1580                                 if test $ol_cv_pthread_select_yields = cross ; then
1581                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1582                                 fi
1583
1584                                 if test $ol_cv_pthread_select_yields = yes ; then
1585                                         ol_with_yielding_select=yes
1586                                 fi
1587                         fi
1588
1589                         dnl restore flags
1590                         CPPFLAGS="$save_CPPFLAGS"
1591                         LIBS="$save_LIBS"
1592                 else
1593                         AC_MSG_ERROR([could not locate usable POSIX Threads])
1594                 fi
1595         fi
1596
1597         if test $ol_with_threads = posix ; then
1598                 AC_MSG_ERROR([could not locate POSIX Threads])
1599         fi
1600         ;;
1601 esac
1602
1603 case $ol_with_threads in auto | yes | mach)
1604
1605         dnl check for Mach CThreads
1606         AC_CHECK_HEADERS(mach/cthreads.h cthreads.h)
1607         if test $ac_cv_header_mach_cthreads_h = yes ; then
1608                 ol_with_threads=found
1609
1610                 dnl check for cthreads support in current $LIBS
1611                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1612
1613                 if test $ol_link_threads = no ; then
1614                         dnl try -all_load
1615                         dnl this test needs work
1616                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1617                                 [ol_cv_cthread_all_load], [
1618                                 dnl save the flags
1619                                 save_LIBS="$LIBS"
1620                                 LIBS="-all_load $LIBS"
1621                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <mach/cthreads.h>]], [[
1622                                         cthread_fork((void *)0, (void *)0);
1623                                         ]])],[ol_cv_cthread_all_load=yes],[ol_cv_cthread_all_load=no])
1624                                 dnl restore the LIBS
1625                                 LIBS="$save_LIBS"
1626                         ])
1627
1628                         if test $ol_cv_cthread_all_load = yes ; then
1629                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1630                                 ol_link_threads=mach
1631                                 ol_with_threads=found
1632                         fi
1633                 fi
1634
1635         elif test $ac_cv_header_cthreads_h = yes ; then
1636                 dnl Hurd variant of Mach Cthreads
1637                 dnl uses <cthreads.h> and -lthreads
1638
1639                 ol_with_threads=found
1640
1641                 dnl save the flags
1642                 save_LIBS="$LIBS"
1643                 LIBS="$LIBS -lthreads"
1644                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1645                 LIBS="$save_LIBS"
1646
1647                 if test $ol_link_threads = yes ; then
1648                         LTHREAD_LIBS="-lthreads"
1649                         ol_link_threads=mach
1650                         ol_with_threads=found
1651                 else
1652                         AC_MSG_ERROR([could not link with Mach CThreads])
1653                 fi
1654
1655         elif test $ol_with_threads = mach ; then
1656                 AC_MSG_ERROR([could not locate Mach CThreads])
1657         fi
1658
1659         if test $ol_link_threads = mach ; then
1660                 AC_DEFINE(HAVE_MACH_CTHREADS,1,
1661                         [define if you have Mach Cthreads])
1662         elif test $ol_with_threads = found ; then
1663                 AC_MSG_ERROR([could not link with Mach CThreads])
1664         fi
1665         ;;
1666 esac
1667
1668 case $ol_with_threads in auto | yes | pth)
1669
1670         AC_CHECK_HEADERS(pth.h)
1671
1672         if test $ac_cv_header_pth_h = yes ; then
1673                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1674
1675                 if test $have_pth = yes ; then
1676                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1677                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1678                         ol_link_threads=pth
1679                         ol_with_threads=found
1680
1681                         if test $ol_with_yielding_select = auto ; then
1682                                 ol_with_yielding_select=yes
1683                         fi
1684                 fi
1685         fi
1686         ;;
1687 esac
1688
1689 case $ol_with_threads in auto | yes | lwp)
1690
1691         dnl check for SunOS5 LWP
1692         AC_CHECK_HEADERS(thread.h synch.h)
1693         if test $ac_cv_header_thread_h = yes &&
1694            test $ac_cv_header_synch_h = yes ; then
1695                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1696
1697                 if test $have_thr = yes ; then
1698                         AC_DEFINE(HAVE_THR,1,
1699                                 [if you have Solaris LWP (thr) package])
1700                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1701                         ol_link_threads=thr
1702
1703                         if test $ol_with_yielding_select = auto ; then
1704                                 ol_with_yielding_select=yes
1705                         fi
1706
1707                         dnl Check for setconcurreny functions
1708                         AC_CHECK_FUNCS( \
1709                                 thr_setconcurrency \
1710                                 thr_getconcurrency \
1711                         )
1712                 fi
1713         fi
1714         ;;
1715 esac
1716
1717 if test $ol_with_yielding_select = yes ; then
1718         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1719                 [define if select implicitly yields])
1720 fi
1721
1722 if test $ol_with_threads = manual ; then
1723         dnl User thinks he can manually configure threads.
1724         ol_link_threads=yes
1725
1726         AC_MSG_WARN([thread defines and link options must be set manually])
1727
1728         AC_CHECK_HEADERS(pthread.h sched.h)
1729         AC_CHECK_FUNCS(sched_yield pthread_yield)
1730         OL_HEADER_LINUX_THREADS
1731
1732         AC_CHECK_HEADERS(mach/cthreads.h)
1733         AC_CHECK_HEADERS(thread.h synch.h)
1734 fi
1735
1736 if test $ol_link_threads != no && test $ol_link_threads != nt ; then
1737         dnl needed to get reentrant/threadsafe versions
1738         dnl
1739         AC_DEFINE(REENTRANT,1)
1740         AC_DEFINE(_REENTRANT,1)
1741         AC_DEFINE(THREAD_SAFE,1)
1742         AC_DEFINE(_THREAD_SAFE,1)
1743         AC_DEFINE(THREADSAFE,1)
1744         AC_DEFINE(_THREADSAFE,1)
1745         AC_DEFINE(_SGI_MP_SOURCE,1)
1746
1747         dnl The errno declaration may dependent upon _REENTRANT.
1748         dnl If it does, we must link with thread support.
1749         AC_CACHE_CHECK([for thread specific errno],
1750                 [ol_cv_errno_thread_specific], [
1751                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[errno = 0;]])],[ol_cv_errno_thread_specific=yes],[ol_cv_errno_thread_specific=no])
1752         ])
1753
1754         dnl The h_errno declaration may dependent upon _REENTRANT.
1755         dnl If it does, we must link with thread support.
1756         AC_CACHE_CHECK([for thread specific h_errno],
1757                 [ol_cv_h_errno_thread_specific], [
1758                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[h_errno = 0;]])],[ol_cv_h_errno_thread_specific=yes],[ol_cv_h_errno_thread_specific=no])
1759         ])
1760
1761         if test $ol_cv_errno_thread_specific != yes ||
1762            test $ol_cv_h_errno_thread_specific != yes ; then
1763                 LIBS="$LTHREAD_LIBS $LIBS"
1764                 LTHREAD_LIBS=""
1765         fi
1766
1767 dnl When in thread environment, use
1768 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) || defined( HAVE_FUNC_R )
1769 dnl                     func_r(...);
1770 dnl             #else
1771 dnl             #       if defined( HAVE_THREADS )
1772 dnl                             /* lock */
1773 dnl             #       endif
1774 dnl                             func(...);
1775 dnl             #       if defined( HAVE_THREADS )
1776 dnl                             /* unlock */
1777 dnl             #       endif
1778 dnl             #endif
1779 dnl
1780 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1781 dnl             _POSIX_REENTRANT_FUNCTIONS
1782 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1783 dnl             _POSIX_THREADSAFE_FUNCTIONS
1784 dnl
1785 dnl             and is currently defined in <ldap_pvt_thread.h>
1786 dnl
1787 dnl HAVE_THREADS is defined by <ldap_pvt_thread.h> iff -UNO_THREADS
1788 dnl
1789 dnl libldap/*.c should only include <ldap_pvt_thread.h> iff
1790 dnl LDAP_R_COMPILE is defined.  ie:
1791 dnl             #ifdef LDAP_R_COMPILE
1792 dnl             #       include <ldap_pvt_thread.h>
1793 dnl             #endif
1794 dnl
1795 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1796 dnl specifically for compiling the threadsafe version of
1797 dnl     the ldap library (-lldap_r).
1798 dnl
1799 dnl     dnl check for reentrant/threadsafe functions
1800 dnl     dnl
1801 dnl     dnl note: these should only be used when linking
1802 dnl     dnl             with $LTHREAD_LIBS
1803 dnl     dnl
1804 dnl     save_CPPFLAGS="$CPPFLAGS"
1805 dnl     save_LIBS="$LIBS"
1806 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1807 dnl     AC_CHECK_FUNCS( \
1808 dnl             gmtime_r \
1809 dnl             gethostbyaddr_r gethostbyname_r \
1810 dnl             feof_unlocked unlocked_feof \
1811 dnl             putc_unlocked unlocked_putc \
1812 dnl             flockfile ftrylockfile \
1813 dnl     )
1814 dnl     CPPFLAGS="$save_CPPFLAGS"
1815 dnl     LIBS="$save_LIBS"
1816 fi
1817
1818 if test $ol_link_threads = no ; then
1819         if test $ol_with_threads = yes ; then
1820                 AC_MSG_ERROR([no suitable thread support])
1821         fi
1822
1823         if test $ol_with_threads = auto ; then
1824                 AC_MSG_WARN([no suitable thread support, disabling threads])
1825                 ol_with_threads=no
1826         fi
1827
1828         AC_DEFINE(NO_THREADS,1,
1829                 [define if you have (or want) no threads])
1830         LTHREAD_LIBS=""
1831         BUILD_THREAD=no
1832 else
1833         BUILD_THREAD=yes
1834 fi
1835
1836 if test $ol_link_threads != no ; then
1837         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1,
1838                 [define to 1 if library is thread safe])
1839 fi
1840
1841 dnl ----------------------------------------------------------------
1842 dnl Tests for reentrant functions necessary to build -lldap_r
1843 AC_CHECK_FUNCS(         \
1844         ctime_r                 \
1845         gmtime_r localtime_r \
1846         gethostbyname_r gethostbyaddr_r \
1847 )
1848
1849 if test "$ac_cv_func_ctime_r" = no ; then
1850         ol_cv_func_ctime_r_nargs=0
1851 else
1852         OL_FUNC_CTIME_R_NARGS
1853 dnl     OL_FUNC_CTIME_R_TYPE
1854 fi
1855
1856 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1857         OL_FUNC_GETHOSTBYNAME_R_NARGS
1858 else
1859         ol_cv_func_gethostbyname_r_nargs=0
1860 fi
1861
1862 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1863         OL_FUNC_GETHOSTBYADDR_R_NARGS
1864 else
1865         ol_cv_func_gethostbyaddr_r_nargs=0
1866 fi
1867
1868 dnl ----------------------------------------------------------------
1869 ol_link_bdb=no
1870
1871 if test $ol_enable_bdb/$ol_enable_hdb != no/no; then
1872         OL_BERKELEY_DB
1873
1874         if test $ol_cv_berkeley_db = no ; then
1875                 AC_MSG_ERROR(BDB/HDB: BerkeleyDB not available)
1876         fi
1877
1878         AC_DEFINE(HAVE_BERKELEY_DB,1,
1879                 [define this if Berkeley DB is available])
1880
1881         dnl $ol_cv_lib_db should be yes or -ldb
1882         dnl (it could be no, but that would be an error
1883         if test $ol_cv_lib_db != yes ; then
1884                 BDB_LIBS="$BDB_LIBS $ol_cv_lib_db"
1885         fi
1886
1887         SLAPD_LIBS="$SLAPD_LIBS \$(BDB_LIBS)"
1888
1889         ol_link_bdb=yes
1890 fi
1891
1892 dnl ----------------------------------------------------------------
1893
1894 if test $ol_enable_dynamic = yes && test $enable_shared = yes ; then
1895         BUILD_LIBS_DYNAMIC=shared
1896         AC_DEFINE(LDAP_LIBS_DYNAMIC, 1, [define if LDAP libs are dynamic])
1897         LTSTATIC=""
1898 else
1899         BUILD_LIBS_DYNAMIC=static
1900         LTSTATIC="-static"
1901 fi
1902 AC_SUBST(LTSTATIC)dnl
1903
1904 dnl ----------------------------------------------------------------
1905 if test $ol_enable_wrappers != no ; then
1906         AC_CHECK_HEADERS(tcpd.h,[
1907                 AC_MSG_CHECKING([for TCP wrappers library])
1908                 save_LIBS="$LIBS"
1909                 LIBS="$LIBS -lwrap"
1910                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1911 #include <tcpd.h>
1912 int allow_severity = 0;
1913 int deny_severity  = 0;
1914
1915 struct request_info *req;
1916                 ]], [[
1917 hosts_access(req)
1918                 ]])],[AC_MSG_RESULT([-lwrap])
1919                 have_wrappers=yes
1920                 LIBS="$save_LIBS"],[
1921                 dnl try with -lnsl
1922                 LIBS="$LIBS -lnsl"
1923                 AC_TRY_LINK([
1924 #include <tcpd.h>
1925 int allow_severity = 0;
1926 int deny_severity  = 0;
1927
1928 struct request_info *req;
1929                 ],[
1930 hosts_access(req)
1931                 ],[AC_MSG_RESULT([-lwrap -lnsl])
1932                 have_wrappers=yes
1933                 LIBS="$save_LIBS -lnsl"],[
1934                 AC_MSG_RESULT(no)
1935                 have_wrappers=no
1936                 LIBS=$save_LIBS])])],[have_wrappers=no])
1937
1938         if test $have_wrappers = yes ; then
1939                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1940                 WRAP_LIBS="-lwrap"
1941         elif test $ol_enable_wrappers = yes ; then
1942                 AC_MSG_ERROR([could not find TCP wrappers, select apppropriate options or disable])
1943         else
1944                 AC_MSG_WARN([could not find TCP wrappers, support disabled])
1945                 WRAP_LIBS=""
1946         fi
1947 fi
1948
1949 dnl ----------------------------------------------------------------
1950 if test $ol_enable_syslog != no ; then
1951         AC_CHECK_FUNC(openlog)
1952         if test $ac_cv_func_openlog = no && test $ol_enable_syslog = yes; then
1953                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1954         fi
1955         ol_enable_syslog=$ac_cv_func_openlog
1956 fi
1957
1958 dnl ----------------------------------------------------------------
1959 dnl SQL
1960 ol_link_sql=no
1961 if test $ol_enable_sql != no ; then
1962         AC_CHECK_HEADERS(sql.h sqlext.h,[],[
1963                 AC_MSG_ERROR([could not locate SQL headers])
1964         ])
1965
1966         sql_LIBS="$LIBS"
1967         LIBS="$LTHREAD_LIBS"
1968
1969         if test $ol_with_odbc = auto ; then
1970                 ol_with_odbc="iodbc unixodbc odbc32"
1971         fi
1972
1973         for odbc in $ol_with_odbc ; do
1974                 if test $ol_link_sql = no ; then
1975                         case $odbc in
1976                         iodbc)
1977                                 AC_CHECK_LIB(iodbc, SQLDriverConnect, [have_iodbc=yes], [have_iodbc=no])
1978                                 if test $have_iodbc = yes ; then
1979                                         ol_link_sql="-liodbc"
1980                                 fi
1981                                 ;;
1982
1983                         unixodbc)
1984                                 AC_CHECK_LIB(odbc, SQLDriverConnect, [have_odbc=yes], [have_odbc=no])
1985                                 if test $have_odbc = yes ; then
1986                                         ol_link_sql="-lodbc"
1987                                 fi
1988                                 ;;
1989
1990                         odbc32)
1991                                 AC_CHECK_LIB(odbc32, SQLDriverConnect, [have_odbc32=yes], [have_odbc32=no])
1992                                 if test $have_odbc32 = yes ; then
1993                                         ol_link_sql="-lodbc32"
1994                                 fi
1995                                 ;;
1996
1997                         *)
1998                                 AC_MSG_ERROR([unknown ODBC library])
1999                                 ;;
2000                         esac
2001                 fi
2002         done
2003
2004         LIBS="$sql_LIBS"
2005
2006         if test $ol_link_sql != no ; then
2007                 SLAPD_SQL_LIBS="$ol_link_sql"
2008
2009         elif test $ol_enable_sql != auto ; then
2010                 AC_MSG_ERROR([could not locate suitable ODBC library])
2011         fi
2012 fi
2013
2014 dnl ----------------------------------------------------------------
2015 dnl MySQL NDBapi
2016 dnl Note: uses C++, but we don't want to add C++ test overhead to
2017 dnl the rest of the libtool machinery.
2018 ol_link_ndb=no
2019 if test $ol_enable_ndb != no ; then
2020         AC_CHECK_PROG(MYSQL,mysql_config,yes)
2021         if test "$MYSQL" != yes ; then
2022                 AC_MSG_ERROR([could not locate mysql_config])
2023         fi
2024
2025         SQL_INC=`mysql_config --include`
2026         SLAPD_NDB_INCS="$SQL_INC $SQL_INC/storage/ndb $SQL_INC/storage/ndb/ndbapi"
2027
2028         save_CPPFLAGS="$CPPFLAGS"
2029         CPPFLAGS="$SLAPD_NDB_INCS"
2030         AC_MSG_CHECKING(for NdbApi.hpp)
2031         AC_PREPROC_IFELSE(
2032                 [AC_LANG_SOURCE([[#include <NdbApi.hpp>]])],
2033                         AC_MSG_RESULT(yes),
2034                         AC_MSG_ERROR([could not locate NdbApi headers])
2035         )
2036         CPPFLAGS="$save_CPPFLAGS"
2037
2038         SQL_LIB=`mysql_config --libs_r`
2039         SLAPD_NDB_LIBS="$SQL_LIB -lndbclient -lstdc++"
2040
2041         save_LDFLAGS="$LDFLAGS"
2042         save_LIBS="$LIBS"
2043         LDFLAGS="$SQL_LIB"
2044         AC_CHECK_LIB(ndbclient,ndb_init,[: ok],[
2045                 AC_MSG_ERROR([could not locate ndbclient library])
2046         ],[-lstdc++])
2047         LIBS="$save_LIBS"
2048         LDFLAGS="$save_LDFLAGS"
2049
2050         if test "$ol_enable_ndb" = yes ; then
2051                 SLAPD_LIBS="$SLAPD_LIBS \$(SLAPD_NDB_LIBS)"
2052         fi
2053 fi
2054
2055 dnl ----------------------------------------------------------------
2056 dnl International Components for Unicode
2057 OL_ICU
2058 if test "$ol_icu" = no ; then
2059         AC_MSG_WARN([ICU not available])
2060 else
2061         ICU_LIBS="$ol_icu"
2062 fi
2063 dnl ----------------------------------------------------------------
2064 dnl
2065 dnl Check for Cyrus SASL
2066 dnl
2067 WITH_SASL=no
2068 ol_link_sasl=no
2069 ol_link_spasswd=no
2070 if test $ol_with_cyrus_sasl != no ; then
2071         AC_CHECK_HEADERS(sasl/sasl.h sasl.h)
2072
2073         if test $ac_cv_header_sasl_sasl_h = yes ||
2074            test $ac_cv_header_sasl_h = yes; then
2075                 AC_CHECK_LIB(sasl2, sasl_client_init,
2076                         [ol_link_sasl="-lsasl2"],
2077                         [AC_CHECK_LIB(sasl, sasl_client_init,
2078                                 [ol_link_sasl="-lsasl"])])
2079         fi
2080
2081         if test $ol_link_sasl = no ; then
2082                 if test $ol_with_cyrus_sasl != auto ; then
2083                         AC_MSG_ERROR([Could not locate Cyrus SASL])
2084                 else
2085                         AC_MSG_WARN([Could not locate Cyrus SASL])
2086                         AC_MSG_WARN([SASL authentication not supported!])
2087                         if test $ol_link_tls = no ; then
2088                                 AC_MSG_WARN([Strong authentication not supported!])
2089                         fi
2090                 fi
2091         else
2092                 OL_SASL_COMPAT
2093                 if test $ol_cv_sasl_compat = no ; then
2094                         ol_link_sasl=no
2095                         AC_MSG_ERROR([Cyrus SASL library located but is incompatible])
2096                 fi
2097
2098                 AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
2099                 SASL_LIBS="$ol_link_sasl"
2100                 if test $ol_enable_spasswd != no ; then
2101                         ol_link_spasswd=yes
2102                 fi
2103
2104                 ac_save_LIBS="$LIBS"
2105                 LIBS="$LIBS $ol_link_sasl"
2106                 AC_CHECK_FUNC(sasl_version, [AC_DEFINE(HAVE_SASL_VERSION,1,
2107                         [define if your SASL library has sasl_version()])])
2108                 LIBS="$ac_save_LIBS"
2109
2110                 WITH_SASL=yes
2111         fi
2112
2113 else
2114         AC_MSG_WARN([SASL authentication not supported!])
2115         if test $ol_link_tls = no ; then
2116                 AC_MSG_WARN([Strong authentication not supported!])
2117         fi
2118 fi
2119
2120 dnl ----------------------------------------------------------------
2121 dnl Check for entropy sources
2122 if test $cross_compiling != yes && test "$ac_cv_mingw32" != yes ; then
2123         dev=no
2124         if test -r /dev/urandom ; then
2125                 dev="/dev/urandom";
2126         elif test -r /idev/urandom ; then
2127                 dev="/idev/urandom";
2128         elif test -r /dev/srandom ; then
2129                 dev="/dev/srandom";
2130         elif test -r /dev/random ; then
2131                 dev="/dev/random";
2132         elif test -r /idev/random ; then
2133                 dev="/idev/random";
2134         fi
2135
2136         if test $dev != no ; then
2137                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
2138         fi
2139 fi
2140
2141 dnl ----------------------------------------------------------------
2142 dnl
2143 dnl Check for fetch URL support
2144 dnl             should be extended to support other fetch URL APIs
2145 dnl
2146 ol_link_fetch=no
2147 if test $ol_with_fetch != no ; then
2148         OL_LIB_FETCH
2149
2150         if test $ol_cv_lib_fetch != no ; then
2151                 LUTIL_LIBS="$LUTIL_LIBS $ol_link_fetch"
2152                 ol_link_fetch=freebsd
2153
2154         elif test $ol_with_fetch != auto ; then
2155                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
2156         fi
2157 fi
2158
2159 dnl ----------------------------------------------------------------
2160 dnl FreeBSD (and others) have crypt(3) in -lcrypt
2161 if test $ol_enable_crypt != no ; then
2162         save_LIBS="$LIBS"
2163         LIBS="$TLS_LIBS $LIBS"
2164
2165         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
2166                 LIBS="$save_LIBS"
2167                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
2168                         have_crypt=yes], [have_crypt=no])])
2169
2170         LIBS="$save_LIBS"
2171
2172         if test $have_crypt = yes ; then
2173                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
2174         else
2175                 AC_MSG_WARN([could not find crypt])
2176                 if test $ol_enable_crypt = yes ; then
2177                         AC_MSG_ERROR([could not find crypt, select appropriate options or disable])
2178                 fi
2179
2180                 AC_MSG_WARN([disabling crypt support])
2181                 ol_enable_crypt=no
2182         fi
2183 fi
2184
2185 dnl ----------------------------------------------------------------
2186 dnl FreeBSD (and others) have setproctitle(3) in -lutil
2187 if test $ol_enable_proctitle != no ; then
2188         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
2189                 AC_CHECK_LIB(util, setproctitle,
2190                         [have_setproctitle=yes
2191                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
2192                         [have_setproctitle=no
2193                         AC_LIBOBJ(setproctitle)
2194                         LIBSRCS="$LIBSRCS setproctitle.c"])])
2195
2196         if test $have_setproctitle = yes ; then
2197                 AC_DEFINE(HAVE_SETPROCTITLE,1,
2198                         [define if setproctitle(3) is available])
2199         fi
2200 fi
2201
2202 dnl ----------------------------------------------------------------
2203 if test $ol_enable_slp != no ; then
2204         AC_CHECK_HEADERS( slp.h )
2205
2206         if test $ac_cv_header_slp_h = yes ; then
2207                 AC_CHECK_LIB(slp, SLPOpen, [have_slp=yes], [have_slp=no])
2208                 if test $have_slp = yes ; then
2209                         AC_DEFINE(HAVE_SLP, 1, [define if you have -lslp])
2210                         SLAPD_SLP_LIBS=-lslp
2211                 fi
2212
2213         elif test $ol_enable_slp = yes ; then
2214                 AC_MSG_ERROR([SLP not found])
2215         fi
2216 fi
2217
2218 dnl ----------------------------------------------------------------
2219 dnl Checks for typedefs, structures, and compiler characteristics.
2220
2221 AC_CHECK_TYPE(mode_t, int)
2222 AC_CHECK_TYPE(off_t, long)
2223 AC_CHECK_TYPE(pid_t, int)
2224 AC_CHECK_TYPE(ssize_t, [signed int])
2225 AC_CHECK_TYPE(caddr_t,  [char *])
2226 AC_CHECK_TYPE(size_t, unsigned)
2227
2228 AC_CHECK_TYPES([long long])
2229 AC_CHECK_TYPES([ptrdiff_t])
2230
2231
2232 AC_CHECK_TYPE([socklen_t],,, [$ac_includes_default
2233 #ifdef HAVE_SYS_SOCKET_H
2234 #include <sys/socket.h>
2235 #endif])
2236
2237 dnl socklen_t-like type in accept(), default socklen_t or int:
2238 dnl - The OS might define socklen_t without using it.  POSIX moved from
2239 dnl   int to size_t to socklen_t, hoping to stay at a 32-bit type, and
2240 dnl   HP-UX now has selectors for what to use.
2241 dnl - On Solaris 2.8 the prototype has void *len, but the default is OK.
2242 AC_MSG_CHECKING([the type of arg 3 to accept()])
2243 AC_CACHE_VAL(ol_cv_type_ber_socklen_t, [
2244         set socklen_t int unsigned "unsigned long" long size_t
2245         test "$ac_cv_type_socklen_t" = yes || shift
2246         ol_cv_type_ber_socklen_t=$1 guessing="guessing "
2247         for lentype in "$@" ; do for addrtype in "struct sockaddr" void ; do
2248                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([$ac_includes_default
2249 #ifdef HAVE_SYS_SOCKET_H
2250 #include <sys/socket.h>
2251 #endif
2252 extern int accept(int s, $addrtype *ap, $lentype *lp);
2253 ], [
2254 accept(0, (struct sockaddr *) 0, ($lentype *) 0);
2255 ])], [ol_cv_type_ber_socklen_t=$lentype guessing= ; break 2])
2256         done ; done])
2257 AC_MSG_RESULT([$guessing$ol_cv_type_ber_socklen_t *])
2258 AC_DEFINE_UNQUOTED(ber_socklen_t, $ol_cv_type_ber_socklen_t,
2259         [Define to the type of arg 3 for `accept'.])
2260
2261 dnl Modules should use ber_socklen_t, not socklen_t.  Define socklen_t
2262 dnl for the time being anyway, for backwards compatibility.
2263 if test "$ac_cv_type_socklen_t" != yes; then
2264         AC_DEFINE_UNQUOTED([socklen_t], [$ol_cv_type_ber_socklen_t],
2265                 [Define like ber_socklen_t if <sys/socket.h> does not define.])
2266 fi
2267
2268
2269 AC_TYPE_SIGNAL
2270
2271 AC_CHECK_TYPE([sig_atomic_t],,
2272         [AC_DEFINE_UNQUOTED([sig_atomic_t], [int],
2273                 [Define to `int' if <signal.h> does not define.])],
2274         [$ac_includes_default
2275 #include <signal.h>
2276         ])
2277
2278 AC_TYPE_UID_T
2279
2280 AC_HEADER_TIME
2281 AC_STRUCT_TM
2282 AC_CHECK_MEMBERS([struct stat.st_blksize])
2283 AC_CHECK_MEMBERS([struct passwd.pw_gecos],,,[$ac_includes_default
2284 #include <pwd.h>])
2285 AC_CHECK_MEMBERS([struct passwd.pw_passwd],,,[$ac_includes_default
2286 #include <pwd.h>])
2287
2288 OL_C_UPPER_LOWER
2289 AC_C_CONST
2290 OL_C_VOLATILE
2291
2292 if test $cross_compiling = yes ; then
2293         AC_MSG_WARN([Crossing compiling... all bets are off!])
2294         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2295 else
2296         AC_C_BIGENDIAN
2297 fi
2298
2299 AC_CHECK_SIZEOF(short)
2300 AC_CHECK_SIZEOF(int)
2301 AC_CHECK_SIZEOF(long)
2302 AC_CHECK_SIZEOF(long long)
2303 AC_CHECK_SIZEOF(wchar_t)
2304
2305 if test "$ac_cv_sizeof_int" -lt 4 ; then
2306         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2307
2308         AC_DEFINE(LBER_INT_T,long,[define to 32-bit or greater integer type])
2309 else
2310         AC_DEFINE(LBER_INT_T,int,[define to 32-bit or greater integer type])
2311 fi
2312
2313 AC_DEFINE(LBER_LEN_T,long,[define to large integer type])
2314 AC_DEFINE(LBER_SOCKET_T,int,[define to socket descriptor type])
2315 AC_DEFINE(LBER_TAG_T,long,[define to large integer type])
2316
2317 dnl ----------------------------------------------------------------
2318 dnl Check for multiple precision support
2319 if test $ol_with_mp = longlong || test $ol_with_mp = auto ; then
2320         if test $ac_cv_sizeof_long_long -gt 4 ; then
2321                 ol_with_mp=longlong
2322                 AC_DEFINE(USE_MP_LONG_LONG,1,[define to use 'long long' for MP])
2323         elif test $ol_with_mp = longlong ; then
2324                 AC_MSG_ERROR([long long unusable for multiple precision])
2325         fi
2326 fi
2327 if test $ol_with_mp = long || test $ol_with_mp = auto ; then
2328         if test $ac_cv_sizeof_long -gt 4 ; then
2329                 ol_with_mp=long
2330                 AC_DEFINE(USE_MP_LONG,1,[define to use 'long' for MP])
2331         elif test $ol_with_mp = long ; then
2332                 AC_MSG_ERROR([long unusable for multiple precision])
2333         fi
2334 fi
2335 if test $ol_with_mp = bignum || test $ol_with_mp = auto ; then
2336         AC_CHECK_HEADERS(openssl/bn.h)
2337         AC_CHECK_HEADERS(openssl/crypto.h)
2338         if test "$ac_cv_header_openssl_bn_h" = "yes" &&
2339                 test "$ac_cv_header_openssl_crypto_h" = "yes" &&
2340                 test "$ol_with_tls" = "found" ; then
2341                 ol_with_mp=bignum
2342                 AC_DEFINE(USE_MP_BIGNUM,1,[define to use OpenSSL BIGNUM for MP])
2343         elif test $ol_with_mp = bignum ; then
2344                 AC_MSG_ERROR([bignum not available])
2345         fi
2346 fi
2347 if test $ol_with_mp = gmp || test $ol_with_mp = auto ; then
2348         AC_CHECK_HEADERS(gmp.h)
2349         AC_CHECK_LIB(gmp, __gmpz_add_ui)
2350         if test $ac_cv_header_gmp_h = yes && test $ac_cv_lib_gmp___gmpz_add_ui = yes ; then
2351                 AC_DEFINE(USE_MP_GMP,1,[define to use GMP for MP])
2352                 ol_with_mp=gmp
2353         elif test $ol_with_mp = gmp ; then
2354                 AC_MSG_ERROR([gmp not available])
2355         fi
2356 fi
2357 if test $ol_with_mp = auto ; then
2358         ol_with_mp=no
2359 fi
2360
2361 dnl ----------------------------------------------------------------
2362 dnl Checks for library functions.
2363 AC_FUNC_MEMCMP
2364
2365 if test $ac_cv_func_memcmp_working = no ; then
2366         AC_DEFINE(NEED_MEMCMP_REPLACEMENT,1,
2367                 [define if memcmp is not 8-bit clean or is otherwise broken])
2368 fi
2369
2370 AC_FUNC_STRFTIME
2371
2372 OL_FUNC_INET_ATON
2373
2374 dnl Check for NT specific routines
2375 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2376
2377 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2378         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2379 ])
2380
2381 AC_CHECK_FUNCS(vsnprintf _vsnprintf)
2382
2383 if test $ac_cv_func_vsnprintf = no -a $ac_cv_func__vsnprintf = yes ; then
2384         ac_cv_func_vsnprintf=yes
2385         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2386 fi
2387
2388 AC_FUNC_VPRINTF
2389
2390 if test $ac_cv_func_vprintf = yes ; then
2391         dnl check for vsnprintf
2392         AC_CHECK_FUNCS(snprintf vsnprintf)
2393 fi
2394
2395 AC_CHECK_FUNCS(                 \
2396         bcopy                   \
2397         closesocket             \
2398         chroot                  \
2399         endgrent                \
2400         endpwent                \
2401         fcntl                   \
2402         flock                   \
2403         fstat                   \
2404         getdtablesize           \
2405         geteuid                 \
2406         getgrgid                \
2407         gethostname             \
2408         getpassphrase           \
2409         getpwuid                \
2410         getpwnam                \
2411         getspnam                \
2412         gettimeofday            \
2413         initgroups              \
2414         inet_ntoa_b             \
2415         ioctl                   \
2416         lockf                   \
2417         memcpy                  \
2418         memmove                 \
2419         memrchr                 \
2420         mkstemp                 \
2421         mktemp                  \
2422         pipe                    \
2423         read                    \
2424         recv                    \
2425         recvfrom                \
2426         setpwfile               \
2427         setgid                  \
2428         setegid                 \
2429         setsid                  \
2430         setuid                  \
2431         seteuid                 \
2432         signal                  \
2433         strdup                  \
2434         strpbrk                 \
2435         strrchr                 \
2436         strsep                  \
2437         strstr                  \
2438         strtol                  \
2439         strtoul                 \
2440         strtoq                  \
2441         strtouq                 \
2442         strtoll                 \
2443         strtoull                \
2444         strspn                  \
2445         sysconf                 \
2446         waitpid                 \
2447         wait4                   \
2448         write                   \
2449         send                    \
2450         sendmsg                 \
2451         sendto                  \
2452 )
2453
2454 dnl We actually may need to replace more than this.
2455 AC_REPLACE_FUNCS(getopt getpeereid)
2456
2457 if test "$ac_cv_func_getopt" != yes; then
2458         LIBSRCS="$LIBSRCS getopt.c"
2459 fi
2460
2461 if test "$ac_cv_func_getpeereid" != yes; then
2462         AC_CHECK_FUNCS( getpeerucred )
2463         if test "$ac_cv_func_getpeerucred" != yes ; then
2464                 AC_CHECK_MEMBERS([struct msghdr.msg_accrightslen],,,
2465                         [$ac_includes_default
2466 #ifdef HAVE_SYS_SOCKET_H
2467 #include <sys/socket.h>
2468 #endif])
2469                 if test "$ac_cv_member_struct_msghdr_msg_accrightslen" != yes; then
2470                         AC_CHECK_MEMBERS([struct msghdr.msg_control],,,
2471                                 [$ac_includes_default
2472 #ifdef HAVE_SYS_SOCKET_H
2473 #include <sys/socket.h>
2474 #endif])
2475                 fi
2476                 AC_CHECK_MEMBERS([struct stat.st_fstype, struct stat.st_vfstype])
2477                 if test "$ac_cv_member_struct_stat_st_fstype" = yes; then
2478                         AC_COMPILE_IFELSE([struct stat st; char *ptr=st.st_fstype;],
2479                                 AC_DEFINE([HAVE_STRUCT_STAT_ST_FSTYPE_CHAR],1,[define to 1 if st_fstype is char *]),
2480                                 AC_DEFINE([HAVE_STRUCT_STAT_ST_FSTYPE_INT],1,[define to 1 if st_fstype is int]))
2481                 fi
2482         fi
2483         LIBSRCS="$LIBSRCS getpeereid.c"
2484 fi
2485
2486 if test "$ac_cv_func_snprintf" != yes ||
2487    test "$ac_cv_func_vsnprintf" != yes; then
2488         if test "$ac_cv_func_snprintf" != yes; then
2489                 AC_DEFINE(snprintf, ber_pvt_snprintf, [define to snprintf routine])
2490         fi
2491         if test "$ac_cv_func_vsnprintf" != yes; then
2492                 AC_DEFINE(vsnprintf, ber_pvt_vsnprintf, [define to snprintf routine])
2493         fi
2494 fi
2495
2496 dnl ----------------------------------------------------------------
2497 dnl Sort out defines
2498
2499 if test "$ol_enable_slapi" != no ; then
2500         dnl This check is done also if --enable-modules is used;
2501         dnl it is duplicated here, 'cause it'd be cached anyway
2502         AC_CHECK_HEADERS(ltdl.h)
2503
2504         if test $ac_cv_header_ltdl_h != yes ; then
2505                 AC_MSG_ERROR([could not locate <ltdl.h>])
2506         fi
2507         AC_CHECK_LIB(ltdl, lt_dlinit, [
2508                 SLAPI_LIBS=-lltdl
2509                 LIBSLAPI=libslapi.a
2510                 LIBSLAPITOOLS=../libslapi.a
2511                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
2512         ],[AC_MSG_ERROR([could not locate libtool -lltdl])])
2513
2514         AC_DEFINE(LDAP_SLAPI,1, [define this to add SLAPI code])
2515 fi
2516
2517 if test "$ol_enable_debug" != no ; then
2518         if test "$ol_enable_debug" = traditional; then
2519                 AC_DEFINE(OLD_DEBUG,1,
2520                         [define to use the original debug style])
2521         fi
2522         AC_DEFINE(LDAP_DEBUG,1,
2523                 [define this to add debugging code])
2524 fi
2525 if test "$ol_enable_syslog" = yes ; then
2526         AC_DEFINE(LDAP_SYSLOG,1,
2527                 [define this to add syslog code])
2528 fi
2529 if test "$ol_enable_proctitle" != no ; then
2530         AC_DEFINE(LDAP_PROCTITLE,1,
2531                 [define this for LDAP process title support])
2532 fi
2533 if test "$ol_enable_referrals" != no ; then
2534         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION,
2535                 [define to LDAP VENDOR VERSION])
2536 fi
2537 if test "$ol_enable_local" != no; then
2538         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2539 fi
2540 if test "$ol_link_ipv6" != no; then
2541         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2542 fi
2543 if test "$ol_enable_cleartext" != no ; then
2544         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2545 fi
2546 if test "$ol_enable_crypt" != no ; then
2547         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2548 fi
2549 if test "$ol_link_spasswd" != no ; then
2550         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2551 fi
2552 if test "$ol_enable_rlookups" != no ; then
2553         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2554 fi
2555 if test "$ol_enable_aci" != no ; then
2556         if test $ol_enable_dynacl = no ; then
2557                 ol_enable_dynacl=yes
2558                 AC_MSG_WARN([ACIs need dynacl])
2559         fi
2560         if test "$ol_enable_aci" = mod ; then
2561                 MFLAG=SLAPD_MOD_DYNAMIC
2562                 dnl remove this after moving servers/slapd/aci.c in contrib/slapd-modules/acl
2563                 AC_MSG_ERROR([ACI build as dynamic module not supported (yet)])
2564         else
2565                 MFLAG=SLAPD_MOD_STATIC
2566         fi
2567         WITH_ACI_ENABLED=$ol_enable_aci
2568         AC_DEFINE_UNQUOTED(SLAPD_ACI_ENABLED,$MFLAG,[define to support per-object ACIs])
2569 else
2570         WITH_ACI_ENABLED=no
2571 fi
2572 if test "$ol_enable_dynacl" != no ; then
2573         AC_DEFINE(SLAP_DYNACL,1,[define to support run-time loadable ACL])
2574 fi
2575
2576 if test "$ol_link_modules" != no ; then
2577         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2578         BUILD_SLAPD=yes
2579         SLAPD_MODULES_LDFLAGS="-dlopen self"
2580 fi
2581
2582 AC_DEFINE(SLAPD_MOD_STATIC,1,[statically linked module])
2583 AC_DEFINE(SLAPD_MOD_DYNAMIC,2,[dynamically linked module])
2584
2585 dnl back-monitor goes first (well, after back-config)
2586 if test "$ol_enable_monitor" != no ; then
2587         BUILD_SLAPD=yes
2588         BUILD_MONITOR=$ol_enable_monitor
2589         if test "$ol_enable_monitor" = mod ; then
2590                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-monitor"
2591                 MFLAG=SLAPD_MOD_DYNAMIC
2592         else
2593                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-monitor"
2594                 MFLAG=SLAPD_MOD_STATIC
2595         fi
2596         AC_DEFINE_UNQUOTED(SLAPD_MONITOR,$MFLAG,[define to support cn=Monitor backend])
2597 fi
2598
2599 if test "$ol_enable_bdb" != no ; then
2600         BUILD_SLAPD=yes
2601         BUILD_BDB=$ol_enable_bdb
2602         if test "$ol_enable_bdb" = mod ; then
2603                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-bdb"
2604                 MFLAG=SLAPD_MOD_DYNAMIC
2605         else
2606                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-bdb"
2607                 MFLAG=SLAPD_MOD_STATIC
2608         fi
2609         AC_DEFINE_UNQUOTED(SLAPD_BDB,$MFLAG,[define to support BDB backend])
2610 fi
2611
2612 if test "$ol_enable_dnssrv" != no ; then
2613         BUILD_SLAPD=yes
2614         BUILD_DNSSRV=$ol_enable_dnssrv
2615         if test "$ol_enable_dnssrv" = mod ; then
2616                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-dnssrv"
2617                 MFLAG=SLAPD_MOD_DYNAMIC
2618         else
2619                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-dnssrv"
2620                 MFLAG=SLAPD_MOD_STATIC
2621         fi
2622         AC_DEFINE_UNQUOTED(SLAPD_DNSSRV,$MFLAG,[define to support DNS SRV backend])
2623 fi
2624
2625 if test "$ol_enable_hdb" != no ; then
2626         BUILD_SLAPD=yes
2627         BUILD_HDB=$ol_enable_hdb
2628         if test "$ol_enable_hdb" = mod ; then
2629                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-hdb"
2630                 MFLAG=SLAPD_MOD_DYNAMIC
2631         else
2632                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-hdb"
2633                 MFLAG=SLAPD_MOD_STATIC
2634         fi
2635         AC_DEFINE_UNQUOTED(SLAPD_HDB,$MFLAG,[define to support HDB backend])
2636 fi
2637
2638 if test "$ol_enable_ldap" != no ; then
2639         BUILD_SLAPD=yes
2640         BUILD_LDAP=$ol_enable_ldap
2641         if test "$ol_enable_ldap" = mod ; then
2642                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ldap"
2643                 MFLAG=SLAPD_MOD_DYNAMIC
2644         else
2645                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ldap"
2646                 MFLAG=SLAPD_MOD_STATIC
2647         fi
2648         AC_DEFINE_UNQUOTED(SLAPD_LDAP,$MFLAG,[define to support LDAP backend])
2649 fi
2650
2651 if test "$ol_enable_meta" != no ; then
2652         BUILD_SLAPD=yes
2653         BUILD_META=$ol_enable_meta
2654         BUILD_REWRITE=yes
2655         if test "$ol_enable_meta" = mod ; then
2656                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-meta"
2657                 MFLAG=SLAPD_MOD_DYNAMIC
2658         else
2659                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-meta"
2660                 MFLAG=SLAPD_MOD_STATIC
2661         fi
2662         AC_DEFINE_UNQUOTED(SLAPD_META,$MFLAG,[define to support LDAP Metadirectory backend])
2663 fi
2664
2665 if test "$ol_enable_ndb" != no ; then
2666         BUILD_SLAPD=yes
2667         BUILD_NDB=$ol_enable_ndb
2668         if test "$ol_enable_ndb" = mod ; then
2669                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ndb"
2670                 MFLAG=SLAPD_MOD_DYNAMIC
2671         else
2672                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ndb"
2673                 MFLAG=SLAPD_MOD_STATIC
2674         fi
2675         AC_DEFINE_UNQUOTED(SLAPD_NDB,$MFLAG,[define to support NDB backend])
2676 fi
2677
2678 if test "$ol_enable_null" != no ; then
2679         BUILD_SLAPD=yes
2680         BUILD_NULL=$ol_enable_null
2681         if test "$ol_enable_null" = mod ; then
2682                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-null"
2683                 MFLAG=SLAPD_MOD_DYNAMIC
2684         else
2685                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-null"
2686                 MFLAG=SLAPD_MOD_STATIC
2687         fi
2688         AC_DEFINE_UNQUOTED(SLAPD_NULL,$MFLAG,[define to support NULL backend])
2689 fi
2690
2691 if test "$ol_enable_passwd" != no ; then
2692         BUILD_SLAPD=yes
2693         BUILD_PASSWD=$ol_enable_passwd
2694         if test "$ol_enable_passwd" = mod ; then
2695                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-passwd"
2696                 MFLAG=SLAPD_MOD_DYNAMIC
2697         else
2698                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-passwd"
2699                 MFLAG=SLAPD_MOD_STATIC
2700         fi
2701         AC_DEFINE_UNQUOTED(SLAPD_PASSWD,$MFLAG,[define to support PASSWD backend])
2702 fi
2703
2704 if test "$ol_link_perl" != no ; then
2705         BUILD_SLAPD=yes
2706         BUILD_PERL=$ol_enable_perl
2707         if test "$ol_enable_perl" = mod ; then
2708                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-perl"
2709                 MFLAG=SLAPD_MOD_DYNAMIC
2710         else
2711                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-perl"
2712                 MFLAG=SLAPD_MOD_STATIC
2713         fi
2714         AC_DEFINE_UNQUOTED(SLAPD_PERL,$MFLAG,[define to support PERL backend])
2715 fi
2716
2717 if test "$ol_enable_relay" != no ; then
2718         BUILD_SLAPD=yes
2719         BUILD_RELAY=$ol_enable_relay
2720         if test "$ol_enable_relay" = mod ; then
2721                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-relay"
2722                 MFLAG=SLAPD_MOD_DYNAMIC
2723         else
2724                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-relay"
2725                 MFLAG=SLAPD_MOD_STATIC
2726         fi
2727         AC_DEFINE_UNQUOTED(SLAPD_RELAY,$MFLAG,[define to support relay backend])
2728 fi
2729
2730 if test "$ol_enable_shell" != no ; then
2731         if test "$ol_link_threads" != no ; then
2732                 AC_MSG_WARN([Use of --without-threads is recommended with back-shell])
2733         fi
2734         BUILD_SLAPD=yes
2735         BUILD_SHELL=$ol_enable_shell
2736         if test "$ol_enable_shell" = mod ; then
2737                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-shell"
2738                 MFLAG=SLAPD_MOD_DYNAMIC
2739         else
2740                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-shell"
2741                 MFLAG=SLAPD_MOD_STATIC
2742         fi
2743         AC_DEFINE_UNQUOTED(SLAPD_SHELL,$MFLAG,[define to support SHELL backend])
2744 fi
2745
2746 if test "$ol_enable_sock" != no ; then
2747         BUILD_SLAPD=yes
2748         BUILD_SOCK=$ol_enable_sock
2749         if test "$ol_enable_sock" = mod ; then
2750                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-sock"
2751                 MFLAG=SLAPD_MOD_DYNAMIC
2752         else
2753                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-sock"
2754                 MFLAG=SLAPD_MOD_STATIC
2755         fi
2756         AC_DEFINE_UNQUOTED(SLAPD_SOCK,$MFLAG,[define to support SOCK backend])
2757 fi
2758
2759 if test "$ol_link_sql" != no ; then
2760         BUILD_SLAPD=yes
2761         BUILD_SQL=$ol_enable_sql
2762         if test "$ol_enable_sql" = mod; then
2763                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-sql"
2764                 MFLAG=SLAPD_MOD_DYNAMIC
2765         else
2766                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-sql"
2767                 MFLAG=SLAPD_MOD_STATIC
2768         fi
2769         AC_DEFINE_UNQUOTED(SLAPD_SQL,$MFLAG,[define to support SQL backend])
2770 fi
2771
2772 if test "$ol_enable_accesslog" != no ; then
2773         BUILD_ACCESSLOG=$ol_enable_accesslog
2774         if test "$ol_enable_accesslog" = mod ; then
2775                 MFLAG=SLAPD_MOD_DYNAMIC
2776                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS accesslog.la"
2777         else
2778                 MFLAG=SLAPD_MOD_STATIC
2779                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS accesslog.o"
2780         fi
2781         AC_DEFINE_UNQUOTED(SLAPD_OVER_ACCESSLOG,$MFLAG,[define for In-Directory Access Logging overlay])
2782 fi
2783
2784 if test "$ol_enable_auditlog" != no ; then
2785         BUILD_AUDITLOG=$ol_enable_auditlog
2786         if test "$ol_enable_auditlog" = mod ; then
2787                 MFLAG=SLAPD_MOD_DYNAMIC
2788                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS auditlog.la"
2789         else
2790                 MFLAG=SLAPD_MOD_STATIC
2791                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS auditlog.o"
2792         fi
2793         AC_DEFINE_UNQUOTED(SLAPD_OVER_AUDITLOG,$MFLAG,[define for Audit Logging overlay])
2794 fi
2795
2796 if test "$ol_enable_collect" != no ; then
2797         BUILD_COLLECT=$ol_enable_collect
2798         if test "$ol_enable_collect" = mod ; then
2799                 MFLAG=SLAPD_MOD_DYNAMIC
2800                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS collect.la"
2801         else
2802                 MFLAG=SLAPD_MOD_STATIC
2803                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS collect.o"
2804         fi
2805         AC_DEFINE_UNQUOTED(SLAPD_OVER_COLLECT,$MFLAG,[define for Collect overlay])
2806 fi
2807
2808 if test "$ol_enable_constraint" != no ; then
2809         BUILD_CONSTRAINT=$ol_enable_constraint
2810         if test "$ol_enable_constraint" = mod ; then
2811                 MFLAG=SLAPD_MOD_DYNAMIC
2812                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS constraint.la"
2813         else
2814                 MFLAG=SLAPD_MOD_STATIC
2815                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS constraint.o"
2816         fi
2817         AC_DEFINE_UNQUOTED(SLAPD_OVER_CONSTRAINT,$MFLAG,[define for Attribute Constraint overlay])
2818 fi
2819
2820 if test "$ol_enable_dds" != no ; then
2821         BUILD_DDS=$ol_enable_dds
2822         if test "$ol_enable_dds" = mod ; then
2823                 MFLAG=SLAPD_MOD_DYNAMIC
2824                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dds.la"
2825         else
2826                 MFLAG=SLAPD_MOD_STATIC
2827                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dds.o"
2828         fi
2829         AC_DEFINE_UNQUOTED(SLAPD_OVER_DDS,$MFLAG,[define for Dynamic Directory Services overlay])
2830 fi
2831
2832 if test "$ol_enable_deref" != no ; then
2833         BUILD_DEREF=$ol_enable_deref
2834         if test "$ol_enable_deref" = mod ; then
2835                 MFLAG=SLAPD_MOD_DYNAMIC
2836                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS deref.la"
2837         else
2838                 MFLAG=SLAPD_MOD_STATIC
2839                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS deref.o"
2840         fi
2841         AC_DEFINE_UNQUOTED(SLAPD_OVER_DEREF,$MFLAG,[define for Dynamic Directory Services overlay])
2842 fi
2843
2844 if test "$ol_enable_dyngroup" != no ; then
2845         BUILD_DYNGROUP=$ol_enable_dyngroup
2846         if test "$ol_enable_dyngroup" = mod ; then
2847                 MFLAG=SLAPD_MOD_DYNAMIC
2848                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dyngroup.la"
2849         else
2850                 MFLAG=SLAPD_MOD_STATIC
2851                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dyngroup.o"
2852         fi
2853         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNGROUP,$MFLAG,[define for Dynamic Group overlay])
2854 fi
2855
2856 if test "$ol_enable_dynlist" != no ; then
2857         BUILD_DYNLIST=$ol_enable_dynlist
2858         if test "$ol_enable_dynlist" = mod ; then
2859                 MFLAG=SLAPD_MOD_DYNAMIC
2860                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dynlist.la"
2861         else
2862                 MFLAG=SLAPD_MOD_STATIC
2863                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dynlist.o"
2864         fi
2865         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNLIST,$MFLAG,[define for Dynamic List overlay])
2866 fi
2867
2868 if test "$ol_enable_memberof" != no ; then
2869         BUILD_MEMBEROF=$ol_enable_memberof
2870         if test "$ol_enable_memberof" = mod ; then
2871                 MFLAG=SLAPD_MOD_DYNAMIC
2872                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS memberof.la"
2873         else
2874                 MFLAG=SLAPD_MOD_STATIC
2875                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS memberof.o"
2876         fi
2877         AC_DEFINE_UNQUOTED(SLAPD_OVER_MEMBEROF,$MFLAG,[define for Reverse Group Membership overlay])
2878 fi
2879
2880 if test "$ol_enable_ppolicy" != no ; then
2881         BUILD_PPOLICY=$ol_enable_ppolicy
2882         if test "$ol_enable_ppolicy" = mod ; then
2883                 MFLAG=SLAPD_MOD_DYNAMIC
2884                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS ppolicy.la"
2885         else
2886                 MFLAG=SLAPD_MOD_STATIC
2887                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS ppolicy.o"
2888         fi
2889         AC_DEFINE_UNQUOTED(SLAPD_OVER_PPOLICY,$MFLAG,[define for Password Policy overlay])
2890 fi
2891
2892 if test "$ol_enable_proxycache" != no ; then
2893         BUILD_PROXYCACHE=$ol_enable_proxycache
2894         if test "$ol_enable_proxycache" = mod ; then
2895                 MFLAG=SLAPD_MOD_DYNAMIC
2896                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS pcache.la"
2897         else
2898                 MFLAG=SLAPD_MOD_STATIC
2899                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS pcache.o"
2900         fi
2901         AC_DEFINE_UNQUOTED(SLAPD_OVER_PROXYCACHE,$MFLAG,[define for Proxy Cache overlay])
2902 fi
2903
2904 if test "$ol_enable_refint" != no ; then
2905         BUILD_REFINT=$ol_enable_refint
2906         if test "$ol_enable_refint" = mod ; then
2907                 MFLAG=SLAPD_MOD_DYNAMIC
2908                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS refint.la"
2909         else
2910                 MFLAG=SLAPD_MOD_STATIC
2911                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS refint.o"
2912         fi
2913         AC_DEFINE_UNQUOTED(SLAPD_OVER_REFINT,$MFLAG,[define for Referential Integrity overlay])
2914 fi
2915
2916 if test "$ol_enable_retcode" != no ; then
2917         BUILD_RETCODE=$ol_enable_retcode
2918         if test "$ol_enable_retcode" = mod ; then
2919                 MFLAG=SLAPD_MOD_DYNAMIC
2920                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS retcode.la"
2921         else
2922                 MFLAG=SLAPD_MOD_STATIC
2923                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS retcode.o"
2924         fi
2925         AC_DEFINE_UNQUOTED(SLAPD_OVER_RETCODE,$MFLAG,[define for Referential Integrity overlay])
2926 fi
2927
2928 if test "$ol_enable_rwm" != no ; then
2929         BUILD_REWRITE=yes
2930         BUILD_RWM=$ol_enable_rwm
2931         if test "$ol_enable_rwm" = mod ; then
2932                 MFLAG=SLAPD_MOD_DYNAMIC
2933                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS rwm.la"
2934         else
2935                 MFLAG=SLAPD_MOD_STATIC
2936                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS rwm_x.o"
2937         fi
2938         AC_DEFINE_UNQUOTED(SLAPD_OVER_RWM,$MFLAG,[define for Rewrite/Remap overlay])
2939 fi
2940
2941 if test "$ol_enable_seqmod" != no ; then
2942         BUILD_SEQMOD=$ol_enable_seqmod
2943         if test "$ol_enable_seqmod" = mod ; then
2944                 MFLAG=SLAPD_MOD_DYNAMIC
2945                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS seqmod.la"
2946         else
2947                 MFLAG=SLAPD_MOD_STATIC
2948                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS seqmod.o"
2949         fi
2950         AC_DEFINE_UNQUOTED(SLAPD_OVER_SEQMOD,$MFLAG,[define for Sequential Modify overlay])
2951 fi
2952
2953 if test "$ol_enable_sssvlv" != no ; then
2954         BUILD_SSSVLV=$ol_enable_sssvlv
2955         if test "$ol_enable_sssvlv" = mod ; then
2956                 MFLAG=SLAPD_MOD_DYNAMIC
2957                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS sssvlv.la"
2958         else
2959                 MFLAG=SLAPD_MOD_STATIC
2960                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS sssvlv.o"
2961         fi
2962         AC_DEFINE_UNQUOTED(SLAPD_OVER_SSSVLV,$MFLAG,[define for ServerSideSort/VLV overlay])
2963 fi
2964
2965 if test "$ol_enable_syncprov" != no ; then
2966         BUILD_SYNCPROV=$ol_enable_syncprov
2967         if test "$ol_enable_syncprov" = mod ; then
2968                 MFLAG=SLAPD_MOD_DYNAMIC
2969                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS syncprov.la"
2970         else
2971                 MFLAG=SLAPD_MOD_STATIC
2972                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS syncprov.o"
2973         fi
2974         AC_DEFINE_UNQUOTED(SLAPD_OVER_SYNCPROV,$MFLAG,[define for Syncrepl Provider overlay])
2975 fi
2976
2977 if test "$ol_enable_translucent" != no ; then
2978         BUILD_TRANSLUCENT=$ol_enable_translucent
2979         if test "$ol_enable_translucent" = mod ; then
2980                 MFLAG=SLAPD_MOD_DYNAMIC
2981                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS translucent.la"
2982         else
2983                 MFLAG=SLAPD_MOD_STATIC
2984                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS translucent.o"
2985         fi
2986         AC_DEFINE_UNQUOTED(SLAPD_OVER_TRANSLUCENT,$MFLAG,[define for Translucent Proxy overlay])
2987 fi
2988
2989 if test "$ol_enable_unique" != no ; then
2990         BUILD_UNIQUE=$ol_enable_unique
2991         if test "$ol_enable_unique" = mod ; then
2992                 MFLAG=SLAPD_MOD_DYNAMIC
2993                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS unique.la"
2994         else
2995                 MFLAG=SLAPD_MOD_STATIC
2996                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS unique.o"
2997         fi
2998         AC_DEFINE_UNQUOTED(SLAPD_OVER_UNIQUE,$MFLAG,[define for Attribute Uniqueness overlay])
2999 fi
3000
3001 if test "$ol_enable_valsort" != no ; then
3002         BUILD_VALSORT=$ol_enable_valsort
3003         if test "$ol_enable_valsort" = mod ; then
3004                 MFLAG=SLAPD_MOD_DYNAMIC
3005                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS valsort.la"
3006         else
3007                 MFLAG=SLAPD_MOD_STATIC
3008                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS valsort.o"
3009         fi
3010         AC_DEFINE_UNQUOTED(SLAPD_OVER_VALSORT,$MFLAG,[define for Value Sorting overlay])
3011 fi
3012
3013 if test "$ol_enable_rewrite" != no ; then
3014         AC_DEFINE(ENABLE_REWRITE,1,[define to enable rewriting in back-ldap and back-meta])
3015         BUILD_REWRITE=yes
3016 fi
3017
3018 if test "$ol_enable_slapi" != no ; then
3019         AC_DEFINE(ENABLE_SLAPI,1,[define to enable slapi library])
3020         BUILD_SLAPI=yes
3021         SLAPD_SLAPI_DEPEND=libslapi.a
3022 fi
3023
3024 dnl ----------------------------------------------------------------
3025
3026 dnl
3027 dnl For Windows build, we don't want to include -dlopen flags.
3028 dnl They hurt more than they help.
3029 dnl
3030
3031 if test "$ac_cv_mingw32" = yes -o $ol_cv_msvc = yes ; then
3032         PLAT=NT
3033         SLAPD_MODULES_LDFLAGS=
3034 else
3035         PLAT=UNIX
3036 fi
3037
3038 AC_SUBST(LIBSRCS)
3039 AC_SUBST(PLAT)
3040 AC_SUBST(WITH_SASL)
3041 AC_SUBST(WITH_TLS)
3042 AC_SUBST(WITH_MODULES_ENABLED)
3043 AC_SUBST(WITH_ACI_ENABLED)
3044 AC_SUBST(BUILD_THREAD)
3045 AC_SUBST(BUILD_LIBS_DYNAMIC)
3046
3047 AC_SUBST(BUILD_SLAPD)
3048 dnl slapi
3049   AC_SUBST(BUILD_SLAPI)
3050   AC_SUBST(SLAPD_SLAPI_DEPEND)
3051 dnl backends
3052   AC_SUBST(BUILD_BDB)
3053   AC_SUBST(BUILD_DNSSRV)
3054   AC_SUBST(BUILD_HDB)
3055   AC_SUBST(BUILD_LDAP)
3056   AC_SUBST(BUILD_META)
3057   AC_SUBST(BUILD_MONITOR)
3058   AC_SUBST(BUILD_NDB)
3059   AC_SUBST(BUILD_NULL)
3060   AC_SUBST(BUILD_PASSWD)
3061   AC_SUBST(BUILD_RELAY)
3062   AC_SUBST(BUILD_PERL)
3063   AC_SUBST(BUILD_SHELL)
3064   AC_SUBST(BUILD_SOCK)
3065   AC_SUBST(BUILD_SQL)
3066 dnl overlays
3067   AC_SUBST(BUILD_ACCESSLOG)
3068   AC_SUBST(BUILD_AUDITLOG)
3069   AC_SUBST(BUILD_COLLECT)
3070   AC_SUBST(BUILD_CONSTRAINT)
3071   AC_SUBST(BUILD_DDS)
3072   AC_SUBST(BUILD_DENYOP)
3073   AC_SUBST(BUILD_DEREF)
3074   AC_SUBST(BUILD_DYNGROUP)
3075   AC_SUBST(BUILD_DYNLIST)
3076   AC_SUBST(BUILD_LASTMOD)
3077   AC_SUBST(BUILD_MEMBEROF)
3078   AC_SUBST(BUILD_PPOLICY)
3079   AC_SUBST(BUILD_PROXYCACHE)
3080   AC_SUBST(BUILD_REFINT)
3081   AC_SUBST(BUILD_RETCODE)
3082   AC_SUBST(BUILD_RWM)
3083   AC_SUBST(BUILD_SEQMOD)
3084   AC_SUBST(BUILD_SSSVLV)
3085   AC_SUBST(BUILD_SYNCPROV)
3086   AC_SUBST(BUILD_TRANSLUCENT)
3087   AC_SUBST(BUILD_UNIQUE)
3088   AC_SUBST(BUILD_VALSORT)
3089
3090 AC_SUBST(LDAP_LIBS)
3091 AC_SUBST(SLAPD_LIBS)
3092 AC_SUBST(BDB_LIBS)
3093 AC_SUBST(SLAPD_NDB_LIBS)
3094 AC_SUBST(SLAPD_NDB_INCS)
3095 AC_SUBST(LTHREAD_LIBS)
3096 AC_SUBST(LUTIL_LIBS)
3097 AC_SUBST(WRAP_LIBS)
3098
3099 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
3100 AC_SUBST(SLAPD_MODULES_LDFLAGS)
3101
3102 AC_SUBST(SLAPD_NO_STATIC)
3103 AC_SUBST(SLAPD_STATIC_BACKENDS)
3104 AC_SUBST(SLAPD_DYNAMIC_BACKENDS)
3105 AC_SUBST(SLAPD_STATIC_OVERLAYS)
3106 AC_SUBST(SLAPD_DYNAMIC_OVERLAYS)
3107
3108 AC_SUBST(PERL_CPPFLAGS)
3109 AC_SUBST(SLAPD_PERL_LDFLAGS)
3110 AC_SUBST(MOD_PERL_LDFLAGS)
3111
3112 AC_SUBST(KRB4_LIBS)
3113 AC_SUBST(KRB5_LIBS)
3114 AC_SUBST(SASL_LIBS)
3115 AC_SUBST(TLS_LIBS)
3116 AC_SUBST(MODULES_LIBS)
3117 AC_SUBST(SLAPI_LIBS)
3118 AC_SUBST(LIBSLAPI)
3119 AC_SUBST(LIBSLAPITOOLS)
3120 AC_SUBST(AUTH_LIBS)
3121 AC_SUBST(ICU_LIBS)
3122
3123 AC_SUBST(SLAPD_SLP_LIBS)
3124 AC_SUBST(SLAPD_GMP_LIBS)
3125
3126 AC_SUBST(SLAPD_SQL_LDFLAGS)
3127 AC_SUBST(SLAPD_SQL_LIBS)
3128 AC_SUBST(SLAPD_SQL_INCLUDES)
3129
3130 dnl ----------------------------------------------------------------
3131 dnl final help output
3132 AC_ARG_WITH(xxinstall,[
3133 See INSTALL file for further details.])
3134
3135 dnl ----------------------------------------------------------------
3136 dnl final output
3137 dnl
3138
3139 AC_CONFIG_FILES([Makefile:build/top.mk:Makefile.in:build/dir.mk]
3140 [doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk]
3141 [doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk]
3142 [doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk]
3143 [doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk]
3144 [doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk]
3145 [doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk]
3146 [clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk]
3147 [clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk]
3148 [include/Makefile:build/top.mk:include/Makefile.in]
3149 [libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk]
3150 [libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk]
3151 [libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk]
3152 [libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk]
3153 [libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk]
3154 [libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk]
3155 [libraries/librewrite/Makefile:build/top.mk:libraries/librewrite/Makefile.in:build/lib.mk:build/lib-static.mk]
3156 [servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk]
3157 [servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk]
3158 [servers/slapd/back-bdb/Makefile:build/top.mk:servers/slapd/back-bdb/Makefile.in:build/mod.mk]
3159 [servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk]
3160 [servers/slapd/back-hdb/Makefile:build/top.mk:servers/slapd/back-hdb/Makefile.in:build/mod.mk]
3161 [servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk]
3162 [servers/slapd/back-ldif/Makefile:build/top.mk:servers/slapd/back-ldif/Makefile.in:build/mod.mk]
3163 [servers/slapd/back-meta/Makefile:build/top.mk:servers/slapd/back-meta/Makefile.in:build/mod.mk]
3164 [servers/slapd/back-monitor/Makefile:build/top.mk:servers/slapd/back-monitor/Makefile.in:build/mod.mk]
3165 [servers/slapd/back-ndb/Makefile:build/top.mk:servers/slapd/back-ndb/Makefile.in:build/mod.mk]
3166 [servers/slapd/back-null/Makefile:build/top.mk:servers/slapd/back-null/Makefile.in:build/mod.mk]
3167 [servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk]
3168 [servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk]
3169 [servers/slapd/back-relay/Makefile:build/top.mk:servers/slapd/back-relay/Makefile.in:build/mod.mk]
3170 [servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk]
3171 [servers/slapd/back-sock/Makefile:build/top.mk:servers/slapd/back-sock/Makefile.in:build/mod.mk]
3172 [servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk]
3173 [servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk]
3174 [servers/slapd/slapi/Makefile:build/top.mk:servers/slapd/slapi/Makefile.in:build/lib.mk:build/lib-shared.mk]
3175 [servers/slapd/overlays/Makefile:build/top.mk:servers/slapd/overlays/Makefile.in:build/lib.mk]
3176 [tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk]
3177 [tests/run]
3178 [tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk])
3179
3180 AC_CONFIG_COMMANDS([default],[[
3181 chmod +x tests/run
3182 date > stamp-h
3183 BACKENDSC="servers/slapd/backends.c"
3184 echo "Making $BACKENDSC"
3185 rm -f $BACKENDSC
3186 cat > $BACKENDSC << ENDX
3187 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
3188  *
3189  * Copyright 1998-2010 The OpenLDAP Foundation.
3190  * All rights reserved.
3191  *
3192  * Redistribution and use in source and binary forms, with or without
3193  * modification, are permitted only as authorized by the OpenLDAP
3194  * Public License.
3195  *
3196  * A copy of this license is available in the file LICENSE in the
3197  * top-level directory of the distribution or, alternatively, at
3198  * <http://www.OpenLDAP.org/license.html>.
3199  */
3200 /* This file is automatically generated by configure; please do not edit. */
3201
3202 #include "portable.h"
3203 #include "slap.h"
3204
3205 ENDX
3206 if test "${STATIC_BACKENDS}"; then
3207         for b in config ${STATIC_BACKENDS}; do
3208                 bb=`echo "${b}" | sed -e 's/back-//'`
3209                 cat >> $BACKENDSC << ENDX
3210 extern BI_init ${bb}_back_initialize;
3211 ENDX
3212         done
3213
3214         cat >> $BACKENDSC << ENDX
3215
3216 BackendInfo slap_binfo[] = {
3217 ENDX
3218
3219         for b in config ${STATIC_BACKENDS}; do
3220                 bb=`echo "${b}" | sed -e 's/back-//'`
3221                 echo "    Add ${bb} ..."
3222                 cat >> $BACKENDSC << ENDX
3223         { "${bb}", ${bb}_back_initialize },
3224 ENDX
3225         done
3226
3227         cat >> $BACKENDSC << ENDX
3228         { NULL, NULL },
3229 };
3230
3231 /* end of generated file */
3232 ENDX
3233 fi
3234 OVERLAYSC="servers/slapd/overlays/statover.c"
3235 echo "Making $OVERLAYSC"
3236 rm -f $OVERLAYSC
3237 cat > $OVERLAYSC << ENDX
3238 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
3239  *
3240  * Copyright 1998-2010 The OpenLDAP Foundation.
3241  * All rights reserved.
3242  *
3243  * Redistribution and use in source and binary forms, with or without
3244  * modification, are permitted only as authorized by the OpenLDAP
3245  * Public License.
3246  *
3247  * A copy of this license is available in the file LICENSE in the
3248  * top-level directory of the distribution or, alternatively, at
3249  * <http://www.OpenLDAP.org/license.html>.
3250  */
3251 /* This file is automatically generated by configure; please do not edit. */
3252
3253 #include "portable.h"
3254 #include "slap.h"
3255
3256 ENDX
3257 if test "${STATIC_OVERLAYS}"; then
3258         for o in ${STATIC_OVERLAYS}; do
3259                 oo=`echo "${o}" | sed -e 's/.o$//' -e 's/_x$//'`
3260                 cat >> $OVERLAYSC << ENDX
3261 extern OV_init ${oo}_initialize;
3262 ENDX
3263         done
3264 fi
3265
3266 cat >> $OVERLAYSC << ENDX
3267
3268 OverlayInit slap_oinfo[] = {
3269 ENDX
3270
3271 if test "${STATIC_OVERLAYS}"; then
3272         for o in ${STATIC_OVERLAYS}; do
3273                 oo=`echo "${o}" | sed -e 's/.o$//' -e 's/_x$//'`
3274                 echo "    Add ${oo} ..."
3275                 cat >> $OVERLAYSC << ENDX
3276         { "${oo}", ${oo}_initialize },
3277 ENDX
3278         done
3279 fi
3280
3281         cat >> $OVERLAYSC << ENDX
3282         { NULL, NULL },
3283 };
3284
3285 /* end of generated file */
3286 ENDX
3287
3288 if test "${ol_cv_mkdep}" = no; then
3289         echo '(Do not "make depend"; we do not know how to build dependencies)'
3290 else
3291         echo 'Please run "make depend" to build dependencies'
3292 fi
3293 ]],[[
3294 STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS"
3295 STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS"
3296 ]])
3297 AC_OUTPUT