git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Configure.in for OpenLDAP
  11 AC_INIT(include/ldap.h)dnl
  12 AC_CONFIG_AUX_DIR(build)dnl
  13 AM_INIT_AUTOMAKE(openldap,[1.2], [no ac_define])dnl
  14
  15 dnl Do not use AutoConf 2.12; it produces a configuration script
  16 dnl that causes an "internal 2K buffer" error on HPUX when run
  17 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  18 AC_PREREQ(2.10)dnl Required Autoconf version
  19
  20 AC_CONFIG_HEADER(include/portable.h)dnl
  21
  22 dnl
  23 dnl Start Args
  24 AC_MSG_CHECKING(configure arguments)
  25 AC_PREFIX_DEFAULT(/usr/local)
  26
  27 top_builddir=`pwd`
  28 AC_SUBST(top_builddir)dnl
  29
  30 ldap_subdir="openldap"
  31
  32 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  33         if test "$withval" = "no"; then
  34                 ldap_subdir=""
  35         elif test "$withval" != "yes"; then
  36                 ldap_subdir="$withval"
  37         fi
  38 ])dnl
  39
  40 AC_SUBST(ldap_subdir)dnl
  41
  42 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  43 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  44 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  45 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  46 OL_ARG_ENABLE(dns,[  --enable-dns               enable dns support], no)dnl
  47 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable referrals], yes)dnl
  48 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  49 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  50         no, [yes no])dnl
  51
  52 dnl General "with" options
  53 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  54         auto, [auto k5 k4 afs yes no])
  55 OL_ARG_WITH(threads,[  --with-threads   use threads],
  56         auto, [auto posix mach lwp yes no manual] )
  57 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  58         auto, [auto yes no manual] )
  59
  60 dnl Server options
  61
  62 dnl LDAPD OPTIONS
  63 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  64 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  65
  66 dnl SLAPD OPTIONS
  67 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  68 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  69 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  70 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  71 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  72 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  73 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  74 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  75
  76 dnl SLAPD Backend options
  77 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  78 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  79         [auto db2 db gdbm ndbm manual])
  80 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  81         [auto btree hash])
  82
  83 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  84 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  85
  86 dnl SLURPD OPTIONS
  87 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  88 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  89
  90 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
  91 AM_ENABLE_STATIC
  92 AM_DISABLE_SHARED
  93 dnl AM_ENABLE_SHARED
  94
  95 dnl General "enable" options
  96 # validate options
  97 if test $ol_enable_referrals = no ; then
  98         if test $ol_enable_dns = yes ; then
  99                 AC_MSG_WARN([dns disabled, ignoring --enable-dns argument])
 100         fi
 101         ol_enable_dns=no
 102 fi
 103
 104 if test $ol_enable_slapd = no ; then
 105         dnl SLAPD was specificallly disabled
 106         if test $ol_enable_ldbm = yes ; then
 107                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 108         fi
 109         if test $ol_enable_passwd = yes ; then
 110                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 111         fi
 112         if test $ol_enable_shell = yes ; then
 113                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 114         fi
 115         if test $ol_enable_aclgroups = yes ; then
 116                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 117         fi
 118         if test $ol_enable_wrappers = yes ; then
 119                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 120         fi
 121         if test $ol_enable_phonetic = yes ; then
 122                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 123         fi
 124         if test $ol_enable_rlookups = yes ; then
 125                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 126         fi
 127         if test $ol_with_ldbm_api != auto ; then
 128                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 129         fi
 130         if test $ol_with_ldbm_type != auto ; then
 131                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 132         fi
 133         if test $ol_enable_slurpd = yes ; then
 134                 AC_MSG_ERROR([slurpd requires slapd])
 135         fi
 136
 137         # force settings to no
 138         ol_enable_ldbm=no
 139         ol_enable_shell=no
 140         ol_enable_passwd=no
 141         ol_enable_aclgroups=no
 142         ol_enable_wrappers=no
 143         ol_enable_phonetic=no
 144         ol_enable_rlookups=no
 145         ol_with_ldbm_api=no
 146         ol_with_ldbm_type=no
 147         ol_enable_slurpd=no
 148
 149 elif test $ol_enable_ldbm = no ; then
 150         dnl SLAPD without LDBM
 151
 152         if test $ol_with_ldbm_api != auto ; then
 153                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 154         fi
 155
 156         if test $ol_with_ldbm_type != auto ; then
 157                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 158         fi
 159
 160         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 161                 AC_MSG_ERROR([slapd requires a backend])
 162         fi
 163
 164         ol_with_ldbm_api=no
 165         ol_with_ldbm_type=no
 166
 167 else
 168         dnl SLAPD with LDBM
 169
 170         if test $ol_with_ldbm_api = gdbm -a \
 171                 $ol_with_ldbm_type = btree ; then
 172                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 173         fi
 174         if test $ol_with_ldbm_api = ndbm -a \
 175                 $ol_with_ldbm_type = btree ; then
 176                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 177         fi
 178 fi
 179
 180 if test $ol_enable_slurpd = yes ; then
 181         dnl SLURPD was specifically enabled
 182         if test $ol_with_threads = no ; then
 183                 AC_MSG_ERROR([slurpd requires threads])
 184         fi
 185 fi
 186
 187 AC_MSG_RESULT(done)
 188
 189 AC_CANONICAL_HOST
 190
 191 ## Initialize vars
 192 LDAP_LIBS=
 193 LDBM_LIBS=
 194 LTHREAD_LIBS=
 195 LUTIL_LIBS=
 196
 197 LDAPD_LIBS=
 198 SLAPD_LIBS=
 199 SLURPD_LIBS=
 200
 201 BUILD_LDAPD=no
 202 BUILD_SLAPD=no
 203 BUILD_SLURPD=no
 204
 205 BUILD_LDBM=no
 206 BUILD_PASSWD=no
 207 BUILD_SHELL=no
 208 BUILD_THREAD=no
 209
 210 KRB_LIBS=
 211 TERMCAP_LIBS=
 212
 213 dnl ----------------------------------------------------------------
 214 dnl Checks for programs
 215
 216 AC_PROG_INSTALL
 217 AM_PROG_LIBTOOL
 218 dnl AC_PROG_MAKE_SET
 219
 220 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 221         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 222 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 223 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 224
 225 dnl Checks the compiler and UNIX Variants
 226
 227 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 228         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 229
 230 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 231         AC_MSG_WARN([programs compiled here do run here...])
 232         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 233
 234 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 235         AC_MSG_WARN([programs compiled here do not run here...])
 236         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 237 fi
 238
 239 AC_PROG_CPP
 240
 241 AC_AIX
 242 AC_ISC_POSIX
 243 AC_MINIX
 244
 245 dnl OpenLDAP requires STDC features
 246 AM_PROG_CC_STDC
 247 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 248         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 249 fi
 250
 251 dnl AM_C_PROTOTYPES
 252
 253 dnl Checks for libraries
 254
 255 dnl Find socket()
 256 dnl Likely combinations:
 257 dnl             -lsocket [ -lnsl_s | -lnsl ]
 258 dnl             -linet
 259
 260 AC_CHECK_FUNC(socket, [have_socket=yes], [
 261 dnl
 262 dnl hopefully we won't include too many libraries
 263 dnl
 264         AC_CHECK_LIB(socket, main)
 265         AC_CHECK_LIB(net, main)
 266         AC_CHECK_LIB(nsl_s, main)
 267         AC_CHECK_LIB(nsl, main)
 268         AC_CHECK_LIB(inet, socket)
 269         AC_CHECK_LIB(gen, main)
 270 ])
 271
 272 dnl Check for resolver routines
 273 AC_CHECK_FUNCS(res_search)
 274 if test $ac_cv_func_res_search = "no" ; then
 275         AC_CHECK_LIB(bind, res_search)
 276         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 277                 AC_DEFINE(HAVE_RES_SEARCH,1)
 278         else
 279                 AC_CHECK_LIB(resolv, res_search)
 280                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 281                         AC_DEFINE(HAVE_RES_SEARCH,1)
 282                 fi
 283         fi
 284 fi
 285
 286 dnl HP-UX requires -lV3
 287 AC_CHECK_LIB(V3, sigset)
 288
 289 # ISODE tests
 290 ol_link_isode=no
 291 if test $ol_enable_ldapd != no ; then
 292         dnl look for ISODE libraries
 293         AC_CHECK_LIB(xtpp, main, [
 294                 ol_link_isode=yes
 295                 AC_DEFINE(HAVE_XTPP,1)
 296                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 297                 ],:,[-lxtdsap -lxtisode -losi])
 298         AC_CHECK_LIB(dsap, main, [
 299                 ol_link_isode=yes
 300                 AC_DEFINE(HAVE_DSAP,1)
 301                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 302                 ],:,[-lisode])
 303         AC_CHECK_LIB(isode, main, [
 304                 ol_link_isode=yes
 305                 AC_DEFINE(HAVE_ISODE,1)
 306                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 307                 ],:)
 308 fi
 309
 310 if test $ol_link_isode != no; then
 311         AC_CHECK_LIB(pp, main, [
 312                 AC_DEFINE(HAVE_PP,1)
 313                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 314                 ],:)
 315
 316         AC_PATH_PROG(PEPSY, pepsy)
 317 fi
 318
 319 dnl
 320 dnl check for kerberos
 321 dnl
 322 ol_link_kerberos=no
 323
 324 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 325         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 326
 327         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 328                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 329                         [-lkrb5 -ldes425])
 330
 331                 if test $have_k5 = yes ; then
 332                         ol_with_kerberos=found
 333                         ol_link_kerberos=yes
 334
 335                         AC_DEFINE(HAVE_KERBEROS)
 336                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 337                 fi
 338         fi
 339 fi
 340
 341 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 342         AC_CHECK_HEADERS(krb.h des.h)
 343
 344         if test $ac_cv_header_krb_h = yes ; then
 345                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 346
 347                 if test $have_k4 = yes ; then
 348                         ol_with_kerberos=found
 349                         ol_link_kerberos=yes
 350
 351                         AC_DEFINE(HAVE_KERBEROS)
 352                         KRB_LIBS="-lkrb -ldes"
 353                 fi
 354         fi
 355 fi
 356
 357 dnl     if test $ol_link_kerberos = yes ; then
 358 dnl             save_LIBS=$LIBS
 359 dnl             LIBS="$KRB_LIBS $LIBS"
 360 dnl             AC_CHECK_FUNCS(des_string_to_key)
 361 dnl             LIBS=$save_LIBS
 362 dnl fi
 363
 364 ol_link_threads=no
 365 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 366         -o $ol_with_threads = posix ; then
 367
 368         AC_CHECK_HEADERS(pthread.h sched.h)
 369
 370         if test $ac_cv_header_pthread_h = yes ; then
 371                 OL_POSIX_THREAD_VERSION
 372
 373                 if test $ol_cv_pthread_version = final ; then
 374                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 375                 elif test $ol_cv_pthread_version = draft4 ; then
 376                         AC_DEFINE(HAVE_PTHREADS_D4)
 377                 else
 378                         AC_MSG_ERROR([unknown pthread version])
 379                 fi
 380
 381                 # consider threads found
 382                 ol_with_threads=found
 383
 384                 OL_LINUX_THREADS
 385
 386                 if test $ol_cv_linux_threads = yes ; then
 387                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 388                 fi
 389
 390                 dnl Now the hard part, how to link
 391
 392                 dnl Check for pthread support in current $LIBS
 393                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 394
 395                 if test $ol_link_threads = no ; then
 396                         dnl try -kthread
 397                         AC_CACHE_CHECK([for pthread_create with -kthread],
 398                                 [ol_cv_kthread_flag], [
 399                                 dnl save the flags
 400                                 save_LIBS="$LIBS"
 401                                 LIBS="-kthread $LIBS"
 402                                 AC_TRY_LINK([char pthread();],[
 403                                         pthread_create();
 404                                         ], ol_cv_kthread_flag=yes, ol_cv_kthread_flag=no)
 405                                 dnl restore the LIBS
 406                                 LIBS="$save_LIBS"
 407                         ])
 408
 409                         if test $ol_cv_kthread_flag = yes ; then
 410                                 LTHREAD_LIBS="$LTHREAD_LIBS -kthread"
 411                                 ol_link_threads=posix
 412                         fi
 413                 fi
 414
 415                 if test $ol_link_threads = no ; then
 416                         dnl try -pthread
 417                         AC_CACHE_CHECK([for pthread_create with -pthread],
 418                                 [ol_cv_pthread_flag], [
 419                                 dnl save the flags
 420                                 save_LIBS="$LIBS"
 421                                 LIBS="-pthread $LIBS"
 422                                 AC_TRY_LINK([char pthread();],[
 423                                         pthread_create();
 424                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 425                                 dnl restore the LIBS
 426                                 LIBS="$save_LIBS"
 427                         ])
 428
 429                         if test $ol_cv_pthread_flag = yes ; then
 430                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 431                                 ol_link_threads=posix
 432                         fi
 433                 fi
 434
 435                 if test $ol_link_threads = no ; then
 436                         dnl try -pthreads
 437                         AC_CACHE_CHECK([for pthread_create with -pthreads],
 438                                 [ol_cv_pthreads_flag], [
 439                                 dnl save the flags
 440                                 save_LIBS="$LIBS"
 441                                 LIBS="-pthreads $LIBS"
 442                                 AC_TRY_LINK([char pthread();],[
 443                                         pthread_create();
 444                                         ], ol_cv_pthreads_flag=yes, ol_cv_pthreads_flag=no)
 445                                 dnl restore the LIBS
 446                                 LIBS="$save_LIBS"
 447                         ])
 448
 449                         if test $ol_cv_pthreads_flag = yes ; then
 450                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthreads"
 451                                 ol_link_threads=posix
 452                         fi
 453                 fi
 454
 455                 if test $ol_link_threads = no ; then
 456                         dnl try -thread
 457                         AC_CACHE_CHECK([for pthread_create with -thread],
 458                                 [ol_cv_thread_flag], [
 459                                 dnl save the flags
 460                                 save_LIBS="$LIBS"
 461                                 LIBS="-thread $LIBS"
 462                                 AC_TRY_LINK([char pthread();],[
 463                                         pthread_create();
 464                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 465                                 dnl restore the LIBS
 466                                 LIBS="$save_LIBS"
 467                         ])
 468
 469                         if test $ol_cv_thread_flag = yes ; then
 470                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 471                                 ol_link_threads=posix
 472                         fi
 473                 fi
 474
 475                 if test $ol_link_threads = no ; then
 476                         dnl try DEC Threads -lpthread -lexc
 477                         save_LIBS="$LIBS"
 478                         AC_CHECK_LIB(pthread, pthread_mutex_lock, [
 479                                 ol_link_threads=posix
 480                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 481                                 if test $ol_with_yielding_select = auto ; then
 482                                         ol_with_yielding_select=yes
 483                                 fi
 484                                 ],:,[-lexc])
 485                         LIBS="$save_LIBS"
 486                 fi
 487
 488                 if test $ol_link_threads = no ; then
 489                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 490                         save_LIBS="$LIBS"
 491                         AC_CHECK_LIB(pthreads, pthread_mutex_unlock, [
 492                                 ol_link_threads=posix
 493                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 494                                 if test $ol_with_yielding_select = auto ; then
 495                                         ol_with_yielding_select=yes
 496                                 fi
 497                                 ],:,[-lmach -lexc -lc_r])
 498                         LIBS="$save_LIBS"
 499                 fi
 500
 501                 if test $ol_link_threads = no ; then
 502                         dnl try -lpthread
 503                         save_LIBS="$LIBS"
 504                         AC_CHECK_LIB(pthread, pthread_create, [
 505                                 ol_link_threads=posix
 506                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"],:)
 507                         LIBS="$save_LIBS"
 508                 fi
 509
 510                 if test $ol_link_threads = no ; then
 511                         dnl try -lc_r
 512                         save_LIBS="$LIBS"
 513                         AC_CHECK_LIB(c_r, pthread_create, [
 514                                 ol_link_threads=posix
 515                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"],:)
 516                         LIBS="$save_LIBS"
 517                 fi
 518
 519                 if test $ol_link_threads = no ; then
 520                         dnl try -lpthreads
 521                         save_LIBS="$LIBS"
 522                         AC_CHECK_LIB(pthreads, pthread_create, [
 523                                 ol_link_threads=posix
 524                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"],:)
 525                         LIBS="$save_LIBS"
 526                 fi
 527
 528                 dnl IRIX Pthread check
 529                 if test $ol_link_threads = no ; then
 530                         dnl try IRIX Pthreads -Wl,-woff,85 -lpthreads
 531                         save_LIBS="$LIBS"
 532                         AC_CHECK_LIB(pthreads, pthread_join, [
 533                                 ol_link_threads=posix
 534                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"
 535                                 ],:,[-Wl,-woff,85])
 536                         LIBS="$save_LIBS"
 537                 fi
 538
 539                 dnl HP-UX 11 Pthread check
 540                 if test $ol_link_threads = no; then
 541                         save_LIBS="$LIBS"
 542                         LIBS="$LIBS -lpthread"
 543                         AC_MSG_CHECKING([for pthread_create() in HP-UX -lpthread])
 544                         ol_try_pthread_hpux_11=no
 545                         AC_CACHE_VAL(ol_cv_pthread_hpux_11,[
 546                                 AC_TRY_LINK([
 547 #include <pthread.h>
 548 #include <elf.h>
 549 #ifndef ELFABI_HPUX_REL11
 550         die horribly
 551 #endif
 552                                 ], [pthread_create(NULL, NULL, NULL, NULL);],
 553                                         ol_try_pthread_hpux_11=yes
 554                                         ol_cv_pthread_hpux_11=yes,
 555                                         ol_cv_pthread_hpux_11=no)])
 556                         AC_MSG_RESULT(yes)
 557                         LIBS="$save_LIBS"
 558
 559                         if test $ol_cv_pthread_hpux_11=yes ; then
 560                                 ol_link_threads=posix
 561                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"
 562                                 if test $ol_try_pthread_hpux_11=yes ; then
 563                                         dnl Some tests below may fail, cause we aint including
 564                                         dnl pthread.h. Force appropriate ones to yes
 565                                         ac_cv_func_pthread_attr_init=yes
 566                                 fi
 567                         fi
 568                 fi
 569
 570                 if test $ol_link_threads != no ; then
 571                         AC_DEFINE(HAVE_PTHREADS)
 572
 573                         dnl save flags
 574                         save_CPPFLAGS="$CPPFLAGS"
 575                         save_LIBS="$LIBS"
 576                         LIBS="$LTHREAD_LIBS $LIBS"
 577
 578                         dnl All POSIX Thread (final) implementations should have
 579                         dnl sched_yield instead of pthread yield.
 580                         dnl check for both
 581                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 582
 583                         if test $ac_cv_func_sched_yield = no -a \
 584                                 $ac_cv_func_pthread_yield = no ; then
 585                                 dnl Digital UNIX has sched_yield() in -lrt
 586                                 AC_CHECK_LIB(rt, sched_yield,
 587                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 588                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 589                                         ac_cv_func_sched_yield=yes],
 590                                         [ac_cv_func_sched_yield=no])
 591                         fi
 592                         if test $ac_cv_func_sched_yield = no -a \
 593                                 $ac_cv_func_pthread_yield = no ; then
 594                                 dnl Solaris has sched_yield() in -lposix4
 595                                 AC_CHECK_LIB(posix4, sched_yield,
 596                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 597                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 598                                         ac_cv_func_sched_yield=yes],
 599                                         [ac_cv_func_sched_yield=no])
 600                         fi
 601                         if test $ac_cv_func_sched_yield = no -a \
 602                                 $ac_cv_func_pthread_yield = no ; then
 603                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 604                         fi
 605
 606                         dnl Check functions for compatibility
 607                         AC_CHECK_FUNCS(pthread_kill pthread_detach)
 608
 609                         AC_CHECK_FUNCS( \
 610                                 pthread_attr_create pthread_attr_init \
 611                                 pthread_attr_destroy pthread_attr_delete \
 612                                 pthread_attr_setdetachstate pthread_attr_setdetach_np \
 613                         )
 614
 615                         dnl Check for setconcurreny functions
 616                         AC_CHECK_FUNCS( \
 617                                 pthread_setconcurrency \
 618                                 thr_setconcurrency \
 619                         )
 620
 621                         AC_MSG_CHECKING([if pthread_create() works])
 622                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 623                         AC_TRY_RUN([
 624 #include <pthread.h>
 625 #ifndef NULL
 626 #define NULL (void*)0
 627 #endif
 628
 629 static void *task(p)
 630         void *p;
 631 {
 632         return (void *) (p == NULL);
 633 }
 634
 635 int main(argc, argv)
 636         int argc;
 637         char **argv;
 638 {
 639         pthread_t t;
 640         exit(pthread_create(&t, NULL, task, NULL));
 641 }
 642 ],
 643                                 [ol_cv_pthread_create_works=yes],
 644                                 [ol_cv_pthread_create_works=no],
 645                                 [dnl assume yes
 646                                 ol_cv_pthread_create_works=yes])])
 647                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 648
 649                         if test $ol_cv_pthread_create_works = no ; then
 650                                 AC_MSG_ERROR([pthread.h and pthread_create are not compatible])
 651                         fi
 652
 653                         dnl Check if select causes an yield
 654                         if test $ol_with_yielding_select = auto ; then
 655                                 AC_MSG_CHECKING([if select yields when using pthreads])
 656                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 657                                 AC_TRY_RUN([
 658 #include <sys/types.h>
 659 #include <sys/time.h>
 660 #include <unistd.h>
 661 #include <pthread.h>
 662 #ifndef NULL
 663 #define NULL (void*) 0
 664 #endif
 665
 666 static int fildes[2];
 667
 668 static void *task(p)
 669         void *p;
 670 {
 671         int i;
 672         struct timeval tv;
 673
 674         fd_set rfds;
 675
 676         tv.tv_sec=10;
 677         tv.tv_usec=0;
 678
 679         FD_ZERO(&rfds);
 680         FD_SET(fildes[0], &rfds);
 681
 682         /* we're not interested in any fds */
 683         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 684
 685         if(i < 0) {
 686                 perror("select");
 687                 exit(10);
 688         }
 689
 690         exit(0); /* if we exit here, the select blocked the whole process */
 691 }
 692
 693 int main(argc, argv)
 694         int argc;
 695         char **argv;
 696 {
 697         pthread_t t;
 698
 699         /* create a pipe to select */
 700         if(pipe(&fildes[0])) {
 701                 perror("select");
 702                 exit(1);
 703         }
 704
 705 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 706         (void) pthread_setconcurrency(2);
 707 #else
 708 #ifdef HAVE_THR_SETCONCURRENCY
 709         /* Set Solaris LWP concurrency to 2 */
 710         thr_setconcurrency(2);
 711 #endif
 712 #endif
 713
 714         pthread_create(&t, NULL, task, NULL);
 715
 716 #if HAVE_SCHED_YIELD
 717         sched_yield();  /* make sure task runs first */
 718 #else
 719 #ifdef HAVE_PTHREAD_YIELD
 720         pthread_yield();        /* make sure task runs first */
 721 #endif
 722 #endif
 723
 724         exit(2);
 725 }],
 726                                 [ol_cv_pthread_select_yields=no],
 727                                 [ol_cv_pthread_select_yields=yes], [
 728                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
 729                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
 730
 731                                 if test $ol_cv_pthread_select_yields = yes ; then
 732                                         ol_with_yielding_select=yes
 733                                 fi
 734                         fi
 735
 736                         dnl restore flags
 737                         CPPFLAGS="$save_CPPFLAGS"
 738                         LIBS="$save_LIBS"
 739                 else
 740                         AC_MSG_ERROR([could not link with POSIX Threads])
 741                 fi
 742         fi
 743
 744         if test $ol_with_threads = posix ; then
 745                 AC_MSG_ERROR([could not locate POSIX Threads])
 746         fi
 747 fi
 748
 749 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 750         -o $ol_with_threads = mach ; then
 751
 752         dnl check for Mach CThreads
 753         AC_CHECK_HEADERS(mach/cthreads.h)
 754         if test $ac_cv_header_mach_cthreads_h = yes ; then
 755                 ol_with_threads=found
 756
 757                 dnl check for cthread support in current $LIBS
 758                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 759
 760                 if test $ol_link_threads = no ; then
 761                         dnl try -all_load
 762                         dnl this test needs work
 763                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 764                                 [ol_cv_cthread_all_load], [
 765                                 dnl save the flags
 766                                 save_LIBS="$LIBS"
 767                                 LIBS="-all_load $LIBS"
 768                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 769                                         cthread_fork((void *)0, (void *)0);
 770                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 771                                 dnl restore the LIBS
 772                                 LIBS="$save_LIBS"
 773                         ])
 774
 775                         if test $ol_cv_cthread_all_load = yes ; then
 776                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 777                                 ol_link_threads=mach
 778                         fi
 779                 fi
 780
 781                 if test $ol_link_threads != no ; then
 782                         : check for cthread specific functionality here
 783                         AC_DEFINE(HAVE_MACH_CTHREADS,1)
 784                 else
 785                         AC_MSG_ERROR([could not link with Mach CThreads])
 786                 fi
 787         fi
 788
 789         if test $ol_with_threads = mach ; then
 790                 AC_MSG_ERROR([could not locate Mach CThreads])
 791         fi
 792 fi
 793
 794 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 795         -o $ol_with_threads = lwp ; then
 796
 797         dnl check for SunOS5 LWP
 798         AC_CHECK_HEADERS(thread.h synch.h)
 799         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 800                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
 801
 802                 if test $have_thr = yes ; then
 803                         AC_DEFINE(HAVE_THR)
 804                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
 805                         ol_link_threads=thr
 806
 807                         if test $ol_with_yielding_select = auto ; then
 808                                 ol_with_yielding_select=yes
 809                         fi
 810
 811                         AC_CACHE_CHECK([for misplaced posix thread in headers],
 812                                 [ol_cv_header_misplaced_pthreads], [
 813                                 AC_TRY_COMPILE([
 814 #include <sys/types.h>
 815 typedef double pthread_t;
 816                                 ], [
 817                                 pthread_t thread = 0.0;
 818                                 ],
 819                                 [ol_cv_header_misplaced_pthreads=no],
 820                                 [ol_cv_header_misplaced_pthreads=yes])
 821                         ])
 822
 823                         if test "$ol_cv_header_misplaced_pthreads" = yes ; then
 824                                 AC_MSG_ERROR([pthread types are misplaced, use --with-threads=posix]);
 825                         fi
 826                 fi
 827         fi
 828
 829         dnl check for SunOS4 LWP
 830         AC_CHECK_HEADERS(lwp/lwp.h)
 831         if test $ac_cv_header_lwp_lwp_h = yes ; then
 832                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 833
 834                 if test $have_lwp = yes ; then
 835                         AC_DEFINE(HAVE_LWP)
 836                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 837                         ol_link_threads=lwp
 838
 839                         if test $ol_with_yielding_select = auto ; then
 840                                 ol_with_yielding_select=no
 841                         fi
 842                 fi
 843         fi
 844 fi
 845
 846 if test $ol_with_yielding_select = yes ; then
 847         AC_DEFINE(HAVE_YIELDING_SELECT,1)
 848 fi
 849
 850 if test $ol_with_threads = manual ; then
 851         dnl User thinks he can manually configure threads.
 852         ol_link_threads=yes
 853
 854         AC_MSG_WARN([thread defines and link options must be set manually])
 855
 856         AC_CHECK_HEADERS(pthread.h sched.h)
 857         AC_CHECK_FUNCS(sched_yield pthread_yield)
 858         OL_LINUX_THREADS
 859
 860         AC_CHECK_HEADERS(mach/cthreads.h)
 861         AC_CHECK_HEADERS(lwp/lwp.h)
 862         AC_CHECK_HEADERS(thread.h synch.h)
 863 fi
 864
 865 if test $ol_link_threads != no ; then
 866         dnl needed to get reentrant/threadsafe versions
 867         dnl
 868         AC_DEFINE(REENTRANT,1)
 869         AC_DEFINE(_REENTRANT,1)
 870         AC_DEFINE(THREAD_SAFE,1)
 871         AC_DEFINE(_THREAD_SAFE,1)
 872         AC_DEFINE(THREADSAFE,1)
 873         AC_DEFINE(_THREADSAFE,1)
 874
 875         dnl this might cause the errno symbol to be
 876         dnl replaced with a function to get a thread specific errno.
 877         dnl check to see if everything needs to be compiled
 878         dnl with the thread libraries
 879         AC_CACHE_CHECK([for thread specific errno],
 880                 [ol_cv_errno_thread_specific], [
 881                 AC_TRY_LINK([
 882 #include <errno.h>
 883                         ], [
 884 int x = errno;
 885                         ],
 886                         [ol_cv_errno_thread_specific=yes],
 887                         [ol_cv_errno_thread_specific=no])
 888         ])
 889
 890         if test $ol_cv_errno_thread_specific != yes ; then
 891                 LIBS="$LTHREAD_LIBS $LIBS"
 892                 LTHREAD_LIBS=""
 893         fi
 894 fi
 895
 896 dnl ----------------------------------------------------------------
 897
 898 if test $ol_link_threads = no ; then
 899         if test $ol_with_threads = yes ; then
 900                 AC_MSG_ERROR([no suitable thread support])
 901         fi
 902
 903         if test $ol_with_threads = auto ; then
 904                 AC_MSG_WARN([no suitable thread support, disabling threads])
 905                 ol_with_threads=no
 906         fi
 907
 908         AC_CACHE_CHECK([for misplaced posix thread in headers],
 909                 [ol_cv_header_misplaced_pthreads], [
 910                 AC_TRY_COMPILE([
 911 #include <sys/types.h>
 912 typedef double pthread_t;
 913                         ], [
 914                                 pthread_t thread = 0.0;
 915                         ],
 916                         [ol_cv_header_misplaced_pthreads=no],
 917                         [ol_cv_header_misplaced_pthreads=yes])
 918         ])
 919
 920         if test "$ol_cv_header_misplaced_pthreads" = yes ; then
 921                 AC_MSG_ERROR([pthread types are misplaced, use --with-threads=posix]);
 922         fi
 923
 924         AC_DEFINE(NO_THREADS,1)
 925         LTHREAD_LIBS=""
 926 fi
 927
 928 ol_link_ldbm=no
 929 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 930         OL_BERKELEY_DB2
 931
 932         if test $ol_cv_berkeley_db2 = yes ; then
 933                 ol_link_ldbm=db2
 934                 ol_with_ldbm_api=db2
 935
 936                 if test $ol_with_ldbm_type = hash ; then
 937                         AC_DEFINE(LDBM_USE_DBHASH,1)
 938                 else
 939                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 940                 fi
 941
 942                 dnl $ol_cv_lib_db2 should be yes or -ldb
 943                 dnl (it could be no, but that would be an error
 944                 if test $ol_cv_lib_db2 != yes ; then
 945                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 946                 fi
 947         fi
 948 fi
 949
 950 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 951         OL_BERKELEY_DB
 952
 953         if test $ol_cv_berkeley_db = yes ; then
 954                 ol_link_ldbm=db
 955                 ol_with_ldbm_api=db
 956
 957                 if test $ol_with_ldbm_type = hash ; then
 958                         AC_DEFINE(LDBM_USE_DBHASH,1)
 959                 else
 960                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 961                 fi
 962
 963                 dnl $ol_cv_lib_db should be yes or -ldb
 964                 dnl (it could be no, but that would be an error
 965                 if test $ol_cv_lib_db != yes ; then
 966                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 967                 fi
 968         fi
 969 fi
 970
 971 if test $ol_with_ldbm_api = manual ; then
 972         dnl User thinks he can manually configure LDBM api.
 973         ol_link_ldbm=yes
 974
 975         AC_MSG_WARN([LDBM defines and link options must be set manually])
 976
 977         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 978 fi
 979
 980 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 981         AC_MSG_WARN(Could not find LDBM with BTREE support)
 982         ol_with_ldbm_api=none
 983 fi
 984
 985 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 986         OL_GDBM
 987
 988         if test $ol_cv_gdbm = yes ; then
 989                 ol_link_ldbm=gdbm
 990                 ol_with_ldbm_api=gdbm
 991
 992                 if test $ol_cv_lib_gdbm != yes ; then
 993                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 994                 fi
 995         fi
 996 fi
 997
 998 if test $ol_with_ldbm_api = auto ; then
 999         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1000 elif test $ol_with_ldbm_api = ndbm ; then
1001         OL_NDBM
1002
1003         if test $ol_cv_ndbm = yes ; then
1004                 ol_link_ldbm=ndbm
1005                 ol_with_ldbm_api=ndbm
1006
1007                 if test $ol_cv_lib_ndbm != yes ; then
1008                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1009                 fi
1010         fi
1011 fi
1012
1013 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1014         AC_MSG_WARN(could not find suitable LDBM backend)
1015         if test $ol_enable_ldbm = yes ; then
1016                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1017         fi
1018
1019         AC_MSG_WARN(disabling LDBM)
1020         ol_enable_ldbm=no
1021 fi
1022
1023 if test $ol_enable_wrappers != no ; then
1024         AC_CHECK_HEADERS(tcpd.h)
1025
1026         if test $ac_cv_header_tcpd_h != yes ; then
1027                 have_wrappers=no
1028         else
1029                 AC_CHECK_LIB(wrap, main,
1030                         [have_wrappers=yes], [have_wrappers=no])
1031         fi
1032
1033         if test $have_wrappers = yes ; then
1034                 AC_DEFINE(HAVE_TCPD)
1035                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1036         else
1037                 AC_MSG_WARN(could not find -lwrap)
1038                 if test $ol_enable_wrappers = yes ; then
1039                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1040                 fi
1041
1042                 AC_MSG_WARN(disabling wrappers support)
1043                 ol_enable_wrappers=no
1044         fi
1045 fi
1046
1047 # ud needs termcap (should insert check here)
1048 ol_link_termcap=no
1049 AC_CHECK_HEADERS(termcap.h ncurses.h)
1050
1051 if test $ol_link_termcap = no ; then
1052         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1053         if test $have_termcap = yes ; then
1054                 AC_DEFINE(HAVE_TERMCAP)
1055                 ol_link_termcap=yes
1056                 TERMCAP_LIBS=-ltermcap
1057         fi
1058 fi
1059
1060 if test $ol_link_termcap = no ; then
1061         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1062         if test $have_ncurses = yes ; then
1063                 AC_DEFINE(HAVE_NCURSES)
1064                 ol_link_termcap=yes
1065                 TERMCAP_LIBS=-lncurses
1066         fi
1067 fi
1068
1069 if test $ol_link_termcap = no ; then
1070         AC_DEFINE(NO_TERMCAP,1)
1071         TERMCAP_LIBS=
1072 fi
1073
1074 # FreeBSD (and others) have crypt(3) in -lcrypt
1075 if test $ol_enable_crypt != no ; then
1076         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1077                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1078                         have_crypt=yes], [have_crypt=no])])
1079
1080         if test $have_crypt = yes ; then
1081                 AC_DEFINE(HAVE_CRYPT,1)
1082         else
1083                 AC_MSG_WARN(could not find crypt)
1084                 if test $ol_enable_crypt = yes ; then
1085                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1086                 fi
1087
1088                 AC_MSG_WARN(disabling crypt support)
1089                 ol_enable_crypt=no
1090         fi
1091 fi
1092
1093 # FreeBSD (and others) have setproctitle(3) in -lutil
1094 if test $ol_enable_proctitle != no ; then
1095         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1096                 AC_CHECK_LIB(util, setproctitle,
1097                         [have_setproctitle=yes
1098                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1099                         [have_setproctitle=no
1100                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1101
1102         if test $have_setproctitle = yes ; then
1103                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1104         fi
1105 fi
1106
1107 dnl ----------------------------------------------------------------
1108 dnl Checks for header files.
1109 AC_HEADER_STDC
1110
1111 if test $ac_cv_header_stdc != yes; then
1112         AC_MSG_WARN([could not Standard C compliant headers])
1113 fi
1114
1115 AC_HEADER_DIRENT
1116 AC_HEADER_SYS_WAIT
1117 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1118 if test $am_cv_sys_posix_termios = yes ; then
1119         AC_DEFINE(HAVE_POSIX_TERMIOS,1)
1120 fi
1121
1122 AC_CHECK_HEADERS(       \
1123         crypt.h                 \
1124         errno.h                 \
1125         fcntl.h                 \
1126         filio.h                 \
1127         getopt.h                \
1128         libutil.h               \
1129         limits.h                \
1130         malloc.h                \
1131         memory.h                \
1132         regex.h                 \
1133         psap.h                  \
1134         pwd.h                   \
1135         sgtty.h                 \
1136         stdarg.h                \
1137         stddef.h                \
1138         string.h                \
1139         strings.h               \
1140         sys/file.h              \
1141         sys/filio.h             \
1142         sys/errno.h             \
1143         sys/ioctl.h             \
1144         sys/param.h             \
1145         sys/resource.h  \
1146         sys/socket.h    \
1147         sys/syslog.h    \
1148         sys/time.h              \
1149         sys/types.h             \
1150         syslog.h                \
1151         termios.h               \
1152         unistd.h                \
1153 )
1154
1155 dnl ----------------------------------------------------------------
1156 dnl Checks for typedefs, structures, and compiler characteristics.
1157 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1158 AC_TYPE_MODE_T
1159 AC_TYPE_OFF_T
1160 AC_TYPE_PID_T
1161 AM_TYPE_PTRDIFF_T
1162 AC_TYPE_SIGNAL
1163 AC_TYPE_SIZE_T
1164 AC_STRUCT_ST_BLKSIZE
1165 AC_HEADER_TIME
1166 AC_STRUCT_TM
1167
1168 OL_C_UPPER_LOWER
1169 AC_C_CONST
1170
1171 if test $cross_compiling = yes ; then
1172         AC_DEFINE(CROSS_COMPILING, 1)
1173 else
1174         AC_C_BIGENDIAN
1175         AC_CHECK_SIZEOF(short)
1176         AC_CHECK_SIZEOF(int)
1177         AC_CHECK_SIZEOF(long)
1178 fi
1179
1180 dnl ----------------------------------------------------------------
1181 dnl Checks for library functions.
1182 AC_FUNC_MEMCMP
1183 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1184 AC_FUNC_STRFTIME
1185 dnl AM_FUNC_STRTOD
1186 AC_FUNC_VPRINTF
1187
1188 if test $ac_cv_func_vprintf = yes ; then
1189         dnl check for vsnprintf
1190         AC_CHECK_FUNCS(vsnprintf vsprintf)
1191 fi
1192
1193 AC_CHECK_FUNCS(         \
1194         bcopy                   \
1195         flock                   \
1196         getdtablesize   \
1197         gethostname             \
1198         getpwuid                \
1199         gettimeofday    \
1200         lockf                   \
1201         memcpy                  \
1202         memmove                 \
1203         mkstemp                 \
1204         select                  \
1205         setpwfile               \
1206         setsid                  \
1207         signal                  \
1208         sigset                  \
1209         snprintf                \
1210         socket                  \
1211         strerror                \
1212         strpbrk                 \
1213         strrchr                 \
1214         strsep                  \
1215         strstr                  \
1216         strtok                  \
1217         strtol                  \
1218         strtoul                 \
1219         sysconf                 \
1220         waitpid                 \
1221 )
1222
1223 dnl We actually may need to replace more than this.
1224 AC_REPLACE_FUNCS(getopt strdup tempnam)
1225
1226 dnl ----------------------------------------------------------------
1227 # Check Configuration
1228 OL_SYS_ERRLIST
1229
1230 dnl ----------------------------------------------------------------
1231 dnl Sort out defines
1232
1233 if test "$ol_enable_debug" != no ; then
1234         AC_DEFINE(LDAP_DEBUG,1)
1235 fi
1236 if test "$ol_enable_libui" = yes ; then
1237         AC_DEFINE(LDAP_LIBUI,1)
1238 fi
1239 if test "$ol_enable_cache" = no ; then
1240         AC_DEFINE(LDAP_NOCACHE,1)
1241 fi
1242 if test "$ol_enable_dns" != no ; then
1243         AC_DEFINE(LDAP_DNS,1)
1244 fi
1245 if test "$ol_enable_proctitle" != no ; then
1246         AC_DEFINE(LDAP_PROCTITLE,1)
1247 fi
1248 if test "$ol_enable_referrals" != no ; then
1249         AC_DEFINE(LDAP_REFERRALS,1)
1250 fi
1251 if test "$ol_enable_cldap" != no ; then
1252         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1253 fi
1254
1255 if test "$ol_enable_aclgroups" != no ; then
1256         AC_DEFINE(SLAPD_ACLGROUPS,1)
1257 fi
1258 if test "$ol_enable_crypt" != no ; then
1259         AC_DEFINE(SLAPD_CRYPT,1)
1260 fi
1261 if test "$ol_enable_cleartext" != no ; then
1262         AC_DEFINE(SLAPD_CLEARTEXT,1)
1263 fi
1264 if test "$ol_enable_phonetic" != no ; then
1265         AC_DEFINE(SLAPD_PHONETIC,1)
1266 fi
1267 if test "$ol_enable_rlookups" != no ; then
1268         AC_DEFINE(SLAPD_RLOOKUPS,1)
1269 fi
1270
1271 if test "$ol_link_ldbm" != no ; then
1272         AC_DEFINE(SLAPD_LDBM,1)
1273         BUILD_SLAPD=yes
1274         BUILD_LDBM=yes
1275 fi
1276
1277 if test "$ol_enable_passwd" != no ; then
1278         AC_DEFINE(SLAPD_PASSWD,1)
1279         BUILD_SLAPD=yes
1280         BUILD_PASSWD=yes
1281 fi
1282
1283 if test "$ol_enable_shell" != no ; then
1284         AC_DEFINE(SLAPD_SHELL,1)
1285         BUILD_SLAPD=yes
1286         BUILD_SHELL=yes
1287 fi
1288
1289 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1290         $BUILD_SLAPD = yes ; then
1291         BUILD_SLURPD=yes
1292 fi
1293
1294 if test "$ol_link_isode" != no ; then
1295         BUILD_LDAPD=yes
1296 fi
1297
1298 dnl ----------------------------------------------------------------
1299
1300 AC_SUBST(BUILD_LDAPD)
1301 AC_SUBST(BUILD_SLAPD)
1302   AC_SUBST(BUILD_LDBM)
1303   AC_SUBST(BUILD_PASSWD)
1304   AC_SUBST(BUILD_SHELL)
1305 AC_SUBST(BUILD_SLURPD)
1306
1307 AC_SUBST(LDAP_LIBS)
1308 AC_SUBST(LDAPD_LIBS)
1309 AC_SUBST(SLAPD_LIBS)
1310 AC_SUBST(SLURPD_LIBS)
1311 AC_SUBST(LDBM_LIBS)
1312 AC_SUBST(LTHREAD_LIBS)
1313 AC_SUBST(LUTIL_LIBS)
1314
1315 AC_SUBST(KRB_LIBS)
1316 AC_SUBST(TERMCAP_LIBS)
1317
1318 dnl ----------------------------------------------------------------
1319 dnl final output
1320 dnl
1321
1322 AC_OUTPUT( \
1323 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1324 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1325 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1326 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1327 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1328 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1329 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1330 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1331 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1332 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1333 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1334 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1335 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1336 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1337 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1338 include/Makefile:build/top.mk:include/Makefile.in \
1339 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1340 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1341 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1342 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1343 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1344 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1345 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk:build/lib-static.mk    \
1346 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1347 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1348 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1349 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1350 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1351 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1352 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1353 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1354 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1355 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1356 tests/Makefile:build/top.mk:tests/Makefile.in \
1357 ,[
1358 date > stamp-h
1359 echo Please \"make depend\" to build dependencies
1360 ])