git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Disable config.cache!
  11 define([AC_CACHE_LOAD], )dnl
  12 define([AC_CACHE_SAVE], )dnl
  13
  14 dnl Configure.in for OpenLDAP
  15 AC_INIT(include/ldap.h)dnl
  16 AC_CONFIG_AUX_DIR(build)dnl
  17 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel])dnl
  18 AC_SUBST(PACKAGE)
  19 AC_SUBST(VERSION)
  20
  21 dnl We use autoconf features new to 2.13.
  22 dnl     aclocal.m4 should be built using aclocal from automake 1.4
  23 AC_PREREQ(2.13)dnl Required Autoconf version
  24
  25 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  26
  27 dnl
  28 dnl Start Args
  29 AC_MSG_CHECKING(configure arguments)
  30 AC_PREFIX_DEFAULT(/usr/local)
  31
  32 top_builddir=`pwd`
  33 AC_SUBST(top_builddir)dnl
  34
  35 ldap_subdir="openldap"
  36
  37 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  38         if test "$withval" = "no"; then
  39                 ldap_subdir=""
  40         elif test "$withval" != "yes"; then
  41                 ldap_subdir="$withval"
  42         fi
  43 ])dnl
  44
  45 AC_SUBST(ldap_subdir)dnl
  46
  47 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  48 dnl ol_enable_syslog=no
  49 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  50 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  51 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  52 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  53 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  54 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  55 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  56         no, [yes no])dnl
  57
  58 dnl General "with" options
  59 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  60
  61 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  62         auto, [auto k5 k4 afs yes no])
  63 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  64         auto, [auto yes no] )
  65 OL_ARG_WITH(threads,[  --with-threads   use threads],
  66         auto, [auto posix mach lwp yes no manual] )
  67 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  68         auto, [auto ssleay openssl yes no] )
  69 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  70         auto, [auto yes no manual] )
  71
  72 dnl Server options
  73
  74 dnl LDAPD OPTIONS
  75 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  76 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  77
  78 dnl SLAPD OPTIONS
  79 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  80 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  81 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  82 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  83 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  84 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
  85 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  86 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  87 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  88
  89 dnl SLAPD Backend options
  90 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
  91 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  92 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  93         [auto db2 db mdbm gdbm ndbm manual])
  94 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  95         [auto btree hash])
  96
  97 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  98 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
  99 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 100 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 101
 102 dnl SLURPD OPTIONS
 103 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
 104 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 105
 106 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 107 AM_ENABLE_STATIC
 108 dnl AM_DISABLE_SHARED
 109 AM_ENABLE_SHARED
 110
 111 dnl General "enable" options
 112 # validate options
 113 if test $ol_enable_dns = yes ; then
 114         if test $ol_enable_referrals = no ; then
 115                 AC_MSG_ERROR([DNS requires --enable-referrals])
 116         fi
 117         if test $ol_enable_referrals = auto ; then
 118                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 119                 ol_enable_referrals=yes
 120         fi
 121 fi
 122
 123 if test $ol_enable_slapd = no ; then
 124         dnl SLAPD was specificallly disabled
 125         if test $ol_enable_bdb2 = yes ; then
 126                 AC_MSG_WARN([slapd disabled, ignoring --enable_bdb2 argument])
 127         fi
 128         if test $ol_enable_ldbm = yes ; then
 129                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 130         fi
 131         if test $ol_enable_passwd = yes ; then
 132                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 133         fi
 134         if test $ol_enable_perl = yes ; then
 135                 AC_MSG_WARN([slapd disabled, ignoring --enable_perl argument])
 136         fi
 137         if test $ol_enable_shell = yes ; then
 138                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 139         fi
 140         if test $ol_enable_tcl = yes ; then
 141                 AC_MSG_WARN([slapd disabled, ignoring --enable_tcl argument])
 142         fi
 143         if test $ol_enable_aclgroups = yes ; then
 144                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 145         fi
 146         if test $ol_enable_modules = yes ; then
 147                 AC_MSG_WARN([slapd disabled, ignoring --enable_modules argument])
 148         fi
 149         if test $ol_enable_wrappers = yes ; then
 150                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 151         fi
 152         if test $ol_enable_phonetic = yes ; then
 153                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 154         fi
 155         if test $ol_enable_rlookups = yes ; then
 156                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 157         fi
 158         if test $ol_with_ldbm_api != auto ; then
 159                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 160         fi
 161         if test $ol_with_ldbm_type != auto ; then
 162                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 163         fi
 164         if test $ol_enable_slurpd = yes ; then
 165                 AC_MSG_ERROR([slurpd requires slapd])
 166         fi
 167
 168         # force settings to no
 169         ol_enable_bdb2=no
 170         ol_enable_ldbm=no
 171         ol_enable_passwd=no
 172         ol_enable_perl=no
 173         ol_enable_shell=no
 174         ol_enable_tcl=no
 175
 176         ol_enable_aclgroups=no
 177         ol_enable_modules=no
 178         ol_enable_phonetic=no
 179         ol_enable_rlookups=no
 180         ol_enable_wrappers=no
 181
 182         ol_with_ldbm_api=no
 183         ol_with_ldbm_type=no
 184
 185         ol_enable_slurpd=no
 186
 187 elif test $ol_enable_ldbm = no ; then
 188         dnl SLAPD without LDBM
 189
 190         if test $ol_with_ldbm_api != auto ; then
 191                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 192         fi
 193
 194         if test $ol_with_ldbm_type != auto ; then
 195                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 196         fi
 197
 198         if test $ol_enable_bdb2 = yes ; then
 199                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 200         fi
 201
 202         if test $ol_enable_modules != yes -a \
 203                 $ol_enable_passwd = no -a \
 204                 $ol_enable_perl = no -a \
 205                 $ol_enable_shell = no -a \
 206                 $ol_enable_tcl = no ; then
 207                 AC_MSG_ERROR([slapd requires a backend])
 208         fi
 209
 210         ol_with_ldbm_api=no
 211         ol_with_ldbm_type=no
 212
 213 elif test $ol_enable_bdb2 = yes ; then
 214         dnl SLAPD with BDB2
 215
 216         if test $ol_with_ldbm_api != auto -a \
 217                 $ol_with_ldbm_api != db2 ; then
 218                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 219         fi
 220
 221         ol_with_ldbm_api=db2
 222
 223 else
 224         dnl SLAPD with LDBM
 225
 226         if test $ol_enable_bdb2 != no ; then
 227                 if test $ol_with_ldbm_api != auto -a \
 228                         $ol_with_ldbm_api != db2 ; then
 229                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 230                         ol_enable_bdb2=no
 231                 fi
 232         fi
 233
 234         if test $ol_with_ldbm_api = gdbm -a \
 235                 $ol_with_ldbm_type = btree ; then
 236                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 237         fi
 238         if test $ol_with_ldbm_api = mdbm -a \
 239                 $ol_with_ldbm_type = btree ; then
 240                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 241         fi
 242         if test $ol_with_ldbm_api = ndbm -a \
 243                 $ol_with_ldbm_type = btree ; then
 244                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 245         fi
 246 fi
 247
 248 if test $ol_enable_slurpd = yes ; then
 249         dnl SLURPD was specifically enabled
 250         if test $ol_with_threads = no ; then
 251                 AC_MSG_ERROR([slurpd requires threads])
 252         fi
 253 fi
 254
 255 AC_MSG_RESULT(done)
 256
 257 ## Initialize vars
 258 LDAP_LIBS=
 259 LDBM_LIBS=
 260 LTHREAD_LIBS=
 261 LUTIL_LIBS=
 262
 263 LDAPD_LIBS=
 264 SLAPD_LIBS=
 265 SLURPD_LIBS=
 266
 267 BUILD_LDAPD=no
 268 BUILD_SLAPD=no
 269 BUILD_SLURPD=no
 270
 271 BUILD_BDB2=no
 272 BUILD_LDBM=no
 273 BUILD_PASSWD=no
 274 BUILD_PERL=no
 275 BUILD_SHELL=no
 276 BUILD_TCL=no
 277 BUILD_THREAD=no
 278
 279 SLAPD_MODULES_LDFLAGS=
 280 SLAPD_MODULES_CPPFLAGS=
 281
 282 SLAPD_PERL_LDFLAGS=
 283 SLAPD_PERL_CPPFLAGS=
 284
 285 KRB_LIBS=
 286 READLINE_LIBS=
 287 TERMCAP_LIBS=
 288 TLS_LIBS=
 289
 290 dnl ----------------------------------------------------------------
 291 dnl Checks for programs
 292
 293 AC_PROG_INSTALL
 294
 295 dnl The default compiler is cc (NOT gcc)
 296 CC=${CC-"cc"}
 297 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 298 dnl CFLAGS=${CFLAGS-""}
 299
 300 AM_PROG_LIBTOOL
 301 dnl AC_PROG_MAKE_SET
 302
 303 AC_PROG_AWK
 304 OL_PROG_LN_H
 305 AC_PROG_LN_S
 306
 307 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 308         LN_S="$LN_H"
 309 fi
 310
 311 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 312         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 313 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 314 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 315
 316 ol_link_modules=no
 317 if test $ol_enable_modules != no ; then
 318         AC_PATH_PROG(GLIBCONFIG, glib-config)
 319
 320         if test "no$GLIBCONFIG" = "no" ; then
 321                 if test $ol_enable_modules = yes ; then
 322                         AC_MSG_ERROR([could not locate glib-config])
 323                 fi
 324
 325         else
 326                 SLAPD_MODULES_VERSION="`$GLIBCONFIG --version gmodule`"
 327                 SLAPD_MODULES_CPPFLAGS="`$GLIBCONFIG --cflags gmodule`"
 328                 SLAPD_MODULES_LDFLAGS="`$GLIBCONFIG --libs gmodule`"
 329
 330                 dnl should check glib version
 331                 ol_link_modules=yes
 332         fi
 333 fi
 334
 335 ol_link_perl=no
 336 if test $ol_enable_perl != no ; then
 337         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 338
 339         if test "no$PERLBIN" = "no" ; then
 340                 if test $ol_enable_perl = yes ; then
 341                         AC_MSG_ERROR([could not locate perl])
 342                 fi
 343
 344         else
 345                 SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 346                 SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 347
 348                 dnl should check perl version
 349                 ol_link_perl=yes
 350         fi
 351 fi
 352
 353 AC_PROG_CPP
 354
 355 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 356         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 357
 358 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 359         AC_MSG_WARN([programs compiled here do run here...])
 360         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 361
 362 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 363         AC_MSG_WARN([programs compiled here do not run here...])
 364         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 365 fi
 366
 367 dnl Checks for UNIX Variants
 368 AC_AIX
 369 AC_ISC_POSIX
 370 AC_MINIX
 371
 372 dnl BeOS requires -lbe -lroot -lnet
 373 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot"], :, [-lroot])
 374
 375 dnl Checks for system services
 376 AC_CYGWIN
 377 AC_MINGW32
 378 AC_EXEEXT
 379 AC_OBJEXT
 380
 381 dnl OpenLDAP requires STDC features
 382 AM_PROG_CC_STDC
 383 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 384         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 385 fi
 386
 387 dnl AM_C_PROTOTYPES
 388
 389 dnl Checks for libraries
 390
 391 dnl Find socket()
 392 dnl Likely combinations:
 393 dnl             -lsocket [ -lnsl_s | -lnsl ]
 394 dnl             -linet
 395
 396 AC_CHECK_FUNC(socket, :, [
 397 dnl
 398 dnl hopefully we won't include too many libraries
 399 dnl
 400         AC_CHECK_LIB(socket, main)
 401         AC_CHECK_LIB(net, main)
 402         AC_CHECK_LIB(net, socket)
 403         AC_CHECK_LIB(nsl_s, main)
 404         AC_CHECK_LIB(nsl, main)
 405         AC_CHECK_LIB(inet, socket)
 406         AC_CHECK_LIB(gen, main)
 407 ])
 408
 409 dnl Check for resolver routines
 410 AC_CHECK_FUNCS(res_search)
 411 if test $ac_cv_func_res_search = "no" ; then
 412         AC_CHECK_LIB(bind, res_search)
 413         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 414                 AC_DEFINE(HAVE_RES_SEARCH,1)
 415         else
 416                 AC_CHECK_LIB(resolv, res_search)
 417                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 418                         AC_DEFINE(HAVE_RES_SEARCH,1)
 419                 fi
 420         fi
 421 fi
 422
 423 dnl HP-UX requires -lV3
 424 AC_CHECK_LIB(V3, sigset)
 425
 426 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 427
 428 dnl Select arg types
 429 dnl (if this detection becomes permenent, it and the select() detection
 430 dnl should be done before the yielding select test)
 431 AC_FUNC_SELECT_ARGTYPES
 432
 433 # ISODE tests
 434 ol_link_isode=no
 435 if test $ol_enable_ldapd != no ; then
 436         dnl look for ISODE libraries
 437         AC_CHECK_LIB(xtpp, main, [
 438                 ol_link_isode=yes
 439                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 440                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 441                 ],:,[-lxtdsap -lxtisode -losi])
 442         AC_CHECK_LIB(dsap, main, [
 443                 ol_link_isode=yes
 444                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 445                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 446                 ],:,[-lisode])
 447         AC_CHECK_LIB(isode, main, [
 448                 ol_link_isode=yes
 449                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 450                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 451                 ],:)
 452 fi
 453
 454 if test $ol_link_isode != no; then
 455         AC_CHECK_LIB(pp, main, [
 456                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 457                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 458                 ],:)
 459
 460         AC_PATH_PROG(PEPSY, pepsy)
 461 fi
 462
 463 dnl
 464 dnl check for kerberos
 465 dnl
 466 ol_link_kerberos=no
 467
 468 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 469         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 470
 471         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 472                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 473                         [-lkrb5 -ldes425])
 474
 475                 if test $have_k5 = yes ; then
 476                         ol_with_kerberos=found
 477                         ol_link_kerberos=yes
 478
 479                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 480
 481                         LIBS="$KRB_LIBS $LIBS"
 482
 483                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 484                                 [ol_cv_var_des_debug], [
 485                                 dnl save the flags
 486                                 save_LIBS="$LIBS"
 487                                 LIBS="$KRB_LIBS $LIBS"
 488                                 AC_TRY_LINK([
 489 #include <kerberosIV/krb.h>
 490 #include <kerberosIV/des.h>
 491 extern int des_debug;
 492 ],[
 493 des_debug = 1;
 494 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 495                                 dnl restore the LIBS
 496                                 LIBS="$save_LIBS"
 497                         ])
 498
 499                         if test $ol_cv_var_des_debug = yes ; then
 500                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 501                                         [define if you have Kerberos des_debug])
 502                         fi
 503
 504                         LIBS="$save_LIBS"
 505                 fi
 506         fi
 507 fi
 508
 509 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 510         AC_CHECK_HEADERS(krb.h des.h)
 511
 512         if test $ac_cv_header_krb_h = yes ; then
 513                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 514
 515                 if test $have_k4 = yes ; then
 516                         ol_with_kerberos=found
 517                         ol_link_kerberos=yes
 518
 519                         KRB_LIBS="-lkrb -ldes"
 520                 fi
 521         fi
 522 fi
 523
 524 if test $ol_link_kerberos = yes ; then
 525         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 526 fi
 527
 528 dnl
 529 dnl Check for SSL/TLS
 530 dnl
 531 ol_link_tls=no
 532 if test $ol_with_tls != no ; then
 533
 534         AC_CHECK_HEADERS(ssl.h)
 535
 536         if test $ac_cv_header_ssl_h = yes ; then
 537                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 538                         [have_ssleay=yes
 539                         need_rsaref=no],
 540                         [have_ssleay=no],
 541                         [-lcrypto])
 542
 543                 if test $have_ssleay = no ; then
 544                         AC_CHECK_LIB(ssl, ssl3_accept,
 545                                 [have_ssleay=yes
 546                                 need_rsaref=yes], [have_ssleay=no],
 547                                 [-lcrypto -lRSAglue -lrsaref])
 548                 fi
 549
 550                 if test $have_ssleay = yes ; then
 551                         ol_with_tls=found
 552                         ol_link_tls=yes
 553
 554                         AC_DEFINE(HAVE_SSLEAY, 1,
 555                                 [define if you have SSLeay or OpenSSL])
 556
 557                         if test $need_rsaref = yes; then
 558                                 AC_DEFINE(HAVE_RSAREF, 1,
 559                                         [define if you have RSAref])
 560
 561                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 562                         else
 563                                 TLS_LIBS="-lssl -lcrypto"
 564                         fi
 565                 fi
 566         fi
 567 fi
 568
 569 if test $ol_link_tls = yes ; then
 570         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 571 fi
 572
 573 dnl Tests for reentrant functions necessary to build a
 574 dnl thread_safe -lldap.
 575 AC_CHECK_FUNCS(         \
 576         ctime_r                 \
 577         gethostbyname_r gethostbyaddr_r \
 578 )
 579
 580 if test "$ac_cv_func_ctime_r" = no ; then
 581         ol_cv_func_ctime_r_nargs=0
 582 else
 583         OL_FUNC_CTIME_R_NARGS
 584 dnl     OL_FUNC_CTIME_R_TYPE
 585 fi
 586
 587 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 588         OL_FUNC_GETHOSTBYNAME_R_NARGS
 589 else
 590         ol_cv_func_gethostbyname_r_nargs=0
 591 fi
 592
 593 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 594         OL_FUNC_GETHOSTBYADDR_R_NARGS
 595 else
 596         ol_cv_func_gethostbyaddr_r_nargs=0
 597 fi
 598
 599 if test "$ac_cv_func_ctime_r" = yes \
 600         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 601         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 602         -a "$ac_cv_func_gethostbyname_r" = yes \
 603         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 604         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 605         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 606         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 607         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 608         ; then
 609
 610         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 611 fi
 612
 613 ol_link_threads=no
 614 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 615         -o $ol_with_threads = posix ; then
 616
 617         AC_CHECK_HEADERS(pthread.h sched.h)
 618
 619         if test $ac_cv_header_pthread_h = yes ; then
 620                 OL_POSIX_THREAD_VERSION
 621
 622                 if test $ol_cv_pthread_version = final ; then
 623                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 624                                 [define if pthreads API compatible with final spec])
 625                 elif test $ol_cv_pthread_version = draft4 ; then
 626                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 627                                 [define if pthreads API compatible with draft4 spec])
 628                 else
 629                         AC_MSG_ERROR([unknown pthread version])
 630                 fi
 631
 632                 # consider threads found
 633                 ol_with_threads=found
 634
 635                 OL_HEADER_LINUX_THREADS
 636
 637                 dnl Now the hard part, how to link?
 638                 dnl
 639                 dnl currently supported checks:
 640                 dnl
 641                 dnl Check for no flags
 642                 dnl     pthread_create() in $LIBS
 643                 dnl
 644                 dnl Check special pthread (final) flags
 645                 dnl     pthread_create() with -mt (Solaris)
 646                 dnl     pthread_create() with -kthread (FreeBSD)
 647                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 648                 dnl     pthread_create() with -pthreads (?)
 649                 dnl     pthread_create() with -thread (?)
 650                 dnl
 651                 dnl Check pthread (final) libraries
 652                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 653                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 654                 dnl     (skipped) pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 655                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
 656                 dnl     pthread_create() in -lpthread (many)
 657                 dnl     pthread_create() in -lc_r (FreeBSD)
 658                 dnl
 659                 dnl Check pthread (draft4) flags (depreciated)
 660                 dnl     pthread_create() with -threads (OSF/1)
 661                 dnl
 662                 dnl Check pthread (draft4) libraries (depreciated)
 663                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 664                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 665                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 666                 dnl     pthread_create() in -lpthreads (many)
 667                 dnl
 668
 669                 dnl pthread_create in $LIBS
 670                 AC_MSG_CHECKING([for pthread_create in default libraries])
 671                 AC_CACHE_VAL(ol_cv_pthread_create,[
 672                 AC_TRY_RUN([
 673 #include <pthread.h>
 674 #ifndef NULL
 675 #define NULL (void*)0
 676 #endif
 677
 678 static void *task(p)
 679         void *p;
 680 {
 681         return (void *) (p == NULL);
 682 }
 683
 684 int main(argc, argv)
 685         int argc;
 686         char **argv;
 687 {
 688         pthread_t t;
 689         int status;
 690
 691         /* make sure pthread_create() isn't just a stub */
 692 #if HAVE_PTHREADS_D4
 693         status = pthread_create(&t, pthread_attr_default, task, NULL);
 694 #else
 695         status = pthread_create(&t, NULL, task, NULL);
 696 #endif
 697
 698         if( status ) return status;
 699
 700         /* make sure pthread_detach() isn't just a stub */
 701 #if HAVE_PTHREADS_D4
 702         status = pthread_detach( &t );
 703 #else
 704         status = pthread_detach( t );
 705 #endif
 706
 707         if( status ) return status;
 708
 709         return status;
 710 }
 711 ],
 712                         [ol_cv_pthread_create=yes],
 713                         [ol_cv_pthread_create=no],
 714                         [dnl assume yes
 715                         ol_cv_pthread_create=yes])])
 716                 AC_MSG_RESULT($ol_cv_pthread_create)
 717
 718                 if test $ol_cv_pthread_create != no ; then
 719                         ol_link_threads=posix
 720                         ol_link_pthreads=""
 721                 fi
 722
 723                 OL_PTHREAD_TRY_LINK([-mt],              [ol_cv_pthread_mt])
 724                 OL_PTHREAD_TRY_LINK([-kthread], [ol_cv_pthread_kthread])
 725                 OL_PTHREAD_TRY_LINK([-pthread], [ol_cv_pthread_pthread])
 726                 OL_PTHREAD_TRY_LINK([-pthreads],[ol_cv_pthread_pthreads])
 727                 OL_PTHREAD_TRY_LINK([-thread],  [ol_cv_pthread_thread])
 728
 729                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc -lc_r],
 730                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
 731                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc],
 732                         [ol_cv_pthread_lpthread_lmach_lexc])
 733 dnl             OL_PTHREAD_TRY_LINK([-lpthread -lexc],
 734 dnl                     [ol_cv_pthread_lpthread_lexc])
 735
 736                 OL_PTHREAD_TRY_LINK([-lpthread -Wl,-woff,85],
 737                         [ol_cv_pthread_lib_lpthread_woff])
 738
 739                 OL_PTHREAD_TRY_LINK([-lpthread],[ol_cv_pthread_lpthread])
 740                 OL_PTHREAD_TRY_LINK([-lc_r],    [ol_cv_pthread_lc_r])
 741
 742                 OL_PTHREAD_TRY_LINK([-threads], [ol_cv_pthread_threads])
 743
 744                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc -lc_r],
 745                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
 746                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc],
 747                         [ol_cv_pthread_lpthreads_lmach_lexc])
 748                 OL_PTHREAD_TRY_LINK([-lpthreads -lexc],
 749                         [ol_cv_pthread_lpthreads_lexc])
 750
 751                 OL_PTHREAD_TRY_LINK([-lpthreads],       [ol_cv_pthread_lib_lpthreads])
 752
 753                 if test $ol_link_threads != no ; then
 754                         AC_DEFINE(HAVE_PTHREADS,1,
 755                                 [define if you have POSIX Threads])
 756
 757                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
 758
 759                         dnl save flags
 760                         save_CPPFLAGS="$CPPFLAGS"
 761                         save_LIBS="$LIBS"
 762                         LIBS="$LTHREAD_LIBS $LIBS"
 763
 764                         dnl All POSIX Thread (final) implementations should have
 765                         dnl sched_yield instead of pthread yield.
 766                         dnl check for both
 767                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 768
 769                         if test $ac_cv_func_sched_yield = no -a \
 770                                 $ac_cv_func_pthread_yield = no ; then
 771                                 dnl Digital UNIX has sched_yield() in -lrt
 772                                 AC_CHECK_LIB(rt, sched_yield,
 773                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 774                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 775                                         ac_cv_func_sched_yield=yes],
 776                                         [ac_cv_func_sched_yield=no])
 777                         fi
 778                         if test $ac_cv_func_sched_yield = no -a \
 779                                 $ac_cv_func_pthread_yield = no ; then
 780                                 dnl Solaris has sched_yield() stub in -lposix4
 781                                 dnl but we'll use thr_yield instead.
 782                                 AC_CHECK_FUNCS(thr_yield)
 783                         fi
 784                         if test $ac_cv_func_sched_yield = no -a \
 785                                 $ac_cv_func_pthread_yield = no -a \
 786                                 "$ac_cv_func_thr_yield" = no ; then
 787                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 788                         fi
 789
 790                         dnl Check functions for compatibility
 791                         AC_CHECK_FUNCS(pthread_kill)
 792
 793                         dnl Check for pthread_detach with <pthread.h> inclusion
 794                         dnl as it's symbol may have been mangled.
 795                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
 796                                 [ol_cv_func_pthread_detach], [
 797                                 dnl save the flags
 798                                 AC_TRY_LINK([
 799 #include <pthread.h>
 800 #ifndef NULL
 801 #define NULL (void*)0
 802 #endif
 803 ],
 804                                         [pthread_detach(NULL);],
 805                                         [ol_cv_func_pthread_detach=yes],
 806                                         [ol_cv_func_pthread_detach=no])
 807                         ])
 808
 809                         if test $ol_cv_func_pthread_detach = no ; then
 810                                 AC_MSG_ERROR([could not locate pthread_detach()])
 811                         fi
 812
 813                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
 814                                 [define if you have pthread_detach function])
 815
 816                         dnl Check for setconcurreny functions
 817                         AC_CHECK_FUNCS( \
 818                                 pthread_setconcurrency \
 819                                 pthread_getconcurrency \
 820                                 thr_setconcurrency \
 821                                 thr_getconcurrency \
 822                         )
 823
 824                         OL_SYS_LINUX_THREADS
 825                         OL_LINUX_THREADS
 826
 827                         if test $ol_cv_linux_threads = error; then
 828                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
 829                         fi
 830
 831                         AC_MSG_CHECKING([if pthread_create() works])
 832                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 833                         AC_TRY_RUN([
 834 #include <pthread.h>
 835 #ifndef NULL
 836 #define NULL (void*)0
 837 #endif
 838
 839 static void *task(p)
 840         void *p;
 841 {
 842         return (void *) (p == NULL);
 843 }
 844
 845 int main(argc, argv)
 846         int argc;
 847         char **argv;
 848 {
 849         pthread_t t;
 850 #if HAVE_PTHREADS_D4
 851         exit(pthread_create(&t, pthread_attr_default, task, NULL));
 852 #else
 853         exit(pthread_create(&t, NULL, task, NULL));
 854 #endif
 855 }
 856 ],
 857                                 [ol_cv_pthread_create_works=yes],
 858                                 [ol_cv_pthread_create_works=no],
 859                                 [dnl assume yes
 860                                 ol_cv_pthread_create_works=yes])])
 861                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 862
 863                         if test $ol_cv_pthread_create_works = no ; then
 864                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
 865                         fi
 866
 867                         dnl Check if select causes an yield
 868                         if test $ol_with_yielding_select = auto ; then
 869                                 AC_MSG_CHECKING([if select yields when using pthreads])
 870                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 871                                 AC_TRY_RUN([
 872 #include <sys/types.h>
 873 #include <sys/time.h>
 874 #include <unistd.h>
 875 #include <pthread.h>
 876 #ifndef NULL
 877 #define NULL (void*) 0
 878 #endif
 879
 880 static int fildes[2];
 881
 882 static void *task(p)
 883         void *p;
 884 {
 885         int i;
 886         struct timeval tv;
 887
 888         fd_set rfds;
 889
 890         tv.tv_sec=10;
 891         tv.tv_usec=0;
 892
 893         FD_ZERO(&rfds);
 894         FD_SET(fildes[0], &rfds);
 895
 896         /* we're not interested in any fds */
 897         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 898
 899         if(i < 0) {
 900                 perror("select");
 901                 exit(10);
 902         }
 903
 904         exit(0); /* if we exit here, the select blocked the whole process */
 905 }
 906
 907 int main(argc, argv)
 908         int argc;
 909         char **argv;
 910 {
 911         pthread_t t;
 912
 913         /* create a pipe to select */
 914         if(pipe(&fildes[0])) {
 915                 perror("select");
 916                 exit(1);
 917         }
 918
 919 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 920         (void) pthread_setconcurrency(2);
 921 #else
 922 #ifdef HAVE_THR_SETCONCURRENCY
 923         /* Set Solaris LWP concurrency to 2 */
 924         thr_setconcurrency(2);
 925 #endif
 926 #endif
 927
 928 #if HAVE_PTHREADS_D4
 929         pthread_create(&t, pthread_attr_default, task, NULL);
 930 #else
 931         pthread_create(&t, NULL, task, NULL);
 932 #endif
 933
 934 #if HAVE_SCHED_YIELD
 935         sched_yield();  /* make sure task runs first */
 936 #else
 937 #ifdef HAVE_PTHREAD_YIELD
 938         pthread_yield();        /* make sure task runs first */
 939 #endif
 940 #endif
 941
 942         exit(2);
 943 }],
 944                                 [ol_cv_pthread_select_yields=no],
 945                                 [ol_cv_pthread_select_yields=yes], [
 946                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
 947                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
 948
 949                                 if test $ol_cv_pthread_select_yields = yes ; then
 950                                         ol_with_yielding_select=yes
 951                                 fi
 952                         fi
 953
 954                         dnl restore flags
 955                         CPPFLAGS="$save_CPPFLAGS"
 956                         LIBS="$save_LIBS"
 957                 else
 958                         AC_MSG_ERROR([could not link with POSIX Threads])
 959                 fi
 960         fi
 961
 962         if test $ol_with_threads = posix ; then
 963                 AC_MSG_ERROR([could not locate POSIX Threads])
 964         fi
 965 fi
 966
 967 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 968         -o $ol_with_threads = mach ; then
 969
 970         dnl check for Mach CThreads
 971         AC_CHECK_HEADERS(mach/cthreads.h)
 972         if test $ac_cv_header_mach_cthreads_h = yes ; then
 973                 ol_with_threads=found
 974
 975                 dnl check for cthread support in current $LIBS
 976                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 977
 978                 if test $ol_link_threads = no ; then
 979                         dnl try -all_load
 980                         dnl this test needs work
 981                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 982                                 [ol_cv_cthread_all_load], [
 983                                 dnl save the flags
 984                                 save_LIBS="$LIBS"
 985                                 LIBS="-all_load $LIBS"
 986                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 987                                         cthread_fork((void *)0, (void *)0);
 988                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 989                                 dnl restore the LIBS
 990                                 LIBS="$save_LIBS"
 991                         ])
 992
 993                         if test $ol_cv_cthread_all_load = yes ; then
 994                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 995                                 ol_link_threads=mach
 996                         fi
 997                 fi
 998
 999                 if test $ol_link_threads != no ; then
1000                         : check for cthread specific functionality here
1001                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1002                                 [define if you have Mach Cthreads])
1003                 else
1004                         AC_MSG_ERROR([could not link with Mach CThreads])
1005                 fi
1006         fi
1007
1008         if test $ol_with_threads = mach ; then
1009                 AC_MSG_ERROR([could not locate Mach CThreads])
1010         fi
1011 fi
1012
1013 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1014         -o $ol_with_threads = lwp ; then
1015
1016         dnl check for SunOS5 LWP
1017         AC_CHECK_HEADERS(thread.h synch.h)
1018         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1019                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1020
1021                 if test $have_thr = yes ; then
1022                         AC_DEFINE(HAVE_THR,1,
1023                                 [if you have Solaris LWP (thr) package])
1024                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1025                         ol_link_threads=thr
1026
1027                         if test $ol_with_yielding_select = auto ; then
1028                                 ol_with_yielding_select=yes
1029                         fi
1030
1031                         dnl Check for setconcurreny functions
1032                         AC_CHECK_FUNCS( \
1033                                 thr_setconcurrency \
1034                                 thr_getconcurrency \
1035                         )
1036                 fi
1037         fi
1038
1039         dnl check for SunOS4 LWP
1040         AC_CHECK_HEADERS(lwp/lwp.h)
1041         if test $ac_cv_header_lwp_lwp_h = yes ; then
1042                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1043
1044                 if test $have_lwp = yes ; then
1045                         AC_DEFINE(HAVE_LWP,1,
1046                                 [if you have SunOS LWP package])
1047                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1048                         ol_link_threads=lwp
1049
1050                         if test $ol_with_yielding_select = auto ; then
1051                                 ol_with_yielding_select=no
1052                         fi
1053                 fi
1054         fi
1055 fi
1056
1057 if test $ol_with_yielding_select = yes ; then
1058         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1059                 [define if select implicitly yields])
1060 fi
1061
1062 if test $ol_with_threads = manual ; then
1063         dnl User thinks he can manually configure threads.
1064         ol_link_threads=yes
1065
1066         AC_MSG_WARN([thread defines and link options must be set manually])
1067
1068         AC_CHECK_HEADERS(pthread.h sched.h)
1069         AC_CHECK_FUNCS(sched_yield pthread_yield)
1070         OL_HEADER_LINUX_THREADS
1071
1072         AC_CHECK_HEADERS(mach/cthreads.h)
1073         AC_CHECK_HEADERS(lwp/lwp.h)
1074         AC_CHECK_HEADERS(thread.h synch.h)
1075 fi
1076
1077 if test $ol_link_threads != no ; then
1078         dnl needed to get reentrant/threadsafe versions
1079         dnl
1080         AC_DEFINE(REENTRANT,1)
1081         AC_DEFINE(_REENTRANT,1)
1082         AC_DEFINE(THREAD_SAFE,1)
1083         AC_DEFINE(_THREAD_SAFE,1)
1084         AC_DEFINE(THREADSAFE,1)
1085         AC_DEFINE(_THREADSAFE,1)
1086
1087         dnl The errno declaration may dependent upon _REENTRANT.
1088         dnl If it does, we must link with thread support.
1089         AC_CACHE_CHECK([for thread specific errno],
1090                 [ol_cv_errno_thread_specific], [
1091                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1092                         [ol_cv_errno_thread_specific=yes],
1093                         [ol_cv_errno_thread_specific=no])
1094         ])
1095
1096         if test $ol_cv_errno_thread_specific != yes ; then
1097                 LIBS="$LTHREAD_LIBS $LIBS"
1098                 LTHREAD_LIBS=""
1099         fi
1100
1101 dnl When in thread environment, use
1102 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1103 dnl                     || defined( HAVE_FUNC_R )
1104 dnl                     func_r(...);
1105 dnl             #else
1106 dnl             #       if defined( HAVE_THREADS )
1107 dnl                             /* lock */
1108 dnl             #       endif
1109 dnl                             func(...);
1110 dnl             #       if defined( HAVE_THREADS )
1111 dnl                             /* unlock */
1112 dnl             #       endif
1113 dnl             #endif
1114 dnl
1115 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1116 dnl             _POSIX_REENTRANT_FUNCTIONS
1117 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1118 dnl             _POSIX_THREADSAFE_FUNCTIONS
1119 dnl
1120 dnl             and is currently defined in lthread.h
1121 dnl
1122 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1123 dnl
1124 dnl libldap/*.c should only include <lthread.h> iff
1125 dnl LDAP_R_COMPILE is defined.  ie:
1126 dnl             #ifdef LDAP_R_COMPILE
1127 dnl             #       include LDAP_R_COMPILE
1128 dnl             #endif
1129 dnl
1130 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1131 dnl specifically for compiling the threadsafe version of
1132 dnl     the ldap library (-lldap_r).
1133 dnl
1134 dnl     dnl check for reentrant/threadsafe functions
1135 dnl     dnl
1136 dnl     dnl note: these should only be used when linking
1137 dnl     dnl       with $LTHREAD_LIBS
1138 dnl     dnl
1139 dnl     save_CPPFLAGS="$CPPFLAGS"
1140 dnl     save_LIBS="$LIBS"
1141 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1142 dnl     AC_CHECK_FUNCS( \
1143 dnl             gmtime_r \
1144 dnl             gethostbyaddr_r gethostbyname_r \
1145 dnl             feof_unlocked unlocked_feof \
1146 dnl             putc_unlocked unlocked_putc \
1147 dnl             flockfile ftrylockfile \
1148 dnl     )
1149 dnl     CPPFLAGS="$save_CPPFLAGS"
1150 dnl     LIBS="$save_LIBS"
1151 fi
1152
1153 if test $ol_link_threads = no ; then
1154         if test $ol_with_threads = yes ; then
1155                 AC_MSG_ERROR([no suitable thread support])
1156         fi
1157
1158         if test $ol_with_threads = auto ; then
1159                 AC_MSG_WARN([no suitable thread support, disabling threads])
1160                 ol_with_threads=no
1161         fi
1162
1163         AC_DEFINE(NO_THREADS,1,
1164                 [define if you have (or want) no threads])
1165         LTHREAD_LIBS=""
1166 fi
1167
1168 if test $ol_link_threads != no ; then
1169         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1170 fi
1171
1172 dnl ----------------------------------------------------------------
1173
1174 ol_link_ldbm=no
1175 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1176         OL_BERKELEY_DB2
1177
1178         if test $ol_cv_berkeley_db2 = yes ; then
1179                 ol_link_ldbm=db2
1180                 ol_with_ldbm_api=db2
1181
1182                 if test $ol_with_ldbm_type = hash ; then
1183                         AC_DEFINE(LDBM_USE_DBHASH,1)
1184                 else
1185                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1186                 fi
1187
1188                 dnl $ol_cv_lib_db2 should be yes or -ldb
1189                 dnl (it could be no, but that would be an error
1190                 if test $ol_cv_lib_db2 != yes ; then
1191                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1192                 fi
1193         fi
1194 fi
1195
1196 ol_link_bdb2=no
1197 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1198         ol_link_bdb2=yes
1199 fi
1200
1201 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1202         OL_BERKELEY_DB
1203
1204         if test $ol_cv_berkeley_db = yes ; then
1205                 ol_link_ldbm=db
1206                 ol_with_ldbm_api=db
1207
1208                 if test $ol_with_ldbm_type = hash ; then
1209                         AC_DEFINE(LDBM_USE_DBHASH,1)
1210                 else
1211                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1212                 fi
1213
1214                 dnl $ol_cv_lib_db should be yes or -ldb
1215                 dnl (it could be no, but that would be an error
1216                 if test $ol_cv_lib_db != yes ; then
1217                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1218                 fi
1219         fi
1220 fi
1221
1222 if test $ol_with_ldbm_api = manual ; then
1223         dnl User thinks he can manually configure LDBM api.
1224         ol_link_ldbm=yes
1225
1226         AC_MSG_WARN([LDBM defines and link options must be set manually])
1227
1228         AC_CHECK_HEADERS(db1/db.h db.h db_185.h gdbm.h ndbm.h)
1229 fi
1230
1231 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1232         AC_MSG_WARN(Could not find LDBM with BTREE support)
1233         ol_with_ldbm_api=none
1234 fi
1235
1236 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1237         OL_MDBM
1238
1239         if test $ol_cv_mdbm = yes ; then
1240                 ol_link_ldbm=mdbm
1241                 ol_with_ldbm_api=mdbm
1242                 if test $ol_cv_lib_mdbm != yes ; then
1243                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1244                 fi
1245         fi
1246 fi
1247
1248 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1249         OL_GDBM
1250
1251         if test $ol_cv_gdbm = yes ; then
1252                 ol_link_ldbm=gdbm
1253                 ol_with_ldbm_api=gdbm
1254
1255                 if test $ol_cv_lib_gdbm != yes ; then
1256                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1257                 fi
1258         fi
1259 fi
1260
1261 if test $ol_with_ldbm_api = auto ; then
1262         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1263 elif test $ol_with_ldbm_api = ndbm ; then
1264         OL_NDBM
1265
1266         if test $ol_cv_ndbm = yes ; then
1267                 ol_link_ldbm=ndbm
1268                 ol_with_ldbm_api=ndbm
1269
1270                 if test $ol_cv_lib_ndbm != yes ; then
1271                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1272                 fi
1273         fi
1274 fi
1275
1276 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1277         AC_MSG_WARN(could not find suitable LDBM backend)
1278         if test $ol_enable_ldbm = yes ; then
1279                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1280         fi
1281
1282         AC_MSG_WARN(disabling LDBM)
1283         ol_enable_ldbm=no
1284 fi
1285
1286 if test $ol_enable_wrappers != no ; then
1287         AC_CHECK_HEADERS(tcpd.h)
1288
1289         if test $ac_cv_header_tcpd_h != yes ; then
1290                 have_wrappers=no
1291         else
1292                 AC_CHECK_LIB(wrap, main,
1293                         [have_wrappers=yes], [have_wrappers=no])
1294         fi
1295
1296         if test $have_wrappers = yes ; then
1297                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1298                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1299
1300                 dnl We add another check for -lnsl since some libwrap's
1301                 dnl need it, but it isn't always included from above
1302                 AC_CHECK_LIB(nsl, main)
1303         else
1304                 AC_MSG_WARN(could not find -lwrap)
1305                 if test $ol_enable_wrappers = yes ; then
1306                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1307                 fi
1308
1309                 AC_MSG_WARN(disabling wrappers support)
1310                 ol_enable_wrappers=no
1311         fi
1312 fi
1313
1314 if test $ol_enable_syslog != no ; then
1315         AC_CHECK_FUNC(openlog)
1316         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1317                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1318         fi
1319         ol_enable_syslog=$ac_cv_func_openlog
1320 fi
1321
1322 if test $ol_enable_dmalloc != no ; then
1323         AC_CHECK_HEADERS(dmalloc.h)
1324         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1325 fi
1326
1327 if test $ol_enable_tcl != no ; then
1328         AC_CHECK_HEADERS(tcl.h)
1329
1330         if test $ac_cv_header_tcl_h != yes ; then
1331                 have_tcl=no
1332         else
1333                 AC_CHECK_LIB(tcl,main,
1334                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1335                         [have_tcl=no])
1336
1337                 if test $have_tcl != yes; then
1338                         AC_CHECK_LIB(tcl7.6,main,
1339                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1340                                 [have_tcl=no])
1341                 fi
1342
1343                 if test $have_tcl != yes; then
1344                         AC_CHECK_LIB(tcl8.0,main,
1345                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1346                                 [have_tcl=no])
1347                 fi
1348         fi
1349
1350         if test $have_tcl != yes ; then
1351                 AC_MSG_WARN([could not find -ltcl])
1352                 if test $ol_enable_tcl = yes ; then
1353                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1354                 fi
1355
1356                 ol_enable_tcl=no
1357         fi
1358 fi
1359
1360 # ud needs termcap (should insert check here)
1361 ol_link_termcap=no
1362 AC_CHECK_HEADERS(termcap.h ncurses.h)
1363
1364 if test $ol_link_termcap = no ; then
1365         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1366         if test $have_termcap = yes ; then
1367                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1368                 ol_link_termcap=yes
1369                 TERMCAP_LIBS=-ltermcap
1370         fi
1371 fi
1372
1373 if test $ol_link_termcap = no ; then
1374         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1375         if test $have_ncurses = yes ; then
1376                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1377                 ol_link_termcap=yes
1378                 TERMCAP_LIBS=-lncurses
1379         fi
1380 fi
1381
1382 if test $ol_link_termcap = no ; then
1383         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1384         TERMCAP_LIBS=
1385 fi
1386
1387 dnl
1388 dnl Check for GNU readline
1389 dnl
1390 ol_link_readline=no
1391 if test $ol_with_readline != no ; then
1392         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1393
1394         if test $ac_cv_header_readline_readline_h = yes ; then
1395                 save_LIBS="$LIBS"
1396                 LIBS="$TERMCAP_LIBS $LIBS"
1397                 AC_CHECK_LIB(readline, readline,
1398                         [have_readline=yes], [have_readline=no])
1399                 LIBS="$save_LIBS"
1400
1401                 if test $have_readline = yes ; then
1402                         ol_with_readline=found
1403                         ol_link_readline=yes
1404
1405                         READLINE_LIBS="-lreadline"
1406                 fi
1407         fi
1408 fi
1409
1410 if test $ol_link_readline = yes ; then
1411         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1412 fi
1413
1414
1415 # FreeBSD (and others) have crypt(3) in -lcrypt
1416 if test $ol_enable_crypt != no ; then
1417         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1418                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1419                         have_crypt=yes], [have_crypt=no])])
1420
1421         if test $have_crypt = yes ; then
1422                 AC_DEFINE(HAVE_CRYPT,1)
1423         else
1424                 AC_MSG_WARN(could not find crypt)
1425                 if test $ol_enable_crypt = yes ; then
1426                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1427                 fi
1428
1429                 AC_MSG_WARN(disabling crypt support)
1430                 ol_enable_crypt=no
1431         fi
1432 fi
1433
1434 # FreeBSD (and others) have setproctitle(3) in -lutil
1435 if test $ol_enable_proctitle != no ; then
1436         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1437                 AC_CHECK_LIB(util, setproctitle,
1438                         [have_setproctitle=yes
1439                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1440                         [have_setproctitle=no
1441                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1442
1443         if test $have_setproctitle = yes ; then
1444                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1445         fi
1446 fi
1447
1448 dnl ----------------------------------------------------------------
1449 dnl Checks for header files.
1450 OL_HEADER_STDC
1451
1452 if test $ol_cv_header_stdc != yes; then
1453         AC_MSG_WARN([could not locate Standard C compliant headers])
1454 fi
1455
1456 AC_HEADER_DIRENT
1457 AC_HEADER_SYS_WAIT
1458 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1459 if test $am_cv_sys_posix_termios = yes ; then
1460         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1461                 [define if you have POSIX termios])
1462 fi
1463
1464 AC_CHECK_HEADERS(       \
1465         arpa/inet.h             \
1466         arpa/nameser.h  \
1467         assert.h                \
1468         crypt.h                 \
1469         errno.h                 \
1470         fcntl.h                 \
1471         filio.h                 \
1472         getopt.h                \
1473         grp.h                   \
1474         libutil.h               \
1475         limits.h                \
1476         locale.h                \
1477         malloc.h                \
1478         memory.h                \
1479         regex.h                 \
1480         psap.h                  \
1481         pwd.h                   \
1482         resolv.h                \
1483         sgtty.h                 \
1484         stdarg.h                \
1485         stddef.h                \
1486         string.h                \
1487         strings.h               \
1488         sysexits.h              \
1489         sys/file.h              \
1490         sys/filio.h             \
1491         sys/errno.h             \
1492         sys/ioctl.h             \
1493         sys/param.h             \
1494         sys/resource.h  \
1495         sys/socket.h    \
1496         sys/syslog.h    \
1497         sys/time.h              \
1498         sys/types.h             \
1499         syslog.h                \
1500         termios.h               \
1501         unistd.h                \
1502 )
1503
1504 dnl ----------------------------------------------------------------
1505 dnl Checks for typedefs, structures, and compiler characteristics.
1506 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1507 AC_TYPE_MODE_T
1508 AC_TYPE_OFF_T
1509 AC_TYPE_PID_T
1510 AM_TYPE_PTRDIFF_T
1511 AC_TYPE_SIGNAL
1512 OL_TYPE_SIG_ATOMIC_T
1513 AC_TYPE_SIZE_T
1514 AC_STRUCT_ST_BLKSIZE
1515 AC_HEADER_TIME
1516 AC_STRUCT_TM
1517 OL_STRUCT_PASSWD_PW_GECOS
1518
1519 OL_C_UPPER_LOWER
1520 AC_C_CONST
1521 OL_C_VOLATILE
1522
1523 if test $cross_compiling = yes ; then
1524         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1525 else
1526         AC_C_BIGENDIAN
1527         AC_CHECK_SIZEOF(short)
1528         AC_CHECK_SIZEOF(int)
1529         AC_CHECK_SIZEOF(long)
1530 fi
1531
1532 dnl ----------------------------------------------------------------
1533 dnl Checks for library functions.
1534 AC_FUNC_MEMCMP
1535 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1536 AC_FUNC_STRFTIME
1537 dnl AM_FUNC_STRTOD
1538
1539 dnl we should use vfork instead of fork in a number of places...
1540 dnl AC_FUNC_VFORK
1541 AC_FUNC_VPRINTF
1542
1543 if test $ac_cv_func_vprintf = yes ; then
1544         dnl check for vsnprintf
1545         AC_CHECK_FUNCS(vsnprintf vsprintf)
1546 fi
1547
1548 AC_CHECK_FUNCS(         \
1549         bcopy                   \
1550         endgrent                \
1551         endpwent                \
1552         flock                   \
1553         getdtablesize   \
1554         getgrgid                \
1555         gethostname             \
1556         getpass                 \
1557         getpwuid                \
1558         gettimeofday    \
1559         initgroups              \
1560         lockf                   \
1561         memcpy                  \
1562         memmove                 \
1563         mkstemp                 \
1564         recv                    \
1565         recvfrom                \
1566         setpwfile               \
1567         setgid                  \
1568         setegid                 \
1569         setsid                  \
1570         setuid                  \
1571         seteuid                 \
1572         signal                  \
1573         sigset                  \
1574         snprintf                \
1575         strdup                  \
1576         strerror                \
1577         strpbrk                 \
1578         strrchr                 \
1579         strsep                  \
1580         strstr                  \
1581         strtol                  \
1582         strtoul                 \
1583         strspn                  \
1584         sysconf                 \
1585         waitpid                 \
1586         wait4                   \
1587 )
1588
1589 dnl We actually may need to replace more than this.
1590 AC_REPLACE_FUNCS(getopt tempnam)
1591
1592 dnl ----------------------------------------------------------------
1593 # Check Configuration
1594 OL_SYS_ERRLIST
1595
1596 dnl ----------------------------------------------------------------
1597 dnl Check our declaration of strdup()
1598 OL_DECL_STRDUP
1599
1600 dnl ----------------------------------------------------------------
1601 dnl Sort out defines
1602
1603 if test "$ol_enable_debug" != no ; then
1604         AC_DEFINE(LDAP_DEBUG,1)
1605 fi
1606 if test "$ol_enable_syslog" = yes ; then
1607         AC_DEFINE(LDAP_SYSLOG,1)
1608 fi
1609 if test "$ol_enable_libui" = yes ; then
1610         AC_DEFINE(LDAP_LIBUI,1)
1611 fi
1612 if test "$ol_enable_cache" = no ; then
1613         AC_DEFINE(LDAP_NOCACHE,1)
1614 fi
1615 if test "$ol_enable_dns" != no ; then
1616         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1617 fi
1618 if test "$ol_enable_proctitle" != no ; then
1619         AC_DEFINE(LDAP_PROCTITLE,1)
1620 fi
1621 if test "$ol_enable_referrals" != no ; then
1622         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1623 fi
1624 if test "$ol_enable_cldap" != no ; then
1625         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1626 fi
1627
1628 if test "$ol_enable_aclgroups" != no ; then
1629         AC_DEFINE(SLAPD_ACLGROUPS,1)
1630 fi
1631 if test "$ol_enable_crypt" != no ; then
1632         AC_DEFINE(SLAPD_CRYPT,1)
1633 fi
1634 if test "$ol_enable_cleartext" != no ; then
1635         AC_DEFINE(SLAPD_CLEARTEXT,1)
1636 fi
1637 if test "$ol_enable_phonetic" != no ; then
1638         AC_DEFINE(SLAPD_PHONETIC,1)
1639 fi
1640 if test "$ol_enable_rlookups" != no ; then
1641         AC_DEFINE(SLAPD_RLOOKUPS,1)
1642 fi
1643
1644 if test "$ol_link_modules" != no ; then
1645         AC_DEFINE(SLAPD_MODULES,1)
1646         BUILD_SLAPD=yes
1647 fi
1648
1649 if test "$ol_link_bdb2" != no ; then
1650         AC_DEFINE(SLAPD_BDB2,1)
1651         BUILD_SLAPD=yes
1652         BUILD_BDB2=yes
1653 fi
1654
1655 if test "$ol_link_ldbm" != no ; then
1656         AC_DEFINE(SLAPD_LDBM,1)
1657         BUILD_SLAPD=yes
1658         BUILD_LDBM=yes
1659 fi
1660
1661 if test "$ol_enable_passwd" != no ; then
1662         AC_DEFINE(SLAPD_PASSWD,1)
1663         BUILD_SLAPD=yes
1664         BUILD_PASSWD=yes
1665 fi
1666
1667 if test "$ol_link_perl" != no ; then
1668         AC_DEFINE(SLAPD_PERL,1)
1669         BUILD_SLAPD=yes
1670         BUILD_PERL=yes
1671 fi
1672
1673 if test "$ol_enable_shell" != no ; then
1674         AC_DEFINE(SLAPD_SHELL,1)
1675         BUILD_SLAPD=yes
1676         BUILD_SHELL=yes
1677 fi
1678
1679 if test "$ol_enable_tcl" != no ; then
1680         AC_DEFINE(SLAPD_TCL,1)
1681         BUILD_SLAPD=yes
1682         BUILD_TCL=yes
1683 fi
1684
1685 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1686         $BUILD_SLAPD = yes ; then
1687         BUILD_SLURPD=yes
1688 fi
1689
1690 if test "$ol_link_isode" != no ; then
1691         BUILD_LDAPD=yes
1692 fi
1693
1694 dnl ----------------------------------------------------------------
1695
1696 AC_SUBST(BUILD_LDAPD)
1697 AC_SUBST(BUILD_SLAPD)
1698   AC_SUBST(BUILD_BDB2)
1699   AC_SUBST(BUILD_LDBM)
1700   AC_SUBST(BUILD_PASSWD)
1701   AC_SUBST(BUILD_PERL)
1702   AC_SUBST(BUILD_SHELL)
1703   AC_SUBST(BUILD_TCL)
1704 AC_SUBST(BUILD_SLURPD)
1705
1706 AC_SUBST(LDAP_LIBS)
1707 AC_SUBST(LDAPD_LIBS)
1708 AC_SUBST(SLAPD_LIBS)
1709 AC_SUBST(SLURPD_LIBS)
1710 AC_SUBST(LDBM_LIBS)
1711 AC_SUBST(LTHREAD_LIBS)
1712 AC_SUBST(LUTIL_LIBS)
1713
1714 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
1715 AC_SUBST(SLAPD_MODULES_LDFLAGS)
1716
1717 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1718 AC_SUBST(SLAPD_PERL_LDFLAGS)
1719
1720 AC_SUBST(KRB_LIBS)
1721 AC_SUBST(READLINE_LIBS)
1722 AC_SUBST(TERMCAP_LIBS)
1723 AC_SUBST(TLS_LIBS)
1724
1725 dnl ----------------------------------------------------------------
1726 dnl final output
1727 dnl
1728
1729 AC_OUTPUT( \
1730 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1731 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1732 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1733 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1734 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1735 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1736 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1737 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1738 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1739 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1740 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1741 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1742 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1743 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1744 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1745 include/Makefile:build/top.mk:include/Makefile.in \
1746 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1747 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1748 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1749 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1750 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1751 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1752 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1753 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1754 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1755 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1756 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1757 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
1758 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1759 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1760 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
1761 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1762 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
1763 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1764 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1765 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1766 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
1767 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
1768 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
1769 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
1770 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
1771 ,[
1772 date > stamp-h
1773 echo Please \"make depend\" to build dependencies
1774 ])