git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Disable config.cache!
  11 define([AC_CACHE_LOAD], )dnl
  12 define([AC_CACHE_SAVE], )dnl
  13
  14 dnl Configure.in for OpenLDAP
  15 AC_INIT(include/ldap.h)dnl
  16 AC_CONFIG_AUX_DIR(build)dnl
  17 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no defines])dnl
  18 AC_SUBST(PACKAGE)
  19 AC_SUBST(VERSION)
  20 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  21 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  22
  23 dnl We use autoconf features new to 2.13.
  24 dnl     aclocal.m4 should be built using aclocal from automake 1.4
  25 AC_PREREQ(2.13)dnl Required Autoconf version
  26
  27 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  28
  29 dnl
  30 dnl Start Args
  31 AC_MSG_CHECKING(configure arguments)
  32 AC_PREFIX_DEFAULT(/usr/local)
  33
  34 top_builddir=`pwd`
  35 AC_SUBST(top_builddir)dnl
  36
  37 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
  38
  39 ldap_subdir="openldap"
  40
  41 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  42         if test "$withval" = "no"; then
  43                 ldap_subdir=""
  44         elif test "$withval" != "yes"; then
  45                 ldap_subdir="$withval"
  46         fi
  47 ])dnl
  48
  49 AC_SUBST(ldap_subdir)dnl
  50
  51 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  52 dnl ol_enable_syslog=no
  53 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  54 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  55 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  56 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  57 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  58 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  59 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  60         no, [yes no])dnl
  61
  62 dnl General "with" options
  63 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  64
  65 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  66         auto, [auto k5 k4 afs yes no])
  67 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  68         auto, [auto yes no] )
  69 OL_ARG_WITH(threads,[  --with-threads   use threads],
  70         auto, [auto posix mach lwp yes no manual] )
  71 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  72         auto, [auto ssleay openssl yes no] )
  73 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  74         auto, [auto yes no manual] )
  75
  76 dnl Server options
  77
  78 dnl LDAPD OPTIONS
  79 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  80 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  81
  82 dnl SLAPD OPTIONS
  83 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  84 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  85 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  86 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  87 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  88 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
  89 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  90 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  91 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  92
  93 dnl SLAPD Backend options
  94 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
  95 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
  96 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  97 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  98         [auto db2 db mdbm gdbm ndbm manual])
  99 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 100         [auto btree hash])
 101
 102 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 103 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 104 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 105 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 106
 107 dnl SLURPD OPTIONS
 108 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
 109 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 110
 111 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 112 AM_ENABLE_STATIC
 113 dnl AM_DISABLE_SHARED
 114 AM_ENABLE_SHARED
 115
 116 dnl General "enable" options
 117 # validate options
 118 if test $ol_enable_dns = yes ; then
 119         if test $ol_enable_referrals = no ; then
 120                 AC_MSG_ERROR([DNS requires --enable-referrals])
 121         fi
 122         if test $ol_enable_referrals = auto ; then
 123                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 124                 ol_enable_referrals=yes
 125         fi
 126 fi
 127
 128 if test $ol_enable_slapd = no ; then
 129         dnl SLAPD was specificallly disabled
 130         if test $ol_enable_bdb2 = yes ; then
 131                 AC_MSG_WARN([slapd disabled, ignoring --enable_bdb2 argument])
 132         fi
 133         if test $ol_enable_ldbm = yes ; then
 134                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 135         fi
 136         if test $ol_enable_passwd = yes ; then
 137                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 138         fi
 139         if test $ol_enable_perl = yes ; then
 140                 AC_MSG_WARN([slapd disabled, ignoring --enable_perl argument])
 141         fi
 142         if test $ol_enable_shell = yes ; then
 143                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 144         fi
 145         if test $ol_enable_tcl = yes ; then
 146                 AC_MSG_WARN([slapd disabled, ignoring --enable_tcl argument])
 147         fi
 148         if test $ol_enable_aclgroups = yes ; then
 149                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 150         fi
 151         if test $ol_enable_modules = yes ; then
 152                 AC_MSG_WARN([slapd disabled, ignoring --enable_modules argument])
 153         fi
 154         if test $ol_enable_wrappers = yes ; then
 155                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 156         fi
 157         if test $ol_enable_phonetic = yes ; then
 158                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 159         fi
 160         if test $ol_enable_rlookups = yes ; then
 161                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 162         fi
 163         if test $ol_with_ldbm_api != auto ; then
 164                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 165         fi
 166         if test $ol_with_ldbm_type != auto ; then
 167                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 168         fi
 169         if test $ol_enable_slurpd = yes ; then
 170                 AC_MSG_ERROR([slurpd requires slapd])
 171         fi
 172
 173         # force settings to no
 174         ol_enable_bdb2=no
 175         ol_enable_ldbm=no
 176         ol_enable_passwd=no
 177         ol_enable_perl=no
 178         ol_enable_shell=no
 179         ol_enable_tcl=no
 180
 181         ol_enable_aclgroups=no
 182         ol_enable_modules=no
 183         ol_enable_phonetic=no
 184         ol_enable_rlookups=no
 185         ol_enable_wrappers=no
 186
 187         ol_with_ldbm_api=no
 188         ol_with_ldbm_type=no
 189
 190         ol_enable_slurpd=no
 191
 192 elif test $ol_enable_ldbm = no ; then
 193         dnl SLAPD without LDBM
 194
 195         if test $ol_with_ldbm_api != auto ; then
 196                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 197         fi
 198
 199         if test $ol_with_ldbm_type != auto ; then
 200                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 201         fi
 202
 203         if test $ol_enable_bdb2 = yes ; then
 204                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 205         fi
 206
 207         if test $ol_enable_modules != yes -a \
 208                 $ol_enable_passwd = no -a \
 209                 $ol_enable_perl = no -a \
 210                 $ol_enable_shell = no -a \
 211                 $ol_enable_tcl = no ; then
 212                 AC_MSG_ERROR([slapd requires a backend])
 213         fi
 214
 215         ol_with_ldbm_api=no
 216         ol_with_ldbm_type=no
 217
 218 elif test $ol_enable_bdb2 = yes ; then
 219         dnl SLAPD with BDB2
 220
 221         if test $ol_with_ldbm_api != auto -a \
 222                 $ol_with_ldbm_api != db2 ; then
 223                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 224         fi
 225
 226         ol_with_ldbm_api=db2
 227
 228 else
 229         dnl SLAPD with LDBM
 230
 231         if test $ol_enable_bdb2 != no ; then
 232                 if test $ol_with_ldbm_api != auto -a \
 233                         $ol_with_ldbm_api != db2 ; then
 234                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 235                         ol_enable_bdb2=no
 236                 fi
 237         fi
 238
 239         if test $ol_with_ldbm_api = gdbm -a \
 240                 $ol_with_ldbm_type = btree ; then
 241                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 242         fi
 243         if test $ol_with_ldbm_api = mdbm -a \
 244                 $ol_with_ldbm_type = btree ; then
 245                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 246         fi
 247         if test $ol_with_ldbm_api = ndbm -a \
 248                 $ol_with_ldbm_type = btree ; then
 249                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 250         fi
 251 fi
 252
 253 if test $ol_enable_slurpd = yes ; then
 254         dnl SLURPD was specifically enabled
 255         if test $ol_with_threads = no ; then
 256                 AC_MSG_ERROR([slurpd requires threads])
 257         fi
 258 fi
 259
 260 AC_MSG_RESULT(done)
 261
 262 ## Initialize vars
 263 LDAP_LIBS=
 264 LDBM_LIBS=
 265 LTHREAD_LIBS=
 266 LUTIL_LIBS=
 267
 268 LDAPD_LIBS=
 269 SLAPD_LIBS=
 270 SLURPD_LIBS=
 271
 272 BUILD_LDAPD=no
 273 BUILD_SLAPD=no
 274 BUILD_SLURPD=no
 275
 276 BUILD_BDB2=no
 277 BUILD_LDAP=no
 278 BUILD_LDBM=no
 279 BUILD_PASSWD=no
 280 BUILD_PERL=no
 281 BUILD_SHELL=no
 282 BUILD_TCL=no
 283 BUILD_THREAD=no
 284
 285 SLAPD_MODULES_LDFLAGS=
 286 SLAPD_MODULES_CPPFLAGS=
 287
 288 SLAPD_PERL_LDFLAGS=
 289 SLAPD_PERL_CPPFLAGS=
 290
 291 KRB_LIBS=
 292 READLINE_LIBS=
 293 TERMCAP_LIBS=
 294 TLS_LIBS=
 295
 296 dnl ----------------------------------------------------------------
 297 dnl Checks for programs
 298
 299 AC_PROG_INSTALL
 300
 301 dnl The default compiler is cc (NOT gcc)
 302 CC=${CC-"cc"}
 303 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 304 dnl CFLAGS=${CFLAGS-""}
 305
 306 AM_PROG_LIBTOOL
 307 dnl AC_PROG_MAKE_SET
 308
 309 AC_PROG_AWK
 310 OL_PROG_LN_H
 311 AC_PROG_LN_S
 312
 313 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 314         LN_S="$LN_H"
 315 fi
 316
 317 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 318         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 319 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 320 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 321
 322 ol_link_modules=no
 323 if test $ol_enable_modules != no ; then
 324         AC_PATH_PROG(GLIBCONFIG, glib-config)
 325
 326         if test "no$GLIBCONFIG" = "no" ; then
 327                 if test $ol_enable_modules = yes ; then
 328                         AC_MSG_ERROR([could not locate glib-config])
 329                 fi
 330
 331         else
 332                 SLAPD_MODULES_VERSION="`$GLIBCONFIG --version gmodule`"
 333                 SLAPD_MODULES_CPPFLAGS="`$GLIBCONFIG --cflags gmodule`"
 334                 SLAPD_MODULES_LDFLAGS="`$GLIBCONFIG --libs gmodule`"
 335
 336                 dnl should check glib version
 337                 ol_link_modules=yes
 338         fi
 339 fi
 340
 341 ol_link_perl=no
 342 if test $ol_enable_perl != no ; then
 343         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 344
 345         if test "no$PERLBIN" = "no" ; then
 346                 if test $ol_enable_perl = yes ; then
 347                         AC_MSG_ERROR([could not locate perl])
 348                 fi
 349
 350         else
 351                 SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 352                 SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 353
 354                 dnl should check perl version
 355                 ol_link_perl=yes
 356         fi
 357 fi
 358
 359 AC_PROG_CPP
 360
 361 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 362         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 363
 364 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 365         AC_MSG_WARN([programs compiled here do run here...])
 366         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 367
 368 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 369         AC_MSG_WARN([programs compiled here do not run here...])
 370         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 371 fi
 372
 373 dnl Checks for UNIX Variants
 374 AC_AIX
 375 AC_ISC_POSIX
 376 AC_MINIX
 377
 378 dnl BeOS requires -lbe -lroot
 379 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot"], :, [-lroot])
 380
 381 dnl Checks for system services
 382 AC_CYGWIN
 383 AC_MINGW32
 384 AC_EXEEXT
 385 AC_OBJEXT
 386
 387 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 388
 389 dnl OpenLDAP requires STDC features
 390 AM_PROG_CC_STDC
 391 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 392         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 393 fi
 394
 395 dnl AM_C_PROTOTYPES
 396
 397 dnl Checks for libraries
 398
 399 dnl Find socket()
 400 dnl Likely combinations:
 401 dnl             -lsocket [ -lnsl_s | -lnsl ]
 402 dnl             -linet
 403
 404 AC_CHECK_FUNC(socket, :, [
 405 dnl
 406 dnl hopefully we won't include too many libraries
 407 dnl
 408         AC_CHECK_LIB(socket, main)
 409         AC_CHECK_LIB(net, main)
 410         AC_CHECK_LIB(net, socket)
 411         AC_CHECK_LIB(nsl_s, main)
 412         AC_CHECK_LIB(nsl, main)
 413         AC_CHECK_LIB(inet, socket)
 414         AC_CHECK_LIB(gen, main)
 415 ])
 416
 417 dnl Check for resolver routines
 418 AC_CHECK_FUNCS(res_search)
 419 if test $ac_cv_func_res_search = "no" ; then
 420         AC_CHECK_LIB(bind, res_search)
 421         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 422                 AC_DEFINE(HAVE_RES_SEARCH,1)
 423         else
 424                 AC_CHECK_LIB(resolv, res_search)
 425                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 426                         AC_DEFINE(HAVE_RES_SEARCH,1)
 427                 fi
 428         fi
 429 fi
 430
 431 dnl HP-UX requires -lV3
 432 AC_CHECK_LIB(V3, sigset)
 433
 434 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 435
 436 dnl Select arg types
 437 dnl (if this detection becomes permenent, it and the select() detection
 438 dnl should be done before the yielding select test)
 439 AC_FUNC_SELECT_ARGTYPES
 440
 441 # ISODE tests
 442 ol_link_isode=no
 443 if test $ol_enable_ldapd != no ; then
 444         dnl look for ISODE libraries
 445         AC_CHECK_LIB(xtpp, main, [
 446                 ol_link_isode=yes
 447                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 448                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 449                 ],:,[-lxtdsap -lxtisode -losi])
 450         AC_CHECK_LIB(dsap, main, [
 451                 ol_link_isode=yes
 452                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 453                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 454                 ],:,[-lisode])
 455         AC_CHECK_LIB(isode, main, [
 456                 ol_link_isode=yes
 457                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 458                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 459                 ],:)
 460 fi
 461
 462 if test $ol_link_isode != no; then
 463         AC_CHECK_LIB(pp, main, [
 464                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 465                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 466                 ],:)
 467
 468         AC_PATH_PROG(PEPSY, pepsy)
 469 fi
 470
 471 dnl
 472 dnl check for kerberos
 473 dnl
 474 ol_link_kerberos=no
 475
 476 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 477         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 478
 479         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 480                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 481                         [-lkrb5 -ldes425])
 482
 483                 if test $have_k5 = yes ; then
 484                         ol_with_kerberos=found
 485                         ol_link_kerberos=yes
 486
 487                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 488
 489                         LIBS="$KRB_LIBS $LIBS"
 490
 491                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 492                                 [ol_cv_var_des_debug], [
 493                                 dnl save the flags
 494                                 save_LIBS="$LIBS"
 495                                 LIBS="$KRB_LIBS $LIBS"
 496                                 AC_TRY_LINK([
 497 #include <kerberosIV/krb.h>
 498 #include <kerberosIV/des.h>
 499 extern int des_debug;
 500 ],[
 501 des_debug = 1;
 502 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 503                                 dnl restore the LIBS
 504                                 LIBS="$save_LIBS"
 505                         ])
 506
 507                         if test $ol_cv_var_des_debug = yes ; then
 508                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 509                                         [define if you have Kerberos des_debug])
 510                         fi
 511
 512                         LIBS="$save_LIBS"
 513                 fi
 514         fi
 515 fi
 516
 517 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 518         AC_CHECK_HEADERS(krb.h des.h)
 519
 520         if test $ac_cv_header_krb_h = yes ; then
 521                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 522
 523                 if test $have_k4 = yes ; then
 524                         ol_with_kerberos=found
 525                         ol_link_kerberos=yes
 526
 527                         KRB_LIBS="-lkrb -ldes"
 528                 fi
 529         fi
 530 fi
 531
 532 if test $ol_link_kerberos = yes ; then
 533         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 534 fi
 535
 536 dnl
 537 dnl Check for SSL/TLS
 538 dnl
 539 ol_link_tls=no
 540 if test $ol_with_tls != no ; then
 541
 542         AC_CHECK_HEADERS(ssl.h)
 543
 544         if test $ac_cv_header_ssl_h = yes ; then
 545                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 546                         [have_ssleay=yes
 547                         need_rsaref=no],
 548                         [have_ssleay=no],
 549                         [-lcrypto])
 550
 551                 if test $have_ssleay = no ; then
 552                         AC_CHECK_LIB(ssl, ssl3_accept,
 553                                 [have_ssleay=yes
 554                                 need_rsaref=yes], [have_ssleay=no],
 555                                 [-lcrypto -lRSAglue -lrsaref])
 556                 fi
 557
 558                 if test $have_ssleay = yes ; then
 559                         ol_with_tls=found
 560                         ol_link_tls=yes
 561
 562                         AC_DEFINE(HAVE_SSLEAY, 1,
 563                                 [define if you have SSLeay or OpenSSL])
 564
 565                         if test $need_rsaref = yes; then
 566                                 AC_DEFINE(HAVE_RSAREF, 1,
 567                                         [define if you have RSAref])
 568
 569                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 570                         else
 571                                 TLS_LIBS="-lssl -lcrypto"
 572                         fi
 573                 fi
 574         fi
 575 fi
 576
 577 if test $ol_link_tls = yes ; then
 578         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 579 fi
 580
 581 dnl Tests for reentrant functions necessary to build a
 582 dnl thread_safe -lldap.
 583 AC_CHECK_FUNCS(         \
 584         ctime_r                 \
 585         gethostbyname_r gethostbyaddr_r \
 586 )
 587
 588 if test "$ac_cv_func_ctime_r" = no ; then
 589         ol_cv_func_ctime_r_nargs=0
 590 else
 591         OL_FUNC_CTIME_R_NARGS
 592 dnl     OL_FUNC_CTIME_R_TYPE
 593 fi
 594
 595 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 596         OL_FUNC_GETHOSTBYNAME_R_NARGS
 597 else
 598         ol_cv_func_gethostbyname_r_nargs=0
 599 fi
 600
 601 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 602         OL_FUNC_GETHOSTBYADDR_R_NARGS
 603 else
 604         ol_cv_func_gethostbyaddr_r_nargs=0
 605 fi
 606
 607 if test "$ac_cv_func_ctime_r" = yes \
 608         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 609         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 610         -a "$ac_cv_func_gethostbyname_r" = yes \
 611         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 612         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 613         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 614         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 615         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 616         ; then
 617
 618         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 619 fi
 620
 621 ol_link_threads=no
 622 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 623         -o $ol_with_threads = posix ; then
 624
 625         AC_CHECK_HEADERS(pthread.h sched.h)
 626
 627         if test $ac_cv_header_pthread_h = yes ; then
 628                 OL_POSIX_THREAD_VERSION
 629
 630                 if test $ol_cv_pthread_version = final ; then
 631                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 632                                 [define if pthreads API compatible with final spec])
 633                 elif test $ol_cv_pthread_version = draft4 ; then
 634                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 635                                 [define if pthreads API compatible with draft4 spec])
 636                 else
 637                         AC_MSG_ERROR([unknown pthread version])
 638                 fi
 639
 640                 # consider threads found
 641                 ol_with_threads=found
 642
 643                 OL_HEADER_LINUX_THREADS
 644
 645                 dnl Now the hard part, how to link?
 646                 dnl
 647                 dnl currently supported checks:
 648                 dnl
 649                 dnl Check for no flags
 650                 dnl     pthread_create() in $LIBS
 651                 dnl
 652                 dnl Check special pthread (final) flags
 653                 dnl     pthread_create() with -mt (Solaris)
 654                 dnl     pthread_create() with -kthread (FreeBSD)
 655                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 656                 dnl     pthread_create() with -pthreads (?)
 657                 dnl     pthread_create() with -thread (?)
 658                 dnl
 659                 dnl Check pthread (final) libraries
 660                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 661                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 662                 dnl     (skipped) pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 663                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
 664                 dnl     pthread_create() in -lpthread (many)
 665                 dnl     pthread_create() in -lc_r (FreeBSD)
 666                 dnl
 667                 dnl Check pthread (draft4) flags (depreciated)
 668                 dnl     pthread_create() with -threads (OSF/1)
 669                 dnl
 670                 dnl Check pthread (draft4) libraries (depreciated)
 671                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 672                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 673                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 674                 dnl     pthread_create() in -lpthreads (many)
 675                 dnl
 676
 677                 dnl pthread_create in $LIBS
 678                 AC_MSG_CHECKING([for pthread_create in default libraries])
 679                 AC_CACHE_VAL(ol_cv_pthread_create,[
 680                 AC_TRY_RUN([
 681 #include <pthread.h>
 682 #ifndef NULL
 683 #define NULL (void*)0
 684 #endif
 685
 686 static void *task(p)
 687         void *p;
 688 {
 689         return (void *) (p == NULL);
 690 }
 691
 692 int main(argc, argv)
 693         int argc;
 694         char **argv;
 695 {
 696         pthread_t t;
 697         int status;
 698
 699         /* make sure pthread_create() isn't just a stub */
 700 #if HAVE_PTHREADS_D4
 701         status = pthread_create(&t, pthread_attr_default, task, NULL);
 702 #else
 703         status = pthread_create(&t, NULL, task, NULL);
 704 #endif
 705
 706         if( status ) return status;
 707
 708         /* make sure pthread_detach() isn't just a stub */
 709 #if HAVE_PTHREADS_D4
 710         status = pthread_detach( &t );
 711 #else
 712         status = pthread_detach( t );
 713 #endif
 714
 715         if( status ) return status;
 716
 717         return status;
 718 }
 719 ],
 720                         [ol_cv_pthread_create=yes],
 721                         [ol_cv_pthread_create=no],
 722                         [dnl assume yes
 723                         ol_cv_pthread_create=yes])])
 724                 AC_MSG_RESULT($ol_cv_pthread_create)
 725
 726                 if test $ol_cv_pthread_create != no ; then
 727                         ol_link_threads=posix
 728                         ol_link_pthreads=""
 729                 fi
 730
 731                 OL_PTHREAD_TRY_LINK([-mt],              [ol_cv_pthread_mt])
 732                 OL_PTHREAD_TRY_LINK([-kthread], [ol_cv_pthread_kthread])
 733                 OL_PTHREAD_TRY_LINK([-pthread], [ol_cv_pthread_pthread])
 734                 OL_PTHREAD_TRY_LINK([-pthreads],[ol_cv_pthread_pthreads])
 735                 OL_PTHREAD_TRY_LINK([-thread],  [ol_cv_pthread_thread])
 736
 737                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc -lc_r],
 738                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
 739                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc],
 740                         [ol_cv_pthread_lpthread_lmach_lexc])
 741 dnl             OL_PTHREAD_TRY_LINK([-lpthread -lexc],
 742 dnl                     [ol_cv_pthread_lpthread_lexc])
 743
 744                 OL_PTHREAD_TRY_LINK([-lpthread -Wl,-woff,85],
 745                         [ol_cv_pthread_lib_lpthread_woff])
 746
 747                 OL_PTHREAD_TRY_LINK([-lpthread],[ol_cv_pthread_lpthread])
 748                 OL_PTHREAD_TRY_LINK([-lc_r],    [ol_cv_pthread_lc_r])
 749
 750                 OL_PTHREAD_TRY_LINK([-threads], [ol_cv_pthread_threads])
 751
 752                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc -lc_r],
 753                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
 754                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc],
 755                         [ol_cv_pthread_lpthreads_lmach_lexc])
 756                 OL_PTHREAD_TRY_LINK([-lpthreads -lexc],
 757                         [ol_cv_pthread_lpthreads_lexc])
 758
 759                 OL_PTHREAD_TRY_LINK([-lpthreads],       [ol_cv_pthread_lib_lpthreads])
 760
 761                 if test $ol_link_threads != no ; then
 762                         AC_DEFINE(HAVE_PTHREADS,1,
 763                                 [define if you have POSIX Threads])
 764
 765                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
 766
 767                         dnl save flags
 768                         save_CPPFLAGS="$CPPFLAGS"
 769                         save_LIBS="$LIBS"
 770                         LIBS="$LTHREAD_LIBS $LIBS"
 771
 772                         dnl All POSIX Thread (final) implementations should have
 773                         dnl sched_yield instead of pthread yield.
 774                         dnl check for both
 775                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 776
 777                         if test $ac_cv_func_sched_yield = no -a \
 778                                 $ac_cv_func_pthread_yield = no ; then
 779                                 dnl Digital UNIX has sched_yield() in -lrt
 780                                 AC_CHECK_LIB(rt, sched_yield,
 781                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 782                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 783                                         ac_cv_func_sched_yield=yes],
 784                                         [ac_cv_func_sched_yield=no])
 785                         fi
 786                         if test $ac_cv_func_sched_yield = no -a \
 787                                 $ac_cv_func_pthread_yield = no ; then
 788                                 dnl Solaris has sched_yield() stub in -lposix4
 789                                 dnl but we'll use thr_yield instead.
 790                                 AC_CHECK_FUNCS(thr_yield)
 791                         fi
 792                         if test $ac_cv_func_sched_yield = no -a \
 793                                 $ac_cv_func_pthread_yield = no -a \
 794                                 "$ac_cv_func_thr_yield" = no ; then
 795                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 796                         fi
 797
 798                         dnl Check functions for compatibility
 799                         AC_CHECK_FUNCS(pthread_kill)
 800
 801                         dnl Check for pthread_detach with <pthread.h> inclusion
 802                         dnl as it's symbol may have been mangled.
 803                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
 804                                 [ol_cv_func_pthread_detach], [
 805                                 dnl save the flags
 806                                 AC_TRY_LINK([
 807 #include <pthread.h>
 808 #ifndef NULL
 809 #define NULL (void*)0
 810 #endif
 811 ],
 812                                         [pthread_detach(NULL);],
 813                                         [ol_cv_func_pthread_detach=yes],
 814                                         [ol_cv_func_pthread_detach=no])
 815                         ])
 816
 817                         if test $ol_cv_func_pthread_detach = no ; then
 818                                 AC_MSG_ERROR([could not locate pthread_detach()])
 819                         fi
 820
 821                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
 822                                 [define if you have pthread_detach function])
 823
 824                         dnl Check for setconcurreny functions
 825                         AC_CHECK_FUNCS( \
 826                                 pthread_setconcurrency \
 827                                 pthread_getconcurrency \
 828                                 thr_setconcurrency \
 829                                 thr_getconcurrency \
 830                         )
 831
 832                         OL_SYS_LINUX_THREADS
 833                         OL_LINUX_THREADS
 834
 835                         if test $ol_cv_linux_threads = error; then
 836                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
 837                         fi
 838
 839                         AC_MSG_CHECKING([if pthread_create() works])
 840                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 841                         AC_TRY_RUN([
 842 #include <pthread.h>
 843 #ifndef NULL
 844 #define NULL (void*)0
 845 #endif
 846
 847 static void *task(p)
 848         void *p;
 849 {
 850         return (void *) (p == NULL);
 851 }
 852
 853 int main(argc, argv)
 854         int argc;
 855         char **argv;
 856 {
 857         pthread_t t;
 858 #if HAVE_PTHREADS_D4
 859         exit(pthread_create(&t, pthread_attr_default, task, NULL));
 860 #else
 861         exit(pthread_create(&t, NULL, task, NULL));
 862 #endif
 863 }
 864 ],
 865                                 [ol_cv_pthread_create_works=yes],
 866                                 [ol_cv_pthread_create_works=no],
 867                                 [dnl assume yes
 868                                 ol_cv_pthread_create_works=yes])])
 869                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 870
 871                         if test $ol_cv_pthread_create_works = no ; then
 872                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
 873                         fi
 874
 875                         dnl Check if select causes an yield
 876                         if test $ol_with_yielding_select = auto ; then
 877                                 AC_MSG_CHECKING([if select yields when using pthreads])
 878                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 879                                 AC_TRY_RUN([
 880 #include <sys/types.h>
 881 #include <sys/time.h>
 882 #include <unistd.h>
 883 #include <pthread.h>
 884 #ifndef NULL
 885 #define NULL (void*) 0
 886 #endif
 887
 888 static int fildes[2];
 889
 890 static void *task(p)
 891         void *p;
 892 {
 893         int i;
 894         struct timeval tv;
 895
 896         fd_set rfds;
 897
 898         tv.tv_sec=10;
 899         tv.tv_usec=0;
 900
 901         FD_ZERO(&rfds);
 902         FD_SET(fildes[0], &rfds);
 903
 904         /* we're not interested in any fds */
 905         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 906
 907         if(i < 0) {
 908                 perror("select");
 909                 exit(10);
 910         }
 911
 912         exit(0); /* if we exit here, the select blocked the whole process */
 913 }
 914
 915 int main(argc, argv)
 916         int argc;
 917         char **argv;
 918 {
 919         pthread_t t;
 920
 921         /* create a pipe to select */
 922         if(pipe(&fildes[0])) {
 923                 perror("select");
 924                 exit(1);
 925         }
 926
 927 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 928         (void) pthread_setconcurrency(2);
 929 #else
 930 #ifdef HAVE_THR_SETCONCURRENCY
 931         /* Set Solaris LWP concurrency to 2 */
 932         thr_setconcurrency(2);
 933 #endif
 934 #endif
 935
 936 #if HAVE_PTHREADS_D4
 937         pthread_create(&t, pthread_attr_default, task, NULL);
 938 #else
 939         pthread_create(&t, NULL, task, NULL);
 940 #endif
 941
 942 #if HAVE_SCHED_YIELD
 943         sched_yield();  /* make sure task runs first */
 944 #else
 945 #ifdef HAVE_PTHREAD_YIELD
 946         pthread_yield();        /* make sure task runs first */
 947 #endif
 948 #endif
 949
 950         exit(2);
 951 }],
 952                                 [ol_cv_pthread_select_yields=no],
 953                                 [ol_cv_pthread_select_yields=yes], [
 954                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
 955                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
 956
 957                                 if test $ol_cv_pthread_select_yields = yes ; then
 958                                         ol_with_yielding_select=yes
 959                                 fi
 960                         fi
 961
 962                         dnl restore flags
 963                         CPPFLAGS="$save_CPPFLAGS"
 964                         LIBS="$save_LIBS"
 965                 else
 966                         AC_MSG_ERROR([could not link with POSIX Threads])
 967                 fi
 968         fi
 969
 970         if test $ol_with_threads = posix ; then
 971                 AC_MSG_ERROR([could not locate POSIX Threads])
 972         fi
 973 fi
 974
 975 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 976         -o $ol_with_threads = mach ; then
 977
 978         dnl check for Mach CThreads
 979         AC_CHECK_HEADERS(mach/cthreads.h)
 980         if test $ac_cv_header_mach_cthreads_h = yes ; then
 981                 ol_with_threads=found
 982
 983                 dnl check for cthread support in current $LIBS
 984                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 985
 986                 if test $ol_link_threads = no ; then
 987                         dnl try -all_load
 988                         dnl this test needs work
 989                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 990                                 [ol_cv_cthread_all_load], [
 991                                 dnl save the flags
 992                                 save_LIBS="$LIBS"
 993                                 LIBS="-all_load $LIBS"
 994                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 995                                         cthread_fork((void *)0, (void *)0);
 996                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 997                                 dnl restore the LIBS
 998                                 LIBS="$save_LIBS"
 999                         ])
1000
1001                         if test $ol_cv_cthread_all_load = yes ; then
1002                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1003                                 ol_link_threads=mach
1004                         fi
1005                 fi
1006
1007                 if test $ol_link_threads != no ; then
1008                         : check for cthread specific functionality here
1009                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1010                                 [define if you have Mach Cthreads])
1011                 else
1012                         AC_MSG_ERROR([could not link with Mach CThreads])
1013                 fi
1014         fi
1015
1016         if test $ol_with_threads = mach ; then
1017                 AC_MSG_ERROR([could not locate Mach CThreads])
1018         fi
1019 fi
1020
1021 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1022         -o $ol_with_threads = lwp ; then
1023
1024         dnl check for SunOS5 LWP
1025         AC_CHECK_HEADERS(thread.h synch.h)
1026         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1027                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1028
1029                 if test $have_thr = yes ; then
1030                         AC_DEFINE(HAVE_THR,1,
1031                                 [if you have Solaris LWP (thr) package])
1032                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1033                         ol_link_threads=thr
1034
1035                         if test $ol_with_yielding_select = auto ; then
1036                                 ol_with_yielding_select=yes
1037                         fi
1038
1039                         dnl Check for setconcurreny functions
1040                         AC_CHECK_FUNCS( \
1041                                 thr_setconcurrency \
1042                                 thr_getconcurrency \
1043                         )
1044                 fi
1045         fi
1046
1047         dnl check for SunOS4 LWP
1048         AC_CHECK_HEADERS(lwp/lwp.h)
1049         if test $ac_cv_header_lwp_lwp_h = yes ; then
1050                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1051
1052                 if test $have_lwp = yes ; then
1053                         AC_DEFINE(HAVE_LWP,1,
1054                                 [if you have SunOS LWP package])
1055                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1056                         ol_link_threads=lwp
1057
1058                         if test $ol_with_yielding_select = auto ; then
1059                                 ol_with_yielding_select=no
1060                         fi
1061                 fi
1062         fi
1063 fi
1064
1065 if test $ol_with_yielding_select = yes ; then
1066         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1067                 [define if select implicitly yields])
1068 fi
1069
1070 if test $ol_with_threads = manual ; then
1071         dnl User thinks he can manually configure threads.
1072         ol_link_threads=yes
1073
1074         AC_MSG_WARN([thread defines and link options must be set manually])
1075
1076         AC_CHECK_HEADERS(pthread.h sched.h)
1077         AC_CHECK_FUNCS(sched_yield pthread_yield)
1078         OL_HEADER_LINUX_THREADS
1079
1080         AC_CHECK_HEADERS(mach/cthreads.h)
1081         AC_CHECK_HEADERS(lwp/lwp.h)
1082         AC_CHECK_HEADERS(thread.h synch.h)
1083 fi
1084
1085 if test $ol_link_threads != no ; then
1086         dnl needed to get reentrant/threadsafe versions
1087         dnl
1088         AC_DEFINE(REENTRANT,1)
1089         AC_DEFINE(_REENTRANT,1)
1090         AC_DEFINE(THREAD_SAFE,1)
1091         AC_DEFINE(_THREAD_SAFE,1)
1092         AC_DEFINE(THREADSAFE,1)
1093         AC_DEFINE(_THREADSAFE,1)
1094
1095         dnl The errno declaration may dependent upon _REENTRANT.
1096         dnl If it does, we must link with thread support.
1097         AC_CACHE_CHECK([for thread specific errno],
1098                 [ol_cv_errno_thread_specific], [
1099                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1100                         [ol_cv_errno_thread_specific=yes],
1101                         [ol_cv_errno_thread_specific=no])
1102         ])
1103
1104         if test $ol_cv_errno_thread_specific != yes ; then
1105                 LIBS="$LTHREAD_LIBS $LIBS"
1106                 LTHREAD_LIBS=""
1107         fi
1108
1109 dnl When in thread environment, use
1110 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1111 dnl                     || defined( HAVE_FUNC_R )
1112 dnl                     func_r(...);
1113 dnl             #else
1114 dnl             #       if defined( HAVE_THREADS )
1115 dnl                             /* lock */
1116 dnl             #       endif
1117 dnl                             func(...);
1118 dnl             #       if defined( HAVE_THREADS )
1119 dnl                             /* unlock */
1120 dnl             #       endif
1121 dnl             #endif
1122 dnl
1123 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1124 dnl             _POSIX_REENTRANT_FUNCTIONS
1125 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1126 dnl             _POSIX_THREADSAFE_FUNCTIONS
1127 dnl
1128 dnl             and is currently defined in lthread.h
1129 dnl
1130 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1131 dnl
1132 dnl libldap/*.c should only include <lthread.h> iff
1133 dnl LDAP_R_COMPILE is defined.  ie:
1134 dnl             #ifdef LDAP_R_COMPILE
1135 dnl             #       include LDAP_R_COMPILE
1136 dnl             #endif
1137 dnl
1138 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1139 dnl specifically for compiling the threadsafe version of
1140 dnl     the ldap library (-lldap_r).
1141 dnl
1142 dnl     dnl check for reentrant/threadsafe functions
1143 dnl     dnl
1144 dnl     dnl note: these should only be used when linking
1145 dnl     dnl       with $LTHREAD_LIBS
1146 dnl     dnl
1147 dnl     save_CPPFLAGS="$CPPFLAGS"
1148 dnl     save_LIBS="$LIBS"
1149 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1150 dnl     AC_CHECK_FUNCS( \
1151 dnl             gmtime_r \
1152 dnl             gethostbyaddr_r gethostbyname_r \
1153 dnl             feof_unlocked unlocked_feof \
1154 dnl             putc_unlocked unlocked_putc \
1155 dnl             flockfile ftrylockfile \
1156 dnl     )
1157 dnl     CPPFLAGS="$save_CPPFLAGS"
1158 dnl     LIBS="$save_LIBS"
1159 fi
1160
1161 if test $ol_link_threads = no ; then
1162         if test $ol_with_threads = yes ; then
1163                 AC_MSG_ERROR([no suitable thread support])
1164         fi
1165
1166         if test $ol_with_threads = auto ; then
1167                 AC_MSG_WARN([no suitable thread support, disabling threads])
1168                 ol_with_threads=no
1169         fi
1170
1171         AC_DEFINE(NO_THREADS,1,
1172                 [define if you have (or want) no threads])
1173         LTHREAD_LIBS=""
1174 fi
1175
1176 if test $ol_link_threads != no ; then
1177         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1178 fi
1179
1180 dnl ----------------------------------------------------------------
1181
1182 ol_link_ldbm=no
1183 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1184         OL_BERKELEY_DB2
1185
1186         if test $ol_cv_berkeley_db2 = yes ; then
1187                 ol_link_ldbm=db2
1188                 ol_with_ldbm_api=db2
1189
1190                 if test $ol_with_ldbm_type = hash ; then
1191                         AC_DEFINE(LDBM_USE_DBHASH,1)
1192                 else
1193                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1194                 fi
1195
1196                 dnl $ol_cv_lib_db2 should be yes or -ldb
1197                 dnl (it could be no, but that would be an error
1198                 if test $ol_cv_lib_db2 != yes ; then
1199                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1200                 fi
1201         fi
1202 fi
1203
1204 ol_link_bdb2=no
1205 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1206         ol_link_bdb2=yes
1207 fi
1208
1209 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1210         OL_BERKELEY_DB
1211
1212         if test $ol_cv_berkeley_db = yes ; then
1213                 ol_link_ldbm=db
1214                 ol_with_ldbm_api=db
1215
1216                 if test $ol_with_ldbm_type = hash ; then
1217                         AC_DEFINE(LDBM_USE_DBHASH,1)
1218                 else
1219                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1220                 fi
1221
1222                 dnl $ol_cv_lib_db should be yes or -ldb
1223                 dnl (it could be no, but that would be an error
1224                 if test $ol_cv_lib_db != yes ; then
1225                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1226                 fi
1227         fi
1228 fi
1229
1230 if test $ol_with_ldbm_api = manual ; then
1231         dnl User thinks he can manually configure LDBM api.
1232         ol_link_ldbm=yes
1233
1234         AC_MSG_WARN([LDBM defines and link options must be set manually])
1235
1236         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1237 fi
1238
1239 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1240         AC_MSG_WARN(Could not find LDBM with BTREE support)
1241         ol_with_ldbm_api=none
1242 fi
1243
1244 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1245         OL_MDBM
1246
1247         if test $ol_cv_mdbm = yes ; then
1248                 ol_link_ldbm=mdbm
1249                 ol_with_ldbm_api=mdbm
1250                 if test $ol_cv_lib_mdbm != yes ; then
1251                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1252                 fi
1253         fi
1254 fi
1255
1256 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1257         OL_GDBM
1258
1259         if test $ol_cv_gdbm = yes ; then
1260                 ol_link_ldbm=gdbm
1261                 ol_with_ldbm_api=gdbm
1262
1263                 if test $ol_cv_lib_gdbm != yes ; then
1264                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1265                 fi
1266         fi
1267 fi
1268
1269 if test $ol_with_ldbm_api = auto ; then
1270         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1271 elif test $ol_with_ldbm_api = ndbm ; then
1272         OL_NDBM
1273
1274         if test $ol_cv_ndbm = yes ; then
1275                 ol_link_ldbm=ndbm
1276                 ol_with_ldbm_api=ndbm
1277
1278                 if test $ol_cv_lib_ndbm != yes ; then
1279                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1280                 fi
1281         fi
1282 fi
1283
1284 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1285         AC_MSG_WARN(could not find suitable LDBM backend)
1286         if test $ol_enable_ldbm = yes ; then
1287                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1288         fi
1289
1290         AC_MSG_WARN(disabling LDBM)
1291         ol_enable_ldbm=no
1292 fi
1293
1294 if test $ol_enable_wrappers != no ; then
1295         AC_CHECK_HEADERS(tcpd.h)
1296
1297         if test $ac_cv_header_tcpd_h != yes ; then
1298                 have_wrappers=no
1299         else
1300                 AC_CHECK_LIB(wrap, main,
1301                         [have_wrappers=yes], [have_wrappers=no])
1302         fi
1303
1304         if test $have_wrappers = yes ; then
1305                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1306                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1307
1308                 dnl We add another check for -lnsl since some libwrap's
1309                 dnl need it, but it isn't always included from above
1310                 AC_CHECK_LIB(nsl, main)
1311         else
1312                 AC_MSG_WARN(could not find -lwrap)
1313                 if test $ol_enable_wrappers = yes ; then
1314                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1315                 fi
1316
1317                 AC_MSG_WARN(disabling wrappers support)
1318                 ol_enable_wrappers=no
1319         fi
1320 fi
1321
1322 if test $ol_enable_syslog != no ; then
1323         AC_CHECK_FUNC(openlog)
1324         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1325                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1326         fi
1327         ol_enable_syslog=$ac_cv_func_openlog
1328 fi
1329
1330 if test $ol_enable_dmalloc != no ; then
1331         AC_CHECK_HEADERS(dmalloc.h)
1332         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1333 fi
1334
1335 if test $ol_enable_tcl != no ; then
1336         AC_CHECK_HEADERS(tcl.h)
1337
1338         if test $ac_cv_header_tcl_h != yes ; then
1339                 have_tcl=no
1340         else
1341                 AC_CHECK_LIB(tcl,main,
1342                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1343                         [have_tcl=no])
1344
1345                 if test $have_tcl != yes; then
1346                         AC_CHECK_LIB(tcl7.6,main,
1347                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1348                                 [have_tcl=no])
1349                 fi
1350
1351                 if test $have_tcl != yes; then
1352                         AC_CHECK_LIB(tcl8.0,main,
1353                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1354                                 [have_tcl=no])
1355                 fi
1356         fi
1357
1358         if test $have_tcl != yes ; then
1359                 AC_MSG_WARN([could not find -ltcl])
1360                 if test $ol_enable_tcl = yes ; then
1361                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1362                 fi
1363
1364                 ol_enable_tcl=no
1365         fi
1366 fi
1367
1368 # ud needs termcap (should insert check here)
1369 ol_link_termcap=no
1370 AC_CHECK_HEADERS(termcap.h ncurses.h)
1371
1372 if test $ol_link_termcap = no ; then
1373         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1374         if test $have_termcap = yes ; then
1375                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1376                 ol_link_termcap=yes
1377                 TERMCAP_LIBS=-ltermcap
1378         fi
1379 fi
1380
1381 if test $ol_link_termcap = no ; then
1382         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1383         if test $have_ncurses = yes ; then
1384                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1385                 ol_link_termcap=yes
1386                 TERMCAP_LIBS=-lncurses
1387         fi
1388 fi
1389
1390 if test $ol_link_termcap = no ; then
1391         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1392         TERMCAP_LIBS=
1393 fi
1394
1395 dnl
1396 dnl Check for GNU readline
1397 dnl
1398 ol_link_readline=no
1399 if test $ol_with_readline != no ; then
1400         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1401
1402         if test $ac_cv_header_readline_readline_h = yes ; then
1403                 save_LIBS="$LIBS"
1404                 LIBS="$TERMCAP_LIBS $LIBS"
1405                 AC_CHECK_LIB(readline, readline,
1406                         [have_readline=yes], [have_readline=no])
1407                 LIBS="$save_LIBS"
1408
1409                 if test $have_readline = yes ; then
1410                         ol_with_readline=found
1411                         ol_link_readline=yes
1412
1413                         READLINE_LIBS="-lreadline"
1414                 fi
1415         fi
1416 fi
1417
1418 if test $ol_link_readline = yes ; then
1419         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1420 fi
1421
1422
1423 # FreeBSD (and others) have crypt(3) in -lcrypt
1424 if test $ol_enable_crypt != no ; then
1425         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1426                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1427                         have_crypt=yes], [have_crypt=no])])
1428
1429         if test $have_crypt = yes ; then
1430                 AC_DEFINE(HAVE_CRYPT,1)
1431         else
1432                 AC_MSG_WARN(could not find crypt)
1433                 if test $ol_enable_crypt = yes ; then
1434                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1435                 fi
1436
1437                 AC_MSG_WARN(disabling crypt support)
1438                 ol_enable_crypt=no
1439         fi
1440 fi
1441
1442 # FreeBSD (and others) have setproctitle(3) in -lutil
1443 if test $ol_enable_proctitle != no ; then
1444         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1445                 AC_CHECK_LIB(util, setproctitle,
1446                         [have_setproctitle=yes
1447                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1448                         [have_setproctitle=no
1449                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1450
1451         if test $have_setproctitle = yes ; then
1452                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1453         fi
1454 fi
1455
1456 dnl ----------------------------------------------------------------
1457 dnl Checks for header files.
1458 OL_HEADER_STDC
1459
1460 if test $ol_cv_header_stdc != yes; then
1461         AC_MSG_WARN([could not locate Standard C compliant headers])
1462 fi
1463
1464 AC_HEADER_DIRENT
1465 AC_HEADER_SYS_WAIT
1466 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1467 if test $am_cv_sys_posix_termios = yes ; then
1468         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1469                 [define if you have POSIX termios])
1470 fi
1471
1472 AC_CHECK_HEADERS(       \
1473         arpa/inet.h             \
1474         arpa/nameser.h  \
1475         assert.h                \
1476         crypt.h                 \
1477         errno.h                 \
1478         fcntl.h                 \
1479         filio.h                 \
1480         getopt.h                \
1481         grp.h                   \
1482         libutil.h               \
1483         limits.h                \
1484         locale.h                \
1485         malloc.h                \
1486         memory.h                \
1487         regex.h                 \
1488         psap.h                  \
1489         pwd.h                   \
1490         resolv.h                \
1491         sgtty.h                 \
1492         stdarg.h                \
1493         stddef.h                \
1494         string.h                \
1495         strings.h               \
1496         sysexits.h              \
1497         sys/file.h              \
1498         sys/filio.h             \
1499         sys/errno.h             \
1500         sys/ioctl.h             \
1501         sys/param.h             \
1502         sys/resource.h  \
1503         sys/select.h    \
1504         sys/socket.h    \
1505         sys/syslog.h    \
1506         sys/time.h              \
1507         sys/types.h             \
1508         syslog.h                \
1509         termios.h               \
1510         unistd.h                \
1511 )
1512
1513 dnl ----------------------------------------------------------------
1514 dnl Checks for typedefs, structures, and compiler characteristics.
1515 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1516 AC_TYPE_MODE_T
1517 AC_TYPE_OFF_T
1518 AC_TYPE_PID_T
1519 AM_TYPE_PTRDIFF_T
1520 AC_TYPE_SIGNAL
1521 OL_TYPE_SIG_ATOMIC_T
1522 AC_TYPE_SIZE_T
1523 AC_STRUCT_ST_BLKSIZE
1524 AC_HEADER_TIME
1525 AC_STRUCT_TM
1526 OL_STRUCT_PASSWD_PW_GECOS
1527
1528 OL_C_UPPER_LOWER
1529 AC_C_CONST
1530 OL_C_VOLATILE
1531
1532 if test $cross_compiling = yes ; then
1533         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1534 else
1535         AC_C_BIGENDIAN
1536         AC_CHECK_SIZEOF(short)
1537         AC_CHECK_SIZEOF(int)
1538         AC_CHECK_SIZEOF(long)
1539 fi
1540
1541 dnl ----------------------------------------------------------------
1542 dnl Checks for library functions.
1543 AC_FUNC_MEMCMP
1544 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1545 AC_FUNC_STRFTIME
1546 dnl AM_FUNC_STRTOD
1547
1548 dnl we should use vfork instead of fork in a number of places...
1549 dnl AC_FUNC_VFORK
1550 AC_FUNC_VPRINTF
1551
1552 if test $ac_cv_func_vprintf = yes ; then
1553         dnl check for vsnprintf
1554         AC_CHECK_FUNCS(vsnprintf vsprintf)
1555 fi
1556
1557 AC_CHECK_FUNCS(         \
1558         bcopy                   \
1559         endgrent                \
1560         endpwent                \
1561         flock                   \
1562         getdtablesize   \
1563         getgrgid                \
1564         gethostname             \
1565         getpass                 \
1566         getpwuid                \
1567         gettimeofday    \
1568         initgroups              \
1569         lockf                   \
1570         memcpy                  \
1571         memmove                 \
1572         mkstemp                 \
1573         recv                    \
1574         recvfrom                \
1575         setpwfile               \
1576         setgid                  \
1577         setegid                 \
1578         setsid                  \
1579         setuid                  \
1580         seteuid                 \
1581         signal                  \
1582         sigset                  \
1583         snprintf                \
1584         strdup                  \
1585         strerror                \
1586         strpbrk                 \
1587         strrchr                 \
1588         strsep                  \
1589         strstr                  \
1590         strtol                  \
1591         strtoul                 \
1592         strspn                  \
1593         sysconf                 \
1594         waitpid                 \
1595         wait4                   \
1596 )
1597
1598 dnl We actually may need to replace more than this.
1599 AC_REPLACE_FUNCS(getopt tempnam)
1600
1601 dnl ----------------------------------------------------------------
1602 # Check Configuration
1603 OL_SYS_ERRLIST
1604
1605 dnl ----------------------------------------------------------------
1606 dnl Sort out defines
1607
1608 if test "$ol_enable_debug" != no ; then
1609         AC_DEFINE(LDAP_DEBUG,1)
1610 fi
1611 if test "$ol_enable_syslog" = yes ; then
1612         AC_DEFINE(LDAP_SYSLOG,1)
1613 fi
1614 if test "$ol_enable_libui" = yes ; then
1615         AC_DEFINE(LDAP_LIBUI,1)
1616 fi
1617 if test "$ol_enable_cache" = no ; then
1618         AC_DEFINE(LDAP_NOCACHE,1)
1619 fi
1620 if test "$ol_enable_dns" != no ; then
1621         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1622 fi
1623 if test "$ol_enable_proctitle" != no ; then
1624         AC_DEFINE(LDAP_PROCTITLE,1)
1625 fi
1626 if test "$ol_enable_referrals" != no ; then
1627         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1628 fi
1629 if test "$ol_enable_cldap" != no ; then
1630         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1631 fi
1632
1633 if test "$ol_enable_aclgroups" != no ; then
1634         AC_DEFINE(SLAPD_ACLGROUPS,1)
1635 fi
1636 if test "$ol_enable_crypt" != no ; then
1637         AC_DEFINE(SLAPD_CRYPT,1)
1638 fi
1639 if test "$ol_enable_cleartext" != no ; then
1640         AC_DEFINE(SLAPD_CLEARTEXT,1)
1641 fi
1642 if test "$ol_enable_phonetic" != no ; then
1643         AC_DEFINE(SLAPD_PHONETIC,1)
1644 fi
1645 if test "$ol_enable_rlookups" != no ; then
1646         AC_DEFINE(SLAPD_RLOOKUPS,1)
1647 fi
1648
1649 if test "$ol_link_modules" != no ; then
1650         AC_DEFINE(SLAPD_MODULES,1)
1651         BUILD_SLAPD=yes
1652 fi
1653
1654 if test "$ol_link_bdb2" != no ; then
1655         AC_DEFINE(SLAPD_BDB2,1)
1656         BUILD_SLAPD=yes
1657         BUILD_BDB2=yes
1658 fi
1659
1660 if test "$ol_link_ldap" != no ; then
1661         AC_DEFINE(SLAPD_LDAP,1)
1662         BUILD_SLAPD=yes
1663         BUILD_LDAP=yes
1664 fi
1665
1666 if test "$ol_link_ldbm" != no ; then
1667         AC_DEFINE(SLAPD_LDBM,1)
1668         BUILD_SLAPD=yes
1669         BUILD_LDBM=yes
1670 fi
1671
1672 if test "$ol_enable_passwd" != no ; then
1673         AC_DEFINE(SLAPD_PASSWD,1)
1674         BUILD_SLAPD=yes
1675         BUILD_PASSWD=yes
1676 fi
1677
1678 if test "$ol_link_perl" != no ; then
1679         AC_DEFINE(SLAPD_PERL,1)
1680         BUILD_SLAPD=yes
1681         BUILD_PERL=yes
1682 fi
1683
1684 if test "$ol_enable_shell" != no ; then
1685         AC_DEFINE(SLAPD_SHELL,1)
1686         BUILD_SLAPD=yes
1687         BUILD_SHELL=yes
1688 fi
1689
1690 if test "$ol_enable_tcl" != no ; then
1691         AC_DEFINE(SLAPD_TCL,1)
1692         BUILD_SLAPD=yes
1693         BUILD_TCL=yes
1694 fi
1695
1696 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1697         $BUILD_SLAPD = yes ; then
1698         BUILD_SLURPD=yes
1699 fi
1700
1701 if test "$ol_link_isode" != no ; then
1702         BUILD_LDAPD=yes
1703 fi
1704
1705 dnl ----------------------------------------------------------------
1706
1707 AC_SUBST(BUILD_LDAPD)
1708 AC_SUBST(BUILD_SLAPD)
1709   AC_SUBST(BUILD_BDB2)
1710   AC_SUBST(BUILD_LDAP)
1711   AC_SUBST(BUILD_LDBM)
1712   AC_SUBST(BUILD_PASSWD)
1713   AC_SUBST(BUILD_PERL)
1714   AC_SUBST(BUILD_SHELL)
1715   AC_SUBST(BUILD_TCL)
1716 AC_SUBST(BUILD_SLURPD)
1717
1718 AC_SUBST(LDAP_LIBS)
1719 AC_SUBST(LDAPD_LIBS)
1720 AC_SUBST(SLAPD_LIBS)
1721 AC_SUBST(SLURPD_LIBS)
1722 AC_SUBST(LDBM_LIBS)
1723 AC_SUBST(LTHREAD_LIBS)
1724 AC_SUBST(LUTIL_LIBS)
1725
1726 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
1727 AC_SUBST(SLAPD_MODULES_LDFLAGS)
1728
1729 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1730 AC_SUBST(SLAPD_PERL_LDFLAGS)
1731
1732 AC_SUBST(KRB_LIBS)
1733 AC_SUBST(READLINE_LIBS)
1734 AC_SUBST(TERMCAP_LIBS)
1735 AC_SUBST(TLS_LIBS)
1736
1737 dnl ----------------------------------------------------------------
1738 dnl final output
1739 dnl
1740
1741 AC_OUTPUT( \
1742 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1743 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1744 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1745 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1746 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1747 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1748 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1749 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1750 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1751 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1752 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1753 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1754 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1755 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1756 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1757 include/Makefile:build/top.mk:include/Makefile.in \
1758 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1759 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1760 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1761 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1762 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1763 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1764 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1765 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1766 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1767 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1768 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1769 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
1770 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/srv.mk \
1771 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1772 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1773 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
1774 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1775 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
1776 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1777 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1778 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1779 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
1780 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
1781 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
1782 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
1783 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
1784 ,[
1785 date > stamp-h
1786 echo Please \"make depend\" to build dependencies
1787 ])