git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998-2001 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms, with or without
   6 dnl modification, are permitted only as authorized by the OpenLDAP
   7 dnl Public License.  A copy of this license is available at
   8 dnl http://www.OpenLDAP.org/license.html or in file LICENSE in the
   9 dnl top-level directory of the distribution.
  10 dnl
  11 dnl ----------------------------------------------------------------
  12 dnl Redefine AC_INIT_BINSH to provide RCS IDs and copyright notice
  13 dnl at top of generated configure script.  Prints simple copyright.
  14 define([AC_INIT_BINSH],
  15 [[#! /bin/sh
  16 # $]OpenLDAP[$
  17 # from] translit([$OpenLDAP$], $")] [
  18
  19 # Copyright 1998-2001 The OpenLDAP Foundation.  All Rights Reserved.
  20 #
  21 # Redistribution and use in source and binary forms, with or without
  22 # modification, are permitted only as authorized by the OpenLDAP
  23 # Public License.  A copy of this license is available at
  24 # http://www.OpenLDAP.org/license.html or in file LICENSE in the
  25 # top-level directory of the distribution.
  26
  27 echo "Copyright 1998-2001 The OpenLDAP Foundation,  All Rights Reserved."
  28 echo "Restrictions apply, see COPYRIGHT and LICENSE files."
  29 ])dnl
  30 dnl ----------------------------------------------------------------
  31 dnl Disable config.cache!
  32 define([AC_CACHE_LOAD], )dnl
  33 define([AC_CACHE_SAVE], )dnl
  34 dnl ================================================================
  35 dnl Configure.in for OpenLDAP
  36 AC_INIT(build/version)dnl
  37
  38 # set unset (borrowed from autoconf 2.49c)
  39 if (OL_FOO=OL_FOO; unset OL_FOO) >/dev/null 2>&1; then
  40   ol_unset=unset
  41 else
  42   ol_unset=false
  43 fi
  44 # unset CDPATH
  45 $ol_unset CDPATH || test "${CDPATH+set}" != set || { CDPATH=:; export CDPATH; }
  46
  47 AC_CONFIG_AUX_DIR(build)dnl
  48
  49 OL_VERSION=`cat $ac_aux_dir/version`
  50 if test -z "$OL_VERSION"; then
  51         AC_MSG_ERROR([could not determine version])
  52 fi
  53
  54 echo "Configuring OpenLDAP $OL_VERSION ..."
  55
  56 dnl Determine host platform
  57 dnl             we try not to use this for much
  58 AC_CANONICAL_SYSTEM
  59
  60 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  61 AC_SUBST(PACKAGE)dnl
  62 AC_SUBST(VERSION)dnl
  63 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  64 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  65
  66 dnl We use autoconf features new to 2.13.
  67 dnl aclocal.m4 should be built using aclocal from automake 1.4
  68 dnl libtool 1.3.3 should be installed.
  69 AC_PREREQ(2.13)dnl Required Autoconf version
  70
  71 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  72
  73 dnl ================================================================
  74 dnl Start Args
  75 AC_MSG_CHECKING(configure arguments)
  76 AC_PREFIX_DEFAULT(/usr/local)
  77
  78 top_builddir=`pwd`
  79 AC_SUBST(top_builddir)dnl
  80
  81 dnl ----------------------------------------------------------------
  82 dnl --with-subdir
  83 ldap_subdir="/openldap"
  84
  85 AC_ARG_WITH(subdir,
  86 [  --with-subdir=DIR      change default subdirectory used for installs],
  87 [case "$withval" in
  88         no) ldap_subdir=""
  89                 ;;
  90         yes)
  91                 ;;
  92         /*|\\*)
  93                 ldap_subdir="$withval"
  94                 ;;
  95         *)
  96                 ldap_subdir="/$withval"
  97                 ;;
  98 esac
  99 ])dnl
 100
 101 AC_SUBST(ldap_subdir)dnl
 102
 103 dnl ----------------------------------------------------------------
 104 dnl General "enable" options
 105 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes)dnl
 106 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 107 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 108 OL_ARG_ENABLE(cache,[  --enable-cache     enable caching], yes)dnl
 109 OL_ARG_ENABLE(referrals,[  --enable-referrals     enable V2 Referrals extension], yes)dnl
 110 OL_ARG_ENABLE(kbind,[  --enable-kbind     enable V2 Kerberos IV bind], no)dnl
 111 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 112 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 113 OL_ARG_ENABLE(x_compile,[  --enable-x-compile     enable cross compiling],
 114         no, [yes no])dnl
 115
 116 dnl ----------------------------------------------------------------
 117 dnl General "with" options
 118 dnl OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc     enable debug malloc support], no)dnl
 119
 120 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 121         auto, [auto yes no] )
 122 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch URL support],
 123         auto, [auto yes no] )
 124 OL_ARG_WITH(kerberos,[  --with-kerberos   with support],
 125         auto, [auto k5 k5only k425 kth k4 afs yes no])
 126 OL_ARG_WITH(readline,[  --with-readline   with readline support],
 127         auto, [auto yes no] )
 128 OL_ARG_WITH(threads,[  --with-threads     with threads],
 129         auto, [auto nt posix mach pth lwp yes no manual] )
 130 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support],
 131         auto, [auto ssleay openssl yes no] )
 132 OL_ARG_WITH(yielding_select,[  --with-yielding-select  with implicitly yielding select],
 133         auto, [auto yes no manual] )
 134
 135 dnl ----------------------------------------------------------------
 136 dnl Server options
 137 dnl ----------------------------------------------------------------
 138
 139 dnl ----------------------------------------------------------------
 140 dnl SLAPD OPTIONS
 141 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 142 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 143 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 144 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], auto)dnl
 145 OL_ARG_ENABLE(kpasswd,[    --enable-kpasswd       enable kerberos password verification], no)dnl
 146 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 147 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 148 dnl OL_ARG_ENABLE(multimaster,[    --enable-multimaster  enable multimaster replication], no)dnl
 149 OL_ARG_ENABLE(phonetic,[    --enable-phonetic     enable phonetic/soundex], no)dnl
 150 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups], no)dnl
 151 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs], no)dnl
 152 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 153 OL_ARG_ENABLE(dynamic,[    --enable-dynamic       enable linking built binaries with dynamic libs], no)dnl
 154
 155 dnl SLAPD Backend options
 156 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend], no)dnl
 157 OL_ARG_WITH(dnssrv_module,[    --with-dnssrv-module  module type], static,
 158         [static dynamic])
 159 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend], no)dnl
 160 OL_ARG_WITH(ldap_module,[    --with-ldap-module   module type], static,
 161         [static dynamic])
 162 OL_ARG_ENABLE(ldbm,[    --enable-ldbm     enable ldbm backend], yes)dnl
 163 OL_ARG_WITH(ldbm_api,[    --with-ldbm-api       with LDBM API], auto,
 164         [auto berkeley bcompat mdbm gdbm])
 165 OL_ARG_WITH(ldbm_module,[    --with-ldbm-module   module type], static,
 166         [static dynamic])
 167 OL_ARG_WITH(ldbm_type,[    --with-ldbm-type       use LDBM type], auto,
 168         [auto btree hash])
 169 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend], no)dnl
 170 OL_ARG_WITH(passwd_module,[    --with-passwd-module  module type], static,
 171         [static dynamic])
 172 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend], no)dnl
 173 OL_ARG_WITH(shell_module,[    --with-shell-module         module type], static,
 174         [static dynamic])
 175 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend], no)dnl
 176 OL_ARG_WITH(sql_module,[    --with-sql-module     module type], static,
 177         [static dynamic])
 178
 179 dnl ----------------------------------------------------------------
 180 dnl SLURPD OPTIONS
 181 AC_ARG_WITH(xxslurpdoptions,[SLURPD (Replication Daemon) Options:])
 182 OL_ARG_ENABLE(slurpd,[  --enable-slurpd   enable building slurpd], auto)dnl
 183
 184 dnl ----------------------------------------------------------------
 185 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 186 AC_ENABLE_STATIC
 187 dnl AC_DISABLE_SHARED
 188 AC_ENABLE_SHARED
 189
 190 dnl ----------------------------------------------------------------
 191
 192 dnl General "enable" options
 193 # validate options
 194 if test $ol_enable_slapd = no ; then
 195         dnl SLAPD was specificallly disabled
 196         if test $ol_enable_dnssrv = yes ; then
 197                 AC_MSG_WARN([slapd disabled, ignoring --enable-dnssrv argument])
 198         fi
 199         if test $ol_enable_ldap = yes ; then
 200                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 201         fi
 202         if test $ol_enable_ldbm = yes ; then
 203                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 204         fi
 205         if test $ol_enable_passwd = yes ; then
 206                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 207         fi
 208         if test $ol_enable_shell = yes ; then
 209                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 210         fi
 211         if test $ol_enable_sql = yes ; then
 212                 AC_MSG_WARN([slapd disabled, ignoring --enable-sql argument])
 213         fi
 214         if test $ol_enable_modules = yes ; then
 215                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 216         fi
 217 dnl     if test $ol_enable_multimaster = yes ; then
 218 dnl             AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 219 dnl     fi
 220         if test $ol_enable_wrappers = yes ; then
 221                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 222         fi
 223         if test $ol_enable_phonetic = yes ; then
 224                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 225         fi
 226         if test $ol_enable_rlookups = yes ; then
 227                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 228         fi
 229         if test $ol_enable_aci = yes ; then
 230                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 231         fi
 232         if test $ol_with_ldbm_api != auto ; then
 233                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 234         fi
 235         if test $ol_with_ldbm_type != auto ; then
 236                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 237         fi
 238         if test $ol_with_dnssrv_module != static ; then
 239                 AC_MSG_WARN([slapd disabled, ignoring --with-dnssrv-module argument])
 240         fi
 241         if test $ol_with_ldap_module != static ; then
 242                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 243         fi
 244         if test $ol_with_ldbm_module != static ; then
 245                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 246         fi
 247         if test $ol_with_passwd_module != static ; then
 248                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 249         fi
 250         if test $ol_with_shell_module != static ; then
 251                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 252         fi
 253         if test $ol_with_sql_module != static ; then
 254                 AC_MSG_WARN([slapd disabled, ignoring --with-sql-module argument])
 255         fi
 256         if test $ol_enable_slurpd = yes ; then
 257                 AC_MSG_ERROR([slurpd requires slapd])
 258         fi
 259
 260         # force settings to no
 261         ol_enable_dnssrv=no
 262         ol_enable_ldap=no
 263         ol_enable_ldbm=no
 264         ol_enable_passwd=no
 265         ol_enable_shell=no
 266         ol_enable_sql=no
 267
 268         ol_enable_modules=no
 269 dnl     ol_enable_multimaster=no
 270         ol_enable_phonetic=no
 271         ol_enable_rlookups=no
 272         ol_enable_aci=no
 273         ol_enable_wrappers=no
 274         ol_enable_dynamic=no
 275
 276         ol_with_ldbm_api=no
 277         ol_with_ldbm_type=no
 278
 279         ol_with_dnssrv_module=static
 280         ol_with_ldap_module=static
 281         ol_with_ldbm_module=static
 282         ol_with_passwd_module=static
 283         ol_with_shell_module=static
 284         ol_with_sql_module=static
 285
 286         ol_enable_slurpd=no
 287
 288 elif test $ol_enable_ldbm = no ; then
 289         dnl SLAPD without LDBM
 290
 291         if test $ol_with_ldbm_api != auto ; then
 292                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 293         fi
 294
 295         if test $ol_with_ldbm_type != auto ; then
 296                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 297         fi
 298
 299         if test $ol_with_ldbm_module != static ; then
 300                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 301         fi
 302
 303         if test $ol_enable_modules != yes -a \
 304                 $ol_enable_dnssrv = no -a \
 305                 $ol_enable_ldap = no -a \
 306                 $ol_enable_passwd = no -a \
 307                 $ol_enable_shell = no -a \
 308                 $ol_enable_sql = no ; then
 309                 AC_MSG_ERROR([slapd requires a backend])
 310         fi
 311
 312         ol_with_ldbm_api=no
 313         ol_with_ldbm_type=no
 314         ol_with_ldbm_module=static
 315
 316 else
 317         dnl SLAPD with LDBM
 318         if test $ol_with_ldbm_api = gdbm -a \
 319                 $ol_with_ldbm_type = btree ; then
 320                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 321         fi
 322         if test $ol_with_ldbm_api = mdbm -a \
 323                 $ol_with_ldbm_type = btree ; then
 324                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 325         fi
 326         if test $ol_with_ldbm_api = ndbm -a \
 327                 $ol_with_ldbm_type = btree ; then
 328                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 329         fi
 330 fi
 331
 332 if test $ol_enable_slurpd = yes ; then
 333         dnl SLURPD was specifically enabled
 334         if test $ol_with_threads = no ; then
 335                 AC_MSG_ERROR([slurpd requires threads])
 336         fi
 337 fi
 338
 339 if test $ol_enable_kbind = yes -o $ol_enable_kpasswd = yes ; then
 340         if test $ol_with_kerberos = no ; then
 341                 AC_MSG_ERROR([options require --with-kerberos])
 342         fi
 343         ol_with_kerberos=yes
 344 elif test $ol_enable_kbind = no -o $ol_enable_kpasswd = no ; then
 345         if test $ol_with_kerberos != no -a $ol_with_kerberos != auto ; then
 346                 AC_MSG_WARN([Kerberos detection enabled unnecessarily]);
 347         fi
 348         ol_with_kerberos=no
 349 fi
 350
 351 if test $ol_enable_spasswd = yes ; then
 352         if test $ol_with_cyrus_sasl = no ; then
 353                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 354         fi
 355         ol_with_cyrus_sasl=yes
 356 fi
 357
 358 AC_MSG_RESULT(done)
 359
 360 dnl ----------------------------------------------------------------
 361 dnl Initialize vars
 362 LDAP_LIBS=
 363 LDIF_LIBS=
 364 LDBM_LIBS=
 365 LTHREAD_LIBS=
 366 LUTIL_LIBS=
 367
 368 SLAPD_LIBS=
 369 SLURPD_LIBS=
 370
 371 BUILD_SLAPD=no
 372 BUILD_SLURPD=no
 373
 374 BUILD_THREAD=no
 375
 376 BUILD_DNSSRV=no
 377 BUILD_LDAP=no
 378 BUILD_LDBM=no
 379 BUILD_PASSWD=no
 380 BUILD_SHELL=no
 381 BUILD_SQL=no
 382
 383 BUILD_DNSSRV_DYNAMIC=static
 384 BUILD_LDAP_DYNAMIC=static
 385 BUILD_LDBM_DYNAMIC=static
 386 BUILD_PASSWD_DYNAMIC=static
 387 BUILD_SHELL_DYNAMIC=static
 388 BUILD_SQL_DYNAMIC=static
 389
 390 SLAPD_MODULES_LDFLAGS=
 391 SLAPD_MODULES_CPPFLAGS=
 392 SLAPD_MODULES_LIST=
 393
 394 SLAPD_SQL_LDFLAGS=
 395 SLAPD_SQL_LIBS=
 396 SLAPD_SQL_INCLUDES=
 397
 398 KRB4_LIBS=
 399 KRB5_LIBS=
 400 READLINE_LIBS=
 401 SASL_LIBS=
 402 TERMCAP_LIBS=
 403 TLS_LIBS=
 404 MODULES_LIBS=
 405 AUTH_LIBS=
 406
 407 dnl ================================================================
 408 dnl Checks for programs
 409
 410 dnl AC_PROG_INSTALL
 411
 412 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 413
 414 dnl ----------------------------------------------------------------
 415 dnl
 416 dnl Determine which C translator to use
 417 dnl
 418
 419 dnl AIX Thread requires we use cc_r or xlc_r.
 420 dnl But only do this IF AIX and CC is not set
 421 dnl and threads are auto|yes|posix.
 422 dnl
 423 dnl If we find cc_r|xlc_r, force pthreads and assume
 424 dnl             pthread_create is in $LIBS (ie: don't bring in
 425 dnl             any additional thread libraries)
 426 dnl If we do not find cc_r|xlc_r, disable threads
 427
 428 ol_aix_threads=no
 429 case "$target" in
 430 *-*-aix*) dnl all AIX is not a good idea.
 431         if test -z "$CC" ; then
 432                 case "$ol_with_threads" in
 433                 auto | yes |  posix) ol_aix_threads=yes ;;
 434                 esac
 435         fi
 436 ;;
 437 esac
 438
 439 if test $ol_aix_threads = yes ; then
 440         if test -z "${CC}" ; then
 441                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 442
 443                 if test "$CC" = cc ; then
 444                         dnl no CC! don't allow --with-threads
 445                         if test $ol_with_threads != auto ; then
 446                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 447                         else
 448                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 449                         fi
 450                         ol_with_threads=no
 451                 fi
 452         fi
 453
 454         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 455                 ol_with_threads=posix
 456                 ol_cv_pthread_create=yes
 457         fi
 458 fi
 459
 460 if test -z "${CC}"; then
 461         AC_CHECK_PROGS(CC,cc)
 462 fi
 463
 464 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 465 dnl (for now, let autoconf sort this out)
 466 dnl CFLAGS=${CFLAGS-""}
 467
 468 AC_LIBTOOL_WIN32_DLL
 469 AC_LIBTOOL_DLOPEN
 470 AC_PROG_LIBTOOL
 471
 472 AC_PROG_AWK
 473 OL_PROG_LN_H
 474 AC_PROG_LN_S
 475
 476 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 477         LN_S="$LN_H"
 478 fi
 479
 480 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 481         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 482 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 483 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 484
 485 AC_PROG_CPP
 486
 487 dnl ----------------------------------------------------------------
 488 dnl Cross compiling checks
 489 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 490         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 491
 492 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 493         AC_MSG_WARN([programs compiled here do run here...])
 494         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 495
 496 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 497         AC_MSG_WARN([programs compiled here do not run here...])
 498         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 499 fi
 500
 501 dnl ----------------------------------------------------------------
 502 dnl Checks for UNIX Variants
 503 AC_AIX
 504 AC_ISC_POSIX
 505 AC_MINIX
 506
 507 dnl ----------------------------------------------------------------
 508 dnl Checks for system services
 509 AC_CYGWIN
 510 AC_MINGW32
 511 AC_EXEEXT
 512 AC_OBJEXT
 513
 514 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 515
 516 dnl ----------------------------------------------------------------
 517 dnl BeOS requires -lbe -lroot -lnet
 518 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 519
 520 dnl ----------------------------------------------------------------
 521 dnl OpenLDAP requires STDC features
 522 AM_PROG_CC_STDC
 523 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 524         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 525 fi
 526
 527 dnl ----------------------------------------------------------------
 528 dnl Check cc depend flags
 529 OL_MKDEPEND
 530 if test "${ol_cv_mkdep}" = no ; then
 531         # this will soon become an error
 532         AC_MSG_WARN([do not know how to generate dependencies])
 533 fi
 534
 535 dnl ----------------------------------------------------------------
 536 dnl Check for AIX security library
 537 AC_CHECK_LIB(s, afopen, [
 538         AUTH_LIBS=-ls
 539         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 540 ])
 541
 542
 543 dnl ----------------------------------------------------------------
 544 dnl Check for module support
 545 ol_link_modules=no
 546 if test $ol_enable_modules != no ; then
 547         AC_CHECK_HEADERS(ltdl.h)
 548
 549         if test $ac_cv_header_ltdl_h = no ; then
 550                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 551         fi
 552
 553         AC_CHECK_LIB(ltdl, lt_dlinit, [
 554             MODULES_LIBS=-lltdl
 555             AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 556         ])
 557
 558         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 559                 AC_MSG_ERROR([could not locate libtool -lltdl])
 560         fi
 561         ol_link_modules=yes
 562 else
 563         ol_with_dnssrv_module=static
 564         ol_with_ldap_module=static
 565         ol_with_ldbm_module=static
 566         ol_with_passwd_module=static
 567         ol_with_shell_module=static
 568         ol_with_sql_module=static
 569 fi
 570
 571 dnl ----------------------------------------------------------------
 572 dnl Checks for header files.
 573 OL_HEADER_STDC
 574
 575 if test $ol_cv_header_stdc != yes; then
 576         AC_MSG_WARN([could not locate Standard C compliant headers])
 577 fi
 578
 579 AC_HEADER_DIRENT
 580 AC_HEADER_SYS_WAIT
 581 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 582 if test $am_cv_sys_posix_termios = yes ; then
 583         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 584                 [define if you have POSIX termios])
 585 fi
 586
 587 AC_CHECK_HEADERS(       \
 588         arpa/inet.h             \
 589         arpa/nameser.h  \
 590         assert.h                \
 591         conio.h                 \
 592         crypt.h                 \
 593         direct.h                \
 594         errno.h                 \
 595         fcntl.h                 \
 596         filio.h                 \
 597         getopt.h                \
 598         grp.h                   \
 599         io.h                    \
 600         libutil.h               \
 601         limits.h                \
 602         locale.h                \
 603         netinet/tcp.h   \
 604         malloc.h                \
 605         memory.h                \
 606         psap.h                  \
 607         pwd.h                   \
 608         process.h               \
 609         resolv.h                \
 610         sgtty.h                 \
 611         shadow.h                \
 612         stddef.h                \
 613         string.h                \
 614         strings.h               \
 615         sysexits.h              \
 616         sys/file.h              \
 617         sys/filio.h             \
 618         sys/errno.h             \
 619         sys/ioctl.h             \
 620         sys/param.h             \
 621         sys/resource.h  \
 622         sys/select.h    \
 623         sys/socket.h    \
 624         sys/syslog.h    \
 625         sys/time.h              \
 626         sys/types.h             \
 627         syslog.h                \
 628         termios.h               \
 629         unistd.h                \
 630         winsock.h               \
 631 )
 632
 633
 634 dnl ----------------------------------------------------------------
 635 dnl Checks for libraries
 636
 637 dnl SASL and SSL need dlopen on some platforms
 638 AC_CHECK_FUNC(dlopen, :, [AC_CHECK_LIB(dl, dlopen)])
 639
 640 dnl HP-UX requires -lV3
 641 AC_CHECK_LIB(V3, sigset)
 642
 643 dnl Gotta check for winsock manually
 644 if test $ac_cv_header_winsock_h = yes; then
 645         AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 646         AC_TRY_LINK([#include <winsock.h>],[
 647                         socket(0,0,0);
 648                         select(0,NULL,NULL,NULL,NULL);
 649                         closesocket(0);
 650                         gethostname(NULL,0);
 651         ],[ol_cv_winsock=yes],[ol_cv_winsock=no])])
 652
 653         if test $ol_cv_winsock = yes ; then
 654                 AC_DEFINE(HAVE_WINSOCK,1,[define if you have winsock])
 655                 ac_cv_func_socket=yes
 656                 ac_cv_func_select=yes
 657                 ac_cv_func_closesocket=yes
 658                 ac_cv_func_gethostname=yes
 659         fi
 660 fi
 661
 662 dnl Find socket()
 663 dnl Likely combinations:
 664 dnl             -lsocket [ -lnsl_s | -lnsl ]
 665 dnl             -linet
 666
 667 AC_CHECK_FUNC(socket, :, [
 668 dnl hopefully we won't include too many libraries
 669         AC_CHECK_LIB(socket, main)
 670         AC_CHECK_LIB(net, main)
 671         AC_CHECK_LIB(nsl_s, main)
 672         AC_CHECK_LIB(nsl, main)
 673         AC_CHECK_LIB(inet, socket)
 674         AC_CHECK_LIB(gen, main)
 675 ])
 676
 677 dnl require select
 678 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 679
 680 if test "${ac_cv_header_winsock_h}" != yes; then
 681     dnl Select arg types
 682     dnl (if this detection becomes permenent, it and the select() detection
 683     dnl should be done before the yielding select test)
 684     AC_FUNC_SELECT_ARGTYPES
 685 fi
 686
 687 dnl check to see if system call automatically restart
 688 dnl AC_SYS_RESTARTABLE_SYSCALLS
 689
 690 dnl ----------------------------------------------------------------
 691 dnl require POSIX regex
 692 AC_CHECK_HEADERS( regex.h )
 693 if test "$ac_cv_header_regex_h" != yes ; then
 694         AC_MSG_ERROR([POSIX regex.h required.])
 695 fi
 696 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 697
 698 OL_POSIX_REGEX
 699 if test "$ol_cv_c_posix_regex" = no ; then
 700         AC_MSG_ERROR([broken POSIX regex!])
 701 fi
 702
 703 dnl ----------------------------------------------------------------
 704 dnl Check for resolver routines
 705 ol_link_dnssrv=no
 706 AC_CHECK_FUNC(res_query,:)
 707 if test $ac_cv_func_res_query = no ; then
 708         AC_CHECK_LIB(bind, res_query)
 709         ac_cv_func_res_query=$ac_cv_lib_bind_res_query
 710 fi
 711
 712 if test $ac_cv_func_res_query = no ; then
 713         AC_CHECK_LIB(bind, __res_query)
 714         ac_cv_func_res_query=$ac_cv_lib_bind___res_query
 715 fi
 716
 717 if test $ac_cv_func_res_query = no ; then
 718         AC_CHECK_LIB(resolv, res_query)
 719         ac_cv_func_res_query=$ac_cv_lib_resolv_res_query
 720 fi
 721
 722 if test "$ac_cv_func_res_query" = yes ; then
 723         AC_DEFINE(HAVE_RES_QUERY,1,
 724                 [define if you have res_query()])
 725
 726         if test $ol_enable_dnssrv != no ; then
 727                 ol_link_dnssrv=yes
 728         fi
 729 fi
 730
 731 if test "$ol_enable_dnssrv" = yes -a "$ol_link_dnssrv" = no ; then
 732         AC_MSG_ERROR([DNSSRV requires res_query()])
 733 fi
 734
 735 dnl ----------------------------------------------------------------
 736 dnl PF_INET6 support requires getaddrinfo and INET6_ADDRSTRLEN
 737 dnl PF_LOCAL may use getaddrinfo in available
 738 AC_CHECK_FUNCS( getaddrinfo inet_ntop )
 739
 740 ol_link_ipv6=no
 741 if test $ac_cv_func_getaddrinfo = no -o $ac_cv_func_inet_ntop = no ; then
 742         if test $ol_enable_ipv6 = yes ; then
 743                 AC_MSG_ERROR([IPv6 support requires getaddrinfo() and inet_ntop()])
 744         fi
 745 else
 746         AC_CHECK_FUNCS( gai_strerror )
 747
 748         AC_CACHE_CHECK([INET6_ADDRSTRLEN],[ol_cv_inet6_addrstrlen],[
 749                 AC_EGREP_CPP(__has_inet6_addrstrlen__,[
 750 #                       include <netinet/in.h>
 751 #                       ifdef INET6_ADDRSTRLEN
 752                                 __has_inet6_addrstrlen__;
 753 #                       endif
 754                 ], [ol_cv_inet6_addrstrlen=yes], [ol_cv_inet6_addrstrlen=no])])
 755
 756         if test $ol_cv_inet6_addrstrlen = yes ; then
 757                 ol_link_ipv6=yes
 758         elif test $ol_enable_ipv6 = yes ; then
 759                 AC_MSG_ERROR([IPv6 support requires INET6_ADDRSTRLEN])
 760         fi
 761 fi
 762
 763 if test $ol_enable_local != no ; then
 764         AC_CHECK_HEADERS( sys/un.h )
 765
 766         if test $ol_enable_local = auto ; then
 767                 ol_enable_local=$ac_cv_header_sys_un_h
 768         elif test $ac_cv_header_sys_un_h = no ; then
 769                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
 770         fi
 771 fi
 772
 773 dnl ----------------------------------------------------------------
 774 dnl Kerberos
 775 ol_link_kbind=no
 776 ol_link_kpasswd=no
 777 ol_link_krb5=no
 778 ol_link_krb4=no
 779
 780 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
 781         -o $ol_with_kerberos = k5 -o $ol_with_kerberos = k5only \
 782         -o $ol_with_kerberos = k425 ; then
 783
 784         AC_CHECK_HEADERS(krb5.h)
 785
 786         if test $ac_cv_header_krb5_h = yes ; then
 787                 dnl lazy check for Heimdal Kerberos
 788                 AC_CHECK_HEADERS(heim_err.h)
 789                 if test $ac_cv_header_heim_err_h = yes ; then
 790                         krb5_impl=heimdal
 791                 else
 792                         krb5_impl=mit
 793                 fi
 794
 795                 if test $krb5_impl = mit; then
 796                         AC_CHECK_LIB(krb5, main,
 797                                 [have_krb5=yes
 798                                 KRB5_LIBS="-lkrb5 -lcrypto -lcom_err"],
 799                                 [have_krb5=no],
 800                                 [-lcrypto -lcom_err])
 801
 802                 elif test $krb5_impl = heimdal; then
 803                         AC_CHECK_LIB(krb5, main,
 804                                 [have_krb5=yes
 805                                 KRB5_LIBS="-lkrb5 -ldes -lasn1 -lroken -lcom_err"],
 806                                 [have_krb5=no],
 807                                 [-ldes -lasn1 -lroken -lcom_err])
 808
 809                         AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1,
 810                                 [define if you have HEIMDAL Kerberos])
 811                 else
 812                         have_krb5=no
 813                         AC_MSG_WARN([Unrecongized Kerberos V Implementation])
 814                 fi
 815
 816                 if test $have_krb5 = yes ; then
 817                         ol_link_krb5=yes
 818
 819                         AC_DEFINE(HAVE_KRB5, 1,
 820                                 [define if you have Kerberos V])
 821
 822                         if test $ol_enable_kpasswd != no ; then
 823                                 ol_link_kpasswd=yes;
 824                         fi
 825
 826                         if test $ol_with_kerberos = k5only ; then
 827                                 ol_with_kerberos=found
 828                         fi
 829
 830                 elif test $ol_with_kerberos != auto ; then
 831                         AC_MSG_ERROR([Required Kerberos 5 support not available])
 832                 fi
 833
 834         fi
 835 fi
 836
 837 if test $ol_link_krb5 = yes -a \( $ol_with_kerberos = yes -o \
 838         $ol_with_kerberos = auto -o $ol_with_kerberos = k425 \) ; then
 839
 840         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 841
 842         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 843                 if test $krb5_impl = mit; then
 844                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 845                                 KRB4_LIBS="-lkrb4 -ldes425"], [have_k425=no],
 846                                 [-ldes425 -lkrb5 -lcrypto -lcom_err])
 847
 848                 elif test $krb5_impl = heimdal; then
 849                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 850                                 KRB4_LIBS="-lkrb4"], [have_k425=no],
 851                                 [-lkrb5 -ldes -lasn1 -lroken -lcom_err])
 852
 853                 else
 854                         have_425=no
 855                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 856                 fi
 857
 858                 if test $have_k425 = yes ; then
 859                         ol_with_kerberos=found
 860                         ol_link_krb4=yes
 861
 862                         AC_DEFINE(HAVE_KRB425, 1,
 863                                 [define if you have Kerberos V with IV support])
 864                         AC_DEFINE(HAVE_KRB4, 1,
 865                                 [define if you have Kerberos IV])
 866
 867                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 868                                 [ol_cv_var_des_debug], [
 869                                 dnl save the flags
 870                                 save_LIBS="$LIBS"
 871                                 LIBS="$KRB4_LIBS $KRB5_LIBS $LIBS"
 872                                 AC_TRY_LINK([
 873 #include <kerberosIV/krb.h>
 874 #include <kerberosIV/des.h>
 875 extern int des_debug;
 876 ],[
 877 des_debug = 1;
 878 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 879                                 dnl restore the LIBS
 880                                 LIBS="$save_LIBS"
 881                         ])
 882
 883                         if test $ol_cv_var_des_debug = yes ; then
 884                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 885                                         [define if you have Kerberos des_debug])
 886                         fi
 887
 888                         LIBS="$save_LIBS"
 889                 fi
 890         fi
 891 fi
 892
 893 if test $ol_link_krb5 = yes ; then
 894         ol_with_kerberos=found
 895 fi
 896
 897 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
 898         -o $ol_with_kerberos = k4 -o $ol_with_kerberos = kth ; then
 899
 900         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
 901
 902         if test $ac_cv_header_krb_h = yes ; then
 903                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 904
 905                 if test $have_k4 = yes ; then
 906                         ol_with_kerberos=found
 907                         ol_link_krb4=yes
 908
 909                         AC_DEFINE(HAVE_KRB4, 1,
 910                                 [define if you have Kerberos IV])
 911
 912                         KRB4_LIBS="-lkrb -ldes"
 913
 914                         if test $ac_cv_header_krb_archaeology_h = yes ; then
 915                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
 916                                         [define if you have Kth Kerberos])
 917                         fi
 918                 fi
 919         fi
 920 fi
 921
 922 if test $ol_link_krb4 = yes -a $ol_enable_kpasswd != no ; then
 923         ol_link_kpasswd=yes
 924 fi
 925
 926 if test $ol_link_krb4 = yes -a $ol_enable_kbind != no ; then
 927         ol_link_kbind=yes
 928
 929 elif test $ol_enable_kbind = yes ; then
 930         AC_MSG_ERROR([Kerberos IV detection failed])
 931 fi
 932
 933 if test $ol_link_krb4 = yes -o $ol_link_krb5 = yes ; then
 934         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 935
 936 elif test $ol_with_kerberos != auto -a $ol_with_kerberos != no ; then
 937         AC_MSG_ERROR([Kerberos detection failed])
 938 fi
 939
 940 dnl ----------------------------------------------------------------
 941 dnl TLS/SSL
 942 ol_link_tls=no
 943 if test $ol_with_tls != no ; then
 944         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 945
 946         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 947                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 948                         [have_ssleay=yes
 949                         need_rsaref=no],
 950                         [have_ssleay=no],
 951                         [-lcrypto])
 952
 953                 if test $have_ssleay = no ; then
 954                         AC_CHECK_LIB(ssl, SSL_library_init,
 955                                 [have_ssleay=yes
 956                                 need_rsaref=no], [have_ssleay=no],
 957                                 [-lcrypto])
 958                 fi
 959
 960                 if test $have_ssleay = no ; then
 961                         AC_CHECK_LIB(ssl, ssl3_accept,
 962                                 [have_ssleay=yes
 963                                 need_rsaref=yes], [have_ssleay=no],
 964                                 [-lcrypto -lRSAglue -lrsaref])
 965                 fi
 966
 967                 if test $have_ssleay = yes ; then
 968                         ol_with_tls=found
 969                         ol_link_tls=yes
 970
 971                         AC_DEFINE(HAVE_SSLEAY, 1,
 972                                 [define if you have SSLeay or OpenSSL])
 973
 974                         if test $need_rsaref = yes; then
 975                                 AC_DEFINE(HAVE_RSAREF, 1,
 976                                         [define if you have RSAref])
 977
 978                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 979                         else
 980                                 TLS_LIBS="-lssl -lcrypto"
 981                         fi
 982                 fi
 983         fi
 984
 985 else
 986         AC_WARN([TLS privacy protection not supported!])
 987 fi
 988
 989 if test $ol_link_tls = yes ; then
 990         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 991
 992 elif test $ol_with_tls = auto ; then
 993         AC_WARN([Could not locate TLS/SSL package])
 994         AC_WARN([TLS privacy protection not supported!])
 995
 996 elif test $ol_with_tls != no ; then
 997         AC_ERROR([Could not locate TLS/SSL package])
 998 fi
 999
1000 dnl ----------------------------------------------------------------
1001 dnl Tests for reentrant functions necessary to build a
1002 dnl thread_safe -lldap.
1003 AC_CHECK_FUNCS(         \
1004         ctime_r                 \
1005         gethostbyname_r gethostbyaddr_r \
1006 )
1007
1008 if test "$ac_cv_func_ctime_r" = no ; then
1009         ol_cv_func_ctime_r_nargs=0
1010 else
1011         OL_FUNC_CTIME_R_NARGS
1012 dnl     OL_FUNC_CTIME_R_TYPE
1013 fi
1014
1015 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1016         OL_FUNC_GETHOSTBYNAME_R_NARGS
1017 else
1018         ol_cv_func_gethostbyname_r_nargs=0
1019 fi
1020
1021 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1022         OL_FUNC_GETHOSTBYADDR_R_NARGS
1023 else
1024         ol_cv_func_gethostbyaddr_r_nargs=0
1025 fi
1026
1027 if test "$ac_cv_func_ctime_r" = yes \
1028         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
1029         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
1030         -a "$ac_cv_func_gethostbyname_r" = yes \
1031         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
1032         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
1033         -a "$ac_cv_func_gethostbyaddr_r" = yes \
1034         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
1035         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
1036         ; then
1037
1038         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
1039 fi
1040
1041 dnl ----------------------------------------------------------------
1042 dnl Threads?
1043 ol_link_threads=no
1044
1045 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1046         -o $ol_with_threads = nt ; then
1047
1048         OL_NT_THREADS
1049
1050         if test "$ol_cv_nt_threads" = yes ; then
1051         ol_link_threads=nt
1052         ol_with_threads=found
1053         ol_with_yielding_select=yes
1054
1055                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1056                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1057         fi
1058
1059         if test $ol_with_threads = nt ; then
1060                 AC_MSG_ERROR([could not locate NT Threads])
1061         fi
1062 fi
1063
1064 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1065         -o $ol_with_threads = posix ; then
1066
1067         AC_CHECK_HEADERS(pthread.h)
1068
1069         if test $ac_cv_header_pthread_h = yes ; then
1070                 OL_POSIX_THREAD_VERSION
1071
1072                 if test $ol_cv_pthread_version = final ; then
1073                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
1074                                 [define if pthreads API compatible with final spec])
1075                 elif test $ol_cv_pthread_version = draft4 ; then
1076                         AC_DEFINE(HAVE_PTHREADS_D4,1,
1077                                 [define if pthreads API compatible with draft4 spec])
1078                 else
1079                         AC_MSG_ERROR([unknown pthread version])
1080                 fi
1081
1082                 # consider threads found
1083                 ol_with_threads=found
1084
1085                 OL_HEADER_LINUX_THREADS
1086                 OL_HEADER_GNU_PTH_PTHREAD_H
1087
1088                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1089                         AC_CHECK_HEADERS(sched.h)
1090                 fi
1091
1092                 dnl Now the hard part, how to link?
1093                 dnl
1094                 dnl currently supported checks:
1095                 dnl
1096                 dnl Check for no flags
1097                 dnl     pthread_create() in $LIBS
1098                 dnl
1099                 dnl Check special pthread (final) flags
1100                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1101                 dnl     pthread_create() with -kthread (FreeBSD)
1102                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1103                 dnl     pthread_create() with -pthreads (?)
1104                 dnl     pthread_create() with -mthreads (AIX)
1105                 dnl     pthread_create() with -thread (?)
1106                 dnl
1107                 dnl Check pthread (final) libraries
1108                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1109                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1110                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1111                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1112                 dnl     pthread_create() in -lpthread (many)
1113                 dnl     pthread_create() in -lc_r (FreeBSD)
1114                 dnl
1115                 dnl Check pthread (draft4) flags (depreciated)
1116                 dnl     pthread_create() with -threads (OSF/1)
1117                 dnl
1118                 dnl Check pthread (draft4) libraries (depreciated)
1119                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1120                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1121                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1122                 dnl     pthread_create() in -lpthreads (many)
1123                 dnl
1124
1125                 dnl pthread_create in $LIBS
1126                 AC_CACHE_CHECK([for pthread_create in default libraries],
1127                         ol_cv_pthread_create,[
1128                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1129                         [ol_cv_pthread_create=yes],
1130                         [ol_cv_pthread_create=no],
1131                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1132                                 [ol_cv_pthread_create=yes],
1133                                 [ol_cv_pthread_create=no])])])
1134
1135                 if test $ol_cv_pthread_create != no ; then
1136                         ol_link_threads=posix
1137                         ol_link_pthreads=""
1138                 fi
1139
1140 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1141                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1142                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1143                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1144                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1145                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1146
1147                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1148                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1149                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1150                         [ol_cv_pthread_lpthread_lmach_lexc])
1151 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1152 dnl                     [ol_cv_pthread_lpthread_lexc])
1153
1154                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1155                         [ol_cv_pthread_lib_lpthread_woff])
1156
1157                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1158                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1159
1160                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1161
1162                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1163                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1164                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1165                         [ol_cv_pthread_lpthreads_lmach_lexc])
1166                 OL_PTHREAD_TRY([-lpthreads -lexc],
1167                         [ol_cv_pthread_lpthreads_lexc])
1168
1169                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1170
1171                 if test $ol_link_threads != no ; then
1172                         AC_DEFINE(HAVE_PTHREADS,1,
1173                                 [define if you have POSIX Threads])
1174
1175                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1176
1177                         dnl save flags
1178                         save_CPPFLAGS="$CPPFLAGS"
1179                         save_LIBS="$LIBS"
1180                         LIBS="$LTHREAD_LIBS $LIBS"
1181
1182                         dnl All POSIX Thread (final) implementations should have
1183                         dnl sched_yield instead of pthread yield.
1184                         dnl check for both
1185                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1186
1187                         if test $ac_cv_func_sched_yield = no -a \
1188                                 $ac_cv_func_pthread_yield = no ; then
1189                                 dnl Digital UNIX has sched_yield() in -lrt
1190                                 AC_CHECK_LIB(rt, sched_yield,
1191                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1192                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1193                                                 [Define if you have the sched_yield function.])
1194                                         ac_cv_func_sched_yield=yes],
1195                                         [ac_cv_func_sched_yield=no])
1196                         fi
1197                         if test $ac_cv_func_sched_yield = no -a \
1198                                 $ac_cv_func_pthread_yield = no ; then
1199                                 dnl Solaris has sched_yield() stub in -lposix4
1200                                 dnl but we'll use thr_yield instead.
1201                                 AC_CHECK_FUNCS(thr_yield)
1202                         fi
1203                         if test $ac_cv_func_sched_yield = no -a \
1204                                 $ac_cv_func_pthread_yield = no -a \
1205                                 "$ac_cv_func_thr_yield" = no ; then
1206                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1207                         fi
1208
1209                         dnl Check functions for compatibility
1210                         AC_CHECK_FUNCS(pthread_kill pthread_rwlock_destroy)
1211
1212                         dnl Check for pthread_detach with <pthread.h> inclusion
1213                         dnl as it's symbol may have been mangled.
1214                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1215                                 [ol_cv_func_pthread_detach], [
1216                                 dnl save the flags
1217                                 AC_TRY_LINK([
1218 #include <pthread.h>
1219 #ifndef NULL
1220 #define NULL (void*)0
1221 #endif
1222 ],
1223                                         [pthread_detach(NULL);],
1224                                         [ol_cv_func_pthread_detach=yes],
1225                                         [ol_cv_func_pthread_detach=no])
1226                         ])
1227
1228                         if test $ol_cv_func_pthread_detach = no ; then
1229                                 AC_MSG_ERROR([could not locate pthread_detach()])
1230                         fi
1231
1232                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1233                                 [define if you have pthread_detach function])
1234
1235                         dnl Check for setconcurreny functions
1236                         AC_CHECK_FUNCS( \
1237                                 pthread_setconcurrency \
1238                                 pthread_getconcurrency \
1239                                 thr_setconcurrency \
1240                                 thr_getconcurrency \
1241                         )
1242
1243                         OL_SYS_LINUX_THREADS
1244                         OL_LINUX_THREADS
1245
1246                         if test $ol_cv_linux_threads = error; then
1247                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1248                         fi
1249
1250                         AC_CACHE_CHECK([if pthread_create() works],
1251                                 ol_cv_pthread_create_works,[
1252                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1253                                 [ol_cv_pthread_create_works=yes],
1254                                 [ol_cv_pthread_create_works=no],
1255                                 [dnl assume yes
1256                                 ol_cv_pthread_create_works=yes])])
1257
1258                         if test $ol_cv_pthread_create_works = no ; then
1259                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1260                         fi
1261
1262                         dnl Check if select causes an yield
1263                         if test $ol_with_yielding_select = auto ; then
1264                                 AC_CACHE_CHECK([if select yields when using pthreads],
1265                                         ol_cv_pthread_select_yields,[
1266                                 AC_TRY_RUN([
1267 #include <sys/types.h>
1268 #include <sys/time.h>
1269 #include <unistd.h>
1270 #include <pthread.h>
1271 #ifndef NULL
1272 #define NULL (void*) 0
1273 #endif
1274
1275 static int fildes[2];
1276
1277 static void *task(p)
1278         void *p;
1279 {
1280         int i;
1281         struct timeval tv;
1282
1283         fd_set rfds;
1284
1285         tv.tv_sec=10;
1286         tv.tv_usec=0;
1287
1288         FD_ZERO(&rfds);
1289         FD_SET(fildes[0], &rfds);
1290
1291         /* we're not interested in any fds */
1292         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1293
1294         if(i < 0) {
1295                 perror("select");
1296                 exit(10);
1297         }
1298
1299         exit(0); /* if we exit here, the select blocked the whole process */
1300 }
1301
1302 int main(argc, argv)
1303         int argc;
1304         char **argv;
1305 {
1306         pthread_t t;
1307
1308         /* create a pipe to select */
1309         if(pipe(&fildes[0])) {
1310                 perror("select");
1311                 exit(1);
1312         }
1313
1314 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1315         (void) pthread_setconcurrency(2);
1316 #else
1317 #ifdef HAVE_THR_SETCONCURRENCY
1318         /* Set Solaris LWP concurrency to 2 */
1319         thr_setconcurrency(2);
1320 #endif
1321 #endif
1322
1323 #if HAVE_PTHREADS_D4
1324         pthread_create(&t, pthread_attr_default, task, NULL);
1325 #else
1326         pthread_create(&t, NULL, task, NULL);
1327 #endif
1328
1329 #if HAVE_SCHED_YIELD
1330         sched_yield();  /* make sure task runs first */
1331 #else
1332 #ifdef HAVE_PTHREAD_YIELD
1333         pthread_yield();        /* make sure task runs first */
1334 #endif
1335 #endif
1336
1337         exit(2);
1338 }],
1339                                 [ol_cv_pthread_select_yields=no],
1340                                 [ol_cv_pthread_select_yields=yes],
1341                                 [ol_cv_pthread_select_yields=cross])])
1342
1343                                 if test $ol_cv_pthread_select_yields = cross ; then
1344                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1345                                 fi
1346
1347                                 if test $ol_cv_pthread_select_yields = yes ; then
1348                                         ol_with_yielding_select=yes
1349                                 fi
1350                         fi
1351
1352                         dnl restore flags
1353                         CPPFLAGS="$save_CPPFLAGS"
1354                         LIBS="$save_LIBS"
1355                 else
1356                         AC_MSG_ERROR([could not link with POSIX Threads])
1357                 fi
1358         fi
1359
1360         if test $ol_with_threads = posix ; then
1361                 AC_MSG_ERROR([could not locate POSIX Threads])
1362         fi
1363 fi
1364
1365 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1366         -o $ol_with_threads = mach ; then
1367
1368         dnl check for Mach CThreads
1369         AC_CHECK_HEADERS(mach/cthreads.h)
1370         if test $ac_cv_header_mach_cthreads_h = yes ; then
1371                 ol_with_threads=found
1372
1373                 dnl check for cthread support in current $LIBS
1374                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1375
1376                 if test $ol_link_threads = no ; then
1377                         dnl try -all_load
1378                         dnl this test needs work
1379                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1380                                 [ol_cv_cthread_all_load], [
1381                                 dnl save the flags
1382                                 save_LIBS="$LIBS"
1383                                 LIBS="-all_load $LIBS"
1384                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1385                                         cthread_fork((void *)0, (void *)0);
1386                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1387                                 dnl restore the LIBS
1388                                 LIBS="$save_LIBS"
1389                         ])
1390
1391                         if test $ol_cv_cthread_all_load = yes ; then
1392                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1393                                 ol_link_threads=mach
1394                         fi
1395                 fi
1396
1397                 if test $ol_link_threads != no ; then
1398                         : check for cthread specific functionality here
1399                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1400                                 [define if you have Mach Cthreads])
1401                 else
1402                         AC_MSG_ERROR([could not link with Mach CThreads])
1403                 fi
1404         fi
1405
1406         if test $ol_with_threads = mach ; then
1407                 AC_MSG_ERROR([could not locate Mach CThreads])
1408         fi
1409 fi
1410
1411 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1412         -o $ol_with_threads = pth ; then
1413
1414         AC_CHECK_HEADERS(pth.h)
1415
1416         if test $ac_cv_header_pth_h = yes ; then
1417                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1418
1419                 if test $have_pth = yes ; then
1420                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1421                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1422                         ol_link_threads=pth
1423
1424                         if test $ol_with_yielding_select = auto ; then
1425                                 ol_with_yielding_select=yes
1426                         fi
1427                 fi
1428         fi
1429 fi
1430
1431 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1432         -o $ol_with_threads = lwp ; then
1433
1434         dnl check for SunOS5 LWP
1435         AC_CHECK_HEADERS(thread.h synch.h)
1436         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1437                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1438
1439                 if test $have_thr = yes ; then
1440                         AC_DEFINE(HAVE_THR,1,
1441                                 [if you have Solaris LWP (thr) package])
1442                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1443                         ol_link_threads=thr
1444
1445                         if test $ol_with_yielding_select = auto ; then
1446                                 ol_with_yielding_select=yes
1447                         fi
1448
1449                         dnl Check for setconcurreny functions
1450                         AC_CHECK_FUNCS( \
1451                                 thr_setconcurrency \
1452                                 thr_getconcurrency \
1453                         )
1454                 fi
1455         fi
1456
1457         dnl check for SunOS4 LWP
1458         AC_CHECK_HEADERS(lwp/lwp.h)
1459         if test $ac_cv_header_lwp_lwp_h = yes ; then
1460                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1461
1462                 if test $have_lwp = yes ; then
1463                         AC_DEFINE(HAVE_LWP,1,
1464                                 [if you have SunOS LWP package])
1465                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1466                         ol_link_threads=lwp
1467
1468                         if test $ol_with_yielding_select = auto ; then
1469                                 ol_with_yielding_select=no
1470                         fi
1471                 fi
1472         fi
1473 fi
1474
1475 if test $ol_with_yielding_select = yes ; then
1476         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1477                 [define if select implicitly yields])
1478 fi
1479
1480 if test $ol_with_threads = manual ; then
1481         dnl User thinks he can manually configure threads.
1482         ol_link_threads=yes
1483
1484         AC_MSG_WARN([thread defines and link options must be set manually])
1485
1486         AC_CHECK_HEADERS(pthread.h sched.h)
1487         AC_CHECK_FUNCS(sched_yield pthread_yield)
1488         OL_HEADER_LINUX_THREADS
1489
1490         AC_CHECK_HEADERS(mach/cthreads.h)
1491         AC_CHECK_HEADERS(lwp/lwp.h)
1492         AC_CHECK_HEADERS(thread.h synch.h)
1493 fi
1494
1495 if test $ol_link_threads != no -a $ol_link_threads != nt ; then
1496         dnl needed to get reentrant/threadsafe versions
1497         dnl
1498         AC_DEFINE(REENTRANT,1)
1499         AC_DEFINE(_REENTRANT,1)
1500         AC_DEFINE(THREAD_SAFE,1)
1501         AC_DEFINE(_THREAD_SAFE,1)
1502         AC_DEFINE(THREADSAFE,1)
1503         AC_DEFINE(_THREADSAFE,1)
1504         AC_DEFINE(_SGI_MP_SOURCE,1)
1505
1506         dnl The errno declaration may dependent upon _REENTRANT.
1507         dnl If it does, we must link with thread support.
1508         AC_CACHE_CHECK([for thread specific errno],
1509                 [ol_cv_errno_thread_specific], [
1510                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1511                         [ol_cv_errno_thread_specific=yes],
1512                         [ol_cv_errno_thread_specific=no])
1513         ])
1514
1515         dnl The h_errno declaration may dependent upon _REENTRANT.
1516         dnl If it does, we must link with thread support.
1517         AC_CACHE_CHECK([for thread specific h_errno],
1518                 [ol_cv_h_errno_thread_specific], [
1519                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1520                         [ol_cv_h_errno_thread_specific=yes],
1521                         [ol_cv_h_errno_thread_specific=no])
1522         ])
1523
1524         if test $ol_cv_errno_thread_specific != yes \
1525                 -o $ol_cv_h_errno_thread_specific != yes ; then
1526                 LIBS="$LTHREAD_LIBS $LIBS"
1527                 LTHREAD_LIBS=""
1528         fi
1529
1530 dnl When in thread environment, use
1531 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1532 dnl                     || defined( HAVE_FUNC_R )
1533 dnl                     func_r(...);
1534 dnl             #else
1535 dnl             #       if defined( HAVE_THREADS )
1536 dnl                             /* lock */
1537 dnl             #       endif
1538 dnl                             func(...);
1539 dnl             #       if defined( HAVE_THREADS )
1540 dnl                             /* unlock */
1541 dnl             #       endif
1542 dnl             #endif
1543 dnl
1544 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1545 dnl             _POSIX_REENTRANT_FUNCTIONS
1546 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1547 dnl             _POSIX_THREADSAFE_FUNCTIONS
1548 dnl
1549 dnl             and is currently defined in lthread.h
1550 dnl
1551 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1552 dnl
1553 dnl libldap/*.c should only include <lthread.h> iff
1554 dnl LDAP_R_COMPILE is defined.  ie:
1555 dnl             #ifdef LDAP_R_COMPILE
1556 dnl             #       include LDAP_R_COMPILE
1557 dnl             #endif
1558 dnl
1559 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1560 dnl specifically for compiling the threadsafe version of
1561 dnl     the ldap library (-lldap_r).
1562 dnl
1563 dnl     dnl check for reentrant/threadsafe functions
1564 dnl     dnl
1565 dnl     dnl note: these should only be used when linking
1566 dnl     dnl       with $LTHREAD_LIBS
1567 dnl     dnl
1568 dnl     save_CPPFLAGS="$CPPFLAGS"
1569 dnl     save_LIBS="$LIBS"
1570 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1571 dnl     AC_CHECK_FUNCS( \
1572 dnl             gmtime_r \
1573 dnl             gethostbyaddr_r gethostbyname_r \
1574 dnl             feof_unlocked unlocked_feof \
1575 dnl             putc_unlocked unlocked_putc \
1576 dnl             flockfile ftrylockfile \
1577 dnl     )
1578 dnl     CPPFLAGS="$save_CPPFLAGS"
1579 dnl     LIBS="$save_LIBS"
1580 fi
1581
1582 if test $ol_link_threads = no ; then
1583         if test $ol_with_threads = yes ; then
1584                 AC_MSG_ERROR([no suitable thread support])
1585         fi
1586
1587         if test $ol_with_threads = auto ; then
1588                 AC_MSG_WARN([no suitable thread support, disabling threads])
1589                 ol_with_threads=no
1590         fi
1591
1592         AC_DEFINE(NO_THREADS,1,
1593                 [define if you have (or want) no threads])
1594         LTHREAD_LIBS=""
1595 fi
1596
1597 if test $ol_link_threads != no ; then
1598         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1599 fi
1600
1601 dnl ----------------------------------------------------------------
1602 ol_link_ldbm=no
1603
1604 if test $ol_with_ldbm_api = auto \
1605         -o $ol_with_ldbm_api = berkeley \
1606         -o $ol_with_ldbm_api = bcompat ; then
1607
1608         if test $ol_with_ldbm_api = bcompat; then \
1609                 OL_BERKELEY_COMPAT_DB
1610         else
1611                 OL_BERKELEY_DB
1612         fi
1613
1614         if test $ol_cv_berkeley_db != no ; then
1615                 AC_DEFINE(HAVE_BERKELEY_DB,1,
1616                         [define this if Berkeley DB is available])
1617
1618                 ol_link_ldbm=berkeley
1619                 ol_with_ldbm_api=db
1620
1621                 if test $ol_with_ldbm_type = hash ; then
1622                         AC_DEFINE(LDBM_USE_DBHASH,1,
1623                                 [define this to use DBHASH w/ LDBM backend])
1624                 else
1625                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1626                                 [define this to use DBBTREE w/ LDBM backend])
1627                 fi
1628
1629                 dnl $ol_cv_lib_db should be yes or -ldb
1630                 dnl (it could be no, but that would be an error
1631                 if test $ol_cv_lib_db != yes ; then
1632                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1633                 fi
1634         fi
1635 fi
1636
1637 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1638         AC_MSG_WARN(Could not find LDBM with BTREE support)
1639         ol_with_ldbm_api=none
1640 fi
1641
1642 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1643         OL_MDBM
1644
1645         if test $ol_cv_mdbm = yes ; then
1646                 ol_link_ldbm=mdbm
1647                 ol_with_ldbm_api=mdbm
1648                 if test $ol_cv_lib_mdbm != yes ; then
1649                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1650                 fi
1651         fi
1652 fi
1653
1654 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1655         OL_GDBM
1656
1657         if test $ol_cv_gdbm = yes ; then
1658                 ol_link_ldbm=gdbm
1659                 ol_with_ldbm_api=gdbm
1660
1661                 if test $ol_cv_lib_gdbm != yes ; then
1662                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1663                 fi
1664         fi
1665 fi
1666
1667 if test $ol_with_ldbm_api = ndbm ; then
1668         OL_NDBM
1669
1670         if test $ol_cv_ndbm = yes ; then
1671                 ol_link_ldbm=ndbm
1672                 ol_with_ldbm_api=ndbm
1673
1674                 if test $ol_cv_lib_ndbm != yes ; then
1675                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1676                 fi
1677         fi
1678 fi
1679
1680 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1681         AC_MSG_WARN(could not find suitable LDBM backend)
1682         if test $ol_enable_ldbm = yes ; then
1683                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1684         fi
1685
1686         AC_MSG_WARN(disabling LDBM)
1687         ol_enable_ldbm=no
1688 fi
1689
1690 dnl ----------------------------------------------------------------
1691 if test $ol_enable_dynamic = yes -a $enable_shared = yes ; then
1692         LINK_BINS_DYNAMIC="yes"
1693 else
1694         LINK_BINS_DYNAMIC="no"
1695 fi
1696
1697 dnl ----------------------------------------------------------------
1698 if test $ol_enable_wrappers != no ; then
1699         AC_CHECK_HEADERS(tcpd.h)
1700
1701         if test $ac_cv_header_tcpd_h != yes ; then
1702                 have_wrappers=no
1703         else
1704                 AC_TRY_COMPILE([
1705 int allow_severity = 0;
1706 int deny_severity  = 0;
1707                 ],[hosts_access()],[have_wrappers=yes],[have_wrappers=no])
1708         fi
1709
1710         if test $have_wrappers = yes ; then
1711                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1712                 WRAP_LIBS="-lwrap"
1713
1714                 dnl We add another check for -lnsl since some libwrap's
1715                 dnl need it, but it isn't always included from above
1716                 AC_CHECK_LIB(nsl, main)
1717         else
1718                 AC_MSG_WARN(could not find -lwrap)
1719                 if test $ol_enable_wrappers = yes ; then
1720                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1721                 fi
1722
1723                 AC_MSG_WARN(disabling wrappers support)
1724                 ol_enable_wrappers=no
1725                 WRAP_LIBS=""
1726         fi
1727 fi
1728
1729 dnl ----------------------------------------------------------------
1730 if test $ol_enable_syslog != no ; then
1731         AC_CHECK_FUNC(openlog)
1732         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1733                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1734         fi
1735         ol_enable_syslog=$ac_cv_func_openlog
1736 fi
1737
1738 dnl ----------------------------------------------------------------
1739 dnl SQL
1740 ol_link_sql=no
1741 if test $ol_enable_sql != no ; then
1742         AC_CHECK_LIB(iodbc,SQLDriverConnect,[have_iodbc=yes],[have_iodbc=no])
1743         if test $have_iodbc = yes ; then
1744                 ol_link_sql="-liodbc"
1745         else
1746                 AC_CHECK_LIB(odbc,SQLDriverConnect,[have_odbc=yes],[have_odbc=no])
1747                 if test $have_odbc = yes ; then
1748                         ol_link_sql="-lodbc"
1749                 fi
1750         fi
1751
1752         if test $ol_link_sql != no ; then
1753                 SLAPD_SQL_LIBS="$ol_link_sql"
1754
1755         elif test $ol_enable_sql != auto ; then
1756                 AC_MSG_ERROR([could not locate suitable ODBC library])
1757         fi
1758 fi
1759
1760 dnl ----------------------------------------------------------------
1761 dnl ud needs termcap (should insert check here)
1762 ol_link_termcap=no
1763 AC_CHECK_HEADERS(termcap.h ncurses.h)
1764
1765 if test $ol_link_termcap = no ; then
1766         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1767         if test $have_termcap = yes ; then
1768                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1769                 ol_link_termcap=yes
1770                 TERMCAP_LIBS=-ltermcap
1771         fi
1772 fi
1773
1774 if test $ol_link_termcap = no ; then
1775         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1776         if test $have_ncurses = yes ; then
1777                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1778                 ol_link_termcap=yes
1779                 TERMCAP_LIBS=-lncurses
1780         fi
1781 fi
1782
1783 if test $ol_link_termcap = no ; then
1784         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1785         TERMCAP_LIBS=
1786 fi
1787
1788 dnl ----------------------------------------------------------------
1789 dnl
1790 dnl Check for Cyrus SASL
1791 dnl
1792 ol_link_sasl=no
1793 ol_link_spasswd=no
1794 if test $ol_with_cyrus_sasl != no ; then
1795         AC_CHECK_HEADERS(sasl.h)
1796
1797         if test $ac_cv_header_sasl_h = yes ; then
1798                 AC_CHECK_LIB(sasl, sasl_client_init,
1799                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1800
1801                 if test $have_cyrus_sasl != no ; then
1802                         SASL_LIBS="-lsasl"
1803                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1804                         ol_link_sasl=yes
1805                 fi
1806         fi
1807
1808         if test $ol_link_sasl = no ; then
1809                 if test $ol_with_cyrus_sasl != auto ; then
1810                         AC_MSG_ERROR([Could not locate Cyrus SASL])
1811                 else
1812                         AC_MSG_WARN([Could not locate Cyrus SASL])
1813                         AC_MSG_WARN([SASL authentication not supported!])
1814                         if test $ol_link_tls = no ; then
1815                                 AC_MSG_WARN([Strong authentication not supported!])
1816                         fi
1817                 fi
1818
1819         elif test $ol_enable_spasswd != no ; then
1820                 ol_link_spasswd=yes
1821         fi
1822
1823 else
1824         AC_MSG_WARN([SASL authentication not supported!])
1825         if test $ol_link_tls = no ; then
1826                 AC_MSG_WARN([Strong authentication not supported!])
1827         fi
1828 fi
1829
1830 dnl ----------------------------------------------------------------
1831 dnl Check for entropy sources
1832 if test $cross_compiling != yes ; then
1833         dev=no
1834         if test -r /dev/urandom ; then
1835                 dev="/dev/urandom";
1836         elif test -r /idev/urandom ; then
1837                 dev="/idev/urandom";
1838         elif test -r /dev/srandom ; then
1839                 dev="/dev/srandom";
1840         elif test -r /dev/random ; then
1841                 dev="/dev/random";
1842         elif test -r /idev/random ; then
1843                 dev="/idev/random";
1844         fi
1845
1846         if test $dev != no ; then
1847                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
1848         fi
1849 fi
1850
1851 dnl ----------------------------------------------------------------
1852 dnl
1853 dnl Check for fetch URL support
1854 dnl             should be extended to support other fetch URL APIs
1855 dnl
1856 ol_link_fetch=no
1857 if test $ol_with_fetch != no ; then
1858         OL_LIB_FETCH
1859
1860         if test $ol_cv_lib_fetch != no ; then
1861                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1862                 ol_link_fetch=freebsd
1863
1864         elif test $ol_with_fetch != auto ; then
1865                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1866         fi
1867 fi
1868
1869 dnl ----------------------------------------------------------------
1870 dnl
1871 dnl Check for GNU readline
1872 dnl
1873 ol_link_readline=no
1874 if test $ol_with_readline != no ; then
1875         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1876
1877         if test $ac_cv_header_readline_readline_h = yes ; then
1878                 save_LIBS="$LIBS"
1879                 LIBS="$TERMCAP_LIBS $LIBS"
1880                 AC_CHECK_LIB(readline, readline,
1881                         [have_readline=yes], [have_readline=no])
1882                 LIBS="$save_LIBS"
1883
1884                 if test $have_readline = yes ; then
1885                         ol_with_readline=found
1886                         ol_link_readline=yes
1887
1888                         READLINE_LIBS="-lreadline"
1889                 fi
1890         fi
1891 fi
1892
1893 if test $ol_link_readline = yes ; then
1894         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1895 fi
1896
1897
1898 dnl ----------------------------------------------------------------
1899 dnl FreeBSD (and others) have crypt(3) in -lcrypt
1900 if test $ol_enable_crypt != no ; then
1901         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1902                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1903                         have_crypt=yes], [have_crypt=no])])
1904
1905         if test $have_crypt = yes ; then
1906                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1907         else
1908                 AC_MSG_WARN(could not find crypt)
1909                 if test $ol_enable_crypt = yes ; then
1910                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1911                 fi
1912
1913                 AC_MSG_WARN(disabling crypt support)
1914                 ol_enable_crypt=no
1915         fi
1916 fi
1917
1918 dnl ----------------------------------------------------------------
1919 dnl FreeBSD (and others) have setproctitle(3) in -lutil
1920 if test $ol_enable_proctitle != no ; then
1921         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1922                 AC_CHECK_LIB(util, setproctitle,
1923                         [have_setproctitle=yes
1924                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1925                         [have_setproctitle=no
1926                         LIBOBJS="$LIBOBJS setproctitle.o"
1927                         LIBSRCS="$LIBSRCS setproctitle.c"])])
1928
1929         if test $have_setproctitle = yes ; then
1930                 AC_DEFINE(HAVE_SETPROCTITLE,1,
1931                         [define if setproctitle(3) is available])
1932         fi
1933 fi
1934
1935 dnl ----------------------------------------------------------------
1936 dnl Checks for typedefs, structures, and compiler characteristics.
1937 AC_TYPE_MODE_T
1938 AC_TYPE_OFF_T
1939 AC_TYPE_PID_T
1940 AM_TYPE_PTRDIFF_T
1941 AC_TYPE_SIGNAL
1942 AC_TYPE_SIZE_T
1943
1944 AC_CHECK_TYPE(ssize_t, [signed int])
1945 AC_CHECK_TYPE(caddr_t,  [char *])
1946
1947 OL_TYPE_SOCKLEN_T
1948 AC_STRUCT_ST_BLKSIZE
1949 AC_HEADER_TIME
1950 AC_STRUCT_TM
1951 AC_TYPE_UID_T
1952 OL_TYPE_SIG_ATOMIC_T
1953
1954 dnl AC_TYPE_GETGROUPS
1955
1956 OL_STRUCT_PASSWD_PW_GECOS
1957 OL_STRUCT_PASSWD_PW_PASSWD
1958
1959 OL_C_UPPER_LOWER
1960 AC_C_CONST
1961 OL_C_VOLATILE
1962
1963 if test $cross_compiling = yes ; then
1964         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1965 else
1966         AC_C_BIGENDIAN
1967 fi
1968
1969 AC_COMPILE_CHECK_SIZEOF(short)
1970 AC_COMPILE_CHECK_SIZEOF(int)
1971 AC_COMPILE_CHECK_SIZEOF(long)
1972
1973 if test "$ac_cv_sizeof_int" -lt 4 ; then
1974         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
1975
1976         AC_DEFINE(LBER_INT_T,long)
1977 else
1978         AC_DEFINE(LBER_INT_T,int)
1979 fi
1980
1981 AC_DEFINE(LBER_LEN_T,long)
1982 AC_DEFINE(LBER_SOCKET_T,int)
1983 AC_DEFINE(LBER_TAG_T,long)
1984
1985 dnl ----------------------------------------------------------------
1986 dnl Checks for library functions.
1987 AC_FUNC_MEMCMP
1988 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1989 AC_FUNC_STRFTIME
1990 dnl AM_FUNC_STRTOD
1991
1992 OL_FUNC_INET_ATON
1993
1994 dnl Check for NT specific routines
1995 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
1996
1997 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
1998         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
1999 ])
2000
2001 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2002         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2003 ])
2004
2005 AC_FUNC_VPRINTF
2006
2007 if test $ac_cv_func_vprintf = yes ; then
2008         dnl check for vsnprintf
2009         AC_CHECK_FUNCS(vsnprintf vsprintf)
2010 fi
2011
2012 AC_CHECK_FUNCS(         \
2013         bcopy                   \
2014         closesocket             \
2015         chroot                  \
2016         endgrent                \
2017         endpwent                \
2018         fcntl                   \
2019         flock                   \
2020         getdtablesize   \
2021         getgrgid                \
2022         gethostname             \
2023         getpass                 \
2024         getpassphrase   \
2025         getpwuid                \
2026         getpwnam                \
2027         getspnam                \
2028         gettimeofday    \
2029         initgroups              \
2030         lockf                   \
2031         memcpy                  \
2032         memmove                 \
2033         mkstemp                 \
2034         pipe                    \
2035         read                    \
2036         recv                    \
2037         recvfrom                \
2038         setpwfile               \
2039         setgid                  \
2040         setegid                 \
2041         setsid                  \
2042         setuid                  \
2043         seteuid                 \
2044         sigaction               \
2045         signal                  \
2046         sigset                  \
2047         snprintf                \
2048         strdup                  \
2049         strerror                \
2050         strpbrk                 \
2051         strrchr                 \
2052         strsep                  \
2053         strstr                  \
2054         strtol                  \
2055         strtoul                 \
2056         strspn                  \
2057         sysconf                 \
2058         waitpid                 \
2059         wait4                   \
2060         write                   \
2061         send                    \
2062         sendto                  \
2063 )
2064
2065 dnl We actually may need to replace more than this.
2066 AC_REPLACE_FUNCS(getopt tempnam)
2067
2068 if test "$ac_cv_func_getopt" != yes; then
2069     LIBSRCS="$LIBSRCS getopt.c"
2070 fi
2071
2072 if test "$ac_cv_func_tempnam" != yes; then
2073     LIBSRCS="$LIBSRCS tempnam.c"
2074 fi
2075
2076 dnl ----------------------------------------------------------------
2077 # Check Configuration
2078 OL_SYS_ERRLIST
2079
2080 dnl ----------------------------------------------------------------
2081 dnl Sort out defines
2082
2083 if test "$ol_enable_debug" != no ; then
2084         AC_DEFINE(LDAP_DEBUG,1,
2085                 [define this to add debugging code])
2086 fi
2087 if test "$ol_enable_syslog" = yes ; then
2088         AC_DEFINE(LDAP_SYSLOG,1,
2089                 [define this to add syslog code])
2090 fi
2091 if test "$ol_enable_cache" = no ; then
2092         AC_DEFINE(LDAP_NOCACHE,1,
2093                 [define this to remove -lldap cache support])
2094 fi
2095 if test "$ol_link_kbind" != no ; then
2096         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_KBIND,LDAP_VENDOR_VERSION)
2097 fi
2098 if test "$ol_enable_proctitle" != no ; then
2099         AC_DEFINE(LDAP_PROCTITLE,1,
2100                 [define this for LDAP process title support])
2101 fi
2102 if test "$ol_enable_referrals" != no ; then
2103         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
2104 fi
2105 if test "$ol_enable_local" != no; then
2106         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2107 fi
2108 if test "$ol_link_ipv6" != no; then
2109         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2110 fi
2111 if test "$ol_enable_cleartext" != no ; then
2112         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2113 fi
2114 if test "$ol_enable_crypt" != no ; then
2115         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2116 fi
2117 if test "$ol_link_kpasswd" != no ; then
2118         AC_DEFINE(SLAPD_KPASSWD,1,[define to support Kerberos passwords])
2119 fi
2120 if test "$ol_link_spasswd" != no ; then
2121         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2122 fi
2123 dnl if test "$ol_enable_multimaster" != no ; then
2124 dnl     AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2125 dnl fi
2126 if test "$ol_enable_phonetic" != no ; then
2127         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
2128 fi
2129 if test "$ol_enable_rlookups" != no ; then
2130         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2131 fi
2132 if test "$ol_enable_aci" != no ; then
2133         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2134 fi
2135
2136 if test "$ol_link_modules" != no ; then
2137         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2138         BUILD_SLAPD=yes
2139         SLAPD_MODULES_LDFLAGS="-dlopen self"
2140 fi
2141
2142 if test "$ol_link_dnssrv" != no ; then
2143         AC_DEFINE(SLAPD_DNSSRV,1,[define to support DNS SRV backend])
2144         BUILD_SLAPD=yes
2145         BUILD_DNSSRV=yes
2146         if test "$ol_with_dnssrv_module" != static ; then
2147                 AC_DEFINE(SLAPD_DNSSRV_DYNAMIC,1,
2148                         [define to support dynamic DNS SRV backend])
2149                 BUILD_DNSSRV=mod
2150                 BUILD_DNSSRV_DYNAMIC=shared
2151                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-dnssrv/back_dnssrv.la"
2152         fi
2153 fi
2154
2155 if test "$ol_enable_ldap" != no ; then
2156         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
2157         BUILD_SLAPD=yes
2158         BUILD_LDAP=yes
2159         if test "$ol_with_ldap_module" != static ; then
2160                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
2161                         [define to support dynamic LDAP backend])
2162                 BUILD_LDAP=mod
2163                 BUILD_LDAP_DYNAMIC=shared
2164                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
2165         fi
2166 fi
2167
2168 if test "$ol_link_ldbm" != no ; then
2169         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
2170         BUILD_SLAPD=yes
2171         BUILD_LDBM=yes
2172         if test "$ol_with_ldbm_module" != static ; then
2173                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
2174                         [define to support dynamic LDBM backend])
2175                 BUILD_LDBM=mod
2176                 BUILD_LDBM_DYNAMIC=shared
2177                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
2178         fi
2179 fi
2180
2181 if test "$ol_enable_passwd" != no ; then
2182         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2183         BUILD_SLAPD=yes
2184         BUILD_PASSWD=yes
2185         if test "$ol_with_passwd_module" != static ; then
2186                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2187                         [define to support dynamic PASSWD backend])
2188                 BUILD_PASSWD=mod
2189                 BUILD_PASSWD_DYNAMIC=shared
2190                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
2191         fi
2192 fi
2193
2194 if test "$ol_enable_shell" != no ; then
2195         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2196         BUILD_SLAPD=yes
2197         BUILD_SHELL=yes
2198         if test "$ol_with_shell_module" != static ; then
2199                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2200                         [define to support dynamic SHELL backend])
2201                 BUILD_SHELL=mod
2202                 BUILD_SHELL_DYNAMIC=shared
2203                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2204         fi
2205 fi
2206
2207 if test "$ol_enable_sql" != no ; then
2208         AC_DEFINE(SLAPD_SQL,1,[define to support SQL backend])
2209         BUILD_SLAPD=yes
2210         BUILD_SQL=yes
2211         if test "$ol_with_sql_module" != static; then
2212                 AC_DEFINE(SLAPD_SQL_DYNAMIC,1,
2213                         [define to support dynamic SQL backend])
2214                 BUILD_SQL=mod
2215                 BUILD_SQL_DYNAMIC=shared
2216                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-sql/back_sql.la"
2217         fi
2218 fi
2219
2220 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2221         $BUILD_SLAPD = yes ; then
2222         BUILD_SLURPD=yes
2223 fi
2224
2225 dnl ----------------------------------------------------------------
2226
2227 if test "$LINK_BINS_DYNAMIC" = yes; then
2228     LIB_LINKAGE=DYN
2229     LT_LIB_LINKAGE=shared
2230 else
2231     LIB_LINKAGE=STAT
2232     LT_LIB_LINKAGE=static
2233 fi
2234
2235 if test "$ac_cv_mingw32" = yes ; then
2236     PLAT=NT
2237     DYN_EXT=dll
2238 else
2239     PLAT=UNIX
2240     DYN_EXT=so
2241 fi
2242
2243 AC_SUBST(LIBSRCS)
2244
2245 AC_SUBST(PLAT)
2246 AC_SUBST(LIB_LINKAGE)
2247 AC_SUBST(LT_LIB_LINKAGE)
2248 AC_SUBST(DYN_EXT)
2249
2250 AC_SUBST(BUILD_SLAPD)
2251   AC_SUBST(BUILD_DNSSRV)
2252   AC_SUBST(BUILD_LDAP)
2253   AC_SUBST(BUILD_LDBM)
2254   AC_SUBST(BUILD_PASSWD)
2255   AC_SUBST(BUILD_SHELL)
2256   AC_SUBST(BUILD_SQL)
2257   AC_SUBST(BUILD_DNSSRV_DYNAMIC)
2258   AC_SUBST(BUILD_LDAP_DYNAMIC)
2259   AC_SUBST(BUILD_LDBM_DYNAMIC)
2260   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2261   AC_SUBST(BUILD_SHELL_DYNAMIC)
2262   AC_SUBST(BUILD_SQL_DYNAMIC)
2263 AC_SUBST(BUILD_SLURPD)
2264
2265 AC_SUBST(LDAP_LIBS)
2266 AC_SUBST(LDIF_LIBS)
2267 AC_SUBST(SLAPD_LIBS)
2268 AC_SUBST(SLURPD_LIBS)
2269 AC_SUBST(LDBM_LIBS)
2270 AC_SUBST(LTHREAD_LIBS)
2271 AC_SUBST(LUTIL_LIBS)
2272 AC_SUBST(WRAP_LIBS)
2273 AC_SUBST(LINK_BINS_DYNAMIC)
2274
2275 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2276 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2277 AC_SUBST(SLAPD_MODULES_LIST)
2278
2279 AC_SUBST(KRB4_LIBS)
2280 AC_SUBST(KRB5_LIBS)
2281 AC_SUBST(READLINE_LIBS)
2282 AC_SUBST(SASL_LIBS)
2283 AC_SUBST(TERMCAP_LIBS)
2284 AC_SUBST(TLS_LIBS)
2285 AC_SUBST(MODULES_LIBS)
2286 AC_SUBST(AUTH_LIBS)
2287
2288 AC_SUBST(SLAPD_SQL_LDFLAGS)
2289 AC_SUBST(SLAPD_SQL_LIBS)
2290 AC_SUBST(SLAPD_SQL_INCLUDES)
2291
2292 dnl ----------------------------------------------------------------
2293 dnl final output
2294 dnl
2295
2296 AC_OUTPUT( \
2297 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2298 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2299 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2300 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2301 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2302 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2303 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2304 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2305 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2306 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2307 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2308 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2309 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2310 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2311 clients/maildap/Makefile:build/top.mk:clients/maildap/Makefile.in:build/rules.mk \
2312 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2313 include/Makefile:build/top.mk:include/Makefile.in \
2314 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2315 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2316 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2317 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2318 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2319 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2320 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2321 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2322 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2323 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2324 servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk \
2325 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2326 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2327 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2328 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2329 servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk \
2330 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2331 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2332 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2333 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2334 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2335 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2336 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2337 ,[
2338 date > stamp-h
2339 echo Please \"make depend\" to build dependencies
2340 ])