git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8
   9 dnl Configure.in for OpenLDAP
  10 AC_INIT(include/ldap.h)dnl
  11 AC_CONFIG_AUX_DIR(build)dnl
  12 AM_INIT_AUTOMAKE(OpenLDAP,[1.1-beta], [no ac_define])dnl
  13
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_PREREQ(2.10)dnl Required Autoconf version
  18
  19 AC_CONFIG_HEADER(include/portable.h)dnl
  20
  21 dnl
  22 dnl Start Args
  23 AC_MSG_CHECKING(configure arguments)
  24 AC_PREFIX_DEFAULT(/usr/local)
  25
  26 top_builddir=`pwd`
  27 AC_SUBST(top_builddir)dnl
  28
  29 ldap_subdir="openldap"
  30
  31 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  32         if test "$withval" = "no"; then
  33                 ldap_subdir=""
  34         elif test "$withval" != "yes"; then
  35                 ldap_subdir="$withval"
  36         fi
  37 ])dnl
  38
  39 AC_SUBST(ldap_subdir)dnl
  40
  41 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  42 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  43 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  44 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  45 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  46 OL_ARG_ENABLE(dns,[  --enable-dns               enable dns support], no)dnl
  47 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable referrals], yes)dnl
  48 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  49 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  50         no, [yes no])dnl
  51
  52 dnl General "with" options
  53 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  54         auto, [auto k5 k4 afs yes no])
  55 OL_ARG_WITH(threads,[  --with-threads   use threads],
  56         auto, [auto posix mach lwp yes no manual] )
  57 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  58         auto, [auto yes no manual] )
  59
  60 dnl Server options
  61
  62 dnl LDAPD OPTIONS
  63 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  64 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  65
  66 dnl SLAPD OPTIONS
  67 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  68 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  69 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  70 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  71 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  72 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  73 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  74 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  75
  76 dnl SLAPD Backend options
  77 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  78 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  79         [auto db2 db gdbm ndbm manual])
  80 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  81         [auto btree hash])
  82
  83 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  84 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  85
  86 dnl SLURPD OPTIONS
  87 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  88 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  89
  90 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
  91 AM_ENABLE_STATIC
  92 AM_DISABLE_SHARED
  93 dnl AM_ENABLE_SHARED
  94
  95 dnl General "enable" options
  96 # validate options
  97 if test $ol_enable_referrals = no ; then
  98         if test $ol_enable_dns = yes ; then
  99                 AC_MSG_WARN([dns disabled, ignoring --enable-dns argument])
 100         fi
 101         ol_enable_dns=no
 102 fi
 103
 104 if test $ol_enable_slapd = no ; then
 105         dnl SLAPD was specificallly disabled
 106         if test $ol_enable_ldbm = yes ; then
 107                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 108         fi
 109         if test $ol_enable_passwd = yes ; then
 110                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 111         fi
 112         if test $ol_enable_shell = yes ; then
 113                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 114         fi
 115         if test $ol_enable_aclgroups = yes ; then
 116                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 117         fi
 118         if test $ol_enable_wrappers = yes ; then
 119                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 120         fi
 121         if test $ol_enable_phonetic = yes ; then
 122                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 123         fi
 124         if test $ol_enable_rlookups = yes ; then
 125                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 126         fi
 127         if test $ol_with_ldbm_api != auto ; then
 128                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 129         fi
 130         if test $ol_with_ldbm_type != auto ; then
 131                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 132         fi
 133         if test $ol_enable_slurpd = yes ; then
 134                 AC_MSG_ERROR([slurpd requires slapd])
 135         fi
 136
 137         # force settings to no
 138         ol_enable_ldbm=no
 139         ol_enable_shell=no
 140         ol_enable_passwd=no
 141         ol_enable_aclgroups=no
 142         ol_enable_wrappers=no
 143         ol_enable_phonetic=no
 144         ol_enable_rlookups=no
 145         ol_with_ldbm_api=no
 146         ol_with_ldbm_type=no
 147         ol_enable_slurpd=no
 148
 149 elif test $ol_enable_ldbm = no ; then
 150         dnl SLAPD without LDBM
 151
 152         if test $ol_with_ldbm_api != auto ; then
 153                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 154         fi
 155
 156         if test $ol_with_ldbm_type != auto ; then
 157                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 158         fi
 159
 160         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 161                 AC_MSG_ERROR([slapd requires a backend])
 162         fi
 163
 164         ol_with_ldbm_api=no
 165         ol_with_ldbm_type=no
 166
 167 else
 168         dnl SLAPD with LDBM
 169
 170         if test $ol_with_ldbm_api = gdbm -a \
 171                 $ol_with_ldbm_type = btree ; then
 172                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 173         fi
 174         if test $ol_with_ldbm_api = ndbm -a \
 175                 $ol_with_ldbm_type = btree ; then
 176                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 177         fi
 178 fi
 179
 180 if test $ol_enable_slurpd = yes ; then
 181         dnl SLURPD was specifically enabled
 182         if test $ol_with_threads = no ; then
 183                 AC_MSG_ERROR([slurpd requires threads])
 184         fi
 185 fi
 186
 187 AC_MSG_RESULT(done)
 188
 189 AC_CANONICAL_HOST
 190
 191 ## Initialize vars
 192 LDAP_LIBS=
 193 LDBM_LIBS=
 194 LTHREAD_LIBS=
 195 LUTIL_LIBS=
 196
 197 LDAPD_LIBS=
 198 SLAPD_LIBS=
 199 SLURPD_LIBS=
 200
 201 BUILD_LDAPD=no
 202 BUILD_SLAPD=no
 203 BUILD_SLURPD=no
 204
 205 BUILD_LDBM=no
 206 BUILD_PASSWD=no
 207 BUILD_SHELL=no
 208 BUILD_THREAD=no
 209
 210 KRB_LIBS=
 211 TERMCAP_LIBS=
 212
 213 dnl ----------------------------------------------------------------
 214 dnl Checks for programs
 215
 216 AC_PROG_INSTALL
 217 AM_PROG_LIBTOOL
 218 dnl AC_PROG_MAKE_SET
 219
 220 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 221         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 222 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 223 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 224
 225 dnl Checks the compiler and UNIX Variants
 226
 227 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 228         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 229
 230 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 231         AC_MSG_WARN([programs compiled here do run here...])
 232         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 233
 234 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 235         AC_MSG_WARN([programs compiled here do not run here...])
 236         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 237 fi
 238
 239 AC_PROG_CPP
 240
 241 AC_AIX
 242 AC_ISC_POSIX
 243 AC_MINIX
 244
 245 dnl OpenLDAP requires STDC features
 246 AM_PROG_CC_STDC
 247 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 248         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 249 fi
 250
 251 dnl AM_C_PROTOTYPES
 252
 253 dnl Checks for libraries
 254
 255 dnl Find socket()
 256 dnl Likely combinations:
 257 dnl             -lsocket [ -lnsl_s | -lnsl ]
 258 dnl             -linet
 259
 260 AC_CHECK_FUNC(socket, [have_socket=yes], [
 261 dnl
 262 dnl hopefully we won't include too many libraries
 263 dnl
 264         AC_CHECK_LIB(socket, main)
 265         AC_CHECK_LIB(net, main)
 266         AC_CHECK_LIB(nsl_s, main)
 267         AC_CHECK_LIB(nsl, main)
 268         AC_CHECK_LIB(inet, socket)
 269         AC_CHECK_LIB(gen, main)
 270 ])
 271
 272 dnl Check for resolv
 273 AC_CHECK_LIB(resolv, res_search)
 274
 275 dnl HP-UX requires -lV3
 276 AC_CHECK_LIB(V3, sigset)
 277
 278 # ISODE tests
 279 ol_link_isode=no
 280 if test $ol_enable_ldapd != no ; then
 281         dnl look for ISODE libraries
 282         AC_CHECK_LIB(xtpp, main, [
 283                 ol_link_isode=yes
 284                 AC_DEFINE(HAVE_XTPP,1)
 285                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 286                 ],:,[-lxtdsap -lxtisode -losi])
 287         AC_CHECK_LIB(dsap, main, [
 288                 ol_link_isode=yes
 289                 AC_DEFINE(HAVE_DSAP,1)
 290                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 291                 ],:,[-lisode])
 292         AC_CHECK_LIB(isode, main, [
 293                 ol_link_isode=yes
 294                 AC_DEFINE(HAVE_ISODE,1)
 295                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 296                 ],:)
 297 fi
 298
 299 if test $ol_link_isode != no; then
 300         AC_CHECK_LIB(pp, main, [
 301                 AC_DEFINE(HAVE_PP,1)
 302                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 303                 ],:)
 304
 305         AC_PATH_PROG(PEPSY, pepsy)
 306 fi
 307
 308 dnl
 309 dnl check for kerberos
 310 dnl
 311 ol_link_kerberos=no
 312
 313 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 314         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 315
 316         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 317                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 318                         [-lkrb5 -ldes425])
 319
 320                 if test $have_k5 = yes ; then
 321                         ol_with_kerberos=found
 322                         ol_link_kerberos=yes
 323
 324                         AC_DEFINE(HAVE_KERBEROS)
 325                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 326                 fi
 327         fi
 328 fi
 329
 330 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 331         AC_CHECK_HEADERS(krb.h des.h)
 332
 333         if test $ac_cv_header_krb_h = yes ; then
 334                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 335
 336                 if test $have_k4 = yes ; then
 337                         ol_with_kerberos=found
 338                         ol_link_kerberos=yes
 339
 340                         AC_DEFINE(HAVE_KERBEROS)
 341                         KRB_LIBS="-lkrb -ldes"
 342                 fi
 343         fi
 344 fi
 345
 346 dnl     if test $ol_link_kerberos = yes ; then
 347 dnl             save_LIBS=$LIBS
 348 dnl             LIBS="$KRB_LIBS $LIBS"
 349 dnl             AC_CHECK_FUNCS(des_string_to_key)
 350 dnl             LIBS=$save_LIBS
 351 dnl fi
 352
 353 ol_link_threads=no
 354 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 355         -o $ol_with_threads = posix ; then
 356
 357         AC_CHECK_HEADERS(pthread.h sched.h)
 358
 359         if test $ac_cv_header_pthread_h = yes ; then
 360                 OL_POSIX_THREAD_VERSION
 361
 362                 if test $ol_cv_pthread_version = final ; then
 363                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 364                 elif test $ol_cv_pthread_version = draft4 ; then
 365                         AC_DEFINE(HAVE_PTHREADS_D4)
 366                 else
 367                         AC_MSG_ERROR([unknown pthread version])
 368                 fi
 369
 370                 # consider threads found
 371                 ol_with_threads=found
 372
 373                 OL_LINUX_THREADS
 374
 375                 if test $ol_cv_linux_threads = yes ; then
 376                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 377                 fi
 378
 379                 dnl Now the hard part, how to link
 380
 381                 dnl Check for pthread support in current $LIBS
 382                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 383
 384                 if test $ol_link_threads = no ; then
 385                         dnl try -pthread
 386                         AC_CACHE_CHECK([for pthread_create with -pthread],
 387                                 [ol_cv_pthread_flag], [
 388                                 dnl save the flags
 389                                 save_LIBS="$LIBS"
 390                                 LIBS="-pthread $LIBS"
 391                                 AC_TRY_LINK([char pthread();],[
 392                                         pthread_create();
 393                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 394                                 dnl restore the LIBS
 395                                 LIBS="$save_LIBS"
 396                         ])
 397
 398                         if test $ol_cv_pthread_flag = yes ; then
 399                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 400                                 ol_link_threads=posix
 401                         fi
 402                 fi
 403
 404                 if test $ol_link_threads = no ; then
 405                         dnl try -pthreads
 406                         AC_CACHE_CHECK([for pthread_create with -pthreads],
 407                                 [ol_cv_pthreads_flag], [
 408                                 dnl save the flags
 409                                 save_LIBS="$LIBS"
 410                                 LIBS="-pthreads $LIBS"
 411                                 AC_TRY_LINK([char pthread();],[
 412                                         pthread_create();
 413                                         ], ol_cv_pthreads_flag=yes, ol_cv_pthreads_flag=no)
 414                                 dnl restore the LIBS
 415                                 LIBS="$save_LIBS"
 416                         ])
 417
 418                         if test $ol_cv_pthreads_flag = yes ; then
 419                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthreads"
 420                                 ol_link_threads=posix
 421                         fi
 422                 fi
 423
 424                 if test $ol_link_threads = no ; then
 425                         dnl try -thread
 426                         AC_CACHE_CHECK([for pthread_create with -thread],
 427                                 [ol_cv_thread_flag], [
 428                                 dnl save the flags
 429                                 save_LIBS="$LIBS"
 430                                 LIBS="-thread $LIBS"
 431                                 AC_TRY_LINK([char pthread();],[
 432                                         pthread_create();
 433                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 434                                 dnl restore the LIBS
 435                                 LIBS="$save_LIBS"
 436                         ])
 437
 438                         if test $ol_cv_thread_flag = yes ; then
 439                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 440                                 ol_link_threads=posix
 441                         fi
 442                 fi
 443
 444                 if test $ol_link_threads = no ; then
 445                         dnl try DEC Threads -lpthread -lexc
 446                         save_LIBS="$LIBS"
 447                         AC_CHECK_LIB(pthread, pthread_join, [
 448                                 ol_link_threads=posix
 449                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 450                                 if test $ol_with_yielding_select = auto ; then
 451                                         ol_with_yielding_select=yes
 452                                 fi
 453                                 ],,[-lexc])
 454                         LIBS="$save_LIBS"
 455                 fi
 456
 457                 if test $ol_link_threads = no ; then
 458                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 459                         save_LIBS="$LIBS"
 460                         AC_CHECK_LIB(pthreads, pthread_join, [
 461                                 ol_link_threads=posix
 462                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 463                                 if test $ol_with_yielding_select = auto ; then
 464                                         ol_with_yielding_select=yes
 465                                 fi
 466                                 ],,[-lmach -lexc -lc_r])
 467                         LIBS="$save_LIBS"
 468                 fi
 469
 470                 if test $ol_link_threads = no ; then
 471                         dnl try -lpthread
 472                         save_LIBS="$LIBS"
 473                         AC_CHECK_LIB(pthread, pthread_create, [
 474                                 ol_link_threads=posix
 475                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 476                         LIBS="$save_LIBS"
 477                 fi
 478
 479                 if test $ol_link_threads = no ; then
 480                         dnl try -lc_r
 481                         save_LIBS="$LIBS"
 482                         AC_CHECK_LIB(c_r, pthread_create, [
 483                                 ol_link_threads=posix
 484                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 485                         LIBS="$save_LIBS"
 486                 fi
 487
 488                 if test $ol_link_threads = no ; then
 489                         dnl try -lpthreads
 490                         save_LIBS="$LIBS"
 491                         AC_CHECK_LIB(pthreads, pthread_create, [
 492                                 ol_link_threads=posix
 493                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"])
 494                         LIBS="$save_LIBS"
 495                 fi
 496
 497                 dnl HP-UX 11 check
 498                 if test $ol_link_threads = no; then
 499                         save_LIBS="$LIBS"
 500                         LIBS="$LIBS -lpthread"
 501                         AC_MSG_CHECKING([for pthread_create() in HP-UX -lpthread])
 502                         ol_try_pthread_hpux_11=no
 503                         AC_CACHE_VAL(ol_cv_pthread_hpux_11,[
 504                                 AC_TRY_LINK([
 505 #include <pthread.h>
 506 #include <elf.h>
 507 #ifndef ELFABI_HPUX_REL11
 508         die horribly
 509 #endif
 510                                 ], [pthread_create(NULL, NULL, NULL, NULL);],
 511                                         ol_try_pthread_hpux_11=yes
 512                                         ol_cv_pthread_hpux_11=yes,
 513                                         ol_cv_pthread_hpux_11=no)])
 514                         AC_MSG_RESULT(yes)
 515                         LIBS="$save_LIBS"
 516
 517                         if test $ol_cv_pthread_hpux_11=yes ; then
 518                                 ol_link_threads=posix
 519                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"
 520                                 if test $ol_try_pthread_hpux_11=yes ; then
 521                                         dnl Some tests below may fail, cause we aint including
 522                                         dnl pthread.h. Force appropriate ones to yes
 523                                         ac_cv_func_pthread_attr_init=yes
 524                                 fi
 525                         fi
 526                 fi
 527
 528                 if test $ol_link_threads != no ; then
 529                         AC_DEFINE(HAVE_PTHREADS)
 530
 531                         dnl save flags
 532                         save_CPPFLAGS="$CPPFLAGS"
 533                         save_LIBS="$LIBS"
 534                         LIBS="$LTHREAD_LIBS $LIBS"
 535
 536                         dnl All POSIX Thread (final) implementations should have
 537                         dnl sched_yield instead of pthread yield.
 538                         dnl check for both
 539                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 540
 541                         if test $ac_cv_func_sched_yield = no -a \
 542                                 $ac_cv_func_pthread_yield = no ; then
 543                                 dnl Digital UNIX has sched_yield() in -lrt
 544                                 AC_CHECK_LIB(rt, sched_yield,
 545                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 546                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 547                                         ac_cv_func_sched_yield=yes],
 548                                         [ac_cv_func_sched_yield=no])
 549                         fi
 550                         if test $ac_cv_func_sched_yield = no -a \
 551                                 $ac_cv_func_pthread_yield = no ; then
 552                                 dnl Solaris has sched_yield() in -lposix4
 553                                 AC_CHECK_LIB(posix4, sched_yield,
 554                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 555                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 556                                         ac_cv_func_sched_yield=yes],
 557                                         [ac_cv_func_sched_yield=no])
 558                         fi
 559                         if test $ac_cv_func_sched_yield = no -a \
 560                                 $ac_cv_func_pthread_yield = no ; then
 561                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 562                                 AC_MSG_ERROR([POSIX Threads are not usable])
 563                         fi
 564
 565                         dnl Check functions for compatibility
 566                         AC_CHECK_FUNCS(pthread_kill)
 567                         AC_CHECK_FUNCS( \
 568                                 pthread_attr_create pthread_attr_init \
 569                                 pthread_attr_destroy pthread_attr_delete \
 570                                 pthread_attr_setdetachstate pthread_attr_setdetach_np \
 571                         )
 572
 573                         dnl Check for setconcurreny functions
 574                         AC_CHECK_FUNCS( \
 575                                 pthread_setconcurrency \
 576                                 thr_setconcurrency \
 577                         )
 578
 579                         AC_MSG_CHECKING([if pthread_create() works])
 580                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 581                         AC_TRY_RUN([
 582 #include <pthread.h>
 583 #ifndef NULL
 584 #define NULL (void*)0
 585 #endif
 586
 587 static void *task(p)
 588         void *p;
 589 {
 590         return (void *) (p == NULL);
 591 }
 592
 593 int main(argc, argv)
 594         int argc;
 595         char **argv;
 596 {
 597         pthread_t t;
 598         exit(pthread_create(&t, NULL, task, NULL));
 599 }
 600 ],
 601                                 [ol_cv_pthread_create_works=yes],
 602                                 [ol_cv_pthread_create_works=no],
 603                                 [dnl assume yes
 604                                 ol_cv_pthread_create_works=yes])])
 605                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 606
 607                         if test $ol_cv_pthread_create_works = no ; then
 608                                 AC_MSG_ERROR([pthread.h and pthread_create are not compatible])
 609                         fi
 610
 611                         dnl Check if select causes an yield
 612                         if test $ol_with_yielding_select = auto ; then
 613                                 AC_MSG_CHECKING([if select yields when using pthreads])
 614                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 615                                 AC_TRY_RUN([
 616 #include <sys/types.h>
 617 #include <sys/time.h>
 618 #include <unistd.h>
 619 #include <pthread.h>
 620 #ifndef NULL
 621 #define NULL (void*) 0
 622 #endif
 623
 624 static int fildes[2];
 625
 626 static void *task(p)
 627         void *p;
 628 {
 629         int i;
 630         struct timeval tv;
 631
 632         fd_set rfds;
 633
 634         tv.tv_sec=10;
 635         tv.tv_usec=0;
 636
 637         FD_ZERO(&rfds);
 638         FD_SET(fildes[0], &rfds);
 639
 640         /* we're not interested in any fds */
 641         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 642
 643         if(i < 0) {
 644                 perror("select");
 645                 exit(10);
 646         }
 647
 648         exit(0); /* if we exit here, the select blocked the whole process */
 649 }
 650
 651 int main(argc, argv)
 652         int argc;
 653         char **argv;
 654 {
 655         pthread_t t;
 656
 657         /* create a pipe to select */
 658         if(pipe(&fildes[0])) {
 659                 perror("select");
 660                 exit(1);
 661         }
 662
 663 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 664         (void) pthread_setconcurrency(2);
 665 #else
 666 #ifdef HAVE_THR_SETCONCURRENCY
 667         /* Set Solaris LWP concurrency to 2 */
 668         thr_setconcurrency(2);
 669 #endif
 670 #endif
 671
 672         pthread_create(&t, NULL, task, NULL);
 673
 674 #if HAVE_SCHED_YIELD
 675         sched_yield();  /* make sure task runs first */
 676 #else
 677 #ifdef HAVE_PTHREAD_YIELD
 678         pthread_yield();        /* make sure task runs first */
 679 #endif
 680 #endif
 681
 682         exit(2);
 683 }],
 684                                 [ol_cv_pthread_select_yields=no],
 685                                 [ol_cv_pthread_select_yields=yes], [
 686                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
 687                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
 688
 689                                 if test $ol_cv_pthread_select_yields = yes ; then
 690                                         ol_with_yielding_select=yes
 691                                 fi
 692                         fi
 693
 694                         dnl restore flags
 695                         CPPFLAGS="$save_CPPFLAGS"
 696                         LIBS="$save_LIBS"
 697                 else
 698                         AC_MSG_ERROR([could not link with POSIX Threads])
 699                 fi
 700         fi
 701
 702         if test $ol_with_threads = posix ; then
 703                 AC_MSG_ERROR([could not locate POSIX Threads])
 704         fi
 705 fi
 706
 707 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 708         -o $ol_with_threads = mach ; then
 709
 710         dnl check for Mach CThreads
 711         AC_CHECK_HEADERS(mach/cthreads.h)
 712         if test $ac_cv_header_mach_cthreads_h = yes ; then
 713                 ol_with_threads=found
 714
 715                 dnl check for cthread support in current $LIBS
 716                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 717
 718                 if test $ol_link_threads = no ; then
 719                         dnl try -all_load
 720                         dnl this test needs work
 721                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 722                                 [ol_cv_cthread_all_load], [
 723                                 dnl save the flags
 724                                 save_LIBS="$LIBS"
 725                                 LIBS="-all_load $LIBS"
 726                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 727                                         cthread_fork((void *)0, (void *)0);
 728                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 729                                 dnl restore the LIBS
 730                                 LIBS="$save_LIBS"
 731                         ])
 732
 733                         if test $ol_cv_cthread_all_load = yes ; then
 734                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 735                                 ol_link_threads=mach
 736                         fi
 737                 fi
 738
 739                 if test $ol_link_threads != no ; then
 740                         : check for cthread specific functionality here
 741                         AC_DEFINE(HAVE_MACH_CTHREADS,1)
 742                 else
 743                         AC_MSG_ERROR([could not link with Mach CThreads])
 744                 fi
 745         fi
 746
 747         if test $ol_with_threads = mach ; then
 748                 AC_MSG_ERROR([could not locate Mach CThreads])
 749         fi
 750 fi
 751
 752 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 753         -o $ol_with_threads = lwp ; then
 754
 755         dnl check for SunOS5 LWP
 756         AC_CHECK_HEADERS(thread.h synch.h)
 757         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 758                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
 759
 760                 if test $have_thr = yes ; then
 761                         AC_DEFINE(HAVE_THR)
 762                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
 763                         ol_link_threads=thr
 764
 765                         if test $ol_with_yielding_select = auto ; then
 766                                 ol_with_yielding_select=yes
 767                         fi
 768                 fi
 769         fi
 770
 771         dnl check for SunOS4 LWP
 772         AC_CHECK_HEADERS(lwp/lwp.h)
 773         if test $ac_cv_header_lwp_lwp_h = yes ; then
 774                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 775
 776                 if test $have_lwp = yes ; then
 777                         AC_DEFINE(HAVE_LWP)
 778                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 779                         ol_link_threads=lwp
 780
 781                         if test $ol_with_yielding_select = auto ; then
 782                                 ol_with_yielding_select=no
 783                         fi
 784                 fi
 785         fi
 786 fi
 787
 788 if test $ol_with_yielding_select = yes ; then
 789         AC_DEFINE(HAVE_YIELDING_SELECT,1)
 790 fi
 791
 792 if test $ol_with_threads = manual ; then
 793         dnl User thinks he can manually configure threads.
 794         ol_link_threads=yes
 795
 796         AC_MSG_WARN([thread defines and link options must be set manually])
 797
 798         AC_CHECK_HEADERS(pthread.h sched.h)
 799         AC_CHECK_FUNCS(sched_yield pthread_yield)
 800         OL_LINUX_THREADS
 801
 802         AC_CHECK_HEADERS(mach/cthreads.h)
 803         AC_CHECK_HEADERS(lwp/lwp.h)
 804         AC_CHECK_HEADERS(thread.h synch.h)
 805 fi
 806
 807 if test $ol_link_threads != no ; then
 808         dnl needed to get reentrant/threadsafe versions
 809         dnl
 810         AC_DEFINE(REENTRANT,1)
 811         AC_DEFINE(_REENTRANT,1)
 812         AC_DEFINE(THREAD_SAFE,1)
 813         AC_DEFINE(_THREAD_SAFE,1)
 814         AC_DEFINE(THREADSAFE,1)
 815         AC_DEFINE(_THREADSAFE,1)
 816
 817         dnl this might cause the errno symbol to be
 818         dnl replaced with a function to get a thread specific errno.
 819         dnl check to see if everything needs to be compiled
 820         dnl with the thread libraries
 821         AC_CACHE_CHECK([for thread specific errno],
 822                 [ol_cv_errno_thread_specific], [
 823                 AC_TRY_LINK([
 824 #include <errno.h>
 825                         ], [
 826 int x = errno;
 827                         ],
 828                         [ol_cv_errno_thread_specific=yes],
 829                         [ol_cv_errno_thread_specific=no])
 830         ])
 831
 832         if test $ol_cv_errno_thread_specific != yes ; then
 833                 LIBS="$LTHREAD_LIBS $LIBS"
 834                 LTHREAD_LIBS=""
 835         fi
 836
 837         dnl check for reentrant/threadsafe functions
 838         dnl
 839         dnl note: these should only be used when linking
 840         dnl       with $LTHREAD_LIBS
 841         dnl
 842         save_CPPFLAGS="$CPPFLAGS"
 843         save_LIBS="$LIBS"
 844         LIBS="$LTHREAD_LIBS $LIBS"
 845         AC_CHECK_FUNCS( \
 846                 strtok_r \
 847                 gmtime_r \
 848                 gethostbyaddr_r gethostbyname_r \
 849                 feof_unlocked unlocked_feof \
 850                 putc_unlocked unlocked_putc \
 851                 flockfile ftrylockfile \
 852         )
 853         CPPFLAGS="$save_CPPFLAGS"
 854         LIBS="$save_LIBS"
 855 fi
 856
 857 dnl ----------------------------------------------------------------
 858
 859 if test $ol_link_threads = no ; then
 860         if test $ol_with_threads = yes ; then
 861                 AC_MSG_ERROR([no suitable thread support])
 862         fi
 863
 864         if test $ol_with_threads = auto ; then
 865                 AC_MSG_WARN([no suitable thread support, disabling threads])
 866                 ol_with_threads=no
 867         fi
 868
 869         AC_DEFINE(NO_THREADS,1)
 870         LTHREAD_LIBS=""
 871 fi
 872
 873 ol_link_ldbm=no
 874 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 875         OL_BERKELEY_DB2
 876
 877         if test $ol_cv_berkeley_db2 = yes ; then
 878                 ol_link_ldbm=db2
 879                 ol_with_ldbm_api=db2
 880
 881                 if test $ol_with_ldbm_type = hash ; then
 882                         AC_DEFINE(LDBM_USE_DBHASH,1)
 883                 else
 884                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 885                 fi
 886
 887                 dnl $ol_cv_lib_db2 should be yes or -ldb
 888                 dnl (it could be no, but that would be an error
 889                 if test $ol_cv_lib_db2 != yes ; then
 890                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 891                 fi
 892         fi
 893 fi
 894
 895 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 896         OL_BERKELEY_DB
 897
 898         if test $ol_cv_berkeley_db = yes ; then
 899                 ol_link_ldbm=db
 900                 ol_with_ldbm_api=db
 901
 902                 if test $ol_with_ldbm_type = hash ; then
 903                         AC_DEFINE(LDBM_USE_DBHASH,1)
 904                 else
 905                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 906                 fi
 907
 908                 dnl $ol_cv_lib_db should be yes or -ldb
 909                 dnl (it could be no, but that would be an error
 910                 if test $ol_cv_lib_db != yes ; then
 911                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 912                 fi
 913         fi
 914 fi
 915
 916 if test $ol_with_ldbm_api = manual ; then
 917         dnl User thinks he can manually configure LDBM api.
 918         ol_link_ldbm=yes
 919
 920         AC_MSG_WARN([LDBM defines and link options must be set manually])
 921
 922         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 923 fi
 924
 925 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 926         AC_MSG_WARN(Could not find LDBM with BTREE support)
 927         ol_with_ldbm_api=none
 928 fi
 929
 930 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 931         OL_GDBM
 932
 933         if test $ol_cv_gdbm = yes ; then
 934                 ol_link_ldbm=gdbm
 935                 ol_with_ldbm_api=gdbm
 936
 937                 if test $ol_cv_lib_gdbm != yes ; then
 938                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 939                 fi
 940         fi
 941 fi
 942
 943 if test $ol_with_ldbm_api = auto ; then
 944         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
 945 elif test $ol_with_ldbm_api = ndbm ; then
 946         OL_NDBM
 947
 948         if test $ol_cv_ndbm = yes ; then
 949                 ol_link_ldbm=ndbm
 950                 ol_with_ldbm_api=ndbm
 951
 952                 if test $ol_cv_lib_ndbm != yes ; then
 953                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 954                 fi
 955         fi
 956 fi
 957
 958 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 959         AC_MSG_WARN(could not find suitable LDBM backend)
 960         if test $ol_enable_ldbm = yes ; then
 961                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 962         fi
 963
 964         AC_MSG_WARN(disabling LDBM)
 965         ol_enable_ldbm=no
 966 fi
 967
 968 if test $ol_enable_wrappers = yes ; then
 969         AC_CHECK_LIB(wrap, main,
 970                 [have_wrappers=yes], [have_wrappers=no])
 971
 972         if test $have_wrappers = yes ; then
 973                 AC_DEFINE(HAVE_TCPD)
 974                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 975         else
 976                 AC_MSG_WARN(could not find -lwrap)
 977                 if test $ol_enable_wrappers = yes ; then
 978                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 979                 fi
 980
 981                 AC_MSG_WARN(disabling wrappers support)
 982                 ol_enable_wrappers=no
 983         fi
 984
 985 fi
 986
 987 # ud needs termcap (should insert check here)
 988 ol_link_termcap=no
 989 AC_CHECK_HEADERS(termcap.h ncurses.h)
 990
 991 if test $ol_link_termcap = no ; then
 992         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 993         if test $have_termcap = yes ; then
 994                 AC_DEFINE(HAVE_TERMCAP)
 995                 ol_link_termcap=yes
 996                 TERMCAP_LIBS=-ltermcap
 997         fi
 998 fi
 999
1000 if test $ol_link_termcap = no ; then
1001         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1002         if test $have_ncurses = yes ; then
1003                 AC_DEFINE(HAVE_NCURSES)
1004                 ol_link_termcap=yes
1005                 TERMCAP_LIBS=-lncurses
1006         fi
1007 fi
1008
1009 if test $ol_link_termcap = no ; then
1010         AC_DEFINE(NO_TERMCAP,1)
1011         TERMCAP_LIBS=
1012 fi
1013
1014 # FreeBSD (and others) have crypt(3) in -lcrypt
1015 if test $ol_enable_crypt != no ; then
1016         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1017                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1018                         have_crypt=yes], [have_crypt=no])])
1019
1020         if test $have_crypt = yes ; then
1021                 AC_DEFINE(HAVE_CRYPT,1)
1022         else
1023                 AC_MSG_WARN(could not find crypt)
1024                 if test $ol_enable_crypt = yes ; then
1025                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1026                 fi
1027
1028                 AC_MSG_WARN(disabling crypt support)
1029                 ol_enable_crypt=no
1030         fi
1031 fi
1032
1033 # FreeBSD (and others) have setproctitle(3) in -lutil
1034 if test $ol_enable_proctitle != no ; then
1035         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1036                 AC_CHECK_LIB(util, setproctitle,
1037                         [have_setproctitle=yes
1038                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1039                         [have_setproctitle=no
1040                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1041
1042         if test $have_setproctitle = yes ; then
1043                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1044         fi
1045 fi
1046
1047 dnl ----------------------------------------------------------------
1048 dnl Checks for header files.
1049 AC_HEADER_STDC
1050
1051 if test $ac_cv_header_stdc != yes; then
1052         AC_MSG_WARN([could not Standard C compliant headers])
1053 fi
1054
1055 AC_HEADER_DIRENT
1056 AC_HEADER_SYS_WAIT
1057 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1058 if test $am_cv_sys_posix_termios = yes ; then
1059         AC_DEFINE(HAVE_POSIX_TERMIOS,1)
1060 fi
1061
1062 AC_CHECK_HEADERS(       \
1063         crypt.h                 \
1064         errno.h                 \
1065         fcntl.h                 \
1066         filio.h                 \
1067         getopt.h                \
1068         libutil.h               \
1069         limits.h                \
1070         malloc.h                \
1071         memory.h                \
1072         regex.h                 \
1073         psap.h                  \
1074         pwd.h                   \
1075         sgtty.h                 \
1076         stdarg.h                \
1077         stddef.h                \
1078         string.h                \
1079         strings.h               \
1080         sys/file.h              \
1081         sys/filio.h             \
1082         sys/errno.h             \
1083         sys/ioctl.h             \
1084         sys/param.h             \
1085         sys/resource.h  \
1086         sys/socket.h    \
1087         sys/syslog.h    \
1088         sys/time.h              \
1089         sys/types.h             \
1090         syslog.h                \
1091         termios.h               \
1092         unistd.h                \
1093 )
1094
1095 dnl ----------------------------------------------------------------
1096 dnl Checks for typedefs, structures, and compiler characteristics.
1097 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1098 AC_TYPE_MODE_T
1099 AC_TYPE_OFF_T
1100 AC_TYPE_PID_T
1101 AM_TYPE_PTRDIFF_T
1102 AC_TYPE_SIGNAL
1103 AC_TYPE_SIZE_T
1104 AC_STRUCT_ST_BLKSIZE
1105 AC_HEADER_TIME
1106 AC_STRUCT_TM
1107
1108 OL_C_UPPER_LOWER
1109 AC_C_CONST
1110
1111 if test $cross_compiling = yes ; then
1112         AC_DEFINE(CROSS_COMPILING, 1)
1113 else
1114         AC_C_BIGENDIAN
1115         AC_CHECK_SIZEOF(short)
1116         AC_CHECK_SIZEOF(int)
1117         AC_CHECK_SIZEOF(long)
1118 fi
1119
1120 dnl ----------------------------------------------------------------
1121 dnl Checks for library functions.
1122 AC_FUNC_MEMCMP
1123 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1124 AC_FUNC_STRFTIME
1125 dnl AM_FUNC_STRTOD
1126 AC_FUNC_VPRINTF
1127
1128 if test $ac_cv_func_vprintf = yes ; then
1129         dnl check for vsnprintf
1130         AC_CHECK_FUNCS(vsnprintf vsprintf)
1131 fi
1132
1133 AC_FUNC_WAIT3
1134
1135 AC_CHECK_FUNCS(         \
1136         bcopy                   \
1137         flock                   \
1138         getdtablesize   \
1139         gethostname             \
1140         getpwuid                \
1141         gettimeofday    \
1142         lockf                   \
1143         memcpy                  \
1144         memmove                 \
1145         mkstemp                 \
1146         res_search              \
1147         select                  \
1148         setpwfile               \
1149         setsid                  \
1150         signal                  \
1151         sigset                  \
1152         snprintf                \
1153         socket                  \
1154         strerror                \
1155         strpbrk                 \
1156         strrchr                 \
1157         strsep                  \
1158         strstr                  \
1159         strtok                  \
1160         strtol                  \
1161         strtoul                 \
1162         sysconf                 \
1163         waitpid                 \
1164 )
1165
1166 dnl We actually may need to replace more than this.
1167 AC_REPLACE_FUNCS(getopt strdup tempnam)
1168
1169 dnl ----------------------------------------------------------------
1170 # Check Configuration
1171 OL_SYS_ERRLIST
1172
1173 dnl ----------------------------------------------------------------
1174 dnl Sort out defines
1175
1176 if test "$ol_enable_debug" != no ; then
1177         AC_DEFINE(LDAP_DEBUG,1)
1178 fi
1179 dnl     if test "$ol_enable_syslog" != no ; then
1180 dnl             AC_DEFINE(LDAP_SYSLOG,1)
1181 dnl     fi
1182 if test "$ol_enable_libui" = yes ; then
1183         AC_DEFINE(LDAP_LIBUI,1)
1184 fi
1185 if test "$ol_enable_cache" = no ; then
1186         AC_DEFINE(LDAP_NOCACHE,1)
1187 fi
1188 if test "$ol_enable_dns" != no ; then
1189         AC_DEFINE(LDAP_DNS,1)
1190 fi
1191 if test "$ol_enable_proctitle" != no ; then
1192         AC_DEFINE(LDAP_PROCTITLE,1)
1193 fi
1194 if test "$ol_enable_referrals" != no ; then
1195         AC_DEFINE(LDAP_REFERRALS,1)
1196 fi
1197 if test "$ol_enable_cldap" != no ; then
1198         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1199 fi
1200
1201 if test "$ol_enable_aclgroups" != no ; then
1202         AC_DEFINE(SLAPD_ACLGROUPS,1)
1203 fi
1204 if test "$ol_enable_crypt" != no ; then
1205         AC_DEFINE(SLAPD_CRYPT,1)
1206 fi
1207 if test "$ol_enable_cleartext" != no ; then
1208         AC_DEFINE(SLAPD_CLEARTEXT,1)
1209 fi
1210 if test "$ol_enable_phonetic" != no ; then
1211         AC_DEFINE(SLAPD_PHONETIC,1)
1212 fi
1213 if test "$ol_enable_rlookups" != no ; then
1214         AC_DEFINE(SLAPD_RLOOKUPS,1)
1215 fi
1216
1217 if test "$ol_link_ldbm" != no ; then
1218         AC_DEFINE(SLAPD_LDBM,1)
1219         BUILD_SLAPD=yes
1220         BUILD_LDBM=yes
1221 fi
1222
1223 if test "$ol_enable_passwd" != no ; then
1224         AC_DEFINE(SLAPD_PASSWD,1)
1225         BUILD_SLAPD=yes
1226         BUILD_PASSWD=yes
1227 fi
1228
1229 if test "$ol_enable_shell" != no ; then
1230         AC_DEFINE(SLAPD_SHELL,1)
1231         BUILD_SLAPD=yes
1232         BUILD_SHELL=yes
1233 fi
1234
1235 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1236         $BUILD_SLAPD = yes ; then
1237         BUILD_SLURPD=yes
1238 fi
1239
1240 if test "$ol_link_isode" != no ; then
1241         BUILD_LDAPD=yes
1242 fi
1243
1244 dnl ----------------------------------------------------------------
1245
1246 AC_SUBST(BUILD_LDAPD)
1247 AC_SUBST(BUILD_SLAPD)
1248   AC_SUBST(BUILD_LDBM)
1249   AC_SUBST(BUILD_PASSWD)
1250   AC_SUBST(BUILD_SHELL)
1251 AC_SUBST(BUILD_SLURPD)
1252
1253
1254 AC_SUBST(LDAP_LIBS)
1255 AC_SUBST(LDAPD_LIBS)
1256 AC_SUBST(SLAPD_LIBS)
1257 AC_SUBST(SLURPD_LIBS)
1258 AC_SUBST(LDBM_LIBS)
1259 AC_SUBST(LTHREAD_LIBS)
1260 AC_SUBST(LUTIL_LIBS)
1261
1262 AC_SUBST(KRB_LIBS)
1263 AC_SUBST(TERMCAP_LIBS)
1264
1265 dnl ----------------------------------------------------------------
1266 dnl final output
1267 dnl
1268
1269 AC_OUTPUT( \
1270 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1271 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1272 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1273 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1274 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1275 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1276 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1277 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1278 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1279 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1280 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1281 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1282 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1283 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1284 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1285 include/Makefile:build/top.mk:include/Makefile.in \
1286 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1287 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1288 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1289 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1290 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1291 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1292 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk:build/lib-static.mk    \
1293 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1294 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1295 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1296 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1297 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1298 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1299 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1300 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1301 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1302 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1303 tests/Makefile:build/top.mk:tests/Makefile.in \
1304 ,[
1305 date > stamp-h
1306 echo Please \"make depend\" to build dependencies
1307 ])