git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8
   9 dnl Configure.in for OpenLDAP
  10 AC_INIT(include/ldap.h)dnl
  11 AC_CONFIG_AUX_DIR(build)dnl
  12 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no ac_define])dnl
  13
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_PREREQ(2.10)dnl Required Autoconf version
  18
  19 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  20
  21 dnl
  22 dnl Start Args
  23 AC_MSG_CHECKING(configure arguments)
  24 AC_PREFIX_DEFAULT(/usr/local)
  25
  26 top_builddir=`pwd`
  27 AC_SUBST(top_builddir)dnl
  28
  29 ldap_subdir="openldap"
  30
  31 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  32         if test "$withval" = "no"; then
  33                 ldap_subdir=""
  34         elif test "$withval" != "yes"; then
  35                 ldap_subdir="$withval"
  36         fi
  37 ])dnl
  38
  39 AC_SUBST(ldap_subdir)dnl
  40
  41 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  42 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  43 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  44 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  45 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  46 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  47 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  48 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  49 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  50         no, [yes no])dnl
  51
  52 dnl General "with" options
  53 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  54         auto, [auto k5 k4 afs yes no])
  55 OL_ARG_WITH(threads,[  --with-threads   use threads],
  56         auto, [auto posix mach lwp yes no manual] )
  57 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  58         auto, [auto yes no manual] )
  59
  60 dnl Server options
  61
  62 dnl LDAPD OPTIONS
  63 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  64 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  65
  66 dnl SLAPD OPTIONS
  67 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  68 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  69 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  70 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  71 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  72 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  73 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  74 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  75 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  76
  77 dnl SLAPD Backend options
  78 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  79 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  80         [auto db2 db gdbm ndbm manual])
  81 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  82         [auto btree hash])
  83
  84 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  85 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  86
  87 dnl SLURPD OPTIONS
  88 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  89 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  90
  91 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
  92 AM_ENABLE_STATIC
  93 dnl AM_DISABLE_SHARED
  94 AM_ENABLE_SHARED
  95
  96 dnl General "enable" options
  97 # validate options
  98 if test $ol_enable_referrals = no ; then
  99         if test $ol_enable_dns = yes ; then
 100                 AC_MSG_WARN([dns disabled, ignoring --enable-dns argument])
 101         fi
 102         ol_enable_dns=no
 103 fi
 104
 105 if test $ol_enable_slapd = no ; then
 106         dnl SLAPD was specificallly disabled
 107         if test $ol_enable_ldbm = yes ; then
 108                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 109         fi
 110         if test $ol_enable_passwd = yes ; then
 111                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 112         fi
 113         if test $ol_enable_shell = yes ; then
 114                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 115         fi
 116         if test $ol_enable_aclgroups = yes ; then
 117                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 118         fi
 119         if test $ol_enable_crypt = yes ; then
 120                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument])
 121         fi
 122         if test $ol_enable_md5 = yes ; then
 123                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument])
 124         fi
 125         if test $ol_enable_sha1 = yes ; then
 126                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument])
 127         fi
 128         if test $ol_enable_wrappers = yes ; then
 129                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 130         fi
 131         if test $ol_enable_phonetic = yes ; then
 132                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 133         fi
 134         if test $ol_enable_rlookups = yes ; then
 135                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 136         fi
 137         if test $ol_with_ldbm_api != auto ; then
 138                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 139         fi
 140         if test $ol_with_ldbm_type != auto ; then
 141                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 142         fi
 143         if test $ol_enable_slurpd = yes ; then
 144                 AC_MSG_ERROR([slurpd requires slapd])
 145         fi
 146
 147         # force settings to no
 148         ol_enable_ldbm=no
 149         ol_enable_shell=no
 150         ol_enable_passwd=no
 151         ol_enable_aclgroups=no
 152         ol_enable_crypt=no
 153         ol_enable_md5=no
 154         ol_enable_sha1=no
 155         ol_enable_wrappers=no
 156         ol_enable_phonetic=no
 157         ol_enable_rlookups=no
 158         ol_with_ldbm_api=no
 159         ol_with_ldbm_type=no
 160         ol_enable_slurpd=no
 161
 162 elif test $ol_enable_ldbm = no ; then
 163         dnl SLAPD without LDBM
 164
 165         if test $ol_with_ldbm_api != auto ; then
 166                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 167         fi
 168
 169         if test $ol_with_ldbm_type != auto ; then
 170                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 171         fi
 172
 173         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 174                 AC_MSG_ERROR([slapd requires a backend])
 175         fi
 176
 177         ol_with_ldbm_api=no
 178         ol_with_ldbm_type=no
 179
 180 else
 181         dnl SLAPD with LDBM
 182
 183         if test $ol_with_ldbm_api = gdbm -a \
 184                 $ol_with_ldbm_type = btree ; then
 185                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 186         fi
 187         if test $ol_with_ldbm_api = ndbm -a \
 188                 $ol_with_ldbm_type = btree ; then
 189                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 190         fi
 191 fi
 192
 193 if test $ol_enable_slurpd = yes ; then
 194         dnl SLURPD was specifically enabled
 195         if test $ol_with_threads = no ; then
 196                 AC_MSG_ERROR([slurpd requires threads])
 197         fi
 198 fi
 199
 200 AC_MSG_RESULT(done)
 201
 202 AC_CANONICAL_HOST
 203
 204 ## Initialize vars
 205 LDAP_LIBS=
 206 LDBM_LIBS=
 207 LTHREAD_LIBS=
 208 LUTIL_LIBS=
 209
 210 LDAPD_LIBS=
 211 SLAPD_LIBS=
 212 SLURPD_LIBS=
 213
 214 BUILD_LDAPD=no
 215 BUILD_SLAPD=no
 216 BUILD_SLURPD=no
 217
 218 BUILD_LDBM=no
 219 BUILD_PASSWD=no
 220 BUILD_SHELL=no
 221 BUILD_THREAD=no
 222
 223 KRB_LIBS=
 224 TERMCAP_LIBS=
 225
 226 dnl ----------------------------------------------------------------
 227 dnl Checks for programs
 228
 229 AC_PROG_INSTALL
 230 AM_PROG_LIBTOOL
 231 dnl AC_PROG_MAKE_SET
 232
 233 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 234         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 235 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 236 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 237
 238 dnl Checks the compiler and UNIX Variants
 239
 240 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 241         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 242
 243 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 244         AC_MSG_WARN([programs compiled here do run here...])
 245         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 246
 247 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 248         AC_MSG_WARN([programs compiled here do not run here...])
 249         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 250 fi
 251
 252 AC_PROG_CPP
 253
 254 AC_AIX
 255 AC_ISC_POSIX
 256 AC_MINIX
 257
 258 dnl OpenLDAP requires STDC features
 259 AM_PROG_CC_STDC
 260 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 261         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 262 fi
 263
 264 dnl AM_C_PROTOTYPES
 265
 266 dnl Checks for libraries
 267
 268 dnl Find socket()
 269 dnl Likely combinations:
 270 dnl             -lsocket [ -lnsl_s | -lnsl ]
 271 dnl             -linet
 272
 273 AC_CHECK_FUNC(socket, [have_socket=yes], [
 274 dnl
 275 dnl hopefully we won't include too many libraries
 276 dnl
 277         AC_CHECK_LIB(socket, main)
 278         AC_CHECK_LIB(net, main)
 279         AC_CHECK_LIB(nsl_s, main)
 280         AC_CHECK_LIB(nsl, main)
 281         AC_CHECK_LIB(inet, socket)
 282         AC_CHECK_LIB(gen, main)
 283 ])
 284
 285 dnl Check for resolv
 286 AC_CHECK_LIB(resolv, res_search)
 287
 288 dnl HP-UX requires -lV3
 289 AC_CHECK_LIB(V3, sigset)
 290
 291 # ISODE tests
 292 ol_link_isode=no
 293 if test $ol_enable_ldapd != no ; then
 294         dnl look for ISODE libraries
 295         AC_CHECK_LIB(xtpp, main, [
 296                 ol_link_isode=yes
 297                 AC_DEFINE(HAVE_XTPP,1)
 298                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 299                 ],:,[-lxtdsap -lxtisode -losi])
 300         AC_CHECK_LIB(dsap, main, [
 301                 ol_link_isode=yes
 302                 AC_DEFINE(HAVE_DSAP,1)
 303                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 304                 ],:,[-lisode])
 305         AC_CHECK_LIB(isode, main, [
 306                 ol_link_isode=yes
 307                 AC_DEFINE(HAVE_ISODE,1)
 308                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 309                 ],:)
 310 fi
 311
 312 if test $ol_link_isode != no; then
 313         AC_CHECK_LIB(pp, main, [
 314                 AC_DEFINE(HAVE_PP,1)
 315                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 316                 ],:)
 317
 318         AC_PATH_PROG(PEPSY, pepsy)
 319 fi
 320
 321 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 322         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 323
 324         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 325                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 326                         [-lkrb5 -ldes425])
 327
 328                 if test $have_k5 = yes ; then
 329                         ol_with_kerberos=found
 330                         ol_link_kerberos=yes
 331
 332                         AC_DEFINE(HAVE_KERBEROS)
 333
 334                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 335                 fi
 336         fi
 337 fi
 338 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 339         AC_CHECK_HEADERS(krb.h des.h)
 340
 341         if test $ac_cv_header_krb_h = yes ; then
 342                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 343
 344                 if test $have_k4 = yes ; then
 345                         ol_with_kerberos=found
 346                         ol_link_kerberos=yes
 347
 348                         AC_DEFINE(HAVE_KERBEROS)
 349                         KRB_LIBS="-lkrb -ldes"
 350
 351                         AC_CHECK_FUNCS(des_string_to_key)
 352                 fi
 353         fi
 354 fi
 355
 356 ol_link_threads=no
 357 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 358         AC_CHECK_HEADERS(pthread.h sched.h)
 359
 360         if test $ac_cv_header_pthread_h = yes ; then
 361                 OL_POSIX_THREAD_VERSION
 362
 363                 if test $ol_cv_pthread_version = final ; then
 364                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 365                 elif test $ol_cv_pthread_version = draft4 ; then
 366                         AC_DEFINE(HAVE_PTHREADS_D4)
 367                 else
 368                         AC_MSG_ERROR([unknown pthread version])
 369                 fi
 370
 371                 # consider threads found
 372                 ol_with_threads=found
 373
 374                 OL_LINUX_THREADS
 375
 376                 if test $ol_cv_linux_threads = yes ; then
 377                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 378                 fi
 379
 380                 dnl Now the hard part, how to link
 381
 382                 dnl Check for pthread support in current $LIBS
 383                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 384
 385                 if test $ol_link_threads = no ; then
 386                         dnl try -pthread
 387                         AC_CACHE_CHECK([for pthread_create with -pthread],
 388                                 [ol_cv_pthread_flag], [
 389                                 dnl save the flags
 390                                 save_LIBS="$LIBS"
 391                                 LIBS="-pthread $LIBS"
 392                                 AC_TRY_LINK([char pthread();],[
 393                                         pthread_create();
 394                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 395                                 dnl restore the LIBS
 396                                 LIBS="$save_LIBS"
 397                         ])
 398
 399                         if test $ol_cv_pthread_flag = yes ; then
 400                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 401                                 ol_link_threads=posix
 402                         fi
 403                 fi
 404
 405                 if test $ol_link_threads = no ; then
 406                         dnl try -thread
 407                         AC_CACHE_CHECK([for pthread_create with -thread],
 408                                 [ol_cv_thread_flag], [
 409                                 dnl save the flags
 410                                 save_LIBS="$LIBS"
 411                                 LIBS="-thread $LIBS"
 412                                 AC_TRY_LINK([char pthread();],[
 413                                         pthread_create();
 414                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 415                                 dnl restore the LIBS
 416                                 LIBS="$save_LIBS"
 417                         ])
 418
 419                         if test $ol_cv_thread_flag = yes ; then
 420                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 421                                 ol_link_threads=posix
 422                         fi
 423                 fi
 424
 425                 if test $ol_link_threads = no ; then
 426                         dnl try DEC Threads -lpthread -lexc
 427                         save_LIBS="$LIBS"
 428                         AC_CHECK_LIB(pthread, pthread_join, [
 429                                 ol_link_threads=posix
 430                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 431                                 if test $ol_with_yielding_select = auto ; then
 432                                         ol_with_yielding_select=yes
 433                                 fi
 434                                 ],,[-lexc])
 435                         LIBS="$save_LIBS"
 436                 fi
 437
 438                 if test $ol_link_threads = no ; then
 439                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 440                         save_LIBS="$LIBS"
 441                         AC_CHECK_LIB(pthreads, pthread_join, [
 442                                 ol_link_threads=posix
 443                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 444                                 if test $ol_with_yielding_select = auto ; then
 445                                         ol_with_yielding_select=yes
 446                                 fi
 447                                 ],,[-lmach -lexc -lc_r])
 448                         LIBS="$save_LIBS"
 449                 fi
 450
 451                 if test $ol_link_threads = no ; then
 452                         dnl try -lpthread
 453                         save_LIBS="$LIBS"
 454                         AC_CHECK_LIB(pthread, pthread_create, [
 455                                 ol_link_threads=posix
 456                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 457                         LIBS="$save_LIBS"
 458                 fi
 459
 460                 if test $ol_link_threads = no ; then
 461                         dnl try -lc_r
 462                         save_LIBS="$LIBS"
 463                         AC_CHECK_LIB(c_r, pthread_create, [
 464                                 ol_link_threads=posix
 465                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 466                         LIBS="$save_LIBS"
 467                 fi
 468
 469                 if test $ol_link_threads != no ; then
 470                         AC_DEFINE(HAVE_PTHREADS)
 471
 472                         dnl save flags
 473                         save_CPPFLAGS="$CPPFLAGS"
 474                         save_LIBS="$LIBS"
 475                         LIBS="$LTHREAD_LIBS $LIBS"
 476
 477                         dnl All POSIX Thread (final) implementations should have
 478                         dnl sched_yield instead of pthread yield.
 479                         dnl check for both
 480                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 481
 482                         if test $ac_cv_func_sched_yield = no -a \
 483                                 $ac_cv_func_pthread_yield = no ; then
 484                                 dnl Digital UNIX has sched_yield() in -lrt
 485                                 AC_CHECK_LIB(rt, sched_yield,
 486                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 487                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 488                                         ac_cv_func_sched_yield=yes],
 489                                         [ac_cv_func_sched_yield=no])
 490                         fi
 491                         if test $ac_cv_func_sched_yield = no -a \
 492                                 $ac_cv_func_pthread_yield = no ; then
 493                                 dnl Solaris has sched_yield() in -lposix4
 494                                 AC_CHECK_LIB(posix4, sched_yield,
 495                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 496                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 497                                         ac_cv_func_sched_yield=yes],
 498                                         [ac_cv_func_sched_yield=no])
 499                         fi
 500                         if test $ac_cv_func_sched_yield = no -a \
 501                                 $ac_cv_func_pthread_yield = no ; then
 502                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 503                                 AC_MSG_ERROR([POSIX Threads are not usable])
 504                         fi
 505
 506                         dnl Check functions for compatibility
 507                         AC_CHECK_FUNCS(pthread_kill)
 508                         AC_CHECK_FUNCS( \
 509                                 pthread_attr_create pthread_attr_init \
 510                                 pthread_attr_destroy pthread_attr_delete \
 511                                 pthread_attr_setdetachstate pthread_attr_setdetach_np \
 512                         )
 513
 514                         dnl Check for setconcurreny functions
 515                         AC_CHECK_FUNCS( \
 516                                 pthread_setconcurrency \
 517                                 thr_setconcurrency \
 518                         )
 519
 520                         AC_MSG_CHECKING([if pthread_create() works])
 521                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 522                         AC_TRY_RUN([
 523 #include <pthread.h>
 524 #ifndef NULL
 525 #define NULL (void*)0
 526 #endif
 527
 528 static void *task(p)
 529         void *p;
 530 {
 531         return (void *) (p == NULL);
 532 }
 533
 534 int main(argc, argv)
 535         int argc;
 536         char **argv;
 537 {
 538         pthread_t t;
 539         exit(pthread_create(&t, NULL, task, NULL));
 540 }
 541 ],
 542                                 [ol_cv_pthread_create_works=yes],
 543                                 [ol_cv_pthread_create_works=no],
 544                                 [dnl assume yes
 545                                 ol_cv_pthread_create_works=yes])])
 546                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 547
 548                         if test $ol_cv_pthread_create_works = no ; then
 549                                 AC_MSG_ERROR([pthread.h and pthread_create are not compatible])
 550                         fi
 551
 552                         dnl Check if select causes an yield
 553                         if test $ol_with_yielding_select = auto ; then
 554                                 AC_MSG_CHECKING([if select yields when using pthreads])
 555                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 556                                 AC_TRY_RUN([
 557 #include <sys/types.h>
 558 #include <sys/time.h>
 559 #include <unistd.h>
 560 #include <pthread.h>
 561 #ifndef NULL
 562 #define NULL (void*) 0
 563 #endif
 564
 565 static int fildes[2];
 566
 567 static void *task(p)
 568         void *p;
 569 {
 570         int i;
 571         struct timeval tv;
 572
 573         fd_set rfds;
 574
 575         tv.tv_sec=10;
 576         tv.tv_usec=0;
 577
 578         FD_ZERO(&rfds);
 579         FD_SET(fildes[0], &rfds);
 580
 581         /* we're not interested in any fds */
 582         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 583
 584         if(i < 0) {
 585                 perror("select");
 586                 exit(0);
 587         }
 588
 589         exit(1); /* if we exit here, the select blocked the whole process */
 590 }
 591
 592 int main(argc, argv)
 593         int argc;
 594         char **argv;
 595 {
 596         pthread_t t;
 597
 598         /* create a pipe to select */
 599         if(pipe(&fildes[0])) {
 600                 perror("select");
 601                 exit(0);
 602         }
 603
 604 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 605         (void) pthread_setconcurrency(2);
 606 #else
 607 #ifdef HAVE_THR_SETCONCURRENCY
 608         /* Set Solaris LWP concurrency to 2 */
 609         thr_setconcurrency(2);
 610 #endif
 611 #endif
 612
 613         pthread_create(&t, NULL, task, NULL);
 614
 615 #if HAVE_SCHED_YIELD
 616         sched_yield();  /* make sure task runs first */
 617 #else
 618 #ifdef HAVE_PTHREAD_YIELD
 619         pthread_yield();        /* make sure task runs first */
 620 #endif
 621 #endif
 622         exit(0);
 623 }],
 624                                 [ol_cv_pthread_select_yields=yes],
 625                                 [ol_cv_pthread_select_yields=no], [
 626                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
 627                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
 628
 629                                 if test $ol_cv_pthread_select_yields = yes ; then
 630                                         ol_with_yielding_select=yes
 631                                 fi
 632                         fi
 633
 634 dnl                     dnl check for reentrant/threadsafe functions
 635 dnl                     AC_CHECK_FUNCS( \
 636 dnl                             feof_unlocked \
 637 dnl                             unlocked_feof \
 638 dnl                             ftrylockfile \
 639 dnl                             flockfile \
 640 dnl                             putc_unlocked \
 641 dnl                             gmtime_r \
 642 dnl                             strtok_r \
 643 dnl                     )
 644
 645                         dnl restore flags
 646                         CPPFLAGS="$save_CPPFLAGS"
 647                         LIBS="$save_LIBS"
 648                 else
 649                         AC_MSG_ERROR([could not link with POSIX Threads])
 650                 fi
 651         fi
 652
 653         if test $ol_with_threads = posix ; then
 654                 AC_MSG_ERROR([could not locate POSIX Threads])
 655         fi
 656 fi
 657
 658 if test $ol_with_threads = auto -o $ol_with_threads = mach ; then
 659         dnl check for Mach CThreads
 660         AC_CHECK_HEADERS(mach/cthreads.h)
 661         if test $ac_cv_header_mach_cthreads_h = yes ; then
 662                 ol_with_threads=found
 663
 664                 dnl check for cthread support in current $LIBS
 665                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 666
 667                 if test $ol_link_threads = no ; then
 668                         dnl try -all_load
 669                         dnl this test needs work
 670                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 671                                 [ol_cv_cthread_all_load], [
 672                                 dnl save the flags
 673                                 save_LIBS="$LIBS"
 674                                 LIBS="-all_load $LIBS"
 675                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 676                                         cthread_fork((void *)0, (void *)0);
 677                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 678                                 dnl restore the LIBS
 679                                 LIBS="$save_LIBS"
 680                         ])
 681
 682                         if test $ol_cv_cthread_all_load = yes ; then
 683                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 684                                 ol_link_threads=mach
 685                         fi
 686                 fi
 687
 688                 if test $ol_link_threads != no ; then
 689                         : check for cthread specific functionality here
 690                         AC_DEFINE(HAVE_MACH_CTHREADS,1)
 691                 else
 692                         AC_MSG_ERROR([could not link with Mach CThreads])
 693                 fi
 694         fi
 695
 696         if test $ol_with_threads = mach ; then
 697                 AC_MSG_ERROR([could not locate Mach CThreads])
 698         fi
 699 fi
 700
 701 if test $ol_with_threads = auto -o $ol_with_threads = lwp ; then
 702         dnl check for SunOS5 LWP
 703         AC_CHECK_HEADERS(thread.h synch.h)
 704         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 705                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
 706
 707                 if test $have_thr = yes ; then
 708                         AC_DEFINE(HAVE_THR)
 709                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
 710                         ol_link_threads=thr
 711
 712                         if test $ol_with_yielding_select = auto ; then
 713                                 ol_with_yielding_select=yes
 714                         fi
 715                 fi
 716         fi
 717
 718         dnl check for SunOS4 LWP
 719         AC_CHECK_HEADERS(lwp/lwp.h)
 720         if test $ac_cv_header_lwp_lwp_h = yes ; then
 721                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 722
 723                 if test $have_lwp = yes ; then
 724                         AC_DEFINE(HAVE_LWP)
 725                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 726                         ol_link_threads=lwp
 727
 728                         if test $ol_with_yielding_select = auto ; then
 729                                 ol_with_yielding_select=no
 730                         fi
 731                 fi
 732         fi
 733 fi
 734
 735 if test $ol_with_yielding_select = yes ; then
 736         AC_DEFINE(HAVE_YIELDING_SELECT,1)
 737 fi
 738
 739 if test $ol_with_threads = manual ; then
 740         dnl User thinks he can manually configure threads.
 741         ol_link_threads=yes
 742
 743         AC_MSG_WARN([thread defines and link options must be set manually])
 744
 745         AC_CHECK_HEADERS(pthread.h sched.h)
 746         AC_CHECK_FUNCS(sched_yield pthread_yield)
 747         OL_LINUX_THREADS
 748
 749         AC_CHECK_HEADERS(mach/cthreads.h)
 750         AC_CHECK_HEADERS(lwp/lwp.h)
 751         AC_CHECK_HEADERS(thread.h synch.h)
 752 fi
 753
 754 if test $ol_with_threads != no ; then
 755         dnl needed to get reentrant/threadsafe versions
 756         dnl
 757         AC_DEFINE(REENTRANT,1)
 758         AC_DEFINE(_REENTRANT,1)
 759         AC_DEFINE(THREAD_SAFE,1)
 760         AC_DEFINE(_THREAD_SAFE,1)
 761         AC_DEFINE(THREADSAFE,1)
 762         AC_DEFINE(_THREADSAFE,1)
 763
 764         dnl this might cause the errno symbol to be
 765         dnl replaced with a function to get a thread specific errno.
 766         dnl check to see if everything needs to be compiled
 767         dnl with the thread libraries
 768         AC_CACHE_CHECK([for thread specific errno],
 769                 [ol_cv_errno_thread_specific], [
 770                 AC_TRY_LINK([
 771 #include <errno.h>
 772                         ], [
 773 int x = errno;
 774                         ],
 775                         [ol_cv_errno_thread_specific=yes],
 776                         [ol_cv_errno_thread_specific=no])
 777         ])
 778
 779         if test $ol_cv_errno_thread_specific != yes ; then
 780                 LIBS="$LTHREAD_LIBS $LIBS"
 781                 LTHREAD_LIBS=""
 782         fi
 783 fi
 784
 785 dnl ----------------------------------------------------------------
 786
 787 if test $ol_link_threads = no ; then
 788         if test $ol_with_threads = yes ; then
 789                 AC_MSG_ERROR([no suitable thread support])
 790         fi
 791
 792         if test $ol_with_threads = auto ; then
 793                 AC_MSG_WARN([no suitable thread support, disabling threads])
 794                 ol_with_threads=no
 795         fi
 796
 797         AC_DEFINE(NO_THREADS,1)
 798         LTHREAD_LIBS=""
 799 fi
 800
 801 ol_link_ldbm=no
 802 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 803         OL_BERKELEY_DB2
 804
 805         if test $ol_cv_berkeley_db2 = yes ; then
 806                 ol_link_ldbm=db2
 807                 ol_with_ldbm_api=db2
 808
 809                 if test $ol_with_ldbm_type = hash ; then
 810                         AC_DEFINE(LDBM_USE_DBHASH,1)
 811                 else
 812                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 813                 fi
 814
 815                 dnl $ol_cv_lib_db2 should be yes or -ldb
 816                 dnl (it could be no, but that would be an error
 817                 if test $ol_cv_lib_db2 != yes ; then
 818                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 819                 fi
 820         fi
 821 fi
 822
 823 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 824         OL_BERKELEY_DB
 825
 826         if test $ol_cv_berkeley_db = yes ; then
 827                 ol_link_ldbm=db
 828                 ol_with_ldbm_api=db
 829
 830                 if test $ol_with_ldbm_type = hash ; then
 831                         AC_DEFINE(LDBM_USE_DBHASH,1)
 832                 else
 833                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 834                 fi
 835
 836                 dnl $ol_cv_lib_db should be yes or -ldb
 837                 dnl (it could be no, but that would be an error
 838                 if test $ol_cv_lib_db != yes ; then
 839                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 840                 fi
 841         fi
 842 fi
 843
 844 if test $ol_with_ldbm_api = manual ; then
 845         dnl User thinks he can manually configure LDBM api.
 846         ol_link_ldbm=yes
 847
 848         AC_MSG_WARN([LDBM defines and link options must be set manually])
 849
 850         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 851 fi
 852
 853 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 854         AC_MSG_WARN(Could not find LDBM with BTREE support)
 855         ol_with_ldbm_api=none
 856 fi
 857
 858 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 859         OL_GDBM
 860
 861         if test $ol_cv_gdbm = yes ; then
 862                 ol_link_ldbm=gdbm
 863                 ol_with_ldbm_api=gdbm
 864
 865                 if test $ol_cv_lib_gdbm != yes ; then
 866                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 867                 fi
 868         fi
 869 fi
 870
 871 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 872         OL_NDBM
 873
 874         if test $ol_cv_ndbm = yes ; then
 875                 if test $ol_with_ldbm_api = auto ; then
 876                         AC_MSG_WARN([Attempting to use NDBM.  Functionality will be limited.])
 877                 fi
 878
 879                 ol_link_ldbm=ndbm
 880                 ol_with_ldbm_api=ndbm
 881
 882                 if test $ol_cv_lib_ndbm != yes ; then
 883                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 884                 fi
 885         fi
 886 fi
 887
 888 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 889         AC_MSG_WARN(could not find suitable LDBM backend)
 890         if test $ol_enable_ldbm = yes ; then
 891                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 892         fi
 893
 894         AC_MSG_WARN(disabling LDBM)
 895         ol_enable_ldbm=no
 896 fi
 897
 898 if test $ol_enable_wrappers = yes ; then
 899         AC_CHECK_LIB(wrap, hosts_access,
 900                 [have_wrappers=yes], [have_wrappers=no])
 901
 902         if test $have_wrappers = yes ; then
 903                 AC_DEFINE(HAVE_TCPD)
 904                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 905         else
 906                 AC_MSG_WARN(could not find -lwrap)
 907                 if test $ol_enable_wrappers = yes ; then
 908                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 909                 fi
 910
 911                 AC_MSG_WARN(disabling wrappers support)
 912                 ol_enable_wrappers=no
 913         fi
 914
 915 fi
 916
 917 # ud needs termcap (should insert check here)
 918 ol_link_termcap=no
 919 AC_CHECK_HEADERS(termcap.h ncurses.h)
 920
 921 if test $ol_link_termcap = no ; then
 922         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 923         if test $have_termcap = yes ; then
 924                 AC_DEFINE(HAVE_TERMCAP)
 925                 ol_link_termcap=yes
 926                 TERMCAP_LIBS=-ltermcap
 927         fi
 928 fi
 929
 930 if test $ol_link_termcap = no ; then
 931         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 932         if test $have_ncurses = yes ; then
 933                 AC_DEFINE(HAVE_NCURSES)
 934                 ol_link_termcap=yes
 935                 TERMCAP_LIBS=-lncurses
 936         fi
 937 fi
 938
 939 if test $ol_link_termcap = no ; then
 940         AC_DEFINE(NO_TERMCAP,1)
 941         TERMCAP_LIBS=
 942 fi
 943
 944 # FreeBSD (and others) have crypt(3) in -lcrypt
 945 if test $ol_enable_crypt != no ; then
 946         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 947                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 948                         have_crypt=yes], [have_crypt=no])])
 949
 950         if test $have_crypt = yes ; then
 951                 AC_DEFINE(HAVE_CRYPT,1)
 952         else
 953                 AC_MSG_WARN(could not find crypt)
 954                 if test $ol_enable_crypt = yes ; then
 955                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 956                 fi
 957
 958                 AC_MSG_WARN(disabling crypt support)
 959                 ol_enable_crypt=no
 960         fi
 961 fi
 962
 963 # FreeBSD (and others) have setproctitle(3) in -lutil
 964 if test $ol_enable_proctitle != no ; then
 965         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 966                 AC_CHECK_LIB(util, setproctitle,
 967                         [have_setproctitle=yes
 968                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 969                         [have_setproctitle=no
 970                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 971
 972         if test $have_setproctitle = yes ; then
 973                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 974         fi
 975 fi
 976
 977 dnl ----------------------------------------------------------------
 978 dnl Checks for header files.
 979 AC_HEADER_STDC
 980
 981 if test $ac_cv_header_stdc != yes; then
 982         AC_MSG_WARN([could not Standard C compliant headers])
 983 fi
 984
 985 AC_HEADER_DIRENT
 986 AC_HEADER_SYS_WAIT
 987 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 988 if test $am_cv_sys_posix_termios = yes ; then
 989         AC_DEFINE(HAVE_POSIX_TERMIOS,1)
 990 fi
 991
 992 AC_CHECK_HEADERS(       \
 993         crypt.h                 \
 994         errno.h                 \
 995         fcntl.h                 \
 996         filio.h                 \
 997         getopt.h                \
 998         libutil.h               \
 999         limits.h                \
1000         malloc.h                \
1001         memory.h                \
1002         regex.h                 \
1003         psap.h                  \
1004         pwd.h                   \
1005         sgtty.h                 \
1006         stdarg.h                \
1007         stddef.h                \
1008         string.h                \
1009         strings.h               \
1010         sys/file.h              \
1011         sys/filio.h             \
1012         sys/errno.h             \
1013         sys/ioctl.h             \
1014         sys/param.h             \
1015         sys/resource.h  \
1016         sys/socket.h    \
1017         sys/syslog.h    \
1018         sys/time.h              \
1019         sys/types.h             \
1020         syslog.h                \
1021         termios.h               \
1022         unistd.h                \
1023 )
1024
1025 dnl ----------------------------------------------------------------
1026 dnl Checks for typedefs, structures, and compiler characteristics.
1027 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1028 AC_TYPE_MODE_T
1029 AC_TYPE_OFF_T
1030 AC_TYPE_PID_T
1031 AM_TYPE_PTRDIFF_T
1032 AC_TYPE_SIGNAL
1033 AC_TYPE_SIZE_T
1034 AC_STRUCT_ST_BLKSIZE
1035 AC_HEADER_TIME
1036 AC_STRUCT_TM
1037
1038 OL_C_UPPER_LOWER
1039 AC_C_CONST
1040
1041 if test $cross_compiling = yes ; then
1042         AC_DEFINE(CROSS_COMPILING, 1)
1043 else
1044         AC_C_BIGENDIAN
1045         AC_CHECK_SIZEOF(short)
1046         AC_CHECK_SIZEOF(int)
1047         AC_CHECK_SIZEOF(long)
1048 fi
1049
1050 dnl ----------------------------------------------------------------
1051 dnl Checks for library functions.
1052 AC_FUNC_MEMCMP
1053 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1054 AC_FUNC_STRFTIME
1055 dnl AM_FUNC_STRTOD
1056 AC_FUNC_VPRINTF
1057
1058 if test $ac_cv_func_vprintf = yes ; then
1059         dnl check for vsnprintf
1060         AC_CHECK_FUNCS(vsnprintf)
1061 fi
1062
1063 AC_FUNC_WAIT3
1064
1065 AC_CHECK_FUNCS(         \
1066         bcopy                   \
1067         flock                   \
1068         getdtablesize   \
1069         gethostname             \
1070         getpwuid                \
1071         gettimeofday    \
1072         lockf                   \
1073         memcpy                  \
1074         memmove                 \
1075         mkstemp                 \
1076         res_search              \
1077         select                  \
1078         setpwfile               \
1079         setsid                  \
1080         signal                  \
1081         sigset                  \
1082         snprintf                \
1083         socket                  \
1084         strerror                \
1085         strpbrk                 \
1086         strrchr                 \
1087         strsep                  \
1088         strstr                  \
1089         strtok                  \
1090         strtol                  \
1091         strtoul                 \
1092         sysconf                 \
1093         waitpid                 \
1094 )
1095
1096 dnl We actually may need to replace more than this.
1097 AC_REPLACE_FUNCS(getopt strdup tempnam)
1098
1099 dnl ----------------------------------------------------------------
1100 # Check Configuration
1101 OL_SYS_ERRLIST
1102
1103 dnl ----------------------------------------------------------------
1104 dnl Sort out defines
1105
1106 if test $ol_enable_debug != no ; then
1107         AC_DEFINE(LDAP_DEBUG,1)
1108 fi
1109 dnl     if test $ol_enable_syslog != no ; then
1110 dnl             AC_DEFINE(LDAP_SYSLOG,1)
1111 dnl     fi
1112 if test $ol_enable_libui = yes ; then
1113         AC_DEFINE(LDAP_LIBUI,1)
1114 fi
1115 if test $ol_enable_cache = no ; then
1116         AC_DEFINE(LDAP_NOCACHE,1)
1117 fi
1118 if test $ol_enable_dns != no ; then
1119         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_API_VENDOR_VERSION,1)
1120 fi
1121 if test $ol_enable_proctitle != no ; then
1122         AC_DEFINE(LDAP_PROCTITLE,1)
1123 fi
1124 if test $ol_enable_referrals != no ; then
1125         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_API_VENDOR_VERSION,1)
1126 fi
1127 if test $ol_enable_cldap != no ; then
1128         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1129 fi
1130
1131 if test $ol_enable_aclgroups != no ; then
1132         AC_DEFINE(SLAPD_ACLGROUPS,1)
1133 fi
1134 if test $ol_enable_crypt != no ; then
1135         AC_DEFINE(SLAPD_CRYPT,1)
1136 fi
1137 if test $ol_enable_md5 != no ; then
1138         AC_DEFINE(SLAPD_MD5,1)
1139 fi
1140 if test $ol_enable_sha1 != no ; then
1141         AC_DEFINE(SLAPD_SHA1,1)
1142 fi
1143 if test $ol_enable_phonetic != no ; then
1144         AC_DEFINE(SLAPD_PHONETIC,1)
1145 fi
1146 if test $ol_enable_rlookups != no ; then
1147         AC_DEFINE(SLAPD_RLOOKUPS,1)
1148 fi
1149
1150 if test $ol_link_ldbm != no ; then
1151         AC_DEFINE(SLAPD_LDBM,1)
1152         BUILD_SLAPD=yes
1153         BUILD_LDBM=yes
1154 fi
1155
1156 if test $ol_enable_passwd != no ; then
1157         AC_DEFINE(SLAPD_PASSWD,1)
1158         BUILD_SLAPD=yes
1159         BUILD_PASSWD=yes
1160 fi
1161
1162 if test $ol_enable_shell != no ; then
1163         AC_DEFINE(SLAPD_SHELL,1)
1164         BUILD_SLAPD=yes
1165         BUILD_SHELL=yes
1166 fi
1167
1168 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
1169         $BUILD_SLAPD = yes ; then
1170         BUILD_SLURPD=yes
1171 fi
1172
1173 if test $ol_link_isode != no ; then
1174         BUILD_LDAPD=yes
1175 fi
1176
1177 dnl ----------------------------------------------------------------
1178
1179 AC_SUBST(BUILD_LDAPD)
1180 AC_SUBST(BUILD_SLAPD)
1181   AC_SUBST(BUILD_LDBM)
1182   AC_SUBST(BUILD_PASSWD)
1183   AC_SUBST(BUILD_SHELL)
1184 AC_SUBST(BUILD_SLURPD)
1185
1186
1187 AC_SUBST(LDAP_LIBS)
1188 AC_SUBST(LDAPD_LIBS)
1189 AC_SUBST(SLAPD_LIBS)
1190 AC_SUBST(SLURPD_LIBS)
1191 AC_SUBST(LDBM_LIBS)
1192 AC_SUBST(LTHREAD_LIBS)
1193 AC_SUBST(LUTIL_LIBS)
1194
1195 AC_SUBST(KRB_LIBS)
1196 AC_SUBST(TERMCAP_LIBS)
1197
1198 dnl ----------------------------------------------------------------
1199 dnl final output
1200 dnl
1201
1202 AC_OUTPUT( \
1203 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1204 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1205 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1206 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1207 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1208 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1209 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1210 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1211 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1212 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1213 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1214 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1215 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1216 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1217 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1218 include/Makefile:build/top.mk:include/Makefile.in \
1219 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1220 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1221 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1222 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1223 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1224 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1225 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk:build/lib-static.mk    \
1226 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1227 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1228 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1229 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1230 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1231 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1232 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1233 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1234 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1235 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1236 tests/Makefile:build/top.mk:tests/Makefile.in \
1237 ,[
1238 date > stamp-h
1239 echo Please \"make depend\" to build dependencies
1240 ])