git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Disable config.cache!
  11 define([AC_CACHE_LOAD], )dnl
  12 define([AC_CACHE_SAVE], )dnl
  13
  14 dnl Configure.in for OpenLDAP
  15 AC_INIT(build/version)dnl
  16 AC_CONFIG_AUX_DIR(build)dnl
  17
  18 OL_VERSION=`cat $ac_aux_dir/version`
  19 if test -z "$OL_VERSION"; then
  20         AC_MSG_ERROR([could not determine version])
  21 fi
  22
  23 dnl ----------------------------------------------------------------
  24 dnl Determine host platform
  25 dnl             we try not to use this for much
  26 AC_CANONICAL_SYSTEM
  27
  28 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  29 AC_SUBST(PACKAGE)
  30 AC_SUBST(VERSION)
  31 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  32 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  33
  34 dnl We use autoconf features new to 2.13.
  35 dnl     aclocal.m4 should be built using aclocal from automake 1.4
  36 AC_PREREQ(2.13)dnl Required Autoconf version
  37
  38 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  39
  40 dnl
  41 dnl Start Args
  42 AC_MSG_CHECKING(configure arguments)
  43 AC_PREFIX_DEFAULT(/usr/local)
  44
  45 top_builddir=`pwd`
  46 AC_SUBST(top_builddir)dnl
  47
  48 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
  49
  50 ldap_subdir="openldap"
  51
  52 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  53         if test "$withval" = "no"; then
  54                 ldap_subdir=""
  55         elif test "$withval" != "yes"; then
  56                 ldap_subdir="$withval"
  57         fi
  58 ])dnl
  59
  60 AC_SUBST(ldap_subdir)dnl
  61
  62 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  63 dnl ol_enable_syslog=no
  64 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  65 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  66 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  67 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  68 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  69 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  70 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  71         no, [yes no])dnl
  72
  73 dnl General "with" options
  74 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  75
  76 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  77         auto, [auto k5 k4 afs yes no])
  78 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  79         auto, [auto yes no] )
  80 OL_ARG_WITH(threads,[  --with-threads   use threads],
  81         auto, [auto posix mach lwp yes no manual] )
  82 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  83         auto, [auto ssleay openssl yes no] )
  84 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  85         auto, [auto yes no manual] )
  86
  87 dnl Server options
  88
  89 dnl LDAPD OPTIONS
  90 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  91 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  92
  93 dnl SLAPD OPTIONS
  94 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  95 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  96 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  97 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  98 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
  99 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
 100 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
 101 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
 102
 103 dnl SLAPD Backend options
 104 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 105 OL_ARG_WITH(bdb2_module,[      --with-bdb2-module       module type], static,
 106         [static dynamic])
 107 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 108 OL_ARG_WITH(ldap_module,[      --with-ldap-module       module type], static,
 109         [static dynamic])
 110 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 111 OL_ARG_WITH(ldbm_module,[      --with-ldbm-module       module type], static,
 112         [static dynamic])
 113 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 114         [auto db2 db mdbm gdbm ndbm manual])
 115 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 116         [auto btree hash])
 117
 118 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 119 OL_ARG_WITH(passwd_module,[      --with-passwd-module   module type], static,
 120         [static dynamic])
 121 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 122 OL_ARG_WITH(perl_module,[      --with-perl-module       module type], static,
 123         [static dynamic])
 124 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 125 OL_ARG_WITH(shell_module,[      --with-shell-module     module type], static,
 126         [static dynamic])
 127 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 128 OL_ARG_WITH(tcl_module,[      --with-tcl-module module type], static,
 129         [static dynamic])
 130
 131 dnl SLURPD OPTIONS
 132 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
 133 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 134
 135 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 136 AM_ENABLE_STATIC
 137 dnl AM_DISABLE_SHARED
 138 AM_ENABLE_SHARED
 139
 140 dnl General "enable" options
 141 # validate options
 142 if test $ol_enable_dns = yes ; then
 143         if test $ol_enable_referrals = no ; then
 144                 AC_MSG_ERROR([DNS requires --enable-referrals])
 145         fi
 146         if test $ol_enable_referrals = auto ; then
 147                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 148                 ol_enable_referrals=yes
 149         fi
 150 fi
 151
 152 if test $ol_enable_slapd = no ; then
 153         dnl SLAPD was specificallly disabled
 154         if test $ol_enable_bdb2 = yes ; then
 155                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 156         fi
 157         if test $ol_enable_ldap = yes ; then
 158                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 159         fi
 160         if test $ol_enable_ldbm = yes ; then
 161                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 162         fi
 163         if test $ol_enable_passwd = yes ; then
 164                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 165         fi
 166         if test $ol_enable_perl = yes ; then
 167                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 168         fi
 169         if test $ol_enable_shell = yes ; then
 170                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 171         fi
 172         if test $ol_enable_tcl = yes ; then
 173                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 174         fi
 175         if test $ol_enable_modules = yes ; then
 176                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 177         fi
 178         if test $ol_enable_wrappers = yes ; then
 179                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 180         fi
 181         if test $ol_enable_phonetic = yes ; then
 182                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 183         fi
 184         if test $ol_enable_rlookups = yes ; then
 185                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 186         fi
 187         if test $ol_with_ldbm_api != auto ; then
 188                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 189         fi
 190         if test $ol_with_ldbm_type != auto ; then
 191                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 192         fi
 193         if test $ol_with_bdb2_module != static ; then
 194                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb2-module argument])
 195         fi
 196         if test $ol_with_ldap_module != static ; then
 197                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 198         fi
 199         if test $ol_with_ldbm_module != static ; then
 200                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 201         fi
 202         if test $ol_with_passwd_module != static ; then
 203                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 204         fi
 205         if test $ol_with_perl_module != static ; then
 206                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 207         fi
 208         if test $ol_with_shell_module != static ; then
 209                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 210         fi
 211         if test $ol_with_tcl_module != static ; then
 212                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 213         fi
 214         if test $ol_enable_slurpd = yes ; then
 215                 AC_MSG_ERROR([slurpd requires slapd])
 216         fi
 217
 218         # force settings to no
 219         ol_enable_bdb2=no
 220         ol_enable_ldap=no
 221         ol_enable_ldbm=no
 222         ol_enable_passwd=no
 223         ol_enable_perl=no
 224         ol_enable_shell=no
 225         ol_enable_tcl=no
 226
 227         ol_enable_modules=no
 228         ol_enable_phonetic=no
 229         ol_enable_rlookups=no
 230         ol_enable_wrappers=no
 231
 232         ol_with_ldbm_api=no
 233         ol_with_ldbm_type=no
 234
 235         ol_with_bdb2_module=static
 236         ol_with_ldap_module=static
 237         ol_with_ldbm_module=static
 238         ol_with_passwd_module=static
 239         ol_with_perl_module=static
 240         ol_with_shell_module=static
 241         ol_with_tcl_module=static
 242
 243         ol_enable_slurpd=no
 244
 245 elif test $ol_enable_ldbm = no ; then
 246         dnl SLAPD without LDBM
 247
 248         if test $ol_with_ldbm_api != auto ; then
 249                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 250         fi
 251
 252         if test $ol_with_ldbm_type != auto ; then
 253                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 254         fi
 255
 256         if test $ol_with_ldbm_module != static ; then
 257                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 258         fi
 259
 260         if test $ol_enable_bdb2 = yes ; then
 261                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 262         fi
 263
 264         if test $ol_enable_modules != yes -a \
 265                 $ol_enable_ldap = no -a \
 266                 $ol_enable_passwd = no -a \
 267                 $ol_enable_perl = no -a \
 268                 $ol_enable_shell = no -a \
 269                 $ol_enable_tcl = no ; then
 270                 AC_MSG_ERROR([slapd requires a backend])
 271         fi
 272
 273         ol_with_ldbm_api=no
 274         ol_with_ldbm_type=no
 275         ol_with_ldbm_module=static
 276
 277 elif test $ol_enable_bdb2 = yes ; then
 278         dnl SLAPD with BDB2
 279
 280         if test $ol_with_ldbm_api != auto -a \
 281                 $ol_with_ldbm_api != db2 ; then
 282                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 283         fi
 284
 285         ol_with_ldbm_api=db2
 286
 287 else
 288         dnl SLAPD with LDBM
 289
 290         if test $ol_enable_bdb2 != no ; then
 291                 if test $ol_with_ldbm_api != auto -a \
 292                         $ol_with_ldbm_api != db2 ; then
 293                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 294                         ol_enable_bdb2=no
 295                 fi
 296         fi
 297
 298         if test $ol_with_ldbm_api = gdbm -a \
 299                 $ol_with_ldbm_type = btree ; then
 300                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 301         fi
 302         if test $ol_with_ldbm_api = mdbm -a \
 303                 $ol_with_ldbm_type = btree ; then
 304                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 305         fi
 306         if test $ol_with_ldbm_api = ndbm -a \
 307                 $ol_with_ldbm_type = btree ; then
 308                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 309         fi
 310 fi
 311
 312 if test $ol_enable_slurpd = yes ; then
 313         dnl SLURPD was specifically enabled
 314         if test $ol_with_threads = no ; then
 315                 AC_MSG_ERROR([slurpd requires threads])
 316         fi
 317 fi
 318
 319 AC_MSG_RESULT(done)
 320
 321 ## Initialize vars
 322 LDAP_LIBS=
 323 LDBM_LIBS=
 324 LTHREAD_LIBS=
 325 LUTIL_LIBS=
 326
 327 LDAPD_LIBS=
 328 SLAPD_LIBS=
 329 SLURPD_LIBS=
 330
 331 BUILD_LDAPD=no
 332 BUILD_SLAPD=no
 333 BUILD_SLURPD=no
 334
 335 BUILD_BDB2=no
 336 BUILD_LDAP=no
 337 BUILD_LDBM=no
 338 BUILD_PASSWD=no
 339 BUILD_PERL=no
 340 BUILD_SHELL=no
 341 BUILD_TCL=no
 342 BUILD_THREAD=no
 343
 344 BUILD_BDB2_DYNAMIC=no
 345 BUILD_LDAP_DYNAMIC=no
 346 BUILD_LDBM_DYNAMIC=no
 347 BUILD_PASSWD_DYNAMIC=no
 348 BUILD_PERL_DYNAMIC=no
 349 BUILD_SHELL_DYNAMIC=no
 350 BUILD_TCL_DYNAMIC=no
 351
 352 SLAPD_MODULES_LDFLAGS=
 353 SLAPD_MODULES_CPPFLAGS=
 354
 355 SLAPD_PERL_LDFLAGS=
 356 SLAPD_PERL_CPPFLAGS=
 357
 358 KRB_LIBS=
 359 READLINE_LIBS=
 360 TERMCAP_LIBS=
 361 TLS_LIBS=
 362
 363 dnl ----------------------------------------------------------------
 364 dnl Checks for programs
 365
 366 dnl AC_PROG_INSTALL
 367
 368 dnl AIX Thread requires we use cc_r or xlc_r.
 369 dnl But only do this IF AIX and CC is not set
 370 dnl and threads are auto|yes|posix.
 371 dnl
 372 dnl If we find cc_r|xlc_r, force pthreads and assume
 373 dnl             pthread_create is in $LIBS (ie: don't bring in
 374 dnl             any additional thread libraries)
 375 dnl If we do not find cc_r|xlc_r, disable threads
 376
 377 ol_aix_threads=no
 378 case "$target" in
 379 *-*-aix*) dnl all AIX is not a good idea.
 380         if test -z "CC" ; then
 381                 case "$ol_with_threads" in
 382                 auto | yes |  posix) ol_aix_threads=yes ;;
 383                 esac
 384         fi
 385 ;;
 386 esac
 387
 388 if test $ol_aix_threads = yes ; then
 389         if test -z "${CC}" ; then
 390                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 391
 392                 if test "$CC" = cc ; then
 393                         dnl no CC! don't allow --with-threads
 394                         if test $ol_with_threads != auto ; then
 395                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 396                         else
 397                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 398                         fi
 399                         ol_with_threads=no
 400                 fi
 401         fi
 402
 403         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 404                 ol_with_threads=posix
 405                 ol_cv_pthread_create=yes
 406         fi
 407 fi
 408
 409 if test -z "${CC}"; then
 410         AC_CHECK_PROGS(CC,cc)
 411 fi
 412
 413 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 414 dnl (for now, let autoconf sort this out)
 415 dnl CFLAGS=${CFLAGS-""}
 416
 417 AM_PROG_LIBTOOL
 418 dnl AC_PROG_MAKE_SET
 419
 420 AC_PROG_AWK
 421 OL_PROG_LN_H
 422 AC_PROG_LN_S
 423
 424 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 425         LN_S="$LN_H"
 426 fi
 427
 428 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 429         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 430 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 431 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 432
 433 ol_link_modules=no
 434 if test $ol_enable_modules != no ; then
 435         AC_PATH_PROG(GLIBCONFIG, glib-config)
 436
 437         if test "no$GLIBCONFIG" = "no" ; then
 438                 if test $ol_enable_modules = yes ; then
 439                         AC_MSG_ERROR([could not locate glib-config])
 440                 fi
 441
 442         else
 443                 SLAPD_MODULES_VERSION="`$GLIBCONFIG --version gmodule`"
 444                 SLAPD_MODULES_CPPFLAGS="`$GLIBCONFIG --cflags gmodule`"
 445                 SLAPD_MODULES_LDFLAGS="`$GLIBCONFIG --libs gmodule`"
 446
 447                 dnl should check glib version
 448                 ol_link_modules=yes
 449         fi
 450 else
 451         ol_with_bdb2_module=static
 452         ol_with_ldap_module=static
 453         ol_with_ldbm_module=static
 454         ol_with_passwd_module=static
 455         ol_with_perl_module=static
 456         ol_with_shell_module=static
 457         ol_with_tcl_module=static
 458 fi
 459
 460 ol_link_perl=no
 461 if test $ol_enable_perl != no ; then
 462         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 463
 464         if test "no$PERLBIN" = "no" ; then
 465                 if test $ol_enable_perl = yes ; then
 466                         AC_MSG_ERROR([could not locate perl])
 467                 fi
 468
 469         else
 470                 SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 471                 SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 472
 473                 dnl should check perl version
 474                 ol_link_perl=yes
 475         fi
 476 fi
 477
 478 AC_PROG_CPP
 479
 480 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 481         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 482
 483 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 484         AC_MSG_WARN([programs compiled here do run here...])
 485         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 486
 487 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 488         AC_MSG_WARN([programs compiled here do not run here...])
 489         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 490 fi
 491
 492 dnl Checks for UNIX Variants
 493 AC_AIX
 494 AC_ISC_POSIX
 495 AC_MINIX
 496
 497 dnl BeOS requires -lbe -lroot -lnet
 498 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 499
 500 dnl Checks for system services
 501 AC_CYGWIN
 502 AC_MINGW32
 503 AC_EXEEXT
 504 AC_OBJEXT
 505
 506 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 507
 508 dnl OpenLDAP requires STDC features
 509 AM_PROG_CC_STDC
 510 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 511         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 512 fi
 513
 514 dnl AM_C_PROTOTYPES
 515
 516 dnl Check cc depend flags
 517 OL_MKDEPEND
 518 if test "${ol_cv_mkdep}" = no ; then
 519         # this will soon become an error
 520         AC_MSG_WARN([do not know how to generate dependencies])
 521 fi
 522
 523 dnl Checks for libraries
 524
 525 dnl Find socket()
 526 dnl Likely combinations:
 527 dnl             -lsocket [ -lnsl_s | -lnsl ]
 528 dnl             -linet
 529
 530 AC_CHECK_FUNC(socket, :, [
 531 dnl
 532 dnl hopefully we won't include too many libraries
 533 dnl
 534         AC_CHECK_LIB(socket, main)
 535         AC_CHECK_LIB(net, main)
 536         AC_CHECK_LIB(net, socket)
 537         AC_CHECK_LIB(nsl_s, main)
 538         AC_CHECK_LIB(nsl, main)
 539         AC_CHECK_LIB(inet, socket)
 540         AC_CHECK_LIB(gen, main)
 541 ])
 542
 543 dnl Check for resolver routines
 544 AC_CHECK_FUNCS(res_search)
 545 if test $ac_cv_func_res_search = "no" ; then
 546         AC_CHECK_LIB(bind, res_search)
 547         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 548                 AC_DEFINE(HAVE_RES_SEARCH,1)
 549         else
 550                 AC_CHECK_LIB(resolv, res_search)
 551                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 552                         AC_DEFINE(HAVE_RES_SEARCH,1)
 553                 fi
 554         fi
 555 fi
 556
 557 dnl HP-UX requires -lV3
 558 AC_CHECK_LIB(V3, sigset)
 559
 560 AC_CHECK_HEADERS( regex.h )
 561 if test "$ac_cv_header_regex_h" != yes ; then
 562         AC_MSG_ERROR([POSIX regex.h required.])
 563 fi
 564 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 565
 566 OL_POSIX_REGEX
 567 if test "$ol_cv_c_posix_regex" = no ; then
 568         AC_MSG_ERROR([broken POSIX regex!])
 569 fi
 570
 571 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 572
 573 dnl Select arg types
 574 dnl (if this detection becomes permenent, it and the select() detection
 575 dnl should be done before the yielding select test)
 576 AC_FUNC_SELECT_ARGTYPES
 577
 578 # ISODE tests
 579 ol_link_isode=no
 580 if test $ol_enable_ldapd != no ; then
 581         AC_MSG_WARN([ldapd is not supported and may suffer from bit rot.])
 582
 583         dnl look for ISODE libraries
 584         AC_CHECK_LIB(xtpp, main, [
 585                 ol_link_isode=yes
 586                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 587                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 588                 ],:,[-lxtdsap -lxtisode -losi])
 589         AC_CHECK_LIB(dsap, main, [
 590                 ol_link_isode=yes
 591                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 592                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 593                 ],:,[-lisode])
 594         AC_CHECK_LIB(isode, main, [
 595                 ol_link_isode=yes
 596                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 597                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 598                 ],:)
 599 fi
 600
 601 if test $ol_link_isode != no; then
 602         AC_CHECK_LIB(pp, main, [
 603                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 604                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 605                 ],:)
 606
 607         AC_PATH_PROG(PEPSY, pepsy)
 608 fi
 609
 610 dnl
 611 dnl check for kerberos
 612 dnl
 613 ol_link_kerberos=no
 614
 615 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 616         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 617
 618         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 619                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 620                         [-lkrb5 -ldes425])
 621
 622                 if test $have_k5 = yes ; then
 623                         ol_with_kerberos=found
 624                         ol_link_kerberos=yes
 625
 626                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 627
 628                         LIBS="$KRB_LIBS $LIBS"
 629
 630                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 631                                 [ol_cv_var_des_debug], [
 632                                 dnl save the flags
 633                                 save_LIBS="$LIBS"
 634                                 LIBS="$KRB_LIBS $LIBS"
 635                                 AC_TRY_LINK([
 636 #include <kerberosIV/krb.h>
 637 #include <kerberosIV/des.h>
 638 extern int des_debug;
 639 ],[
 640 des_debug = 1;
 641 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 642                                 dnl restore the LIBS
 643                                 LIBS="$save_LIBS"
 644                         ])
 645
 646                         if test $ol_cv_var_des_debug = yes ; then
 647                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 648                                         [define if you have Kerberos des_debug])
 649                         fi
 650
 651                         LIBS="$save_LIBS"
 652                 fi
 653         fi
 654 fi
 655
 656 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 657         AC_CHECK_HEADERS(krb.h des.h)
 658
 659         if test $ac_cv_header_krb_h = yes ; then
 660                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 661
 662                 if test $have_k4 = yes ; then
 663                         ol_with_kerberos=found
 664                         ol_link_kerberos=yes
 665
 666                         KRB_LIBS="-lkrb -ldes"
 667                 fi
 668         fi
 669 fi
 670
 671 if test $ol_link_kerberos = yes ; then
 672         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 673 fi
 674
 675 dnl
 676 dnl Check for SSL/TLS
 677 dnl
 678 ol_link_tls=no
 679 if test $ol_with_tls != no ; then
 680
 681         AC_CHECK_HEADERS(ssl.h)
 682
 683         if test $ac_cv_header_ssl_h = yes ; then
 684                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 685                         [have_ssleay=yes
 686                         need_rsaref=no],
 687                         [have_ssleay=no],
 688                         [-lcrypto])
 689
 690                 if test $have_ssleay = no ; then
 691                         AC_CHECK_LIB(ssl, ssl3_accept,
 692                                 [have_ssleay=yes
 693                                 need_rsaref=yes], [have_ssleay=no],
 694                                 [-lcrypto -lRSAglue -lrsaref])
 695                 fi
 696
 697                 if test $have_ssleay = yes ; then
 698                         ol_with_tls=found
 699                         ol_link_tls=yes
 700
 701                         AC_DEFINE(HAVE_SSLEAY, 1,
 702                                 [define if you have SSLeay or OpenSSL])
 703
 704                         if test $need_rsaref = yes; then
 705                                 AC_DEFINE(HAVE_RSAREF, 1,
 706                                         [define if you have RSAref])
 707
 708                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 709                         else
 710                                 TLS_LIBS="-lssl -lcrypto"
 711                         fi
 712                 fi
 713         fi
 714 fi
 715
 716 if test $ol_link_tls = yes ; then
 717         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 718 fi
 719
 720 dnl Tests for reentrant functions necessary to build a
 721 dnl thread_safe -lldap.
 722 AC_CHECK_FUNCS(         \
 723         ctime_r                 \
 724         gethostbyname_r gethostbyaddr_r \
 725 )
 726
 727 if test "$ac_cv_func_ctime_r" = no ; then
 728         ol_cv_func_ctime_r_nargs=0
 729 else
 730         OL_FUNC_CTIME_R_NARGS
 731 dnl     OL_FUNC_CTIME_R_TYPE
 732 fi
 733
 734 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 735         OL_FUNC_GETHOSTBYNAME_R_NARGS
 736 else
 737         ol_cv_func_gethostbyname_r_nargs=0
 738 fi
 739
 740 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 741         OL_FUNC_GETHOSTBYADDR_R_NARGS
 742 else
 743         ol_cv_func_gethostbyaddr_r_nargs=0
 744 fi
 745
 746 if test "$ac_cv_func_ctime_r" = yes \
 747         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 748         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 749         -a "$ac_cv_func_gethostbyname_r" = yes \
 750         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 751         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 752         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 753         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 754         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 755         ; then
 756
 757         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 758 fi
 759
 760 ol_link_threads=no
 761 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 762         -o $ol_with_threads = posix ; then
 763
 764         AC_CHECK_HEADERS(pthread.h sched.h)
 765
 766         if test $ac_cv_header_pthread_h = yes ; then
 767                 OL_POSIX_THREAD_VERSION
 768
 769                 if test $ol_cv_pthread_version = final ; then
 770                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 771                                 [define if pthreads API compatible with final spec])
 772                 elif test $ol_cv_pthread_version = draft4 ; then
 773                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 774                                 [define if pthreads API compatible with draft4 spec])
 775                 else
 776                         AC_MSG_ERROR([unknown pthread version])
 777                 fi
 778
 779                 # consider threads found
 780                 ol_with_threads=found
 781
 782                 OL_HEADER_LINUX_THREADS
 783
 784                 dnl Now the hard part, how to link?
 785                 dnl
 786                 dnl currently supported checks:
 787                 dnl
 788                 dnl Check for no flags
 789                 dnl     pthread_create() in $LIBS
 790                 dnl
 791                 dnl Check special pthread (final) flags
 792                 dnl     pthread_create() with -mt (Solaris)
 793                 dnl     pthread_create() with -kthread (FreeBSD)
 794                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 795                 dnl     pthread_create() with -pthreads (?)
 796                 dnl     pthread_create() with -thread (?)
 797                 dnl
 798                 dnl Check pthread (final) libraries
 799                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 800                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 801                 dnl     (skipped) pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 802                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
 803                 dnl     pthread_create() in -lpthread (many)
 804                 dnl     pthread_create() in -lc_r (FreeBSD)
 805                 dnl
 806                 dnl Check pthread (draft4) flags (depreciated)
 807                 dnl     pthread_create() with -threads (OSF/1)
 808                 dnl
 809                 dnl Check pthread (draft4) libraries (depreciated)
 810                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 811                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 812                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 813                 dnl     pthread_create() in -lpthreads (many)
 814                 dnl
 815
 816                 dnl pthread_create in $LIBS
 817                 AC_MSG_CHECKING([for pthread_create in default libraries])
 818                 AC_CACHE_VAL(ol_cv_pthread_create,[
 819                 AC_TRY_RUN([
 820 #include <pthread.h>
 821 #ifndef NULL
 822 #define NULL (void*)0
 823 #endif
 824
 825 static void *task(p)
 826         void *p;
 827 {
 828         return (void *) (p == NULL);
 829 }
 830
 831 int main(argc, argv)
 832         int argc;
 833         char **argv;
 834 {
 835         pthread_t t;
 836         int status;
 837
 838         /* make sure pthread_create() isn't just a stub */
 839 #if HAVE_PTHREADS_D4
 840         status = pthread_create(&t, pthread_attr_default, task, NULL);
 841 #else
 842         status = pthread_create(&t, NULL, task, NULL);
 843 #endif
 844
 845         if( status ) return status;
 846
 847         /* make sure pthread_detach() isn't just a stub */
 848 #if HAVE_PTHREADS_D4
 849         status = pthread_detach( &t );
 850 #else
 851         status = pthread_detach( t );
 852 #endif
 853
 854         if( status ) return status;
 855
 856         return status;
 857 }
 858 ],
 859                         [ol_cv_pthread_create=yes],
 860                         [ol_cv_pthread_create=no],
 861                         [dnl assume yes
 862                         ol_cv_pthread_create=yes])])
 863                 AC_MSG_RESULT($ol_cv_pthread_create)
 864
 865                 if test $ol_cv_pthread_create != no ; then
 866                         ol_link_threads=posix
 867                         ol_link_pthreads=""
 868                 fi
 869
 870                 OL_PTHREAD_TRY_LINK([-mt],              [ol_cv_pthread_mt])
 871                 OL_PTHREAD_TRY_LINK([-kthread], [ol_cv_pthread_kthread])
 872                 OL_PTHREAD_TRY_LINK([-pthread], [ol_cv_pthread_pthread])
 873                 OL_PTHREAD_TRY_LINK([-pthreads],[ol_cv_pthread_pthreads])
 874                 OL_PTHREAD_TRY_LINK([-thread],  [ol_cv_pthread_thread])
 875
 876                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc -lc_r],
 877                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
 878                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc],
 879                         [ol_cv_pthread_lpthread_lmach_lexc])
 880 dnl             OL_PTHREAD_TRY_LINK([-lpthread -lexc],
 881 dnl                     [ol_cv_pthread_lpthread_lexc])
 882
 883                 OL_PTHREAD_TRY_LINK([-lpthread -Wl,-woff,85],
 884                         [ol_cv_pthread_lib_lpthread_woff])
 885
 886                 OL_PTHREAD_TRY_LINK([-lpthread],[ol_cv_pthread_lpthread])
 887                 OL_PTHREAD_TRY_LINK([-lc_r],    [ol_cv_pthread_lc_r])
 888
 889                 OL_PTHREAD_TRY_LINK([-threads], [ol_cv_pthread_threads])
 890
 891                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc -lc_r],
 892                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
 893                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc],
 894                         [ol_cv_pthread_lpthreads_lmach_lexc])
 895                 OL_PTHREAD_TRY_LINK([-lpthreads -lexc],
 896                         [ol_cv_pthread_lpthreads_lexc])
 897
 898                 OL_PTHREAD_TRY_LINK([-lpthreads],       [ol_cv_pthread_lib_lpthreads])
 899
 900                 if test $ol_link_threads != no ; then
 901                         AC_DEFINE(HAVE_PTHREADS,1,
 902                                 [define if you have POSIX Threads])
 903
 904                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
 905
 906                         dnl save flags
 907                         save_CPPFLAGS="$CPPFLAGS"
 908                         save_LIBS="$LIBS"
 909                         LIBS="$LTHREAD_LIBS $LIBS"
 910
 911                         dnl All POSIX Thread (final) implementations should have
 912                         dnl sched_yield instead of pthread yield.
 913                         dnl check for both
 914                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 915
 916                         if test $ac_cv_func_sched_yield = no -a \
 917                                 $ac_cv_func_pthread_yield = no ; then
 918                                 dnl Digital UNIX has sched_yield() in -lrt
 919                                 AC_CHECK_LIB(rt, sched_yield,
 920                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 921                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 922                                         ac_cv_func_sched_yield=yes],
 923                                         [ac_cv_func_sched_yield=no])
 924                         fi
 925                         if test $ac_cv_func_sched_yield = no -a \
 926                                 $ac_cv_func_pthread_yield = no ; then
 927                                 dnl Solaris has sched_yield() stub in -lposix4
 928                                 dnl but we'll use thr_yield instead.
 929                                 AC_CHECK_FUNCS(thr_yield)
 930                         fi
 931                         if test $ac_cv_func_sched_yield = no -a \
 932                                 $ac_cv_func_pthread_yield = no -a \
 933                                 "$ac_cv_func_thr_yield" = no ; then
 934                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 935                         fi
 936
 937                         dnl Check functions for compatibility
 938                         AC_CHECK_FUNCS(pthread_kill)
 939
 940                         dnl Check for pthread_detach with <pthread.h> inclusion
 941                         dnl as it's symbol may have been mangled.
 942                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
 943                                 [ol_cv_func_pthread_detach], [
 944                                 dnl save the flags
 945                                 AC_TRY_LINK([
 946 #include <pthread.h>
 947 #ifndef NULL
 948 #define NULL (void*)0
 949 #endif
 950 ],
 951                                         [pthread_detach(NULL);],
 952                                         [ol_cv_func_pthread_detach=yes],
 953                                         [ol_cv_func_pthread_detach=no])
 954                         ])
 955
 956                         if test $ol_cv_func_pthread_detach = no ; then
 957                                 AC_MSG_ERROR([could not locate pthread_detach()])
 958                         fi
 959
 960                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
 961                                 [define if you have pthread_detach function])
 962
 963                         dnl Check for setconcurreny functions
 964                         AC_CHECK_FUNCS( \
 965                                 pthread_setconcurrency \
 966                                 pthread_getconcurrency \
 967                                 thr_setconcurrency \
 968                                 thr_getconcurrency \
 969                         )
 970
 971                         OL_SYS_LINUX_THREADS
 972                         OL_LINUX_THREADS
 973
 974                         if test $ol_cv_linux_threads = error; then
 975                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
 976                         fi
 977
 978                         AC_MSG_CHECKING([if pthread_create() works])
 979                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 980                         AC_TRY_RUN([
 981 #include <pthread.h>
 982 #ifndef NULL
 983 #define NULL (void*)0
 984 #endif
 985
 986 static void *task(p)
 987         void *p;
 988 {
 989         return (void *) (p == NULL);
 990 }
 991
 992 int main(argc, argv)
 993         int argc;
 994         char **argv;
 995 {
 996         pthread_t t;
 997 #if HAVE_PTHREADS_D4
 998         exit(pthread_create(&t, pthread_attr_default, task, NULL));
 999 #else
1000         exit(pthread_create(&t, NULL, task, NULL));
1001 #endif
1002 }
1003 ],
1004                                 [ol_cv_pthread_create_works=yes],
1005                                 [ol_cv_pthread_create_works=no],
1006                                 [dnl assume yes
1007                                 ol_cv_pthread_create_works=yes])])
1008                         AC_MSG_RESULT($ol_cv_pthread_create_works)
1009
1010                         if test $ol_cv_pthread_create_works = no ; then
1011                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1012                         fi
1013
1014                         dnl Check if select causes an yield
1015                         if test $ol_with_yielding_select = auto ; then
1016                                 AC_MSG_CHECKING([if select yields when using pthreads])
1017                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
1018                                 AC_TRY_RUN([
1019 #include <sys/types.h>
1020 #include <sys/time.h>
1021 #include <unistd.h>
1022 #include <pthread.h>
1023 #ifndef NULL
1024 #define NULL (void*) 0
1025 #endif
1026
1027 static int fildes[2];
1028
1029 static void *task(p)
1030         void *p;
1031 {
1032         int i;
1033         struct timeval tv;
1034
1035         fd_set rfds;
1036
1037         tv.tv_sec=10;
1038         tv.tv_usec=0;
1039
1040         FD_ZERO(&rfds);
1041         FD_SET(fildes[0], &rfds);
1042
1043         /* we're not interested in any fds */
1044         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1045
1046         if(i < 0) {
1047                 perror("select");
1048                 exit(10);
1049         }
1050
1051         exit(0); /* if we exit here, the select blocked the whole process */
1052 }
1053
1054 int main(argc, argv)
1055         int argc;
1056         char **argv;
1057 {
1058         pthread_t t;
1059
1060         /* create a pipe to select */
1061         if(pipe(&fildes[0])) {
1062                 perror("select");
1063                 exit(1);
1064         }
1065
1066 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1067         (void) pthread_setconcurrency(2);
1068 #else
1069 #ifdef HAVE_THR_SETCONCURRENCY
1070         /* Set Solaris LWP concurrency to 2 */
1071         thr_setconcurrency(2);
1072 #endif
1073 #endif
1074
1075 #if HAVE_PTHREADS_D4
1076         pthread_create(&t, pthread_attr_default, task, NULL);
1077 #else
1078         pthread_create(&t, NULL, task, NULL);
1079 #endif
1080
1081 #if HAVE_SCHED_YIELD
1082         sched_yield();  /* make sure task runs first */
1083 #else
1084 #ifdef HAVE_PTHREAD_YIELD
1085         pthread_yield();        /* make sure task runs first */
1086 #endif
1087 #endif
1088
1089         exit(2);
1090 }],
1091                                 [ol_cv_pthread_select_yields=no],
1092                                 [ol_cv_pthread_select_yields=yes], [
1093                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
1094                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
1095
1096                                 if test $ol_cv_pthread_select_yields = yes ; then
1097                                         ol_with_yielding_select=yes
1098                                 fi
1099                         fi
1100
1101                         dnl restore flags
1102                         CPPFLAGS="$save_CPPFLAGS"
1103                         LIBS="$save_LIBS"
1104                 else
1105                         AC_MSG_ERROR([could not link with POSIX Threads])
1106                 fi
1107         fi
1108
1109         if test $ol_with_threads = posix ; then
1110                 AC_MSG_ERROR([could not locate POSIX Threads])
1111         fi
1112 fi
1113
1114 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1115         -o $ol_with_threads = mach ; then
1116
1117         dnl check for Mach CThreads
1118         AC_CHECK_HEADERS(mach/cthreads.h)
1119         if test $ac_cv_header_mach_cthreads_h = yes ; then
1120                 ol_with_threads=found
1121
1122                 dnl check for cthread support in current $LIBS
1123                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1124
1125                 if test $ol_link_threads = no ; then
1126                         dnl try -all_load
1127                         dnl this test needs work
1128                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1129                                 [ol_cv_cthread_all_load], [
1130                                 dnl save the flags
1131                                 save_LIBS="$LIBS"
1132                                 LIBS="-all_load $LIBS"
1133                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1134                                         cthread_fork((void *)0, (void *)0);
1135                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1136                                 dnl restore the LIBS
1137                                 LIBS="$save_LIBS"
1138                         ])
1139
1140                         if test $ol_cv_cthread_all_load = yes ; then
1141                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1142                                 ol_link_threads=mach
1143                         fi
1144                 fi
1145
1146                 if test $ol_link_threads != no ; then
1147                         : check for cthread specific functionality here
1148                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1149                                 [define if you have Mach Cthreads])
1150                 else
1151                         AC_MSG_ERROR([could not link with Mach CThreads])
1152                 fi
1153         fi
1154
1155         if test $ol_with_threads = mach ; then
1156                 AC_MSG_ERROR([could not locate Mach CThreads])
1157         fi
1158 fi
1159
1160 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1161         -o $ol_with_threads = lwp ; then
1162
1163         dnl check for SunOS5 LWP
1164         AC_CHECK_HEADERS(thread.h synch.h)
1165         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1166                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1167
1168                 if test $have_thr = yes ; then
1169                         AC_DEFINE(HAVE_THR,1,
1170                                 [if you have Solaris LWP (thr) package])
1171                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1172                         ol_link_threads=thr
1173
1174                         if test $ol_with_yielding_select = auto ; then
1175                                 ol_with_yielding_select=yes
1176                         fi
1177
1178                         dnl Check for setconcurreny functions
1179                         AC_CHECK_FUNCS( \
1180                                 thr_setconcurrency \
1181                                 thr_getconcurrency \
1182                         )
1183                 fi
1184         fi
1185
1186         dnl check for SunOS4 LWP
1187         AC_CHECK_HEADERS(lwp/lwp.h)
1188         if test $ac_cv_header_lwp_lwp_h = yes ; then
1189                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1190
1191                 if test $have_lwp = yes ; then
1192                         AC_DEFINE(HAVE_LWP,1,
1193                                 [if you have SunOS LWP package])
1194                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1195                         ol_link_threads=lwp
1196
1197                         if test $ol_with_yielding_select = auto ; then
1198                                 ol_with_yielding_select=no
1199                         fi
1200                 fi
1201         fi
1202 fi
1203
1204 if test $ol_with_yielding_select = yes ; then
1205         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1206                 [define if select implicitly yields])
1207 fi
1208
1209 if test $ol_with_threads = manual ; then
1210         dnl User thinks he can manually configure threads.
1211         ol_link_threads=yes
1212
1213         AC_MSG_WARN([thread defines and link options must be set manually])
1214
1215         AC_CHECK_HEADERS(pthread.h sched.h)
1216         AC_CHECK_FUNCS(sched_yield pthread_yield)
1217         OL_HEADER_LINUX_THREADS
1218
1219         AC_CHECK_HEADERS(mach/cthreads.h)
1220         AC_CHECK_HEADERS(lwp/lwp.h)
1221         AC_CHECK_HEADERS(thread.h synch.h)
1222 fi
1223
1224 if test $ol_link_threads != no ; then
1225         dnl needed to get reentrant/threadsafe versions
1226         dnl
1227         AC_DEFINE(REENTRANT,1)
1228         AC_DEFINE(_REENTRANT,1)
1229         AC_DEFINE(THREAD_SAFE,1)
1230         AC_DEFINE(_THREAD_SAFE,1)
1231         AC_DEFINE(THREADSAFE,1)
1232         AC_DEFINE(_THREADSAFE,1)
1233         AC_DEFINE(_SGI_MP_SOURCE,1)
1234
1235         dnl The errno declaration may dependent upon _REENTRANT.
1236         dnl If it does, we must link with thread support.
1237         AC_CACHE_CHECK([for thread specific errno],
1238                 [ol_cv_errno_thread_specific], [
1239                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1240                         [ol_cv_errno_thread_specific=yes],
1241                         [ol_cv_errno_thread_specific=no])
1242         ])
1243
1244         dnl The h_errno declaration may dependent upon _REENTRANT.
1245         dnl If it does, we must link with thread support.
1246         AC_CACHE_CHECK([for thread specific h_errno],
1247                 [ol_cv_h_errno_thread_specific], [
1248                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1249                         [ol_cv_h_errno_thread_specific=yes],
1250                         [ol_cv_h_errno_thread_specific=no])
1251         ])
1252
1253         if test $ol_cv_errno_thread_specific != yes \
1254                 -o $ol_cv_h_errno_thread_specific != yes ; then
1255                 LIBS="$LTHREAD_LIBS $LIBS"
1256                 LTHREAD_LIBS=""
1257         fi
1258
1259 dnl When in thread environment, use
1260 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1261 dnl                     || defined( HAVE_FUNC_R )
1262 dnl                     func_r(...);
1263 dnl             #else
1264 dnl             #       if defined( HAVE_THREADS )
1265 dnl                             /* lock */
1266 dnl             #       endif
1267 dnl                             func(...);
1268 dnl             #       if defined( HAVE_THREADS )
1269 dnl                             /* unlock */
1270 dnl             #       endif
1271 dnl             #endif
1272 dnl
1273 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1274 dnl             _POSIX_REENTRANT_FUNCTIONS
1275 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1276 dnl             _POSIX_THREADSAFE_FUNCTIONS
1277 dnl
1278 dnl             and is currently defined in lthread.h
1279 dnl
1280 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1281 dnl
1282 dnl libldap/*.c should only include <lthread.h> iff
1283 dnl LDAP_R_COMPILE is defined.  ie:
1284 dnl             #ifdef LDAP_R_COMPILE
1285 dnl             #       include LDAP_R_COMPILE
1286 dnl             #endif
1287 dnl
1288 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1289 dnl specifically for compiling the threadsafe version of
1290 dnl     the ldap library (-lldap_r).
1291 dnl
1292 dnl     dnl check for reentrant/threadsafe functions
1293 dnl     dnl
1294 dnl     dnl note: these should only be used when linking
1295 dnl     dnl       with $LTHREAD_LIBS
1296 dnl     dnl
1297 dnl     save_CPPFLAGS="$CPPFLAGS"
1298 dnl     save_LIBS="$LIBS"
1299 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1300 dnl     AC_CHECK_FUNCS( \
1301 dnl             gmtime_r \
1302 dnl             gethostbyaddr_r gethostbyname_r \
1303 dnl             feof_unlocked unlocked_feof \
1304 dnl             putc_unlocked unlocked_putc \
1305 dnl             flockfile ftrylockfile \
1306 dnl     )
1307 dnl     CPPFLAGS="$save_CPPFLAGS"
1308 dnl     LIBS="$save_LIBS"
1309 fi
1310
1311 if test $ol_link_threads = no ; then
1312         if test $ol_with_threads = yes ; then
1313                 AC_MSG_ERROR([no suitable thread support])
1314         fi
1315
1316         if test $ol_with_threads = auto ; then
1317                 AC_MSG_WARN([no suitable thread support, disabling threads])
1318                 ol_with_threads=no
1319         fi
1320
1321         AC_DEFINE(NO_THREADS,1,
1322                 [define if you have (or want) no threads])
1323         LTHREAD_LIBS=""
1324 fi
1325
1326 if test $ol_link_threads != no ; then
1327         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1328 fi
1329
1330 dnl ----------------------------------------------------------------
1331
1332 ol_link_ldbm=no
1333 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1334         OL_BERKELEY_DB2
1335
1336         if test $ol_cv_berkeley_db2 = yes ; then
1337                 ol_link_ldbm=db2
1338                 ol_with_ldbm_api=db2
1339
1340                 if test $ol_with_ldbm_type = hash ; then
1341                         AC_DEFINE(LDBM_USE_DBHASH,1)
1342                 else
1343                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1344                 fi
1345
1346                 dnl $ol_cv_lib_db2 should be yes or -ldb
1347                 dnl (it could be no, but that would be an error
1348                 if test $ol_cv_lib_db2 != yes ; then
1349                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1350                 fi
1351         fi
1352 fi
1353
1354 ol_link_bdb2=no
1355 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1356         ol_link_bdb2=yes
1357 fi
1358
1359 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1360         OL_BERKELEY_DB
1361
1362         if test $ol_cv_berkeley_db = yes ; then
1363                 ol_link_ldbm=db
1364                 ol_with_ldbm_api=db
1365
1366                 if test $ol_with_ldbm_type = hash ; then
1367                         AC_DEFINE(LDBM_USE_DBHASH,1)
1368                 else
1369                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1370                 fi
1371
1372                 dnl $ol_cv_lib_db should be yes or -ldb
1373                 dnl (it could be no, but that would be an error
1374                 if test $ol_cv_lib_db != yes ; then
1375                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1376                 fi
1377         fi
1378 fi
1379
1380 if test $ol_with_ldbm_api = manual ; then
1381         dnl User thinks he can manually configure LDBM api.
1382         ol_link_ldbm=yes
1383
1384         AC_MSG_WARN([LDBM defines and link options must be set manually])
1385
1386         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1387 fi
1388
1389 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1390         AC_MSG_WARN(Could not find LDBM with BTREE support)
1391         ol_with_ldbm_api=none
1392 fi
1393
1394 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1395         OL_MDBM
1396
1397         if test $ol_cv_mdbm = yes ; then
1398                 ol_link_ldbm=mdbm
1399                 ol_with_ldbm_api=mdbm
1400                 if test $ol_cv_lib_mdbm != yes ; then
1401                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1402                 fi
1403         fi
1404 fi
1405
1406 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1407         OL_GDBM
1408
1409         if test $ol_cv_gdbm = yes ; then
1410                 ol_link_ldbm=gdbm
1411                 ol_with_ldbm_api=gdbm
1412
1413                 if test $ol_cv_lib_gdbm != yes ; then
1414                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1415                 fi
1416         fi
1417 fi
1418
1419 if test $ol_with_ldbm_api = auto ; then
1420         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1421 elif test $ol_with_ldbm_api = ndbm ; then
1422         OL_NDBM
1423
1424         if test $ol_cv_ndbm = yes ; then
1425                 ol_link_ldbm=ndbm
1426                 ol_with_ldbm_api=ndbm
1427
1428                 if test $ol_cv_lib_ndbm != yes ; then
1429                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1430                 fi
1431         fi
1432 fi
1433
1434 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1435         AC_MSG_WARN(could not find suitable LDBM backend)
1436         if test $ol_enable_ldbm = yes ; then
1437                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1438         fi
1439
1440         AC_MSG_WARN(disabling LDBM)
1441         ol_enable_ldbm=no
1442 fi
1443
1444 if test $ol_enable_wrappers != no ; then
1445         AC_CHECK_HEADERS(tcpd.h)
1446
1447         if test $ac_cv_header_tcpd_h != yes ; then
1448                 have_wrappers=no
1449         else
1450                 AC_CHECK_LIB(wrap, main,
1451                         [have_wrappers=yes], [have_wrappers=no])
1452         fi
1453
1454         if test $have_wrappers = yes ; then
1455                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1456                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1457
1458                 dnl We add another check for -lnsl since some libwrap's
1459                 dnl need it, but it isn't always included from above
1460                 AC_CHECK_LIB(nsl, main)
1461         else
1462                 AC_MSG_WARN(could not find -lwrap)
1463                 if test $ol_enable_wrappers = yes ; then
1464                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1465                 fi
1466
1467                 AC_MSG_WARN(disabling wrappers support)
1468                 ol_enable_wrappers=no
1469         fi
1470 fi
1471
1472 if test $ol_enable_syslog != no ; then
1473         AC_CHECK_FUNC(openlog)
1474         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1475                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1476         fi
1477         ol_enable_syslog=$ac_cv_func_openlog
1478 fi
1479
1480 if test $ol_enable_dmalloc != no ; then
1481         AC_CHECK_HEADERS(dmalloc.h)
1482         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1483 fi
1484
1485 if test $ol_enable_tcl != no ; then
1486         AC_CHECK_HEADERS(tcl.h)
1487
1488         if test $ac_cv_header_tcl_h != yes ; then
1489                 have_tcl=no
1490         else
1491                 AC_CHECK_LIB(tcl,main,
1492                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1493                         [have_tcl=no])
1494
1495                 if test $have_tcl != yes; then
1496                         AC_CHECK_LIB(tcl7.6,main,
1497                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1498                                 [have_tcl=no])
1499                 fi
1500
1501                 if test $have_tcl != yes; then
1502                         AC_CHECK_LIB(tcl8.0,main,
1503                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1504                                 [have_tcl=no])
1505                 fi
1506         fi
1507
1508         if test $have_tcl != yes ; then
1509                 AC_MSG_WARN([could not find -ltcl])
1510                 if test $ol_enable_tcl = yes ; then
1511                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1512                 fi
1513
1514                 ol_enable_tcl=no
1515         fi
1516 fi
1517
1518 # ud needs termcap (should insert check here)
1519 ol_link_termcap=no
1520 AC_CHECK_HEADERS(termcap.h ncurses.h)
1521
1522 if test $ol_link_termcap = no ; then
1523         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1524         if test $have_termcap = yes ; then
1525                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1526                 ol_link_termcap=yes
1527                 TERMCAP_LIBS=-ltermcap
1528         fi
1529 fi
1530
1531 if test $ol_link_termcap = no ; then
1532         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1533         if test $have_ncurses = yes ; then
1534                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1535                 ol_link_termcap=yes
1536                 TERMCAP_LIBS=-lncurses
1537         fi
1538 fi
1539
1540 if test $ol_link_termcap = no ; then
1541         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1542         TERMCAP_LIBS=
1543 fi
1544
1545 dnl
1546 dnl Check for GNU readline
1547 dnl
1548 ol_link_readline=no
1549 if test $ol_with_readline != no ; then
1550         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1551
1552         if test $ac_cv_header_readline_readline_h = yes ; then
1553                 save_LIBS="$LIBS"
1554                 LIBS="$TERMCAP_LIBS $LIBS"
1555                 AC_CHECK_LIB(readline, readline,
1556                         [have_readline=yes], [have_readline=no])
1557                 LIBS="$save_LIBS"
1558
1559                 if test $have_readline = yes ; then
1560                         ol_with_readline=found
1561                         ol_link_readline=yes
1562
1563                         READLINE_LIBS="-lreadline"
1564                 fi
1565         fi
1566 fi
1567
1568 if test $ol_link_readline = yes ; then
1569         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1570 fi
1571
1572
1573 # FreeBSD (and others) have crypt(3) in -lcrypt
1574 if test $ol_enable_crypt != no ; then
1575         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1576                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1577                         have_crypt=yes], [have_crypt=no])])
1578
1579         if test $have_crypt = yes ; then
1580                 AC_DEFINE(HAVE_CRYPT,1)
1581         else
1582                 AC_MSG_WARN(could not find crypt)
1583                 if test $ol_enable_crypt = yes ; then
1584                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1585                 fi
1586
1587                 AC_MSG_WARN(disabling crypt support)
1588                 ol_enable_crypt=no
1589         fi
1590 fi
1591
1592 # FreeBSD (and others) have setproctitle(3) in -lutil
1593 if test $ol_enable_proctitle != no ; then
1594         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1595                 AC_CHECK_LIB(util, setproctitle,
1596                         [have_setproctitle=yes
1597                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1598                         [have_setproctitle=no
1599                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1600
1601         if test $have_setproctitle = yes ; then
1602                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1603         fi
1604 fi
1605
1606 dnl ----------------------------------------------------------------
1607 dnl Checks for header files.
1608 OL_HEADER_STDC
1609
1610 if test $ol_cv_header_stdc != yes; then
1611         AC_MSG_WARN([could not locate Standard C compliant headers])
1612 fi
1613
1614 AC_HEADER_DIRENT
1615 AC_HEADER_SYS_WAIT
1616 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1617 if test $am_cv_sys_posix_termios = yes ; then
1618         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1619                 [define if you have POSIX termios])
1620 fi
1621
1622 AC_CHECK_HEADERS(       \
1623         arpa/inet.h             \
1624         arpa/nameser.h  \
1625         assert.h                \
1626         crypt.h                 \
1627         errno.h                 \
1628         fcntl.h                 \
1629         filio.h                 \
1630         getopt.h                \
1631         grp.h                   \
1632         libutil.h               \
1633         limits.h                \
1634         locale.h                \
1635         malloc.h                \
1636         memory.h                \
1637         psap.h                  \
1638         pwd.h                   \
1639         resolv.h                \
1640         sgtty.h                 \
1641         shadow.h                \
1642         stdarg.h                \
1643         stddef.h                \
1644         string.h                \
1645         strings.h               \
1646         sysexits.h              \
1647         sys/file.h              \
1648         sys/filio.h             \
1649         sys/errno.h             \
1650         sys/ioctl.h             \
1651         sys/param.h             \
1652         sys/resource.h  \
1653         sys/select.h    \
1654         sys/socket.h    \
1655         sys/syslog.h    \
1656         sys/time.h              \
1657         sys/types.h             \
1658         syslog.h                \
1659         termios.h               \
1660         unistd.h                \
1661 )
1662
1663 dnl ----------------------------------------------------------------
1664 dnl Checks for typedefs, structures, and compiler characteristics.
1665 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1666 AC_TYPE_MODE_T
1667 AC_TYPE_OFF_T
1668 AC_TYPE_PID_T
1669 AM_TYPE_PTRDIFF_T
1670 AC_TYPE_SIGNAL
1671 OL_TYPE_SIG_ATOMIC_T
1672 AC_TYPE_SIZE_T
1673 AC_STRUCT_ST_BLKSIZE
1674 AC_HEADER_TIME
1675 AC_STRUCT_TM
1676 OL_STRUCT_PASSWD_PW_GECOS
1677 OL_STRUCT_PASSWD_PW_PASSWD
1678
1679 OL_C_UPPER_LOWER
1680 AC_C_CONST
1681 OL_C_VOLATILE
1682
1683 if test $cross_compiling = yes ; then
1684         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1685
1686         AC_DEFINE(LBER_INT_T,long)
1687         AC_DEFINE(LBER_TAG_T,long)
1688         AC_DEFINE(LBER_SOCKET_T,int)
1689
1690 else
1691         AC_C_BIGENDIAN
1692         AC_CHECK_SIZEOF(short)
1693         AC_CHECK_SIZEOF(int)
1694         AC_CHECK_SIZEOF(long)
1695
1696         if test "$ac_cv_sizeof_int" -lt 4 ; then
1697                 AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
1698
1699                 AC_DEFINE(LBER_INT_T,long)
1700                 AC_DEFINE(LBER_TAG_T,long)
1701                 AC_DEFINE(LBER_SOCKET_T,int)
1702         else
1703                 AC_DEFINE(LBER_INT_T,int)
1704                 AC_DEFINE(LBER_TAG_T,long)
1705                 AC_DEFINE(LBER_SOCKET_T,int)
1706         fi
1707 fi
1708
1709 AC_DEFINE(LBER_LEN_T,long)
1710
1711 dnl ----------------------------------------------------------------
1712 dnl Checks for library functions.
1713 AC_FUNC_MEMCMP
1714 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1715 AC_FUNC_STRFTIME
1716 dnl AM_FUNC_STRTOD
1717
1718 dnl we should use vfork instead of fork in a number of places...
1719 dnl AC_FUNC_VFORK
1720 AC_FUNC_VPRINTF
1721
1722 if test $ac_cv_func_vprintf = yes ; then
1723         dnl check for vsnprintf
1724         AC_CHECK_FUNCS(vsnprintf vsprintf)
1725 fi
1726
1727 AC_CHECK_FUNCS(         \
1728         bcopy                   \
1729         closesocket             \
1730         endgrent                \
1731         endpwent                \
1732         flock                   \
1733         getdtablesize   \
1734         getgrgid                \
1735         gethostname             \
1736         getpass                 \
1737         getpwuid                \
1738         getpwnam                \
1739         getspnam                \
1740         gettimeofday    \
1741         initgroups              \
1742         lockf                   \
1743         memcpy                  \
1744         memmove                 \
1745         mkstemp                 \
1746         read                    \
1747         recv                    \
1748         recvfrom                \
1749         setpwfile               \
1750         setgid                  \
1751         setegid                 \
1752         setsid                  \
1753         setuid                  \
1754         seteuid                 \
1755         signal                  \
1756         sigset                  \
1757         snprintf                \
1758         strdup                  \
1759         strerror                \
1760         strpbrk                 \
1761         strrchr                 \
1762         strsep                  \
1763         strstr                  \
1764         strtol                  \
1765         strtoul                 \
1766         strspn                  \
1767         sysconf                 \
1768         waitpid                 \
1769         wait4                   \
1770         write                   \
1771         send                    \
1772         sendto                  \
1773 )
1774
1775 dnl We actually may need to replace more than this.
1776 AC_REPLACE_FUNCS(getopt tempnam)
1777
1778 dnl ----------------------------------------------------------------
1779 # Check Configuration
1780 OL_SYS_ERRLIST
1781
1782 dnl ----------------------------------------------------------------
1783 dnl Sort out defines
1784
1785 if test "$ol_enable_debug" != no ; then
1786         AC_DEFINE(LDAP_DEBUG,1)
1787 fi
1788 if test "$ol_enable_syslog" = yes ; then
1789         AC_DEFINE(LDAP_SYSLOG,1)
1790 fi
1791 if test "$ol_enable_libui" = yes ; then
1792         AC_DEFINE(LDAP_LIBUI,1)
1793 fi
1794 if test "$ol_enable_cache" = no ; then
1795         AC_DEFINE(LDAP_NOCACHE,1)
1796 fi
1797 if test "$ol_enable_dns" != no ; then
1798         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1799 fi
1800 if test "$ol_enable_proctitle" != no ; then
1801         AC_DEFINE(LDAP_PROCTITLE,1)
1802 fi
1803 if test "$ol_enable_referrals" != no ; then
1804         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1805 fi
1806 if test "$ol_enable_cldap" != no ; then
1807         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1808 fi
1809
1810 if test "$ol_enable_crypt" != no ; then
1811         AC_DEFINE(SLAPD_CRYPT,1)
1812 fi
1813 if test "$ol_enable_cleartext" != no ; then
1814         AC_DEFINE(SLAPD_CLEARTEXT,1)
1815 fi
1816 if test "$ol_enable_phonetic" != no ; then
1817         AC_DEFINE(SLAPD_PHONETIC,1)
1818 fi
1819 if test "$ol_enable_rlookups" != no ; then
1820         AC_DEFINE(SLAPD_RLOOKUPS,1)
1821 fi
1822
1823 if test "$ol_link_modules" != no ; then
1824         AC_DEFINE(SLAPD_MODULES,1)
1825         BUILD_SLAPD=yes
1826 fi
1827
1828 if test "$ol_link_bdb2" != no ; then
1829         AC_DEFINE(SLAPD_BDB2,1)
1830         BUILD_SLAPD=yes
1831         BUILD_BDB2=yes
1832         if test "$ol_with_bdb2_module" != static ; then
1833                 AC_DEFINE(SLAPD_BDB2_DYNAMIC,1)
1834                 BUILD_BDB2_DYNAMIC=yes
1835         fi
1836 fi
1837
1838 if test "$ol_enable_ldap" != no ; then
1839         AC_DEFINE(SLAPD_LDAP,1)
1840         BUILD_SLAPD=yes
1841         BUILD_LDAP=yes
1842         if test "$ol_with_ldap_module" != static ; then
1843                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1)
1844                 BUILD_LDAP_DYNAMIC=yes
1845         fi
1846 fi
1847
1848 if test "$ol_link_ldbm" != no ; then
1849         AC_DEFINE(SLAPD_LDBM,1)
1850         BUILD_SLAPD=yes
1851         BUILD_LDBM=yes
1852         if test "$ol_with_ldbm_module" != static ; then
1853                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1)
1854                 BUILD_LDBM_DYNAMIC=yes
1855         fi
1856 fi
1857
1858 if test "$ol_enable_passwd" != no ; then
1859         AC_DEFINE(SLAPD_PASSWD,1)
1860         BUILD_SLAPD=yes
1861         BUILD_PASSWD=yes
1862         if test "$ol_with_passwd_module" != static ; then
1863                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1)
1864                 BUILD_PASSWD_DYNAMIC=yes
1865         fi
1866 fi
1867
1868 if test "$ol_link_perl" != no ; then
1869         AC_DEFINE(SLAPD_PERL,1)
1870         BUILD_SLAPD=yes
1871         BUILD_PERL=yes
1872         if test "$ol_with_perl_module" != static ; then
1873                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1)
1874                 BUILD_PERL_DYNAMIC=yes
1875         fi
1876 fi
1877
1878 if test "$ol_enable_shell" != no ; then
1879         AC_DEFINE(SLAPD_SHELL,1)
1880         BUILD_SLAPD=yes
1881         BUILD_SHELL=yes
1882         if test "$ol_with_shell_module" != static ; then
1883                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1)
1884                 BUILD_SHELL_DYNAMIC=yes
1885         fi
1886 fi
1887
1888 if test "$ol_enable_tcl" != no ; then
1889         AC_DEFINE(SLAPD_TCL,1)
1890         BUILD_SLAPD=yes
1891         BUILD_TCL=yes
1892         if test "$ol_with_tcl_module" != static; then
1893                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1)
1894                 BUILD_TCL_DYNAMIC=yes
1895         fi
1896 fi
1897
1898 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1899         $BUILD_SLAPD = yes ; then
1900         BUILD_SLURPD=yes
1901 fi
1902
1903 if test "$ol_link_isode" != no ; then
1904         BUILD_LDAPD=yes
1905 fi
1906
1907 dnl ----------------------------------------------------------------
1908
1909 AC_SUBST(BUILD_LDAPD)
1910 AC_SUBST(BUILD_SLAPD)
1911   AC_SUBST(BUILD_BDB2)
1912   AC_SUBST(BUILD_LDAP)
1913   AC_SUBST(BUILD_LDBM)
1914   AC_SUBST(BUILD_PASSWD)
1915   AC_SUBST(BUILD_PERL)
1916   AC_SUBST(BUILD_SHELL)
1917   AC_SUBST(BUILD_TCL)
1918   AC_SUBST(BUILD_BDB2_DYNAMIC)
1919   AC_SUBST(BUILD_LDAP_DYNAMIC)
1920   AC_SUBST(BUILD_LDBM_DYNAMIC)
1921   AC_SUBST(BUILD_PASSWD_DYNAMIC)
1922   AC_SUBST(BUILD_PERL_DYNAMIC)
1923   AC_SUBST(BUILD_SHELL_DYNAMIC)
1924   AC_SUBST(BUILD_TCL_DYNAMIC)
1925 AC_SUBST(BUILD_SLURPD)
1926
1927 AC_SUBST(LDAP_LIBS)
1928 AC_SUBST(LDAPD_LIBS)
1929 AC_SUBST(SLAPD_LIBS)
1930 AC_SUBST(SLURPD_LIBS)
1931 AC_SUBST(LDBM_LIBS)
1932 AC_SUBST(LTHREAD_LIBS)
1933 AC_SUBST(LUTIL_LIBS)
1934
1935 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
1936 AC_SUBST(SLAPD_MODULES_LDFLAGS)
1937
1938 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1939 AC_SUBST(SLAPD_PERL_LDFLAGS)
1940
1941 AC_SUBST(KRB_LIBS)
1942 AC_SUBST(READLINE_LIBS)
1943 AC_SUBST(TERMCAP_LIBS)
1944 AC_SUBST(TLS_LIBS)
1945
1946 dnl ----------------------------------------------------------------
1947 dnl final output
1948 dnl
1949
1950 AC_OUTPUT( \
1951 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1952 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1953 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1954 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1955 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1956 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1957 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1958 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1959 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1960 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1961 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1962 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1963 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1964 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1965 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1966 include/Makefile:build/top.mk:include/Makefile.in \
1967 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1968 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1969 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1970 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1971 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1972 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1973 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1974 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1975 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1976 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1977 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1978 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
1979 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/srv.mk \
1980 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1981 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1982 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
1983 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1984 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
1985 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1986 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1987 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1988 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
1989 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
1990 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
1991 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
1992 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
1993 ,[
1994 date > stamp-h
1995 echo Please \"make depend\" to build dependencies
1996 ])