git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms are permitted only
   6 dnl as authorized by the OpenLDAP Public License.  A copy of this
   7 dnl license is available at http://www.OpenLDAP.org/license.html or
   8 dnl in file LICENSE in the top-level directory of the distribution.
   9 dnl
  10 dnl ----------------------------------------------------------------
  11 dnl Redefine AC_INIT_BINSH to provide RCS IDs and copyright notice
  12 dnl at top of generated configure script.  Prints simple copyright.
  13 define([AC_INIT_BINSH],
  14 [[#! /bin/sh
  15 # $]OpenLDAP[$
  16 # from] translit([$OpenLDAP$], $")] [
  17
  18 # Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
  19 #
  20 # Redistribution and use in source and binary forms are permitted only
  21 # as authorized by the OpenLDAP Public License.  A copy of this
  22 # license is available at http://www.OpenLDAP.org/license.html or
  23 # in file LICENSE in the top-level directory of the distribution.
  24
  25 echo "Copyright 1998-2000 The OpenLDAP Foundation,  All Rights Reserved."
  26 echo "Restrictions apply, see COPYRIGHT and LICENSE files."
  27 ])dnl
  28 dnl ----------------------------------------------------------------
  29 dnl Disable config.cache!
  30 define([AC_CACHE_LOAD], )dnl
  31 define([AC_CACHE_SAVE], )dnl
  32 dnl ================================================================
  33 dnl Configure.in for OpenLDAP
  34 AC_INIT(build/version)dnl
  35
  36 # set unset (borrowed from autoconf 2.14a)
  37 if (unset FOO) >/dev/null 2>&1; then
  38   ol_unset=unset
  39 else
  40   ol_unset=false
  41 fi
  42 # unset CDPATH
  43 $ol_unset CDPATH || test "${CDPATH+set}" != set || CDPATH=: && export CDPATH
  44
  45 AC_CONFIG_AUX_DIR(build)dnl
  46
  47 OL_VERSION=`cat $ac_aux_dir/version`
  48 if test -z "$OL_VERSION"; then
  49         AC_MSG_ERROR([could not determine version])
  50 fi
  51
  52 echo "Configuring OpenLDAP $OL_VERSION ..."
  53
  54 dnl Determine host platform
  55 dnl             we try not to use this for much
  56 AC_CANONICAL_SYSTEM
  57
  58 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  59 AC_SUBST(PACKAGE)
  60 AC_SUBST(VERSION)
  61 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  62 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  63
  64 dnl We use autoconf features new to 2.13.
  65 dnl aclocal.m4 should be built using aclocal from automake 1.4
  66 dnl libtool 1.3.3 should be installed.
  67 AC_PREREQ(2.13)dnl Required Autoconf version
  68
  69 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  70
  71 dnl ================================================================
  72 dnl Start Args
  73 AC_MSG_CHECKING(configure arguments)
  74 AC_PREFIX_DEFAULT(/usr/local)
  75
  76 top_builddir=`pwd`
  77 AC_SUBST(top_builddir)dnl
  78
  79 dnl ----------------------------------------------------------------
  80 dnl --with-subdir
  81 ldap_subdir="/openldap"
  82
  83 AC_ARG_WITH(subdir,
  84 [  --with-subdir=DIR change default subdirectory used for installs],
  85 [case "$withval" in
  86         no) ldap_subdir=""
  87                 ;;
  88         yes)
  89                 ;;
  90         /*|\\*)
  91                 ldap_subdir="$withval"
  92                 ;;
  93         *)
  94                 ldap_subdir="/$withval"
  95                 ;;
  96 esac
  97 ])dnl
  98
  99 AC_SUBST(ldap_subdir)dnl
 100
 101 dnl ----------------------------------------------------------------
 102 dnl General "enable" options
 103 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes)dnl
 104 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 105 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 106 OL_ARG_ENABLE(cache,[  --enable-cache     enable caching], yes)dnl
 107 OL_ARG_ENABLE(referrals,[  --enable-referrals     enable V2 Referrals extension], yes)dnl
 108 OL_ARG_ENABLE(kbind,[  --enable-kbind     enable V2 Kerberos IV bind], no)dnl
 109 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 110 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 111 OL_ARG_ENABLE(x_compile,[  --enable-x-compile     enable cross compiling],
 112         no, [yes no])dnl
 113
 114 dnl ----------------------------------------------------------------
 115 dnl General "with" options
 116 dnl OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc     enable debug malloc support], no)dnl
 117
 118 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 119         auto, [auto yes no] )
 120 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch URL support],
 121         auto, [auto yes no] )
 122 OL_ARG_WITH(kerberos,[  --with-kerberos   with support],
 123         auto, [auto k5 k5only k425 kth k4 afs yes no])
 124 OL_ARG_WITH(readline,[  --with-readline   with readline support],
 125         auto, [auto yes no] )
 126 OL_ARG_WITH(threads,[  --with-threads     with threads],
 127         auto, [auto nt posix mach pth lwp yes no manual] )
 128 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support],
 129         auto, [auto ssleay openssl yes no] )
 130 OL_ARG_WITH(yielding_select,[  --with-yielding-select  with implicitly yielding select],
 131         auto, [auto yes no manual] )
 132
 133 dnl ----------------------------------------------------------------
 134 dnl Server options
 135 dnl ----------------------------------------------------------------
 136
 137 dnl ----------------------------------------------------------------
 138 dnl SLAPD OPTIONS
 139 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 140 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 141 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 142 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], auto)dnl
 143 OL_ARG_ENABLE(kpasswd,[    --enable-kpasswd       enable kerberos password verification], no)dnl
 144 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 145 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 146 OL_ARG_ENABLE(multimaster,[    --enable-multimaster  enable multimaster replication], no)dnl
 147 OL_ARG_ENABLE(phonetic,[    --enable-phonetic     enable phonetic/soundex], no)dnl
 148 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups], auto)dnl
 149 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs], no)dnl
 150 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 151 OL_ARG_ENABLE(dynamic,[    --enable-dynamic       enable linking built binaries with dynamic libs], no)dnl
 152
 153 dnl SLAPD Backend options
 154 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend], no)dnl
 155 OL_ARG_WITH(dnssrv_module,[    --with-dnssrv-module  module type], static,
 156         [static dynamic])
 157 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend], no)dnl
 158 OL_ARG_WITH(ldap_module,[    --with-ldap-module   module type], static,
 159         [static dynamic])
 160 OL_ARG_ENABLE(ldbm,[    --enable-ldbm     enable ldbm backend], yes)dnl
 161 OL_ARG_WITH(ldbm_api,[    --with-ldbm-api       with LDBM API], auto,
 162         [auto berkeley bcompat mdbm gdbm])
 163 OL_ARG_WITH(ldbm_module,[    --with-ldbm-module   module type], static,
 164         [static dynamic])
 165 OL_ARG_WITH(ldbm_type,[    --with-ldbm-type       use LDBM type], auto,
 166         [auto btree hash])
 167 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend], no)dnl
 168 OL_ARG_WITH(passwd_module,[    --with-passwd-module  module type], static,
 169         [static dynamic])
 170 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend], no)dnl
 171 OL_ARG_WITH(shell_module,[    --with-shell-module         module type], static,
 172         [static dynamic])
 173 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend], no)dnl
 174 OL_ARG_WITH(sql_module,[    --with-sql-module     module type], static,
 175         [static dynamic])
 176
 177 dnl ----------------------------------------------------------------
 178 dnl SLURPD OPTIONS
 179 AC_ARG_WITH(xxslurpdoptions,[SLURPD (Replication Daemon) Options:])
 180 OL_ARG_ENABLE(slurpd,[  --enable-slurpd   enable building slurpd], auto)dnl
 181
 182 dnl ----------------------------------------------------------------
 183 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 184 AC_ENABLE_STATIC
 185 dnl AC_DISABLE_SHARED
 186 AC_ENABLE_SHARED
 187
 188 dnl ----------------------------------------------------------------
 189
 190 dnl General "enable" options
 191 # validate options
 192 if test $ol_enable_slapd = no ; then
 193         dnl SLAPD was specificallly disabled
 194         if test $ol_enable_dnssrv = yes ; then
 195                 AC_MSG_WARN([slapd disabled, ignoring --enable-dnssrv argument])
 196         fi
 197         if test $ol_enable_ldap = yes ; then
 198                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 199         fi
 200         if test $ol_enable_ldbm = yes ; then
 201                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 202         fi
 203         if test $ol_enable_passwd = yes ; then
 204                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 205         fi
 206         if test $ol_enable_shell = yes ; then
 207                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 208         fi
 209         if test $ol_enable_sql = yes ; then
 210                 AC_MSG_WARN([slapd disabled, ignoring --enable-sql argument])
 211         fi
 212         if test $ol_enable_modules = yes ; then
 213                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 214         fi
 215         if test $ol_enable_multimaster = yes ; then
 216                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 217         fi
 218         if test $ol_enable_wrappers = yes ; then
 219                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 220         fi
 221         if test $ol_enable_phonetic = yes ; then
 222                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 223         fi
 224         if test $ol_enable_rlookups = yes ; then
 225                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 226         fi
 227         if test $ol_enable_aci = yes ; then
 228                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 229         fi
 230         if test $ol_with_ldbm_api != auto ; then
 231                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 232         fi
 233         if test $ol_with_ldbm_type != auto ; then
 234                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 235         fi
 236         if test $ol_with_dnssrv_module != static ; then
 237                 AC_MSG_WARN([slapd disabled, ignoring --with-dnssrv-module argument])
 238         fi
 239         if test $ol_with_ldap_module != static ; then
 240                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 241         fi
 242         if test $ol_with_ldbm_module != static ; then
 243                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 244         fi
 245         if test $ol_with_passwd_module != static ; then
 246                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 247         fi
 248         if test $ol_with_shell_module != static ; then
 249                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 250         fi
 251         if test $ol_with_sql_module != static ; then
 252                 AC_MSG_WARN([slapd disabled, ignoring --with-sql-module argument])
 253         fi
 254         if test $ol_enable_slurpd = yes ; then
 255                 AC_MSG_ERROR([slurpd requires slapd])
 256         fi
 257
 258         # force settings to no
 259         ol_enable_dnssrv=no
 260         ol_enable_ldap=no
 261         ol_enable_ldbm=no
 262         ol_enable_passwd=no
 263         ol_enable_shell=no
 264         ol_enable_sql=no
 265
 266         ol_enable_modules=no
 267         ol_enable_multimaster=no
 268         ol_enable_phonetic=no
 269         ol_enable_rlookups=no
 270         ol_enable_aci=no
 271         ol_enable_wrappers=no
 272         ol_enable_dynamic=no
 273
 274         ol_with_ldbm_api=no
 275         ol_with_ldbm_type=no
 276
 277         ol_with_dnssrv_module=static
 278         ol_with_ldap_module=static
 279         ol_with_ldbm_module=static
 280         ol_with_passwd_module=static
 281         ol_with_shell_module=static
 282         ol_with_sql_module=static
 283
 284         ol_enable_slurpd=no
 285
 286 elif test $ol_enable_ldbm = no ; then
 287         dnl SLAPD without LDBM
 288
 289         if test $ol_with_ldbm_api != auto ; then
 290                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 291         fi
 292
 293         if test $ol_with_ldbm_type != auto ; then
 294                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 295         fi
 296
 297         if test $ol_with_ldbm_module != static ; then
 298                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 299         fi
 300
 301         if test $ol_enable_modules != yes -a \
 302                 $ol_enable_dnssrv = no -a \
 303                 $ol_enable_ldap = no -a \
 304                 $ol_enable_passwd = no -a \
 305                 $ol_enable_shell = no -a \
 306                 $ol_enable_sql = no ; then
 307                 AC_MSG_ERROR([slapd requires a backend])
 308         fi
 309
 310         ol_with_ldbm_api=no
 311         ol_with_ldbm_type=no
 312         ol_with_ldbm_module=static
 313
 314 else
 315         dnl SLAPD with LDBM
 316         if test $ol_with_ldbm_api = gdbm -a \
 317                 $ol_with_ldbm_type = btree ; then
 318                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 319         fi
 320         if test $ol_with_ldbm_api = mdbm -a \
 321                 $ol_with_ldbm_type = btree ; then
 322                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 323         fi
 324         if test $ol_with_ldbm_api = ndbm -a \
 325                 $ol_with_ldbm_type = btree ; then
 326                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 327         fi
 328 fi
 329
 330 if test $ol_enable_slurpd = yes ; then
 331         dnl SLURPD was specifically enabled
 332         if test $ol_with_threads = no ; then
 333                 AC_MSG_ERROR([slurpd requires threads])
 334         fi
 335 fi
 336
 337 if test $ol_enable_kbind = yes -o $ol_enable_kpasswd = yes ; then
 338         if test $ol_with_kerberos = no ; then
 339                 AC_MSG_ERROR([options require --with-kerberos])
 340         fi
 341         ol_with_kerberos=yes
 342 elif test $ol_enable_kbind = no -o $ol_enable_kpasswd = no ; then
 343         if test $ol_with_kerberos != no -a $ol_with_kerberos != auto ; then
 344                 AC_MSG_WARN([Kerberos detection enabled unnecessarily]);
 345         fi
 346         ol_with_kerberos=no
 347 fi
 348
 349 if test $ol_enable_spasswd = yes ; then
 350         if test $ol_with_cyrus_sasl = no ; then
 351                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 352         fi
 353         ol_with_cyrus_sasl=yes
 354 fi
 355
 356 AC_MSG_RESULT(done)
 357
 358 dnl ----------------------------------------------------------------
 359 dnl Initialize vars
 360 LDAP_LIBS=
 361 LDIF_LIBS=
 362 LDBM_LIBS=
 363 LTHREAD_LIBS=
 364 LUTIL_LIBS=
 365
 366 SLAPD_LIBS=
 367 SLURPD_LIBS=
 368
 369 BUILD_SLAPD=no
 370 BUILD_SLURPD=no
 371
 372 BUILD_THREAD=no
 373
 374 BUILD_DNSSRV=no
 375 BUILD_LDAP=no
 376 BUILD_LDBM=no
 377 BUILD_PASSWD=no
 378 BUILD_SHELL=no
 379 BUILD_SQL=no
 380
 381 BUILD_DNSSRV_DYNAMIC=static
 382 BUILD_LDAP_DYNAMIC=static
 383 BUILD_LDBM_DYNAMIC=static
 384 BUILD_PASSWD_DYNAMIC=static
 385 BUILD_SHELL_DYNAMIC=static
 386 BUILD_SQL_DYNAMIC=static
 387
 388 SLAPD_MODULES_LDFLAGS=
 389 SLAPD_MODULES_CPPFLAGS=
 390 SLAPD_MODULES_LIST=
 391
 392 SLAPD_SQL_LDFLAGS=
 393 SLAPD_SQL_LIBS=
 394 SLAPD_SQL_INCLUDES=
 395
 396 KRB4_LIBS=
 397 KRB5_LIBS=
 398 READLINE_LIBS=
 399 SASL_LIBS=
 400 TERMCAP_LIBS=
 401 TLS_LIBS=
 402 MODULES_LIBS=
 403 AUTH_LIBS=
 404
 405 dnl ================================================================
 406 dnl Checks for programs
 407
 408 dnl AC_PROG_INSTALL
 409
 410 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 411
 412 dnl ----------------------------------------------------------------
 413 dnl
 414 dnl Determine which C translator to use
 415 dnl
 416
 417 dnl AIX Thread requires we use cc_r or xlc_r.
 418 dnl But only do this IF AIX and CC is not set
 419 dnl and threads are auto|yes|posix.
 420 dnl
 421 dnl If we find cc_r|xlc_r, force pthreads and assume
 422 dnl             pthread_create is in $LIBS (ie: don't bring in
 423 dnl             any additional thread libraries)
 424 dnl If we do not find cc_r|xlc_r, disable threads
 425
 426 ol_aix_threads=no
 427 case "$target" in
 428 *-*-aix*) dnl all AIX is not a good idea.
 429         if test -z "$CC" ; then
 430                 case "$ol_with_threads" in
 431                 auto | yes |  posix) ol_aix_threads=yes ;;
 432                 esac
 433         fi
 434 ;;
 435 esac
 436
 437 if test $ol_aix_threads = yes ; then
 438         if test -z "${CC}" ; then
 439                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 440
 441                 if test "$CC" = cc ; then
 442                         dnl no CC! don't allow --with-threads
 443                         if test $ol_with_threads != auto ; then
 444                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 445                         else
 446                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 447                         fi
 448                         ol_with_threads=no
 449                 fi
 450         fi
 451
 452         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 453                 ol_with_threads=posix
 454                 ol_cv_pthread_create=yes
 455         fi
 456 fi
 457
 458 if test -z "${CC}"; then
 459         AC_CHECK_PROGS(CC,cc)
 460 fi
 461
 462 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 463 dnl (for now, let autoconf sort this out)
 464 dnl CFLAGS=${CFLAGS-""}
 465
 466 AC_LIBTOOL_WIN32_DLL
 467 AC_LIBTOOL_DLOPEN
 468 AC_PROG_LIBTOOL
 469
 470 AC_PROG_AWK
 471 OL_PROG_LN_H
 472 AC_PROG_LN_S
 473
 474 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 475         LN_S="$LN_H"
 476 fi
 477
 478 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 479         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 480 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 481 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 482
 483 AC_PROG_CPP
 484
 485 dnl ----------------------------------------------------------------
 486 dnl Cross compiling checks
 487 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 488         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 489
 490 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 491         AC_MSG_WARN([programs compiled here do run here...])
 492         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 493
 494 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 495         AC_MSG_WARN([programs compiled here do not run here...])
 496         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 497 fi
 498
 499 dnl ----------------------------------------------------------------
 500 dnl Checks for UNIX Variants
 501 AC_AIX
 502 AC_ISC_POSIX
 503 AC_MINIX
 504
 505 dnl ----------------------------------------------------------------
 506 dnl Checks for system services
 507 AC_CYGWIN
 508 AC_MINGW32
 509 AC_EXEEXT
 510 AC_OBJEXT
 511
 512 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 513
 514 dnl ----------------------------------------------------------------
 515 dnl BeOS requires -lbe -lroot -lnet
 516 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 517
 518 dnl ----------------------------------------------------------------
 519 dnl OpenLDAP requires STDC features
 520 AM_PROG_CC_STDC
 521 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 522         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 523 fi
 524
 525 dnl ----------------------------------------------------------------
 526 dnl Check cc depend flags
 527 OL_MKDEPEND
 528 if test "${ol_cv_mkdep}" = no ; then
 529         # this will soon become an error
 530         AC_MSG_WARN([do not know how to generate dependencies])
 531 fi
 532
 533 dnl ----------------------------------------------------------------
 534 dnl Check for AIX security library
 535 AC_CHECK_LIB(s, afopen, [
 536         AUTH_LIBS=-ls
 537         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 538 ])
 539
 540
 541 dnl ----------------------------------------------------------------
 542 dnl Check for module support
 543 ol_link_modules=no
 544 if test $ol_enable_modules != no ; then
 545         AC_CHECK_HEADERS(ltdl.h)
 546
 547         if test $ac_cv_header_ltdl_h = no ; then
 548                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 549         fi
 550
 551         AC_CHECK_LIB(ltdl, lt_dlinit, [
 552             MODULES_LIBS=-lltdl
 553             AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 554         ])
 555
 556         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 557                 AC_MSG_ERROR([could not locate libtool -lltdl])
 558         fi
 559         ol_link_modules=yes
 560 else
 561         ol_with_dnssrv_module=static
 562         ol_with_ldap_module=static
 563         ol_with_ldbm_module=static
 564         ol_with_passwd_module=static
 565         ol_with_shell_module=static
 566         ol_with_sql_module=static
 567 fi
 568
 569 dnl ----------------------------------------------------------------
 570 dnl Checks for header files.
 571 OL_HEADER_STDC
 572
 573 if test $ol_cv_header_stdc != yes; then
 574         AC_MSG_WARN([could not locate Standard C compliant headers])
 575 fi
 576
 577 AC_HEADER_DIRENT
 578 AC_HEADER_SYS_WAIT
 579 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 580 if test $am_cv_sys_posix_termios = yes ; then
 581         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 582                 [define if you have POSIX termios])
 583 fi
 584
 585 AC_CHECK_HEADERS(       \
 586         arpa/inet.h             \
 587         arpa/nameser.h  \
 588         assert.h                \
 589         conio.h                 \
 590         crypt.h                 \
 591         direct.h                \
 592         errno.h                 \
 593         fcntl.h                 \
 594         filio.h                 \
 595         getopt.h                \
 596         grp.h                   \
 597         io.h                    \
 598         libutil.h               \
 599         limits.h                \
 600         locale.h                \
 601         netinet/tcp.h   \
 602         malloc.h                \
 603         memory.h                \
 604         psap.h                  \
 605         pwd.h                   \
 606         process.h               \
 607         resolv.h                \
 608         sgtty.h                 \
 609         shadow.h                \
 610         stddef.h                \
 611         string.h                \
 612         strings.h               \
 613         sysexits.h              \
 614         sys/file.h              \
 615         sys/filio.h             \
 616         sys/errno.h             \
 617         sys/ioctl.h             \
 618         sys/param.h             \
 619         sys/resource.h  \
 620         sys/select.h    \
 621         sys/socket.h    \
 622         sys/syslog.h    \
 623         sys/time.h              \
 624         sys/types.h             \
 625         syslog.h                \
 626         termios.h               \
 627         unistd.h                \
 628         winsock.h               \
 629 )
 630
 631
 632 dnl ----------------------------------------------------------------
 633 dnl Checks for libraries
 634
 635 dnl HP-UX requires -lV3
 636 AC_CHECK_LIB(V3, sigset)
 637
 638 dnl Gotta check for winsock manually
 639 if test $ac_cv_header_winsock_h = yes; then
 640         AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 641         AC_TRY_LINK([#include <winsock.h>],[
 642                         socket(0,0,0);
 643                         select(0,NULL,NULL,NULL,NULL);
 644                         closesocket(0);
 645                         gethostname(NULL,0);
 646         ],[ol_cv_winsock=yes],[ol_cv_winsock=no])])
 647
 648         if test $ol_cv_winsock = yes ; then
 649                 AC_DEFINE(HAVE_WINSOCK,1,[define if you have winsock])
 650                 ac_cv_func_socket=yes
 651                 ac_cv_func_select=yes
 652                 ac_cv_func_closesocket=yes
 653                 ac_cv_func_gethostname=yes
 654         fi
 655 fi
 656
 657 dnl Find socket()
 658 dnl Likely combinations:
 659 dnl             -lsocket [ -lnsl_s | -lnsl ]
 660 dnl             -linet
 661
 662 AC_CHECK_FUNC(socket, :, [
 663 dnl hopefully we won't include too many libraries
 664         AC_CHECK_LIB(socket, main)
 665         AC_CHECK_LIB(net, main)
 666         AC_CHECK_LIB(nsl_s, main)
 667         AC_CHECK_LIB(nsl, main)
 668         AC_CHECK_LIB(inet, socket)
 669         AC_CHECK_LIB(gen, main)
 670 ])
 671
 672 dnl require select
 673 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 674
 675 if test "${ac_cv_header_winsock_h}" != yes; then
 676     dnl Select arg types
 677     dnl (if this detection becomes permenent, it and the select() detection
 678     dnl should be done before the yielding select test)
 679     AC_FUNC_SELECT_ARGTYPES
 680 fi
 681
 682 dnl check to see if system call automatically restart
 683 dnl AC_SYS_RESTARTABLE_SYSCALLS
 684
 685 dnl ----------------------------------------------------------------
 686 dnl require POSIX regex
 687 AC_CHECK_HEADERS( regex.h )
 688 if test "$ac_cv_header_regex_h" != yes ; then
 689         AC_MSG_ERROR([POSIX regex.h required.])
 690 fi
 691 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 692
 693 OL_POSIX_REGEX
 694 if test "$ol_cv_c_posix_regex" = no ; then
 695         AC_MSG_ERROR([broken POSIX regex!])
 696 fi
 697
 698 dnl ----------------------------------------------------------------
 699 dnl Check for resolver routines
 700 ol_link_dnssrv=no
 701 AC_CHECK_FUNC(res_query,:)
 702 if test $ac_cv_func_res_query = no ; then
 703         AC_CHECK_LIB(bind, res_query)
 704         ac_cv_func_res_query=$ac_cv_lib_bind_res_query
 705 fi
 706
 707 if test $ac_cv_func_res_query = no ; then
 708         AC_CHECK_LIB(bind, __res_query)
 709         ac_cv_func_res_query=$ac_cv_lib_bind___res_query
 710 fi
 711
 712 if test $ac_cv_func_res_query = no ; then
 713         AC_CHECK_LIB(resolv, res_query)
 714         ac_cv_func_res_query=$ac_cv_lib_resolv_res_query
 715 fi
 716
 717 if test "$ac_cv_func_res_query" = yes ; then
 718         AC_DEFINE(HAVE_RES_QUERY,1,
 719                 [define if you have res_query()])
 720
 721         if test $ol_enable_dnssrv != no ; then
 722                 ol_link_dnssrv=yes
 723         fi
 724 fi
 725
 726 if test "$ol_enable_dnssrv" = yes -a "$ol_link_dnssrv" = no ; then
 727         AC_MSG_ERROR([DNSSRV requires res_query()])
 728 fi
 729
 730 dnl ----------------------------------------------------------------
 731 dnl PF_INET6 support requires getaddrinfo and INET6_ADDRSTRLEN
 732 dnl PF_LOCAL may use getaddrinfo in available
 733 AC_CHECK_FUNCS( getaddrinfo )
 734
 735 ol_link_ipv6=no
 736 if test $ac_cv_func_getaddrinfo = no ; then
 737         if test $ol_enable_ipv6 = yes ; then
 738                 AC_MSG_ERROR([IPv6 support requires getaddrinfo()])
 739         fi
 740 else
 741         AC_CACHE_CHECK([INET6_ADDRSTRLEN],[ol_cv_inet6_addrstrlen],[
 742                 AC_EGREP_CPP(__has_inet6_addrstrlen__,[
 743 #                       include <netinet/in.h>
 744 #                       ifdef INET6_ADDRSTRLEN
 745                                 __has_inet6_addrstrlen__;
 746 #                       endif
 747                 ], [ol_cv_inet6_addrstrlen=yes], [ol_cv_inet6_addrstrlen=no])])
 748
 749         if test $ol_cv_inet6_addrstrlen = yes ; then
 750                 ol_link_ipv6=yes
 751         elif test $ol_enable_ipv6 = yes ; then
 752                 AC_MSG_ERROR([IPv6 support requires INET6_ADDRSTRLEN])
 753         fi
 754 fi
 755
 756 if test $ol_enable_local != no ; then
 757         AC_CHECK_HEADERS( sys/un.h )
 758
 759         if test $ol_enable_local = auto ; then
 760                 ol_enable_local=$ac_cv_header_sys_un_h
 761         elif test $ac_cv_header_sys_un_h = no ; then
 762                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
 763         fi
 764 fi
 765
 766 dnl ----------------------------------------------------------------
 767 dnl Kerberos
 768 ol_link_kbind=no
 769 ol_link_kpasswd=no
 770 ol_link_krb5=no
 771 ol_link_krb4=no
 772
 773 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
 774         -o $ol_with_kerberos = k5 -o $ol_with_kerberos = k5only \
 775         -o $ol_with_kerberos = k425 ; then
 776
 777         AC_CHECK_HEADERS(krb5.h)
 778
 779         if test $ac_cv_header_krb5_h = yes ; then
 780                 dnl lazy check for Heimdal Kerberos
 781                 AC_CHECK_HEADERS(heim_err.h)
 782                 if test $ac_cv_header_heim_err_h = yes ; then
 783                         krb5_impl=heimdal
 784                 else
 785                         krb5_impl=mit
 786                 fi
 787
 788                 if test $krb5_impl = mit; then
 789                         AC_CHECK_LIB(krb5, main,
 790                                 [have_krb5=yes
 791                                 KRB5_LIBS="-lkrb5 -lcrypto -lcom_err"],
 792                                 [have_krb5=no],
 793                                 [-lcrypto -lcom_err])
 794
 795                 elif test $krb5_impl = heimdal; then
 796                         AC_CHECK_LIB(krb5, main,
 797                                 [have_krb5=yes
 798                                 KRB5_LIBS="-lkrb5 -ldes -lasn1 -lroken -lcom_err"],
 799                                 [have_krb5=no],
 800                                 [-ldes -lasn1 -lroken -lcom_err])
 801
 802                         AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1,
 803                                 [define if you have HEIMDAL Kerberos])
 804                 else
 805                         have_krb5=no
 806                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 807                 fi
 808
 809                 if test $have_krb5 = yes ; then
 810                         ol_link_krb5=yes
 811
 812                         AC_DEFINE(HAVE_KRB5, 1,
 813                                 [define if you have Kerberos V])
 814
 815                         if test $ol_enable_kpasswd != no ; then
 816                                 ol_link_kpasswd=yes;
 817                         fi
 818
 819                         if test $ol_with_kerberos = k5only ; then
 820                                 ol_with_kerberos=found
 821                         fi
 822
 823                 elif test $ol_with_kerberos != auto ; then
 824                         AC_MSG_ERROR([Required Kerberos 5 support not available])
 825                 fi
 826
 827         fi
 828 fi
 829
 830 if test $ol_link_krb5 = yes -a \( $ol_with_kerberos = yes -o \
 831         $ol_with_kerberos = auto -o $ol_with_kerberos = k425 \) ; then
 832
 833         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 834
 835         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 836                 if test $krb5_impl = mit; then
 837                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 838                                 KRB4_LIBS="-lkrb4 -ldes425"], [have_k425=no],
 839                                 [-ldes425 -lkrb5 -lcrypto -lcom_err])
 840
 841                 elif test $krb5_impl = heimdal; then
 842                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 843                                 KRB4_LIBS="-lkrb4"], [have_k425=no],
 844                                 [-lkrb5 -ldes -lasn1 -lroken -lcom_err])
 845
 846                 else
 847                         have_425=no
 848                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 849                 fi
 850
 851                 if test $have_k425 = yes ; then
 852                         ol_with_kerberos=found
 853                         ol_link_krb4=yes
 854
 855                         AC_DEFINE(HAVE_KRB425, 1,
 856                                 [define if you have Kerberos V with IV support])
 857                         AC_DEFINE(HAVE_KRB4, 1,
 858                                 [define if you have Kerberos IV])
 859
 860                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 861                                 [ol_cv_var_des_debug], [
 862                                 dnl save the flags
 863                                 save_LIBS="$LIBS"
 864                                 LIBS="$KRB4_LIBS $KRB5_LIBS $LIBS"
 865                                 AC_TRY_LINK([
 866 #include <kerberosIV/krb.h>
 867 #include <kerberosIV/des.h>
 868 extern int des_debug;
 869 ],[
 870 des_debug = 1;
 871 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 872                                 dnl restore the LIBS
 873                                 LIBS="$save_LIBS"
 874                         ])
 875
 876                         if test $ol_cv_var_des_debug = yes ; then
 877                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 878                                         [define if you have Kerberos des_debug])
 879                         fi
 880
 881                         LIBS="$save_LIBS"
 882                 fi
 883         fi
 884 fi
 885
 886 if test $ol_link_krb5 = yes ; then
 887         ol_with_kerberos=found
 888 fi
 889
 890 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
 891         -o $ol_with_kerberos = k4 -o $ol_with_kerberos = kth ; then
 892
 893         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
 894
 895         if test $ac_cv_header_krb_h = yes ; then
 896                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 897
 898                 if test $have_k4 = yes ; then
 899                         ol_with_kerberos=found
 900                         ol_link_krb4=yes
 901
 902                         AC_DEFINE(HAVE_KRB4, 1,
 903                                 [define if you have Kerberos IV])
 904
 905                         KRB4_LIBS="-lkrb -ldes"
 906
 907                         if test $ac_cv_header_krb_archaeology_h = yes ; then
 908                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
 909                                         [define if you have Kth Kerberos])
 910                         fi
 911                 fi
 912         fi
 913 fi
 914
 915 if test $ol_link_krb4 = yes -a $ol_enable_kpasswd != no ; then
 916         ol_link_kpasswd=yes
 917 fi
 918
 919 if test $ol_link_krb4 = yes -a $ol_enable_kbind != no ; then
 920         ol_link_kbind=yes
 921
 922 elif test $ol_enable_kbind = yes ; then
 923         AC_MSG_ERROR([Kerberos IV detection failed])
 924 fi
 925
 926 if test $ol_link_krb4 = yes -o $ol_link_krb5 = yes ; then
 927         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 928
 929 elif test $ol_with_kerberos != auto -a $ol_with_kerberos != no ; then
 930         AC_MSG_ERROR([Kerberos detection failed])
 931 fi
 932
 933 dnl ----------------------------------------------------------------
 934 dnl TLS/SSL
 935 ol_link_tls=no
 936 if test $ol_with_tls != no ; then
 937         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 938
 939         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 940                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 941                         [have_ssleay=yes
 942                         need_rsaref=no],
 943                         [have_ssleay=no],
 944                         [-lcrypto])
 945
 946                 if test $have_ssleay = no ; then
 947                         AC_CHECK_LIB(ssl, SSL_library_init,
 948                                 [have_ssleay=yes
 949                                 need_rsaref=no], [have_ssleay=no],
 950                                 [-lcrypto])
 951                 fi
 952
 953                 if test $have_ssleay = no ; then
 954                         AC_CHECK_LIB(ssl, ssl3_accept,
 955                                 [have_ssleay=yes
 956                                 need_rsaref=yes], [have_ssleay=no],
 957                                 [-lcrypto -lRSAglue -lrsaref])
 958                 fi
 959
 960                 if test $have_ssleay = yes ; then
 961                         ol_with_tls=found
 962                         ol_link_tls=yes
 963
 964                         AC_DEFINE(HAVE_SSLEAY, 1,
 965                                 [define if you have SSLeay or OpenSSL])
 966
 967                         if test $need_rsaref = yes; then
 968                                 AC_DEFINE(HAVE_RSAREF, 1,
 969                                         [define if you have RSAref])
 970
 971                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 972                         else
 973                                 TLS_LIBS="-lssl -lcrypto"
 974                         fi
 975                 fi
 976         fi
 977
 978 else
 979         AC_WARN([TLS privacy protection not supported!])
 980 fi
 981
 982 if test $ol_link_tls = yes ; then
 983         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 984
 985 elif test $ol_with_tls = auto ; then
 986         AC_WARN([Could not locate TLS/SSL package])
 987         AC_WARN([TLS privacy protection not supported!])
 988
 989 elif test $ol_with_tls != no ; then
 990         AC_ERROR([Could not locate TLS/SSL package])
 991 fi
 992
 993 dnl ----------------------------------------------------------------
 994 dnl Tests for reentrant functions necessary to build a
 995 dnl thread_safe -lldap.
 996 AC_CHECK_FUNCS(         \
 997         ctime_r                 \
 998         gethostbyname_r gethostbyaddr_r \
 999 )
1000
1001 if test "$ac_cv_func_ctime_r" = no ; then
1002         ol_cv_func_ctime_r_nargs=0
1003 else
1004         OL_FUNC_CTIME_R_NARGS
1005 dnl     OL_FUNC_CTIME_R_TYPE
1006 fi
1007
1008 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1009         OL_FUNC_GETHOSTBYNAME_R_NARGS
1010 else
1011         ol_cv_func_gethostbyname_r_nargs=0
1012 fi
1013
1014 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1015         OL_FUNC_GETHOSTBYADDR_R_NARGS
1016 else
1017         ol_cv_func_gethostbyaddr_r_nargs=0
1018 fi
1019
1020 if test "$ac_cv_func_ctime_r" = yes \
1021         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
1022         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
1023         -a "$ac_cv_func_gethostbyname_r" = yes \
1024         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
1025         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
1026         -a "$ac_cv_func_gethostbyaddr_r" = yes \
1027         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
1028         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
1029         ; then
1030
1031         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
1032 fi
1033
1034 dnl ----------------------------------------------------------------
1035 dnl Threads?
1036 ol_link_threads=no
1037
1038 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1039         -o $ol_with_threads = nt ; then
1040
1041         OL_NT_THREADS
1042
1043         if test "$ol_cv_nt_threads" = yes ; then
1044         ol_link_threads=nt
1045         ol_with_threads=found
1046         ol_with_yielding_select=yes
1047
1048                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1049                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1050         fi
1051
1052         if test $ol_with_threads = nt ; then
1053                 AC_MSG_ERROR([could not locate NT Threads])
1054         fi
1055 fi
1056
1057 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1058         -o $ol_with_threads = posix ; then
1059
1060         AC_CHECK_HEADERS(pthread.h)
1061
1062         if test $ac_cv_header_pthread_h = yes ; then
1063                 OL_POSIX_THREAD_VERSION
1064
1065                 if test $ol_cv_pthread_version = final ; then
1066                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
1067                                 [define if pthreads API compatible with final spec])
1068                 elif test $ol_cv_pthread_version = draft4 ; then
1069                         AC_DEFINE(HAVE_PTHREADS_D4,1,
1070                                 [define if pthreads API compatible with draft4 spec])
1071                 else
1072                         AC_MSG_ERROR([unknown pthread version])
1073                 fi
1074
1075                 # consider threads found
1076                 ol_with_threads=found
1077
1078                 OL_HEADER_LINUX_THREADS
1079                 OL_HEADER_GNU_PTH_PTHREAD_H
1080
1081                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1082                         AC_CHECK_HEADERS(sched.h)
1083                 fi
1084
1085                 dnl Now the hard part, how to link?
1086                 dnl
1087                 dnl currently supported checks:
1088                 dnl
1089                 dnl Check for no flags
1090                 dnl     pthread_create() in $LIBS
1091                 dnl
1092                 dnl Check special pthread (final) flags
1093                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1094                 dnl     pthread_create() with -kthread (FreeBSD)
1095                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1096                 dnl     pthread_create() with -pthreads (?)
1097                 dnl     pthread_create() with -mthreads (AIX)
1098                 dnl     pthread_create() with -thread (?)
1099                 dnl
1100                 dnl Check pthread (final) libraries
1101                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1102                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1103                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1104                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1105                 dnl     pthread_create() in -lpthread (many)
1106                 dnl     pthread_create() in -lc_r (FreeBSD)
1107                 dnl
1108                 dnl Check pthread (draft4) flags (depreciated)
1109                 dnl     pthread_create() with -threads (OSF/1)
1110                 dnl
1111                 dnl Check pthread (draft4) libraries (depreciated)
1112                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1113                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1114                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1115                 dnl     pthread_create() in -lpthreads (many)
1116                 dnl
1117
1118                 dnl pthread_create in $LIBS
1119                 AC_CACHE_CHECK([for pthread_create in default libraries],
1120                         ol_cv_pthread_create,[
1121                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1122                         [ol_cv_pthread_create=yes],
1123                         [ol_cv_pthread_create=no],
1124                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1125                                 [ol_cv_pthread_create=yes],
1126                                 [ol_cv_pthread_create=no])])])
1127
1128                 if test $ol_cv_pthread_create != no ; then
1129                         ol_link_threads=posix
1130                         ol_link_pthreads=""
1131                 fi
1132
1133 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1134                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1135                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1136                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1137                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1138                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1139
1140                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1141                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1142                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1143                         [ol_cv_pthread_lpthread_lmach_lexc])
1144 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1145 dnl                     [ol_cv_pthread_lpthread_lexc])
1146
1147                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1148                         [ol_cv_pthread_lib_lpthread_woff])
1149
1150                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1151                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1152
1153                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1154
1155                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1156                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1157                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1158                         [ol_cv_pthread_lpthreads_lmach_lexc])
1159                 OL_PTHREAD_TRY([-lpthreads -lexc],
1160                         [ol_cv_pthread_lpthreads_lexc])
1161
1162                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1163
1164                 if test $ol_link_threads != no ; then
1165                         AC_DEFINE(HAVE_PTHREADS,1,
1166                                 [define if you have POSIX Threads])
1167
1168                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1169
1170                         dnl save flags
1171                         save_CPPFLAGS="$CPPFLAGS"
1172                         save_LIBS="$LIBS"
1173                         LIBS="$LTHREAD_LIBS $LIBS"
1174
1175                         dnl All POSIX Thread (final) implementations should have
1176                         dnl sched_yield instead of pthread yield.
1177                         dnl check for both
1178                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1179
1180                         if test $ac_cv_func_sched_yield = no -a \
1181                                 $ac_cv_func_pthread_yield = no ; then
1182                                 dnl Digital UNIX has sched_yield() in -lrt
1183                                 AC_CHECK_LIB(rt, sched_yield,
1184                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1185                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1186                                                 [Define if you have the sched_yield function.])
1187                                         ac_cv_func_sched_yield=yes],
1188                                         [ac_cv_func_sched_yield=no])
1189                         fi
1190                         if test $ac_cv_func_sched_yield = no -a \
1191                                 $ac_cv_func_pthread_yield = no ; then
1192                                 dnl Solaris has sched_yield() stub in -lposix4
1193                                 dnl but we'll use thr_yield instead.
1194                                 AC_CHECK_FUNCS(thr_yield)
1195                         fi
1196                         if test $ac_cv_func_sched_yield = no -a \
1197                                 $ac_cv_func_pthread_yield = no -a \
1198                                 "$ac_cv_func_thr_yield" = no ; then
1199                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1200                         fi
1201
1202                         dnl Check functions for compatibility
1203                         AC_CHECK_FUNCS(pthread_kill pthread_rwlock_destroy)
1204
1205                         dnl Check for pthread_detach with <pthread.h> inclusion
1206                         dnl as it's symbol may have been mangled.
1207                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1208                                 [ol_cv_func_pthread_detach], [
1209                                 dnl save the flags
1210                                 AC_TRY_LINK([
1211 #include <pthread.h>
1212 #ifndef NULL
1213 #define NULL (void*)0
1214 #endif
1215 ],
1216                                         [pthread_detach(NULL);],
1217                                         [ol_cv_func_pthread_detach=yes],
1218                                         [ol_cv_func_pthread_detach=no])
1219                         ])
1220
1221                         if test $ol_cv_func_pthread_detach = no ; then
1222                                 AC_MSG_ERROR([could not locate pthread_detach()])
1223                         fi
1224
1225                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1226                                 [define if you have pthread_detach function])
1227
1228                         dnl Check for setconcurreny functions
1229                         AC_CHECK_FUNCS( \
1230                                 pthread_setconcurrency \
1231                                 pthread_getconcurrency \
1232                                 thr_setconcurrency \
1233                                 thr_getconcurrency \
1234                         )
1235
1236                         OL_SYS_LINUX_THREADS
1237                         OL_LINUX_THREADS
1238
1239                         if test $ol_cv_linux_threads = error; then
1240                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1241                         fi
1242
1243                         AC_CACHE_CHECK([if pthread_create() works],
1244                                 ol_cv_pthread_create_works,[
1245                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1246                                 [ol_cv_pthread_create_works=yes],
1247                                 [ol_cv_pthread_create_works=no],
1248                                 [dnl assume yes
1249                                 ol_cv_pthread_create_works=yes])])
1250
1251                         if test $ol_cv_pthread_create_works = no ; then
1252                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1253                         fi
1254
1255                         dnl Check if select causes an yield
1256                         if test $ol_with_yielding_select = auto ; then
1257                                 AC_CACHE_CHECK([if select yields when using pthreads],
1258                                         ol_cv_pthread_select_yields,[
1259                                 AC_TRY_RUN([
1260 #include <sys/types.h>
1261 #include <sys/time.h>
1262 #include <unistd.h>
1263 #include <pthread.h>
1264 #ifndef NULL
1265 #define NULL (void*) 0
1266 #endif
1267
1268 static int fildes[2];
1269
1270 static void *task(p)
1271         void *p;
1272 {
1273         int i;
1274         struct timeval tv;
1275
1276         fd_set rfds;
1277
1278         tv.tv_sec=10;
1279         tv.tv_usec=0;
1280
1281         FD_ZERO(&rfds);
1282         FD_SET(fildes[0], &rfds);
1283
1284         /* we're not interested in any fds */
1285         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1286
1287         if(i < 0) {
1288                 perror("select");
1289                 exit(10);
1290         }
1291
1292         exit(0); /* if we exit here, the select blocked the whole process */
1293 }
1294
1295 int main(argc, argv)
1296         int argc;
1297         char **argv;
1298 {
1299         pthread_t t;
1300
1301         /* create a pipe to select */
1302         if(pipe(&fildes[0])) {
1303                 perror("select");
1304                 exit(1);
1305         }
1306
1307 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1308         (void) pthread_setconcurrency(2);
1309 #else
1310 #ifdef HAVE_THR_SETCONCURRENCY
1311         /* Set Solaris LWP concurrency to 2 */
1312         thr_setconcurrency(2);
1313 #endif
1314 #endif
1315
1316 #if HAVE_PTHREADS_D4
1317         pthread_create(&t, pthread_attr_default, task, NULL);
1318 #else
1319         pthread_create(&t, NULL, task, NULL);
1320 #endif
1321
1322 #if HAVE_SCHED_YIELD
1323         sched_yield();  /* make sure task runs first */
1324 #else
1325 #ifdef HAVE_PTHREAD_YIELD
1326         pthread_yield();        /* make sure task runs first */
1327 #endif
1328 #endif
1329
1330         exit(2);
1331 }],
1332                                 [ol_cv_pthread_select_yields=no],
1333                                 [ol_cv_pthread_select_yields=yes],
1334                                 [ol_cv_pthread_select_yields=cross])])
1335
1336                                 if test $ol_cv_pthread_select_yields = cross ; then
1337                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1338                                 fi
1339
1340                                 if test $ol_cv_pthread_select_yields = yes ; then
1341                                         ol_with_yielding_select=yes
1342                                 fi
1343                         fi
1344
1345                         dnl restore flags
1346                         CPPFLAGS="$save_CPPFLAGS"
1347                         LIBS="$save_LIBS"
1348                 else
1349                         AC_MSG_ERROR([could not link with POSIX Threads])
1350                 fi
1351         fi
1352
1353         if test $ol_with_threads = posix ; then
1354                 AC_MSG_ERROR([could not locate POSIX Threads])
1355         fi
1356 fi
1357
1358 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1359         -o $ol_with_threads = mach ; then
1360
1361         dnl check for Mach CThreads
1362         AC_CHECK_HEADERS(mach/cthreads.h)
1363         if test $ac_cv_header_mach_cthreads_h = yes ; then
1364                 ol_with_threads=found
1365
1366                 dnl check for cthread support in current $LIBS
1367                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1368
1369                 if test $ol_link_threads = no ; then
1370                         dnl try -all_load
1371                         dnl this test needs work
1372                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1373                                 [ol_cv_cthread_all_load], [
1374                                 dnl save the flags
1375                                 save_LIBS="$LIBS"
1376                                 LIBS="-all_load $LIBS"
1377                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1378                                         cthread_fork((void *)0, (void *)0);
1379                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1380                                 dnl restore the LIBS
1381                                 LIBS="$save_LIBS"
1382                         ])
1383
1384                         if test $ol_cv_cthread_all_load = yes ; then
1385                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1386                                 ol_link_threads=mach
1387                         fi
1388                 fi
1389
1390                 if test $ol_link_threads != no ; then
1391                         : check for cthread specific functionality here
1392                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1393                                 [define if you have Mach Cthreads])
1394                 else
1395                         AC_MSG_ERROR([could not link with Mach CThreads])
1396                 fi
1397         fi
1398
1399         if test $ol_with_threads = mach ; then
1400                 AC_MSG_ERROR([could not locate Mach CThreads])
1401         fi
1402 fi
1403
1404 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1405         -o $ol_with_threads = pth ; then
1406
1407         AC_CHECK_HEADERS(pth.h)
1408
1409         if test $ac_cv_header_pth_h = yes ; then
1410                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1411
1412                 if test $have_pth = yes ; then
1413                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1414                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1415                         ol_link_threads=pth
1416
1417                         if test $ol_with_yielding_select = auto ; then
1418                                 ol_with_yielding_select=yes
1419                         fi
1420                 fi
1421         fi
1422 fi
1423
1424 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1425         -o $ol_with_threads = lwp ; then
1426
1427         dnl check for SunOS5 LWP
1428         AC_CHECK_HEADERS(thread.h synch.h)
1429         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1430                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1431
1432                 if test $have_thr = yes ; then
1433                         AC_DEFINE(HAVE_THR,1,
1434                                 [if you have Solaris LWP (thr) package])
1435                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1436                         ol_link_threads=thr
1437
1438                         if test $ol_with_yielding_select = auto ; then
1439                                 ol_with_yielding_select=yes
1440                         fi
1441
1442                         dnl Check for setconcurreny functions
1443                         AC_CHECK_FUNCS( \
1444                                 thr_setconcurrency \
1445                                 thr_getconcurrency \
1446                         )
1447                 fi
1448         fi
1449
1450         dnl check for SunOS4 LWP
1451         AC_CHECK_HEADERS(lwp/lwp.h)
1452         if test $ac_cv_header_lwp_lwp_h = yes ; then
1453                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1454
1455                 if test $have_lwp = yes ; then
1456                         AC_DEFINE(HAVE_LWP,1,
1457                                 [if you have SunOS LWP package])
1458                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1459                         ol_link_threads=lwp
1460
1461                         if test $ol_with_yielding_select = auto ; then
1462                                 ol_with_yielding_select=no
1463                         fi
1464                 fi
1465         fi
1466 fi
1467
1468 if test $ol_with_yielding_select = yes ; then
1469         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1470                 [define if select implicitly yields])
1471 fi
1472
1473 if test $ol_with_threads = manual ; then
1474         dnl User thinks he can manually configure threads.
1475         ol_link_threads=yes
1476
1477         AC_MSG_WARN([thread defines and link options must be set manually])
1478
1479         AC_CHECK_HEADERS(pthread.h sched.h)
1480         AC_CHECK_FUNCS(sched_yield pthread_yield)
1481         OL_HEADER_LINUX_THREADS
1482
1483         AC_CHECK_HEADERS(mach/cthreads.h)
1484         AC_CHECK_HEADERS(lwp/lwp.h)
1485         AC_CHECK_HEADERS(thread.h synch.h)
1486 fi
1487
1488 if test $ol_link_threads != no -a $ol_link_threads != nt ; then
1489         dnl needed to get reentrant/threadsafe versions
1490         dnl
1491         AC_DEFINE(REENTRANT,1)
1492         AC_DEFINE(_REENTRANT,1)
1493         AC_DEFINE(THREAD_SAFE,1)
1494         AC_DEFINE(_THREAD_SAFE,1)
1495         AC_DEFINE(THREADSAFE,1)
1496         AC_DEFINE(_THREADSAFE,1)
1497         AC_DEFINE(_SGI_MP_SOURCE,1)
1498
1499         dnl The errno declaration may dependent upon _REENTRANT.
1500         dnl If it does, we must link with thread support.
1501         AC_CACHE_CHECK([for thread specific errno],
1502                 [ol_cv_errno_thread_specific], [
1503                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1504                         [ol_cv_errno_thread_specific=yes],
1505                         [ol_cv_errno_thread_specific=no])
1506         ])
1507
1508         dnl The h_errno declaration may dependent upon _REENTRANT.
1509         dnl If it does, we must link with thread support.
1510         AC_CACHE_CHECK([for thread specific h_errno],
1511                 [ol_cv_h_errno_thread_specific], [
1512                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1513                         [ol_cv_h_errno_thread_specific=yes],
1514                         [ol_cv_h_errno_thread_specific=no])
1515         ])
1516
1517         if test $ol_cv_errno_thread_specific != yes \
1518                 -o $ol_cv_h_errno_thread_specific != yes ; then
1519                 LIBS="$LTHREAD_LIBS $LIBS"
1520                 LTHREAD_LIBS=""
1521         fi
1522
1523 dnl When in thread environment, use
1524 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1525 dnl                     || defined( HAVE_FUNC_R )
1526 dnl                     func_r(...);
1527 dnl             #else
1528 dnl             #       if defined( HAVE_THREADS )
1529 dnl                             /* lock */
1530 dnl             #       endif
1531 dnl                             func(...);
1532 dnl             #       if defined( HAVE_THREADS )
1533 dnl                             /* unlock */
1534 dnl             #       endif
1535 dnl             #endif
1536 dnl
1537 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1538 dnl             _POSIX_REENTRANT_FUNCTIONS
1539 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1540 dnl             _POSIX_THREADSAFE_FUNCTIONS
1541 dnl
1542 dnl             and is currently defined in lthread.h
1543 dnl
1544 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1545 dnl
1546 dnl libldap/*.c should only include <lthread.h> iff
1547 dnl LDAP_R_COMPILE is defined.  ie:
1548 dnl             #ifdef LDAP_R_COMPILE
1549 dnl             #       include LDAP_R_COMPILE
1550 dnl             #endif
1551 dnl
1552 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1553 dnl specifically for compiling the threadsafe version of
1554 dnl     the ldap library (-lldap_r).
1555 dnl
1556 dnl     dnl check for reentrant/threadsafe functions
1557 dnl     dnl
1558 dnl     dnl note: these should only be used when linking
1559 dnl     dnl       with $LTHREAD_LIBS
1560 dnl     dnl
1561 dnl     save_CPPFLAGS="$CPPFLAGS"
1562 dnl     save_LIBS="$LIBS"
1563 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1564 dnl     AC_CHECK_FUNCS( \
1565 dnl             gmtime_r \
1566 dnl             gethostbyaddr_r gethostbyname_r \
1567 dnl             feof_unlocked unlocked_feof \
1568 dnl             putc_unlocked unlocked_putc \
1569 dnl             flockfile ftrylockfile \
1570 dnl     )
1571 dnl     CPPFLAGS="$save_CPPFLAGS"
1572 dnl     LIBS="$save_LIBS"
1573 fi
1574
1575 if test $ol_link_threads = no ; then
1576         if test $ol_with_threads = yes ; then
1577                 AC_MSG_ERROR([no suitable thread support])
1578         fi
1579
1580         if test $ol_with_threads = auto ; then
1581                 AC_MSG_WARN([no suitable thread support, disabling threads])
1582                 ol_with_threads=no
1583         fi
1584
1585         AC_DEFINE(NO_THREADS,1,
1586                 [define if you have (or want) no threads])
1587         LTHREAD_LIBS=""
1588 fi
1589
1590 if test $ol_link_threads != no ; then
1591         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1592 fi
1593
1594 dnl ----------------------------------------------------------------
1595 ol_link_ldbm=no
1596
1597 if test $ol_with_ldbm_api = auto \
1598         -o $ol_with_ldbm_api = berkeley \
1599         -o $ol_with_ldbm_api = bcompat ; then
1600
1601         if test $ol_with_ldbm_api = bcompat; then \
1602                 OL_BERKELEY_COMPAT_DB
1603         else
1604                 OL_BERKELEY_DB
1605         fi
1606
1607         if test $ol_cv_berkeley_db != no ; then
1608                 AC_DEFINE(HAVE_BERKELEY_DB,1,
1609                         [define this if Berkeley DB is available])
1610
1611                 ol_link_ldbm=berkeley
1612                 ol_with_ldbm_api=db
1613
1614                 if test $ol_with_ldbm_type = hash ; then
1615                         AC_DEFINE(LDBM_USE_DBHASH,1,
1616                                 [define this to use DBHASH w/ LDBM backend])
1617                 else
1618                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1619                                 [define this to use DBBTREE w/ LDBM backend])
1620                 fi
1621
1622                 dnl $ol_cv_lib_db should be yes or -ldb
1623                 dnl (it could be no, but that would be an error
1624                 if test $ol_cv_lib_db != yes ; then
1625                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1626                 fi
1627         fi
1628 fi
1629
1630 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1631         AC_MSG_WARN(Could not find LDBM with BTREE support)
1632         ol_with_ldbm_api=none
1633 fi
1634
1635 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1636         OL_MDBM
1637
1638         if test $ol_cv_mdbm = yes ; then
1639                 ol_link_ldbm=mdbm
1640                 ol_with_ldbm_api=mdbm
1641                 if test $ol_cv_lib_mdbm != yes ; then
1642                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1643                 fi
1644         fi
1645 fi
1646
1647 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1648         OL_GDBM
1649
1650         if test $ol_cv_gdbm = yes ; then
1651                 ol_link_ldbm=gdbm
1652                 ol_with_ldbm_api=gdbm
1653
1654                 if test $ol_cv_lib_gdbm != yes ; then
1655                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1656                 fi
1657         fi
1658 fi
1659
1660 if test $ol_with_ldbm_api = ndbm ; then
1661         OL_NDBM
1662
1663         if test $ol_cv_ndbm = yes ; then
1664                 ol_link_ldbm=ndbm
1665                 ol_with_ldbm_api=ndbm
1666
1667                 if test $ol_cv_lib_ndbm != yes ; then
1668                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1669                 fi
1670         fi
1671 fi
1672
1673 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1674         AC_MSG_WARN(could not find suitable LDBM backend)
1675         if test $ol_enable_ldbm = yes ; then
1676                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1677         fi
1678
1679         AC_MSG_WARN(disabling LDBM)
1680         ol_enable_ldbm=no
1681 fi
1682
1683 dnl ----------------------------------------------------------------
1684 if test $ol_enable_dynamic = yes -a $enable_shared = yes ; then
1685         LINK_BINS_DYNAMIC="yes"
1686 else
1687         LINK_BINS_DYNAMIC="no"
1688 fi
1689
1690 dnl ----------------------------------------------------------------
1691 if test $ol_enable_wrappers != no ; then
1692         AC_CHECK_HEADERS(tcpd.h)
1693
1694         if test $ac_cv_header_tcpd_h != yes ; then
1695                 have_wrappers=no
1696         else
1697                 AC_TRY_COMPILE([
1698 int allow_severity = 0;
1699 int deny_severity  = 0;
1700                 ],[hosts_access()],[have_wrappers=yes],[have_wrappers=no])
1701         fi
1702
1703         if test $have_wrappers = yes ; then
1704                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1705                 WRAP_LIBS="-lwrap"
1706
1707                 dnl We add another check for -lnsl since some libwrap's
1708                 dnl need it, but it isn't always included from above
1709                 AC_CHECK_LIB(nsl, main)
1710         else
1711                 AC_MSG_WARN(could not find -lwrap)
1712                 if test $ol_enable_wrappers = yes ; then
1713                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1714                 fi
1715
1716                 AC_MSG_WARN(disabling wrappers support)
1717                 ol_enable_wrappers=no
1718                 WRAP_LIBS=""
1719         fi
1720 fi
1721
1722 dnl ----------------------------------------------------------------
1723 if test $ol_enable_syslog != no ; then
1724         AC_CHECK_FUNC(openlog)
1725         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1726                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1727         fi
1728         ol_enable_syslog=$ac_cv_func_openlog
1729 fi
1730
1731 dnl ----------------------------------------------------------------
1732 dnl SQL
1733 ol_link_sql=no
1734 if test $ol_enable_sql != no ; then
1735         AC_CHECK_LIB(iodbc,SQLDriverConnect,[have_iodbc=yes],[have_iodbc=no])
1736         if test $have_iodbc = yes ; then
1737                 ol_link_sql="-liodbc"
1738         else
1739                 AC_CHECK_LIB(odbc,SQLDriverConnect,[have_odbc=yes],[have_odbc=no])
1740                 if test $have_odbc = yes ; then
1741                         ol_link_sql="-lodbc"
1742                 fi
1743         fi
1744
1745         if test $ol_link_sql != no ; then
1746                 SLAPD_SQL_LIBS="$ol_link_sql"
1747
1748         elif test $ol_enable_sql != auto ; then
1749                 AC_MSG_ERROR([could not locate suitable ODBC library])
1750         fi
1751 fi
1752
1753 dnl ----------------------------------------------------------------
1754 dnl ud needs termcap (should insert check here)
1755 ol_link_termcap=no
1756 AC_CHECK_HEADERS(termcap.h ncurses.h)
1757
1758 if test $ol_link_termcap = no ; then
1759         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1760         if test $have_termcap = yes ; then
1761                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1762                 ol_link_termcap=yes
1763                 TERMCAP_LIBS=-ltermcap
1764         fi
1765 fi
1766
1767 if test $ol_link_termcap = no ; then
1768         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1769         if test $have_ncurses = yes ; then
1770                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1771                 ol_link_termcap=yes
1772                 TERMCAP_LIBS=-lncurses
1773         fi
1774 fi
1775
1776 if test $ol_link_termcap = no ; then
1777         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1778         TERMCAP_LIBS=
1779 fi
1780
1781 dnl ----------------------------------------------------------------
1782 dnl
1783 dnl Check for Cyrus SASL
1784 dnl
1785 ol_link_sasl=no
1786 ol_link_spasswd=no
1787 if test $ol_with_cyrus_sasl != no ; then
1788         AC_CHECK_HEADERS(sasl.h)
1789
1790         if test $ac_cv_header_sasl_h = yes ; then
1791                 AC_CHECK_LIB(sasl, sasl_client_init,
1792                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1793
1794                 if test $have_cyrus_sasl != no ; then
1795                         SASL_LIBS="-lsasl"
1796                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1797                         ol_link_sasl=yes
1798                 fi
1799         fi
1800
1801         if test $ol_link_sasl = no ; then
1802                 if test $ol_with_cyrus_sasl != auto ; then
1803                         AC_MSG_ERROR([Could not locate Cyrus SASL])
1804                 else
1805                         AC_MSG_WARN([Could not locate Cyrus SASL])
1806                         AC_MSG_WARN([SASL authentication not supported!])
1807                         if test $ol_link_tls = no ; then
1808                                 AC_MSG_WARN([Strong authentication not supported!])
1809                         fi
1810                 fi
1811
1812         elif test $ol_enable_spasswd != no ; then
1813                 ol_link_spasswd=yes
1814         fi
1815
1816 else
1817         AC_MSG_WARN([SASL authentication not supported!])
1818         if test $ol_link_tls = no ; then
1819                 AC_MSG_WARN([Strong authentication not supported!])
1820         fi
1821 fi
1822
1823 dnl ----------------------------------------------------------------
1824 dnl Check for entropy sources
1825 if test $cross_compiling != yes ; then
1826         dev=no
1827         if test -r /dev/urandom ; then
1828                 dev="/dev/urandom";
1829         elif test -r /idev/urandom ; then
1830                 dev="/idev/urandom";
1831         elif test -r /dev/srandom ; then
1832                 dev="/dev/srandom";
1833         elif test -r /dev/random ; then
1834                 dev="/dev/random";
1835         elif test -r /idev/random ; then
1836                 dev="/idev/random";
1837         fi
1838
1839         if test $dev != no ; then
1840                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
1841         fi
1842 fi
1843
1844 dnl ----------------------------------------------------------------
1845 dnl
1846 dnl Check for fetch URL support
1847 dnl             should be extended to support other fetch URL APIs
1848 dnl
1849 ol_link_fetch=no
1850 if test $ol_with_fetch != no ; then
1851         OL_LIB_FETCH
1852
1853         if test $ol_cv_lib_fetch != no ; then
1854                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1855                 ol_link_fetch=freebsd
1856
1857         elif test $ol_with_fetch != auto ; then
1858                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1859         fi
1860 fi
1861
1862 dnl ----------------------------------------------------------------
1863 dnl
1864 dnl Check for GNU readline
1865 dnl
1866 ol_link_readline=no
1867 if test $ol_with_readline != no ; then
1868         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1869
1870         if test $ac_cv_header_readline_readline_h = yes ; then
1871                 save_LIBS="$LIBS"
1872                 LIBS="$TERMCAP_LIBS $LIBS"
1873                 AC_CHECK_LIB(readline, readline,
1874                         [have_readline=yes], [have_readline=no])
1875                 LIBS="$save_LIBS"
1876
1877                 if test $have_readline = yes ; then
1878                         ol_with_readline=found
1879                         ol_link_readline=yes
1880
1881                         READLINE_LIBS="-lreadline"
1882                 fi
1883         fi
1884 fi
1885
1886 if test $ol_link_readline = yes ; then
1887         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1888 fi
1889
1890
1891 dnl ----------------------------------------------------------------
1892 dnl FreeBSD (and others) have crypt(3) in -lcrypt
1893 if test $ol_enable_crypt != no ; then
1894         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1895                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1896                         have_crypt=yes], [have_crypt=no])])
1897
1898         if test $have_crypt = yes ; then
1899                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1900         else
1901                 AC_MSG_WARN(could not find crypt)
1902                 if test $ol_enable_crypt = yes ; then
1903                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1904                 fi
1905
1906                 AC_MSG_WARN(disabling crypt support)
1907                 ol_enable_crypt=no
1908         fi
1909 fi
1910
1911 dnl ----------------------------------------------------------------
1912 dnl FreeBSD (and others) have setproctitle(3) in -lutil
1913 if test $ol_enable_proctitle != no ; then
1914         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1915                 AC_CHECK_LIB(util, setproctitle,
1916                         [have_setproctitle=yes
1917                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1918                         [have_setproctitle=no
1919                         LIBOBJS="$LIBOBJS setproctitle.o"
1920                         LIBSRCS="$LIBSRCS setproctitle.c"])])
1921
1922         if test $have_setproctitle = yes ; then
1923                 AC_DEFINE(HAVE_SETPROCTITLE,1,
1924                         [define if setproctitle(3) is available])
1925         fi
1926 fi
1927
1928 dnl ----------------------------------------------------------------
1929 dnl Checks for typedefs, structures, and compiler characteristics.
1930 AC_TYPE_MODE_T
1931 AC_TYPE_OFF_T
1932 AC_TYPE_PID_T
1933 AM_TYPE_PTRDIFF_T
1934 AC_TYPE_SIGNAL
1935 AC_TYPE_SIZE_T
1936
1937 AC_CHECK_TYPE(ssize_t, [signed int])
1938 AC_CHECK_TYPE(caddr_t,  [char *])
1939
1940 OL_TYPE_SOCKLEN_T
1941 AC_STRUCT_ST_BLKSIZE
1942 AC_HEADER_TIME
1943 AC_STRUCT_TM
1944 AC_TYPE_UID_T
1945 OL_TYPE_SIG_ATOMIC_T
1946
1947 dnl AC_TYPE_GETGROUPS
1948
1949 OL_STRUCT_PASSWD_PW_GECOS
1950 OL_STRUCT_PASSWD_PW_PASSWD
1951
1952 OL_C_UPPER_LOWER
1953 AC_C_CONST
1954 OL_C_VOLATILE
1955
1956 if test $cross_compiling = yes ; then
1957         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1958 else
1959         AC_C_BIGENDIAN
1960 fi
1961
1962 AC_COMPILE_CHECK_SIZEOF(short)
1963 AC_COMPILE_CHECK_SIZEOF(int)
1964 AC_COMPILE_CHECK_SIZEOF(long)
1965
1966 if test "$ac_cv_sizeof_int" -lt 4 ; then
1967         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
1968
1969         AC_DEFINE(LBER_INT_T,long)
1970 else
1971         AC_DEFINE(LBER_INT_T,int)
1972 fi
1973
1974 AC_DEFINE(LBER_LEN_T,long)
1975 AC_DEFINE(LBER_SOCKET_T,int)
1976 AC_DEFINE(LBER_TAG_T,long)
1977
1978 dnl ----------------------------------------------------------------
1979 dnl Checks for library functions.
1980 AC_FUNC_MEMCMP
1981 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1982 AC_FUNC_STRFTIME
1983 dnl AM_FUNC_STRTOD
1984
1985 OL_FUNC_INET_ATON
1986
1987 dnl Check for NT specific routines
1988 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
1989
1990 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
1991         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
1992 ])
1993
1994 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
1995         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
1996 ])
1997
1998 AC_FUNC_VPRINTF
1999
2000 if test $ac_cv_func_vprintf = yes ; then
2001         dnl check for vsnprintf
2002         AC_CHECK_FUNCS(vsnprintf vsprintf)
2003 fi
2004
2005 AC_CHECK_FUNCS(         \
2006         bcopy                   \
2007         closesocket             \
2008         chroot                  \
2009         endgrent                \
2010         endpwent                \
2011         flock                   \
2012         getdtablesize   \
2013         getgrgid                \
2014         gethostname             \
2015         getpass                 \
2016         getpassphrase   \
2017         getpwuid                \
2018         getpwnam                \
2019         getspnam                \
2020         gettimeofday    \
2021         initgroups              \
2022         lockf                   \
2023         memcpy                  \
2024         memmove                 \
2025         mkstemp                 \
2026         pipe                    \
2027         read                    \
2028         recv                    \
2029         recvfrom                \
2030         setpwfile               \
2031         setgid                  \
2032         setegid                 \
2033         setsid                  \
2034         setuid                  \
2035         seteuid                 \
2036         sigaction               \
2037         signal                  \
2038         sigset                  \
2039         snprintf                \
2040         strdup                  \
2041         strerror                \
2042         strpbrk                 \
2043         strrchr                 \
2044         strsep                  \
2045         strstr                  \
2046         strtol                  \
2047         strtoul                 \
2048         strspn                  \
2049         sysconf                 \
2050         waitpid                 \
2051         wait4                   \
2052         write                   \
2053         send                    \
2054         sendto                  \
2055 )
2056
2057 dnl We actually may need to replace more than this.
2058 AC_REPLACE_FUNCS(getopt tempnam)
2059
2060 if test "$ac_cv_func_getopt" != yes; then
2061     LIBSRCS="$LIBSRCS getopt.c"
2062 fi
2063
2064 if test "$ac_cv_func_tempnam" != yes; then
2065     LIBSRCS="$LIBSRCS tempnam.c"
2066 fi
2067
2068 dnl ----------------------------------------------------------------
2069 # Check Configuration
2070 OL_SYS_ERRLIST
2071
2072 dnl ----------------------------------------------------------------
2073 dnl Sort out defines
2074
2075 if test "$ol_enable_debug" != no ; then
2076         AC_DEFINE(LDAP_DEBUG,1,
2077                 [define this to add debugging code])
2078 fi
2079 if test "$ol_enable_syslog" = yes ; then
2080         AC_DEFINE(LDAP_SYSLOG,1,
2081                 [define this to add syslog code])
2082 fi
2083 if test "$ol_enable_libui" = yes ; then
2084         AC_DEFINE(LDAP_LIBUI,1,
2085                 [define this for LDAP User Interface support])
2086 fi
2087 if test "$ol_enable_cache" = no ; then
2088         AC_DEFINE(LDAP_NOCACHE,1,
2089                 [define this to remove -lldap cache support])
2090 fi
2091 if test "$ol_link_kbind" != no ; then
2092         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_KBIND,LDAP_VENDOR_VERSION)
2093 fi
2094 if test "$ol_enable_proctitle" != no ; then
2095         AC_DEFINE(LDAP_PROCTITLE,1,
2096                 [define this for LDAP process title support])
2097 fi
2098 if test "$ol_enable_referrals" != no ; then
2099         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
2100 fi
2101 if test "$ol_enable_local" != no; then
2102         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2103 fi
2104 if test "$ol_link_ipv6" != no; then
2105         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2106 fi
2107 if test "$ol_enable_cleartext" != no ; then
2108         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2109 fi
2110 if test "$ol_enable_crypt" != no ; then
2111         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2112 fi
2113 if test "$ol_link_kpasswd" != no ; then
2114         AC_DEFINE(SLAPD_KPASSWD,1,[define to support Kerberos passwords])
2115 fi
2116 if test "$ol_link_spasswd" != no ; then
2117         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2118 fi
2119 if test "$ol_enable_multimaster" != no ; then
2120         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2121 fi
2122 if test "$ol_enable_phonetic" != no ; then
2123         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
2124 fi
2125 if test "$ol_enable_rlookups" != no ; then
2126         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2127 fi
2128 if test "$ol_enable_aci" != no ; then
2129         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2130 fi
2131
2132 if test "$ol_link_modules" != no ; then
2133         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2134         BUILD_SLAPD=yes
2135         SLAPD_MODULES_LDFLAGS="-dlopen self"
2136 fi
2137
2138 if test "$ol_link_dnssrv" != no ; then
2139         AC_DEFINE(SLAPD_DNSSRV,1,[define to support DNS SRV backend])
2140         BUILD_SLAPD=yes
2141         BUILD_DNSSRV=yes
2142         if test "$ol_with_dnssrv_module" != static ; then
2143                 AC_DEFINE(SLAPD_DNSSRV_DYNAMIC,1,
2144                         [define to support dynamic DNS SRV backend])
2145                 BUILD_DNSSRV=mod
2146                 BUILD_DNSSRV_DYNAMIC=shared
2147                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-dnssrv/back_dnssrv.la"
2148         fi
2149 fi
2150
2151 if test "$ol_enable_ldap" != no ; then
2152         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
2153         BUILD_SLAPD=yes
2154         BUILD_LDAP=yes
2155         if test "$ol_with_ldap_module" != static ; then
2156                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
2157                         [define to support dynamic LDAP backend])
2158                 BUILD_LDAP=mod
2159                 BUILD_LDAP_DYNAMIC=shared
2160                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
2161         fi
2162 fi
2163
2164 if test "$ol_link_ldbm" != no ; then
2165         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
2166         BUILD_SLAPD=yes
2167         BUILD_LDBM=yes
2168         if test "$ol_with_ldbm_module" != static ; then
2169                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
2170                         [define to support dynamic LDBM backend])
2171                 BUILD_LDBM=mod
2172                 BUILD_LDBM_DYNAMIC=shared
2173                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
2174         fi
2175 fi
2176
2177 if test "$ol_enable_passwd" != no ; then
2178         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2179         BUILD_SLAPD=yes
2180         BUILD_PASSWD=yes
2181         if test "$ol_with_passwd_module" != static ; then
2182                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2183                         [define to support dynamic PASSWD backend])
2184                 BUILD_PASSWD=mod
2185                 BUILD_PASSWD_DYNAMIC=shared
2186                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
2187         fi
2188 fi
2189
2190 if test "$ol_enable_shell" != no ; then
2191         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2192         BUILD_SLAPD=yes
2193         BUILD_SHELL=yes
2194         if test "$ol_with_shell_module" != static ; then
2195                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2196                         [define to support dynamic SHELL backend])
2197                 BUILD_SHELL=mod
2198                 BUILD_SHELL_DYNAMIC=shared
2199                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2200         fi
2201 fi
2202
2203 if test "$ol_enable_sql" != no ; then
2204         AC_DEFINE(SLAPD_SQL,1,[define to support SQL backend])
2205         BUILD_SLAPD=yes
2206         BUILD_SQL=yes
2207         if test "$ol_with_sql_module" != static; then
2208                 AC_DEFINE(SLAPD_SQL_DYNAMIC,1,
2209                         [define to support dynamic SQL backend])
2210                 BUILD_SQL=mod
2211                 BUILD_SQL_DYNAMIC=shared
2212                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-sql/back_sql.la"
2213         fi
2214 fi
2215
2216 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2217         $BUILD_SLAPD = yes ; then
2218         BUILD_SLURPD=yes
2219 fi
2220
2221 dnl ----------------------------------------------------------------
2222
2223 if test "$LINK_BINS_DYNAMIC" = yes; then
2224     LIB_LINKAGE=DYN
2225     LT_LIB_LINKAGE=shared
2226 else
2227     LIB_LINKAGE=STAT
2228     LT_LIB_LINKAGE=static
2229 fi
2230
2231 if test "$ac_cv_mingw32" = yes ; then
2232     PLAT=NT
2233     DYN_EXT=dll
2234 else
2235     PLAT=UNIX
2236     DYN_EXT=so
2237 fi
2238
2239 AC_SUBST(LIBSRCS)
2240
2241 AC_SUBST(PLAT)
2242 AC_SUBST(LIB_LINKAGE)
2243 AC_SUBST(LT_LIB_LINKAGE)
2244 AC_SUBST(DYN_EXT)
2245
2246 AC_SUBST(BUILD_SLAPD)
2247   AC_SUBST(BUILD_DNSSRV)
2248   AC_SUBST(BUILD_LDAP)
2249   AC_SUBST(BUILD_LDBM)
2250   AC_SUBST(BUILD_PASSWD)
2251   AC_SUBST(BUILD_SHELL)
2252   AC_SUBST(BUILD_SQL)
2253   AC_SUBST(BUILD_DNSSRV_DYNAMIC)
2254   AC_SUBST(BUILD_LDAP_DYNAMIC)
2255   AC_SUBST(BUILD_LDBM_DYNAMIC)
2256   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2257   AC_SUBST(BUILD_SHELL_DYNAMIC)
2258   AC_SUBST(BUILD_SQL_DYNAMIC)
2259 AC_SUBST(BUILD_SLURPD)
2260
2261 AC_SUBST(LDAP_LIBS)
2262 AC_SUBST(LDIF_LIBS)
2263 AC_SUBST(SLAPD_LIBS)
2264 AC_SUBST(SLURPD_LIBS)
2265 AC_SUBST(LDBM_LIBS)
2266 AC_SUBST(LTHREAD_LIBS)
2267 AC_SUBST(LUTIL_LIBS)
2268 AC_SUBST(WRAP_LIBS)
2269 AC_SUBST(LINK_BINS_DYNAMIC)
2270
2271 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2272 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2273 AC_SUBST(SLAPD_MODULES_LIST)
2274
2275 AC_SUBST(KRB4_LIBS)
2276 AC_SUBST(KRB5_LIBS)
2277 AC_SUBST(READLINE_LIBS)
2278 AC_SUBST(SASL_LIBS)
2279 AC_SUBST(TERMCAP_LIBS)
2280 AC_SUBST(TLS_LIBS)
2281 AC_SUBST(MODULES_LIBS)
2282 AC_SUBST(AUTH_LIBS)
2283
2284 AC_SUBST(SLAPD_SQL_LDFLAGS)
2285 AC_SUBST(SLAPD_SQL_LIBS)
2286 AC_SUBST(SLAPD_SQL_INCLUDES)
2287
2288 dnl ----------------------------------------------------------------
2289 dnl final output
2290 dnl
2291
2292 AC_OUTPUT( \
2293 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2294 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2295 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2296 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2297 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2298 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2299 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2300 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2301 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2302 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2303 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2304 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2305 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2306 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2307 clients/maildap/Makefile:build/top.mk:clients/maildap/Makefile.in:build/rules.mk \
2308 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2309 include/Makefile:build/top.mk:include/Makefile.in \
2310 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2311 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2312 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2313 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2314 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2315 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2316 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2317 libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk  \
2318 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2319 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2320 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2321 servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk \
2322 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2323 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2324 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2325 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2326 servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk \
2327 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2328 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2329 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2330 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2331 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2332 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2333 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2334 ,[
2335 date > stamp-h
2336 echo Please \"make depend\" to build dependencies
2337 ])