git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Disable config.cache!
  11 define([AC_CACHE_LOAD], )dnl
  12 define([AC_CACHE_SAVE], )dnl
  13
  14 dnl Configure.in for OpenLDAP
  15 AC_INIT(build/version)dnl
  16 AC_CONFIG_AUX_DIR(build)dnl
  17
  18 OL_VERSION=`cat $ac_aux_dir/version`
  19 if test -z "$OL_VERSION"; then
  20         AC_MSG_ERROR([could not determine version])
  21 fi
  22
  23 dnl ----------------------------------------------------------------
  24 dnl Determine host platform
  25 dnl             we try not to use this for much
  26 AC_CANONICAL_SYSTEM
  27
  28 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  29 AC_SUBST(PACKAGE)
  30 AC_SUBST(VERSION)
  31 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  32 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  33
  34 dnl We use autoconf features new to 2.13.
  35 dnl     aclocal.m4 should be built using aclocal from automake 1.4
  36 AC_PREREQ(2.13)dnl Required Autoconf version
  37
  38 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  39
  40 dnl
  41 dnl Start Args
  42 AC_MSG_CHECKING(configure arguments)
  43 AC_PREFIX_DEFAULT(/usr/local)
  44
  45 top_builddir=`pwd`
  46 AC_SUBST(top_builddir)dnl
  47
  48 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
  49
  50 ldap_subdir="openldap"
  51
  52 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  53         if test "$withval" = "no"; then
  54                 ldap_subdir=""
  55         elif test "$withval" != "yes"; then
  56                 ldap_subdir="$withval"
  57         fi
  58 ])dnl
  59
  60 AC_SUBST(ldap_subdir)dnl
  61
  62 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  63 dnl ol_enable_syslog=no
  64 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  65 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  66 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  67 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  68 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  69 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  70 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  71         no, [yes no])dnl
  72
  73 dnl General "with" options
  74 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  75
  76 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  77         auto, [auto k5 k4 afs yes no])
  78 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  79         auto, [auto yes no] )
  80 OL_ARG_WITH(threads,[  --with-threads   use threads],
  81         auto, [auto posix mach lwp yes no manual] )
  82 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  83         auto, [auto ssleay openssl yes no] )
  84 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  85         auto, [auto yes no manual] )
  86
  87 dnl Server options
  88
  89 dnl LDAPD OPTIONS
  90 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  91 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  92
  93 dnl SLAPD OPTIONS
  94 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  95 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  96 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  97 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  98 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
  99 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
 100 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
 101 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
 102
 103 dnl SLAPD Backend options
 104 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 105 OL_ARG_WITH(bdb2_module,[      --with-bdb2-module       module type], static,
 106         [static dynamic])
 107 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 108 OL_ARG_WITH(ldap_module,[      --with-ldap-module       module type], static,
 109         [static dynamic])
 110 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 111 OL_ARG_WITH(ldbm_module,[      --with-ldbm-module       module type], static,
 112         [static dynamic])
 113 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 114         [auto db2 db mdbm gdbm ndbm manual])
 115 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 116         [auto btree hash])
 117
 118 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 119 OL_ARG_WITH(passwd_module,[      --with-passwd-module   module type], static,
 120         [static dynamic])
 121 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 122 OL_ARG_WITH(perl_module,[      --with-perl-module       module type], static,
 123         [static dynamic])
 124 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 125 OL_ARG_WITH(shell_module,[      --with-shell-module     module type], static,
 126         [static dynamic])
 127 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 128 OL_ARG_WITH(tcl_module,[      --with-tcl-module module type], static,
 129         [static dynamic])
 130
 131 dnl SLURPD OPTIONS
 132 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
 133 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 134
 135 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 136 AM_ENABLE_STATIC
 137 dnl AM_DISABLE_SHARED
 138 AM_ENABLE_SHARED
 139
 140 dnl General "enable" options
 141 # validate options
 142 if test $ol_enable_dns = yes ; then
 143         if test $ol_enable_referrals = no ; then
 144                 AC_MSG_ERROR([DNS requires --enable-referrals])
 145         fi
 146         if test $ol_enable_referrals = auto ; then
 147                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 148                 ol_enable_referrals=yes
 149         fi
 150 fi
 151
 152 if test $ol_enable_slapd = no ; then
 153         dnl SLAPD was specificallly disabled
 154         if test $ol_enable_bdb2 = yes ; then
 155                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 156         fi
 157         if test $ol_enable_ldap = yes ; then
 158                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 159         fi
 160         if test $ol_enable_ldbm = yes ; then
 161                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 162         fi
 163         if test $ol_enable_passwd = yes ; then
 164                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 165         fi
 166         if test $ol_enable_perl = yes ; then
 167                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 168         fi
 169         if test $ol_enable_shell = yes ; then
 170                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 171         fi
 172         if test $ol_enable_tcl = yes ; then
 173                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 174         fi
 175         if test $ol_enable_modules = yes ; then
 176                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 177         fi
 178         if test $ol_enable_wrappers = yes ; then
 179                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 180         fi
 181         if test $ol_enable_phonetic = yes ; then
 182                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 183         fi
 184         if test $ol_enable_rlookups = yes ; then
 185                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 186         fi
 187         if test $ol_with_ldbm_api != auto ; then
 188                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 189         fi
 190         if test $ol_with_ldbm_type != auto ; then
 191                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 192         fi
 193         if test $ol_with_bdb2_module != static ; then
 194                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb2-module argument])
 195         fi
 196         if test $ol_with_ldap_module != static ; then
 197                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 198         fi
 199         if test $ol_with_ldbm_module != static ; then
 200                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 201         fi
 202         if test $ol_with_passwd_module != static ; then
 203                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 204         fi
 205         if test $ol_with_perl_module != static ; then
 206                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 207         fi
 208         if test $ol_with_shell_module != static ; then
 209                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 210         fi
 211         if test $ol_with_tcl_module != static ; then
 212                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 213         fi
 214         if test $ol_enable_slurpd = yes ; then
 215                 AC_MSG_ERROR([slurpd requires slapd])
 216         fi
 217
 218         # force settings to no
 219         ol_enable_bdb2=no
 220         ol_enable_ldap=no
 221         ol_enable_ldbm=no
 222         ol_enable_passwd=no
 223         ol_enable_perl=no
 224         ol_enable_shell=no
 225         ol_enable_tcl=no
 226
 227         ol_enable_modules=no
 228         ol_enable_phonetic=no
 229         ol_enable_rlookups=no
 230         ol_enable_wrappers=no
 231
 232         ol_with_ldbm_api=no
 233         ol_with_ldbm_type=no
 234
 235         ol_with_bdb2_module=static
 236         ol_with_ldap_module=static
 237         ol_with_ldbm_module=static
 238         ol_with_passwd_module=static
 239         ol_with_perl_module=static
 240         ol_with_shell_module=static
 241         ol_with_tcl_module=static
 242
 243         ol_enable_slurpd=no
 244
 245 elif test $ol_enable_ldbm = no ; then
 246         dnl SLAPD without LDBM
 247
 248         if test $ol_with_ldbm_api != auto ; then
 249                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 250         fi
 251
 252         if test $ol_with_ldbm_type != auto ; then
 253                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 254         fi
 255
 256         if test $ol_with_ldbm_module != static ; then
 257                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 258         fi
 259
 260         if test $ol_enable_bdb2 = yes ; then
 261                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 262         fi
 263
 264         if test $ol_enable_modules != yes -a \
 265                 $ol_enable_ldap = no -a \
 266                 $ol_enable_passwd = no -a \
 267                 $ol_enable_perl = no -a \
 268                 $ol_enable_shell = no -a \
 269                 $ol_enable_tcl = no ; then
 270                 AC_MSG_ERROR([slapd requires a backend])
 271         fi
 272
 273         ol_with_ldbm_api=no
 274         ol_with_ldbm_type=no
 275         ol_with_ldbm_module=static
 276
 277 elif test $ol_enable_bdb2 = yes ; then
 278         dnl SLAPD with BDB2
 279
 280         if test $ol_with_ldbm_api != auto -a \
 281                 $ol_with_ldbm_api != db2 ; then
 282                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 283         fi
 284
 285         ol_with_ldbm_api=db2
 286
 287 else
 288         dnl SLAPD with LDBM
 289
 290         if test $ol_enable_bdb2 != no ; then
 291                 if test $ol_with_ldbm_api != auto -a \
 292                         $ol_with_ldbm_api != db2 ; then
 293                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 294                         ol_enable_bdb2=no
 295                 fi
 296         fi
 297
 298         if test $ol_with_ldbm_api = gdbm -a \
 299                 $ol_with_ldbm_type = btree ; then
 300                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 301         fi
 302         if test $ol_with_ldbm_api = mdbm -a \
 303                 $ol_with_ldbm_type = btree ; then
 304                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 305         fi
 306         if test $ol_with_ldbm_api = ndbm -a \
 307                 $ol_with_ldbm_type = btree ; then
 308                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 309         fi
 310 fi
 311
 312 if test $ol_enable_slurpd = yes ; then
 313         dnl SLURPD was specifically enabled
 314         if test $ol_with_threads = no ; then
 315                 AC_MSG_ERROR([slurpd requires threads])
 316         fi
 317 fi
 318
 319 AC_MSG_RESULT(done)
 320
 321 ## Initialize vars
 322 LDAP_LIBS=
 323 LDBM_LIBS=
 324 LTHREAD_LIBS=
 325 LUTIL_LIBS=
 326
 327 LDAPD_LIBS=
 328 SLAPD_LIBS=
 329 SLURPD_LIBS=
 330
 331 BUILD_LDAPD=no
 332 BUILD_SLAPD=no
 333 BUILD_SLURPD=no
 334
 335 BUILD_BDB2=no
 336 BUILD_LDAP=no
 337 BUILD_LDBM=no
 338 BUILD_PASSWD=no
 339 BUILD_PERL=no
 340 BUILD_SHELL=no
 341 BUILD_TCL=no
 342 BUILD_THREAD=no
 343
 344 BUILD_BDB2_DYNAMIC=no
 345 BUILD_LDAP_DYNAMIC=no
 346 BUILD_LDBM_DYNAMIC=no
 347 BUILD_PASSWD_DYNAMIC=no
 348 BUILD_PERL_DYNAMIC=no
 349 BUILD_SHELL_DYNAMIC=no
 350 BUILD_TCL_DYNAMIC=no
 351
 352 SLAPD_MODULES_LDFLAGS=
 353 SLAPD_MODULES_CPPFLAGS=
 354
 355 SLAPD_PERL_LDFLAGS=
 356 SLAPD_PERL_CPPFLAGS=
 357
 358 KRB_LIBS=
 359 READLINE_LIBS=
 360 TERMCAP_LIBS=
 361 TLS_LIBS=
 362
 363 dnl ----------------------------------------------------------------
 364 dnl Checks for programs
 365
 366 dnl AC_PROG_INSTALL
 367
 368 dnl AIX Thread requires we use cc_r or xlc_r.
 369 dnl But only do this IF AIX and CC is not set
 370 dnl and threads are auto|yes|posix.
 371 dnl
 372 dnl If we find cc_r|xlc_r, force pthreads and assume
 373 dnl             pthread_create is in $LIBS (ie: don't bring in
 374 dnl             any additional thread libraries)
 375 dnl If we do not find cc_r|xlc_r, disable threads
 376
 377 ol_aix_threads=no
 378 case "$target" in
 379 *-*-aix*) dnl all AIX is not a good idea.
 380         if test -z "$CC" ; then
 381                 case "$ol_with_threads" in
 382                 auto | yes |  posix) ol_aix_threads=yes ;;
 383                 esac
 384         fi
 385 ;;
 386 esac
 387
 388 if test $ol_aix_threads = yes ; then
 389         if test -z "${CC}" ; then
 390                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 391
 392                 if test "$CC" = cc ; then
 393                         dnl no CC! don't allow --with-threads
 394                         if test $ol_with_threads != auto ; then
 395                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 396                         else
 397                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 398                         fi
 399                         ol_with_threads=no
 400                 fi
 401         fi
 402
 403         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 404                 ol_with_threads=posix
 405                 ol_cv_pthread_create=yes
 406         fi
 407 fi
 408
 409 if test -z "${CC}"; then
 410         AC_CHECK_PROGS(CC,cc)
 411 fi
 412
 413 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 414 dnl (for now, let autoconf sort this out)
 415 dnl CFLAGS=${CFLAGS-""}
 416
 417 AM_PROG_LIBTOOL
 418 dnl AC_PROG_MAKE_SET
 419
 420 AC_PROG_AWK
 421 OL_PROG_LN_H
 422 AC_PROG_LN_S
 423
 424 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 425         LN_S="$LN_H"
 426 fi
 427
 428 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 429         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 430 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 431 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 432
 433 ol_link_modules=no
 434 if test $ol_enable_modules != no ; then
 435         AC_PATH_PROG(GLIBCONFIG, glib-config)
 436
 437         if test "no$GLIBCONFIG" = "no" ; then
 438                 if test $ol_enable_modules = yes ; then
 439                         AC_MSG_ERROR([could not locate glib-config])
 440                 fi
 441
 442         else
 443                 SLAPD_MODULES_VERSION="`$GLIBCONFIG --version gmodule`"
 444                 SLAPD_MODULES_CPPFLAGS="`$GLIBCONFIG --cflags gmodule`"
 445                 SLAPD_MODULES_LDFLAGS="`$GLIBCONFIG --libs gmodule`"
 446
 447                 dnl should check glib version
 448                 ol_link_modules=yes
 449         fi
 450 else
 451         ol_with_bdb2_module=static
 452         ol_with_ldap_module=static
 453         ol_with_ldbm_module=static
 454         ol_with_passwd_module=static
 455         ol_with_perl_module=static
 456         ol_with_shell_module=static
 457         ol_with_tcl_module=static
 458 fi
 459
 460 ol_link_perl=no
 461 if test $ol_enable_perl != no ; then
 462         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 463
 464         if test "no$PERLBIN" = "no" ; then
 465                 if test $ol_enable_perl = yes ; then
 466                         AC_MSG_ERROR([could not locate perl])
 467                 fi
 468
 469         else
 470                 SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 471                 SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 472
 473                 dnl should check perl version
 474                 ol_link_perl=yes
 475         fi
 476 fi
 477
 478 AC_PROG_CPP
 479
 480 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 481         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 482
 483 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 484         AC_MSG_WARN([programs compiled here do run here...])
 485         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 486
 487 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 488         AC_MSG_WARN([programs compiled here do not run here...])
 489         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 490 fi
 491
 492 dnl Checks for UNIX Variants
 493 AC_AIX
 494 AC_ISC_POSIX
 495 AC_MINIX
 496
 497 dnl BeOS requires -lbe -lroot -lnet
 498 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 499
 500 dnl Checks for system services
 501 AC_CYGWIN
 502 AC_MINGW32
 503 AC_EXEEXT
 504 AC_OBJEXT
 505
 506 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 507
 508 dnl OpenLDAP requires STDC features
 509 AM_PROG_CC_STDC
 510 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 511         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 512 fi
 513
 514 dnl AM_C_PROTOTYPES
 515
 516 dnl Check cc depend flags
 517 OL_MKDEPEND
 518 if test "${ol_cv_mkdep}" = no ; then
 519         # this will soon become an error
 520         AC_MSG_WARN([do not know how to generate dependencies])
 521 fi
 522
 523 dnl Checks for libraries
 524
 525 dnl Find socket()
 526 dnl Likely combinations:
 527 dnl             -lsocket [ -lnsl_s | -lnsl ]
 528 dnl             -linet
 529
 530 AC_CHECK_FUNC(socket, :, [
 531 dnl
 532 dnl hopefully we won't include too many libraries
 533 dnl
 534         AC_CHECK_LIB(socket, main)
 535         AC_CHECK_LIB(net, main)
 536         AC_CHECK_LIB(net, socket)
 537         AC_CHECK_LIB(nsl_s, main)
 538         AC_CHECK_LIB(nsl, main)
 539         AC_CHECK_LIB(inet, socket)
 540         AC_CHECK_LIB(gen, main)
 541 ])
 542
 543 dnl Check for resolver routines
 544 AC_CHECK_FUNCS(res_search)
 545 if test $ac_cv_func_res_search = "no" ; then
 546         AC_CHECK_LIB(bind, res_search)
 547         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 548                 AC_DEFINE(HAVE_RES_SEARCH,1)
 549         else
 550                 AC_CHECK_LIB(resolv, res_search)
 551                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 552                         AC_DEFINE(HAVE_RES_SEARCH,1)
 553                 fi
 554         fi
 555 fi
 556
 557 dnl HP-UX requires -lV3
 558 AC_CHECK_LIB(V3, sigset)
 559
 560 AC_CHECK_HEADERS( regex.h )
 561 if test "$ac_cv_header_regex_h" != yes ; then
 562         AC_MSG_ERROR([POSIX regex.h required.])
 563 fi
 564 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 565
 566 OL_POSIX_REGEX
 567 if test "$ol_cv_c_posix_regex" = no ; then
 568         AC_MSG_ERROR([broken POSIX regex!])
 569 fi
 570
 571 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 572
 573 dnl Select arg types
 574 dnl (if this detection becomes permenent, it and the select() detection
 575 dnl should be done before the yielding select test)
 576 AC_FUNC_SELECT_ARGTYPES
 577
 578 # ISODE tests
 579 ol_link_isode=no
 580 if test $ol_enable_ldapd != no ; then
 581         AC_MSG_WARN([ldapd is not supported and may suffer from bit rot.])
 582
 583         dnl look for ISODE libraries
 584         AC_CHECK_LIB(xtpp, main, [
 585                 ol_link_isode=yes
 586                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 587                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 588                 ],:,[-lxtdsap -lxtisode -losi])
 589         AC_CHECK_LIB(dsap, main, [
 590                 ol_link_isode=yes
 591                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 592                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 593                 ],:,[-lisode])
 594         AC_CHECK_LIB(isode, main, [
 595                 ol_link_isode=yes
 596                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 597                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 598                 ],:)
 599 fi
 600
 601 if test $ol_link_isode != no; then
 602         AC_CHECK_LIB(pp, main, [
 603                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 604                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 605                 ],:)
 606
 607         AC_PATH_PROG(PEPSY, pepsy)
 608 fi
 609
 610 dnl
 611 dnl check for kerberos
 612 dnl
 613 ol_link_kerberos=no
 614
 615 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 616         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 617
 618         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 619                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 620                         [-lkrb5 -ldes425])
 621
 622                 if test $have_k5 = yes ; then
 623                         ol_with_kerberos=found
 624                         ol_link_kerberos=yes
 625
 626                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 627
 628                         LIBS="$KRB_LIBS $LIBS"
 629
 630                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 631                                 [ol_cv_var_des_debug], [
 632                                 dnl save the flags
 633                                 save_LIBS="$LIBS"
 634                                 LIBS="$KRB_LIBS $LIBS"
 635                                 AC_TRY_LINK([
 636 #include <kerberosIV/krb.h>
 637 #include <kerberosIV/des.h>
 638 extern int des_debug;
 639 ],[
 640 des_debug = 1;
 641 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 642                                 dnl restore the LIBS
 643                                 LIBS="$save_LIBS"
 644                         ])
 645
 646                         if test $ol_cv_var_des_debug = yes ; then
 647                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 648                                         [define if you have Kerberos des_debug])
 649                         fi
 650
 651                         LIBS="$save_LIBS"
 652                 fi
 653         fi
 654 fi
 655
 656 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 657         AC_CHECK_HEADERS(krb.h des.h)
 658
 659         if test $ac_cv_header_krb_h = yes ; then
 660                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 661
 662                 if test $have_k4 = yes ; then
 663                         ol_with_kerberos=found
 664                         ol_link_kerberos=yes
 665
 666                         KRB_LIBS="-lkrb -ldes"
 667                 fi
 668         fi
 669 fi
 670
 671 if test $ol_link_kerberos = yes ; then
 672         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 673 fi
 674
 675 dnl
 676 dnl Check for SSL/TLS
 677 dnl
 678 ol_link_tls=no
 679 if test $ol_with_tls != no ; then
 680
 681         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 682
 683         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 684                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 685                         [have_ssleay=yes
 686                         need_rsaref=no],
 687                         [have_ssleay=no],
 688                         [-lcrypto])
 689
 690                 if test $have_ssleay = no ; then
 691                         AC_CHECK_LIB(ssl, SSL_library_init,
 692                                 [have_ssleay=yes
 693                                 need_rsaref=no], [have_ssleay=no],
 694                                 [-lcrypto])
 695                 fi
 696
 697                 if test $have_ssleay = no ; then
 698                         AC_CHECK_LIB(ssl, ssl3_accept,
 699                                 [have_ssleay=yes
 700                                 need_rsaref=yes], [have_ssleay=no],
 701                                 [-lcrypto -lRSAglue -lrsaref])
 702                 fi
 703
 704                 if test $have_ssleay = yes ; then
 705                         ol_with_tls=found
 706                         ol_link_tls=yes
 707
 708                         AC_DEFINE(HAVE_SSLEAY, 1,
 709                                 [define if you have SSLeay or OpenSSL])
 710
 711                         if test $need_rsaref = yes; then
 712                                 AC_DEFINE(HAVE_RSAREF, 1,
 713                                         [define if you have RSAref])
 714
 715                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 716                         else
 717                                 TLS_LIBS="-lssl -lcrypto"
 718                         fi
 719                 fi
 720         fi
 721 fi
 722
 723 if test $ol_link_tls = yes ; then
 724         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 725 fi
 726
 727 dnl Tests for reentrant functions necessary to build a
 728 dnl thread_safe -lldap.
 729 AC_CHECK_FUNCS(         \
 730         ctime_r                 \
 731         gethostbyname_r gethostbyaddr_r \
 732 )
 733
 734 if test "$ac_cv_func_ctime_r" = no ; then
 735         ol_cv_func_ctime_r_nargs=0
 736 else
 737         OL_FUNC_CTIME_R_NARGS
 738 dnl     OL_FUNC_CTIME_R_TYPE
 739 fi
 740
 741 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 742         OL_FUNC_GETHOSTBYNAME_R_NARGS
 743 else
 744         ol_cv_func_gethostbyname_r_nargs=0
 745 fi
 746
 747 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 748         OL_FUNC_GETHOSTBYADDR_R_NARGS
 749 else
 750         ol_cv_func_gethostbyaddr_r_nargs=0
 751 fi
 752
 753 if test "$ac_cv_func_ctime_r" = yes \
 754         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 755         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 756         -a "$ac_cv_func_gethostbyname_r" = yes \
 757         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 758         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 759         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 760         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 761         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 762         ; then
 763
 764         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 765 fi
 766
 767 ol_link_threads=no
 768 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 769         -o $ol_with_threads = posix ; then
 770
 771         AC_CHECK_HEADERS(pthread.h sched.h)
 772
 773         if test $ac_cv_header_pthread_h = yes ; then
 774                 OL_POSIX_THREAD_VERSION
 775
 776                 if test $ol_cv_pthread_version = final ; then
 777                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 778                                 [define if pthreads API compatible with final spec])
 779                 elif test $ol_cv_pthread_version = draft4 ; then
 780                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 781                                 [define if pthreads API compatible with draft4 spec])
 782                 else
 783                         AC_MSG_ERROR([unknown pthread version])
 784                 fi
 785
 786                 # consider threads found
 787                 ol_with_threads=found
 788
 789                 OL_HEADER_LINUX_THREADS
 790
 791                 dnl Now the hard part, how to link?
 792                 dnl
 793                 dnl currently supported checks:
 794                 dnl
 795                 dnl Check for no flags
 796                 dnl     pthread_create() in $LIBS
 797                 dnl
 798                 dnl Check special pthread (final) flags
 799                 dnl     pthread_create() with -mt (Solaris)
 800                 dnl     pthread_create() with -kthread (FreeBSD)
 801                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 802                 dnl     pthread_create() with -pthreads (?)
 803                 dnl     pthread_create() with -thread (?)
 804                 dnl
 805                 dnl Check pthread (final) libraries
 806                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 807                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 808                 dnl     (skipped) pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 809                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
 810                 dnl     pthread_create() in -lpthread (many)
 811                 dnl     pthread_create() in -lc_r (FreeBSD)
 812                 dnl
 813                 dnl Check pthread (draft4) flags (depreciated)
 814                 dnl     pthread_create() with -threads (OSF/1)
 815                 dnl
 816                 dnl Check pthread (draft4) libraries (depreciated)
 817                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 818                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 819                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 820                 dnl     pthread_create() in -lpthreads (many)
 821                 dnl
 822
 823                 dnl pthread_create in $LIBS
 824                 AC_MSG_CHECKING([for pthread_create in default libraries])
 825                 AC_CACHE_VAL(ol_cv_pthread_create,[
 826                 AC_TRY_RUN([
 827 #include <pthread.h>
 828 #ifndef NULL
 829 #define NULL (void*)0
 830 #endif
 831
 832 static void *task(p)
 833         void *p;
 834 {
 835         return (void *) (p == NULL);
 836 }
 837
 838 int main(argc, argv)
 839         int argc;
 840         char **argv;
 841 {
 842         pthread_t t;
 843         int status;
 844
 845         /* make sure pthread_create() isn't just a stub */
 846 #if HAVE_PTHREADS_D4
 847         status = pthread_create(&t, pthread_attr_default, task, NULL);
 848 #else
 849         status = pthread_create(&t, NULL, task, NULL);
 850 #endif
 851
 852         if( status ) return status;
 853
 854         /* make sure pthread_detach() isn't just a stub */
 855 #if HAVE_PTHREADS_D4
 856         status = pthread_detach( &t );
 857 #else
 858         status = pthread_detach( t );
 859 #endif
 860
 861         if( status ) return status;
 862
 863         return status;
 864 }
 865 ],
 866                         [ol_cv_pthread_create=yes],
 867                         [ol_cv_pthread_create=no],
 868                         [dnl assume yes
 869                         ol_cv_pthread_create=yes])])
 870                 AC_MSG_RESULT($ol_cv_pthread_create)
 871
 872                 if test $ol_cv_pthread_create != no ; then
 873                         ol_link_threads=posix
 874                         ol_link_pthreads=""
 875                 fi
 876
 877                 OL_PTHREAD_TRY_LINK([-mt],              [ol_cv_pthread_mt])
 878                 OL_PTHREAD_TRY_LINK([-kthread], [ol_cv_pthread_kthread])
 879                 OL_PTHREAD_TRY_LINK([-pthread], [ol_cv_pthread_pthread])
 880                 OL_PTHREAD_TRY_LINK([-pthreads],[ol_cv_pthread_pthreads])
 881                 OL_PTHREAD_TRY_LINK([-thread],  [ol_cv_pthread_thread])
 882
 883                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc -lc_r],
 884                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
 885                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc],
 886                         [ol_cv_pthread_lpthread_lmach_lexc])
 887 dnl             OL_PTHREAD_TRY_LINK([-lpthread -lexc],
 888 dnl                     [ol_cv_pthread_lpthread_lexc])
 889
 890                 OL_PTHREAD_TRY_LINK([-lpthread -Wl,-woff,85],
 891                         [ol_cv_pthread_lib_lpthread_woff])
 892
 893                 OL_PTHREAD_TRY_LINK([-lpthread],[ol_cv_pthread_lpthread])
 894                 OL_PTHREAD_TRY_LINK([-lc_r],    [ol_cv_pthread_lc_r])
 895
 896                 OL_PTHREAD_TRY_LINK([-threads], [ol_cv_pthread_threads])
 897
 898                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc -lc_r],
 899                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
 900                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc],
 901                         [ol_cv_pthread_lpthreads_lmach_lexc])
 902                 OL_PTHREAD_TRY_LINK([-lpthreads -lexc],
 903                         [ol_cv_pthread_lpthreads_lexc])
 904
 905                 OL_PTHREAD_TRY_LINK([-lpthreads],       [ol_cv_pthread_lib_lpthreads])
 906
 907                 if test $ol_link_threads != no ; then
 908                         AC_DEFINE(HAVE_PTHREADS,1,
 909                                 [define if you have POSIX Threads])
 910
 911                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
 912
 913                         dnl save flags
 914                         save_CPPFLAGS="$CPPFLAGS"
 915                         save_LIBS="$LIBS"
 916                         LIBS="$LTHREAD_LIBS $LIBS"
 917
 918                         dnl All POSIX Thread (final) implementations should have
 919                         dnl sched_yield instead of pthread yield.
 920                         dnl check for both
 921                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 922
 923                         if test $ac_cv_func_sched_yield = no -a \
 924                                 $ac_cv_func_pthread_yield = no ; then
 925                                 dnl Digital UNIX has sched_yield() in -lrt
 926                                 AC_CHECK_LIB(rt, sched_yield,
 927                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 928                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 929                                         ac_cv_func_sched_yield=yes],
 930                                         [ac_cv_func_sched_yield=no])
 931                         fi
 932                         if test $ac_cv_func_sched_yield = no -a \
 933                                 $ac_cv_func_pthread_yield = no ; then
 934                                 dnl Solaris has sched_yield() stub in -lposix4
 935                                 dnl but we'll use thr_yield instead.
 936                                 AC_CHECK_FUNCS(thr_yield)
 937                         fi
 938                         if test $ac_cv_func_sched_yield = no -a \
 939                                 $ac_cv_func_pthread_yield = no -a \
 940                                 "$ac_cv_func_thr_yield" = no ; then
 941                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 942                         fi
 943
 944                         dnl Check functions for compatibility
 945                         AC_CHECK_FUNCS(pthread_kill)
 946
 947                         dnl Check for pthread_detach with <pthread.h> inclusion
 948                         dnl as it's symbol may have been mangled.
 949                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
 950                                 [ol_cv_func_pthread_detach], [
 951                                 dnl save the flags
 952                                 AC_TRY_LINK([
 953 #include <pthread.h>
 954 #ifndef NULL
 955 #define NULL (void*)0
 956 #endif
 957 ],
 958                                         [pthread_detach(NULL);],
 959                                         [ol_cv_func_pthread_detach=yes],
 960                                         [ol_cv_func_pthread_detach=no])
 961                         ])
 962
 963                         if test $ol_cv_func_pthread_detach = no ; then
 964                                 AC_MSG_ERROR([could not locate pthread_detach()])
 965                         fi
 966
 967                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
 968                                 [define if you have pthread_detach function])
 969
 970                         dnl Check for setconcurreny functions
 971                         AC_CHECK_FUNCS( \
 972                                 pthread_setconcurrency \
 973                                 pthread_getconcurrency \
 974                                 thr_setconcurrency \
 975                                 thr_getconcurrency \
 976                         )
 977
 978                         OL_SYS_LINUX_THREADS
 979                         OL_LINUX_THREADS
 980
 981                         if test $ol_cv_linux_threads = error; then
 982                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
 983                         fi
 984
 985                         AC_MSG_CHECKING([if pthread_create() works])
 986                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 987                         AC_TRY_RUN([
 988 #include <pthread.h>
 989 #ifndef NULL
 990 #define NULL (void*)0
 991 #endif
 992
 993 static void *task(p)
 994         void *p;
 995 {
 996         return (void *) (p == NULL);
 997 }
 998
 999 int main(argc, argv)
1000         int argc;
1001         char **argv;
1002 {
1003         pthread_t t;
1004 #if HAVE_PTHREADS_D4
1005         exit(pthread_create(&t, pthread_attr_default, task, NULL));
1006 #else
1007         exit(pthread_create(&t, NULL, task, NULL));
1008 #endif
1009 }
1010 ],
1011                                 [ol_cv_pthread_create_works=yes],
1012                                 [ol_cv_pthread_create_works=no],
1013                                 [dnl assume yes
1014                                 ol_cv_pthread_create_works=yes])])
1015                         AC_MSG_RESULT($ol_cv_pthread_create_works)
1016
1017                         if test $ol_cv_pthread_create_works = no ; then
1018                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1019                         fi
1020
1021                         dnl Check if select causes an yield
1022                         if test $ol_with_yielding_select = auto ; then
1023                                 AC_MSG_CHECKING([if select yields when using pthreads])
1024                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
1025                                 AC_TRY_RUN([
1026 #include <sys/types.h>
1027 #include <sys/time.h>
1028 #include <unistd.h>
1029 #include <pthread.h>
1030 #ifndef NULL
1031 #define NULL (void*) 0
1032 #endif
1033
1034 static int fildes[2];
1035
1036 static void *task(p)
1037         void *p;
1038 {
1039         int i;
1040         struct timeval tv;
1041
1042         fd_set rfds;
1043
1044         tv.tv_sec=10;
1045         tv.tv_usec=0;
1046
1047         FD_ZERO(&rfds);
1048         FD_SET(fildes[0], &rfds);
1049
1050         /* we're not interested in any fds */
1051         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1052
1053         if(i < 0) {
1054                 perror("select");
1055                 exit(10);
1056         }
1057
1058         exit(0); /* if we exit here, the select blocked the whole process */
1059 }
1060
1061 int main(argc, argv)
1062         int argc;
1063         char **argv;
1064 {
1065         pthread_t t;
1066
1067         /* create a pipe to select */
1068         if(pipe(&fildes[0])) {
1069                 perror("select");
1070                 exit(1);
1071         }
1072
1073 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1074         (void) pthread_setconcurrency(2);
1075 #else
1076 #ifdef HAVE_THR_SETCONCURRENCY
1077         /* Set Solaris LWP concurrency to 2 */
1078         thr_setconcurrency(2);
1079 #endif
1080 #endif
1081
1082 #if HAVE_PTHREADS_D4
1083         pthread_create(&t, pthread_attr_default, task, NULL);
1084 #else
1085         pthread_create(&t, NULL, task, NULL);
1086 #endif
1087
1088 #if HAVE_SCHED_YIELD
1089         sched_yield();  /* make sure task runs first */
1090 #else
1091 #ifdef HAVE_PTHREAD_YIELD
1092         pthread_yield();        /* make sure task runs first */
1093 #endif
1094 #endif
1095
1096         exit(2);
1097 }],
1098                                 [ol_cv_pthread_select_yields=no],
1099                                 [ol_cv_pthread_select_yields=yes], [
1100                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
1101                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
1102
1103                                 if test $ol_cv_pthread_select_yields = yes ; then
1104                                         ol_with_yielding_select=yes
1105                                 fi
1106                         fi
1107
1108                         dnl restore flags
1109                         CPPFLAGS="$save_CPPFLAGS"
1110                         LIBS="$save_LIBS"
1111                 else
1112                         AC_MSG_ERROR([could not link with POSIX Threads])
1113                 fi
1114         fi
1115
1116         if test $ol_with_threads = posix ; then
1117                 AC_MSG_ERROR([could not locate POSIX Threads])
1118         fi
1119 fi
1120
1121 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1122         -o $ol_with_threads = mach ; then
1123
1124         dnl check for Mach CThreads
1125         AC_CHECK_HEADERS(mach/cthreads.h)
1126         if test $ac_cv_header_mach_cthreads_h = yes ; then
1127                 ol_with_threads=found
1128
1129                 dnl check for cthread support in current $LIBS
1130                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1131
1132                 if test $ol_link_threads = no ; then
1133                         dnl try -all_load
1134                         dnl this test needs work
1135                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1136                                 [ol_cv_cthread_all_load], [
1137                                 dnl save the flags
1138                                 save_LIBS="$LIBS"
1139                                 LIBS="-all_load $LIBS"
1140                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1141                                         cthread_fork((void *)0, (void *)0);
1142                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1143                                 dnl restore the LIBS
1144                                 LIBS="$save_LIBS"
1145                         ])
1146
1147                         if test $ol_cv_cthread_all_load = yes ; then
1148                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1149                                 ol_link_threads=mach
1150                         fi
1151                 fi
1152
1153                 if test $ol_link_threads != no ; then
1154                         : check for cthread specific functionality here
1155                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1156                                 [define if you have Mach Cthreads])
1157                 else
1158                         AC_MSG_ERROR([could not link with Mach CThreads])
1159                 fi
1160         fi
1161
1162         if test $ol_with_threads = mach ; then
1163                 AC_MSG_ERROR([could not locate Mach CThreads])
1164         fi
1165 fi
1166
1167 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1168         -o $ol_with_threads = lwp ; then
1169
1170         dnl check for SunOS5 LWP
1171         AC_CHECK_HEADERS(thread.h synch.h)
1172         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1173                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1174
1175                 if test $have_thr = yes ; then
1176                         AC_DEFINE(HAVE_THR,1,
1177                                 [if you have Solaris LWP (thr) package])
1178                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1179                         ol_link_threads=thr
1180
1181                         if test $ol_with_yielding_select = auto ; then
1182                                 ol_with_yielding_select=yes
1183                         fi
1184
1185                         dnl Check for setconcurreny functions
1186                         AC_CHECK_FUNCS( \
1187                                 thr_setconcurrency \
1188                                 thr_getconcurrency \
1189                         )
1190                 fi
1191         fi
1192
1193         dnl check for SunOS4 LWP
1194         AC_CHECK_HEADERS(lwp/lwp.h)
1195         if test $ac_cv_header_lwp_lwp_h = yes ; then
1196                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1197
1198                 if test $have_lwp = yes ; then
1199                         AC_DEFINE(HAVE_LWP,1,
1200                                 [if you have SunOS LWP package])
1201                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1202                         ol_link_threads=lwp
1203
1204                         if test $ol_with_yielding_select = auto ; then
1205                                 ol_with_yielding_select=no
1206                         fi
1207                 fi
1208         fi
1209 fi
1210
1211 if test $ol_with_yielding_select = yes ; then
1212         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1213                 [define if select implicitly yields])
1214 fi
1215
1216 if test $ol_with_threads = manual ; then
1217         dnl User thinks he can manually configure threads.
1218         ol_link_threads=yes
1219
1220         AC_MSG_WARN([thread defines and link options must be set manually])
1221
1222         AC_CHECK_HEADERS(pthread.h sched.h)
1223         AC_CHECK_FUNCS(sched_yield pthread_yield)
1224         OL_HEADER_LINUX_THREADS
1225
1226         AC_CHECK_HEADERS(mach/cthreads.h)
1227         AC_CHECK_HEADERS(lwp/lwp.h)
1228         AC_CHECK_HEADERS(thread.h synch.h)
1229 fi
1230
1231 if test $ol_link_threads != no ; then
1232         dnl needed to get reentrant/threadsafe versions
1233         dnl
1234         AC_DEFINE(REENTRANT,1)
1235         AC_DEFINE(_REENTRANT,1)
1236         AC_DEFINE(THREAD_SAFE,1)
1237         AC_DEFINE(_THREAD_SAFE,1)
1238         AC_DEFINE(THREADSAFE,1)
1239         AC_DEFINE(_THREADSAFE,1)
1240         AC_DEFINE(_SGI_MP_SOURCE,1)
1241
1242         dnl The errno declaration may dependent upon _REENTRANT.
1243         dnl If it does, we must link with thread support.
1244         AC_CACHE_CHECK([for thread specific errno],
1245                 [ol_cv_errno_thread_specific], [
1246                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1247                         [ol_cv_errno_thread_specific=yes],
1248                         [ol_cv_errno_thread_specific=no])
1249         ])
1250
1251         dnl The h_errno declaration may dependent upon _REENTRANT.
1252         dnl If it does, we must link with thread support.
1253         AC_CACHE_CHECK([for thread specific h_errno],
1254                 [ol_cv_h_errno_thread_specific], [
1255                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1256                         [ol_cv_h_errno_thread_specific=yes],
1257                         [ol_cv_h_errno_thread_specific=no])
1258         ])
1259
1260         if test $ol_cv_errno_thread_specific != yes \
1261                 -o $ol_cv_h_errno_thread_specific != yes ; then
1262                 LIBS="$LTHREAD_LIBS $LIBS"
1263                 LTHREAD_LIBS=""
1264         fi
1265
1266 dnl When in thread environment, use
1267 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1268 dnl                     || defined( HAVE_FUNC_R )
1269 dnl                     func_r(...);
1270 dnl             #else
1271 dnl             #       if defined( HAVE_THREADS )
1272 dnl                             /* lock */
1273 dnl             #       endif
1274 dnl                             func(...);
1275 dnl             #       if defined( HAVE_THREADS )
1276 dnl                             /* unlock */
1277 dnl             #       endif
1278 dnl             #endif
1279 dnl
1280 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1281 dnl             _POSIX_REENTRANT_FUNCTIONS
1282 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1283 dnl             _POSIX_THREADSAFE_FUNCTIONS
1284 dnl
1285 dnl             and is currently defined in lthread.h
1286 dnl
1287 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1288 dnl
1289 dnl libldap/*.c should only include <lthread.h> iff
1290 dnl LDAP_R_COMPILE is defined.  ie:
1291 dnl             #ifdef LDAP_R_COMPILE
1292 dnl             #       include LDAP_R_COMPILE
1293 dnl             #endif
1294 dnl
1295 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1296 dnl specifically for compiling the threadsafe version of
1297 dnl     the ldap library (-lldap_r).
1298 dnl
1299 dnl     dnl check for reentrant/threadsafe functions
1300 dnl     dnl
1301 dnl     dnl note: these should only be used when linking
1302 dnl     dnl       with $LTHREAD_LIBS
1303 dnl     dnl
1304 dnl     save_CPPFLAGS="$CPPFLAGS"
1305 dnl     save_LIBS="$LIBS"
1306 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1307 dnl     AC_CHECK_FUNCS( \
1308 dnl             gmtime_r \
1309 dnl             gethostbyaddr_r gethostbyname_r \
1310 dnl             feof_unlocked unlocked_feof \
1311 dnl             putc_unlocked unlocked_putc \
1312 dnl             flockfile ftrylockfile \
1313 dnl     )
1314 dnl     CPPFLAGS="$save_CPPFLAGS"
1315 dnl     LIBS="$save_LIBS"
1316 fi
1317
1318 if test $ol_link_threads = no ; then
1319         if test $ol_with_threads = yes ; then
1320                 AC_MSG_ERROR([no suitable thread support])
1321         fi
1322
1323         if test $ol_with_threads = auto ; then
1324                 AC_MSG_WARN([no suitable thread support, disabling threads])
1325                 ol_with_threads=no
1326         fi
1327
1328         AC_DEFINE(NO_THREADS,1,
1329                 [define if you have (or want) no threads])
1330         LTHREAD_LIBS=""
1331 fi
1332
1333 if test $ol_link_threads != no ; then
1334         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1335 fi
1336
1337 dnl ----------------------------------------------------------------
1338
1339 ol_link_ldbm=no
1340 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1341         OL_BERKELEY_DB2
1342
1343         if test $ol_cv_berkeley_db2 = yes ; then
1344                 ol_link_ldbm=db2
1345                 ol_with_ldbm_api=db2
1346
1347                 if test $ol_with_ldbm_type = hash ; then
1348                         AC_DEFINE(LDBM_USE_DBHASH,1)
1349                 else
1350                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1351                 fi
1352
1353                 dnl $ol_cv_lib_db2 should be yes or -ldb
1354                 dnl (it could be no, but that would be an error
1355                 if test $ol_cv_lib_db2 != yes ; then
1356                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1357                 fi
1358         fi
1359 fi
1360
1361 ol_link_bdb2=no
1362 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1363         ol_link_bdb2=yes
1364 fi
1365
1366 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1367         OL_BERKELEY_DB
1368
1369         if test $ol_cv_berkeley_db = yes ; then
1370                 ol_link_ldbm=db
1371                 ol_with_ldbm_api=db
1372
1373                 if test $ol_with_ldbm_type = hash ; then
1374                         AC_DEFINE(LDBM_USE_DBHASH,1)
1375                 else
1376                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1377                 fi
1378
1379                 dnl $ol_cv_lib_db should be yes or -ldb
1380                 dnl (it could be no, but that would be an error
1381                 if test $ol_cv_lib_db != yes ; then
1382                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1383                 fi
1384         fi
1385 fi
1386
1387 if test $ol_with_ldbm_api = manual ; then
1388         dnl User thinks he can manually configure LDBM api.
1389         ol_link_ldbm=yes
1390
1391         AC_MSG_WARN([LDBM defines and link options must be set manually])
1392
1393         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1394 fi
1395
1396 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1397         AC_MSG_WARN(Could not find LDBM with BTREE support)
1398         ol_with_ldbm_api=none
1399 fi
1400
1401 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1402         OL_MDBM
1403
1404         if test $ol_cv_mdbm = yes ; then
1405                 ol_link_ldbm=mdbm
1406                 ol_with_ldbm_api=mdbm
1407                 if test $ol_cv_lib_mdbm != yes ; then
1408                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1409                 fi
1410         fi
1411 fi
1412
1413 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1414         OL_GDBM
1415
1416         if test $ol_cv_gdbm = yes ; then
1417                 ol_link_ldbm=gdbm
1418                 ol_with_ldbm_api=gdbm
1419
1420                 if test $ol_cv_lib_gdbm != yes ; then
1421                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1422                 fi
1423         fi
1424 fi
1425
1426 if test $ol_with_ldbm_api = auto ; then
1427         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1428 elif test $ol_with_ldbm_api = ndbm ; then
1429         OL_NDBM
1430
1431         if test $ol_cv_ndbm = yes ; then
1432                 ol_link_ldbm=ndbm
1433                 ol_with_ldbm_api=ndbm
1434
1435                 if test $ol_cv_lib_ndbm != yes ; then
1436                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1437                 fi
1438         fi
1439 fi
1440
1441 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1442         AC_MSG_WARN(could not find suitable LDBM backend)
1443         if test $ol_enable_ldbm = yes ; then
1444                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1445         fi
1446
1447         AC_MSG_WARN(disabling LDBM)
1448         ol_enable_ldbm=no
1449 fi
1450
1451 if test $ol_enable_wrappers != no ; then
1452         AC_CHECK_HEADERS(tcpd.h)
1453
1454         if test $ac_cv_header_tcpd_h != yes ; then
1455                 have_wrappers=no
1456         else
1457                 AC_CHECK_LIB(wrap, main,
1458                         [have_wrappers=yes], [have_wrappers=no])
1459         fi
1460
1461         if test $have_wrappers = yes ; then
1462                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1463                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1464
1465                 dnl We add another check for -lnsl since some libwrap's
1466                 dnl need it, but it isn't always included from above
1467                 AC_CHECK_LIB(nsl, main)
1468         else
1469                 AC_MSG_WARN(could not find -lwrap)
1470                 if test $ol_enable_wrappers = yes ; then
1471                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1472                 fi
1473
1474                 AC_MSG_WARN(disabling wrappers support)
1475                 ol_enable_wrappers=no
1476         fi
1477 fi
1478
1479 if test $ol_enable_syslog != no ; then
1480         AC_CHECK_FUNC(openlog)
1481         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1482                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1483         fi
1484         ol_enable_syslog=$ac_cv_func_openlog
1485 fi
1486
1487 if test $ol_enable_dmalloc != no ; then
1488         AC_CHECK_HEADERS(dmalloc.h)
1489         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1490 fi
1491
1492 if test $ol_enable_tcl != no ; then
1493         AC_CHECK_HEADERS(tcl.h)
1494
1495         if test $ac_cv_header_tcl_h != yes ; then
1496                 have_tcl=no
1497         else
1498                 AC_CHECK_LIB(tcl,main,
1499                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1500                         [have_tcl=no])
1501
1502                 if test $have_tcl != yes; then
1503                         AC_CHECK_LIB(tcl7.6,main,
1504                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1505                                 [have_tcl=no])
1506                 fi
1507
1508                 if test $have_tcl != yes; then
1509                         AC_CHECK_LIB(tcl8.0,main,
1510                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1511                                 [have_tcl=no])
1512                 fi
1513         fi
1514
1515         if test $have_tcl != yes ; then
1516                 AC_MSG_WARN([could not find -ltcl])
1517                 if test $ol_enable_tcl = yes ; then
1518                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1519                 fi
1520
1521                 ol_enable_tcl=no
1522         fi
1523 fi
1524
1525 # ud needs termcap (should insert check here)
1526 ol_link_termcap=no
1527 AC_CHECK_HEADERS(termcap.h ncurses.h)
1528
1529 if test $ol_link_termcap = no ; then
1530         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1531         if test $have_termcap = yes ; then
1532                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1533                 ol_link_termcap=yes
1534                 TERMCAP_LIBS=-ltermcap
1535         fi
1536 fi
1537
1538 if test $ol_link_termcap = no ; then
1539         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1540         if test $have_ncurses = yes ; then
1541                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1542                 ol_link_termcap=yes
1543                 TERMCAP_LIBS=-lncurses
1544         fi
1545 fi
1546
1547 if test $ol_link_termcap = no ; then
1548         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1549         TERMCAP_LIBS=
1550 fi
1551
1552 dnl
1553 dnl Check for GNU readline
1554 dnl
1555 ol_link_readline=no
1556 if test $ol_with_readline != no ; then
1557         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1558
1559         if test $ac_cv_header_readline_readline_h = yes ; then
1560                 save_LIBS="$LIBS"
1561                 LIBS="$TERMCAP_LIBS $LIBS"
1562                 AC_CHECK_LIB(readline, readline,
1563                         [have_readline=yes], [have_readline=no])
1564                 LIBS="$save_LIBS"
1565
1566                 if test $have_readline = yes ; then
1567                         ol_with_readline=found
1568                         ol_link_readline=yes
1569
1570                         READLINE_LIBS="-lreadline"
1571                 fi
1572         fi
1573 fi
1574
1575 if test $ol_link_readline = yes ; then
1576         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1577 fi
1578
1579
1580 # FreeBSD (and others) have crypt(3) in -lcrypt
1581 if test $ol_enable_crypt != no ; then
1582         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1583                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1584                         have_crypt=yes], [have_crypt=no])])
1585
1586         if test $have_crypt = yes ; then
1587                 AC_DEFINE(HAVE_CRYPT,1)
1588         else
1589                 AC_MSG_WARN(could not find crypt)
1590                 if test $ol_enable_crypt = yes ; then
1591                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1592                 fi
1593
1594                 AC_MSG_WARN(disabling crypt support)
1595                 ol_enable_crypt=no
1596         fi
1597 fi
1598
1599 # FreeBSD (and others) have setproctitle(3) in -lutil
1600 if test $ol_enable_proctitle != no ; then
1601         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1602                 AC_CHECK_LIB(util, setproctitle,
1603                         [have_setproctitle=yes
1604                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1605                         [have_setproctitle=no
1606                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1607
1608         if test $have_setproctitle = yes ; then
1609                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1610         fi
1611 fi
1612
1613 dnl ----------------------------------------------------------------
1614 dnl Checks for header files.
1615 OL_HEADER_STDC
1616
1617 if test $ol_cv_header_stdc != yes; then
1618         AC_MSG_WARN([could not locate Standard C compliant headers])
1619 fi
1620
1621 AC_HEADER_DIRENT
1622 AC_HEADER_SYS_WAIT
1623 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1624 if test $am_cv_sys_posix_termios = yes ; then
1625         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1626                 [define if you have POSIX termios])
1627 fi
1628
1629 AC_CHECK_HEADERS(       \
1630         arpa/inet.h             \
1631         arpa/nameser.h  \
1632         assert.h                \
1633         crypt.h                 \
1634         errno.h                 \
1635         fcntl.h                 \
1636         filio.h                 \
1637         getopt.h                \
1638         grp.h                   \
1639         libutil.h               \
1640         limits.h                \
1641         locale.h                \
1642         malloc.h                \
1643         memory.h                \
1644         psap.h                  \
1645         pwd.h                   \
1646         resolv.h                \
1647         sgtty.h                 \
1648         shadow.h                \
1649         stdarg.h                \
1650         stddef.h                \
1651         string.h                \
1652         strings.h               \
1653         sysexits.h              \
1654         sys/file.h              \
1655         sys/filio.h             \
1656         sys/errno.h             \
1657         sys/ioctl.h             \
1658         sys/param.h             \
1659         sys/resource.h  \
1660         sys/select.h    \
1661         sys/socket.h    \
1662         sys/syslog.h    \
1663         sys/time.h              \
1664         sys/types.h             \
1665         syslog.h                \
1666         termios.h               \
1667         unistd.h                \
1668 )
1669
1670 dnl ----------------------------------------------------------------
1671 dnl Checks for typedefs, structures, and compiler characteristics.
1672 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1673 AC_TYPE_MODE_T
1674 AC_TYPE_OFF_T
1675 AC_TYPE_PID_T
1676 AM_TYPE_PTRDIFF_T
1677 AC_TYPE_SIGNAL
1678 OL_TYPE_SIG_ATOMIC_T
1679 AC_TYPE_SIZE_T
1680 OL_TYPE_SOCKLEN_T
1681 AC_STRUCT_ST_BLKSIZE
1682 AC_HEADER_TIME
1683 AC_STRUCT_TM
1684 OL_STRUCT_PASSWD_PW_GECOS
1685 OL_STRUCT_PASSWD_PW_PASSWD
1686
1687 OL_C_UPPER_LOWER
1688 AC_C_CONST
1689 OL_C_VOLATILE
1690
1691 if test $cross_compiling = yes ; then
1692         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1693
1694         AC_DEFINE(LBER_INT_T,long)
1695         AC_DEFINE(LBER_TAG_T,long)
1696         AC_DEFINE(LBER_SOCKET_T,int)
1697
1698 else
1699         AC_C_BIGENDIAN
1700         AC_CHECK_SIZEOF(short)
1701         AC_CHECK_SIZEOF(int)
1702         AC_CHECK_SIZEOF(long)
1703
1704         if test "$ac_cv_sizeof_int" -lt 4 ; then
1705                 AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
1706
1707                 AC_DEFINE(LBER_INT_T,long)
1708                 AC_DEFINE(LBER_TAG_T,long)
1709                 AC_DEFINE(LBER_SOCKET_T,int)
1710         else
1711                 AC_DEFINE(LBER_INT_T,int)
1712                 AC_DEFINE(LBER_TAG_T,long)
1713                 AC_DEFINE(LBER_SOCKET_T,int)
1714         fi
1715 fi
1716
1717 AC_DEFINE(LBER_LEN_T,long)
1718
1719 dnl ----------------------------------------------------------------
1720 dnl Checks for library functions.
1721 AC_FUNC_MEMCMP
1722 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1723 AC_FUNC_STRFTIME
1724 dnl AM_FUNC_STRTOD
1725
1726 dnl we should use vfork instead of fork in a number of places...
1727 dnl AC_FUNC_VFORK
1728 AC_FUNC_VPRINTF
1729
1730 if test $ac_cv_func_vprintf = yes ; then
1731         dnl check for vsnprintf
1732         AC_CHECK_FUNCS(vsnprintf vsprintf)
1733 fi
1734
1735 AC_CHECK_FUNCS(         \
1736         bcopy                   \
1737         closesocket             \
1738         endgrent                \
1739         endpwent                \
1740         flock                   \
1741         getdtablesize   \
1742         getgrgid                \
1743         gethostname             \
1744         getpass                 \
1745         getpwuid                \
1746         getpwnam                \
1747         getspnam                \
1748         gettimeofday    \
1749         initgroups              \
1750         lockf                   \
1751         memcpy                  \
1752         memmove                 \
1753         mkstemp                 \
1754         read                    \
1755         recv                    \
1756         recvfrom                \
1757         setpwfile               \
1758         setgid                  \
1759         setegid                 \
1760         setsid                  \
1761         setuid                  \
1762         seteuid                 \
1763         signal                  \
1764         sigset                  \
1765         snprintf                \
1766         strdup                  \
1767         strerror                \
1768         strpbrk                 \
1769         strrchr                 \
1770         strsep                  \
1771         strstr                  \
1772         strtol                  \
1773         strtoul                 \
1774         strspn                  \
1775         sysconf                 \
1776         waitpid                 \
1777         wait4                   \
1778         write                   \
1779         send                    \
1780         sendto                  \
1781 )
1782
1783 dnl We actually may need to replace more than this.
1784 AC_REPLACE_FUNCS(getopt tempnam)
1785
1786 dnl ----------------------------------------------------------------
1787 # Check Configuration
1788 OL_SYS_ERRLIST
1789
1790 dnl ----------------------------------------------------------------
1791 dnl Sort out defines
1792
1793 if test "$ol_enable_debug" != no ; then
1794         AC_DEFINE(LDAP_DEBUG,1)
1795 fi
1796 if test "$ol_enable_syslog" = yes ; then
1797         AC_DEFINE(LDAP_SYSLOG,1)
1798 fi
1799 if test "$ol_enable_libui" = yes ; then
1800         AC_DEFINE(LDAP_LIBUI,1)
1801 fi
1802 if test "$ol_enable_cache" = no ; then
1803         AC_DEFINE(LDAP_NOCACHE,1)
1804 fi
1805 if test "$ol_enable_dns" != no ; then
1806         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1807 fi
1808 if test "$ol_enable_proctitle" != no ; then
1809         AC_DEFINE(LDAP_PROCTITLE,1)
1810 fi
1811 if test "$ol_enable_referrals" != no ; then
1812         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1813 fi
1814 if test "$ol_enable_cldap" != no ; then
1815         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1816 fi
1817
1818 if test "$ol_enable_crypt" != no ; then
1819         AC_DEFINE(SLAPD_CRYPT,1)
1820 fi
1821 if test "$ol_enable_cleartext" != no ; then
1822         AC_DEFINE(SLAPD_CLEARTEXT,1)
1823 fi
1824 if test "$ol_enable_phonetic" != no ; then
1825         AC_DEFINE(SLAPD_PHONETIC,1)
1826 fi
1827 if test "$ol_enable_rlookups" != no ; then
1828         AC_DEFINE(SLAPD_RLOOKUPS,1)
1829 fi
1830
1831 if test "$ol_link_modules" != no ; then
1832         AC_DEFINE(SLAPD_MODULES,1)
1833         BUILD_SLAPD=yes
1834 fi
1835
1836 if test "$ol_link_bdb2" != no ; then
1837         AC_DEFINE(SLAPD_BDB2,1)
1838         BUILD_SLAPD=yes
1839         BUILD_BDB2=yes
1840         if test "$ol_with_bdb2_module" != static ; then
1841                 AC_DEFINE(SLAPD_BDB2_DYNAMIC,1)
1842                 BUILD_BDB2_DYNAMIC=yes
1843         fi
1844 fi
1845
1846 if test "$ol_enable_ldap" != no ; then
1847         AC_DEFINE(SLAPD_LDAP,1)
1848         BUILD_SLAPD=yes
1849         BUILD_LDAP=yes
1850         if test "$ol_with_ldap_module" != static ; then
1851                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1)
1852                 BUILD_LDAP_DYNAMIC=yes
1853         fi
1854 fi
1855
1856 if test "$ol_link_ldbm" != no ; then
1857         AC_DEFINE(SLAPD_LDBM,1)
1858         BUILD_SLAPD=yes
1859         BUILD_LDBM=yes
1860         if test "$ol_with_ldbm_module" != static ; then
1861                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1)
1862                 BUILD_LDBM_DYNAMIC=yes
1863         fi
1864 fi
1865
1866 if test "$ol_enable_passwd" != no ; then
1867         AC_DEFINE(SLAPD_PASSWD,1)
1868         BUILD_SLAPD=yes
1869         BUILD_PASSWD=yes
1870         if test "$ol_with_passwd_module" != static ; then
1871                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1)
1872                 BUILD_PASSWD_DYNAMIC=yes
1873         fi
1874 fi
1875
1876 if test "$ol_link_perl" != no ; then
1877         AC_DEFINE(SLAPD_PERL,1)
1878         BUILD_SLAPD=yes
1879         BUILD_PERL=yes
1880         if test "$ol_with_perl_module" != static ; then
1881                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1)
1882                 BUILD_PERL_DYNAMIC=yes
1883         fi
1884 fi
1885
1886 if test "$ol_enable_shell" != no ; then
1887         AC_DEFINE(SLAPD_SHELL,1)
1888         BUILD_SLAPD=yes
1889         BUILD_SHELL=yes
1890         if test "$ol_with_shell_module" != static ; then
1891                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1)
1892                 BUILD_SHELL_DYNAMIC=yes
1893         fi
1894 fi
1895
1896 if test "$ol_enable_tcl" != no ; then
1897         AC_DEFINE(SLAPD_TCL,1)
1898         BUILD_SLAPD=yes
1899         BUILD_TCL=yes
1900         if test "$ol_with_tcl_module" != static; then
1901                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1)
1902                 BUILD_TCL_DYNAMIC=yes
1903         fi
1904 fi
1905
1906 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1907         $BUILD_SLAPD = yes ; then
1908         BUILD_SLURPD=yes
1909 fi
1910
1911 if test "$ol_link_isode" != no ; then
1912         BUILD_LDAPD=yes
1913 fi
1914
1915 dnl ----------------------------------------------------------------
1916
1917 AC_SUBST(BUILD_LDAPD)
1918 AC_SUBST(BUILD_SLAPD)
1919   AC_SUBST(BUILD_BDB2)
1920   AC_SUBST(BUILD_LDAP)
1921   AC_SUBST(BUILD_LDBM)
1922   AC_SUBST(BUILD_PASSWD)
1923   AC_SUBST(BUILD_PERL)
1924   AC_SUBST(BUILD_SHELL)
1925   AC_SUBST(BUILD_TCL)
1926   AC_SUBST(BUILD_BDB2_DYNAMIC)
1927   AC_SUBST(BUILD_LDAP_DYNAMIC)
1928   AC_SUBST(BUILD_LDBM_DYNAMIC)
1929   AC_SUBST(BUILD_PASSWD_DYNAMIC)
1930   AC_SUBST(BUILD_PERL_DYNAMIC)
1931   AC_SUBST(BUILD_SHELL_DYNAMIC)
1932   AC_SUBST(BUILD_TCL_DYNAMIC)
1933 AC_SUBST(BUILD_SLURPD)
1934
1935 AC_SUBST(LDAP_LIBS)
1936 AC_SUBST(LDAPD_LIBS)
1937 AC_SUBST(SLAPD_LIBS)
1938 AC_SUBST(SLURPD_LIBS)
1939 AC_SUBST(LDBM_LIBS)
1940 AC_SUBST(LTHREAD_LIBS)
1941 AC_SUBST(LUTIL_LIBS)
1942
1943 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
1944 AC_SUBST(SLAPD_MODULES_LDFLAGS)
1945
1946 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1947 AC_SUBST(SLAPD_PERL_LDFLAGS)
1948
1949 AC_SUBST(KRB_LIBS)
1950 AC_SUBST(READLINE_LIBS)
1951 AC_SUBST(TERMCAP_LIBS)
1952 AC_SUBST(TLS_LIBS)
1953
1954 dnl ----------------------------------------------------------------
1955 dnl final output
1956 dnl
1957
1958 AC_OUTPUT( \
1959 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1960 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1961 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1962 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1963 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1964 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1965 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1966 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1967 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1968 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1969 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1970 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1971 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1972 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1973 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1974 include/Makefile:build/top.mk:include/Makefile.in \
1975 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1976 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1977 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1978 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1979 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1980 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1981 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1982 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1983 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1984 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1985 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1986 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
1987 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/srv.mk \
1988 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1989 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1990 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
1991 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1992 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
1993 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1994 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1995 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1996 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
1997 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
1998 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
1999 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2000 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2001 ,[
2002 date > stamp-h
2003 echo Please \"make depend\" to build dependencies
2004 ])